RNR      TITLE 'IHKRNR - RENUMBER COMMAND PROCESSOR'                    00100019
         TITLE 'IHKRNR - RENUMBER COMMAND PROCESSOR'                    00200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00300019
*STATUS                                                               * 00400019
*   CHANGE LEVEL 0                                                    * 00500019
*FUNCTION                                                             * 00600019
*   THE OPERANDS, IF ANY, OF THE SUBCOMMAND ARE CHECKED.  THE FIRST   * 00700019
*   OPERAND IS ASSUMED TO BE THE STARTING LINE NUMBER AND THE SECOND, * 00800019
*   IF PRESENT, IS ASSUMED TO BE THE INCREMENT.  A MAXIMUM OF TWO     * 00900019
*   OPERANDS IS ALLOWED.  EACH OPERAND MUST BE NUMERIC AND NO MORE    * 01000019
*   THAN EIGHT CHARACTERS IN LENGTH.  THE INCREMENT OPERAND MAY NOT   * 01100019
*   BE ZERO.  IF AN ERROR IS FOUND, AN ERROR MESSAGE IS QUEUED FOR    * 01200019
*   THE USER AND RETURN IS MADE TO THE CALLING ROUTINE.  THE DEFAULT  * 01300019
*   VALUE FOR ANY MISSING OPERANDS IS TEN.                            * 01400019
*   THE DATA SET INCREMENT ATTRIBUTE IN THE DIR IS REPLACED BY THE    * 01500019
*   NEW INCREMENT VALUE.  IF A RENUMBER SUBCOMMAND IS ENTERED FOR A   * 01600019
*   NULL DATA SET, THEN RETURN IS MADE TO THE CALLING ROUTINE AFTER   * 01700019
*   THE DIR IS UPDATED.                                               * 01800019
*   AFTER THE OPERAND VALUES ARE STORED IN A WORK AREA, A UTILITY     * 01900019
*   GLOBAL FILE IS ACCESSED.  A BLOCK OF RECORDS IS READ FROM THE     * 02000019
*   ACTIVE FILE AND THE KEYS ARE RESEQUENCED.  IF LINE NUMBERS ARE    * 02100019
*   INCLUDED IN THE LINE TUBCORRN WILL BE SET ON AND THEY ARE         * 02200019
*   ALSO CHANGED.  WHEN ALL LINES IN THE BLOCK ARE RESEQUENCED, THE   * 02300019
*   BLOCK IS WRITTEN TO THE UTILITY FILE.  THIS PROCESS CONTINUES     * 02400019
*   UNTIL EOD IS ENCOUNTERED IN THE ACTIVE FILE.  THE UTILITY FILE    * 02500019
*   IS THEN READ AND THE UPDATED LINES ARE WRITTEN BACK TO THE        * 02600019
*   ACTIVE FILE.  THE UTILITY FILE IS RELEASED WHEN THE ENTIRE FILE   * 02700019
*   HAS BEEN WRITTEN BACK AND CONTROL IS RETURNED TO THE CALLING      * 02800019
*   ROUTINE.                                                          * 02900019
*ENTRY POINTS                                                         * 03000019
*        IHKRNR  TO RENUMBER A DATA SET AND/OR CHANGE THE DATA SET    * 03100019
*        INCREMENT ATTRIBUTE                                          * 03200019
*        FOR ASSOCIATED PARAMETER LIST, SEE INPUT                     * 03300019
*INPUT                                                                * 03400019
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING     * 03500019
*   THE ADDRESSES OF THE TUB AND THE AVT                              * 03600019
*OUTPUT                                                               * 03700019
*   N/A                                                               * 03800019
*EXTERNAL REFERENCES                                                  * 03900019
*        IHKNUM TO VERIFY NUMERIC OPERANDS                            * 04000019
*        IHKAFI  TO MANIPULATE ACTIVE FILE AND GLOBAL UTILITY FILE    * 04100019
*        IHKMSG  TO QUEUE ERROR MESSAGES  (ENTRY POINT: IHKMSG01)     * 04200019
*EXITS, NORMAL                                                        * 04300019
*   RETURN TO CALLING ROUTINE WITH ZERO IN REGISTER 15                * 04400019
*EXITS, ERROR                                                         * 04500019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN        * 04600019
*   CODES IN REGISTER 15                                              * 04700019
*   4  - LINE ERROR                                                   * 04800019
*   8  - GETMAIN FAILED                                               * 04900019
*   12 - ACTIVE AREA I/O ERROR                                        * 05000019
*   16 - ERROR MESSAGE LOST                                           * 05100019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 05200019
*TABLES/WORK AREAS                                                    * 05300019
*   18-WORD SAVE AREA                                                 * 05400019
*   888-BYTE BUFFER USED BY AFIO                                      * 05500019
*   TUB                                                               * 05600019
*   TUBPPTAD - CONTAINS ADDRESS OF PPT                                * 05700019
*   TUBUFFAD - CONTAINS ADDRESS OF USER BUFFER                        * 05800019
*   TUBFLG2 - TESTED TO DETERMINE IF LINE NUMBERS ARE INCLUDED        * 05900019
*   TUBPRMLS - CONTAINS PARAMETER LIST FOR CALLS TO IHKNUM, IHKAFI,   * 06000019
*              AND IHKMSG                                             * 06100019
*   AFIO CONTROL INFORMATION                                          * 06200019
*   PPT - CONTAINS RENUMBER SUBCOMMAND AND OPERANDS                   * 06300019
*   USER BUFFER - LAST 48 BYTES USED AS WORK AREA                     * 06400019
*   DIR                                                               * 06500019
*   DIRINCRE - CONTAINS DATA SET INCREMENT ATTRIBUTE                  * 06600019
*ATTRIBUTES                                                           * 06700019
*   REENTRANT AND NONRESIDENT                                         * 06800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 06900019
         EJECT                                                          07000019
IHKRNR   CSECT                                                          07100019
         SPACE                                                          07200019
*********************************************************************** 07300019
*                         REGISTER EQUATES                            * 07400019
*********************************************************************** 07500019
         SPACE                                                          07600019
R0       EQU   0                                                        07700019
R1       EQU   1                                                        07800019
R2       EQU   2                             AVT                        07900019
R3       EQU   3                             TUB                        08000019
R4       EQU   4                             PPT & RAFIO BUFFER POINTER 08100019
R5       EQU   5                             PPT POINTER & DEFAULT TBL  08200019
R6       EQU   6                             USER BUFFER                08300019
R7       EQU   7                             WORK                       08400019
R8       EQU   8                                                        08500019
R9       EQU   9                             WORK                       08600019
R10      EQU   10                            RAFIO BUFFER               08700019
R11      EQU   11                            BASE                       08800019
R12      EQU   12                            WORK                       08900019
R13      EQU   13                                                       09000019
R14      EQU   14                                                       09100019
R15      EQU   15                                                       09200019
         SPACE 2                                                        09300019
         SAVE  (14,12),,IHKRNR-11/17/69                                 09400019
         LR    R11,R15                       INITLZ BASE REG            09500019
         USING IHKRNR,R11                                               09600019
         L     R3,0(R1)                      R3 HAS TUB ADDR            09700019
         USING TUBDSECT,R3                                              09800019
         L      R2,4(R1)                     R2 HAS AVT ADDR            09900019
         USING AVTDSECT,R2                                              10000019
         EJECT                                                          10100019
*********************************************************************** 10200019
*                         GETMAIN FOR SAVE AREA                       * 10300019
*********************************************************************** 10400019
         SPACE                                                          10500019
         L     R1,IHKYYGML                                              10600019
         LA    R7,72                                                    10700019
         LA    R8,TUBPARM1                                              10800019
         GETMAIN   EC,LV=(R7),A=(R8),MF=(E,(1))                         10900019
         L     R12,TUBPARM1                                             11000019
         LTR   R15,R15                       WAS REQUEST SUCCESSFUL?    11100019
         BZ    CHAINSAV                      YES, CHAIN SAVE AREAS      11200019
GETERR   LA    R15,EIGHT                     NO, LD R15 WITH RTRN CD 8  11300019
         B     RNRRET                        BR TO RETURN               11400019
CHAINSAV ST    R12,8(R13)                    CHAIN SAVE AREAS           11500019
         ST    R13,4(R12)                                               11600019
         LR    R13,R12                                                  11700019
         L     R4,TUBPPTAD                   R4 HAS PPT ADDR            11800019
         USING PPTDSECT,R4                                              11900019
         L     R6,TUBUFFAD                   R6 HAS USER BUFFER ADDR    12000019
         USING WKDSECT,R6                                               12100019
         MVC   WKAREA(1),ZERO                INITLZ WORK AREA WITH ZERO 12200019
         MVC   WKAREA+1(39),WKAREA                                      12300019
         LA    R14,TSTOP1                                               12400019
         SPACE                                                          12500019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 12600019
*              ROUTINE TO CHECK FOR LAST OPERAND                      * 12700019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 12800019
         SPACE                                                          12900019
PPTRTN1  LA    R5,PPTPARS                    R5 HAS ADDR OF LNG CD      13000019
PPTRTN2  CLI   0(R5),HEXFF                   ANY MORE OPERANDS IN PPT?  13100019
         BNE   PPTRTN3                       YES, BRANCH                13200019
         CLC   PPTCHAD+1(3),ZERO             IS THERE ANOTHER PPT?      13300019
         BE    PPTRTN3                       NO, BRANCH                 13400019
         L     R4,PPTCHAD                    R4 HAS ADDR OF NEXT PPT    13500019
         DROP  R4                                                       13600019
         USING PPTDSECT,R4                                              13700019
         B     PPTRTN1                       BR, CHK FOR MORE OPNDS     13800019
PPTRTN3  BR    R14                           PPT RTN EXIT               13900019
 EJECT                                                                  14000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 14100019
*                        OPERAND VERIFICATION                         * 14200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 14300019
         SPACE                                                          14400019
TSTOP1   CLI   0(R5),HEXFF                   ANY OPERANDS IN PPT?       14500019
         BE    TSTOP5                        NO, BRANCH                 14600019
         OI    SWITCH,SLINE                  SET LINENUM SWITCH ON      14700019
         LA    R7,WLINUM                     R7 HAS ADDR FOR LINENUM    14800019
TSTOP2   TM    0(R5),PARENS                  IS OPND IN PARENTHESIS?    14900019
         BZ    TSTOP2A                       NO, CONTINUE PROCESSING    15000019
         NI    0(R5),PARENSF                 SET OFF PARENTHESIS INDR   15100019
         IC    R8,0(R5)                      SAVE LNG                   15200019
         BAL   R9,E302                       SEND ERROR MSG             15300019
         STC   R8,0(R5)                      REPLACE OPND LNG           15400019
TSTOP2A  ST    R7,TUBPARM5                   ST ADDR FOR CHKD OPND      15500019
         ST    R5,TUBPARM3                   STORE OPRND LENGTH ADDR    15600019
         LA    R7,1(0,R5)                    R7 HAS ADDR OF OPRND       15700019
         ST    R7,TUBPARM4                   STORE R7 IN PARM LIST      15800019
         OI    TUBPARM5,HEX80                FLAG LAST WORD OF PARMLIST 15900019
         LA    R1,TUBPARM3                   R1 HAS ADDR OF PARM LIST   16000019
         SR    R7,R7                         MOVE ZEROS TO R7           16100019
         IC    R7,0(R5)                      R7 HAS OPERAND LENGTH      16200019
         L     R15,IHKYYNUM                  R15 HAS ADDR OF IHKNUM     16300019
         BALR  R14,R15                       CHECK LENGTH & NUMERICS    16400019
         LTR   R15,R15                       IS OPERAND VALID?          16500019
         BNZ   E307302                       NO, BRANCH                 16600019
         TM    SWITCH,SINCRE                 IS INCREMENT SWITCH ON?    16700019
         BZ    TSTOP3                        NO, CONTINUE TESTING PPT   16800019
         PACK  WINCRE(8),WINCRE(8)           *  CONVERT ZONED           16900019
         CVB   R8,WINCRE                     *    INCREMENT             17000019
         ST    R8,WORKINC                    *  TO BINARY               17100019
         LTR   R8,R8                         DOES INCREMENT = 0 ?       17200019
         BZ    E307302                       YES, SEND ERROR MSG        17300019
 EJECT                                                                  17400019
TSTOP3   LA    R5,1(R7,R5)                   INCREMENT TO NEXT LENGTH   17500019
         LA    R15,PPTRTN2                   R15 HAS ADDR OF PPT RTN    17600019
         BALR  R14,R15                       CHECK FOR NEXT OPRND       17700019
         CLI   0(R5),HEXFF                   IS THERE ANOTHER OPERAND?  17800019
         BE    TSTOP5                        NO, BRANCH                 17900019
         TM    SWITCH,SINCRE                 IS INCREMENT SWITCH ON?    18000019
         BNZ   E334                          YES, BRANCH EXCESSIVE OPS  18100019
         OI    SWITCH,SINCRE                 SET INCREMENT SWITCH ON    18200019
         LA    R7,WINCRE                     R7 HAS ADDR FOR INCREMENT  18300019
         B     TSTOP2                        BR TO VALIDATE INCREMENT   18400019
TSTOP5   TM    SWITCH,SERROR                 WERE THE OPERANDS VALID?   18500019
         BNZ   FREESAV                       NO, BRANCH                 18600019
         DROP  R4                                                       18700019
         TM    SWITCH,SINCRE                 WAS AN INCREMENT SUBMITTED 18800019
         BNZ   PACLIN                        YES, PACK LINE NUMBER      18900019
         MVI   WORKINC+3,TEN                 NO, ST DEFAULT INCREMENT   19000019
         TM    SWITCH,SLINE                  WAS A LINE NO. SUBMITTED   19100019
         BNZ   PACLIN                        YES, PACK LINE NUMBER      19200019
         MVI   WORKLIN+3,TEN                 NO, ST DEFAULT LINE NO 10  19300019
         L     R7,WORKLIN                    * CONVERT LINE NUMBER      19400019
         CVD   R7,WTEMPLIN                   *    FROM BINARY           19500019
         UNPK  WLINUM(8),WTEMPLIN(8)         * TO ZONED DECIMAL         19600019
         OI    WLINUM+7,HEXF0                                           19700019
         B     TSTOP6                        PROCESS THE ACTIVE AREA    19800019
PACLIN   PACK  WTEMPLIN(8),WLINUM(8)         *  CONVERT ZONED           19900019
         CVB   R7,WTEMPLIN                   *    LINE NO.              20000019
         ST    R7,WORKLIN                    *   TO BINARY              20100019
TSTOP6   SR    R5,R5                         R5 = ZERO                  20200019
         SR    R7,R7                         R7 = ZERO                  20300019
         EJECT                                                          20400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 20500019
*            RETRIEVE RECORDS FROM ACTIVE FILE                        * 20600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 20700019
         SPACE                                                          20800019
         SPACE                                                          20900019
*                        CHECK FOR NULL FILE                          * 21000019
         SPACE                                                          21100019
RAFRTN1  BAL   R14,RAFPARM                   SET UP RAFIO PARM LIST     21200019
         ST    R6,TUBRAFBF                   PROVIDE ADDR OF USER BFR   21300019
         OI    TUBAFISW,TUBFCTLN             USE BFR CONTROL            21400019
         RPOINT B,R,KEY=FIRST                POINT TO FIRST RECORD      21500019
         NI    TUBAFISW,TUBFCTLF             DROP BFR CONTROL           21600019
         B     PNTA1(R15)                    BRANCH ON RAFIO RETURN CD  21700019
PNTA1    B     RAFRTN2                       RETURN CD 0 GOOD RETURN    21800019
         B     NULLFILE                      RETURN CD 4, NULL FILE     21900019
         B     RAFRTN2                       RETURN CD 8 NOT APPLICABLE 22000019
         OI    SRETSW,SRET12                 RETURN CD 12 I/O ERROR     22100019
         B     FREESAV                                                  22200019
         SPACE                                                          22300019
*                        CREATE GLOBAL UTILITY FILE                   * 22400019
         SPACE                                                          22500019
RAFRTN2  BAL   R14,RAFPARM                                              22600019
         CREATE IS,ACTNUM=8,FTYPE=XGBL       CREATE GLOBAL WORK FILE    22700019
         B     CRTG1(R15)                    BRANCH ON RAFIO RETURN CD  22800019
CRTG1    B     RAFRTN3                       RETURN CD 0 GOOD RETURN    22900019
         B     RET20B                        RETURN CD 4                23000019
         B     RAFRTN3                       RETURN CD 8 NOT APPLICABLE 23100019
         OI    SRETSW,SRET12                 RETURN CD 12 I/O ERROR     23200019
         B     REP7                                                     23300019
 EJECT                                                                  23400019
*                        GETMAIN FOR AFIO BUFFER                      * 23500019
         SPACE                                                          23600019
RAFRTN3  GETMAIN EC,LV=888,A=SAVAD,SP=0      GETMAIN FOR AFIO BUFFER    23700019
         LTR   R15,R15                       WAS GETMAIN SUCCESSFUL?    23800019
         BZ    RAFRTN3A                      YES, PROCEED               23900019
         OI    SRETSW,SRET08                 RETURN CD 8 GETMAIN FAIL   24000019
         B     REP6B                                                    24100019
RAFRTN3A L     R10,SAVAD                     R10 HAS ADDR OF BFR AREA   24200019
         USING RAFDSECT,R10                                             24300019
         ST    R10,TUBRAFBF                  ST BFR ADDR IN TUB         24400019
         BAL   R14,RAFPARM                   SET UP PARMLIST FOR AFIO   24500019
         RPOINT B,NR,KEY=FIRST,FTYPE=XGBL    POINT TO START OF FILE     24600019
         B     PNTG1(R15)                    BRANCH ON RAFIO RETURN CD  24700019
PNTG1    B     RAFRTN4                       RETURN CD 0 GOOD RETURN    24800019
         B     RAFRTN4                       RETURN CD 4                24900019
         B     RAFRTN4                       RETURN CD 8 NOT APPLICABLE 25000019
         OI    SRETSW,SRET12                 RETURN CD 12 I/O ERROR     25100019
         B     REP6A                                                    25200019
 EJECT                                                                  25300019
*                        GET RECORDS FROM ACTIVE FILE                 * 25400019
         SPACE                                                          25500019
RAFRTN4  MVI   TUBCNTFS,HEX00                                           25600019
         MVI   TUBCNTFS+1,TEN                SET RECORD COUNT FOR GET   25700019
         BAL   R14,RAFPARM                   SET UP RAFIO PARM LIST     25800019
         OI    TUBAFISW,TUBFCTLN             USE BFR CONTROL            25900019
         RGET  R,M,A                         GET RECORDS FROM ACTIVE    26000019
         NI    TUBAFISW,TUBFCTLF             DROP BFR CONTROL           26100019
         B     GETA1(R15)                    BRANCH ON RAFIO RETURN CD  26200019
GETA1    B     RAFRTN5                       RETURN CD 0 GOOD RETURN    26300019
         B     EOD                           RETURN CD 4                26400019
         B     RAFRTN5                       RETURN CD 8 NOT APPLICABLE 26500019
         B     ERR1                          RETURN CD 12 I/O ERROR     26600019
RAFRTN5  BAL   R14,RAFPARM                   SET UP RAFIO PARM LIST     26700019
         OI    TUBAFISW,TUBFCTLN             USE BFR CONTROL            26800019
         RGET  XK,S,B                        GET KEY FOR NEXT BLOCK     26900019
         NI    TUBAFISW,TUBFCTLF             DROP BFR CONTROL           27000019
         B     GETA2(R15)                    BRANCH ON RAFIO RETURN CD  27100019
GETA2    B     RNR0                          RETURN CD 0 GOOD RETURN    27200019
         B     EOD                           RETURN CD 4                27300019
         B     RNR0                          RETURN CD 8 NOT APPLICABLE 27400019
         B     ERR1                          RETURN CD 12 I/O ERROR     27500019
EOD      OI    SWITCH,SEOD                   SET EOD SWITCH ON          27600019
         EJECT                                                          27700019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 27800019
*                           RENUMBER RECORDS                          * 27900019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 28000019
         SPACE                                                          28100019
RNR0     IC    R5,TUBCNTFS                   NO OF RECORDS RETRIEVED    28200019
         CLI   TUBCNTFS,HEX00                ANY RECORDS RETRIEVED?     28300019
         BH    RNR1                          YES, BR TO RENUMBER RCDS   28400019
         TM    SWITCH,SFIRST                 NO, ANY PRIOR RETRIEVALS   28500019
         BZ    REP6                          NO, TERMINATE              28600019
         B     RNR9                          YES, RELEASE ACTIVE AREA   28700019
RNR1     L     R7,WORKLIN                    R7 HAS LINE NUM IN BINARY  28800019
         LA    R4,RAFKEY                     ADDRESS OF FIRST RECORD    28900019
         TM    SWITCH,SFIRST                 IS THIS THE 1ST RECORD?    29000019
         BZ    RNR3                          YES, BRANCH TO ST LINE NO  29100019
RNR2     A     R7,WORKINC                    INCREMENT LINE NUMBER      29200019
         BO    E348                          BRANCH ON OVERFLOW         29300019
         ST    R7,WORKLIN                    STORE LINE NUMBER          29400019
RNR3     OI    SWITCH,SFIRST                 SET 1ST RECORD SWITCH ON   29500019
RNR4     CVD   R7,WTEMPLIN                   CONVERT LINE NUM TO DEC.   29600019
         CLC   WTEMPLIN(4),CLINEMAX          LINE NUMBER EXCEED 8 CHAR? 29700019
         BH    E348                          YES, ERROR                 29800019
         UNPK  0(8,R4),WTEMPLIN              NO, PUT LINE NO IN RCD     29900019
         OI    7(R4),HEXF0                   ZONE LOW-ORDER DIGIT       30000019
         TM    TUBFLG2,TUBLNUMN              DOES RCD HAVE LINE NO      30100019
         BZ    NONUMREC                      NO, CONTINUE PROCESSING    30200019
         MVC   80(8,R4),0(R4)                PUT LINE NO AT END OF RCD  30300019
NONUMREC LA    R4,88(0,R4)                   MOVE POINTER TO NEXT RCD   30400019
         BCT   R5,RNR2                       SUBTRACT 1 FROM RECORD CTR 30500019
*                                            BR IF ANY TO BE PROCESSED  30600019
         SPACE                                                          30700019
*                   MOVE RENUMBERED RECORDS TO GLOBAL FILE            * 30800019
         SPACE                                                          30900019
         BAL   R14,RAFPARM                                              31000019
         MVC   TUBCNTFS+1(1),TUBCNTFS        ST NO OF RCDS FOR INSERT   31100019
         MVI   TUBCNTFS,HEX00                                           31200019
         OI    TUBAFISW,TUBFCTLN             USE BFR CONTROL            31300019
         INSERT M,A,FTYPE=XGBL               MOVE RENUM RCD TO GBL FILE 31400019
         NI    TUBAFISW,TUBFCTLF             DROP BFR CONTROL           31500019
         B     INSG1(R15)                    BRANCH ON RAFIO RETURN CD  31600019
INSG1    B     RNR8                          RETURN CD 0 GOOD RETURN    31700019
         B     RET20                         RETURN CD 4                31800019
         B     RNR8                          RETURN CD 8 NOT APPLICABLE 31900019
         B     ERR1                          RETURN CD 12 I/O ERROR     32000019
RNR8     TM    SWITCH,SEOD                   LAST RECORD RENUMBERED?    32100019
         BZ    RAFRTN4                       NO, GET RCD FROM ACTIVE    32200019
RNR9     NI    SWITCH,SEODOFF                YES, TURN OFF EOD SWITCH   32300019
         EJECT                                                          32400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 32500019
*              REPLACE RENUMBERED RECORDS INTO ACTIVE FILE            * 32600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 32700019
         SPACE                                                          32800019
         BAL   R14,RAFPARM                                              32900019
         RELEASE A                           RELEASE ACTIVE FILE        33000019
         B     RELA1(R15)                    BRANCH ON RAFIO RETURN CD  33100019
RELA1    B     RNR10                         RETURN CD 0 GOOD RETURN    33200019
         B     RNR10                         RETURN CD 4                33300019
         B     RNR10                         RETURN CD 8 NOT APPLICABLE 33400019
         B     ERR1                          RETURN CD 12 I/O ERROR     33500019
RNR10    BAL   R14,RAFPARM                                              33600019
         CREATE IS                           CREATE ACTIVE FILE         33700019
         B     CRTA1(R15)                    BRANCH ON RAFIO RETURN CD  33800019
CRTA1    B     REP0                          RETURN CD 0 GOOD RETURN    33900019
         B     RET20                         RETURN CD 4                34000019
         B     REP0                          RETURN CD 8 NOT APPLICABLE 34100019
         B     ERR1                          RETURN CD 12 I/O ERROR     34200019
REP0     NI    SWITCH,SFIRSTF                TURN OFF FIRST RECORD SW   34300019
         BAL   R14,RAFPARM                   SET UP RAFIO PARM LIST     34400019
         RPOINT B,NR,KEY=FIRST,FTYPE=XGBL    BEGINNING OF GLOBAL FILE   34500019
         B     PNTG2(R15)                    BRANCH ON RAFIO RETURN CD  34600019
PNTG2    B     REP1                          RETURN CD 0 GOOD RETURN    34700019
         B     REP1                          RETURN CD 4                34800019
         B     REP1                          RETURN CD 8 NOT APPLICABLE 34900019
         B     ERR1                          RETURN CD 12 I/O ERROR     35000019
REP1     BAL   R14,RAFPARM                   SET UP RAFIO PARM LIST     35100019
         RPOINT B,NR,KEY=FIRST               POINT TO START OF ACTIVE   35200019
         B     PNTA2(R15)                    BRANCH ON RAFIO RETURN CD  35300019
PNTA2    B     REP2                          RETURN CD 0 GOOD RETURN    35400019
         B     REP2                          RETURN CD 4                35500019
         B     REP2                          RETURN CD 8 NOT APPLICABLE 35600019
         B     ERR1                          RETURN CD 12 I/O ERROR     35700019
 EJECT                                                                  35800019
REP2     BAL   R14,RAFPARM                   SET UP RAFIO PARM LIST     35900019
         MVI   TUBCNTFS,HEX00                                           36000019
         MVI   TUBCNTFS+1,TEN                GET BLK OF RCDS FROM GBL   36100019
         OI    TUBAFISW,TUBFCTLN             USE BFR CONTROL            36200019
         RGET  R,M,A,FTYPE=XGBL                                         36300019
         NI    TUBAFISW,TUBFCTLF             DROP BFR CONTROL           36400019
         B     GETG1(R15)                    BRANCH ON RAFIO RETURN CD  36500019
GETG1    B     REP3                          RETURN CD 0 GOOD RETURN    36600019
         B     XEOD                          RETURN CD 4                36700019
         B     REP3                          RETURN CD 8 NOT APPLICABLE 36800019
         B     ERR1                          RETURN CD 12 I/O ERROR     36900019
REP3     BAL   R14,RAFPARM                                              37000019
         OI    TUBAFISW,TUBFCTLN             USE BFR CONTROL            37100019
         RGET  XK,S,B,FTYPE=XGBL             GET KEY FOR NEXT BLOCK     37200019
         NI    TUBAFISW,TUBFCTLF             DROP BFR CONTROL           37300019
         B     GETG2(R15)                    BRANCH ON RAFIO RETURN CD  37400019
GETG2    B     REP4                          RETURN CD 0 GOOD RETURN    37500019
         B     XEOD                          RETURN CD 4                37600019
         B     REP4                          RETURN CD 8 NOT APPLICABLE 37700019
         B     ERR1                          RETURN CD 12 I/O ERROR     37800019
XEOD     OI    SWITCH,SEOD                   SET GBL FILE EOD SWITCH    37900019
REP4     CLI   TUBCNTFS,HEX00                ANY RCDS RETRIEVED?        38000019
         BNH   REP6                          NO, RELEASE GBL FILE       38100019
         MVC   TUBCNTFS+1(1),TUBCNTFS        SET INSERT RCD COUNT       38200019
         MVI   TUBCNTFS,HEX00                                           38300019
         BAL   R14,RAFPARM                   SET UP RAFIO PARM LIST     38400019
         OI    TUBAFISW,TUBFCTLN             USE BFR CONTROL            38500019
         INSERT M,A                          INSERT RENUM RCD IN ACTIVE 38600019
         NI    TUBAFISW,TUBFCTLF             DROP BFR CONTROL           38700019
         B     INSA1(R15)                    BRANCH ON RAFIO RETURN CD  38800019
INSA1    B     REP5                          RETURN CD 0 GOOD RETURN    38900019
         B     RET20                         RETURN CD 4                39000019
         B     REP5                          RETURN CD 8 NOT APPLICABLE 39100019
         B     ERR1                          RETURN CD 12 I/O ERROR     39200019
REP5     TM    SWITCH,SEOD                   ANY MORE RCDS IN GBL FILE? 39300019
         BZ    REP2                          YES, GET RCDS              39400019
         BAL   R14,UPDATINC                  SET NEW INCREMENT          39500019
         EJECT                                                          39600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 39700019
*              END GLOBAL FILE PROCESSING                             * 39800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 39900019
         SPACE                                                          40000019
REP6     BAL   R14,RAFPARM                   SET UP PARMLIST FOR RAFIO  40100019
         ENDUP FTYPE=XGBL                    ENDUP ON GLOBAL FILE       40200019
         B     ENDG1(R15)                    BRANCH ON RAFIO RETURN CD  40300019
ENDG1    B     REP6A                         RETURN CD 0 GOOD RETURN    40400019
         B     REP6A                         RETURN CD 4                40500019
         B     REP6A                         RETURN CD 8 NOT APPLICABLE 40600019
         OI    SRETSW,SRET12                 RETURN CD 12 I/O ERROR     40700019
         SPACE                                                          40800019
*********************************************************************** 40900019
*                   FREE BUFFER USED FOR AFIO OPERATIONS              * 41000019
*********************************************************************** 41100019
         SPACE                                                          41200019
REP6A    ST    R10,SAVAD                     ST AFIO BFR ADDR           41300019
         FREEMAIN E,LV=888,A=SAVAD,SP=0      FREE AFIO BUFFER           41400019
REP6B    BAL   R14,RAFPARM                                              41500019
         RELEASE A,FTYPE=GBL                 RELEASE GLOBAL FILE        41600019
         B     RELG1(R15)                    BRANCH ON RAFIO RETURN CD  41700019
RELG1    B     REP7                          RETURN CD 0 GOOD RETURN    41800019
         B     REP7                          RETURN CD 4                41900019
         B     REP7                          RETURN CD 8 NOT APPLICABLE 42000019
         OI    SRETSW,SRET12                 RETURN CD 12 I/O ERROR     42100019
 EJECT                                                                  42200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 42300019
*                        END ACTIVE FILE PROCESSING                   * 42400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 42500019
         SPACE                                                          42600019
REP7     BAL   R14,RAFPARM                   SET UP PARMLIST FOR RAFIO  42700019
         ENDUP                                                          42800019
         B     ENDA1(R15)                    BRANCH ON RAFIO RETURN CD  42900019
ENDA1    B     REP8                          RETURN CD 0 GOOD RETURN    43000019
         B     REP8                          RETURN CD 4                43100019
         B     REP8                          RETURN CD 8 NOT APPLICABLE 43200019
         OI    SRETSW,SRET12                 RETURN CD 12 I/O ERROR     43300019
REP8     TM    SWITCH,SERR348                IS MAX LINE NO. SWITCH ON? 43400019
         BZ    REP8A                                                    43500019
         MVC   WMSGNUM(3),C348               MAXIMUM LINE NO. EXCEEDED  43600019
         BAL   R9,ERRRTN                     SEND ERROR MSG             43700019
REP8A    TM    SRETSW,SRET20                 TEST FOR RTRN CD OF 20     43800019
         BZ    FREESAV                       NO, FREE CORE              43900019
         MVC   WMSGNUM(3),C357               ACTIVE AREA OUT OF SPACE   44000019
         BAL   R9,ERRRTN                     SEND ERROR MSG             44100019
         B     FREESAV                       TERMINATE                  44200019
 SPACE 3                                                                44300019
NULLFILE BAL R14,UPDATINC                    SET NEW INCREMENT          44400019
         B     FREESAV                       TERMINATE                  44500019
 SPACE 3                                                                44600019
UPDATINC L     R4,TUBDIRAD                   DIRECTORY ENTRY ADDRESS    44700019
         USING DIRDSECT,R4                                              44800019
         MVC   DIRINC(4),WORKINC             UPDATE DEFAULT INCREMENT   44900019
         BR    R14                           RETURN TO CALLING POINT    45000019
         DROP  R4                                                       45100019
         EJECT                                                          45200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 45300019
*                              FREE SAVE AREA                         * 45400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 45500019
         SPACE                                                          45600019
FREESAV  L     R12,4(R13)                    LOAD CALLER'S SAVEAREA ADD 45700019
         ST    R13,SAVAD                     STORE CURRENT SAVEAREA ADD 45800019
         FREEMAIN E,LV=72,A=SAVAD,SP=0       FREE SAVE AREA             45900019
         SPACE                                                          46000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46100019
*                            RETURN TO CALLER                         * 46200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46300019
         SPACE                                                          46400019
         LR    R13,R12                       LOAD CALLER'S SAVEAREA ADD 46500019
         SR    R15,R15                       MOVE ZEROS TO R15          46600019
         TM    SRETSW,SRETN                  HAS A RETURN CD BEEN SET?  46700019
         BZ    RNRRET                        NO, BRANCH TO RETURN       46800019
         NI    SRETSW,SRETF                  TURN OFF RET CD INDICATOR  46900019
         IC    R15,SRETSW                    LOAD R15 WITH RETURN CD    47000019
RNRRET   ST    R15,16(R13)                                              47100019
         RETURN (14,12),T                                               47200019
         EJECT                                                          47300019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 47400019
*                            ERROR ROUTINES                           * 47500019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 47600019
         SPACE                                                          47700019
E307302  LA    R9,TSTOP3                     TEST NEXT OPRND AFTER MSG  47800019
         TM    SWITCH,SLINCR                 IS ERROR IN LINE NUMBER?   47900019
         BO    E302                          NO, INVALID OPND ERROR     48000019
E307     MVC   WMSGNUM(3),C307               INVALID LINE NUMBER        48100019
         B     ERRRTN                                                   48200019
E302     MVC   WMSGNUM(3),C302               INVALID INCREMENT          48300019
         B     ERRRTN                        COMPLETE PARM LIST         48400019
E348     OI    SWITCH,SERR348                SET MAX LINE NO. ERROR SW  48500019
         B     REP6                          RELEASE & ENDUP            48600019
E334     MVC   WMSGNUM(3),C334               EXCESSIVE OPERANDS         48700019
         NI    0(R5),PARENSF                 TURN OFF PAREN FLAG        48800019
         LA    R9,FREESAV                    END PROCESSING AFTER MSG   48900019
         SPACE                                                          49000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 49100019
*              INITIALIZE PARAMETER LIST FOR CALL TO IHKMSG           * 49200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 49300019
         SPACE                                                          49400019
ERRRTN   LA    R12,TUBUSRID                  R12 HAS USERID ADDR        49500019
         ST    R12,TUBPARM3                  STORE USERID ADDR          49600019
         ST    R3,TUBPARM2                   STORE TUB ADDR             49700019
         MVI   WMSGREP,HEX00                 MOVE ZERO TO REPLY CODE    49800019
         LA    R12,WMSGREP                   R12 HAS MSG NUM ADDR       49900019
         ST    R12,TUBPARM4                  STORE MSG NUM ADDR         50000019
         TM    SWITCH,SERR348                IS MAX LINE NO. SWITCH ON? 50100019
         BZ    ERRRTN2                       NO, BUILD TEXT PARM        50200019
         OI    TUBPARM4,HEX80                FLAG LAST WORD OF PARMLIST 50300019
         B     ERRRTN3                       BR, TO SEND MSG            50400019
ERRRTN2  CLI   0(R5),TEN                     IS OPRND LENGTH > THAN TEN 50500019
         BNH   ERRRTN1                       NO, STORE ADDR OF LENGTH   50600019
         MVI   0(R5),TEN                     MOVE 10 TO LENGTH OF MSG   50700019
ERRRTN1  ST    R5,TUBPARM5                   STORE ADDR OF LENGTH CODE  50800019
         OI    TUBPARM5,HEX80                FLAG LAST WORD OF PARMLIST 50900019
 EJECT                                                                  51000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 51100019
*                            SEND ERROR MSG                           * 51200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 51300019
         SPACE                                                          51400019
ERRRTN3  OI    SWITCH,SERROR                 SET ERROR SWITCH ON        51500019
         LA    R1,TUBPARM2                   R1 HAS ADDR OF PARMLIST    51600019
         L     R15,IHKYMSG1                  MESSAGE WRITER ENTRY PT    51700019
         BALR  R14,R15                       ENQUEUE ERROR MSG          51800019
         B     ERRRET(R15)                   BR ON IHKMSG RETURN CODE   51900019
ERRRET   B     GOODRET                       GOOD RETURN                52000019
         B     BADRET                        TP LINE ERROR RC=4         52100019
         B     BADRET                        GETMAIN FAILED RC=8        52200019
         B     BADRET                        MESSAGE LOST   RC=12       52300019
         B     BADRET                        DISK ERROR     RC=16       52400019
         B     BADRET                        OUT OF SPACE   RC=20       52500019
GOODRET  BR    R9                            MESSAGE WRITER EXIT        52600019
BADRET   STC   R15,SRETSW                    SAVE RETURN CD FROM IHKMSG 52700019
         OI    SRETSW,SRETN                  TURN ON RET CD INDICATOR   52800019
         B     FREESAV                       BR FREESAVEAREA            52900019
         EJECT                                                          53000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 53100019
*                PREPARE AFIO PARAMETER LIST                          * 53200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 53300019
         SPACE                                                          53400019
RAFPARM  ST    R3,TUBPARM3                                              53500019
         LA    R1,TUBPARM3         PROVIDE TUB ADDRESS                  53600019
         BR    R14                                                      53700019
         SPACE                                                          53800019
         SPACE                                                          53900019
         SPACE                                                          54000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54100019
*                  STORE ERROR RETURN CODES                           * 54200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 54300019
         SPACE                                                          54400019
ERR1     OI    SRETSW,SRET12       I/O ERROR                            54500019
         B     REP6                BR, FREE AFIO BUFFER                 54600019
RET20    LA    R9,REP6             AFTER MSG, ENDUP GBL                 54700019
         B     RET20C                                                   54800019
RET20B   LA    R9,REP7             AFTER MSG, ENDUP ACTIVE AREA         54900019
RET20C   OI    SRETSW,SRET20       RETURN CD 20, ACTIVE AREA OUT SPACE  55000019
         BR    R9                  CLOSE, RELEASE, & FREEMAIN AS NEED   55100019
         EJECT                                                          55200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 55300019
*                                  EQUATES                            * 55400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 55500019
         SPACE                                                          55600019
HEXFF    EQU   X'FF'                                                    55700019
HEX80    EQU   X'80'                                                    55800019
HEX00    EQU   X'00'                                                    55900019
HEX7F    EQU   X'7F'                                                    56000019
PARENS   EQU   X'C0'                    TEST IF OPND IS IN PARENTHESIS  56100019
PARENSF  EQU   X'3F'                    TURN OFF PARENTHESIS INDR       56200019
EIGHT    EQU   8                                                        56300019
TEN      EQU   10                                                       56400019
HEXF0    EQU   X'F0'                                                    56500019
         SPACE                                                          56600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 56700019
*                  MESSAGE NUMBER CONSTANTS                           * 56800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 56900019
         SPACE                                                          57000019
C357     DC    C'357'                        ACTIVE AREA SPACE ERROR    57100019
C348     DC    C'348'                        MAXIMUM LINE NO. EXCEEDED  57200019
C334     DC    C'334'                        EXCESSIVE OPS.             57300019
C307     DC    C'307'                        INVALID LINE NUMBER        57400019
C302     DC    C'302'                        INVALID OPERAND            57500019
         SPACE                                                          57600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 57700019
*                                  CONSTANTS                          * 57800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 57900019
         SPACE                                                          58000019
SAVAD    DC    F'0'                                                     58100019
ZERO     DC    F'0'                                                     58200019
CLINEMAX DC    XL4'00000009'                                            58300019
         EJECT                                                          58400019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 58500019
*                                  DSECTS                            *  58600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 58700019
         SPACE                                                          58800019
         SPACE                                                          58900019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 59000019
*                DSECT FOR AFIO BUFFER                               *  59100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 59200019
         SPACE                                                          59300019
RAFDSECT DSECT                                                          59400019
RAFLEN   DS    F                                                        59500019
RAFBUFAD DS    F                                                        59600019
RAFRECS  DS    10CL88                                                   59700019
         ORG   RAFRECS                                                  59800019
RAFKEY   DS    2F                                                       59900019
RAFLINE  DS    20F                                                      60000019
         SPACE                                                          60100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 60200019
*                 DSECT FOR WORK AREA IN USER BUFFER                 *  60300019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 60400019
         SPACE                                                          60500019
WKDSECT  DSECT                                                          60600019
         DS    CL96                                                     60700019
WKAREA   DS    0CL40                                                    60800019
WINCRE   DS    CL8                                                      60900019
         ORG   WINCRE                                                   61000019
WORKINC  DS    CL4                                                      61100019
         DS    CL4                                                      61200019
WLINUM   DS    CL8                                                      61300019
WTEMPLIN DS    CL8                                                      61400019
WORKLIN  DS    CL4                                                      61500019
WMSGREP  DS    C                                                        61600019
WMSGNUM  DS    CL3                                                      61700019
SWITCH   DS    C                                                        61800019
SLINE    EQU   X'80'                                                    61900019
SINCRE   EQU   X'40'                                                    62000019
SERROR   EQU   X'20'                                                    62100019
SEOD     EQU   X'10'                                                    62200019
SFIRST   EQU   X'08'                                                    62300019
SERR348  EQU   X'04'                                                    62400019
SFIRSTF  EQU   X'F7'                                                    62500019
SEODOFF  EQU   X'EF'                                                    62600019
SLINCR   EQU   X'C0'                                                    62700019
SRETSW   DS    C                                                        62800019
SRETN    EQU   X'80'                                                    62900019
SRETF    EQU   X'7F'                                                    63000019
SRET04   EQU   X'84'                                                    63100019
SRET08   EQU   X'88'                                                    63200019
SRET12   EQU   X'8C'                                                    63300019
SRET16   EQU   X'90'                                                    63400019
SRET20   EQU   X'94'                                                    63500019
         EJECT                                                          63600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 63700019
*                   DSECT FOR AVT, TUB, PPT, AND DIR                  * 63800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 63900019
         SPACE                                                          64000019
         IHKCDSCT AVT=YES,TUB=YES,PPT=YES,DIR=YES                       64100019
         TUBEQU                                                         64200019
         END                                                            64300019
