SAV      TITLE 'IHKSAV - SAVE COMMAND PROCESSOR'                        00100019
***********************************                                     00100120
*                                                                       00100220
IHKSAV   CSECT                                                          00100320
*                                                                       00100420
***********************************                                     00100520
*A 000200,748000,788000,894000,920000                            S21085 00100621
*C 001036,004000,011000,022000,030000,048300,139000,396000,      S21085 00100721
*C 485000-491000                                                 S21085 00100821
*D 303000,374000,859000-860000,867000-869000                     S21085 00100921
* 002000-006000,048300,680000-681000                             A34591 00101021
*A700000                                                         A48979 00101300
*C048300                                                         A48979 00101600
* C 048300, A 411000                                            OS63569 00101728
*********************************************************************** 00101900
*                                                                     * 00102200
*STATUS                                                               * 00102719
*   CHANGE LEVEL 1                                                    * 00103621
*FUNCTION                                                             * 00104519
*   THE OPERANDS, IF ANY, ARE CHECKED AND IF AN ERROR IS FOUND, AN    * 00105419
*   ERROR MESSAGE IS SENT TO THE USER AND CONTROL IS RETURNED WITH A  * 00106319
*   0 IN REGISTER 15.  IF THE OLD KEYWORD IS SPECIFIED ON THE EDIT    * 00107219
*   SUBCOMMAND AND EITHER THE DSNAME IS NOT SPECIFIED ON THE SAVE     * 00108119
*   SUBCOMMAND OR THE DSNAME ON THE SAVE SUBCOMMAND IS THE SAME AS    * 00109019
*   THE DSNAME ON THE EDIT COMMAND, THE ACTIVE FILE REPLACES THE CRJE * 00109919
*   DATA SET WITH THE SAME NAME.  IF THE NEW KEYWORD WAS SPECIFIED ON * 00110819
*   THE EDIT COMMAND, OR IF THE DSNAME ON THE SAVE SUBCOMMAND IS      * 00111719
*   DIFFERENT FROM THE DSNAME ON THE EDIT COMMAND, CRJE CHECKS FOR AN * 00112619
*   EXISTING DATA SET WITH THE SAME NAME.  IF A DUPLICATE DATA SET    * 00113519
*   NAME IS FOUND, THE USER IS PROMPTED FOR A NEW DSNAME.  IF THE     * 00114419
*   USER RESPONDS WITH NULL INPUT, THEN THE ACTIVE DATA SET REPLACES  * 00115319
*   THE DATA SET IN THE USER LIBRARY, AND A NEW CREATION DATA IS      * 00116219
*   ENTERED IN THE DIRECTORY.  IN ALL CASES THE LAST MODIFIED DATE IS * 00117119
*   UPDATED.  IF THERE IS NOT ENOUGH SPACE IN THE USER LIBRARY, THE   * 00118019
*   LIBRARY IS AUTOMATICALLY CONDENSED TO FREE UNUSED SPACE.  IF      * 00118919
*   SUFFICIENT SPACE IS NOT AVAILABLE AFTER CONDENSING, THE USER IS   * 00119819
*   NOTIFIED THAT HIS LIBRARY IS FULL AND IS ASKED FOR THE NAME OF A  * 00120719
*   DATA SET THAT CAN BE DELETED.  IF THE DSNAME THE USER SENDS IN    * 00121619
*   RESPONSE IS VALID, IT IS DELETED.  THE USER IS PROMPTED FOR DATA  * 00122519
*   SET NAMES UNTIL HE ENTERS A NUL LINE.  THEN THE LIBRARY IS AGAIN  * 00123419
*   CONDENSED.  IF THERE IS STILL NOT ENOUGH SPACE, THE PROCESS IS    * 00124319
*   REPEATED BEGINNING WITH THE DELETION PROMPTS.  IF THE USER IS     * 00125219
*   UNABLE TO GIVE A DATA SET NAME FOR DELETION THE FIRST TIME THAT   * 00126119
*   HE IS PROMPTED TO DO SO SUBSEQUENT TO EACH CONDENSING OF THE      * 00127019
*   LIBRARY, HE MAY TERMINATE THE SAVE ATTEMPT BY ENTERING A NULL     * 00127919
*   LINE.  IF ENOUGH SPACE BECOMES AVAILABLE, THE ACTIVE FILE IS      * 00128819
*   SAVED IN HIS LIBRARY.  AFTER THE ACTIVE FILE IS SAVED OR AFTER    * 00129719
*   THE USER TERMINATES THE PROCESS OF CONDENSING, CONTROL IS         * 00130619
*   RETURNED TO THE CALLING ROUTINE WITH A 0 IN REGISTER 15.  IF THE  * 00131519
*   USER ENTERS A VALID PROTECTION KEY OPERAND WITHOUT A DATA SET     * 00132419
*   NAME, THE KEY IS POSITIONED IN THE KEY FIELD OF THE DIRECTORY     * 00133319
*   BELONGING TO THE DATA SET NAMED IN THE EDIT COMMAND.  IF A VALID  * 00134219
*   PROTECTION KEY IS GIVEN ALONG WITH A DATA SET NAME, THE DIRECTORY * 00135119
*   FOR THAT DATA SET RECEIVES THE NEW KEY.  IN BOTH CASES THE KEY    * 00136019
*   REPLACES ANY EXISTING KEY WITHOUT NOTIFICATION TO THE USER.  IF   * 00136919
*   NEITHER THE DSNAME NOR A KEY IS SPECIFIED WITH THE SAVE           * 00137819
*   SUBCOMMAND, THE KEY FIELD OF THE DIRECTORY BELONGING TO THE DATA  * 00138719
*   SET NAMED IN THE EDIT COMMAND REMAINS UNCHANGED.  IF A DSNAME IS  * 00139619
*   GIVEN WITH THE SAVE COMMAND BUT NO KEY IS SPECIFIED, THE KEY      * 00140519
*   FIELD IS BLANKED IN THE DIRECTORY BELONGING TO THE NAMED DATA     * 00141419
*   SET.  THIS IS THE MEANS THAT CRJE PROVIDES FOR DROPPING A KEY     * 00142319
*   ALREADY ASSIGNED TO A DATA SET.  HOWEVER, NO CHECK OF THE KEY     * 00143219
*   FIELD IS MADE PRIOR TO THE BLANKING OUT AND IF A KEY IS DESTROYED * 00144119
*   NO WARNING NOTIFICATION IS ISSUED TO THE USER.                    * 00145019
*ENTRY POINTS                                                         * 00146819
*        IHKSAV - SAVES ACTIVE AREA IN USER LIBRARY                   * 00147719
*               - SETS DSNAME IF GIVEN                                * 00148619
*               - SETS PROTECTION KEY IF GIVEN                        * 00149519
*               - CONDENSES LIBRARY IF NECESSARY                      * 00150419
*               - DELETED DATA SETS IF REQUESTED                      * 00151319
*INPUT                                                                * 00152219
*   REGISTER 1 MUST POINT TO A TWO WORD PARAMETER LIST CONTAINING     * 00153119
*   THE ADDRESS OF THE TUB IN THE FIRST WORD AND                      * 00154019
*   THE ADDRESS OF THE AVT IN THE SECOND                              * 00154919
*OUTPUT                                                               * 00155819
*   N/A                                                               * 00156719
*EXTERNAL REFERENCES                                                  * 00157619
*        IHKAFI - TO MANIPULATE ACTIVE AREA                           * 00158519
*        IHKBPM - TO MANIPULATE USER LIBRARY                          * 00159419
*        IHKWTR - TO CHECK ON COMPLETION OF RWRITE MACRO              * 00160319
*        IHKUTM - TO QUEUE FOR LIBRARY I/O OPERATIONS                 * 00161219
*        IHKMSG - (ENTRY POINT INKMSG) TO PROMPT USER FOR DSNAMES     * 00162119
*        IHKMSG - (ENTRY POINT IHKMSG01) TO INFORM THE USER OF ERRORS * 00163019
*        IHKRNQ - TO QUEUE FOR LIBRARY I/O AFTER THE INITIAL USE OF   * 00163919
*        IHKRNQ - TO QUEUE FOR LIBRARY I/O AFTER THE INITIAL UTM USE  * 00164819
*        IHKCDP - TO CONDENSE USER LIBRARY                            * 00165719
*EXITS, NORMAL                                                        * 00166619
*   RETURN TO THE CALLING ROUTINE WITH ZERO IN REGISTER 15            * 00167519
*EXITS, ERROR                                                         * 00168419
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 00169319
*   IN REGISTER 15                                                    * 00170219
*   4  - LINE ERROR                                                   * 00171119
*   8  - GETMAIN FAILED                                               * 00172019
*   12 - ACTIVE AREA I/O ERROR                                        * 00172919
*   16 - ERROR MESSAGE LOST                                           * 00173819
*   20 - ACTIVE AREA OUT OF SPACE                                     * 00174719
*TABLES/WORK AREAS                                                    * 00175619
*   18-WORD SAVE AREA                                                 * 00176519
*   PPT-FLAG BYTE USED FOR SAVR INDICATORS                            * 00177419
*   KONBOX                                                            * 00178319
*   BPBLDLST+4 AND SUCCEDING BYTES SET WITH NEW DIRECTORY INFORMATION * 00179219
*   BPPARMFS USED TO RETRIEVE DDNAME FROM UTM                         * 00180119
*   BPQCTLFW USED FOR BPAM QUEUE CONTROL                              * 00181019
*   TUB                                                               * 00181919
*   TUBCNTFS SET FOR RGET AND RESET BY RGET FOR RWRITE                * 00182819
*   TUBFILNM SET WITH NEW DSNAME IF SPECIFIED AS AN OPERAND           * 00183719
*   TUBFLG2 TESTED FOR ABEND CALL TO IHKSAV                           * 00184619
*   TUBPRMLS USED FOR PARAMETERS TO EXTERNAL ROUTINES.                * 00185519
*   TUBGBLKY USED FOR USERID FOR IHKUTM                               * 00186419
*   TUBDATAL USED TO RETRIEVE USER RESPONSE TO PROMPT                 * 00187319
*   TUBBPQEL CHECKED FOR BPAM QUEUE ELEMENT FOR IHKRNQ                * 00188219
*   TUBBPPTAD CHECKED FOR ADDRESS OF PPT                              * 00189119
*   TUBRAFBF USED FOR RETRIEVAL OF LINE BY RPOINT MACRO,              * 00190019
*        REFERENCED TO PASS RECORD FROM RGET AFIO BUFFER TO SFBUFF1   * 00190919
*   TUBUFFAD REFERENCED WHEN RETURNED FROM MESSAGE WRITER PROMPTS     * 00191819
*   TUBUSERID REFERENCED FOR IHKUTM AND FOR MESSAGE WRITER            * 00192719
*   DIR                                                               * 00193619
*   DIRNAME USED TO RETAIN FILE NAME AS EDITED                        * 00194519
*ATTRIBUTES                                                           * 00195419
*   NONRESIDENT AND REENTRANT                                         * 00196319
*                                                                     * 00197219
*********************************************************************** 00198119
         EJECT                                                          00199019
 SPACE 2                                                                00650019
R0       EQU   0                                                        00700019
R1       EQU   1                   PARAMETER LIST ADDRESS               00800019
R2       EQU   2                   INTERNAL BRANCHING                   00900019
R3       EQU   3                   MESSAGE CODE POINTER, RETURN CODE    01000019
R4       EQU   4                       KBXPT USING               S21085 01100021
R5       EQU   5                   DIRPT          USING                 01200019
R6       EQU   6                   INCR,INNERBR2,PPTESTRG               01300019
R7       EQU   7                   OPNDCTR,BLKCNT                       01400019
R8       EQU   8                   USRBUFAD,PPTPT                       01500019
R9       EQU   9                   PPTADDR                              01600019
R10      EQU   10                  AVTPT          USING                 01700019
R11      EQU   11                  TUBPT          USING                 01800019
R12      EQU   12                  BASE REGISTER  USING                 01900019
R13      EQU   13                  SAVEPT         USING                 02000019
R14      EQU   14                  RETURN ADDRESS                       02100019
R15      EQU   15                      RETURN CODES, KBXDIRAD    S21085 02200021
         SPACE 2                                                        02300019
COUNT    EQU   0                   REGISTER USED TO SUM RECORDS         02400019
PARMREG  EQU   1                   REGISTER FOR PARMS, PARMPTS, & LISTS 02500019
INNERBR  EQU   2                   REGISTER FOR INTERNAL BRANCH/LINK    02600019
MSGCODE  EQU   3                   REGISTER FOR MESSAGE CODES           02700019
RTRNREG  EQU   3                   REGISTER FOR RETAINING RETURN CODE   02800019
KBXPT    EQU   4                   REGISTER FOR POINTER TO KONBOX       02900019
KBXDIRAD EQU   15                      REGISTER FOR KONBOX DIR.  S21085 03000021
DIRPT    EQU   5                   REGISTER FOR POINTER TO DIRECTORY    03100019
INNERBR2 EQU   6                   REGISTER FOR INTERNAL BRANCHING      03200019
INCR     EQU   6                   REGISTER FOR INCREMENTING PARAM PTR  03300019
PPTESTRG EQU   6                   REGISTER FOR TESTING NEXT PPT IN CHN 03400019
OPNDCTR  EQU   7                   REGISTER FOR OPERAND COUNTER         03500019
BLKCNT   EQU   7                   REGISTER FOR BLOCK COUNT             03600019
USRBUFAD EQU   8                   REGISTER FOR USER BUFFER ADDRESS     03700019
PPTPT    EQU   8                   REGISTER FOR PARAMETER POINTER       03800019
PPTADDR  EQU   9                   REGISTER FOR ADDRESS OF PPT          03900019
AVTPT    EQU   10                  POINTER TO ADDRESS VECTOR TABLE      04000019
TUBPT    EQU   11                  POINTER TO TERMINAL USER BLOCK       04100019
         EJECT                                                          04200019
***********************************                                     04300019
*                                                                       04400019
* SAVE REGISTERS AND ESTABLISH ADDRESSABILITY                           04500019
*                                                                       04600019
***********************************                                     04700019
 SPACE                                                                  04760019
         SAVE  (14,12),,SAV73230                                OS63569 04830028
         LR    R12,R15             SET BASE ADDRESS                     04900019
         USING IHKSAV,R12          ADDRESSABILITY FOR IHKSAV            05000019
         SPACE 2                                                        05100019
***********************************                                     05200019
*                                                                       05300019
* DYNAMIC STORAGE FOR SAVE AND WORK AREAS                               05400019
*                                                                       05500019
***********************************                                     05600019
 SPACE                                                                  05700019
         L     TUBPT,0(,R1)        LOAD ADDRESS TO THE TUB              05800019
         USING TUBDSECT,TUBPT      ADDRESSABILITY FOR TUB               05900019
         L     AVTPT,4(,R1)        LOAD ADDRESS TO THE AVT              06000019
         USING AVTDSECT,AVTPT      ADDRESSABILITY FOR AVT               06100019
         L     1,IHKYYGML                                               06200019
         LA    R2,NEED             PROVIDE STORAGE NEEDS                06300019
         LA    R3,TUBPARM1         PROVIDE FOR POINTER TO GETMAIN AREA  06400019
         GETMAIN EC,LV=(R2),A=(R3),MF=(E,(1))                           06500019
         LTR   R15,R15             TEST FOR SUCCESSFUL COMPLETION       06600019
         BNZ   RTRNBAD2            IF IN ERROR, INDICATE GETMAIN  FAIL  06700019
         EJECT                                                          06750019
 SPACE                                                                  06800019
***********************************                                     06900019
*                                                                       07000019
* ESTABLISH LINKAGE OF SAVE AREAS AND DSECT ADDRESSABILITY              07100019
*                                                                       07200019
***********************************                                     07300019
 SPACE                                                                  07400019
         L     R15,TUBPARM1        LOAD SAVE AREA ADDRESS               07500019
         ST    R13,CALLNGSA(R15)   STORE LA SAVE AREA ADDR IN SAV       07600019
         ST    R15,CALLEDSA(R13)   STORE SAV SAVE AREA ADDR IN LA       07700019
         LR    R13,R15             PLACE SAV SAVE AREA ADDR IN R13      07800019
         L     PPTADDR,TUBPPTAD    LOAD ADDRESS OF PPT                  07900019
         USING PPTDSECT,PPTADDR    ADDRESSABILITY FOR PPT               08000019
         L     DIRPT,TUBDIRAD      OBTAIN ADDRESS OF DIRECTORY          08100019
         USING DIRDSECT,DIRPT      ADDRESSABILITY TO DIRECTORY          08200019
         L     KBXPT,IHKYYKBX      LOAD ADDRESS OF KONBOX               08300019
         USING RAFKNBX,KBXPT       ADDRESSABILITY FOR KONBOX            08400019
         TM    PPTFLG,CNDSFLAG     TEST FOR RETURN FROM CONDENSE        08500019
         BO    RTRNCNDS            IF RETURNING FROM CDP, CHK RTRN CODE 08600019
         EJECT                                                          08700019
***********************************                                     08800019
*                                                                       08900019
* OPERAND CHECKING                                                      09000019
*                                                                       09100019
***********************************                                     09200019
 SPACE                                                                  09300019
         TM    TUBFLG2,TUBABEND    TEST FOR ABEND TERMINATION           09400019
         BO    DSACTIVE            IF ABEND, SET DSNAME TO ACTIVE       09500019
         MVC   TUBPMFNM,DIRFNAME   PROVIDE FILE NAME FOR BPAM           09600019
         MVC   TUBPARM5,DBLWDBLK   BLANK KEY WORD SAVE AREA             09700019
         SR    OPNDCTR,OPNDCTR     INITIALIZE OPND COUNTER TO ZERO      09800019
         LA    PPTPT,PPTPARS       OBTAIN POINTER TO PARAMETER FLD      09900019
         BAL   INNERBR,FRSTTEST    TEST FIRST OPERAND                   10000019
         XR    COUNT,COUNT         CLEAR COUNT                          10070019
         IC    COUNT,0(PPTPT)      OBTAIN LENGTH COUNT                  10140019
         LA    PARMREG,1(PPTPT)    OBTAIN ADDRESS OF DSNAME             10210019
         LA    INNERBR2,ERRNOPND   PROVIDE ALPHATST BRANCHING ADDRESS   10300019
         BAL   INNERBR,ALFATST1    TEST FOR ALPHABETIC FIRST CHARACTER  10400019
         IC    INCR,0(PPTPT)       OBTAIN LENGTH OF OPERAND             10500019
         BAL   INNERBR,MOVDSNM1    MOVE DSNAME INTO TUB                 10600019
         OI    PPTFLG,DSOPFLAG     SET FLAG FOR DSNAME OPERAND FOUND    10700019
TSTOPND2 DS    0H                                                       10800019
         CLC   MDLKEY1,0(PPTPT)    TEST FOR  'KEY' OPERAND              10900019
         BE    TSTOPND3            IF 'KEY' OPND, TEST NEXT OPERAND     11000019
         CLC   MDLKEY2,0(PPTPT)    TEST FOR  'K' OPERAND                11100019
         BE    TSTOPND3            IF 'K' OPND, TEST NEXT OPERAND       11200019
         CH    OPNDCTR,TWO         IF THIS IS THE SECOND OPERAND,       11300019
         BE    ERRNOPND            SEND ERROR MESSAGE TO USER           11400019
         BAL   INNERBR,NEXTTEST     TEST FOR SECOND OPERAND PRESENT     11500019
         B     TSTOPND2            TEST FOR VALID SECOND OPERAND        11600019
TSTOPND3 DS    0H                                                       11700019
         BAL   INNERBR,NEXTTEST    TEST FOR THIRD OPERAND PRESENT       11800019
         CLI   0(PPTPT),MDLKEY     TEST FOR KEY WORD LENGTH OF 3 IN ()S 11900019
         BNE   ERRKEY              IF NOT 3 CHARS IN ()S, ERROR         12000019
         MVC   TUBPARM5(KEYLNG),1(PPTPT)     SAVE KEY IN PARM5          12100019
         CH    OPNDCTR,TWO         IF THIS IS THE THIRD OPERAND,        12200019
         BNE   LASTTEST            TEST FOR PRESENTS OF EXCESSIVE OPND  12300019
         MVC   TUBPMFNM,DIRFNAME   IF SECOND OPND, RESET FILE NAME      12400019
         NI    PPTFLG,DSOPFLGN     SET TO OFF DSNAME OPERAND FLAG       12500019
LASTTEST DS    0H                                                       12600019
         BAL   INNERBR,NEXTTEST    TEST FOR NEXT OPERAND                12700019
         BAL   INNERBR,MSGNSRT     IF OPERAND FOUND, ERROR              12800019
         LA    MSGCODE,MSGEXCSS    INDICATE EXCESSIVE OPERAND           12900019
         B     ERREXIT             SEND MSG TO USER & RTRN CODE OF 0    13000019
 EJECT                                                                  13100019
***********************************                                     13200019
*                                                                       13300019
* SET DSNAME EQUAL TO ACTIVE FOR ABEND SAVE                             13400019
*                                                                       13500019
***********************************                                     13600019
 SPACE                                                                  13700019
DSACTIVE DS    0H                                                       13800019
         MVC   TUBPMFNM,ACTIVEKN       SET DSNAME TO ACTIVE      S21085 13900021
         B     POINT                                                    14000019
         SPACE 2                                                        14100019
***********************************                                     14200019
*                                                                       14300019
*  TEST FOR ANY ERRORS IN OPERAND CHECKING                              14400019
*                                                                       14500019
***********************************                                     14600019
 SPACE                                                                  14700019
CHKERRSW DS    0H                                                       14800019
         TM    PPTFLG,ERRORSW      TEST FOR ERROR CONDITION IN PARAMS   14900019
         BO    RTRNGOOD                                                 15000019
         L     PPTESTRG,TUBPPTAD   OBTAIN ADDRESS OF FIRST PPT          15100019
         OC    0(1,PPTESTRG),0(PPTADDR) MOVE FLAFS INTO FIRST PPT       15200019
         LR    PPTADDR,PPTESTRG    SET ADDRESSABILITY TO FIRST PPT      15300019
         MVC   PPTWD1(KEYLNG,PPTADDR),TUBPARM5    SAVE KEY (IF ANY)     15350019
         CLC   TUBPMFNM,DBLWDBLK   TEST FOR BLANK FILE NAME             15400019
         BE    NODSPRMT            IF BLANK, PROMPT FOR FILE NAME       15500019
          EJECT                                                         15700019
***********************************                                     15800019
*                                                                       15900019
* POINT TO BEGINNING OF USER'S ACTIVE FILE                              16000019
*                                                                       16100019
***********************************                                     16200019
 SPACE                                                                  16300019
POINT    DS    0H                                                       16400019
         CLC   TUBPMFNM,DBLWDBLK   TEST FOR BLANK FILE NAME             16500019
         BE    RTRNGOOD            IF BLANK, TERMINATE SAVE             16600019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          16700019
         RPOINT B,R,KEY=FIRST      POINT TO BEGINNING OF FILE           16800019
         B     *+4(R15)            EVALUATE RETURN CODE                 16900019
         B     FREERAFB            NO ERRORS, FREE RAFIO BUFFER         17000019
         B     NULLFILE            NULL FILE, INDICATE TO USER          17100019
         B     RETURN              GETMAIN FAILURE                      17200019
         B     RETURN              I/O ERROR, INDICATE TO USER          17300019
 SPACE                                                                  17400019
NULLFILE DS    0H                                                       17500019
         TM    TUBFLG2,TUBABEND    TEST FOR ABEND TERMINATION           17600019
         BO    SETABND1            IF ABEND, EXIT SAVE                  17700019
         LA    MSGCODE,MSGNULDS    LOAD CODE FOR NULL FILE MESSAGE      17800019
         B     ERREXIT             SEND MSG TO USER & RTRN CODE OF 0    17900019
 SPACE                                                                  18000019
FREERAFB DS    0H                                                       18100019
         BAL   INNERBR,FRERAFBF    FREE THE AREA FROM THE RPOINT        18200019
          EJECT                                                         18300019
***********************************                                     18400019
*                                                                       18500019
*  ENQUEUE FOR BPAM                                                     18600019
*                                                                       18700019
***********************************                                     18800019
 SPACE                                                                  18900019
         TM    PPTFLG,CNDSFLAG     TEST FOR PREVIOUS CONDENSE OPERATION 19000019
         BNO   ENQUEUE             IF NOT CONDENSED, ENQUEUE WITH UTM   19100019
         BAL   INNERBR,RNQUEUE     ENQUEUE FOR BPAM                     19200019
         B     FIND1               NO ERRORS, PROCEED TO FIND           19300019
RNQUEUE  DS    0H                                                       19400019
         LA    PARMREG,TUBBPQEL                                         19500019
         ST    PARMREG,TUBPARM1    PROVIDE POINTER TO BPAM QUEUE ELEMNT 19600019
         LA    PARMREG,BPQCTLFW                                         19700019
         ST    PARMREG,TUBPARM2    PROVIDE POINTER TO BPAM COUNT        19800019
         LA    PARMREG,TUBPRMLS    PROVIDE POINTER TO PARM LIST         19900019
         L     R15,IHKYYRNQ                                             20000019
         BALR  R14,R15             ENQUEUE WITH RNQ                     20100019
         MVC   BPPARMFS(DBLWDLNG),PPTWD2(PPTADDR) RESTORE KONBOX DDNAME 20200019
         LTR   R15,R15             EVALUATE RETURN CODE                 20300019
         BZ    0(INNERBR)          IF NO ERRORS, RETURN TO CALLING RTRN 20400019
         B     RTRNBAD2            GETMAIN FAILURE                      20500019
         SPACE 2                                                        20600019
ENQUEUE  DS    0H                                                       20700019
         LA    PARMREG,UTMCODE                                          20800019
         ST    PARMREG,TUBPARM2    PROVIDE UTM CODE POINTER             20900019
         BAL   INNERBR,CALLUTM     ENQUEUE FOR BPAM OPERATIONS          21000019
         B     FIND                PROCEED TO FIND DATA SET             21100019
 SPACE                                                                  21200019
CALLUTM  DS    0H                                                       21300019
         ST    TUBPT,TUBPARM1      PROVIDE PT TO TUB POINTER            21400019
         MVC   TUBGBLKY,TUBUSRID   MOVE USER ID INTO GLOBAL KEY FOR UTM 21500019
         LA    PARMREG,TUBPRMLS    PROVIDE POINTER TO PARM LST          21600019
         L     R15,IHKYYUTM        LOAD ADDRESS OF USER FILE MANAGER    21700019
         BALR  R14,R15             BRANCH TO USER FILE MANAGER          21800019
         B     *+4(R15)            EVALUATE RETURN CODE                 21900019
         B     0(INNERBR)          NO ERRORS, PROCEED                   22000019
         B     ERRDD               USER NOT IN DIRECTORY                22100019
         B     RETURN              GETMAIN FAILURE                      22200019
         B     RETURN              DISK ERROR IN ACTIVE AREA            22300019
         B     ERRDD               DDNAME BLANK                         22400019
         B     0(INNERBR)          USERID ACTIVE, ACCEPTABLE CONDITION  22500019
         B     ERRLIBNO            INDICATE LIBRARY INOPERATIVE         22600019
          EJECT                                                         22700019
***********************************                                     22800019
*                                                                       22900019
*  INITIALIZE FOR ACCESS TO LIBRARY                                     23000019
*                                                                       23100019
***********************************                                     23200019
 SPACE                                                                  23300019
FIND     DS    0H                                                       23400019
         MVC   PPTWD2(DBLWDLNG,PPTADDR),BPPARMFS PROVIDE DDNAME FOR CDP 23500019
FIND1    DS    0H                                                       23600019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          23700019
         RFIND O                   INITIATE STANDARD ACCESS FOR RWRITE  23800019
         B     *+4(R15)            EVALUATE RETURN CODES                23900019
         B     PRMTDUPL            DUPLICATE DSNAME, PROMPT FOR DSNAME  24000019
         B     SETFIRST            UNIQUE DSNAME, SET FIRST PASS FLAG   24100019
         B     RTRNOSTW            GETMAIN FAILURE                      24200019
         B     RTRNOSTW            I/O ERROR                            24300019
         SPACE 2                                                        24400019
***********************************                                     24500019
*                                                                       24600019
*  DIRECTORY FULL CONDITION                                             24700019
*                                                                       24800019
***********************************                                     24900019
 SPACE                                                                  25000019
         OI    PPTFLG,CNDSFLAG     DIRECTORY FULL, SET CONDENSE FLAG    25100019
         OI    PPTFLG,FULLFLAG     SET FULL FLAG TO FORCE SCRATCH       25200019
         OI    PPTFLG,DIRFULL      SET DIRECTORY FULL FLAG              25300019
         XR    R15,R15             ZERO RETURN CODE                     25400019
         B     RTRNOSTW                                                 25500019
         EJECT                                                          25600019
***********************************                                     25700019
*                                                                       25800019
* DUPLICATE NAME, PROMPT USER FOR NEW DSNAME                            25900019
*                                                                       26000019
***********************************                                     26100019
 SPACE                                                                  26200019
PRMTDUPL DS    0H                                                       26300019
         TM    PPTFLG,CNDSFLAG     TEST FOR PREVIOUS CONDENSE           26400019
         BO    SETFIRST            IF YES, BYPASS DUPL CONDITION TEST   26500019
         TM    PPTFLG,DUPLFLAG     TEST FOR PRIOR DUPL CONDITION        26600019
         BNO   SETDUPON            IF NO, TEST FOR DUPL CONDITION       26700019
         XI    PPTFLG,DUPLFLAG     TURN OFF PRIOR DUPL FLAG             26800019
         B     SETFIRST            SET FIRST PASS INDICATOR             26900019
SETDUPON DS    0H                                                       27000019
         XR    R15,R15             CLEAR REGISTER OF RETURN CODE        27050019
         TM    TUBFLG2,TUBABEND    TEST FOR ABEND SAVE                  27100019
         BO    SETFIRST            IF YES, BYPASS DUPL CONDITION        27200019
         OI    PPTFLG,DUPLFLAG     SET DUPL FLAG                        27300019
         CLC   TUBPMFNM,DIRFNAME   COMPARE SAVE NAME TO EDIT NAME       27400019
         BNE   RTRNOSTW            IF NOT EQUAL, SEND DUPL MSG          27500019
         TM    DIRATTRO,DIROLD     TEST FOR EDIT OLD                    27600019
         BNO   RTRNOSTW            IF NOT OLD, SEND DUPL MSG            27700019
SETFIRST DS    0H                                                       27800019
         OI    PPTFLG,FIRSTGET     INITIALIZE FIRST-TIME FLAG ON        27900019
         SR    BLKCNT,BLKCNT       INITIALIZE BLOCK COUNT TO ZERO       28000019
         SPACE 2                                                        28100019
***********************************                                     28200019
*                                                                       28300019
* GET A BLOCK FROM THE ACTIVE AREA                                      28400019
*                                                                       28500019
***********************************                                     28600019
 SPACE                                                                  28700019
GETBLOCK DS    0H                                                       28800019
         LA    COUNT,BLKSIZE                                            28900019
         STH   COUNT,TUBCNTFS      PROVIDE COUNT FOR MULTIPLE RGET      29000019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          29100019
         RGET  R,M,A               GET A BLOCK FROM THE ACTIVE FILE     29200019
         B     *+4(R15)            EVALUATE RETURN CODES                29300019
         B     FIRSTEST            NO ERRORS, TEST FOR FIRST PASS       29400019
         B     SETEODON            END OF DATA, SET INDICATOR           29500019
         B     RTRNOSTW            GETMAIN FAILURE                      29600019
         LNR   R15,R15             SIGNAL NOSTOW ACTIVE AREA I/O ERROR  29650019
         B     RTRNOSTW            I/O ERROR                            29700019
          EJECT                                                         29800019
FIRSTEST DS    0H                                                       29900019
         TM    PPTFLG,FIRSTGET     TEST FOR FIRST TIME FOR RGET         30000019
         BNO   CHKWRITE                                                 30100019
         XI    PPTFLG,FIRSTGET     SET FIRSTGET FLAG OFF                30200019
         MVC   SFBUFF1,TUBRAFBF    PROVIDE BUFFER ADDRESS               30400019
         SPACE 2                                                        30500019
***********************************                                     30600019
*                                                                       30700019
* WRITE A BLOCK TO USER LIBRARY                                         30800019
*                                                                       30900019
***********************************                                     31000019
 SPACE                                                                  31100019
WRITEBLK DS    0H                                                       31200019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          31300019
         RWRITE                    WRITE THE BLOCK                      31400019
         B     GETBLOCK                                                 31500019
         EJECT                                                          31600019
SETEODON DS    0H                                                       31700019
         OI    PPTFLG,EODFLAG      SET EOD FLAG INDICATOR ON            31800019
         SPACE 2                                                        31900019
***********************************                                     32000019
*                                                                       32100019
* CHECK RESULTS OF LAST RWRITE INSTRUCTION                              32200019
*                                                                       32300019
***********************************                                     32400019
 SPACE                                                                  32450019
CHKWRITE DS    0H                                                       32500019
         LA    R1,PTTUBPT(0,R13)   LOAD POINTER TO TUB POINTER          32600019
         L     R15,IHKYYWTR        LOAD ADDRESS OF WRITER CHECKER       32700019
         BALR  R14,R15             TEST SUCCESS OF LAST WRITE OP        32800019
         B     *+4(R15)            EVALUTE RETURN CODES                 32900019
         B     UPBLKCNT            NO ERRORS, INCREASE BLOCKS SAVED CNT 33000019
         B     PRMTFULL            LIBRARY OUT OF SPACE                 33100019
         B     RTRNOSTW            GETMAIN FAILURE                      33200019
         B     RTRNOSTW            I/O ERROR                            33300019
         SPACE 2                                                        33400019
***********************************                                     33500019
*                                                                       33600019
* LIBRARY OUT OF SPACE, ATTEMPT CONDENSE                                33700019
*                                                                       33800019
***********************************                                     33900019
 SPACE                                                                  34000019
PRMTFULL DS    0H                                                       34100019
         BAL   INNERBR,TESTEOD     IF NOT RGET EOD, FREE RAFIO BFFER    34200019
         NI    PPTFLG,EODFLAGN     REMOVE THE END-OF-DATA INDICATOR     34300019
         OI    PPTFLG,FULLFLAG     SET TO ON THE LIBRARY FULL FLAG      34400019
         XR    R15,R15             ZERO RETURN CODE                     34500019
         B     RTRNOSTW                                                 34600019
 SPACE                                                                  34700019
TESTEOD  DS    0H                                                       34800019
         TM    PPTFLG,EODFLAG      TEST FOR EOD ON LAST RGET            34900019
         BO    0(INNERBR)          IF EOD, NO NEED FOR FREEMAIN         35000019
 SPACE                                                                  35100019
FRERAFBF DS    0H                                                       35200019
         L     R1,TUBRAFBF         OBTAIN ADDRESS OF RAFIO BUFFER       35300019
         LM    R0,R1,0(R1)         PROVIDE SIZE AND ADDRESS OF BUFFER   35400019
         FREEMAIN  R,LV=(0),A=(1)  FREE BUFFER FROM RAFIO               35500019
         B     0(INNERBR)          RETURN TO CALLING POINT              35600019
          EJECT                                                         35700019
***********************************                                     35800019
*                                                                       35900019
* SET DATA SET ATTRIBUTES                                               36000019
*                                                                       36100019
***********************************                                     36200019
 SPACE                                                                  36300019
UPBLKCNT DS    0H                                                       36400019
         LA    BLKCNT,1(BLKCNT)    INCREASE BLOCK COUNT BY ONE          36500019
         TM    PPTFLG,EODFLAG      IF END OF DATA, TERMINATE            36600019
         BNO   WRITEBLK            IF NOT END OF DATA, WRITE BLOCK      36700019
         MVC   BPBLDLST+4(DIRSIZE),DIRDSECT      INSERT DIR IN KBX      36800019
         TIME  DEC                 OBTAIN TIME                          36900019
         ST    R1,TUBPARM4         STORE  DATE                          37000019
         LA    KBXDIRAD,BPBLDLST+4 OBTAIN ADDRESS OF KONBOX DIR. FIELD  37100019
         CLC   TUBPMFNM,DIRFNAME   TEST FOR DSNAME DIFFERENT FROM EDIT  37200019
         DROP  DIRPT                                                    37300019
         USING DIRDSECT,KBXDIRAD                                        37500019
         BE    SETDATE             IF NAMES EQUAL, DO NOT ZERO X-SAVED  37600019
         XC    DIRSAV,DIRSAV       IF NAMES NOT EQUAL, ZERO X-SAVED     37700019
         MVC   DIRCRE,TUBPARM4+1   IF NEW, SET NEW CREATION DATE        37800019
SETDATE  DS    0H                                                       37900019
         MVC   DIRMODAT,TUBPARM4+1 SET NEW LAST MODIFIED DATE           38000019
         MVC   DIRFNAME,TUBPMFNM   SET DATA SET FILE NAME               38100019
         STH   BLKCNT,DIRNOBLK     SET BLOCK COUNT                      38200019
         CLC   PPTWD1(KEYLNG,PPTADDR),DBLWDBLK   TEST FOR KEY OF BLANKS 38300019
         BNE   SETKEY              IF KEY NOT BLANKS, LOAD KEY INTO DIR 38400019
         TM    PPTFLG,DSOPFLAG     TEST FOR DSNAME OPERAND              38500019
         BNO   CLOSTOW             IF NO OPERAND, RETAIN EXISTING KEY   38600019
 SPACE                                                                  38700019
SETKEY   DS    0H                                                       38800019
         MVC   DIRKEY,PPTWD1(PPTADDR) IF OPERAND, SET NEW KEY WORD      38900019
         DROP  KBXDIRAD                                                 39000019
         USING DIRDSECT,DIRPT                                           39100019
CLOSTOW  DS    0H                                                       39200019
         LA    R1,PTTUBPT(0,R13)   LOAD ADDRESS OF POINTER TO TUB       39300019
         RCLOSE    STOW                                                 39400019
         B     *+4(R15)            EVALUATE RETURN CODES                39500019
         B     RTRNCLS                 GOOD RETURN               S21085 39600021
         B     CONDENS1            END OF VOLUME,ATTEMPT CONDENSE       39700019
         B     RETURN              GETMAIN FAILURE                      39800019
         B     LIBIOERR            I/O ERROR                            39900019
         OI    PPTFLG,DIRFULL      SET DIRECTORY FULL FLAG              40000019
         B     SCRATCH             DIRECTORY FULL, ATTEMPT SCRATCH      40100019
          EJECT                                                         40200019
***********************************                                     40300019
*                                                                       40400019
* CONDENSE THE USER LIBRARY - SCRATCH DATA SETS                         40500019
*                                                                       40600019
***********************************                                     40700019
 SPACE                                                                  40800019
CONDENSE DS    0H                                                       40900019
         XI    PPTFLG,FULLFLAG     SET TO OFF FLAG FOR FULL LIBRARY     41000019
CONDENS1 DS    0H                                                       41100019
         NI    PPTFLG,EODFLAGN                                  OS63569 41150028
         MVC   PPTWD0(DBLWDLNG,PPTADDR),TUBPMFNM  SAVE FILE NAME        41200019
         TM    PPTFLG,CNDSFLAG     TEST FOR PREVIOUS CONDENSE ATTEMPT   41300019
         BNO   SETCNDS             IF FIRST PASS, SET CONDENSE FLAG ON  41400019
         XI    PPTFLG,CNDSFLAG     SET THE CONDENSE FLAG                41500019
SCRATCH  DS    0H                                                       41600019
         MVC   PPTWD0(DBLWDLNG,PPTADDR),TUBPMFNM  SAVE THE FILE NAME    41700019
         TM    TUBFLG2,TUBABEND    TEST FOR ABEND SAVE                  41800019
         BO    SETABND1            IF ABEND, USE ABEND TERMINATION      41900019
         TM    PPTFLG,DIRFULL      TEST FOR DIRECTORY FULL CONDITION    42000019
         BZ    LIBSRTCH            IF NOT, LIBRARY FULL CONDITION       42100019
         LA    MSGCODE,MSGSRTC0    PROMPT DIR FULL, SCRATCH DS NAME     42200019
         B     MSGSRTCH                                                 42300019
         SPACE 1                                                        42400019
LIBSRTCH DS    0H                                                       42500019
         LA    MSGCODE,MSGSRTC1    ADVISE LIBRARY FULL                  42600019
MSGSRTCH DS    0H                                                       42700019
         BAL   INNERBR,CALLMSG     PROMPT USER FOR DSNAME TO DELETE     42800019
TSTDSNM  DS    0H                                                       42900019
         L     USRBUFAD,TUBUFFAD   OBTAIN ADDRESS OF DSNAME RETURNED    43000019
         LH    COUNT,TUBDATAL      OBTAIN LENGTH OF DSNAME RETURNED     43100019
         LTR   COUNT,COUNT         TEST FOR DSNAME RETURNED             43200019
         BZ    CHKSRTCH            IF NO DSNAME, TEST FOR PRIOR SCRATCH 43300019
         LA    INNERBR2,ERRDSNM    PROVIDE ALPHATST BRANCHING ADDRESS   43600019
         BAL   INNERBR,ALFATST     TEST FOR ALPHABETIC FIRST CHARACTER  43700019
         BAL   INNERBR,MOVDSNM     MOVE DSNAME INTO TUB                 43800019
         BAL   INNERBR,RNQUEUE     ENQUEUE FOR BPAM I/O                 43900019
         LA    R1,PTTUBPT(0,R13)   PROVIDE POINTER TO TUB POINTER       44000019
         RSCRATCH                  REMOVE DATA SET FROM USER LIBRARY    44100019
         B     *+4(R15)            EVALUATE RETURN CODE                 44200019
         B     SETSRTCH            NO ERRORS, SET SCRATCH INDICATOR     44300019
         B     ERRDSNM             DATA SET NOT FOUND, PROMPT FOR NEW   44400019
         B     RETURN              GETMAIN FAILURE                      44500019
         B     LIBIOERR            I/O ERROR                            44600019
         EJECT                                                          44700019
SETSRTCH DS    0H                                                       44800019
         OI    PPTFLG,SRTCFLAG     SET SUCCESSFUL SCRATCH INDICATOR     44900019
         LA    MSGCODE,MSGSRTC2    PROMPT USER FOR ANOTHER DSNAME       45000019
         BAL   INNERBR,CALLMSG                                          45100019
         B     TSTDSNM             TEST THE ACCEPTABILITY OF NEW DSNAME 45200019
ERRDSNM  DS    0H                                                       45300019
         LA    MSGCODE,MSGSRTC3    INFORM USER OF ERROR IN LAST DSNAME  45400019
         BAL   INNERBR,CALLMSG     PROMPT FOR NEW DSNAME                45500019
         B     TSTDSNM             TEST THE ACCEPTABILITY OF NEW DSNAME 45600019
CHKSRTCH DS    0H                                                       45700019
         TM    PPTFLG,SRTCFLAG     TEST FOR PRIOR SCRATCH OF DATA SET   45800019
         BZ    RTRNGOOD            IF NONE SCRATCHED, END SAVE ATTEMPT  45900019
         XI    PPTFLG,SRTCFLAG     REMOVE SCRATCH INDICATOR             46000019
         TM    PPTFLG,DIRFULL      TEST FOR DIRECTORY FULL CONDITION    46100019
         BZ    SETCNDS             IF NOT, LIBRARY FULL, CONDENSE       46200019
         XI    PPTFLG,DIRFULL      SET DIRECTORY FULL FLAG OFF          46300019
         MVC   TUBPMFNM,PPTWD0(PPTADDR) RESTORE SPECIFIED FILE NAME     46400019
         B     POINT               RETRY SAVE                           46500019
          EJECT                                                         46600019
***********************************                                     46700019
*                                                                       46800019
* CONDENSE THE USER LIBRARY                                             46900019
*                                                                       47000019
***********************************                                     47100019
         SPACE 1                                                        47200019
SETCNDS  DS    0H                                                       47300019
         OI    PPTFLG,CNDSFLAG     SET FLAG TO INDICATE CONDENSING      47400019
         ST    TUBPT,TUBPARM1      PROVIDE ADDRESS OF TUB               47500019
         ST    AVTPT,TUBPARM2      PROVIDE ADDRESS OF AVT               47600019
         LA    PARMREG,TUBPRMLS    PROVIDE ADDRESS OF PARM LIST         47700019
         LA    RTRNREG,CMDCDP      OBTAIN THE CONDENSE COMMAND CODE     47800019
         LNR   RTRNREG,RTRNREG     LOAD NEGATIVE OF CONDENSE CODE       47900019
         B     RETURN2             EXIT SAVE FOR CONDENSE OPERATION     48000019
         SPACE 2                                                        48100019
RTRNCNDS DS    0H                                                       48200019
         MVC   TUBPMFNM,PPTWD0(PPTADDR) RESTORE SPECIFIED FILE NAME     48300019
         L     R15,TUBPARM5        OBTAIN THE CONDENSE RETURN CODE      48400019
         LTR   R15,R15                 EVALUATE RETURN CODE      S21085 48500021
         BZ    POINT                   NO ERRORS, RETURN TO POINTS21085 48600021
         CH    R15,H20KN               I/O OR GETMAIN ERROR      S21085 48700021
         BE    RTRNBAD2                 GETMAIN ERROR            S21085 48800021
         SPACE 1                                                        49200019
 SPACE                                                                  49700019
ERRCNDS1 DS    0H                                                       49800019
         LA    MSGCODE,MSGCNDS     PROVIDE CODE FOR LIBRARY I/O ERROR   49900019
         BAL   INNERBR,CALLMSG1    PROCEED TO MESSAGE WRITER            50000019
         B     RTRNGOOD            TERMINATE SAVE                       50100019
          EJECT                                                         50200019
***********************************                                     50300019
*                                                                       50400019
* PROMPT USER FOR NEW DSNAME TO REPLACE DUPLICATE NAME                  50500019
*                                                                       50600019
***********************************                                     50700019
 SPACE                                                                  50800019
PRMTDSNM DS    0H                                                       50900019
         LA    MSGCODE,MSGDSNM     PROMPT USER FOR DSNAME               51000019
         BAL   INNERBR,CALLMSG     SEND REQUEST                         51100019
TSTDSDUP DS    0H                                                       51200019
         L     USRBUFAD,TUBUFFAD   OBTAIN ADDRESS OF DSNAME RETURNED    51300019
         LH    COUNT,TUBDATAL      OBTAIN LENGTH OF DSNAME RETURNED     51400019
         LTR   COUNT,COUNT         TEST FOR DSNAME RETURNED             51500019
         BZ    POINT               IF NO DSNAME, SAVE AND REPLACE DUPL  51600019
         NI    PPTFLG,DUPLFLGN     SET TO OFF THE DUPLICATE FLAG        51700019
         LA    INNERBR2,ERRDSDUP   PROVIDE ALPHATST BRANCHING ADDRESS   52000019
         BAL   INNERBR,ALFATST     TEST FOR ALPHABETIC FIRST CHARACTER  52100019
         BAL   INNERBR,MOVDSNM     INSERT DSNAME INTO TUB               52200019
         B     POINT               RETRY SAVE WITH NEW DSNAME           52300019
 SPACE                                                                  52400019
NODSPRMT DS    0H                                                       52430019
         OI    PPTFLG,DSOPFLAG     SET FLAG TO BLANK KEY FIELD          52460019
ERRDSDUP DS    0H                                                       52500019
         LA    MSGCODE,MSGSRTC3    PROMPT USER FOR CORRECTED DSNAME     52600019
         BAL   INNERBR,CALLMSG     SEND REQUEST                         52700019
         B     TSTDSDUP            TEST ACCEPTABILITY OF DSNAME         52800019
*                                                                       52900019
          EJECT                                                         53000019
***********************************                                     53100019
*                                                                       53200019
* TEST FIRST CHARACTER FOR ALPHABETIC                                   53300019
*                                                                       53400019
***********************************                                     53500019
 SPACE                                                                  53600019
ALFATST  DS    0H                                                       53700019
         LR    PARMREG,USRBUFAD    PROVIDE ADDRESS OF DSNAME            53720019
ALFATST1 DS    0H                                                       53740019
         CH    COUNT,DSNMLNG       TEST LENGTH OF DSNAME                53760019
         BCR   HIGH,INNERBR2       IF TOO LONG, SEND ERROR MSG.         53780019
         B     ALFATST3            FIRST TEST FOR A-Z,$,#,@             53800019
ALFATST2 DS    0H                                                       53820019
         CLI   0(PARMREG),C0       TEST FOR CHAR. LESS THAN 0           53840019
         BL    ALFATST3            IF LESS, TEST FOR A-Z,$,#,@          53860019
         CLI   0(PARMREG),C9       TEST FOR CHAR. GREATER THAN 9        53880019
         BCR   HIGH,INNERBR2       IF GREATER, ERROR                    53900019
         B     ALFATST4            IF BETWEEN 0 AND 9, TEST NEXT CHAR.  53920019
ALFATST3 DS    0H                                                       53940019
         CLI   0(PARMREG),C$       TEST FOR $                           53960019
         BE    ALFATST4            IF $, TEST NEXT CHAR.                53980019
         CLI   0(PARMREG),C#       TEST FOR #                           54000019
         BE    ALFATST4            IF #, TEST NEXT CHAR.                54020019
         CLI   0(PARMREG),C@       TEST FOR @                           54040019
         BE    ALFATST4            IF @, TEST NEXT CHAR.                54060019
         CLI   0(PARMREG),CA       TEST FOR CHAR. LESS THAN A           54080019
         BCR   LOW,INNERBR2        IF LESS, INDICATE ERROR              54100019
         CLI   0(PARMREG),CZ       TEST FOR CHAR. GREATER THAN Z        54120019
         BCR   HIGH,INNERBR2       IF GREATER, INDICATE ERROR           54140019
ALFATST4 DS    0H                                                       54160019
         LA    PARMREG,1(PARMREG)  POINT TO NEXT CHAR. OF DSNAME        54180019
         BCT   COUNT,ALFATST2      TEST NEXT CHAR. OF DSNAME            54200019
         BR    INNERBR             RETURN TO CALLING POINT              54400019
         SPACE 2                                                        54500019
***********************************                                     54600019
*                                                                       54700019
* MOVE DSNAME INTO TUB BPAM FILE NAME FIELD                             54800019
*                                                                       54900019
***********************************                                     55000019
 SPACE 2                                                                55100019
MOVDSNM  DS    0H                                                       55200019
         BCTR  USRBUFAD,0          SET DSNAME PTR BACK ONE              55250019
         LH    INCR,TUBDATAL       PROVIDE LENGTH OF DSNAME             55300019
MOVDSNM1 DS    0H                                                       55400019
         MVC   TUBPMFNM,DBLWDBLK   BLANK OUT TUB FILE NAME              55500019
         BCTR  INCR,0              DECREMENT LENGTH FOR EXECUTE INST    55600019
         EX    INCR,NSRTDSNM       MOVE DSNAME OPERAND INTO TUB         55700019
         BR    INNERBR             RETURN TO CALLING POINT              55800019
 SPACE                                                                  55900019
NSRTDSNM DS    0H                                                       56000019
         MVC   TUBPMFNM(0),1(R8)        PROVIDE DSNAME OPERAND FOR BPAM 56100019
*                                                                       56200019
         EJECT                                                          56300019
***********************************                                     56400019
*                                                                       56500019
* ADVANCE PPT POINTER TO THE NEXT OPERAND AND TEST FOR LAST OPERAND     56600019
*                                                                       56700019
***********************************                                     56800019
 SPACE                                                                  56900019
NEXTTEST DS    0H                                                       57000019
         XR    INCR,INCR           CLEAR REG OF INCREMENT               57100019
         NI    0(PPTPT),MX3F       ISOLATE THE OPERAND LENGTH COUNT     57200019
         IC    INCR,0(,PPTPT)      OBTAIN LENGTH OF PARAMETER FIELD     57300019
         LA    PPTPT,1(INCR,PPTPT) INCREMENT PPT POINTER                57400019
FRSTTEST DS    0H                                                       57500019
         LA    OPNDCTR,1(OPNDCTR)  INCREMENT OPERAND COUNTER            57600019
RETEST   DS    0H                                                       57700019
         TM    0(PPTPT),LASTOPND                                        57800019
         BNO   0(INNERBR)          IF NO OPERAND, RETURN                57900019
         L     PPTESTRG,PPTCHAD    OBTAIN ADDR FLD OF NEXT PPT IN CHAIN 58000019
         LA    PPTESTRG,0(PPTESTRG)                                     58100019
         LTR   PPTESTRG,PPTESTRG   TEST FOR PRESENTS OF ADDRESS         58200019
         BZ    CHKERRSW            IF NO ADDRESS, CHECK ERROR SWITCH    58300019
         OC    0(1,PPTESTRG),0(PPTADDR) MOVE FLAGS TO NEXT PPT          58400019
         LR    PPTADDR,PPTESTRG    CHANGE POINTER TO NEXT PPT           58500019
         LA    PPTPT,PPTPARS       OBTAIN ADDRESS OF PARAMETER FLD      58600019
         B     RETEST                                                   58700019
          EJECT                                                         58800019
***********************************                                     58900019
*                                                                       59000019
* INVALID OPERAND ERROR                                                 59100019
*                                                                       59200019
***********************************                                     59300019
 SPACE 2                                                                59400019
ERRKEY   DS    0H                                                       59500019
         BAL   INNERBR,MSGNSRT     INSERT INTO MESSAGE                  59600019
         LA    MSGCODE,MSGKEY      PROVIDE MSG CODE FOR INVALID KEY     59700019
         B     ERROPND1                                                 59800019
ERRNOPND DS    0H                                                       59900019
         BAL   INNERBR,MSGNSRT     INSERT INTO MESSAGE                  60000019
         LA    MSGCODE,MSGNOPND    MESSAGE CODE FOR INVALID OPERAND     60100019
ERROPND1 DS    0H                                                       60200019
         BAL   INNERBR,CALLMSG1                                         60300019
         STC   R0,0(PPTPT)         RESORE    LENGTH BYTE TO PPT         60400019
         OI    0(PPTADDR),ERRORSW  INDICATE ERROR                       60500019
         BAL   INNERBR,NEXTTEST    RETURN TO TEST FOR NEXT OPERAND      60600019
         CH    OPNDCTR,TWO         TEST OPERAND COUNTER                 60700019
         BE    TSTOPND2            IF SECOND OPND, CHECK FOR KEY        60800019
         B     LASTTEST            OTHER THAN SECON OPND, TEST FOR LAST 60900019
         SPACE 2                                                        61000019
***********************************                                     61100019
*                                                                       61200019
* NO DDNAME OR NO LIBRARY ERROR                                         61300019
*                                                                       61400019
***********************************                                     61500019
 SPACE                                                                  61600019
ERRDD    DS    0H                                                       61700019
         LA    MSGCODE,MSGDD       POINT TO CODE FOR NO DDNAME GIVEN    61800019
 SPACE                                                                  62300019
ERREXIT  DS    0H                                                       62900019
         BAL   INNERBR,CALLMSG1    SEND MESSAGE TO USER                 63000019
         B     RTRNGOOD            RETURN CODE OF ZERO TO CALLER        63100019
         EJECT                                                          63200019
***********************************                                     63300019
*                                                                       63400019
* INSERT TEXT INTO MESSAGE                                              63500019
*                                                                       63600019
***********************************                                     63700019
 SPACE                                                                  63800019
MSGNSRT  DS    0H                                                       63900019
         NI    0(PPTPT),MX3F       ISOLATE THE OPERAND LENGTH COUNT     64000019
         IC    R0,0(PPTPT)         SAVE LENGTH BYTE FROM PPT            64100019
         CLI   0(PPTPT),MAXINSRT   TEST FOR LENGTH TOO GREAT            64200019
         BNH   ACCPTABL            IF LENGTH NOT TOO GREAT, ACCEPABLE   64300019
         MVI   0(PPTPT),MAXINSRT   REPLACE LENGTH WITH MAXIMUM          64400019
ACCPTABL DS    0H                                                       64500019
         ST    PPTPT,TUBPARM4      PROVIDE POINTER TO BAD PARM.         64600019
         OI    TUBPARM4,MX80       SET LAST PARM FLAG                   64700019
         BR    INNERBR             RETURN                               64800019
         SPACE 2                                                        64900019
***********************************                                     65000019
*                                                                       65100019
* CALL MESSAGE WRITER TO NOTIFY USER OF CONDITION                       65200019
*                                                                       65300019
***********************************                                     65400019
 SPACE                                                                  65500019
CALLMSG  DS    0H                                                       65600019
         ST    MSGCODE,TUBPARM3    STORE THE MESSAGE CODE ADDRESS       65700019
         MVI   TUBPARM3,MX80       SET THE LAST PARAMETER INDICATOR     65800019
         ST    TUBPT,TUBPARM2      STORE THE TUB ADDRESS IN PARM LIST   65900019
CALLMSG0 DS    0H                                                       66000019
         ST    TUBPT,TUBPARM1      STORE THE TUB ADDRESS IN PARM LIST   66100019
         LA    PARMREG,TUBPRMLS    PROVIDE ADDRESS OF PARAMETER LIST    66200019
         L     R15,IHKYYMSG        OBTAIN ADDRESS OF MESSAGE WRITER     66300019
         B     MSGWTR              CALL MESSAGE WRITER                  66400019
         SPACE 2                                                        66500019
CALLMSG1 DS    0H                                                       66600019
         ST    MSGCODE,TUBPARM3    PROVIDE POINTER TO MSG CODE          66700019
         MVC   TUBPARM3(1),0(MSGCODE)  LAST PARAMETER FLAG IF APPROP.   66800019
         LA    MSGCODE,TUBUSRID                                         66900019
         ST    MSGCODE,TUBPARM2    PROVIDE POINTER TO USER ID           67000019
         ST    TUBPT,TUBPARM1      PROVIDE POINTER TO TUB               67100019
         LA    PARMREG,TUBPRMLS    PROVIDE ADDRESS OF PARAMETER LIST    67200019
         L     R15,IHKYMSG1        OBTAIN ADDRESS OF MESSAGE WRITER     67300019
         SPACE 2                                                        67400019
MSGWTR   DS    0H                                                       67500019
         BALR  R14,R15             BRANCH TO MESSAGE WRITER             67600019
         TM    TUBFLG2,TUBABEND    TEST FOR ABEND TERMINATION           67700019
         BO    0(INNERBR)          IF ABEND, RETURN WITH NEGATIVE END   67800019
         LTR   R15,R15                                                  67900019
         BCR   8,INNERBR           NO ERRORS                     A34591 67970020
         NI    PPTFLG,DUPLFLGN     TURN OFF DUPLICATE DSNAME     A34591 68040020
         B     RETURN              SET RETURN CODE               A34591 68110020
          EJECT                                                         68200019
***********************************                                     68300019
*                                                                       68400019
* RETURN AFTER NOSTOW CLOSE                                             68500019
*                                                                       68600019
***********************************                                     68700019
 SPACE                                                                  68800019
RTRNOSTW DS    0H                                                       68900019
         LR    RTRNREG,R15                                              69000019
         LA    R1,PTTUBPT(0,R13)   LOAD ADDRESS OF POINTER TO TUB       69100019
         RCLOSE    NOSTOW                                               69200019
         B     *+4(R15)            EVALUATE RETURN CODE                 69300019
         B     CHKFOR12            NO ERROR, CHECK FOR I/O ERROR        69350019
         BCR   0,R15               END OF VOLUME                        69450019
         XR    R15,R15             NO VALID MEANING                     69550019
         B     CHKFOR12            GETMAIN FAILURE                      69650019
         B     LIBIOERR            I/O ERROR                            69750019
 SPACE                                                                  69900019
CHKFOR12 DS    0H                                                       70000019
         LA    R1,GTMNFAIL         OBTAIN MODEL OF GETMAIN FAIL  A48979 70010000
         CLR   R1,RTRNREG          TEST FOR GETMAIN FAIL ERROR   A48979 70020000
         BE    RTRNBAD2            IF EQUAL, INDICATE GETMAIN FAIL      70030000
*                                                                A48979 70040000
         LA    R1,AAIOFAIL         OBTAIN MODEL OF LIBRARY I/O ERROR    70060019
         CLR   R1,RTRNREG          TEST FOR LIBRARY I/O ERROR           70120019
         BE    LIBIOERR            IF EQUAL, INDICATE LIBRARY I/O ERROR 70180019
         LNR   R1,R1               OBTAIN MODEL OF ACTIVE AREA I/O ERR  70240019
         CLR   R1,RTRNREG          TEST FOR ACTIVE AREA I/O ERROR       70300019
         BE    RTRNBAD3            IF EQUAL, INDICATE ACTIVE AREA I/O E 70360019
         B     RETURN              IF NOT I/O ERROR, SET RETURN CODE    70420019
          EJECT                                                         70500019
***********************************                                     70600019
*                                                                       70700019
* LIBRARY I/O ERROR                                                     70800019
*                                                                       70900019
***********************************                                     71000019
 SPACE                                                                  71100019
LIBIOERR DS    0H                                                       71200019
         LA    PARMREG,UTMCODE1    PROVIDE UTM CODE FOR LIB INOPERATIVE 71300019
         ST    PARMREG,TUBPARM2                                         71400019
         BAL   INNERBR,CALLUTM     FLAG LIBRARY AS INOPERATIVE          71500019
         XR    PARMREG,PARMREG                                          71600019
         ST    PARMREG,TUBPARM2    INDICATE MSG FOR CENTRAL OPERATOR    71700019
         LA    MSGCODE,MSGLIBER                                         71800019
         ST    MSGCODE,TUBPARM3    PROVIDE CODE FOR LIB IN ERROR        71900019
         L     USRBUFAD,TUBUFFAD                                        72000019
         USING TEXTNSRT,USRBUFAD   USE USER BUFFER FOR MSG INSERTS      72100019
         MVI   TEXT1LNG,LNG8       SET LENGTH FOR DDNAME INSERT         72200019
         MVC   TEXT1TXT,PPTWD2(PPTADDR) PROVIDE DDNAME AS INSERT        72300019
         MVI   TEXT2LNG,LNG8       SET LENGTH FOR USERID INSERT         72400019
         MVC   TEXT2TXT,TUBUSRID   PROVIDE USERID AS INSERT             72500019
         LA    PARMREG,TEXT1                                            72600019
         ST    PARMREG,TUBPARM4    PROVIDE ADDRESS OF DDNAME            72700019
         LA    PARMREG,TEXT2                                            72800019
         ST    PARMREG,TUBPARM5    PROVIDE ADDRESS OF USERID            72900019
         DROP  USRBUFAD                                                 73000019
         BAL   INNERBR,CALLMSG0    SEND LIBRARY ERROR MSG TO CENTRAL    73100019
ERRLIBNO DS    0H                                                       73200019
         LA    MSGCODE,MSGLIBNO    PROVIDE MSG CODE FOR LIBRARY INOP    73300019
         BAL   INNERBR,CALLMSG1                                         73400019
          EJECT                                                         73600019
***********************************                                     73700019
*                                                                       73800019
* RETURN CODES AND EXIT PROCEEDUSES                                     73900019
*                                                                       74000019
***********************************                                     74100019
 SPACE                                                                  74110019
RTRNGOOD DS    0H                  RETURN CODE FOR NO ERROR             74120019
         XR    R15,R15                                                  74130019
         TM    TUBFLG2,TUBABEND    TEST FOR ABEND TERMINATION           74140019
         BO    SETABND1            IF ABEND, SEND ACTIVE AREA LOST MSG  74150019
         B     RETURN                                                   74160019
 SPACE                                                                  74170019
 SPACE                                                                  74200019
RTRNBAD3 DS    0H                  RETURN CODE FOR ACTIVE AREA I/O ERR  74300019
         LA    R15,AAIOFAIL                                             74400019
         B     RETURN                                                   74500019
 SPACE                                                                  74600019
RTRNBAD2 DS    0H                  RETURN CODE FOR FAILURE OF GETMAIN   74700019
         LA    R15,GTMNFAIL                                             74800019
         SPACE 2                                                 S21085 74900021
RTRNCLS  TM    TUBFLG4,TUBLIB80        DATA LOST SAVING 80 CHAR. S21085 75000021
         BZ    RETURN                  NO                        S21085 75100021
         LA    MSGCODE,MSGLNO      GET MESSAGE CODE              S21085 75200021
         BAL   INNERBR,CALLMSG1    QUEUE MESSAGE                 S21085 75300021
         B     RETURN                                            S21085 75400021
         EJECT                                                          75500019
***********************************                                     75600019
*                                                                       75700019
* RETURN TO CALLING ROUTINE                                             75800019
*                                                                       75900019
***********************************                                     76000019
 SPACE                                                                  76100019
RETURN   DS    0H                                                       76200019
         LR    RTRNREG,R15                                              76300019
RETURN1  DS    0H                                                       76400019
         TM    TUBFLG2,TUBABEND    TEST FOR ABEND SAVE                  76500019
         BZ    RETURN2                                                  76600019
         TM    PPTFLG,DIRFULL      CHECK FOR DIRECTORY FULL             76700019
         BO    SETABND1            IF DIR FULL, SEND NOT-SAVED MSG      76800019
         TM    PPTFLG,FULLFLAG     CHECK FOR LIBRARY FULL               76900019
         BO    CONDENSE            LIBRARY FULL, ATTEMPT CONDENSE       77000019
SETABND  DS    0H                                                       77100019
         LTR   RTRNREG,RTRNREG     TEST FOR A RETURN CODE OF ZERO       77200019
         BNZ   SETABND1            IF NON-ZERO, SEND MSG FOR NO SAVE    77300019
         LA    MSGCODE,MSGABND     IF ZERO, SEND MSG FOR SAVE OF ACTIVE 77400019
         B     SETABND2                                                 77500019
SETABND1 DS    0H                                                       77600019
         LA    MSGCODE,MSGABND1    IF NON-ZERO, SEND MSG FOR NO SAVE    77700019
SETABND2 DS    0H                                                       77800019
         XC    PPTFLG,PPTFLG       CLEAR THE SPECIAL CONDITION FLAGS    77900019
         BAL   INNERBR,CALLMSG1    ENQUEUE MSG TO USER                  78000019
         LA    RTRNREG,CMDEND      PROVIDE RETURN CODE FOR ABEND        78100019
         LNR   RTRNREG,RTRNREG                                          78200019
RETURN2  DS    0H                                                       78300019
         TM    PPTFLG,FULLFLAG     TEST FOR FULL LIBRARY FLAG           78400019
         BO    CONDENSE            IF FULL FLAG ON, CONDENSE LIBRARY    78500019
         TM    PPTFLG,DUPLFLAG     TEST FOR DUPLICATE DSNAME INDICATOR  78600019
         BO    PRMTDSNM            IF SET, PROMPT FOR NEW DSNAME        78700019
         MVC   TUBPMFNM,DIRFNAME   RESTORE ORIGINAL DS NAME TO TUB      78800019
         NI    TUBFLG4,X'FF'-TUBLIB80  TURN OFF 80 CHAR. SWITCH  S21085 78850021
         L     R11,CALLNGSA(R13)   LOAD ADDRESS OF CALLING SAVE AREA    78900019
         ST    RTRNREG,RTRNCODE(0,R11)       PLACE RETURN CODE IN HSA   79000019
         LA    R0,NEED       PROVIDE SIZE OF SAVE AREA                  79100019
         LR    R1,R13              PROVIDE ADDRESS OF SAVE AREA         79200019
         FREEMAIN  R,LV=(0),A=(1)                                       79300019
         LR    R13,R11             RESTORE ADDRESS OF CALLING SAVE AREA 79400019
         RETURN (14,12),T          RETURN TO LINE ADMINISTRATOR         79500019
         EJECT                                                          79600019
***********************************                                     79700019
*                                                                       79800019
*        EQUATES                                                        79900019
*                                                                       80000019
***********************************                                     80100019
 SPACE                                                                  80200019
MAXINSRT EQU   10                  LENGTH OF MAXIMUN MESSAGE INSERT     80300019
DBLWDLNG EQU   8                   LENGTH OF DOUBLE WORD                80400019
KEYLNG   EQU   3                   LENGTH OF KEY OPERAND                80600019
 SPACE                                                                  80700019
MX80     EQU   X'80'               FLAG FOR LAST OPERAND                80800019
DUPLFLAG EQU   X'01'               FLAG FOR DUPLICATE DSNAME            80900019
DUPLFLGN EQU   X'FE'               FLAG FOR SETTING TO OFF DUPLFLAG     81000019
FIRSTGET EQU   X'01'               FLAG FOR FIRST RGET                  81100019
EODFLAG  EQU   X'02'               FLAG FOR EOD FOUND IN ACTIVE FILE    81200019
EODFLAGN EQU   X'FD'                                                    81300019
DIRFULL  EQU   X'04'               FLAG FOR DIRECTORY FULL CONDITION    81400019
DSOPFLAG EQU   X'10'               FLAG FOR DSNAME OPERAND IN PPT       81500019
DSOPFLGN EQU   X'EF'               FLAG FOR SETTING TO OFF DSOPFLAG     81600019
CNDSFLAG EQU   X'20'               FLAG FOR LIBRARY CONDENSE TRIED      81700019
SRTCFLAG EQU   X'40'               FLAG FOR SUCCESSFUL SCRATCH          81800019
FULLFLAG EQU   X'80'               FLAG FOR LIBRARY FULL                81900019
ERRORSW  EQU   X'20'               SWITCH FOR ERROR CONDITION IN PARAMS 82000019
 SPACE                                                                  82100019
NEED     EQU   72                  NEEDED SPACE FOR SAVE                82200019
BLKSIZE  EQU   10                  BLOCKING FACTOR                      82300019
 SPACE                                                                  82400019
LASTOPND EQU   X'FF'               MASK FOR TESTING LAST OPERAND        82500019
MX3F     EQU   X'3F'               MASK FOR ISOLATING OPND LNG CTR      82600019
MDLKEY   EQU   X'C3'               MASK FOR KEY OPERAND                 82700019
C0       EQU   C'0'                NAME TEST FOR 0                      82730019
C9       EQU   C'9'                NAME TEST FOR 9                      82760019
C$       EQU   C'$'                NAME TEST FOR $                      82790019
C#       EQU   C'#'                NAME TEST FOR #                      82820019
C@       EQU   C'@'                NAME TEST FOR @                      82850019
CA       EQU   C'A'                NAME TEST FOR A                      82880019
CZ       EQU   C'Z'                NAME TEST FOR Z                      82910019
 SPACE                                                                  83000019
PPTWD0   EQU   8                                                        83100019
PPTWD1   EQU   16                  DISPLACEMENT OF FIRST DBL WD IN PPT  83200019
PPTWD2   EQU   24                  DISPLACEMENT OF SECOND DBL WD IN PPT 83300019
PTTUBPT  EQU   64                  DISPLACEMENT OF PT TO TUB PT         83400019
LGNALLOC EQU   0                   DISPLACEMENT OF LENGTH ALLOCATION    83500019
CALLNGSA EQU   4                   DISPLACEMENT OF CALLING SAVE AREA PT 83600019
CALLEDSA EQU   8                   DISPLACEMENT OF CALLED  SAVE AREA PT 83700019
RETURNPT EQU   12                  DISPLACEMENT OF RETURN POINTER       83800019
RTRNCODE EQU   16                  DISPLACEMENT OF RETURN CODE IN SV AR 84000019
SAVEREGS EQU   20                  DISPLACEMENT OF REGISTERS SAVED      84100019
 SPACE                                                                  84200019
LOW      EQU   4                   CONDITION CODE FOR COMPARE LOW       84300019
HIGH     EQU   2                   CONDITION CODE FOR COMPARE HIGH      84400019
 SPACE                                                                  84500019
NOERROR  EQU   0                   RETURN CODE FOR NO ERROR             84600019
LINEERR  EQU   4                   RETURN CODE FOR LINE ERROR           84700019
GTMNFAIL EQU   8                   RETURN CODE FOR FAILURE OF GETMAIN   84800019
AAIOFAIL EQU   12                  RETURN CODE FOR ACTIVE AREA I/O ERR  84900019
 SPACE                                                                  85000019
LNG8     EQU   X'08'               LENGTH FOR DDNAME AND USERID         85100019
         EJECT                                                          85200019
***********************************                                     85300019
*                                                                       85400019
*        CONSTANTS                                                      85500019
*                                                                       85600019
***********************************                                     85700019
 SPACE                                                                  85800019
UTMCODE  DC    X'80'               CODE FOR UTM ENQUEUE                 86100019
UTMCODE1 DC    X'04'               CODE FOR UTM FLAGING OF LIBRARY      86200019
 SPACE                                                                  86300019
MDLKEY1  DC    X'03D2C5E8'         MODEL FOR KEY                        86400019
MDLKEY2  DC    X'01D2'             MODEL FOR K                          86500019
 SPACE                                                                  86600019
         EJECT                                                          87000019
***********************************                                     87100019
*                                                                       87200019
*        MESSAGE NUMBER CONSTANTS                                       87300019
*                                                                       87400019
***********************************                                     87500019
         SPACE 2                                                        87600019
         CNOP  0,4                                                      87700019
 SPACE                                                                  87800019
MSGLIBER DC    X'00F2F4F1'         MESSAGE CODE FOR LIBRARY I/O ERROR   87900019
MSGNOPND DC    X'00F3F0F2'         MESSAGE CODE FOR OPERAND INVALID     88000019
MSGCNDS  DC    X'80F3F1F8'         MESSAGE CODE FOR CONDENSE ERROR MSG  88100019
MSGEXCSS DC    X'00F3F3F4'         MESSAGE CODE FOR EXCESSIVE OPERANDS  88200019
MSGKEY   DC    X'00F3F6F9'         MESSAGE CODE FOR INVALID KEY         88400019
MSGLIBNO DC    X'80F3F7F0'         MESSAGE CODE FOR LIBRARY INOPRTV     88500019
MSGDD    DC    X'80F3F7F5'         MESSAGE CODE FOR NO DDNAME OR LIBRRY 88600019
MSGABND  DC    X'80F3F8F9'         MESSAGE CODE FOR ABEND SAVE          88700019
MSGNULDS DC    X'80F3F9F2'         MESSAGE CODE FOR NULL DATA SET MSG   88800019
MSGDSNM  DC    X'01F3F9F4'         MESSAGE CODE FOR DUPLICATE DSNAME    88900019
MSGSRTC1 DC    X'01F3F9F5'         MESSAGE CODE FOR LIBRARY FULL        89000019
MSGSRTC2 DC    X'01F3F9F6'         MESSAGE CODE FOR DELETE DSNAME       89100019
MSGSRTC3 DC    X'01F3F9F7'         MESSAGE CODE FOR DSNAME IN ERROR     89200019
MSGABND1 DC    X'80F4F0F3'         MESSAGE CODE FOR ABEND WITH NO SAVE  89300019
MSGSRTC0 DC    X'01F4F0F9'         MESSAGE CODE FOR DIR FULL - SCRATCH  89400019
MSGLNO   DC    X'00F4F1F0'         MESSAGE CODE FOR DATA LOST    S21085 89450021
         EJECT                                                          89500019
***********************************                                     89600019
*                                                                       89700019
*        DSECT                                                          89800019
*                                                                       89900019
***********************************                                     90000019
 SPACE                                                                  90100019
TEXTNSRT DSECT                                                          90200019
         DS    CL88                FIELD USER BY MSG WTR                90300019
TEXT1    DS    0C                                                       90400019
TEXT1LNG DS    C                   LENGTH BYTE FOR FIRST TEXT           90500019
TEXT1TXT DS    CL8                 TEXT FIELD OF FIRST TEXT             90600019
TEXT2    DS    0C                                                       90700019
TEXT2LNG DS    C                   LENGTH BYTE FOR SECOND TEXT          90800019
TEXT2TXT DS    CL8                 TEXT FIELD OF SECOND TEXT            90900019
         EJECT                                                          91000019
         IHKCDSCT  TUB=YES                                              91100019
         EJECT                                                          91200019
         IHKCDSCT  PPT=YES                                              91300019
         EJECT                                                          91400019
         IHKCDSCT  AVT=YES                                              91500019
         EJECT                                                          91600019
         IHKCDSCT  DIR=YES                                              91700019
*                                                                       91800019
*                                                                       91900019
         RAFKNBX   TYPE=DSECT                                           92000019
DBLWDBLK EQU   K8X40KN                                           S21085 92020021
DSNMLNG  EQU   H8KN                                              S21085 92040021
TWO      EQU   H2KN                                              S21085 92060021
*                                                                       92100019
         CMDEQU                                                         92200019
         TUBEQU                                                         92300019
*                                                                       92400019
         END                                                            92500019
