SCN      TITLE 'IHKSCN - SCAN COMMAND PROCESSOR'                        00100019
IHKSCN   CSECT                                                          00200019
*STATUS -- CHANGE LEVEL 0                                             * 00300019
*                                                                     * 00400019
*FUNCTION -- DELAYED SCAN COMMAND PROCESSOR                           * 00500019
*   CHECKS OPERANDS, PASSES LINE NUMBER RANGE TO BE SCANNED TO IHKSYN.* 00600019
*   SCAN ON OR SCAN OFF WITH NO OTHER OPERANDS TURNS BIT ON OR OFF    * 00700019
*   AND NO SCAN.  SCAN WITH NO OPERANDS CAUSES ENTIRE DATASET TO BE   * 00800019
*   SCANNED.  ON SYNTAX ERRORS IHKSYN RETURNS WITH MESSAGE ENQUEUD    * 00900019
*   AND NEXT LINE TO BE SCANNED IN FIRST LINE NUMBER OF RANGE.  IF THE* 01000019
*   FIRST LINE NUMBER IS NOT GREATER THAN THE LAST, IHKSCN GOES TO    * 01100019
*   IHKMSG TO SEND THE MESSAGE(S) AND RETURNS TO IHKSYN TO CONTINUE   * 01200019
*   SCANNING.  WHEN THE SCAN IS DONE, IHKSCN DOES NOT SENT MESSAGES   * 01300019
*   BUT RETURNS TO THE CALLER.                                        * 01400019
*                                                                     * 01500019
*ENTRY POINT --                                                       * 01600019
*        IHKSCN- REGISTER ONE POINTS TO ONE WORD AREA CONTAINING      * 01700019
*        ADDRESS OF TUB.                                              * 01800019
*                                                                     * 01900019
*INPUT                                                                * 02000019
*   PPT CONTAINS OPERANDS, IF ANY.                                    * 02100019
*                                                                     * 02200019
*OUTPUT -- NONE.                                                      * 02300019
*                                                                     * 02400019
*EXTERNAL REFERENCES --                                               * 02500019
*                                                                     * 02600019
*        IHKAVT- USED FOR ADDRESSES.                                  * 02700019
*        IHKCCT- CCTOPT1- CCTPLI CHECKED IF USER DATASET IS PL/1.     * 02800019
*                CCTOPT2- CCTFORT CHECKED IF DATASET IS FORTRAN.      * 02900019
*        IHKGML- USED IN GETMAIN FOR WORK/SAVE AREA.                  * 03000019
*        IHKKBX- SYNQCTEL USED TO ENQUEUE FOR IHKSYN.                 * 03100019
*        IHKRNQ- ENTERED TO ENQUEUE FOR IHKSYN.                       * 03200019
*        IHKMSG- IHKMSGO1 USED TO ENQUEUE ERROR MESSAGES,             * 03300019
*                IHKMSG USED TO SEND SYNTAX ERROR MESSAGES.           * 03400019
*        IHKNUM- USED TO CHECK LINE NUMBER OPERANDS FOR NUMERICS.     * 03500019
*        IHKSYN- ENTERED TO SEND LINES TO SYNTAX CHECKER.             * 03600019
*                                                                     * 03700019
*EXITS, NORMAL --                                                     * 03800019
*        REGISTER 15= 0                                               * 03900019
*                                                                     * 04000019
*EXITS, ERROR --                                                      * 04100019
*        REGISTER 15= 4  TP LINE ERROR.                               * 04200019
*        REGISTER 15= 8  GETMAIN FAIL.                                * 04300019
*        REGISTER 15=12  ACTIVE AREA I/O ERROR.                       * 04400019
*        REGISTER 15=16  MESSAGE LOST.                                * 04500019
*                                                                     * 04600019
*TABLES, WORK AREAS --                                                * 04700019
*   SAVE AREA                                                         * 04800019
*   PPT- USED FOR FIRST AND LAST LINE NUMBERS PASSED TO IHKSYN,       * 04900019
*   AND FOR Q ELEMENT WHILE USING IHKSYN.                             * 05000019
*   USER BUFFER- USED FOR WORK AREA WHILE EXAMINING OPERANDS.         * 05100019
*        TUB- TUBFLG1- TUBSCN TURNED ON OR OFF AS SPECIFIED.          * 05200019
*                                                                     * 05300019
*ATTRIBUTES --  RE-ENTRANT, RESIDENT, REFRESHABLE.                    * 05400019
*                                                                     * 05500019
*NOTES -- NONE                                                        * 05600019
         EJECT                                                          05700019
*********************************************************************** 05800019
*   REGISTER EQUATES                                                    05900019
*********************************************************************** 06000019
R0       EQU   0                                                        06100019
R1       EQU   1                                                        06200019
RTUB     EQU   2                  TUB BASE                              06300019
RPPT     EQU   3                  POINTER TO PPT-OPERAND,PARAMETERS     06400019
R4       EQU   4                  KONBOX BASE                           06500019
ROPCNT   EQU   5                  OPERAND COUNTER                       06600019
R6       EQU   6                  WORK REGISTER                         06700019
R7       EQU   7                  WORK REGISTER                         06800019
RSWITCH  EQU   8                  POINTER TO WORK AREA IN USER BUFFER   06900019
RCCT     EQU   9                  CCT BASE                              07000019
REGRTN   EQU   10                 RETURN CODE                           07100019
RAVT     EQU   11                 AVT BASE                              07200019
RBAS     EQU   12                 IHKSCN BASE                           07300019
R13      EQU   13                                                       07400019
R14      EQU   14                                                       07500019
R15      EQU   15                                                       07600019
*********************************************************************** 07700019
*   OTHER EQUATES                                                       07800019
*********************************************************************** 07900019
HEX40    EQU   X'40'              CHECK FOR PAREN                       08000019
HIBIT    EQU   X'80'              HIGH ORDER BIT SET FOR PARAMETER LIST 08100019
ALLBITS  EQU   X'FF'              TEST FOR ANY SWITCH SET               08200019
THREEF   EQU   X'3F'              OMIT PAREN BIT                        08300019
ZERO     EQU   X'00'                                                    08400019
ZEROZD   EQU   C'0'               ZONED DECIMAL ZERO                    08500019
NINEZD   EQU   C'9'                                                     08600019
HEX02    EQU   X'02'                                                    08700019
NQFLAG   EQU   X'40'              POST NEXT Q ELEMETT READY             08800019
RPPTDBL  EQU   X'08'              DOUBLE WORD BOUNDARY IN PPT           08900019
GETMNFAL EQU   8                  GETMAIN FAIL RETURN CODE              09000019
RTRN16   EQU   X'10'              MESSAGE LOST RETURN CODE              09100019
MAXOP    EQU   3                  MAXIMUM NUMBER OF OPERANDS ALLOWED    09200019
         EJECT                                                          09300019
*********************************************************************** 09400019
*                                                                       09500019
*   SET UP BASE REGISTERS                                               09600019
*                                                                       09700019
*********************************************************************** 09800019
         USING IHKSCN,RBAS                                              09900019
         USING TUBDSECT,RTUB                                            10000019
         USING SYNDSECT,R13                                             10100019
         USING PPTDSECT,RPPT                                            10200019
         USING CCTDSECT,RCCT                                            10300019
         USING AVTDSECT,RAVT                                            10400019
         USING SWITCHD,RSWITCH                                          10500019
*                                                                       10600019
         SAVE  (14,12),,IHKSCN-12/02/69                                 10700019
         LR    RBAS,R15           SET UP IHKSCN BASE                    10800019
         L     RTUB,0(R1)         TUB BASE                              10900019
         L     RPPT,TUBPPTAD      PPT BASE                              11000019
         L     RAVT,AVTADDR       AVT BASE                              11100019
         L     RCCT,IHKYYCCT      CCT BASE                              11200019
*********************************************************************** 11300019
*                                                                       11400019
*   USER BUFFER USED FOR TEMPORARY STORAGE                              11500019
*   PPT USED FOR Q ELEMENT, AND LINE NUMBERS WHEN PASSED TO SYN         11600019
*                                                                       11700019
*********************************************************************** 11800019
         L     RSWITCH,TUBUFFAD   BASE FOR WORK AREA IN USER BUFFER     11900019
         LA    R6,SYNDLNG         LENGTH FOR GETMAIN                    12000019
         LA    R7,TUBPARM1                                              12100019
         L     R1,IHKYYGML        GO GET SAVEAREA                       12200019
         GETMAIN EC,LV=(R6),A=(R7),MF=(E,(1))                           12300019
         LTR   R15,R15                                                  12400019
         BNZ   GETFAIL            BR= GETMAIN FAIL                      12500019
         L     R1,TUBPARM1                                              12600019
         ST    R1,8(R13)          STORE SAVEAREA IN CALLERS             12700019
         ST    R13,4(R1)          STORE CALLERS IN THIS SAVEAREA        12800019
         LR    R13,R1             SET UP SAVEAREA                       12900019
*********************************************************************** 13000019
*                                                                       13100019
*   INITIALIZE                                                          13200019
*                                                                       13300019
*********************************************************************** 13400019
         SR    REGRTN,REGRTN                                            13500019
         SR    ROPCNT,ROPCNT      WILL CONTAIN OPERAND COUNT            13600019
         NI    SWITCH,ZERO        SET SWITCH TO ZERO                    13700019
         EJECT                                                          13800019
*********************************************************************** 13900019
*                                                                       14000019
*   CHECK IF SYNTAX CHECKER PRESENT                                     14100019
*                                                                       14200019
*********************************************************************** 14300019
         TM    TUBFLG1,TUBFOR     IS THIS FORTRAN                       14400019
         BO    CKFRTRN            BR=YES                                14500019
         TM    TUBFLG1,TUBPL1     NO, IS IT PL/1                        14600019
         BZ    ILLATTR            BR= ILLEGAL ATTRIBUTE                 14700019
*********************************************************************** 14800019
*   IS PL/1 DATASET                                                     14900019
*********************************************************************** 15000019
         TM    CCTOPT1,CCTPL1     IS PL/1 CHECKER THERE                 15100019
         BO    SETUPPT            BR = YES                              15200019
         B     NOTAVAIL           BR=NO, ENQ NOT AVAILABLE MSG          15300019
*********************************************************************** 15400019
*                                                                       15500019
*   IS FORTRAN DATASET                                                  15600019
*                                                                       15700019
*********************************************************************** 15800019
CKFRTRN  TM    CCTOPT2,CCTFORT    IS FORTRAN CHECKER THERE              15900019
         BZ    NOTAVAIL           BR=NO, ENQ NOT AVAILABLE MSG          16000019
*********************************************************************** 16100019
*                                                                       16200019
*       CHECK FOR NEXT OPERAND                                          16300019
*                                                                       16400019
*********************************************************************** 16500019
SETUPPT  ST    RPPT,SAVPPT        SAVE CURRENT PPT ADDRESS              16600019
         LA    RPPT,PPTPARS       POINT TO BEGIN OF OPERANDS            16700019
NEXTOP   TM    0(RPPT),ALLBITS    IS OPERAND PRESENT                    16800019
         BO    NOMORE             B = NO                                16900019
         TM    0(RPPT),HEX40      CHECK FOR PAREN- INVALID              17000019
         BO    ILLOP                                                    17100019
         LA    ROPCNT,1(ROPCNT)   INCREASE OPERAND COUNT                17200019
         LA    R1,MAXOP           MAXIMUM NUMBER OF OPERANDS            17300019
         CR    ROPCNT,R1          HAS MAX BEEN FOUND                    17400019
         BH    EXCESS             BR= YES, ENQ EXCESS OP MSG            17500019
         TM    SWITCH,SWSCAN      HAS OFF OR ON BEEN FOUND              17600019
         BO    EXCESS             BR= YES, INVALID-MUST BE LAST         17700019
         LA    R6,INCROP          ENTERNUM WILL RETURN TO INCROP        17800019
         CLC   OFF,0(RPPT)        IS OPERAND=OFF                        17900019
         BE    SETOFF             BR=OFF                                18000019
         CLC   ON,0(RPPT)         IS OPERAND =ON                        18100019
         BE    SETON              BR=ON                                 18200019
         TM    SWITCH,LINE1       HAS FIRST LINE NUMBER BEEN FOUND      18300019
         BZ    CKLINE2            BR=NO                                 18400019
         LA    R14,LSTLN          HAS TO BE END LINE                    18500019
         OI    SWITCH,LINE2       SET SWITCH- LAST LINE NUMBER          18600019
         XI    SWITCH,LINE1       SET TO ZERO FIRST LINE NUMBER SWITCH  18700019
         LA    R6,CKLAST          ENTERNUM WILL RETURN TO CKLAST        18800019
         B     ENTERNUM                                                 18900019
         EJECT                                                          19000019
*********************************************************************** 19100019
*                                                                       19200019
*   CHECK FOR BEGIN LINE                                                19300019
*                                                                       19400019
*********************************************************************** 19500019
CKLINE2  TM    SWITCH,LINE2       HAS LAST LINE NUMBER BEEN FOUND       19600019
         BO    ILLOP              BR= YES, INVALID                      19700019
         OI    SWITCH,LINE1       SET SWITCH- FIRST LINE FOUND          19800019
         LA    R14,FSTLN          LINE NUMBER WILL BE STORED HERE       19900019
*********************************************************************** 20000019
*                                                                       20100019
*   SET UP TO CHECK NUMERIC                                             20200019
*                                                                       20300019
*********************************************************************** 20400019
ENTERNUM LA    R1,TUBPARM3        PARAMETER 1                           20500019
         ST    R14,TUBPARM5       PARAMETER 3- STORE LINE NUMBER HERE   20600019
         LA    R7,1(RPPT)                                               20700019
         ST    RPPT,TUBPARM3      PARAMETER 1- LENGTH                   20800019
         ST    R7,TUBPARM4        PARAMETER 2- ADDRESS OF NUMBER        20900019
         L     R15,IHKYYNUM                                             21000019
         BALR  14,15              GO TO IHKNUM                          21100019
*                                                                       21200019
         LTR   R15,R15            IS IT NUMERIC AND VALID LENGTH        21300019
         BNZ   ILLOP              BR= NO, ENQ INVALID OP MSG            21400019
         B     0(R6)              NUMBER IS VALID- RETURN               21500019
*********************************************************************** 21600019
*                                                                       21700019
*   CHECK SECOND LINE NUMBER- MUST BE GREATER THAN OR EQUAL TO FIRST    21800019
*                                                                       21900019
*********************************************************************** 22000019
CKLAST   CLC   LSTLN,FSTLN        IS SECOND SMALLER THAN FIRST          22100019
         BL    ILLRNG             BR=YES, ENQ INVALID RANGE MSG         22200019
*********************************************************************** 22300019
*                                                                       22400019
*   INCREMENT TO NEXT OPERAND                                           22500019
*                                                                       22600019
*********************************************************************** 22700019
INCROP   SR    R6,R6                                                    22800019
         IC    R6,0(RPPT)         LENGTH OF OPERAND                     22900019
         AR    RPPT,R6            END OF CURRENT OPERAND                23000019
         LA    RPPT,1(RPPT)       POINTS AT LENGTH OF NEXT              23100019
         B     NEXTOP                                                   23200019
*********************************************************************** 23300019
*                                                                       23400019
*   IS OFF OR ON- SET SWITCHES                                          23500019
*                                                                       23600019
*********************************************************************** 23700019
SETOFF   OI    SWITCH,SWOFF                                             23800019
         B     SETSW                                                    23900019
SETON    OI    SWITCH,SWON                                              24000019
SETSW    OI    SWITCH,SWSCAN                                            24100019
         B     INCROP                                                   24200019
         EJECT                                                          24300019
*********************************************************************** 24400019
*                                                                       24500019
*   NO MORE OPERANDS IN THIS PPT- CHECK FOR ANOTHER                     24600019
*                                                                       24700019
*********************************************************************** 24800019
NOMORE   L     RPPT,SAVPPT        RESTORE CURRENT PPT                   24900019
         L     RPPT,PPTFLG        ADDRESS OF NEXT PPT, IF ANY           25000019
         LA    RPPT,0(RPPT)       CLEAR HIGH ORDER BYTE                 25100019
         LTR   RPPT,RPPT                                                25200019
         BNZ   SETUPPT            BR = ANOTHER PPT                      25300019
         TM    SWITCH,ALLBITS     HAVE ANY OPERANDS BEEN PROCESSED      25400019
         BM    CKLINE1            BR=YES                                25500019
*********************************************************************** 25600019
*                                                                       25700019
*   NO OPERANDS - SCAN ENTIRE DATASET                                   25800019
*                                                                       25900019
*********************************************************************** 26000019
         MVI   FSTLN,ZEROZD                                             26100019
         MVC   FSTLN+1(7),FSTLN    STORE ZEROES IN FIRST LINE NUMBER    26200019
         MVI   LSTLN,NINEZD                                             26300019
         MVC   LSTLN+1(7),LSTLN    STORE NINES IN LAST LINE NUMBER      26400019
         B     CALLSYN            GO ENQ FOR IHKSYN                     26500019
*********************************************************************** 26600019
*                                                                       26700019
*   TEST FOR BOTH LINE NUMBERS SPECIFIED                                26800019
*                                                                       26900019
*********************************************************************** 27000019
CKLINE1  TM    SWITCH,LINE1       WAS FIRST LINE ONLY SPECIFIED         27100019
         BZ    CKSWSCAN           BR=NO                                 27200019
         MVC   LSTLN,FSTLN        YES, STORE FIRST IN LAST LINE NUMBER  27300019
         OI    SWITCH,LINE2       TURN ON LAST LINE NUMBER SWITCH       27400019
*********************************************************************** 27500019
*                                                                       27600019
*   IF OFF OR ON SPECIFIED, SET BIT                                     27700019
*                                                                       27800019
*********************************************************************** 27900019
CKSWSCAN  TM    SWITCH,SWOFF            WAS OFF SPECIFIED               28000019
         BZ    CKON               BR= NO                                28100019
         NI    TUBFLG1,TUBSCNF    TURN OFF                              28200019
         B     CKLIN                                                    28300019
CKON     TM    SWITCH,SWON        WAS ON SPECIFIED                      28400019
         BZ    CKLIN              BR= NO                                28500019
         OI    TUBFLG1,TUBSCN     YES, SET BIT IN TUB                   28600019
*********************************************************************** 28700019
*   CHECK FOR LINE NUMBERS SPECIFIED                                    28800019
*********************************************************************** 28900019
CKLIN    TM    SWITCH,LINE2       HAVE LINE NUMBERS BEEN SPECIFIED      29000019
         BZ    RETURN0            BR = NO- ON OR OFF ONLY, RETURN       29100019
*********************************************************************** 29200019
*                                                                       29300019
*   SET DELAYED SCAN BIT, MOVE LINE NUMBER RANGE TO PPT                 29400019
*                                                                       29500019
*********************************************************************** 29600019
CALLSYN  OI    TUBFLG3,TUBDLAYN   SET DELAYED SCAN BIT IN TUB           29700019
         L     RPPT,TUBPPTAD      RESTORE PPT                           29800019
         LA    RPPT,RPPTDBL(RPPT) POINT TO DOUBLE WORD IN PPT           29900019
         USING SYNPARMD,RPPT                                            30000019
         MVC   SCANFRST,FSTLN     MOVE LINE NUMBERS TO PPT              30100019
         MVC   SCANLAST,LSTLN     TO BE PASSED TO IHKSYN                30200019
         LA    R1,SCANFRST                                              30300019
         ST    R1,TUBIRLSA        POINTER TO LINE NUMBER RANGE          30400019
*********************************************************************** 30500019
*                                                                       30600019
*   ENQ FOR IHKSYN- IS SERIAL                                           30700019
*                                                                       30800019
*********************************************************************** 30900019
RTRNSYN  L     R4,IHKYYKBX        ADDRESS OF KONBOX                     31000019
         USING RAFKNBX,R4                                               31100019
         LA    R1,SYNQCTEL        IHKSYN Q CONTROL ELEMENT              31200019
         ST    R1,TUBPARM4                                              31300019
         LA    R1,QEL             Q ELEMENT IN PPT                      31400019
         ST    R1,TUBPARM3                                              31500019
         MVI   QEL+4,ZERO                                               31600019
         LA    R1,TUBPARM3        ADDRESS OF Q ELEMENT                  31700019
         L     R15,IHKYYRNQ                                             31800019
         BALR  R14,R15            GO ENQ FOR IHKSYN                     31900019
         LTR   R15,R15            TEST FOR GETMAIN FAIL                 32000019
         BNZ   RET8               BR= GETMAIN FAIL, RETURN              32100019
*********************************************************************** 32200019
*                                                                       32300019
*   GO TO IHKSYN                                                        32400019
*                                                                       32500019
*********************************************************************** 32600019
         LA    R1,ADDRTUB(R13)                                          32700019
         L     R15,IHKYYSYN       GO TO IHKSYN                          32800019
         BALR  14,15                                                    32900019
*********************************************************************** 33000019
*                                                                       33100019
*   DEQ                                                                 33200019
*                                                                       33300019
*********************************************************************** 33400019
         L     R6,QEL             POINTER TO NEXT Q ELEMENT             33500019
         ST    R6,SYNQCTEL        POINT CONTROL ELEMENT TO NEXT         33600019
         LA    R6,0(R6)           CLEAR BYTE 0                          33700019
         LA    R1,SYNQCTEL+4                                            33800019
         CR    R6,R1              WAS THIS LAST ENTRY                   33900019
         BE    SYNRETRN           BR= YES                               34000019
         OI    4(R6),NQFLAG       POST NEXT Q ELEMENT READY             34100019
*********************************************************************** 34200019
*                                                                       34300019
*   BRANCH ON RETURN FROM IHKSYN                                        34400019
*                                                                       34500019
*********************************************************************** 34600019
SYNRETRN B     RTN(R15)                                                 34700019
RTN      B     RETURN0            0- SCAN FINISHED                      34800019
         B     CKLINUM            4- ERROR(S)- CHECK IF DONE            34900019
         B     RETCD              8   GETMAIN FAIL                      35000019
         B     RETCD              12  AA I/O ERROR                      35100019
         B     RETCD              16  MSG LOST                          35200019
         B     RETURN0            20 WRONG LANGUAGE LEVEL               35300019
*********************************************************************** 35400019
*                                                                       35500019
*   ERROR MESSAGE(S) ENQUEUED- CHECK IF DONE                            35600019
*                                                                       35700019
*********************************************************************** 35800019
CKLINUM  CLC   SCANLAST,SCANFRST  IS FIRST LINE LARGER                  35900019
         BL    RETURN0            BR= YES, SCAN FINISHED- RETURN        36000019
*********************************************************************** 36100019
*                                                                       36200019
*   NOT FINISHED SCANNING- SEND MESSAGES TO USER AND RETURN TO IHKSYN   36300019
*                                                                       36400019
*********************************************************************** 36500019
         ST    RTUB,TUBPARM2      PARAMETER 1- TUB                      36600019
         ST    RTUB,TUBPARM3      PARAMETER 2 - TUB                     36700019
         MVI   TUBPARM5+1,ZEROZD  STORE HEX ZEROES                      36800019
         MVC   TUBPARM5+2(2),TUBPARM5+1                                 36900019
         MVI   TUBPARM5,HEX02                                           37000019
         LA    R1,TUBPARM5                                              37100019
         ST    R1,TUBPARM4        PARAMETER 3- POINTS TO ZEROES         37200019
         MVI   TUBPARM4,HIBIT     NO INSERTIONS                         37300019
         LA    R1,TUBPARM2                                              37400019
         L     R15,IHKYYMSG       IHKMSG- SEND MSG(S) TO USER           37500019
         BALR  R14,R15                                                  37600019
         B     RTN1(R15)                                                37700019
RTN1     B     RTRNSYN            0  SUCCESSFUL                         37800019
         B     RETCD              4   LINE ERROR                        37900019
         B     RETCD              8   GETMAIN FAIL                      38000019
         B     RETCD              12  AA I/O ERROR                      38100019
         B     RETCD              16  MSG LOST                          38200019
         B     RTRNSYN            20  NOT USED                          38300019
         B     RET16              24  USERID INVALID                    38400019
         EJECT                                                          38500019
*********************************************************************** 38600019
*                                                                       38700019
*   ERROR MESSAGE ROUTINES                                              38800019
*                                                                       38900019
*********************************************************************** 39000019
*                                                                       39100019
*   ENQ EXCESSIVE OPERANDS MSG                                          39200019
*                                                                       39300019
EXCESS   LA    R1,MSG334                                                39400019
         B     THREPARM           ONE INSERTION                         39500019
*                                                                       39600019
*   ILLEGAL ATTRIBUTE                                                   39700019
*                                                                       39800019
ILLATTR  LA    R1,MSG360                                                39900019
         B     SETHI              NO INSERTIONS                         40000019
*                                                                       40100019
*   RANGE INVALID                                                       40200019
*                                                                       40300019
ILLRNG   LA    R1,MSG367                                                40400019
         B     THREPARM           ONE INSERTION                         40500019
*                                                                       40600019
*   ENQ  CHECKER NOT AVAILABLE MSG                                      40700019
*                                                                       40800019
NOTAVAIL LA    R1,MSG387                                                40900019
SETHI    ST    R1,TUBPARM4        NO INSERTIONS                         41000019
         MVI   TUBPARM4,HIBIT                                           41100019
         B     ENTERMSG                                                 41200019
*                                                                       41300019
*   ENQ INVALID OPERAND MSG                                             41400019
*                                                                       41500019
ILLOP    LA    R1,MSG302                                                41600019
THREPARM ST    R1,TUBPARM4                                              41700019
         NI    0(RPPT),THREEF     OMIT PAREN BITS                       41800019
         ST    RPPT,TUBPARM5      ONE INSERTION                         41900019
         MVI   TUBPARM5,HIBIT     FLAG LAST PARAMETER                   41950019
*********************************************************************** 42000019
*                                                                       42100019
*   ENQUEUE ERROR MESSAGE FOR USER                                      42200019
*                                                                       42300019
*********************************************************************** 42400019
ENTERMSG ST    RTUB,TUBPARM2      PARAMETER 1- TUB                      42500019
         LA    R1,TUBUSRID                                              42600019
         ST    R1,TUBPARM3        PARAMETER 2- USERID                   42700019
         LA    R1,TUBPARM2                                              42800019
         L     R15,IHKYMSG1       IHKMSG01                              42900019
         BALR  R14,R15                                                  43000019
         LTR   REGRTN,REGRTN      WAS ERROR RETURN SET                  43100019
         BNZ   RETURN              BR= ERROR ALREADY SET                43200019
         B     RTN3(R15)                                                43300019
RTN3     B     RETURN0            0  SUCCESSFUL                         43400019
         B     RETCD              4   TP LINE ERROR                     43500019
         B     RETCD              8   GETMAIN FAIL                      43600019
         B     RETCD              12  AA I/O ERROR                      43700019
         B     RETCD              16  MSG LOST                          43800019
         B     RETCD              20  AA OUT OF SPACE                   43900019
         B     RET16              24  INVALID ISERID                    44000019
*********************************************************************** 44100019
*                                                                       44200019
*   ERROR RETURNS                                                       44300019
*                                                                       44400019
*********************************************************************** 44500019
RETCD    LR    REGRTN,R15                                               44600019
         B     RETURN                                                   44700019
*                                                                       44800019
GETFAIL  LA    R15,GETMNFAL       GETMAIN FAIL FOR SAVEAREA             44900019
         B     NOCORE                                                   45000019
*                                                                       45100019
RET8     LA    REGRTN,GETMNFAL    GETMAIN FAIL FROM IHKRNQ              45200019
         B     RETURN                                                   45300019
*                                                                       45400019
RET16    LA    REGRTN,RTRN16      MESSAGE LOST RETURN                   45500019
         B     RETURN                                                   45600019
*********************************************************************** 45700019
*                                                                       45800019
*   NORMAL RETURN- SCAN COMPLETE                                        45900019
*                                                                       46000019
*********************************************************************** 46100019
RETURN0  LA    REGRTN,ZERO        SET RETURN CODE 0                     46200019
RETURN   L     R7,4(R13)          CALLERS SAVEAREA                      46300019
         NI    TUBFLG3,TUBDLAYF   TURN OFF DELAYED SCAN BIT             46400019
         LA    R1,SYNDLNG         LENGTH OF GETMAIN                     46500019
         LR    R0,R1                                                    46600019
         LR    R1,R13                                                   46700019
         FREEMAIN R,LV=(0),A=(1)                                        46800019
         LR    R13,R7                                                   46900019
         LR    R15,REGRTN                                               47000019
NOCORE   RETURN  (14,12),RC=(15)                                        47100019
         EJECT                                                          47200019
*********************************************************************** 47300019
*                                                                       47400019
*   MESSAGE CODES                                                       47500019
*                                                                       47600019
*********************************************************************** 47700019
         DS    0F                                                       47800019
MSG302   DC    X'00F3F0F2'        302 INVALID OPERAND                   47900019
MSG334   DC    X'00F3F3F4'        334 EXCESSIVE OPERANDS                48000019
MSG360   DC    X'00F3F6F0'        360 INVALID ATTRIBUTE FOR SCAN        48100019
MSG367   DC    X'00F3F6F7'        367 RANGE INVALID                     48200019
MSG387   DC    X'00F3F8F7'        387 CHECKER NOT AVAIBLE               48300019
*********************************************************************** 48400019
*                                                                       48500019
*   CONSTANTS                                                           48600019
*                                                                       48700019
*********************************************************************** 48800019
AVTADDR  DC    V(IHKAVT)                                                48900019
OFF      DC    X'03D6C6C6'        OPERAND OFF                           49000019
ON       DC    X'02D6D5'          OPERAND ON                            49100019
         EJECT                                                          49200019
*********************************************************************** 49300019
*                                                                       49400019
*   SAVEAREA                                                            49500019
*                                                                       49600019
*********************************************************************** 49700019
SYNDSECT DSECT                                                          49800019
SAVEAREA DS    CL72                                                     49900019
ADDRTUB  EQU   28                  TUB BASE REGISTER 2                  50000019
SYNDLNG  EQU   *-SYNDSECT                                               50100019
*********************************************************************** 50200019
*                                                                       50300019
*   PPT USED FOR LINE NUMBER RANGE AND Q ELEMENT                        50400019
*                                                                       50500019
*********************************************************************** 50600019
SYNPARMD DSECT                                                          50700019
SCANFRST DS    D                   FIRST LINE TO BE SCANNED             50800019
SCANLAST DS    D                   LAST LINE                            50900019
QEL      DS    2F                  Q ELEMENT                            51000019
*********************************************************************** 51100019
*                                                                       51200019
*   USER BUFFER USED FOR TEMPORARY WORK AREA                            51300019
*                                                                       51400019
*********************************************************************** 51500019
SWITCHD  DSECT                                                          51600019
FSTLN    DS    D                   FIRST LINE TO BE SCANNED             51700019
LSTLN    DS    D                   LAST LINE                            51800019
SAVPPT   DS    F                   CURRENT PPT                          51900019
SWITCH   DS    C                                                        52000019
LINE1    EQU   X'40'                    FIRST LINE NUMBER PROCESSED     52100019
LINE2    EQU   X'20'               SECOND LINE NUMBER FOUND             52200019
SWON     EQU   X'10'               ON PROCESSED                         52300019
SWOFF    EQU   X'08'               OFF PROCESSED                        52400019
SWSCAN   EQU   X'04'               OFF OR ON FOUND                      52500019
*                                                                       52600019
         RAFKNBX  TYPE=DSECT                                            52700019
         IHKCDSCT  TUB=YES,PPT=YES,AVT=YES,CCT=YES                      52800019
         END                                                            52900019
