STP      TITLE 'IHKSTP - CRJE STOP ROUTINE'                             00600019
IHKSTP   CSECT                                                          01200019
*A636000                                                         A36804 01400020
*C378000,510000,882000                                           A36804 01600020
* C378000                                                       OX00339 01660002
* D638800                                                       OX00339 01720002
*********************************************************************** 01800019
*                                                                     * 02400019
*STATUS-                                                              * 03000019
*   CHANGE LEVEL 0                                                    * 03600019
*                                                                     * 04200019
*FUNCTION/OPERATION-                                                  * 04800019
*   IHKSTP FIRST TURNS ON THE STOP BIT. STOP THEN SCANS THE CLBS. IF  * 05400019
*   THE STOP ACKNOWLEDGE ECB IS POSTED, STOP MOVES TO THE NEXT CLB. IF* 06000019
*   NOT POSTED, IHKSTP CHECKS THE LAST I/O OPERATION ON THE LINE. IF  * 06600019
*   IT WAS A READ INITIAL OR READ CONVERSATIONAL, A HALT IO IS ISSUED * 07200019
*   REGARDLESS OF ISSUING THE RESETPL, IHKSTP THEN WAITS IN THE       * 07800019
*   DISPATCHER FOR THE LINE TO SHUT DOWN. WHEN ALL LINES ARE SHUT DOWN* 08400019
*   (CLBSAECB POSTED IN EACH CLB), IHKBSH IS CALLED TO WRITE THE      * 09000019
*   ACTIVE AREA GLOBAL FILES TO CRJE.SYSLIB. STOP THEN POSTS THE STOP * 09600019
*   ECB FOR THE JOB TERMINATOR (INDICATING IHKSPT PROCESSING COMPLETE * 10200019
*   AND IHKSDQ CAN NOW RETURN TO IHKBGN). IHKSTP CHECKS WHETHER IHKSDQ* 10800019
*   IS BUSY OR NOT. IF NOT BUSY IT POSTS THE Q MGR ECB OF IHKSDQ (    * 11400019
*   SINCE AT THIS TIME IHKSDQ WILL BE WAITING ON EITHER QMGR OR STOP  * 12000019
*   ECB). RETURN IS THEN MADE TO IHKCII WHICH WILL WAIT IN THE        * 12600019
*   DISPATCHER GIVING IHKSDQ CONTROL.                                 * 13200019
*                                                                     * 13800019
*ENTRY POINTS-                                                        * 14400019
*        IHKSTP IS THE ONLY ENTRY POINT. AT ENTRY REGISTER ONE        * 15000019
*   CONTAINS THE ADDRESS OF THE CRJE ADDRESS VECTOR TABLE (IHKAVT).   * 15600019
*                                                                     * 16200019
*INPUT-                                                               * 16800019
*   N/A                                                               * 17400019
*                                                                     * 18000019
*OUTPUT-                                                              * 18600019
*   ALL LINES ARE CLOSED DOWN.                                        * 19200019
*                                                                     * 19800019
*EXTERNAL ROUTINES-                                                   * 20400019
*        IHKDSP- DISPATCHER - WAIT FOR LINES TO SHUT DOWN             * 21000019
*        IHKBSH- ROLL OUT GLOBAL FILES TO CRJE.SYSLIB                 * 21600019
*                                                                     * 22200019
*EXITS NORMAL-                                                        * 22800019
*   RETURN TO IHKCCI.                                                 * 23400019
*                                                                     * 24000019
*EXITS ERROR -                                                        * 24600019
*   N/A                                                               * 25200019
*                                                                     * 25800019
*TABLES/WORK AREAS-                                                   * 26400019
*   AN 18 WORD SAVE AREA IS PROVIDED.                                 * 27000019
*                                                                     * 27600019
*ATTRIBUTES-                                                          * 28200019
*   SERIALLY REUSABLE AND NON-RESIDENT.                               * 28800019
ZIP      EQU   0                                                        29400019
PAR      EQU   1                                                        30000019
DCB      EQU   2                   BASE FOR DCB                         30600019
DECB     EQU   3                                                        31200019
PCL      EQU   4                                                        31800019
CLB      EQU   5                                                        32400019
WOK      EQU   8                                                        33000019
CCT      EQU   9                                                        33600019
UCB      EQU   10                  BASE FOR UCB                         34200019
AVT      EQU   11                                                       34800019
BAS      EQU   12                                                       35400019
SAV      EQU   13                                                       36000019
BAC      EQU   14                                                       36600019
GO       EQU   15                                                       37200019
         SAVE (14,12),,STP72306        SAVE CALLERS REGISTERS           37800002
         BALR  BAS,ZIP                                                  38400019
         USING *,BAS                                                    39000019
         LA    WOK,SAVE                                                 39600019
         ST    SAV,FOR(WOK)                                             40200019
         ST    WOK,ATE(SAV)                                             40800019
         LR    SAV,WOK                                                  41400019
         L     AVT,0(PAR)          GET BASE FOR AVT                     42000019
         USING AVTDSECT,AVT                                             42600019
         SPACE 2                                                        43200019
         L     CCT,IHKYYCCT        GET BASE FOR CCT                     43800019
         USING CCTDSECT,CCT                                             44400019
         OI    CCTOPT,CCTCLS       SET STOP BIT                         45000019
         L     PCL,IHKYYCLB        ADDRESS OF FIRST CLB POINTER         45600019
         LTR   PCL,PCL             ANY LINES IN PROCEDURE               46200019
         BZ    ROLLOUT             NO LINES-ROLL OUT TABLES             46800019
CHCKCLB  L     CLB,0(PCL)          ADDRESS OF CLB                       47400019
         USING CLBDSECT,CLB                                             48000019
         OI    CLBREQST,CLBSTOPN   SET STOP FLAG IN CLB                 48600019
         CLI   CLBSAECB,POST       IS STOP ACK ECB POSTED (LINE         49200019
*                                  FINISHED PROCESSING)                 49800019
         BE    BUMPCLB             YES, CHECK NEXT CLB                  50400019
TRYHALT  L     PAR,CLBLDECB        ADDRESS OF DECB FOR RESETPL   A36804 51000020
         USING IECTDECB,PAR                                             51600019
         TM    DECSDECB,WAITING    LINE ADMINASTOR WAITING FOR I/O      52200019
         BNZ   BUMPCLB             NO CHECK NEXT CLB                    52800019
         TM    DECTYPE+1,READOUT   READ OUTSTANDING ON LINE             53400019
         BZ    BUMPCLB             NO CHECK NEXT CLB                    54000019
         L     DCB,DECDCBAD        ADDRESS OF DCB                       54600019
         USING IHADCB,DCB                                               55200019
         SR    ZIP,ZIP             CLEAR REGISTER FOR INSERT            55800019
         IC    ZIP,DECRLN          GET RELATIVE LINE NUMBER             56400019
         SR    PAR,PAR             CLEAR REGISTER FOR INSERT            57000019
         IC    PAR,DCBEIOBX        OFFSET INTO IOB                      57600019
         MR    ZIP,ZIP             GET OFFSET TO IOB                    58200019
         A     PAR,DCBIOBAD        ADD TO ADDRESS OF IOB BASE           58800019
         OI    1(PAR),RESETFLG     SET RESETPL FLAG IN IOB              59400019
         SR    GO,GO               CLEAR REGISTER FOR INSERT            60000019
         IC    GO,IOBUCBX(PAR)     OFFSET TO UCB ADDRESS                60600019
         SLL   GO,2                MULTIPLY BY FOUR                     61200019
         L     BAC,DCBDEBAD        ADDRESS OF DEB                       61800019
         L     PAR,DEBUCBAD(BAC,GO) ADDRESS OF UCB FOR HALT I/O         62400019
         SPACE                                                          63000019
         SVC   HALTIO              ISSUE HALT I/O                       63600019
         SPACE 2                                                 A36804 63670020
         CH    GO,FOUR             HALT SUCCESSFUL               A36804 63740020
         BL    BUMPCLB             YES                           A36804 63810020
         SPACE 1                                                 A36804 63950020
         L     PAR,CLBLDECB        GET DECB ECB                  A36804 64020020
         MVI   0(PAR),POST         POST LINE ECB                 A36804 64090020
         SPACE                                                          64200019
         DROP  PAR                                                      64800019
         SPACE 3                                                        65400019
BUMPCLB  CLI   0(PCL),ENDCLBS      LAST CLB                             69600019
         LA    PCL,4(PCL)          BUMP TO NEXT CLB                     70200019
         BE    CLBWAIT             ALL LINES CLOSED  WAIT FOR LINES     70800019
         B     CHCKCLB             CHECK NEXT CLB                       71400019
         SPACE 2                                                        72000019
CLBWAIT  L     PCL,IHKYYCLB        ADDRESS OF FIRST CLB POINTER         72030019
         SPACE                                                          72060019
WAITCLB  L     CLB,0(PCL)          ADDRESS OF CLB                       72090019
         CLI   CLBSAECB,POST       IS STOP ACK ECB POSTED FOR LINE      72120019
         BE    CLBBUMP             YES, CHECK NEXT CLB                  72150019
         LA    PAR,CLBSAECB        NO, WAIT FOR POST                    72180019
         L     GO,IHKYYDSP         ADDRESS OF DISPATCHER                72210019
         SPACE                                                          72240019
         BALR  BAC,GO              WAIT                                 72270019
         SPACE 2                                                        72300019
CLBBUMP  CLI   0(PCL),ENDCLBS      LAST CLB                             72330019
         LA    PCL,4(PCL)          BUMP TO NEXT CLB                     72360019
         BE    ROLLOUT             ALL LINES CLOSED DOWN ROLL TABLES    72390019
         B     WAITCLB             WAIT FOR NEXT LINE TO SHUT DOWN      72420019
         SPACE 2                                                        72450019
*                   ALL LINE ACTIVITY IS NOW COMPLETE. GIVE CONTROL TO  72600019
*                   LIBRARY I/O SHUTDOWN MODULE TO SAVE ACTIVE AREA     73200019
         SPACE 2                                                        73800019
ROLLOUT  EQU   *                                                        74400019
         MVC   SAVETUB(4),IHKYYTUB SAVE CONTENTS OF TUB POINTER         75000019
         LA    PAR,DUMTUB          ADDRESS OF DUMMY TUB FOR IHKBSH      75600019
         ST    PAR,IHKYYTUB                                             76200019
         LR    PAR,AVT             PASS ADDRESS OF AVT                  76800019
         LINK  EP=IHKBSH                                                77400019
         SPACE 3                                                        78000019
         MVC   IHKYYTUB(4),SAVETUB RESTORE TUB POINTER                  78600019
         L     WOK,IHKYYDQS        ADDRESS OF STOP ACK ECB FOR JOB      79200019
*                                  TERMINATOR                           79800019
         MVI   0(WOK),POST         POST IT                              80400019
         TM    CCTOPT+1,CCTJTBSY   IS JOB TERMINATOR PROCESSING A JOB   81000019
         BO    RETURN              YES, RETURN IHKSDQ WILL RECOGNIZE    81600019
*                                  STOP PENDING                         82200019
         L     WOK,IHKYYDQE        ADDRESS OF Q MANAGER ECB WHICH JOB   82800019
*                                  TERMINATOR IS WAITING ON             83400019
         MVI   0(WOK),POST         POST ECB                             84000019
         SPACE                                                          84600019
RETURN   L     SAV,SAVE+4                                               85200019
         RETURN (14,12),T                                               85800019
SAVE     DC    18F'0'                                                   86400019
SAVETUB  DC    F'0'                                                     87000019
DUMTUB   DC    100F'0'                                                  87600019
FOR      EQU   4                                                        88200019
FOUR     DC    H'4'                CHECK RETURN FROM HALT I/O    A36804 88500020
ATE      EQU   8                                                        88800019
ENDCLBS  EQU   X'80'                                                    89400019
POST     EQU   X'40'                                                    90000019
READOUT  EQU   X'01'                                                    90600019
RESETFLG EQU   1                                                        91200019
IOBUCBX  EQU   32                  OFFSET TO UCB POINTER IN IOB         91800019
DEBUCBAD EQU   32              OFFSET IN DEB TO UCB ADDRESS             92400019
WAITING  EQU   X'7F'                                                    93000019
HALTIO   EQU   33                                                       93600019
POST48   EQU   X'48'               I/O HALT POST CODE                   94200019
         IHKCDSCT AVT=YES,CCT=YES,CLB=YES                               95400019
         IECTDECB                                                       96000019
         DCBD  DSORG=CX                                                 96600019
         END                                                            97200019
