SUB      TITLE 'IHKSUB - SUBMIT COMMAND PROCESSOR'                      00100019
IHKSUB   CSECT                                                   A36810 00110020
*A043000,186000,210000,352000,353000,357000,358000,495000,496000 A36810 00120020
*A618000,625000,635000,643000,646000,655000,661000,777000        A36810 00130020
*C005000,099000,618000,635000,655000                             A36810 00140020
*D078000                                                         A36810 00150020
*A001000,218000,727000                                           A36818 00160020
*C099000                                                         A36818 00170020
*D078000                                                         A36818 00180020
*C099000,475000,697000                                           A47412 00190000
*********************************************************************** 00200019
**                                                                    * 00300019
*STATUS-                                                              * 00400019
*   CHANGE LEVEL 1                                               A36810 00500020
*                                                                     * 00600019
*FUNCTION/OPERATION-                                                  * 00700019
*   THE SUBMIT COMMAND PROCESSOR ALLOWS UP TO TEN CRJE DATA SETS (PLUS* 00800019
*   DSNAMES FOUND IN DSLIST FILES), COMBINED INTO A SEQUENTIAL DATA   * 00900019
*   SET, TO BE ENTERED INTO THE O. S. JOB INPUT STREAM.               * 01000019
*   THE FOLLOWING TWO MODULES PERFORM SPECIAL SERVICES FOR THE SUBMIT * 01100019
*   PROCESSOR. IHKGET SYNTAX CHECKS THE DSNAMES SUBMITTED AND         * 01200019
*   POSITIONS TO THE BEGINING OF THESE DATA SETS. IHKALC ALLOCATES THE* 01300019
*   SEQUENTIAL READER/INTERPRETER INPUT DATA SET AND BUILDS THE START * 01400019
*   RDRCRJE COMMAND.                                                  * 01500019
*   IHKSUB INSPECTS ALL RECORDS TO BE SUBMITTED FOR JOB STATEMENTS,   * 01600019
*   AND DD DATA STATEMENTS. ALL JCL STATEMENTS ARE GIVEN TO THE JCL   * 01700019
*   EXIT, IF IT EXISTS. THE EXIT MAY CAUSE IHKSUB TO ACCEPT THE       * 01800019
*   STATEMENT, OR ABORT THE SUBMIT WITH OR WITHOUT A MESSAGE FROM THE * 01900019
*   EXIT. JCL INSPECTION IS SUSPENDED WHILE PROCESSING DD DATA INPUT. * 02000019
*   WHEN THE FIRST JOB CARD IS FOUND, IHKALC IS CALLED TO ALLOCATE THE* 02100019
*   READER/INTERPRETER DATA SET.                                      * 02200019
*   ALL RECORDS ARE BLOCKED WHEN WRITTEN TO THE R/I DATA SET EXCEPT   * 02300019
*   THE JOB CARD. THIS PREVENTS LOSS OF DATA IF THE READER (RDRCRJE)  * 02400019
*   IS ROLLED OUT IN MFT. AFTER THE JOB CARD HAS BEEN WRITTEN, THE TTR* 02500019
*   OF THE STATEMENT IS SAVED FOR ABNORMAL PROCESSING.                * 02600019
*   WHEN A COMPLETE JOB HAS BEEN COLLECTED AND AN EXEC STATEMENT WAS  * 02700019
*   PRESENT IN THE JOB, THE RJCT ENTRY FOR THE JOB IS WRITTEN IN THE  * 02800019
*   JBTBLS GLOBAL FILE. IF NO EXEC STATEMENT WAS RECEIVED FOR THE JOB,* 02900019
*   THE SUBMIT IS ABORTED.                                            * 03000019
*   IF THE SUBMIT IS TO BE ABORTED BECAUSE OF A BAD RETURN CODE FROM  * 03100019
*   THE IHKGET ROUTINE, THE ERROR MESSAGE RETURNED BY IHKGET IS SENT  * 03200019
*   TO THE USER AND THE IHKGET MODULE IS DELETED. IF THE ABORT IS FOR * 03300019
*   ANY OTHER CAUSE, IHKGET IS CALLED TO FORCE END OF INPUT AND THE   * 03400019
*   RJCT BASE REGISTER IS CLEARED.                                    * 03500019
*   IN NORMAL SUBMIT TERMINATION THE RJCT BASE IS TESTED. IF IT IS    * 03600019
*   NONZERO, THE RJCT ENTRY FOR THE LAST JOB IS WRITTEN. IF NO JOBS   * 03700019
*   WERE COLLECTED A MESSAGE IS SENT TO THE USER INFORMING HIM THAT   * 03800019
*   NO JOBS WERE FOUND. THE CRJE SERVICE ROUTINE (IHKSRV) IS CALLED TO* 03900019
*   CLOSE THE R/I DATA SET DCB AND START THE READER PROCEEDURE        * 04000019
*   (RDRCRJE) ON THE DATA SET. THEN THE SAVE AND WORK AREA IS FREED,  * 04100019
*   AND CONTROL RETURN TO IHKCMD.                                     * 04200019
*                                                                     * 04300019
*   IF EITHER THE LOADER/CONTROLLER OR SERVICE TASK HAS ABENDED  A36810 04320020
*   CONTROL IS RETURNED TO THE SYSTEM ADMINISTRATOR WITH A       A36810 04340020
*   RETURN CODE OF 12.                                           A36810 04360020
*ENTRY POINTS-                                                        * 04400019
*        IHKSUB IS THE ONLY ENTRY POINT.                              * 04500019
*                                                                     * 04600019
*INPUT-                                                               * 04700019
*   INPUT IS THE FOLLOWING PARAMETER LIST ADDRESSED BY REGISTER 1:    * 04800019
*   (1) ADDRESS OF THE TUB                                            * 04900019
*   (2) ADDRESS OF THE AVT                                            * 05000019
*                                                                     * 05100019
*OUTPUT-                                                              * 05200019
*   R/I DATA SET OF JOBS TO BE SUBMITTED IS BUILT.                    * 05300019
*                                                                     * 05400019
*EXTERNAL ROUTINES-                                                   * 05500019
*        IHKALC - ALLOCATE READER/INTERPRETER DATA SET.               * 05600019
*        IHKGET - POSITION TO DSNAMES TO SUBMITTED                    * 05700019
*        IHKAFI - TO WRITE RJCT ENTRY AND READ ACTIVE FILES TO BE     * 05800019
*                 SUBMITTED.                                          * 05900019
*        IHKBPM - READ LIBRARY FILES TO BE SUBMITTED.                 * 06000019
*        IHKMSG - SEND ERROR MESSAGES                                 * 06100019
*                                                                     * 06200019
*EXITS-NORMAL-                                                        * 06300019
*   RETURN TO IHKCMD WITH CODE OF 0 IN REGISTER 15.                   * 06400019
*                                                                     * 06500019
*EXITS-ERROR-                                                         * 06600019
*   RETURN TO IHKCMD WITH CODE IN REGISTER 15:                        * 06700019
*        12- ACTIVE AREA I/O ERROR                                    * 06800019
*        8 - GETMAIN FAILURE                                          * 06900019
*                                                                     * 07000019
*TABLES/WORK AREAS-                                                   * 07100019
*   GETMAINED 432 SAVE AREA, RJCT, DCB, DECB, AND WORK AREA.          * 07200019
*                                                                     * 07300019
*ATTRIBUTES-                                                          * 07400019
*   NONRESIDENT AND REENTRANT (MARKED REUSABLE IN IHKMOD TABLE).      * 07500019
*                                                                     * 07600019
*********************************************************************** 07700019
ZIP      EQU   0                                                        07900019
PAR      EQU   1                                                        08000019
NEW      EQU   1                                                        08100019
REC      EQU   2                                                        08200019
R3       EQU   3                   AVT BASE                             08300019
R4       EQU   4                                                        08400019
DCB      EQU   5                   BASE FOR DCB                         08500019
RTR      EQU   6                   RETURN FOR INTERNAL BRANCHES         08600019
RJCT     EQU   7                   BASE FOR RJCT                        08700019
R8       EQU   8                   WORK                                 08800019
WOK      EQU   8                                                        08900019
R9       EQU   9                   WORK                                 09000019
R10      EQU   10                  BASE FOR CLB                         09100019
R11      EQU   11                  BASE FOR USER TABLE                  09200019
BAS      EQU   12                  BASE FOR CSECT                       09300019
SAV      EQU   13                  SAVE AND WORKAREA BASE               09400019
BAC      EQU   14                                                       09500019
LNG      EQU   14                                                       09600019
GO       EQU   15                                                       09700019
OLD      EQU   15                                                       09800019
         SAVE  (14,12),,SUB72060                                 A47412 09900000
         BALR  BAS,ZIP                                                  10000019
         USING *,BAS                                                    10100019
         USING IHADCB,DCB                                               10200019
         USING AVTDSECT,R3                                              10300019
         USING TUBDSECT,R11                                             10400019
         L     R3,FOUR(PAR)        ADDRESS OF AVT                       10500019
         L     R11,0(PAR)          SAVE ADDRESS OF USER TABLE           10600019
         ST    R11,TUBPARM4        SAVE TUB ADDRESS                     10700019
         ST    R3,TUBPARM5         SAVE AVT ADDRESS                     10800019
         L     R4,IHKYYKBX         BASE FOR KON BOX                     10900019
         USING RAFKNBX,R4                                               11000019
         USING WORKSECT,SAV                                             11100019
         LA    R8,WORKEND          LENGTH FOR GETMAIN                   11200019
         LA    R9,TUBPARM3         ADDRESS FOR GOTTEN CORE              11300019
         L     PAR,IHKYYGML        ADDRESS OF GETMAIN LIST              11400019
         GETMAIN EC,LV=(8),A=(9),MF=(E,(1))                             11500019
         LTR   GO,GO               CORE AVAILABE                        11600019
         LA    GO,ATE              ASSUME NOT                           11700019
         BNZ   ERRTURN             EXIT IF NO CORE                      11800019
         L     R9,TUBPARM3         CORE ADDRESS                         11900019
         ST    R9,ATE(SAV)         CHAIN SAVE AREAS                     12000019
         ST    SAV,FOUR(R9)                                             12100019
         LR    SAV,R9                                                   12200019
         LA    DCB,SUBDCB          ADDRESS OF DCB FOR R/I DATA SET      12300019
         XC    SUBSWT(4),SUBSWT    CLEAR SUBSWT, CODE, AND PASSONE      12400019
         XR    RJCT,RJCT           CLEAR RJCT POINTER                   12500019
         ST    RJCT,TUBIRLSA       CLEAR POINTER TO START PARMS         12600019
         ST    RJCT,RTRNCODE       SET RETURN CODE TO ZERO              12700019
         ST    RJCT,BLOCKAD        CLEAR ADDRESS OF OUTPUT BLOCK        12800019
         ST    RJCT,NOTETTR        CLEAR TTR                            12900019
         LA    R10,SUBEXLST        ADDRESS OF EXLIST                    13000019
         ST    R10,XLSTPTR         SAVE ADDRESS FOR IHKJCP              13100019
         LA    R10,SUBSYNAD        ADDRESS OF SYNAD ROUTINE             13200019
         ST    R10,SYNADPTR        SAVE ADDRESS FOR IHKJCP              13300019
         L    R10,TUBCLBAD         ADDRESS OF CLB                       13400019
         USING CLBDSECT,R10                                             13500019
         B     SUBREAD1            GET FIRST BLOCK OF INPUT             13600019
         SPACE 2                                                        13700019
ERRCLSE  EQU   *                                                        13800019
       MVC     TUBGBLKY(8),TUBUSRNM USER LIBRARY TO MARK INOPERATIVE    13900019
         MVI   UTMCODE,FOUR        REQUEST CODE FOR INOPERATIVE         14000019
         LA    PAR,UTMPARM         ADDRESS OF PARM LIST BUILT BY IHKGET 14100019
         L     GO,IHKYYUTM         ADDRESS OF IHKUTM                    14200019
         BALR  BAC,GO              MARK LIBRARY INOPERATIVE             14300019
         SPACE 2                                                        14400019
         MVC   MSGNAM(8),TUBUSRNM  USER ID OF INOPERATIVE LIBRARY       14500019
         MVC   MSGIX(2),M70        MESSAGE NUMBER                       14600019
         SPACE                                                          14700019
         BAL   RTR,SENDMSG1        SEND MESSAGE TO USER                 14800019
         SPACE                                                          14900019
         MVC   MSGOFF+1(3),M241    MESSAGE NUMBER FOR CENTRAL           15000019
         B     NODDMSG             SEND MESSAGE TO CENTRAL              15100019
         SPACE 2                                                        15200019
GETFAIL  LA    R8,ATE              SET RETURN CODE TO EIGHT             15300019
         SPACE                                                          15400019
ERRCLOSE EQU   *                                                        15500019
         LR    GO,R8               MOVE RETURN CODE TO REGISTER FIFTEEN 15600019
SETRTN   ST    GO,RTRNCODE         SET RETURN CODE                      15700019
         SPACE 2                                                        15800019
SUBABND  EQU   *                                                        15900019
         SPACE 2                                                        16000019
GETCLOSE OI    SUBSWT,CLSGET       SET CLOSE BIT                        16100019
         SR    RJCT,RJCT           INDICATE RJCT NOT TO BE WRITTEN      16200019
         TM    WRTSWT,LIBOPEN      IS LIBRARY OPEN                      16300019
         BO    READEOD             YES CLOSE BEFORE GOING TO IHKGET     16400019
         B     SUBREAD1            NO CALL IHKGET TO CLOSE DOWN         16500019
         SPACE 3                                                        16600019
SUBEND   EQU   *                                                        16700019
         L     PAR,BLOCKAD         ADDRESS OF OUTPUT BLOCK              16800019
         LTR   PAR,PAR             DOES BLOCK EXIST                     16900019
         BZ    WRTJOB                                                   17000019
         LM    ZIP,PAR,0(PAR)      GET LENGTH AND ADDRESS TO FREE       17100019
         FREEMAIN R,LV=(0),A=(1)                                        17200019
         SPACE                                                          17300019
WRTJOB   LTR   RJCT,RJCT           NEED TO WRITE RJCT ENTRY             17400019
         BZ    CLOSE               NO CLOSE R/I DATA SET                17500019
         BAL   RTR,SRCHRJCT        WRITE RJCT ENTRY                     17600019
CLOSE    EQU   *                                                        17700019
         TM    SUBSWT,RIDS         HAS READER/INTERPRETER DATA SET BEEN 17800019
*                                  ALLOCATED                            17900019
         BZ    NOJOBS              NO RETURN TO CALLER                  18000019
         SPACE 2                                                        18100019
*              INVOKE IHKSRV TO START READER ON JOB STREAM              18200019
         SPACE                                                          18300019
         LR    GO,DCB              ADDRESS OF DCB TO CLOSE              18400019
         LR    PAR,R11             ADDRESS OF TUB FOR IHKSRV            18500019
         MVI    SRVCODE,ATE        SET REQUEST CODE TO START RDRCRJE    18600019
         TM    WRTSWT,SRVABD       IF SERVICE TASK ABENDED       A36810 18630020
         BO    RETURN              EXIT                          A36810 18660020
         BAL   BAC,SRVGO           INVOKE IHKSRV TO START RDRCRJE       18700019
         SPACE                                                          18800019
         L     PAR,TUBIRLSA        ADDRESS OF START RDRCRJE PARMS       18900019
         LTR   PAR,PAR             ANY JOBS COLLECTED                   19000019
         BNZ   RETURN              YES  RETURN                          19100019
NOJOBS   MVC   MSGIX(2),M78        NO JOBS IN SUBMIT MESSAGE            19200019
         LA    R9,ZERO             NO VARIABLE PARMS ON MESSAGE         19300019
         BAL   RTR,SENDMSG         SEND MESSAGE TO USER                 19400019
         SPACE 3                                                        19500019
RETURN   LA    ZIP,WORKEND         LENGTH OF WORK AREA                  19600019
         LR    PAR,SAV             ADDRESS OF WORK AREA                 19700019
         L     GO,RTRNCODE         GET RETURN CODE                      19800019
         L     SAV,FOUR(SAV)       RESTORE TO OLD SAVE AREA             19900019
         FREEMAIN R,LV=(0),A=(1)                                        20000019
         XC    TUBIRLSA(4),TUBIRLSA CLEAR POINTER TO S RDRCRJE PARMS    20100019
ERRTURN  RETURN (14,12),,RC=(15)                                        20200019
         SPACE 5                                                        20300019
READEOD  EQU   *                                                        20400019
         LA    PAR,TUBPTR(SAV)     TUB POINTER                          20500019
         RCLOSE                    CLOSE LIBRARY                        20600019
         NI    WRTSWT,FF-LIBOPEN   TURN OFF OPEN SWITCH                 20700019
         SPACE 2                                                        20800019
SUBREAD1 EQU   *                                                        20900019
         LA    R9,CMDGET           REQUEST CODE FOR IHKGET              21000019
         TM    WRTSWT,LDCABD       IF LOADER/CONTROLLER ABENDED  A36810 21030020
         BO    SUBEND              CLEAN UP AND EXIT             A36810 21060020
         BAL   RTR,LDCGO           LOAD , EXECUTE, AND DELETE IHKGET    21100019
         SPACE                                                          21200019
         LH    PAR,TUBPARM1        ADDRESS OF MESSAGE                   21300019
         LTR   PAR,PAR             IS THERE A MESSAGE                   21400019
         BZ    GETRTN              NO MESSAGE CHECK RETURN CODE         21500019
         STH   PAR,MSGIX           PUT MESSAGE NUMBER IN PARM LIST      21600019
         LA    R9,CURNTLNG         ADDRESS OF VARIABLE PARMS (DSNAME)   21700019
         BAL   RTR,SENDMSG         SEND MESSAGE TO USER                 21800019
         SPACE 1                                                 A36818 21810020
         CLC   RTRNCODE(2),M72     TEST FOR COMMA WARNING        A36818 21820020
         BNE   GETRTN              IF NONE, CHECK RETURN CODE    A36818 21830020
         LA    R9,ZERO             NO VARIABLE PARAMETERS        A36818 21840020
         MVC   RTRNCODE(2),ZERO    RESTORE RETURN CODE AREA      A36818 21850020
         MVC   MSGIX(2),M72        MSG NO TO LIST                A36818 21860020
         BAL   RTR,SENDMSG         SEND MESSAGE TO USER          A36818 21870020
         SPACE 1                                                 A36818 21880020
         SPACE                                                          21900019
GETRTN   B     *+4(R8)                                                  22000019
         B     SUBREAD2            PROCESS RECORD                       22100019
          B     SUBEND             EOF  CLEAN UP BEFORE EXIT            22200019
         B     ERRCLOSE            GETMAIN FAILURE                      22300019
         B     ERRCLOSE            I/O ERROR IN ACTIVE AREA             22400019
         B     ERRCLSE             LIBRARY I/O ERROR                    22500019
         SPACE 3                                                        22600019
NEXTREC1 STH   PAR,RECOUNT         SAVE COUNT                           22700019
         LA    REC,80(REC)         NO BUMP TO NEXT RECORD               22800019
         LR    PAR,REC             PUT RECORD ADDRESS IN ONE            22900019
         CLC   0(1,REC),SLASH      SLASH IN COLUMN ONE                  23000019
         BNE   WRITIT              NO, WRITE IT TO R/I DATA SET         23100019
         TM    SUBSWT,DDDATA       NOW PROCESSING DO DATA               23200019
         BO    EDDDATA             YES, CHECK FOR /*                    23300019
         CLC   0(2,REC),SLASH      SLASHES IN COLUMNS 1 AND 2           23400019
         BNE   WRITIT              NO, WRITE IT                         23500019
         SPACE 2                                                        23600019
IEXIT    EQU   *                                                        23700019
         ST    REC,TUBPARM1       SAVE ADDRESS OF RECORD                23800019
ISXGO    LA    PAR,TUBUSRID        ADDRESS OF USER ID                   23900019
         ST    PAR,TUBPARM2       SAVE ADDRESS OF USERID                24000019
         LA    PAR,TUBPARM1        PARMS TO INSTALLATION EXIT           24100019
         L     BAC,IHKYYCCT        ADDRESS OF CCT                       24200019
         USING CCTDSECT,BAC                                             24300019
         L     GO,CCTISX          GET ADDRESS OF EXIT                   24400019
         DROP  BAC                                                      24500019
         LTR   GO,GO               DOES EXIT EXIST                      24600019
         BZ    ISXGOOD             NO PROCESS JOB STATMENT              24700019
         BALR  BAC,GO             GO TO INSTALLATION EXIT               24800019
         B     *+4(GO)             CHECK INSTALLATION RETURN CODE       24900019
         B     ISXGOOD             JOB CARD O K                         25000019
         B     IXBAD               ABORT SUBMIT                         25100019
         SPACE 3                                                        25200019
         LR    RTR,PAR             SAVE ADDRESS OF EXITS MESSAGE        25300019
         TM    WRTSWT,LIBOPEN      IS LIBRARY OPEN                      25400019
         BZ    ISWRIT              NO SKIP CLOSE BEFORE WRITE           25500019
         SPACE                                                          25600019
         LA    PAR,TUBPTR(SAV)     TUB POINTER                          25700019
         RCLOSE                    CLOSE LIBRARY                        25800019
         NI    WRTSWT,FF-LIBOPEN   TURN OFF OPEN SWITCH                 25900019
         SPACE 2                                                        26000019
*              SEND EXITS ERROR MESSAGE THEN PUNT                       26100019
         SPACE 2                                                        26200019
ISWRIT   LA    R9,60               MAX LENGTH OF MESSAGE                26300019
         STH   R9,TUBDATAL         SET LENGTH                           26400019
         L     R9,TUBUFFAD         BUFFER ADDRESS                       26500019
         MVC   0(60,R9),0(RTR)     MOVE MESSAGE TO TO BUFFER            26600019
         ST    R9,TUBPARM1         ADDRESS OF MESSAGE IN EXIT PARM LIST 26700019
         OI    TUBREQST,TUBWRITN   SET FLAG TO REQUEST WRITE            26800019
         SPACE                                                          26900019
LINEIO   LA    PAR,TUBPARM4        ADDRESS OF TUB FOR IHKLAD            27000019
         L     GO,IHKYYLAD         ADDRESS OF LINE ADMINISTRATOR        27100019
         BALR  BAC,GO              LINKAGE TO IHKLAD                    27200019
         SPACE                                                          27300019
         B     IXBAD               SEND MESSAGE 376 TO USER             27400019
         SPACE 2                                                        27500019
ISXGOOD  CLI   3(REC),ASSTR        IF * CARD IS COMMENT                 27600019
         BE    WRITIT              COMMENT WRITE IT                     27700019
*                                                                       27800019
*        SCAN  FOR NON-BLANK                                            27900019
*                                                                       28000019
         LA    R8,2(REC)           BEGINING OF NAME                     28100019
         LA    R9,1(REC)           POSITION BEFORE NAME                 28200019
NAMAGN   LA    R9,1(R9)            BUMP TO NEXT BYTE                    28300019
         CLI   0(R9),BLANK         CKECK FOR BLANK                      28400019
         BNE   NAMAGN              NO CHECK NEXT BYTE                   28500019
         LR    PAR,R9              SAVE END OF NAME                     28600019
SUBOVER  LA    PAR,1(PAR)          UPDATE POINTER                       28700019
         CLI   0(PAR),BLANK        IS IT A BLANK                        28800019
         BE    SUBOVER             YES, TRY AGAIN                       28900019
*                                  NO, NOW AT FIRST NON-BLANK  SHOULD   29000019
*                                  BE DD .                              29100019
         CLC   0(3,PAR),DD         IS IT                                29200019
         BE    SUBDATA             HOW ABOUT THAT. CHECK FOR DATA       29300019
         CLC   0(4,PAR),JOB        NOPE, IT'S GOT TO BE A JOB CARD      29400019
         BNE   WRITIT              MISSED ALL WAY AROUND - WRITE IT     29500019
         SPACE 5                                                        29600019
*        PROCESS JOB STATEMENT                                          29700019
         SPACE 3                                                        29800019
SETSWT   SR    R9,R8               GET LENGTH OF NAME                   29900019
         STC   R9,JNMLNG           SAVE LENGTH OF JOBNAME               30000019
         SPACE                                                          30100019
         TM    SUBSWT,RIDS         IS THIS FIRST JOB CARD               30200019
         BZ    MOVEIT              YES  GET JOBNAME                     30300019
*                                                                       30400019
         BAL   RTR,SRCHRJCT        WRITE RJCT TO ACTIVE AREA            30500019
         SPACE 5                                                        30600019
*  SEARCH FOR RJCT    FIND JOBNAME AND MOVE IT TO WORKAREA              30700019
         SPACE 5                                                        30800019
MOVEIT   MVI  TUBGBLKY,BLANK       BLANK GLOBAL KEY                     30900019
         MVC   TUBGBLKY+1(7),TUBGBLKY CLEAR FOR JOBNAME                 31000019
         NI    SUBSWT,FF-JOBC-DDDATA CLEAR JOB AND DD DATA SWITCHES     31100019
         CLI   JNMLNG,ZIP          IS THERE A JOB NAME                  31200019
         BE    LNGERR              NO JOBNAME, SEND MESSAGE AND EXIT    31300019
         CLI   JNMLNG,ATE          IS NAME LESS THAN OR EQUAL 8 BYTES   31400019
          BH   LNGERR              YES SEND MESSAGE AND EXIT            31500019
         IC    R9,JNMLNG           RESTORE LENGTH OF JOB NAME           31600019
         EX    R9,MOVNAME          MOVE NAME FOR SAFEKEEPING            31700019
         SPACE                                                          31800019
         LA    GO,RJCTAD          SET BASE FOR RJCT ENTRY               31900019
         USING RJCTSECT,GO                                              32000019
         MVC   RJCTJOB(8),TUBGBLKY MOVE JOBNAME TO RJCT                 32100019
         MVC   RJCTUSER(8),TUBUSRID INSERT USER ID                      32200019
         MVC   RJCTTTRB(4),ONETTR  SET TTR TO FIRST AND CLEAR FLAGS     32300019
         DROP  GO                                                       32400019
         SPACE 2                                                        32500019
         MVI   TUBGBLNM,RJCTNM     SET GLOBAL FILE TO RJCT              32600019
         LA    PAR,TUBPARM4        ADDRESS OF TUB POINTER               32700019
         SPACE                                                          32800019
         RPOINT B,NR,FTYPE=GBL                                          32900019
         SPACE                                                          33000019
         CH    GO,RC4            CHECK RETURN CODE                      33100019
         BL   DUP                 BRANCH IF NAME FOUND - DUPLICATE      33200019
         BH    SETRTN              I/O ERROR IN ACTIVE FILE             33300019
         SPACE 2                                                        33400019
         TM    SUBSWT,RIDS        IF GOOD, HAS R/I D.S. ALLOCATED       33500019
         BO    CONT                NOT FIRST JOB SET JOB SWITCH         33600019
         SPACE 3                                                        33700019
*                                                                       33800019
*                   ALLOCATE READER INTERPRETER DATA SET AND            33900019
*                   SUPPLY UNIT AND VOLUME INFO FOR START RDR           34000019
         MVI    SRVCODE,FOUR       REQUEST IHKALC RUN IN SERVICE TASK   34100019
         LA    R9,CMDALC           REQUEST CODE FOR IHKALC              34200019
         BAL   RTR,LDCGO           LOAD , EXECUTE, AND DELETE IHKALC01  34300019
         B     *+4(R8)             CHECK RETURN CODE                    34400019
         B     CONT                GOOD RETURN                          34500019
         B     DUP                 DUPLICATE NAME                       34600019
         B     OUTSPACE            NO SPACE FOR R/I DATA SET            34700019
         B     SUBIOE              I/O ERROR ON R/I DATA SET            34800019
         B     GETFAIL             ALC UNABLE TO GET WORK AREA          34900019
         B     NODD                NO DD STATEMENT IN PROCEDURE         35000019
         SPACE 3                                                        35100019
NOT231X  EQU   *                                                        35200019
         L     RTR,TUBCLBAD        ADDRESS OF CLB                A36810 35230020
         USING CLBDSECT,RTR                                      A36810 35260020
         MVC   MSGNAM(8),CLBDDNAM                                       35300019
         DROP  RTR                                               A36810 35350020
         MVC   MSGIX(2),M98        DDNAME NOT IN CRJE PROCEDURE         35400019
         B     NAMERR1             SEND ERROR TO USER AND ABORT SUBMIT  35500019
         SPACE 3                                                        35600019
NODD     EQU   *                   NO DD STATEMENT IN PROC.             35700019
         L     RTR,TUBCLBAD        ADDRESS OF CLB                A36810 35730020
         USING CLBDSECT,RTR                                      A36810 35760020
         MVC   MSGNAM(8),CLBDDNAM                                       35800019
         DROP  RTR                                               A36810 35850020
         MVC   MSGIX(2),M75        DDNAME NOT IN CRJE PROCEDURE         35900019
         BAL   RTR,SENDMSG1        SEND MESSAGE TO USER                 36000019
         MVC   MSGOFF+1(3),M235    MESSAGE FOR CENTRAL                  36100019
NODDMSG  L     GO,IHKYYMSG         ADDRESS OF MESSAGE WRITER            36200019
         LA    PAR,ZERO            INDICATE DESTINATION IS CENTRAL      36300019
         BAL   RTR,SENDMSG2        SEND MESSAGE TO CENTRAL              36400019
         MVI   MSGOFF+1,M3         RESET FOR REMOTE MESSAGES            36500019
         B     SUBABND             ABORT SUBMIT                         36600019
         SPACE 3                                                        36700019
         USING RJCTSECT,RJCT                                            36800019
CONT     LA    RJCT,RJCTAD        SET BASE FOR RJCT ENTRY               36900019
         LH    R8,RECOUNT          NUMBER RECORDS TO PROCESS            37000019
         MH    R8,LRECL            GET LENGTH                           37100019
         STH   R8,TUBPARM1         SAVE LENGTH                          37200019
BLKWRIT  LH    R8,WLG              GET LENGTH OF BLOCK TO WRITE         37300019
         SH    R8,TUBPARM1         FIND LENGTH OF BUFFER REMAINING      37400019
*                                  TO BE PROCESSED                      37500019
         LTR   R8,R8               ANY TO WRITE                         37600019
         BZ    DUMWRIT             SKIP WRITE OF PREVIOUS RECORDS       37700019
         SPACE                                                          37800019
         STH   R8,WLG              SET LENGTH OF WRITE IN DECB          37900019
         SPACE 2                                                        38000019
         BAL   RTR,WRITIT02        WRITE RECORDS                        38100019
         L     R8,BUFFAD           ADDRESS OF BUFFER                    38200019
         AH    R8,WLG              BUMP PAST RECORDS WRITTEN            38300019
         ST    R8,BUFFAD           UPDATE BUFFER POINTER                38400019
         SPACE 2                                                        38500019
DUMWRIT  LH    R9,TUBPARM1         GET LENGTH OF RECORDS TO PROCESS     38600019
         MVC   WLG(2),LRECL        RESET BLOCK SIZE TO 80               38700019
         SPACE 2                                                        38800019
         BAL   RTR,WRITIT02        WRITE JOB STATEMENT                  38900019
         OI    SUBSWT,JOBC        TURN ON JOB CARD SWITCH               39000019
         SH    R9,LRECL            DECREMENT BLKSIZE BY 80              39100019
         STH   R9,WLG              UPDATE BLKSIZE IN DCB                39200019
         LA    R8,LREC(REC)        ADDRESS OF NEXT RECORD               39300019
         ST    R8,BUFFAD           RESET LOGICAL START OF BUFFER        39400019
         LA    RTR,NEXTREC         PROCESS NEXT RECORD AFTER NOTE       39500019
         SPACE 3                                                        39600019
NOTEONE  NOTE  (5)                 GET TTR                              39700019
         SPACE                                                          39800019
         ST    PAR,NOTETTR         SAVE TTR                             39900019
         BR    RTR                 RETURN TO CALLER                     40000019
         SPACE 3                                                        40100019
IXBAD    MVC   MSGIX(2),M76        USER EXIT ABORTING SUBMIT            40200019
         B     NAMERR              ABORT SUBMIT                         40300019
LNGERR   MVC   MSGIX(2),M65        JOB NAME TOO LONG                    40400019
NAMERR   MVC    MSGNAM(8),2(REC)   MOVE NAME FOR MESSAGE                40500019
NAMERR1  BAL   RTR,SENDMSG1        SEND MESSAGE TO USER                 40600019
         TM    SUBSWT,RIDS         R/I DATA SET ALLOCATED               40700019
         BZ    SUBABND             NO SKIP NOTE                         40800019
         TM    SUBSWT,JOBC         IS THIS JOB CONTINUATION             40900019
         BO    SUBABND             YES SKIP NOTE                        41000019
         BAL   RTR,NOTEONE         NOTE TTR OF R/I DATA SET             41100019
         A     PAR,ONETTR          ADD ONE TO TTR SO RECORD IS NOT LOST 41200019
         ST    PAR,NOTETTR         SAVE TTR FOR POINT                   41300019
         B     SUBABND             ABORT SUBMIT                         41400019
         SPACE 2                                                        41500019
SRCHRJCT L     BAC,IHKYYCCT        ADDRESS OF CCT                       41600019
         USING CCTDSECT,BAC                                             41700019
         LH    R9,CCTJOBS          COUNT OF JOBS                        41800019
         LTR   R9,R9               MORE JOBS ALLOWED                    41900019
         BZ    MAXJOBS             NO SEND MESSAGE AND EXIT             42000019
         SPACE                                                          42100019
         LA    PAR,RJCTAD-8        RJCT FOT BUFFER                      42200019
         ST    PAR,TUBRAFBF        SET AS AFIO BUFFER                   42300019
         MVI   TUBGBLNM,RJCTNM     SET FILE NUMBER TO RJCT              42400019
         MVC   TUBGBLKY(8),RJCTJOB SET KEY TO JOB NAME                  42500019
         OI    TUBAFISW,TUBFCTLN   USE BUFFER CONTROL                   42600019
         LA    PAR,TUBPARM4        ADDRESS OF TUB POINTER               42700019
         SPACE                                                          42800019
         RPOINT A,NR,KEY=HIEQ,FTYPE=XGBL POSITION FOR INSERT            42900019
         SPACE                                                          43000019
         LR    R8,GO               SAVE RETURN CODE                     43100019
         CH    GO,RC4            CHECK RETURN CODE                      43200019
         BH    ENDAFI              NOT A NOT FOUND RETURN CODE          43300019
         SPACE 2                                                        43400019
         INSERT S,A,FTYPE=XGBL                                          43500019
         SPACE                                                          43600019
         LTR   R8,GO               SAVE RETURN CODE                     43700019
         BNZ   ENDAFI              NOT GOOD RETURN                      43800019
         L     BAC,IHKYYCCT        RE-ADDRESS CCT                       43900019
         BCTR  R9,ZIP              DECREMENT COUNT OF JOBS ALLOWED      44000019
         STH   R9,CCTJOBS          SAVE NEW COUNT                       44100019
         DROP  BAC                                                      44200019
         SPACE 2                                                        44300019
ENDAFI   ENDUP FTYPE=GBL                                                44400019
         NI    TUBAFISW,TUBFCTLF   TURN OFF BUFFER CONTROL              44500019
         CH    R8,RC4            CHECK RETURN CODE                      44600019
         BE    ACTNSPC             OUT OF SPACE IN ACTIVE FILE          44700019
         BH    ERRCLOSE            I/O ERROR IN ACTIVE FILE             44800019
         OI    WRTSWT,RJCWRT       INDICATE JOB WRITTEN TO RJCT         44900019
         BR    RTR                 RETURN TO INVOKER                    45000019
         SPACE 3                                                        45100019
ACTNSPC  MVC   MSGIX(2),M57        OUT OF SPACE ACTIVE AREA MSG         45200019
         B     EXECERR1            SEND MESSAGE AND EXIT                45300019
         SPACE 3                                                        45400019
MAXJOBS  MVC   MSGIX(2),M28        MAX JOBS EXCEEDED MESSAGE            45500019
         SPACE 5                                                        45600019
EXECERR1 MVC   MSGNAM(8),RJCTAD+(RJCTJOB-RJCTSECT) NAME FOR MESSAGE     45700019
         B     NAMERR1             SEND ERROR TO USER AND ABORT SUBMIT  45800019
         SPACE 5                                                        45900019
*                                                                       46000019
*        PROCESS STATEMENT IN DD DATA DATA SET                          46100019
*                                                                       46200019
EDDDATA  CLI   1(REC),ASSTR        IS STATEMENT /*                      46300019
         BNE   WRITIT              NO, WRITE IT                         46400019
         NI    SUBSWT,DDDATOFF     YES, TURN OFF DD DATA SWITCH         46500019
         B     WRITIT01            WRITE IT                             46600019
         SPACE 5                                                        46700019
*                                                                       46800019
*        PROCESS DD STATEMENT                                           46900019
*                                                                       47000019
SUBDATA  LA    PAR,2(PAR)          STEP PAST DD                         47100019
SUBDAGN  LA    PAR,1(PAR)          UPDATE FOR SCAN                      47200019
         CLI   0(PAR),BLANK        IS IT BLANK                          47300019
         BE    SUBDAGN             YES, LET'S TRY ONE MORE TIME         47400019
         CLC   0(4,PAR),DATA       MADE IT THRU LOOP. IS IT DATA A47412 47500000
         BNE   WRITIT              NO, WRITE IT                         47600019
         OI    SUBSWT,DDDATA       YES, TURN ON DD DATA SWITCH          47700019
         B     WRITIT              WRITE RECORD OUT TO R/I DATA SET     47800019
         SPACE 5                                                        47900019
*        DUPLICATE JOBNAME                                              48000019
DUP      MVC   MSGIX(2),M26        DUPLICATE JOBNAME                    48100019
         B     EXECERR1            SEND MSG TO USER AND EXIT            48200019
         SPACE 5                                                        48300019
SUBNOSP  OI    SUBSWT,NOSPACE      TURN ON EXLIST SWITCH                48400019
         LA    GO,ONE              SET CODE FOR EOV ROUTINE             48500019
         BR    BAC                 RETURN TO EOV ROUTINE WHICH WILL     48600019
*                                  COME TO SYNAD                        48700019
         SPACE 5                                                        48800019
SUBSYNAD EQU   *                                                        48900019
         TM    SUBSWT,NOSPACE      TEST EXLST SWITCH                    49000019
         BO    OUTSPACE            BRANCH IF OUT OF SPACE               49100019
         L     R9,DCBDEBAD         GET ADDRESS OF DEB                   49200019
         CLI   DEBNMEXT(R9),NOEXT  TEST NUMBER OF EXTENTS IN DEB        49300019
         BL    SUBIOE                                                   49400019
OUTSPACE MVC   MSGIX(2),M00        OUT OF SPACE                         49500019
         L     RTR,TUBCLBAD        ADDRESS OF CLB                A36810 49520020
         USING CLBDSECT,RTR                                      A36810 49540020
         MVC   MSGNAM(8),CLBDDNAM                                       49560019
         B     NAMERR1             SEND ERROR MESSAGE 342               49620019
         DROP  RTR                                               A36810 49660020
         SPACE 5                                                        49700019
SUBIOE   MVC   MSGIX(2),M32        I/O ERROR                            49800019
         B     EXECERR1            SEND MESSAGE AND EXIT                49900019
         SPACE 5                                                        50000019
WRITIT   TM    SUBSWT,RIDS         R/I DATA SET ALLOCATED               50100019
         BO    WRITIT01            YES WRITE RECORD                     50200019
         NI    SUBSWT,DDDATOFF     TURN OFF DD DATA SWITCH              50300019
         B     NEXTREC             GET NEXT RECORD                      50400019
WRITIT01 LA    RTR,SUBREAD         GET RETURN POINT                     50500019
         LH    PAR,RECOUNT         RECORDS LEFT IN BLOCK                50600019
         BCT   PAR,NEXTREC1        DECREMENT NUMBER RECORDS INSPECTED   50700019
WRITIT02 L     R8,BUFFAD           ADDRESS OF BLOCK                     50800019
WRITIT03 WRITE SUBDECB,SF,(5),(8),,MF=E                                 50900019
         OI    WRTSWT,ONEWRT       INDICATE WRITE HAS BEEN DONE         51000019
         LA    GO,SUBREAD                                               51100019
         CR    GO,RTR              READ BLOCK AFTER WRIT                51200019
         BNE   WRITWAIT            NO WAIT ON I/O                       51300019
         SPACE                                                          51400019
*  READ   RECORD                                                        51500019
SUBREAD2 LA    PAR,TUBPTR(SAV)                                          51600019
         LA    WOK,BLKNUM                                               51700019
         STH   WOK,TUBCNTFS        SET NUMBER OF RECORDS TO GET         51800019
         TM    SUBSWT,ACTSWT       ACTIVE OR LIBRARY FILE               51900019
         BO    READACT             ACTIVE FILE                          52000019
         SPACE                                                          52100019
SUBREAD3 RREAD                                                          52200019
         SPACE                                                          52300019
         MVC   TUBRAFBF(4),SFBUFF1 MOVE BUFFER POINTER TO TUB           52400019
         LR    R8,GO               SAVE RETURN CODE                     52500019
         B     FREEBUF             SEE IF I/O DONE AND BUFFER FREED     52600019
READACT  TM    WRTSWT,ACTDSLST     IS ACTIVE AREA DSLIST FILE           52700019
         BO    SUBREAD3            YES THEN REALLY WANT TO READ LIB.    52800019
         RGET  R,M,A                                                    52900019
         SR    LNG,LNG             CLEAR FOR COUNT OF RECORDS READ      53000019
         IC    LNG,TUBCNTFS        NUMBER OF RECORDS READ               53100019
         STH   LNG,TUBCNTFS        SET COUNT TO HALFWORD VALUE          53200019
         LA    R8,16(GO)           SAVE RETURN CODE AND BUMP BY 16      53300019
FREEBUF  TM    WRTSWT,ONEWRT       WRITE OUTSTANDING                    53400019
         BZ    SUBREAD             NOPROCESS BLOCK                      53500019
WRITWAIT LA    PAR,SUBDECB         CLEAR HIGH ORDER BYTE FOR WAIT       53600019
         TM    SUBDECB,POST        IS I/O COMPLETE                      53700019
         BO    WRTCHECK            YES SKIP DISPATCHER CALL             53800019
         SPACE                                                          53900019
         L     GO,IHKYYDSP         ADDRESS OF DISPATCHER                54000019
         BALR  BAC,GO              WAIT FOR I/O                         54100019
WRTCHECK CHECK (1)                                                      54200019
         NI    WRTSWT,FF-ONEWRT    INDICATE NO WRITES OUTSTANDING       54300019
         SPACE                                                          54400019
         LA    GO,SUBREAD          RETURN POINT IF READ DONE            54500019
         CR    RTR,GO              DID READ FOLLOW WRITE                54600019
         BCR   7,RTR               NO RETURN TO CALLER                  54700019
BUFFREE  L     PAR,BLOCKAD         ADDRESS OF OUTPUT BLOCK              54800019
         LTR   PAR,PAR             DOES BLOCK EXIST                     54900019
         BCR   8,RTR               NONE TO FREE                         55000019
         LM    ZIP,PAR,0(PAR)      GET LENGTH AND ADDRESS TO FREE       55100019
         FREEMAIN R,LV=(0),A=(1)                                        55200019
         XC    BLOCKAD(4),BLOCKAD  CLEAR POINTER TO BLOCK OF OUTPUT     55300019
         BR    RTR                 RETURN TO CALLER                     55400019
         SPACE                                                          55500019
SUBREAD  EQU   *                                                        55600019
         SR    REC,REC             CLEAR POINTER TO RECORD              55700019
         B     *+4(R8)             CHECK RETURN FROM RREAD OR RGET      55800019
         B     EDITBLK             EDIT BLOCK                           55900019
         B     READEOD             END OF DATA ON RREAD                 56000019
         B     ERRCLOSE            GETMAIN FAILURE                      56100019
         B     ERRCLSE             I/O ERROR                            56200019
         B     EDITBLK             EDIT BLOCK                           56300019
         B     SUBREAD1            E O D  GET NEXT DSNAME               56400019
         B     ERRCLOSE            GETMAIN FAILURE                      56500019
         B     ERRCLOSE            I/O ERROR IN ACTIVE AREA             56600019
         SPACE                                                          56700019
EDITBLK  EQU   *                                                        56800019
         LH    LNG,TUBCNTFS        NUMBER OF BLOCKS READ                56900019
         L     OLD,TUBRAFBF        ADDRESS OF BLOCK READ                57000019
         ST    OLD,BLOCKAD         SAVE ADDRESS OF BLOCK                57100019
         LA    LNG,1(LNG)          BUMP FOR BCT LOOP                    57200019
         STH   LNG,RECOUNT         SAVE COUNT OF RECORDS PLUS ONE       57300019
         LA    OLD,8(OLD)          BUMP PAST CONTROL BYTES              57400019
         ST    OLD,BUFFAD          SAVE ADDRESS OF BUFFER               57500019
         LR    NEW,OLD                                                  57600019
EDITBLK2 BCT   LNG,EDITMVC         EDIT ONE RECORD OF BLOCK             57700019
         SPACE                                                          57800019
GOTREC   LH    REC,RECOUNT         NUMBER OF RECORDS READ PLUS ONE      57900019
         BCTR  REC,ZIP             GET NUMBER OF RECORDS READ           58000019
         MH    REC,LRECL           GET LENGTH OF BLOCK                  58100019
         STH   REC,WLG             PUT LENGTH IN DECB                   58200019
         L     REC,BUFFAD          ADDRESS OF BLOCK READ                58300019
         SH    REC,LRECL           POSITION BUFFER POINTER FOR LOOP     58400019
         SPACE 2                                                        58500019
NEXTREC  LH    PAR,RECOUNT         NUMBER OF RECORDS READ               58600019
         BCT   PAR,NEXTREC1        DECREMENT NUMBER RECORDS INSPECTED   58700019
         LA    RTR,SUBREAD2        SET RETURN TO READ NEXT BLOCK        58800019
         B     BUFFREE             IF ZERO READ NEXT BLOCK              58900019
         SPACE 2                                                        59000019
EDITMVC  EQU   *                                                        59100019
         MVC   0(80,NEW),8(OLD)    MOVE RECORD                          59200019
         LA    NEW,80(NEW)         BUMP TO NEXT RECORD                  59300019
         LA    OLD,88(OLD)                                              59400019
         B     EDITBLK2            PROCESS NEXT RECORD                  59500019
         SPACE 4                                                        59600019
*              S E N D M E S S A G E S   T O   U S E R S   A N D        59700019
*              C E N T R A L   O P E R A T O R                          59800019
         SPACE 4                                                        59900019
SENDMSG1 LA    R9,MSGPARM          GET ADDRESS OF VARIABLE PARMS        60000019
         SPACE 2                                                        60100019
SENDMSG  L     GO,IHKYMSG1         ADDRESS OF MESSAGE WRITER            60200019
         LA    PAR,TUBUSRID        ADDRESS OF USER ID                   60300019
SENDMSG2 ST    R9,MSGVP            PUT VARIABLE PARMS IN LIST           60400019
         MVI   MSGVP,JOB1          INDICATE END OF PARM LIST            60500019
         ST    PAR,MSGTUB          PUT TUB IN PARM LIST                 60600019
         ST    R11,MSGPARMS        PUT TUB ADDRESS IN MESSAGE WRITER    60700019
*                                  PARAMETER LIST                       60800019
         LA    PAR,MSGPARMS        PARM LIST FOR MESSAGE WRITER         60900019
         BALR  BAC,GO              SEND MESSAGE                         61000019
         BR    RTR                 RETURN TO CALLER                     61100019
         SPACE 5                                                        61200019
LDCGO    EQU   *                                                        61300019
         SPACE                                                          61400019
         XC    LDCPARM(7),LDCPARM  CLEAR PARMS FOR LOADER/CONTROLLER    61500019
         STC   R9,LOADCODE         SET MODULE CODE                      61600019
         LA    ZIP,LDCPARM         ADDRESS OF PARMS                     61700019
         TM    IHKYYLCE,POST       IF POSTED IHKLDC HAS ABENDED  A36810 61750020
         BO    ABENDLDC            CLEAN UP AND EXIT             A36810 61800020
         LA    PAR,CLBLCECB        ECB TO POST IHKLDC            A36810 61850020
         SPACE                                                          61900019
         POST  (1),(0)             POST LOADER/CONTROLLER               62000019
         SPACE                                                          62100019
         LA    PAR,LDCPARM         ECB POSTED BY IHKLDC ON COMPLETION   62200019
         L     GO,IHKYYDSP         ADDRESS OF CRJE DISPATCHER           62300019
         BALR  BAC,GO              WAIT FOR IHKLDC TO SERVICE REQUEST   62400019
         SPACE 2                                                        62500019
         TM    3(PAR),ONE          LOADER/CONTROLLER ABEND       A36810 62530020
         BO    ABENDLDC            YES, CLEAN UP AND EXIT        A36810 62560020
         L     GO,0(PAR)           ADDRESS OF ROUTINE (IHKGET OR IHKALC 62600019
         LA    PAR,TUBPARM3        PARM LIST                            62700019
         CLI   LOADCODE,CMDGET     IS REQUEST FOR IHKGET                62800019
         BNE   SRVGO1              NO INVOKE IHKSRV FOR IHKALC          62900019
         BALR  BAC,GO              EXICUTE ROUTINE                      63000019
         SPACE 2                                                        63100019
LDCDLT   XC    LDCPARM(6),LDCPARM  CLEAR PARMS FOR DELETE               63200019
         STC   R9,DELTCODE         MODULE CODE                          63300019
         LR    R8,GO               SAVE RETURN CODE                     63400019
         TM    IHKYYLCE,POST       IF POSTED IHKLDC HAS ABENDED  A36810 63450020
         BO    ABENDLDC            CLEAN UP AND EXIT             A36810 63500020
         LA    PAR,CLBLCECB        ECB TO POST IHKLDC            A36810 63550020
         LA    ZIP,LDCPARM         ADDRESS OF PARMS                     63600019
         SPACE                                                          63700019
         POST  (1),(0)             POST LOADER/CONTROLLER               63800019
         SPACE                                                          63900019
         LA    PAR,LDCPARM         ECB POSTED BY IHKLDC ON COMPLETION   64000019
         L     GO,IHKYYDSP         ADDRESS OF CRJE DISPATCHER           64100019
         BALR  BAC,GO              WAIT FOR IHKLDC TO SERVICE REQUEST   64200019
         SPACE 2                                                        64300019
         TM    3(PAR),ONE          LOADER/CONTROLLER ABEND       A36810 64330020
         BO    ABENDLDC            YES, CLEAN UP AND EXIT        A36810 64360020
         BR    RTR                 RETURN TO INVOKER                    64400019
         SPACE 2                                                        64500019
SRVGO1   BAL   BAC,SRVGO           REQUEST IHKSRV                       64600019
         TM    3(PAR),ONE          SERVICE TASK ABEND            A36810 64630020
         BO    ABENDSRV            YES, CLEAN UP AND EXIT        A36810 64660020
         L     GO,0(PAR)           GET RETURN CODE                      64700019
         LA    GO,0(GO)            CLEAR HIGH ORDER BYTE                64800019
         B     LDCDLT              DELETE IHKALC                        64900019
         SPACE 5                                                        65000019
SRVGO    ST    GO,SRVALC           SET ADDRESS OF IHKALC                65100019
         ST    PAR,SRVALCPM        PUT ALC PARMS IN SRV PARM LIST       65200019
         NI    SRVECB,ZIP          INSURE ECB NOT POSTED                65300019
         LA    ZIP,SRVPARM         SRV PARM LIST FOR POST CODE          65400019
         TM    IHKYYSRE,POST       IF POSTED IHKSRV HAS ABENDED  A36810 65450020
         BO    ABENDSRV            YES, CLEAN UP AND EXIT        A36810 65500020
         LA    PAR,CLBUTECB        ECB TO POST IHKSRV            A36810 65550020
         SPACE                                                          65600019
         POST  (1),(0)                                                  65700019
         SPACE                                                          65800019
         LA    PAR,SRVECB          ECB POSTED ON COMPLETION             65900019
         L     GO,IHKYYDSP         ADDRESS OF CRJE DISPATCHER           66000019
         BR    GO                  WAIT FOR ALLOCATION                  66100019
         SPACE 3                                                 A36810 66110020
ABENDLDC OI    WRTSWT,LDCABD       SET IHKLDC ABEND SWITCH       A36810 66120020
         B     SETRTN1                                           A36810 66130020
         SPACE 2                                                 A36810 66140020
ABENDSRV OI    WRTSWT,SRVABD       SET IHKSRV ABEND SWITCH       A36810 66150020
SETRTN1  LA    GO,12              SET RETURN CODE TO TWELVE      A36810 66160020
         B     SETRTN              ATTEMPT CLEAN-UP AND EXIT     A36810 66170020
         SPACE 5                                                        66200019
MOVNAME  MVC  TUBGBLKY(0),2(REC)   SAVE JOBNAME                         66300019
         SPACE 5                                                        66400019
*        C O N S T A N T S                                              66500019
         SPACE 5                                                        66600019
RJCTNM   EQU   5                   GLOBAL FILE NUMBER FOR RJCT          66700019
WRITE    EQU   12                                                       66800019
ONE      EQU   1                                                        66900019
FOUR     EQU   4                                                        67000019
ATE      EQU   8                                                        67100019
LREC     EQU   80                                                       67200019
JOBCOFF  EQU   X'BF'                                                    67300019
DDDATOFF EQU   X'DF'                                                    67400019
EXECOFF  EQU   X'EF'                                                    67500019
DEBNMEXT EQU   16                                                       67600019
FF       EQU   X'FF'                                                    67700019
BLANK    EQU   C' '                                                     67800019
ASSTR    EQU   C'*'                                                     67900019
MSGLNG   EQU   48                                                       68000019
BLKNUM   EQU   10                                                       68100019
TUBPTR   EQU   64                                                       68200019
H88      DC    H'88'                                                    68300019
LRECL    DC    H'80'                                                    68400019
JOB1     EQU   X'80'               FIRST JOB CARD SWITCH                68500019
NOEXT    EQU   X'10'                                                    68600019
RC4      DC    H'4'                                                     68700019
M32      DC   C'32'                                                     68800019
SRVPARM  DC    A(SRVECB)                                                68900019
         DC    A(SRVCODE)                                               69000019
SRVALCPM DC    A(0)                PARM LIST TO IHKALC                  69100019
SRVALC   DC    A(0)                                                     69200019
SRVECB   DC    F'0'                                                     69300019
SRVCODE  DC    X'04'                                                    69400019
SLASH    DC    C'//'                                                    69500019
DD       DC    C'DD '                                                   69600019
DATA     DC    C'DATA'                                           A47412 69700000
JOB      DC    C'JOB '                                                  69800019
JNMLNG   DS    X                   LENGTH OF JOBNAME IN S RDR           69900019
ZERO     DC    F'0'                                                     70000019
ONETTR   DC    X'00000100'                                              70100019
SUBEXLST DC    X'88'                                                    70200019
         DC    AL3(SUBNOSP)                                             70300019
         SPACE 2                                                        70400019
MSGPARMS DC    F'0'                ADDRESS OF TUB FOR MESSAGE WRITER    70500019
MSGTUB   DC    F'0'                                                     70600019
         DC    A(MSGOFF)                                                70700019
MSGVP    DC    A(MSGVP)                                                 70800019
MSGOFF   DC    X'0'                                                     70900019
         DC    C'3'                                                     71000019
MSGIX    DC   C'00'                                                     71100019
MSGPARM  DC    X'8'                                                     71200019
MSGNAM   DC    CL8' '                                                   71300019
         SPACE 2                                                        71400019
M57      DC    C'57'                                                    71500019
M78      DC    C'78'                                                    71600019
M75      DC   C'75'                                                     71700019
M76      DC    C'76'                                                    71800019
M65      DC   C'65'                                                     71900019
M70      DC    C'70'                                                    72000019
M28      DC   C'28'                                                     72100019
M26      DC   C'26'                                                     72200019
M00      DC    C'42'                                                    72300019
M98      DC    C'98'                                                    72400019
M235     DC   C'235'                                                    72500019
M241     DC    C'241'                                                   72600019
M3       EQU   C'3'                                                     72700019
M72      DC    C'72'               EXCESSIVE COMMAS WARINIG      A36818 72750020
POST     EQU   X'40'                                                    72800019
         EJECT                                                          72900019
         SPACE 5                                                        73000019
*        W O R K A R E A                                                73100019
         SPACE 5                                                        73200019
WORKSECT DSECT                                                          73300019
SUBSAVE  DC    18F'0'              SAVE AREA FOR IHKSUB                 73400019
SAVE     DS    18F                 SAVE AREA                            73500019
NOTETTR  DC    F'0'                                                     73600019
RJCTAD   DS    20F                 RJCT                                 73700019
SUBDECB  DS    5F                  DECB FOR WRITES                      73800019
GETRDR   EQU   104                                                      73900019
SUBDCB   DS    22F                 READER/INTERPRETER DATA SET DCB      74000019
WLG      EQU   SUBDCB+62                                                74100019
XLSTPTR  DC    F'0'                                                     74200019
SYNADPTR DC    F'0'                                                     74300019
RTRNCODE DC    F'0'                                                     74400019
UTMPARM  DC    F'0'                                                     74500019
         DC    A(0)                                                     74600019
BLOCKAD  DC    F'0'                ADDRESS OF BLOCK INCLUDING CONTROL   74700019
BUFFAD   DC    A(0)                                                     74800019
SAVPPT   DC    3F'0'                                                    74900019
COUNT    DS    0H                                                       75000019
PPTPTCT  DC    H'10'                                                    75100019
SUBSWT   DS    X                                                        75200019
*              X'80'         FORCE END OF DATA FOR IHKGET               75300019
*              X'40'         PROCESSING JOB STATEMENT CONTINUATION      75400019
*              X'20'         PROCESSING DD DATA                         75500019
*              X'10'         EXEC PRESENT FOR PREVIOUS JOB              75600019
*              X'08'         READER/INTERPRETER DATA SET ALLOCATED      75700019
*              X'04'         INPUT FROM D S LIST                        75800019
*              X'02'         INPUT FROM ACTIVE AREA                     75900019
*              X'01'         OUT OF SPACE ON R/I DATA SET               76000019
CLSGET   EQU   X'80'                                                    76100019
JOBC     EQU   X'40'               JOB CARD CONTINUED SWITCH            76200019
DDDATA   EQU   X'20'               DD DATA SWITCH                       76300019
EXECS    EQU   X'10'               EXEC SWITCH                          76400019
RIDS     EQU   X'08'                                                    76500019
DSLSWT   EQU   4                   BIT 5 OF SUBSWT SET TO 1 IF          76600019
*                                  PROCESSING D S LIST TYPE DSNAME      76700019
ACTSWT   EQU   2                   BIT 6 OF GSUBWT SET TO 1 FOR ACTIVE  76800019
*                                  AREA IN USE                          76900019
NOSPACE  EQU   1                                                        77000019
PASSONE  DC    X'0'                                                     77100019
WRTSWT   DC    X'0'                                                     77200019
ONEWRT   EQU   X'80'               FIRST WRITE SWITCH                   77300019
LIBOPEN  EQU   X'40'                                                    77400019
ACTDSLST EQU   X'20'                                                    77500019
RJCWRT   EQU   X'10'                                                    77600019
LINENUM  EQU   X'08'               LINE NUMBER PRESENT IN DSLIST RECORD 77700019
LDCABD   EQU   X'04'                                             A36810 77730020
SRVABD   EQU   X'02'                                             A36810 77760020
UTMCODE  DS    X                                                        77800019
LNGPARM  DS    0H                                                       77900019
         DC    X'0'                                                     78000019
CURNTLNG DC    X'0'                                                     78100019
CURNTDSN DC    CL9' '              LENGTH AND CURRENT DSNAME            78200019
CURNTUSR DC    CL9' '                                                   78300019
CURNTKEY DC    CL4' '                                                   78400019
CURNTLIN DC    CL8' '                                                   78500019
RECOUNT  DC    H'0'                COUNT OF RECORDS IN BLOCK            78600019
LDCPARM  DS    0F                                                       78700019
LDCECB   DC    F'0'                ECB FOR LOADER CONTROLLER            78800019
DELTCODE DC    X'0'                                                     78900019
LOADCODE DC    X'0'                                                     79000019
LDCZERO  DC    X'0'                                                     79100019
WORKEND  EQU   *-WORKSECT                                               79200019
         SPACE 5                                                        79300019
         CMDEQU                                                         79400019
         DCBD DSORG=BS,DEVD=DA                                          79500019
         IHKCDSCT AVT=YES                                               79600019
         IHKCDSCT TUB=YES                                               79700019
         IHKCDSCT CLB=YES                                               79800019
         IHKCDSCT CCT=YES                                               79900019
         IHKCDSCT RJCT=YES                                              80000019
         TUBEQU                                                         80100019
         RAFKNBX TYPE=DSECT                                             80200019
         END                                                            80300019
