TAB      TITLE 'IHKTAB - TABSET COMMAND PROCESSOR'                      00100019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 00200019
*                                                                     * 00300019
*STATUS                                                               * 00400019
*        CHANGE LEVEL 0                                               * 00500019
*FUNCTION                                                             * 00600019
*        WHEN NO OPERANDS ARE SPECIFIED OR WHEN 'IN' OR 'INPUT' AND/OR* 00700019
*        'OFF' ARE SPECIFIED, TUBTABAD IS TESTED.  IF IT CONTAINS AN  * 00800019
*        ADDRESS, THE TAB SETTING AREA TO WHICH IT POINTS IS DEALLO-  * 00900019
*        CATED AND TUBTABAD IS SET TO ZERO.  IF TUBTABAD IS ALREADY   * 01000019
*        ZERO, NO ACTION IS TAKEN.  WHEN 'OUT' OR 'OUTPUT' ALONE OR   * 01100019
*        WITH 'OFF' ARE SPECIFIED, TUBOUTAB IS TESTED AND THE SAME    * 01200019
*        ACTION AS SPECIFIED FOR INPUT TABS IS AFFECTED ON THE OUTPUT * 01300019
*        TABS.  WHEN TAB SETTINGS ARE SPECIFIED, THEY MUST BE NUMERIC,* 01400019
*        AND IN ASCENDING ORDER OR AN ERROR MESSAGE IS SENT TO THE    * 01500019
*        USER AND THE SETTINGS REJECTED.  SETTINGS OF 0 AND 1 ARE     * 01600019
*        REJECTED AS BEING WITHOUT MEANING, THE USER IS NOTIFIED, AND * 01700019
*        THE SETTINGS IGNORED.  A SETTING GREATER THAN 80 FOR INPUT   * 01800019
*        OR 120 FOR OUTPUT IS REJECTED, THE USER NOTIFIED, THE        * 01900019
*        ACCEPTABLE SETTINGS RETAINED, AND THE CHECKING OF REMAINING  * 02000019
*        SETTINGS TERMINATED.  WHEN MORE THAN 10 SETTINGS ARE ACCEPTED* 02100019
*        AN EXCESSIVE OPERAND MESSAGE IS SENT TO THE USER AND THE     * 02200019
*        FIRST TEN SETTINGS ARE RETAINED.  AS THE SETTINGS ARE CHECKED* 02300019
*        THEY ARE TEMPORARILY STORED IN THE USER BUFFER.  WHEN ONLY   * 02400019
*        SETTINGS ARE SPECIFIED OR WHEN 'IN' OR 'INPUT' IS ALSO GIVEN,* 02500019
*        TUBTABAD IS TESTED.  IF IT CONTAINS AN ADDRESS, THE TAB      * 02600019
*        SETTING AREA TO WHICH IT POINTS IS USED.  IF IT CONTAINS ZERO* 02700019
*        AN AREA IS DYNAMICALLY ALLOCATED FOR INPUT TAB SETTINGS AND  * 02800019
*        THE ADDRESS IS STORED IN TUBTABAD.  WHEN 'OUT' OR 'OUTPUT' IS* 02900019
*        GIVEN WITH THE SETTINGS, TUBOUTAB IS TESTED AND THE SAME     * 03000019
*        ACTION AS SPECIFIED FOR INPUT TABS IS AFFECTED FOR OUTPUT    * 03100019
*        TABS.  AFTER ALL THE OPERANDS HAVE BEEN CHECKED AND NO       * 03200019
*        TERMINAL ERRORS DETECTED, THE NUMBER OF SETTINGS IS PLACED   * 03300019
*        IN THE FIRST HALFWORD OF THE AREA FOLLOWED BY THE SETTINGS.  * 03400019
 EJECT                                                                  03500019
*                                                                     * 03600019
*ENTRY POINTS:                                                        * 03700019
*        IHKTAB IS THE ONLY ENTRY POINT TO THIS ROUTINE               * 03800019
*                                                                     * 03900019
*INPUT:                                                               * 04000019
*        REGISTER 1 CONTAINS THE ADDRESS OF A 2 WORD PARAMETER LIST   * 04100019
*        WORD 1 - ADDRESS OF THE TUB                                  * 04200019
*        WORD 2 - ADDRESS OF THE AVT                                  * 04300019
*                                                                     * 04400019
*OUTPUT:                                                              * 04500019
*        N/A                                                          * 04600019
*                                                                     * 04700019
*EXTERNAL REFERENCES                                                  * 04800019
*        IHKMSG - ENTRY POINT IHKMSG01: TO BUILD AND SEND ERROR MSGS  * 04900019
*                                                                     * 05000019
*EXITS:                                                               * 05100019
*        NORMAL - RETURN TO CALLER WITH 0 INE REGISTER 15             * 05200019
*        ERROR - RETURN TO CALLER WITH ONE OF THE FOLLOWING RETURN    * 05300019
*        CODES IN REGISTER 15.                                        * 05400019
*   4  - LINE ERROR                                                   * 05500019
*   8  - GETMAIN FAILED                                               * 05600019
*   12 - ACTIVE AREA I/O ERROR                                        * 05700019
*   16 - ERROR MESSAGE LOST                                           * 05800019
*   20 - ACTIVE AREA OUT OF SPACE                                     * 05900019
*                                                                     * 06000019
*TABLES/WORK AREAS:                                                   * 06100019
*        TUB                                                          * 06200019
*             TUBUFFAD - CONTAINS ADDRESS OF USER BUFFER              * 06300019
*             TUBTABAD - CONTAINS ADDRESS OF INPUT TAB TABLE          * 06400019
*             TUBOUTAB - CONTAINS ADDRESS OF OUTPUT TAB TABLE         * 06500019
*        USER BUFFER - LAST 40 BYTES USED AS WORK AREA                * 06600019
*        INPUT TAB TABLE - CONTAINS INPUT TAB SETTINGS                * 06700019
*        OUTPUT TAB TABLE - CONTAINS OUTPUT TAB SETTINGS              * 06800019
*        PPT - CONTAINS THE TABSET COMMAND                            * 06900019
*        18 WORD SAVE AREA                                            * 07000019
*        16 BYTE TAB AREA                                             * 07100019
*                                                                     * 07200019
*ATTRIBUTES:                                                          * 07300019
*        NON-RESIDENT                                                 * 07400019
*        RE-ENTRANT                                                   * 07500019
*                                                                     * 07600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 07700019
         EJECT                                                          07800019
IHKTAB   CSECT                                                          07900019
         SPACE                                                          08000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 08100019
*                            REGISTER EQUATES                         * 08200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 08300019
         SPACE                                                          08400019
R0       EQU   0                                                        08500019
R1       EQU   1                                                        08600019
R2       EQU   2              WKAREA                                    08700019
R3       EQU   3              TUB                                       08800019
R4       EQU   4              PPT                                       08900019
R5       EQU   5              PPTPARS LENGTH CODE POINTER               09000019
R6       EQU   6              OPERAND LENGTH                            09100019
R7       EQU   7              PPTPARS OPERAND POINTER                   09200019
R8       EQU   8                                                        09300019
R9       EQU   9              WKAREA POINTER                            09400019
R10      EQU   10             CTR                                       09500019
R11      EQU   11             BASE                                      09600019
R12      EQU   12                                                       09700019
R13      EQU   13                                                       09800019
R14      EQU   14                                                       09900019
R15      EQU   15                                                       10000019
 EJECT                                                                  10100019
*********************************************************************** 10200019
*                                                                     * 10300019
*                           INITIALIZATION                            * 10400019
*                                                                     * 10500019
*********************************************************************** 10600019
         SAVE  (14,12),,IHKTAB-11/17/69                                 10700019
         LR    R11,R15                                                  10800019
         USING IHKTAB,R11                                               10900019
         L     R3,0(R1)                                                 11000019
         USING TUBDSECT,R3                                              11100019
         L     R6,4(R1)                      GET ADDR OF AVT            11200019
         USING AVTDSECT,R6                                              11300019
         L     R1,IHKYYGML                                              11400019
         LA    R2,72                    INDICATE SAVE AREA SPACE NEEDED 11500019
         LA    R4,TUBPARM1                                              11600019
         GETMAIN  EC,LV=(R2),A=(R4),MF=(E,(1))                          11700019
         LTR   R15,R15                                                  11800019
         BZ    INITIAL                  IF NO ERROR, INITIALIZE TAB     11900019
         LA    R15,EIGHT                LOAD GETMAIN FAILURE CODE       12000019
         ST    R15,16(R13)              STORE RETURN CODE               12100019
         B     TABRET                   END TAB                         12200019
INITIAL  DS    0H                                                       12300019
         L     R12,TUBPARM1             SECURE SAVE AREA ADDRESS        12400019
         ST    R12,8(R13)               LINK WITH HIGH ROUTINE          12500019
         ST    R13,4(R12)               LINK WITH HIGH ROUTINE          12600019
         LR    R13,R12                  SET SAVE AREA ADDRESS           12700019
         L     R2,TUBUFFAD              INITLZ REG 2 WITH USER BFR ADDR 12800019
         USING WKDSECT,R2                                               12900019
         MVC   WKAREA(1),ZERO           INITLZ BFR WITH ZEROS           13000019
         MVC   WKAREA+1(36),WKAREA                                      13100019
         XR    R10,R10                                                  13200019
         L     R4,TUBPPTAD                                              13300019
         USING PPTDSECT,R4                                              13400019
         LA    R7,TSTERR                IF NO OPERAND, TEST FOR ERRORS  13500019
         BAL   R14,PPTFIRST             FIND FIRST OPERAND              13600019
         B     OPNDCNTR                 BEGIN TESTING OPERAND           13700019
 EJECT                                                                  13800019
*********************************************************************** 13900019
*                                                                     * 14000019
*                          OPERAND CHECKING                           * 14100019
*                                                                       14200019
*********************************************************************** 14300019
OPNDNEXT DS 0H                                                          14400019
         LA    R7,TSTERR                IF NO OPND, TEST FOR ERRORS     14500019
         BAL   R14,PPTNEXT              FIND NEXT OPERAND               14600019
OPNDCNTR LA    R10,1(0,R10)             INCREMENT OPERAND COUNTER       14700019
         TM    SWITCH,SPARENS           TEST FOR PARENS OUTSTANDING     14800019
         BO    OPNDCHK                  PARENS OUTSTANDING, SKIP EXCESS 14900019
         CH    R10,TWO                  TEST FOR OPND CNT MORE THAN 2   15000019
         BH    ERR334                   IF MORE THAN 2,EXCESSIVE OPND   15100019
OPNDCHK  LA    R7,OPNDNEXT              IF PARENS, FIND NEXT OPND       15200019
         BAL   R14,PARENCHK             CHECK FOR PARENS                15300019
         CLC   OFF,0(R5)                TEST FOR OFF OPERAND            15400019
         BE    SETOFF                                                   15500019
         TM    1(R5),MSKF0              TEST FOR NUMERICAL OPERAND      15600019
         BO    SETNUM                                                   15700019
         TM    SWITCH,MSKINOUT          TEST FOR PRIOR IN/OUT OPND      15800019
         BM    INOUT321                 TEST FOR MULTI/CONTRA OPND      15900019
         BAL   R14,INOUTEST             TEST FOR INPUT OR OUTPUT        16000019
         TM    SWITCH,MSKINOUT          TEST FOR DETECTION OF IN/OUT    16100019
         BM    OPNDNEXT                 IF IN/OUT FOUND, CHECK NEXT     16200019
OPNDNVLD LA    R7,OPNDNEXT              PROVIDE ROUTING AFTER MSG       16300019
         B     ERR302                   INVALID OPERAND                 16400019
SETOFF   TM    SWITCH,MSKOFF            TEST FOR PREVIOUS OFF OPND      16500019
         LA    R7,OPNDNEXT              PROVIDE ROUTING AFTER MSG       16600019
         BO    ERR321                   IF SO, MULTI OPND               16700019
         OI    SWITCH,MSKOFF            SET OFF INDICATOR               16800019
         B     OPNDNEXT                 POINT TO NEXT OPND              16900019
SETNUM   TM    SWITCH,MSKOFF            TEST FOR PREVIOUS OFF OPND      17000019
         BO    OPNDNVLD                 IF SO, ERROR                    17100019
         OI    SWITCH,MSKNUM            SET NUM INDICATOR               17200019
         TM    SWITCH,MSKINOUT          TEST FOR IN/OUT OPND            17300019
         BM    TSTERR                   IF IN/OUT, TEST FOR ERRORS      17400019
         B     PPTNEXT3                                                 17500019
PPTNEXT2 LA    R7,PPTNEXT4              IF NO OPND, POINT TO FIRST OPND 17600019
         BAL   R14,PPTNEXT              FIND THE NEXT OPERAND           17700019
PPTNEXT3 LA    R7,PPTNEXT2              IF PARENS, RETURN FOR NEXT OPND 17800019
         BAL   R14,PARENCHK             CHECK FOR PARENS                17900019
         BAL   R14,INOUTEST             TEST FOR IN OR OUT OPND         18000019
         TM    SWITCH,MSKINOUT          TEST FOR IN OR OUT OPND FOUND   18100019
         BZ    PPTNEXT2                 IF NOT FOUND, FIND NEXT OPND    18200019
         LR    R9,R5                    RETAIN ADDRESS OF IN OR OUT OPD 18300019
         LA    R14,ERR334               IF OPND IS FOUND, EXCESSIVE OPD 18400019
         BAL   R7,PPTNEXT               TEST FOR NEXT OPERAND           18500019
         OI    0(R9),HEXFF              IF NO OPND, DROP IN OR OUT OPND 18600019
PPTNEXT4 L     R4,TUBPPTAD              OBTAIN ADDRESS OF FIRST PPT     18700019
         LA    R7,TABEND                IF NO FIRST OPND, TERMINATE     18800019
         BAL   R14,PPTFIRST             POINT TO FIRST OPERAND          18900019
 EJECT                                                                  19000019
*********************************************************************** 19100019
*                                                                       19200019
*                      OPERARION DETERMINATION                        * 19300019
*                                                                     * 19400019
*********************************************************************** 19500019
TSTERR   TM    SWITCH,SERROR            HAS ERROR OCCURED               19600019
         BO    TABEND                   IF ERROR, END                   19700019
         XR    R7,R7                                                    19800019
         IC    R7,SWITCH                                                19900019
         B     *+4(R7)                  BRANCH ACCORDING TO FLAGS       20000019
         B     OFFIN                    NO OPERANDS                     20100019
         B     OFFIN                    IN OPERAND                      20200019
         B     OFFOUT                   OUT OPERAND                     20300019
         B     TABEND                   IN AND OUT OPERANDS             20400019
         B     OFFIN                    OFF OPERAND                     20500019
         B     OFFIN                    OFF AND IN OPERANDS             20600019
         B     OFFOUT                   OFF AND OUT OPERANDS            20700019
         B     TABEND                   OFF AND IN AND OUT OPERANDS     20800019
         B     NUMIN                    NUMBER OPERAND                  20900019
         B     NUMIN                    NUMBER AND IN OPERANDS          21000019
         B     NUMOUT                   NUMBER AND OUT OPERANDS         21100019
 EJECT                                                                  21200019
*********************************************************************** 21300019
*                                                                     * 21400019
*                 INPUT AND OUTPUT TAB OFF OPERATION                  * 21500019
*                                                                     * 21600019
*********************************************************************** 21700019
OFFIN    L     R12,TUBTABAD             OBTAIN ADDRESS OF INPUT TABS    21800019
         MVC   TUBTABAD,ZERO            ZERO TAB ADDRESS                21900019
         B     OFFOUT1                                                  22000019
OFFOUT   L     R12,TUBOUTAB             OBTAIN ADDRESS OF OUTPUT TABS   22100019
         MVC   TUBOUTAB,ZERO            ZERO TAB ADDRESS                22200019
OFFOUT1  LTR   R12,R12                  TEST FOR ZERO ADDRESS           22300019
         BZ    TABEND                   IF ZERO, END                    22400019
         FREEMAIN  R,LV=16,A=(12)       FREE THE TAB AREA               22500019
         B     TABEND                                                   22600019
 EJECT                                                                  22700019
*********************************************************************** 22800019
*                                                                     * 22900019
*             INPUT AND OUTPUT TAB SETTING EVALUATION                 * 23000019
*                                                                     * 23100019
*********************************************************************** 23200019
NUMIN    DS    0H                                                       23300019
NUMOUT   DS    0H                                                       23400019
         XR    R10,R10                                                  23500019
ADDCNT   LA    R10,1(0,R10)             ADD TO OPND COUNTER             23600019
         CL    R10,TEN                  TEST FOR LIMIT OF TEN NUM OPND  23700019
         LA    R7,ENDPPT                PROVIDE ROUTING AFTER MSG       23800019
         BH    ERR334A                  IF MORE THAN TEN, ERROR         23900019
         TM    0(R5),MSK3C              TEST FOR OPND LNG MORE THAN 3   24000019
         BM    ERR302A                  LNG MORE THAN 3, ERROR          24100019
TSTNUM   LR    R1,R5                    R1 WIL POINT TO CHARACTERS      24200019
         XR    R7,R7                                                    24300019
         IC    R7,0(R5)                 OBTAIN OPND LNG                 24400019
         XR    R8,R8                                                    24500019
NEXTNUM  LA    R1,1(0,R1)               POINT TO NEXT OPND POSITION     24600019
         SLL   R8,8                     MAKE ROOM FOR NEXT CHARACTER    24700019
         IC    R8,0(R1)                 INSERT CHARACTER                24800019
         TM    0(R1),MSKF0              TEST FOR NUMERIC OPND           24900019
         BNO   ERR302A                  NOT NUMERIC, ERROR              25000019
         BCT   R7,NEXTNUM               TEST NEXT OPND CHARACTER        25100019
         ST    R8,PREPAC                STORE TESTED OPND               25200019
         PACK  WKPAC(8),PREPAC(4)       PACK OPERAMD                    25300019
         CVB   R8,WKPAC                 CONVERT OPND TO BINARY          25400019
         CH    R8,TWO                   TEST FOR OPND GREATER THAN 1    25500019
         LA    R7,TSTLST                PROVIDE ROUTING AFTER MSG       25600019
         BL    ERR302B                  IF LESS THAN 2, ERROR           25700019
         TM    SWITCH,MSKOUT            TEST FOR OUTPUT TABS            25800019
         BO    OUTLIMIT                 OUTPUT TABS, TEST FOR 120       25900019
         CH    R8,EIGHTY                TEST FOR INPUT LIMIT OF 80      26000019
         BH    ERR381                   IF MORE THAN 80, ERROR          26100019
         B     STORENUM                 STORE GOOD NUMBER               26200019
OUTLIMIT CH    R8,ONETWNTY              TEST FOR OUTPUT LIMIT OF 120    26300019
         BH    ERR381                   MORE THAN 120, ERROR            26400019
STORENUM DS    0H                                                       26500019
         STC   R8,TEMPTAB+1(R10)        MOVE OPND TO TEMP AREA          26600019
CHECKSEQ CH    R10,ONE                  IS THIS THE FIRST OPND          26700019
         BE    SAVTAB                   IF FIRST, SAVE TAB OPND         26800019
         CLR   R8,R9                    TEST SEQUENC2NG OF OPND         26900019
         BNH   ERRSEQ                   IF NOT SEQUENCED, ERROR         27000019
SAVTAB   LR    R9,R8                    SAVE OPND FOR NEXT SEQ TEST     27100019
TSTLST   LA    R14,ADDCNT               IF OPERAND, RETURN TO CHK OPND  27200019
         BAL   R7,PPTNEXT               FIND NEXT OPERAND               27300019
ENDPPT   TM    SWITCH,SERROR            TEST FOR PREVIOUS ERROR         27400019
         BO    TABEND                   PRIOR ERROR, END                27500019
 EJECT                                                                  27600019
*********************************************************************** 27700019
*                                                                     * 27800019
*                      STORING THE TAB SETTINGS                       * 27900019
*                                                                     * 28000019
*********************************************************************** 28100019
STORTAB  LTR   R10,R10                  TEST FOR NO NUMBERS             28200019
         BZ    TABEND                   NO NUMBERS, END                 28300019
         STH   R10,TEMPTAB              STORE TAB COUNT IN TEMP AREA    28400019
         TM    SWITCH,MSKOUT            TEST FOR OUTPUT TABS            28500019
         BO    STORTAB1                 OUTPUT TABS, USE TUBOUTAB       28600019
         L     R12,TUBTABAD             INPUT TABS, USE TUBTABAD        28700019
         B     STORTAB2                                                 28800019
STORTAB1 L     R12,TUBOUTAB             OUTPUT TABS, USE TUBOUTAB       28900019
STORTAB2 LTR   R12,R12                  TEST FOR ZERO ADDRESS           29000019
         BNZ   STTAB1                   NOT ZERO SET TABS               29100019
         LA    R0,16                    PROVIDE COUNT OF TABLE SIZE     29200019
GETTAB   GETMAIN   EC,LV=(R0),A=(R1)    OBTAIN TAB TABLE AREA           29300019
         LTR   R15,R15                  TEST FOR SUCCESS OF GETMAIN     29400019
         BZ    STTAB                    NO FAILURE, SET TABS            29500019
         LA    R15,EIGHT                SET RTRN CODE FOR GETMAIN FAIL  29600019
         B     TABEND1                  END TAB                         29700019
STTAB    L     R12,0(R1)                LOAD TAB TABLE ADDRESS          29800019
         USING TABDSECT,R12                                             29900019
STTAB1   MVC   TABAREA(16),TEMPTAB      SET TABS                        30000019
         DROP  R12                                                      30100019
         TM    SWITCH,MSKOUT            TEST FOR OUTPUT TABS            30200019
         BO    STTAB2                   IF OUTPUT, SET OUTPUT TAB ADD   30300019
         ST    R12,TUBTABAD             IF INPUT, SET INPUT TAB ADDRES  30400019
         B     TABEND                                                   30500019
STTAB2   ST    R12,TUBOUTAB             SET OUTPUT TAB ADDRESS          30600019
 EJECT                                                                  30700019
*********************************************************************** 30800019
*                                                                     * 30900019
*                             TERNIMATION                               31000019
*                                                                     * 31100019
*********************************************************************** 31200019
TABEND   XR    R15,R15                  SET RTRN CODE TO ZERO           31300019
TABEND1  L     R12,4(R13)               OBTAIN HIGH ROUTIN SAVE AREA AD 31400019
         ST    R15,16(R12)              SET RETURN CODE                 31500019
         FREEMAIN R,LV=72,A=(13)                                        31600019
         LR    R13,R12                  SET HIGH SAVE AREA ADDRESS      31700019
TABRET   RETURN (14,12),T               RETURN                          31800019
 EJECT                                                                  31900019
*********************************************************************** 32000019
*                                                                     * 32100019
*                                                                     * 32200019
*                             SUBROUTINES                             * 32300019
*                                                                     * 32400019
*                                                                       32500019
*********************************************************************** 32600019
 SPACE 3                                                                32700019
*********************************************************************** 32800019
*                                                                     * 32900019
*                   INPUT AND OUTPUT OPERAND CHECK                    * 33000019
*                                                                     * 33100019
*********************************************************************** 33200019
INOUTEST CLC   IN,0(R5)                 TEST FOR IN OPND                33300019
         BE    SETIN                                                    33400019
         CLC   INPUT,0(R5)              TEST FOR INPUT OPND             33500019
         BE    SETIN                                                    33600019
         CLC   OUT,0(R5)                TEST FOR OUT OPND               33700019
         BE    SETOUT                                                   33800019
         CLC   OUTPUT,0(R5)             TEST FOR OUTPUT OPND            33900019
         BE    SETOUT                                                   34000019
         BR    R14                                                      34100019
SETIN    OI    SWITCH,MSKIN             SET IN FLAG                     34200019
         BR    R14                                                      34300019
SETOUT   OI    SWITCH,MSKOUT            SET OUT FLAG                    34400019
         BR    R14                                                      34500019
         SPACE                                                          34600019
*********************************************************************** 34700019
*                                                                     * 34800019
*           MULTI/CONTRA USE OF INPUT/OUTPUT OPERAND CHECKER          * 34900019
*                                                                     * 35000019
*********************************************************************** 35100019
INOUT321 CLC   IN,0(R5)                 TEST FOR IN OPND                35200019
         BE    ERR321                   MULTI OR CONTRA OPND            35300019
         CLC   INPUT,0(R5)              TEST FOR INPUT OPND             35400019
         BE    ERR321                   MULTI OR CONTRA OPND            35500019
         CLC   OUT,0(R5)                TEST FOR OUT OPND               35600019
         BE    ERR321                   MULTI OR CONTRA OPND            35700019
         CLC   OUTPUT,0(R5)             TEST FOR OUTPUT OPND            35800019
         BE    ERR321                   MULTI OR CONTRA OPND            35900019
         B     OPNDNVLD                 OPND INVALID                    36000019
 EJECT                                                                  36100019
*********************************************************************** 36200019
*                                                                     * 36300019
*                        ERROR MESSAGES                               * 36400019
*                                                                     * 36500019
*********************************************************************** 36600019
ERR381   BCT   R10,ERR381A                                              36700019
ERR381A  LA    R7,STORTAB               PROVIDE ROUTING AFTER MSG       36800019
         LA    R1,MSG381                PROVIDE MSG CODE                36900019
         ST    R1,TUBPARM3                                              37000019
         OI    TUBPARM3,HEX80           SET LAST PARAM FLAG             37100019
         B     MSGWTR1                  CALL MSG WTR                    37200019
ERRSEQ   LA    R7,TABEND                PROVIDE ROUTING AFTER MSG       37300019
         LA    R1,MSGSEQ                PROVIDE MSG WTR                 37400019
         ST    R1,TUBPARM3                                              37500019
         OI    TUBPARM3,HEX80           SET LAST PARAM FLAG             37600019
         B     MSGWTR1                  CALL MSG WTR                    37700019
ERR302A  LA    R7,TSTLST                PROVIDE ROUTING AFTER MSG       37800019
ERR302   OI    SWITCH,SERROR            SET ERROR SWITCH                37900019
         B     ERR302C                                                  38000019
ERR302B  BCT   R10,ERR302C              DECRIMENT NUM COUNT BY ONE      38100019
ERR302C  LA    R1,MSG302                PROVIDE MSG CODE                38200019
         B     MSGNSRT                  INSERT OPERAND                  38300019
ERR334   LA    R7,TABEND                AFTER MSG, TERMINATE            38400019
ERR334A  BCT   R10,ERR334B              DECRIMENT NUM COUNT             38500019
ERR334B  LA    R1,MSG334                PROVIDE MSG CODE                38600019
         B     MSGNSRT                  INSERT OPND                     38700019
ERR321   OI    SWITCH,SERROR            SET ERROR SWITCH                38800019
         LA    R1,MSG321                PROVIDE MSG CODE                38900019
 EJECT                                                                  39000019
*********************************************************************** 39100019
*                                                                     * 39200019
*                           MESSAGE INSERTS                           * 39300019
*                                                                     * 39400019
*********************************************************************** 39500019
MSGNSRT  NI    0(R5),MSK3F              PROTECTION FROM PARENS          39600019
         ST    R1,TUBPARM3                                              39700019
         XR    R8,R8                                                    39800019
         IC    R8,0(R5)                 OBTAIN OPND LNG                 39900019
         CLI   0(R5),MAXNSRT            TEXT FOR TOO GREAT A LENGTH     40000019
         BNH   MSGNSRT1                 RETAIN LENGTH IF ACCEPTABLE     40100019
         MVI   0(R5),MAXNSRT            IF TOO BIG, SET TO MAXIMUN      40200019
MSGNSRT1 ST    R5,TUBPARM4              PROVIDE POINTER TO OPND         40300019
         OI    TUBPARM4,HEX80           SET LAST PARAM FLAG             40400019
 EJECT                                                                  40500019
*********************************************************************** 40600019
*                                                                     * 40700019
*              CALL TO MESSAGE WRITER FOR USER MESSAGES               * 40800019
*                                                                     * 40900019
*********************************************************************** 41000019
MSGWTR1  ST    R3,TUBPARM1              PROVIDE ADDRESS OF TUB          41100019
         LA    R1,TUBUSRID              PROVIDE POINTER TO USERID       41200019
         ST    R1,TUBPARM2                                              41300019
         LA    R1,TUBPRMLS              PROVIDE POINTER TO PARM LIST    41400019
         L     R15,IHKYMSG1             ADDRESS OF MSG WTR              41500019
         BALR  R14,R15                  WRITE MESSAGE TO USER           41600019
         STC   R8,0(R5)                 RESTORE OPERAND LENGTH          41700019
         LTR   R15,R15                  TEST RETURN CODE                41800019
         BZ    0(R7)                    IF ZERO, RETURN AS DIRECTED     41900019
         B     TABEND1                  IF ERROR, END                   42000019
 EJECT                                                                  42100019
*********************************************************************** 42200019
*                                                                     * 42300019
*           ADVANCE OPERAND POINTER TO NEXT OPERAND OF PPT            * 42400019
*                                                                     * 42500019
*********************************************************************** 42600019
PPTFIRST LA    R5,PPTPARS               POINT TO THE FIRST PARAM OF PPT 42700019
         B     PPTLAST                  CHECK FOR LAST PARAMETER        42800019
PPTNEXT  XR    R1,R1                                                    42900019
         NI    0(R5),MSK3F              PROTECTION FROM PAREN FLAGS     43000019
         IC    R1,0(R5)                 OBTAIN LENGTH                   43100019
         LA    R5,1(R1,R5)              POINT TO THE NEXT PARAM IN PPT  43200019
PPTLAST  CLI   0(R5),HEXFF              TEST FOR LAST PARAM OF PPT      43300019
         BNE   0(R14)                   BRANCH FOR OPERAND FOUND        43400019
         CLC   PPTCHAD+1(3),ZERO        TEST FOR NO CHAINING ADDRESS    43500019
         BE    0(R7)                    BRANCH FOR LAST OPERAND         43600019
         L     R4,PPTCHAD               POINT TO THE FIRST PARAM OF PPT 43700019
         B     PPTFIRST                 POINT TO FIRST PARAM NEXT PPT   43800019
 EJECT                                                                  43900019
*********************************************************************** 44000019
*                                                                     * 44100019
*                         PAREN ERROR CHECKER                         * 44200019
*                                                                     * 44300019
*********************************************************************** 44400019
PARENCHK TM    0(R5),PARENS             CHECK FOR OPND IN PARENS        44500019
         BZ    0(R14)                   IF NO PARENS, RETURN            44600019
         TM    0(R5),PARENS                                             44700019
         BO    PARENLST                 LAST PAREN OPND, TEST FOR MSG   44800019
         NI    0(R5),MSK3F              CLEAR PAREN FLAGS               44900019
         TM    SWITCH,SPARENS           TEST FOR PRIOR MSG SENT         45000019
         BO    PARENOUT                 IF MSG SENT, DECREACE CNT & RTN 45100019
         OI    SWITCH,SPARENS           SET SWITSH FOR PAREN ERROR MSG  45200019
         B     ERR302                   SEND INVALIN OPND ERROR MSG     45300019
PARENLST NI    0(R5),MSK3F              CLEAR THE PAREN FLAGS           45400019
         TM    SWITCH,SPARENS           TEST FOR PRIOR MSG SENT         45500019
         BZ    ERR302                   IF NOT, SEND ERROR MSG          45600019
         XI    SWITCH,SPARENS           TURN OFF THR PAREN ERROR SWITCH 45700019
PARENOUT BCT   R10,0(R7)                DECREASE OPND CNT BY ONE        45800019
         BR    R7                       RETURN TO CALLING POINT         45900019
         EJECT                                                          46000019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46100019
*                            EQUATES                                  * 46200019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 46300019
HEXFF    EQU   X'FF'                                                    46400019
MSKF0    EQU   X'F0'                                                    46500019
PARENS   EQU   X'C0'                    CHK IF OPND IS IN PARENTHESIS   46600019
MSK3F    EQU   X'3F'                                                    46700019
HEX80    EQU   X'80'                                                    46800019
EIGHT    EQU   8                                                        46900019
MSK3C    EQU   X'3C'                                                    47000019
MSKIN    EQU   X'04'                    MASK TO TEST IN                 47100019
MSKOUT   EQU   X'08'                    MASK TO TEST OUT                47200019
MSKINOUT EQU   X'0C'                    MASK TO TEST IN OR OUT          47300019
MSKOFF   EQU   X'10'                    MASK TO TEST OFF                47400019
MSKNUM   EQU   X'20'                    MASK TO TEST NUMBER OPERANDS    47500019
MAXNSRT  EQU   10                                                       47600019
         SPACE                                                          47700019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 47800019
*                          CONSTANTS                                  * 47900019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 48000019
         SPACE                                                          48100019
         DS    0D                                                       48200019
TABAD    DC    F'0'                                                     48300019
ZERO     DC    F'0'                                                     48400019
         DS    0D                                                       48500019
TEN      DC    F'10'                                                    48600019
EIGHTY   DC    XL2'00050'                                               48700019
ONETWNTY DC    XL2'0078'                                                48800019
ONE      DC    XL2'0001'                                                48900019
TWO      DC    XL2'0002'                                                49000019
OFF      DC    X'03D6C6C6'              TEST FOR OFF OPND               49100019
IN       DC    X'02C9D5'                TEST FOR IN OPND                49200019
INPUT    DC    X'05C9D5D7E4E3'          TEST FOR INPUT OPND             49300019
OUT      DC    X'03D6E4E3'              TEST FOR OUT                    49400019
OUTPUT   DC    X'06D6E4E3D7E4E3'        TEST FOR OUTPUT                 49500019
         SPACE                                                          49600019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 49700019
*                  MESSAGE NUMBER CONSTANTS                           * 49800019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 49900019
         SPACE                                                          50000019
         DS    0F                                                       50100019
MSG302   DC    X'00F3F0F2'              INVALID OPERAND                 50200019
MSG321   DC    X'00F3F2F1'              MULTI/CONTRA OPERAND            50300019
MSG334   DC    X'00F3F3F4'              EXCESSIVE OPERAND               50400019
MSG381   DC    X'00F3F8F1'              EXCEED TAB LIMITS               50500019
MSGSEQ   DC    X'00F3F8F2'              TABS NOT IN ASCENDING ORDER     50600019
         EJECT                                                          50700019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 50800019
*                            DSECTS                                   * 50900019
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * 51000019
         SPACE                                                          51100019
         SPACE                                                          51200019
*                 DSECT FOR WORK AREA IN USER BUFFER                 *  51300019
         SPACE                                                          51400019
WKDSECT  DSECT                                                          51500019
         DS    CL88                                                     51600019
WKAREA   DS    0CL37                                                    51700019
WKPAC    DS    CL8                                                      51800019
PREPAC   DS    F                                                        51900019
TEMPTAB  DS    CL16                                                     52000019
SWITCH   DS    C                                                        52100019
SPARENS  EQU   X'01'                    SWITCH FOR PAREN ERROR MSG SENT 52200019
SERROR   EQU   X'80'                                                    52300019
SERRORF  EQU   X'7F'                                                    52400019
         EJECT                                                          52500019
*                           DSECT FOR TAB BUFFER                      * 52600019
         SPACE                                                          52700019
TABDSECT DSECT                                                          52800019
         DS    0F                                                       52900019
TABAREA  DS    CL16                                                     53000019
         SPACE                                                          53100019
*                        DSECT FOR TUB, PPT, AND AVT                  * 53200019
         SPACE                                                          53300019
         IHKCDSCT TUB=YES,PPT=YES,AVT=YES                               53400019
         END                                                            53500019
