UTM      TITLE 'IHKUTM - USER VERIFICATION FILE MANAGER'                00200019
IHKUTM   CSECT                                                          00400019
*********************************************************************** 00600019
*                                                                     * 00800019
*STATUS:                                                              * 01000019
*   CHANGE LEVEL 0                                                    * 01200019
*                                                                     * 01400019
*FUNCTION:                                                            * 01600019
*   THE ROUTINE IS CALLED TO VERIFY THE USERID AND TO PERFORM CERTAIN * 01800019
*   FUNCTIONS AS REQUESTED BY THE FOLLOWING REQUEST CODES:            * 02000019
*   1.X'80' - ENQUEUE FOR LIBRARY I/O. ALSO, DETERMINE WHETHER OR     * 02200019
*     NOT THE USER'S LIBRARY IS INOPERATIVE, PLACE THE USERID IN      * 02400019
*     TUBUSRNM, AND PLACE THE DDNAME IN THE KONBOX.                   * 02600019
*   2.X'40' - TEST ACTIVE BIT IN CONTROL BYTE OF USER VERIFICATION    * 02800019
*     RECORD (UVR)                                                    * 03000019
*   3.X'60' - TEST ACTIVE BIT IN UVR, AND IF NOT SET, SET THE BIT     * 03200019
*     ON. SET TUBMSG AND TUBLMSGN IN THE TUB TO CORRESPOND TO         * 03400019
*     UVRDMSG AND UVRLMSGN IN UVR, RESPECTIVELY. PUT TUB SEQUENCE     * 03600019
*     NUMBER IN UVR, AND PUT PASSWORD AND CONSOLE ID'S IN THE TUB.    * 03800019
*   4.X'10' - TURN OFF ACTIVE BIT IN UVR. SET UVRDMSG AND UVRLMSGN    * 04000019
*     IN UVR TO CORRESPOND TO TUBMSG AND TUBLMSGN IN TUB, RESPEC-     * 04200019
*     TIVELY. CLEAR UVRLNSEQ FIELD AND PUT CONSOLE ID'S IN TUB.       * 04400019
*   5.X'18' - SET ABNORMAL TERMINATION BIT IN UVR AND PERFORM ALL     * 04600019
*     FUNCTIONS UNDER 4.                                              * 04800019
*   6.X'04' - SET LIBRARY INOPERATIVE BIT IN CONTROL BYTE OF UVR.     * 05000019
*                                                                     * 05200019
*ENTRY POINTS:                                                        * 05400019
*   IHKUTM IS THE ONLY ENTRY POINT.                                   * 05600019
*                                                                     * 05800019
*INPUT:                                                               * 06000019
*   INPUT IS THE FOLLOWING PARAMETER LIST ADDRESSED BY REGISTER 1:    * 06200019
*   (1) ADDRESS OF THE TUB.                                           * 06400019
*   (2) ADDRESS OF ONE BYTE REQUEST CODE.                             * 06600019
*                                                                     * 06800019
*OUTPUT:                                                              * 07000019
*   FOR THE REQUEST CODE X'60',X'10', OR X'18', THE FOLLOWING         * 07200019
*   INFORMATION IS RETURNED IN THE TUB:                               * 07400019
*   (1) TUBPARM3 CONTAINS THE CONSOLE ID'S SPECIFIED IN UVRCID1,      * 07600019
*       UVRCID2, AND UVRCID3                                          * 07800019
*   (2) TUBPARM4 AND TUBPARM5 CONTAIN THE PASSWORD FROM UVRPASSW      * 08000019
*                                                                     * 08200019
*EXTERNAL REFERENCES:                                                 * 08400019
*        IHKRNQ - TO ENQUEUE FOR LIBRARY I/O.                         * 08600019
*        IHKAFI - TO MANIPULATE GLOBAL FILES.                         * 08800019
*                                                                     * 09000019
*EXITS,NORMAL:                                                        * 09200019
*   RETURN BY REGISTER 14 TO THE CALLING ROUTINE WITH A ZERO IN       * 09400019
*   REGISTER 15.                                                      * 09600019
*                                                                     * 09800019
*EXITS,ERROR:                                                         * 10000019
*   RETURN BY REGISTER 14 TO THE CALLING ROUTINE WITH ONE OF THE      * 10200019
*   FOLLOWING CODES IN REGISTER 15:                                   * 10400019
*   4 - USERID NOT FOUND                                              * 10600019
*   8 - GETMAIN FAILED                                                * 10800019
*   12- AFIO I/O ERROR                                                * 11000019
*   16- DDNAME BLANK                                                  * 11200019
*   20- USERID ACTIVE                                                 * 11400019
*   24- LIBRARY INOPERATIVE                                           * 11600019
*                                                                     * 11800019
*TABLES/WORK AREAS:                                                   * 12000019
*   18 WORD SAVE AREA                                                 * 12200019
*   TUB                                                               * 12400019
*        TUBAFISW - BUFFER CONTROL SWITCH                             * 12600019
*        TUBGBLKY - CONTAINS KEY FOR AFIO; SET BY CALLER.             * 12800019
*        TUBUSRNM - SET EQUAL TO TUBGBLKY ON REQUEST X'80'            * 13000019
*        TUBPARM4 - SET EQUAL TO UVRPASSW ON REQUEST X'60'            * 13200019
*        TUBPARM3 - SET EQUAL TO UVRCID1-UVRCID3 ON REQUESTS X'60'    * 13400019
*                   AND X'10'                                         * 13600019
*        TUBLNSEQ - CONTAINS TUB SEQUENCE NUMBER.                     * 13800019
*        TUBMSG   - TESTED OR SET, AS REQUESTED                       * 14000019
*        TUBLMSGN - TESTED OR SET, AS REQUESTED                       * 14200019
*   KONBOX                                                            * 14400019
*        BBPARMFS - DDNAME SET EQUAL TO UVRDDNAM ON REQUEST X'80'.    * 14600019
*   UVR                                                               * 14800019
*        UVRACTVN - ACTIVE BIT                                        * 15000019
*        UVBABTM1 - ABNORMAL TERMINATION BIT                          * 15200019
*        UVRDDNAM - DDNAME                                            * 15400019
*        UVRDMSG  - TESTED OR SET, AS REQUESTED                       * 15600019
*        UVRLMSGN - TESTED OR SET, AS REQUESTED                       * 15800019
*        UVRLIBIN - TESTED OR SET, AS REQUESTED                       * 16000019
*        UVRLNSEQ - SET EQUAL TO TUBLNSEQ OR CLEARED TO ZEROS, AS     * 16200019
*                   REQUESTED                                         * 16400019
*                                                                     * 16600019
*ATTRIBUTES:                                                          * 16800019
*   REENTRANT AND RESIDENT                                            * 17000019
*                                                                     * 17200019
*NOTES:                                                               * 17400019
*   THE OPERATION OF THIS MODULE DEPENDS UPON AN INTERNAL             * 17600019
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET WHICH IS             * 17800019
*   EQUIVALENT TO THE ONE USED AT ASSEMBLY TIME. THE CODING           * 18000019
*   HAS BEEN ARRANGED SO THAT THE REDEFINITION OF 'CHARACTER'         * 18200019
*   CONSTANTS, BY REASSEMBLY, WILL RESULT IN A CORRECT MODULE         * 18400019
*   FOR THE NEW DEFINITIONS.                                          * 18600019
*                                                                     * 18800019
*********************************************************************** 19000019
         EJECT                                                          19200019
*        REGISTER EQUATES                                               19400019
         SPACE                                                          19600019
REG0     EQU   0                        SYSTEM REGISTER                 19800019
REG1     EQU   1                        POINTER TO PARM LIST            20000019
REG2     EQU   2                        CONTAINS RETURN CODE            20200019
REG3     EQU   3                        WORK REGISTER                   20400019
REG4     EQU   4                        WORK REGISTER                   20600019
REG5     EQU   5                        WORK REGISTER                   20800019
REG6     EQU   6                        WORK REGISTER                   21000019
UVRREG   EQU   7                        POINTER TO UVR                  21200019
PARM     EQU   8                        POINTER TO REQUEST CODE         21400019
KBXRG    EQU   9                        POINTER TO KONBOX               21600019
AVTREG   EQU   10                       POINTER TO AVT                  21800019
BASEREG  EQU   11                       BASE REGISTER                   22000019
TUBREG   EQU   12                       POINTER TO THE TUB              22200019
REG13    EQU   13                       POINTER TO SAVE AREA            22400019
BRANCH   EQU   14                       RETURN POINT                    22600019
RETREG   EQU   15                       ENTRY POINT                     22800019
         SPACE 2                                                        23000019
*        NUMERIC EQUATES                                                23200019
         SPACE 1                                                        23400019
ZERO     EQU   0                                                        23600019
ONE      EQU   1                                                        23800019
TWO      EQU   2                                                        24000019
THREE    EQU   3                                                        24200019
FOUR     EQU   4                                                        24400019
EIGHT    EQU   8                                                        24600019
TWELVE   EQU   12                                                       24800019
TWENTY   EQU   20                                                       25000019
         SPACE 1                                                        25200019
RC8      EQU   8                        RETURN CODE 8                   25400019
RC16     EQU   16                       RETURN CODE 16                  25600019
RC20     EQU   20                       RETURN CODE 20                  25800019
RC24     EQU   24                       RETURN CODE 24                  26000019
         SPACE                                                          26200019
HEX00    EQU   X'00'                    HEX 00                          26400019
SESS     EQU   X'80'                    SHOW SESSION                    26600019
         SPACE 2                                                        26800019
*        REQUEST CODES FOR IHKUTM                                       27000019
         SPACE 1                                                        27200019
ENQACT   EQU   X'C0'                    ENQUEUE AND VERIFICATION        27400019
ENQUEUE  EQU   X'80'                    ENQUEUE FOR BPAM                27600019
ACT      EQU   X'40'                    CHECK ACTIVE BIT                27800019
ACTON    EQU   X'02'                    TURN ON ACTIVE BIT              28000019
ACTOFF   EQU   X'10'                    TURN OFF ACTIVE BIT             28200019
ABNOR    EQU   X'08'                    TURN ON ABTRM SWITCH            28400019
INOP     EQU   X'04'                    LIBRARY INOPERATIVE             28600019
PASSW    EQU   X'20'                    RETURN PASSWORD                 28700019
         EJECT                                                          28800019
*        SAVE REGISTERS AND SET BASE REGISTER                           29000019
         SPACE 1                                                        29200019
         SAVE  (14,12),,IHKUTM-10/17/69                                 29400019
         LR    BASEREG,RETREG           SET BASE REGISTER               29600019
         USING IHKUTM,BASEREG                                           29800019
         SPACE 1                                                        30000019
         L     PARM,FOUR(REG1)          PARM POINTS TO REQUEST CODE     30200019
         SPACE 2                                                        30400019
*        SET REGISTERS FOR DSECTS                                       30600019
         SPACE 1                                                        30800019
         L     AVTREG,ADDRAVT           ADDRESS OF AVT                  31000019
         USING AVTDSECT,AVTREG                                          31200019
         L     KBXRG,IHKYYKBX           ADDRESS OF KONBOX               31400019
         USING RAFKNBX,KBXRG                                            31600019
         L     TUBREG,ZERO(REG1)        ADDRESS OF TUB                  31800019
         USING TUBDSECT,TUBREG                                          32000019
         L     UVRREG,TUBUFFAD          ADDRESS OF USER BUFFER          32200019
         USING UVRDSECT,UVRREG                                          32400019
*        INITIALIZE TUBRAFBF TO POINT TO USER BUFFER                    32600019
         ST    UVRREG,TUBRAFBF                                          32800019
         SPACE 2                                                        33000019
*        GET STORAGE FOR REENTRANTABILITY                               33200019
         SPACE 1                                                        33400019
         LA    REG3,LEN                 LENGTH                          33600019
         LA    REG5,TUBPARM1            ADDR OF GETMAIN IN TUBPARM1     33800019
         L     REG1,IHKYYGML            ADDRESS OF GETMAIN LIST         34000019
         GETMAIN EC,LV=(3),A=(5),MF=(E,(1))                             34200019
         LTR   RETREG,RETREG            WAS GETMAIN SUCCESSFUL ?        34400019
         BZ    LDGET                    IF YES, SET UP REGISTERS        34600019
         LA    REG2,RC8                 GETMAIN FAILED                  34800019
         B     RETURN                   RETURN TO CALLER                35000019
LDGET    DS    0H                                                       35200019
         LR    REG1,REG13               SAVE CALLER'S REG13 IN REG1     35400019
         L     REG13,TUBPARM1           REG13 POINTS TO GETMAIN AREA    35600019
         USING GETAREA,REG13                                            35800019
         ST    REG1,SAVEAREA+4          SAVE CALLER'S REG13 IN SAVEAREA 36000019
         ST    REG13,EIGHT(REG1)        SAVE REG13 IN CALLER'S SAVEAREA 36200019
         SR    REG2,REG2                INITIALIZE RETURN CODE TO 0     36400019
         EJECT                                                          36600019
*        ISSUE RPOINT WITH RETRIEVAL                                    36800019
         SPACE 1                                                        37000019
PTR      DS    0H                                                       37200019
         MVI   GBLNUMFS,TWO             SET GLOBAL FILE NUMBER          37400019
         BAL   REG4,RAF                 SET UP FOR RAFIO                37600019
         RPOINT B,R,FTYPE=XGBL                                          37800019
         NI    TUBAFISW,TUBFCTLF        RESET OPTIONAL BUFFER CONTROL   38000019
*        TEST RETURN CODE                                               38200019
         B     *+4(RETREG)                                              38400019
         B     SET                      GOOD RETURN                     38600019
         B     SAVE1                    RECORD NOT FOUND                38800019
         B     SAVE2                    GETMAIN FAILED                  39000019
         B     SAVE1                    AFIO I/O ERROR                  39200019
         SPACE 2                                                        39400019
*        TEST REQUEST CODE                                              39600019
         SPACE 1                                                        39800019
SET      DS    0H                                                       40000019
         TM    ZERO(PARM),INOP          LIBRARY INOPERATIVE ?           40200019
         BO    SETINOP                  IF YES, SET BIT IN UVR          40400019
         TM    ZERO(PARM),ACT           CHECK ACTIVE BIT ?              40600019
         BO    CHKACT                   IF YES, GO TO CHECK             40800019
         TM    ZERO(PARM),ACTOFF        TURN OFF ACTIVE BIT ?           41000019
         BO    OFF                      IF YES, TURN OFF ACTIVE BIT     41200019
         B     ENDUP                    OTHERWISE, ISSUE ENDUP          41400019
         SPACE 2                                                        41600019
*        CHECK ACTIVE BIT                                               41800019
         SPACE 1                                                        42000019
CHKACT   DS    0H                                                       42200019
         TM    UVRCNTL1,UVRACTVN        IS USERID ACTIVE ?              42400019
         BO    RET20                    IF YES, SET RETURN CODE TO 20   42600019
         TM    ZERO(PARM),PASSW         RETURN PASSWORD?                42640019
         BZ    CHKAC                    IF NOT, CHECK ACTIVE BIT        42680019
         MVC   TUBPARM4(EIGHT),UVRPASSW PUT PASSWORD INTO TUB           42720019
CHKAC    DS    0H                                                       42760019
         TM    ZERO(PARM),ACTON         TURN ON ACTIVE BIT ?            42800019
         BZ    ENDUP                    IF NOT, CALL ENDUP              43000019
         TM    UVRCNTL1,UVRDMSG         DELAYED MESSAGES (IN UVR) ?     43200019
         BZ    B1                       IF NOT, CHECK FOR MSG LOST      43400019
         OI    TUBFLG1,TUBMSG           SET DELAYED MESSAGES (IN TUB)   43600019
B1       DS    0H                                                       43800019
         TM    UVRCNTL1,UVRLMSGN        MESSAGE LOST (IN UVR) ?         44000019
         BZ    B2                       IF NOT, SET UP PASSWORD         44200019
         OI    TUBFLG2,TUBLMSGN         SET MESSAGE LOST (IN TUB)       44400019
B2       DS    0H                                                       44600019
         OI    UVRCNTL1,UVRACTVN        TURN ON ACTIVE BIT              45000019
         MVC   UVRLNSEQ(TWO),TUBLNSEQ   PUT TUB SEQUENCE NO. INTO UVR   45200019
         MVC   TUBPARM3(UVRMXCON),UVRCID1 PUT CONSOLE ID'S IN TUB       45400019
         TM    UVRCNTL1,UVRSESS         SHOW SESSION FOR USERID ?       45600019
         BZ    REP                      IF NOT, DO NOT SET SESS BIT     45800019
         OI    TUBPARM3,SESS            SET SHOW SESS BIT FOR LOGON     46000019
         B     REP                      REPLACE USER RECORD             46200019
         EJECT                                                          46400019
*        TURN OFF ACTIVE BIT                                            46600019
         SPACE 1                                                        46800019
OFF      DS    0H                                                       47000019
         NI    UVRCNTL1,UVRACTVF        TURN OFF ACTIVE BIT             47200019
         XC    UVRLNSEQ(TWO),UVRLNSEQ   CLEAR TUB SEQUENCE NO. IN UVR   47400019
         TM    TUBFLG1,TUBMSG           DELAYED MESSAGES (IN TUB) ?     47600019
         BZ    B3                       IF NOT, TURN OFF DEL MSG IN UVR 47800019
         OI    UVRCNTL1,UVRDMSG         OTHERWISE, SET DEL MSG IN UVR   48000019
         B     B4                       CHECK FOR MESSAGE LOST          48200019
B3       DS    0H                                                       48400019
         NI    UVRCNTL1,UVRDMSGF        TURN OFF DEL MSG IN UVR         48600019
B4       DS    0H                                                       48800019
         TM    TUBFLG2,TUBLMSGN         MESSAGE LOST (IN TUB) ?         49000019
         BZ    B5                       IF NOT,TURN OFF MSG LOST IN UVR 49200019
         OI    UVRCNTL1,UVRLMSGN        OTHERWISE, SET MSG LOST IN UVR  49400019
         B     B6                       GET CONSOLE ID'S                49600019
B5       DS    0H                                                       49800019
         NI    UVRCNTL1,UVRLMSGF        TURN OFF MSG LOST IN UVR        50000019
B6       DS    0H                                                       50200019
         MVC   TUBPARM3(UVRMXCON),UVRCID1 PUT CONSOLE ID'S IN TUB       50400019
         TM    UVRCNTL1,UVRSESS         SHOW SESSION FOR USERID ?       50600019
         BZ    CA                       IF NOT, DO NOT SET SESS BIT     50800019
         OI    TUBPARM3,SESS            SET SHOW SESS BIT FOR LOGONFF   51000019
CA       DS    0H                                                       51200019
         TM    ZERO(PARM),ABNOR         TURN ON ABTRM SWITCH ?          51400019
         BZ    REP                      IF NOT, GO REPLACE USER RECORD  51600019
         OI    UVRCNTL1,UVRABTM1        TURN ON ABTRM SWITCH IN UVR     51800019
         B     REP                      REPLACE USER RECORD             52000019
         SPACE 2                                                        52200019
*        MARK LIBRARY INOPERATIVE                                       52400019
         SPACE 1                                                        52600019
SETINOP  DS    0H                                                       52800019
         OI    UVRCNTL1,UVRLIBIN        MARK LIBRARY INOPERATIVE        53000019
         SPACE 2                                                        53200019
*        REPLACE FILE RECORD                                            53400019
         SPACE 1                                                        53600019
REP      DS    0H                                                       53800019
         BAL   REG4,RAF                 SET UP FOR RAFIO                54000019
         REPLACE NXK,FTYPE=XGBL                                         54200019
         NI    TUBAFISW,TUBFCTLF        RESET OPTIONAL BUFFER CONTROL   54400019
*        TEST RETURN CODE                                               54600019
         B     *+4(RETREG)                                              54800019
         B     ENDUP                    GOOD RETURN                     55000019
         B     SAVE1                    END OF DATA REACHED             55200019
         B     SAVE2                    GETMAIN FAILED                  55400019
         B     SAVE1                    AFIO I/O ERROR                  55600019
         EJECT                                                          55800019
*        SET UP FOR RAFIO                                               56000019
         SPACE 1                                                        56200019
RAF      DS    0H                                                       56400019
         OI    TUBAFISW,TUBFCTLN        USE OPTIONAL BUFFER CONTROL     56600019
RAF1     DS    0H                                                       56800019
         ST    TUBREG,TUBPARM2          ADDRESS OF TUB                  57000019
         LA    REG1,TUBPARM2            REG1 POINTS TO PARM LIST        57200019
         BR    REG4                     RETURN                          57400019
         SPACE 2                                                        57600019
*        SAVE RETURN CODE                                               57800019
         SPACE 1                                                        58000019
SAVE1    DS    0H                                                       58200019
         LR    REG2,RETREG              SAVE RETURN CODE                58400019
         B     ENDUP                    ISSUE ENDUP MACRO               58600019
         SPACE 2                                                        58800019
RET20    DS    0H                                                       59000019
         LA    REG2,RC20                RETURN CODE 20                  59200019
         SPACE 2                                                        59400019
*        INSURE FOR COMPLETION OF UPDATES                               59600019
         SPACE 1                                                        59800019
ENDUP    DS    0H                                                       60000019
         BAL   REG4,RAF1                SET UP FOR RAFIO                60200019
         ENDUP FTYPE=GBL                                                60400019
         LA    REG3,FOUR                                                60600019
         CLR   RETREG,REG3              COMPARE RETURN CODE TO 4        60800019
*        IF < OR = 4, TEST IHKUTM RETURN CODE                           61000019
         BNH   TEST                                                     61200019
         B     SAVE2                    GETMAIN FAILED OR I/O ERROR     61400019
         SPACE 2                                                        61600019
*        TEST IHKUTM'S RETURN CODE                                      61800019
         SPACE 1                                                        62000019
TEST     DS    0H                                                       62200019
         LTR   REG2,REG2                RETURN CODE = 0 ?               62400019
         BNZ   RESTORE                  IF NOT, RETURN TO CALLER        62600019
         SPACE 1                                                        62800019
         TM    ZERO(PARM),ENQUEUE       WAS ENQUEUE REQUESTED ?         63000019
         BZ    RESTORE                  IF NOT, RETURN TO CALLER        63200019
         EJECT                                                          63400019
*        CHECK LIBRARY INOPERATIVE AND DDNAME                           63600019
         SPACE 1                                                        63800019
         TM    UVRCNTL1,UVRLIBIN        IS LIBRARY INOPERATIVE ?        64000019
         BO    RET24                    IF YES, SEND RETURN CODE 24     64200019
         SPACE 1                                                        64400019
         CLC   UVRDDNAM(ONE),BLANK      IS DDNAME BLANK ?               64600019
         BE    RET16                    IF YES, SET RETURN CODE TO 16   64800019
         SPACE 2                                                        65000019
         MVC   TUBUSRNM(EIGHT),TUBGBLKY PUT USERID INTO TUBUSRNM        65200019
         SPACE 2                                                        65400019
*        ENQUEUE FOR LIBRARY I/O                                        65600019
         SPACE 1                                                        65800019
RNQ      DS    0H                                                       66000019
         LA    REG3,TUBBPQEL            ADDRESS OF QUEUE ELEMENT        66200019
         ST    REG3,TUBPARM2            STORE IN 1ST WORD OF PARM LIST  66400019
         LA    REG3,BPQCTLFW            ADDRESS OF QUEUE CONTROL ELEM   66600019
         ST    REG3,TUBPARM3            STORE IN 2ND WORD OF PARM LIST  66800019
         LA    REG1,TUBPARM2            REG1 POINTS TO PARM LIST        67000019
         L     RETREG,IHKYYRNQ          ADDRESS OF IHKRNQ               67200019
         BALR  BRANCH,RETREG            ENQUEUE                         67400019
         LTR   RETREG,RETREG            WAS ENQUEUE SUCCESSFUL ?        67600019
         BZ    MOVEDDN                  IF YES, MOVE DDNAME             67800019
         LA    REG2,RC8                 GETMAIN FAILED IN IHKRNQ        68000019
         B     RESTORE                  PREPARE TO RETURN TO CALLER     68200019
         SPACE 2                                                        68400019
*        MOVE DDNAME FROM UVR INTO KONBOX                               68600019
         SPACE 1                                                        68800019
MOVEDDN  DS    0H                                                       69000019
         MVC   BPPARMFS(EIGHT),UVRDDNAM                                 69200019
         B     RESTORE                  PREPARE TO RETURN TO CALLER     69400019
         SPACE 2                                                        69600019
*        SAVE RETURN CODE                                               69800019
         SPACE 1                                                        70000019
SAVE2    DS    0H                                                       70200019
         LR    REG2,RETREG              SAVE RETURN CODE                70400019
         B     RESTORE                  PREPARE TO RETURN TO CALLER     70600019
         SPACE 2                                                        70800019
*        SET RETURN CODES                                               71000019
         SPACE 1                                                        71200019
RET16    DS    0H                                                       71400019
         LA    REG2,RC16                DDNAME BLANK                    71600019
         B     RESTORE                  PREPARE TO RETURN TO CALLER     71800019
         SPACE 2                                                        72000019
RET24    DS    0H                                                       72200019
         LA    REG2,RC24                USER LIBRARY INOPERATIVE        72400019
         EJECT                                                          72600019
*        FREE GETMAIN AREA                                              72800019
         SPACE 1                                                        73000019
RESTORE  DS    0H                                                       73200019
         LR    REG1,REG13               CONTAINS ADDRESS OF GETAREA     73400019
         L     REG13,SAVEAREA+4         RESTORE CALLER'S REGISTER 13    73600019
         LA    REG0,LEN                 LENGTH OF GETMAIN               73800019
         FREEMAIN R,LV=(0),A=(1)                                        74000019
         SPACE 2                                                        74200019
*        RESTORE REGISTERS                                              74400019
         SPACE 1                                                        74600019
RETURN   DS    0H                                                       74800019
         LR    RETREG,REG2              SET RETURN CODE                 75000019
         L     BRANCH,TWELVE(REG13)                                     75200019
         LM    ZERO,TWELVE,TWENTY(REG13)                                75400019
         BR    BRANCH                                                   75600019
         SPACE 2                                                        75800019
*        DEFINE CONSTANTS AND STORAGE                                   76000019
         SPACE 1                                                        76200019
         DS    0F                                                       76400019
ADDRAVT  DC    V(IHKAVT)                ADDRESS OF AVT                  76600019
BLANK    DC    C' '                     BLANK                           76800019
         SPACE 3                                                        77000019
*        GETMAIN DSECT                                                  77200019
         SPACE 1                                                        77400019
GETAREA  DSECT                                                          77600019
SAVEAREA DS    18F                      SAVE AREA                       77800019
LEN      EQU   *-GETAREA                                                78000019
         SPACE 3                                                        78200019
         RAFKNBX  TYPE=DSECT                                            78600019
         IHKCDSCT TUB=YES,AVT=YES,UVR=YES                               78800019
         TUBEQU                                                         79000019
         END                                                            79200019
