WTR      TITLE 'IHKWTR - LIBRARY I/O WAIT MODULE'                       01000019
*********************************************************************** 01010019
*                                                                     * 01020019
*STATUS-                                                              * 01030019
*   CHANGE LEVEL 0                                                    * 01040019
*                                                                     * 01050019
*FUNCTION/OPERATION-                                                  * 01060019
*   THE PURPOSE OF THIS WAIT MODULE IS TO ALLOW OVERLAPPING OF I/O    * 01070019
*   WHEN WRITING TO A USER LIBRARY OF CRJE SYSTEM LIBRARY. OVERLAPPING* 01080019
*   IS ACHIEVED BY THE RWRITE (LIBRARY I/O) MACRO INITIATING THE I/O  * 01090019
*   AND IHKWTR TESTING FOR ERRORS AND EXCEPTIONAL CONDITIONS AT THE   * 01100019
*   COMPLETION OF THE I/O. A CALL TO IHKWTR MUST BE MADE FOR EACH     * 01110019
*   RWRITE MACRO BEFORE ANOTHER RWRITE MACRO MAY BE ISSUED.           * 01120019
*   UPON ENTRY THIS MODULE CHECKS WHETHER OR NOT THE I/O IS COMPLETE. * 01130019
*   IF NOT, IHKWTR WAITS IN THE CRJE DISPATCHER UNTIL THE I/O IS      * 01140019
*   POSTED COMPLETE. A CHECK MACRO IS THEN ISSUED TO INSPECT THE      * 01150019
*   RESULTS. IF AN ERROR OCCURRED, THE CHECK MACRO PASSES CONTROL TO  * 01160019
*   THE SYNAD ROUTINE IN LIBRARY I/O MODULE, WHICH SETS THE I/O ERROR * 01170019
*   FLAG IN THE TUBPAMSW FIELD AND RETURNS. WHEN CONTROL IS RETURNED  * 01180019
*   FROM CHECK, IHKWTR FREES THE OUTPUT BUFFER, MOVES THE TUB BUFFER  * 01190019
*   POINTER TO THE BPAM OUTPUT BUFFER LOCATION, GETS THE COMPLETION   * 01200019
*   CODE FROM THE TUBPAMSW FIELD, AND RETURNS TO THE CALLER.          * 01210019
*   IF THE ROUTINE INVOKING IHKWTR SPECIFIES THAT IT WILL CONTROL ITS * 01220019
*   OWN BUFFERS (BIT 0 OF TUBAFISW FIELD SET TO ONE), NO FREEING OF   * 01230019
*   THE OUTPUT BUFFER OR SWITCHING OF THE TUB AFIO BUFFER POINTER     * 01240019
*   (TUBRAFBR) TO THE LIBRARY I/O OUTPUT BUFFER (SFBUFF1 IN IHKNBX) IS* 01250019
*   DONE.                                                             * 01260019
*   IF THE I/O IS POSTED COMPLETE WHEN THIS MODULE GAIN CONTROL, A    * 01270019
*   CHECK IS MADE FOR THE FOLLOWING TWO EXCEPTIONAL CONDITIONS:       * 01280019
*        END-OF-VOLUME - WHEN END-OF-VOLUME IS DETECTED BY THE RWRITE * 01290019
*                        PROCESSOR (IHKBPM), THE END-OF-VOLUME SWITCH * 01300019
*                        IN TUBPAMSW IS SET AND THE OUTPUT BUFFER IS  * 01310019
*                        FREED BEFORE CONTROL IS RETURNED TO THE      * 01320019
*                        CALLER (UNLESS BUFFER CONTROL WAS SPECIFIED).* 01330019
*        I/O ERROR     - WHEN THE LIBRARY I/O MODULE DETERMINES THAT  * 01340019
*                        THE START I/O FAILED ON THE WRITE OPERATION, * 01350019
*                        IT SETS THE I/O ERROR SWITCH IN THE TUBPAMSW * 01360019
*                        FIELD AND FREES THE OUTPUT BUFFER (UNLESS    * 01370019
*                        BUFFER CONTROL WAS SPECIFIED).               * 01380019
*   IF EITHER OF THESE CONDITIONS IS FOUND, THE ISSUING OF THE CHECK  * 01390019
*   MACRO AND THE FREEING OF THE OUTPUT BUFFER IS BYPASSED. IF NEITHER* 01400019
*   OF THESE TWO CONDITIONS IS FOUND, PROCESSING IS RESUMED AT THE    * 01410019
*   POINT WHERE THE CHECK MACRO IS ISSUED.                            * 01420019
*                                                                     * 01430019
*ENTRY POINTS-                                                        * 01440019
*        IHKWTR IS THE ONLY ENTRY POINT.                              * 01450019
*                                                                     * 01460019
*INPUT-                                                               * 01470019
*   AT ENTRY REGISTER ONE MUST CONTAIN A POINTER TO THE ADDRESS OF THE* 01480019
*   TUB.                                                              * 01490019
*                                                                     * 01500019
*OUTPUT-                                                              * 01510019
*   RESULT OF I/O OPERATION IS RETURNED TO THE CALLER AND THE OUTPUT  * 01520019
*   BUFFER (UNLESS BUFFER CONTROL SPECIFIED) IS FREED.                * 01530019
*                                                                     * 01540019
*EXTERNAL ROUTINES-                                                   * 01550019
*        IHKDSP       - CRJE DISPATCHER TO WAIT ON I/O.               * 01560019
*        BSAM (CHECK) - TO INSPECT RESULTS OF I/O.                    * 01570019
*                                                                     * 01580019
*EXITS-NORMAL-                                                        * 01590019
*   RETURN TO CALLING ROUTINE WITH ONE OF THE FOLLOWING RETURN CODES  * 01600019
*   IN REGISTER 15:                                                   * 01610019
*        0  - NORMAL RETURN, I/O COMPLETE WITH NO ERRORS.             * 01620019
*        4  - END-OF VOLUME                                           * 01630019
*        12 - I/O ERROR                                               * 01640019
*                                                                     * 01650019
*TABLES/WORK AREAS-                                                   * 01660019
*   TUB                                                               * 01670019
*       TUBSAVE  - 18 WORD SAVE AREA IN TUB.                          * 01680019
*       TUBPAMSW - (BPM SWITCH BYTE) BITS 6 AND 7 USED TO SET RETURN  * 01690019
*                  CODE; BITS 4 AND 6 INSPECTED FOR I/O ERROR.        * 01700019
*       TOBRAFBF - (AFIO BUFFER POINTER) MOVED TO LIBRARY I/O BUFFER  * 01710019
*                  POINTER.                                           * 01720019
*   KNOBOX                                                            * 01730019
*       SFBUFF1  - (LIBRARY I/O BUFFER POINTER) REPLACED BY TUBRAFBR, * 01740019
*                                                                     * 01750019
*ATTRIBUTES-                                                          * 01760019
*   RESIDENT AND REENTRANT.                                           * 01770019
*                                                                     * 01780019
*********************************************************************** 01790019
IHKWTR   CSECT                                                          02000019
         SAVE  (14,12),,*                                               03000019
          BALR BAS,ZIP                                                  04000019
         USING *,BAS                                                    05000019
         L     AVT,AVTAD           GET AVT                              06000019
         USING AVTDSECT,AVT                                             07000019
         L     TUB,0(PAR)          GET TUB                              08000019
         USING TUBDSECT,TUB                                             09000019
         LA    OSV,TUBSAVE                                              10000019
         ST    OSV,8(SAV)          CHAIN SAVE AREAS                     11000019
         ST    SAV,4(OSV)                                               12000019
         LR    SAV,OSV                                                  13000019
         L     KBX,IHKYYKBX        GET KON BOX                          14000019
         USING RAFKNBX,KBX                                              15000019
         SPACE 2                                                        16000019
         LA    PAR,BPDECB          GET ECB FOR WAIT                     17000019
         TM    BPDECB,POST         IS I/O COMPLETE                      18000019
         BO    NOWAIT1             YES SKIP WAIT                        19000019
         SPACE                                                          20000019
         L     GO,IHKYYDSP         DISPATCHER ADDRESS                   21000019
         BALR  BAC,GO              WAIT FOR I/O                         22000019
         SPACE                                                          23000019
NOWAIT   CHECK (1)                 INSPECT I/O FOR ERROR                24000019
         SPACE                                                          25000019
         TM    TUBAFISW,BUFCNTRL   DYNAMIC BUFFERS BEING USED           26000019
         BO    NOFREE              NO  DON'T FREE BUFFER                27000019
         L     WOK,SFBUFF1         ADDRESS OF BPAM BUFFER               28000019
         LM    ZIP,PAR,0(WOK)      LENGTH AND ADDRESS TO FREE           29000019
         SPACE 2                                                        30000019
         FREEMAIN R,A=(1),LV=(0)                                        31000019
         SPACE 2                                                        32000019
NOFREE   EQU   *                                                        33000019
         TM    TUBAFISW,BUFCNTRL   DYNAMIC BUFFERS BEING USED           34000019
         BO    ENDIT               NO DON'T SWAP BUFFER POINTERS        35000019
         MVC   SFBUFF1(4),TUBRAFBF MOVE BUFFER POINTER TO LIB I/O       36000019
         SPACE                                                          37000019
ENDIT    SR    GO,GO               CLEAR REGISTER FIFTEEN FOR CODE      38000019
         IC     GO,BPAMSWCS        GET COMPLETION CODE                  39000019
         SLL   GO,30                                                    40000019
         LCR   15,15                                                    41000019
         BC    8,B1                                                     42000019
         BC    4,B2                                                     43000019
B4       LA    15,12                                                    44000019
EXIT     EQU   *                                                        45000019
         IC    ZIP,BPAMSWCS        GET COMPLETION CODE                  46000019
         SLL   ZIP,30                                                   47000019
         L     SAV,TUBSAVE+4       CALLER'S SAVE AREA                   48000019
         L     14,12(13)                                                49000019
         RETURN (1,12),T,RC=(15)                                        50000019
B1       LA    15,0                                                     51000019
         B     EXIT                                                     52000019
B2       LA    15,4                                                     53000019
         B     EXIT                                                     54000019
NOWAIT1  L     DCB,BPDCBPTR        ADDRESS OF DCB                       55000019
         USING IHADCB,DCB                                               56000019
         TM    DCBCIND1,VOLFUL     END OF VOLUME REACHED                57000019
         BO    NOFREE              YES  SKIP FREEING OF BUFFER.         58000019
*                                  FREED BY IHKBPM WHEN WRITE ISSUED    59000019
         TM    BPAMSWCS,ERROR      I/O ERROR- NO I/O INITIATED          60000019
         BO    NOFREE              YES- BUFFER ALREADY FREED            61000019
         B     NOWAIT              CHECK FOR I/O ERRORS                 62000019
GO       EQU   15                                                       63000019
BAC      EQU   14                                                       64000019
SAV      EQU   13                                                       65000019
BAS      EQU   12                                                       66000019
AVT      EQU   11                                                       67000019
WOK      EQU   10                                                       68000019
TUB      EQU   9                                                        69000019
KBX      EQU   8                                                        70000019
OSV      EQU   7                                                        71000019
DCB      EQU   6                                                        72000019
PAR      EQU   1                                                        73000019
ZIP      EQU   0                                                        74000019
VOLFUL   EQU   X'20'                                                    75000019
POST     EQU   X'40'                                                    76000019
ERROR    EQU   X'0A'                                                    77000019
BUFCNTRL EQU   X'80'                                                    78000019
AVTAD    DC    A(IHKAVT)                                                79000019
         EXTRN IHKAVT                                                   80000019
         SPACE 5                                                        81000019
         IHKCDSCT TUB=YES,AVT=YES                                       83000019
         TUBEQU                                                         84000019
         SPACE 4                                                        85000019
         RAFKNBX TYPE=DSECT                                             86000019
         DCBD  DSORG=(PO),DEVD=(DA)                                     87000019
         END                                                            88000019
