         TITLE 'IES000  OS/360 RPG PREPHASE                          2' 00020000
* STATUS       CHANGE LEVEL 1-9                                  A32707 00040020
*                                                                       00060000
*FUNCTION/OPERATION - OPEN PROCESSOR DATA SETS                          00080000
*                   - GET CORE FOR PROCESSOR TABLES AND ALLOCATE        00100000
*                   - INITIALIZE TABLES AND CIOEX CONSTANTS             00120000
*                   - READ AND DIAGNOSE RPG CONTROL CARD                00140000
*                                                                       00160000
*ENTRY POINT   IES00010 FROM IES00910                                   00180000
*              CALLING SEQUENCE   PHSLINK  L     15,PHSADDR             00200000
*                                          BALR  7,15                   00220000
*                                          *                            00240000
*                                          *                            00260000
*                                          *                            00280000
*                                 PHSADDR  DC    V(IES00010)            00300000
*                                                                       00320000
*              ADDRESS OF THE CIOEX DATA AREA PASSED IN REGISTERS       00340000
*              6 AND 12                                                 00360000
*                                                                       00380000
*INPUT   ADDRESS OF OPTIONS LIST POINTER IN REGISTER 1                  00400000
*        ADDRESSES OF DCB'S IN CIOEX DATA AREA                          00420000
*        DATE, JOB NAME, AND STEP NAME FROM OS                          00440000
*        ADDRESS OF READ/PUNCH BUFFER IN CIOEX DATA AREA                00460000
*        ADDRESS OF PRINT BUFFER IN CIOEX DATA AREA                     00480000
*        RPG CONTROL CARD FROM SYSIN                                    00500000
*                                                                       00520000
*OUTPUT   COMPILER OPTION BYTE IN CIOEX DATA AREA (THIS REFLECTS        00540000
*           THE OPTIONS PARAMETER GIVEN IN THE // EXEC CARD)            00560000
*         ADDRESS OF RESULT INDICATOR TABLE IN CIOEX DATA AREA          00580000
*         ADDRESS AND LENGTH OF FIELD NAME TABLE IN CIOEX DATA AREA     00600000
*         ADDRESS AND LENGTH OF LITERAL TABLE IN CIOEX DATA AREA        00620000
*         ADDRESS AND LENGTH OF COMPRESSION IN CIOEX DATA AREA          00640000
*         ADDRESS OF COMPRESSION IN REGISTER 3                          00660000
*         ADDRESS OF READ/PUNCH BUFFER IN REGISTER 4                    00680000
*         ADDRESS OF PRINT BUFFER IN REGISTER 10                        00700000
*         DATE, JOB NAME, AND STEP NAME IN CIOEX DATA AREA              00720000
*         STERLING CODE, ALTERNATE COLLATING SEQUENCE, AND INVERTED     00740000
*           PRINT SWITCHES IN CIOEX DATA AREA (THESE REFLECT ENTRIES    00760000
*           IN THE RPG CONTROL CARD)                                    00780000
*        ERROR NOTE SWITCHES IN CIOEX DATA AREA                         00800000
*        PRINTED RPG CONTROL CARD AND ERROR NOTES ON SYSPRINT           00820000
*                                                                       00840000
*EXTERNAL ROUTINES   IES00910 - CIOEX ROUTINES FOR PREPHASE             00860000
*                      RDSPEC - READ SPECIFICATION FROM SYSIN           00880000
*                      PNTSPC - PRINT SPECIFICATION ON SYSPRINT         00900000
*                      PNTERR - PRINT ERROR NOTE ON SYSPRINT            00920000
*                      PHSCAL - CALL NEXT PHASE TO BE EXECUTED          00940000
*                                                                       00960000
*EXIT - NORMAL   TO ENTER PHASE 1 VIA CIOEX PHSCAL AFTER PROCESSING     00980000
*                RPG CONTROL CARD                                       01000000
*                                                                       01020000
*EXIT - ERROR   TO DIAGNOSTIC PHASE 1 VIA CIOEX PHSCAL IF NO RPG        01040000
*               CONTROL CARD OR ON EOF ON SYSIN                         01060000
*                                                                       01080000
*TABLES/WORK AREAS   RESULT INDICATOR TABLE                             01100000
*                    FIELD NAME TABLE                                   01120000
*                    LITERAL TABLE                                      01140000
*                    COMPRESSION                                        01160000
*                    COMPILER OPTION TABLE (OPTNTBL)                    01180000
*                    MONTH/DAY TABLE FOR DATE CONVERSION (MONTHTBL)     01200000
*                    FORM TYPE TABLE TO DETECT VALID RPG SPEC (FORMTBL) 01220000
*                    STERLING TABLE (STLTBL)                            01240000
*                                                                       01260000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             01280000
*                                                                       01300000
IES00010 START                                                          01320000
*0753000400,013300,105200,135000                                   000D 01326017
*0753045600,108600-108800                                          000E 01333017
* 151780                                                           I168 01336000
PREPHASE EQU   *                                                        01340000
DADEVT   EQU   X'20'                    DEVICE TYPE CODE FOR DIRECT ACC 01360000
DCBDDNAM EQU   X'28'                    DISPL TO DDNAME IN PNCHGO DCB   01380000
*****************************************                          000Z 01380517
* GENERAL REGISTER ASSIGNMENTS                                     000Z 01381017
*****************************************                          000Z 01381517
XR0      EQU   0                                                   000Z 01382017
XR1      EQU   1                                                   000Z 01382517
XR2      EQU   2                                                   000Z 01383017
XR3      EQU   3                                                   000Z 01383517
XR4      EQU   4                                                   000Z 01384017
XR5      EQU   5                                                   000Z 01384517
XR6      EQU   6                                                   000Z 01385017
XR7      EQU   7                                                   000Z 01385517
XR8      EQU   8                                                   000Z 01386017
XR9      EQU   9                                                   000Z 01386517
XR10     EQU   10                                                  000Z 01387017
XR11     EQU   11                                                  000Z 01387517
XR12     EQU   12                                                  000Z 01388017
XR13     EQU   13                                                  000Z 01388517
XR14     EQU   14                                                  000Z 01389017
XR15     EQU   15                                                  000Z 01389517
REG11    EQU   11                                                  000A 01390016
GR2      EQU   2                                                   000D 01392017
GR5      EQU   5                                                   000D 01394017
GR7      EQU   7                                                   000D 01396017
         BALR  XR8,0                    LOAD                       000Z 01406017
         USING *,XR8                     BASE REG 8 FOR PREPHASE   000Z 01416017
         USING CXDATA,XR6               REFERENCE CIOEX DATA BASE  000Z 01426017
***********************************************                         01460000
*INITIALIZE COMPILER OPTION BYTE                                        01480000
* BY INTERROGATING OPTIONS LIST GIVEN IN EXEC CARD, E.G.                01500000
*                                                                       01520000
*//      EXEC  PGM=RPG,PARM='LIST,DC,NCAL',                             01540000
*                                                                       01560000
*    COMPILER OPTION BYTE                                               01580000
*        BITS 0-4  NOT USED                                             01600000
*               5  0=LIST (ASSUMED)                                     01620000
*                  1=NOLIST                                             01640000
*             6-7  00=LOAD,NODECK (ASSUMED)                             01660000
*                  01=NOLOAD,DECK                                       01680000
*                  10=LOAD,DECK                                         01700000
*                  11=NOLOAD,NODECK                                     01720000
***********************************************                         01740000
         L     XR1,CXSAVEAR+4                                      000Z 01760017
         L     XR1,24(XR1)              POINTER TO PARM LIST       000Z 01780017
         L     XR2,0(,XR1)              POINTER TO OPTIONS LIST    000Z 01800017
         LH    XR3,0(,XR2)              LOAD REG 3 WITH            000Z 01820017
*                                         BIN LENGTH OF OPTION STRING   01840000
         LTR   XR3,XR3                  ANY OPTIONS SPECIFIED      000Z 01860017
         BZ    DDNAMES                  NO, SKIP ROUTINE                01880000
         LA    XR2,1(XR2)              SET ON FIRST OPTION BYTE    000Z 01900017
         B     OPTNLKUP                 LOOK UP FIRST OPTION            01920000
COMMALOK CLI   0(XR2),C','              SCAN STRING TO COMMA       000Z 01940017
         BNE   NEXTCHAR                                                 01960000
OPTNLKUP LA    XR9,OPTNTBL              ADDR OF OPTIONS TABLE      000Z 01980017
         LA    REG11,4       NUMBER OF ENTRIES IN OPTION TABLE     000A 02000016
OPTNLOOK CLC   1(6,XR2),0(XR9)          COMP OPTION IN PARM LIST   000Z 02020017
         BE    NOPTNFND                   TO NO OPTION IN TABLE,        02040000
         CLC   1(4,XR2),2(XR9)            TO YES OPTION IN TABLE   000Z 02060017
         BE    YOPTNFND                                                 02080000
         LA    XR9,8(XR9)               ADV TO NEXT TABLE ENTRY    000Z 02100017
         BCT   XR11,OPTNLOOK            LAST ENTRY TEST            000Z 02120017
         B     NEXTCHAR                 OPTION NOT FOUND IN TABLE       02140000
NOPTNFND OC    CXCMPOPT(1),6(XR9)       NO OPTION FOUND, TURN ON   000Z 02160017
         B     NEXTCHAR                   CORRESP COMPILER OPTION BIT   02180000
YOPTNFND OC    CXCMPOPT(1),7(XR9)       YES OPTION FOUND, TURN ON  000Z 02200017
*                                         CORRESP COMPILER OPTION BIT   02220000
NEXTCHAR LA    XR2,1(XR2)               ADV TO NEXT CHAR IN STRING 000Z 02240017
         BCT   XR3,COMMALOK             LAST CHAR TEST             000Z 02260017
         TM    CXCMPOPT,X'01'           WAS NOLOAD SPECIFIED            02280000
         BZ    DDNAMES                  NO                              02300000
*                                       YES, ADJUST BIT PATTERN         02320000
         TM    CXCMPOPT,X'02'           WAS DECK SPECIFIED              02340000
         BZ    *+12                                                     02360000
         NI    CXCMPOPT,X'FD'           YES, SET NOLOAD,DECK CONFIG     02380000
         B     DDNAMES                                                  02400000
         OI    CXCMPOPT,X'02'           NO, SET NOLOAD,NODECK CONFIG    02420000
***********************************************                         02440000
*PICK UP DDNAMES PASSED FROM INVOKER, IF ANY                            02460000
***********************************************                         02480000
DDNAMES  TM    0(XR1),X'80'             IS A(OPTIONS) THE LAST ITEM000Z 02500017
         BO    SETDDNAM                 YES, SKIP FURTHER INVOCATION    02520000
         L     XR2,4(,XR1)              POINTER TO DDNAMES         000Z 02540017
         LH    XR3,0(,XR2)              LOAD REG 3 WITH            000Z 02560017
*                                         BIN LENGTH OF DDNAMES STRING  02580000
         SH    XR3,HALF32               ANY DDNAMES PASSED RE RPG  000Z 02600017
         BNP   HEADING                  NO, SKIP TO HEADING ROUTINE     02620000
         LA    XR2,34(XR2)           SET TO DDNAME CORRESP TO S    000Z 02640017
         LA    XR9,CXDCBSRC             SET TO ADDR OF SYSIN DCB   000Z 02660017
         LA    XR4,6                  NUMBER OF DDNAMES IN STAN    000Z 02680017
CONTDD   CLC   0(8,XR2),BINZEROS        IS THIS DDNAME BINARY ZEROS000Z 02700017
         BE    NEXTDD                   YES, ASSUME STANDARD DDNAME     02720000
         L     XR11,0(XR9)              PICK UP ADDR OF DCB        000Z 02740017
         MVC   DCBDDNAM(8,XR11),0(XR2)  MOVE IN USER DDNAME        000Z 02760017
NEXTDD   LA    XR2,8(XR2)              ADV TO NEXT DDNAME IN ST    000Z 02780017
         LA    XR9,4(XR9)               ADV TO NEXT DCB ADDR       000Z 02800017
         SH    XR3,HALF8            DECR LENGTH OF STRING REMAI    000Z 02820017
         BNP   HEADING                  STRING EXHAUSTED                02840000
         BCT   XR4,CONTDD               FORCE END AFTER 6 DDNAMES  000Z 02860017
         CLC   0(8,XR2),BINZEROS        IS THERE ANOTHER DDNAME    000Z 02880017
         BE    HEADING                  NO                              02900000
         MVC   SYSGO(8),0(XR2)          ASSUME THIS IS SYSGO DDNAME000Z 02920017
***********************************************                         02940000
*PICK UP PAGE NUMBER PASSED FROM INVOKER, IF ANY                        02960000
***********************************************                         02980000
HEADING  TM    4(XR1),X'80'             IS A(DDNAMES) THE LAST ITEM000Z 03000017
         BO    SETDDNAM                 YES, SKIP HEADING ROUTINE       03020000
         L     XR2,8(,XR1)              POINTER TO HEADING         000Z 03040017
         CLC   0(2,XR2),HALF4           IS PAGE NUMBER SPECIFIED   000Z 03060017
         BL    SETDDNAM                 NO                              03080000
         PACK  CXPAGNUM(4),2(4,XR2)  PACK USER PAGE NUM INTO CX    000Z 03100017
         SP    CXPAGNUM(4),CXONEPCK     SUBTR 1 TO OFFSET CIOEX PNTSPC  03120000
         MVI   CXHDGSW,X'F0'            SET TO RESTORE USER PAGE NUM    03140000
***********************************************                         03160000
*SET DDNAME IN SYSGO/SYSPUNCH DCB -                                     03180000
*   IF NOLOAD,DECK  DDNAME=SYSPUNCH                                     03200000
*      LOAD,NODECK  DDNAME=SYSGO                                        03220000
*      LOAD,DECK    DDNAME=SYSGO                                        03240000
***********************************************                         03260000
SETDDNAM TM    CXCMPOPT,X'01'           WAS NOLOAD,DECK SPECIFIED       03280000
         BO    OPEN                     YES, LEAVE SYSPUNCH DDNAME      03300000
         L     XR4,CXDCBPGO             PICK UP ADDR OF PNCHGO DCB 000Z 03320017
         MVC   CXSYSPDD(8),DCBDDNAM(XR4) SAVE SYSPUNCH DDNAME      000Z 03340017
         MVC   DCBDDNAM(8,XR4),SYSGO    REPLACE WITH SYSGO DDNAME  000Z 03360017
***********************************************                         03380000
*OPEN FILES                                                             03400000
***********************************************                         03420000
OPEN     LM    XR2,XR4,CXDCBSRC     PICK UP DCB ADDRS FOR ALL F    000Z 03440017
         LM    XR9,XR11,CXDCBWK1                                   000Z 03460017
         OPEN  ((3),(OUTPUT,DISP),                                     X03480000
               (4),(OUTPUT,DISP),                                      X03500000
               (9),(OUTIN,REREAD),                                     X03520000
               (10),(OUTIN,REREAD),                                    X03540000
               (11),(OUTIN,REREAD))                                     03560000
         OPEN  ((2),(INPUT,DISP))                                       03580000
***********************************************                         03600000
*INSURE THAT IF COMPRESSION AND BLANK AFTER FILES ARE MIXED,            03620000
*COMPRESSION STARTS OUT ON DIRECT ACCESS                                03640000
***********************************************                         03660000
         TM    17(XR10),DADEVT         IS COMPRESSION ALREADY O    000Z 03680017
         BO    SETDSWCH                 YES                             03700000
         TM    17(XR9),DADEVT           NO, IS BLANK AFTER ON DA   000Z 03720017
         BZ    GETCORE                      NO, NEITHER ONE ON DA       03740000
         ST    XR9,CXDCBWK2                 YES, SWITCH ASSIGNMENTS000Z 03760017
         ST    XR10,CXDCBWK1                   OF SYSUT1 AND SY    000Z 03780017
SETDSWCH MVI   CXCMPOVF,X'F0'           SET DA SWITCH IN CIOEX DATA     03800000
***********************************************                         03820000
*RESERVE CORE FOR CPS FUNCTIONS                                         03840000
***********************************************                         03860000
GETCORE  GETMAIN EU,LV=1024,A=CPSADDR                                   03880000
***********************************************                         03900000
*GET CORE FOR PROCESSOR TABLES                                          03920000
*    RI TABLE, 720 BYTES FIXED                                     I173 03940000
*    FIELD NAME TABLE, LITERAL TABLE, COMPRESSION, 2352 BYTES MIN       03960000
*                                             2**24 - 8 BYTES MAX       03980000
***********************************************                         04000000
         LA    XR9,CXRIADDR                                        000Z 04020017
         GETMAIN VU,LA=MINLENG,A=(9)                                    04040000
***********************************************                         04060000
*DIVIDE UP CORE FOR TABLES AS FOLLOWS -                                 04080000
*    RATIO (FIELD NAME TABLE/LITERAL TABLE/COMPRESSION) = 5/3/2         04100000
*                                       TO NEAREST DOUBLE WORD BOUNDARY 04120000
*    LENGTH OF FIELD NAME TABLE = TOTAL LENGTH/2                        04140000
*    LENGTH OF LITERAL TABLE = (TOTAL LENGTH*3)/10                      04160000
*    LENGTH OF COMPRESSION = REMAINDER, UP TO 3624                      04180000
***********************************************                         04200000
         L     XR3,CXFLDADD             TOTAL LENGTH FROM GETMAIN  000Z 04220017
         S     XR3,RILENG           SUBTRACT OFF LENGTH OF RI T    000Z 04240017
         SRL   XR3,1                    DIV BY 2                   000Z 04260017
         ST    XR3,CXFLDLEN             LENGTH OF FIELD NAME TABLE 000Z 04280017
         NI    CXFLDLEN+3,X'F8'         ROUND TO NEXT LOWEST DBL WORD   04300000
         LA    XR4,3                                               000Z 04320017
         MR    XR2,XR4                  MULT BY 3                  000Z 04340017
         LA    XR4,5                                               000Z 04360017
         DR    XR2,XR4                  DIV BY 5                   000Z 04380017
         ST    XR3,CXLITLEN             LENGTH OF LITERAL TABLE    000Z 04400017
         NI    CXLITLEN+3,X'F8'         ROUND TO NEXT LOWEST DBL WORD   04420000
         L     XR3,CXFLDADD             TOTAL LENGTH FROM GETMAIN  000Z 04440017
         S     XR3,RILENG              - LENGTH OF RESULT IND T    000Z 04460017
         S     XR3,CXFLDLEN            - LENGTH OF FIELD NAME T    000Z 04480017
         S     XR3,CXLITLEN               - LENGTH OF LITERAL TABLE000Z 04500017
         ST    XR3,CXCMPEXT               = LENGTH OF COMPRESSION  000Z 04520017
***********************************************                         04540000
* GIVE EXCESS OF COMPRESSION OVER 1736 (SIZE OF COMPRESSION WAS    000E 04550017
*  CHANGED FROM 3624 TO 1736 TO BE COMPATIBLE WITH ALL DASD )      000E 04560017
*TO FIELD NAME TABLE AND LITERAL TABLE                                  04580000
*IN 5/3 PROPORTION                                                      04600000
***********************************************                         04620000
         S     XR3,MXCMPEXT             IS COMPRESSION OVER 3624   000Z 04640017
         BNP   TBLADDR                  NO                              04660000
         SRL   XR3,3                    APPORTION EXCESS - DIV BY 8000Z 04680017
         LA    XR4,5                                               000Z 04700017
         MR    XR2,XR4                                    MULT     000Z 04720017
         ST    XR3,CXDUBLWD             SAVE 5/8 QUANTITY          000Z 04740017
         NI    CXDUBLWD+3,X'F8'         ROUND TO NEXT LOWEST DBL WORD   04760000
         A     XR3,CXFLDLEN             5/8 TO FIELD NAME TABLE    000Z 04780017
         ST    XR3,CXFLDLEN          NEW LENGTH OF FIELD NAME T    000Z 04800017
         NI    CXFLDLEN+3,X'F8'         ROUND TO NEXT LOWEST DBL WORD   04820000
         L     XR3,CXCMPEXT                                        000Z 04840017
         S     XR3,MXCMPEXT             TOTAL EXCESS OVER 3624     000Z 04860017
         S     XR3,CXDUBLWD               - 5/8 TO FIELD NAME TABLE000Z 04880017
         A     XR3,CXLITLEN               = 3/8 TO LITERAL TABLE   000Z 04900017
         ST    XR3,CXLITLEN             NEW LENGTH OF LITERAL TABLE000Z 04920017
         MVC   CXCMPEXT(4),MXCMPEXT     FIX LENGTH OF COMPR AT 3624     04940000
***********************************************                         04960000
*COMPUTE TABLE ADDRESSES                                                04980000
***********************************************                         05000000
*                      GETMAIN SUPPLIED ADDR OF RESULT IND TABLE        05020000
TBLADDR  L     XR3,CXRIADDR             ADDR OF RESULT IND TABLE   000Z 05040017
         A     XR3,RILENG              + LENGTH OF RESULT IND T    000Z 05060017
         ST    XR3,CXFLDADD              = ADDR OF FIELD NAME T    000Z 05080017
         A     XR3,CXFLDLEN            + LENGTH OF FIELD NAME T    000Z 05100017
         ST    XR3,CXLITADD               = ADDR OF LITERAL TABLE  000Z 05120017
         A     XR3,CXLITLEN               + LENGTH OF LITERAL TABLE000Z 05140017
         ST    XR3,CXCMPADD               = ADDR OF COMPRESSION    000Z 05160017
***********************************************                         05180000
*RETURN CORE FOR CPS FUNCTIONS                                          05200000
***********************************************                         05220000
         FREEMAIN E,LV=1024,A=CPSADDR                                   05240000
***********************************************                         05260000
*INITIALIZE TABLES                                                      05280000
***********************************************                         05300000
*    RESULT INDICATOR TABLE                                             05320000
***********************************************                         05340000
         L     XR2,CXRIADDR                                        000Z 05360017
         MVC   0(256,XR2),RITABLE       MOVE 680-BYTE RES IND TABLE000Z 05380017
         MVC   256(256,XR2),RITABLE+256 FROM PREPHASE DIRECTLY     000Z 05400017
         MVC   512(208,GR2),RITABLE+512   RI TABLE AREA            I173 05420000
***********************************************                         05440000
*     FIELD NAME TABLE                                                  05460000
***********************************************                         05480000
         L     XR2,CXFLDADD             ADDR OF FIELD NAME TABLE   000Z 05500017
         L     XR3,CXFLDLEN             LENG OF FIELD NAME TABLE   000Z 05520017
         LA    XR4,13                   LENG OF TRAILER (X'FF')    000Z 05540017
         BAL   XR5,TBLINIT              PERFORM INITIALIZATION     000Z 05560017
***********************************************                         05580000
*     LITERAL TABLE                                                     05600000
***********************************************                         05620000
         L     XR2,CXLITADD             ADDR OF LITERAL TABLE      000Z 05640017
         L     XR3,CXLITLEN             LENG OF LITERAL TABLE      000Z 05660017
         LA    XR4,33                   LENG OF TRAILER (X'FF')    000Z 05680017
         BAL   XR5,TBLINIT              PERFORM INITIALIZATION     000Z 05700017
***********************************************                         05720000
*     COMPRESSION AREA                                                  05740000
***********************************************                         05760000
         L     XR2,CXCMPADD             ADDR OF COMPRESSION        000Z 05780017
         L     XR3,CXCMPEXT             LENG OF COMPRESSION        000Z 05800017
         LA    XR4,60                   LENG OF TRAILER (X'FF')    000Z 05820017
         BAL   XR5,TBLINIT              PERFORM INITIALIZATION     000Z 05840017
         B     DATEROUT                 TO DATE ROUTINE                 05860000
***********************************************                         05880000
*TABLE INITIALIZATION SUBROUTINE                                        05900000
*    TABLE AREA FILLED WITH X'FE' UP TO TRAILER                         05920000
*    TRAILER FILLED WITH X'FF'                                          05940000
*    REG 2 CONTAINS ADDR OF TABLE                                       05960000
*    REG 3 CONTAINS LENG OF TABLE                                       05980000
*    REG 4 CONTAINS LENG OF TRAILER                                     06000000
***********************************************                         06020000
TBLINIT  LA    XR9,255                  MAX MOVE LENGTH            000Z 06040017
         MVI   0(XR2),X'FE'             X'FE' TO FIRST TABLE POS   000Z 06060017
         SR    XR3,XR4               LENGTH TO BE FILLED WITH X    000Z 06080017
INIT256  CR    XR3,XR9                 IS X'FE' LENGTH GTR THAN    000Z 06100017
         BNH   INITREM                  NO, FILL REMAINDER              06120000
         EX    XR9,EXMOVE              YES, FILL 256 POS WITH X    000Z 06140017
         AR    XR2,XR9                  INCR TARGET ADDR BY 255    000Z 06160017
         SR    XR3,XR9                  DECR X'FE' LENGTH BY 255   000Z 06180017
         B     INIT256                  REPEAT                          06200000
INITREM  EX    XR3,EXMOVE             FILL REMAINING POS WITH X    000Z 06220017
         AR    XR2,XR3                INCR TARGET ADDR BY REMAI    000Z 06240017
         MVI   0(XR2),X'FF'             X'FF' TO FIRST TRAILER POS 000Z 06260017
         BCTR  XR4,0                  SUBTR 2 FROM LENG OF TRAI    000Z 06280017
         BCTR  XR4,0                  1 TO COMPENSATE FOR FIRST    000Z 06300017
*                                         1 TO COMPENSATE FOR EXEC INST 06320000
         EX    XR4,EXMOVE               FILL TRAILER POS WITH X'FF'000Z 06340017
         BR    XR5                      RETURN                     000Z 06360017
*    EXECUTE INSTRUCTION                                                06380000
EXMOVE   MVC   1(1,XR2),0(XR2)          PROPAGATE FILL CHAR        000Z 06400017
***********************************************                         06420000
*PICK UP DATE, STEP NAME, AND JOB NAME FROM SUPERVISOR                  06440000
*CONVERT DATE FROM YYDDD FORMAT TO MONTH/DAY/YEAR FORMAT                06460000
***********************************************                         06480000
DATEROUT TIME  DEC                      GET PACKED JULIAN DATE YYDDD    06500000
         ST    XR1,CXDUBLWD             STORE IN WORK AREA         000Z 06520017
         UNPK  CXDUBLWD(8),CXDUBLWD(4)  UNPACK                          06540000
         MVC   CXTODAY+6(2),CXDUBLWD+3  MOVE YEAR TO DATE CONST         06560000
         STH   XR1,DAY                  PICK OFF PACKED DAY        000Z 06580017
         NI    DAY+1,X'FC'              INSURE STANDARD PLUS SIGN       06600000
       CLI     CXTODAY+7,C'2'      TEST FOR LEAP YEAR            A32707 06610020
         BNE   *+18                NO                            A32707 06620020
         CLI   CXTODAY+7,C'6'      TEST FOR LEAP YEAR            A32707 06630020
         BNE   *+10                NO                            A32707 06640020
         AP    FEB,CXONEPCK             YES, MAKE FEB 29 DAYS           06660000
         LA    XR9,MONTHTBL             ADDR OF MONTH/DAY TABLE    000Z 06680017
         LA    XR11,12                  MONTH COUNT                000Z 06700017
MONTHLOK CP    DAY,0(2,9)               IS DAY CONTAINED IN THIS MONTH  06720000
         BNH   FOUND                    YES                             06740000
         SP    DAY,0(2,9)               NO, SUBTR DAYS IN THIS MONTH    06760000
         AP    MONTH,CXONEPCK           ADD 1 TO MONTH NUMBER           06780000
         LA    XR9,2(XR9)               ADV TO NEXT MONTH IN TABLE 000Z 06800017
         BCT   XR11,MONTHLOK            LAST MONTH TEST, CONTINUE  000Z 06820017
         MVI   CXTODAY,C' '             DATE NO GOOD,                   06840000
         MVC   CXTODAY+1(7),CXTODAY       SET DATE CONST TO BLANKS      06860000
         B     JOBNSTEP                                                 06880000
FOUND    UNPK  CXTODAY(2),MONTH         UNPACK MONTH NUMBER INTO DATE   06900000
         OI    CXTODAY+1,X'F0'          CONVERT ZONE                    06920000
         UNPK  CXTODAY+3(2),DAY         UNPACK DAY OF MONTH INTO DATE   06940000
         OI    CXTODAY+4,X'F0'          CONVERT ZONE                    06960000
CVTPTR   EQU   16                       ABSOL LOC OF THE CVT POINTER    06980000
CVTTCBP  EQU   0                        DISPL TO THE ADDRESS-4 OF THE   07000000
*                                         CURRENT TCB POINTER           07020000
*                                         WITHIN THE CVT                07040000
TCBTIOTP EQU   12                       DISPL TO THE TIOT POINTER       07060000
*                                         WITHIN THE TCB                07080000
TIOTJOB  EQU   0                        DISPL TO THE JOB NAME           07100000
*                                         WITHIN THE TIOT               07120000
TIOTSTEP EQU   8                        DISPL TO THE STEP NAME          07140000
*                                         WITHIN THE TIOT               07160000
JOBNSTEP L     XR1,CVTPTR               THREAD WAY                 000Z 07180017
         L     XR1,CVTTCBP(XR1)           TO JOB NAME AND STEP NAME000Z 07200017
         L     XR1,4(XR1)                 CONTAINED IN THE TIOT    000Z 07220017
         L     XR1,TCBTIOTP(XR1)                                   000Z 07240017
         MVC   CXJOBNAM(8),TIOTJOB(XR1) INIT JOB NAME AND          000Z 07260017
         MVC   CXSTEPNA(8),TIOTSTEP(XR1)  STEP NAME IN CIOEX DATA  000Z 07280017
***********************************************                         07300000
*INITIALIZE KEY REGISTERS                                               07320000
***********************************************                         07340000
         L     XR3,CXCMPADD             ADDR OF COMPRESSION        000Z 07360017
         LA    XR4,RDRPCHAR             ADDR OF READER/PUNCH BUFFER000Z 07380017
         L     XR7,CXRADDR              ENTRY TO CIOEX ROUTINES    000Z 07400017
         LA    XR10,PNTRAREA            ADDR OF PRINT BUFFER       000Z 07420017
***********************************************                         07440000
*INITIALIZE PRINTER                                                     07460000
***********************************************                         07480000
         MVI   PNTRAREA,C' '            CLEAR                           07500000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT AREA                    07520000
         LA    XR2,PNTSPC               PRINT ONE BLANK LINE,      000Z 07530017
         BALR  XR5,XR7                EJECT PAGE, PRINT HEADING    000Z 07540017
         XC    CXSEQCHK(6),CXSEQCHK    SET SEQ NO. TO ZERO         000A 07570016
***********************************************                         07580000
*REQUEST CODES FOR CIOEX ROUTINES                                       07600000
***********************************************                         07620000
PHSCAL   EQU   4                                                        07640000
PNTERR   EQU   6                                                        07660000
PNTSPC   EQU   8                                                        07680000
RDSPEC   EQU   10                                                       07700000
         USING READAREA,XR4             READ AREA BASE REG         000Z 07720017
         USING PRNTAREA,XR10            PRINT AREA BASE REG        000Z 07740017
***********************************************                         07760000
*READ AND DIAGNOSE RPG CONTROL CARD                                     07780000
***********************************************                         07800000
RDCTLCD  LA    XR2,RDSPEC               READ SPEC                  000Z 07820017
         BALR  XR5,XR7                                             000Z 07840017
         MVC   PAGEPRNT(2),PAGECARD     ASSEMBLE INTO                   07860000
         MVC   LINEPRNT(3),LINECARD       PRINT AREA                    07880000
         MVC   TEXT(75),FORMTYPE                                        07900000
         LA    XR2,PNTSPC               PRINT SPEC                 000Z 07920017
         BALR  XR5,XR7                                             000Z 07940017
         CLI   FORMTYPE,C'H'            TEST FOR CONTROL CARD IDENT     07960000
         BE    TESTSTL                    FOUND, START PROCESSING       07980000
         LA    XR9,FORMTBL              ADDR OF FORM TYPE TABLE    000Z 08000017
         LA    XR11,6                 NUMBER OF POSSIBLE FORM T    000Z 08020017
FORMLOOK CLC   FORMTYPE(1),0(XR9)     TEST FOR VALID SPEC FORM     000Z 08040017
         BE    NOCTLCD                    FOUND, NO CONTROL CARD        08060000
         LA    XR9,1(XR9)               ADV TO NEXT FORM TYPE      000Z 08080017
         BCT   XR11,FORMLOOK            LAST ENTRY TEST            000Z 08100017
         B     RDCTLCD                    NOT FOUND, TREAT AS A COMMENT 08120000
*                                         READ NEXT SPEC                08140000
***********************************************                         08160000
*NO CONTROL CARD OR CONTROL CARD OUT OF SEQUENCE, TERMINATE THE RUN     08180000
***********************************************                         08200000
NOCTLCD  MVC   ERRNOTE(3),NOTE255       ERROR NOTE NUMBER TO PRINT AREA 08220000
         LA    XR2,PNTERR               PRINT THE ERROR NOTE       000Z 08240017
         BALR  XR5,XR7                                             000Z 08260017
         MVC   CXPHSNAM(8),RPG10190     LOAD PHASE NAME FOR DIAG 1      08280000
         LA    XR2,PHSCAL               CALL DIAG 1                000Z 08300017
         BR    XR7                                                 000Z 08320017
***********************************************                         08340000
*DIAGNOSE STERLING ENTRIES AND SET CIOEX STERLING SWITCHES              08360000
*                                                                       08380000
*    STERLING BYTE                                                      08400000
*        BITS 0-1  00  SHILLINGS COL BLANK/INPUT  (BLANK IN COL 17)     08420000
*                  01  IBM SHILLINGS FOR INPUT    (1 IN COL 17)         08440000
*                  10  BSI SHILLINGS FOR INPUT    (2 IN COL 17)         08460000
*             2-3  00  PENCE COL BLANK/INPUT      (BLANK IN COL 18)     08480000
*                  01  IBM PENCE FOR INPUT        (1 IN COL 18)         08500000
*                  10  BSI PENCE FOR INPUT        (2 IN COL 18)         08520000
*             4-5  00  SHILLINGS COL BLANK/OUTPUT (BLANK IN COL 19)     08540000
*                  01  IBM SHILLINGS FOR OUTPUT   (1 IN COL 19)         08560000
*                  10  BSI SHILLINGS FOR OUTPUT   (2 IN COL 19)         08580000
*             6-7  00  PENCE COL BLANK/OUTPUT     (BLANK IN COL 20)     08600000
*                  01  IBM PENCE FOR OUTPUT       (1 IN COL 20)         08620000
*                  10  BSI PENCE FOR OUTPUT       (2 IN COL 20)         08640000
*                                                                       08660000
*        POSSIBLE ENTRIES BY COL PAIRS (INPUT HANDLED AS 1 CASE,        08680000
*            (SHILLINGS,PENCE)          OUTPUT AS ANOTHER)              08700000
*             BLANK,BLANK  NO STERLING SPECIFIED                        08720000
*             1,1          IBM,IBM                                      08740000
*             1,2          IBM,BSI                                      08760000
*             2,1          BSI,IBM                                      08780000
*             2,2          BSI,BSI                                      08800000
*                                                                       08820000
*    IN CASE OF ERROR STANDARD OPTION WILL BE (IBM,IBM)                 08840000
*    FOR BOTH INPUT AND OUTPUT                                          08860000
*                                                                       08880000
*    BIT CONFIGURATION DETERMINED BY PERFORMING A  TABLE LOOK UP        08900000
*    ON COL PAIRS (SHILLING,PENCE)                                      08920000
***********************************************                         08940000
*PROCESS STERLING INPUT COLUMNS                                         08960000
***********************************************                         08980000
TESTSTL  LA    XR9,STLTBL               ADDR OF STERLING TABLE     000Z 09000017
         LA    XR11,5                   NUMBER OF ENTRIES          000Z 09020017
SIPTLOOK CLC   SHILLIPT(2),0(XR9)     TEST FOR VALID STL INPUT     000Z 09040017
         BE    SIPTFND                  FOUND                           09060000
         LA    XR9,4(XR9)               ADV TO NEXT COMB           000Z 09080017
         BCT   XR11,SIPTLOOK            LAST ENTRY TEST            000Z 09100017
***********************************************                         09120000
*NOT FOUND, ASSUME STANDARD OF IBM,IBM FOR INPUT                        09140000
***********************************************                         09160000
         LA    XR9,STLSTAND           POSITION TO STANDARD IN T    000Z 09180017
         MVC   ERRNOTE(3),NOTE252       ERROR NOTE FOR INVAL STL INPUT  09200000
         LA    XR2,PNTERR               PRINT ERROR NOTE           000Z 09220017
         BALR  XR5,XR7                                             000Z 09240017
***********************************************                         09260000
*FOUND OR ASSUME, TURN ON CORRESP INPUT BIT PATTERN                     09280000
***********************************************                         09300000
SIPTFND  OC    CXSTRLNG(1),2(XR9)                                  000Z 09320017
***********************************************                         09340000
*PROCESS STERLING OUTPUT COLUMNS                                        09360000
***********************************************                         09380000
         LA    XR9,STLTBL               ADDR OF STERLING TABLE     000Z 09400017
         LA    XR11,5                   NUMBER OF ENTRIES          000Z 09420017
SOPTLOOK CLC   SHILLOPT(2),0(XR9)    TEST FOR VALID STL OUTPUT     000Z 09440017
         BE    SOPTFND                  FOUND                           09460000
         LA    XR9,4(XR9)               ADV TO NEXT COMB           000Z 09480017
         BCT   XR11,SOPTLOOK            LAST ENTRY TEST            000Z 09500017
***********************************************                         09520000
*NOT FOUND, ASSUME STANDARD OF IBM,IBM FOR OUTPUT                       09540000
***********************************************                         09560000
         LA    XR9,STLSTAND           POSITION TO STANDARD IN T    000Z 09580017
         MVC   ERRNOTE(3),NOTE253       ERROR NOTE FOR INVAL STL OUTPUT 09600000
         LA    XR2,PNTERR               PRINT ERROR                000Z 09620017
         BALR  XR5,XR7                                             000Z 09640017
***********************************************                         09660000
*FOUND OR ASSUME, TURN ON CORRESP OUTPUT BIT PATTERN                    09680000
***********************************************                         09700000
SOPTFND  OC    CXSTRLNG(1),3(XR9)                                  000Z 09720017
***********************************************                         09740000
*DIAGNOSE INVERTED PRINT                                                09760000
*                                                                       09780000
*    VALID ENTRIES ARE BLANK OR I(INVERTED PRINT)                       09800000
*    IF ERROR THEN I ASSUMED                                            09820000
*                                                                       09840000
*    SWITCH SETTING (CXINVPRT) X'F0' INVERTED PRINT                     09860000
*                              X'00' BLANK                              09880000
***********************************************                         09900000
         CLI   INVPRNT,C' '             IS ENTRY BLANK                  09920000
         BE    ALTCSTST                 YES, TO PROCESS ALT COLL SEQ    09940000
         CLI   INVPRNT,C'D'       ALSO A VALID ENTRY, SAME AS BLANK000D 09946017
         BE    ALTCSTST           CONT PROCESSING, DO NOT SET BIT  000D 09952017
         CLI   INVPRNT,C'I'             NO, IS ENTRY I(INVERTED PRINT)  09960000
         BE    INVPRFND                 YES, SET SWITCH ACCORDINGLY     09980000
         MVC   ERRNOTE(3),NOTE254       NO, ERROR, INVALID INV PRINT    10000000
         LA    XR2,PNTERR               PRINT ERROR NOTE           000Z 10020017
         BALR  XR5,XR7                                             000Z 10040017
INVPRFND OI    CXINVPRT,X'F0'           SET SWITCH FOR INVERTED PRINT   10060000
***********************************************                         10080000
*DIAGNOSE ALTERNATE COLLATING SEQUENCE                                  10100000
*                                                                       10120000
*    VALID ENTRIES ARE BLANK OR A(ALT COLL SEQ)                         10140000
*    IF ERROR THEN A ASSUMED                                            10160000
*                                                                       10180000
*    SWITCH SETTING (CXCOLSEQ)  X'F0' ALT COLL SEQ                      10200000
*                               X'00' BLANK                             10220000
***********************************************                         10240000
ALTCSTST CLI   ALTCOLL,C' '             IS ENTRY BLANK                  10260000
         BE    PGMIDTST                 YES, TO PROCESS PROGRAM IDENT   10280000
         CLI   ALTCOLL,C'A'             NO, IS ENTRY A(ALT COLL SEQ)    10300000
         BE    ALTCSFND                 YES, SET SWITCH ACCORDINGLY     10320000
         MVC   ERRNOTE(3),NOTE248       NO, ERROR, INVALID ALT COLL SEQ 10340000
         LA    XR2,PNTERR               PRINT ERROR NOTE           000Z 10360017
         BALR  XR5,XR7                                             000Z 10380017
ALTCSFND OI    CXCOLSEQ,X'F0'           SET SWITCH FOR ALT COLL SEQ     10400000
***********************************************                         10420000
*PICK UP PROGRAM IDENTIFICATION FROM COLS 75-80 OF CONTROL CARD         10440000
*IF COL 75 IS BLANK, USE STANDARD IDENT OF 'RPGOBJ'                     10460000
***********************************************                         10480000
PGMIDTST CLI   PGMIDENT,C' '            IS ENTRY BLANK                  10500000
         BE    CHKUFORM           CHECK FOR USER DATE FORMAT       000D 10520017
         MVC   CXPGRNAM(6),PGMIDENT     NO, MOVE IN USER IDENT          10540000
***************************************                            000D 10541017
*                                                                  000D 10542017
*  CHECK FOR USER DATE---------C'D' OR C'I' = DAY-MONTH-YEAR,      000D 10543017
* C' ' = MONTH-DAY-YEAR                                            000D 10544017
*                                                                  000D 10545017
***************************************                            000D 10546017
CHKUFORM CLI   INVPRNT,C' '       CHECK FOR MONTH-DAY YEAR         000D 10547017
         BE    CALLEN01           NOT BLANK, DO NOT SET BIT        000D 10548017
         CLI   INVPRNT,C'I'       CHECK FOR DAY-MONTH-YEAR         000D 10549017
         BE    DMY                SET BIT TO GIVE DAY-MONTH-YEAR   000D 10550017
         CLI   INVPRNT,C'D'       CHECK FOR DAY-MONTH-YEAR         000D 10551017
         BNE   SETOBLNK           IF INVALID, THEN SET TO BLANK    000D 10552017
DMY      OI    CXCMPOPT,X'80'     SET BIT FOR WORLD TRADE OPTION   000D 10553017
*                                   IN THE COMPILER OPTION BYTE    000D 10554017
         B     CALLEN01           CONTINUE TO NEXT STEP            000D 10555017
SETOBLNK MVC   ERRNOTE(3),NOTE067 INDICATE USE OF BLANK AS DEFAULT 000D 10556017
         LA    GR2,PNTERR         GET ADDRESS OF ERROR ROUTINE     000D 10557017
         BALR  GR5,GR7            BRANCH TO PUT OUT ERROR NOTE     000D 10558017
***********************************************                         10560000
*CALL ENTER PHASE 1                                                     10580000
***********************************************                         10600000
CALLEN01 MVC   CXPHSNAM(8),RPG10030     LOAD PHASE NAME FOR ENTER 1     10620000
         LA    XR2,PHSCAL               CALL ENTER 1               000Z 10640017
         BR    XR7                                                 000Z 10660017
         EJECT                                                          10680000
***********************************************                         10700000
*CONSTANTS, TABLES, AND WORK AREAS                                      10720000
***********************************************                         10740000
HALF4    DC    H'4'                     CONSTANT 4                      10760000
HALF8    DC    H'8'                              8                      10780000
HALF32   DC    H'32'                             32                     10800000
BINZEROS DC    XL8'00'                  BINARY ZEROS                    10820000
RILENG   DC    F'720'                   LENGTH OF RESULT IND TABL  I173 10840000
MXCMPEXT DC    F'1736'            MAX COMP ON A D.A. DEVICE        000E 10860017
MINLENG  DC    F'4096'                  MIN,MAX AREA SIZES FOR     000E 10880017
MAXLENG  DC    F'16777208'                RI TABLE, FIELD NAME TABLE,   10900000
*                                         LITERAL TABLE AND COMPRESSION 10920000
CPSADDR  DC    A(0)                     ADDR OF CORE AVAILABLE TO CPS   10940000
DAY      DC    H'0'                     DAY (FOR DATE CONVERSION)       10960000
MONTH    DC    PL2'1'                   MONTH                           10980000
SYSGO    DC    C'SYSGO   '              DDNAME FOR SYSGO, PNCHGO DCB    11000000
RPG10030 DC    C'RPG10030'              PHASE NAME FOR ENTER PHASE 1    11020000
RPG10190 DC    C'RPG10190'              PHASE NAME FOR DIAG PHASE 1     11040000
CXRADDR  DC    V(IES00910)              ADDR OF ENTRY TO CIOEX ROUTINES 11060000
***********************************************                         11080000
*SIGNIFICANT OPTIONS AND THEIR CORRESPONDING COMPILER OPTION BITS       11100000
***********************************************                         11120000
OPTNTBL  DC    C'NOLOAD'                                                11140000
         DC    X'01'                    NOLOAD,DECK                     11160000
         DC    X'00'                    LOAD,NODECK                     11180000
         DC    C'NODECK'                                                11200000
         DC    X'00'                    LOAD,NODECK                     11220000
         DC    X'02'                    LOAD,DECK                       11240000
         DC    C'NOLIST'                                                11260000
         DC    X'04'                    NOLIST                          11280000
         DC    X'00'                    LIST                            11300000
         DC    C'NOSEQN'     SEQUENCE CHECK OPTION                 000A 11305016
         DC    X'00'         NO SEQ CHK, ALSO DEFAULT VALUE        000A 11310016
         DC    X'08'         SEQ CHK SPECIFIED                     000A 11315016
***********************************************                         11320000
*MONTH/DAY TABLE FOR DATE CONVERSION                                    11340000
***********************************************                         11360000
MONTHTBL DC    P'31'                    JAN                             11380000
FEB      DC    P'28'                    FEB                             11400000
         DC    P'31'                    MAR                             11420000
         DC    P'30'                    APR                             11440000
         DC    P'31'                    MAY                             11460000
         DC    P'30'                    JUN                             11480000
         DC    P'31'                    JUL                             11500000
         DC    P'31'                    AUG                             11520000
         DC    P'30'                    SEP                             11540000
         DC    P'31'                    OCT                             11560000
         DC    P'30'                    NOV                             11580000
         DC    P'31'                    DEC                             11600000
***********************************************                         11620000
*FORM TYPE TABLE                                                        11640000
***********************************************                         11660000
FORMTBL  DC    C'F'                     FILE DESCRIPTION SPEC           11680000
         DC    C'E'                     FILE EXTENSION SPEC             11700000
         DC    C'L'                     LINE COUNTER SPEC               11720000
         DC    C'I'                     INPUT SPEC                      11740000
         DC    C'C'                     CALC SPEC                       11760000
         DC    C'O'                     OUTPUT SPEC                     11780000
***********************************************                         11800000
*ERROR NOTE TABLE                                                       11820000
***********************************************                         11840000
NOTE248  DC    C'248'                   ERROR IN ALT COLL SEQ COL       11860000
NOTE252  DC    C'252'                   ERROR IN STERLING INPUT COLS    11880000
NOTE253  DC    C'253'                   ERROR IN STERLING OUTPUT COLS   11900000
NOTE254  DC    C'254'                   ERROR IN INVERTED PRINT COL     11920000
NOTE255  DC    C'255'                   NO PROCESSOR CONTROL CARD       11940000
NOTE067  DC    C'067'             USER DATE FORMAT ERROR NOTE      000D 11950017
***********************************************                         11960000
*STERLING TABLE                                                         11980000
***********************************************                         12000000
STLTBL   DC    C'  '                    NO STERLING SPECIFIED           12020000
         DC    B'00000000'              (BLANK,BLANK) INPUT BIT PATTERN 12040000
         DC    B'00000000'              (BLANK,BLANK) OUTPUT BIT PATTRN 12060000
STLSTAND DC    C'11'                    IBM,IBM                         12080000
         DC    B'01010000'              (1,1) INPUT BIT PATTERN         12100000
         DC    B'00000101'              (1,1) OUTPUT BIT PATTERN        12120000
         DC    C'12'                    IBM,BSI                         12140000
         DC    B'01100000'              (1,2) INPUT BIT PATTERN         12160000
         DC    B'00000110'              (1,2) OUTPUT BIT PATTERN        12180000
         DC    C'21'                    BSI,IBM                         12200000
         DC    B'10010000'              (2,1) INPUT BIT PATTERN         12220000
         DC    B'00001001'              (2,1) OUTPUT BIT PATTERN        12240000
         DC    C'22'                    BSI,BSI                         12260000
         DC    B'10100000'              (2,2) INPUT BIT PATTERN         12280000
         DC    B'00001010'              (2,2) OUTPUT BIT PATTERN        12300000
***********************************************                         12320000
*RESULTING INDICATOR TABLE                                              12340000
***********************************************                         12360000
RITABLE  EQU   *                                                   I173 12368000
         DC    X'E4F1010000E4F2010000E4F3010000E4F4010000'  U1-U4  I173 12376000
         DC    X'E4F5010000E4F6010000E4F7010000E4F8010000'  U5-U8  I173 12384000
         DC    X'D6C1000000D6C2000000D6C3000000D6C4000000'  OA-OD  I173 12392000
         DC    X'D6C5000000D6C6000000D6C7000000D6E5000000'  OE-OG,OV    12400000
         DC    X'F1D7070000D3D9030000'                      1P,LR       12420000
         DC    X'F0F0070000F0F1000000F0F2000000F0F3000000'  00-03       12440000
         DC    X'F0F4000000F0F5000000F0F6000000F0F7000000'  04-07       12460000
         DC    X'F0F8000000F0F9000000F1F0000000F1F1000000'  08-11       12480000
         DC    X'F1F2000000F1F3000000F1F4000000F1F5000000'  12-15       12500000
         DC    X'F1F6000000F1F7000000F1F8000000F1F9000000'  16-19       12520000
         DC    X'F2F0000000F2F1000000F2F2000000F2F3000000'  20-23       12540000
         DC    X'F2F4000000F2F5000000F2F6000000F2F7000000'  24-27       12560000
         DC    X'F2F8000000F2F9000000F3F0000000F3F1000000'  28-31       12580000
         DC    X'F3F2000000F3F3000000F3F4000000F3F5000000'  32-35       12600000
         DC    X'F3F6000000F3F7000000F3F8000000F3F9000000'  36-39       12620000
         DC    X'F4F0000000F4F1000000F4F2000000F4F3000000'  40-43       12640000
         DC    X'F4F4000000F4F5000000F4F6000000F4F7000000'  44-47       12660000
         DC    X'F4F8000000F4F9000000F5F0000000F5F1000000'  48-51       12680000
         DC    X'F5F2000000F5F3000000F5F4000000F5F5000000'  52-55       12700000
         DC    X'F5F6000000F5F7000000F5F8000000F5F9000000'  56-59       12720000
         DC    X'F6F0000000F6F1000000F6F2000000F6F3000000'  60-63       12740000
         DC    X'F6F4000000F6F5000000F6F6000000F6F7000000'  64-67       12760000
         DC    X'F6F8000000F6F9000000F7F0000000F7F1000000'  68-71       12780000
         DC    X'F7F2000000F7F3000000F7F4000000F7F5000000'  72-75       12800000
         DC    X'F7F6000000F7F7000000F7F8000000F7F9000000'  76-79       12820000
         DC    X'F8F0000000F8F1000000F8F2000000F8F3000000'  80-83       12840000
         DC    X'F8F4000000F8F5000000F8F6000000F8F7000000'  84-87       12860000
         DC    X'F8F8000000F8F9000000F9F0000000F9F1000000'  88-91       12880000
         DC    X'F9F2000000F9F3000000F9F4000000F9F5000000'  92-95       12900000
         DC    X'F9F6000000F9F7000000F9F8000000F9F9000000'  96-99       12920000
         DC    X'D3F0070000D3F1000000D3F2000000D3F3000000'  L0-L3       12940000
         DC    X'D3F4000000D3F5000000D3F6000000D3F7000000'  L4-L7       12960000
         DC    X'D3F8000000D3F9000000'                      L8-L9       12980000
         DC    X'D4D9000000'                                MR          13000000
         DC    X'C8F0030000C8F1030000C8F2030000C8F3030000'  H0-H3       13020000
         DC    X'C8F4030000C8F5030000C8F6030000C8F7030000'  H4-H7       13040000
         DC    X'C8F8030000C8F9030000'                      H8-H9       13060000
         DC    25X'FF'                  END OF RI TABLE                 13080000
***********************************************                         13100000
*EXPAND PREPHASE TO MEET OS/RPG DESIGN POINT                            13120000
***********************************************                         13140000
         ORG   PREPHASE+4095                                            13160000
         DC    X'00'                                                    13180000
***********************************************                         13200000
*RPG CONTROL CARD FORMAT                                                13220000
***********************************************                         13240000
READAREA DSECT                                                          13260000
PAGECARD DS    2C                       PAGE NUMBER COL 1-2             13280000
LINECARD DS    3C                       LINE NUMBER COL 3-5             13300000
FORMTYPE DS    1C                       FORM TYPE   COL 6               13320000
         DS    10C                      FILLER                          13340000
SHILLIPT DS    1C                       SHILLING INPUT FORMAT   COL 17  13360000
PENCEIPT DS    1C                       PENCE INPUT FORMAT      COL 18  13380000
SHILLOPT DS    1C                       SHILLING OUTPUT FORMAT  COL 19  13400000
PENCEOPT DS    1C                       PENCE OUTPUT FORMAT     COL 20  13420000
INVPRNT  DS    1C                       INVERTED PRINT CODE     COL 21  13440000
         DS    4C                       FILLER                          13460000
ALTCOLL  DS    1C                       ALTERNATE COLLATING SEQ COL 26  13480000
         DS    6C                 FILLER                           000D 13490017
UFORMAT  DS    1C                 USER DATE FORMAT                 000D 13500017
         DS    41C                FILLER                           000D 13510017
PGMIDENT DS    6C                       PROGRAM IDENT COL 75-80         13520000
***********************************************                         13540000
*PRINT LINE FORMAT                                                      13560000
***********************************************                         13580000
PRNTAREA DSECT                                                          13600000
         DS    13C                      FILLER                          13620000
PAGEPRNT DS    2C                       PAGE NUMBER POS 14-15           13640000
         DS    1C                       SPACE                           13660000
LINEPRNT DS    3C                       LINE NUMBER POS 17-19           13680000
         DS    1C                       SPACE                           13700000
TEXT     DS    75C                      TEXT        POS 21-95           13720000
         DS    1C                       SPACE                           13740000
ERRNOTE  DS    3C                       ERROR NOTE NUMBER POS 97-99     13760000
         DS    21C                      FILLER                          13780000
***********************************************                         13800000
*CIOEX DATA AREA                                                        13820000
***********************************************                         13840000
CXDATA   DSECT                                                          13860000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       13880000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 13900000
*                                         (START WITH PREPHASE)         13920000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 13940000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       13960000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   13980000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     14000000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     14020000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     14040000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        14060000
CXFLDADD DS    F                                FIELD NAME TABLE        14080000
CXLITADD DS    F                                LITERAL TABLE           14100000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 14120000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     14140000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      14160000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   14180000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                14200000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      14220000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         14240000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      14260000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    14280000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     14300000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    14320000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            14340000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    14360000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   14380000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           14400000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      14420000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  14440000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   14460000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 14480000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    14500000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         14520000
CXRETCDE DC    X'00'                    RETURN CODE                     14540000
CXIPTEOF BR    XR2                      LINKAGE TO EOF ROUTINE     000Z 14560017
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            14580000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          14600000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    14620000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           14640000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     14660000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    14680000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                14700000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             14720000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            14740000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     14760000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      14780000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    14800000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   14820000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        14840000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               14860000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     14880000
CXSYNERR B     4(XR2)                LINKAGE TO SYNCH ERROR ROU    000Z 14900017
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    14920000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     14940000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        14960000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          14980000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        15000000
CXTODAY  DC    C'  /  /  '              DATE                            15020000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             15040000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        15060000
RDRPCHAR DS    80C                      READER/PUNCH AREA               15080000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       15100000
PNTRAREA DS    120C                     PRINT AREA                      15120000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 15140000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 15160000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 15165015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 15170015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 15175015
CXSEQCHK DS    6C                       PAGE/LINE SEQUENCE CHECK   000A 15177016
CXCRDCNT DS    H                         SOURCE STATEMENT COUNT    I168 15178000
CXDEND   EQU   *                                                        15180000
         END   PREPHASE                                                 15200000
