         TITLE 'IES009  OS/360 RPG CIOEX OF PREPHASE                 3' 00020000
* STATUS       CHANGE LEVEL 1-7                                    I173 00040018
*                                                                       00060000
*FUNCTION/OPERATION   THE CIOEX ROUTINES ARE A SET OF EXTERNAL          00080000
*                     SUBROUTINES WHICH PERFORM ALL OF THE INPUT/OUTPUT 00100000
*                     OPERATIONS FOR THE COMPILER PHASES.  THE CIOEX    00120000
*                     ROUTINES OPERATE IN CONJUNCTION WITH THE CIOEX    00140000
*                     DATA AREA (POINTED TO BY REGISTER 6) WHICH        00160000
*                     CONTAINS THE DCB ADDRESSES, THE PRINTER AND       00180000
*                     READER/PUNCH BUFFERS, AND INFORMATION TO BE       00200000
*                     UPDATED WITH EACH INPUT/OUTPUT OPERATION.         00220000
*                     THE INDIVIDUAL CIOEX ROUTINES AND THE FUNCTIONS   00240000
*                     THEY PERFORM ARE DESCRIBED AT THE BEGINNING       00260000
*                     OF EACH ROUTINE.                                  00280000
*                                                                       00300000
*                     THOSE CIOEX ROUTINES REQUIRED BY A PHASE          00320000
*                     ARE ASSEMBLED AS A SEPARATE MODULE AND            00340000
*                     LINK-EDITED WITH THE PARENT PHASE.                00360000
*                     THE CIOEX CSECT ALSO SERVES AS THE ENTRY POINT    00380000
*                     FOR THE PHASE LOAD MODULE.                        00400000
*                                                                       00420000
*ENTRY POINT, INITIAL   IESCEX FROM IESRPG VIA THE LINK MACRO           00440000
*                                                                       00460000
*ENTRY POINT, CIOEX ROUTINES   IES00910 FROM IES00010                   00480000
*                              CALLING SEQUENCE   EXTRN IES00910        00500000
*                                                 L     7,CXRADDR       00520000
*                                                 LA    2,CXRCODE       00540000
*                                                 BALR  5,7             00560000
*                                                 *                     00580000
*                                                 *                     00600000
*                                                 *                     00620000
*                                        CXRADDR  DC    A(IES00910)     00640000
*                                        CXRCODE  EQU   0,2,...50 DISPL 00660000
*                                                       TO THE ADDRESS  00680000
*                                                       OF THE CIOEX    00700000
*                                                       ROUTINE WANTED  00720000
*                                                       WITHIN THE      00740000
*                                                       TRANSFER VECTOR 00760000
*                                                                       00780000
*                              ADDRESS OF THE CIOEX DATA AREA PASSED    00800000
*                              IN REGISTER 6                            00820000
*                                                                       00840000
*INPUT   REQUEST CODE FOR THE CIOEX ROUTINE WANTED IN REGISTER 2        00860000
*        CIOEX DATA AREA                                                00880000
*                                                                       00900000
*OUTPUT   COMPLETED I/O OPERATION AS REQUESTED                          00920000
*         UPDATED CIOEX DATA AREA                                       00940000
*                                                                       00960000
*EXTERNAL ROUTINES   NONE                                               00980000
*                                                                       01000000
*EXIT, INITIAL   TO IES00010                                            01020000
*                CALLING SEQUENCE   PHSLINK  L     15,PHSADDR           01040000
*                                            BALR  7,15                 01060000
*                                            *                          01080000
*                                            *                          01100000
*                                            *                          01120000
*                                   PHSADDR  DC    V(IES00010)          01140000
*                                                                       01160000
*EXIT, CIOEX ROUTINES (EXCEPT PHSCAL)   BR    5        CIOEX RETURN REG 01180000
*                                                                       01200000
*EXIT, CIOEX PHSCAL   XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA       01220000
*                                                                       01240000
*EXIT, SYNCHRONOUS I/O ERROR   SET RETURN CODE TO 20                    01260000
*                              CALL TERMINAL PHASE VIA CIOEX PHSCAL     01280000
*                                                                       01300000
*TABLES/WORK AREAS   NONE                                               01320000
*                                                                       01340000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             01360000
*                                                                       01380000
*NOTES   ALL I/O OPERATIONS ARE PERFORMED WITH BSAM                     01400000
*        THE FOLLOWING MACROS ARE USED - READ                           01420000
*                                        WRITE                          01440000
*                                        CHECK                          01460000
*                                        NOTE                           01480000
*                                        POINT                          01500000
*                                                                       01520000
IESCEX   START                                                          01540000
*0753000400,015500                                                 000D 01544017
*                                                                  000D 01548017
PRECIOEX EQU   *                        LABEL OF BEGINNING OF PHASE000D 01552017
*                                                                  000D 01556017
         ENTRY IES00910                                                 01560000
         USING CXDATA,6                                                 01580000
         USING *,15                                                     01600000
         ST    14,CXHLDREG              SAVE RETURN ADDR                01620000
PHSLINK  L     15,PHSADDR               LOAD PHASE ENTRY POINT ADDR     01640000
         BALR  7,15                     LINK TO USER PHASE              01660000
         USING *,7                                                      01680000
CXBASE   ST    13,CXSAVEAR+8            SAVE USER WORK REG, NON-VOLATLE 01700000
         LA    13,CXSAVEAR              LOAD SAVE AREA ADDR             01720000
         ST    5,CXSAVEAR               SAVE USER RETURN ADDR           01740000
         LA    5,CXRETURN               FORCE RETURN VIA CIOEX          01760000
         LH    2,CXRTAB(2)              DISP TO CIOEX ROUTINE           01780000
         AR    2,7                      ADD BASE REG                    01800000
SPECRTRN BR    2                        BRANCH TO CIOEX ROUTINE WANTED  01820000
***********************************************                         01840000
*RETURN VIA CIOEX TO RESTORE WORK REG 13                                01860000
***********************************************                         01880000
CXRETURN L     13,CXSAVEAR+8            RESTORE USER WORK REG 13        01900000
         L     5,CXSAVEAR               RESTORE USER RETURN ADDRESS     01920000
DUMRTRN  BR    5                        RETURN TO USER                  01940000
***********************************************                         01960000
*TABLE OF DISPLACEMENTS TO CIOEX ROUTINES FROM BASE REG ADDRESS         01980000
***********************************************                         02000000
CXRTAB   DC    AL2(GETCMP-CXBASE)       GET COMPRESSION      ROUTINE 0  02020000
         DC    AL2(PUTCMP-CXBASE)       PUT COMPRESSION      ROUTINE 2  02040000
         DC    AL2(PHSCAL-CXBASE)       PHASE CALL           ROUTINE 4  02060000
         DC    AL2(PNTERR-CXBASE)       PRINT ERROR NOTE     ROUTINE 6  02080000
         DC    AL2(PNTSPC-CXBASE)       PRINT SPEC           ROUTINE 8  02100000
         DC    AL2(RDSPEC-CXBASE)       READ SPEC            ROUTINE 10 02120000
         DC    AL2(PUTCOD-CXBASE)       PUNCH/GO OUTPUT      ROUTINE 12 02140000
         DC    AL2(SWITCH-CXBASE)       SWITCH WKFIL1,WKFIL2 ROUTINE 14 02160000
         DC    AL2(PTCMPR-CXBASE)       POINT COMP FOR READ  ROUTINE 16 02180000
         DC    AL2(RLDOUT-CXBASE)       WRITE RLD            ROUTINE 18 02200000
         DC    AL2(RLDIN-CXBASE)        READ RLD             ROUTINE 20 02220000
         DC    AL2(PTRLDW-CXBASE)       POINT RLD FOR WRITE  ROUTINE 22 02240000
         DC    AL2(BLKOUT-CXBASE)       WRITE BLANK AFTER    ROUTINE 24 02260000
         DC    AL2(BLKIN-CXBASE)        READ BLANK AFTER     ROUTINE 26 02280000
         DC    AL2(PTBLKW-CXBASE)       POINT BLKAFTR, WRITE ROUTINE 28 02300000
         DC    AL2(PNTINP-CXBASE)       POINT FIRST INPUT SP ROUTINE 30 02320000
         DC    AL2(PNTCLC-CXBASE)       POINT FIRST CALC SP  ROUTINE 32 02340000
         DC    AL2(PNTOUT-CXBASE)       POINT FIRST OUTPT SP ROUTINE 34 02360000
         DC    AL2(NOTEIN-CXBASE)       NOTE FIRST INPUT SP  ROUTINE 36 02380000
         DC    AL2(NOTECL-CXBASE)       NOTE FIRST CALC SP   ROUTINE 38 02400000
         DC    AL2(NOTEOT-CXBASE)       NOTE FIRST OUTPUT SP ROUTINE 40 02420000
         DC    AL2(NTASGN-CXBASE)       NOTE ANY SPEC        ROUTINE 42 02440000
         DC    AL2(PTASGN-CXBASE)       POINT TO PREV NOTE   ROUTINE 44 02460000
         DC    AL2(PHDUMP-CXBASE)       DUMP WITHIN LIMITS   ROUTINE 46 02480000
         DC    AL2(PTBLKR-CXBASE)       POINT BLKAFTR, READ  ROUTINE 48 02500000
         DC    AL2(PTRLDR-CXBASE)       POINT RLD FOR READ   ROUTINE 50 02520000
PHSADDR  DC    V(IES00010)              PHASE ENTRY POINT ADDR          02540000
DADEVT   EQU   X'20'                    DEVICE TYPE CODE FOR DIRECT ACC 02560000
IES00910 EQU   CXBASE                                                   02580000
***********************************************                         02600000
*COMMON READ/WRITE/CHECK ROUTINE FOR ALL FILES                          02620000
***********************************************                         02640000
READ     MVI   TYPE,X'80'               SET FOR READ SF                 02660000
         B     *+8                                                      02680000
WRITE    MVI   TYPE,X'20'               SET FOR WRITE SF                02700000
         LA    1,DECB                   LOAD DECB ADDR                  02720000
         STM   14,15,8(1)               STORE DCB ADDR AND AREA ADDR    02740000
         L     15,48(0,14)              LOAD DCB OFFSET                 02760000
         BALR  14,15                    LINK FOR READ/WRITE             02780000
*        CHECK DECB                                                     02800000
         LA    1,DECB                   LOAD DECB ADDR                  02820000
         L     14,8(0,1)                LOAD DCB ADDR                   02840000
         L     15,52(0,14)              LOAD CHECK ROUT ADDR            02860000
         LR    14,2                     SET FOR DIRECT RETURN TO USER   02880000
         BALR  2,15                     LINK TO CHECK                   02900000
***********************************************                         02920000
*LINKAGE TO EOF ROUTINE                                                 02940000
***********************************************                         02960000
         B     RDSPECA                                                  02980000
***********************************************                         03000000
*SYNCHRONOUS ERROR ROUTINE                                              03020000
***********************************************                         03040000
         MVI   CXRETCDE,20              SYNCH ERROR RETURN CODE         03060000
         MVC   CXPHSNAM(8),TERMPHS      SET TO CALL TERMINAL PHASE      03080000
         B     PHSCALC                  CLOSE FILES AND RETURN TO SUPV  03100000
TERMPHS  DC    C'RPG10250'              PHASE NAME FOR TERMINAL PHASE   03120000
***********************************************                         03140000
*COMMON DECB FOR ALL FILES                                              03160000
***********************************************                         03180000
DECB     DC    F'0'                     EVENT CONTROL BLOCK             03200000
OPFLD    DC    X'00'                    OP FIELD                        03220000
TYPE     DC    X'00'                    READ/WRITE SF                   03240000
LENGFLD  DC    AL2(0)                   LENGTH FIELD                    03260000
DCBADDR  DC    A(0)                     DCB ADDRESS                     03280000
AREADDR  DC    A(0)                     AREA ADDRESS                    03300000
         DC    A(0)                     POINTER TO STATUS INDICATORS    03320000
***********************************************                         03340000
*PHASE CALL ROUTINE                                                     03360000
***********************************************                         03380000
*TEST IF NEXT PHASE IS DIAGNOSTIC 1                                     03400000
*IF YES, FREEMAIN ALL TABLES                                            03420000
***********************************************                         03440000
PHSCAL   CLC   CXPHSNAM+5(3),PHSCALB    IS PHASE NAME DIAGNOSTIC 1      03460000
         BNE   PHSCALC                  NO                              03480000
         LA    14,680                   LENGTH OF RESULT IND TABLE      03500000
         A     14,CXFLDLEN                      + FIELD NAME TABLE      03520000
         A     14,CXLITLEN                      + LITERAL TABLE         03540000
         A     14,CXCMPEXT                      + COMPRESSION           03560000
         ST    14,CXFLDADD                      = TOTAL TABLES          03580000
         LA    9,CXRIADDR               BEG ADDR OF TABLES              03600000
         FREEMAIN V,A=(9)               FREE TABLES                     03620000
         B     PHSCALC                  CALL DIAG 1                     03640000
PHSCALB  DC    C'190'                   NUMERIC PORTION OF DIAGNOSTIC 1 03660000
***********************************************                         03680000
*XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA                            03700000
***********************************************                         03720000
PHSCALC  LR    12,6                     REINIT REG 12 TO CIOEX DATA AR  03740000
         L     14,CXHLDREG              RESTORE RETURN ADDR             03760000
         LA    9,CXPHSNAM                                               03780000
         XCTL  EPLOC=(9)                CALL NEXT PHASE                 03800000
***********************************************                         03820000
*ERROR NOTE ROUTINE                                                     03840000
***********************************************                         03860000
PNTERR   PACK  CXDUBLWD(8),PNTRAREA+96(3)                               03880000
         CVB   14,CXDUBLWD              CONVERT NOTE NUMBER TO BINARY   03900000
         LA    15,7                     MASK FOR REMAINDER              03920000
         NR    15,14                    PICK OFF REMAINDER              03940000
         SRL   14,3                     DIVIDE NOTE NUMBER BY 8         03960000
         LA    2,256                    INIT BIT TO TURN ON ERROR NOTE  03980000
         LA    15,1(15)                 INCR REMAINDER FOR BCT INSTR    04000000
PNTERRA  SRL   2,1                      ADJUST BIT TO CORRESP TO REMAIN 04020000
         BCT   15,PNTERRA                                               04040000
         IC    15,CXNOTES(14)           PICK UP ERROR NOTE BYTE         04060000
         OR    15,2                     TURN ON BIT CORRESP TO ERR NOTE 04080000
         STC   15,CXNOTES(14)           STORE UPDATED ERROR NOTE BYTE   04100000
         MVC   PNTRAREA+93(3),PNTERRB   MOVE 'IES' TO PRINT BUFF        04120000
         MVI   PNTRAREA+99,C'I'         INSERT INFORMATION IDENT        04140000
         B     PRNTLINE                                            000A 04160016
PNTERRB  DC    C'IES'                   OS/RPG PREFIX                   04180000
***********************************************                         04200000
*PRINT SPECIFICATION                                                    04220000
***********************************************                         04240000
SEQCHK   CLC   PNTRAREA+13(6),CXSEQCHK COMP PRESENT NO TO PREVIOUS 000A 04243016
         BNH   WRNGSEQ                 OUT OF SEQ, B TO ERROR      000A 04246016
         MVC   CXSEQCHK(6),PNTRAREA+13 PRESENT PAGE/LINE TO OLD NO 000A 04249016
         B     PRNTLINE                IN SEQUENCE, PRINT SPEC     000A 04252016
WRNGSEQ  MVI   PNTRAREA+11,C'S'        FLAG SPEC  AS SEQ ERROR     000A 04255016
         MVC   PNTRAREA+96(3),ERNUM65  SET UP FOR ERROR NOTE RTN   000A 04258016
         MVC   CXSEQCHK(6),PNTRAREA+13   PRESENT PAGE/LINE TO OLD  000A 04261016
         B     PNTERR                  PRINT MESSAGE(FLAG), SPEC   000A 04264016
PNTSPC   TM    CXCMPOPT,X'08'          TEST FOR SEQ CHK OPT        000A 04267016
         BO    SEQCHK                  CHK FOR SEQUENCING          000A 04270016
PRNTLINE TM    CXCMPOPT,X'04'          CHK FOR LIST OPT            000A 04273016
         BCR   1,5                        RETURN TO USER                04280000
*        WRITE DECB,SF,LSTFIL,PNTRARAC                                  04300000
         L     14,CXDCBLST              LOAD LIST FILE DCB ADDR AND     04320000
         LA    15,PNTRARAC                   PRINT BUFFER ADDR W/CTL CH 04340000
         BAL   2,WRITE                  LINK FOR WRITE                  04360000
         MVI   PNTRAREA,C' '            CLEAR                           04380000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT BUFFER                  04400000
***********************************************                         04420000
*TAKE CARE OF CARRIAGE CONTROL, OVERFLOW AND HEADING                    04440000
***********************************************                         04460000
         CLI   PNTRARAC,C'0'            WAS DOUBLE SPACE SPECIFIED      04480000
         BNE   *+10                     NO                              04500000
         SP    CXLINBCT(2),CXONEPCK     YES, DECR LINE COUNT ONE EXTRA  04520000
         MVC   PNTRARAC(1),PNTSPCA      SET CONTROL CHAR FOR NEXT PRINT 04540000
         MVI   PNTSPCA,C' '             SET FOR SING SP, NEXT PRINT + 1 04560000
         SP    CXLINBCT(2),CXONEPCK     DECREMENT LINE COUNT            04580000
         BCR   2,5                      IF POSITIVE RETURN TO USER      04600000
         MVI   PNTRARAC,C'1'            SET CONTROL CHAR FOR PAGE EJECT 04620000
         MVC   CXLINBCT(2),CXLINCNT     INIT LINE COUNT - 52 LINES      04640000
         AP    CXPAGNUM(4),CXONEPCK     INCR PAGE NUMBER                04660000
         UNPK  PNTRAREA+96(4),CXPAGNUM(4) PLACE PAGE NUM IN PRINT AREA  04680000
         OI    PNTRAREA+99,X'F0'        ERASE PLUS SIGN                 04700000
         MVC   PNTRAREA+91(4),PNTSPCB   MOVE 'PAGE' INTO PRINT BUFF     04720000
         MVC   PNTRAREA+70(8),CXTODAY   MOVE IN DATE                    04740000
         MVC   PNTRAREA+50(8),CXSTEPNA  MOVE IN STEP NAME               04760000
         MVC   PNTRAREA+40(8),CXJOBNAM  MOVE IN JOB NAME                04780000
         MVC   PNTRAREA+5(17),CXHEADIN  MOVE IN RPG/E IDENT             04800000
         MVI   PNTSPCA,C'0'             SET FOR DOUB SP, NEXT PRINT + 1 04820000
         B     PRNTLINE                                            000A 04840016
PNTSPCA  DC    C' '                     SINGLE SPACE                    04860000
PNTSPCB  DC    C'PAGE'                                                  04880000
ERNUM65  DC    C'065'                  ERR NUMBER FOR SEG CHK RRR  000A 04890016
***********************************************                         04900000
*READ A SPECIFICATION FROM SYSIPT                                       04920000
***********************************************                         04940000
*        READ  DECB,SF,SRCFIL,RDRPCHAR                                  04960000
RDSPEC   ST    5,RDSPSAVE               SAVE RETURN REGISTER       3142 04963015
         L     15,CXDBLKAD              GET ADDR OF RESIDENT       3142 04966015
         BALR  5,15                      DEBLK RTN & GO THERE      3142 04969015
*                                                                  3142 04972015
*   THE FOLLOWING LINKAGE VECTOR IS USED BY THE RESIDENT           3142 04975015
*   DEBLOCK ROUTINE TO RETURN TO CIOEX AND TAKE CORRECT ACTION     3142 04978015
*   FOR HANDLING OF BLOCKED SOURCE RECORDS FROM SYSIN              3142 04981015
*                                                                  3142 04984015
         B     READEXIT                 RECORD MOVED TO WK AREA    3142 04987015
         B     READBLK                  READ A BLK & RETURN        3142 04990015
         B     RDSPECA                  EOF IN DEBLK RTN           3142 04993015
*                                                                  3142 04996015
*   THE FOLLOWING ROUTINES ARE CALLED FROM THE RESIDENT            3142 04999015
*   DEBLOCK ROUTINE THRU THE LINKAGE VECTOR ABOVE                  3142 05002015
*                                                                  3142 05005015
READEXIT L     5,RDSPSAVE               RESTORE RETURN REGISTER    3142 05008015
         BR    5                        RETURN TO CALLER           3142 05011015
*                                                                  3142 05014015
READBLK  L     14,CXDCBSRC              LOAD SOURCE DCB ADDR &     3142 05017015
         L     15,CXINAREA               SOURCE BUFFER ADDR        3142 05020015
         BAL   2,READ                   LINK TO READ A BLOCK       3142 05023015
         L     5,RDSPSAVE               RESTORE RETURN REGISTER    3142 05026015
         B     RDSPEC                   GO DEBLOCK FROM NEW BLOCK  3142 05029015
*                                                                  3142 05032015
RDSPSAVE DS    F                        RETURN REG SAVE AREA       3142 05035015
*                                                                  3142 05038015
***********************************************                         05060000
*EOF ROUTINE                                                            05080000
***********************************************                         05100000
RDSPECA  MVC   PNTRAREA+96(3),RDSPECD   ERROR NOTE 255 TO PRINT AREA    05120000
         BAL   5,PNTERR                 PRINT ERROR NOTE                05140000
         MVC   CXPHSNAM(8),RDSPECC      SET TO CALL DIAG 1              05160000
         B     PHSCAL                   CALL DIAG 1                     05180000
RDSPECC  DC    C'RPG10190'              PHASE NAME FOR DIAG 1           05200000
RDSPECD  DC    C'255'                   ERROR NOTE 255                  05220000
*                                                                  000D 05225017
         ORG   PRECIOEX+1524           PAD PHASE TO 1.5K           I173 05230018
*                                                                  000D 05235017
GETCMP   EQU   DUMRTRN                                                  05240000
PUTCMP   EQU   DUMRTRN                                                  05260000
PUTCOD   EQU   DUMRTRN                                                  05280000
SWITCH   EQU   DUMRTRN                                                  05300000
PTCMPR   EQU   DUMRTRN                                                  05320000
RLDOUT   EQU   DUMRTRN                                                  05340000
RLDIN    EQU   DUMRTRN                                                  05360000
PTRLDW   EQU   DUMRTRN                                                  05380000
BLKOUT   EQU   DUMRTRN                                                  05400000
BLKIN    EQU   DUMRTRN                                                  05420000
PTBLKW   EQU   DUMRTRN                                                  05440000
PNTINP   EQU   DUMRTRN                                                  05460000
PNTCLC   EQU   DUMRTRN                                                  05480000
PNTOUT   EQU   DUMRTRN                                                  05500000
NOTEIN   EQU   DUMRTRN                                                  05520000
NOTECL   EQU   DUMRTRN                                                  05540000
NOTEOT   EQU   DUMRTRN                                                  05560000
NTASGN   EQU   DUMRTRN                                                  05580000
PTASGN   EQU   DUMRTRN                                                  05600000
PHDUMP   EQU   DUMRTRN                                                  05620000
PTBLKR   EQU   DUMRTRN                                                  05640000
PTRLDR   EQU   DUMRTRN                                                  05660000
***********************************************                         05680000
*CIOEX DATA AREA                                                        05700000
***********************************************                         05720000
CXDATA   DSECT                                                          05740000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       05760000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 05780000
*                                         (START WITH PREPHASE)         05800000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 05820000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       05840000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   05860000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     05880000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     05900000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     05920000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        05940000
CXFLDADD DS    F                                FIELD NAME TABLE        05960000
CXLITADD DS    F                                LITERAL TABLE           05980000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 06000000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     06020000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      06040000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   06060000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                06080000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      06100000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         06120000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      06140000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    06160000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     06180000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    06200000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            06220000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    06240000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   06260000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           06280000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      06300000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  06320000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   06340000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 06360000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    06380000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         06400000
CXRETCDE DC    X'00'                    RETURN CODE                     06420000
CXIPTEOF BR    2                        LINKAGE TO EOF ROUTINE          06440000
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            06460000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          06480000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    06500000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           06520000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     06540000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    06560000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                06580000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             06600000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            06620000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     06640000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      06660000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    06680000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   06700000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        06720000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               06740000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     06760000
CXSYNERR B     4(2)                     LINKAGE TO SYNCH ERROR ROUTINE  06780000
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    06800000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     06820000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        06840000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          06860000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        06880000
CXTODAY  DC    C'  /  /  '              DATE                            06900000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             06920000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        06940000
RDRPCHAR DS    80C                      READER/PUNCH AREA               06960000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       06980000
PNTRAREA DS    120C                     PRINT AREA                      07000000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 07020000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 07040000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 07045015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 07050015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 07055015
CXSEQCHK DS    6C                       PAGE/LINE SEQUENCE CHECK   000A 07057016
CXDEND   EQU   *                                                        07060000
         END   IESCEX                                                   07080000
