         TITLE 'IES060  OS/360 RPG ENTER PHASE 4                    10' 00020000
* STATUS       CHANGE LEVEL 1-8                                  A25423 00040000
*FUNCTION/OPERATION:  ENTER PHASE 4 IS A PREPROCESSING PHASE FOR CALC   00060000
*        SPECIFICATIONS.  SPECS ARE SCANNED, LITERAL ENTRIES ARE BUILT  00080000
*        AND PRELIMINARY DIAGNOSTICS ARE MADE. SPECS CONTAINING CERTAIN 00100000
*        OP CODES (EXTCV, RPGCV, KEYCV, RLABL, ULABL, TAG, GOTO, EXIT,  00120000
*        ERPGC) ARE COMPRESSED AND THE OTHERS ARE PARTIALLY PROCESSED.  00140000
*        ALL SPECS, BOTH COMPRESSED AND PART. PROCESSED ARE PUT OUT ON  00160000
*        SYSUT3 FOR PROCESSING BY ENTER PHASE 5.                        00180000
*ENTRY POINT: IES06010 FROM IES06910                                    00200000
*INPUT:  CALCULATION SPECIFICATIONS VIA SYSIN                           00220000
*        FIELD NAME TABLE VIA POINTER IN CIOEX DATA AREA                00240000
*        RESULTING INDICATOR TABLE VIA POINTER IN CIOEX DATA AREA       00260000
*                                                                       00280000
*OUTPUT:  COMPRESSED AND PARTIALLY PROCESSED SPECS INCLUDING ERROR DATA 00300000
*        ON SYSUT3                                                      00320000
*        FIELD NAME TABLE IN CIOEX DATA AREA                            00340000
*        LITERAL TABLE IN CIOEX DATA AREA                               00360000
*        RESULTING INDICATOR TABLE IN CIOEX DATA AREA                   00380000
*                                                                       00400000
*EXTERNAL ROUTINES      IES06910 - CIOEX ROUTINES FOR ENTER PHASE 4     00420000
*        PHASCL - GET NEXT PHASE                                        00440000
*        REDSPC - READ A SPEC                                           00460000
*        WRTRLD - WRITE ON SYSUT3                                       00480000
*        RWDRLD - REWIND SYSUT3                                         00500000
*                                                                       00520000
*                                                                       00540000
*EXITS - NORMAL   VIA CIOEX PHSCAL ON LAST CALC SPEC IN SYSIN           00560000
*                                                                       00580000
*TABLES/WORKAREAS:                                                      00600000
*        RIT - RESULTING INDICATOR TABLE                                00620000
*        FLD - FIELD NAME TABLE                                         00640000
*        LIT - LITERAL TABLE                                            00660000
*        SCQ - SEQUENCE NUMBER FOR CALC SPECS                           00680000
*        SOQ - SEQUENCE NUMBER FOR OUTPUT SPECS                         00700000
*                                                                       00720000
*ATTRIBUTES:  EDITABLE,DOWNWARD COMPATIBLE                              00740000
*                                                                       00760000
*                                                                       00780000
*                                                                       00800000
IES06010 START                                                          00820000
*0141008300,125200,129000,132000-133000,134000                     7359 00826017
*0141000400,122000                                                 000D 00832017
* 023500,111880-112120                                             I173 00834000
CMPOPT   EQU   146                      COMPILER OPTION BYTE       I173 00836000
ET4      EQU   *                                                        00840000
******************************************************************      00860000
*                   CALCULATION SPECIFICATION FIELDS                    00880000
******************************************************************      00900000
FORM     EQU   5                                                        00920000
CLEV     EQU   6                                                        00940000
CONDCD   EQU   8                                                        00960000
FACT1    EQU   17                                                       00980000
OP       EQU   27                                                       01000000
FACT2    EQU   32                                                       01020000
RESFLD   EQU   42                                                       01040000
FLDLEN   EQU   48                                                       01060000
DECPOS   EQU   51                                                       01080000
HADJ     EQU   52                                                       01100000
RESIND   EQU   53                                                       01120000
******************************************************************      01140000
*              OP CODE EQUIVALENCES                                     01160000
******************************************************************      01180000
AD       EQU   X'FA'                    ADD                             01200000
ZA       EQU   X'F8'                    Z-ADD                           01220000
SB       EQU   X'FB'                    SUB                             01240000
ZS       EQU   X'F9'                    Z-SUB                           01260000
MT       EQU   X'FC'                    MULT                            01280000
DV       EQU   X'FD'                    DIV                             01300000
MR       EQU   X'FE'                    MVR                             01320000
MV       EQU   X'D2'                    MOVE                            01340000
ML       EQU   X'D6'                    MOVEL                           01360000
LH       EQU   X'D7'                    MLHZO                           01380000
HL       EQU   X'D5'                    MHLZO                           01400000
HH       EQU   X'D1'                    MHHZO                           01420000
LL       EQU   X'D3'                    MLLZO                           01440000
CP       EQU   X'DA'                    COMP                            01460000
TZ       EQU   X'DC'                    TESTZ                           01480000
GO       EQU   X'C4'                    GOTO                            01500000
TG       EQU   X'E8'                    TAG                             01520000
EX       EQU   X'C5'                    EXIT                            01540000
RL       EQU   X'E9'                    RLABL                           01560000
UL       EQU   X'EA'                    ULABL                           01580000
SO       EQU   X'C1'                    SETON                           01600000
SF       EQU   X'C3'                    SETOF                           01620000
LU       EQU   X'C8'                    LOKUP                           01640000
RV       EQU   X'C2'                    RPGCV                           01660000
EV       EQU   X'C7'                    EXTCV                           01680000
ER       EQU   X'C6'                    ERPGC                           01700000
KV       EQU   X'EB'                    KEYCV                           01720000
******************************************************************      01740000
*              REGISTER ASSIGNMENTS                                     01760000
******************************************************************      01780000
GR1      EQU   1                        SYSTEM REGISTER                 01800000
SERVRG   EQU   2                        SERVICE REGISTER                01820000
CMPREG   EQU   3                        COMPRESSION REGISTER            01840000
RDREG    EQU   4                        CONTAINS ADDR OF READ AREA      01860000
LNKREG   EQU   5                        LINKAGE REGISTER                01880000
GR7      EQU   7                        LINKAGE REGISTER                01900000
BASREG   EQU   8                        BASE REGISTER                   01920000
WKREG    EQU   9                        WORK REGISTER                   01940000
PNTREG   EQU   10                       CONTAINS ADDR OF PRINT AREA     01960000
GR11     EQU   11                       WORK REGISTER                   01980000
GR12     EQU   12                       ADDR OF INTERFACE TABLES        02000000
GR13     EQU   13                       WORK REGISTER                   02020000
GR14     EQU   14                       WORK REGISTER                   02040000
GR15     EQU   15                       WORK REGISTER                   02060000
*                                                                       02080000
******************************************************************      02100000
*              DISPLACEMENTS TO INTERFACE STORAGE AREAS                 02120000
******************************************************************      02140000
RIT      EQU   X'28'                    R. I. TABLE  ADDR               02160000
FLD      EQU   X'2C'                    FIELD NAME TABLE ADDR           02180000
LIT      EQU   X'30'                    LIT. TABLE ADDR                 02200000
PSN      EQU   8                        PHASE NAME HOLDING AREA         02220000
SCQ      EQU   X'A6'                    SEQ NO FOR CALCS FOUND HERE     02240000
SOQ      EQU   X'AA'                    SEQ NO FOR OUTPUTS STORED HERE  02260000
PHASCL   EQU   4                        SERVICE ROUTINE NO TO GET PHASE 02280000
REDSPC   EQU   10                       SERV ROUTINE TO READ A SPEC     02300000
WRTRLD   EQU   18                       SERV ROUTINE TO WRITE WRKFIL3   02320000
RWDRLD   EQU   22                       SERV ROUTINE TO REWIND WRKFIL3  02340000
******************************************************************      02360000
*                                                                       02380000
         EXTRN IES06910                                                 02400000
ENTER4   BALR  BASREG,0                                                 02420000
*                                                                       02440000
         USING *,BASREG                 BASE REG 8 FOR ENTER 4     000Z 02460017
         L     GR7,CXRADDR                                         000Z 02480017
         MVC   PSN(8,GR12),ASSN1                                   000Z 02500017
******************************************************************      02520000
*              THIS ROUTINE MOVES A SPEC TO THE OUTPUT BUFFER           02540000
*              AND DETERMINES SPECIFICATION TYPE                        02560000
******************************************************************      02580000
BEGIN    LR    WKREG,GR12                                               02600000
         MVI   TOTSW,X'00'                                              02620000
         ST    GR7,SAVSEV                                               02640000
START    MVC   RLDBUF(80),0(RDREG)                                      02660000
         MVI   IBYT,X'00'               CLEAR INFORMATION AND ERROR     02680000
         MVC   ERBYT(2),DUMCMP          BYTES                           02700000
         CLI   FORM(RDREG),C'O'         IF OUTPUT GO SETUP FOR ENTER 5  02720000
         BE    CALFIV                                                   02740000
         CLI   CLEV(RDREG),C'*'         WRITE OUT COMMENT, GET NEXT     02760000
         BE    ENDSPC                   SPEC                            02780000
         CLI   FORM(RDREG),C'C'         IF CALC SPEC, START SCAN        02800000
         BE    TSTLEV                                                   02820000
         OI    ERBYT,X'01'              NONE OF ABOVE, SET BIT FOR      02840000
         B     ERROUT                   INVALID SPEC TYPE               02860000
TSTLEV   CLI   CLEV(RDREG),C' '                                         02880000
         BE    TSTDSW                                                   02900000
SETOTL   MVI   TOTSW,X'FF'                                              02920000
         B     SCNSPC                   IS IN SEQ. IF YES, CONTINUE     02940000
TSTDSW   CLI   TOTSW,X'FF'              IF NO, SET ERR. BIT AND DROP    02960000
         BNE   SCNSPC                   SPEC                            02980000
         OI    ERBYT+1,X'08'                                            03000000
         B     ERROUT                                                   03020000
*                                                                       03040000
******************************************************************      03060000
*              THIS ROUTINE  SETS UP THE FACTOR SCAN FOR F1, F2,        03080000
*              AND THE RESULT FIELD. SWITCHES ARE SET TO INDICATE       03100000
*              WHETHER A FACTOR IS A LITERAL OR A FIELD NAME.           03120000
******************************************************************      03140000
SCNSPC   MVI   ABYT,X'00'               CLEAR ALPHA BYTE                03160000
         ST    RDREG,REGSAV             SAVE ADDR IN WD-ALIGNED STORAGE 03180000
         MVI   FACTSW,X'00'                                             03200000
         MVI   SCNSW,X'00'                                              03220000
         LA    GR11,FACT1(RDREG)        POINT TO FACTOR1 FIELD          03240000
         CLI   OP(RDREG),C'G'      IS OP A GOTO                  A33633 03245000
         BNE   NOTGO                                             A33633 03250000
         MVI   0(GR11),X'40'       PUT BLANK IN FACT 1           A33633 03255000
NOTGO    BAL   GR14,FACSCN                                       A33633 03265000
         TM    SCNSW,X'20'              WAS IT A VALID FIELD NAME       03280000
         BO    SETF1F                                                   03300000
         TM    SCNSW,X'80'              NO IS IT NUMERIC LITERAL        03320000
         BO    SETF1L                                                   03340000
         TM    SCNSW,X'40'              NO IS IT AN ALPHA LITERAL       03360000
         BZ    TFACT2                                                   03380000
SETF1L   OI    FACTSW,X'40'             SET SW FOR F1 EQ. A LITERAL     03400000
         MVC   F1COMP(12),WKCOMP        MOVE LIT TO PERMANENT STORAGE   03420000
         B     TFACT2                                                   03440000
SETF1F   OI    FACTSW,X'80'                                             03460000
TFACT2   LA    RDREG,15(RDREG)                                          03480000
         MVI   SCNSW,X'00'              CLEAR SW FOR THIS SCAN          03500000
         LA    GR11,FACT1(RDREG)                                        03520000
         BAL   GR14,FACSCN                                              03540000
         TM    SCNSW,X'20'              IS IT A FIELD NAME              03560000
         BO    SETF2F                                                   03580000
         TM    SCNSW,X'80'              NO- NUMERIC LITERAL             03600000
         BO    SETF2L                                                   03620000
         TM    SCNSW,X'40'              NO- ALPHA LITERAL               03640000
         BZ    RESFD                                                    03660000
SETF2L   OI    FACTSW,X'04'             SET SW FOR F2 EQ A LITERAL      03680000
         MVC   F2COMP(12),WKCOMP        MOVE LIT TO PERMANENT STORAGE   03700000
         B     RESFD                                                    03720000
SETF2F   OI    FACTSW,X'08'             SET SW FOR F2 EQ A FIELD NAME   03740000
RESFD    LA    RDREG,10(RDREG)          POINT TO RESULT FIELD           03760000
         MVI   SCNSW,X'10'              INDICATE FIELD ONLY 6 POS LONG  03780000
         LA    GR11,FACT1(RDREG)                                        03800000
         BAL   GR14,FACSCN              GO SCAN RESULT  FIELD           03820000
         TM    SCNSW,X'20'                                              03840000
         BZ    GETFOR                                                   03860000
         OI    FACTSW,X'01'                                             03880000
GETFOR   L     RDREG,REGSAV                                             03900000
******************************************************************      03920000
*              THIS ROUTINE SCANS THE OP CODE TABLE, CALCULATES         03940000
*              THE ADDRESS OF THE OP CODE ROUTINE AND BRANCHES          03960000
*              TO IT.                                                   03980000
******************************************************************      04000000
OPCODE   LA    GR11,OPSYM               GET FWA OF OP TABLE             04020000
         LA    GR13,195                                                 04040000
         AR    GR13,GR11                                                04060000
         LA    GR12,7                   INCREMENT COUNT BY 7            04080000
TSTOP    CLC   OP(5,RDREG),0(GR11)                                      04100000
         BE    OPFIND                                                   04120000
         BXLE  GR11,GR12,TSTOP                                          04140000
         OI    ERBYT,X'10'              IF OP NOT FOUND SET BIT FOR     04160000
         B     ERROUT                   INVALID OP AND EXIT             04180000
OPFIND   MVC   N(2),5(GR11)             MOVE ADCON TO H-WD ALIGNED AREA 04200000
         LH    GR12,N                                                   04220000
         B     START(GR12)              BRANCH TO OP CODE ROUTINE       04240000
*                                                                       04260000
******************************************************************      04280000
*              THIS ROUTINE WILL SCAN ANY OF THE FACTOR FIELDS AND      04300000
*              THE RESULT FIELD AND UPON RECOGNITION OF KEY CHARACTERS  04320000
*              IN THE FIRST POSITION WILL BRANCH OUT TO EITHER THE      04340000
*              ALPHA LIT., NUMERIC LIT., OR FIELD NAME  ROUTINES        04360000
*              LINKAGE TO THIS ROUTINE IS BY GR14                       04380000
******************************************************************      04400000
DECNT    EQU   GR12                                                     04420000
DIGCNT   EQU   GR13                                                     04440000
*                                                                       04460000
FACSCN   SR    DECNT,DECNT                                              04480000
         SR    DIGCNT,DIGCNT                                            04500000
         CLI   0(GR11),C' '                                             04520000
         BE    FACEXT                                                   04540000
         CLI   0(GR11),C''''            IF QUOTE, GO SCAN FIELD FOR     04560000
         BNE   TSPLUS                   ALPHA LITERAL                   04580000
         MVI   PAKSW,X'00'                                              04600000
         BAL   GR15,ALFSCN                                              04620000
         B     FACEXT                                                   04640000
TSPLUS   CLI   0(GR11),C'+'             IF 1ST CHARACTER IS +, -, ., ,, 04660000
         BE    SETDGT                   OR VALID DIGIT, SET UP A        04680000
         CLI   0(GR11),C'-'             DIGIT CNTR., A DEC. CNTR., AND  04700000
         BNE   TSDCPT                   BRANCH TO SCAN FIELD FOR        04720000
         MVI   MINSW,X'FF'              NUMERIC LITERAL.                04740000
         B     SETDGT                                                   04760000
TSDCPT   CLI   0(GR11),C'.'                                             04780000
         BE    SETNUM                                                   04800000
         CLI   0(GR11),C','                                             04820000
         BNE   TSDIGT                                                   04840000
SETNUM   MVI   DECSW,X'FF'                                              04860000
SETDGT   MVI   PAKSW,X'00'                                              04880000
CALNUM   BAL   GR15,NUMSCN                                              04900000
         B     FACEXT                                                   04920000
TSDIGT   CLI   0(GR11),C'0'                                             04940000
         BL    CALFLN                                                   04960000
         CLI   0(GR11),C'9'                                             04980000
         BNH   STNUM                    IF 1ST CHAR IS GR. THAN 9,      05000000
         MVI   0(GR11),C' '             FIELD IS INVALID. STORE A       05020000
         B     FACEXT                   BLANK IN FIRST POSITION AND     05040000
STNUM    LA    DIGCNT,1(DIGCNT)         EXIT                            05060000
         BAL   LNKREG,FORPAK            IF CHAR IS LESS THAN F0 BUT NOT 05080000
         B     CALNUM                   EQUAL TO THOSE PREVIOUSLY       05100000
CALFLN   BAL   GR15,VERFLN              TESTED, GO SCAN FIELD FOR A     05120000
FACEXT   BCR   15,GR14                  FIELD NAME ENTRY.               05140000
*                                                                       05160000
******************************************************************      05180000
*              THIS ROUTINE SCANS F1 OR F2 FOR A VALID NUMERIC          05200000
*              THIS ROUTINE SCANS F1 OR F2 FOR A VALID NUMERIC          05220000
*              LITERAL. DIGITS ARE PACKED WITH VALID SIGN NOTATION      05240000
*              IN WKCOMP. THE ENTIRE LITERAL IS FORMED IN THIS AREA     05260000
*              AND IS IN THE FORMAT OF  NDLITERAL ENTRYLDF  WHERE       05280000
*                                                                       05300000
*                        N=LENGTH OF ENTRY+2(HEX)                       05320000
*                        D=DEC. POS.(UNPACKED NUMBER)                   05340000
*                        L=NO. OF DIGITS IN ORIGINAL UNPACKED ENTRY     05360000
*                        F=PAD CHARACTER TO FILL OUT LIT FIELD(HEX FF)  05380000
*                                                                       05400000
*              LINKAGE TO THIS ROUTINE IS BY GR15                       05420000
******************************************************************      05440000
NUMSCN   NI    SCNSW,X'7F'              CLEAR NUM. LIT. SW.             05460000
         LA    GR7,9                    SET UP LOOP TO TEST REST OF     05480000
NUMSET   LCR   GR11,GR7                                                 05500000
         LA    GR11,9(GR11)                                             05520000
         LA    GR11,FACT1+1(GR11,RDREG) POINT TO 2ND POSITION           05540000
         CLI   0(GR11),C'0'             IF VALID DIGIT, BUMP DIGIT      05560000
         BL    TDECPT                   CNT. AND MOVE DIGIT TO A PACK   05580000
         CLI   0(GR11),C'9'             AREA.                           05600000
         BH    NUMEXT                                                   05620000
         LA    DIGCNT,1(DIGCNT)         POINT. IF GR THAN 9, LITERAL IS 05640000
         CLI   PAKSW,X'FF'              INVALID                         05660000
         BNE   INTPAK                                                   05680000
         BAL   LNKREG,MOVPAK                                            05700000
         B     TDECSW                                                   05720000
INTPAK   BAL   LNKREG,FORPAK                                            05740000
TDECSW   CLI   DECSW,X'FF'              IF DEC. POINT ALREADY NOTED,    05760000
         BNE   NMLOOP                   BUMP DEC POS. CTR.              05780000
         LA    DECNT,1(DECNT)                                           05800000
         B     NMLOOP                                                   05820000
TDECPT   CLI   0(GR11),C'.'             IF CHAR IS NOT DEC PT OR COMMA  05840000
         BE    SDECSW                   AND IS NOT A DIGIT, TEST FOR    05860000
         CLI   0(GR11),C','             BLANK.                          05880000
         BNE   BLKCHK                                                   05900000
SDECSW   CLI   DECSW,X'FF'              IF 2 DECIMAL SYMBOLS            05920000
         BE    NUMEXT                    ENCOUNTERED, LITERAL INVALID   05940000
         MVI   DECSW,X'FF'                                              05960000
         B     NMLOOP                                                   05980000
BLKCHK   SH    GR7,H1                                                   06000000
         EX    GR7,TBLANK               IF REST OF FLD IS BLANK, GO     06020000
         BE    BLDNUM                   BUILD LITERAL. IF NOT, FIELD    06040000
         B     NUMEXT                   POSITION OF FIELD AND EXIT      06060000
NMLOOP   BCT   GR7,NUMSET                                               06080000
*                                                                       06100000
*              THIS PORTION OF THE ROUTINE BUILDS THE LITERAL ENTRY     06120000
*                                                                       06140000
BLDNUM   LTR   DIGCNT,DIGCNT            IF NO LENGTH FOR LITERAL, EXIT  06160000
         BZ    NUMEXT                                                   06180000
         MVC   WKCOMP(12),FFS           INITIALIZE WORK AREA WITH NUM.  06200000
         MVC   N(2),DUMCMP                                              06220000
         STC   DECNT,SAVDEC             PAD CHAR. SAVE NO. OF DEC. POS. 06240000
         STH   DIGCNT,SAVDGT            SAVE NO. OF DIGITS IN ORIGINAL  06260000
         SRL   DIGCNT,1                 ENTRY. FORM PACKED LENGTH AND   06280000
         AH    DIGCNT,H1                SAVE. MINIMUM PACKED LEN. IS 3  06300000
         STH   DIGCNT,PAKDGT            IF LESS LEN IS SET TO 3 AND N   06320000
         CH    DIGCNT,H3                TO 5                            06340000
         MVI   WKCOMP,X'05'                                             06360000
         MVI   N+1,X'05'                                                06380000
         BL    TDSW                                                     06400000
         AH    DIGCNT,H2                PACKED LEN IS GR OR EQ TO 3,    06420000
         STH   DIGCNT,N                 ADD 2 TO FORM N AND SAVE        06440000
         MVC   WKCOMP(1),N+1            MOVE N TO LIT WK-AREA           06460000
TDSW     MVZ   SAVDEC(1),C8             MOVE F-ZONE TO DEC POS AND      06480000
         MVC   WKCOMP+1(1),SAVDEC       STORE AS 2ND ENTRY              06500000
         MVZ   0(1,SERVRG),CIN          MOVE C-ZONE FOR POS. LIT.       06520000
         CLI   MINSW,X'FF'                                              06540000
         BNE   PACKDG                   IF LIT. IS NEG., MOVE D-ZONE    06560000
         MVZ   0(1,SERVRG),ENT5+1                                       06580000
PACKDG   SR    GR12,GR12                FORM 2 LENGTHS IN 1 BYTE        06600000
         LH    GR12,PAKDGT              GET PACKED LENGTH AND MOVE IT   06620000
         SLL   GR12,4                   TO L1 POS. ADD UNPACKED LENGTH  06640000
         AH    GR12,SAVDGT              FOR L2. SUBTRACT 1 FROM EACH    06660000
         SH    GR12,H17                 LENGTH AND EXECUTE A PACK. DIG. 06680000
         EX    GR12,DOPACK              IN PACKAR PACKED INTO LIT WORK  06700000
         STC   GR12,SAVDGT+1            AREA. MOVE UNPACKED LEN-1 BACK  06720000
         NI    SAVDGT+1,X'0F'                                           06740000
         LA    GR7,WKCOMP               TO STORAGE. POSITION PTR. N     06760000
         AH    GR7,N                    BYTES FROM WKCOMP (PAST N, DEC. 06780000
         MVC   0(1,GR7),SAVDGT+1        POS., PACKED LIT. ENTRY). STORE 06800000
         MVC   1(1,GR7),SAVDEC          NO. UNPACKED DIGITS-1 AND DEC   06820000
         OI    SCNSW,X'80'              POS. SET SW FOR NUMERIC LIT.    06840000
NUMEXT   MVI   DECSW,X'00'                                              06860000
         MVI   MINSW,X'00'                                              06880000
         BCR   15,GR15                                                  06900000
*                                                                       06920000
*   THE FOLLOWING INSTRUCTION IS EXECUTED BY INSTRUCTIONS FOLLOWING000Z 06926017
*   THE LABEL 'PACKDG' TO PACK A DIGIT INTO A WORK AREA            000Z 06932017
DOPACK   PACK  WKCOMP+2(0),PACKAR(0)                                    06940000
*                                                                       06960000
*   FOLLOWING INSTRUCTION IS EXECUTED BY INSTRUCTIONS FOLLOWING    000Z 06966017
*   THE LABELS 'BLKCHK', 'ALFBLK' AND 'BLKFLD'                     000Z 06972017
TBLANK   CLC   0(0,GR11),BLANKS                                         06980000
*                                                                       07000000
FORPAK   LA    SERVRG,PACKAR-1          INITIALIZE PACK AREA            07020000
MOVPAK   LA    SERVRG,1(SERVRG)                                         07040000
         MVC   0(1,SERVRG),0(GR11)      MOVE CHAR FROM SPEC             07060000
         MVI   PAKSW,X'FF'                                              07080000
         BCR   15,LNKREG                                                07100000
*                                                                       07120000
******************************************************************      07140000
*              THIS ROUTINE SCANS A F1 OR F2 FOR EMBEDDED (DOUBLE)      07160000
*              AND END QUOTES. ALL CHARACTERS ARE VALID IN ALPHA        07180000
*              LITERALS. ALPHA LIT. BUILT IN SAME MANNER AS NUM.        07200000
*              LITERAL.                                                 07220000
******************************************************************      07240000
LITCNT   EQU   GR12                                                     07260000
*                                                                       07280000
ALFSCN   NI    SCNSW,X'BF'              CLEAR ALPHA LIT. SWITCH AND     07300000
         SR    LITCNT,LITCNT            CHAR. CNT. REGISTER             07320000
         CLI   1(GR11),C''''            IS 2ND POS EQ QUOTE             07340000
         BE    QUOT2                                                    07360000
         LA    GR7,9                    NO, SET SCAN OF 9 POS           07380000
         B     STLOOP                                                   07400000
QUOT2    CLI   2(GR11),C''''            YES, 3RD MUST BE QUOTE          07420000
         BNE   ALFEXT                                                   07440000
         LA    GR7,8                                                    07460000
         B     LOOP                                                     07480000
STLOOP   LCR   GR11,GR7                                                 07500000
         LA    GR11,9(GR11)                                             07520000
         LA    GR11,FACT1+1(GR11,RDREG) MOVE PTR. TO NEXT CHARACTER     07540000
         CLI   0(GR11),C''''            IF QUOTE, TEST FOR ANOTHER      07560000
         BNE   LOOP                     IF NOT, GO STORE CHAR           07580000
         CLI   1(GR11),C''''            QUOTE FOUND, IS THIS A QUOTE    07600000
         BNE   ALFBLK                   IF NOT TEST REST OF FLD FOR     07620000
         LA    SERVRG,1(SERVRG)         BLANKS.                         07640000
         MVC   0(1,SERVRG),1(GR11)      STORE IMBEDDED QUOTE, REDUCE    07660000
         SH    GR7,H1                   SCAN CTR BY1                    07680000
         B     ADDLIT                                                   07700000
ALFBLK   SH    GR7,H2                                                   07720000
         BC    4,ALFBLD                 COMP. IF BCT IS LESS THAN 0,    07740000
         LCR   GR11,GR7                 FIELD WAS FULL, IF 0 OR GREATER 07760000
         LA    GR11,9(GR11)             POSITION PTR IN FLD AND TEST    07780000
         LA    GR11,FACT1(GR11,RDREG)   FOR BLANKS                      07800000
         EX    GR7,TBLANK                                               07820000
         BE    ALFBLD                   IF REST OF FLD IS BLANK, BUILD  07840000
         B     ALFEXT                   1ST POS FOR INVALID LIT-  EXIT  07860000
LOOP     CLI   PAKSW,X'FF'              HAVE PREV. CHAR BEEN MOVED TO   07880000
         BNE   STCH                     HOLDING AREA                    07900000
         BAL   LNKREG,MOVPAK            YES                             07920000
         B     ADDLIT                                                   07940000
STCH     BAL   LNKREG,FORPAK            NO, GO STORE CHAR               07960000
ADDLIT   LA    LITCNT,1(LITCNT)         BUMP LIT CNT.                   07980000
         BCT   GR7,STLOOP               FINISHED                        08000000
         B     ALFEXT                                                   08020000
ALFBLD   MVC   WKCOMP(12),ZFS                                           08040000
         MVC   N(2),DUMCMP                                              08060000
         SH    LITCNT,H1                CHAR                            08080000
         STH   LITCNT,SAVDGT            SUB 1 FROM LIT CNT, SAVE IT AND 08100000
         EX    LITCNT,MOVLIT            MOVE  CHAR TO LIT ENTRY         08120000
         CH    LITCNT,H2                IS LIT ENTRY EQ TO OR GR THAN 3 08140000
         MVI   WKCOMP,X'05'                                             08160000
         MVI   N+1,X'05'                                                08180000
         BL    STOBLK                   IF YES, ENTRY IS SET            08200000
         AH    LITCNT,H3                NO, FORM N AND STORE            08220000
         STH   LITCNT,N                                                 08240000
         MVC   WKCOMP(1),N+1                                            08260000
STOBLK   MVI   WKCOMP+1,C' '            BLANK EQ ALPHA LIT. ENTRY       08280000
         LA    GR7,WKCOMP                                               08300000
         AH    GR7,N                    MOVE PTR PAST LITERAL           08320000
         MVC   0(1,GR7),SAVDGT+1        MOVE L-1 TO ENTRY               08340000
         MVI   1(GR7),C' '              REPEAT ALPHA LIT. INDICATION    08360000
         OI    SCNSW,X'40'              SET SW FOR VALID ALPHA LITERAL  08380000
ALFEXT   BCR   15,GR15                  EXIT                            08400000
*                                                                       08420000
*   THE FOLLOWING INSTRUCTION IS EXECUTED BY INSTRUCTION FOLLOWING 000Z 08426017
*   THE LABEL 'ALFBLD'                                             000Z 08432017
MOVLIT   MVC   WKCOMP+2(0),PACKAR                                       08440000
*                                                                       08460000
******************************************************************      08480000
*              THIS ROUTINE WILL SCAN A F1, F2, OR RESULT FIELD         08500000
*              FOR A VALID 6 CHAR NAME. IF BIT 3 OF SCNSW,(X'10')       08520000
*              IS 0, A FACTOR FIELD IS BEING SCANNED (CK A MAX OF       08540000
*              9 POS FOR TRAILING BLANKS). BIT 3 EQ TO 1, THE           08560000
*              NAME IS FROM A RESULT FIELD (CK.UP TO 5 POS FOR          08580000
*              TRAILING BLANKS) LINKAGE  BY  GR15                       08600000
******************************************************************      08620000
*                                                                       08640000
VERFLN   NI    SCNSW,X'DF'              CLEAR VALID FIELD NAME SW.      08660000
         LA    GR12,6                                                   08680000
STFLN    LCR   GR11,GR12                                                08700000
         LA    GR11,6(GR11)                                             08720000
         LA    GR11,FACT1(GR11,RDREG)                                   08740000
         CLI   0(GR11),C'$'             VALID ALPHA CHAR ARE $, POUND,  08760000
         BE    TNCOL                    AT, A-Z AND NUMERICS            08780000
         CLI   0(GR11),X'7B'            IF NONE OF ABOVE TEST FIELD     08800000
         BE    TNCOL                    FOR BLANKS                      08820000
         CLI   0(GR11),X'7C'                                            08840000
         BE    TNCOL                                                    08860000
         CLI   0(GR11),C'A'                                             08880000
         BL    TSBLNK                                                   08900000
TNCOL    BCT   GR12,STFLN               FINISHED                        08920000
         TM    SCNSW,X'10'              YES, WAS THIS A RESULT FIELD    08940000
         BO    CLRBIT                                                   08960000
         LA    GR11,1(GR11)             NO TEST REST OF FACTOR FIELD    08980000
         B     ADTHR                    FOR BLANKS                      09000000
CLRBIT   OI    SCNSW,X'20'              CLEAR RES. FLD  SW              09020000
CLRSW    NI    SCNSW,X'EF'              SET VALID FIELD NAME SW         09040000
FLNEXT   BCR   15,GR15                                                  09060000
TSBLNK   CLI   0(GR11),C' '             IF CHAR IS NOT BLANK, NAME IS   09080000
         BNE   CLRSW                                                    09100000
         TM    SCNSW,X'10'              POS IS BLANK, IF NAME IS FROM   09120000
         BC    12,ADTHR                 RF, SUB 1 FOR EX. OF COMPARE.   09140000
         SH    GR12,H1                  IF FROM F1, F2, ADD 3 TO SCAN   09160000
         B     BLKFLD                   CNT AND COMPARE                 09180000
ADTHR    AH    GR12,H3                                                  09200000
BLKFLD   EX    GR12,TBLANK                                              09220000
         BE    CLRBIT                                                   09240000
FLDERR   MVI   FACT1(RDREG),C' '        REST OF FIELD N-BLANK. NAME IS  09260000
         B     CLRSW                    INVALID                         09280000
*                                                                       09300000
******************************************************************      09320000
*              THESE OP CODES WILL BE PROCESSED IN ENTER5. THEIR        09340000
*              1 BYTE EQUIVALENCE, LITERALS AND SWITCHES WILL BE        09360000
*              WRITTEN,ALONG WITH THE SPECIFICATION, ON WRKFIL3.        09380000
******************************************************************      09400000
ADD      MVI   SAVEOP,AD                                                09420000
         B     LITOUT                                                   09440000
ZADD     MVI   SAVEOP,ZA                                                09460000
         B     LITOUT                                                   09480000
SUB      MVI   SAVEOP,SB                                                09500000
         B     LITOUT                                                   09520000
ZSUB     MVI   SAVEOP,ZS                                                09540000
         B     LITOUT                                                   09560000
MULT     MVI   SAVEOP,MT                                                09580000
         B     LITOUT                                                   09600000
DIV      MVI   SAVEOP,DV                                                09620000
         B     LITOUT                                                   09640000
MVR      MVI   SAVEOP,MR                                                09660000
         B     LITOUT                                                   09680000
MOVE     MVI   SAVEOP,MV                                                09700000
         B     LITOUT                                                   09720000
MOVEL    MVI   SAVEOP,ML                                                09740000
         B     LITOUT                                                   09760000
MLHZO    MVI   SAVEOP,LH                                                09780000
         B     LITOUT                                                   09800000
MHLZO    MVI   SAVEOP,HL                                                09820000
         B     LITOUT                                                   09840000
MHHZO    MVI   SAVEOP,HH                                                09860000
         B     LITOUT                                                   09880000
MLLZO    MVI   SAVEOP,LL                                                09900000
         B     LITOUT                                                   09920000
COMP     MVI   SAVEOP,CP                                                09940000
         B     LITOUT                                                   09960000
TESTZ    MVI   SAVEOP,TZ                                                09980000
         B     LITOUT                                                   10000000
SETON    MVI   SAVEOP,SO                                                10020000
         B     LITOUT                                                   10040000
SETOF    MVI   SAVEOP,SF                                                10060000
         B     LITOUT                                                   10080000
LOKUP    MVI   SAVEOP,LU                                                10100000
         B     LITOUT                                                   10120000
*                                                                       10140000
LITOUT   OI    IBYT,X'20'               INDICATE A PRE-PROCESSED SPEC,  10160000
         MVC   RLDBUF+82(1),FACTSW      IF ANY.                         10180000
         B     ENDSPC                                                   10200000
*                                                                       10220000
******************************************************************      10240000
*              ROUTINE TO TEST AND VERIFY CONTROL LEVEL                 10260000
******************************************************************      10280000
TESTCL   CLC   CLEV(2,RDREG),BLANKS                                     10300000
         BE    CLEXT                    IF CTL LEV SPECIFIED, REFERENCE 10320000
         CLI   CLEV(RDREG),C'L'         TEST FOR VALID CTL LEVEL   I173 10330000
         BNE   SETLZ                   INDICATOR AND SET L0 IF     I173 10340000
*                                      INDICATOR IS INVALID.       I173 10350000
         MVI   REF,X'02'                IT                              10380000
         MVC   ARG(2),CLEV(RDREG)                                       10400000
         BAL   GR15,RITLU                                               10420000
         CLI   FSW,X'FF'                WAS IND SPEC. PROPERLY          10440000
         MVC   0(2,GR14),ARG                                            10460000
         BE    SETALF                   YES, MOVE CL TO BUFFER          10480000
SETLZ    OI    ERBYT+1,X'04'                                            10500000
         MVC   0(2,GR14),CL0            LEVEL ZERO. INDICATE CL IN      10520000
SETALF   OI    ABYT,X'80'               ALPHA BYTE  AND EXIT            10540000
         LA    GR14,2(GR14)                                             10560000
CLEXT    BCR   15,GR13                                                  10580000
******************************************************************      10600000
*                                                                       10620000
*              THIS ROUTINE SCANS A 9 POSITION FIELD FOR CONDITION      10640000
*              CODES. IF 1 OR MORE IS FOUND, THE INDICATORS WILL BE     10660000
*              REFERENCED AND ALL 9 POSITIONS MOVED TO THE OUTPUT       10680000
*              BUFFER. X'00' USED IN BLANK POSITIONS. IND. 00 ASSUMED   10700000
*              IF INVALID INDICATOR SPECIFIED.                          10720000
******************************************************************      10740000
TSTIND   CLC   CONDCD(9,RDREG),BLANKS   IF COND. CODES SPECIFIED, SET   10760000
         BE    CNDEXT                   UP LOOP TO SCAN FIELD           10780000
         LA    GR11,3                                                   10800000
TINDST   LCR   GR12,GR11                                                10820000
         LA    GR12,3(GR12)                                             10840000
         LR    GR15,GR12                                                10860000
         SLL   GR12,2                                                   10880000
         SR    GR12,GR15                                                10900000
         LA    GR12,CONDCD(GR12,RDREG)                                  10920000
         CLC   0(3,GR12),BLANKS         IS 1ST COND. CODE FIELD BLANK   10940000
         BNE   CCREF                                                    10960000
         MVC   0(3,GR14),DUMCMP         YES, MOVE IN X'00' AND TEST     10980000
         B     INDEXT                   NEXT FIELD                      11000000
CCREF    MVC   ARG(2),1(GR12)                                           11020000
         MVI   REF,X'02'                SET BIT TO REF  THIS INDICATOR  11040000
         BAL   GR15,RITLU               GO LOOK UP IND                  11060000
         CLI   FSW,X'FF'                WAS INDICATOR VALID             11080000
         MVC   1(2,GR14),ARG                                            11100000
         BE    CCABYT                   YES, MOVE IT TO BUFFER AND SET  11120000
         OI    ERBYT+1,X'02'            BIT IN ALPHA. IF NOT VALID SET  11140000
         MVC   1(2,GR14),CCZ            ERR BIT AND ASSUME 00           11160000
CCABYT   OI    ABYT,X'40'                                               11180000
         CLI   ARG,C'U'                 TEST FOR USE OF A          I173 11188000
         BNE   CCINDON                 'U' INDICATOR AND SET       I173 11196000
         OI    CMPOPT(WKREG),X'40'     THE COMPILER OPTION BIT.    I173 11204000
CCINDON  CLI   0(GR12),C' '             IS THE INDICATOR TO BE ON  I173 11212000
         MVI   0(GR14),X'00'            YES, MOVE IN X'00' AND TEST     11220000
         BE    INDEXT                   NEXT                            11240000
         CLI   0(GR12),C'N'                                             11260000
         MVI   0(GR14),C'N'                                             11280000
         BE    INDEXT                                                   11300000
         OI    ERBYT+1,X'80'            NOT BLANK OR N, SET ERR BIT     11320000
INDEXT   LA    GR14,3(GR14)             AND ASSUME N                    11340000
         BCT   GR11,TINDST                                              11360000
CNDEXT   BCR   15,GR13                                                  11380000
*                                                                       11400000
******************************************************************      11420000
*              THIS ROUTINE SCANS AND BUILDS THE FIELD NAME TABLE.      11440000
*              IT ALSO VERIFIES THE FIELD NAME USAGE.                   11460000
******************************************************************      11480000
FLDSCN   L     GR11,FLD(WKREG)                                          11500000
         B     CMPNAM                                                   11520000
CKFNAM   CLC   0(6,GR11),NAMBUF         NAME FOUND                      11540000
         BNE   GETNEX                                                   11560000
         NC    FLDMSK(1),12(GR11)                                A33632 11580000
         BC    8,TSTREF                                                 11600000
         MVI   6(GR11),C'M'             NO, SET FIELD AS MULTI-DEFINED  11620000
         OI    ERBYT+1,X'20'            SPECIFY F.N. USED IMPROPERLY    11640000
         B     ERROUT                   EXIT                            11660000
TSTREF   CLI   USESW,X'FF'              IS NAME FROM F1 OR F2           11680000
         BNE   TSTABL                                                   11700000
         CLI   6(GR11),C'X'       IS THE FIELD BOTH UNDEF AND UNREF7359 11706017
         BE    SETU                SET TO UNDEF BUT REFERENCED     7359 11712017
         CLI   6(GR11),C' '             YES, IF REF IS BLANK, NAME HAS  11720000
         BNE   ORGAM                    NOW BEEN REF AND DEFINED. SET   11740000
         MVI   6(GR11),C'R'             REF BYTE TO R. REF NOT BLANK    11760000
ORGAM    OC    12(1,GR11),LENBYT+2      OR GAMMAS AND EXIT              11780000
         B     FLDEXT                                                   11800000
SETU     MVI   6(GR11),C'U'      SET TO REFERENCED BUT UNDEFINED   7359 11806017
         B     ORGAM                                               7359 11812017
GETNEX   LA    GR11,13(GR11)            POINT AT NEXT ENTRY             11820000
CMPNAM   CLI   0(GR11),X'FF'            IS THIS END OF TABLE            11840000
         BNE   CTD14                                                    11860000
TSTGAM   CLI   LENBYT+2,X'20'           CAUSED O'FLOW. IF NAME WAS A    11880000
         BE    SETERR                                                   11900000
         BAL   GR13,CHKUWRD       CHK IF NAME IS A USER DATE WORD  000D 11905017
** IF THE USER DATE WORD IS NOT USED PROPERLY, THEN DO NOT PROCESS 000D 11910017
** IF THE NAME IS USED PROPERLY OR IS NOT A USER DAT WRD,RET HERE  000D 11915017
         MVI   0(GR11),X'FD'            YES, SET INDICATOR AND SET BIT  11920000
         OI    IBYT,X'08'               TO INDICATE THAT THIS SPEC      11940000
         B     FLDEXT                                                   11960000
SETERR   OI    ERBYT,X'08'              THEN IT IS IN ERROR             11980000
         B     ERROUT                                                   12000000
CTD14    CLI   0(GR11),X'FD'            IS TABLE FULL                   12020000
         BNE   CKFE                                                     12040000
         CLI   LENBYT+2,X'20'                                           12060000
         BE    SETERR                                                   12080000
         BAL   GR13,CHKUWRD       CHK IF NAME IS A USER DATE WORD  000D 12085017
** IF THE USER DATE WORD IS NOT USED PROPERLY, THEN DO NOT PROCESS 000D 12090017
** IF THE NAME IS USED PROPERLY OR IS NOT A USER DAT WRD,RET HERE  000D 12095017
         B     FLDEXT                                                   12100000
CKFE     CLI   0(GR11),X'FE'                                            12120000
         BNE   CKFNAM                                                   12140000
         CLI   LENBYT+2,X'20'           YES, IS NAME A CONV. NAME       12160000
         BE    SETERR                   YES, ERROR                      12180000
         LA    GR13,NXT5          SET GR13 FOR A BRANCH=NOT END OF 000D 12180817
*                                  TABLE. I.E. CONT PROC AT NXT5   000D 12181617
CHKUWRD  CLI   NAMBUF,C'U'        DOES NAME START WITH 'U'         000D 12182417
         BNE   CONT               NO, BYPASS CHECK                 000D 12183217
         CLC   NAMBUF(6),UDATE    CHECK FOR 'UDATE'                000D 12184017
         BE    LNGH6              YES, CHECK LENGTH OF 6           000D 12184817
         CLC   NAMBUF(6),UMONTH   CHECK FOR 'UMONTH'               000D 12185617
         BE    LNGH2              YES, CHECK FOR LENGTH OF 2       000D 12186417
         CLC   NAMBUF(6),UDAY     CHECK FOR 'UDAY'                 000D 12187217
         BE    LNGH2              YES, CHECK FOR LENGTH OF 2       000D 12188017
         CLC   NAMBUF(6),UYEAR    CHECK FOR 'UYEAR'                000D 12188817
         BNE   CONT               IF NOT USER DATE, CONT PROCESSING000D 12189617
LNGH2    CLC   LENBYT(2),TWOZERO  CHK FOR LEN OF 2 AND DEC POS = 0 000D 12190417
         BE    NXT1               YES, NO ERROR                    000D 12191217
         CLC   LENBYT(2),NOENTRY  CHK FOR BLANK ENTRY              000D 12192017
         MVC   LENBYT(2),TWOZERO  ASSUME PROPER ENTRYS             000D 12192817
         BE    NXT1               CONTINUE PROCESSING              000D 12193617
         B     LENER              NO, BRANCH TO SET AN ERROR BIT   000D 12194417
LNGH6    CLC   LENBYT(2),SIXZERO  CHK FOR LEN OF 6 AND DEC POS = 0 000D 12195217
         BE    NXT1               YES, O.K.                        000D 12196017
         CLC   LENBYT(2),NOENTRY  CHK FOR BLANK ENTRY              000D 12196817
         MVC   LENBYT(2),SIXZERO  ASSUME PROPER ENTRYS             000D 12197617
         BE    NXT1               CONTINUE PROCESSING              000D 12198417
LENER    OI    ERBYT+1,X'20'      FACTOR NAME USED IMPROPERLY      000D 12199217
NXT1     CLI   LENBYT+2,X'04'     IS OP CODE RLABL                 000D 12200017
         BE    NXT2               YES,O.K.                         000D 12200817
         OI    ERBYT+1,X'20'      FACTOR NAME USED IMPROPERLY      000D 12201617
NXT2     CLI   USESW,X'00'        IS FIELD NAME = RESULT FIELD     000D 12202417
         BE    NXT4               CONTINUE PROCESSING IF EQUAL     000D 12203217
         OI    ERBYT+1,X'20'      FACTOR NAME USED IMPROPERLY      000D 12204017
NXT4     CLI   ERBYT+1,X'00'      CHECK FOR ANY ERRORS             000D 12204817
         BE    0(GR13)            NO ERROR, DEFINE OR RETURN       000D 12205617
         B     ERROUT             IF ANY ERRORS, THEN DO NOT DEFINE000D 12206417
NXT5     MVI   6(GR11),C'R'       INDICATE REFERENCED              000D 12207217
         MVI   LENBYT+2,X'84'     GAMMA, NORMAL AND RLABL          000D 12208017
         MVC   0(6,GR11),NAMBUF   MOVE FIELD NAME TO TABLE         000D 12208817
         B     STOLDG             STORE LENGTH, DEC POS, AND GAMMA 000D 12209617
UDATE    DC    C'UDATE '          RESERVED WORD                    000D 12210417
UMONTH   DC    C'UMONTH'          RESERVED WORD                    000D 12211217
UDAY     DC    C'UDAY  '          RESERVED WORD                    000D 12212017
UYEAR    DC    C'UYEAR '          RESERVED WORD                    000D 12212817
TWOZERO  DC    X'01F0'            LEN OF 2 WITH NO DEC POSITIONS   000D 12213617
SIXZERO  DC    X'05F0'            LEN OF 6 WITH NO DEC POSITIONS   000D 12214417
NOENTRY  DC    X'0040'            ENTRY OF BLANK IN LEN AND DEC POS000D 12215217
CONT     CLI   0(GR11),X'FE' CHK IF END OF TABLE PASS, FD OR FF    000D 12216017
         BNE   0(GR13)            IF YES, RET TO END OF TAB PROCES 000D 12216817
         MVC   0(6,GR11),NAMBUF    MOVE NAME TO TABLE              000D 12217617
         CLI   USESW,X'FF'              IS NAME FROM A FACTOR FIELD     12220000
         BNE   ENTNAM                                                   12240000
         MVI   9(GR11),X'00'                                            12260000
         MVI   10(GR11),X'06'                                           12280000
         MVI   11(GR11),X'F0'                                           12300000
         MVI   12(GR11),X'80'                                           12320000
         MVI   6(GR11),C'U'             YES, SET REF. BYTE UNDEFINED    12340000
         MVC   12(1,GR11),LENBYT+2      STORE GAMMA BYTE                12360000
         B     FLDEXT                                                   12380000
ENTNAM   CLI   LENBYT+2,X'10'           IF NAME IS F2 OF EXTCV OR EXIT, 12400000
         BNE   TSTLEN                   SET REF. BYTE TO R AND STORE    12420000
         MVI   6(GR11),C'R'             LENGTH, DEC. POS. AND GAMMA     12440000
         B     STOLDG                                                   12460000
TSTLEN   TM    LENBYT+3,X'F0'           IF A LENGTH IS NOT SPECIFIED    12480000
         BO    TKVIV                    THE 1ST TIME THE FIELD IS       12500000
         MVI   6(GR11),C'X'                                        7359 12520017
         BAL   GR13,OPCK1                                               12540000
         CLI   YES,X'FF'                IS OPCODE RPGCV OR EXTCV        12560000
         BE    TKVIV                                                    12580000
         MVI   LENBYT,X'03'             ASSUME A LENGTH OF 4. SET ZONE  12600000
         MVZ   LENBYT+3(1),CZ           OF H-ADJ TO 'F' FOR LENGTH      12620000
         B     STOLDG                                              7359 12630017
TKVIV    CLI   LENBYT+2,X'40'           IF NAME IS RF OF KEYCV OR IDCV  12640000
         MVI   6(GR11),C'R'             FOLLOWING AN EXTCV, SET FIELD   12660000
         BE    STOLDG                   AS REFERENCED.                  12680000
         MVI   6(GR11),C' '             IF NOT, SET REF BYTE BLANK      12700000
STOLDG   MVC   7(2,GR11),BLANKS                                         12720000
         MVI   9(GR11),X'00'            SET BETA BYTE                   12740000
         MVC   10(3,GR11),LENBYT        STORE LEN., DEC. POS., GAMMA    12760000
FLDEXT   BCR   15,GR15                                                  12780000
TSTABL   TM    LENBYT+3,X'F0'           IF NO LENGTH SPECIFIED, CHECK   12800000
         BC    5,CKLD                   FOR RPGCV OR EXTCV              12820000
         BAL   GR13,OPCK1                                               12840000
CKLD     CLI   6(GR11),C' '             ENTER HERE W/SEARCH NAME FROM   12860000
         BNE   REFU                     R.F. IF MATCHING TABLE NAME WAS 12880000
CHECKL   TM    LENBYT+3,X'F0'     FROM R.F. TEST TO SEE IF LEN.    7359 12900017
         BC    12,CKGAM                                                 12920000
         CLC   10(2,GR11),LENBYT                                        12940000
         BE    CKGAM                    NAMES. IF EQ TEST GAMMA.IF N-EQ 12960000
         MVI   6(GR11),C'M'             SET REF TO M AND 'OR' GAMMAS.   12980000
         B     ORGAM                    IF NO LEN. W/SEARCH NAME, TEST  13000000
CKGAM    CLI   LENBYT+2,X'01'           SEARCH GAMMA FOR RLABL,ULABL    13020000
         BE    SETREF                   TYPES. IF PRESENT, SET REF TO   13040000
         CLI   LENBYT+2,X'04'           R                               13060000
         BNE   ORGAM                                                    13080000
SETREF   MVI   6(GR11),C'R'                                             13100000
         B     ORGAM                                                    13120000
REFU     CLI   6(GR11),C'U'             IF TABLE NAME WAS FROM A F1 OR  13140000
         BNE   REFM                     F2 AND SEARCH NAME IS FROM RF,  13160000
         TM    LENBYT+3,X'F0'           TEST SEARCH NAME FOR LENGTH. IF 13180000
         BZ    ORGAM                   NO LENGTH GIVEN LEAVE REF   7359 13210017
         MVI   6(GR11),C'R'             SET REFERENCE BYTE TO R    7359 13240017
SETL     MVC   7(2,GR11),BLANKS         MOVE IN LENGTH             7359 13270017
         MVI   9(GR11),X'00'                                            13320000
         MVC   10(2,GR11),LENBYT        POS, OR GAMMAS AND EXIT         13340000
         B     ORGAM                                                    13360000
REFM     CLI   SAVEOP,TG           IS IT TAG OPER                A33632 13365000
         BNE   NOTAG               NO                            A33632 13370000
         MVI   6(GR11),C'M'        MAKE MULTI-DEFINED            A33632 13375000
         B     ORGAM                                             A33632 13380000
NOTAG    CLI   6(GR11),C'M'      IF REF IS M, OR GAMMAS AND EXIT A33632 13385000
         BE    ORGAM                    IF NOT, IT IS R OR X,      7359 13390017
         CLI   6(GR11),C'X'             IF NOT X GO CHECK LENGTH   7359 13400017
         BNE   CHECKL                   AT CHECKL, IF LEN SPEC.    7359 13410017
         TM    LENBYT+3,X'F0'           W/SEARCH NAME, COMPARE  SCH AND 13420000
         BC    12,ORGAM                 TAB. NAME LEN. AND DEC POS. IF  13440000
         CLC   10(2,GR11),LENBYT        EQ. OR GAMMAS AND EXIT. IF N-EQ 13460000
         BE    ORGAM                    CHANGE REF. TO M, OR GAMMAS AND 13480000
         MVI   6(GR11),C'M'             EXIT                            13500000
         B     ORGAM                                                    13520000
******************************************************************      13540000
*              THIS ROUTINE  VERIFIES, DIAGNOSES, AND CONVERTS          13560000
*              A FIELD LENGTH.                                          13580000
******************************************************************      13600000
GETLEN   CLC   FLDLEN(3,RDREG),BLANKS   IF FIELD LENGTH IS BLANK, STORE 13620000
         MVI   LENBYT,X'00'             ZERO IN LEN. AND SET IND IN     13640000
         MVI   LENBYT+1,C' '                                            13660000
         MVZ   LENBYT+3(1),HEXZ         ZONE OF H-ADJ BYTE              13680000
         BE    LENEX                                                    13700000
         MVI   FDSW,X'00'               IF N-BLANK, VERIFY LEN. IS      13720000
         LA    GR11,3                   VALID NUMERIC. ZERO ASSUMED FOR 13740000
         MVI   VALSW,X'00'     SET VALID SW OFF                    4277 13750015
CKFLEN   LCR   GR12,GR11                IMBEDDED BLANKS                 13760000
         LA    GR12,3(GR12)                                             13780000
         LA    GR12,FLDLEN(GR12,RDREG)                                  13800000
         CLI   0(GR12),C' '   BLANK BYTE, QQ                       4277 13810015
         BNE   CHECKZN        NO, GO CHECK ZONE                    4277 13820015
         CLI   VALSW,X'FF'    BLANK ENTRY VALID HERE, QQ           4277 13830015
         BNE   FLEN           YES, GO ASSUME LEN ZERO              4277 13840015
         B     SETBAD         NO, ASSUME ZERO, SET ERROR SW        4277 13850015
CHECKZN  TM    0(GR12),X'F0'  SEE IF ZONE IS NUMERIC               4277 13860015
         BC    12,SETBAD      INVALID, GO SET SW AND ASSUME ZERO   4277 13870015
         MVI   VALSW,X'FF'    SET SW THAT VALID ENTRY FOUND, BLANKS4277 13880015
         B     FLDCTR         INVALID FROM HERE ON                 4277 13890015
SETBAD   MVI   FDSW,X'FF'     SET SW SO NOTE 83 IS PRINTED         4277 13900015
FLEN     MVI   0(GR12),C'0'                                        4277 13910015
FLDCTR   BCT   GR11,CKFLEN                                         4277 13920015
         CLI   FDSW,X'FF'                                               13960000
         BNE   PAKLEN                   IF ERR SW SET, SET BIT IN ERR.  13980000
         OI    ERBYT,X'20'              BYTE                            14000000
PAKLEN   PACK  SAVREG(8),FLDLEN(3,RDREG) PACK FIELD LEN. FOR CONV. AND  14020000
*  BLANK TO LENBYT.  BRANCH TO BRTCK1 IF RPGCV SPECIFIED, TO ISBIG 000Z 14026017
*  FOR EXTCV                                                       000Z 14032017
         MVI   LENBYT+1,C' '                                            14040000
         CLI   SAVEOP,RV                                                14060000
         BE    BRTCK1                                                   14080000
         CLI   SAVEOP,EV                                                14100000
         BNE   ISBIG                                                    14120000
*  CONVERT FLD LEN TO BINARY IF EQUAL TO 3 OR 8, OTHERWISE RESET   000Z 14125017
*  LENBYT AND CVB IF LEN IS 5 OR 15.  IF NONE OF THESE, SET ERROR  000Z 14130017
*  IND AND SET FLD LEN TO ASSUMED 8 AND CVB.                       000Z 14135017
BRTCK1   CP    SAVREG+5(3),P3                                           14140000
         BE    CNVLEN                                                   14160000
         MVI   LENBYT+1,X'F0'                                           14180000
         CP    SAVREG+5(3),P5                                           14200000
         BE    CNVLEN                                                   14220000
         MVI   LENBYT+1,C' '                                            14240000
         OI    ERBYT+1,X'01'                                            14260000
         ZAP   SAVREG+5(3),P3                                           14280000
         B     CNVLEN                                                   14300000
ISBIG    CP    SAVREG+5(3),P256                                         14320000
         BNH   CNVLEN                   THAN 256                        14340000
         OI    ERBYT+1,X'10'                                            14360000
         ZAP   SAVREG+5(3),P256         ASSUME 256                      14380000
CNVLEN   CVB   SERVRG,SAVREG                                            14400000
         SH    SERVRG,H1                                                14420000
         STC   SERVRG,LENBYT            CONVERT AND STORE               14440000
         MVI   LENBYT+3,C'0'                                            14460000
TSDP     CLI   DECPOS(RDREG),C' '       DEC POS SHOULD BE BLANK         14480000
         BE    LENEX                                                    14500000
*   TEST DECIMAL POSITIONS FOR OP CODES OF X'09' AND X'0A', ANY    000Z 14506017
*  OTHERS CAUSE ERROR BIT TO BE SET.                               000Z 14512017
         TM    SAVEOP,X'09'                                             14520000
         BO    TSTDP                                                    14540000
         TM    SAVEOP,X'0A'                                             14560000
         BC    12,DECERR                                                14580000
TSTDP    TM    DECPOS(RDREG),X'F0'                                      14600000
         BC    12,STONUM                                                14620000
         MVC   LENBYT+1(1),DECPOS(RDREG)                                14640000
         B     LENEX                                                    14660000
STONUM   MVI   LENBYT+1,C'0'                                            14680000
DECERR   OI    ERBYT,X'40'              IF NOT SET ERR BIT AND EXIT     14700000
LENEX    BCR   15,GR15                                                  14720000
******************************************************************      14740000
***            BEGIN CHECK FOR RPGCV_EXTCV RESULT FIELD LENGTH  **      14760000
******************************************************************      14780000
OPCK1    MVI   YES,X'00'                                                14800000
         CLI   SAVEOP,RV                IS RPGCV                        14820000
         BE    BRTCK2                   YES-INSERT LENGTH               14840000
         CLI   SAVEOP,EV                IS EXTCV                        14860000
         BNE   OUTOF                                                    14880000
BRTCK2   MVI   LENBYT,X'07'                                             14900000
         MVZ   LENBYT+3(1),CZ           SET HALF-ADJUST TO 'F'          14920000
         MVI   YES,X'FF'                                                14940000
OUTOF    BCR   15,GR13                                                  14960000
*                                                                       14980000
******************************************************************      15000000
*              ROUTINE TO WRITE SPEC, READ A SPEC AND CONTINUE          15020000
******************************************************************      15040000
ENDSPC   BAL   GR15,WRTOUT                                              15060000
         BAL   GR15,READX                                               15080000
         B     START                                                    15100000
*                                                                       15120000
******************************************************************      15140000
*              ROUTINE TO REWIND WRKFIL3 AND CALL NEXT PHASE            15160000
******************************************************************      15180000
CALFIV   BAL   GR15,WRTOUT                                              15200000
         LA    SERVRG,RWDRLD            LOAD SERVICE ROUTINE NO. TO     15220000
         BALR  LNKREG,GR7               REWIND WRKFIL3                  15240000
         MVC   SOQ(4,WKREG),SCQ(WKREG)                                  15260000
         SP    SOQ(4,WKREG),P1                                          15280000
         LA    GR11,PSN(WKREG)                                          15300000
         MVC   0(8,GR11),ENT5           STORE PHASE NAME                15320000
         LA    SERVRG,PHASCL            CALL NEXT PHASE                 15340000
         B     OUT                                                      15360000
*                                                                       15380000
******************************************************************      15400000
*              THIS ROUTINE  WRITES A RECORD ON WRKFIL3                 15420000
******************************************************************      15440000
WRTOUT   LA    GR1,RLDBUF               FWA OF OUTPUT BUFFER            15460000
         LA    SERVRG,WRTRLD            SERVICE ROUTINE NO TO WRITE ON  15480000
         B     OUT                      WRKFIL3                         15500000
*                                                                       15520000
******************************************************************      15540000
*              ROUTINE TO WRITE INVALID SPEC AND ERROR                  15560000
******************************************************************      15580000
ERROUT   OI    IBYT,X'40'               SPEC RECORD CONTAINS SPEC. AND  15600000
         B     ENDSPC                   BUFFER                          15620000
*                                                                       15640000
******************************************************************      15660000
*              ROUTINE TO READ A SPEC                                   15680000
******************************************************************      15700000
READX    LA    SERVRG,REDSPC            LOAD SERVICE ROUTINE NO TO READ 15720000
OUT      ST    GR15,REGSAV              A SPEC                          15740000
         L     GR7,SAVSEV                                               15760000
         BALR  LNKREG,GR7               SAVE REG 15                     15780000
         L     GR15,REGSAV                                              15800000
         BCR   15,GR15                                                  15820000
*                                                                       15840000
******************************************************************      15860000
*              RESULT INDICATOR TABLE LOOK UP ROUTINE                   15880000
******************************************************************      15900000
RITLU    L     GR7,RIT(WKREG)                                           15920000
         MVI   FSW,X'00'                CLEAR SW. FOR VALID INDICATOR   15940000
         LA    SERVRG,139               SET CNT TO NO. IN TABLE    I173 15960000
CMPARG   CLC   0(2,GR7),ARG                                             15980000
         BNE   NEXARG                                                   16000000
         MVI   FSW,X'FF'                YES, SET SW AND 'OR' REF BIT    16020000
         OC    2(1,GR7),REF                                             16040000
         B     RITEXT                                                   16060000
*  INCREMENT TO NEXT INDICATOR, CONTINUE SEARCH IF POSSIBLE.       000Z 16070017
NEXARG   LA    GR7,5(GR7)                                               16080000
         BCT   SERVRG,CMPARG                                            16100000
RITEXT   BCR   15,GR15                                                  16120000
*                                                                       16140000
******************************************************************      16160000
*              THIS ROUTINE PROCESSES EXTCV, RPGCV, IDCV, KEYCV, RLABL, 16180000
*              AND ULABL.  THE COMPRESSED SPEC. IS PLACED IN THE        16200000
*              OUTPUT BUFFER AND WILL BE  FINALIZED IN ENTER5.          16220000
******************************************************************      16240000
*                                                                       16260000
EXTCV    MVI   SAVEOP,EV                                                16280000
ENTRV    MVI   ERSW,X'00'               CLEAR ERROR SW                  16300000
         TM    FACTSW,X'80'             IS FACT1 A F. N.                16320000
         BO    TESTAG                                                   16340000
         OI    ERBYT,X'08'              NO, INDICATE ERROR              16360000
         MVI   ERSW,X'FF'                                               16380000
         CLI   SAVEOP,TG                IF ERR AND OP IS TAG, EXIT      16400000
         BE    ERROUT                                                   16420000
         CLI   SAVEOP,RV                IF ERR AND OP IS RV,CHECK RES   16440000
         BE    B                        FLD                             16460000
         B     FAC2                     OP IS EV, TEST FACT 2           16480000
TESTAG   CLI   SAVEOP,TG                FACT1 IS FN, IF TAG, GO PROCESS 16500000
         BE    MVFN                                                     16520000
         OI    ABYT,X'20'               INDICATE F1 IN ALPHA BYTE       16540000
         CLI   SAVEOP,EV                IF EXTCV, TEST FOR FACT2        16560000
         BNE   B                                                        16580000
FAC2     TM    FACTSW,X'08'             IS FACT2 PRESENT                16600000
         BO    TSEXIT                                                   16620000
         OI    ERBYT,X'04'              NO, SET ERR BIT AND ERR SW.     16640000
         MVI   ERSW,X'FF'                                               16660000
         CLI   SAVEOP,EX                IF OP IS EXIT OR GOTO, SCAN     16680000
         BE    ERROUT                    FINISHED                       16700000
         CLI   SAVEOP,GO                                                16720000
         BE    ERROUT                                                   16740000
         B     B                                                        16760000
TSEXIT   CLI   SAVEOP,EX                F2 IS FIELD NAME, GO PROCESS    16780000
         BE    EXNAM                                                    16800000
         CLI   SAVEOP,GO                                                16820000
         BE    EXNAM                                                    16840000
B        TM    FACTSW,X'01'             IS RES. FLD A FIELD NAME        16860000
         BO    TRESFD                                                   16880000
         OI    ERBYT,X'02'              NO, SET BIT AND EXIT            16900000
         B     ERROUT                                                   16920000
TRESFD   CLI   ERSW,X'FF'               YES,HAS ANY OTHER FACTOR BEEN   16940000
         BE    ERROUT                   IN ERROR- IF YES,DROP SPEC      16960000
         TM    SAVEOP,X'E0'             NO- PROCESS SPEC                16980000
         BO    MOVE1                                                    17000000
         MVI   LENBYT+2,X'20'           NO, RV OR EV. SET GAMMA FOR F1  17020000
         MVI   FLDMSK,X'DF'             SET FIELD MASK, MOVE F. N. TO   17040000
         MVC   NAMBUF(6),FACT1(RDREG)   WK AREA                         17060000
         MVI   USESW,X'FF'              INDICATE NAME IS FROM A FACTOR  17080000
         BAL   GR15,FLDSCN              GO SEARCH FIELD NAME TABLE      17100000
MOVE1    LA    GR14,RLDBUF+87                                           17120000
         TM    SAVEOP,X'E0'             IF OP IS RV OR EV, MOVE IN F1   17140000
         BO    MVOP                                                     17160000
         MVC   0(6,GR14),FACT1(RDREG)                                   17180000
         LA    GR14,6(GR14)                                             17200000
MVOP     MVC   0(1,GR14),SAVEOP         MOVE IN OP                      17220000
         LA    GR14,1(GR14)                                             17240000
         CLI   SAVEOP,EV                IF OP IS EXTCV GO TEST FACTOR 2 17260000
         BE    TSTF2                                                    17280000
         MVC   0(7,GR14),DUMCMP         OTHERWISE MOVE IN A DUMMY F2    17300000
         LA    GR14,7(GR14)                                             17320000
         TM    SAVEOP,X'E0'             AND GAMMA. IF OP IS RPGCV(ZONE  17340000
         BO    TST4                     C), SET GAMMA AND FIELD MASK    17360000
SETNOR   MVI   LENBYT+2,X'80'           FOR NORMAL F.N. AND GO TEST     17380000
         MVI   FLDMSK,X'32'             RESULT FIELD.                   17400000
         B     TWO                                                      17420000
TST4     CLI   LENBYT+2,X'04'           IS IT KEYCV AFTER EXTCV, OR     17440000
         BNE   TST1                     RLABL TYPE. IF YES, IS RES FLD  17460000
         CLC   RESFLD(2,RDREG),CIN      AN INDICATOR. IF IT IS, SET REF 17480000
         BNE   SETFMK                   TO RLABL USAGE, REF., AND       17500000
         MVI   REF,X'0B'                DEFINED. MOVE IND. TO WK-AREA   17520000
         MVC   ARG(2),RESFLD+2(RDREG)   AND CALL R.I. LOOKUP            17540000
         BAL   GR15,RITLU                                               17560000
         CLI   FSW,X'FF'                IF IND. WAS NOT IN THE TABLE,   17580000
         BNE   SETER4                                                   17600000
         OI    ABYT,X'04'                                               17620000
         MVC   0(10,GR14),DUMCMP                                        17640000
         MVC   10(2,GR14),ARG                                           17660000
         LA    GR14,12(GR14)                                            17680000
         B     TSIBYT                                                   17700000
SETER4   OI    ERBYT,X'04'                                              17720000
         B     ERROUT                                                   17740000
SETFMK   MVI   FLDMSK,X'33'             RLABL R.F. HAS FIELD NAME, SET  17760000
         B     TWO                      MASK AND GO TEST RES. FLD.      17780000
TST1     CLI   LENBYT+2,X'01'           IF OP IS NOT KV OR IV AFTER EV, 17800000
         BNE   SETNOR                   OR RL OR UL THEN IT IS KV OR IV 17820000
         MVI   FLDMSK,X'7E'             AFTER RV AND IS SET AS A NORMAL 17840000
         B     TWO                      FIELD NAME. IF UL SET MASK      17860000
TSTF2    MVI   LENBYT+2,X'10'           OP IS EV, SET GAMMA AND MASK    17880000
         MVI   USESW,X'00'                                              17900000
         MVI   LENBYT,X'03'                                             17920000
         MVI   LENBYT+1,C' '                                            17940000
         MVI   LENBYT+3,C'0'                                            17960000
         MVI   FLDMSK,X'EF'             FOR F2, AND TEST NAME           17980000
         MVC   NAMBUF(6),FACT2(RDREG)                                   18000000
         BAL   GR15,FLDSCN                                              18020000
         MVC   1(6,GR14),FACT2(RDREG)    OP FIELD. MOVE F2 TO ITS POS.  18040000
         MVI   0(GR14),X'10'            STORE GAMMA OF F2 IN BYTE 2 OF  18060000
         LA    GR14,7(GR14)                                             18080000
         MVI   LENBYT+2,X'04'           IN COMPRESSION. SET GAMMA AND   18100000
         MVI   FLDMSK,X'33'             MASK FOR RF OF EV.              18120000
TWO      BAL   GR15,GETLEN              PROCESS LENGTH OF RES. FLD.     18140000
         MVC   NAMBUF(6),RESFLD(RDREG)                                  18160000
         MVI   USESW,X'00'              INDICATE FIELD NAME FROM R.F.   18180000
         BAL   GR15,FLDSCN              SEARCH FIELD NAME TABLE         18200000
STORF    MVC   0(6,GR14),RESFLD(RDREG)     MOVE R.F. TO COMP            18220000
         MVC   6(4,GR14),LENBYT         MOVE LEN., DEC. POS., GAMMA,    18240000
         LA    GR14,10(GR14)                                            18260000
TSIBYT   LA    GR13,RLDBUF+86                                           18280000
         SR    GR14,GR13                                                18300000
SETEND   OI    IBYT,X'80'                                               18320000
         STC   GR14,DELTA                                               18340000
         MVI   RLDBUF+85,C'C'                                           18360000
         B     ENDSPC                   GO WRITE  RECORD                18380000
*                                                                       18400000
RPGCV    MVI   SAVEOP,RV                SAVE 1 BYTE OP                  18420000
         B     ENTRV                    GO PROCESS SPEC                 18440000
*                                                                       18460000
KEYCV    BAL   GR15,TSTVB               TEST PREV OP                    18480000
         MVI   SAVEOP,KV                SAVE  THIS OP AND PROCESS       18500000
         MVI   ERSW,X'00'                                               18520000
         B     B                                                        18540000
*                                                                       18560000
*                                                                       18580000
TSTVB    CLI   SAVEOP,RV                KV       MUST FOLLOW RV OR EV.  18600000
         BNE   TEV                      IF NOT ERR BIT IS SET AND SPEC  18620000
         MVI   LENBYT+2,X'80'           WILL NOT BE PROCESSED.          18640000
         B     KVEXT                    IF KV OR IV FOLLOW RPGCV, THEIR 18660000
TEV      CLI   SAVEOP,EV                R.F. IS A NORMAL FIELD NAME.    18680000
         BE    SETOPB                   IF THEY FOLLOW EXTCV, THEIR     18700000
         OI    ERBYT,X'80'              RES. FIELD IS OF RLABL TYPE.    18720000
         B     ERROUT                                                   18740000
SETOPB   MVI   LENBYT+2,X'04'                                           18760000
KVEXT    BCR   15,GR15                                                  18780000
*                                                                       18800000
RLABL    MVI   SAVEOP,RL                SAVE THE OP, SET PROPER GAMMA,  18820000
         MVI   LENBYT+2,X'04'           AND GO PROCESS                  18840000
         MVI   ERSW,X'00'                                               18860000
         B     B                                                        18880000
*                                                                       18900000
*  SAVE ULABEL OP CODE, SET LENGTH BYTE, RESET ERROR SWITCH.       000Z 18910017
ULABL    MVI   SAVEOP,UL                                                18920000
         MVI   LENBYT+2,X'01'                                           18940000
         MVI   ERSW,X'00'                                               18960000
         B     B                                                        18980000
*                                                                       19000000
ERPGC    MVI   SAVEOP,ER                ERPGC IS ALWAYS VALID. INDICATE 19020000
         LA    GR14,19                                                  19040000
         MVI   RLDBUF+87,ER                                             19060000
         MVC   RLDBUF+88(17),DUMCMP                                     19080000
         B     SETEND                   GO STORE IBYT AND ERBYTS.       19100000
*                                                                       19120000
EXIT     MVI   SAVEOP,EX                SET UP GAMMA AND FIELD MASK     19140000
         MVI   LENBYT+2,X'10'           FOR EXIT                        19160000
         MVI   FLDMSK,X'EF'                                             19180000
         MVI   ERSW,X'00'                                               19200000
         B     FAC2                                                     19220000
*                                                                       19240000
TAG      MVI   SAVEOP,TG                SET UP GAMMA AND FLD MASK       19260000
         MVI   LENBYT+2,X'02'           FOR TAG AND GOTO                19280000
         MVI   FLDMSK,X'FD'                                             19300000
         B     ENTRV                                                    19320000
*  SAVE GO TO OP CODE, SET LEN BYTE AND FLDMSK, RESET ERROR SWITCH 000Z 19326017
*  AND GO TO TEST FOR FACTOR 2 SPEC ENTRY.                         000Z 19332017
GOTO     MVI   SAVEOP,GO                                                19340000
         MVI   LENBYT+2,X'02'                                           19360000
         MVI   FLDMSK,X'FD'                                             19380000
         MVI   ERSW,X'00'                                               19400000
         B     FAC2                                                     19420000
******************************************************************      19440000
*              THIS ROUTINE HANDLES EXIT, TAG, AND GOTO                 19460000
******************************************************************      19480000
EXNAM    MVC   NAMBUF(6),FACT2(RDREG)   MOVE F2 TO WK-AREA              19500000
         MVI   USESW,X'FF'              SET FACTOR SW. IF GOTO, GO      19520000
         CLI   SAVEOP,GO                SEARCH FN TABLE.                19540000
         BE    CALFLD                                                   19560000
         B     SETRF                                                    19580000
MVFN     MVC   NAMBUF(6),FACT1(RDREG)   IF TAG, MOVE F1 TO WK-AREA.     19600000
SETRF    MVI   USESW,X'00'              SET SW FOR FN W/LEN.            19620000
         MVI   LENBYT,X'03'             SET LEN TO 4                    19640000
         MVI   LENBYT+1,C' '            DEC POS BLANK(ALPHA FIELD)      19660000
         MVI   LENBYT+3,C'0'            GAMMA HAS ALREADY BEEN SET,     19680000
CALFLD   BAL   GR15,FLDSCN              INDICATE LEN AND NO H-ADJ IN    19700000
         LA    GR14,RLDBUF+87                                           19720000
         BAL   GR13,TESTCL                                              19740000
         BAL   GR13,TSTIND              IND SPECIFIED. TEST  FOR THEM   19760000
         MVC   0(1,GR14),SAVEOP         MOVE OP. IF GOTO, STORE GAMMA   19780000
         CLI   SAVEOP,GO                FOR F2 IN 2ND BYTE OF OP        19800000
         MVC   1(1,GR14),LENBYT+2                                       19820000
         MVC   2(6,GR14),NAMBUF         MOVE IN F.N AND DUMMY RF AND    19840000
         MVC   8(10,GR14),DUMCMP        L,D,G,H                         19860000
         BE    BMPCMP                                                   19880000
         MVC   1(7,GR14),DUMCMP         IF TG OR EX, MOVE IN DUMMY F2   19900000
         MVC   8(6,GR14),NAMBUF         STORE FN IN RF W/LDGH           19920000
         MVC   14(4,GR14),LENBYT                                        19940000
BMPCMP   LA    GR14,18(GR14)                                            19960000
         B     TSIBYT                                                   19980000
******************************************************************      20000000
*              OP CODE TABLE AND DISPLACEMENTS TO ROUTINES              20020000
******************************************************************      20040000
OPSYM    DC    C'ADD  '                                                 20060000
         DC    AL2(ADD-START)                                           20080000
         DC    C'Z-ADD'                                                 20100000
         DC    AL2(ZADD-START)                                          20120000
         DC    C'SUB  '                                                 20140000
         DC    AL2(SUB-START)                                           20160000
         DC    C'Z-SUB'                                                 20180000
         DC    AL2(ZSUB-START)                                          20200000
         DC    C'MULT '                                                 20220000
         DC    AL2(MULT-START)                                          20240000
         DC    C'DIV  '                                                 20260000
         DC    AL2(DIV-START)                                           20280000
         DC    C'MVR  '                                                 20300000
         DC    AL2(MVR-START)                                           20320000
         DC    C'MOVE '                                                 20340000
         DC    AL2(MOVE-START)                                          20360000
         DC    C'MOVEL'                                                 20380000
         DC    AL2(MOVEL-START)                                         20400000
         DC    C'MLHZO'                                                 20420000
         DC    AL2(MLHZO-START)                                         20440000
         DC    C'MHLZO'                                                 20460000
         DC    AL2(MHLZO-START)                                         20480000
         DC    C'MHHZO'                                                 20500000
         DC    AL2(MHHZO-START)                                         20520000
         DC    C'MLLZO'                                                 20540000
         DC    AL2(MLLZO-START)                                         20560000
         DC    C'COMP '                                                 20580000
         DC    AL2(COMP-START)                                          20600000
         DC    C'TESTZ'                                                 20620000
         DC    AL2(TESTZ-START)                                         20640000
         DC    C'GOTO '                                                 20660000
         DC    AL2(GOTO-START)                                          20680000
         DC    C'TAG  '                                                 20700000
         DC    AL2(TAG-START)                                           20720000
         DC    C'EXIT '                                                 20740000
         DC    AL2(EXIT-START)                                          20760000
         DC    C'RLABL'                                                 20780000
         DC    AL2(RLABL-START)                                         20800000
         DC    C'ULABL'                                                 20820000
         DC    AL2(ULABL-START)                                         20840000
         DC    C'SETON'                                                 20860000
         DC    AL2(SETON-START)                                         20880000
         DC    C'SETOF'                                                 20900000
         DC    AL2(SETOF-START)                                         20920000
         DC    C'LOKUP'                                                 20940000
         DC    AL2(LOKUP-START)                                         20960000
         DC    C'RPGCV'                                                 20980000
         DC    AL2(RPGCV-START)                                         21000000
         DC    C'EXTCV'                                                 21020000
         DC    AL2(EXTCV-START)                                         21040000
         DC    C'ERPGC'                                                 21060000
         DC    AL2(ERPGC-START)                                         21080000
         DC    C'KEYCV'                                                 21100000
         DC    AL2(KEYCV-START)                                         21120000
*                                                                       21140000
******************************************************************      21160000
*              PROGRAM CONSTANTS                                        21180000
******************************************************************      21200000
H1       DC    H'1'                                                     21220000
H2       DC    H'2'                                                     21240000
H3       DC    H'3'                                                     21260000
H17      DC    H'17'                                                    21280000
P1       DC    P'1'                                                     21300000
P3       DC    P'3'                                                     21320000
P5       DC    P'5'                                                     21340000
P8       DC    P'8'                                                     21360000
P15      DC    P'15'                                                    21380000
BLANKS   DC    9C' '                                                    21400000
HEXZ     DC    X'00'                                                    21420000
CCZ      DC    C'00'                                                    21440000
CZ       DC    C'0'                                                     21460000
C8       DC    C'8'                                                     21480000
P256     DC    P'256'                                                   21500000
DUMCMP   DC    17X'00'                                                  21520000
FFS      DC    12X'FF'                                                  21540000
ZFS      DC    12X'0F'                                                  21560000
ENT5     DC    C'RPG10070'                                              21580000
ASSN1    DC    C'RPG10090'                                              21600000
CIN      DC    C'IN'                                                    21620000
CL0      DC    C'L0'                                                    21640000
ZRZR     DC    C'00'                                                    21660000
CXRADDR  DC    A(IES06910)                                              21680000
******************************************************************      21700000
*              PROGRAM VARIABLES                                        21720000
******************************************************************      21740000
RLDBUF   DS    CL132                                                    21760000
IBYT     EQU   RLDBUF+80                                                21780000
SAVEOP   EQU   RLDBUF+81                                                21800000
ERBYT    EQU   RLDBUF+120                                               21820000
F1COMP   EQU   RLDBUF+83                                                21840000
DELTA    EQU   RLDBUF+84                                                21860000
ABYT     EQU   RLDBUF+86                                                21880000
F2COMP   EQU   RLDBUF+95                                                21900000
         DS    0D                                                       21920000
SAVREG   DC    8X'00'                                                   21940000
SAVSEV   DS    F                                                        21960000
FACTSW   DC    X'00'                                                    21980000
SCNSW    DC    X'00'                                                    22000000
PACKAR   DS    CL10                                                     22020000
WKCOMP   DS    CL12                                                     22040000
NAMBUF   DS    CL6                                                      22060000
USESW    DC    X'00'                                                    22080000
FLDMSK   DC    X'00'                                                    22100000
LENBYT   DS    CL4                                                      22120000
FDSW     DC    X'00'                                                    22140000
PAKSW    DC    X'00'                                                    22160000
MINSW    DC    X'00'                                                    22180000
DECSW    DC    X'00'                                                    22200000
SAVDEC   DC    X'00'                                                    22220000
SAVDGT   DS    H                                                        22240000
PAKDGT   DS    H                                                        22260000
N        DS    H                                                        22280000
REGSAV   DS    F                                                        22300000
TOTSW    DC    X'00'                                                    22320000
REF      DC    X'00'                                                    22340000
ERSW     DC    X'00'                                                    22360000
FSW      DC    X'00'                                                    22380000
YES      DC    X'00'                                                    22400000
ARG      DS    CL2                                                      22420000
VALSW    DC    X'00'                                               4277 22430015
         END   ENTER4                                                   22440000
