         TITLE 'IES069  OS/360 RPG CIOEX OF ENTER PHASE 4           11' 00020000
*STATUS  CHANGE LEVEL 1-7                                               00040018
*                                                                       00060000
*FUNCTION/OPERATION   THE CIOEX ROUTINES ARE A SET OF EXTERNAL          00080000
*                     SUBROUTINES WHICH PERFORM ALL OF THE INPUT/OUTPUT 00100000
*                     OPERATIONS FOR THE COMPILER PHASES.  THE CIOEX    00120000
*                     ROUTINES OPERATE IN CONJUNCTION WITH THE CIOEX    00140000
*                     DATA AREA (POINTED TO BY REGISTER 6) WHICH        00160000
*                     CONTAINS THE DCB ADDRESSES, THE PRINTER AND       00180000
*                     READER/PUNCH BUFFERS, AND INFORMATION TO BE       00200000
*                     UPDATED WITH EACH INPUT/OUTPUT OPERATION.         00220000
*                     THE INDIVIDUAL CIOEX ROUTINES AND THE FUNCTIONS   00240000
*                     THEY PERFORM ARE DESCRIBED AT THE BEGINNING       00260000
*                     OF EACH ROUTINE.                                  00280000
*                                                                       00300000
*                     THOSE CIOEX ROUTINES REQUIRED BY A PHASE          00320000
*                     ARE ASSEMBLED AS A SEPARATE MODULE AND            00340000
*                     LINK-EDITED WITH THE PARENT PHASE.                00360000
*                     THE CIOEX CSECT ALSO SERVES AS THE ENTRY POINT    00380000
*                     FOR THE PHASE LOAD MODULE.                        00400000
*                                                                       00420000
*ENTRY POINT, INITIAL   IESCEX FROM THE CALLING PHASE VIA THE XCTL MACR 00440000
*                                                                       00460000
*ENTRY POINT, CIOEX ROUTINES   IES06910 FROM IES06010                   00480000
*                              CALLING SEQUENCE   EXTRN IES06910        00500000
*                                                 L     7,CXRADDR       00520000
*                                                 LA    2,CXRCODE       00540000
*                                                 BALR  5,7             00560000
*                                                 *                     00580000
*                                                 *                     00600000
*                                                 *                     00620000
*                                        CXRADDR  DC    A(IES06910)     00640000
*                                        CXRCODE  EQU   0,2,...50 DISPL 00660000
*                                                       TO THE ADDRESS  00680000
*                                                       OF THE CIOEX    00700000
*                                                       ROUTINE WANTED  00720000
*                                                       WITHIN THE      00740000
*                                                       TRANSFER VECTOR 00760000
*                                                                       00780000
*                              ADDRESS OF THE CIOEX DATA AREA PASSED    00800000
*                              IN REGISTER 6                            00820000
*                                                                       00840000
*INPUT   REQUEST CODE FOR THE CIOEX ROUTINE WANTED IN REGISTER 2        00860000
*        CIOEX DATA AREA                                                00880000
*                                                                       00900000
*OUTPUT   COMPLETED I/O OPERATION AS REQUESTED                          00920000
*         UPDATED CIOEX DATA AREA                                       00940000
*                                                                       00960000
*EXTERNAL ROUTINES   NONE                                               00980000
*                                                                       01000000
*EXIT, INITIAL   TO IES06010                                            01020000
*                CALLING SEQUENCE   PHSLINK  L     15,PHSADDR           01040000
*                                            BALR  7,15                 01060000
*                                            *                          01080000
*                                            *                          01100000
*                                            *                          01120000
*                                   PHSADDR  DC    V(IES06010)          01140000
*                                                                       01160000
*EXIT, CIOEX ROUTINES (EXCEPT PHSCAL)   BR    5        CIOEX RETURN REG 01180000
*                                                                       01200000
*EXIT, CIOEX PHSCAL   XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA       01220000
*                                                                       01240000
*EXIT, SYNCHRONOUS I/O ERROR   SET RETURN CODE TO 20                    01260000
*                              CALL TERMINAL PHASE VIA CIOEX PHSCAL     01280000
*                                                                       01300000
*TABLES/WORK AREAS   NONE                                               01320000
*                                                                       01340000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             01360000
*                                                                       01380000
*NOTES   ALL I/O OPERATIONS ARE PERFORMED WITH BSAM                     01400000
*        THE FOLLOWING MACROS ARE USED - READ                           01420000
*                                        WRITE                          01440000
*                                        CHECK                          01460000
*                                        NOTE                           01480000
*                                        POINT                          01500000
*                                                                       01520000
IESCEX   START                                                          01540000
*005600040,047000-047600                                           3142 01550015
* 015406-155740                                                    000Z 01550318
* 047260-047320,073760-073770                                      I168 01550618
         SPACE 1                                                        01550918
****************************************************************** 000Z 01551218
*                                                                  000Z 01551518
*        GENERAL REGISTER EQUATES FOR THIS PHASE                   000Z 01551818
*                                                                  000Z 01552118
****************************************************************** 000Z 01552418
XR0      EQU   0                                                        01552718
XR1      EQU   1                                                   000Z 01553018
XR2      EQU   2                                                   000Z 01553318
XR3      EQU   3                                                   000Z 01553618
XR4      EQU   4                                                   000Z 01553918
XR5      EQU   5                                                   000Z 01554218
XR6      EQU   6                                                   000Z 01554518
XR7      EQU   7                                                   000Z 01554818
XR8      EQU   8                                                   000Z 01555118
XR9      EQU   9                                                   000Z 01555418
XR10     EQU   10                                                  000Z 01555718
XR11     EQU   11                                                  000Z 01556018
XR12     EQU   12                                                  000Z 01556318
XR13     EQU   13                                                  000Z 01556618
XR14     EQU   14                                                  000Z 01556918
XR15     EQU   15                                                  000Z 01557218
         SPACE 1                                                        01557518
         ENTRY IES06910                                                 01560000
         USING CXDATA,6                                                 01580000
         USING *,15                                                     01600000
         ST    XR14,CXHLDREG            SAVE RETURN ADDR           000Z 01620018
PHSLINK  L     XR15,PHSADDR             LOAD PHASE ENTRY POINT ADDR000Z 01640018
         BALR  XR7,XR15                 LINK TO USER PHASE         000Z 01660018
         USING *,7                                                      01680000
CXBASE   ST    XR13,CXSAVEAR+8      SAVE USER WORK REG, NON-VOL    000Z 01700018
         LA    XR13,CXSAVEAR            LOAD SAVE AREA ADDR        000Z 01720018
         ST    XR5,CXSAVEAR             SAVE USER RETURN ADDR      000Z 01740018
         LA    XR5,CXRETURN             FORCE RETURN VIA CIOEX     000Z 01760018
         LH    XR2,CXRTAB(XR2)          DISP TO CIOEX ROUTINE      000Z 01780018
         AR    XR2,XR7                  ADD BASE REG               000Z 01800018
SPECRTRN BR    XR2                   BRANCH TO CIOEX ROUTINE WA    000Z 01820018
***********************************************                         01840000
*RETURN VIA CIOEX TO RESTORE WORK REG 13                                01860000
***********************************************                         01880000
CXRETURN L     XR13,CXSAVEAR+8          RESTORE USER WORK REG 13   000Z 01900018
         L     XR5,CXSAVEAR             RESTORE USER RETURN ADDRESS000Z 01920018
DUMRTRN  BR    XR5                      RETURN TO USER             000Z 01940018
***********************************************                         01960000
*TABLE OF DISPLACEMENTS TO CIOEX ROUTINES FROM BASE REG ADDRESS         01980000
***********************************************                         02000000
CXRTAB   DC    AL2(GETCMP-CXBASE)       GET COMPRESSION      ROUTINE 0  02020000
         DC    AL2(PUTCMP-CXBASE)       PUT COMPRESSION      ROUTINE 2  02040000
         DC    AL2(PHSCAL-CXBASE)       PHASE CALL           ROUTINE 4  02060000
         DC    AL2(PNTERR-CXBASE)       PRINT ERROR NOTE     ROUTINE 6  02080000
         DC    AL2(PNTSPC-CXBASE)       PRINT SPEC           ROUTINE 8  02100000
         DC    AL2(RDSPEC-CXBASE)       READ SPEC            ROUTINE 10 02120000
         DC    AL2(PUTCOD-CXBASE)       PUNCH/GO OUTPUT      ROUTINE 12 02140000
         DC    AL2(SWITCH-CXBASE)       SWITCH WKFIL1,WKFIL2 ROUTINE 14 02160000
         DC    AL2(PTCMPR-CXBASE)       POINT COMP FOR READ  ROUTINE 16 02180000
         DC    AL2(RLDOUT-CXBASE)       WRITE RLD            ROUTINE 18 02200000
         DC    AL2(RLDIN-CXBASE)        READ RLD             ROUTINE 20 02220000
         DC    AL2(PTRLDW-CXBASE)       POINT RLD FOR WRITE  ROUTINE 22 02240000
         DC    AL2(BLKOUT-CXBASE)       WRITE BLANK AFTER    ROUTINE 24 02260000
         DC    AL2(BLKIN-CXBASE)        READ BLANK AFTER     ROUTINE 26 02280000
         DC    AL2(PTBLKW-CXBASE)       POINT BLKAFTR, WRITE ROUTINE 28 02300000
         DC    AL2(PNTINP-CXBASE)       POINT FIRST INPUT SP ROUTINE 30 02320000
         DC    AL2(PNTCLC-CXBASE)       POINT FIRST CALC SP  ROUTINE 32 02340000
         DC    AL2(PNTOUT-CXBASE)       POINT FIRST OUTPT SP ROUTINE 34 02360000
         DC    AL2(NOTEIN-CXBASE)       NOTE FIRST INPUT SP  ROUTINE 36 02380000
         DC    AL2(NOTECL-CXBASE)       NOTE FIRST CALC SP   ROUTINE 38 02400000
         DC    AL2(NOTEOT-CXBASE)       NOTE FIRST OUTPUT SP ROUTINE 40 02420000
         DC    AL2(NTASGN-CXBASE)       NOTE ANY SPEC        ROUTINE 42 02440000
         DC    AL2(PTASGN-CXBASE)       POINT TO PREV NOTE   ROUTINE 44 02460000
         DC    AL2(PHDUMP-CXBASE)       DUMP WITHIN LIMITS   ROUTINE 46 02480000
         DC    AL2(PTBLKR-CXBASE)       POINT BLKAFTR, READ  ROUTINE 48 02500000
         DC    AL2(PTRLDR-CXBASE)       POINT RLD FOR READ   ROUTINE 50 02520000
PHSADDR  DC    V(IES06010)              PHASE ENTRY POINT ADDR          02540000
DADEVT   EQU   X'20'                    DEVICE TYPE CODE FOR DIRECT ACC 02560000
IES06910 EQU   CXBASE                                                   02580000
***********************************************                         02600000
*COMMON READ/WRITE/CHECK ROUTINE FOR ALL FILES                          02620000
***********************************************                         02640000
READ     MVI   TYPE,X'80'               SET FOR READ SF                 02660000
         B     *+8                                                      02680000
WRITE    MVI   TYPE,X'20'               SET FOR WRITE SF                02700000
         LA    XR1,DECB                 LOAD DECB ADDR             000Z 02720018
         STM   XR14,XR15,8(XR1)        STORE DCB ADDR AND AREA     000Z 02740018
         L     XR15,48(,XR14)           LOAD DCB OFFSET            000Z 02760018
         BALR  XR14,XR15                LINK FOR READ/WRITE        000Z 02780018
*        CHECK DECB                                                     02800000
         LA    XR1,DECB                 LOAD DECB ADDR             000Z 02820018
         L     XR14,8(,XR1)             LOAD DCB ADDR              000Z 02840018
         L     XR15,52(,XR14)           LOAD CHECK ROUT ADDR       000Z 02860018
         LR    XR14,XR2               SET FOR DIRECT RETURN TO     000Z 02880018
         BALR  XR2,XR15                 LINK TO CHECK              000Z 02900018
***********************************************                         02920000
*LINKAGE TO EOF ROUTINE                                                 02940000
***********************************************                         02960000
         B     RDSPECA                                                  02980000
***********************************************                         03000000
*SYNCHRONOUS ERROR ROUTINE                                              03020000
***********************************************                         03040000
         MVI   CXRETCDE,20              SYNCH ERROR RETURN CODE         03060000
         MVC   CXPHSNAM(8),TERMPHS      SET TO CALL TERMINAL PHASE      03080000
         B     PHSCALC                  CLOSE FILES AND RETURN TO SUPV  03100000
TERMPHS  DC    C'RPG10250'              PHASE NAME FOR TERMINAL PHASE   03120000
***********************************************                         03140000
*COMMON DECB FOR ALL FILES                                              03160000
***********************************************                         03180000
DECB     DC    F'0'                     EVENT CONTROL BLOCK             03200000
OPFLD    DC    X'00'                    OP FIELD                        03220000
TYPE     DC    X'00'                    READ/WRITE SF                   03240000
LENGFLD  DC    AL2(0)                   LENGTH FIELD                    03260000
DCBADDR  DC    A(0)                     DCB ADDRESS                     03280000
AREADDR  DC    A(0)                     AREA ADDRESS                    03300000
         DC    A(0)                     POINTER TO STATUS INDICATORS    03320000
***********************************************                         03340000
*PHASE CALL ROUTINE                                                     03360000
***********************************************                         03380000
*XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA                            03400000
***********************************************                         03420000
PHSCALC  LR    XR12,XR6              REINIT REG 12 TO CIOEX DAT    000Z 03440018
PHSCAL   EQU   PHSCALC                                                  03460000
         L     XR14,CXHLDREG            RESTORE RETURN ADDR        000Z 03480018
         LA    XR9,CXPHSNAM                                        000Z 03500018
         XCTL  EPLOC=(9)                CALL NEXT PHASE                 03520000
***********************************************                         03540000
*ERROR NOTE ROUTINE                                                     03560000
***********************************************                         03580000
PNTERR   PACK  CXDUBLWD(8),PNTRAREA+96(3)                               03600000
         CVB   XR14,CXDUBLWD          CONVERT NOTE NUMBER TO BI    000Z 03620018
         LA    XR15,7                   MASK FOR REMAINDER         000Z 03640018
         NR    XR15,XR14                PICK OFF REMAINDER         000Z 03660018
         SRL   XR14,3                   DIVIDE NOTE NUMBER BY 8    000Z 03680018
         LA    XR2,256               INIT BIT TO TURN ON ERROR     000Z 03700018
         LA    XR15,1(XR15)            INCR REMAINDER FOR BCT I    000Z 03720018
PNTERRA  SRL   XR2,1                ADJUST BIT TO CORRESP TO RE    000Z 03740018
         BCT   XR15,PNTERRA                                        000Z 03760018
         IC    XR15,CXNOTES(XR14)       PICK UP ERROR NOTE BYTE    000Z 03780018
         OR    XR15,XR2             TURN ON BIT CORRESP TO ERR     000Z 03800018
         STC   XR15,CXNOTES(XR14)     STORE UPDATED ERROR NOTE     000Z 03820018
         MVC   PNTRAREA+93(3),PNTERRB   MOVE 'IES' TO PRINT BUFF        03840000
         MVI   PNTRAREA+99,C'I'         INSERT INFORMATION IDENT        03860000
         B     PNTSPC                   PRINT ERROR NOTE                03880000
PNTERRB  DC    C'IES'                   OS/RPG PREFIX                   03900000
***********************************************                         03920000
*PRINT SPECIFICATION                                                    03940000
***********************************************                         03960000
PNTSPC   TM    CXCMPOPT,X'04'           IF NOLIST                       03980000
         BCR   1,XR5                      RETURN TO USER           000Z 04000018
*        WRITE DECB,SF,LSTFIL,PNTRARAC                                  04020000
         L     XR14,CXDCBLST            LOAD LIST FILE DCB ADDR AND000Z 04040018
         LA    XR15,PNTRARAC             PRINT BUFFER ADDR W/CT    000Z 04060018
         BAL   XR2,WRITE                LINK FOR WRITE             000Z 04080018
         MVI   PNTRAREA,C' '            CLEAR                           04100000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT BUFFER                  04120000
***********************************************                         04140000
*TAKE CARE OF CARRIAGE CONTROL, OVERFLOW AND HEADING                    04160000
***********************************************                         04180000
         CLI   PNTRARAC,C'0'            WAS DOUBLE SPACE SPECIFIED      04200000
         BNE   *+10                     NO                              04220000
         SP    CXLINBCT(2),CXONEPCK     YES, DECR LINE COUNT ONE EXTRA  04240000
         MVC   PNTRARAC(1),PNTSPCA      SET CONTROL CHAR FOR NEXT PRINT 04260000
         MVI   PNTSPCA,C' '             SET FOR SING SP, NEXT PRINT + 1 04280000
         SP    CXLINBCT(2),CXONEPCK     DECREMENT LINE COUNT            04300000
         BCR   2,XR5                    IF POSITIVE RETURN TO USER 000Z 04320018
         MVI   PNTRARAC,C'1'            SET CONTROL CHAR FOR PAGE EJECT 04340000
         MVC   CXLINBCT(2),CXLINCNT     INIT LINE COUNT - 52 LINES      04360000
         AP    CXPAGNUM(4),CXONEPCK     INCR PAGE NUMBER                04380000
         UNPK  PNTRAREA+96(4),CXPAGNUM(4) PLACE PAGE NUM IN PRINT AREA  04400000
         OI    PNTRAREA+99,X'F0'        ERASE PLUS SIGN                 04420000
         MVC   PNTRAREA+91(4),PNTSPCB   MOVE 'PAGE' INTO PRINT BUFF     04440000
         MVC   PNTRAREA+70(8),CXTODAY   MOVE IN DATE                    04460000
         MVC   PNTRAREA+50(8),CXSTEPNA  MOVE IN STEP NAME               04480000
         MVC   PNTRAREA+40(8),CXJOBNAM  MOVE IN JOB NAME                04500000
         MVC   PNTRAREA+5(17),CXHEADIN  MOVE IN RPG/E IDENT             04520000
         MVI   PNTSPCA,C'0'             SET FOR DOUB SP, NEXT PRINT + 1 04540000
         B     PNTSPC                   PRINT HEADING LINE              04560000
PNTSPCA  DC    C' '                     SINGLE SPACE                    04580000
PNTSPCB  DC    C'PAGE'                                                  04600000
***********************************************                         04620000
*READ A SPECIFICATION FROM SYSIPT                                       04640000
***********************************************                         04660000
*        READ  DECB,SF,SRCFIL,RDRPCHAR                                  04680000
RDSPEC   ST    XR5,RDSPSAVE         SAVE RETURN REGISTER           000Z 04683018
         L     XR15,CXDBLKAD        GET ADDR OF RESIDENT           000Z 04686018
         BALR  XR5,XR15              DEBLK RTN & GO THERE          000Z 04689018
*                                                                  3142 04692015
*   THE FOLLOWING LINKAGE VECTOR IS USED BY THE RESIDENT           3142 04695015
*   DEBLOCK ROUTINE TO RETURN TO CIOEX AND TAKE CORRECT ACTION     3142 04698015
*   FOR HANDLING OF BLOCKED SOURCE RECORDS FROM SYSIN              3142 04701015
*                                                                  3142 04704015
         B     READEXIT                 RECORD MOVED TO WK AREA    3142 04707015
         B     READBLK                  READ A BLK & RETURN        3142 04710015
         B     RDSPECA                  EOF IN DEBLK RTN           3142 04713015
*                                                                  3142 04716015
*   THE FOLLOWING ROUTINES ARE CALLED FROM THE RESIDENT            3142 04719015
*   DEBLOCK ROUTINE THRU THE LINKAGE VECTOR ABOVE                  3142 04722015
*                                                                  3142 04725015
READEXIT L     XR5,RDSPSAVE         RESTORE RETURN REGISTER        000Z 04726018
         CLI   RDRPCHAR+6,C'*'          IS IT A COMMENTS CARD      I168 04727018
         BCR   8,XR5                    YES, RETURN                I168 04728018
         LH    XR2,CXCRDCNT             COUNT EACH OF THE          I168 04729018
         LA    XR2,1(XR2)              SOURCE STATEMENTS           I168 04730018
         STH   XR2,CXCRDCNT            AS THEY ARE READ.           I168 04731018
         BR    XR5                  RETURN TO CALLER               000Z 04732018
*                                                                  3142 04734015
READBLK  L     XR14,CXDCBSRC        LOAD SOURCE DCB ADDR &         000Z 04737018
         L     XR15,CXINAREA         SOURCE BUFFER ADDR            000Z 04740018
         BAL   XR2,READ             LINK TO READ A BLOCK           000Z 04743018
         L     XR5,RDSPSAVE         RESTORE RETURN REGISTER        000Z 04746018
         B     RDSPEC                   GO DEBLOCK FROM NEW BLOCK  3142 04749015
*                                                                  3142 04752015
RDSPSAVE DS    F                        RETURN REG SAVE AREA       3142 04755015
*                                                                  3142 04758015
***********************************************                         04780000
*EOF ROUTINE                                                            04800000
***********************************************                         04820000
RDSPECA  MVC   PNTRAREA+96(3),RDSPECD   ERROR NOTE 250 TO PRINT AREA    04840000
         ST    XR5,RDSPECB              SAVE USER RETURN REG       000Z 04860018
         BAL   XR5,PNTERR               PRINT ERROR NOTE           000Z 04880018
         L     XR5,RDSPECB              RESTORE USER RETURN REG    000Z 04900018
         MVC   0(8,XR4),RDSPECC         MOVE IN DUMMY OUTPUT SPEC  000Z 04920018
         BR    XR5                      RETURN TO USER             000Z 04940018
RDSPECB  DS    F                        RETURN REG HOLD                 04960000
RDSPECC  DC    C'DUMMYO**'              DUMMY OUTPUT SPEC               04980000
RDSPECD  DC    C'250'                   ERROR NOTE 250                  05000000
***********************************************                         05020000
*WORK FILE SERVICE   (REG 1 CONTAINS ADDR OF I/O AREA)                  05040000
***********************************************                         05060000
*        WRITE DECB,SF,(CXDCBWK3),(1),132                               05080000
RLDOUT   ST    XR1,RLDOUTE              STORE ADDR OF I/O AREA     000Z 05100018
         MVC   LENGFLD(2),RLDOUTF       SUPPLY LENGTH TO DECB           05120000
         L     XR14,CXDCBWK3            LOAD DCB ADDR AND          000Z 05140018
         L     XR15,RLDOUTE                  ADDR OF I/O AREA      000Z 05160018
         BAL   XR2,WRITE                LINK FOR WRITE             000Z 05180018
         LH    XR14,CXNUMRLD            LOAD FILE COUNTER          000Z 05200018
         LA    XR14,1(XR14)             INCREMENT                  000Z 05220018
         STH   XR14,CXNUMRLD            STORE UPDATED COUNTER      000Z 05240018
         L     XR1,RLDOUTE              RESTORE REG 1 FOR USER     000Z 05260018
         BR    XR5                      RETURN TO USER             000Z 05280018
RLDOUTE  DS    F                        ADDR OF I/O AREA                05300000
RLDOUTF  DC    H'132'                   LENGTH OF RECORD                05320000
***********************************************                         05340000
*POINT TO BEGINNING OF A FILE FOR WKFIL1, WKFIL2, WKFIL3                05360000
***********************************************                         05380000
PTRLD    L     XR1,CXDCBWK3             LOAD DCB ADDR              000Z 05400018
         LA    XR0,256              LOAD TTRZ BLOCK ID FOR DA,     000Z 05420018
         TM    17(XR1),DADEVT           IS DEVICE TYPE DA          000Z 05440018
         BO    PTRLDA                   YES                             05460000
         LA    XR0,1                    LOAD ZZCC ID FOR TAPE, 0001000Z 05480018
PTRLDA   ST    XR0,CXDUBLWD+4           STORE BLOCK ID FOR POINT   000Z 05500018
         LA    XR0,CXDUBLWD+4       LOAD ADDR OF BLOCK ID FOR P    000Z 05520018
         POINT (1),(0)                  POINT TO BLOCK 1                05540000
         BR    XR5                      RETURN TO USER             000Z 05560018
PTRLDR   EQU   PTRLD                                                    05580000
PTRLDW   EQU   PTRLD                                                    05600000
GETCMP   EQU   DUMRTRN                                                  05620000
PUTCMP   EQU   DUMRTRN                                                  05640000
PUTCOD   EQU   DUMRTRN                                                  05660000
SWITCH   EQU   DUMRTRN                                                  05680000
PTCMPR   EQU   DUMRTRN                                                  05700000
RLDIN    EQU   DUMRTRN                                                  05720000
BLKOUT   EQU   DUMRTRN                                                  05740000
BLKIN    EQU   DUMRTRN                                                  05760000
PTBLKW   EQU   DUMRTRN                                                  05780000
PNTINP   EQU   DUMRTRN                                                  05800000
PNTCLC   EQU   DUMRTRN                                                  05820000
PNTOUT   EQU   DUMRTRN                                                  05840000
NOTEIN   EQU   DUMRTRN                                                  05860000
NOTECL   EQU   DUMRTRN                                                  05880000
NOTEOT   EQU   DUMRTRN                                                  05900000
NTASGN   EQU   DUMRTRN                                                  05920000
PTASGN   EQU   DUMRTRN                                                  05940000
PHDUMP   EQU   DUMRTRN                                                  05960000
PTBLKR   EQU   DUMRTRN                                                  05980000
***********************************************                         06000000
*CIOEX DATA AREA                                                        06020000
***********************************************                         06040000
CXDATA   DSECT                                                          06060000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       06080000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 06100000
*                                         (START WITH PREPHASE)         06120000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 06140000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       06160000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   06180000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     06200000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     06220000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     06240000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        06260000
CXFLDADD DS    F                                FIELD NAME TABLE        06280000
CXLITADD DS    F                                LITERAL TABLE           06300000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 06320000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     06340000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      06360000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   06380000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                06400000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      06420000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         06440000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      06460000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    06480000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     06500000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    06520000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            06540000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    06560000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   06580000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           06600000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      06620000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  06640000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   06660000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 06680000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    06700000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         06720000
CXRETCDE DC    X'00'                    RETURN CODE                     06740000
CXIPTEOF BR    XR2                      LINKAGE TO EOF ROUTINE     000Z 06760018
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            06780000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          06800000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    06820000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           06840000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     06860000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    06880000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                06900000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             06920000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            06940000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     06960000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      06980000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    07000000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   07020000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        07040000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               07060000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     07080000
CXSYNERR B     4(XR2)                LINKAGE TO SYNCH ERROR ROU    000Z 07100018
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    07120000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     07140000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        07160000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          07180000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        07200000
CXTODAY  DC    C'  /  /  '              DATE                            07220000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             07240000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        07260000
RDRPCHAR DS    80C                      READER/PUNCH AREA               07280000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       07300000
PNTRAREA DS    120C                     PRINT AREA                      07320000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 07340000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 07360000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 07365015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 07370015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 07375015
CXSEQCHK DS    6C                        PAGE/LINE SEQUENCE CHECK  I168 07376018
CXCRDCNT DS    H                        SOURCE STATEMENT COUNT     I168 07377018
CXDEND   EQU   *                                                        07380000
         END   IESCEX                                                   07400000
