         TITLE 'IES079  OS/360 RPG CIOEX OF ENTER PHASE 5           13' 00020000
* STATUS     CHANGE LEVEL  1-5                                     000A 00040016
*                                                                       00060000
*FUNCTION/OPERATION   THE CIOEX ROUTINES ARE A SET OF EXTERNAL          00080000
*                     SUBROUTINES WHICH PERFORM ALL OF THE INPUT/OUTPUT 00100000
*                     OPERATIONS FOR THE COMPILER PHASES.  THE CIOEX    00120000
*                     ROUTINES OPERATE IN CONJUNCTION WITH THE CIOEX    00140000
*                     DATA AREA (POINTED TO BY REGISTER 6) WHICH        00160000
*                     CONTAINS THE DCB ADDRESSES, THE PRINTER AND       00180000
*                     READER/PUNCH BUFFERS, AND INFORMATION TO BE       00200000
*                     UPDATED WITH EACH INPUT/OUTPUT OPERATION.         00220000
*                     THE INDIVIDUAL CIOEX ROUTINES AND THE FUNCTIONS   00240000
*                     THEY PERFORM ARE DESCRIBED AT THE BEGINNING       00260000
*                     OF EACH ROUTINE.                                  00280000
*                                                                       00300000
*                     THOSE CIOEX ROUTINES REQUIRED BY A PHASE          00320000
*                     ARE ASSEMBLED AS A SEPARATE MODULE AND            00340000
*                     LINK-EDITED WITH THE PARENT PHASE.                00360000
*                     THE CIOEX CSECT ALSO SERVES AS THE ENTRY POINT    00380000
*                     FOR THE PHASE LOAD MODULE.                        00400000
*                                                                       00420000
*ENTRY POINT, INITIAL   IESCEX FROM THE CALLING PHASE VIA THE XCTL MACR 00440000
*                                                                       00460000
*ENTRY POINT, CIOEX ROUTINES   IES07910 FROM IES07010                   00480000
*                              CALLING SEQUENCE   EXTRN IES07910        00500000
*                                                 L     7,CXRADDR       00520000
*                                                 LA    2,CXRCODE       00540000
*                                                 BALR  5,7             00560000
*                                                 *                     00580000
*                                                 *                     00600000
*                                                 *                     00620000
*                                        CXRADDR  DC    A(IES07910)     00640000
*                                        CXRCODE  EQU   0,2,...50 DISPL 00660000
*                                                       TO THE ADDRESS  00680000
*                                                       OF THE CIOEX    00700000
*                                                       ROUTINE WANTED  00720000
*                                                       WITHIN THE      00740000
*                                                       TRANSFER VECTOR 00760000
*                                                                       00780000
*                              ADDRESS OF THE CIOEX DATA AREA PASSED    00800000
*                              IN REGISTER 6                            00820000
*                                                                       00840000
*INPUT   REQUEST CODE FOR THE CIOEX ROUTINE WANTED IN REGISTER 2        00860000
*        CIOEX DATA AREA                                                00880000
*                                                                       00900000
*OUTPUT   COMPLETED I/O OPERATION AS REQUESTED                          00920000
*         UPDATED CIOEX DATA AREA                                       00940000
*                                                                       00960000
*EXTERNAL ROUTINES   NONE                                               00980000
*                                                                       01000000
*EXIT, INITIAL   TO IES07010                                            01020000
*                CALLING SEQUENCE   PHSLINK  L     15,PHSADDR           01040000
*                                            BALR  7,15                 01060000
*                                            *                          01080000
*                                            *                          01100000
*                                            *                          01120000
*                                   PHSADDR  DC    V(IES07010)          01140000
*                                                                       01160000
*EXIT, CIOEX ROUTINES (EXCEPT PHSCAL)   BR    5        CIOEX RETURN REG 01180000
*                                                                       01200000
*EXIT, CIOEX PHSCAL   XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA       01220000
*                                                                       01240000
*EXIT, SYNCHRONOUS I/O ERROR   SET RETURN CODE TO 20                    01260000
*                              CALL TERMINAL PHASE VIA CIOEX PHSCAL     01280000
*                                                                       01300000
*TABLES/WORK AREAS   NONE                                               01320000
*                                                                       01340000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             01360000
*                                                                       01380000
*NOTES   ALL I/O OPERATIONS ARE PERFORMED WITH BSAM                     01400000
*        THE FOLLOWING MACROS ARE USED - READ                           01420000
*                                        WRITE                          01440000
*                                        CHECK                          01460000
*                                        NOTE                           01480000
*                                        POINT                          01500000
*                                                                       01520000
IESCEX   START                                                          01540000
*0141000400,015500,055200,056200,062000                            000A 01550016
         ENTRY IES07910                                                 01560000
         USING CXDATA,6                                                 01580000
         USING *,15                                                     01600000
         ST    14,CXHLDREG              SAVE RETURN ADDR                01620000
PHSLINK  L     15,PHSADDR               LOAD PHASE ENTRY POINT ADDR     01640000
         BALR  7,15                     LINK TO USER PHASE              01660000
         USING *,7                                                      01680000
CXBASE   ST    13,CXSAVEAR+8            SAVE USER WORK REG, NON-VOLATLE 01700000
         LA    13,CXSAVEAR              LOAD SAVE AREA ADDR             01720000
         ST    5,CXSAVEAR               SAVE USER RETURN ADDR           01740000
         LA    5,CXRETURN               FORCE RETURN VIA CIOEX          01760000
         LH    2,CXRTAB(2)              DISP TO CIOEX ROUTINE           01780000
         AR    2,7                      ADD BASE REG                    01800000
SPECRTRN BR    2                        BRANCH TO CIOEX ROUTINE WANTED  01820000
***********************************************                         01840000
*RETURN VIA CIOEX TO RESTORE WORK REG 13                                01860000
***********************************************                         01880000
CXRETURN L     13,CXSAVEAR+8            RESTORE USER WORK REG 13        01900000
         L     5,CXSAVEAR               RESTORE USER RETURN ADDRESS     01920000
DUMRTRN  BR    5                        RETURN TO USER                  01940000
***********************************************                         01960000
*TABLE OF DISPLACEMENTS TO CIOEX ROUTINES FROM BASE REG ADDRESS         01980000
***********************************************                         02000000
CXRTAB   DC    AL2(GETCMP-CXBASE)       GET COMPRESSION      ROUTINE 0  02020000
         DC    AL2(PUTCMP-CXBASE)       PUT COMPRESSION      ROUTINE 2  02040000
         DC    AL2(PHSCAL-CXBASE)       PHASE CALL           ROUTINE 4  02060000
         DC    AL2(PNTERR-CXBASE)       PRINT ERROR NOTE     ROUTINE 6  02080000
         DC    AL2(PNTSPC-CXBASE)       PRINT SPEC           ROUTINE 8  02100000
         DC    AL2(RDSPEC-CXBASE)       READ SPEC            ROUTINE 10 02120000
         DC    AL2(PUTCOD-CXBASE)       PUNCH/GO OUTPUT      ROUTINE 12 02140000
         DC    AL2(SWITCH-CXBASE)       SWITCH WKFIL1,WKFIL2 ROUTINE 14 02160000
         DC    AL2(PTCMPR-CXBASE)       POINT COMP FOR READ  ROUTINE 16 02180000
         DC    AL2(RLDOUT-CXBASE)       WRITE RLD            ROUTINE 18 02200000
         DC    AL2(RLDIN-CXBASE)        READ RLD             ROUTINE 20 02220000
         DC    AL2(PTRLDW-CXBASE)       POINT RLD FOR WRITE  ROUTINE 22 02240000
         DC    AL2(BLKOUT-CXBASE)       WRITE BLANK AFTER    ROUTINE 24 02260000
         DC    AL2(BLKIN-CXBASE)        READ BLANK AFTER     ROUTINE 26 02280000
         DC    AL2(PTBLKW-CXBASE)       POINT BLKAFTR, WRITE ROUTINE 28 02300000
         DC    AL2(PNTINP-CXBASE)       POINT FIRST INPUT SP ROUTINE 30 02320000
         DC    AL2(PNTCLC-CXBASE)       POINT FIRST CALC SP  ROUTINE 32 02340000
         DC    AL2(PNTOUT-CXBASE)       POINT FIRST OUTPT SP ROUTINE 34 02360000
         DC    AL2(NOTEIN-CXBASE)       NOTE FIRST INPUT SP  ROUTINE 36 02380000
         DC    AL2(NOTECL-CXBASE)       NOTE FIRST CALC SP   ROUTINE 38 02400000
         DC    AL2(NOTEOT-CXBASE)       NOTE FIRST OUTPUT SP ROUTINE 40 02420000
         DC    AL2(NTASGN-CXBASE)       NOTE ANY SPEC        ROUTINE 42 02440000
         DC    AL2(PTASGN-CXBASE)       POINT TO PREV NOTE   ROUTINE 44 02460000
         DC    AL2(PHDUMP-CXBASE)       DUMP WITHIN LIMITS   ROUTINE 46 02480000
         DC    AL2(PTBLKR-CXBASE)       POINT BLKAFTR, READ  ROUTINE 48 02500000
         DC    AL2(PTRLDR-CXBASE)       POINT RLD FOR READ   ROUTINE 50 02520000
PHSADDR  DC    V(IES07010)              PHASE ENTRY POINT ADDR          02540000
DADEVT   EQU   X'20'                    DEVICE TYPE CODE FOR DIRECT ACC 02560000
IES07910 EQU   CXBASE                                                   02580000
***********************************************                         02600000
*COMMON READ/WRITE/CHECK ROUTINE FOR ALL FILES                          02620000
***********************************************                         02640000
READ     MVI   TYPE,X'80'               SET FOR READ SF                 02660000
         B     *+8                                                      02680000
WRITE    MVI   TYPE,X'20'               SET FOR WRITE SF                02700000
         LA    1,DECB                   LOAD DECB ADDR                  02720000
         STM   14,15,8(1)               STORE DCB ADDR AND AREA ADDR    02740000
         L     15,48(0,14)              LOAD DCB OFFSET                 02760000
         BALR  14,15                    LINK FOR READ/WRITE             02780000
*        CHECK DECB                                                     02800000
         LA    1,DECB                   LOAD DECB ADDR                  02820000
         L     14,8(0,1)                LOAD DCB ADDR                   02840000
         L     15,52(0,14)              LOAD CHECK ROUT ADDR            02860000
         LR    14,2                     SET FOR DIRECT RETURN TO USER   02880000
         BALR  2,15                     LINK TO CHECK                   02900000
         NOP   0                                                        02920000
***********************************************                         02940000
*SYNCHRONOUS ERROR ROUTINE                                              02960000
***********************************************                         02980000
         MVI   CXRETCDE,20              SYNCH ERROR RETURN CODE         03000000
         MVC   CXPHSNAM(8),TERMPHS      SET TO CALL TERMINAL PHASE      03020000
         B     PHSCALC                  CLOSE FILES AND RETURN TO SUPV  03040000
TERMPHS  DC    C'RPG10250'              PHASE NAME FOR TERMINAL PHASE   03060000
***********************************************                         03080000
*COMMON DECB FOR ALL FILES                                              03100000
***********************************************                         03120000
DECB     DC    F'0'                     EVENT CONTROL BLOCK             03140000
OPFLD    DC    X'00'                    OP FIELD                        03160000
TYPE     DC    X'00'                    READ/WRITE SF                   03180000
LENGFLD  DC    AL2(0)                   LENGTH FIELD                    03200000
DCBADDR  DC    A(0)                     DCB ADDRESS                     03220000
AREADDR  DC    A(0)                     AREA ADDRESS                    03240000
         DC    A(0)                     POINTER TO STATUS INDICATORS    03260000
***********************************************                         03280000
*PUT COMPRESSION                                                        03300000
***********************************************                         03320000
*        WRITE DECB,SF,WKFIL2,(CXCMPADD),(CXCMPEXT)                     03340000
PUTCMP   MVC   LENGFLD(2),CXCMPEXT+2    LENGTH OF COMPR TO DECB         03360000
         L     14,CXDCBWK2              LOAD WORK FILE 1 DCB ADDR AND   03380000
         L     15,CXCMPADD                   COMPR ADDR                 03400000
         BAL   2,WRITE                  LINK FOR WRITE                  03420000
***********************************************                         03440000
*NOTE THE LAST COMPRESSION BLOCK WRITTEN, IF REQUIRED                   03460000
***********************************************                         03480000
         L     1,CXDCBWK2               LOAD COMPR DCB ADDR             03500000
         NOTE  (1)                      NOTE                            03520000
         LA    14,CXCALCNT              LOAD ADDR OF FIRST NOTE NUM     03540000
         LA    15,4                     LOAD COUNT OF NOTE NUMS         03560000
PUTCMPF  CLI   0(14),X'FF'              IS THIS NOTE NUM FLAGGED        03580000
         BNE   PUTCMPH                  NO, SKIP                        03600000
         ST    1,0(0,14)                YES, STORE BLOCK ID THERE       03620000
PUTCMPH  LA    14,4(14)                 INCREMENT TO NEXT NOTE NUM      03640000
         BCT   15,PUTCMPF               CONTINUE                        03660000
         ST    1,CXDUBLWD               ACCUM MAX BLOCK NUM             03680000
         CLC   CXDUBLWD+2(1),CXTRKBF      PER TRACK                     03700000
         BNH   *+10                       FOR DIRECT ACCESS             03720000
         MVC   CXTRKBF(1),CXDUBLWD+2                                    03740000
***********************************************                         03760000
*INITIALIZE COMPRESSION WITH X'FE' UP TO LAST 60 BYTES,                 03780000
*    THEN X'FF' TO END                                                  03800000
***********************************************                         03820000
         ST    5,CXDUBLWD               FREE REG 5 FOR WORK             03840000
         L     14,CXCMPADD              ADDR OF COMPR                   03860000
         L     15,CXCMPEXT              LENG OF COMPR                   03880000
         LA    2,60                     LENG OF TRAILER                 03900000
         LA    5,255                    MAX MOVE LENGTH                 03920000
         MVI   0(14),X'FE'              X'FE' TO FIRST COMPR BYTE       03940000
         SR    15,2                     COMPUTE LENGTH TO FILL X'FE'    03960000
PUTCMPA  CR    15,5                     IS X'FE' LENGTH GTR THAN 255    03980000
         BNH   PUTCMPB                  NO, FILL REMAINDER              04000000
         EX    5,PUTCMPC                YES, FILL 256 BYTES WITH X'FE'  04020000
         AR    14,5                     INCR TARGET ADDR BY 255         04040000
         SR    15,5                     DECR X'FE' LENGTH BY 255        04060000
         B     PUTCMPA                  REPEAT                          04080000
PUTCMPB  EX    15,PUTCMPC               FILL REMAINING BYTES WITH X'FE' 04100000
         AR    14,15                    INCR TARGET ADDR BY REMAINDER   04120000
         MVI   0(14),X'FF'              X'FF' TO FIRST TRAILER BYTE     04140000
         BCTR  2,0                      SUBTR 2 FROM LENG OF TRAILER,   04160000
         BCTR  2,0                        1 TO COMPENSATE FOR FIRST CH, 04180000
*                                         1 TO COMPENSATE FOR EXEC INST 04200000
         EX    2,PUTCMPC                FILL TRAILER BYTES WITH X'FF'   04220000
         LH    14,CXNUMCMP              LOAD COMPR BLOCK COUNT          04240000
         LA    14,1(14)                 INCREMENT                       04260000
         STH   14,CXNUMCMP              STORE UPDATED BLOCK COUNT       04280000
         MVC   CXBLKNUM(2),CXNUMCMP     UPDATE COMPR BLOCK NUMBER       04300000
*                                         CURRENTLY BEING PROCESSED     04320000
         OI    CXCMPOVF+1,X'F0'         TURN ON COMPR OVERFLOW SWITCH   04340000
         L     5,CXDUBLWD               RESTORE REG 5 TO RETURN ADDR    04360000
PUTCMPD  L     3,CXCMPADD               REINIT COMPR REG TO BEG OF BLK  04380000
         BR    5                        RETURN TO USER                  04400000
***********************************************                         04420000
*    EXECUTE INSTRUCTION                                                04440000
***********************************************                         04460000
PUTCMPC  MVC   1(1,14),0(14)            PROPAGATE FILL CHAR             04480000
***********************************************                         04500000
*PHASE CALL ROUTINE                                                     04520000
***********************************************                         04540000
*TEST IF EOF HAS OCCURRED IN INPUT STREAM                               04560000
*IF YES, CALL DIAGNOSTIC PHASE 1                                        04580000
***********************************************                         04600000
PHSCAL   TM    CXNOTES+31,X'20'         IS NOTE 250 POSTED              04620000
         BZ    PHSCALA                  NO                              04640000
         MVC   CXPHSNAM(8),PHSCALB      SET TO CALL DIAG 1              04660000
***********************************************                         04680000
*FREEMAIN ALL TABLES                                                    04700000
***********************************************                         04720000
         LA    14,680                   LENGTH OF RESULT IND TABLE      04740000
         A     14,CXFLDLEN                      + FIELD NAME TABLE      04760000
         A     14,CXLITLEN                      + LITERAL TABLE         04780000
         A     14,CXCMPEXT                      + COMPRESSION           04800000
         ST    14,CXFLDADD                      = TOTAL TABLES          04820000
         LA    9,CXRIADDR               BEG ADDR OF TABLES              04840000
         FREEMAIN V,A=(9)               FREE TABLES                     04860000
         B     PHSCALC                  CALL DIAG 1                     04880000
PHSCALB  DC    C'RPG10190'              PHASE NAME FOR DIAG 1           04900000
***********************************************                         04920000
*TEST FOR COMPRESSION OVERFLOW AFTER ENTER PHASES                       04940000
***********************************************                         04960000
PHSCALA  CLI   0(3),X'FF'               END OF COMPRESSION              04980000
         BNE   PHSCALC                  NO, SKIP                        05000000
         BAL   5,PUTCMP                 YES, WRITE OUT LAST BLOCK       05020000
***********************************************                         05040000
*XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA                            05060000
***********************************************                         05080000
PHSCALC  LR    12,6                     REINIT REG 12 TO CIOEX DATA AR  05100000
         L     14,CXHLDREG              RESTORE RETURN ADDR             05120000
         LA    9,CXPHSNAM                                               05140000
         XCTL  EPLOC=(9)                CALL NEXT PHASE                 05160000
***********************************************                         05180000
*ERROR NOTE ROUTINE                                                     05200000
***********************************************                         05220000
PNTERR   PACK  CXDUBLWD(8),PNTRAREA+96(3)                               05240000
         CVB   14,CXDUBLWD              CONVERT NOTE NUMBER TO BINARY   05260000
         LA    15,7                     MASK FOR REMAINDER              05280000
         NR    15,14                    PICK OFF REMAINDER              05300000
         SRL   14,3                     DIVIDE NOTE NUMBER BY 8         05320000
         LA    2,256                    INIT BIT TO TURN ON ERROR NOTE  05340000
         LA    15,1(15)                 INCR REMAINDER FOR BCT INSTR    05360000
PNTERRA  SRL   2,1                      ADJUST BIT TO CORRESP TO REMAIN 05380000
         BCT   15,PNTERRA                                               05400000
         IC    15,CXNOTES(14)           PICK UP ERROR NOTE BYTE         05420000
         OR    15,2                     TURN ON BIT CORRESP TO ERR NOTE 05440000
         STC   15,CXNOTES(14)           STORE UPDATED ERROR NOTE BYTE   05460000
         MVC   PNTRAREA+93(3),PNTERRB   MOVE 'IES' TO PRINT BUFF        05480000
         MVI   PNTRAREA+99,C'I'         INSERT INFORMATION IDENT        05500000
         B     PRNTLINE                                            000A 05520016
PNTERRB  DC    C'IES'                   OS/RPG PREFIX                   05540000
***********************************************                         05560000
*PRINT SPECIFICATION                                                    05580000
***********************************************                         05600000
SEQCHK   CLC   PNTRAREA+13(6),CXSEQCHK COMP PRESENT NO TO PREVIOUS 000A 05603016
         BNH   WRNGSEQ                 OUT OF SEQ, B TO ERROR      000A 05606016
         MVC   CXSEQCHK(6),PNTRAREA+13 PRESENT PAGE/LINE TO OLD NO 000A 05609016
         B     PRNTLINE                IN SEQUENCE, PRINT SPEC     000A 05612016
WRNGSEQ  MVI   PNTRAREA+11,C'S'        FLAG SPEC  AS SEQ ERROR     000A 05615016
         MVC   PNTRAREA+96(3),ERNUM65  SET UP FOR ERROR NOTE RTN   000A 05618016
         MVC   CXSEQCHK(6),PNTRAREA+13   PRESENT PAGE/LINE TO OLD  000A 05621016
         B     PNTERR                  PRINT MESSAGE(FLAG), SPEC   000A 05624016
PNTSPC   TM    CXCMPOPT,X'08'          TEST FOR SEQ CHK OPT        000A 05627016
         BO    SEQCHK                  CHK FOR SEQUENCING          000A 05630016
PRNTLINE TM    CXCMPOPT,X'04'          CHK FOR LIST OPT            000A 05633016
         BCR   1,5                        RETURN TO USER                05640000
*        WRITE DECB,SF,LSTFIL,PNTRARAC                                  05660000
         L     14,CXDCBLST              LOAD LIST FILE DCB ADDR AND     05680000
         LA    15,PNTRARAC                   PRINT BUFFER ADDR W/CTL CH 05700000
         BAL   2,WRITE                  LINK FOR WRITE                  05720000
         MVI   PNTRAREA,C' '            CLEAR                           05740000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT BUFFER                  05760000
***********************************************                         05780000
*TAKE CARE OF CARRIAGE CONTROL, OVERFLOW AND HEADING                    05800000
***********************************************                         05820000
         CLI   PNTRARAC,C'0'            WAS DOUBLE SPACE SPECIFIED      05840000
         BNE   *+10                     NO                              05860000
         SP    CXLINBCT(2),CXONEPCK     YES, DECR LINE COUNT ONE EXTRA  05880000
         MVC   PNTRARAC(1),PNTSPCA      SET CONTROL CHAR FOR NEXT PRINT 05900000
         MVI   PNTSPCA,C' '             SET FOR SING SP, NEXT PRINT + 1 05920000
         SP    CXLINBCT(2),CXONEPCK     DECREMENT LINE COUNT            05940000
         BCR   2,5                      IF POSITIVE RETURN TO USER      05960000
         MVI   PNTRARAC,C'1'            SET CONTROL CHAR FOR PAGE EJECT 05980000
         MVC   CXLINBCT(2),CXLINCNT     INIT LINE COUNT - 52 LINES      06000000
         AP    CXPAGNUM(4),CXONEPCK     INCR PAGE NUMBER                06020000
         UNPK  PNTRAREA+96(4),CXPAGNUM(4) PLACE PAGE NUM IN PRINT AREA  06040000
         OI    PNTRAREA+99,X'F0'        ERASE PLUS SIGN                 06060000
         MVC   PNTRAREA+91(4),PNTSPCB   MOVE 'PAGE' INTO PRINT BUFF     06080000
         MVC   PNTRAREA+70(8),CXTODAY   MOVE IN DATE                    06100000
         MVC   PNTRAREA+50(8),CXSTEPNA  MOVE IN STEP NAME               06120000
         MVC   PNTRAREA+40(8),CXJOBNAM  MOVE IN JOB NAME                06140000
         MVC   PNTRAREA+5(17),CXHEADIN  MOVE IN RPG/E IDENT             06160000
         MVI   PNTSPCA,C'0'             SET FOR DOUB SP, NEXT PRINT + 1 06180000
         B     PRNTLINE                                            000A 06200016
PNTSPCA  DC    C' '                     SINGLE SPACE                    06220000
PNTSPCB  DC    C'PAGE'                                                  06240000
ERNUM65  DC    C'065'                  ERR NUMBER FOR SEG CHK RRR  000A 06250016
***********************************************                         06260000
*WORK FILE SERVICE   (REG 1 CONTAINS ADDR OF I/O AREA)                  06280000
***********************************************                         06300000
*        READ  DECB,SF,(CXDCBWK3),(1),132                               06320000
RLDIN    ST    1,RLDINE                 STORE ADDR OF I/O AREA          06340000
         MVC   LENGFLD(2),RLDINF        SUPPLY LENGTH TO DECB           06360000
         L     14,CXDCBWK3              LOAD DCB ADDR AND               06380000
         L     15,RLDINE                     ADDR OF I/O AREA           06400000
         BAL   2,READ                   LINK FOR READ                   06420000
         L     1,RLDINE                 RESTORE REG 1 FOR USER          06440000
         BR    5                        RETURN TO USER                  06460000
RLDINE   DS    F                        ADDR OF I/O AREA                06480000
RLDINF   DC    H'132'                   LENGTH OF RECORD                06500000
***********************************************                         06520000
*POINT TO BEGINNING OF A FILE FOR WKFIL1, WKFIL2, WKFIL3                06540000
***********************************************                         06560000
PTRLD    L     1,CXDCBWK3               LOAD DCB ADDR                   06580000
         LA    0,256                    LOAD TTRZ BLOCK ID FOR DA, 0010 06600000
         TM    17(1),DADEVT             IS DEVICE TYPE DA               06620000
         BO    PTRLDA                   YES                             06640000
         LA    0,1                      LOAD ZZCC ID FOR TAPE, 0001     06660000
PTRLDA   ST    0,CXDUBLWD+4             STORE BLOCK ID FOR POINT        06680000
         LA    0,CXDUBLWD+4             LOAD ADDR OF BLOCK ID FOR POINT 06700000
         POINT (1),(0)                  POINT TO BLOCK 1                06720000
         BR    5                        RETURN TO USER                  06740000
PTRLDR   EQU   PTRLD                                                    06760000
PTRLDW   EQU   PTRLD                                                    06780000
***********************************************                         06800000
*NOTE THE COMPRESSION BLOCK CONTAINING THE FIRST                        06820000
*   INPUT, CALC, OR OUTPUT SPECIFICATION,                               06840000
*   AND NOTE THE DISPLACEMENT TO THAT SPEC WITHIN THE BLOCK.            06860000
*   ALSO, NOTE ANY COMPRESSION BLOCK AND ANY DISPLACEMENT               06880000
*                                                                       06900000
*  (NOTE IS EXECUTED AFTER NEXT PUTCMP)                                 06920000
***********************************************                         06940000
NOTECL   LR    14,3                     COMPUTE DISPLACEMENT            06960000
         L     15,CXCMPADD                TO SPEC THAT HAS BEEN NOTED   06980000
         SR    14,15                      IN COMPRESSION BLOCK          07000000
         STH   14,CXCDSPLC              STORE DISPLACEMENT              07020000
         MVI   CXCALCNT,X'FF'           FLAG WHERE BLOCK ID IS TO GO    07040000
         BR    5                        RETURN TO USER                  07060000
GETCMP   EQU   DUMRTRN                                                  07080000
RDSPEC   EQU   DUMRTRN                                                  07100000
PUTCOD   EQU   DUMRTRN                                                  07120000
SWITCH   EQU   DUMRTRN                                                  07140000
PTCMPR   EQU   DUMRTRN                                                  07160000
RLDOUT   EQU   DUMRTRN                                                  07180000
BLKOUT   EQU   DUMRTRN                                                  07200000
BLKIN    EQU   DUMRTRN                                                  07220000
PTBLKW   EQU   DUMRTRN                                                  07240000
PNTINP   EQU   DUMRTRN                                                  07260000
PNTCLC   EQU   DUMRTRN                                                  07280000
PNTOUT   EQU   DUMRTRN                                                  07300000
NOTEIN   EQU   DUMRTRN                                                  07320000
NOTEOT   EQU   DUMRTRN                                                  07340000
NTASGN   EQU   DUMRTRN                                                  07360000
PTASGN   EQU   DUMRTRN                                                  07380000
PHDUMP   EQU   DUMRTRN                                                  07400000
PTBLKR   EQU   DUMRTRN                                                  07420000
***********************************************                         07440000
*CIOEX DATA AREA                                                        07460000
***********************************************                         07480000
CXDATA   DSECT                                                          07500000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       07520000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 07540000
*                                         (START WITH PREPHASE)         07560000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 07580000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       07600000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   07620000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     07640000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     07660000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     07680000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        07700000
CXFLDADD DS    F                                FIELD NAME TABLE        07720000
CXLITADD DS    F                                LITERAL TABLE           07740000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 07760000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     07780000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      07800000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   07820000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                07840000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      07860000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         07880000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      07900000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    07920000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     07940000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    07960000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            07980000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    08000000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   08020000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           08040000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      08060000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  08080000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   08100000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 08120000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    08140000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         08160000
CXRETCDE DC    X'00'                    RETURN CODE                     08180000
CXIPTEOF BR    2                        LINKAGE TO EOF ROUTINE          08200000
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            08220000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          08240000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    08260000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           08280000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     08300000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    08320000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                08340000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             08360000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            08380000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     08400000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      08420000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    08440000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   08460000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        08480000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               08500000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     08520000
CXSYNERR B     4(2)                     LINKAGE TO SYNCH ERROR ROUTINE  08540000
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    08560000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     08580000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        08600000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          08620000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        08640000
CXTODAY  DC    C'  /  /  '              DATE                            08660000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             08680000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        08700000
RDRPCHAR DS    80C                      READER/PUNCH AREA               08720000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       08740000
PNTRAREA DS    120C                     PRINT AREA                      08760000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 08780000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 08800000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 08805015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 08810015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 08815015
CXSEQCHK DS    6C                       PAGE/LINE SEQUENCE CHECK   000A 08817016
CXDEND   EQU   *                                                        08820000
         END   IESCEX                                                   08840000
