         TITLE 'IES089  OS/360 RPG CIOEX OF ENTER PHASE 6           15' 00020000
* STATUS       CHANGE LEVEL 1-7                                    I168 00040018
*                                                                       00060000
*FUNCTION/OPERATION   THE CIOEX ROUTINES ARE A SET OF EXTERNAL          00080000
*                     SUBROUTINES WHICH PERFORM ALL OF THE INPUT/OUTPUT 00100000
*                     OPERATIONS FOR THE COMPILER PHASES.  THE CIOEX    00120000
*                     ROUTINES OPERATE IN CONJUNCTION WITH THE CIOEX    00140000
*                     DATA AREA (POINTED TO BY REGISTER 6) WHICH        00160000
*                     CONTAINS THE DCB ADDRESSES, THE PRINTER AND       00180000
*                     READER/PUNCH BUFFERS, AND INFORMATION TO BE       00200000
*                     UPDATED WITH EACH INPUT/OUTPUT OPERATION.         00220000
*                     THE INDIVIDUAL CIOEX ROUTINES AND THE FUNCTIONS   00240000
*                     THEY PERFORM ARE DESCRIBED AT THE BEGINNING       00260000
*                     OF EACH ROUTINE.                                  00280000
*                                                                       00300000
*                     THOSE CIOEX ROUTINES REQUIRED BY A PHASE          00320000
*                     ARE ASSEMBLED AS A SEPARATE MODULE AND            00340000
*                     LINK-EDITED WITH THE PARENT PHASE.                00360000
*                     THE CIOEX CSECT ALSO SERVES AS THE ENTRY POINT    00380000
*                     FOR THE PHASE LOAD MODULE.                        00400000
*                                                                       00420000
*ENTRY POINT, INITIAL   IESCEX FROM THE CALLING PHASE VIA THE XCTL MACR 00440000
*                                                                       00460000
*ENTRY POINT, CIOEX ROUTINES   IES08910 FROM IES08010                   00480000
*                              CALLING SEQUENCE   EXTRN IES08910        00500000
*                                                 L     7,CXRADDR       00520000
*                                                 LA    2,CXRCODE       00540000
*                                                 BALR  5,7             00560000
*                                                 *                     00580000
*                                                 *                     00600000
*                                                 *                     00620000
*                                        CXRADDR  DC    A(IES08910)     00640000
*                                        CXRCODE  EQU   0,2,...50 DISPL 00660000
*                                                       TO THE ADDRESS  00680000
*                                                       OF THE CIOEX    00700000
*                                                       ROUTINE WANTED  00720000
*                                                       WITHIN THE      00740000
*                                                       TRANSFER VECTOR 00760000
*                                                                       00780000
*                              ADDRESS OF THE CIOEX DATA AREA PASSED    00800000
*                              IN REGISTER 6                            00820000
*                                                                       00840000
*INPUT   REQUEST CODE FOR THE CIOEX ROUTINE WANTED IN REGISTER 2        00860000
*        CIOEX DATA AREA                                                00880000
*                                                                       00900000
*OUTPUT   COMPLETED I/O OPERATION AS REQUESTED                          00920000
*         UPDATED CIOEX DATA AREA                                       00940000
*                                                                       00960000
*EXTERNAL ROUTINES   NONE                                               00980000
*                                                                       01000000
*EXIT, INITIAL   TO IES08010                                            01020000
*                CALLING SEQUENCE   PHSLINK  L     15,PHSADDR           01040000
*                                            BALR  7,15                 01060000
*                                            *                          01080000
*                                            *                          01100000
*                                            *                          01120000
*                                   PHSADDR  DC    V(IES08010)          01140000
*                                                                       01160000
*EXIT, CIOEX ROUTINES (EXCEPT PHSCAL)   BR    5        CIOEX RETURN REG 01180000
*                                                                       01200000
*EXIT, CIOEX PHSCAL   XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA       01220000
*                                                                       01240000
*EXIT, SYNCHRONOUS I/O ERROR   SET RETURN CODE TO 20                    01260000
*                              CALL TERMINAL PHASE VIA CIOEX PHSCAL     01280000
*                                                                       01300000
*TABLES/WORK AREAS   NONE                                               01320000
*                                                                       01340000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             01360000
*                                                                       01380000
*NOTES   ALL I/O OPERATIONS ARE PERFORMED WITH BSAM                     01400000
*        THE FOLLOWING MACROS ARE USED - READ                           01420000
*                                        WRITE                          01440000
*                                        CHECK                          01460000
*                                        NOTE                           01480000
*                                        POINT                          01500000
*                                                                       01520000
IESCEX   START                                                          01540000
*0141000400,015500,054200,055200,061000                            000A 01550016
* 0154600-015586                                                   000Z 01550318
* 062660-062720,087180                                             I168 01550618
         SPACE 1                                                        01550918
****************************************************************** 000Z 01551218
*                                                                  000Z 01551518
*        GENERAL REGISTER EQUATES FOR THIS PHASE                   000Z 01551818
*                                                                  000Z 01552118
****************************************************************** 000Z 01552418
XR0      EQU   0                                                        01552718
XR1      EQU   1                                                   000Z 01553018
XR2      EQU   2                                                   000Z 01553318
XR3      EQU   3                                                   000Z 01553618
XR4      EQU   4                                                   000Z 01553918
XR5      EQU   5                                                   000Z 01554218
XR6      EQU   6                                                   000Z 01554518
XR7      EQU   7                                                   000Z 01554818
XR8      EQU   8                                                   000Z 01555118
XR9      EQU   9                                                   000Z 01555418
XR10     EQU   10                                                  000Z 01555718
XR11     EQU   11                                                  000Z 01556018
XR12     EQU   12                                                  000Z 01556318
XR13     EQU   13                                                  000Z 01556618
XR14     EQU   14                                                  000Z 01556918
XR15     EQU   15                                                  000Z 01557218
         SPACE 1                                                        01557518
         ENTRY IES08910                                                 01560000
         USING CXDATA,6                                                 01580000
         USING *,15                                                     01600000
         ST    XR14,CXHLDREG            SAVE RETURN ADDR           000Z 01620018
PHSLINK  L     XR15,PHSADDR             LOAD PHASE ENTRY POINT ADDR000Z 01640018
         BALR  XR7,XR15                 LINK TO USER PHASE         000Z 01660018
         USING *,7                                                      01680000
CXBASE   ST    XR13,CXSAVEAR+8      SAVE USER WORK REG, NON-VOL    000Z 01700018
         LA    XR13,CXSAVEAR            LOAD SAVE AREA ADDR        000Z 01720018
         ST    XR5,CXSAVEAR             SAVE USER RETURN ADDR      000Z 01740018
         LA    XR5,CXRETURN             FORCE RETURN VIA CIOEX     000Z 01760018
         LH    XR2,CXRTAB(XR2)          DISP TO CIOEX ROUTINE      000Z 01780018
         AR    XR2,XR7                  ADD BASE REG               000Z 01800018
SPECRTRN BR    XR2                   BRANCH TO CIOEX ROUTINE WA    000Z 01820018
***********************************************                         01840000
*RETURN VIA CIOEX TO RESTORE WORK REG 13                                01860000
***********************************************                         01880000
CXRETURN L     XR13,CXSAVEAR+8          RESTORE USER WORK REG 13   000Z 01900018
         L     XR5,CXSAVEAR             RESTORE USER RETURN ADDRESS000Z 01920018
DUMRTRN  BR    XR5                      RETURN TO USER             000Z 01940018
***********************************************                         01960000
*TABLE OF DISPLACEMENTS TO CIOEX ROUTINES FROM BASE REG ADDRESS         01980000
***********************************************                         02000000
CXRTAB   DC    AL2(GETCMP-CXBASE)       GET COMPRESSION      ROUTINE 0  02020000
         DC    AL2(PUTCMP-CXBASE)       PUT COMPRESSION      ROUTINE 2  02040000
         DC    AL2(PHSCAL-CXBASE)       PHASE CALL           ROUTINE 4  02060000
         DC    AL2(PNTERR-CXBASE)       PRINT ERROR NOTE     ROUTINE 6  02080000
         DC    AL2(PNTSPC-CXBASE)       PRINT SPEC           ROUTINE 8  02100000
         DC    AL2(RDSPEC-CXBASE)       READ SPEC            ROUTINE 10 02120000
         DC    AL2(PUTCOD-CXBASE)       PUNCH/GO OUTPUT      ROUTINE 12 02140000
         DC    AL2(SWITCH-CXBASE)       SWITCH WKFIL1,WKFIL2 ROUTINE 14 02160000
         DC    AL2(PTCMPR-CXBASE)       POINT COMP FOR READ  ROUTINE 16 02180000
         DC    AL2(RLDOUT-CXBASE)       WRITE RLD            ROUTINE 18 02200000
         DC    AL2(RLDIN-CXBASE)        READ RLD             ROUTINE 20 02220000
         DC    AL2(PTRLDW-CXBASE)       POINT RLD FOR WRITE  ROUTINE 22 02240000
         DC    AL2(BLKOUT-CXBASE)       WRITE BLANK AFTER    ROUTINE 24 02260000
         DC    AL2(BLKIN-CXBASE)        READ BLANK AFTER     ROUTINE 26 02280000
         DC    AL2(PTBLKW-CXBASE)       POINT BLKAFTR, WRITE ROUTINE 28 02300000
         DC    AL2(PNTINP-CXBASE)       POINT FIRST INPUT SP ROUTINE 30 02320000
         DC    AL2(PNTCLC-CXBASE)       POINT FIRST CALC SP  ROUTINE 32 02340000
         DC    AL2(PNTOUT-CXBASE)       POINT FIRST OUTPT SP ROUTINE 34 02360000
         DC    AL2(NOTEIN-CXBASE)       NOTE FIRST INPUT SP  ROUTINE 36 02380000
         DC    AL2(NOTECL-CXBASE)       NOTE FIRST CALC SP   ROUTINE 38 02400000
         DC    AL2(NOTEOT-CXBASE)       NOTE FIRST OUTPUT SP ROUTINE 40 02420000
         DC    AL2(NTASGN-CXBASE)       NOTE ANY SPEC        ROUTINE 42 02440000
         DC    AL2(PTASGN-CXBASE)       POINT TO PREV NOTE   ROUTINE 44 02460000
         DC    AL2(PHDUMP-CXBASE)       DUMP WITHIN LIMITS   ROUTINE 46 02480000
         DC    AL2(PTBLKR-CXBASE)       POINT BLKAFTR, READ  ROUTINE 48 02500000
         DC    AL2(PTRLDR-CXBASE)       POINT RLD FOR READ   ROUTINE 50 02520000
PHSADDR  DC    V(IES08010)              PHASE ENTRY POINT ADDR          02540000
DADEVT   EQU   X'20'                    DEVICE TYPE CODE FOR DIRECT ACC 02560000
IES08910 EQU   CXBASE                                                   02580000
***********************************************                         02600000
*COMMON READ/WRITE/CHECK ROUTINE FOR ALL FILES                          02620000
***********************************************                         02640000
READ     MVI   TYPE,X'80'               SET FOR READ SF                 02660000
         B     *+8                                                      02680000
WRITE    MVI   TYPE,X'20'               SET FOR WRITE SF                02700000
         LA    XR1,DECB                 LOAD DECB ADDR             000Z 02720018
         STM   XR14,XR15,8(XR1)        STORE DCB ADDR AND AREA     000Z 02740018
         L     XR15,48(,XR14)           LOAD DCB OFFSET            000Z 02760018
         BALR  XR14,XR15                LINK FOR READ/WRITE        000Z 02780018
*        CHECK DECB                                                     02800000
         LA    XR1,DECB                 LOAD DECB ADDR             000Z 02820018
         L     XR14,8(,XR1)             LOAD DCB ADDR              000Z 02840018
         L     XR15,52(,XR14)           LOAD CHECK ROUT ADDR       000Z 02860018
         LR    XR14,XR2               SET FOR DIRECT RETURN TO     000Z 02880018
         BALR  XR2,XR15                 LINK TO CHECK              000Z 02900018
***********************************************                         02920000
*LINKAGE TO EOF ROUTINE                                                 02940000
***********************************************                         02960000
         B     RDSPECA                                                  02980000
***********************************************                         03000000
*SYNCHRONOUS ERROR ROUTINE                                              03020000
***********************************************                         03040000
         MVI   CXRETCDE,20              SYNCH ERROR RETURN CODE         03060000
         MVC   CXPHSNAM(8),TERMPHS      SET TO CALL TERMINAL PHASE      03080000
         B     PHSCALC                  CLOSE FILES AND RETURN TO SUPV  03100000
TERMPHS  DC    C'RPG10250'              PHASE NAME FOR TERMINAL PHASE   03120000
***********************************************                         03140000
*COMMON DECB FOR ALL FILES                                              03160000
***********************************************                         03180000
DECB     DC    F'0'                     EVENT CONTROL BLOCK             03200000
OPFLD    DC    X'00'                    OP FIELD                        03220000
TYPE     DC    X'00'                    READ/WRITE SF                   03240000
LENGFLD  DC    AL2(0)                   LENGTH FIELD                    03260000
DCBADDR  DC    A(0)                     DCB ADDRESS                     03280000
AREADDR  DC    A(0)                     AREA ADDRESS                    03300000
         DC    A(0)                     POINTER TO STATUS INDICATORS    03320000
***********************************************                         03340000
*PUT COMPRESSION                                                        03360000
***********************************************                         03380000
*        WRITE DECB,SF,WKFIL2,(CXCMPADD),(CXCMPEXT)                     03400000
PUTCMP   MVC   LENGFLD(2),CXCMPEXT+2    LENGTH OF COMPR TO DECB         03420000
         L     XR14,CXDCBWK2          LOAD WORK FILE 1 DCB ADDR    000Z 03440018
         L     XR15,CXCMPADD                 COMPR ADDR            000Z 03460018
         BAL   XR2,WRITE                LINK FOR WRITE             000Z 03480018
***********************************************                         03500000
*NOTE THE LAST COMPRESSION BLOCK WRITTEN, IF REQUIRED                   03520000
***********************************************                         03540000
         L     XR1,CXDCBWK2             LOAD COMPR DCB ADDR        000Z 03560018
         NOTE  (1)                      NOTE                            03580000
         LA    XR14,CXCALCNT            LOAD ADDR OF FIRST NOTE NUM000Z 03600018
         LA    XR15,4                   LOAD COUNT OF NOTE NUMS    000Z 03620018
PUTCMPF  CLI   0(XR14),X'FF'            IS THIS NOTE NUM FLAGGED   000Z 03640018
         BNE   PUTCMPH                  NO, SKIP                        03660000
         ST    XR1,0(,XR14)             YES, STORE BLOCK ID THERE  000Z 03680018
PUTCMPH  LA    XR14,4(XR14)             INCREMENT TO NEXT NOTE NUM 000Z 03700018
         BCT   XR15,PUTCMPF             CONTINUE                   000Z 03720018
         ST    XR1,CXDUBLWD             ACCUM MAX BLOCK NUM        000Z 03740018
         CLC   CXDUBLWD+2(1),CXTRKBF      PER TRACK                     03760000
         BNH   *+10                       FOR DIRECT ACCESS             03780000
         MVC   CXTRKBF(1),CXDUBLWD+2                                    03800000
***********************************************                         03820000
*INITIALIZE COMPRESSION WITH X'FE' UP TO LAST 60 BYTES,                 03840000
*    THEN X'FF' TO END                                                  03860000
***********************************************                         03880000
         ST    XR5,CXDUBLWD             FREE REG 5 FOR WORK        000Z 03900018
         L     XR14,CXCMPADD            ADDR OF COMPR              000Z 03920018
         L     XR15,CXCMPEXT            LENG OF COMPR              000Z 03940018
         LA    XR2,60                   LENG OF TRAILER            000Z 03960018
         LA    XR5,255                  MAX MOVE LENGTH            000Z 03980018
         MVI   0(XR14),X'FE'            X'FE' TO FIRST COMPR BYTE  000Z 04000018
         SR    XR15,XR2                COMPUTE LENGTH TO FILL X    000Z 04020018
PUTCMPA  CR    XR15,XR5                IS X'FE' LENGTH GTR THAN    000Z 04040018
         BNH   PUTCMPB                  NO, FILL REMAINDER              04060000
         EX    XR5,PUTCMPC           YES, FILL 256 BYTES WITH X    000Z 04080018
         AR    XR14,XR5                 INCR TARGET ADDR BY 255    000Z 04100018
         SR    XR15,XR5                 DECR X'FE' LENGTH BY 255   000Z 04120018
         B     PUTCMPA                  REPEAT                          04140000
PUTCMPB  EX    XR15,PUTCMPC         FILL REMAINING BYTES WITH X    000Z 04160018
         AR    XR14,XR15              INCR TARGET ADDR BY REMAI    000Z 04180018
         MVI   0(XR14),X'FF'            X'FF' TO FIRST TRAILER BYTE000Z 04200018
         BCTR  XR2,0                  SUBTR 2 FROM LENG OF TRAI    000Z 04220018
         BCTR  XR2,0                  1 TO COMPENSATE FOR FIRST    000Z 04240018
*                                         1 TO COMPENSATE FOR EXEC INST 04260000
         EX    XR2,PUTCMPC            FILL TRAILER BYTES WITH X    000Z 04280018
         LH    XR14,CXNUMCMP            LOAD COMPR BLOCK COUNT     000Z 04300018
         LA    XR14,1(XR14)             INCREMENT                  000Z 04320018
         STH   XR14,CXNUMCMP            STORE UPDATED BLOCK COUNT  000Z 04340018
         MVC   CXBLKNUM(2),CXNUMCMP     UPDATE COMPR BLOCK NUMBER       04360000
*                                         CURRENTLY BEING PROCESSED     04380000
         OI    CXCMPOVF+1,X'F0'         TURN ON COMPR OVERFLOW SWITCH   04400000
         L     XR5,CXDUBLWD            RESTORE REG 5 TO RETURN     000Z 04420018
PUTCMPD  L     XR3,CXCMPADD          REINIT COMPR REG TO BEG OF    000Z 04440018
         BR    XR5                      RETURN TO USER             000Z 04460018
***********************************************                         04480000
*    EXECUTE INSTRUCTION                                                04500000
***********************************************                         04520000
PUTCMPC  MVC   1(1,XR14),0(XR14)        PROPAGATE FILL CHAR        000Z 04540018
***********************************************                         04560000
*PHASE CALL ROUTINE                                                     04580000
***********************************************                         04600000
*TEST FOR COMPRESSION OVERFLOW AFTER ENTER PHASES                       04620000
***********************************************                         04640000
PHSCAL   CLI   0(XR3),X'FF'             END OF COMPRESSION         000Z 04660018
         BNE   PHSCALA                  NO, SKIP                        04680000
         BAL   XR5,PUTCMP               YES, WRITE OUT LAST BLOCK  000Z 04700018
***********************************************                         04720000
*TEST FOR LOAD,DECK OPTION                                              04740000
*IF YES, CALL INTERMEDIATE PHASE                                        04760000
***********************************************                         04780000
PHSCALA  TM    CXCMPOPT,X'01'           IS LOAD WANTED                  04800000
         BO    PHSCALC                  NO                              04820000
         TM    CXCMPOPT,X'02'           IS LOAD,DECK WANTED             04840000
         BZ    PHSCALC                  NO                              04860000
         MVC   CXPHSNAM(8),PHSCALB      SET TO CALL INTERMEDIATE PHASE  04880000
         B     PHSCALC                  CALL INTERMEDIATE PHASE         04900000
PHSCALB  DC    C'RPG1008A'              PHASE NAME FOR INTERMEDIATE PHS 04920000
***********************************************                         04940000
*XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA                            04960000
***********************************************                         04980000
PHSCALC  LR    XR12,XR6              REINIT REG 12 TO CIOEX DAT    000Z 05000018
         L     XR14,CXHLDREG            RESTORE RETURN ADDR        000Z 05020018
         LA    XR9,CXPHSNAM                                        000Z 05040018
         XCTL  EPLOC=(9)                CALL NEXT PHASE                 05060000
***********************************************                         05080000
*ERROR NOTE ROUTINE                                                     05100000
***********************************************                         05120000
PNTERR   PACK  CXDUBLWD(8),PNTRAREA+96(3)                               05140000
         CVB   XR14,CXDUBLWD          CONVERT NOTE NUMBER TO BI    000Z 05160018
         LA    XR15,7                   MASK FOR REMAINDER         000Z 05180018
         NR    XR15,XR14                PICK OFF REMAINDER         000Z 05200018
         SRL   XR14,3                   DIVIDE NOTE NUMBER BY 8    000Z 05220018
         LA    XR2,256               INIT BIT TO TURN ON ERROR     000Z 05240018
         LA    XR15,1(XR15)            INCR REMAINDER FOR BCT I    000Z 05260018
PNTERRA  SRL   XR2,1                ADJUST BIT TO CORRESP TO RE    000Z 05280018
         BCT   XR15,PNTERRA                                        000Z 05300018
         IC    XR15,CXNOTES(XR14)       PICK UP ERROR NOTE BYTE    000Z 05320018
         OR    XR15,XR2             TURN ON BIT CORRESP TO ERR     000Z 05340018
         STC   XR15,CXNOTES(XR14)     STORE UPDATED ERROR NOTE     000Z 05360018
         MVC   PNTRAREA+93(3),PNTERRB   MOVE 'IES' TO PRINT BUFF        05380000
         MVI   PNTRAREA+99,C'I'         INSERT INFORMATION IDENT        05400000
         B     PRNTLINE                                            000A 05420016
PNTERRB  DC    C'IES'                   OS/RPG PREFIX                   05440000
***********************************************                         05460000
*PRINT SPECIFICATION                                                    05480000
***********************************************                         05500000
SEQCHK   CLC   PNTRAREA+13(6),CXSEQCHK COMP PRESENT NO TO PREVIOUS 000A 05503016
         BNH   WRNGSEQ                 OUT OF SEQ, B TO ERROR      000A 05506016
         MVC   CXSEQCHK(6),PNTRAREA+13 PRESENT PAGE/LINE TO OLD NO 000A 05509016
         B     PRNTLINE                IN SEQUENCE, PRINT SPEC     000A 05512016
WRNGSEQ  MVI   PNTRAREA+11,C'S'        FLAG SPEC  AS SEQ ERROR     000A 05515016
         MVC   PNTRAREA+96(3),ERNUM65  SET UP FOR ERROR NOTE RTN   000A 05518016
         MVC   CXSEQCHK(6),PNTRAREA+13   PRESENT PAGE/LINE TO OLD  000A 05521016
         B     PNTERR                  PRINT MESSAGE(FLAG), SPEC   000A 05524016
PNTSPC   TM    CXCMPOPT,X'08'          TEST FOR SEQ CHK OPT        000A 05527016
         BO    SEQCHK                  CHK FOR SEQUENCING          000A 05530016
PRNTLINE TM    CXCMPOPT,X'04'          CHK FOR LIST OPT            000A 05533016
         BCR   1,XR5                      RETURN TO USER           000Z 05543018
*        WRITE DECB,SF,LSTFIL,PNTRARAC                                  05560000
         L     XR14,CXDCBLST            LOAD LIST FILE DCB ADDR AND000Z 05580018
         LA    XR15,PNTRARAC             PRINT BUFFER ADDR W/CT    000Z 05600018
         BAL   XR2,WRITE                LINK FOR WRITE             000Z 05620018
         MVI   PNTRAREA,C' '            CLEAR                           05640000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT BUFFER                  05660000
***********************************************                         05680000
*TAKE CARE OF CARRIAGE CONTROL, OVERFLOW AND HEADING                    05700000
***********************************************                         05720000
         CLI   PNTRARAC,C'0'            WAS DOUBLE SPACE SPECIFIED      05740000
         BNE   *+10                     NO                              05760000
         SP    CXLINBCT(2),CXONEPCK     YES, DECR LINE COUNT ONE EXTRA  05780000
         MVC   PNTRARAC(1),PNTSPCA      SET CONTROL CHAR FOR NEXT PRINT 05800000
         MVI   PNTSPCA,C' '             SET FOR SING SP, NEXT PRINT + 1 05820000
         SP    CXLINBCT(2),CXONEPCK     DECREMENT LINE COUNT            05840000
         BCR   2,XR5                    IF POSITIVE RETURN TO USER 000Z 05860018
         MVI   PNTRARAC,C'1'            SET CONTROL CHAR FOR PAGE EJECT 05880000
         MVC   CXLINBCT(2),CXLINCNT     INIT LINE COUNT - 52 LINES      05900000
         AP    CXPAGNUM(4),CXONEPCK     INCR PAGE NUMBER                05920000
         UNPK  PNTRAREA+96(4),CXPAGNUM(4) PLACE PAGE NUM IN PRINT AREA  05940000
         OI    PNTRAREA+99,X'F0'        ERASE PLUS SIGN                 05960000
         MVC   PNTRAREA+91(4),PNTSPCB   MOVE 'PAGE' INTO PRINT BUFF     05980000
         MVC   PNTRAREA+70(8),CXTODAY   MOVE IN DATE                    06000000
         MVC   PNTRAREA+50(8),CXSTEPNA  MOVE IN STEP NAME               06020000
         MVC   PNTRAREA+40(8),CXJOBNAM  MOVE IN JOB NAME                06040000
         MVC   PNTRAREA+5(17),CXHEADIN  MOVE IN RPG/E IDENT             06060000
         MVI   PNTSPCA,C'0'             SET FOR DOUB SP, NEXT PRINT + 1 06080000
         B     PRNTLINE                                            000A 06100016
PNTSPCA  DC    C' '                     SINGLE SPACE                    06120000
PNTSPCB  DC    C'PAGE'                                                  06140000
ERNUM65  DC    C'065'                  ERR NUMBER FOR SEG CHK RRR  000A 06150016
***********************************************                         06160000
*READ A SPECIFICATION FROM SYSIPT                                       06180000
***********************************************                         06200000
*        READ  DECB,SF,SRCFIL,RDRPCHAR                                  06220000
RDSPEC   ST    XR5,RDSPSAVE         SAVE RETURN REGISTER           000Z 06223018
         L     XR15,CXDBLKAD        GET ADDR OF RESIDENT           000Z 06226018
         BALR  XR5,XR15              DEBLK RTN & GO THERE          000Z 06229018
*                                                                  3142 06232015
*   THE FOLLOWING LINKAGE VECTOR IS USED BY THE RESIDENT           3142 06235015
*   DEBLOCK ROUTINE TO RETURN TO CIOEX AND TAKE CORRECT ACTION     3142 06238015
*   FOR HANDLING OF BLOCKED SOURCE RECORDS FROM SYSIN              3142 06241015
*                                                                  3142 06244015
         B     READEXIT                 RECORD MOVED TO WK AREA    3142 06247015
         B     READBLK                  READ A BLK & RETURN        3142 06250015
         B     RDSPECA                  EOF IN DEBLK RTN           3142 06253015
*                                                                  3142 06256015
*   THE FOLLOWING ROUTINES ARE CALLED FROM THE RESIDENT            3142 06259015
*   DEBLOCK ROUTINE THRU THE LINKAGE VECTOR ABOVE                  3142 06262015
*                                                                  3142 06265015
READEXIT L     XR5,RDSPSAVE         RESTORE RETURN REGISTER        000Z 06266018
         CLI   RDRPCHAR+6,C'*'          IS IT A COMMENTS CARD      I168 06267018
         BCR   8,XR5                    YES, RETURN                I168 06268018
         LH    XR2,CXCRDCNT             COUNT EACH OF THE          I168 06269018
         LA    XR2,1(XR2)              SOURCE STATEMENTS           I168 06270018
         STH   XR2,CXCRDCNT            AS THEY ARE READ.           I168 06271018
         BR    XR5                  RETURN TO CALLER               000Z 06272018
*                                                                  3142 06274015
READBLK  L     XR14,CXDCBSRC        LOAD SOURCE DCB ADDR &         000Z 06277018
         L     XR15,CXINAREA         SOURCE BUFFER ADDR            000Z 06280018
         BAL   XR2,READ             LINK TO READ A BLOCK           000Z 06283018
         L     XR5,RDSPSAVE         RESTORE RETURN REGISTER        000Z 06286018
         B     RDSPEC                   GO DEBLOCK FROM NEW BLOCK  3142 06289015
*                                                                  3142 06292015
RDSPSAVE DS    F                        RETURN REG SAVE AREA       3142 06295015
*                                                                  3142 06298015
***********************************************                         06320000
*EOF ROUTINE                                                            06340000
***********************************************                         06360000
RDSPECA  MVI   0(XR3),X'FD'             MARK END OF COMPRESSION    000Z 06380018
         MVC   CXPHSNAM(8),RDSPECC      SET TO CALL ASSIGN 1            06400000
         TM    CXCMPOVF+1,X'F0'         TEST FOR COMPRESSION OVERFLOW   06420000
         BZ    RDSPECB                  NO, DON'T WRITE OUT             06440000
         BAL   XR5,PUTCMP              YES, PUT LAST BLOCK OF C    000Z 06460018
RDSPECB  CP    CXLINBCT,RDSPECD         WAS PAGE EJECT JUST GIVEN       06480000
         BE    PHSCAL                   YES                             06500000
         SP    CXLINBCT,CXLINBCT        ZERO LINE COUNT                 06520000
         MVI   PNTRAREA,C' '            CLEAR                           06540000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT BUFFER                  06560000
         XC    CXSEQCHK(6),CXSEQCHK    SET LAST PAGE/LINE ENTRY =0 000A 06570016
         BAL   XR5,PNTSPC              FORCE PAGE EJECT AND HEA    000Z 06580018
         B     PHSCAL                   CALL INTERMEDIATE PHASE         06600000
RDSPECC  DC    C'RPG10090'              PHASE NAME FOR ASSIGN 1         06620000
RDSPECD  DC    X'051C'                  ONE LESS THAN CXLINCNT          06640000
***********************************************                         06660000
*NOTE THE COMPRESSION BLOCK CONTAINING THE FIRST                        06680000
*   INPUT, CALC, OR OUTPUT SPECIFICATION,                               06700000
*   AND NOTE THE DISPLACEMENT TO THAT SPEC WITHIN THE BLOCK.            06720000
*   ALSO, NOTE ANY COMPRESSION BLOCK AND ANY DISPLACEMENT               06740000
*                                                                       06760000
*  (NOTE IS EXECUTED AFTER NEXT PUTCMP)                                 06780000
***********************************************                         06800000
NOTEOT   LR    XR14,XR3                 COMPUTE DISPLACEMENT       000Z 06820018
         L     XR15,CXCMPADD            TO SPEC THAT HAS BEEN N    000Z 06840018
         SR    XR14,XR15                  IN COMPRESSION BLOCK     000Z 06860018
         STH   XR14,CXODSPLC            STORE DISPLACEMENT         000Z 06880018
         MVI   CXOUTCNT,X'FF'           FLAG WHERE BLOCK ID IS TO GO    06900000
         BR    XR5                      RETURN TO USER             000Z 06920018
GETCMP   EQU   DUMRTRN                                                  06940000
PUTCOD   EQU   DUMRTRN                                                  06960000
SWITCH   EQU   DUMRTRN                                                  06980000
PTCMPR   EQU   DUMRTRN                                                  07000000
RLDOUT   EQU   DUMRTRN                                                  07020000
RLDIN    EQU   DUMRTRN                                                  07040000
PTRLDW   EQU   DUMRTRN                                                  07060000
BLKOUT   EQU   DUMRTRN                                                  07080000
BLKIN    EQU   DUMRTRN                                                  07100000
PTBLKW   EQU   DUMRTRN                                                  07120000
PNTINP   EQU   DUMRTRN                                                  07140000
PNTCLC   EQU   DUMRTRN                                                  07160000
PNTOUT   EQU   DUMRTRN                                                  07180000
NOTEIN   EQU   DUMRTRN                                                  07200000
NOTECL   EQU   DUMRTRN                                                  07220000
NTASGN   EQU   DUMRTRN                                                  07240000
PTASGN   EQU   DUMRTRN                                                  07260000
PHDUMP   EQU   DUMRTRN                                                  07280000
PTBLKR   EQU   DUMRTRN                                                  07300000
PTRLDR   EQU   DUMRTRN                                                  07320000
***********************************************                         07340000
*CIOEX DATA AREA                                                        07360000
***********************************************                         07380000
CXDATA   DSECT                                                          07400000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       07420000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 07440000
*                                         (START WITH PREPHASE)         07460000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 07480000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       07500000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   07520000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     07540000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     07560000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     07580000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        07600000
CXFLDADD DS    F                                FIELD NAME TABLE        07620000
CXLITADD DS    F                                LITERAL TABLE           07640000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 07660000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     07680000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      07700000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   07720000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                07740000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      07760000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         07780000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      07800000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    07820000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     07840000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    07860000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            07880000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    07900000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   07920000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           07940000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      07960000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  07980000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   08000000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 08020000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    08040000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         08060000
CXRETCDE DC    X'00'                    RETURN CODE                     08080000
CXIPTEOF BR    XR2                      LINKAGE TO EOF ROUTINE     000Z 08100018
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            08120000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          08140000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    08160000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           08180000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     08200000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    08220000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                08240000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             08260000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            08280000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     08300000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      08320000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    08340000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   08360000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        08380000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               08400000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     08420000
CXSYNERR B     4(XR2)                LINKAGE TO SYNCH ERROR ROU    000Z 08440018
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    08460000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     08480000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        08500000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          08520000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        08540000
CXTODAY  DC    C'  /  /  '              DATE                            08560000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             08580000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        08600000
RDRPCHAR DS    80C                      READER/PUNCH AREA               08620000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       08640000
PNTRAREA DS    120C                     PRINT AREA                      08660000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 08680000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 08700000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 08705015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 08710015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 08715015
CXSEQCHK DS    6C                       PAGE/LINE SEQUENCE CHECK   000A 08717016
CXCRDCNT DS    H                        SOURCE STATEMENT COUNT     I168 08718018
CXDEND   EQU   *                                                        08720000
         END   IESCEX                                                   08740000
