         TITLE 'IES08A  OS/360 RPG INTERMEDIATE PHASE               16' 00020000
* STATUS  CHANGE LEVEL 1-4                                         3142 00040015
*FUNCTIONS OF RPG/E INTERMEDIATE PHASE                                  00060000
*  - CLOSE SOURCE LANGUAGE FILE                                         00080000
*  - OVERLAY SOURCE LANGUAGE DCB WITH PUNCH/GO DCB                      00100000
*  - OPEN PUNCH/GO FILE                                                 00120000
*  - CALL ASSIGN PHASE 1                                                00140000
***********************************************                         00160000
IES08A10 START                                                          00180000
*0057000400                                                        3142 00190015
INTPHASE EQU   *                                                        00200000
DCBDDNAM EQU   X'28'                    DISPL TO DDNAME IN PNCHGO DCB   00220000
DCBSYNAD EQU   X'38'                    DISPL TO SYNAD IN PNCHGO DCB    00240000
         BALR  8,0                      LOAD BASE REG                   00260000
         USING *,8                                                      00280000
         USING CXDATA,6                 REFERENCE CIOEX DATA AREA BASE  00300000
         ST    14,CXHLDREG              SAVE RETURN ADDR                00320000
***********************************************                         00340000
*CLOSE SOURCE LANG FILE                                                 00360000
***********************************************                         00380000
         L     2,CXDCBSRC               LOAD DCB ADDR OF SOURCE LANG FL 00400000
         CLOSE ((2),DISP)                                               00420000
***********************************************                         00440000
*OVERLAY SOURCE LANGUAGE DCB WITH PUNCH/GO DCB                          00460000
***********************************************                         00480000
         MVC   PNCHGO+DCBDDNAM(8),CXSYSPDD   MOVE IN SYSPUNCH DDNAME    00500000
         LA    11,CXSYNERR              PUT ADDR OF SYNCH ERROR ROUTINE 00520000
         ST    11,PNCHGO+DCBSYNAD         IN PUNCH/GO DCB               00540000
         MVC   0(PGDCBL,2),PNCHGO       MOVE IN PUNCH/GO DCB            00560000
***********************************************                         00580000
*OPEN PUNCH/GO FILE                                                     00600000
***********************************************                         00620000
         OPEN  ((2),(OUTPUT,DISP))                                      00640000
***********************************************                         00660000
*CALL ASSIGN PHASE 1                                                    00680000
***********************************************                         00700000
         MVC   CXPHSNAM,RPG10090        LOAD PHASE NAME FOR ASSIGN 1    00720000
         L     14,CXHLDREG              RESTORE RETURN ADDR             00740000
         LA    9,CXPHSNAM                                               00760000
         XCTL  EPLOC=(9)                CALL ASSIGN 1                   00780000
***********************************************                         00800000
*CONSTANTS                                                              00820000
***********************************************                         00840000
RPG10090 DC    C'RPG10090'              PHASE NAME FOR ASSIGN 1         00860000
***********************************************                         00880000
*DCB FOR PUNCH/GO FILE                                                  00900000
***********************************************                         00920000
PNCHGO   DCB   DSORG=PS,MACRF=(W),DDNAME=SYSPUNCH,DEVD=DA,RECFM=F,     X00940000
               LRECL=80,BLKSIZE=80,NCP=1                                00960000
PGDCBL   EQU   *-PNCHGO                 LENGTH OF PUNCH/GO DCB          00980000
***********************************************                         01000000
*CIOEX DATA AREA                                                        01020000
***********************************************                         01040000
CXDATA   DSECT                                                          01060000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       01080000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 01100000
*                                         (START WITH PREPHASE)         01120000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 01140000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       01160000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   01180000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     01200000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     01220000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     01240000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        01260000
CXFLDADD DS    F                                FIELD NAME TABLE        01280000
CXLITADD DS    F                                LITERAL TABLE           01300000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 01320000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     01340000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      01360000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   01380000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                01400000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      01420000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         01440000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      01460000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    01480000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     01500000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    01520000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            01540000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    01560000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   01580000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           01600000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      01620000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  01640000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   01660000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 01680000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    01700000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         01720000
CXRETCDE DC    X'00'                    RETURN CODE                     01740000
CXIPTEOF BR    2                        LINKAGE TO EOF ROUTINE          01760000
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            01780000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          01800000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    01820000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           01840000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     01860000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    01880000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                01900000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             01920000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            01940000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     01960000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      01980000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    02000000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   02020000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        02040000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               02060000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     02080000
CXSYNERR B     4(2)                     LINKAGE TO SYNCH ERROR ROUTINE  02100000
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    02120000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     02140000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        02160000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          02180000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        02200000
CXTODAY  DC    C'  /  /  '              DATE                            02220000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             02240000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        02260000
RDRPCHAR DS    80C                      READER/PUNCH AREA               02280000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       02300000
PNTRAREA DS    120C                     PRINT AREA                      02320000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 02340000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 02360000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 02365015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 02370015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 02375015
CXDEND   EQU   *                                                        02380000
         END   INTPHASE                                                 02400000
