         TITLE 'IES109  OS/360 RPG CIOEX OF ASSIGN PHASE 2          20' 00020000
* STATUS  CHANGE LEVEL 1-4                                         3142 00040015
*                                                                       00060000
*FUNCTION/OPERATION   THE CIOEX ROUTINES ARE A SET OF EXTERNAL          00080000
*                     SUBROUTINES WHICH PERFORM ALL OF THE INPUT/OUTPUT 00100000
*                     OPERATIONS FOR THE COMPILER PHASES.  THE CIOEX    00120000
*                     ROUTINES OPERATE IN CONJUNCTION WITH THE CIOEX    00140000
*                     DATA AREA (POINTED TO BY REGISTER 6) WHICH        00160000
*                     CONTAINS THE DCB ADDRESSES, THE PRINTER AND       00180000
*                     READER/PUNCH BUFFERS, AND INFORMATION TO BE       00200000
*                     UPDATED WITH EACH INPUT/OUTPUT OPERATION.         00220000
*                     THE INDIVIDUAL CIOEX ROUTINES AND THE FUNCTIONS   00240000
*                     THEY PERFORM ARE DESCRIBED AT THE BEGINNING       00260000
*                     OF EACH ROUTINE.                                  00280000
*                                                                       00300000
*                     THOSE CIOEX ROUTINES REQUIRED BY A PHASE          00320000
*                     ARE ASSEMBLED AS A SEPARATE MODULE AND            00340000
*                     LINK-EDITED WITH THE PARENT PHASE.                00360000
*                     THE CIOEX CSECT ALSO SERVES AS THE ENTRY POINT    00380000
*                     FOR THE PHASE LOAD MODULE.                        00400000
*                                                                       00420000
*ENTRY POINT, INITIAL   IESCEX FROM THE CALLING PHASE VIA THE XCTL MACR 00440000
*                                                                       00460000
*ENTRY POINT, CIOEX ROUTINES   IES10910 FROM IES10010                   00480000
*                              CALLING SEQUENCE   EXTRN IES10910        00500000
*                                                 L     7,CXRADDR       00520000
*                                                 LA    2,CXRCODE       00540000
*                                                 BALR  5,7             00560000
*                                                 *                     00580000
*                                                 *                     00600000
*                                                 *                     00620000
*                                        CXRADDR  DC    A(IES10910)     00640000
*                                        CXRCODE  EQU   0,2,...50 DISPL 00660000
*                                                       TO THE ADDRESS  00680000
*                                                       OF THE CIOEX    00700000
*                                                       ROUTINE WANTED  00720000
*                                                       WITHIN THE      00740000
*                                                       TRANSFER VECTOR 00760000
*                                                                       00780000
*                              ADDRESS OF THE CIOEX DATA AREA PASSED    00800000
*                              IN REGISTER 6                            00820000
*                                                                       00840000
*INPUT   REQUEST CODE FOR THE CIOEX ROUTINE WANTED IN REGISTER 2        00860000
*        CIOEX DATA AREA                                                00880000
*                                                                       00900000
*OUTPUT   COMPLETED I/O OPERATION AS REQUESTED                          00920000
*         UPDATED CIOEX DATA AREA                                       00940000
*                                                                       00960000
*EXTERNAL ROUTINES   NONE                                               00980000
*                                                                       01000000
*EXIT, INITIAL   TO IES10010                                            01020000
*                CALLING SEQUENCE   PHSLINK  L     15,PHSADDR           01040000
*                                            BALR  7,15                 01060000
*                                            *                          01080000
*                                            *                          01100000
*                                            *                          01120000
*                                   PHSADDR  DC    V(IES10010)          01140000
*                                                                       01160000
*EXIT, CIOEX ROUTINES (EXCEPT PHSCAL)   BR    5        CIOEX RETURN REG 01180000
*                                                                       01200000
*EXIT, CIOEX PHSCAL   XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA       01220000
*                                                                       01240000
*EXIT, SYNCHRONOUS I/O ERROR   SET RETURN CODE TO 20                    01260000
*                              CALL TERMINAL PHASE VIA CIOEX PHSCAL     01280000
*                                                                       01300000
*TABLES/WORK AREAS   NONE                                               01320000
*                                                                       01340000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             01360000
*                                                                       01380000
*NOTES   ALL I/O OPERATIONS ARE PERFORMED WITH BSAM                     01400000
*        THE FOLLOWING MACROS ARE USED - READ                           01420000
*                                        WRITE                          01440000
*                                        CHECK                          01460000
*                                        NOTE                           01480000
*                                        POINT                          01500000
*                                                                       01520000
IESCEX   START                                                          01540000
*0057000400                                                        3142 01550015
         ENTRY IES10910                                                 01560000
         USING CXDATA,6                                                 01580000
         USING *,15                                                     01600000
         ST    14,CXHLDREG              SAVE RETURN ADDR                01620000
PHSLINK  L     15,PHSADDR               LOAD PHASE ENTRY POINT ADDR     01640000
         BALR  7,15                     LINK TO USER PHASE              01660000
         USING *,7                                                      01680000
CXBASE   ST    13,CXSAVEAR+8            SAVE USER WORK REG, NON-VOLATLE 01700000
         LA    13,CXSAVEAR              LOAD SAVE AREA ADDR             01720000
         ST    5,CXSAVEAR               SAVE USER RETURN ADDR           01740000
         LA    5,CXRETURN               FORCE RETURN VIA CIOEX          01760000
         LH    2,CXRTAB(2)              DISP TO CIOEX ROUTINE           01780000
         AR    2,7                      ADD BASE REG                    01800000
SPECRTRN BR    2                        BRANCH TO CIOEX ROUTINE WANTED  01820000
***********************************************                         01840000
*RETURN VIA CIOEX TO RESTORE WORK REG 13                                01860000
***********************************************                         01880000
CXRETURN L     13,CXSAVEAR+8            RESTORE USER WORK REG 13        01900000
         L     5,CXSAVEAR               RESTORE USER RETURN ADDRESS     01920000
DUMRTRN  BR    5                        RETURN TO USER                  01940000
***********************************************                         01960000
*TABLE OF DISPLACEMENTS TO CIOEX ROUTINES FROM BASE REG ADDRESS         01980000
***********************************************                         02000000
CXRTAB   DC    AL2(GETCMP-CXBASE)       GET COMPRESSION      ROUTINE 0  02020000
         DC    AL2(PUTCMP-CXBASE)       PUT COMPRESSION      ROUTINE 2  02040000
         DC    AL2(PHSCAL-CXBASE)       PHASE CALL           ROUTINE 4  02060000
         DC    AL2(PNTERR-CXBASE)       PRINT ERROR NOTE     ROUTINE 6  02080000
         DC    AL2(PNTSPC-CXBASE)       PRINT SPEC           ROUTINE 8  02100000
         DC    AL2(RDSPEC-CXBASE)       READ SPEC            ROUTINE 10 02120000
         DC    AL2(PUTCOD-CXBASE)       PUNCH/GO OUTPUT      ROUTINE 12 02140000
         DC    AL2(SWITCH-CXBASE)       SWITCH WKFIL1,WKFIL2 ROUTINE 14 02160000
         DC    AL2(PTCMPR-CXBASE)       POINT COMP FOR READ  ROUTINE 16 02180000
         DC    AL2(RLDOUT-CXBASE)       WRITE RLD            ROUTINE 18 02200000
         DC    AL2(RLDIN-CXBASE)        READ RLD             ROUTINE 20 02220000
         DC    AL2(PTRLDW-CXBASE)       POINT RLD FOR WRITE  ROUTINE 22 02240000
         DC    AL2(BLKOUT-CXBASE)       WRITE BLANK AFTER    ROUTINE 24 02260000
         DC    AL2(BLKIN-CXBASE)        READ BLANK AFTER     ROUTINE 26 02280000
         DC    AL2(PTBLKW-CXBASE)       POINT BLKAFTR, WRITE ROUTINE 28 02300000
         DC    AL2(PNTINP-CXBASE)       POINT FIRST INPUT SP ROUTINE 30 02320000
         DC    AL2(PNTCLC-CXBASE)       POINT FIRST CALC SP  ROUTINE 32 02340000
         DC    AL2(PNTOUT-CXBASE)       POINT FIRST OUTPT SP ROUTINE 34 02360000
         DC    AL2(NOTEIN-CXBASE)       NOTE FIRST INPUT SP  ROUTINE 36 02380000
         DC    AL2(NOTECL-CXBASE)       NOTE FIRST CALC SP   ROUTINE 38 02400000
         DC    AL2(NOTEOT-CXBASE)       NOTE FIRST OUTPUT SP ROUTINE 40 02420000
         DC    AL2(NTASGN-CXBASE)       NOTE ANY SPEC        ROUTINE 42 02440000
         DC    AL2(PTASGN-CXBASE)       POINT TO PREV NOTE   ROUTINE 44 02460000
         DC    AL2(PHDUMP-CXBASE)       DUMP WITHIN LIMITS   ROUTINE 46 02480000
         DC    AL2(PTBLKR-CXBASE)       POINT BLKAFTR, READ  ROUTINE 48 02500000
         DC    AL2(PTRLDR-CXBASE)       POINT RLD FOR READ   ROUTINE 50 02520000
PHSADDR  DC    V(IES10010)              PHASE ENTRY POINT ADDR          02540000
DADEVT   EQU   X'20'                    DEVICE TYPE CODE FOR DIRECT ACC 02560000
IES10910 EQU   CXBASE                                                   02580000
***********************************************                         02600000
*COMMON READ/WRITE/CHECK ROUTINE FOR ALL FILES                          02620000
***********************************************                         02640000
READ     MVI   TYPE,X'80'               SET FOR READ SF                 02660000
         B     *+8                                                      02680000
WRITE    MVI   TYPE,X'20'               SET FOR WRITE SF                02700000
         LA    1,DECB                   LOAD DECB ADDR                  02720000
         STM   14,15,8(1)               STORE DCB ADDR AND AREA ADDR    02740000
         L     15,48(0,14)              LOAD DCB OFFSET                 02760000
         BALR  14,15                    LINK FOR READ/WRITE             02780000
*        CHECK DECB                                                     02800000
         LA    1,DECB                   LOAD DECB ADDR                  02820000
         L     14,8(0,1)                LOAD DCB ADDR                   02840000
         L     15,52(0,14)              LOAD CHECK ROUT ADDR            02860000
         LR    14,2                     SET FOR DIRECT RETURN TO USER   02880000
         BALR  2,15                     LINK TO CHECK                   02900000
         NOP   0                                                        02920000
***********************************************                         02940000
*SYNCHRONOUS ERROR ROUTINE                                              02960000
***********************************************                         02980000
         MVI   CXRETCDE,20              SYNCH ERROR RETURN CODE         03000000
         MVC   CXPHSNAM(8),TERMPHS      SET TO CALL TERMINAL PHASE      03020000
         B     PHSCALC                  CLOSE FILES AND RETURN TO SUPV  03040000
TERMPHS  DC    C'RPG10250'              PHASE NAME FOR TERMINAL PHASE   03060000
***********************************************                         03080000
*COMMON DECB FOR ALL FILES                                              03100000
***********************************************                         03120000
DECB     DC    F'0'                     EVENT CONTROL BLOCK             03140000
OPFLD    DC    X'00'                    OP FIELD                        03160000
TYPE     DC    X'00'                    READ/WRITE SF                   03180000
LENGFLD  DC    AL2(0)                   LENGTH FIELD                    03200000
DCBADDR  DC    A(0)                     DCB ADDRESS                     03220000
AREADDR  DC    A(0)                     AREA ADDRESS                    03240000
         DC    A(0)                     POINTER TO STATUS INDICATORS    03260000
***********************************************                         03280000
*GET COMPRESSION                                                        03300000
***********************************************                         03320000
GETCMP   TM    CXCMPOVF+1,X'F0'         TEST FOR COMPRESSION OVERFLOW   03340000
         BZ    GETCMPA                  COMPRESSION STILL IN CORE       03360000
*        READ  DECB,SF,WKFIL1,(CXCMPADD),(CXCMPEXT)                     03380000
         MVC   LENGFLD(2),CXCMPEXT+2    LENGTH OF COMPR TO DECB         03400000
         L     14,CXDCBWK1              LOAD WORK FILE 1 DCB ADDR AND   03420000
         L     15,CXCMPADD                   COMPR ADDR                 03440000
         BAL   2,READ                   LINK FOR READ                   03460000
         LH    14,CXBLKNUM              LOAD COMPR BLOCK NO. BEING PROC 03480000
         LA    14,1(14)                 INCREMENT                       03500000
         STH   14,CXBLKNUM              STORE UPDATED COMPR BLOCK NO.   03520000
GETCMPA  L     3,CXCMPADD               REINIT COMPR REG TO BEG OF BLK  03540000
         BR    5                        RETURN TO USER                  03560000
***********************************************                         03580000
*PUT COMPRESSION                                                        03600000
***********************************************                         03620000
PUTCMP   TM    CXCMPOVF+1,X'F0'         TEST FOR COMPRESSSION OVERFLOW  03640000
         BZ    PUTCMPD                  COMPRESSION STILL IN CORE       03660000
*        WRITE DECB,SF,WKFIL2,(CXCMPADD),(CXCMPEXT)                     03680000
         MVC   LENGFLD(2),CXCMPEXT+2    LENGTH OF COMPR TO DECB         03700000
         L     14,CXDCBWK2              LOAD WORK FILE 1 DCB ADDR AND   03720000
         L     15,CXCMPADD                   COMPR ADDR                 03740000
         BAL   2,WRITE                  LINK FOR WRITE                  03760000
PUTCMPD  L     3,CXCMPADD               REINIT COMPR REG TO BEG OF BLK  03780000
         BR    5                        RETURN TO USER                  03800000
***********************************************                         03820000
*PHASE CALL ROUTINE                                                     03840000
***********************************************                         03860000
*FREEMAIN THE FIELD NAME AND LITERAL TABLES                             03880000
***********************************************                         03900000
PHSCAL   L     14,CXFLDLEN              COMPUTE TOTAL LENGTH OF         03920000
         A     14,CXLITLEN                FIELD NAME AND LITERAL TABLES 03940000
         ST    14,CXLITADD                AND STORE FOR FREEMAIN        03960000
         LA    9,CXFLDADD                                               03980000
         FREEMAIN V,A=(9)               FREE TABLES                     04000000
***********************************************                         04020000
*XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA                            04040000
***********************************************                         04060000
PHSCALC  LR    12,6                     REINIT REG 12 TO CIOEX DATA AR  04080000
         L     14,CXHLDREG              RESTORE RETURN ADDR             04100000
         LA    9,CXPHSNAM                                               04120000
         XCTL  EPLOC=(9)                CALL NEXT PHASE                 04140000
***********************************************                         04160000
*ERROR NOTE ROUTINE                                                     04180000
***********************************************                         04200000
PNTERR   PACK  CXDUBLWD(8),PNTRAREA+96(3)                               04220000
         CVB   14,CXDUBLWD              CONVERT NOTE NUMBER TO BINARY   04240000
         LA    15,7                     MASK FOR REMAINDER              04260000
         NR    15,14                    PICK OFF REMAINDER              04280000
         SRL   14,3                     DIVIDE NOTE NUMBER BY 8         04300000
         LA    2,256                    INIT BIT TO TURN ON ERROR NOTE  04320000
         LA    15,1(15)                 INCR REMAINDER FOR BCT INSTR    04340000
PNTERRA  SRL   2,1                      ADJUST BIT TO CORRESP TO REMAIN 04360000
         BCT   15,PNTERRA                                               04380000
         IC    15,CXNOTES(14)           PICK UP ERROR NOTE BYTE         04400000
         OR    15,2                     TURN ON BIT CORRESP TO ERR NOTE 04420000
         STC   15,CXNOTES(14)           STORE UPDATED ERROR NOTE BYTE   04440000
         MVC   PNTRAREA+93(3),PNTERRB   MOVE 'IES' TO PRINT BUFF        04460000
         MVI   PNTRAREA+99,C'I'         INSERT INFORMATION IDENT        04480000
         B     PNTSPC                   PRINT ERROR NOTE                04500000
PNTERRB  DC    C'IES'                   OS/RPG PREFIX                   04520000
***********************************************                         04540000
*PRINT SPECIFICATION                                                    04560000
***********************************************                         04580000
PNTSPC   TM    CXCMPOPT,X'04'           IF NOLIST                       04600000
         BCR   1,5                        RETURN TO USER                04620000
*        WRITE DECB,SF,LSTFIL,PNTRARAC                                  04640000
         L     14,CXDCBLST              LOAD LIST FILE DCB ADDR AND     04660000
         LA    15,PNTRARAC                   PRINT BUFFER ADDR W/CTL CH 04680000
         BAL   2,WRITE                  LINK FOR WRITE                  04700000
         MVI   PNTRAREA,C' '            CLEAR                           04720000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT BUFFER                  04740000
***********************************************                         04760000
*TAKE CARE OF CARRIAGE CONTROL, OVERFLOW AND HEADING                    04780000
***********************************************                         04800000
         CLI   PNTRARAC,C'0'            WAS DOUBLE SPACE SPECIFIED      04820000
         BNE   *+10                     NO                              04840000
         SP    CXLINBCT(2),CXONEPCK     YES, DECR LINE COUNT ONE EXTRA  04860000
         MVC   PNTRARAC(1),PNTSPCA      SET CONTROL CHAR FOR NEXT PRINT 04880000
         MVI   PNTSPCA,C' '             SET FOR SING SP, NEXT PRINT + 1 04900000
         SP    CXLINBCT(2),CXONEPCK     DECREMENT LINE COUNT            04920000
         BCR   2,5                      IF POSITIVE RETURN TO USER      04940000
         MVI   PNTRARAC,C'1'            SET CONTROL CHAR FOR PAGE EJECT 04960000
         MVC   CXLINBCT(2),CXLINCNT     INIT LINE COUNT - 52 LINES      04980000
         AP    CXPAGNUM(4),CXONEPCK     INCR PAGE NUMBER                05000000
         UNPK  PNTRAREA+96(4),CXPAGNUM(4) PLACE PAGE NUM IN PRINT AREA  05020000
         OI    PNTRAREA+99,X'F0'        ERASE PLUS SIGN                 05040000
         MVC   PNTRAREA+91(4),PNTSPCB   MOVE 'PAGE' INTO PRINT BUFF     05060000
         MVC   PNTRAREA+70(8),CXTODAY   MOVE IN DATE                    05080000
         MVC   PNTRAREA+50(8),CXSTEPNA  MOVE IN STEP NAME               05100000
         MVC   PNTRAREA+40(8),CXJOBNAM  MOVE IN JOB NAME                05120000
         MVC   PNTRAREA+5(17),CXHEADIN  MOVE IN RPG/E IDENT             05140000
         MVI   PNTSPCA,C'0'             SET FOR DOUB SP, NEXT PRINT + 1 05160000
         B     PNTSPC                   PRINT HEADING LINE              05180000
PNTSPCA  DC    C' '                     SINGLE SPACE                    05200000
PNTSPCB  DC    C'PAGE'                                                  05220000
***********************************************                         05240000
*PUNCH/GO ROUTINE                                                       05260000
***********************************************                         05280000
PUTCOD   TM    CXCMPOPT,X'03'           IF NOLOAD,NODECK                05300000
         BCR   1,5                        RETURN TO USER                05320000
         MVC   72(4,4),CXPGRNAM         IDENTIFY THE CARD               05340000
         AP    CXPUNCNT(4),CXONEPCK(1)    WITH PROGRAM NAME             05360000
         UNPK  76(4,4),CXPUNCNT(4)        AND SEQUENCE NUMBER           05380000
         OI    79(4),X'F0'              ERASE PLUS SIGN                 05400000
*        WRITE DECB,SF,PNCHGO,RDRPCHAR                                  05420000
         L     14,CXDCBPGO              LOAD PUNCH/GO FILE DCB ADDR AND 05440000
         LA    15,RDRPCHAR                   PUNCH AREA ADDR            05460000
         BAL   2,WRITE                  LINK FOR WRITE                  05480000
         TM    CXCMPOPT,X'02'           TEST FOR LOAD,DECK              05500000
         BZ    PUTCODA                  NO                              05520000
         L     14,CXDCBSRC              YES, PUNCH CARD                 05540000
         LA    15,RDRPCHAR                ONTO SYSPUNCH                 05560000
         BAL   2,WRITE                                                  05580000
PUTCODA  MVI   0(4),C' '                CLEAR                           05600000
         MVC   1(79,4),0(4)               PUNCH BUFFER                  05620000
         BR    5                        RETURN TO USER                  05640000
***********************************************                         05660000
*SWITCH ASSIGNMENTS OF WKFIL1 AND WKFIL2                                05680000
***********************************************                         05700000
SWITCH   ST    5,CXDUBLWD               SAVE USER RETURN REG            05720000
         L     1,CXDCBWK1               LOAD DCB ADDR FOR WKFIL1        05740000
         MVC   CXDCBWK1(4),CXDCBWK2     SWITCH DCB ADDRESSES            05760000
         ST    1,CXDCBWK2                 OF WKFIL1 AND WKFIL2          05780000
         BAL   5,PTBLKW                 POINT TO BEG OF BLANK AFTER, WT 05800000
         BAL   5,PTCMPR                 POINT TO BEG OF COMP FOR READ   05820000
         L     5,CXDUBLWD               RESTORE USER RETURN REG         05840000
         BR    5                        RETURN TO USER                  05860000
***********************************************                         05880000
*POINT TO BEGINNING OF A FILE FOR WKFIL1, WKFIL2, WKFIL3                05900000
***********************************************                         05920000
PTCMP    L     1,CXDCBWK1               LOAD DCB ADDR                   05940000
         LA    0,256                    LOAD TTRZ BLOCK ID FOR DA, 0010 05960000
         TM    17(1),DADEVT             IS DEVICE TYPE DA               05980000
         BO    PTCMPA                   YES                             06000000
         LA    0,1                      LOAD ZZCC ID FOR TAPE, 0001     06020000
PTCMPA   ST    0,CXDUBLWD+4             STORE BLOCK ID FOR POINT        06040000
         LA    0,CXDUBLWD+4             LOAD ADDR OF BLOCK ID FOR POINT 06060000
         POINT (1),(0)                  POINT TO BLOCK 1                06080000
         XC    CXBLKNUM(2),CXBLKNUM     ZERO COMPR BLOCK NUM BEING PROC 06100000
         BR    5                        RETURN TO USER                  06120000
PTCMPR   EQU   PTCMP                                                    06140000
PTCMPW   EQU   PTCMP                                                    06160000
***********************************************                         06180000
*WORK FILE SERVICE   (REG 1 CONTAINS ADDR OF I/O AREA)                  06200000
***********************************************                         06220000
*        WRITE DECB,SF,(CXDCBWK3),(1),132                               06240000
RLDOUT   ST    1,RLDOUTE                STORE ADDR OF I/O AREA          06260000
         MVC   LENGFLD(2),RLDOUTF       SUPPLY LENGTH TO DECB           06280000
         L     14,CXDCBWK3              LOAD DCB ADDR AND               06300000
         L     15,RLDOUTE                    ADDR OF I/O AREA           06320000
         BAL   2,WRITE                  LINK FOR WRITE                  06340000
         LH    14,CXNUMRLD              LOAD FILE COUNTER               06360000
         LA    14,1(14)                 INCREMENT                       06380000
         STH   14,CXNUMRLD              STORE UPDATED COUNTER           06400000
         L     1,RLDOUTE                RESTORE REG 1 FOR USER          06420000
         BR    5                        RETURN TO USER                  06440000
RLDOUTE  DS    F                        ADDR OF I/O AREA                06460000
RLDOUTF  DC    H'132'                   LENGTH OF RECORD                06480000
***********************************************                         06500000
*POINT TO BEGINNING OF A FILE FOR WKFIL1, WKFIL2, WKFIL3                06520000
***********************************************                         06540000
PTBLK    L     1,CXDCBWK2               LOAD DCB ADDR                   06560000
         LA    0,256                    LOAD TTRZ BLOCK ID FOR DA, 0010 06580000
         TM    17(1),DADEVT             IS DEVICE TYPE DA               06600000
         BO    PTBLKA                   YES                             06620000
         LA    0,1                      LOAD ZZCC ID FOR TAPE, 0001     06640000
PTBLKA   ST    0,CXDUBLWD+4             STORE BLOCK ID FOR POINT        06660000
         LA    0,CXDUBLWD+4             LOAD ADDR OF BLOCK ID FOR POINT 06680000
         POINT (1),(0)                  POINT TO BLOCK 1                06700000
         BR    5                        RETURN TO USER                  06720000
PTBLKR   EQU   PTBLK                                                    06740000
PTBLKW   EQU   PTBLK                                                    06760000
***********************************************                         06780000
*POINT TO COMPRESSION BLOCK REFERENCED BY PREVIOUS NOTE                 06800000
*   COPY ACROSS FROM ONE FILE TO THE NEXT                               06820000
***********************************************                         06840000
PTASGN   TM    CXCMPOVF+1,X'F0'         DID COMPRESSION OVERFLOW        06860000
         BCR   8,5                      NO, RETURN TO USER              06880000
         CLI   CXCMPOVF,X'F0'           WERE NOTE NUMS TAKEN ON DA      06900000
         BNE   PTASGNT                  NO                              06920000
         SR    14,14                    YES, CONVERT BLOCK ID TO COUNT  06940000
         IC    14,CXTRKBF                                               06960000
         MH    14,CXNOTNUM              EXTEND TRACK NUM                06980000
         SR    15,15                                                    07000000
         IC    15,CXNOTNUM+2                                            07020000
         AR    14,15                    ADD BLOCK NUM                   07040000
         ST    14,CXNOTNUM              STORE CONVERTED BLOCK ID        07060000
PTASGNT  L     14,CXNOTNUM              LOAD BLOCK NUM FROM NOTE        07080000
         BCTR  14,0                     DECR BLOCK NUM                  07100000
         LTR   14,14                    IS IT ZERO                      07120000
         BCR   12,5                     YES, NOTE REF FIRST BLOCK, RETN 07140000
         ST    5,CXDUBLWD+4             SAVE USER RETURN REG            07160000
PTASGNA  ST    14,CXNOTNUM              STORE UPDATED BLOCK NUM         07180000
         BAL   5,GETCMP                 COPY ACROSS FROM ONE            07200000
         BAL   5,PUTCMP                   FILE TO THE NEXT              07220000
         L     14,CXNOTNUM              LOAD WORKING BLOCK NUM          07240000
         BCT   14,PTASGNA               DECR BLOCK NUM, CONT TIL ZERO   07260000
         L     5,CXDUBLWD+4             RESTORE USER RETURN REG         07280000
         BR    5                        RETURN TO USER                  07300000
RDSPEC   EQU   DUMRTRN                                                  07320000
RLDIN    EQU   DUMRTRN                                                  07340000
PTRLDW   EQU   DUMRTRN                                                  07360000
BLKOUT   EQU   DUMRTRN                                                  07380000
BLKIN    EQU   DUMRTRN                                                  07400000
PNTINP   EQU   DUMRTRN                                                  07420000
PNTCLC   EQU   DUMRTRN                                                  07440000
PNTOUT   EQU   DUMRTRN                                                  07460000
NOTEIN   EQU   DUMRTRN                                                  07480000
NOTECL   EQU   DUMRTRN                                                  07500000
NOTEOT   EQU   DUMRTRN                                                  07520000
NTASGN   EQU   DUMRTRN                                                  07540000
PHDUMP   EQU   DUMRTRN                                                  07560000
PTRLDR   EQU   DUMRTRN                                                  07580000
***********************************************                         07600000
*CIOEX DATA AREA                                                        07620000
***********************************************                         07640000
CXDATA   DSECT                                                          07660000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       07680000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 07700000
*                                         (START WITH PREPHASE)         07720000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 07740000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       07760000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   07780000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     07800000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     07820000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     07840000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        07860000
CXFLDADD DS    F                                FIELD NAME TABLE        07880000
CXLITADD DS    F                                LITERAL TABLE           07900000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 07920000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     07940000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      07960000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   07980000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                08000000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      08020000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         08040000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      08060000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    08080000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     08100000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    08120000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            08140000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    08160000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   08180000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           08200000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      08220000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  08240000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   08260000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 08280000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    08300000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         08320000
CXRETCDE DC    X'00'                    RETURN CODE                     08340000
CXIPTEOF BR    2                        LINKAGE TO EOF ROUTINE          08360000
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            08380000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          08400000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    08420000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           08440000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     08460000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    08480000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                08500000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             08520000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            08540000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     08560000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      08580000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    08600000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   08620000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        08640000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               08660000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     08680000
CXSYNERR B     4(2)                     LINKAGE TO SYNCH ERROR ROUTINE  08700000
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    08720000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     08740000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        08760000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          08780000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        08800000
CXTODAY  DC    C'  /  /  '              DATE                            08820000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             08840000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        08860000
RDRPCHAR DS    80C                      READER/PUNCH AREA               08880000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       08900000
PNTRAREA DS    120C                     PRINT AREA                      08920000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 08940000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 08960000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 08965015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 08970015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 08975015
CXDEND   EQU   *                                                        08980000
         END   IESCEX                                                   09000000
