         TITLE 'IES110  OS/360 RPG ASSEMBLE PHASE 1                 21' 00020000
* STATUS       CHANGE LEVEL 1-8                                  A26410 00040019
*FUNCTION/OPERATION: PROCESS COMPRESSED FILE DESCRIPTION AND FILE       00060000
*   EXTENTION SPECIFICATIONS TO PUT OUT PRECODED SUBROUTINES FOR        00080000
*   CHAINING, TABLE, AND RECORD ADDRESS FILES.                          00100000
*ENTRY POINTS:                                                          00120000
*        IES11010 - ENTER PHASE FROM IES11910.                          00140000
*        PHSLINK  L     15,PHSADDR                                      00160000
*                 BALR  7,15                                            00180000
*                 *                                                     00200000
*                 *                                                     00220000
*        PHSADDR  DC    V(IES11010)                                     00240000
*        POINTERS, COUNTERS, AND CONSTANTS PASSED IN CIOEX DATA AREA    00260000
*        POINTED TO BY REGISTERS 6 AND 12 UPON ENTRY.                   00280000
*INPUT: COMPRESSED RPG SPECIFICATIONS ON SYSUT2.                        00300000
*OUTPUT: OBJECT TEXT ON SYSPUNCH OR SYSGO, AND CIOEX LINKAGE VECTOR     00320000
*   ENTRIES ON SYSUT3.                                                  00340000
*EXTERNAL ROUTINES:                                                     00360000
*        IES11910-CIOEX ROUTINES FOR ASSEMBLE PHASE 1.                  00380000
*        GETCMP - GET NEXT BLOCK OF COMPRESSION                         00400000
*        PHSCAL - LOAD THE NEXT PHASE                                   00420000
*        PUTCOD - PUT OUT TEXT ON SYSGO/SYSPCH                          00440000
*        PNTCMP - REINITIALIZE WORKFILE TO FIRST COMPRESSION BLOCK      00460000
*        RLDOUT - PUT OUT A RECORD ON RLD WORKFILE                      00480000
*EXITS-NORMAL: AM3333 - PHASE FINISHED.BRANCH TO NEXT PHASE VIA PHSCAL. 00500000
*     -ERROR: NONE.                                                     00520000
*TABLES/WORKAREAS: NONE.                                                00540000
*ATTRIBUTES: EDITABLE, DOWNWARD COMPATIBLE.                             00560000
*NOTES: N/A                                                             00580000
*                                                                       00600000
*                                                                       00620000
IES11010 START                                                          00640000
*0142000400,006460-006520,149400                                   9336 00650000
*0142000400,006460-006520,149400,197400,255400                     I222 00655000
ASSEMBL1 EQU   *                                                        00660000
         EXTRN IES11910                                                 00680000
*                                                          *            00700000
*        RPG/D ASSEMBLE PHASE 1                            *            00720000
*              TABLES                                      *            00740000
*              CHAINING                                    *            00760000
*              TAG SORT AND RECORD ADDRESS FILE SUPPORT    *            00780000
************************************************************            00800000
*******************                                                3369 00801015
* NOTE: A CHANGE IN THE STACKER SELECT LOGIC RESULTED IN DELETING  3369 00802015
* CODE FROM VARIOUS ROUTINES OF THIS PHASE.(IF NO STACKER SELECT   3369 00803015
* IS SPECIFIED A CONTROL IS NO LONGER ISSUED)                      3369 00804015
* THE DELETED CODE EFFECTIVELY SET BYTE 14 OF THE IORB TO X'04'    3369 00805015
* FOR A CONTROL AND BRANCHED TO DO THE CONTROL FOR A STACKER       3369 00806015
* SELECT. SINCE A STACKER SELECT CODE WAS NO LONGER NEEDED, BYTE   3369 00807015
* 15 OF THE IORB WAS CHANGED FROM X'01' TO X'00' IN THE DC         3369 00808015
* INSTRUCTION FOR EACH ROUTINE.                                    3369 00809015
********************                                               3369 00810015
         EJECT                                                          00820000
******************************                                          00840000
*                                                                       00860000
*    REGISTER EQUATES // ASSEMBLE 1                                     00880000
*                                                                       00900000
******************************                                          00920000
ADDREG   EQU   13                       ADDRESS REGISTER FOR TEXT OUT   00940000
CMPREG   EQU   3                        COMPRESSION REGISTER            00960000
DATBS1   EQU   3                        FIRST DATA BASE REGISTER        00980000
CNTREG   EQU   11                       COUNT REGISTER FOR TXT CHAR     01000000
LOCREG   EQU   12                       LOCATION REGISTER FOR TXTCHR    01020000
SLVRG1   EQU   15                       PARAMETER REGISTER              01040000
SLVRG2   EQU   1                        PARAMETER REGISTER              01060000
RETURN   EQU   5                        RPG RETURN REGISTER             01080000
RQTPTR   EQU   7                        CIOEX POINTER                   01100000
RQSTPT   EQU   RQTPTR                                                   01120000
LNKREG   EQU   14                       ASSEMBLE 1 LINK REGISTER        01140000
WRKRG1   EQU   2                        WORK REGISTER                   01160000
WRKRG2   EQU   11                       WORK REGISTER                   01180000
WRKRG3   EQU   12                       WORK REGISTER                   01200000
SRTPNT   EQU   0                        SYSTEM PARAMETER REGISTER       01220000
REQSTR   EQU   WRKRG1                   I/O REQUEST REGISTER            01240000
CIOEXD   EQU   6                        CIOEX DATA BASE REGISTER        01260000
PUNREG   EQU   4                        RPG PUNCH REGISTER              01280000
AMBASE   EQU   8                        ASSEMBLE1 BASE REGISTER         01300000
******************************                                          01320000
*                                                                       01340000
*        CHARACTER EQUATES                                              01360000
*                                                                       01380000
******************************                                          01400000
CHARA    EQU   X'C1'                    A                               01420000
CHARE    EQU   X'C5'                    E                               01440000
CHARF    EQU   X'C6'                    F                               01460000
CHARD    EQU   X'C4'                    C                               01480000
CHARP    EQU   X'D7'                    P                               01500000
CHART    EQU   X'E3'                    T                               01520000
CHARC    EQU   X'C3'                    C                               01540000
CHARR    EQU   X'D9'                                                    01560000
******************************                                          01580000
*                                                                       01600000
*        CIOEX ROUTINE EQUATES                                          01620000
*                                                                       01640000
******************************                                          01660000
PUNCOD   EQU   12                       PUNCH A 80 BYTE RECORD          01680000
RLDPUT   EQU   18                       WRITE ON RLD FILE               01700000
GETCMP   EQU   0                        GET NEXT COMPRESSION BLOCK      01720000
PHSCAL   EQU   4                        CALL NEXT PHASE                 01740000
PNTCMP   EQU   16                       REWIND COMPRESSION              01760000
******************************                                          01780000
*                                                                       01800000
*   EQUIVALENCE SECTIONS(CIOEX DATA AREAS)                              01820000
*                                                                       01840000
******************************                                          01860000
ADDCNT   EQU   X'34'                                                    01880000
PASKEY   EQU   X'C4'                                                    01900000
PHSNAM   EQU   X'08'                                                    01920000
         EJECT                                                          01940000
******************************                                          01960000
*                                                                       01980000
*  PHASE PROCESSOR EQUATES                                              02000000
*                                                                       02020000
******************************                                          02040000
LVIORB   EQU   200                      INPUT/OUTPUT REQUEST BLOCK PTR  02060000
IOROUT   EQU   208                      INPUT / OUTPUT ROUTINE          02080000
TABRUT   EQU   160                      DISPLACEMENT TO LINKAGE VECTOR  02100000
CHNRUT   EQU   156                          ENTRY FOR TABLE,CHAINING,   02120000
IOINTR   EQU   148                          INPUT/OUTPUT INTERCEPT,AND  02140000
RAFROT   EQU   152                          RECORD ADDRESS FILE         02160000
LVDRTY   EQU   172                      DETERMINE RECORD TYPE           02180000
LVDSPC   EQU   176                      DATA SPECIFICATION ROUTINE      02200000
LVWORK   EQU   232                      WORK PTR OBJECT CODE            02220000
INDHH0   EQU   133                      DISPLACEMENT TO H0 INDICATOR    02240000
RLDLEN   EQU   6                        LENGTH OF RLD ENTRY IN BUFFR    02260000
ALFTYP   EQU   8                        ALPHA TYPE TABLE ENTRY          02280000
UNPCKD   EQU   4                        UNPACKED TABLE ENTRY            02300000
AMTABL   EQU   32                       MASK TEST BITS FOR TABLE,       02320000
AMCHNG   EQU   16                            CHAINING,                  02340000
AMADRT   EQU   128                           TAG SORT,                  02360000
AMRAF    EQU   64                            AND RECORD ADDRESS FILE    02380000
RAFFRM   EQU   1                        RAF FROM FILE DISPLACE          02400000
RAFTO    EQU   3                        RAF TO FILE DISPLACE            02420000
RAFCND   EQU   5                        DISPLACE TO CONTD               02440000
RAFLEN   EQU   21                       DISPLACE TO ENTRY LENGTH        02460000
RAFCSW   EQU   14                       DISPLACE TO RAF CONV SWITCH     02480000
RAFCRT   EQU   15                       DISPLACE TO CONV ROUT NAME      02500000
DSFLDS   EQU   10                       FILE DESIGNATION DISP           02520000
DSFLOR   EQU   24                       FILE ORGANIZATION DISP          02540000
DSRECL   EQU   17                       RECORD LENGTH DISP              02560000
FDSLEN   EQU   55                       LENGTH FOR FILE DES COMP        02580000
RLNWOC   EQU   15                       RAF COMP LENGTH W/O CONVERSION  02600000
RCVLEN   EQU   9                        RAF CONVERSION LENGTH           02620000
AMISRT   BALR  AMBASE,0                 (SET BASE REGISTER              02640000
         USING *,AMBASE                 FOR ASSEMBLE 1)                 02660000
         L     7,CXRADDR                                                02680000
         ST    RETURN,AMRTHD            (SAVE RETURN REGISTER)          02700000
         L     ADDREG,ADDCNT(CIOEXD)    (PICKUP ADDRESS FOR             02720000
*                                       TEXT OUTPUT)                    02740000
         MVC   AMPSK1(2),PASKEY(CIOEXD)   PICK UP FDS/FES SWITCHES      02760000
AM0100   LA    WRKRG1,PNTCMP            (CONDITION FILE TO PICK         02780000
         BALR  RETURN,RQSTPT            UP FIRST BLOCK)                 02800000
AM0200   LA    WRKRG1,GETCMP            (GET BLOCK OF                   02820000
         BALR  RETURN,RQSTPT            COMPRESSION)                    02840000
AM0250   CLI   0(CMPREG),X'FD'          TEST IF ERROR H AS OCCURRED     02860000
         BE    *+12                                                     02880000
         CLI   0(CMPREG),X'FE'          TEST FOR ERROR                  02900000
         BNE   *+14                                                     02920000
         MVC   PHSNAM(8,CIOEXD),DIAG1     SET TO CALL DIAG 1            02940000
         B     AM3333                                                   02960000
         CLI   0(CMPREG),X'FF'          (IF END OF THIS COMP            02980000
         BE    AM0200                   BLOCK, GET ANOTHER)             03000000
*****************************                                           03020000
*     TEST FOR FDS ENTRY                                                03040000
*****************************                                           03060000
AM0300   CLI   0(CMPREG),CHARF          (TEST FOR FDS ENTRY)            03080000
         BNE   AM0700                   (NOT FDS TEST REST OF TYPES)    03100000
*****************************                                           03120000
*    TEST FOR TAG SORT SUPPPORT                                         03140000
*****************************                                           03160000
AM0500   CLI   DSFLOR(CMPREG),CHART     (IF NOT ADDROUT                 03180000
         BNE   AM0400                   THEN TRY FOR RAF)               03200000
*****************************                                           03220000
*    TAG SORT SUPPORT FILE FOUND                                        03240000
*****************************                                           03260000
         CLI   13(CMPREG),C'V'          TEST FOR VARIABLE LENGTH        03280000
         BNE   AM0600                                                   03300000
         MVI   ACFIXVAR+1,X'04'         SET COUNT FOR VARIABLE LENGTH   03320000
         B     AM0600                                                   03340000
AM0400   CLI   DSFLDS(CMPREG),CHARR     (IF THIS IS NOT A               03360000
         BNE   AM0600                   RAF, TEST NEXT SPEC             03380000
*****************************                                           03400000
*     RECORD ADDRESS FILE FOUND                                         03420000
*****************************                                           03440000
         MVC   DBLWRD(8),ZEROS          (ZERO CONVERSION AREA)          03460000
         MVC   DBLWRD+6(2),RAFLEN(CMPREG) (SET UP RAF ENTRY LENGTH      03480000
         CVB   SLVRG1,DBLWRD            FOR CONVERT TO BINARY)          03500000
         STH   SLVRG1,DCRBLN            (INSERT ENTRY LENGTH            03520000
         STH   SLVRG1,ICKYLN            SUPPORT ROUTINES)               03540000
*****************************                                           03560000
*     BUMP CMPREG AND LOOK AT NEXT COMPRESSED SPEC                      03580000
*****************************                                           03600000
AM0600   LA    CMPREG,FDSLEN(CMPREG)    (BUMP COMPRESSION AND           03620000
         B     AM0250                   LOOK AT NEXT SPEC)              03640000
*****************************                                           03660000
*     TEST IF OTHER THAN EXTENSION TYPE                                 03680000
*****************************                                           03700000
AM0700   LA    SLVRG1,CPTYPE            (SET UP REGISTERS FOR           03720000
         LA    SLVRG2,6                 LEGAL TYPE TESTS)               03740000
AM0720   CLC   0(1,CMPREG),0(SLVRG1)    (TEST TYPES FOR                 03760000
         BE    AM2200                   TERMINATION)                    03780000
         LA    SLVRG1,1(SLVRG1)         (SET FOR NEXT TEST)             03800000
         BCT   SLVRG2,AM0720                                            03820000
*****************************                                           03840000
*    MUST HAVE ENCOUNTERED A FILE EXTENSION TYPE                        03860000
*****************************                                           03880000
         CLI   AMSWTH,X'00'             (IF THIS IS NOT FIRST           03900000
         BNE   AM1600                   PASS, BYPASS CHAINING           03920000
*                                       AND TABLE ROUTINE OUTPUT)       03940000
*****************************                                           03960000
*     IF CHAIN TYPE COMPRESSED OUTPUT CHAIN LOGIC OTHERWISE DUMMY       03980000
*****************************                                           04000000
         TM    AMPSK1,AMCHNG            (IF NO CHAINING TYPES           04020000
         BC    8,AM1400                 THEN PUT OUT DYMMY)             04040000
AM1300   L     CNTREG,XXCHNE            (SET UP LINKAGE TO              04060000
         L     LOCREG,XXCHNS            LET TXTFUL OUTPUT               04080000
         SR    CNTREG,LOCREG            CANNED CHAINING ROUTINE         04100000
         BC    15,AM1500                                                04120000
AM1400   LA    CNTREG,22                (SET UP TO OUTPUT               04140000
         LA    LOCREG,CCDUMY            DUMMY ROUTINE)                  04160000
AM1500   BAL   RETURN,TXTFUL                                            04180000
         ST    SRTPNT,XXCHNA            (ADDRESS FOR LINK VECTOR)       04200000
         MVI   AMSWTH,X'F0'             (SET SWITCH TO IMPLY            04220000
*                                       CANNED ROUTINES CAN BE          04240000
*                                       OVERLAYED (T AND C))            04260000
*****************************                                           04280000
*    TEST TYPE OF THIS EXTENSION SPEC                                   04300000
*****************************                                           04320000
AM1600   CLI   0(CMPREG),CHART          (IS THIS TABLE COMPRESSION)     04340000
         BE    TCBLD                    (YES, BRANCH TO TABLE BUILD)    04360000
AM1700   CLI   0(CMPREG),CHARE          (IS THIS CHAINING)              04380000
         LA    RETURN,AM0250            RETURN POINT FOR NEXT SPEC      04400000
         BE    CHNSUB                   (YES, BRANCH TO CHAIN BUILD)    04420000
*****************************                                           04440000
*    MUST HAVE BEEN AN RAF FILE                                         04460000
*****************************                                           04480000
AM1800   PACK  DBLWRD,RAFFRM(2,CMPREG)  (PICK UP FROM FILE FOR          04500000
         CVB   SLVRG1,DBLWRD            I OR B INFORMATION)             04520000
         STC   SLVRG1,ICFILE            (INDEXED SEQUENTIAL)            04540000
         STC   SLVRG1,ACFILE            (ADROUT FOR TAG SORT)           04560000
         STC   SLVRG1,DCFILE            (DIRECT ORGANIZATION)           04580000
         PACK  DBLWRD,RAFTO(2,CMPREG)   (PICK UP TO FILE FOR            04600000
         CVB   SLVRG1,DBLWRD            I/O INTERCEPT)                  04620000
         STC   SLVRG1,CIFILE            (INTERCEPT ROUTINE)             04640000
         LA    WRKRG1,RAFCND(CMPREG)    PICK UP ADDRESS OF BDDD         04660000
         BAL   RETURN,ADDCNV            LINK TO CONVERSION ROUTINE      04680000
         ST    WRKRG1,ICONTD                                            04700000
         ST    WRKRG1,DCONTD            CONTD ADDRESS TO CANNED         04720000
*                                         ROUTINE FOR RAF SUPPORT       04740000
         CLI   RAFCSW(CMPREG),CHARC     (IF THIS IS NOT D/O RETURN      04760000
         BNE   AM2000                   TO GET ANOTHER SPEC             04780000
AM1900   LA    WRKRG1,RAFCRT(CMPREG)    PICK UP ADDRES OF BDDD          04800000
         BAL   RETURN,ADDCNV            LINK TO CONVERSION ROUTINE      04820000
         ST    WRKRG1,DCCONV            CONVERTED ADDRESS TO CANNED     04840000
*                                         MODULE                        04860000
         MVI   AMDIOR,X'F0'             (TURN ON DIRECT ORG)            04880000
         LA    CMPREG,RCVLEN(CMPREG)    (BUMP FOR CONVERSION)           04900000
AM2000   LA    CMPREG,RLNWOC(CMPREG)    (BUMP FOR REGULAR ENTRY)        04920000
         B     AM0250                   (TEST NEXT SPEC)                04940000
         EJECT                                                          04960000
*****************************                                           04980000
*                                                                       05000000
*  LAST EXTSN SPEC HAS BEEN PROCESSED                                   05020000
*        STARTING WIND UP OF PHASE                                      05040000
*                                                                       05060000
*****************************                                           05080000
AM2200   TM    PASKEY(CIOEXD),AMCHNG    TEST IF CHAINING OUTPUTTED      05100000
         BC    14,AM2250                NO, CHECK FOR TABLES            05120000
         L     SLVRG1,CADTAB            (CHAINING ENTRIES PRESENT       05140000
         MVI   1(SLVRG1),X'FF'                                          05160000
         MVI   0(SLVRG1),X'FF'          FLAG END OF ENTRIES AND         05180000
         MVI   CLSTPS,X'F0'             OUTPUT REST OF PARLIST)         05200000
         LA    SLVRG1,1(SLVRG1)         INCREASE COUNT TO INCLUDE 'FF'  05220000
         ST    SLVRG1,CADTAB                                            05240000
         BAL   RETURN,CHNSUB                                            05260000
AM2250   TM    PASKEY(CIOEXD),AMTABL    WAS TABLE ROUT OUTPUTTED QQQ.   05280000
*****************************                                           05300000
*     IF TABLE TYPE COMPRESSED,OUTPUT TABLE LOGIN OTHERWISE CUMMY       05320000
*****************************                                           05340000
         BC    1,AM1100                 OUTPUT TABLE MODULE)            05360000
AM1000   LA    LOCREG,TCDUMY            (SET UP TO OUTPUT               05380000
         LA    CNTREG,2                 DUMMY ROUTINE)                  05400000
       BAL   RETURN,TXTFUL              OUTPUT DUMMY TABLE              05420000
       ST    SRTPNT,XXTABA              STORE THE TARGET ADDRESS        05440000
       BC    15,AM2500                                                  05460000
AM1100   L     LOCREG,XXTABS            (SET UP TO USE TXTFUL           05480000
         L     CNTREG,XXTABE            TO OUTPUT CANNED                05500000
         MVI 0(CNTREG),X'FF'     POST END OF TABLE PARLISTS             05520000
         LA    CNTREG,1(CNTREG)                                         05540000
         SR    CNTREG,LOCREG            TABLE LOGIC)                    05560000
AM1200   BAL   RETURN,TXTFUL                                            05580000
         ST    ADDREG,AMTATP            (PICK UP TABLE ADDRESS          05600000
*                                       TEXT POINT)                     05620000
         ST    SRTPNT,XXTABA            (ABSOLUTE ADD FOR LINKAGE)      05640000
         EJECT                                                          05660000
*                                                                       05680000
*ROUTINE TO OUTPUT TABLE LINKAGE FIELD                                  05700000
*      TABLE LINKAGE FIELD BUILT FROM TABLE PARLIST ENTRIES             05720000
*                                                                       05740000
*                                                                       05760000
* TABLE LINKAGE OUTPUT 16 BYTES                                         05780000
*        BYTES 1   TABLE TYPE BYTE                                      05800000
*                       BITS 0-3 0000   NOT USED                        05820000
*                              4    0   NUMERIC TABLE                   05840000
*                                   1   ALPHAMERIC TABLE                05860000
*                              5    0   PACKED INPUT                    05880000
*                                   1   UNPACKED INPUT                  05900000
*                            6,7   01   ASCENDING TABLE                 05920000
*                                  10   DESCENDING TABLE                05940000
*                                  00   NEITHER                         05960000
*                                  11   NOT USED                        05980000
*              2   LENGTH OF ENTRY                                      06000000
*              3-4 NUMBER OF TABLE ENTRIES                              06020000
*              5-8 ADDRESS OF START OF TABLE                            06040000
*              9-12ADDRESS OF END OF TABLE                              06060000
*             13-16WORK ADDRESS INITIALIZED AS ZERO                     06080000
******************************                                          06100000
AM2350   L     WRKRG2,XXTABOUT     PICK UP ADDRESS OF PARLIST    A26410 06120019
********************                                                    06140000
*   BUILD TABLE LINKAGE FIELD FOR FIRST TABLE ENTRY                     06160000
********************                                                    06180000
FCLOOP   SR    SLVRG1,SLVRG1            ZERO REGISTER                   06200000
         IC    SLVRG1,TLENG1(WRKRG2)    PICK UP ENTRY LENGTH            06220000
         LA    SLVRG1,1(SLVRG1)         FOR TRUE LENGTH                 06240000
         TM    TCODE1(WRKRG2),X'08'     IS THE TABLE ALPHA,QQQ          06260000
         BC    1,*+12                   TABLE IS ALPHAMUMERIC           06280000
         SRL   SLVRG1,1                 NUMERIC, FORM L/2               06300000
          LA   SLVRG1,1(SLVRG1)         FORM(L/2)+1,TABLE LENGTH NUM    06320000
         MVC   HLFSTR(2),TNUMTB(WRKRG2) ALIGN NUMBER OF ENTRIES IN TABL 06340000
         MH    SLVRG1,HLFSTR            COMPUTE TABLE LENGTH            06360000
         MVC   FCTXTB(1),TCODE1(WRKRG2) TABLE TYPE BYTE TO PUNCH IMAGE  06380000
         MVC   FCTXTP(3),TLFAD1(WRKRG2) TARGET ADDRESS OF TLF 1         06400000
         MVC   FCTXTL(1),TLENG1(WRKRG2) ENTRY LENGTH                    06420000
         MVC   FCTXTL+1(2),TNUMTB(WRKRG2) NUMBER OF ENTRIES PER TABLE   06440000
         BAL   RETURN,FCOUT             LET SUBROUTINE OUTPUT TLF       06460000
********************                                                    06480000
*   BUILD TABLE LINKAGE FIELD FOR SECOND TABLE ENTRY                    06500000
********************                                                    06520000
         TM    TACTIN(WRKRG2),X'03'     TEST FOR PRESENCE OF SECOND TAB 06540000
         BC    14,FCEXIT                IF NO TAB 2 SEE IF FINISHED     06560000
         SR    SLVRG1,SLVRG1            ZERO REGISTER                   06580000
         IC    SLVRG1,TLENG2(WRKRG2)    PICK UP ENTRY LENGTH            06600000
         LA    SLVRG1,1(SLVRG1)         FOR TRUE LENGTH                 06620000
         TM    TCODE2(WRKRG2),X'08'     IS THE TABLE ALPHA,QQQ          06640000
         BC    1,*+12                   TABLE IS ALPHAMUMERIC           06660000
         SRL   SLVRG1,1                 NUMERIC, FORM L/2               06680000
          LA   SLVRG1,1(SLVRG1)         FORM(L/2)+1,TABLE LENGTH NUM    06700000
         MH    SLVRG1,HLFSTR            COMPUTE TABLE LENGTH            06720000
         MVC   FCTXTB(1),TCODE2(WRKRG2) TABLE TYPE BYTE TO PUNCH IMAGE  06740000
         MVC   FCTXTP(3),TLFAD2(WRKRG2) TARGET ADDRESS OF TLF2          06760000
         MVC   FCTXTL(1),TLENG2(WRKRG2) ENTRY LENGTH                    06780000
         BAL   RETURN,FCOUT                                             06800000
FCEXIT   LA    WRKRG2,TENTRY(WRKRG2)    BUMP TABLE POINTER              06820000
         C     WRKRG2,TADDFL            ARE WE FINISHED                 06840000
         BNE   FCLOOP                   NO,PROCESS NEXT SET             06860000
         B     AM2500                                                   06880000
FCOUT    ST    RETURN,HLDRG2            STORE RETURN ADDRESS            06900000
         ST    ADDREG,FCTXTS            INSERT START OF TABLE AREA      06920000
         AR    ADDREG,SLVRG1            COMPUTE END OF TABLE + 1        06940000
         ST    ADDREG,FCTXTE            STORE END OF TABLE+1            06960000
         MVC   0(32,PUNREG),FCTXT       MOVE RECORD TO PUNCH AREA       06980000
         LA    REQSTR,PUNCOD            LET CIOEX PUNCH                 07000000
         BALR  RETURN,RQSTPT                THE RECORD                  07020000
         L     RETURN,HLDRG2            RETURN TO                       07040000
         BCR   15,RETURN                   CALLING ROUTINE              07060000
HLDRG2   DS    F                        ALTERNATE HOLD AREA             07080000
******************************                                          07100000
*                                                                       07120000
*   OUTPUT I/O INTERCEPTOR ROUTINE                                      07140000
*                                                                       07160000
******************************                                          07180000
AM2500   L     CNTREG,XXIOIE            PICK UP LAST ENTRY FOR OUTPUT   07200000
         L     LOCREG,XXIOIS            PICK UP BEGINNING ADDRESS       07220000
         SR    CNTREG,LOCREG            DETERMINE LENGTH                07240000
         BAL   RETURN,TXTFUL            FULL WORD ALIGN ROUTINE         07260000
         ST    SRTPNT,XXIOIA            SAVE TARGET ADDRESS             07280000
*************************                                               07300000
*                                                                       07320000
*   OUTPUT RAF SUPPORT ROUTINE (ADDROUT,D/O,I/S)                        07340000
*                                                                       07360000
*************************                                               07380000
AM2600   TM    PASKEY(CIOEXD),X'80'     TEST FOR TAG SORT               07400000
         BC    1,AM2800                 **SET TAG SORT FOR OUTPUT       07420000
         TM    PASKEY(CIOEXD),X'40'     TEST FOR RECORD ADDRESS FILE    07440000
         BC    14,AM3000                **NOTHING TO OUTPUT             07460000
         TM    AMDIOR,X'F0'             DIRECT ORGANIZATION QQQ..       07480000
         BC    1,AM2700                 YES,D/O                         07500000
         L     LOCREG,XXISQS            NO,INDEXED SEQUENTIAL           07520000
         L     CNTREG,XXISQE                                            07540000
         B     AM2900                   OUTPUT CANNED LOGIC             07560000
AM2700   L     LOCREG,XXDROS            DIRECT ORG TO BE OUTPUTTED      07580000
         L     CNTREG,XXDROE                                            07600000
         B     AM2900                                                   07620000
AM2800   L     LOCREG,XXADRS            ADDROUT SUPPORT TO BE OUTPUTTED 07640000
         L     CNTREG,XXADRE                                            07660000
AM2900   SR    CNTREG,LOCREG            DETERMINE ROUTINE LENGTH        07680000
         BAL   RETURN,TXTFUL            OUTPUT CODE                     07700000
         ST    SRTPNT,XXRAFA            SAVE TARGET ADDRESS             07720000
******************************                                          07740000
*                                                                       07760000
*   OUTPUT LINKAGE VECTOR ENTRIES                                       07780000
*                                                                       07800000
******************************                                          07820000
******************************                                          07840000
*  SET UP LINKAGE SECTOR IMAGES                                         07860000
******************************                                          07880000
AM3000   LA    SLVRG1,XXIOIA            PICK UP ARRAY OF TARGET ADDRESS 07900000
         LA    SLVRG2,4                 COUNT OF ROUTINES OUTPUTTED     07920000
         LA    WRKRG1,RLDIM2            RLD OUTPUT AREA                 07940000
AM3025   MVC   2(4,WRKRG1),0(SLVRG1)    MOVE TARGET ADDRESS TO RLD AREA 07960000
         LA    SLVRG1,4(SLVRG1)         BUMP ARRAY POINTERS BY          07980000
         LA    WRKRG1,6(WRKRG1)            RESPECTIVE ENTRY LENGTH      08000000
         BCT   SLVRG2,AM3025            LOOP UNTIL ALL ROUTINES POSTED  08020000
         LA    1,RLDIM1                 ADDRESS OF RECORD TO BE OUTPUT  08040000
         LA    REQSTR,RLDPUT                                            08060000
         BALR  RETURN,RQTPTR            WRITE OUT RLD ENTRY             08080000
********************                                                    08100000
*  CALL NEXT PHASE                                                      08120000
********************                                                    08140000
         MVC   PHSNAM(8,CIOEXD),ASSEM2  IDENTIFY NEXT PHASE AS ASSEM2   08160000
AM3333   LA    REQSTR,PHSCAL            PHASE CALL                      08180000
         ST    ADDREG,ADDCNT(CIOEXD)    UPDATE ADDRESS COUNTER          08200000
         BCR   15,RQSTPT                                                08220000
ASSEM2   DC    C'RPG10120'                                              08240000
DIAG1    DC    C'RPG10190'              PHASE NEME FOR DIAG 1           08260000
CXRADDR  DC    A(IES11910)                                              08280000
         EJECT                                                          08300000
*                                                                       08320000
*   LINKAGE VECTOR ENTRIES                                              08340000
*                                                                       08360000
******************************                                          08380000
XXIOIA   DC    A(0)                     I/O INTERCEPT                   08400000
XXRAFA   DC    A(0)                     RECORD ADDRESS FILE             08420000
XXCHNA   DC    A(0)                     CHAINING                        08440000
XXTABA   DC    A(0)                     TABLES (INPUT AND OUTPUT)       08460000
******************************                                          08480000
*                                                                       08500000
*   CANNED LOGIC ADDRESS TABLE                                          08520000
*                                                                       08540000
******************************                                          08560000
XXCHNS   DC    A(CHNSTR)                CHAINING ROUTINE START          08580000
XXCHNE   DC    A(TSTABL)                                 END            08600000
XXTABS   DC    A(TC0000)                TABLE ROUTINE START             08620000
XXTABE   DC    A(TABOUT)                              END               08640000
XXADRS   DC    A(AC0000)                ADROUT ROUTINE START            08660000
XXADRE   DC    A(ACEND)                                END              08680000
XXDROS   DC    A(DC0000)                RAF DIRECT ORGANIZATION START   08700000
XXDROE   DC    A(DCMVC+6)                                       END     08720000
XXISQS   DC    A(IC0000)                RAF INDEXED SEQUENTIAL START    08740000
XXISQE   DC    A(ICCLC+6)                                      END      08760000
XXIOIS   DC    A(INTRCP)                I/O INTERCEPTOR START           08780000
XXIOIE   DC    A(CIFILE+1)                              END             08800000
XXTABOUT DC    A(TABOUT)           ADDRESS OF PARLIST            A26410 08810019
FCTXT    DS    0F                       TEXT IMAGE FIELD                08820000
         DC    X'02'                    FOR TLF (32 BYTES)              08840000
         DC    CL3'TXT'                                                 08860000
         DC    X'40'                                                    08880000
FCTXTP   DS    CL3                      POINT TO PUT TLF TXT            08900000
         DC    X'4040'                                                  08920000
         DC    H'16'                    NUMBER OF BYTES                 08940000
         DC    X'4040'                                                  08960000
         DC    H'01'                    EXTERNAL SYMBOL IDENT           08980000
FCTXTB   DS    CL1                      TABLE TYPE BYTE                 09000000
FCTXTL   DS    CL1                      ENTRY LENGTH                    09020000
         DS    H                        NUMBER OF TABLE ENTRIES         09040000
FCTXTS   DS    F                        STARTING TABLE ADDRESS          09060000
FCTXTE   DS    F                        END OF TABLE ADDRESS            09080000
FCTXTW   DC    F'0'                                                     09100000
FCADDR   DC    A(FCTAB)                                                 09120000
FCTAB    DS    CL128                                                    09140000
FCHLF4   DC    H'4'                                                     09160000
FCHLF8   DC    H'8'                                                     09180000
AMRTHD   DS    F                        HOLD AREA FOR RETURN REG.       09200000
AMTBSR   DS    F                        DADRESS OF KEY TABLE            09220000
AMTATP   DS    F                        TABLE ADDRESS TEXT STORAGE      09240000
CPTYPE   DC    CL6'LIDCOM'              COMPRESSION TYPES FOLLOWING     09260000
*                                         FILE EXT TYPES                09280000
ZEROS    DC    8X'00'                                                   09300000
AMDIOR   DC    X'00'                    DIRECT/INDEXED SEQUENTIAL       09320000
AMSWTH   DC    X'00'                    FIRST EXENTSION SPEC SWITCH     09340000
AMPSK1   DS    CL1                      FIRST BYTE OF PASKEY INFO       09360000
AMPSK2   DS    CL1                      EXTERNAL ID COUNT               09380000
******************************                                          09400000
*   IMAGE TO BE OUTPUTTED TO RLD POST PROCESSOR                         09420000
******************************                                          09440000
RLDIM1   DC    C'V'                     TYPE OF ENTRY TO RLD PROCESSOR  09460000
RLDIM2   DC    AL2(IOINTR)                                              09480000
         DS    AL4(0)                   I/O INTERCEPT                   09500000
         DC    AL2(RAFROT)                                              09520000
         DS    AL4(0)                   RECORD ADDRESS FIEL             09540000
         DC    AL2(CHNRUT)                                              09560000
         DS    AL4(0)                   CHAINING                        09580000
         DC    AL2(TABRUT)                                              09600000
         DS    AL4(0)                   TABLE ROUTINE                   09620000
         DC    X'FD'                    AM                              09640000
         EJECT                                                          09660000
******************************                                          09680000
*  TCBLD       SUBROUTINE TO BUILD PARAMETER LIST TABLE FOR             09700000
*              CANNED TABLE LOGIC MODULE                                09720000
*                                                                       09740000
*  PARAMETER ENTRIES                                                    09760000
*        BYTE  1    ACTION BYTE    X'01' FOR STUFF/NO SECOND ENTRY      09780000
*                                  X'03' FOR STUFF/SECOND ENTRY         09800000
*                                  AFTER STUFF  NI  ACTION BYTE,X'FE'   09820000
*              2    INPUT FILE NUMBER(BINARY)                           09840000
*              3    OUTPUT FILE NUMBER(BINARY)                          09860000
*            4,5    NUMBER OF ENTRIES PER RECORD (BINARY)               09880000
*            6,7    NUMBER OF TABLE ENTRIES (BINARY)                    09900000
*            8-10   ADDRESS OF TABNNN-16 FOR FIRST FILE                 09920000
*             11    LENGTH OF TABLE ENTRIES IN FIRST TABLE              09940000
*             12    UNPK/PACK,NUM/ALFA,ASCEND/DESCEND FOR FIRST TABLE   09960000
*           13-15   ADDRESS OF TABNNN-16 FOR SECOND FILE                09980000
*             16    LENGTH OF TABLE ENTRIES IN SECOND TABLE             10000000
*             17    UNPK/PACK,NUM/ALFA,ASCEND/DESCEND FOR SECOND TABLE  10020000
*                       BITS 0-3 0000   NOT USED                        10040000
*                              4    0   NUMERIC TABLE                   10060000
*                                   1   ALPHAMERIC TABLE                10080000
*                              5    0   PACKED INPUT                    10100000
*                                   1   UNPACKED INPUT                  10120000
*                            6,7   01   ASCENDING TABLE                 10140000
*                                  10   DESCENDING TABLE                10160000
*                                  00   NEITHER                         10180000
*                                  11   NOT USED                        10200000
******************************                                          10220000
*  PARAMETER LIST EQUATES                                               10240000
*                                                                       10260000
TENTRY   EQU   17                       LENGTH OF PARLIST               10280000
TACTIN   EQU   0                        DSPLCMNT TO ACTION BYTE         10300000
TINFIL   EQU   1                        DSPLCMNT TO INPUT FILE          10320000
TOTFIL   EQU   2                        DSPLCMNT TO OUTPUT FILE         10340000
TNUMRC   EQU   3                        DSPLCMNT TO ENTRIES/RECORD      10360000
TNUMTB   EQU   5                        DSPLCMNT TO ENTRIES/TABLE       10380000
TLFAD1   EQU   7                        DSPLCMNT TO TLF ADDRESS         10400000
TLENG1   EQU   10                       DSPLCMNT TO LENGTH FOR TAB 1    10420000
TCODE1   EQU   11                       DSPLCMNT TO CODE BYTE FOR TAB1  10440000
TLFAD2   EQU   12                       DSPLCMNT TO TLF ADDRESS         10460000
TLENG2   EQU   15                       DSPLCMNT TO LENGTH FOR TAB 2    10480000
TCODE2   EQU   16                       DSPLCMNT TO CODE BYTE FOR TAB2  10500000
LENBYT   EQU   3                        DISPLC FROM TLF TO LENGTH ENTRY 10520000
DECBYT   EQU   4                        DISPLAC TO CODE BYTE FROM TLF   10540000
DECTYP   EQU   DECBYT                                                   10560000
******************************                                          10580000
*                                                                       10600000
*  COMPRESSION EQUATES                                                  10620000
*                                                                       10640000
******************************                                          10660000
*                                       DISPLACEMENT TO...              10680000
DISFRM   EQU   1                             FROM FILE NAME             10700000
DISTO    EQU   3                             TO FILE NAME               10720000
DSNAM1   EQU   12                            TABLE NAME 1               10740000
DSNEPR   EQU   5                             NUMBER OF ENTRIES PER REC  10760000
DSNEPT   EQU   8                             NUMBER OF ENTRIES PER TAB  10780000
DSLEN1   EQU   19                            LENGTH OF ENTRY/TABLE 1    10800000
DSNMA1   EQU   20                            NUM/ALFA TABLE 1           10820000
DSPAC1   EQU   22                            PACK/UNPK  TABLE 1         10840000
DSSQN1   EQU   23                            ASC/DESC  TABLE 1          10860000
DSSNTB   EQU   24                            SECOND TABLE SWITCH        10880000
DSNAM2   EQU   25                            TABLE NAME 2               10900000
DSLEN2   EQU   32                            LENGTH OF ENTRY/TABLE 2    10920000
DSNMA2   EQU   33                            NUM/ALFA TABLE 2           10940000
DSPAC2   EQU   35                            PACK/UNPK TABLE 2          10960000
DSSQN2   EQU   36                            ASC/DESC TABLE 2           10980000
TCMPMN   EQU   25                       COMPRESSION LENGTH NO SEC TAB   11000000
TCMPMX   EQU   37                       COMPRESSION LENGTH WITH SEC TAB 11020000
******************************                                          11040000
*  DATA NAMES                                                           11060000
*                                                                       11080000
*DUBWRD        DOUBLE WORD FOR PACKING                                  11100000
*TADDFD        CONTAINS ADDRESS OF NEXT PARAMETER ENTRY                 11120000
*TABOUT        BEGINNING ADDRRESS OF TABLE                              11140000
*HLDREG        STORAGE FOR RETURN REGISTER                              11160000
******************************                                          11180000
*  ROUTINE STARTING POINT                                               11200000
*      TABLE BUILDER.                                                   11220000
******************************                                          11240000
TCBLD    ST    RETURN,HLDRG1            STORE RETURN REGISTER           11260000
         L     WRKRG2,TADDFD            PICK UP ENTRY POINT IN TABLE    11280000
         LA    WRKRG3,16                DECREMENT FOR TLF ADDRESSES     11300000
*DETERMINE FROM FILE                                                    11320000
         PACK  DBLWRD,DISFRM(2,CMPREG)  PACK FROM FILE NUMBER           11340000
         CVB   SLVRG1,DBLWRD            CONVERT TO BINARY               11360000
         STC   SLVRG1,TINFIL(WRKRG2)    INSERT INFILE NUMBER INTO PARLT 11380000
*DETERMINE TO FILE                                                      11400000
         PACK  DBLWRD,DISTO(2,CMPREG)   DETERMINE OUTPUT FILE NUMBER    11420000
         OI    DBLWRD+7,X'0F'           FORCE LEGAL PLUS SIGN FOR CVB   11440000
         CVB   SLVRG1,DBLWRD               A BLANK ENTRY WILL BE        11460000
         STC   SLVRG1,TOTFIL(WRKRG2)       CONVERTED TO ZERO            11480000
*DETERMINE NUMBER OF ENTRIES PER RECORD                                 11500000
         PACK  DBLWRD,DSNEPR(3,CMPREG)  PACK NUMBER OF TABLE ENTRIES    11520000
         CVB   SLVRG1,DBLWRD            CONVERT IT TO BINARY            11540000
         STH   SLVRG1,DBLWRD            SET UP SO CAN STORE RESULT IN   11560000
         MVC   TNUMRC(2,WRKRG2),DBLWRD    A NON ALIGNED AREA            11580000
*DETERMINE NUMBER OF ENTRIES PER TABLE                                  11600000
         PACK  DBLWRD,DSNEPT(4,CMPREG)  DETERMINE NUMBER OF ENTRIES IN  11620000
         CVB   SLVRG1,DBLWRD              TABLE AS BINARY AND STORE     11640000
         STH   SLVRG1,DBLWRD              IN A NON-ALIGNED              11660000
         MVC   TNUMTB(2,WRKRG2),DBLWRD    AREA                          11680000
*DETERMINE ADDRESS OF TLF LINK POINT                                    11700000
         LA    WRKRG1,DSNAM1(CMPREG)    PICK UP ADDRESS OF NAME FIELD   11720000
         BAL   RETURN,ADDCNV            LET ADDRESS CONVERT DO THE WORK 11740000
         SR    WRKRG1,WRKRG3            SET ADDRESS TO START TABLE ADDR 11760000
         ST    WRKRG1,DBLWRD            SET UP FOR STORAGE INTO A       11780000
         MVC   TLFAD1(3,WRKRG2),DBLWRD+1  NON-ALIGNED AREA              11800000
*DETERMINE LENGTH FOR FIRST FILE                                        11820000
         MVC   TLENG1(1,WRKRG2),DSLEN1(CMPREG)                          11840000
*DETERMINE CODE BYTE FOR FIRST TABLE                                    11860000
         MVI   TCODE1(WRKRG2),X'00'     INITIALIZE AREA                 11880000
         CLI   DSPAC1(CMPREG),CHARP     TEST FOR PACKED                 11900000
         BE    *+8                        NOT PACKED                    11920000
         OI    TCODE1(WRKRG2),X'04'       PACKED                        11940000
         CLI   DSNMA1(CMPREG),X'40'     TEST FOR ALPHANUMERIC           11960000
         BNE   *+8                        ALPHANUMERIC                  11980000
         OI    TCODE1(WRKRG2),X'08'       NUMERIC                       12000000
         CLI   DSSQN1(CMPREG),CHARD     TEST FOR DESCENDING             12020000
         BNE   *+8                        ASCENDING OR NEITHER          12040000
         OI    TCODE1(WRKRG2),X'02'       DESCENDING                    12060000
         CLI   DSSQN1(CMPREG),CHARA     TEST FOR ALPHA NUMERIC          12080000
         BNE   *+8                      NO, NUMERIC                     12100000
         OI    TCODE1(WRKRG2),X'01'     YES, TURN ON ALPH BIT           12120000
*TEST FOR PRESENCE OF SECOND FILE                                       12140000
         CLI   DSSNTB(CMPREG),CHART                                     12160000
         BE    TABSB2                   SECOND TABLE IS PRESENT         12180000
         MVI   TACTIN(WRKRG2),X'01'     SET ACTION BYTE                 12200000
         LA    SLVRG1,TCMPMN            LOAD LENGTH OF THIS CMP ENTRY   12220000
         BC    15,TSUBXT                LINK TO SUBROUTINE EXIT         12240000
* SECOND TABLE PARLST BUILDER                                           12260000
TABSB2   MVI   TACTIN(WRKRG2),X'03'     SET ACTION BYTE                 12280000
*DETERMINE ADDRESS OF TLF LINK POINT                                    12300000
         LA    WRKRG1,DSNAM2(CMPREG)    PICK UP ADDRESS OF NAME FIELD   12320000
         BAL   RETURN,ADDCNV            LET ADDRESS CONVERT DO THE WORK 12340000
         SR    WRKRG1,WRKRG3            MODIFY TO POINT TO TAB SRT ADDR 12360000
         ST    WRKRG1,DBLWRD            STORE AS A                      12380000
         MVC   TLFAD2(3,WRKRG2),DBLWRD+1      THREE BYTE ADCON          12400000
*DETERMINE LENGTH OF TABLE ENTRIES                                      12420000
         MVC   TLENG2(1,WRKRG2),DSLEN2(CMPREG)                          12440000
*DETERMINE CODE BYTE FOR SECOND FILE                                    12460000
         MVI   TCODE2(WRKRG2),X'00'     INITIALIZE CODE BYTE            12480000
         CLI   DSPAC2(CMPREG),CHARP     TEST FOR PACKED                 12500000
         BE    *+8                        NOT PACKED                    12520000
         OI    TCODE2(WRKRG2),X'04'       PACKED,TURN ON BIT            12540000
         CLI   DSNMA2(CMPREG),X'40'     TEST FOR ALPHA                  12560000
         BNE   *+8                        ALPHANUMERIC                  12580000
         OI    TCODE2(WRKRG2),X'08'       NUMERIC,TURN ON BIT           12600000
         CLI   DSSQN2(CMPREG),CHARD     TEST FOR DESCENDING             12620000
         BNE   *+8                        ASCENDING OR NEITHER          12640000
         OI    TCODE2(WRKRG2),X'02'       DESCENDING,TURN ON BIT        12660000
         CLI   DSSQN2(CMPREG),CHARA     TEST FOR ALPHA NUMERIC          12680000
         BNE   *+8                      NO, NUMERIC                     12700000
         OI    TCODE2(WRKRG2),X'01'     YES, TURN ON ALPH BIT           12720000
*SET UP FOR EXIT                                                        12740000
         LA    SLVRG1,TCMPMX            PICK UP LENGTH OF COMPRESSION   12760000
*EXIT FROM THIS ROUTINE                                                 12780000
TSUBXT   AR    CMPREG,SLVRG1            UPDATE COMPRESSION REGISTER     12800000
         LA    WRKRG2,TENTRY(WRKRG2)    UPDATE PARAMETER ADDRESS        12820000
         ST    WRKRG2,TADDFD            STORE PARLST ADDRESS            12840000
         L     RETURN,HLDRG1            RETURN TO CALLING PROGRAM       12860000
         BC    15,AM0250                                                12880000
         EJECT                                                          12900000
******************************                                          12920000
*  ROUTINE TO BUILD + OUTPUT PARAMETER TABLE                            12940000
*        FOR CHAINING REQUESTS                                          12960000
*                                                                       12980000
*  PARAMETER LIST FORM                                                  13000000
*        BYTE  1    FROM FILE                                           13020000
*              2,3  RECORD SEQUENCE NUMBER                              13040000
*              4    NUMERIC PORTION OF CHAINING FIELD NUMBER            13060000
*              5    TO FILE                                             13080000
*              6-8  CONVERSION ROUTINE LINKAGE POINT ADDRESS            13100000
*                                                                       13120000
*  ENTRIES WILL BE OUTPUTTED IMMEDIATELY FOLLOWING CHAINING LOGIC       13140000
*        WITH 6 ENTRIES PER CARD                                        13160000
*                                                                       13180000
******************************                                          13200000
*  PARAMETER LIST EQUATES DISPLACEMENTS                                 13220000
CDSFRM   EQU   0                        FROM FILE                       13240000
CDSRSQ   EQU   1                        RECORD SEQUENCE                 13260000
CDSNUM   EQU   3                        NUMERIC KEY                     13280000
CDSTO    EQU   4                        TO FILE                         13300000
CDSCNV   EQU   5                        CONVERSION ADDRESS              13320000
******************************                                          13340000
*                                                                       13360000
*  COMPRESSION DISPLACEMENTS                                            13380000
*                                                                       13400000
CHNFRM   EQU   4                        FROM FILE NUMBER                13420000
CHNTO    EQU   6                        TO FILE NUMBER                  13440000
CHNRSQ   EQU   1                        RECORD SEQUENCE                 13460000
CHNUMB   EQU   3                        CHAINING NUMBER                 13480000
CHNCSW   EQU   8                        CONVERSION SWITCH               13500000
CHNMIN   EQU   9                        MINIMUM COMPRESSION LENGTH      13520000
CHNMAX   EQU   18                       MAXIMUM COMPRESSION LENGTH      13540000
CHNCNM   EQU   9                        CONVERSION NAME FIELD           13560000
******************************                                          13580000
*                                                                       13600000
* WORKING EQUATES                                                       13620000
*                                                                       13640000
*                                                                       13660000
CENTRY   EQU   8                        LENGTH OF ENTRY                 13680000
CBKCNT   EQU   6                        NUMBER OF PAR LISTS PER BLOCK   13700000
*                                                                       13720000
******************************                                          13740000
CHNSUB   ST    RETURN,CHNHLD                                            13760000
         CLI   CPSSWT,X'F0'             TEST IF FIRST PASS SWITCH ON    13780000
         BNE   CETEST                   NOT FIRST PASS END OF TABLE     13800000
         MVI   CPSSWT,X'00'                                             13820000
CHNRST   MVI   CHNTAB,X'40'             RESET PARLIST BUFFER            13840000
         MVC   CHNTAB+1(CBKCNT*CENTRY-1),CHNTAB                         13860000
         MVI   CBKCNT*CENTRY+CHNTAB,X'FF'                               13880000
CETEST   L     WRKRG2,CADTAB            PICK UP ADDRESS OF NEXT ENTRY   13900000
         CLI   0(WRKRG2),X'FF'          TEST FOR END OF BUFFER          13920000
         BE    CBKFUL                                                   13940000
         CLI   CLSTPS,X'F0'             TEST FOR REQUEST TO DUMP BLOCK  13960000
         BE    CHNXIT                                                   13980000
******************************                                          14000000
*                                                                       14020000
*BUILD PARAMETER TABLE ENTRY                                            14040000
*                                                                       14060000
******************************                                          14080000
*                                                                       14100000
* FROM FILE NAME                                                        14120000
*                                                                       14140000
         PACK  DBLWRD,CHNFRM(2,CMPREG)  CONVERT FILE NUMBER TO          14160000
         CVB   SLVRG1,DBLWRD               BINARY AND STORE IN          14180000
         STC   SLVRG1,CDSFRM(WRKRG2)       PARAMETER LIST               14200000
*                                                                       14220000
* TO FILE NAME                                                          14240000
*                                                                       14260000
         PACK  DBLWRD,CHNTO(2,CMPREG)   CONVERT  TO FILE NUMBER         14280000
         CVB   SLVRG1,DBLWRD              TO BINARY AND STORE IN        14300000
         STC   SLVRG1,CDSTO(WRKRG2)       PARAMETER LIST                14320000
*                                                                       14340000
* RECORD SEQUENCE NUMBER                                                14360000
*                                                                       14380000
         MVC   CDSRSQ(2,WRKRG2),CHNRSQ(CMPREG)                          14400000
*                                                                       14420000
* CHAINING FIELD IDENTIFICATION NUMBER                                  14440000
*                                                                       14460000
         MVC   CDSNUM(1,WRKRG2),CHNUMB(CMPREG)                          14480000
         NI    CDSNUM(WRKRG2),X'0F'     REMOVE ZONE TO MAKE BINARY      14500000
*                                                                       14520000
* CONVERSION ROUTINE                                                    14540000
*                                                                       14560000
         CLI   CHNCSW(CMPREG),X'40'     TEST FOR NO CONVERSION          14580000
         BNE   CVPRNT                   CONVERSION PRESENT              14600000
         MVC   CDSCNV(3,WRKRG2),CHNCHK  INSERT ZERO                     14620000
         LA    CMPREG,CHNMIN(CMPREG)    UPDATE CMP REGISTER             14640000
         BC    15,CHNXIT                                                14660000
CVPRNT   LA    WRKRG1,CHNCNM(CMPREG)    PICK UP ADDRESS OF CONVERSION   14680000
         BAL   RETURN,ADDCNV               ROUTINE                      14700000
         ST    WRKRG1,FULLWD                                            14720000
         MVC   CDSCNV(3,WRKRG2),FULLWD+1                                14740000
         LA    CMPREG,CHNMAX(CMPREG)    UPDATE COMPRESSION REGISTER     14760000
CHNXIT   LA    WRKRG2,CENTRY(WRKRG2)    UPDATE POINTER FOR NEXT         14780000
         ST    WRKRG2,CADTAB              TABLE ENTRY                   14800000
         L     RETURN,CHNHLD                                            14820000
         BCR   15,RETURN                                                14840000
******************************                                          14860000
* TEXT OUTPUT                                                           14880000
******************************                                          14900000
CBKFUL   L     CNTREG,CADTAB            SET UP PARAMETERS NECESSARY     14920000
         LA    LOCREG,CHNTAB               FOR USAGE OF TEXT OUTPUT     14940000
         ST    LOCREG,CADTAB            RESET POINTER              9336 14950000
         SR    CNTREG,LOCREG               SUBROUTINE                   14960000
         BAL   RETURN,TXTCHR                                            14980000
         ST    SRTPNT,CSRTHD                                            15000000
         BC    15,CHNRST                RESET OUTPUT AREA               15020000
******************************                                          15040000
*                                                                       15060000
* UNIGUE DATA AREAS                                                     15080000
*                                                                       15100000
******************************                                          15120000
CHNHLD   DS    F                        STORAGE FOR RETURN LINKAGE      15140000
CSRTHD   DS    F                                                        15160000
CADTAB   DC    AL4(CHNTAB)                                              15180000
CLSTPS   DC    X'00'                    LAST PASS SWITCH                15200000
CHNCHK   DC    X'000000'                                                15220000
CPSSWT   DC    X'F0'                    FIRST PASS SWITH                15240000
CHNTAB   DS    CL50                     BLOCK AREA                      15260000
         EJECT                                                          15280000
******************************                                          15300000
*                                                                       15320000
* ADDRESS CONVERSION ROUTINE                                            15340000
*                                                                       15360000
*        WRKRG1  POINTS TO  BDDDXXXXXX0K / RETURNS WITH CONVERTED ADDRS 15380000
*                        B= DATA BASE REGISTER(DATBS1 TO DATBS1+4)      15400000
*                      DDD= DISPLACEMENT                                15420000
*                        K= OVERFLOW KEY  0,1,2,3,4                     15440000
*        DATBS1  REPRESENTS LOWEST DATA BASE REGISTER                   15460000
*                                                                       15480000
*        HLFWRD  IS A HALF WORD ALIGNED WORK AREA                       15500000
*                                                                       15520000
*        SLVRG2,LNKREG ARE USED AS WORK REGISTERS                       15540000
******************************                                          15560000
ADDCNV   MVC   HLFWRD(2),0(WRKRG1)      HALF WORD ALIGN BDDD            15580000
         SR    SLVRG2,SLVRG2            ZERO WORK REGISTER TO BE USED   15600000
         IC    SLVRG2,5(WRKRG1)         PICK UP OVERLOW KEY             15620000
         SLL   SLVRG2,12                MULTIPLY BY 4096                15640000
         LH    WRKRG1,HLFWRD            PICK UP BDDD                    15660000
         SH    WRKRG1,ADDKEY            ADJUST BASE REGISTER FOR OFLOW  15680000
         AR    WRKRG1,SLVRG2            ADD ON AMOUNT OF OVERFLOW       15700000
         BCR   15,RETURN                                                15720000
ADDKEY   DC    AL2(DATBS1*4096)         ADJUST FACTOR FOR ADDRESS       15740000
*                                         COMPUTATION                   15760000
         EJECT                                                          15780000
******************************                                          15800000
* OUTPUT TEXT ROUTINES,TXTFUL,TXTHLF,TXTCHR** EACH LINKS TO OUTEXT      15820000
*              SRTPNT RETURNS WITH TARGET ADDRESS                       15840000
*              LOCREG CONTAINS LOCATION OF FIRST BYTE TO BE OUTPUTTED   15860000
*              CNTREG CONTAIN BYTE COUNT                                15880000
*              ADDREG CONTAINS ADDRESS OF TARGET AREA                   15900000
*              PUNREG CONTAINS ADDRESS OF OUTPUT BUFFER                 15920000
******************************                                          15940000
*                                                                       15960000
* FULL WORD ALIGNMENT REQUIRED                                          15980000
******************************                                          16000000
TXTFUL   LA    ADDREG,3(ADDREG)                                         16020000
         N     ADDREG,FULMSK            STRIP OFF RIGHT ORDER BITS      16040000
         BC    15,TXTCHR                OUTPUT CHARACTER ROUTINE        16060000
******************************                                          16080000
* HALF WORD ALIGNMENT REQUIRED                                          16100000
******************************                                          16120000
TXTHLF   LA    ADDREG,1(ADDREG)                                         16140000
         N     ADDREG,HLFMSK            STRIP RIGHT BIT FROM ADDRESS    16160000
******************************                                          16180000
*  CHARACTER ALIGNMENT                                                  16200000
******************************                                          16220000
TXTCHR   ST    ADDREG,LOCSTR            SAVE ADDRESS OF TARGET AREA     16240000
         STH   CNTREG,HLFSTR            SAVE COUNT OF NUMBER OF BYTES   16260000
         ST    RETURN,HLDRG1            SAVE RETURN ADDRESS             16280000
CHRLOP   LA    SLVRG1,56                NUMBER OF BYTES TO GO OUT(MAYBE 16300000
         CLR   CNTREG,SLVRG1            IS COUNT LESS THAN 56           16320000
         BC    10,*+6                   NO                              16340000
         LR    SLVRG1,CNTREG            SET NUMBER OF REMAINING BYTES   16360000
         LR    SLVRG2,ADDREG                                            16380000
         SR    CNTREG,SLVRG1            DETERMINE REMAINING BYTES       16400000
         AR    ADDREG,SLVRG1            BUMP ADDRESS REGISTER           16420000
         BAL   RETURN,OUTEXT            LET OUTEXT DO THE REST OF WORK  16440000
         LTR   CNTREG,CNTREG            TEST FOR ANY MORE TEXT          16460000
         BC    2,CHRLOP                 SOME MORE REMAINING             16480000
         L     SRTPNT,LOCSTR            PICK UP TARGET ADDRESS          16500000
         LH    CNTREG,HLFSTR            RESTORE COUNT                   16520000
         L     RETURN,HLDRG1            RETURN TO THE CALLING ROUTINE   16540000
         BCR   15,RETURN                                                16560000
******************************                                          16580000
* OUTEXT  ROUTINE                                                       16600000
*                                                                       16620000
*        SLVRG1 CONTAINS NUMBER OF BYTES                                16640000
*        SLVRG2 CONTAINS TARGET ADDRESS                                 16660000
*        LOCREG CONTAINS FIELD ADDRESS                                  16680000
******************************                                          16700000
OUTEXT   STH   SLVRG1,HLFWRD            SET COUNT FOR MOVE              16720000
         ST    RETURN,OUTHLD            STORE RETURN                    16740000
         MVC   TXTLEN(2),HLFWRD         MOVE IN LENGTH OF TXT INFO      16760000
         ST    SLVRG2,FULLWD            SET FOR REDUCING TO             16780000
         MVC   TXTADD(3),FULLWD+1           24 BIT ADDRESS              16800000
         MVC   0(16,PUNREG),TXTIMG      MOVE IN FIRST 16 BYTES          16820000
         LR    SLVRG2,LOCREG                                            16840000
         AR    LOCREG,SLVRG1            BUMP LOCATION PTR REGISTER      16860000
         BCTR  SLVRG1,0                 REDUCE COUNT FOR EX OF MVC      16880000
         EX    SLVRG1,PUNMVC            MOVE TEXT INTO PUNCH BUFFER     16900000
         LA    REQSTR,PUNCOD            LINK TO INTERFACE TO OUTPUT     16920000
         BALR  RETURN,RQSTPT                THE TEXT CARD               16940000
         L     RETURN,OUTHLD                                            16960000
         BCR   15,RETURN                                                16980000
PUNMVC   MVC   16(0,PUNREG),0(SLVRG2)                                   17000000
DBLWRD   DS    D                                                        17020000
OUTHLD   DS    1F                                                       17040000
LOCSTR   DS    1F                                                       17060000
FULMSK   DC    X'FFFFFFFC'                                              17080000
HLFMSK   DC    X'FFFFFFFE'                                              17100000
HLDRG1   DS    F                                                        17120000
FULLWD   DS    F                                                        17140000
HLFWRD   DS    H                                                        17160000
HLFSTR   DS    H                                                        17180000
ADDMSK   DC    X'0FFF'                                                  17200000
TSTFLD   DS    CL1                                                      17220000
TXTIMG   DC    X'02'                                                    17240000
         DC    CL3'TXT'                                                 17260000
         DC    X'40'                                                    17280000
TXTADD   DS    CL3                                                      17300000
         DC    X'4040'                                                  17320000
TXTLEN   DS    CL2                                                      17340000
         DC    X'4040'                                                  17360000
TXTESD   DC    X'0001'                                                  17380000
         EJECT                                                          17400000
******************************                                          17420000
*                                                                       17440000
*   DUMMY TABLE ROUTINE                                                 17460000
*                                                                       17480000
******************************                                          17500000
TCDUMY   BCR   15,TCRTRN                LINK BACK DIRECTLY              17520000
******************************                                          17540000
*                                                                       17560000
*   DUMMY CHAINING ROUTINE                                              17580000
*                                                                       17600000
******************************                                          17620000
CCDUMY   MVI   INDHH0(DATBS1),X'F0'     TURN ON HALT INDICATOR 0        17640000
         MVI   288(DATBS1),X'02'        MOVE ERROR CODE FOR H0 INDIC.   17660000
         LR    1,0                      PICK UP CHAINING BLOCK POINTER  17680000
         SH    1,4(1)                   SET TO 1ST CHAIN FIELD REQUEST  17700000
         MVC   284(4,DATBS1),3(1)       POST IDENTIFIER FOR ERROR       17720000
         BCR   15,TCRTRN                                                17740000
******************************                                          17760000
         EJECT                                                          17780000
******************************                                          17800000
*                                                                       17820000
*  RAF ROUTINE FOR INDEXED SEQUENTIAL SUPPORT                           17840000
*                                                                       17860000
******************************                                          17880000
ICIORG   EQU   0                        USED FOR IORB ADDRESS FOR I/O   17900000
ICSLV1   EQU   1                        PARAMETER REGISTER              17920000
ICLINK   EQU   15                       SYSTEM LINKAGE REGISTER         17940000
ICRTRN   EQU   14                       SYSTEM RETURN REGISTER          17960000
ICDAT1   EQU   3                        FIRST DATA BASE REGISTER        17980000
ICDEOF   EQU   19                       DISPLACEMENT TO EOF TAG (IORB)  18000000
ICDPAR   EQU   4                        DISPLC TO PARLST ENTRY IN IORB  18020000
ICWRK1   EQU   12                       WORK REGISTER                   18040000
ICWRK2   EQU   13                       WORK REGISTER                   18060000
ICRLEN   EQU    8                       DISPLC TO REC LENGTH IN IORB    18080000
ICRECD   EQU   0                        DISPLC TO ADDR OF RECORD INPUT  18100000
ICDOIB   EQU   16                       DISP IN HOLD AREA TO ORG IORB   18120000
ICPRLT   EQU   4                        DISP IN IORB TO PARLIST ENTRY   18140000
ICPRTL   EQU   22                       IORB DISP.TO ISF WITH LIMITS SW 18160000
         CNOP  0,4                      FULL WORD ALIGN                 18180000
IC0000   BALR  ICLINK,0                                                 18200000
         USING *,ICLINK                                                 18220000
         STM   ICWRK1,ICSLV1,ICHOLD     STORE REGISTERS TO BE CLOBBERED 18240000
         BALR  ICWRK1,0                 SET UP A WORK REG AS BASE       18260000
         USING *,ICWRK1                                                 18280000
********************                                                    18300000
*   TEST  IF FIRST PASS                                                 18320000
********************                                                    18340000
         LR    ICWRK2,ICIORG            HOLD ADDRESS IN WORK REG        18360000
         CLI   ICPSWT,X'F0'             IS THIS THE FIRST PASS QQQ.     18380000
         BE    IC0750                    YES,BRANCH TO INITIALIZATION   18400000
********************                                                    18420000
*  TEST FOR PARTIAL PROCESSING END OF LIMIT                             18440000
********************                                                    18460000
IC0050   CLI   ICDEOF(ICWRK2),X'33'     IF END OF LIMIT,GET NEXT RECORD 18480000
         BE    IC0055                                                   18500000
         ST    14,ICRTRNSV              SAVE GIRC RETURN POINT          18520000
         CLI   ICPRTL(ICWRK2),C'L'                                      18540000
         BE    IC0275                                                   18560000
         CLI   14(ICWRK2),X'02'  TEST WHETHER THIS IS AN UPDATE CALL,   18580000
         BE    IC0275         IF SO RETURN.                             18600000
         B     IC0200                    BYPASS GET RECORD              18620000
IC0055   MVC   ICHOLD+8(4),ICRTRNSV     RESTORE RETURN TO GIRC          18640000
         MVI   ICDEOF(ICWRK2),X'00'     TURN OFF END OF LIMITS SWITCH   18660000
         B     IC0100                                                   18680000
********************                                                    18700000
*   SET UP RELOCATABLE ADDRESSES AND DETERMINE IORB ADDR FOR RAF FILE   18720000
********************                                                    18740000
IC0750   SR    ICIORG,ICIORG            COMPUTE THE DISPLACEMENT TO     18760000
         IC    ICIORG,ICFILE              THE IORB FOR THE RAF          18780000
         BCTR  ICIORG,0                   FILE FROM THE START OF THE    18800000
         MH    ICIORG,ICRBLN              IORB BLOCK                    18820000
         L     ICSLV1,LVIORB(DATBS1)    PICK UP ADDRESS OF IORB BLOCK   18840000
         AR    ICIORG,ICSLV1            COMPUTE ADDRESS                 18860000
         ST    ICIORG,ICIORB            STORE ADDRESS IN IORB PTR HOLD  18880000
         MVI   ICPSWT,X'00'             TURRN OFF FIRST PASS            18900000
********************                                                    18920000
*  GET RECORD FROM RECORD ADDRESS FILE                                  18940000
********************                                                    18960000
IC0100   L     ICIORG,ICIORB            PICK UP ADDRESS OF IORB         18980000
         LR    ICWRK2,ICIORG                                            19000000
         MVI   14(ICWRK2),X'00'         POST IORB COMMAND FOR READ      19020000
         L     ICLINK,IOROUT(DATBS1)    ADDRESS   I/O ROUTINE           19040000
         BALR  ICRTRN,ICLINK            LINK TO I/O ROUTINE             19060000
         MVC   15(4,ICWRK2),ICCNTL      SET CONTROL CODES IN IORB       19080000
         XC    ICPRCT(2),ICPRCT         ZERO COUNTER OF ENTRIES PROC    19140000
********************                                                    19160000
*  TEST FOR END OF FILE ON RAF                                          19180000
********************                                                    19200000
         CLI   ICDEOF(ICWRK2),X'22'     IS END OF FILE POSTED           19220000
         BE    IC0300                    YES,GO TO POST EOF IN IORB     19240000
********************                                                    19260000
*  FIND NEXT ENTRY TO PROCESS                                           19280000
********************                                                    19300000
IC0200   L     ICLINK,ICIORB            PICK UP ADDRESS OF IORB         19320000
         LH    ICSLV1,ICPRCT            PICK UP PROCESSING COUNT        19340000
         LA    ICSLV1,1(ICSLV1)                                         19360000
         STH   ICSLV1,ICPRCT                                            19380000
         MH    ICSLV1,ICKYLN            COMPUTE NUMBER OF BYTES USED    19400000
         CH    ICSLV1,ICRLEN(ICLINK)    HAS THIS RECORD BEEN COMPLETLY  19420000
*                                         PROCESSED QQ                  19440000
         BH    IC0100                   YES, GET NEXT RECORD            19460000
         SH    ICSLV1,ICKYLN            ADJUST DISPLACEMENT WITHIN RECD 19480000
         L     ICLINK,ICRECD(ICLINK)    PICK UP ADDRESS OF RECORD       19500000
         AR    ICLINK,ICSLV1            SET POINTER TO NEXT ENTRY       19520000
         ST    ICLINK,ICKEYF            STORE ADDRESS OF KEY IN PARLIST 19540000
*                                                                       19560000
*                                                                       19580000
********************                                                    19600000
*  TEST IF ENTRY IS BLANK                                               19620000
********************                                                    19640000
         LH    ICRTRN,ICKYLN            PICK UP ENTRY LENGTH            19660000
         BCTR  ICRTRN,0                 DECREMENT FOR EXECUTE AND       19680000
         BCTR  ICRTRN,0                   PREVIOUS TEST                 19700000
         CLI   0(ICLINK),X'40'          IS THE FIRST CHARACTER BLANK QQ 19720000
         BNE   IC0235                     NO,LET ENTRY BE PROCESSED     19740000
         LTR   ICRTRN,ICRTRN            WAS ENTRY ONE BYTE LONG    I222 19746000
         BM    IC0100                   YES, GET NEXT RECORD       I222 19752000
         EX    ICRTRN,ICCLC             TEST REST OF KEY FOR BLANK      19760000
         BE    IC0100                    ENTRY BLANK,GET NEXT RECORD    19780000
********************                                                    19800000
*  SET UP CONTD FIELD                                                   19820000
********************                                                    19840000
IC0235   L     ICSLV1,ICONTD            PICK UP ABS ADDRESS OF CONV     19860000
         AR    ICSLV1,ICDAT1            RELOCATION FACTOR ADDED ON      19880000
         LA    ICRTRN,1(ICRTRN)         BUMP COUNT FOR MOVE TO CONTD    19900000
         EX    ICRTRN,ICMVC             MOVE FIELD TO CONTD FIELD       19920000
********************                                                    19940000
*  SET FOR LINK TO I/O ROUTINE                                          19960000
********************                                                    19980000
         L     ICLINK,ICHOLD+ICDOIB     PICK UP ADDRESS OF ORIGINAL     20000000
*                                          IORB                         20020000
         LA    ICSLV1,ICKEYF            PICK UP PARLIST ADDRESS         20040000
         ST    ICSLV1,ICPRLT(ICLINK)    INSERT ADDRESS IN IORB          20060000
IC0275   LM    ICWRK1,ICSLV1,ICHOLD     PICK UP STORED REGISTERS        20080000
         L     ICLINK,IOROUT(DATBS1)    LET I/O HAVE CONTROL RETURN     20100000
         BCR   15,ICLINK                  WILL BE TO USER               20120000
********************                                                    20140000
*  END OF FILE HAS OCCURRED ON RECORD ADDRESS FILE                      20160000
********************                                                    20180000
IC0300   L     ICWRK2,ICHOLD+ICDOIB     PICK UP ADDRESS OF ORIGINAL     20200000
*                                          REQUEST BLOCK                20220000
         MVI   ICDEOF(ICWRK2),X'22'     POST EOF                        20240000
         LM    ICWRK1,ICSLV1,ICHOLD     RESTORE REGISTERS               20260000
         BCR   15,ICRTRN                                                20280000
ICONTD   DS    A(0)                     ABS ADDRESS OF CONTD FIELD      20300000
*                                          INSERTED PRIOR TO PUNCHING   20320000
ICHOLD   DS    6F                       STORAGE AREA FOR REGISTERS      20340000
ICRTRNSV DS    F                        SAVE AREA FOR RETURN REGISTER   20360000
ICIORB   DS    F                        ADDRESS OF RAF FILE IORB        20380000
ICKEYF   DS    F                                                        20400000
ICKYLN   DS    H                                                        20420000
ICRBLN   DC    AL2(IORBLN)              LENGTH OF IORB HALF WORD ALIGN  20440000
ICPRCT   DS    H                        NUMBER OF ENTRIES PROCESSED     20460000
*                                         FROM CURRENT RECORD           20480000
ICMVC    MVC   0(0,ICSLV1),0(ICLINK)                                    20500000
ICFILE   DS    CL1                      FILE NUMBER OF RAF FILE         20520000
ICPSWT   DC    X'F0'                    FIRST PASS SWITCH               20540000
ICCNTL   DC    X'00E3FF01'        IORB CONTROL BYTES               3369 20560015
ICCLC    CLC   1(0,ICLINK),0(ICLINK)                                    20580000
         EJECT                                                          20600000
******************************                                          20620000
*                                                                       20640000
*    ROUTINE TO SUPPORT TAG SORT OPTION                                 20660000
*                                                                       20680000
*        ADROUT FILE CONTAINS THE IDENTIFING INFORMATION REQUIRED       20700000
*              TO READ THE PARENT FILE                                  20720000
*                                                                       20740000
******************************                                          20760000
********************                                                    20780000
*                                                                       20800000
*  ABOSLUTE TRACK FORMAT FOR 2311                                       20820000
*                BYTE  1    DEVICE DESIGNATION(INSERTED BY I/O ROUTINE) 20840000
*                     2-4   ZERO FOR 2311,WILL BE USED FOR 2321         20860000
*                      5    0-202,CYLINDER NUMBER                       20880000
*                      6    ZERO FOR 2311,WILL BE USED FOR 2321         20900000
*                      7    0-9,TRACK NUMBER                            20920000
********************                                                    20940000
*                                                                       20960000
*  ID FIELD                                                             20980000
*                BYTE  1    0-255,  RECORD IDENTIFICATION               21000000
*                     2,3   DISPLACEMENT TO THE POINT WHERE THE RECORD  21020000
*                             ACTUALLY BEGINS,NOT CONTROL INFORMATION   21040000
*                             SUCH AS BLOCK LENGTH OR RECORD LENGTH     21060000
*                             INFORMATION                               21080000
********************                                                    21100000
*  ADROUT INPUT FORMAT                                                  21120000
*         BYTE 1  PACK NUMBER                                           21140000
*            2,3  BIN NUMBER                                            21160000
*            4,5  CYLINDER NUMBER                                       21180000
*            6,7  HEAD NUMBER                                           21200000
*              8  NUMBER OF THE RECORD ON THE TRACK                     21220000
*           9,10  =00 FOR UNBLOCKED FIXED LENGTH RECORDS OR DISPLACE-   21240000
*                          MENT IN BYTES IF FIXED LENGTH BLOCKED        21260000
*                 =04 FOR UNBLOCKED VARIABLE-LENGTH RECORDS,OR THE      21280000
*                     DISPLACEMENT WITHIN THE BLOCK FOR BLOCKED         21300000
*                     VARIABLE RECORDS(DISPLACEMENT TO RECORD LENGTH    21320000
*                     WORD)                                             21340000
*                                                                       21360000
********************                                                    21380000
ACIORG   EQU   0                        INPUT/OUTPUT REGISTER           21400000
ACSLV1   EQU   1                        PARAMETER REGISTER              21420000
ACWRK1   EQU   12                       WORK REGISTER                   21440000
ACWRK2   EQU   13                       WORK REGISTER                   21460000
ACLINK   EQU   15                       SYSTEM LINKAGE REGISTER         21480000
ACRTRN   EQU   14                       SYSTEM RETURN REGISTER          21500000
ACDAT1   EQU   3                        FIRST DATA BASE REGISTER        21520000
ACRLEN   EQU   8                        DISPLACEMENT TO REC LEN IN IORB 21540000
ACRECD   EQU   0                        DISPLACE TO ADDRESS OF RECORD   21560000
ACDIOB   EQU   16                       DISPLACE TO ORG IORB IN HOLD    21580000
ACDEOF   EQU   19                       DISPLACEMENT TO EOF FLAG        21600000
ACPRLT   EQU   4                        DISPLACE TO PARLIST ADDR (IORB) 21620000
         CNOP  0,4                      FULL WORD ALIGN                 21640000
AC0000   BALR  ACLINK,0                 CLOBBER LINK REG FOR TEMP BASE  21660000
         USING *,ACLINK                                                 21680000
         STM   ACWRK1,ACSLV1,ACHOLD     STORE REGISTERS IN HOLD AREA    21700000
         BALR  ACWRK1,0                 PICK UP NEW BASE(TO FREE        21720000
         USING *,ACWRK1                    LINKAGE REGISTER)            21740000
********************                                                    21760000
*  TEST FOR FIRST PASS                                                  21780000
********************                                                    21800000
         CLI   ACPSWT,X'F0'             IS THIS THE FIRST PASS,QQ.      21820000
         BNE   AC0100                    NO, LINK TO PROCESS RECORD     21840000
********************                                                    21860000
*  SET UP RELOCATABLE ADDRESSES AND ADDRESS OF IORB FOR ADROUT FILE     21880000
********************                                                    21900000
         LR    ACSLV1,ACIORG                                            21920000
         MVC   ACIOAREA,ACRECD(ACSLV1)  SAVE I/O BUFFER ADDRESS         21940000
         SR    ACIORG,ACIORG            ZERO REGISTER                   21960000
         IC    ACIORG,ACFILE            PICK UP FILE NUMBER             21980000
         BCTR  ACIORG,0                 DECREMENT COUNT FOR COMPUTING   22000000
         MH    ACIORG,ACRBLN            MULTIPLY BY LENGTH OF IORB      22020000
         L     ACSLV1,LVIORB(ACDAT1)    PICK UP ADDRESS OF IORB BLOCK   22040000
         AR    ACSLV1,ACIORG            COMPUTE ADDR OF THIS IORB       22060000
         ST    ACSLV1,ACIORB            STORE IN IORB POINTER HOLD      22080000
         MVI   ACPSWT,X'00'             TURN OFF FIRST PASS SWITCH      22100000
********************                                                    22120000
*  GET ADROUT RECORD FROM INPUT FILE                                    22140000
********************                                                    22160000
AC0050   L     ACIORG,ACIORB            PICK UP IORB ADDRESS FOR ADROUT 22180000
         LR    ACWRK2,ACIORG                                            22200000
         MVI   14(ACWRK2),X'00'         POST FOR READ                   22220000
         L     ACLINK,IOROUT(ACDAT1)    ADDRESS OF INPUT/OUTPUT ROUTINE 22240000
         BALR  ACRTRN,ACLINK            LET I/O ROUTINE DO THE WORK     22260000
         MVC   15(4,ACWRK2),ACIOCNTL   MOVE CONTROL BYTES TO IORB  3369 22290015
         XC    ACPRCT(2),ACPRCT         ZERO PROCESSING COUNTER         22320000
********************                                                    22340000
*  TEST IF END OF FILE HAS BEEN ENCOUNTERED ON ADDROUT                  22360000
********************                                                    22380000
         CLI   ACDEOF(ACWRK2),X'22'     END OF FILE ENCOUNTERED  QQQ.   22400000
         BE    AC0200                    YES,BRANCH TO END OF FILE ROUT 22420000
********************                                                    22440000
*  PICK UP NEXT ENTRY FROM THIS RECORD                                  22460000
********************                                                    22480000
AC0100   L     ACLINK,ACIORB            PICK UP ADDRESS OF IORB         22500000
         LH    ACSLV1,ACPRCT            PICK UP PROCESSING COUNT        22520000
         LA    ACSLV1,1(ACSLV1)         UPDATE PROCESSING COUNT         22540000
         STH   ACSLV1,ACPRCT            STORE UPDATE COUNT FOR NEXT PSS 22560000
         MH    ACSLV1,ACKYLN            COMPUTE NUMBER OF BYTES USED    22580000
         CH    ACSLV1,ACRLEN(ACLINK)    HAS THIS RECORD BEEN COMPLETELY 22600000
*                                          PROCESSED  QQQ.              22620000
         BH    AC0050                   YES, BRANCH TO GET NEXT RECORD  22640000
         SH    ACSLV1,ACKYLN                                            22660000
********************                                                    22680000
*  TEST IF ENTRY IS BLANK                                               22700000
********************                                                    22720000
         L     ACIORG,ACRECD(ACLINK)    PICK UP ADDRESS OF RECORD       22740000
         AR    ACSLV1,ACIORG            SET POINTER TO NEXT ENTRY       22760000
         CLC   0(8,ACSLV1),ACBLNK       IS THE ENTRY BLANK              22780000
         BE    AC0050                    YES,READ NEXT RECORD           22800000
********************                                                    22820000
*  SET ADDRESS FOR LINK TO FLO ROUTINE WITH ORIGINAL I/RB               22840000
********************                                                    22860000
         MVC   ACFULL+2(2),8(ACSLV1)    PICK UP DISPLACEMENT            22880000
         SR    ACSLV1,ACDAT1            REMOVE RELOCATION FACTOR        22900000
         ST    ACSLV1,ACABAD            STORE SEEK ADDRESS LOCATION     22920000
         L     ACSLV1,ACIOAREA          PICK UP BUFFER ADDRESS          22940000
         A     ACSLV1,ACFULL            ADD ON DISPLACEMENT             22960000
         AH    ACSLV1,ACFIXVAR          ADJUST FOR VARIABLE LENGTH      22980000
********************                                                    23000000
*   LINK  TO I/O ROUTINE                                                23020000
********************                                                    23040000
         L     ACLINK,ACHOLD+ACDIOB     PICK UP ADDRESS OF ORIGINAL     23060000
*                                          INPUT/OUTPUT REQUEST BLOCK   23080000
         ST    ACSLV1,ACRECD(ACLINK)                                    23100000
         LA    ACSLV1,ACABAD            PICK UP ADDRESS OF PARLIST      23120000
         ST    ACSLV1,ACPRLT(ACLINK)    STORE PARLIST ADDR IN IORB      23140000
AC0185   LM    ACWRK1,ACSLV1,ACHOLD     PICK UP STORED REGISTERS        23160000
         L     ACLINK,IOROUT(ACDAT1)    LET I/O ROUTINE HAVE CONTROL,   23180000
         BCR   15,ACLINK                  RETURN WILL BE TO USER        23200000
********************                                                    23220000
*  END OF FILE HAS OCURRED ON ADROUT                                    23240000
********************                                                    23260000
AC0200   L     ACWRK2,ACHOLD+ACDIOB     PICK UP ADDRESS OF ORIGINAL     23280000
*                                          REQUEST BLOCK                23300000
         MVI   ACDEOF(ACWRK2),X'22'     POST EOF FOR REQUESTING FILE    23320000
         LM    ACWRK1,ACSLV1,ACHOLD     PICK UP STORED REGISTERS        23340000
         BCR   15,ACRTRN                RETURN TO THE USER              23360000
ACHOLD   DS    6F                       REGISTER HOLD AREA              23380000
ACIORB   DS    F                        STORAGE FOR IORB ADDRESS        23400000
ACIOAREA DS    F                        I/O BUFFER ADDRESS HOLD AREA    23420000
ACFULL   DC    F'0'                     FULL WORD WORK AREA             23440000
ACABAD   DC    F'0'                     ADDRESS OF ABSOLUTE TRACK       23460000
ACIDAD   DC    F'0'                     ADDRESS OF ID FLD               23480000
ACABLN   DC    H'8'                     LENGTH OF ABSOLUTE TRACK FIELD  23500000
ACIDLN   DC    H'0'                     LENGTH OF ID FIELD              23520000
ACRBLN   DC    AL2(IORBLN)              LENGTH OF IORB*HALF ALIGNED*    23540000
ACPRCT   DS    H                        COUNT OF ENTRIES PROCESSED      23560000
ACFIXVAR DC    H'0'                     =0  FOR FIXED LENGTH RECORDS   X23580000
                                        =4  FOR VARIABLE RECORDS        23600000
ACKYLN   DC    H'10'                    LENGTH OF ADROUT ENTRY          23620000
ACPSWT   DC    X'F0'                    FIRST PASS SWITCH               23640000
ACFILE   DS    CL1                      ADROUT FILE NUMBER              23660000
ACBLNK   DC    8CL1' '                  BLANKS FOR TEST                 23680000
ACIOCNTL DC    X'00E3FF01'        IORB CONTROL BYTES               3369 23700015
ACEND    DS    0C                                                       23720000
*        END   ADROUT SUPPORT ROUTINE                                   23740000
         EJECT                                                          23760000
******************************                                          23780000
*                                                                       23800000
*  RECORD  ADDRESS FILE SUPPORT FOR DIRECT ORGANIZATION                 23820000
*                                                                       23840000
******************************                                          23860000
*                                                                       23880000
*   THIS FORM OF ACESS MUST HAVE A CONVERSION ROUTINE*                  23900000
*                                                                       23920000
********************                                                    23940000
DCIORG   EQU   0                        INPUT/OUTPUT PARAMETER REGISTER 23960000
DCSLV1   EQU   1                        PARAMETER REGISTER              23980000
DCSLV2   EQU   11                       USED IN MULTIPLE STORE AND LOAD 24000000
DCLINK   EQU   15                       SYSTEM LINKAGE REGISTER         24020000
DCRTRN   EQU   14                       SYSTEM RETURN REGISTER          24040000
DCDEOF   EQU   19                       DISPLACEMENT TO EOF             24060000
DCDPAR   EQU   4                        DISPLACEMENT TO PAR LIST ENTRY  24080000
DCWRK1   EQU   12                       WORK REGISTER                   24100000
DCWRK2   EQU   13                       WORK REGISTER                   24120000
DCRLEN   EQU   8                        DISPLACEMENT TO RECORD LENGTH   24140000
DCRECD   EQU   0                        DISPLACEMENT TO ADDR OF RECORD  24160000
DCDIOB   EQU   16                       DISP IN HOLD AREA TO ORIG IORB  24180000
DCPRLT   EQU   4                        DISP TO PARLIST ADDRESS         24200000
DCDAT1   EQU   3                        FIRST DATA BASE REGISTER        24220000
         CNOP  0,4                      FULL WORD ALIGN                 24240000
DC0000   BALR  DCLINK,0                 SET UP LINKAGE REGISTER         24260000
         USING *,DCLINK                    AS TEMPORARY BASE            24280000
         STM   DCWRK1,DCSLV2,DCHOLD     STORE REGISTERS TO BE USED      24300000
         BALR  DCWRK1,0                 PICK UP ROUTINE BASE REGISTER   24320000
         USING *,DCWRK1                    AND  ASSIGN VALUE            24340000
********************                                                    24360000
*  TEST FOR FIRST PASS                                                  24380000
********************                                                    24400000
         CLI   DCPSWT,X'F0'             IS FIRST PASS ON,QQQ.           24420000
         BNE   DC0200                     NO,BEGIN PROCESSING           24440000
********************                                                    24460000
*  INITIALIZATION OF IORB                                               24480000
********************                                                    24500000
         MVI   DCPSWT,X'00'             TURN OFF FIRST PASS SWITCH      24520000
         SR    DCIORG,DCIORG            PICK UP FILE NUMBER FOR         24540000
         IC    DCIORG,DCFILE              COMPUTATION OF IORB ADDRESS   24560000
         BCTR  DCIORG,0                 DECREMENT FILE NUMBER           24580000
         MH    DCIORG,DCWKLN            COMPUTE DISPC                   24600000
         L     DCSLV1,LVIORB(DCDAT1)    ADDRESS OF IORB BLOCK           24620000
         AR    DCIORG,DCSLV1            COMPUTE ADDRESS FOR THIS IORB   24640000
         ST    DCIORG,DCIORB            STORE ADDRESS IN IORB PTR HOLD  24660000
********************                                                    24680000
*  GET RECORD FROM INPUT FILE                                           24700000
********************                                                    24720000
DC0100   L     DCIORG,DCIORB            PICK UP IORB ADDRESS FOR ADROUT 24740000
         LR    DCWRK2,DCIORG                                            24760000
         MVI   14(DCWRK2),X'00'         POST IORB COMMAND FOR READ      24780000
         L     DCLINK,IOROUT(DCDAT1)    ADDRESS OF INPUT/OUTPUT ROUTINE 24800000
         BALR  DCRTRN,DCLINK            LET I/O HAVE CONTROL            24820000
         MVC   15(4,DCWRK2),DCCNTL      SET CONTROL CODES IN IORB       24840000
         XC    DCPRCT(2),DCPRCT         ZERO COUNTER OF ENTRIES PROC.   24900000
********************                                                    24920000
*  TEST IF END OF FILE HAS BEEN ENCOUNTERED ON RAF                      24940000
********************                                                    24960000
         CLI   DCDEOF(DCWRK2),X'22'     HAS EOF INDICATION BEEN TURNED  24980000
*                                         ON,QQQ.                       25000000
         BE    DC0300                   YES,BRANCH TO EOF ROUTINE       25020000
         XC    DCPRCT(2),DCPRCT         ZERO PROCESSING COUNTER         25040000
********************                                                    25060000
*  PICK UP NEXT ENTRY TO BE PROCESSED                                   25080000
********************                                                    25100000
DC0200   L     DCLINK,DCIORB            PICK UP ADDRESS OF IORB         25120000
         LR    DCWRK2,DCIORG                                            25140000
         CLI   14(DCWRK2),X'02'         TEST FOR AN UPDATE CALL         25160000
         BE    DC0265                   IF SO BRANCH TO RETURN          25180000
         LH    DCSLV1,DCPRCT            PICK UP PROCESSING COUNT        25200000
         LA    DCSLV1,1(DCSLV1)         BUMP PROCESS COUNT BY 1         25220000
         STH   DCSLV1,DCPRCT            STORE UPDATED COUNT             25240000
         MH    DCSLV1,DCRBLN            COMPUTE AMOUNT OF RECORD USED   25260000
         CH    DCSLV1,DCRLEN(DCLINK)    TEST IF ALL ENTRIES PROCESSED   25280000
         BH    DC0100                   YES GET ANOTHER RECORD          25300000
         SH    DCSLV1,DCRBLN            ADJUST   DISPLACEMENT WITHIN    25320000
*                                         RECORD                        25340000
********************                                                    25360000
*  TEST IF ENTRY IS BLANK                                               25380000
********************                                                    25400000
         L     DCLINK,DCRECD(DCLINK)    PICK UP ADDRESS OF INPUT RECORD 25420000
         AR    DCLINK,DCSLV1            ADD ON DISPLACEMENT             25440000
         LH    DCRTRN,DCRBLN            PICK UP LENGTH OF THE ENTRY     25460000
         BCTR  DCRTRN,0                 MODIFY COUNT TO TEST REST OF    25480000
         BCTR  DCRTRN,0                   FIELD FOR BLANKS              25500000
         CLI   0(DCLINK),X'40'          IS THE FIRST CHARACTER BLANK QQ 25520000
         BNE   DC0235                     NO,START PROCESSING           25540000
         LTR   DCRTRN,DCRTRN            WAS ENTRY ONE BYTE LONG    I222 25546000
         BM    DC0100                   YES, GET ANOTHER ENTRY     I222 25552000
         EX    DCRTRN,DCCLC             TEST REST OF FIELD FOR BLANKS   25560000
         BE    DC0100                     YES,GET ANOTHER ENTRY         25580000
********************                                                    25600000
*  SET UP CONTD FIELD                                                   25620000
********************                                                    25640000
DC0235   L     DCSLV1,DCONTD            PICK UP ABS ADDRESS OF CONV     25660000
         AR    DCSLV1,DCDAT1            RELOCATION FACTOR ADDED ON      25680000
         LA    DCRTRN,1(DCRTRN)         BUMP COUNT FOR MOVE TO CONTD    25700000
         EX    DCRTRN,DCMVC             MOVE FIELD TO CONTD FIELD       25720000
********************                                                    25740000
*  LINK TO CONVERSION ROUTINE                                           25760000
********************                                                    25780000
         L     DCWRK2,DCHOLD+DCDIOB     PICK UP ADDRESS OF ORG IORB     25800000
         L     DCLINK,DCCONV            PICK UP ABS ADDRESS OF CONV PTR 25820000
         AR    DCLINK,DCDAT1            RELOCATE PTR ADDRESS            25840000
         L     DCLINK,0(DCLINK)         ADDRESS OF CONVERSION LINK PNT  25860000
         AR    DCLINK,DCDAT1            RELOCATE THE LINK POINTER       25880000
         ST    DCLINK,DCPRLT(DCWRK2)    STORE PARLIST ADDRESS IN IORB   25900000
         BAL   DCRTRN,12(DCLINK)        BRANCH TO CONVERSION LINK POINT 25920000
********************                                                    25940000
*  SET TO READ ORIGINAL I/O REQUEST                                     25960000
********************                                                    25980000
DC0265   BALR  DCWRK1,0                 SET BASE REGISTER FORR EXIT     26000000
         USING *,DCWRK1                                                 26020000
         LM    DCWRK1,DCSLV2,DCHOLD     PICK UP STORED REG CONTENTS     26040000
         L     DCLINK,IOROUT(DCDAT1)    PICK UP ADDRESS OF I/O ROUTINE  26060000
         BCR   15,DCLINK                LET I/O HAVE CONTROL,WITH       26080000
*                                          RETURN TO ROUTINE WITH       26100000
*                                          ORIGINAL REQUEST             26120000
********************                                                    26140000
*  END OF FILE HAS OCURRED ON RAF,POST EOF IN ORIG IORB                 26160000
********************                                                    26180000
DC0300   BALR  DCWRK1,0                 SET BSE TO RESTRE REGS FOR EXIT 26200000
         USING *,DCWRK1                                                 26220000
         L     DCWRK2,DCHOLD+DCDIOB                                     26240000
         MVI   DCDEOF(DCWRK2),X'22'     POST EOF FOR REQUESTING FILE    26260000
         LM    DCWRK1,DCSLV2,DCHOLD     PICK UP STORED REGISTERS        26280000
         BCR   15,DCRTRN                RETURN TO REQUESTOR             26300000
DCONTD   DS    A(0)                     ABS ADDRESS OF CONTD FIELD      26320000
*                                          INSERTED PRIOR TO PUNCHING   26340000
DCHOLD   DS    16F                      STORAGE FOR REGISTERS           26360000
DCIORB   DS    F                        RAF IORB ADDRESS HOLD           26380000
DCCONV   DS    A(0)                     ABS ADDRESS OF POINTER          26400000
*                                         TO CONVERSION ROUTINE         26420000
DCWKLN   DC    AL2(IORBLN)              LENGTH OF AN IORB BLOCK         26440000
DCPRCT   DS    H                                                        26460000
DCRBLN   DS    H                        LENGTH OF AN ENTRY IN A RECORD  26480000
DCFILE   DS    CL1                      FILE NUMBER                     26500000
DCPSWT   DC    X'F0'                    FIRST PASS SWITCH               26520000
DCCNTL   DC    X'00E3FF01'        IORB CONTROL BYTES               3369 26540015
DCCLC    CLC   1(0,DCLINK),0(DCLINK)                                    26560000
DCMVC    MVC   0(0,DCSLV1),0(DCLINK)                                    26580000
*        END   DIRECT ACCESS RAF SUPPORT WITH CONVERSION                26600000
         EJECT                                                          26620000
******************************                                          26640000
*                                                                       26660000
*   CHAINING LOGIC FOR USER                                             26680000
*                                                                       26700000
******************************                                          26720000
CHNRQT   EQU   0                        REGISTER WITH CHAIN BLOCK ADDR  26740000
CCSLV1   EQU   1                        TEMPORARY WORK REGISTER         26760000
CCSLV2   EQU   2                        TEMPORARY WORK REGISTER         26780000
CCBASE   EQU   8                        ROUTINE BASE REGISTER           26800000
CCLINK   EQU   15                       LINK REGISTER                   26820000
CCRTRN   EQU   14                       RETURN REGISTER                 26840000
CCWRK4   EQU   12                       WORK REGISTER                   26860000
CCWRK1   EQU   9                        WORK REGISTER                   26880000
CCWRK2   EQU   10                       WORK REGISTER                   26900000
CCWRK3   EQU   11                       WORK REGISTER                   26920000
********************                                                    26940000
*   DISPLACEMENTS IN CHAINING REQUEST ENTRIES                           26960000
********************                                                    26980000
CCDPRO   EQU   0                        PROCESSED BYTE                  27000000
CCDFRM   EQU   1                        FROM FILE                       27020000
CCDSEQ   EQU   2                        RECORD SEQUENCE                 27040000
CCNUMB   EQU   4                        CHAINING NUMBER                 27060000
CCLENG   EQU   5                        LENGTH BYTE                     27080000
CCADDR   EQU   6                        BDDD ADDRESS                    27100000
CCRFAC   EQU   8                        RELOCATION FACTOR ADDRESS       27120000
CCOVFL   EQU   0                        BDD OVERFLOW CODE               27140000
********************                                                    27160000
*   PROCESSING EQUATES                                                  27180000
********************                                                    27200000
CCPRSD   EQU   X'F0'                    PROCESSED BIT CONFIG FOR TM     27220000
CCPARL   EQU   4                        DISPLC IN IORB TO PAR LIST ADDR 27240000
******************************                                          27260000
*   ROUTINE START                                                       27280000
******************************                                          27300000
         CNOP  0,4                      FULL WORD ALIGN                 27320000
CHNSTR   BALR  CCBASE,0                 SET AND DEFINE BASE REGISTER    27340000
         USING *,CCBASE                                                 27360000
********************                                                    27380000
*   DETERMINE WHERE TO GO                                               27400000
********************                                                    27420000
CCOUNT   SR    CCSLV1,CCSLV1            ZERO COMPUTATIONAL REGISTER     27440000
         IC    CCSLV1,CCPROS            PICK UP PROCESSING CODE         27460000
         LH    CCSLV1,CCTABL(CCSLV1)    PICK UP DISPLACEMENT FOR ENTRY  27480000
         B     0(CCSLV1,CCBASE)         COMPUTE ENTRY POINT             27500000
CCTABL   DC    AL2(CCPAS1-CCOUNT)       FIRST CASE ENTRY                27520000
         DC    AL2(CCPREM-CCOUNT)       PRE-EMPTED SITUATION            27540000
         DC    AL2(CCRENT-CCOUNT)       RE-ENTRY OF PREVIOUS BLOCK      27560000
         DC    AL2(CCONTU-CCOUNT)       CONTINUE PROCESSING THIS BLOCK  27580000
********************                                                    27600000
*   FIRST PASS                                                          27620000
********************                                                    27640000
CCPAS1   STM   0,15,CCHOLD              SAVE ALL REGISTERS              27660000
         XC    CCSTOR(4),CCSTOR         ZERO STORAGE AREA               27680000
********************                                                    27700000
*   INTERUPT OF CHAIN HAS OCCURRED                                      27720000
********************                                                    27740000
CCPREM   LR    CCWRK1,CHNRQT            PICK UP CHAINING REQUEST START  27760000
         MVC   0(4,CCWRK1),CCSTOR       SET ADDRESS AREA FOR CASCADING  27780000
         ST    CHNRQT,CCSTOR            SAVE ADDRESS OF CURRENT BLOCK   27800000
         BC    15,CCONTU                LET PROCESSING BEGIN            27820000
********************                                                    27840000
*   RE-ENTRY TO A PREVIOUS BLOCK                                        27860000
********************                                                    27880000
CCRENT   MVC   CCIBLK,0(CCWRK1)         PICK UP INTERUPTED BLOCK        27900000
         L     CCWRK1,CCIBLK                                            27920000
         ST    CCWRK1,CCSTOR            SAVE ADDRESS OF CURRENT BLOCK   27940000
********************                                                    27960000
*   BEGIN PROCESSING OF REQUEST ENTRIES                                 27980000
********************                                                    28000000
CCONTU   MVI   CCPROS,X'02'             SET TO DETECT IF PRE-EMPTED     28020000
         L     CCSLV1,LVWORK(DATBS1)                                    28040000
         LA    CCSLV1,256(CCSLV1)                                       28060000
         ST    CCSLV1,CCIDBGN                                           28080000
         XC    CCKYLN,CCKYLN            ZERO MOVE COUNTER CONTROL       28100000
********************                                                    28120000
*   PICK UP FIRST ENTRY ADDRESS                                         28140000
********************                                                    28160000
         LR    CCWRK2,CCWRK1            PICK UP STARTING OF CHAIN       28180000
         SH    CCWRK2,4(CCWRK1)         SUBTRACT FACTOR TO DETEMINE     28200000
*                                         FIRST ENTRY                   28220000
         LA    CCWRK2,2(CCWRK2)         SPACE OVER COMPILER FLAG        28240000
********************                                                    28260000
*   TEST IF ENTRY HAS BEEN PROCESSED                                    28280000
********************                                                    28300000
CCTEST   TM    0(CCWRK2),X'F0'          HAS ENTRY BEEN PROCESSED        28320000
         BC    1,CCLAST                   YES,TEST IF LAST ENTRY        28340000
********************                                                    28360000
*  TEST IF A NON-PROCESSED ENTRY REQUEST HAS ALREADY BEEN ENCOUNTERED   28380000
********************                                                    28400000
         CLI   CCFOND,X'F0'             IF PREVIOUS NON-PROCESSED ENTRY 28420000
         BE    CCSPLT                     ENCOUNTERED,TEST FOR SPLIT    28440000
*                                         FIELDS                        28460000
********************                                                    28480000
*   SET UP KEY FIELD   FOR  SPLIT CHAINING FIELD SUPPORT                28500000
********************                                                    28520000
         MVC   CCKYAR(4),CCDFRM(CCWRK2)  PICK UP KEY FIELD              28540000
         MVI   CCFOND,X'F0'             TURN FOUND SWITCH ON            28560000
         BC    15,CCBILD                BRANCH TO BUILD KEY FIELD       28580000
********************                                                    28600000
*   TEST IF A SPLIT CHAINING FIELD HAS BEEN ENCOUNTED                   28620000
********************                                                    28640000
CCSPLT   CLC   CCKYAR(4),CCDFRM(CCWRK2)  HAS SPLIT OCCURRED QQ.         28660000
         BNE   CCLAST                     NO,TEST FOR LAST ENTRY        28680000
********************                                                    28700000
*   MOVE FIELD INTO WORK AREA                                           28720000
********************                                                    28740000
***************                                                         28760000
*  BDDD,OVERFLOW CONVERSION ROUTINE FOR CHAINING                        28780000
***************                                                         28800000
*              CCWRK2   POINTS TO CHAINING REQUEST ENTRY                28820000
*              CCSLV1   RETURNS WITH ADDRESS AS COMPUTED                28840000
*              CCSLV2   USED AS WORK REGISTER                           28860000
CCBILD   MVC   CCADC1+2(2),CCADDR(CCWRK2)  SET BDDD INTO NEXT INSTRUCT  28880000
CCADC1   LA    CCSLV1,0(0)                    FOR ADDRESS COMPUTATION   28900000
         SR    CCSLV2,CCSLV2               ZERO SLAVE REGISTER          28920000
         IC    CCSLV2,CCOVFL(CCWRK2)       PICK UP OVERFLOW             28940000
         SLL   CCSLV2,12                   MULTIPLY BY 4096             28960000
         AR    CCSLV1,CCSLV2               DETERMINE ADDRESS            28980000
***************                                                         29000000
*  PICK UP LENGTH FOR MOVE                                              29020000
***************                                                         29040000
         SR    CCSLV2,CCSLV2            ZERO REGISTER BEFORE PICKING    29060000
         IC    CCSLV2,CCLENG(CCWRK2)    UP LENGTH-1 FOR REQUEST ENTRY   29080000
         L     CCWRK3,CCIDBGN                                           29100000
         SR    CCWRK3,CCSLV2                                            29120000
         BCTR  CCWRK3,0                 DECREMENT SINCE L-1 USED        29140000
         ST    CCWRK3,CCIDBGN                                           29160000
***************                                                         29180000
*  MOVE INTO WORK AREA                                                  29200000
***************                                                         29220000
         EX    CCSLV2,CCMVC                                             29240000
***************                                                         29260000
         LH    CCSLV1,CCKYLN            STORE UPDATED LENGTH COUNT      29280000
         LA    CCSLV1,1(CCSLV1,CCSLV2)                                  29300000
         STH   CCSLV1,CCKYLN                                            29320000
         OI    CCDPRO(CCWRK2),X'F0'     TURN ON PROCESSED BITS          29340000
***************                                                         29360000
*  TEST IF THIS WAS LAST CHAINING REQUEST ENTRY                         29380000
***************                                                         29400000
CCLAST   LH    CCSLV1,CCRFAC(CCWRK2)    PICK UP RELATIVE FACTOR         29420000
         SR    CCWRK2,CCSLV1            DETERMINE NEXT ENTRY            29440000
         LTR   CCSLV1,CCSLV1            TEST IF END OF ENTRY STRING     29460000
         BC    7,CCTEST                 NOT END,CONTINUE ON AND UPWARD  29480000
***************                                                         29500000
*  TEST IF AN ENTRY WAS FOUND                                           29520000
***************                                                         29540000
CCLTPS   CLI   CCFOND,X'F0'             WAS AN ENTRY FOUND TO PROCESS   29560000
         BE    CCFDOF                     YES,START PREP FOR READ       29580000
***************                                                         29600000
*  TEST IF PROCESSING ORIGINAL BLOCK                                    29620000
***************                                                         29640000
         MVC   CCIBLK,0(CCWRK1)         PICK UP PRE-EMPTED ADDRESS      29660000
         L     CCSLV1,CCIBLK                                            29680000
         LTR   CCSLV1,CCSLV1            SET CONDITION CODE              29700000
         BZ    CCDONE              NO PRE-EXMP ADDRESS,FINISHED  A26410 29720019
         MVI   CCPROS,X'04'             SET FOR RE-ENTRY                29740000
         BCR   15,CCBASE                                                29760000
***************                                                         29780000
*  WIND UP OF THIS CHAINING REQUEST                                     29800000
***************                                                         29820000
CCDONE   CLI   CCH0SAVE,X'F0'      H0 IND SET ON DURNING CHAIN   A26410 29826019
         BE    CCEROR2             YES, GO TURN ON H0            A26410 29832019
CCTHRU   MVI   CCFOND,X'00'             RE-INITIALIZE FOUND SWITCH      29840000
         MVI   CCPROS,X'00'             RE-INIT PROCESS CODE SWITCH     29860000
         LM    0,15,CCHOLD              RESTORE ALL REGISTERS TO RETURN 29880000
         BCR   15,CCRTRN                ONWARD AND UPWARD WITH VALOR    29900000
***************                                                         29920000
*  A CHAINING FIELD HAS BEEN BUILT,NOW SET TO PROCESS FOR LINK TO I/O   29940000
***************                                                         29960000
CCFDOF   MVI   CCFOND,X'00'             TURN OFF FOUND SWITCH           29980000
*  TEST IF LEGAL ENTRY HAS BEEN ENCOUNTERED                             30000000
***************                                                         30020000
         LA    CCWRK2,TSTABL            PICK UP BEGINNING OF TABLE OF   30040000
*                                          ACCEPTABLE CHAINING REQUESTS 30060000
CCTSLP   CLI   0(CCWRK2),X'FF'          END OF TABLE QQQ.               30080000
         BE    CCEROR                   ERROR HAS OCCURRED,TO BAD CHRLY 30100000
         CLC   CDSFRM(4,CCWRK2),CCKYAR  IS THIS THE CORRECT TO FILE     30120000
         BE    CCNVTS                   YES,BRANCH TO TEST FOR CONV     30140000
         LA    CCWRK2,CENTRY(CCWRK2)    INCREMENT POINTER IN TABLE      30160000
         BC    15,CCTSLP                TRY NEXT ENTRY                  30180000
***************                                                         30200000
*  CONVERSION ROUTINE TEST AND LINK                                     30220000
***************                                                         30240000
CCNVTS   MVC   CCPRLT+1(3),CDSCNV(CCWRK2)  ALIGN CONVERSION ADDRESS     30260000
         L     CCLINK,CCPRLT            PICK UP CONVERSION ADDRESS      30280000
         LTR   CCLINK,CCLINK            SET CONDITION CODE              30300000
         BC    8,CCISEQ                 NO CONVERSION,INDEXED SEQUENTL  30320000
         L     CCLINK,0(CCLINK,DATBS1)  PICK UP LINK POINT TO CONVERT   30340000
         AR    CCLINK,DATBS1            ADD ON RELOCATION FACTOR        30360000
         LR    CCWRK3,CCLINK                                            30380000
         LA    CCSLV1,CCIORG            SET RETURN POINT      RMM,TEMP  30400000
         STM   0,15,CCHOLD2                                             30420000
         B     CCONVSN                  LINK TO CONVERSION    RMM,TEMP  30440000
***********************************                              A26410 30442019
* SET SWITCH TO SHOW H0 WAS SET ON                               A26410 30444019
***********************************                              A26410 30446019
CCSTORH0 MVI   INDHH0(DATBS1),X'00'  SET OFF H0                  A26410 30448019
         MVI   CCH0SAVE,X'F0'      SET ON H0 SAVE SWITCH         A26410 30450019
         B     CCREPT                                            A26410 30452019
***************                                                         30460000
*  ERROR HAS OCCURRED                                                   30480000
***************                                                         30500000
CCEROR   MVC   284(5,DATBS1),CCKYAR   POST IDENTIFIER AND CODE   A26410 30510019
CCEROR2  MVI   INDHH0(DATBS1),X'F0'   TURN ON HALT INDICATOR     A26410 30520019
         MVI   CCH0SAVE,X'00'         RE-INIT H0 SAVE SWITCH     A26410 30530019
         BC    15,CCTHRU                                                30560000
***************                                                         30580000
*  SET FOR INDEXED SEQUENTIAL                                           30600000
***************                                                         30620000
CCISEQ   LA    CCWRK3,CCIKEY            PICK UP ADDRESS OF PARLIST      30640000
         MVC   CCIKEY,CCIDBGN           PICK UP ADDRESS OF KEY          30660000
***************                                                         30680000
*  SET FOR LINK TO I/O,FIRST MUST MODIFY IORB                           30700000
***************                                                         30720000
CCIORG   SR    CCSLV1,CCSLV1            ZERO REGISTER                   30740000
         IC    CCSLV1,CDSTO(CCWRK2)     PICK UP FILE NUMBER             30760000
         LR    CCWRK4,CCSLV1                                            30780000
         BCTR  CCSLV1,0                 DECREMENT BY 1                  30800000
         MH    CCSLV1,CCIRLN            MULT BY IORB LENGTH             30820000
         L     CHNRQT,LVIORB(DATBS1)    PICK UP ADDRESS OF 1ST IORB     30840000
         AR    CHNRQT,CCSLV1            COMPUTE IORB ADDRESS FOR FILE   30860000
         LR    CCSLV1,CHNRQT                                            30880000
         MVI   14(CCSLV1),X'00'         POST IORB COMMAND FOR READ      30900000
         ST    CCWRK3,4(CCSLV1)         ADDR. OF PARLIST TO IORB        30920000
         ST    CCWRK1,CCKEEP                                            30940000
         L     CCLINK,IOROUT(DATBS1)    PICK UP ADDRESS OF I/O ROUTINE  30960000
         BALR  CCRTRN,CCLINK            LINK TO I/O ROUTINE             30980000
***************                                                         31000000
*  LINK TO DETERMINE RECORD TYPE AND MOVE DATA                          31020000
***************                                                         31040000
         ST    CCBASE,CCIDBGN           SAVE BASE REGISTER              31060000
         CLI   INDHH0(DATBS1),X'F0'     TEST IF HALT INDIC. H0 IS ON    31080000
         BE    CCSTORH0            BRANCH IF YES                 A26410 31100019
         LR    CCSLV1,CCWRK4            PICK UP FILE NUMBER             31120000
         L     CCLINK,LVDRTY(DATBS1)    ADDRESS OF DET RECORD TYPE      31140000
         BALR  CCRTRN,CCLINK            PASS CONTROL TO DET REC TYPE    31160000
         L     CCLINK,LVDSPC(DATBS1)    ADDRESS OF DATA SPEC ENTRY      31180000
         BALR  CCRTRN,CCLINK            PASS CONTROL TO DATA SPEC       31200000
         CLI   INDHH0(DATBS1),X'F0'    WAS HO SET ON             A26410 31206019
         BE    CCSTORH0                YES                       A26410 31212019
***************                                                         31220000
*  SET FOR CONTINUE OF PROCESSING                                       31240000
***************                                                         31260000
CCREPT   BALR  CCBASE,0                 RESTORE FORMER BASE REGISTER    31280000
         USING *,CCBASE                                                 31300000
         MVI   CCPROS,X'06'             CONTINUE PROCESSING             31320000
         L     CCWRK1,CCKEEP                                            31340000
         L     CCBASE,CCIDBGN                                           31360000
         BCR   15,CCBASE                START THROUGH THE ROUTINE AGAIN 31380000
*******************************                                         31400000
*  LINK TO CONVERSION                                                   31420000
*******************************                                         31440000
CCONVSN  BAL   CCRTRN,12(CCLINK)                                        31460000
         BALR  CCBASE,0                                                 31480000
         USING *,CCBASE                                                 31500000
         LM    0,15,CCHOLD2                                             31520000
         BR    CCSLV1                                                   31540000
CCSTOR   DS    F                        STORAGE FOR CURRENT ADDRESS PNT 31560000
CCHOLD   DS    16F                      SAVE ALL REGISTERS              31580000
CCHOLD2  DS    16F                                                      31600000
CCPRLT   DC    F'0'                     ADDRESS OF PARLIST FOR DASD     31620000
CCIKEY   DS    F                        ADDRESS OF KEY FOR INDEXED SEQ  31640000
CCKYLN   DC    H'0'                        AND LENGTH OF KEY            31660000
CCMVC    MVC   0(0,CCWRK3),0(CCSLV1)                                    31680000
CCHALF   DS    H                        HALF WORD WORK AREA             31700000
CCIRLN   DC    AL2(IORBLN)              LENGTH OF IORB                  31720000
CCPROS   DC    X'00'                    PROCESSING CONTROL SWITCH       31740000
CCKYAR   DS    CL4                      HOLD AREA FOR KEY               31760000
         DC    X'02'                    ERROR CODE FOR H0 INDICATOR     31780000
CCFOND   DC    X'00'                    ENTRY AVAILABLE FOR PROCESSING  31800000
CCH0SAVE DC    X'00'               SAVE H0                       A26410 31810019
CCIDBGN  DC    F'0'                     BEGINNING OF ID FIELD           31820000
CCKEEP   DS    F                                                        31840000
CCIBLK   DS    F                        INTERRUPTED BLOCK ADDR.         31860000
TSTABL   DS    F                        TABLE START AREA                31880000
         EJECT                                                          31900000
******************************                                          31920000
* CANNED LOGIC I/O INTERCEPT ROUTINE                                    31940000
*                                                                       31960000
******************************                                          31980000
CISLV1   EQU   0                        VOLATILE REG CONTAING IORB      32000000
*                                          POINTER                      32020000
CILINK   EQU   15                       LINKAGE REGISTER,ALSO USED A    32040000
*                                          BASE REGISTER FOR THIS       32060000
*                                          ROUTINE                      32080000
CIRTRN   EQU   14                       RETURN REGISTER                 32100000
CIFLNM   EQU   13                       DISPLACEMENT TO FILE NUMBER     32120000
*                                         IORB                          32140000
******************************                                          32160000
         CNOP  0,4                                                      32180000
INTRCP   BALR  CILINK,0                 SET BASE REGISTER FOR INTRCP    32200000
*                                            ROUTINE                    32220000
         USING *,CILINK                                                 32240000
         ST    ICWRK1,STORE             OBTAIN IORB POINTER IN ICWRK1   32260000
         LR    ICWRK1,CISLV1                                            32280000
         CLC   CIFILE(1),CIFLNM(ICWRK1) TEST TO SEE IF INTERCEPT FILE   32300000
         L     ICWRK1,STORE             RESTORE ICWRK1                  32320000
         L     CILINK,RAFROT(DATBS1)                                    32340000
         BCR   8,CILINK                   YES,LINK TO RAF               32360000
         L     CILINK,IOROUT(DATBS1)      NO,LINK ON TO THE I/O ROUTINE 32380000
         BCR   15,CILINK                     THROUGH THE LINKAGE VECTOR 32400000
STORE    DC    1F'0'                    STORE ICWRK1 DURING ABOVE CLC   32420000
CIFILE   DC    X'40'                    RAF REFERENCED FILE NUMBER      32440000
         EJECT                                                          32460000
******************************                                          32480000
*                                                                       32500000
* REGISTER USAGE FOR TABLE LOGIC                                        32520000
*                                                                       32540000
*              TCRTRN    SYSTEM RETURN REGISTER-STORED UPON ENTRY       32560000
*                             USED FOR SECOND LEVEL LINKAGES AND        32580000
*                             LINKAGE TO IO ROUTINES                    32600000
*              TCLINK    SYSTEM LINKAGE REGISTER-USED ALSO AS A         32620000
*                             WORK REGISTER IN SUBROUTINES NOT          32640000
*                             LINKING TO IO ROUTINES                    32660000
*              TCSLV1    SYSTEM PARAMETER REGISTERS-ARE CONSIDERED TO   32680000
*              TCSLV2         BE VOLITLE WHEN LINKING TO EXTERNAL       32700000
*                             ROUTINES                                  32720000
*              TCWRK1    WORK REGISTERS   1 ROUTINE BASE REGISTER       32740000
*              TCWRK2                     2 PARAMETER LIST POINTER      32760000
*              TCWRK3                     3 LENGTH REGISTER             32780000
*              TCWRK4                     4 RETURN REGISTER FOR 1ST LVL 32800000
*              TCWRK5                     5 EXECUTE REGISTER            32820000
TCIORG   EQU   0                        INPUT OUTPUT REGISTER           32840000
TCRTRN   EQU   14                                                       32860000
TCLINK   EQU   15                                                       32880000
TCSLV1   EQU   1                                                        32900000
TCSLV2   EQU   2                                                        32920000
TCWRK1   EQU   8                                                        32940000
TCWRK2   EQU   9                                                        32960000
TCWRK3   EQU   10                                                       32980000
TCWRK4   EQU   11                                                       33000000
TCWRK5   EQU   12                                                       33020000
NOTON    EQU   14                                                       33040000
YES      EQU   1                                                        33060000
ON       EQU   1                                                        33080000
TCEOF    EQU   X'22'                                                    33100000
READ     EQU   0                                                        33120000
WRITE    EQU   2                                                        33140000
TCBASE   EQU   8                                                        33160000
TCIOAC   EQU   X'0E'                    ACTION BYTE FOR READ,WRITE,ETC  33180000
TCSTSL   EQU   X'13'                    CONDITION BYTE FOR EOF,ETC      33200000
TCRLTK   EQU   4                        ADDRESS OF DIRECT PARLIST       33220000
TCRECD   EQU   0                        ADDRESS OF INPUT/OUTPUT RECORD  33240000
IORBLN   EQU   32                       LENGTH OF INPUT/OUTPUT REQ BLK  33260000
TCRCLG   EQU   X'08'                    RECORD LENGTH                   33280000
******************************                                          33300000
*                                                                       33320000
*  TABLE CANNED LOGIC / DRIVER                                          33340000
*                                                                       33360000
******************************                                          33380000
         CNOP  0,4                      FULL WORD ALIGN                 33400000
TC0000   BALR  TCBASE,0                 SET TC BASE ROUTINE             33420000
         USING *,TCBASE                                                 33440000
         ST    TCRTRN,TCHOLD            SAVE RETURN REGISTER            33460000
TC0005   LA    TCWRK2,TABOUT            PICK UP ADD OF PARLIST TABLE    33480000
TC0007   TM    TACTIN(TCWRK2),X'01'                                     33500000
         BC    NOTON,TC0020             UNSTUFF CASE                    33520000
******************************                                          33540000
*  TABLE CANNED LOGIC / STUFF/UNSTUFF ROUTINE                           33560000
******************************                                          33580000
TC0008   LA    TCWRK5,TLFAD1(TCWRK2)    PICK UP ADD OF TLF IN PAR LIST  33600000
         BAL   TCWRK4,TC7000            LET SUBRTNE DO INITIALIZATION   33620000
         TM    TACTIN(TCWRK2),X'02'     TEST FOR SECOND TABLE           33640000
         BC    NOTON,*+12                                               33660000
         LA    TCWRK5,TLFAD2(TCWRK2)    INIT WORK ADDRESS FOR SEC TAB   33680000
         BAL   TCWRK4,TC7000            LET SUBRTNE DO THE WORK         33700000
         MVC   TCHALF(2),TNUMRC(TCWRK2) PICK UP NUMBER PER RECORD       33720000
******************************                                          33740000
*  DETERMINE IORB ADDRESS FOR THIS REQUEST                              33760000
******************************                                          33780000
         SR    TCSLV1,TCSLV1            ZERO PARAMETER REGISTER         33800000
         IC    TCSLV1,TINFIL(TCWRK2)    PICK UP FILE NUMBER REQUESTING  33820000
         TM    TACTIN(TCWRK2),X'01'     TEST IF INPUT PASS              33840000
         BC    ON,*+8                   NOT OUTPUT PASS                 33860000
         IC    TCSLV1,TOTFIL(TCWRK2)    OUTPUT,PICK UP FILE NUMBER      33880000
         BCTR  TCSLV1,0                 SUBTRACT ONE                    33900000
         MH    TCSLV1,TCIRLN            DETERMINE DISPLACEMENT          33920000
         L     TCSLV2,LVIORB(DATBS1)    PICK UP ADDRESS OF IORB AREAS   33940000
         AR    TCSLV1,TCSLV2            ADD ON DISPLACEMENT             33960000
         ST    TCSLV1,TCIRAD            SAVE FILE IORB ADDRESS          33980000
         TM    TACTIN(TCWRK2),X'01'     TEST FOR STUFF/UNSTUFF          34000000
         BC    NOTON,TC0100             BRANCH TO UNSTUFF ROUTINE       34020000
******************************                                          34040000
*      GET INPUT RECORD                                                 34060000
******************************                                          34080000
TC0060   L     TCLINK,IOROUT(DATBS1)    GET RECORD FROM IN FILE         34100000
         LH    TCWRK3,TCHALF                                            34120000
         L     TCIORG,TCIRAD            PICK UP IORB ADDRESS            34140000
         LR    TCSLV1,TCIORG            PICK UP IORD ADDRESS            34160000
         MVI   14(TCSLV1),X'00'    ACTION BYTE = READ TO IORB           34180000
         BALR  TCRTRN,TCLINK                                            34200000
         MVC   15(4,TCSLV1),TCIORBTB   SET CONTORL CODES FOR IO ROUTNS  34220000
         TM    TCSTSL(TCSLV1),TCEOF     TEST FOR END OF FILE            34280000
         BC    YES,TC0010               GO TO TABLE FILL ROUTINE        34300000
         L     TCSLV2,TCIRAD            PICK UP ADDRESS OF THE RECORD   34320000
         L     TCSLV1,TCRECD(TCSLV2)      WHICH   HAS BEEN INPUTTED     34340000
TC0070   BAL   TCWRK4,TC5000            LINK TO MOVER ROUTINE           34360000
         CLR   TCLINK,TCSLV2            IS THE TABLE FULL QQ.           34380000
         BE    TC0010                      YES,GO TO EXIT               34400000
         BCT   TCWRK3,TC0070            IF NOT LAST ENTRY  CONT PROCSS  34420000
         BC    15,TC0060                LAST ENTRY,GET NEW RECORD       34440000
******************************                                          34460000
*      UNSTUFF ROUTINE ENTRY                                            34480000
******************************                                          34500000
TC0100   L     TCSLV2,TCIRAD            PICK UP ADDRESS OF RECORD TO    34520000
         L     TCSLV1,TCRECD(TCSLV2)       BE OUTPUTTED(BUFFER)         34540000
         LH    TCWRK3,TCHALF                                            34560000
TC0110   BAL   TCWRK4,TC5000            LINK TO MOVER ROUTINE           34580000
         CLR   TCLINK,TCSLV2            IS TABLE DEPLETED,QQ.           34600000
         BE    TC0140                     YES, GO TO OUTPUT EXIT        34620000
         BCT   TCWRK3,TC0110            CONTINUE PROCESSING             34640000
         BAL   TCWRK4,TC0200            OUTPUT RECORD                   34660000
         BC    15,TC0100                BRCH TO UNSTUFF ENTRY TO GETBUF 34680000
TC0140   BAL   TCWRK4,TC0200            OUTPUT THE RECORD               34700000
******************************                                          34720000
*       TEST IF FINISHED                                                34740000
******************************                                          34760000
TC0010   NI    TACTIN(TCWRK2),X'FE'     TURN OFF STUFF SWITCH           34780000
         LA    TCWRK5,TLFAD1(TCWRK2)    PICK UP ADDR OF TLF POINTER     34800000
         BAL   TCWRK4,TC001J            INITIALIZE TLF FOR LOKUP        34820000
         TM    TACTIN(TCWRK2),X'02'     TEST FOR SECOND TABLE           34840000
         BC    NOTON,*+12                 NO SECOND TABLE               34860000
         LA    TCWRK5,TLFAD2(TCWRK2)    PICK UP SECOND POINTER          34880000
         BAL   TCWRK4,TC001J                                            34900000
         LA    TCWRK2,TENTRY(TCWRK2)                                    34920000
         CLI   0(TCWRK2),X'FF'          TEST FOR END OF PAR LIST TABLE  34940000
         BNE   TC0007                   MORE ENTRIES                    34960000
         L     TCRTRN,TCHOLD                                            34980000
         BCR   15,TCRTRN                RETURN TO CALLING PROGRAM       35000000
TC001J   MVC   TCFULL+1(3),0(TCWRK5)    FULL WORL ALIGN TLF             35020000
         L     TCWRK5,TCFULL                POINTER                     35040000
         AR    TCWRK5,DATBS1             RELOCATE TLF                   35060000
         L     TCLINK,4(TCWRK5)         PICK UP START OF TABLE          35080000
         ST    TCLINK,12(TCWRK5)         UPDATE WORK ADDRESS            35100000
         SR    TCSLV1,TCSLV1            ZERO MOVE LENGTH REGISTER       35120000
         IC    TCSLV1,1(TCWRK5)    PICK UP LENGTH                       35140000
         TM    0(TCWRK5),ALFTYP     TEST IF ALFA TABLE                  35160000
         BC       ON,*+12                  TWAS ALPHA                   35180000
         LA    TCSLV1,1(TCSLV1)         RESTORE THE TRUE LENGTH TO REG  35200000
         SRL   TCSLV1,1                 DIVIDE BY 2                     35220000
         EX    TCSLV1,TC001K                                            35240000
         BCR   15,TCWRK4                                                35260000
TC001K   MVC   16(0,TCWRK5),0(TCLINK)                                   35280000
******************************                                          35300000
*        TEST IF TABLE OUTPUT  IS REQUIRED                              35320000
******************************                                          35340000
TC0020   CLI   TOTFIL(TCWRK2),X'00'     UNSTUFF CASE,TEST FOR OUTFILE   35360000
         BE    TC0010                   NO OUTPUT REQUEST               35380000
         BC    15,TC0008                LINK TO SUBROUTINE THAT WORKS   35400000
*****************************                                           35420000
*                                                                       35440000
*   OUTPUT DRIVER                                                       35460000
*                                                                       35480000
*****************************                                           35500000
******************************                                          35520000
*                                                                       35540000
*   OUTPUT DRIVER REGISTER USAGE                                        35560000
*                                                                       35580000
*              TCWRK4    RETURN REGISTER                                35600000
*              TCSLV1    PARAMETER                                      35620000
*              TCSLV2       REGISTERS                                   35640000
*              TCLINK    LINKAGE TO I/O ROUTINE                         35660000
*              TCRTRN    RETURN FROM I/O ROUTINE                        35680000
*                                                                       35700000
******************************                                          35720000
TC0200   L     TCLINK,TCIRAD            PICK UP ADDRESS WHERE THE       35740000
         L     TCSLV2,TCRECD(TCLINK)      RECORD WAS BUILT              35760000
         SR    TCSLV1,TCSLV2            DETERMINE RECORD LENGTH         35780000
         STH   TCSLV1,TCRCLG(TCLINK)    INSERT RECORD LENGTH IN IORB    35800000
         L     TCIORG,TCIRAD            LOAD ADDRESS OF IORB            35820000
         MVI   14(TCLINK),X'02'   POST ACTION BYTE FOR WRITE   TEMP     35840000
         MVC   15(4,TCLINK),TCIORBTB    POST CONTROL BYTES              35860000
         L     TCLINK,IOROUT(DATBS1)                                    35880000
         BALR  TCRTRN,TCLINK                                            35900000
         BCR   15,TCWRK4                                                35920000
******************************                                          35940000
* TABLE CANNED LOGIC /MOVER CONTROL                                     35960000
******************************                                          35980000
******************************                                          36000000
*                                                                       36020000
*   MOVER CONTROL REGISTER USAGE                                        36040000
*                                                                       36060000
*              TCWRK2    POINTS TO PARAMETER LIST TABLE                 36080000
*              TCWRK3    CONTAINS NUMBER OF ENTRIES PER RECORD          36100000
*              TCRTRN    RETURN REGISTER FOR CALLED SUBROUTINES         36120000
*              TCSLV2    RETURNS WITH ADDRESS OF END OF TABLE           36140000
*              TCWRK4    RETURN TO CALLING ROUTINE                      36160000
******************************                                          36180000
TC5000   LA    TCSLV2,TLFAD1(TCWRK2)    PICK UP ADDRESS OF TLF ADDR LNK 36200000
         BAL   TCRTRN,TC5500            BRANCH TO MOVE FIRST TAB ENTRY  36220000
         TM    TACTIN(TCWRK2),X'02'     TEST FOR PRESENCE OF SECND TAB  36240000
         BC    NOTON,TC5050             NO SECOND TABLE                 36260000
         LA    TCSLV2,TLFAD2(TCWRK2)    PICK UP SECOND TLF LINK         36280000
         BAL   TCRTRN,TC5500            BRANCH TO MOVE SECOND TAB ENTRY 36300000
TC5050   L     TCSLV2,TCFULL            PICK UP ADDRESS OF TLF FIELD    36320000
         L     TCSLV2,8(TCSLV2)         PICK UP TABLE END               36340000
         BCR   15,TCWRK4                RETURN TO DRIVER OF MOVER       36360000
******************************                                          36380000
******************************                                          36400000
*                                                                       36420000
*   MOVER REGISTER USAGE                                                36440000
*              TCLINK         WORK REGISTER*EXITS WITH ADDRESS OF NEXT  36460000
*                                           ENTRY                       36480000
*              TCSLV2         WORK REGISTER*IN*** CONTAINS ADDRESS OF   36500000
*                                                 PARLIST ENTRY         36520000
*                                          *OUT**  CONTAINS ADDRESS OF  36540000
*                                                  NEXT TABLE ENTRY     36560000
*              TCWRK5         WORK REGISTER*EXITS WITH COUNT OF BYTES   36580000
*                                           USED IN TABLE AREA          36600000
*              TCWRK2         FIXED REG    *CONTAINS ADDRESS OF PAR     36620000
*                                           TABLE                       36640000
*              TCSL1          PARA REG     *POINTS TO NEXT ENTRY IN     36660000
*                                           I/O AREA                    36680000
*  TABLE CANNED LOGIC / MOVER                                           36700000
******************************                                          36720000
TC5500   MVC   TCFULL+1(3),0(TCSLV2)    WORD ALIGN ADDRESS OF TLF1      36740000
         L     TCLINK,TCFULL            PICK UP ADDRESS OF TLF1         36760000
         AR    TCLINK,DATBS1             DO RELOCATION                  36780000
         ST    TCLINK,TCFULL                                            36800000
         L     TCLINK,12(TCLINK)        PICK UP WORK ADDRESS CONTENTS   36820000
         SR    TCWRK5,TCWRK5            ZERO WORK REGISTER              36840000
         IC    TCWRK5,LENBYT(TCSLV2)                                    36860000
         LA    TCWRK5,1(TCWRK5)         RESTORE TRUE LENGTH             36880000
         TM    TACTIN(TCWRK2),X'01'     TEST FOR UNSTUFF/STUFF          36900000
         BC    NOTON,TC5580               UNSTUFF REQUEST               36920000
         TM    DECTYP(TCSLV2),ALFTYP    TEST FOR ALPHA                  36940000
         BC       ON,TC5520                ALPHA BRANCH TO MOVE ENTRY   36960000
         TM    DECTYP(TCSLV2),UNPCKD    TEST FOR UNPACKED INPUT         36980000
         BC       ON,TC5550             UNPACKED INPUT                  37000000
         SRL   TCWRK5,1                 FORM L/2                        37020000
         LA    TCWRK5,1(TCWRK5)                                         37040000
TC5520   BCTR  TCWRK5,0                 SET UP FOR EXECUTE              37060000
         EX    TCWRK5,EXMVCI            EXEC FOR MVC INTO TABLE         37080000
TC5540   TM    DECTYP(TCSLV2),ALFTYP    TEST TI ALPHA TYPE              37100000
         LR    TCSLV2,TCWRK5                                            37120000
         BC    ON,TC5560                YES BYPASS SIGN CHECK           37140000
         BC    15,TC5555                NUMERIC, TEST FOR VALID SIGN    37160000
TC5550   N     TCWRK5,TCMASK            MASK TO A MAX OF 15             37180000
         LR    TCSLV2,TCWRK5                                            37200000
         BCTR  TCSLV2,0                 DECREMENT FOR EXECUTE           37220000
         SRL   TCWRK5,1                 DIVIDE BY TWO                   37240000
         SLL   TCWRK5,4                                                 37260000
         OR    TCWRK5,TCSLV2            SET REGISTER FOR EXECUTE        37280000
         EX    TCWRK5,EXPACK            EXECUTE THE PACK                37300000
         SRL   TCWRK5,4                                                 37320000
TC5555   AR    TCLINK,TCWRK5            DETERMINE SIGN POSITION         37340000
         TM    0(TCLINK),X'0D'          TEST IS PLUS OR MINUS FROM CARD 37360000
         BO    *+12                                                     37380000
         NI    0(TCLINK),X'F0'          STRIP SIGN AND FORCE            37400000
         OI    0(TCLINK),X'0C'          MAKE A VALID SIGN               37420000
         SR    TCLINK,TCWRK5                                            37440000
TC5560   LA    TCWRK5,1(TCWRK5)         INCREMENT REGISTERS USED IN     37460000
         LA    TCSLV2,1(TCSLV2)            EXECUTION INSTRUTIONS        37480000
         AR    TCSLV1,TCSLV2            ADD NUMBER OF I/O BUFFER BYTES  37500000
         AR    TCLINK,TCWRK5            ADD NUMBER OF TABLE BYTES USED  37520000
         L     TCSLV2,TCFULL            UPDATE WORKING ADDRESS COUNT    37540000
         ST    TCLINK,12(TCSLV2)                                        37560000
         BCR   15,TCRTRN                RETURN                          37580000
TC5580   TM    DECBYT(TCSLV2),ALFTYP                                    37600000
         BC    ON,TC5600                                                37620000
         TM    DECBYT(TCSLV2),UNPCKD                                    37640000
         BC    ON,TC5800                                                37660000
         SRL   TCWRK5,1                 DIVIDE BY TWO THEN              37680000
         LA    TCWRK5,1(TCWRK5)            ADD ONE                      37700000
TC5600   BCTR  TCWRK5,0                 SET UP FOR MVC OUT EXECUTION    37720000
         EX    TCWRK5,EXMVCO                                            37740000
         BC    15,TC5540                BRANCH TO SET UP REGISTERS      37760000
TC5800   N     TCWRK5,TCMASK            SET MAX OF 15                   37780000
         LR    TCSLV2,TCWRK5                                            37800000
         BCTR  TCSLV2,0                 SETUP FOR EX UNPK               37820000
         SLL   TCSLV2,4                                                 37840000
         SRL   TCWRK5,1                                                 37860000
        OR     TCSLV2,TCWRK5                                            37880000
         EX    TCSLV2,EXUNPK            EXECUTE THE UNPACKING           37900000
         SRL   TCSLV2,4                 RESET REGISTER                  37920000
         BC    15,TC5560                                                37940000
TC8000   SVC   0                        PADDING ROUTINE AT THIS POINT   37960000
***********************************                                     37980000
* INITIALIZATION OF WORK ADDRESSES                                      38000000
***********************************                                     38020000
TC7000   MVC   TCFULL+1(3),0(TCWRK5)    FULL WORD ALIGN ADDRESS         38040000
         L     TCLINK,TCFULL            PICK UP ADDRESS OF TLF          38060000
         AR    TCLINK,DATBS1               RELOCAT                      38080000
         TM    TACTIN(TCWRK2),X'01'     TEST IF INPUT/OUTPUT PASS       38100000
         BC    NOTON,TC7005             OUTPUT PASS                     38120000
         L     TCWRK5,8(TCLINK)                                         38140000
         AR    TCWRK5,DATBS1                                            38160000
         ST    TCWRK5,8(TCLINK)         STORE IN WORKING ADDRESS        38180000
         L     TCWRK5,4(TCLINK)         PICK UP STARTING TABLE ADDRESS  38200000
         AR    TCWRK5,DATBS1            UPDATE TABLE LINKAGE FIELDS     38220000
         ST    TCWRK5,4(TCLINK)                                         38240000
TC7005   MVC   12(4,TCLINK),4(TCLINK)                                   38260000
         BCR   15,TCWRK4                                                38280000
***********************************                                     38300000
* EXECUTE INSTRUCTIONS                                                  38320000
***********************************                                     38340000
EXMVCI   MVC   0(0,TCLINK),0(TCSLV1)                                    38360000
EXPACK   PACK  0(0,TCLINK),0(0,TCSLV1)                                  38380000
EXUNPK   UNPK  0(0,TCSLV1),0(0,TCLINK)                                  38400000
EXMVCO   MVC   0(0,TCSLV1),0(TCLINK)                                    38420000
***********************************                                     38440000
* DATA AREA                                                             38460000
***********************************                                     38480000
TCIORBTB DC    X'00E3FF01'        IORB CONTROL BYTES               3369 38500015
*                                         FOR TABLE FILES               38520000
         DS    0F                                                       38540000
TCFULL   DC    AL4(0)                                                   38560000
TCIRAD   DS    F                        IORB ADDRESS FOR THIS FILE      38580000
TCIRLN   DC    AL2(IORBLN)              HALF WORD FOR IORB LENGTH       38600000
TCHALF   DS    H                                                        38620000
TCHOLD   DS    F                                                        38640000
TCHLD1   DS    F                                                        38660000
TCMASK   DC    X'0000000F'                                              38680000
TADDFL   EQU   XXTABE                                                   38700000
TADDFD   EQU   TADDFL                                                   38720000
TABOUT   DS    C                                                        38740000
         ORG   AMISRT+5799                                              38760000
         DS    C                                                        38780000
         END   ASSEMBL1                                                 38800000
