         TITLE 'IES119  OS/360 RPG CIOEX OF ASSEMBLE PHASE 1        22' 00020000
* STATUS  CHANGE LEVEL 1-4                                         3142 00040015
*                                                                       00060000
*FUNCTION/OPERATION   THE CIOEX ROUTINES ARE A SET OF EXTERNAL          00080000
*                     SUBROUTINES WHICH PERFORM ALL OF THE INPUT/OUTPUT 00100000
*                     OPERATIONS FOR THE COMPILER PHASES.  THE CIOEX    00120000
*                     ROUTINES OPERATE IN CONJUNCTION WITH THE CIOEX    00140000
*                     DATA AREA (POINTED TO BY REGISTER 6) WHICH        00160000
*                     CONTAINS THE DCB ADDRESSES, THE PRINTER AND       00180000
*                     READER/PUNCH BUFFERS, AND INFORMATION TO BE       00200000
*                     UPDATED WITH EACH INPUT/OUTPUT OPERATION.         00220000
*                     THE INDIVIDUAL CIOEX ROUTINES AND THE FUNCTIONS   00240000
*                     THEY PERFORM ARE DESCRIBED AT THE BEGINNING       00260000
*                     OF EACH ROUTINE.                                  00280000
*                                                                       00300000
*                     THOSE CIOEX ROUTINES REQUIRED BY A PHASE          00320000
*                     ARE ASSEMBLED AS A SEPARATE MODULE AND            00340000
*                     LINK-EDITED WITH THE PARENT PHASE.                00360000
*                     THE CIOEX CSECT ALSO SERVES AS THE ENTRY POINT    00380000
*                     FOR THE PHASE LOAD MODULE.                        00400000
*                                                                       00420000
*ENTRY POINT, INITIAL   IESCEX FROM THE CALLING PHASE VIA THE XCTL MACR 00440000
*                                                                       00460000
*ENTRY POINT, CIOEX ROUTINES   IES11910 FROM IES11010                   00480000
*                              CALLING SEQUENCE   EXTRN IES11910        00500000
*                                                 L     7,CXRADDR       00520000
*                                                 LA    2,CXRCODE       00540000
*                                                 BALR  5,7             00560000
*                                                 *                     00580000
*                                                 *                     00600000
*                                                 *                     00620000
*                                        CXRADDR  DC    A(IES11910)     00640000
*                                        CXRCODE  EQU   0,2,...50 DISPL 00660000
*                                                       TO THE ADDRESS  00680000
*                                                       OF THE CIOEX    00700000
*                                                       ROUTINE WANTED  00720000
*                                                       WITHIN THE      00740000
*                                                       TRANSFER VECTOR 00760000
*                                                                       00780000
*                              ADDRESS OF THE CIOEX DATA AREA PASSED    00800000
*                              IN REGISTER 6                            00820000
*                                                                       00840000
*INPUT   REQUEST CODE FOR THE CIOEX ROUTINE WANTED IN REGISTER 2        00860000
*        CIOEX DATA AREA                                                00880000
*                                                                       00900000
*OUTPUT   COMPLETED I/O OPERATION AS REQUESTED                          00920000
*         UPDATED CIOEX DATA AREA                                       00940000
*                                                                       00960000
*EXTERNAL ROUTINES   NONE                                               00980000
*                                                                       01000000
*EXIT, INITIAL   TO IES11010                                            01020000
*                CALLING SEQUENCE   PHSLINK  L     15,PHSADDR           01040000
*                                            BALR  7,15                 01060000
*                                            *                          01080000
*                                            *                          01100000
*                                            *                          01120000
*                                   PHSADDR  DC    V(IES11010)          01140000
*                                                                       01160000
*EXIT, CIOEX ROUTINES (EXCEPT PHSCAL)   BR    5        CIOEX RETURN REG 01180000
*                                                                       01200000
*EXIT, CIOEX PHSCAL   XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA       01220000
*                                                                       01240000
*EXIT, SYNCHRONOUS I/O ERROR   SET RETURN CODE TO 20                    01260000
*                              CALL TERMINAL PHASE VIA CIOEX PHSCAL     01280000
*                                                                       01300000
*TABLES/WORK AREAS   NONE                                               01320000
*                                                                       01340000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             01360000
*                                                                       01380000
*NOTES   ALL I/O OPERATIONS ARE PERFORMED WITH BSAM                     01400000
*        THE FOLLOWING MACROS ARE USED - READ                           01420000
*                                        WRITE                          01440000
*                                        CHECK                          01460000
*                                        NOTE                           01480000
*                                        POINT                          01500000
*                                                                       01520000
IESCEX   START                                                          01540000
*0058000400                                                        3142 01550015
         ENTRY IES11910                                                 01560000
         USING CXDATA,6                                                 01580000
         USING *,15                                                     01600000
         ST    14,CXHLDREG              SAVE RETURN ADDR                01620000
***********************************************                         01640000
*CONVERT NOTE NUMBERS FROM DIRECT ACCESS FORMAT (TTRZ) TO               01660000
*  MAGNETIC TAPE FORMAT (ZZCC) IF REQUIRED BY MIXED WORKFILES           01680000
*  FOR PNTINP, PNTCLC, PNTOUT                                           01700000
***********************************************                         01720000
         CLI   CXCMPOVF,X'F0'           WERE NOTE NUMS TAKEN ON DA      01740000
         BNE   PHSLINK                  NO, CONV NOT REQD               01760000
         L     1,CXDCBWK1               YES                             01780000
         TM    17(1),DADEVT             IS COMPRESSION STILL ON DA      01800000
         BO    PHSLINK                  YES, CONV NOT REQD              01820000
         LA    1,CXCALCNT               LOAD ADDR OF FIRST NOTE NUM     01840000
         LA    2,3                      LOAD COUNT OF NOTE NUMS         01860000
NOTCNV   SR    14,14                    CONVERT DA BLOCK ID TO COUNT -  01880000
         IC    14,CXTRKBF                                               01900000
         MH    14,0(1)                    EXTEND TRACK NUM              01920000
         SR    0,0                                                      01940000
         IC    0,2(1)                                                   01960000
         AR    14,0                       ADD BLOCK NUM                 01980000
         ST    14,0(1)                    STORE BACK                    02000000
         LA    1,4(1)                   INCREMENT TO NEXT NOTE NUM      02020000
         BCT   2,NOTCNV                 CONTINUE                        02040000
***********************************************                         02060000
PHSLINK  L     15,PHSADDR               LOAD PHASE ENTRY POINT ADDR     02080000
         BALR  7,15                     LINK TO USER PHASE              02100000
         USING *,7                                                      02120000
CXBASE   ST    13,CXSAVEAR+8            SAVE USER WORK REG, NON-VOLATLE 02140000
         LA    13,CXSAVEAR              LOAD SAVE AREA ADDR             02160000
         ST    5,CXSAVEAR               SAVE USER RETURN ADDR           02180000
         LA    5,CXRETURN               FORCE RETURN VIA CIOEX          02200000
         LH    2,CXRTAB(2)              DISP TO CIOEX ROUTINE           02220000
         AR    2,7                      ADD BASE REG                    02240000
SPECRTRN BR    2                        BRANCH TO CIOEX ROUTINE WANTED  02260000
***********************************************                         02280000
*RETURN VIA CIOEX TO RESTORE WORK REG 13                                02300000
***********************************************                         02320000
CXRETURN L     13,CXSAVEAR+8            RESTORE USER WORK REG 13        02340000
         L     5,CXSAVEAR               RESTORE USER RETURN ADDRESS     02360000
DUMRTRN  BR    5                        RETURN TO USER                  02380000
***********************************************                         02400000
*TABLE OF DISPLACEMENTS TO CIOEX ROUTINES FROM BASE REG ADDRESS         02420000
***********************************************                         02440000
CXRTAB   DC    AL2(GETCMP-CXBASE)       GET COMPRESSION      ROUTINE 0  02460000
         DC    AL2(PUTCMP-CXBASE)       PUT COMPRESSION      ROUTINE 2  02480000
         DC    AL2(PHSCAL-CXBASE)       PHASE CALL           ROUTINE 4  02500000
         DC    AL2(PNTERR-CXBASE)       PRINT ERROR NOTE     ROUTINE 6  02520000
         DC    AL2(PNTSPC-CXBASE)       PRINT SPEC           ROUTINE 8  02540000
         DC    AL2(RDSPEC-CXBASE)       READ SPEC            ROUTINE 10 02560000
         DC    AL2(PUTCOD-CXBASE)       PUNCH/GO OUTPUT      ROUTINE 12 02580000
         DC    AL2(SWITCH-CXBASE)       SWITCH WKFIL1,WKFIL2 ROUTINE 14 02600000
         DC    AL2(PTCMPR-CXBASE)       POINT COMP FOR READ  ROUTINE 16 02620000
         DC    AL2(RLDOUT-CXBASE)       WRITE RLD            ROUTINE 18 02640000
         DC    AL2(RLDIN-CXBASE)        READ RLD             ROUTINE 20 02660000
         DC    AL2(PTRLDW-CXBASE)       POINT RLD FOR WRITE  ROUTINE 22 02680000
         DC    AL2(BLKOUT-CXBASE)       WRITE BLANK AFTER    ROUTINE 24 02700000
         DC    AL2(BLKIN-CXBASE)        READ BLANK AFTER     ROUTINE 26 02720000
         DC    AL2(PTBLKW-CXBASE)       POINT BLKAFTR, WRITE ROUTINE 28 02740000
         DC    AL2(PNTINP-CXBASE)       POINT FIRST INPUT SP ROUTINE 30 02760000
         DC    AL2(PNTCLC-CXBASE)       POINT FIRST CALC SP  ROUTINE 32 02780000
         DC    AL2(PNTOUT-CXBASE)       POINT FIRST OUTPT SP ROUTINE 34 02800000
         DC    AL2(NOTEIN-CXBASE)       NOTE FIRST INPUT SP  ROUTINE 36 02820000
         DC    AL2(NOTECL-CXBASE)       NOTE FIRST CALC SP   ROUTINE 38 02840000
         DC    AL2(NOTEOT-CXBASE)       NOTE FIRST OUTPUT SP ROUTINE 40 02860000
         DC    AL2(NTASGN-CXBASE)       NOTE ANY SPEC        ROUTINE 42 02880000
         DC    AL2(PTASGN-CXBASE)       POINT TO PREV NOTE   ROUTINE 44 02900000
         DC    AL2(PHDUMP-CXBASE)       DUMP WITHIN LIMITS   ROUTINE 46 02920000
         DC    AL2(PTBLKR-CXBASE)       POINT BLKAFTR, READ  ROUTINE 48 02940000
         DC    AL2(PTRLDR-CXBASE)       POINT RLD FOR READ   ROUTINE 50 02960000
PHSADDR  DC    V(IES11010)              PHASE ENTRY POINT ADDR          02980000
DADEVT   EQU   X'20'                    DEVICE TYPE CODE FOR DIRECT ACC 03000000
IES11910 EQU   CXBASE                                                   03020000
***********************************************                         03040000
*COMMON READ/WRITE/CHECK ROUTINE FOR ALL FILES                          03060000
***********************************************                         03080000
READ     MVI   TYPE,X'80'               SET FOR READ SF                 03100000
         B     *+8                                                      03120000
WRITE    MVI   TYPE,X'20'               SET FOR WRITE SF                03140000
         LA    1,DECB                   LOAD DECB ADDR                  03160000
         STM   14,15,8(1)               STORE DCB ADDR AND AREA ADDR    03180000
         L     15,48(0,14)              LOAD DCB OFFSET                 03200000
         BALR  14,15                    LINK FOR READ/WRITE             03220000
*        CHECK DECB                                                     03240000
         LA    1,DECB                   LOAD DECB ADDR                  03260000
         L     14,8(0,1)                LOAD DCB ADDR                   03280000
         L     15,52(0,14)              LOAD CHECK ROUT ADDR            03300000
         LR    14,2                     SET FOR DIRECT RETURN TO USER   03320000
         BALR  2,15                     LINK TO CHECK                   03340000
         NOP   0                                                        03360000
***********************************************                         03380000
*SYNCHRONOUS ERROR ROUTINE                                              03400000
***********************************************                         03420000
         MVI   CXRETCDE,20              SYNCH ERROR RETURN CODE         03440000
         MVC   CXPHSNAM(8),TERMPHS      SET TO CALL TERMINAL PHASE      03460000
         B     PHSCALC                  CLOSE FILES AND RETURN TO SUPV  03480000
TERMPHS  DC    C'RPG10250'              PHASE NAME FOR TERMINAL PHASE   03500000
***********************************************                         03520000
*COMMON DECB FOR ALL FILES                                              03540000
***********************************************                         03560000
DECB     DC    F'0'                     EVENT CONTROL BLOCK             03580000
OPFLD    DC    X'00'                    OP FIELD                        03600000
TYPE     DC    X'00'                    READ/WRITE SF                   03620000
LENGFLD  DC    AL2(0)                   LENGTH FIELD                    03640000
DCBADDR  DC    A(0)                     DCB ADDRESS                     03660000
AREADDR  DC    A(0)                     AREA ADDRESS                    03680000
         DC    A(0)                     POINTER TO STATUS INDICATORS    03700000
***********************************************                         03720000
*GET COMPRESSION                                                        03740000
***********************************************                         03760000
GETCMP   TM    CXCMPOVF+1,X'F0'         TEST FOR COMPRESSION OVERFLOW   03780000
         BZ    GETCMPA                  COMPRESSION STILL IN CORE       03800000
*        READ  DECB,SF,WKFIL1,(CXCMPADD),(CXCMPEXT)                     03820000
         MVC   LENGFLD(2),CXCMPEXT+2    LENGTH OF COMPR TO DECB         03840000
         L     14,CXDCBWK1              LOAD WORK FILE 1 DCB ADDR AND   03860000
         L     15,CXCMPADD                   COMPR ADDR                 03880000
         BAL   2,READ                   LINK FOR READ                   03900000
         LH    14,CXBLKNUM              LOAD COMPR BLOCK NO. BEING PROC 03920000
         LA    14,1(14)                 INCREMENT                       03940000
         STH   14,CXBLKNUM              STORE UPDATED COMPR BLOCK NO.   03960000
GETCMPA  L     3,CXCMPADD               REINIT COMPR REG TO BEG OF BLK  03980000
         BR    5                        RETURN TO USER                  04000000
***********************************************                         04020000
*PHASE CALL ROUTINE                                                     04040000
***********************************************                         04060000
*XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA                            04080000
***********************************************                         04100000
PHSCALC  LR    12,6                     REINIT REG 12 TO CIOEX DATA AR  04120000
PHSCAL   EQU   PHSCALC                                                  04140000
         L     14,CXHLDREG              RESTORE RETURN ADDR             04160000
         LA    9,CXPHSNAM                                               04180000
         XCTL  EPLOC=(9)                CALL NEXT PHASE                 04200000
***********************************************                         04220000
*ERROR NOTE ROUTINE                                                     04240000
***********************************************                         04260000
PNTERR   PACK  CXDUBLWD(8),PNTRAREA+96(3)                               04280000
         CVB   14,CXDUBLWD              CONVERT NOTE NUMBER TO BINARY   04300000
         LA    15,7                     MASK FOR REMAINDER              04320000
         NR    15,14                    PICK OFF REMAINDER              04340000
         SRL   14,3                     DIVIDE NOTE NUMBER BY 8         04360000
         LA    2,256                    INIT BIT TO TURN ON ERROR NOTE  04380000
         LA    15,1(15)                 INCR REMAINDER FOR BCT INSTR    04400000
PNTERRA  SRL   2,1                      ADJUST BIT TO CORRESP TO REMAIN 04420000
         BCT   15,PNTERRA                                               04440000
         IC    15,CXNOTES(14)           PICK UP ERROR NOTE BYTE         04460000
         OR    15,2                     TURN ON BIT CORRESP TO ERR NOTE 04480000
         STC   15,CXNOTES(14)           STORE UPDATED ERROR NOTE BYTE   04500000
         MVC   PNTRAREA+93(3),PNTERRB   MOVE 'IES' TO PRINT BUFF        04520000
         MVI   PNTRAREA+99,C'I'         INSERT INFORMATION IDENT        04540000
         B     PNTSPC                   PRINT ERROR NOTE                04560000
PNTERRB  DC    C'IES'                   OS/RPG PREFIX                   04580000
***********************************************                         04600000
*PRINT SPECIFICATION                                                    04620000
***********************************************                         04640000
PNTSPC   TM    CXCMPOPT,X'04'           IF NOLIST                       04660000
         BCR   1,5                        RETURN TO USER                04680000
*        WRITE DECB,SF,LSTFIL,PNTRARAC                                  04700000
         L     14,CXDCBLST              LOAD LIST FILE DCB ADDR AND     04720000
         LA    15,PNTRARAC                   PRINT BUFFER ADDR W/CTL CH 04740000
         BAL   2,WRITE                  LINK FOR WRITE                  04760000
         MVI   PNTRAREA,C' '            CLEAR                           04780000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT BUFFER                  04800000
***********************************************                         04820000
*TAKE CARE OF CARRIAGE CONTROL, OVERFLOW AND HEADING                    04840000
***********************************************                         04860000
         CLI   PNTRARAC,C'0'            WAS DOUBLE SPACE SPECIFIED      04880000
         BNE   *+10                     NO                              04900000
         SP    CXLINBCT(2),CXONEPCK     YES, DECR LINE COUNT ONE EXTRA  04920000
         MVC   PNTRARAC(1),PNTSPCA      SET CONTROL CHAR FOR NEXT PRINT 04940000
         MVI   PNTSPCA,C' '             SET FOR SING SP, NEXT PRINT + 1 04960000
         SP    CXLINBCT(2),CXONEPCK     DECREMENT LINE COUNT            04980000
         BCR   2,5                      IF POSITIVE RETURN TO USER      05000000
         MVI   PNTRARAC,C'1'            SET CONTROL CHAR FOR PAGE EJECT 05020000
         MVC   CXLINBCT(2),CXLINCNT     INIT LINE COUNT - 52 LINES      05040000
         AP    CXPAGNUM(4),CXONEPCK     INCR PAGE NUMBER                05060000
         UNPK  PNTRAREA+96(4),CXPAGNUM(4) PLACE PAGE NUM IN PRINT AREA  05080000
         OI    PNTRAREA+99,X'F0'        ERASE PLUS SIGN                 05100000
         MVC   PNTRAREA+91(4),PNTSPCB   MOVE 'PAGE' INTO PRINT BUFF     05120000
         MVC   PNTRAREA+70(8),CXTODAY   MOVE IN DATE                    05140000
         MVC   PNTRAREA+50(8),CXSTEPNA  MOVE IN STEP NAME               05160000
         MVC   PNTRAREA+40(8),CXJOBNAM  MOVE IN JOB NAME                05180000
         MVC   PNTRAREA+5(17),CXHEADIN  MOVE IN RPG/E IDENT             05200000
         MVI   PNTSPCA,C'0'             SET FOR DOUB SP, NEXT PRINT + 1 05220000
         B     PNTSPC                   PRINT HEADING LINE              05240000
PNTSPCA  DC    C' '                     SINGLE SPACE                    05260000
PNTSPCB  DC    C'PAGE'                                                  05280000
***********************************************                         05300000
*PUNCH/GO ROUTINE                                                       05320000
***********************************************                         05340000
PUTCOD   TM    CXCMPOPT,X'03'           IF NOLOAD,NODECK                05360000
         BCR   1,5                        RETURN TO USER                05380000
         MVC   72(4,4),CXPGRNAM         IDENTIFY THE CARD               05400000
         AP    CXPUNCNT(4),CXONEPCK(1)    WITH PROGRAM NAME             05420000
         UNPK  76(4,4),CXPUNCNT(4)        AND SEQUENCE NUMBER           05440000
         OI    79(4),X'F0'              ERASE PLUS SIGN                 05460000
*        WRITE DECB,SF,PNCHGO,RDRPCHAR                                  05480000
         L     14,CXDCBPGO              LOAD PUNCH/GO FILE DCB ADDR AND 05500000
         LA    15,RDRPCHAR                   PUNCH AREA ADDR            05520000
         BAL   2,WRITE                  LINK FOR WRITE                  05540000
         TM    CXCMPOPT,X'02'           TEST FOR LOAD,DECK              05560000
         BZ    PUTCODA                  NO                              05580000
         L     14,CXDCBSRC              YES, PUNCH CARD                 05600000
         LA    15,RDRPCHAR                ONTO SYSPUNCH                 05620000
         BAL   2,WRITE                                                  05640000
PUTCODA  MVI   0(4),C' '                CLEAR                           05660000
         MVC   1(79,4),0(4)               PUNCH BUFFER                  05680000
         BR    5                        RETURN TO USER                  05700000
***********************************************                         05720000
*POINT TO BEGINNING OF A FILE FOR WKFIL1, WKFIL2, WKFIL3                05740000
***********************************************                         05760000
PTCMP    L     1,CXDCBWK1               LOAD DCB ADDR                   05780000
         LA    0,256                    LOAD TTRZ BLOCK ID FOR DA, 0010 05800000
         TM    17(1),DADEVT             IS DEVICE TYPE DA               05820000
         BO    PTCMPA                   YES                             05840000
         LA    0,1                      LOAD ZZCC ID FOR TAPE, 0001     05860000
PTCMPA   ST    0,CXDUBLWD+4             STORE BLOCK ID FOR POINT        05880000
         LA    0,CXDUBLWD+4             LOAD ADDR OF BLOCK ID FOR POINT 05900000
         POINT (1),(0)                  POINT TO BLOCK 1                05920000
         XC    CXBLKNUM(2),CXBLKNUM     ZERO COMPR BLOCK NUM BEING PROC 05940000
         BR    5                        RETURN TO USER                  05960000
PTCMPR   EQU   PTCMP                                                    05980000
PTCMPW   EQU   PTCMP                                                    06000000
***********************************************                         06020000
*WORK FILE SERVICE   (REG 1 CONTAINS ADDR OF I/O AREA)                  06040000
***********************************************                         06060000
*        WRITE DECB,SF,(CXDCBWK3),(1),132                               06080000
RLDOUT   ST    1,RLDOUTE                STORE ADDR OF I/O AREA          06100000
         MVC   LENGFLD(2),RLDOUTF       SUPPLY LENGTH TO DECB           06120000
         L     14,CXDCBWK3              LOAD DCB ADDR AND               06140000
         L     15,RLDOUTE                    ADDR OF I/O AREA           06160000
         BAL   2,WRITE                  LINK FOR WRITE                  06180000
         LH    14,CXNUMRLD              LOAD FILE COUNTER               06200000
         LA    14,1(14)                 INCREMENT                       06220000
         STH   14,CXNUMRLD              STORE UPDATED COUNTER           06240000
         L     1,RLDOUTE                RESTORE REG 1 FOR USER          06260000
         BR    5                        RETURN TO USER                  06280000
RLDOUTE  DS    F                        ADDR OF I/O AREA                06300000
RLDOUTF  DC    H'132'                   LENGTH OF RECORD                06320000
PUTCMP   EQU   DUMRTRN                                                  06340000
RDSPEC   EQU   DUMRTRN                                                  06360000
SWITCH   EQU   DUMRTRN                                                  06380000
RLDIN    EQU   DUMRTRN                                                  06400000
PTRLDW   EQU   DUMRTRN                                                  06420000
BLKOUT   EQU   DUMRTRN                                                  06440000
BLKIN    EQU   DUMRTRN                                                  06460000
PTBLKW   EQU   DUMRTRN                                                  06480000
PNTINP   EQU   DUMRTRN                                                  06500000
PNTCLC   EQU   DUMRTRN                                                  06520000
PNTOUT   EQU   DUMRTRN                                                  06540000
NOTEIN   EQU   DUMRTRN                                                  06560000
NOTECL   EQU   DUMRTRN                                                  06580000
NOTEOT   EQU   DUMRTRN                                                  06600000
NTASGN   EQU   DUMRTRN                                                  06620000
PTASGN   EQU   DUMRTRN                                                  06640000
PHDUMP   EQU   DUMRTRN                                                  06660000
PTBLKR   EQU   DUMRTRN                                                  06680000
PTRLDR   EQU   DUMRTRN                                                  06700000
***********************************************                         06720000
*CIOEX DATA AREA                                                        06740000
***********************************************                         06760000
CXDATA   DSECT                                                          06780000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       06800000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 06820000
*                                         (START WITH PREPHASE)         06840000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 06860000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       06880000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   06900000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     06920000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     06940000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     06960000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        06980000
CXFLDADD DS    F                                FIELD NAME TABLE        07000000
CXLITADD DS    F                                LITERAL TABLE           07020000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 07040000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     07060000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      07080000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   07100000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                07120000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      07140000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         07160000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      07180000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    07200000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     07220000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    07240000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            07260000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    07280000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   07300000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           07320000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      07340000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  07360000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   07380000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 07400000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    07420000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         07440000
CXRETCDE DC    X'00'                    RETURN CODE                     07460000
CXIPTEOF BR    2                        LINKAGE TO EOF ROUTINE          07480000
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            07500000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          07520000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    07540000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           07560000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     07580000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    07600000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                07620000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             07640000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            07660000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     07680000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      07700000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    07720000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   07740000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        07760000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               07780000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     07800000
CXSYNERR B     4(2)                     LINKAGE TO SYNCH ERROR ROUTINE  07820000
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    07840000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     07860000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        07880000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          07900000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        07920000
CXTODAY  DC    C'  /  /  '              DATE                            07940000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             07960000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        07980000
RDRPCHAR DS    80C                      READER/PUNCH AREA               08000000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       08020000
PNTRAREA DS    120C                     PRINT AREA                      08040000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 08060000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 08080000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 08085015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 08090015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 08095015
CXDEND   EQU   *                                                        08100000
         END   IESCEX                                                   08120000
