         TITLE 'IES120  OS/360 RPG ASSEMBLE PHASE 2                 23' 00020000
* STATUS       CHANGE LEVEL 1-8                                  A25021 00040019
*FUNCTION/OPERATION:  RPG ASSEMBLE PHASE 2 PROCESSES THE COMPRESSED   * 00060000
*                    FILE DESCRIPTION SPECS AND INPUT SPECS. OBJECT   * 00080000
*                    PROGRAM CODE IS GENERATED TO PERFORM THE         * 00100000
*                    FOLLOWING FUNCTIONS:                             * 00120000
*                                                                     * 00140000
*                       MOVE INPUT DATA INTO FIELD AREAS              * 00160000
*                       PROCESS CONTROL LEVEL FIELDS                  * 00180000
*                       PROCESS MATCHING FIELDS                       * 00200000
*                       CHAINING REQUESTS                             * 00220000
         SPACE 1                                                        00240000
*ENTRY POINT:  IES12010 FROM IES12910                                 * 00260000
*                                                                     * 00280000
*              PHSLINK  L    15,PHSADDR                               * 00300000
*                       BALR 7,15                                     * 00320000
*                       *                                             * 00340000
*                       *                                             * 00360000
*                       *                                             * 00380000
*              PHSADDR  DC   V(IES12010)                              * 00400000
*                                                                     * 00420000
*              POINTERS, COUNTERS, AND CONSTANTS PASSED IN CIOEX DATA * 00440000
*              AREA POINTED TO BY REGISTERS 6 AND 12 UPON ENTRY       * 00460000
         SPACE 1                                                        00480000
*INPUT:  COMPRESSION (FILE DESCRIPTION SPECS AND INPUT SPECS) - SYSUT1* 00500000
         SPACE 1                                                        00520000
*OUTPUT:  OBJECT TEXT - SYSPUNCH/SYSGO                                * 00540000
*         TABLES AND INFORMATION PASSED TO ASSEMBLE PHASE 2.5 - SYSUT2* 00560000
*                                                                     * 00580000
         SPACE 1                                                        00600000
*EXTERNAL ROUTINES:  IES12910 - CIOEX ROUTINES FOR ASSEMBLE PHASE 2   * 00620000
*                                                                     * 00640000
*                    GETCMP - GET NEXT BLOCK OF COMPRESSION           * 00660000
*                    PHSCAL - CALL NEXT PHASE                         * 00680000
*                    PNTERR - TURNS ON APPROPRIATE ERROR NOTE SWITCH  * 00700000
*                    PTCMPR - POSITIONS COMPRESSION DATA SET DOR READ-* 00720000
*                              ING AT ORIGIN (REFERRED TO AS PNTCMP   * 00740000
*                              IN THIS PHASE)                         * 00760000
*                    ELDOUT - WRITES RLD ENTRIES                      * 00780000
*                    BLKOUT - WRITES CONTROL LEVEL ENTRIES ON UTILITY * 00800000
*                             DATA SET                                * 00820000
*                             WRITES TABLES AND INFORMATION PASSED TO * 00840000
*                             ASSEMBLE PHASE 2.5 ON UTILITY DATA SET  * 00860000
*                    BLKIN  - READS CONTROL LEVEL ENTRIES WRITTEN ON  * 00880000
*                             UTILITY DATA SET                        * 00900000
*                    PTBLKW - REPOSITIONS, FOR WRITING AT ORIGIN, THE * 00920000
*                             DATA SET CONTAINING CONTROL LEVEL       * 00940000
*                             ENTRIES AND THE INFORMATION PASSED TO   * 00960000
*                             ASSEMBLE PHASE 2.5 (REFERRED AS PNTBLK) * 00980000
*                    PNTINP - CONDITIONS THE COMPRESSION DATA SET TO  * 01000000
*                             READ THE BLOCK CONTAINING THE FIRST     * 01020000
*                             INPUT SPEC                              * 01040000
*                                                                     * 01060000
*                               CIOEX DATA AREA                       * 01080000
*                                                                     * 01100000
*                    ADDCNT - COUNTER OF CORE USED FOR OBJECT PROG    * 01120000
*                    PHSNAM - NAME OF NEXT PHASE                      * 01140000
*                    IDSPLC - DISPLACEMENT TO FIRST INPUT SPEC IN     * 01160000
*                             COMPRESSION                             * 01180000
*                    SEQINP - SEQUENCE NUMBER OF FIRST INPUT SPEC     * 01200000
*                    SEQCAL - SEQUENCE NUMBER OF FIRST CALC SPEC      * 01220000
*                    NUMBLK - NUMBER OF BLOCKS WRITTEN ON SYSUT2      * 01240000
         SPACE 1                                                        01260000
*EXITS - NORMAL:    VIA CIOEX PHSCAL ON LAST INPUT SPECIFICATION      * 01280000
*                   IN COMPRESSION                                    * 01300000
*      - ERROR:     VIA CIOEX PHSCAL IF NO INPUT SPECIFICATIONS       * 01320000
*                   IN COMPRESSION  (CALL ASSEMBLE PHASE 3)           * 01340000
         SPACE 1                                                        01360000
*TABLES/WORK AREAS:  COMMON DATA BEGINNING AT ADTMVF, GENERATED BY    * 01380000
*                    ASSEMBLE PHASE 2 AND PASSED TO ASSEMBLE PHASE 2.5* 01400000
*                                                                     * 01420000
*                    WKBUFF - AREA FOR ASSEMBLY, OUTPUT, AND INPUT    * 01440000
*                             OF CONTROL LEVEL AND MATCHING FIELDS    * 01460000
*                             ENTRIES                                 * 01480000
*                                                                     * 01500000
*                    DPWRR - TABLE USED FOR PROCESSING CONTROL LEVELS * 01520000
*                                                                     * 01540000
*                    DMPTXTBF - AREA FOR ASSEMBLY AND OUTPUT OF       * 01560000
*                               OBJECT TEXT                           * 01580000
         SPACE 1                                                        01600000
*ATTRIBUTES:   EDITABLE, FOWNWARD COMPATIBLE                          * 01620000
*                                                                     * 01640000
         EJECT                                                          01660000
IES12010 START                                                          01680000
*0142000400,017000,390400,394000-394800                            5050 01700017
         EXTRN IES12910                CIOEX ADDRESS                    01720000
         SPACE 2                                                        01740000
*********************************************************************** 01760000
*   THE FOLLOWING CIOEX SUBROUTINES AND DATA AREAS ARE USED BY        * 01780000
*  ASSEMBLE PHASE 2                                                   * 01800000
*********************************************************************** 01820000
         SPACE 1                                                        01840000
GETCMP   EQU   0                        READ NEXT BLOCK OF COMPRESSION  01860000
PHSCAL   EQU   4                        CALL NEXT PHASE                 01880000
PNTERR   EQU   6                                                        01900000
PNTCMP   EQU   16                       CONDITION GETCMP TO READ        01920000
*                                        BEGINNING WITH FIRST BLOCK     01940000
RLDOUT   EQU   18                       WRITE RLD ENTRIES               01960000
BLKOUT   EQU   24                       OUTPUT CONTROL LEVEL ENTRIES    01980000
*                                        AND BLANK AFTER ENTRIES        02000000
BLKIN    EQU   26                       READ CONTROL LEVEL ENTRIES      02020000
PNTBLK   EQU   28                       REPOSITION WK FILE TO ORIGIN    02040000
PNTINP   EQU   30                       CONDITION GETCMP TO READ        02060000
*                                        BEGINNING WITH 1ST BLK OF INP  02080000
ADDCNT   EQU   52                       COUNTER OF HIGHEST LOC USED     02100000
PHSNAM   EQU   8                        NAME OF NEXT PHASE              02120000
IDSPLC   EQU   134                      DISPLACE TO 1ST INPUT SPEC      02140000
SEQINP   EQU   162                      SEQUENCE OF 1ST INPUT AND       02160000
SEQCAL   EQU   166                       CALCULATION SPEC               02180000
NUMBLK   EQU   128                      NUMBER OF BLANK AFTER ENTRIES   02200000
         SPACE 3                                                        02220000
*********************************************************************** 02240000
*   THE FOLLOWING DISPLACEMENTS FOR LINKAGE VECTOR ENTRIES ARE USED   * 02260000
*  BY ASSEMBLE PHASE 2                                                * 02280000
*********************************************************************** 02300000
LVIOI    EQU   148                                                      02320000
LVCHNG   EQU   156                                                      02340000
STERIN   EQU   164                                                      02360000
LVDRTY   EQU   172                                                      02380000
LVDSPC   EQU   176                                                      02400000
LVGIRC   EQU   180                                                      02420000
LVIORB   EQU   200                                                      02440000
LVWORK   EQU   232                                                      02460000
LVOVF1   EQU   236                                                      02480000
LVCLSR   EQU   264                                                      02500000
         EJECT                                                          02520000
*********************************************************************** 02540000
*   OBJECT PROGRAM DISPLACEMENTS                                      * 02560000
*********************************************************************** 02580000
         SPACE 1                                                        02600000
*   DISPLACEMENTS FOR ACCESSING THE IORB                                02620000
         SPACE 1                                                        02640000
IPREC    EQU   0                                                        02660000
ACTBYT   EQU   14                                                       02680000
EOFSW    EQU   19                                                       02700000
SELECT   EQU   15                                                       02720000
EOFVAL   EQU   34                                                       02740000
         SPACE 1                                                        02760000
*   DISPLACEMENTS FOR ACCESSING THE FPB                                 02780000
         SPACE 1                                                        02800000
IORBDP   EQU   6                                                        02820000
FDRRI    EQU   12                       DISPLACEMENT FROM FDRIVR        02840000
FDRCL    EQU   16                       DISPLACEMENT FROM FDRIVR        02860000
FPBMFI   EQU   0                                                        02880000
FPBMVF   EQU   4                                                        02900000
FPBRI    EQU   8                                                        02920000
FPBCL    EQU   12                                                       02940000
FPBSEQ   EQU   16                                                       02960000
FPBEOF   EQU   16                                                       02980000
MFHA     EQU   18                                                       03000000
         SPACE 1                                                        03020000
*   OTHER OBJ PROG DISPLACEMENTS                                        03040000
         SPACE 1                                                        03060000
H0       EQU   133                                                      03080000
LRIND    EQU   21                                                       03100000
RI00     EQU   22                                                       03120000
RI01     EQU   23                       DISPLACEMENT TO RESULT IND 01   03140000
L1       EQU   123                                                      03160000
CLSUBL   EQU   40            SEE CLSUBR IN CANNED CODE OUT-        1579 03180015
*                                        PUT BY PASS 1 (IF CLSUBR       03200000
*                                        CHANGES THE VALUE OF CLSUBL    03220000
*                                        MAY BE AFFECTED)               03240000
         SPACE 1                                                        03260000
*   DISPLACEMENTS FOR PROCESSING CONTROL LEVEL AND MATCHING FIELD SPECS 03280000
*  (SEE DMPSPC SUBR IN PASS 1)                                          03300000
         SPACE 1                                                        03320000
RR       EQU   0                        FIELD-RECORD RELATION INDICATOR 03340000
FF       EQU   2                        ADDR OF INPUT DATA              03360000
LG       EQU   4                        FIELD LENGTH                    03380000
NB       EQU   5                        LEVEL NUMBER AND SPEC TYPE      03400000
FTYPE    EQU   6                        FIELD TYPE (ALPHA,PACKED,ETC.)  03420000
ERRNUM   EQU   96                                                       03440000
         EJECT                                                          03460000
*********************************************************************** 03480000
*   ALLOCATION OF GENERAL REGISTERS FOR ASSEMBLE PHASE 2              * 03500000
*********************************************************************** 03520000
         SPACE 1                                                        03540000
GR0      EQU   0                        VOLATILE                        03560000
GR1      EQU   1                        VOLATILE                        03580000
GR2      EQU   2                        VOLATILE                        03600000
GR3      EQU   3                        COMPRESSION AREA                03620000
GR4      EQU   4                        WORK REGISTER AND CIOEX USAGE   03640000
GR5      EQU   5                        WORK REGISTER AND CIOEX USAGE   03660000
GR6      EQU   6                        WORK REGISTER AND CIOEX USAGE   03680000
GR7      EQU   12                       WORK REGISTER AND CIOEX USAGE   03700000
GR8      EQU   8                        PHASE BASE REGISTER             03720000
GR9      EQU   9                        PHASE BASE REGISTER             03740000
GR10     EQU   10                       CIOEX USAGE (PRINT AREA)        03760000
GR11     EQU   11                       WORK REGISTER                   03780000
GR12     EQU   7                        WORK REGISTER                   03800000
GR13     EQU   13                       WORK REGISTER (COMPRESSION PTR) 03820000
GR14     EQU   14                       VOLATILE (LINKAGE REGISTER)     03840000
GR15     EQU   15                       VOLATILE (RETURN REGISTER)      03860000
         SPACE 1                                                        03880000
*NOTE - THE CONTENTS OF GR4-GR7 ARE SAVED UPON ENTERING ASSEMBLE        03900000
*      PHASE 2 AND ARE RESTORED BEFORE CALLING A CIOEX SUBROUTINE       03920000
         SPACE 2                                                        03940000
*NOTE - TEMPORARILY GR7 IS GENERAL REG 12 AND GR12 IS GENERAL REG 7     03960000
         SPACE 2                                                        03980000
*NOTE - THE TERM 'PASS' APPEARING IN THIS LISTING REFERS TO             04000000
*       ASSEMBLE PHASE 2                                                04020000
         SPACE 2                                                        04040000
*NOTE - THE TERM 'PASS 2' APPEARING IN THIS LISTING REFERS TO           04060000
*       ASSEMBLE PHASE 2.5                                              04080000
         EJECT                                                          04100000
*********************************************************************** 04120000
*   PASS 1 PERFORMS THE FOLLOWING PROCESSING                          * 04140000
*                                                                     * 04160000
*    SCAN FILE DESCRIPTION SPECS AND ENTER INFORMATION IN A FILE      * 04180000
*   ENVIRONMENT TABLE                                                 * 04200000
*                                                                     * 04220000
*    GENERATE OBJECT PROGRAM ROUTINES TO MOVE INPUT DATA INTO FIELDS  * 04240000
*   AND CALL CHAINING SUBR IF CHAINING FIELDS PRESENT                 * 04260000
*                                                                     * 04280000
*     OUTPUT ENTRIES ON A WORK FILE FOR EACH CONTROL LEVEL FIELD (THE * 04300000
*    ENTRIES ARE SUBSEQUENTLY USED FOR GENERATING OBJECT CODE TO      * 04320000
*    DETERMINE CONTROL BREAKS                                         * 04340000
*                                                                     * 04360000
*     RESERVE A COMMON WORKING STORAGE IN THE OBJECT PROGRAM TO BE    * 04380000
*    USED FOR PROCESSING THE CONTROL LEVEL AND MATCHING FIELDS        * 04400000
*********************************************************************** 04420000
         SPACE 1                                                        04440000
ASM20    BALR  8,0                                                      04460000
         USING *,8,9                                                    04480000
BASEP1   L     GR9,B9ADDR                                               04500000
         B     PASS1                                                    04520000
         EJECT                                                          04540000
*********************************************************************** 04560000
*   THE DATA DEFINED BELOW IS COMMON TO PASS 1 AND PASS 2, IT IS GENE-* 04580000
*  RATED BY PASS 1 AND WRITTEN ONTO A WORK FILE . SUBSEQUENTLY THE    * 04600000
*  DATA IS READ IN TO OVERLAY A SIMIARLY DEFINED AREA IN PASS 2.      * 04620000
*********************************************************************** 04640000
         SPACE 1                                                        04660000
         DS    0F                                                       04680000
ADTMVF   DS    300C                     OBJECT PROGRAM ADDRESSES (ABSO- 04700000
*                                        LUTE) OF THE MVFLDS SUB-       04720000
*                                        ROUTINES GENERATED BY PASS 1   04740000
         SPACE 1                                                        04760000
HA       DC    F'0'                     OBJECT PROGRAM ADDR (ABSOLUTE)  04780000
*                                        OF HOLD AREA FOR CONTR LEVELS  04800000
         SPACE 1                                                        04820000
OADSPC   DS    F                        OBJ PROG ADDR OF DSPC SUBR      04840000
         SPACE 1                                                        04860000
RRIOFF   DS    F                        OBJ PROG ADDR OF SUBR TO TURN   04880000
*                                        OFF ALL IMPUT RECORD RESULTING 04900000
*                                        INDICATORS                     04920000
         SPACE 1                                                        04940000
CLMFWS   DC    F'0'                     OBJECT PROGRAM ADDR (ABSOLUTE)  04960000
*                                        OF THE WORKING STORAGE FOR     04980000
*                                        MATCHING FLDS AND CONTR LEVELS 05000000
         SPACE 1                                                        05020000
CLWSDP   DC    9H'00'                   TABLE OF DISPLACEMENTS TO THE   05040000
*                                        STARTING BYTE WITHING WORKING  05060000
*                                        STORAGE FOR EACH CONTROL LEVEL 05080000
         SPACE 1                                                        05100000
CLMAX    DC    9X'00'                   LENGTH OF CONTROL LEVELS L1-L9  05120000
         SPACE 1                                                        05140000
CLSIND   DC    X'00'                    INDACTOR TO PUT OUT CLSUBR      05160000
*                                        IN PASS 2                      05180000
         SPACE 1                                                        05200000
FET      DC    25X'0'                                                   05220000
         SPACE 1                                                        05240000
*   THE FILE ENVIRONMENT TABLE (FET) IS GENERATED FROM A SCAN OF THE    05260000
*  FILE DESCRIPTION SPEC. IT CONSISTS OF ONE BYTE ENTRIES CONTAINING    05280000
*  THE FOLLOWING INFORMATION FOR EACH INPUT FILE                        05300000
         SPACE 1                                                        05320000
*        BITS       VALUE                                               05340000
         SPACE 1                                                        05360000
*        0-1        00 = PRIMARY FILE                                   05380000
*                   01 = SECONDARY FILE                                 05400000
*                   11 = CHAINED FILE                                   05420000
*        2          NOT USED                                            05440000
*        3     1 = MATCHING FIELDS                                      05460000
*              0 = NO MATCHING FIELDS                                   05480000
*        4          1 =  E SPECIFIED IN COL 17 OF FILE DESCRIPT SPEC    05500000
*                   0 =  BLANK IN COL 17                                05520000
*        5          1 =  ASCENDING SEQUENCE                             05540000
*                   0 =  DESCENDING SEQUENCE OR BLANK                   05560000
*        6          NOT USED                                            05580000
*        7          1 =  CARD INPUT DEVICE                              05600000
*                   0 =  OTHER DEVICE                                   05620000
         SPACE 2                                                        05640000
PSFMFL   DC         X'00'               LENGTH OF M1-M3 FOR PRIMARY     05660000
*                                        AND SECONDARY FILES            05680000
         SPACE 1                                                        05700000
CHFMFL   DS    CL25                     TABLE OF M1-M3 LENGTHS FOR EACH 05720000
*                                        CHAINED FILE WITH MATCH FLDS   05740000
NSTAB    DC    25X'00'                  TABLE CONTAINS HIGHEST NUMERIC  05760000
*                                        RECORD SEQUENCE NUMBER FOR     05780000
*                                        EACH INPUT FILE                05800000
         SPACE 1                                                        05820000
NSCTAB   DS    100C                     OBJ PROG ADDR OF NSCB'S         05840000
         SPACE 1                                                        05860000
MULTI    DC    X'00'                    NUMBER OF SECONDARY FILES       05880000
         EJECT                                                          05900000
PASS1    STM   GR4,GR6,CIXSAV           SAVE CIOEX GR4-GR7              05920000
         L     GR12,CXRADDR            LOAD SERVICE ROUTINE             05940000
         CP    SEQINP(4,GR7),SEQCAL(4,GR7)  COMPARE INPUT SEQUENCE      05960000
*                                            NUMBER TO CALC             05980000
         BNE   SCANFD                       IF NOT EQ THEN INPUT SPECS  06000000
*                                            ARE PRESENT (GO PROCESS)   06020000
*                                           OTHERWISE ABANDON SHIP      06040000
         MVC   PHSNAM(8,GR7),NXPHSN                                     06060000
         BE    EXITP1                                                   06080000
         SPACE 1                                                        06100000
*   SCAN FILE DESCRIPTION SPECS                                         06120000
         SPACE 1                                                        06140000
*    DISPLACEMENTS FOR PROCESSING FILE DESCRIPTION SPECS                06160000
         SPACE 1                                                        06180000
FD       EQU   10                       FILE DESIGNATION                06200000
FE       EQU   11                       END OF FILE (E OR BLANK)        06220000
FS       EQU   12                       SEQUENCE (A OR D)               06240000
D1       EQU   30                       DEVICE TYPE                     06260000
         SPACE 1                                                        06280000
SCANFD   LA    GR2,PNTCMP               CONDITION CIOEX TO READ FILE    06300000
         BALR  GR5,GR12                  DESCRIPTION SPECS              06320000
         LA    GR2,GETCMP               CALL CIOEX TO MAKE AVAILABLE    06340000
         BALR  GR5,GR12                  FILE DESCRIPTION SPECS         06360000
         LA    GR1,FET                                                  06380000
         SR    GR5,GR5                                                  06400000
IFF      CLI   0(GR3),C'F'              TEST FOR FILE SPEC              06420000
         BNE   GETN                     BRANCH IF NOT                   06440000
         CLI   FD(GR3),C'P'             TEST FOR PRIMARY FILE           06460000
         BE    IFEOF                    BRANCH IF PRIMARY               06480000
         CLI   FD(GR3),C'S'             OTHERWISE TEST FOR SECONDARY    06500000
         BNE   IFCHAN                   BRANCH IF NOT SECONDARY         06520000
         OI    0(GR1),X'40'             OTHERWISE SET BIT IN FET ENTRY  06540000
         LA    GR5,1(GR5)               COUNT NUMBER OF SECONDARY       06560000
         B     IFEOF                                                    06580000
IFCHAN   CLI   FD(GR3),C'C'             TEST FOR CHAINED FILE           06600000
         BNE   GETNXF                   BRANCH IF NOT                   06620000
         OI    0(GR1),X'C0'             OTHERWISE SET BIT IN FET        06640000
IFEOF    CLI   FE(GR3),C'E'             TEST FOR END OF FILE INDICATOR  06660000
         BNE   ADSEQ                    BRANCH IF NONE                  06680000
         OI    0(GR1),X'08'             OTHERWISE SET BIT IN FET        06700000
ADSEQ    CLI   FS(GR3),C'D'             TEST FOR ASCENDING SEQUENCE     06720000
         BE    DVICE                    BRANCH IF NOT                   06740000
         OI    0(GR1),X'04'             OTHERWISE SET BIT IN FET        06760000
DVICE    CLI   D1(GR3),C'R'             TEST DEVICE TO BE CARD READER   06780000
         BNE   GETNXF                   BRANCH IF OTHER                 06800000
         OI    0(GR1),1                 OTHERWISE SET BIT IN FET        06820000
GETNXF   LA    GR1,1(GR1)               ADVANCE TO NEXT LOC IN FET      06840000
         LA    GR3,55(GR3)              ADVANCE TO NEXT SPEC            06860000
         B     IFF                      LOOP TO PROCESS NEXT SPEC       06880000
         EJECT                                                          06900000
GETN     STC   GR5,MULTI                SAVE SECONDARY COUNT            06920000
         BAL   GR14,ALIGN               FULL WORD ALIGN ADDR COUNTER    06940000
         MVC   OADSPC(4),ADDCNT(GR7)                                    06960000
         BAL   GR14,DMPTXT                                              06980000
         DC    AL2(DSPCLG)                                              07000000
         DC    AL4(DSPC)                                                07020000
         LA    GR11,DSPCLG                                              07040000
         BAL   GR15,ADD2AC+4                                            07060000
         BAL   GR15,GETINP              GET FIRST INPUT SPEC            07080000
         LA    GR2,PNTBLK               POSITION WORK FILE AT ORGIN     07100000
         BAL   GR14,IOEXC                                               07120000
         TM    1(GR3),X'60'             TEST IF 1ST REC SPEC NUMERIC    07140000
         BC    12,*+8                    SEQ, BRANCH IF NOT             07160000
         BAL   GR14,SAVENS              OTHERWISE SAVE SEQ INFO         07180000
         XC    MFTARG(100),MFTARG                                       07200000
         B     INITZO                                                   07220000
         ORG   PASS1                                                    07240000
MFTARG   EQU   *                                                        07260000
         ORG   *+100                                                    07280000
MFLTAB   EQU   *                                                        07300000
         ORG   *+100                                                    07320000
MFDUPS   EQU   *                                                        07340000
         ORG   *+100                                                    07360000
INITZO   XC    MFLTAB(200),MFLTAB                                       07380000
         B     BEGMVF-18                BRANCH TO PROCESS 1ST REC SPEC  07400000
         EJECT                                                          07420000
*********************************************************************** 07440000
*   RESSTO RESERVES WORKING STORAGE IN THE OBJECT PROGRAM FOR PROCESS-* 07460000
*  ING CONTROL LEVELS AND MATCHING FIELDS  GR2 CONTAINS NO OF BYTES   * 07480000
*********************************************************************** 07500000
         SPACE 1                                                        07520000
RESSTO   LA    GR1,3(GR2)               FORCE LENGTH TO MULTIPLE OF 2   07540000
         SRL   GR1,1                     OR 4                           07560000
         SLL   GR1,1                                                    07580000
         AR    GR11,GR1                                                 07600000
         LA    GR5,BUF1LG-100                                           07620000
CK4BOF   SR    GR1,GR5                  CHECK FOR POSSIBLE OVERFLOW OF  07640000
         BC    12,NOBOF                  TEXT BUFFER (BRANCH IF NOT)    07660000
         STH   GR5,LENGTH               OTHERWISE DIVIDE TOTAL LENGTH   07680000
         BAL   GR14,BLDMPTXT             INTO SMALLER UNITS AND LOOP    07700000
         B     CK4BOF                    (CALL DMPTXT TO RESERVE BLANK  07720000
NOBOF    AR    GR1,GR5                    WORKING STOR WITHIN OBJ PROG) 07740000
         STH   GR1,LENGTH               SUPPLY LENGTH TO DMPTXT         07760000
         BAL   GR14,BLDMPTXT            CALL DMPTXT TO RESERVE BLANK    07780000
*                                        WORKING STOR WITHIN OBJ PROG   07800000
         BAL   GR15,ADD2AC              BRANCH TO UPDATE ADDR COUNT     07820000
         BR    GR12                                                     07840000
         SPACE 2                                                        07860000
*********************************************************************** 07880000
*   SAVE MAX LENGTH OF CONTROL FIELDS FOR EACH LEVEL                  * 07900000
*********************************************************************** 07920000
         SPACE 1                                                        07940000
SAVCLL   SR    GR1,GR1                                                  07960000
         LR    GR2,GR1                                                  07980000
         LR    GR6,GR1                                                  08000000
         LA    GR4,X'01'                                                08020000
         LA    GR5,X'08'                                                08040000
SAVMXL   IC    GR2,CLLTAB(GR1)          (GR2) 6 LEVEL LENGTH            08060000
         LTR   GR2,GR2                                                  08080000
         BZ    UP2NXT                   BRANCH IF NOT USED (ZERO)       08100000
         IC    GR6,CLMAX(GR1)           (GR6) = PREVIOUS MAX FOR LEVEL  08120000
         CLR   GR6,GR2                  COMPARE PREVIOUS MAX LENGTH FOR 08140000
*                                        CONTROL LEVEL WITH THAT OF     08160000
*                                        PRECEDING RECORD GROUP         08180000
         BC    10,UP2NXT                BRANCH IF PREVIOUS MAX GT OR EQ 08200000
         STC   GR2,CLMAX(GR1)            OTHERWISE REPLACE WITH THAT    08220000
UP2NXT   BXLE  GR1,GR4,SAVMXL            OF PRECEDING RECORD GROUP      08240000
         XC    CLLIST(27),CLLIST        RESET CLLTAB AND CLLIST TO ZERO 08260000
         BR    GR15                                                     08280000
         SPACE 2                                                        08300000
*********************************************************************** 08320000
*   GENNSB GENERATES A CONYROL BLOCK FOR EACH FILE WITH NUMERIC SEQ   * 08340000
*  RECORDS (RECORDS MUST APPEAR IN PREDETERMINED ORDER). THE BLOCK    * 08360000
*  CONTAINS A BYTE FOR EACH RECORD IN THE FILE GROUP.                 * 08380000
*********************************************************************** 08400000
         SPACE 1                                                        08420000
GENNSB   L     GR1,NSBPTR                                               08440000
         LA    GR2,NSCB-1                                               08460000
         SR    GR1,GR2                                                  08480000
         SRL   GR1,1                    COMPUTE SIZE NSCB (FORCE TO     08500000
         SLL   GR1,1                     HALF WORD MULTIPLE)            08520000
         STH   GR1,NSBOUT                PLACE IN DMPTXT CALL           08540000
         STC   GR1,NSCB+1                                               08560000
         L     GR2,NSCPTR                                               08580000
         MVC   0(4,GR2),ADDCNT(GR7)     SAVE OBJ ADDR OF NSCB IN NSCTAB 08600000
         AR    GR11,GR1                                                 08620000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT NSCB           08640000
NSBOUT   DC    AL2(0)                                                   08660000
         DC    AL4(NSCB)                                                08680000
         BAL   GR15,ADD2AC              BRANCH TO UPDATE OBJ ADDR       08700000
         BR    GR12                     EXIT GENNSB                     08720000
         SPACE 1                                                        08740000
*********************************************************************** 08760000
*   SAVENS SAVES THE SEQ NUMBER AND CONTROL BYTE OF EACH RECORD SPEC  * 08780000
*  WITH NUMERIC SEQUENCE SPECIFIED                                    * 08800000
*********************************************************************** 08820000
         SPACE 1                                                        08840000
SAVENS   PACK  PACWS(8),2(2,GR3)        CONVERT NUMERIC RECORD SEQUENCE 08860000
         CVB   GR2,PACWS                 NUMBER AND SAVE IN NSTAB       08880000
         L     GR1,NSTPTR                                               08900000
         STC   GR2,0(GR1)                                               08920000
         L     GR1,NSBPTR                                               08940000
         MVC   0(1,GR1),1(GR3)          PLACE CONTROL BYTE OF CURRENT   08960000
         LA    GR1,1(GR1)                REC SPEC INTO NSCB             08980000
         ST    GR1,NSBPTR                                               09000000
         BR    GR14                                                     09020000
         EJECT                                                          09040000
*********************************************************************** 09060000
*   PASS 1 PROCESSING OF THE INPUT RECORD TYPE SPEC.                  * 09080000
*  GENERATE THE ENTRY AND EXIT PART OF THE MVFLDS OBJECT PROGRAM SUBR.* 09100000
*  A MVFLDS SUBR IS GENERATED FOR EACH RECORD GROUP. THE FUNCTION OF  * 09120000
*  THIS SUBR IS TO MOVE INPUT DATA INTO ASSIGNED FIELDS, SET FIELD    * 09140000
*  INDICATORS AND CALL THE CHAINING SUBR IF CHAINING FIELDS PRESENT   * 09160000
*********************************************************************** 09180000
         SPACE 2                                                        09200000
RECTYP   TM    1(GR3),X'60'             TEST FOR 'AND','OR',NEW RECORD  09220000
         BO    NUREC-12          NEW RECORD TYPE (NUMERIC SEQ)     8131 09240000
         BM    AORAND                   BRANCH FOR ALPHA OR 'AND'       09260000
         SR    GR1,GR1                  TURN ON INDICATOR IN BYTE IN    09280000
         IC    GR1,3(GR13)               RITAB CORRESPONDING TO THE     09300000
         LA    GR15,RITAB-RI01(GR1)      RESULTING INDICATOR NUMBER     09320000
         OI    0(GR15),X'F0'                                            09340000
         LA    GR13,4(GR13)             ADVANCE CMPPTR                  09360000
         B     NXSPEC                   BRANCH IF 'OR'                  09380000
AORAND   TM    1(GR3),X'20'             TEST FOR ALPHA OR 'AND'         09400000
         BZ    NUREC                    NEW RECORD TYPE (ALPHA SEQ)     09420000
         LA    GR13,2(GR13)             ADVANCE CMPPTR                  09440000
         B     NXSPEC                   BRANCH IF 'AND'                 09460000
*********************************************************************** 09480000
*   THE FOLLOWING PROCESSING OCCURS WHEN THE FIRST SPEC OF A NEW      * 09500000
*  RECORD GROUP IS DETECTED (THE MVFLDS SUBR FOR THE PRECEDING RECORD * 09520000
*  GROUP IS COMPLETED).                                               * 09540000
*********************************************************************** 09560000
         TM    1(GR3),X'04'     TEST FOR FILE NO. IN REC SPEC      8131 09580000
         BO    *+8                      BRANCH IF NEW FILE GROUP   8131 09600000
         BAL   GR14,SAVENS              SAVE SEQ INFO                   09620000
NUREC    BAL   GR12,GENCHR              BRANCH TO GENERATE CHAINING BLK 09640000
         BAL   GR15,RMFLCK              BRANCH TO PERFORM VALIDITY      09660000
*                                        CHECKING OF MATCHING FLDS FOR  09680000
*                                        THE PRECEDING RECORD GROUP     09700000
         BAL   GR15,MRKEOR                                              09720000
         BAL   GR15,SAVCLL                                              09740000
         MVI   OVFLOW,X'00'             RESET FLD ADDR OV IND TO ZERO   09760000
         TM    1(GR3),X'04'             TEST FOR FILE NO. IN REC SPEC   09780000
         BZ    BEGMVF-4                 BRANCH IF NO FILE NO. IN SPEC   09800000
         BAL   GR15,FMFLCK              BRANCH TO PERFORM VALIDITY      09820000
*                                        CHECKING OF MATCHING FLDS      09840000
*                                        SPECIFICATIONS FOR THE PRE-    09860000
*                                        CEDING FILE GROUP              09880000
         L     GR2,NSTPTR               ADVANCE POINTER TO NEXT BYTE    09900000
         CLI   0(GR2),0                 TEST FOR NUMERIC SEQ RECORDS    09920000
*                                        IN PRECEDING FILE              09940000
         LA    GR2,1(GR2)                IN NSTAB FOR NEXT FILE         09960000
         ST    GR2,NSTPTR                                               09980000
         BE    ADVPTR                   BRANCH IF NO NUMERIC SEQ        10000000
         BAL   GR12,GENNSB              OTHERWISE GENERATE NSCB         10020000
         LA    GR1,NSCB+2               RESET NSCB POINTER              10040000
         ST    GR1,NSBPTR                                               10060000
ADVPTR   TM    1(GR3),X'64'   TEST FOR NUM SEQ IN 1ST REC        A25021 10080019
         BC    12,*+8           SPEC OF FILE-BRANCE IF NOT         8131 10100000
         BAL   GR14,SAVENS              OTHERWISE SAVE SEQ INFO    8131 10120000
         L     GR1,NSCPTR     ADVANCE NSCTAB POINTER             A25021 10140019
         LA    GR1,4(GR1)                                               10160000
         ST    GR1,NSCPTR                                               10180000
         PACK  PACWS(8),4(2,GR3)         CONVERT FILE NO. TO BINARY AND 10200000
         CVB   GR2,PACWS                 PLACE IN LOCATION FILENO       10220000
         STC   GR2,FILENO                                               10240000
         LA    GR13,2(GR13)             ADVANCE CMPPTR                  10260000
BEGMVF   L     GR1,MVFPTR                                               10280000
         MVC   0(3,GR1),ADDCNT+1(GR7)   SAVE CURRENT ABSOLUTE ADDR OF   10300000
*                                       OBJECT PROG AS STARTING ADDR    10320000
*                                       OF THE NEXT MVFLDS SUBROUTINE   10340000
         LA    GR1,3(GR1)               ADVANCE POINTER (MVFPTR) TO     10360000
         ST    GR1,MVFPTR               NEXT AVAIL LOC IN TABLE(ADTMVF) 10380000
         SR    GR1,GR1                                                  10400000
         IC    GR1,5(GR13)              TURN ON INDICATOR IN BYTE IN    10420000
         LA    GR15,RITAB-RI01(GR1)      RITAB CORRESPONDING TO THE     10440000
         OI    0(GR15),X'F0'             RESULTING INDICATOR NUMBER     10460000
         LA    GR13,6(GR13)             ADVANCE CMPPTR                  10480000
         MVC   RECSEQ(2),2(GR3)         SAVE RECORD SPEC SEQUENCE FOR   10500000
*                                        POSSIBLE USE IN CHAINING       10520000
*                                        REQUEST BLOCK                  10540000
NXSPEC   TM    1(GR3),X'80'             ADVANCE TO NEXT SPEC            10560000
         BZ    *+8                      TEST FOR STACKER SELECT         10580000
         LA    GR13,1(GR13)             IF SEL ADD 1 TO CMPPTR          10600000
         IC    GR1,1(GR3)                                               10620000
         LA    GR2,X'03'                                                10640000
         NR    GR2,GR1                                                  10660000
         BZ    ADV2NX                    BRANCH IF NO RECORD CODES      10680000
         LA    GR13,5(GR13)              OTHERWISE ADD 5 TO CMPPTR      10700000
         BCT   GR2,*-4                    FOR EACH RECORD CODE          10720000
ADV2NX   BAL   GR15,GNXCMP              BRANCH TO GET NEXT SPEC         10740000
         B     RECTYP                   BRANCH IF NEXT SPEC IS REC TYPE 10760000
         B     FLDTYP                   BRANCH IF NEXT SPEC IS FLD TYPE 10780000
         EJECT                                                          10800000
*********************************************************************** 10820000
*   THE FOLLOWING COMPLETES PASS 1 PROCESSING                         * 10840000
*                                                                     * 10860000
*    IF CONTROL LEVELS AND/OR MATCHING FIELDS ARE PRESENT RESERVE A   * 10880000
*   WORKING STORAGE AREA WITHIN THE OBJECT PROGRAM. THIS AREA IS EQUAL* 10900000
*   TO EITHER THE SUM OF THE MAXIMUM LENGTH SPECIFIED FOR CONTROL     * 10920000
*   LEVELS OR THE SUM OF THE MAXIMUM LENGTH OF THE MATCHING FIELDS.   * 10940000
*                                                                     * 10960000
*    IF CONTROL LEVELS ARE PRESENT, GENERATE A TABLE OF THE DISPLACE- * 10980000
*   MENTS TO THE STARTING BYTE FOR EACH LEVEL (1-9) WITHIN THE COMMON * 11000000
*  WORKING STORAGE                                                    * 11020000
*   IF CONTROL LEVELS ADN/OR MATCHING FIELDS ARE PRESENT PROCESS THE  * 11040000
*  SPECS ON THE WORK FILE. GENERATE THE MCL2WS AND MFSUBR OBJ PROG    * 11060000
*  SUBROUTINES                                                        * 11080000
*********************************************************************** 11100000
         SPACE 2                                                        11120000
         BAL   GR12,GENCHR              BRANCH TO GENERATE CHAINING BLK 11140000
*                                        FOR LAST RECORD GROUP          11160000
         L     GR2,NSTPTR               TEST FOR NUMERIC SEQ RECORDS IN 11180000
         CLI   0(GR2),0                  LAST FILE GROUP                11200000
         BE    *+8                      BRANCH IF NONE                  11220000
         BAL   GR12,GENNSB              OTHERWISE GENERATE NSCB         11240000
         BAL   GR15,RMFLCK              BRANCH TO PERFORM VALIDITY      11260000
*                                        CHECKING OF MATCHING FLDS FOR  11280000
*                                        THE LAST INPUT RECORD GROUP    11300000
         BAL   GR15,FMFLCK              BRANCH TO PERFORM VALIDITY      11320000
*                                        SPECIFICATIONS FOR LAST FILE   11340000
         BAL   GR15,MRKEOR                                              11360000
         MVI   7(6),X'FF'                CHECKING OF MATCHING FLDS      11380000
         BAL   GR15,SAVCLL                                              11400000
         CLI   ERNO63,X'F0'             TEST FOR MF ERROR 63            11420000
         BNE   *+12                     BRANCH IF NOT                   11440000
         LA    GR5,NOTE63               OTHERWISE OUTPUT ERROR NOTE     11460000
         BAL   GR15,ERROR                                               11480000
         SR    GR1,GR1                                                  11500000
         LR    GR0,GR1                                                  11520000
         CLI   CLMAX,X'00'              TEST 1ST BYTE OF CLMAX FOR ZERO 11540000
         BNE   *+14                     BRANCH IF NOT ZERO              11560000
         CLC   CLMAX(9),CLMAX+1         TEST OTHER BYTES OF CLMAX       11580000
         BE    NOCLFL                   BRANCH IF ZERO                  11600000
         MVI   CLS,X'F0'                SET TO INDICATE CL FLDS PRESENT 11620000
         SR    GR2,GR2                                                  11640000
         SR    GR6,GR6                                                  11660000
         LA    GR4,1                                                    11680000
         LA    GR5,8                                                    11700000
         SPACE 1                                                        11720000
*    BUILD TABLE OF DISPLACEMENTS (CLWSDP) TO STARTING BYTE WITHIN      11740000
*    WORKING STORAGE FOR EACH CONTROL LEVEL AND COMPUTE TOTAL NUMBER    11760000
*    OF BYTE REQUIRED FOR THE WORKING STORAGE                           11780000
         SPACE 1                                                        11800000
STWSDP   STH   GR2,CLWSDP(GR6)          STORE DISPLACEMENT              11820000
         IC    GR0,CLMAX(GR1)           GR4 = MAX LENGTH FOR LEVEL(N)   11840000
         AR    GR2,GR0                  COMPUTE DISPLACEMENTS           11860000
*                                        DP(N) = DP(N-1)+L(N-1)         11880000
         LA    GR6,2(GR6)                                               11900000
         BXLE  GR1,GR4,STWSDP                                           11920000
         BCTR  GR2,0                    GR2 = TOTAL BYTES FOR CL WK STO 11940000
         MVC   HA(4),ADDCNT(GR7)        SAVE ADDR OF HOLD AREA          11960000
         BAL   GR12,RESSTO              BRANCH TO RESERVE HOLD AREA     11980000
         MVI   CLSIND,X'F0'             SET INDICATOR TO OUTPUT CLSUBR  12000000
         LA    GR13,CLSTAB              (OBJ PROG SUBR) IN PASS 2 AND   12020000
         SR    GR1,GR1                   SET POINTER TO CLS TAB         12040000
         IC    GR1,MFS                  GR1 = MAX LENGTH OF M1-M3       12060000
         CLR   GR1,GR2                  COMPARE TOT LENGTH OF CL AND MF 12080000
         BL    RSRVWS                   BRANCH IF CL LENGTH GREATER     12100000
         LR    GR2,GR1                  OTHERWISE USE TOT LENGTH OF     12120000
         B     RSRVWS                    M1-M3 FOR RESERVING WORK STOR  12140000
NOCLFL   SR    GR1,GR1                  CONTROL TRANSFERS HERE IF       12160000
         IC    GR1,MFS                   CONTROL LEVELS NOT PRESENT     12180000
         LTR   GR2,GR1                  TEST FOR MATCHING FLDS PRESENT  12200000
         BZ    ENDP1                    BRANCH IF NO MATCHING FLDS      12220000
         LA    GR13,MFSTAB              OTHERWISE SET POINTER TO MFSTAB 12240000
RSRVWS   MVC   CLMFWS(4),ADDCNT(GR7)    SAVE ADDR OF WORKING STOR AREA  12260000
         BAL   GR12,RESSTO              BRANCH TO RESERVE WORKING STOR  12280000
         BAL   GR14,FINTXT                                              12300000
         BAL   GR14,ALIGN     BRANCH TO ALIGN ADDR COUNTER              12320000
         OC    NUMBLK(2,GR7),NUMBLK(GR7) TEST FOR PRIOR OUTPUT ON WKFIL 12340000
         BZ    ZOT                      BRANCH IF NOT                   12360000
         LA    GR1,WKBUFF               OTHERWISE WRITE LAST BLOCK OF   12380000
         LA    GR2,BLKOUT                CONTROL LEVEL AND MATCHING     12400000
         BAL   GR14,IOEXC                FIELD SPECS                    12420000
ZOT      LA    GR1,4                                                    12440000
         LA    GR5,DPWRR                                                12460000
         XC    0(223,GR5),0(GR5)        CLEAR TABLE FOR PROCESSING      12480000
         LA    GR5,223(GR5)                                             12500000
         BCT   GR1,*-10                                                 12520000
         L     GR11,B15                                                 12540000
         ST    GR11,B8                                                  12560000
         SPACE 2                                                        12580000
*   THE TABLES DEFINED BELOW ARE USED FOR SAVING THE ADDRESSES OF       12600000
*  OBJECT PROGRAM SUBROUTINES GENERATED FOR CONTROL LEVELS AND MATCHING 12620000
*  FIELDS. THESE TABLES ARE A PART OF THE COMMON DATA WRITTEN ON TO A   12640000
*  WORK FILE FOR PASS 2 USAGE. THE AREA BEGINNING AT SYMBOLIC LOCATION  12660000
*  PASS1 IS OVERLAID                                                    12680000
         SPACE 2                                                        12700000
CLSTAB   EQU   MULTI+1                                                  12720000
MFSTAB   EQU   CLSTAB+300                                               12740000
DATEND   EQU   MFSTAB+300               END OF COMMON DATA              12760000
DATALG   EQU   DATEND-ADTMVF            LENGTH OF COMMON DATA           12780000
         EJECT                                                          12800000
GENCLM   LA    GR1,WKBUFF                                               12820000
         OC    NUMBLK(2,GR7),NUMBLK(GR7) TEST FOR CL AND MF SPECS ON    12840000
         BZ    IFCLF                     WORK FILE, BRANCH IF NOT       12860000
         MVC   BLKCTR(2),NUMBLK(GR7)                                    12880000
         LA    GR2,PNTBLK                AND CAUSE WORK FILE TO BE      12900000
         BAL   GR14,IOEXC                POSITIONED AT ORGIN            12920000
READWF   LA    GR2,BLKIN                READ WORK FILE                  12940000
         LA    GR1,WKBUFF                                               12960000
         BAL   GR14,IOEXC                                               12980000
         LH    GR2,BLKCTR                                               13000000
         BCTR  GR2,0                    REDUCE BLOCK COUNT              13020000
         STH   GR2,BLKCTR                                               13040000
IFCLF    TM    NB(GR1),X'20'            TEST SPEC TYPE                  13060000
         BO    GENMF                    BRANCH IF MATCHING FLD TYPE     13080000
         CLI   CLS,0                    OTHERWISE TEST FOR BYPASSING    13100000
         BE    CK4EOR                    CL SPECS (BRANCH TO BYPASS)    13120000
         SPACE 1                                                        13140000
*   PROCESS CONTROL LEVEL SPEC                                          13160000
         SPACE 1                                                        13180000
         MVI   TRIGER,X'F0'             SET INDICATOR, CL SPECS PRESENT 13200000
         LA    GR0,15                                                   13220000
         IC    GR4,NB(GR1)                                              13240000
         NR    GR4,GR0                  GR4 = N (LEVEL NUMBER)          13260000
         LR    GR6,GR4                                                  13280000
         AR    GR6,GR6                  GR6 = 2N                        13300000
         SR    GR2,GR2                                                  13320000
         IC    GR2,LG(GR1)              GR2 = FIELD LENGTH              13340000
         TM    FTYPE(GR1),X'F0'         TEST FOR UNPACKED NUMERIC       13360000
         BC    12,TST4RR                BRANCH IF NOT                   13380000
         LA    GR2,1(GR2)               OTHERWISE COMPUTE PACKED LENGTH 13400000
         SRL   GR2,1                                                    13420000
TST4RR   CLI   RR(GR1),X'FD'            TEST FOR NO RR                  13440000
         BNE   CLWRR                    BRANCH IF RR                    13460000
         BAL   GR12,CK4UBA                                              13480000
         IC    GR0,DPWORR-1(GR4)        GR0 = DISPLACEMENT FOR SPLIT    13500000
         LR    GR5,GR0                   FLDS WITHIN WORK STOR FOR THE  13520000
         LA    GR5,1(GR2,GR5)            LEVEL                          13540000
         STC   GR5,DPWORR-1(GR4)        ADD FLD LENGTH FOR CURRENT SPEC 13560000
         SPACE 1                                                        13580000
*********************************************************************** 13600000
*   THE FOLLOWING SEQUENCE GENERATES THE OBJ PROG INSTRUCTION TO MOVE * 13620000
*  CONTROL LEVEL DATA FROM THE INPUT AREA TO WORKING STORAGE          * 13640000
*                                                                     * 13660000
*        MVC   TA(L,GR9),FF(GR2)        MOVES ALPHA AND PACKED DATA   * 13680000
*                                                                     * 13700000
*        PACK  TA(L1,GR9),FF(L2,GR2)    PACK UNPACKED DATA            * 13720000
*                                                                     * 13740000
*              FOR FIELDS WITHOUT A FIELD-RECORD RELATION INDICATOR   * 13760000
*               TA = CLWSDP(N-1)+DPWORR(N-1)                          * 13780000
*                                                                     * 13800000
*              FOR FIELDS WITH A FIELD-RECORD RELATION INDICATOR      * 13820000
*               TA = CLWSDP(N-1)+DPWRR(I)  (N = CONTROL LEVEL NUMBER) * 13840000
*********************************************************************** 13860000
         SPACE 1                                                        13880000
GENM2W   IC    GR2,LG(GR1)              GR2 = FIELD LENGTH              13900000
         AH    GR0,CLWSDP-2(GR6)                                        13920000
         A     GR0,B9                   GR0 = BDDD FOR TARGET FLD       13940000
         LA    GR6,MVF                            GR6 = ADR OF MVC INST 13960000
         TM    FTYPE(GR1),X'F0'         TEST FOR UNPACKED NUMERIC FLD   13980000
         BO    GENPAC                   BRANCH IF UNPACKED              14000000
         MVC   4(2,GR6),FF(GR1)                                         14020000
         BAL   GR15,GENMVF+4            BRANCH TO GENERATE MVC INST     14040000
         CLI   FTYPE(GR1),X'40'         TEST FOR APLHA OR PACKED        14060000
         BE    CK4EOR                   BRANCH IF ALPHA                 14080000
         B     GENAND                   BRANCH IF PACKED                14100000
GENPAC   LA    GR6,CPACK                GENERATE INST TO PACK CL FIELD  14120000
         LR    GR5,GR2                                                  14140000
         LA    GR2,1(GR2)               COMPUTE  L1 LENGTH FOR PACK     14160000
         SRL   GR2,1                     L1=(L+1/2)                     14180000
         SLL   GR2,4                                                    14200000
         OR    GR2,GR5                  FORM L1-L2 IN GR2               14220000
         MVC   4(2,GR6),FF(GR1)                                         14240000
         BAL   GR15,GENMVF+4            BRANCH TO GENERATE PACK INST    14260000
         SRL   GR2,4                    GENERATE NI INST TO FORCE SIGN  14280000
GENAND   AR    GR0,GR2                   OF C ON PACKED FIELD           14300000
         STH   GR0,ANDI+2               PLACE ADDR OF SIGN POSITION IN  14320000
         BAL   GR14,DMPTXT               INST - BRANCH TO OUTPUT TEXT   14340000
         DC    AL2(4)                                                   14360000
         DC    AL4(ANDI)                                                14380000
         LA    GR11,4(GR11)             UPDATE ADDR COUNTER             14400000
         SPACE 1                                                        14420000
CK4EOR   TM    NB(GR1),X'10'            TEST FOR END OF RECORD GROUP    14440000
         BO    GENB                     BRANCH IF END                   14460000
         LA    GR1,7(GR1)               ADVANCE TO NEXT SPEC            14480000
         CLI   0(GR1),X'FF'             TEST FOR END OF BLOCK           14500000
         BNE   IFCLF                    BRANCH IF NOT END OF BLOCK      14520000
         OC    BLKCTR(2),BLKCTR         OTHERWISE TEST BLOCK COUNT      14540000
         BC    7,READWF                 BRANCH TO READ NEXT IF NOT ZERO 14560000
         CLI   CLS,0                    TEST IF CONTROL LEVELS WERE     14580000
*                                        PROCESSED BY 1ST CYCLE GENCLM  14600000
         BE    ENDP1                    IF NO CL'S THEN MF'S WERE       14620000
*                                        PROCESSED (BRANCH TO END PASS) 14640000
CK4MFS   CLI   MFS,0                    OTHERWISE TEST FOR MF'S PRESENT 14660000
         BE    ENDP1                    BRANCH TO END PASS 1            14680000
         XC    CLS(2),CLS               OTHERWISE PREPARE TO PROCESS    14700000
         LA    GR13,MFSTAB               MF SPECS                       14720000
         B     GENCLM                   BRANCH TO PROCESS MF SPECS      14740000
*                                        (REQUIRES 2ND PASS OF WKFIL)   14760000
         SPACE 1                                                        14780000
*   PROCESS CONTROL LEVEL SPEC WITH A FIELD-RECORD RELATION INDICATOR   14800000
         SPACE 1                                                        14820000
CLWRR    BAL   GR15,PROCRR                                              14840000
         LA    GR12,RI01                COMPUTE I FOR ACCESSING DPWRR   14860000
         SR    GR0,GR12                  I = 9((RR-RI01)-1)+(N-1)       14880000
         LR    GR5,GR0                                                  14900000
         SLL   GR5,3                                                    14920000
         AR    GR5,GR0                                                  14940000
         AR    GR4,GR5                  GR4 = I                         14960000
         IC    GR0,DPWRR-1(GR4)         GR0 = DISPLACEMENT FOR SPLIT    14980000
         LR    GR5,GR0                   FLDS WITHIN WORK STOR FOR THE  15000000
         LA    GR5,1(GR2,GR5)            LEVEL                          15020000
         STC   GR5,DPWRR-1(GR4)         ADD FLD LENGTH FOR CURRENT SPEC 15040000
         B     GENM2W                   BRANCH TO GENERATE MOVE         15060000
PROCRR   IC    GR0,RR+1(GR1)            GR0 = DISPLACEMENT TO RR IND    15080000
         CH    GR0,PREVRR               COMPARE WITH RR OF PRECEDING    15100000
         BE    0(0,GR15)                 SPEC, EXIT IF EQUAL            15120000
         STH   GR0,PREVRR               OTHERWISE GENERATE CODING IN    15140000
         BAL   GR12,CK4UBA                                              15160000
         LR    GR3,GR13                  THE OBJ PROG TO TEST THE IND   15180000
         LA    GR13,RR(GR1)                                             15200000
         BAL   GR12,FLDREL                                              15220000
         LR    GR13,GR3                                                 15240000
         BR    GR15                                                     15260000
PREVRR   DC    H'0'                                                     15280000
         EJECT                                                          15300000
GENB     CLI   TRIGER,X'F0'             TEST FOR CL OR MF SPECS IN      15320000
*                                        RECORD GROUP BEING PROCESSED   15340000
         MVI   TRIGER,0                 RESET INDICATOR                 15360000
         BNE   CK4EOR+8                 BRANCH IF NO SPECS PROCESSED    15380000
         CLI   CLS,0               TEST FOR CL SPECS BEING PROCESSED    15400000
         BNE   FINCLS              BRANCH TO FINISH MCL2WS OBJ SUBR     15420000
         SPACE 1                                                        15440000
*********************************************************************** 15460000
*   THE FOLLOWING SEQUENCE COMPLETES GENERATING THE MFSUBR OBJ PROG   * 15480000
*  SUBR. A BRANCH FOR RETURNING CONTROL TO PROCMF IS GENERATED        * 15500000
*********************************************************************** 15520000
         SPACE 1                                                        15540000
         BAL   GR12,CK4UBA                                              15560000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT INSTRUCTION    15580000
         DC    AL2(4)                                                   15600000
         DC    AL4(B4GR14)                                              15620000
         LA    GR11,4(GR11)                                             15640000
         B     GENBX                                                    15660000
         SPACE 1                                                        15680000
B4GR14   B     6(0,GR14)                                                15700000
         SPACE 2                                                        15720000
         SPACE 2                                                        15740000
*********************************************************************** 15760000
*   THE FOLLOWING SEQUENCE COMPLETES GENERATING THE MCL2WS OBJ PROG   * 15780000
*  SUBR. A BAL TO THE CLSUBR IS GENERATED FOR EACH LEVEL PRESENT IN   * 15800000
*  THE RECORD GROUP                                                     15820000
         SPACE 1                                                        15840000
XBAL     BAL   GR11,0(GR7,0)            BRANCH TO CLSUBR (A DISPLACE-   15860000
*                                        MENT TO THE ENTRY POINT IS     15880000
*                                        PLACED IN THE D2 FIELD)        15900000
         SPACE 1                                                        15920000
*  THE FOLLOWING INSTRUCTIONS ARE GENERATED WHEN A LEVEL IS           * 15940000
*  CONDITIONED BY A FIELD-RECORD RELATION INDICATOR                   * 15960000
*        CLI   RI(GR3),X'F0'            TEST INDICATOR TO BE ON       * 15980000
*        BNE   NEXT                     BRANCH IS NOT                 * 16000000
*        BAL   GR11,N(GR12)             OTHERWISE BRANCH TO CLSUBR    * 16020000
         SPACE 1                                                        16040000
BRGR14   BR    GR14                     EXIT (GENERATED AS LAST INST    16060000
*                                        OF THE MCL2WS SUBR)          * 16080000
*********************************************************************** 16100000
         SPACE 1                                                        16120000
FINCLS   BAL   GR12,CK4UBA              DEFINE ANY PRECEDING UBA        16140000
         SR    GR2,GR2                                                  16160000
         LA    GR3,DPWORR                                               16180000
         LA    GR5,DPWORR+8                                             16200000
LOOP1    CLI   0(GR3),0                 SCAN DPWORR FOR LEVELS WITHOUT  16220000
         BE    LPC1-8                    ASSOCIATED RR                  16240000
         BAL   GR4,GENBAL               BRANCH TO GENERATE BAL TO       16260000
         LA    GR4,1                     CLSUB9                         16280000
         LA    GR2,CLSUBL(GR2)          ADVANCE TO NEXT CLSUBR ENTRY PT 16300000
LPC1     BXLE  GR3,GR4,LOOP1            BRANCH IF NOT AT END OF DPWORR  16320000
         ST    GR1,PACWS                                                16340000
         LA    GR1,DPWRR                                                16360000
         LA    GR6,DPWRR+891                                            16380000
         L     GR15,RR01                SCAN DPWRR FOR LEVELS WITH RR   16400000
LOOP2    OC    0(9,GR1),0(GR1)                                          16420000
         BC    7,GENCLR                 BRANCH IF LEVELS FOR A RR GROUP 16440000
         LA    GR1,9(GR1)                                               16460000
LPC2     LA    GR15,1(GR15)             ADVANCE TO NEXT RR IND ADDR     16480000
         CLR   GR1,GR6                  TEST FOR END OF DPWRR           16500000
         BNE   LOOP2                    BRANCH IF NOT AT END            16520000
         BAL   GR12,CK4UBA                                              16540000
         BAL   GR14,DMPTXT              OTHERWISE GENERATE BR GR14 AS   16560000
         DC    AL2(2)                    LAST INST OF THE MCL2WS SUBR   16580000
         DC    AL4(BRGR14)                                              16600000
         LA    GR11,2(GR11)                                             16620000
         L     GR1,PACWS                                                16640000
         XC    DPWORR(9),DPWORR         CLEAR DPWORR                    16660000
GENBX    MVC   0(3,GR13),ADDCNT+1(GR7)  SAVE ADDR OF SUBR               16680000
         LA    GR13,3(GR13)                                             16700000
         BAL   GR15,ADD2AC              BRANCH TO UPDATE ADDR COUNT     16720000
         XC    PREVRR(2),PREVRR                                         16740000
         B     CK4EOR+8                                                 16760000
         SPACE 1                                                        16780000
GENCLR   LA    GR3,DPWORR                                               16800000
         SR    GR2,GR2                                                  16820000
         BAL   GR12,CK4UBA                                              16840000
LOOP3    CLC   0(1,GR3),0(GR1)          IF CORRESPONDING LEVEL OF THE   16860000
         BE    LP3C                      RR GROUP IN DPWORR THEN BYPASS 16880000
         CLI   0(GR3),0                 TEST CORRESPONDING ENTRY IN     16900000
         BE    IFUBA                     DPWORR TO BE ZERO (BE IF ZERO) 16920000
         B     LP3C                     OTHERWISE ERROR                 16940000
*   ADD CODE HERE FOR DIAGNOSTIC                                        16960000
         SPACE 1                                                        16980000
IFUBA    CLI   ABCUSE,0                 TEST FOR CODING TO TEST IND     17000000
         BNE   *+12                      PREVIOUSLY GENERATED           17020000
         STH   GR15,CLIBNE+2            IF NOT GENERATE                 17040000
         BAL   GR12,FLDREL+10                                           17060000
         BAL   GR4,GENBAL               BRANCH TO GENERATE BAL TO       17080000
         LA    GR4,1                     "CSUBR                         17100000
LP3C     LA    GR2,CLSUBL(GR2)                                          17120000
         MVI   0(GR1),0                 CLEAR DPWRR ENTRY               17140000
         LA    GR1,1(GR1)                                               17160000
         LA    GR5,DPWORR+8                                             17180000
         BXLE  GR3,GR4,LOOP3            CONTINUE IF NOT AT END OF RR    17200000
         B     LPC2                      GROUP                          17220000
GENBAL   STH   GR2,XBAL+2               PLACE DISPLACEMENT TO CLSUBR    17240000
         BAL   GR14,DMPTXT               ENTRY POINT TO BAL INST        17260000
         DC    AL2(4)                                                   17280000
         DC    AL4(XBAL)                                                17300000
         LA    GR11,4(GR11)                                             17320000
         BR    GR4                                                      17340000
         EJECT                                                          17360000
*********************************************************************** 17380000
*   GENMF GENERATES THE OBJ PROG SUBR, MFSUBR, WHICH SUPPLIES THE     * 17400000
*  INPUT DATA AREA ADDR AND LENGTH OF MATCHING FIELDS TO THE PROCMF   * 17420000
*  ROUTINE WITHIN DRTY2 SUBR (SEE PROCMF IN CANNED OBJECT CODE OUTPUT * 17440000
*  BY PASS 2).                                                        * 17460000
*   THE FOLLOWING INSTRUCTIONS ARE GENERATED FOR EACH MATCHING FIELD  * 17480000
*                                                                     * 17500000
*   IF AN ASSOCIATED FIELD-RECORD RELATION INDICATOR IS PRESENT       * 17520000
*  (NOTE, IF A GROUP OF FIELDS IS ENCOUNTERED WITH THE SAME IND THE   * 17540000
*   INSTRUCTIONS BELOW ARE GENERATED ONLY ONCE FOR THE GROUP)         * 17560000
*                                                                     * 17580000
*        CLI   RI(GR3),X'F0'            TEST IF FLD-REC REL IND ON    * 17600000
*        BNE   NEXT                     BRANCH IF NOT                 * 17620000
*                                                                     * 17640000
*   IF THE FIELD-RECORD RELATION INDICATOR IS NOT PRESENT             * 17660000
*                                                                     * 17680000
*        CLI   N-1(GR14),0              TEST FOR LENGTH OF LEVEL N FLD* 17700000
*        BNE   NEXT                      PLACED IN RETURN VECTOR BY A * 17720000
*                                        PREVIOUSLY ENCOUNTER FLD WITH* 17740000
*                                        A FLD-REC REL IND WHICH IS ON* 17760000
*                                                                     * 17780000
*   THE FOLLOWING INSTRUCTIONS ARE GENERATED FOR EACH MATCHING FIELD  * 17800000
         SPACE 1                                                        17820000
LAMVI    LA    0,0(0,0)                 LOAD REG WITH INPUT AREA ADDR   17840000
         MVI   0(GR14),0                PLACE FLD LENGTH IN RETURN      17860000
         SPACE 1                                                        17880000
*   THE FOLLOWING INSTRUCTION IS GENERATED IF THE FIELD IS NUMERIC      17900000
*    - THIS RETURNS A TYPE BYTE USE BY THE PROCMF OBJECT ROUTINE      * 17920000
         SPACE 1                                                        17940000
MVITYB   MVI   0(GR14),0                                                17960000
*                                                                     * 17980000
*********************************************************************** 18000000
         SPACE 1                                                        18020000
GENMF    CLI   CLS,0                                                    18040000
         BNE   CK4EOR                                                   18060000
         MVI   TRIGER,X'F0'             SET INDICATOR, MF SPECS PRESENT 18080000
         LA    GR0,15                    SPEC WITHOUT FLD-REC REL IND   18100000
         IC    GR4,NB(GR1)                                              18120000
         NR    GR4,GR0                  GR4 = MATCHING FIELD NO. (1-3)  18140000
         BCTR  GR4,0                                                    18160000
         CLI   RR(GR1),X'FD'            TEST FOR NO RR                  18180000
         BNE   MFWRR                    BRANCH IF RR                    18200000
         BAL   GR12,CK4UBA              OTHERWISE PROCESS MATCHING FLD  18220000
         STC   GR4,CLIBNE+3                                             18240000
         MVI   CLIBNE+2,X'E0'                                           18260000
         MVI   CLIBNE+1,0                                               18280000
         BAL   GR12,FLDREL+10                                           18300000
         MVI   CLIBNE+1,X'F0'                                           18320000
GENMF2   STC   GR4,LAMVI+7                   PLACE N-1 IN D2 FIELD OF   18340000
         LA    GR4,10(GR4)                    MVI INST                  18360000
         SLL   GR4,4                         PLACE REC NO. IN R1 FIELD  18380000
         STC   GR4,LAMVI+1                    LA INST                   18400000
         MVC   LAMVI+2(2),FF(GR1)            PLACE INPUT ADDR (BDDD)    18420000
         IC    GR4,LG(GR1)                    IN LA INST                18440000
         LA    GR4,1(GR4)                    PLACE FLD LENGTH IN I2     18460000
         STC   GR4,LAMVI+5                                              18480000
         LA    GR11,8(GR11)              FIELD OF MVI INST              18500000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT INSTRUCTIONS   18520000
         DC    AL2(8)                                                   18540000
         DC    AL4(LAMVI)                                               18560000
         CLI   FTYPE(GR1),X'40'         TEST MF TO BE ALPHA             18580000
         BE    CK4EOR                   BRANCH IF ALPHA                 18600000
         IC    GR4,LAMVI+7              OTHERWISE FOR NUMERIC GENERATE  18620000
         LA    GR4,3(GR4)                A MVI TO RETURN TYPE BYTE TO   18640000
         STC   GR4,MVITYB+3              PROCMF                         18660000
         MVC   MVITYB+1(1),FTYPE(GR1)   FORM THE MVI INSTRUCTION        18680000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           18700000
         DC    AL2(4)                                                   18720000
         DC    AL4(MVITYB)                                              18740000
         LA    GR11,4(GR11)             UPDATE ADDR COUNTER             18760000
         B     CK4EOR                                                   18780000
         SPACE 1                                                        18800000
*   PROCESS MATCHING FIELD SPEC WITH A FIELD-RECORD RELATION INDICATOR  18820000
         SPACE 1                                                        18840000
MFWRR    BAL   GR15,PROCRR              PROCESS RR (FLD-REC REL IND)    18860000
         B     GENMF2                                                   18880000
         SPACE 2                                                      * 18900000
*********************************************************************** 18920000
*   END ASSEMBLE PHASE 2 PASS1                                        * 18940000
*********************************************************************** 18960000
         SPACE 1                                                        18980000
ENDP1    SR    GR11,GR11                GENERATE OBJ SUBR TO TURN OFF   19000000
         LA    GR1,RI01                  INPUT RECORD INDICATORS (SUBR  19020000
         LA    GR2,RITAB                 IS EXECUTED BEFORE EACH RECORD 19040000
         LA    GR4,1                     IS READ)                       19060000
         LA    GR5,RITAB+98                                             19080000
         MVC   RRIOFF(4),ADDCNT(GR7)    SAVE OBJ ADDR OF SUBR           19100000
NXTRI    CLI   0(GR2),X'F0'                                             19120000
         BNE   IFDONE                                                   19140000
         STC   GR1,TRIOFF+3                                             19160000
         BAL   GR14,DMPTXT              OUTPUT MVI  RI(GR3),0  TO TURN  19180000
         DC    AL2(4)                    OFF EACH INDICATOR USED        19200000
         DC    AL4(TRIOFF)                                              19220000
         LA    GR11,4(GR11)                                             19240000
IFDONE   LA    GR1,1(GR1)                                               19260000
         BXLE  GR2,GR4,NXTRI                                            19280000
         BAL   GR14,DMPTXT              COMPLETE SUBR WITH  BCR 15,14   19300000
         DC    AL2(2)                                                   19320000
         DC    AL4(BRGR14)                                              19340000
         LA    GR11,2(GR11)                                             19360000
         BAL   GR15,ADD2AC+4            ADVANCE OBJ ADDR COUNTER        19380000
         BAL   GR14,FINTXT              BRANCH TO EMPTY TEXT BUFFER     19400000
DATOUT   LM    GR4,GR12,CIXSAV          RESTORE CIOEX REGISTERS (4-7)   19420000
         LA    GR2,PNTBLK               POSITION WORK FILE AT ORGIN     19440000
         BAL   GR14,IOEXC                                               19460000
          LA   1,DATOUT2                                                19480000
          LA   2,24                     WRITE OUT HEADER RECORD         19500000
         BALR  5,7                                                      19520000
          LA   3,ADTMVF                                                 19540000
          LH   13,DATOUT4                                               19560000
DATOUT1   LR   1,3                      WRITE OUT DATA                  19580000
          LA   2,24                                                     19600000
          BALR 5,7                                                      19620000
          AH   3,DATOUT2                                                19640000
          SH   13,DATOUT2                                               19660000
          BP   DATOUT1                  TEST IF FINISHED,NO*TAKE BRANCH 19680000
         MVC   PHSNAM(8,GR7),P2NAME    SET CIOEX TO LOAD ASSEMBLE 2     19700000
EXITP1   LA    GR2,PHSCAL                PASS 2 NEXT                    19720000
         BALR  GR5,GR12                 BRANCH TO CIOEX                 19740000
TRIOFF   MVI   0(GR3),0                                                 19760000
         SPACE 1                                                        19780000
*********************************************************************** 19800000
*   DPWRR IS A TABLE USED BY GENCLM FOR PROCESSING CONTROL LEVELS WITH* 19820000
*  AN ASSOCIATED FIELD-RECORD RELATION INDICATOR. THE TABLE IS TWO    * 19840000
*  DIMENSIONAL (99X9) TO ALLOW 9 LEVELS FOR THE MAXIMUM OF 99 INDI-   * 19860000
*  CATORS .                                                           * 19880000
*********************************************************************** 19900000
         SPACE 1                                                        19920000
DPWRR    EQU   *                        OVERLAYS FOLLOWING CODE         19940000
         EJECT                                                          19960000
*********************************************************************** 19980000
*   GENCHR SUBR GENERATES THE EXIT FROM MVFLDS (OBJECT PROGRAM SUBR)  * 20000000
*********************************************************************** 20020000
         SPACE 2                                                        20040000
*********************************************************************** 20060000
*   IF CHAINING FIELDS ARE PRESENT IN THE RECORD GROUP THE FOLLOWING  * 20080000
*  INSTRUCTIONS ARE GENERATED                                         * 20100000
*                                                                     * 20120000
LMDE     LM    GR13,GR14,SA4DE(GR8)     RESTORE 13-14 BEFORE EXITING    20140000
BRCHNG   L     GR15,LVCHNG(GR3)                                         20160000
         BALR  GR8,0                                                    20180000
         LA    GR0,6(GR8)               GR0 = ADDR OF CHL               20200000
         BR    GR15                     BRANCH TO CHAINING SUBR         20220000
CHL      DC    X'B006'                                                  20240000
         DS    CL4                                                      20260000
*********************************************************************** 20280000
         SPACE 2                                                        20300000
*********************************************************************** 20320000
*   IF CHAINING FIELDS ARE NOT PRESENT IN THE RECORD GROUP THE        * 20340000
*  FOLLOWING INSTRUCTION IS GENERATED                                 * 20360000
*                                                                     * 20380000
*        LM    GR13,GR14,SA4DE(GR8)     RESTORE 13-14 BEFORE EXITING  * 20400000
*        BR    GR14                     RETURN TO MASTER DRIVER       * 20420000
*********************************************************************** 20440000
         SPACE 2                                                        20460000
GENCHR   BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           20480000
         DC    AL2(4)                    (LM INSTRUCTION TO RESTORE     20500000
         DC    AL4(LMDE)                  GR13 GR14 FOR MASTER DRIVER)  20520000
         LA    GR11,4(GR11)                                             20540000
         L     GR1,CHFPTR               TEST FOR CHAINING FIELDS        20560000
         LTR   GR1,GR1                   PRECEDING RECORD GROUP         20580000
         BZ    NOCHR                    BRANCH IF NO CHAINING FIELDS    20600000
         LA    GR2,4(GR11)                                              20620000
         SR    GR2,GR1                  PLACE DECREMENT TO FIRST CHAIN- 20640000
         STH   GR2,BRCHNG+16             ING BLK INTO CALLING SEQUENCE  20660000
         XC    CHFPTR(4),CHFPTR         CLEAR CHFPTR                    20680000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           20700000
         DC    AL2(18)                                                  20720000
         DC    AL4(BRCHNG)                                              20740000
         LA    GR11,18(GR11)            ADVANCE OBJ PROG ADDR           20760000
         B     XITMVS-4                 EXIT GENCHR SUBR                20780000
NOCHR    BAL   GR14,DMPTXT              BRANCH TO OUTPUT BR GR15 FOR    20800000
         DC    AL2(2)                    RECORD GROUP WITHOUT CHAINING  20820000
         DC    AL4(FLDNDX)                                              20840000
         LA    GR11,2(GR11)             ADVANCE OBJ PROG ADDR           20860000
         BAL   GR15,ADD2AC                                              20880000
XITMVS   BR    GR12                     EXIT GENCHR SUBR                20900000
         EJECT                                                          20920000
*********************************************************************** 20940000
*   RMFLCK IS EXECUTED WHEN A NEW RECORD GROUP IS DETECTED AND IF     * 20960000
*  MATCHING FIELDS WERE PRESENT IN THE PRECEDING RECORD GROUP. THE    * 20980000
*  LENGTH OF M1-M3 FIELDS IN THE PRECEDING RECORD GROUP IS CHECKED    * 21000000
*  TO BE EQUAL TO THAT FOR ALL PREVIOSLY PROCESSED RECORD GROUPS OF   * 21020000
*  THE FILE GROUP                                                     * 21040000
*********************************************************************** 21060000
         SPACE 1                                                        21080000
RMFLCK   LA    GR5,1                    TEST FOR MF'S IN PRECEDING REC  21100000
         CH    GR5,MFTPTR                                               21120000
         BCR   2,GR15                   BRANCH IF NONE                  21140000
         BE    RMFCK2                   BRANCH IF ONLY ONE SET          21160000
         LH    GR5,MFTPTR               IF MORE THAN ONE SET            21180000
         LA    GR12,MFLTAB               OBTAIN MAX LENGTH AND STORE    21200000
         SR    GR1,GR1                   IN 1ST BYTE OF MFLTAB          21220000
         SR    GR2,GR2                                                  21240000
         IC    GR1,0(GR12)                                              21260000
TST4GL   IC    GR2,1(GR12)                                              21280000
         CR    GR1,GR2                                                  21300000
         BNL   *+6                                                      21320000
         LR    GR1,GR2                                                  21340000
         LA    GR12,1(GR12)                                             21360000
         BCT   GR5,TST4GL                                               21380000
         STC   GR1,MFLTAB                                               21400000
RMFCK2   CLC   TMFL(1),MFLTAB           COMPARE WITH LENGTH OF M1-M3    21420000
         BE    RMFLCX                    FOR PREVIOUS GROUPS            21440000
         CLI   TMFL,0                                                   21460000
         BE    RMFLCX-6                                                 21480000
         OI    ERNO64,X'F0'             IF NOT EQ TO LENGTH FOR PRE-    21500000
         B     RMFLCX                    VIOUS GROUPS SET INDICATOR     21520000
*                                        TO PUT OUT ERROR NOTE          21540000
         MVC   TMFL(1),MFLTAB                                           21560000
RMFLCX   XC    MFTPTR(2),MFTPTR         CLEAR TABLES FOR PROCESSING     21580000
         XC    MFTARG(200),MFTARG        NEXT RECORD GROUP              21600000
         XC    MFDUPS(100),MFDUPS                                       21620000
         BR    GR15                                                     21640000
         EJECT                                                          21660000
*********************************************************************** 21680000
*   FMFLCK IS EXECUTED WHEN A NEW INPUT FILE GROUP IS DETECTED OR     * 21700000
*  AFTER THE LAST INPUT FILE GROUP AND IF MATCHING FIELDS WERE PRESENT* 21720000
*  IN THE PRECEDING FILE GROUP. THE FOLLOWING VALITIDY CHECKING FOR   * 21740000
*  MATCHING FIELDS IS PERFORMED.                                      * 21760000
*                                                                     * 21780000
*   IF MULTI FILES (PRIMARY AND SECONDARY) ARE SPECIFIED A WARNING    * 21800000
*  NOTE IS PUT OUT IF MATCHING FIELDS ARE NOT SPECIFIED FOR THE       * 21820000
*  PRIMARY FILE                                                       * 21840000
*                                                                     * 21860000
*   A WARNING NOTE IS PUT OUT IF MATCHING FIELDS ARE OMITTED FOR A    * 21880000
*  SECONDARY FILE                                                     * 21900000
*                                                                     * 21920000
*   IF THE LENGTH OF M1-M3 IS NOT THE SAME FOR EACH OF THE SEONDARY   * 21940000
*  FILES (WHERE MATCHING FIELDS ARE SPECIFIED) AND THE PRIMARY FILE   * 21960000
*  AN INDICATOR IS SET TO PUT OUT AN ERROR NOTE AT END OF PASS 1      * 21980000
*                                                                     * 22000000
*   IF AN INDICATOR WAS TURNED ON BY RMFLCK, PUT OUT ERROR NOTE 64    * 22020000
*********************************************************************** 22040000
         SPACE 1                                                        22060000
FMFLCK   LA    GR1,FET-1                GR1 POINTS TO FET ENTRY FOR     22080000
         SR    GR2,GR2                   PRECEDING FILE                 22100000
         IC    GR2,FILENO                                               22120000
         AR    GR1,GR2                                                  22140000
         CLI   TMFL,0                   TEST FOR PRESENCE OF MATCHING   22160000
         BALR  GR2,0                     FLDS IN PRECEDING FILE GROUP   22180000
         BE    *+8                      BRANCH IF NONE                  22200000
         OI    0(GR1),X'10'             OTHERWISE SET BIT INFET BYTE    22220000
         TM    0(GR1),X'C0'             TEST FOR FILE TYPE              22240000
         BZ    PRIM                     BRANCH IF PRIMARY               22260000
         BM    SECOND                   BRANCH IF SECONDARY             22280000
         SPM   GR2                      EXIT IF CHAINNED FILE AND       22300000
         BCR   8,GR15                    NO MATCHING FIELDS             22320000
         L     GR5,CHFMFP               OTHERWISE CHAINED FILE          22340000
         LA    GR5,1(GR5)               GR5 POINTS TO ENTRY IN CHFMFL   22360000
         ST    GR5,CHFMFP                FOR PRECEDING FILE. PLACE TMFL 22380000
         MVC   0(1,GR5),TMFL             (MF'S LENGTH) INTO CHFMFL      22400000
         B     FMFLCX                                                   22420000
SECOND   SPM   GR2                      TEST FOR MF'S FOR SECONDARY     22440000
         BNE   PEQS                     BRANCH IF PRESENT               22460000
         LA    GR5,NOTE62               OTHERWISE PUT OUT WARNING NOTE  22480000
         B     ERROR                                                    22500000
PRIM     CLI   MULTI,0                  TEST FOR MULTI FILES            22520000
         BE    FMFLCX-6                 BRANCH IF NOT                   22540000
         SPM   GR2                      TEST FOR MF'S FOR PRIMARY       22560000
         BNE   PEQS                     BRANCH IF PRESENT               22580000
         LA    GR5,NOTE61               OTHERWISE PUT OUT WARNING NOTE  22600000
         B     ERROR                                                    22620000
PEQS     CLC   TMFL(1),PSFMFL           TEST M1-M3 FOR PRIM AND SECOND  22640000
         BE    FMFLCX                    TO BE EQ (BRANCH IF EQUAL)     22660000
         CLI   PSFMFL,0                 TEST PSFMFL TO BE ZERO (BRANCH  22680000
         BE    FMFLCX-6                  IF ZERO, 1ST FILE OF THE SET)  22700000
         OI    ERNO63,X'F0'             OTHERWISE SET INDICATOR TO PUT  22720000
         B     FMFLCX                    OUT ERROR NOTE                 22740000
         MVC   PSFMFL(1),TMFL                                           22760000
FMFLCX   CLC   MFS(1),TMFL              COMPARE M1-M3 TO PREVIOUS FILES 22780000
         BNL   *+10                     BRANCH IF LENGTH NOT GREATER    22800000
         MVC   MFS(1),TMFL              OTHERWISE SAVE AS MAX LENGTH    22820000
         MVI   TMFL,0                   CLEAR TMFL FOR NEXT FILE GROUP  22840000
         CLI   ERNO64,X'F0'             TEST IF IND ON FOR NOTE 64      22860000
         BNE   0(GR15)                  BRANCH IF NOT (EXIT FMFLCK)     22880000
         MVI   ERNO64,0                 OTHERWISE PUT OUT ERROR NOTE    22900000
         LA    GR5,NOTE64                                               22920000
         B     ERROR                                                    22940000
         EJECT                                                          22960000
*********************************************************************** 22980000
*   PASS 1 PROCESSING OF THE INPUT FIELD TYPE SPEC.                   * 23000000
*  GENERATE THE INSTRUCTIONS WHICH MOVE INPUT DATA INTO ASSIGNED      * 23020000
*  FIELDS, TEST FIELD STATUS, AND SET FIELD INDICATORS. GENERATE      * 23040000
*  CHAINING BLOCK FOR CHAINING FIELDS                                 * 23060000
*********************************************************************** 23080000
         SPACE 2                                                        23100000
*********************************************************************** 23120000
*   FOR NUMERIC INPUT DATA, GENERATE THE CALLING SEQUENCE BELOW TO    * 23140000
*  CALL ON THE OBJECT PROGRAM SUBR THAT MOVES DATA INTO THE ASSIGNED  * 23160000
*  FIELD AREA AND TEST STATUS                                         * 23180000
         SPACE 1                                                        23200000
MV2FLD   LA    GR1,0                    GR1 = FIELD ADDR                23220000
         LA    GR10,0                   GR10= INPUT DATA ADDR           23240000
         LA    GR11,0                   GR11 = LENGTH OF INPUT AND FLD  23260000
         BAL   GR7,0(GR8)               BRANCH TO OBJECT PROGRAM SUBR   23280000
         DC    X'B008'                  DATA IDENTIFER (COMPILER USE)   23300000
         DS    CL6                      FIELD INDICATORS USED PPMMZZ    23320000
*                                         PP = PLUS INDICATOR         * 23340000
*                                         MM = MINUS                  * 23360000
*                                         ZZ = BLANK OR ZERO          * 23380000
*********************************************************************** 23400000
         SPACE 1                                                        23420000
FLDTYP   ZAP   PACWS(8),2(3,GR3)                                        23440000
         CVB   GR1,PACWS                LOAD GR1 WITH THE ADRR (BDDD)   23460000
         BCTR  GR1,0                                                    23480000
         A     GR1,B2                    OF THE INPUT DATA (B= GR2)     23500000
         MVC   PACWS+2(2),9(GR3)                                        23520000
         L     GR0,PACWS                LOAD GR0 WITH THE FIELD ADDR    23540000
         LA    GR13,15(GR13)            LOAD GR13 (CMPPTR) WITH ADDR    23560000
*                                        OF VARIABLE PART OF FIELD SPEC 23580000
         CLC   14(1,GR3),OVFLOW         TEST FLD ADDR OVERFLOW          23600000
         BE    SAORN                    BR IF ZERO OR EQ PRECEDING FLD  23620000
         SR    GR5,GR5                                                  23640000
         IC    GR5,14(GR3)                                              23660000
         STC   GR5,OVFLOW               SAVE OVERFLOW INDICATION (1-4)  23680000
         SPACE 1                                                        23700000
*   IF DATA ADDRESS OVERFLOW GENERATE THE FOLLOWING INSTRUCTION TO LOAD 23720000
*  GR7 IN THE OBJECT PROGRAM                                            23740000
*                                                                       23760000
*        LA    7,LVOVFN(3)              N = 1-4                         23780000
         SPACE 1                                                        23800000
         LA    GR4,LVOVF1-4                                             23820000
         LA    GR4,4(GR4)                                               23840000
         BCT   GR5,*-4                                                  23860000
         STH   GR4,OVLGR7+2                                             23880000
         OI    OVLGR7+2,X'30'                                           23900000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           23920000
         DC    AL2(4)                                                   23940000
         DC    AL4(OVLGR7)                                              23960000
         LA    GR11,4(GR11)             ADVANCE OBJ PROG ADDR           23980000
SAORN    SR    GR2,GR2                                                  24000000
         IC    GR2,5(GR3)               LOAD L (LENGTH) INTO GR2        24020000
         TM    1(GR3),X'02'             TEST FOR STERLING FIELD         24040000
         BO    STERNG                   BRANCH IF STERLING              24060000
         CLI   8(GR3),X'40'             TEST FOR ALPHAMERIC FIELD       24080000
         BE    ALPHA                    BRANCH IF ALPHAMERIC            24100000
         STH   GR0,MV2FLD+2             PLACE FLD ADDR IN CALLING SEQ   24120000
         STH   GR1,MV2FLD+6             PLACE ADDR OF INPUT IN CALL SEQ 24140000
         TM    8(GR3),X'F0'             TEST FOR PACKED OR UNPACKED     24160000
         BM    PACKED                   BRANCH IF PACKED                24180000
         SPACE 1                                                        24200000
*   UNPACKED NUMERIC INPUT DATA, GENERATE CALL ON MOVE FIELDS SUBR TO   24220000
*  PACK DATA INTO FIELD AREA                                            24240000
         SPACE 1                                                        24260000
         LR    GR5,GR2                  COMPUTE LENGTH (NO. OF BYTES-1) 24280000
         LA    GR2,1(GR2)                FOR PACKED FLD L = INTEGER     24300000
         SRL   GR2,1                     OF (L+1/2)+1                   24320000
         BAL   GR15,FLDOPS              BRANCH TO PROCESS CL,REL,CH,MF  24340000
         SR    GR5,GR5                                                  24360000
         IC    GR5,5(GR3)                                               24380000
         SLL   GR2,4                    GR5 CONTAINS LENGTH OF PACKED   24400000
         OR    GR2,GR5                   FLD (BITS 24-27) AND LENGTH OF 24420000
*                                        INPUT DATA (BITS 28-31)        24440000
         LA    GR5,PAC                  GR5 = DISPLACEMENT FOR ENTRY    24460000
         B     GENZAP+4                  TO MOVE FLD SUBR               24480000
         SPACE 1                                                        24500000
*   PACKED NUMERIC INPUT DATA, GENERATE CALL ON MOVE FIELDS SUBR TO     24520000
*  MOVE DATA INTO FIELD AREA                                            24540000
         SPACE 1                                                        24560000
PACKED   LA    GR2,1(GR2)               COMPUTE LENGTH (NUMBER BYTES-1) 24580000
         SRL   GR2,1                     FOR PACKED FLD (LENGTH IN GR2) 24600000
         BAL   GR15,FLDOPS              BRANCH TO PROCESS CL,REL,CH,MF  24620000
         LR    GR5,GR2                                                  24640000
         SLL   GR2,4                                                    24660000
         OR    GR2,GR5                  FORM L1-L2 IN GR2               24680000
GENZAP   LA    GR5,ZAP                  GR5 = DISPLACEMENT FOR ENTRY    24700000
         STC   GR2,MV2FLD+11            PLACE LENGTH(S) IN CALLING SEQ  24720000
         LA    GR4,16                   GR4 = LENGTH OF CALLING SEQ     24740000
         BAL   GR14,FLDIND              BRANCH TO PROCESS FLD INDICATOR 24760000
         STC   GR5,MV2FLD+15            PLACE ENTRY DISPL IN CALL SEQ   24780000
         AR    GR11,GR4                 ADVANCE OBJ PROG ADDR           24800000
         STH   GR4,*+8                  PLACE LENGTH IN DMPTXT CALL     24820000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           24840000
         DC    AL2(0)                                                   24860000
         DC    AL4(MV2FLD)                                              24880000
CK4UDB   BAL   GR12,CK4UBA              TEST FOR UBA                    24900000
         B     ADV2NX                   BRANCH TO GET NEXT SPEC         24920000
         EJECT                                                          24940000
*********************************************************************** 24960000
*   IF FIELD INDICATORS ARE PRESENT FOR NUMERIC FIELDS PLACE THE ADDR * 24980000
*  OF EACH IND USED INTO CALLING SEQUENCE FOR THE MOVE FIELDS SUBR    * 25000000
*  AND CHANGE THE ENTRY DISPLACEMENT SO THE MOVE AND STATUS CHECK ARE * 25020000
*  PERFORMED                                                          * 25040000
*********************************************************************** 25060000
         SPACE 1                                                        25080000
FLDIND   TM    1(GR3),X'1C'             TEST FOR FIELD INDICATORS       25100000
         BZ    0(GR14)                  BRANCH IF NONE                  25120000
         LA    GR4,8(GR4)               OTHERWISE INCREASE LENGTH OF    25140000
*                                        CALL SEQ FOR FLD IND INFO      25160000
         LA    GR5,4(GR5)               CHANGE ENTRY DISPLACEMENT       25180000
         XC    MV2FLD+18(6),MV2FLD+18                                   25200000
         TM    1(GR3),X'10'             TEST FOR PLUS FLD INDICATOR     25220000
         BZ    MINUSN                   BRANCH IF NONE                  25240000
         MVC   MV2FLD+18(2),0(GR13)     OTHERWISE PLACE ADDR OF IND     25260000
         LA    GR13,2(GR13)              IN CALLING SEQUENCE            25280000
MINUSN   TM    1(GR3),X'08'             TEST FOR MINUS FLD INDICATOR    25300000
         BZ    ZEORB                    BRANCH IF NONE                  25320000
         MVC   MV2FLD+20(2),0(GR13)     OTHERWISE PLACE ADDR OF IND     25340000
         LA    GR13,2(GR13)              IN CALLING SEQUENCE            25360000
ZEORB    TM    1(GR3),X'04'             TEST FOR ZERO OR BLANK IND      25380000
         BZ    0(GR14)                  BRANCH IF NONE                  25400000
         MVC   MV2FLD+22(2),0(GR13)     OTHERWISE PLACE ADDR OF IND     25420000
         LA    GR13,2(GR13)              IN CALLING SEQUENCE            25440000
FLDNDX   BR    GR14                     EXIT FLDIND                     25460000
         EJECT                                                          25480000
*   ALPHAMERIC INPUT DATA, GENERATE MVC  FLD(L,GRN),FFF(GR2)            25500000
         SPACE 1                                                        25520000
*     WHERE  FLD(GRN) = FIELD ADDRESS, L = LENGTH, AND                  25540000
*             FFF(GR2) = INPUT DATA ADDRESS                             25560000
         SPACE 1                                                        25580000
*********************************************************************** 25600000
*   IF ALPHAMERIC FIELD HAS A BLANK INDICATOR, GENERATE THE FOLLOWING * 25620000
*  CALL ON TEST4B SUBR                                                * 25640000
         SPACE 1                                                        25660000
IFBL     EQU   16                       DISPLACEMENT FOR ENTERING       25680000
*                                        TEST4B SUBR                    25700000
         SPACE 1                                                        25720000
ALFTST   LA    GR1,0                    GR1 = FIELD ADDR                25740000
         LA    GR11,0(0)                GR11 = LENGTH OF FIELD          25760000
         BAL   GR7,IFBL(GR8)            BRANCH TO TEST FOR BLANK FIELD  25780000
         DC    X'B004'                                                  25800000
         DS    CL2                      ADDR OF BLANK INDICATOR         25820000
*********************************************************************** 25840000
         SPACE 1                                                        25860000
ALPHA    BAL   GR15,FLDOPS              BRANCH TO PROCESS CL,REL,CH,MF  25880000
         LA    GR6,MVF                                                  25900000
         BAL   GR15,GENMVF              BRANCH TO GENERATE MVC INST     25920000
         SPACE 1                                                        25940000
         TM    1(GR3),X'04'             TEST FOR BLANK INDICATOR        25960000
         BZ    CK4UDB                   BRANCH IF NONE                  25980000
         STH   GR0,ALFTST+2             PLACE FLD ADDR IN CALLING SEQ   26000000
         STC   GR2,ALFTST+7             PLACE FLD LENGTH IN CALLING SEQ 26020000
         MVC   ALFTST+14(2),0(GR13)     PLACE ADDR OF FLD IND IN CALL   26040000
         LA    GR13,2(GR13)             ADVANCE CMPPTR                  26060000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           26080000
         DC    AL2(16)                                                  26100000
         DC    AL4(ALFTST)                                              26120000
         LA    GR11,16(GR11)            ADVANCE OBJ PROG ADDR           26140000
         B     CK4UDB                   BRANCH TO GET NEXT SPEC         26160000
         EJECT                                                          26180000
*********************************************************************** 26200000
*   STERLING INPUT DATA, GENERATE THE FOLLOWING CALLING SEQUENCE FOR  * 26220000
*  THE STERLING INPUT CONVERSION SUBR (OBJECT PROGRAM SUBROUTINE)     * 26240000
         SPACE 1                                                        26260000
STRLNG   L     GR10,STERIN(GR3)         GR10 = ADDR OF CONVERSION SUBR  26280000
         BALR  GR1,GR10                 BRANCH TO CONVERSION SUBR       26300000
         DC    X'B00C'                  DATA IDENTIFER (COMPILER USE)   26320000
         DS    H                        DISPLACEMENT TO FIELD           26340000
         DS    H                        DISPLACEMENT TO SIGN            26360000
         DS    C                        NO. OF DECIMAL PENCE POSITIONS  26380000
         DS    C                        SOURCE LENGTH-1                 26400000
         DS    CL4                      BDDD LL    (TARGET FIELD)       26420000
*********************************************************************** 26440000
         SPACE 1                                                        26460000
STERNG   STH   GR0,MV2FLD+2                                             26480000
         BAL   GR15,FLDOPS              BRANCH TO PROCESS CL,REL,CH,MF  26500000
         SR    GR5,GR5                                                  26520000
         BAL   GR14,FLDIND              BRANCH TO PROCESS FIELD IND(S)  26540000
         SH    GR1,B2+2                                                 26560000
         STH   GR1,STRLNG+8             DISPL TO FLD INTO STERIN CALL   26580000
         CLI   3(GR13),C'S'             TEST NORMAL SIGN POSITION       26600000
         BNE   *+10                     BRANCH IF NOT                   26620000
         SR    GR1,GR1                  OTHERWISE PLACE X'FFFF' INTO    26640000
         BCT   GR1,*+14                  STERIN CALLING SEQUENCE        26660000
         PACK  PACWS(8),0(4,GR13)       CONVERT SIGN POSITION (OTHER    26680000
         CVB   GR1,PACWS                 THAN NORMAL) AND PLACE INTO    26700000
         LA    GR13,4(GR13)             ADVANCE CMPPTR                  26720000
         STH   GR1,STRLNG+10              STERIN CALLING SEQUENCE       26740000
         IC    GR1,8(GR3)               PLACE NUMBER OF DECIMAL PENCE   26760000
         STC   GR1,STRLNG+12             POSITIONS INTO STERIN CALL     26780000
         NI    STRLNG+12,X'0F'                                          26800000
         STC   GR2,STRLNG+13            SOURCE LENGTH INTO STERIN CALL  26820000
         MVC   STRLNG+14(2),9(GR3)      TARGET FLD ADDR TO STERIN CALL  26840000
         LA    GR2,1(GR2)               COMPUTE TARGET FLD LENGTH AND   26860000
         SRL   GR2,1                     PLACE IN STERIN CALLING SEQ    26880000
         STC   GR2,STRLNG+16                                            26900000
         MVI   STRLNG+17,0              FLD ADDR OVERFLO TO STERN CALL  26920000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT (STERIN   26940000
         DC    AL2(18)                   CALLING SEQUENCE)              26960000
         DC    AL4(STRLNG)                                              26980000
         LA    GR11,18(GR11)            ADVANCE OBJ PROG ADDR           27000000
         LTR   GR5,GR5                  ARE FIELD INDICATORS PRESENT    27020000
         BZ    CK4UDB                   BRANCH IF NONE                  27040000
*                                       OTHERWISE GENERATE CALLING      27060000
*                                        SEQUENCE FOR FLD STATUS SUBR   27080000
         LR    GR5,GR2                  FORM L1-L2 IN GR2               27100000
         SLL   GR2,4                                                    27120000
         OR    GR2,GR5                                                  27140000
         STC   GR2,MV2FLD+11            PLACE L1-L2 INTO CALLING SEQ    27160000
         LA    GR5,STATUS                                               27180000
         STC   GR5,MV2FLD+15            PLACE ENTRY DISPL IN CALL SEQ   27200000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           27220000
         DC    AL2(24)                                                  27240000
         DC    AL4(MV2FLD)                                              27260000
         LA    GR11,24(GR11)            ADVANCE OBJ PROG ADDR           27280000
         B     CK4UDB                                                   27300000
         EJECT                                                          27320000
*********************************************************************** 27340000
*                                                                     * 27360000
*   THE FLDOPS SUBROUTINE PROCESSES THE CONTROL LEVEL, FIELD-RECORD   * 27380000
*  RELATION AND CHAINING OR MATCHING FIELD SPECIFICATIONS OF THE      * 27400000
*  INPUT FIELD SPEC                                                   * 27420000
*                                                                     * 27440000
*********************************************************************** 27460000
FLDOPS   TM    1(GR3),X'E1'             TEST FOR CL,FLD-REC,CH, AND MF  27480000
         BZ    0(GR15)                  BRANCH IF NONE                  27500000
         TM    1(GR3),X'80'             TEST FOR CONTROL LEVEL          27520000
         BZ    *+14                     BRANCH IF NO CONTROL LEVEL      27540000
         MVN   CLNO(1),0(GR13)          SAVE CONTROL LEVEL NUMBER       27560000
         LA    GR13,1(GR13)             ADVANCE CMPPTR                  27580000
         TM    1(GR3),X'41'             TEST FOR CHAINING OR MATCHING   27600000
         BZ    *+14                     BRANCH IF NOT                   27620000
         MVN   CHFNO(1),0(GR13)         PLACE C OR M NUMBER IN CHFNO    27640000
         LA    GR13,1(GR13)             ADVANCE CMPPTR                  27660000
         TM    1(GR3),X'80'             TEST AGAIN FOR CONTROL LEVEL    27680000
         BZ    NOCL                     BRANCH IF NO CONTROL LEVEL      27700000
*********************************************************************** 27720000
*                                                                     * 27740000
*   CONTROL LEVELS ARE PROCESSED FOR DETERMINING THE MAXIMUM LENGTH   * 27760000
*  OF EACH LEVEL (L1-L9) SO THAT COMMON WORKING STORAGE CAN BE RESER- * 27780000
*  VED IN THE OBJECT PROGRAM. A SINGLE AREA EQUAL TO THE MAXIMUM      * 27800000
*  LENGTH IS RESERVED FOR EACH LEVEL USED IN THE SOURCE PROGRAM. THE  * 27820000
*  OBJECT PROGRAM WILL UTILIZE THE COMMON AREAS FOR ALL RECORDS WITH  * 27840000
*  CONTROL LEVEL FIELDS                                               * 27860000
*                                                                     * 27880000
*********************************************************************** 27900000
         SR    GR4,GR4                                                  27920000
         IC    GR4,CLNO                 GR4 = CONTROL LEVEL NUMBER      27940000
         MVI   PACWS,X'C0'                                              27960000
         BAL   GR12,DMPSPC              BRANCH TO OUTPUT A CONTROL      27980000
*                                        LEVEL SPEC ON THE WORK FILE    28000000
         SR    GR5,GR5                                                  28020000
         TM    1(GR3),X'20'             TEST FOR FLD-REC REL IND        28040000
         BZ    *+8                      BRANCH IF NONE                  28060000
         BAL   GR12,FLDREL              OTHERWISE PROCESS FLD-REC REL   28080000
         SR    GR6,GR6                                                  28100000
         IC    GR6,CLLTAB-1(GR4)        GRG = CLLTAB(N-1)               28120000
         AR    GR4,GR4                  GR4 = DIPLACE TO CLLIST ENTRY   28140000
         LTR   GR6,GR6                  CLLTAB(N-1) = ZERO              28160000
         BZ    AD2CLL                   BRANCH IF ZERO                  28180000
         CH    GR5,CLLIST-2(GR4)        CLLIST(2N-2) = RR               28200000
         BNE   IFCHF                    BRANCH IF NOT EQUAL             28220000
AD2CLL   STH   GR5,CLLIST-2(GR4)        STORE PR IN CLLIST(2N-2)        28240000
         SRL   GR4,1                    GR4 = N (CONTROL LEVEL NUMBER)  28260000
         LA    GR5,1(GR2)               GR5 = FIELD LENGTH              28280000
         AR    GR6,GR5                  ADD FIELD LENGTH TO SUM         28300000
         CH    GR6,D256                 COMPARE SUM TO 256              28320000
         BL    *+8                      BRANCH IF LOW                   28340000
         LA    GR6,255                  OTHERWISE FORCE TO 255          28360000
         STC   GR6,CLLTAB-1(GR4)        PLACE SUM IN CLLTAB(N-1)        28380000
         B     IFCHF                                                    28400000
NOCL     TM    1(GR3),X'20'             TEST AGAIN FOR FLD-REC RELATION 28420000
         BZ    IFCHF                    BRANCH IF NONE                  28440000
         BAL   GR12,FLDREL              BRANCH TO PROCESS FLD-REC REL   28460000
         SPACE 1                                                        28480000
*********************************************************************** 28500000
*   FOR A CHAINING FIELD GENERATE THE CHAINING REQUEST BLOCK AS       * 28520000
*  SHOWN BELOW                                                        * 28540000
*********************************************************************** 28560000
         SPACE 1                                                        28580000
IFCHF    TM    1(GR3),X'01'             TEST FOR CHAINING FIELD         28600000
         BZ    IFMF                     BRANCH IF NONE                  28620000
         LA    GR6,20(GR11)              AND BRANCH TO NEXT FIELD       28640000
         STH   GR6,CHB-2                                                28660000
         LA    GR6,10(GR11)             PLACE OPERAND ADDR IN NI INST   28680000
         STH   GR6,CHB-6                                                28700000
         MVN   CHB+2(1),14(GR3)         FLD ADDR OV INDICATION IN CHB   28720000
         STC   GR2,CHFNO+1              PLACE LENGTH FOR OTHERS IN CHB  28740000
         STH   GR0,CHFNO+2              PLACE FLD ADDR IN CHB           28760000
         L     GR5,CHFPTR                                               28780000
         LTR   GR6,GR5                                                  28800000
         BZ    *+8                      DECREMENT = ZERO FOR 1ST CH FLD 28820000
         LR    GR6,GR11                 COMPUTE DECREMENT FOR ACCESSING 28840000
         SR    GR6,GR5                   PRECEDING CHAINING REQUEST BLK 28860000
         STH   GR6,CHFNO+4               AND PLACE IN CURRENT CHB       28880000
         ST    GR11,CHFPTR              SAVE ADDR OF CURRENT BLK        28900000
         LA    GR11,20(GR11)            ADVANCE OBJ PROG ADDR           28920000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           28940000
         DC    AL2(20)                                                  28960000
         DC    AL4(CHB-8)                                               28980000
         BR    GR15                     EXIT FROM FLDOPS                29000000
         SPACE 1                                                        29020000
*********************************************************************** 29040000
*   CHAINING REQUEST BLOCK                                            * 29060000
         SPACE 1                                                        29080000
         NI    CHB+2,X'0F'                                              29100000
         B     0(0)                                                     29120000
CHB      DC    X'B00C'                  DATA IDENTIFER (COMPILER USE)   29140000
         DC    X'F0'                    PROCESSED CODE AND FLD ADD OV   29160000
FILENO   DS    CL1                      FILE NUMBER (BINARY)            29180000
RECSEQ   DS    CL2                      RECORD SEQUENCE                 29200000
CHFNO    DC    X'00'                    CHAINING FIELD NUMBER           29220000
         DS    CL1                      FIELD LENGTH                    29240000
         DS    CL2                      FIELD ADDRESS                   29260000
         DS    CL2                      DECREMENT FOR ACCESSING PRE-    29280000
*                                        CEDING CHB                   * 29300000
*********************************************************************** 29320000
         EJECT                                                          29340000
**********************************************************************  29360000
*   IF THE INPUT FIELD IS DESIGNATED AS A MATCHING FIELD PERFORM THE  * 29380000
*  FOLLOWING ACTION.                                                  * 29400000
*                                                                     * 29420000
*   ELIMINATE DUPLICATE MATCHING FIELDS (M1-M3 IS ALLOWED ONLY ONCE   * 29440000
*  WITH EACH FIELD-RECORD RELATION INDICATOR AND ONCE WITHOUT AN      * 29460000
*  ASSOCIATED INDICATOR)                                              * 29480000
*                                                                     * 29500000
*   ACCUMULATE THE TOTAL LENGTH FOR EACH SET OF MATCHING FLDS (M1-M3) * 29520000
*                                                                     * 29540000
*   OUTPUT A MATCHING FIELD SPEC ONTO THE WORK FILE (SEE DMPSPC)      * 29560000
*********************************************************************** 29580000
         SPACE 1                                                        29600000
IFMF     TM    1(GR3),X'40'             TEST FOR MATCHINF FIELD         29620000
         BZ    0(GR15)                  BRACNH IF NOT (EXIT FLDOPS)     29640000
         SR    GR4,GR4                                                  29660000
         SR    GR5,GR5                                                  29680000
         SR    GR6,GR6                                                  29700000
         IC    GR4,CHFNO                GR4 = MATCHING FIELD NUMBER     29720000
         TM    1(GR3),X'20'             TEST FOR FLD-REC REL IND        29740000
         BZ    *+14                     BRANCH IF NONE                  29760000
         IC    GR5,CLIBNE+3                                             29780000
         LA    GR6,RI00                                                 29800000
         SR    GR5,GR6                  GR5 = INDICATOR NUMBER (1-99)   29820000
         IC    GR6,MFTARG(GR5)          GR6 = ARGUMENT FOR ACCESSING    29840000
         LTR   GR6,GR6                   MFLTAB AND MFDUPS (TABLES)     29860000
         BC    7,CK4DUP                 BRANCH IF ARGUMENT NON ZERO     29880000
*                                       OTHERWISE USE THE NUMBER OF THE 29900000
         LH    GR12,MFTPTR               NEXT AVAILABLE IN THE MFLTAB   29920000
         LA    GR12,1(GR12)              AS THE ARGUMENT                29940000
         STH   GR12,MFTPTR              ADVANCE ARGUMENT                29960000
         STC   GR12,MFTARG(GR5)          AND PLACE IN ARG TABLE         29980000
         LR    GR6,GR12                  GR6 = ARGUMENT                 30000000
CK4DUP   LA    GR12,MFDUPS-1(GR6)       GR12 = MFDUPS(FLD-REC REL IND)  30020000
         LA    GR5,1                                                    30040000
         SLL   GR5,0(GR4)               GR5 = BIT CONFIGURATION REPRE-  30060000
*                                        SENTING THE M NUMBER           30080000
         EX    GR5,DUPCK                "HECK MFDUPS ENTRY TO SEE IF A  30100000
*                                        FLD FOR THIS M NO. HAS ALREADY 30120000
*                                        BEEN PROCESSED                 30140000
         BO    0(GR15)                  BRANCH IF DUPLICATE             30160000
         EX    GR5,SIMF                 OTHERWISE SET MFDUPS ENTRY      30180000
         IC    GR5,MFLTAB-1(GR6)                                        30200000
         LA    GR5,1(GR2,GR5)           ACCUMLATE TOTAL LENGTH OF FLDS  30220000
         CH    GR5,D256                 COMPARE SUM TO 256              30240000
         BL    *+8                      BRANCH IF LOW                   30260000
         LA    GR5,255                  OTHERWISE FORCE TO 255          30280000
         STC   GR5,MFLTAB-1(GR6)         FOR THE MATCHING FLDS SET      30300000
         MVI   PACWS,X'E0'                                              30320000
         BCTR  GR13,0                                                   30340000
         BCTR  GR13,0                                                   30360000
         BAL   GR12,DMPSPC              BRANCH TO OUTPUT SPEC ONTO      30380000
         LA    GR13,2(GR13)                                             30400000
         BR    GR15                      WORK FILE AND EXIT FLDOPS      30420000
DUPCK    TM    0(GR12),0                                                30440000
SIMF     OI    0(GR12),0                                                30460000
MFTPTR   DC    H'0'                                                     30480000
         EJECT                                                          30500000
*********************************************************************** 30520000
*   DATA STORAGE AND CONSTANTS USED ONLY DURING PASS 1 PROCESSING     * 30540000
*********************************************************************** 30560000
         DS    0D                                                       30580000
PACWS    DS    D                                                        30600000
B2       DC    X'00002000'                                              30620000
RR01     DC    X'00003017'              ADDR (BDDD) OF RI 01            30640000
CLLIST   DC    9H'0'                    CONTR LEVEL INDICATORS LIST     30660000
CLLTAB   DC    9X'0'                                                    30680000
CLNO     DC    X'00'                                                    30700000
CHFPTR   DC    F'0'                     ADDR (BDDD) OF LAST CHAINING    30720000
*                                       BLOCK GENERATED                 30740000
CHFMFP   DC    A(CHFMFL-1)              CHFMFL TABLE POINTER            30760000
MVFPTR   DC    A(ADTMVF)                ADTMVF POINTER                  30780000
NSTPTR   DC    A(NSTAB)                                                 30800000
NSCPTR   DC    A(NSCTAB)                                                30820000
NSBPTR   DC    A(NSCB+2)                                                30840000
ARGSAV   DS    16F                      SAVE AREA FOR ALL GENERAL REG   30860000
CIXSAV   DS    3F                       SAVE AREA FOR GENERAL REGISTERS 30880000
CXRADDR  DC    A(IES12910)             SERVICE ROUTINE ADDRESS          30900000
*                                        USED BY CIOEX                  30920000
B9       DC    X'00009000'                                              30940000
B15      DC    X'0000F000'                                              30960000
B9ADDR   DC    A(BASEP1+4096)                                           30980000
P2NAME   DC    C'RPG10130'                                              31000000
NXPHSN   DC    C'RPG10140'                                              31020000
OVLGR7   L     7,0(3)                                                   31040000
D256     DC    H'256'                                                   31060000
BLKCTR   DC    H'0'                                                     31080000
DATOUT2   DC   H'72'                                                    31100000
DATOUT4   DC   AL2(DATALG)                                              31120000
ABCUSE   DC    X'00'                                                    31140000
OVFLOW   DC    X'00'                    FLD ADDR OVERFLOW INDICATOR     31160000
DPWORR   DC    9X'00'                                                   31180000
TMFL     DC    X'00'                                                    31200000
CLS      DC    X'00'                    CONTROL LEVELS INDICATOR (INDI- 31220000
*                                        CATES IF CONTROL LEVELS ARE    31240000
*                                        PRESENT)                       31260000
MFS      DC    X'00'                    MATCHING FLDS INDICATOR (INDI-  31280000
*                                        CATES IF M FLDS ARE PRESENT)   31300000
NOTE61   DC    C'061'                                                   31320000
NOTE62   DC    C'062'                                                   31340000
NOTE63   DC    C'063'                                                   31360000
ERNO63   DC    X'00'                                                    31380000
NOTE64   DC    C'064'                                                   31400000
ERNO64   DC    X'00'                                                    31420000
NSCB     DC    X'B000'                  DATA IDENT AND LENGTH           31440000
         DS    CL99                     NUMERIC SEQ CONTROL BLOCK       31460000
RITAB    DC    99X'00'                  RECORD RESULTING INDICATOR      31480000
*                                        TABLE (NOTES INDICATORS USED)  31500000
TRIGER   DC    X'00'                    INDICATES CL OR MF SPECS        31520000
*                                        PROCESSSD FOR A RECORD GROUP   31540000
         EJECT                                                          31560000
*********************************************************************** 31580000
*   PASS 1 COMMON SUBROUTINES                                         * 31600000
*********************************************************************** 31620000
         SPACE 2                                                        31640000
*********************************************************************** 31660000
*   ALIGN FORCES THE OBJECT PROGRAM ADDRESS COUNTER TO FULL WORD      * 31680000
*  ALIGNMENT                                                          * 31700000
*********************************************************************** 31720000
         SPACE 1                                                        31740000
ALIGN    L     GR1,ADDCNT(GR7)                                          31760000
         LA    GR1,3(GR1)                                               31780000
         SRL   GR1,2                                                    31800000
         SLL   GR1,2                                                    31820000
         ST    GR1,ADDCNT(GR7)     RESOTRE TO CIOEX DATA AREA           31840000
         ST    GR1,LODLOC          PLACE IN DMPTXT                      31860000
         BR    GR14                                                     31880000
         SPACE 1                                                        31900000
*********************************************************************** 31920000
*   IF FIELD HAS AN ASSOCIATED FIELD-RECORD RELATION INDICATOR GENE-  * 31940000
*  RATE INSTRUCTIONS TO TEST STATUS OF THE INDICATOR AND BRANCH TO    * 31960000
*  THE NEXT FIELD IF THE INDICATOR IS NOT ON                          * 31980000
*********************************************************************** 32000000
         SPACE 1                                                        32020000
FLDREL   MVC   CLIBNE+2(2),0(GR13)      PLACE ADDR OF IND IN CLI        32040000
         LA    GR13,2(GR13)             ADVNACE CMPPTR                  32060000
         LA    GR11,8(GR11)             ADVANCE OBJ PROG ADDR           32080000
         OI    ABCUSE,X'F0'             SET TO INDICATE UBA GENERATED   32100000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           32120000
         DC    AL2(8)                                                   32140000
         DC    AL4(CLIBNE)                                              32160000
         LH    GR5,CLIBNE+2             GR5 = ADDR OF FLD-REC REL IND   32180000
         BR    GR12                     EXIT FLDREL SUBR                32200000
CLIBNE   CLI   0(0),X'F0'               INSTRUCTIONS GENERATED FOR THE  32220000
         BNE   6(0)                      FLD-REC REL                    32240000
         SPACE 1                                                        32260000
*********************************************************************** 32280000
*   CK4UBA DEFINES THE BRANCH ADDRESS FOR THE BNE INSTRUCTION GENE-   * 32300000
*  RATED WHEN THE FIELD-RECORD RELATION IS PRESENT                      32320000
*********************************************************************** 32340000
         SPACE 1                                                        32360000
CK4UBA   CLI   ABCUSE,0                 TEST FOR UBA WITH CODE O6       32380000
         BE    0(0,GR12)                                                32400000
         MVI   ABCUSE,0                                                 32420000
         STH   GR11,*+10                                                32440000
         BAL   GR14,ADRDEF              BRANCH TO DEFINE UBA            32460000
         DC    AL2(6)                                                   32480000
         DC    AL2(0)                                                   32500000
         BR    GR12                                                     32520000
         SPACE 2                                                        32540000
*********************************************************************** 32560000
*   GENMVF GENERATES A MVC OR MVN INSTRUCTION AND CALLS DMPTXT        * 32580000
*********************************************************************** 32600000
         SPACE 1                                                        32620000
GENMVF   STH   GR1,4(GR6)               INPUT DATA ADDR INTO INST       32640000
         STH   GR0,2(GR6)               FIELD ADDR INTO INST            32660000
         STC   GR2,1(GR6)               LENGTH INTO INST                32680000
         ST    GR6,IADDR                ADDR OF INST INTO DMPTXT CALL   32700000
         CNOP  2,4                                                      32720000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           32740000
         DC    AL2(6)                                                   32760000
IADDR    DC    AL4(0)                                                   32780000
         LA    GR11,6(GR11)             ADVANCE OBJ PROG ADDR           32800000
         BR    GR15                     EXIT GENMVF                     32820000
MVF      MVC   0(0,0),0(0)                                              32840000
CPACK    PACK  0(0,0),0(0,0)                                            32860000
ANDI     NI    0(0),X'FC'                                               32880000
         SPACE 2                                                        32900000
*********************************************************************** 32920000
*   ERROR CALLS CIOEX TO OUTPUT ERROR NOTES                           * 32940000
*********************************************************************** 32960000
         SPACE 1                                                        32980000
ERROR    MVC   ERRNUM(3,GR10),0(GR5)    MOVE ERROR NOTE NUMBER INTO     33000000
         LA    GR2,PNTERR                PRINT AREA                     33020000
         BAL   GR14,IOEXC                                               33040000
         BR    GR15                                                     33060000
         EJECT                                                          33080000
*********************************************************************** 33100000
*   DMPSPC CONTROLS BLOCKING AND OUTPUT OF CONTROL LEVEL SPECS AND    * 33120000
*  MATCHING FIELD SPECS ONTO A WORK FILE. THESE SPECS ARE SUBSEQUENTLY* 33140000
*  PROCESSED BY GENCLM AFTER COMPLETION OF PASS 1.                      33160000
*   THE FORMAT OF THE SPECS IS AS FOLLOWS                             . 33180000
*                                                                     * 33200000
*   RRFFLNA   WHERE RR = FIELD-RECORD RELATION INDICATOR (THE FIRST   * 33220000
*                        BYTE OF RR = X'FD' IF NO FLD-REC REL IND)    * 33240000
*                   FF = ADDR OF INPUT DATA (BDDD)                      33260000
*                    L = FIELD LENGTH                                   33280000
*                    N = LEVEL NUMBER (1-9 FOR CONTROL LEVELS AND 1-3   33300000
*                        FOR MATCHING FIELDS, ALSO THE ZONE OF THIS     33320000
*                        BYTE INDICATES THE SPEC TYPE, C FOR CONTROL  * 33340000
*                        LEVEL OR E FOR MATCHING FIELD)               * 33360000
*                    A = DECIMAL POSITION AND PACKED INDICATION (SAME * 33380000
*                         AS COMPRESSION)                             * 33400000
*********************************************************************** 33420000
         SPACE 1                                                        33440000
DMPSPC   L     GR6,WKBPTR                                               33460000
         LA    GR6,7(GR6)                                               33480000
         CLI   0(GR6),X'FF'             TEST FOR END OF WKBUFF          33500000
         BNE   MVNSPC-4                 BRANCH IF NOT AT END            33520000
         LR    GR6,GR1                                                  33540000
         LA    GR1,WKBUFF                                               33560000
         LR    GR5,GR2                                                  33580000
         LA    GR2,BLKOUT                                               33600000
         BAL   GR14,IOEXC               BRANCH TO WRITE OUT WKBUFF      33620000
         LR    GR1,GR6                                                  33640000
         LR    GR2,GR5                                                  33660000
         LA    GR6,WKBUFF                                               33680000
         ST    GR6,WKBPTR                                               33700000
MVNSPC   MVI   RR(GR6),X'FD'            FORM SPEC IN WKBUFF             33720000
         TM    1(GR3),X'20'                                             33740000
         BZ    *+10                                                     33760000
         MVC   RR(2,GR6),0(GR13)                                        33780000
         STH   GR1,PACWS+2                                              33800000
         MVC   FF(2,GR6),PACWS+2                                        33820000
         STC   GR2,LG(GR6)                                              33840000
         TM    8(GR3),X'F0'             TEST FOR UNPACKED NUMERIC       33860000
         BC    12,*+10                  BRANCH IF ALPHA OR PACKED       33880000
         MVC   LG(1,GR6),5(GR3)         LENGTH FROM COMPRESSION INTO LG 33900000
         STC   GR4,NB(GR6)                                              33920000
         MVZ   NB(1,GR6),PACWS          ZONE IS PLACED IN PACWS PRIOR   33940000
         MVC   FTYPE(1,GR6),8(GR3)       TO CALLING DMPSPC              33960000
         BR    GR12                                                     33980000
         SPACE 1                                                        34000000
*   THE FOLLOWING SETS BIT 3 IN THE NB BYTE OF THE LAST SPEC IN WKBUFF  34020000
*  TO INDICATE END OF A RECORD GROUP                                    34040000
         SPACE 1                                                        34060000
MRKEOR   LA    GR6,WKBUFF-7                                             34080000
         CL    GR6,WKBPTR                                               34100000
         BE    0(0,GR15)                                                34120000
         L     GR6,WKBPTR                                               34140000
         OI    NB(GR6),X'10'                                            34160000
         BR    GR15                                                     34180000
WKBPTR   DC    A(WKBUFF-7)                                              34200000
WKBUFF   DC    70X'0'                                                   34220000
         DC    X'FFFF'                                                  34240000
         EJECT                                                          34260000
*********************************************************************** 34280000
*   ADD2AC MAINTAINS THE ADDRESS (ABSOLUTE) OF THE LAST LOCATION      * 34300000
*  (PLUS ONE) USED BY THE GENERATED OBJECT PROGRM                     * 34320000
*********************************************************************** 34340000
         SPACE 2                                                        34360000
ADD2AC   S     GR11,B8                  REMOVE B FROM BDDD IN GR11      34380000
         A     GR11,ADDCNT(GR7)         ADD DDD IN GR11 TO ADRCNT       34400000
         ST    GR11,ADDCNT(GR7)                                         34420000
         L     GR11,B8                  RESET GR11 TO BDDD (B = 8 AND   34440000
         BR    GR15                      DDD = 000)                     34460000
         DS    0F                                                       34480000
B8       DC    X'0000D000'                                              34500000
*********************************************************************** 34520000
*   GNXCMP EXAMINES THE NEXT AVAILABLE BYTE IN THE COMPRESSION BLOCK  * 34540000
*  TO DETERMINE THE TYPE OF SPEC (INPUT RECORD OR FIELD TYPE). IF THE * 34560000
*  END OF THE COMPRESSION BLOCK IS DETECTED, CIOEX GETCMP IS CALLED   * 34580000
*  TO READ THE NEXT BLOCK                                             * 34600000
*********************************************************************** 34620000
         SPACE 2                                                        34640000
GNXCMP   LR    GR3,GR13                 ADVANCE GR3 TO NXT SPEC         34660000
         CLI   0(GR3),C'I'              TEST FOR RECORD TYPE            34680000
         BE    0(GR15)                   BRANCH IF RECORD TYPE          34700000
         CLI   0(GR3),C'D'              TEST FOR FIELD TYPE             34720000
         BE    4(GR15)                   BRANCH IF FIELD TYPE           34740000
         CLI   0(GR3),X'FF'             TEST FOR END OF COMPRESSION BLK 34760000
         BNE   8(GR15)                   BRANCH IF NOT END              34780000
         LA    GR2,GETCMP               OTHERWISE GET NEXT BLOCK        34800000
         BAL   GR14,IOEXC               BRANCH TO CALL CIOEX TO READ    34820000
*                                        NEXT BLOCK OF COMPRESSION      34840000
         LR    GR13,GR3                 RESET CMPPTR TO 1ST SPEC IN BLK 34860000
         B     GNXCMP+2                                                 34880000
         EJECT                                                          34900000
*********************************************************************** 34920000
*   GETINP CALLS CIOEX TO MAKE AVAILABLE WITHIN THE COMPRESSION BLOCK * 34940000
*  THE FIRST INPUT SPEC (UPON EXIT GR3 CONTAINS FIRST BYTE ADDRESS OF * 34960000
*  INPUT SPEC)                                                        * 34980000
*********************************************************************** 35000000
         SPACE 2                                                        35020000
GETINP   LA    GR2,PNTINP               GR2 = ROUTINE NUMBER            35040000
         BAL   GR14,IOEXC               BRANCH TO CALL CIOEX            35060000
         LA    GR2,GETCMP                                               35080000
         BAL   GR14,IOEXC                                               35100000
         AH    GR3,IDSPLC(GR7)          ADD DISPLACE TO 1ST INPUT SPEC  35120000
         LR    GR13,GR3                 INITIALIZE CMPPTR               35140000
         BR    GR15                     EXIT GETINP                     35160000
         SPACE 2                                                        35180000
*********************************************************************** 35200000
*   IOEXC CALLS CIOEX TO PERFORM INPUT/OUTPUT (GR2 CONTAINS NUMBER OF * 35220000
*  CIOEX ROUTINE)                                                     * 35240000
*********************************************************************** 35260000
         SPACE 1                                                        35280000
IOEXC    STM   GR4,GR2,ARGSAV                                           35300000
         LM    GR4,GR12,CIXSAV          RESTORE CIOEX GR4-GR12 (12 = 7) 35320000
         BALR  GR5,GR12                 BRANCH TO CIOEX                 35340000
         LM    GR4,GR2,ARGSAV                                           35360000
         BR    GR14                     EXIT IOEXC                      35380000
         EJECT                                                          35400000
*********************************************************************** 35420000
*   DMPTXT ACCEPTS OBJECT CODE AND FORMS A BINARY TEXT CARD FOR       * 35440000
*  OUTPUT ON EITHER SYSPCH OR SYS000 (GO FILE)                        * 35460000
*********************************************************************** 35480000
BLDMPTXT STM   0,15,ARGSAV                                              35500000
         LH    DMPRG2,LENGTH  HAS THE NUMBER OF BLANKS WE WANT TO ADD   35520000
         A     DMPRG2,PTR1    TO THE OUTPUT STREAM.                     35540000
         ST    DMPRG2,PTRUBA  SET THE PTRUBA OVER THE STREAM OF BLANKS. 35560000
         S     DMPRG2,PTR1                                              35580000
         BCTR  DMPRG2,0       REDUCE THE LENGTH TO ACCOUNT FOR THE      35600000
         L     DMPRG3,PTR1    BLANK MOVED INTO THE FIRST AVAILABLE      35620000
         LA    DMPRG1,1(DMPRG3) BYTE IN THE BUFFER.                     35640000
         MVI   0(DMPRG3),C' ' AFTER MOVING THIS BLANK INTO THE          35660000
         B     DMP1           FIRST AVAILABLE BYTE GO AND REPEAT IT    135680000
                              FOR THE NUMBER OF BLANKS DESIRED.         35700000
DMPTXT   MVC   LENGTH(6),0(GR14) MOVE THE CALLING SEQUENCE.             35720000
         LA    GR14,6(GR14)   BUMP REGISTER OVER CALLING SEQ.           35740000
         STM   0,15,ARGSAV    SAVE ALL REGISTERS PRIOR TO ENTRY .       35760000
         L     DMPRG1,PTR1    POINTS TO THE FIRST AVAILABLE BYTE IN     35780000
         LH    DMPRG2,LENGTH  THE TEXT BUFFER.HAS THE LENGTH OF THE     35800000
         L     DMPRG3,DMPADD  SEGMENT TO BE ADDED,AND ITS ADDRESS.      35820000
DMP1     BAL   DMPRG0,DMPSUB   GO AND MOVE THE SEGMENT TO THE BUFFER.   35840000
         LA    DMPRG1,1(DMPRG1,DMPRG2) SET THE POINTER TO THE           35860000
         ST    DMPRG1,PTR1    FIRST AVAILABLE BYTE IN THE BUFFER.       35880000
         MVI   DMPFLG,X'FF'   SET HE FLAG TO SEARCH OUT THE UBA'S.      35900000
         B     ADR1                                                     35920000
DMPSUB   LA    DMPRG4,256      MOVE ALL THE MULTIPLES OF 256 BYTES      35940000
DMPSUB1  SR    DMPRG2,DMPRG4  FIRST,THEN THE REMAINDER                  35960000
         BC    12,DMPSUB2                                               35980000
         MVC   0(256,DMPRG1),0(DMPRG3)                                  36000000
         AR    DMPRG3,DMPRG4                                            36020000
         BXH   DMPRG1,DMPRG4,DMPSUB1                                    36040000
DMPSUB2  LA    DMPRG2,255(DMPRG2)                                       36060000
         EX    DMPRG2,DMPSUB3 NOW MOVE THE REMAINDER .                  36080000
         BR    DMPRG0                                                   36100000
DMPSUB3  MVC   0(0,DMPRG1),0(DMPRG3)                                    36120000
ADRDEF   MVC   DMPADD(4),0(GR14) MOVE THE CALLING SEQUENCE AF THIS CALL 36140000
         LA    GR14,4(GR14)   AND SET RETURN REGISTER.                  36160000
         STM   0,15,ARGSAV                                              36180000
         LH    DMPRG3,BDDDDFN HAS ADDRESS DEFIN. FOR THIS UBA.          36200000
         MVI   DMPFLG,X'0'    SET SWITCH THAT WE ARE DEFINING UBA'S.    36220000
ADR1     L     DMPRG1,PTRUBA  POINTS TO THE FIRST UBA FOUND IN LAST     36240000
         SR    DMPRG2,DMPRG2  CALL.                                     36260000
         XC    PTRUBA(12),PTRUBA CLEAR UBA POINTERS,AND SAVE AS FIRST   36280000
         MVC   PTRUBA(4),PTR1 UBA POINTER THE NEXT AVAIL.BYTE IN CASE  136300000
                              NO UBA'S ARE FOUND.                       36320000
         LA    DMPRG1,0(DMPRG1) BLANK OUT A POSSIBLE UBA FLAG.          36340000
ADR2     C     DMPRG1,PTR1    HAVE WE SEARCHED THROUGH THE BUFFER.      36360000
         BNL   ADRA           YES ,PUNCH AS MUCH AS POSSIBLE            36380000
         CLI   0(DMPRG1),X'47' IS THIS OPERATION A' 'BRANCH'            36400000
         BE    ADR4           YES,GO SEE WHETHER IT IS A U.B.A.         36420000
         TM    0(DMPRG1),X'B0' IF NOT,IS THIS A SEGMENT OF DATA         36440000
         BC    12,ADR8        NO.                                       36460000
         IC    DMPRG2,1(DMPRG1) PICK UP THE COUNT.                      36480000
         LTR   DMPRG2,DMPRG2    IS IT ZERO,                             36500000
         BC    7,ADR3         SKIP IF NOT,ELSE UPDATE POINTER OVER 256  36520000
         LA    DMPRG1,256(DMPRG1) BYTES OF DATA.                        36540000
ADR3     AR    DMPRG1,DMPRG2  AND ADD LENGTH OF THE DATA SEGMENT.       36560000
         B     ADR2                                                     36580000
ADR4     TM    2(DMPRG1),X'F0' IS THIS BRANCH A U.B.A.                  36600000
         BC    5,ADR8         SKIP IF NOT.                              36620000
         CLI   DMPFLG,X'FF'   ARE WE DEFINING A UBA.                    36640000
         BE    ADR5           NO.                                       36660000
         CLC   IDNO(1),3(DMPRG1) IF SO DO WE DEFINE THIS UBA.           36680000
         BNE   ADR5           SKIP IF NOT.                              36700000
         STH   DMPRG3,2(DMPRG1) ELSE DEFINE THE UBA AND                 36720000
         B     ADR8           GO TO UPDATE POINTER.                     36740000
ADR5     LA    DMPRG4,PTRUBA                                            36760000
         LA    DMPRG2,3                                                 36780000
ADR6     CLC   0(1,DMPRG4),3(DMPRG1) HAS THIS UBA BEEN POSTED.          36800000
         BE    ADR8           YES,ELSE                                  36820000
         CLI   0(DMPRG4),X'0' IS THIS STILL BLANK,                      36840000
         BNE   ADR7                                                     36860000
         ST    DMPRG1,0(DMPRG4) ELSE SAVE THE POINTER                   36880000
         MVC   0(1,DMPRG4),3(DMPRG1) AND THE FLAG.                      36900000
         B     ADR8                                                     36920000
ADR7     LA    DMPRG4,4(DMPRG4) POINT TO NEXT UBA POINTER               36940000
         BCT   DMPRG2,ADR6    POST ONLY 3 DIFFERENT UBA TYPES.          36960000
ADR8     TM    0(DMPRG1),X'C0' TEST FOR INSTRUCTION LENGTH.             36980000
         LA    DMPRG1,2(DMPRG1) ADD 2 FOR  INSTRUCTION OF LENGTH 2      37000000
         BZ    ADR2           CONTINUE                                  37020000
         LA    DMPRG1,2(DMPRG1) ADD 2 MORE FOR LENGTH 4.                37040000
         BM    ADR2           CONTINUE                                  37060000
         LA    DMPRG1,2(DMPRG1) ADD 2 MORE FOR LENGTH 6                 37080000
         B     ADR2           CONTINUE                                  37100000
ADRA     CLC   BUFFRP56+1(3),PTRUBA+1 DO WE HAVE 56 BYTES IN THE        37120000
         BNH   PUSHUP         BUFFER WITHOUT A UBA,IF NOT RETURN.       37140000
DMPTXTRN MVI   CDLEN+1,56     RESTORE CARD LENGTH OF TEXT OUTPUT.       37160000
         S     DMPRG1,BUFTOP  COMPUTE THE NUMBER OF BYTES REMAINING     37180000
         LCR   DMPRG1,DMPRG1  IN THE TEXT BUFFER.                       37200000
         ST    DMPRG1,SOOM                                              37220000
         LM    0,15,ARGSAV    RESTORE ALL REGISTERS TO RETURN.          37240000
         BR    GR14      AND RETURN TO CALLER.                          37260000
PUSHUP   EQU   *                                                        37280000
         LM    4,7,CIXSAV     RESTORE CIOEX REGISTERS.                  37300000
         MVC   0(72,4),PFX     MOVE THE CARD PREFIX TO CIOEX PUNCH      37320000
         MVI   4(4),C' '      BUFFER AND BLANK THE FIRST BYTE OF THE    37340000
         LA    2,12           LOAD ADDRESS TO CONFORM TO TEXT NORM.     37360000
         BALR  5,7            LINK TO PUNCH ROUTINE IN CIOEX.           37380000
         LA    DMPRG1,DMPTXTBF NOW MOVE THE DUMP TEXT BUFFER UP         37400000
         LCR   DMPRG2,DMPRG1  56 BYTES OVERLAYING THE TEXT JUST PUT     37420000
         A     DMPRG2,PTR1    OUT VIA THE CIOEX CALL.                   37440000
         LA    DMPRG3,56(DMPRG1)                                        37460000
         BAL   DMPRG0,DMPSUB                                            37480000
         LA    DMPRG3,PTRUBA  UPDATE ALL UBA POINTERS AS WELL AS        37500000
         LA    DMPRG2,4       THE POINTER TO THE NEXT AVAILABLE BYTE    37520000
PSH1     L     DMPRG1,0(DMPRG3) IN THE DMPTXT BUFFER TO REFLECT THE     37540000
         SH    DMPRG1,CDLEN   LENGTH OF THE CARD PUNCHED OUT.           37560000
         ST    DMPRG1,0(DMPRG3)                                         37580000
         LA    DMPRG3,4(DMPRG3)                                         37600000
         BCT   DMPRG2,PSH1    SIMILARLY ADJUST THE LOAD LOCATION        37620000
         L     DMPRG2,LODLOC  COUNTER TO REFLECT THE TEXT CARD PUT      37640000
         AH    DMPRG2,CDLEN   OUT.                                      37660000
         ST    DMPRG2,LODLOC  THEN GO TO SEE WHETHER WE CANNOT          37680000
         B     ADRA           PUT OUT ANOTHER CARD.                     37700000
FINTXT   STM   0,15,ARGSAV    SAVE ALL REGISTERS PRIOR TO ENTRY .       37720000
         L     DMPRG3,PTR1    FILL WITH BLANKS THE REMAINDER            37740000
         LA    DMPRG2,DMPTXTBF+54 OF THIS INCOMPLETE TEXT CARD          37760000
         SR    DMPRG2,DMPRG3  TO PREPARE IT FOR PUNCHING.               37780000
         LA    DMPRG1,1(DMPRG3)                                         37800000
         MVI   0(DMPRG3),C' '                                           37820000
         EX    DMPRG2,DMPSUB3                                           37840000
         LA    DMPRG1,DMPTXTBF NOW COMPUTE THE LENGTH OF THIS TEXT CARD 37860000
         SR    DMPRG3,DMPRG1  FOR OUTPUT.                               37880000
         BC    12,DMPTXTRN    RETURN DIRECTLY IF THE LENGTH.LE.ZERO.    37900000
         STC   DMPRG3,CDLEN+1                                           37920000
         B     PUSHUP                                                   37940000
PTRUBA   DC    A(DMPTXTBF,0,0,DMPTXTBF) HOLDS THE POINTERS TO THE FIRST137960000
                              UNIQUE OCCURRENCE OF UBA'S IN THE BUFFER. 37980000
PTR1     EQU   PTRUBA+12      POINTER TO THE NEXT AVAILABLE BYTE IN THE138000000
                              DMPTXT BUFFER.                            38020000
BUFFRP56 DC    A(DMPTXTBF+56)                                           38040000
DMPAREA  DC    2F'0'          SCRATCH AREA FOR DMPTXT.                  38060000
DMPFLG   EQU   DMPAREA+1      CONTAINS ADDRESS DEFINITION SWITCH.       38080000
LENGTH   EQU   DMPAREA+2      LENGTH OF SEGMENT TO ADD.                 38100000
DMPADD   EQU   DMPAREA+4      ADDRESS OF FIRST BYTE TO BE ADDED.        38120000
IDNO     EQU   DMPAREA+5      ID NUMBER OF U.B.A TO BE DEFINED.         38140000
BDDDDFN  EQU   DMPAREA+6      'BDDD' DEFINITION FOR THIS U.B.A..        38160000
DMPRG0   EQU   11                                                       38180000
DMPRG1   EQU   12             GENERAL REGISTERS FOR DUMPTEXT ROUTNE     38200000
DMPRG2   EQU   13                                                       38220000
DMPRG3   EQU   14                                                       38240000
DMPRG4   EQU   15                                                       38260000
BUFTOP   DC    A(EOBUF1)                TOP OF BUFFER (HIGH VALUE ADDRS 38280000
SOOM     DC    A(BUF1LG)                REMAINING BYTES IN TEXT BUFFER  38300000
         DC    0F'0'          FORCE TO FULLWORD ALIGNMENT.              38320000
PFX      DC    X'02'          T                                         38340000
         DC    C'TXT'          E  C                                     38360000
LODLOC   DC    F'0'             X  A  P                                 38380000
         DC    C'  '             T  R  R                                38400000
CDLEN    DC    H'56'                 D  E                               38420000
         DC    C'  '                     F                              38440000
         DC    X'00'                      I                             38460000
         DC    X'01'                       X                            38480000
DMPTXTBF DC    0X'0'          BEGINNING OF DUMPTEXT BUFFER.             38500000
         SPACE 2                                                        38520000
*   DMPTXT BUFFER OVERLAYS THE FOLLOWING CANNED OBJECT SUBR WHICH IS    38540000
*  FIRST TEXT OUTPUT BY THIS PHASE                                      38560000
         EJECT                                                          38580000
*********************************************************************** 38600000
*   CANNED OBJECT CODE OUTPUT BY PASS 1                               * 38620000
*********************************************************************** 38640000
         SPACE 2                                                        38660000
*********************************************************************** 38680000
*   DSPC (DATA SPEC SUBR) RECEIVES CONTROL FROM EITHER THE MASTER     * 38700000
*  DRIVER OR THE CHAINING SYBR AND EXECUTES THE MVFLDS SUBR FOR THE   * 38720000
*  AVAILABLE INPUT RECORD TYPE. THE MVFLDS SUBR MOVES THE INPUT DATA  * 38740000
*  INTO THE ASSIGNED FIELDS AND CALLS THE CAHINING SUBR IF CHAINING   * 38760000
*  FIELDS ARE PRESENT.                                                * 38780000
*********************************************************************** 38800000
         SPACE 1                                                        38820000
         CNOP  0,4                                                      38840000
DSPC     BALR  GR8,0                                                    38860000
         USING *,GR8                                                    38880000
         L     GR1,FPBADR               GR1 = ADDR OF FBP               38900000
         LTR   GR1,GR1                  ZERO IF IOERROR ON DASD INPUT   38920000
         BCR   8,GR14                    FILE (EXIT DSPC)               38940000
         SPACE 1                                                        38960000
         L     GR9,FPBMVF(GR1)                                          38980000
         LTR   GR9,GR9                                                  39000000
         BCR   8,GR14                                                   39020000
         STM   GR13,GR14,GJM           STORE REGISTERS             5050 39040016
         LA    GR13,0(GR9,GR3)          GR13 = ADDR OF MVFLDS SUBR      39060000
         LA    GR15,4095                SET BASE REGISTERS 13-15 FOR    39080000
         LA    GR14,1(GR13,GR15)         USE OF MVFLDS SUBR             39100000
         LA    GR15,1(GR14,GR15)                                        39120000
         L     GR9,LVIORB(GR3)                                          39140000
         AH    GR9,IORBDP-4(GR1)                                        39160000
         L     GR2,IPREC(GR9)                                           39180000
         BALR  GR8,GR13                 BRANCH TO MVFLDS SUBR           39200000
*   TRANSFER VECTOR TO PACK, ZAPN, AND FIELD STATUS SUBROUTINES         39220000
         USING *,GR8                                                    39240000
TRV      B     PACK                                                     39260000
         B     PACTST                                                   39280000
         B     ZAPN                                                     39300000
         B     ZAPTST                                                   39320000
         B     TEST4B                                                   39340000
         CNOP  0,4                                                      39360000
FPBADR   DC    X'B0040000'              ADDRESS OF FPB - ALSO USED TO   39380000
GJM      DS    CL8   SAVE 13-14 AREA FOR MVFIELDS SUB              5050 39420016
SA4DE    EQU   GJM-TRV     DISP FOR MVFLDS SUB TO GET 13-14        5050 39460016
         SPACE 1                                                        39500000
*********************************************************************** 39520000
*   STAT SUBR CHECKS THE STATUS OF A NUMERIC FIELD AND SETS ON THE    * 39540000
*  PLUS, MINUS OR ZERO INDICATOR                                      * 39560000
*********************************************************************** 39580000
         SPACE 1                                                        39600000
STAT     LA    GR10,2(GR7)                                              39620000
         LA    GR9,3                                                    39640000
         CLI   0(GR10),0                                                39660000
         BE    INDOFF+4                                                 39680000
         MVC   *+8(2),0(GR10)                                           39700000
INDOFF   MVI   0(0),0                                                   39720000
         LA    GR10,2(GR10)                                             39740000
         BCT   GR9,STAT+8                                               39760000
         CLI   6(GR7),0                 IS ZERO INDICATOR USED          39780000
         BE    IFPLUS                   BRANCH IF NOT                   39800000
         EX    GR11,ZAPF                OTHERWISE TEST FLD TO BE ZERO   39820000
         BC    7,*+12                   BRANCH IF NOT ZERO              39840000
         LA    GR7,6(GR7)               OTHERWISE BRANCH TO SET ON IND  39860000
         B     SETONI                                                   39880000
IFPLUS   LA    GR7,2(GR7)                                               39900000
         CLI   0(GR7),0                 IS PLUS INDICATOR USED          39920000
         BE    IFMIUS                   BRANCH IF NOT                   39940000
         EX    GR11,ZAPF                OTHERWISE TEST FLD TO BE PLUS   39960000
         BP    SETONI                   BRANCH TO SET ON IND IF PLUS    39980000
IFMIUS   CLI   2(GR7),0                 IS MINUS INDICATOR USED         40000000
         BE    SETONI+10                BRANCH IF NOT                   40020000
         EX    GR11,ZAPF                OTHERWISE TEST FLD TO BE MINUS  40040000
         BC    10,SETONI+10             BRANCH IF NOT MINUS             40060000
         LA    GR7,2(GR7)               OTHERWISE SET ON IND            40080000
SETONI   MVC   *+8(2),0(GR7)                                            40100000
         OI    0(0),X'F0'                                               40120000
         BR    GR10                     EXIT STAT SUBR                  40140000
ZAPF     ZAP   0(0,GR1),0(0,GR1)                                        40160000
         SPACE 1                                                        40180000
*********************************************************************** 40200000
*   PACK SUBR PACKS UNPACKED NUMERIC INPUT DATA INTO A PACKED FIELD   * 40220000
*********************************************************************** 40240000
         SPACE 1                                                        40260000
PACK     EX    GR11,PACN                PACK INPUT DATA INTO FIELD      40280000
         LR    GR9,GR11                                                 40300000
         SRL   GR9,4                                                    40320000
         AR    GR1,GR9                  GR1 = UNITS POSITION OF FIELD   40340000
         TM    0(GR1),X'0D'        TEST FOR MINUS SIGN                  40360017
         BO    *+12                BRANCH IF MINUS                      40380017
         NI    0(GR1),X'F0'                                             40400017
         OI    0(GR1),X'0C'        OTHERWISE FORCE SIGN TO BE PLUS      40420017
         SR    GR1,GR9                                                  40440000
         BR    GR7                      EXIT PACK SUBR                  40460000
PACN     PACK  0(0,GR1),0(0,GR10)                                       40480000
         SPACE 1                                                        40500000
*********************************************************************** 40520000
*   PACTST SUBR PACKS NUMERIC INPUT DATA INTO A PACKED FIELD AND      * 40540000
*  CHECKS THE STATUS OF THE FIELD                                     * 40560000
*********************************************************************** 40580000
         SPACE 1                                                        40600000
PACTST   LR    GR0,GR7                  SAVE CONTENTS OF REG 12         40620000
         BAL   GR7,PACK                 BRANCH TO PACK DATA INTO FIELD  40640000
         LR    GR7,GR0                  RESTORE GR7 (REG 12)            40660000
         SRL   GR11,4                                                   40680000
         SLL   GR11,4                                                   40700000
         OR    GR11,GR9                                                 40720000
         B     STAT                     BRANCH TO TEST FIELD STATUS     40740000
         SPACE 1                                                        40760000
*********************************************************************** 40780000
*   ZAPN MOVES PACKED NUMERIC INPUT DATA INTO A FIELD                 * 40800000
*********************************************************************** 40820000
         SPACE 1                                                        40840000
ZAPN     LR    GR9,GR11                                                 40860000
         SRL   GR9,4                                                    40880000
         AR    GR10,GR9                 GR10= UNITS POSITION OF INPUT   40900000
         MVC   SAVBYT+1(1),0(GR10)                                      40920000
         TM    0(GR10),X'0D'            TEST FOR MINUS SIGN             40940000
         BO    *+8                      BRANCH IF MINUS                 40960000
         OI    0(GR10),X'0F'            OTHERWISE FORCE SIGN TO BE PLUS 40980000
         SR    GR10,GR9                 RESTORE GR10TO START OF INPUT   41000000
         EX    GR11,ZAPN2F              MOVE INPUT DATA INTO FIELD      41020000
         AR    GR10,GR9                                                 41040000
SAVBYT   MVI   0(GR10),0                                                41060000
         BR    GR7                      EXIT ZAPN SUBR                  41080000
ZAPN2F   ZAP   0(0,GR1),0(0,GR10)                                       41100000
         SPACE 1                                                        41120000
*********************************************************************** 41140000
*   ZAPTST SUBR MOVES PACK NUMERIC INPUT DATA INTO A FIELD AND CHECKS * 41160000
*  THE STATUS OF THE FIELD                                            * 41180000
*********************************************************************** 41200000
         SPACE 1                                                        41220000
ZAPTST   LR    GR0,GR7                  SAVE CONTENTS OF REG 12         41240000
         BAL   GR7,ZAPN                 BRANCH TO MOVE DATA INTO FIELD  41260000
         LR    GR7,GR0                  RESTORE GR7 (REG 12)            41280000
         B     STAT                     BRANCH TO TEST FIELD STATUS     41300000
         SPACE 1                                                        41320000
*********************************************************************** 41340000
*   TEST4B SUBR CHECKS AN ALPHAMERIC FIELD TO CONTAIN ALL BLANKS AND  * 41360000
*  SETS ON THE BLANK INDICATOR                                        * 41380000
*********************************************************************** 41400000
         SPACE 1                                                        41420000
TEST4B   MVC   *+8(2),2(GR7)                                            41440000
         MVI   0(0),0                                                   41460000
         CLI   0(GR1),X'40'                                             41480000
         BNE   4(0,GR7)                                                 41500000
         LA    GR10,4(GR7)                                              41520000
         LTR   GR11,GR11                                                41540000
         BZ    SETONI-4                                                 41560000
         BCTR  GR11,0                                                   41580000
         EX    GR11,CL4BL                                               41600000
         BE    SETONI-4                                                 41620000
         BR    GR10                                                     41640000
CL4BL    CLC   0(0,GR1),1(GR1)                                          41660000
EDSPC    EQU   *                                                        41680000
DSPCLG   EQU   EDSPC-DSPC                                               41700000
STAFPB   EQU   FPBADR-DSPC              DISPLACEMENT FOR STORING FPB    41720000
*                                        ADDR FOR DSPC SUBR USE         41740000
         SPACE 3                                                        41760000
         ORG   DSPC+500                                                 41780000
EOBUF1   DS    CL2                                                      41800000
BUF1LG   EQU   EOBUF1-DMPTXTBF                                          41820000
         SPACE 1                                                        41840000
*********************************************************************** 41860000
*   DISPLACEMENTS FOR ENTERING THE MOVE FIELDS SUBR TO PERFORM THE    * 41880000
*  FOLLOWING FUNCTIONS                                                * 41900000
         SPACE 1                                                        41920000
PAC      EQU   0                        PACK INPUT DATA INTO FIELD      41940000
PACSET   EQU   4                        PACK AND TEST FIELD STATUS      41960000
ZAP      EQU   8                        MOVE PACKED INPUT DATA INTO FLD 41980000
ZAPSET   EQU   12                       MOVE PACKED DATA AND TEST FLD   42000000
STATUS   EQU   STAT-TRV                 TEST STATUS OF NUMERIC FIELD    42020000
*                                        (PLUS,MINUS OR ZERO)           42040000
*********************************************************************** 42060000
         SPACE 1                                                        42080000
         END   ASM20                                                    42100000
