         TITLE 'IES130  OS/360 RPG ASSEMBLE PHASE 2.5               25' 00020000
*  STATUS    CHANGE LEVEL 1-9                                    A33625 00040020
*FUNCTION/OPERATION:  RPG ASSEMBLE PHASE 2.5 PROCESSES THE COMPRESSED * 00060000
*                    INPUT SPECS AND GENERATES OBJECT PROGRAM CODE    * 00080000
*                    TO PERFORM THE FOLLOWING FUNCTIONS:              * 00100000
*                                                                     * 00120000
*                       GET NEXT INPUT RECORD                         * 00140000
*                       DETERMINE RECORD TYPE AND TURN ON INDICATOR   * 00160000
*                       CHECK ORDER OF RECORDS WHERE A PREDETERMINED  * 00180000
*                        SEQUENCE IS SPECIFIED                        * 00200000
*                       REQUEST STACKER SELECT                        * 00220000
*                       FILE SEQUENCE CHECKING                        * 00240000
*                       DETERMINE NEXT RECORD TO PROCESS OF A GROUP   * 00260000
*                        OF PRIMARY AND SECONDARY FILES (SET MR       * 00280000
*                        INDICATOR)                                   * 00300000
*                       TURN ON APPROPRIATE CONTROL LEVEL INDICATORS  < 00320000
*                       TURN ON LR INDICATOR AT END OF INPUT          < 00340000
         SPACE 1                                                        00360000
*ENTRY POINT:  IES13010 FROM IES13910                                 * 00380000
*                                                                     * 00400000
*              PHSLINK  L    15,PHSADDR                               * 00420000
*                       BALR 7,15                                     * 00440000
*                       *                                             * 00460000
*                       *                                             * 00480000
*                       *                                             * 00500000
*              PHSADDR  DC   V(IES12010)                              * 00520000
*                                                                     * 00540000
*              POINTERS, COUNTERS, AND CONSTANTS PASSED IN CIOEX DATA * 00560000
*              AREA POINTED TO BY REGISTERS 6 AND 12 UPON ENTRY       * 00580000
         SPACE 1                                                        00600000
*INPUT:  TABLES AND INFORMATION PASSED FROM ASSEMBLE PHASE 2 - SYSUT2 * 00620000
*        COMPRESSION (INPUT SPECS) - SYSUT1                           * 00640000
*                                                                     * 00660000
         SPACE 1                                                        00680000
*OUTPUT:  OBJECT TEXT - SYSPUNCH/SYSGO                                * 00700000
*         BLANK AFTER ENTRIES - SYSUT2                                * 00720000
*         RLD ENTRIES - SYSUT3                                        * 00740000
         SPACE 1                                                        00760000
*EXTERNAL ROUTINES:  IES13910 - CIOEX ROUTINES FOR ASSEMBLE PHASE 2.5 * 00780000
*                                                                     * 00800000
*                    GETCMP - GET NEXT BLOCK OF COMPRESSION           * 00820000
*                    PHSCAL - CALL NEXT PHASE                         * 00840000
*                    PTCMPR - POSITIONS COMPRESSION DATA SET FOR      * 00860000
*                             READING AT ORIGIN (REFERRED TO AS       * 00880000
*                              PNTCMP IN THIS PHASE)                  * 00900000
*                    RLDOUT - WRITES RLD ENTRIES                      * 00920000
*                    BLKOUT - WRITES BLANK AFTER ENTRIES              * 00940000
*                    BLKIN  - READS TABLES AND INFORMATION PASSED     * 00960000
*                             FROM ASSEMBLE PHASE 2                   * 00980000
*                    PTBLKW - REPOSITIONS, FOR WRITING AT ORIGIN, THE * 01000000
*                             DATA SET CONTAINING BLANK AFTER ENTRIES * 01020000
*                             (REFERRED TO AS PNTBLK)                 * 01040000
*                    PNTINP - CONDITIONS THE COMPRESSION DATA SET TO  * 01060000
*                             READ THE BLOCK CONTAINING THE FIRST     * 01080000
*                             INPUT SPEC                              * 01100000
*                                                                     * 01120000
*                               CIOEX DATA AREA                       * 01140000
*                                                                     * 01160000
*                    ADDCNT - COUNTER OF CORE USED FOR OBJECT PROG    * 01180000
*                    PHSNAM - NAME OF NEXT PHASE                      * 01200000
*                    IDSPLC - DISPLACEMENT TO FIRST INPUT SPEC IN     * 01220000
*                             COMPRESSION                             * 01240000
*                    SEQINP - SEQUENCE NUMBER OF FIRST INPUT SPEC     * 01260000
*                    SEQCAL - SEQUENCE NUMBER OF FIRST CALC SPEC      * 01280000
*                    NUMBLK - NUMBER OF BLANK AFTER ENTRIES           * 01300000
*                    COLSEQ - ALTERNATE COLLATING SEQUENCE            * 01320000
*                    PASKEY - TEMPORARY STORAGE BETWEEN PHASES        * 01340000
         SPACE 1                                                        01360000
*EXITS - NORMAL:    VIA CIOEX PHSCAL ON LAST INPUT SPECIFICATION      * 01380000
*                   IN COMPRESSION                                    * 01400000
         SPACE 1                                                        01420000
*TABLES/WORK AREAS:  COMMON DATA ADTMVF TO DATEND, PASSED BY          * 01440000
*                    ASSEMBLE PHASE 2                                 * 01460000
*                    ASMBLK - AREA FOR ASSEMBLE OF OBJECT TEXT        * 01480000
*                                                                     * 01500000
*                    DMPTXTBF - AREA FOR OUTPUT OF OBJECT TEXT        * 01520000
         SPACE 1                                                        01540000
*ATTRIBUTES:  EDITABLE, DOWNWARD COMPATIBLE                           * 01560000
*                                                                     * 01580000
         EJECT                                                          01600000
IES13010 START                                                          01620000
*0754016400,379800                                                 7358 01630017
*0754024600,000400                                                 000D 01640017
         EXTRN IES13910                                                 01660000
         SPACE 2                                                        01680000
*********************************************************************** 01700000
*   THE FOLLOWING CIOEX SUBROUTINES AND DATA AREAS ARE USED BY        * 01720000
*  ASSEMBLE PHASE 2.5                                                 * 01740000
*********************************************************************** 01760000
         SPACE 1                                                        01780000
GETCMP   EQU   0                        READ NEXT BLOCK OF COMPRESSION  01800000
PHSCAL   EQU   4                        CALL NEXT PHASE                 01820000
PNTCMP   EQU   16                       CONDITION GETCMP TO READ        01840000
*                                        BEGINNING WITH FIRST BLOCK     01860000
RLDOUT   EQU   18                       WRITE RLD ENTRIES               01880000
BLKOUT   EQU   24                       OUTPUT CONTROL LEVEL ENTRIES    01900000
*                                        AND BLANK AFTER ENTRIES        01920000
BLKIN    EQU   26                       READ CONTROL LEVEL ENTRIES      01940000
PNTBLK   EQU   28                       REPOSITION WK FILE TO ORIGIN    01960000
PNTINP   EQU   30                       CONDITION GETCMP TO READ        01980000
*                                        BEGINNING WITH 1ST BLK OF INP  02000000
ADDCNT   EQU   52                       COUNTER OF HIGHEST LOC USED     02020000
PHSNAM   EQU   8                        NAME OF NEXT PHASE              02040000
IDSPLC   EQU   134                      DISPLACE TO 1ST INPUT SPEC      02060000
NUMBLK   EQU   128                      NUMBER OF BLANK AFTER ENTRIES   02080000
COLSEQ   EQU   148                                                      02100000
PASKEY   EQU   196                                                      02120000
FSSBIT   EQU   X'21C'        FILE STACKER SELECT BITS              3369 02130015
         SPACE 3                                                        02140000
*********************************************************************** 02160000
*   THE FOLLOWING DISPLACEMENTS FOR LINKAGE VECTOR ENTRIES ARE USED   * 02180000
*  BY ASSEMBLE PHASE 2.5                                              * 02200000
*********************************************************************** 02220000
LVIOI    EQU   148                                                      02240000
LVCHNG   EQU   156                                                      02260000
STERIN   EQU   164                                                      02280000
LVDRTY   EQU   172                                                      02300000
LVDSPC   EQU   176                                                      02320000
LVGIRC   EQU   180                                                      02340000
LVIORB   EQU   200                                                      02360000
LVWORK   EQU   232                                                      02380000
LVOVF1   EQU   236                                                      02400000
LVCLSR   EQU   264                                                      02420000
LVDRTZ   EQU   272                                                      02440000
LVALTS   EQU   288                                          A33626      02460020
         EJECT                                                          02480000
*********************************************************************** 02500000
*   OBJECT PROGRAM DISPLACEMENTS                                      * 02520000
*********************************************************************** 02540000
         SPACE 1                                                        02560000
*   DISPLACEMENTS FOR ACCESSING THE IORB                                02580000
         SPACE 1                                                        02600000
IPREC    EQU   0                                                        02620000
ACTBYT   EQU   14                                                       02640000
EOFSW    EQU   19                                                       02660000
SELECT   EQU   15                                                       02680000
EOFVAL   EQU   34                                                       02700000
         SPACE 1                                                        02720000
*   DISPLACEMENTS FOR SAVING AND RESTORING REGISTERS IN A SAVE AREA     02740000
*    WITHIN THE GIRC OBJECT SUBR                                        02760000
         SPACE 1                                                        02780000
CHNGRR   EQU   4                                                        02800000
CHNGBR   EQU   8                                                        02820000
GIRCEX   EQU   4                                                        02840000
MBR      EQU   8                                                        02860000
DRTY2X   EQU   12                                                       02880000
FDRXIT   EQU   16                                                       02900000
GIRCBR   EQU   20                                                       02920000
GNRXIT   EQU   24                                                       02940000
GNXPRR   EQU   28                                                       02960000
GNSXIT   EQU   32                                                       02980000
SAVGR1   EQU   36                                                       03000000
SAV427   EQU   40                                                       03020000
         SPACE 1                                                        03040000
*   DISPLACEMENTS FOR ACCESSING THE FPB                                 03060000
         SPACE 1                                                        03080000
IORBDP   EQU   6                                                        03100000
FDRRI    EQU   12                       DISPLACEMENT FROM FDRIVR        03120000
FDRCL    EQU   16                       DISPLACEMENT FROM FDRIVR        03140000
FPBMFI   EQU   0                                                        03160000
EOFIND   EQU   1                                                        03180000
FPBMVF   EQU   4                                                        03200000
FPBRI    EQU   8                                                        03220000
FPBCL    EQU   12                                                       03240000
LNSCB    EQU   16                                                       03260000
FPBSEQ   EQU   20                                                       03280000
FPBEOF   EQU   20                                                       03300000
NSEQ     EQU   21                                                       03320000
NXTSEQ   EQU   22                                                       03340000
HISEQ    EQU   23                                                       03360000
MFHA     EQU   24                                                       03380000
         SPACE 1                                                        03400000
*   OTHER OBJ PROG DISPLACEMENTS                                        03420000
         SPACE 1                                                        03440000
H0       EQU   133                                                      03460000
MR       EQU   132                                                      03480000
LRIND    EQU   21                                                       03500000
UDFR     EQU   284                      DISPLACEMENT TO AREA CONTAINING 03520000
*                                        IORB ADDR IF AN UNDEFINED REC  03540000
H0CODE   EQU   288                      DISPLACEMENT TO BYTE WHICH      03560000
*                                        CONTAINS CODE FOR H0           03580000
RI01     EQU   23                       DISPLACEMENT TO RESULT IND 01   03600000
L1       EQU   123                                                      03620000
SSCALL   EQU   4                                                        03640000
STAFPB   EQU   72                       SEE DSPC IN CANNED CODE OUTPUT  03660000
*                                        BY PASS 1 (IF DSPC CHANGES     03680000
*                                        THE VALUE OF STAFPB MAY BE     03700000
*                                        AFFECTED)                      03720000
         SPACE 1                                                        03740000
*   DISPLACEMENTS FOR PROCESSING CONTROL LEVEL AND MATCHING FIELD SPECS 03760000
*  (SEE DMPSPC SUBR IN PASS 1)                                          03780000
         SPACE 1                                                        03800000
RR       EQU   0                        FIELD-RECORD RELATION INDICATOR 03820000
FF       EQU   2                        ADDR OF INPUT DATA              03840000
LG       EQU   4                        FIELD LENGTH                    03860000
NB       EQU   5                        LEVEL NUMBER AND SPEC TYPE      03880000
FTYPE    EQU   6                        FIELD TYPE (ALPHA,PACKED,ETC.)  03900000
         EJECT                                                          03920000
*********************************************************************** 03940000
*   ALLOCATION OF GENERAL REGISTERS FOR ASSEMBLE PHASE 2              * 03960000
*********************************************************************** 03980000
         SPACE 1                                                        04000000
GR0      EQU   0                        VOLATILE                        04020000
GR1      EQU   1                        VOL+TILE                        04040000
GR2      EQU   2                        VOLATILE                        04060000
GR3      EQU   3                        COMPRESSION AREA                04080000
GR4      EQU   4                        WORK REGISTER AND CIOEX USAGE   04100000
GR5      EQU   5                        WORK REGISTER AND CIOEX USAGE   04120000
GR6      EQU   6                        WORK REGISTER AND CIOEX USAGE   04140000
GR7      EQU   12                       WORK REGISTER AND CIOEX USAGE   04160000
GR8      EQU   8                        PHASE BASE REGISTER             04180000
GR9      EQU   9                        PHASE BASE REGISTER             04200000
GR10     EQU   10                       CIOEX USAGE (PRINT AREA)        04220000
GR11     EQU   11                       WORK REGISTER                   04240000
GR12     EQU   7                        WORK REGISTER                   04260000
GR13     EQU   13                       WORK REGISTER (COMPRESSION PTR) 04280000
GR14     EQU   14                       VOLATILE (LINKAGE REGISTER)     04300000
GR15     EQU   15                       VOLATILE (RETURN REGISTER)      04320000
         SPACE 1                                                        04340000
*NOTE - THE CONTENTS OF GR4-GR7 ARE SAVED UPON ENTERING ASSEMBLE        04360000
*    PHASE 2.5 AND ARE RESTORED BEFORE CALLING A CIOEX SUBROUTINE       04380000
         SPACE 2                                                        04400000
*NOTE - TEMPORARILY GR7 IS GENERAL REG 12 AND GR12 IS GENERAL REG 7     04420000
         SPACE 2                                                        04440000
*NOTE - THE TERM 'PASS 1' APPEARING IN THIS LISTING REFERS TO           04460000
*       ASSEMBLE PHASE 2                                                04480000
         SPACE 2                                                        04500000
*NOTE - THE TERM 'PASS 2' APPEARING IN THIS LISTING REFERS TO           04520000
*       ASSEMBLE PHASE 2.5                                              04540000
         EJECT                                                          04560000
ASM25    BALR  8,0                                                      04580000
         USING *,8,9                                                    04600000
BASEP2   L     GR9,B9ADDR                                               04620000
         L     GR12,CXRADDR            LOAD CIOEX POINTER               04640000
         STM   GR4,GR6,CIXSAV           SAVE CIOEX REGISTERS (4-7)      04660000
         MVC   PHSNAM(8,GR7),NXPHSN     PLACE NXT PHASE NAME INTO CIOEX 04680000
         BAL   GR14,ALIGN               BRANCH TO WORD ALIGN ADDR CNT   04700000
         LA    GR2,PNTBLK               POSITION WORK FILE AT ORGIN     04720000
         BAL   GR14,IOEXC                                               04740000
         LA    3,ADTMVF                 READ HEADER RECORD              04760000
         LR    1,3                                                      04780000
         LA    2,26                                                     04800000
         BALR  5,7                                                      04820000
         LH    13,ADTMVF+2              PICK UP COUNT OF DATA LENGTH    04840000
         LH    11,ADTMVF                PICK UP RECORD LENGTH           04860000
DATAIN1  LR    1,3                      READ IN DATA AREA               04880000
         LA    2,26                                                     04900000
         BALR  5,7                                                      04920000
         AR    3,11                     BUMP TABLE POINTER              04940000
         SR    13,11                    DECREMENT COUNT                 04960000
         BP    DATAIN1                                                  04980000
         MVC   ADSPC(4),OADSPC          PLACE OBJ ADDR OF DSPC (GENE-   05000000
*                                        RATED BY PASS 1( IN RLD REC    05020000
         MVC   TOFF(4),RRIOFF          PLACE INTO GIRC (OBJ SUBR) THE   05040000
*                                        ADDR OF SUBR GENERATED BY PASS 05060000
*                                        1 TO TURN OFF REC INDICATORS   05080000
         MVC   LOCWS(4),CLMFWS          PLACE OBJ ADDR OF WORK STORAGE  05100000
*                                        INTO DRTY OBJ SUBR             05120000
         MVC   ADRTY(4),ADDCNT(GR7)     PLACE OBJ ADDR OF DRTY IN RLD   05140000
         LA    GR11,DRTYLG              GR11 = LENGTH OF DRTY OBJ SUBR  05160000
         CLI   COLSEQ(GR7),X'F0'        TEST FOR USER ALTSEQ SUBR       05180000
         BNE   *+10                     BRANCH IF SPECIFIED             05200000
         MVC   ALTGO(4),STOGR1          OTHERWISE MODIFY TO             05220000
*                                        CALL USER SUBR                 05240000
         CLI   NSTAB,0                  TEST FOR PREDETERMINED RECORD   05260000
         BNE   A2SRLG                    SEQUENCE                       05280000
         CLC   NSTAB(24),NSTAB+1                                        05300000
         BE    *+8                      BRANCH IF NOT USED              05320000
A2SRLG   LA    GR11,PRESLG(GR11)        OTHERWISE ADD LENGTH OF PRESEQ  05340000
         STH   GR11,SUBRLG               OBJ SUBR (TO FOLLOW DRTY SUBR  05360000
         BAL   GR14,DMPTXT               IN OBJ PROG)                   05380000
SUBRLG   DC    AL2(0)                   OUTPUT SUBROUTINE(S)            05400000
         DC    AL4(DRTY)                                                05420000
         BAL   GR15,ADD2AC+4            ADD SUBR LENGTH TO OBJ ADDR CNT 05440000
         BAL   GR14,FINTXT              COMPLETE OUTPUT OF DRTY         05460000
         BAL   GR14,ALIGN                                               05480000
         CLI   CLSIND,X'F0'             TEST FOR CONTROL LEVELS PRESENT 05500000
         BNE   P2GOGO                   BRANCH IF NOT                   05520000
         SPACE 1                                                        05540000
*   GENERATE THE CLSUBR                                                 05560000
         SPACE 1                                                        05580000
         MVC   CLHA(4),HA                                               05600000
         MVC   ACLSR(4),ADDCNT(GR7)     SAVE ADDR OF CLSUBR             05620000
         OI    PASKEY+4(GR7),X'02'      SET PASKEY IN CIOEX DATA        05640000
         SR    GR3,GR3                                                  05660000
         LR    GR1,GR3                                                  05680000
         LA    GR4,1                                                    05700000
         LA    GR5,8                                                    05720000
         LA    GR1,CLWSDP                                               05740000
GENCLS   MVC   CLCMPR+2(2),0(GR1)       HOLD AREA DISPL INTO CLC   1579 05760015
         MVC   CLCMPR+4(2),0(GR1)       WORK STO DISPL INTO CLC    1579 05780015
         OI    CLCMPR+2,X'A0'                                      1579 05800015
         OI    CLCMPR+4,X'90'                                      1579 05820015
         IC    GR2,CLMAX(GR3)                                           05840000
         BCTR  GR2,0                                                    05860000
         STC   GR2,CLCMPR+1             PLACE LENGTH IN CLC        1579 05880015
         MVC   MV2HA+1(5),CLCMPR+1      OPERANDS OF CLC INTO MVC   1579 05900015
         STC   GR3,MV2HA+7              PLACE LENGTH INTO 2ND MVC INST  05920000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT TEXT           05940000
         DC    AL2(CLSUBL)                                              05960000
         DC    AL4(CLSUBR)                                              05980000
         LA    GR1,2(GR1)               ADVANCE TO NEXT ENTRY IN CLWSDP 06000000
         BXLE  GR3,GR4,GENCLS           REPEAT FOR EACH CONTROL LEVEL   06020000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT DATA FOLLOWING 06040000
         DC    AL2(8)                    CLSUBR                         06060000
         DC    AL4(CLHA-4)                                              06080000
         LA    GR11,CLSRLG                                              06100000
         BAL   GR15,ADD2AC+4            BRANCH TO UPDATE ADDR COUNTER   06120000
P2GOGO   LA    GR2,PNTBLK               POSITION WORK FILE AT ORGIN FOR 06140000
         BAL   GR14,IOEXC                BLANK AFTER ENTRIES            06160000
         XC    NUMBLK(2,GR7),NUMBLK(GR7)                                06180000
         BAL   GR15,GETINP              BRANCH TO GET 1ST INPUT SPEC    06200000
         LA    GR13,6(GR13)                                             06220000
         PACK  PACWS(8),4(2,GR3)                                        06240000
         CVB   GR1,PACWS                CONVERT FILR NO. IN SPEC TO     06260000
         ST    GR1,FILEN                 BINARY AND SAVE                06280000
         LA    GR12,ASMBLK              GR12 = STARTING LOC OF ASMBLK   06300000
         L     GR11,OBJPBR                                              06320000
         LA    GR6,FET-1                                                06340000
         A     GR6,FILEN                                                06360000
         TM    1(GR3),X'60'             TEST FIRST REC SPEC TO HAVE     06380000
         BC    14,FPBFDR+8               NUMERIC SEQ - BRANCH IF NOT    06400000
         PACK  PACWS(8),2(2,GR3)        OTHERWISE CONVERT NUMBER TO     06420000
         CVB   GR2,PACWS                 BINARY AND SAVE                06440000
         STC   GR2,SEQNUM                                               06460000
         MVC   CTLBYT(1),1(GR3)         SAVE CONTROL BYTE               06480000
         B     FPBFDR                   BRANCH TO PROCESS 1ST SPEC      06500000
         SPACE 3                                                        06520000
ASMBLK   EQU   BASEP2                   AREA FOR ASSEMBLING OBJ CODE    06540000
*                                        OVERLAYS PRECEDING CODE        06560000
         SPACE 2                                                        06580000
ARGTAB   EQU   BASEP2+120                AREA FOR GENERATING OBJ PROG   06600000
*                                       TABLES USED BY DRTY (OBJ SUBR)  06620000
CHFTAB   EQU   ARGTAB+26                TO ACCESS FDRIVR AND RECORD     06640000
*                                       GROUP ROUTINES FOR CHAINING     06660000
*                                       FILES (THIS AREA OVERLAYS       06680000
*                                       PRECEDING CODE)                 06700000
         EJECT                                                          06720000
*********************************************************************** 06740000
*   PASS 2 PROCESSING OF THE INPUT RECORD TYPE SPEC.                  * 06760000
*********************************************************************** 06780000
         SPACE 2                                                        06800000
RECSPC   TM    1(GR3),X'60'             TEST TYPE OF RECORD SPEC        06820000
         BZ    ORSPEC                   BRANCH IF 'OR'                  06840000
         BO    NEWREC                   BRANCH IF NUMERIC               06860000
         TM    1(GR3),X'20'             TEST FOR ALPHA OR 'AND'         06880000
         BZ    NEWREC                   BRANCH IF ALPHA                 06900000
         LA    GR13,2(GR13)             OTHERWISE PROCESS 'AND'         06920000
         B     GENIDT                                                   06940000
         SPACE 2                                                        06960000
*********************************************************************** 06980000
*   PROCESS 'OR' SPEC, COMPLETE GENERATING OBJECT CODE FOR PRECEDING  * 07000000
*  'OR' GROUP, GENERATE BRANCH TO RECORD DRIVER, DEFINE UNDEFINE      * 07020000
*   BRANCH INSTRUCTIONS IN THE PRECEDING 'OR' GROUP (BRANCH TO NEXT   * 07040000
*   'OR' GROUP), AND SAVE RESULTING INDICATOR OF THE CURRENT SPEC.    * 07060000
*********************************************************************** 07080000
         SPACE 2                                                        07100000
ORSPEC   BAL   GR15,GENORX                                              07120000
         MVC   0(4,GR12),B04            GENERATE BRANCH TO REC DRIVER   07140000
         LA    GR12,4(GR12)             ADVANCE TO NEXT LOC IN ASMBLK   07160000
         OI    UBA04,X'F0'              INDICATE UBA 04 GENERATED       07180000
         BAL   GR14,TXTOUT                                              07200000
         BAL   GR1,DEFUB2                                               07220000
         LA    GR13,2(GR13)             ADVANCE CMPPTR                  07240000
         B     SAVERI                                                   07260000
         EJECT                                                          07280000
*********************************************************************** 07300000
*   GENERATE THE FOLLOWING INSTRUCTIONS AFTER THE LAST RECORD ID CODE * 07320000
*  TEST WITHIN AN 'OR' GROUP.                                         * 07340000
*                                                                     * 07360000
LA1RI    LA    GR10,0                   GR1 = ADDR OF RESULT INDICATOR  07380000
         SPACE 1                                                        07400000
*   IF FILE DEVICE IS CARD READER GENERATE THE FOLLOWING              * 07420000
         SPACE 1                                                        07440000
SS       MVI   SSCALL(GR14),0           RETURN STACKER CODE TO SCODE    07460000
*                                        IN DRTY2 OBJECT SUBR           07480000
         SPACE 1                                                        07500000
B04      B     4(0)                                                     07520000
*********************************************************************** 07540000
         SPACE 2                                                        07560000
GENORX   MVC   0(4,GR12),LA1RI                                          07580000
         LA    GR12,4(GR12)                                             07600000
         TM    0(GR6),X'01'       TEST FET BYTE FOR  CARD READER   3369 07620015
         BE    DMPORX                   BRANCH IF NOT USED (INPUT       07640000
*                                        DEVICE IS NOT A CARD READER)   07660000
         MVC   0(4,GR12),SS                                             07680000
         LA    GR12,4(GR12)                                             07700000
DMPORX   BAL   GR14,TXTOUT              BRANCH TO OUTPUT TEXT           07720000
         BR    GR15                                                     07740000
         SPACE 2                                                        07760000
GENORN   ST    GR15,PACWS+4                                             07780000
         BAL   GR15,GENORX              COMPLETE OBJ CODE FOR LAST 'OR' 07800000
         CLI   UBA04,0                                                  07820000
         BE    GENORE                                                   07840000
         MVI   UBA04,0                                                  07860000
         BAL   GR1,DEFUB4                                               07880000
GENORE   L     GR15,PACWS+4                                             07900000
         BR    GR15                                                     07920000
         EJECT                                                          07940000
*********************************************************************** 07960000
*   PASS 2 PROCESSING OF THE FIRST SPEC OF A RECORD GROUP             * 07980000
*********************************************************************** 08000000
         SPACE 2                                                        08020000
NEWREC   LA    GR13,6(GR13)             ADVANCE CMPPTR                  08040000
         CLI   FLDSW,X'F0'              TEST FOR FIELD SPECS PRESENT    08060000
*                                        IN PRECEDING RECORD GROUP      08080000
         BE    *+8                      BRANCH IF YES (FLDSW = X'F0')   08100000
         BAL   GR15,GENORN              OTHERWISE COMPLETE OBJ CODE FOR 08120000
*                                        LAST 'OR' OF PRECEDING         08140000
*                                        RECORD GROUP                   08160000
         MVI   FLDSW,0                   SET FLDSW = 0 (OFF)            08180000
         TM    1(GR3),X'04'             TEST FOR FILE NO. IN CURRENT    08200000
         BZ    BEGREC-4                  SPEC, BRANCH IF NONE           08220000
         PACK  PACWS(8),4(2,GR3)        CONVERT FILE NO. TO BINARY      08240000
         CVB   GR1,PACWS                                                08260000
         CL    GR1,FILEN                TEST FOR FILE NO. CHANGE        08280000
         BE    BEGREC-4                 BRANCH IF NO CHANGE (EQUAL)     08300000
         ST    GR1,FILEN                OTHERWISE STORE NEW FILE NO.    08320000
         MVI   SS+1,0                   RESET SS TO ZERO                08340000
         BAL   GR15,GENRDR              BRANCH TO GENERATE DRIVER FOR   08360000
*                                        LAST RECORD GROUP OF A FILE    08380000
         BAL   GR15,GEUNID              GENERATE CODE TO HANDLE UN-     08400000
*                                        IDENTIFIED RECORD              08420000
         BAL   GR15,ADD2AC               BRANCH TO UPDATE ADDRESS COUNT 08440000
         BAL   GR14,FINTXT              FORCE WORD ALIGNMENT FOR OBJ    08460000
         BAL   GR14,ALIGN                CODE OF NEXT FILE GROUP        08480000
         EJECT                                                          08500000
*********************************************************************** 08520000
*   GENERATE A FILE DRIVER (FDRIVR AND FPB) FOR INPUT FILE GROUP      * 08540000
*  (SEE CANNED OBJECT CODE OUTPUT BY PASS 2)                          * 08560000
*********************************************************************** 08580000
         SPACE 1                                                        08600000
FPBFDR   LA    GR6,FET-1                ADVANCE TO NEXT ENTRY IN FET    08620000
         A     GR6,FILEN                                                08640000
         TM    0(GR6),X'C0'             TEST FILE TYPE BITS IN FET      08660000
         BZ    PFILE                    BRANCH IF PRIMARY               08680000
         BM    SFILE                    BRANCH IF SECONDARY             08700000
         LA    GR1,ARGTAB               IF CHAINING SAVE ADDR OF FDRIVR 08720000
         A     GR1,FILEN                 IN CHFTAB AND THE CORRESPOND-  08740000
         IC    GR2,ARGM                  ING ARGUMENT IN ARGTAB         08760000
         STC   GR2,0(GR1)                                               08780000
         LA    GR2,4(GR2)               ADVANCE ARG FOR NEXT FILE USE   08800000
         STC   GR2,ARGM                                                 08820000
         L     GR1,CHFPTR                                               08840000
         MVC   0(4,GR1),ADDCNT(GR7)     PLACE OBJ ADDR OF FDRIVR INTO   08860000
         LA    GR1,4(GR1)                CHFTAB                         08880000
         ST    GR1,CHFPTR               ADVANCE POINTER TO NEXT LOC     08900000
         B     GENFDR                                                   08920000
PFILE    MVC   PRIFPB(4),ADDCNT(GR7)    PLUG INTO GIRC (OBJ SUBR) THE   08940000
*                                        OBJ ADDR OF FDRIVR (FPB) FOR   08960000
*                                        THE PRIMARY FILE               08980000
         TM    0(GR6),X'04'             TEST SEQUENCE BIT IN FET ENTRY  09000000
         BO    TEST4E                   BRANCH IF ASCENDING             09020000
         MVI   SELNXR+11,X'40'          OTHERWISE IF DESCENDING MODIFY  09040000
         MVI   NXTS+11,X'B0'             GIRC INSTRUCTIONS              09060000
         B     TEST4E                   BRANCH TO GENERATE FDRIVR - FPB 09080000
SFILE    CLI   MULTI,1                  TEST FOR ONLY ONE SECONDARY     09100000
         BNE   SFILE2-4                 BRANCH IF MORE                  09120000
         LA    GR1,NXT2ND               OTHERWISE ADDR OF FDRIVR - FPB  09140000
         B     SFILE2                    IS TO BE PLACED INTO NXT2ND    09160000
*                                        LOCATION WITHIN GIRC SUBR      09180000
         L     GR1,PTR2ND               IF 2 OR MORE SECONDARY, PLACE   09200000
*                                        ADDRESSES INTO IP2NDS TABLE    09220000
*                                        IMMEDIATELY FOLLOWING GIRC SUB 09240000
SFILE2   MVC   0(4,GR1),ADDCNT(GR7)                                     09260000
         LA    GR1,4(GR1)               ADVANCE POINTER TO NEXT LOC     09280000
         ST    GR1,PTR2ND                IN IP2NDS TABLE                09300000
TEST4E   TM    0(GR6),X'08'             TEST (FET) FOR E IN COL 17      09320000
*                                        OF FILE SPEC                   09340000
         BZ      GENFDR                 BRANCH IF NOT                   09360000
         LH    GR1,ECOUNT               OTHERWISE ADD TO ECOUNT         09380000
         LA    GR1,1(GR1)                WITHIN GIRC OBJ SUBR           09400000
         STH   GR1,ECOUNT                                               09420000
GENFDR   XC    8(18,GR12),8(GR12)                                       09440000
         MVC   0(8,GR12),FDRIVR                                         09460000
         MVC   24(1,GR12),0(GR6)        PLACE CONTROL BYTE FROM FET     09480000
*                                        INTO FPB                       09500000
         MVI   26(GR12),1                                               09520000
         L     GR1,NSTPTR               GR1 POINTS TO NSTAB             09540000
         MVC   27(1,GR12),0(GR1)        MOVE HIGHEST NUMERIC RECORD SEQ 09560000
*                                        NO. FOR FILE INTO FPB          09580000
         LA    GR1,1(GR1)                CALLING SEQUENCE               09600000
         ST    GR1,NSTPTR               ADVANCE POINTER AND STORE       09620000
         L     GR1,NSCPTR                                               09640000
         MVC   20(4,GR12),0(GR1)                                        09660000
         LA    GR1,4(GR1)                                               09680000
         ST    GR1,NSCPTR                                               09700000
         L     GR1,FILEN                                                09720000
         BCTR  GR1,0                                                    09740000
         SLL   GR1,5                    COMPUTE DISPLACEMENT TO IORB    09760000
         STH   GR1,IORBDP(GR12)          AND PLACE INTO FPB             09780000
         SR    GR1,GR1                                                  09800000
         TM    0(GR6),X'10'             TEST FOR MATCHING FIELDS        09820000
         BZ    AD2AC-8                  BRANCH IF NONE FOR THIS FILE    09840000
         SPACE 1                                                        09860000
*   GENERATE VARIABLE PART OF FPB (MATCHING FIELDS INDICATOR AND        09880000
*  HOLDING AREA                                                         09900000
         SPACE 1                                                        09920000
         TM    0(GR6),X'C0'             TEST FILE TYPE                  09940000
         BO    *+12                     BRANCH IF CHAINED FILE          09960000
         IC    GR1,PSFMFL               GR1 = MF LENGTH FOR PRIMARY     09980000
         B     *+20                      AND/OR SECONDARY FILE(S)       10000000
         L     GR5,CHFMFP               GR5 = POINTER FOR CHAINED FILE  10020000
         IC    GR1,0(GR5)                MF LENGTH LIST                 10040000
         LA    GR5,1(GR5)               GR1 = MF LENGTH FOR CHAIN FILE  10060000
         ST    GR5,CHFMFP               ADD 1 TO CHFMFP AND STORE       10080000
         LA    GR1,1(GR1)                                               10100000
         SRL   GR1,1                                                    10120000
         SLL   GR1,1                    FORCE HALF WORD ALIGNMENT       10140000
         MVI   28(GR12),X'B0'           GENERATE DATA IDENTIFER AND     10160000
         STC   GR1,29(GR12)              LENGTH FOR DMPTXT USE (TO RE-  10180000
         LA    GR2,28(GR1)               SERVE MF HOLD AREA)            10200000
         STH   GR2,2(GR12)              MODIFY BRANCH ADDR OF THE BAL   10220000
*                                        INST PRECEDING FPB IN OBJ PROG 10240000
         LA    GR12,28(GR1,GR12)        ADD LENGTH REQUIRED FOR MF(S)   10260000
*                                        TO GR12                        10280000
         BAL   GR14,TXTOUT              OUTPUT FDRIVR AND FPB           10300000
         SPACE 1                                                        10320000
AD2AC    BAL   GR15,ADD2AC                                              10340000
         B     SAVNS                    BRANCH TO CONTINUE PROCESSING   10360000
*                                        CURRENT RECORD SPEC            10380000
         SPACE 2                                                        10400000
GEUNID   CLI   IDCSW,X'00'              TEST FOR ID CODES IN PRECEDING  10420000
*                                       RECORD GROUP                    10440000
         BE    0(0,GR15)                BRANCH IF NONE                  10460000
         BAL   GR1,DEFUB2                                               10480000
         MVI   IDCSW,0                                                  10500000
         MVC   0(4,GR12),SETHLT         OTHERWISE GENERATE CODE TO      10520000
         MVC   4(4,GR12),RDRIVR+4                                       10540000
         LA    GR12,8(GR12)              HANDLE UNIDENTIFIED RECORDS    10560000
         TM    0(GR6),X'01'             TEST FOR CARD READER AS INPUT   10580000
*                                       DEVICE (TEST FET ENTRY)         10600000
         BZ    GEUNIX                   BRANCH IF OTHER                 10620000
         MVC   0(4,GR12),SS             OTHERWISE GENERATE INSTRUCTION  10640000
         LA    GR12,4(GR12)              TO PLACE SELECT CODE IN IORB   10660000
GEUNIX   MVC   0(4,GR12),RDRXIT                                         10680000
         LA    GR12,4(GR12)                                             10700000
         BAL   GR14,TXTOUT              BRANCH TO OUTPUT TEXT           10720000
         BR    GR15                     EXIT GEUNID                     10740000
DEFUB2   MVI   UBANO+1,2                                                10760000
         B     DEFUB4+4                                                 10780000
DEFUB4   MVI   UBANO+1,4                                                10800000
         LR    GR14,GR11                                                10820000
         SH    GR14,FOUR                                                10840000
         STH   GR14,UBAADR                                              10860000
         BAL   GR14,ADRDEF                                              10880000
UBANO    DC    AL2(0)                                                   10900000
UBAADR   DC    AL2(0)                                                   10920000
         BR    GR1                                                      10940000
         EJECT                                                          10960000
GENRDR   EQU   *                                                        10980000
         MVC   0(8,GR12),RDRIVR         GENERATE FIXED PART OF RDRIVR   11000000
         MVI   SAFETY+1,X'4C'                                           11020000
         LA    GR12,8(GR12)                                             11040000
         BAL   GR14,TXTOUT                                              11060000
         MVI   SAFETY+1,X'0C'                                           11080000
         MVC   0(2,GR12),RDRXIT                                         11100000
         MVI   4(GR12),X'B0'            DATA IDENTIFIER PRECEDING ADD-  11120000
         ST    GR3,ARGSAV               SAVE GR3                        11140000
         ST    GR6,ARGSAV+4                                             11160000
         LM    GR1,GR3,MVFPTR           LOAD OINTERS                    11180000
         LR    GR6,GR12                                                 11200000
         LA    GR12,6(GR12)                                             11220000
         MVI   0(GR12),0                                                11240000
         MVC   1(3,GR12),0(GR1)         PLACE ADDR OF MVFLDS IN RDRIVR  11260000
         LA    GR12,4(GR12)                                             11280000
         LA    GR1,3(GR1)               ADVANCE MVFPTR                  11300000
         SR    GR5,GR5                                                  11320000
         CLI   CLS,X'F0'                TEST FOR CONTROL LEVELS         11340000
         BNE   TRYMFS                   BRANCH IF NONE                  11360000
         MVI   0(GR12),0                                                11380000
         MVC   1(3,GR12),0(GR2)         OTHERWISE PLACE ADDR OF MCL2WS  11400000
         LA    GR12,4(GR12)              (OBT SUBR) IN RDRIVR           11420000
         LA    GR2,3(GR2)               ADVANCE CLSPTR                  11440000
         LA    GR5,4                                                    11460000
TRYMFS   CLI   MFS,X'F0'                TEST FOR MATCHING FLDS          11480000
         BNE   GENRDM                   BRANCH IF NONE                  11500000
         MVI   0(GR12),0                                                11520000
         MVC   1(3,GR12),0(GR3)         OTHERWISE PLACE ADDR OF MFSUBR  11540000
         LA    GR12,4(GR12)              (OBJ SUBR) IN RDRIVR           11560000
         LA    GR3,3(GR3)                                               11580000
         LA    GR5,4(GR5)                                               11600000
GENRDM   MVC   0(4,GR12),XMVC           GENERATE MVC TO MOVE ADDR OF    11620000
         LA    GR4,2(GR11)               MVFLDS INTO FPB                11640000
         STH   GR4,4(GR12)                                              11660000
         LA    GR12,6(GR12)                                             11680000
         CLI   CLS,X'F0'                TEST AGAIN FOR CONTROL LEVELS   11700000
         BNE   TRYMF2                   BRANCH IF NONE                  11720000
         MVC   0(4,GR12),XMVC2          OTHERWISE GENERATE MVC TO MOVE  11740000
         LA    GR4,4(GR4)                ADDR OF MCL2WS INTO FPB        11760000
         STH   GR4,4(GR12)                                              11780000
         LA    GR12,6(GR12)                                             11800000
TRYMF2   CLI   MFS,X'F0'                TEST AGAIN FOR MATCHING LFDS    11820000
         BNE   GENRDX                   BRANCH IF NONE                  11840000
         MVC   0(2,GR12),XMVC           OTHERWISE GENERATE MVC TO       11860000
         MVI   2(GR12),X'E0'             RETURN ADDR OF MFSUBR TO DRTY2 11880000
         MVI   3(GR12),0                                                11900000
         LA    GR4,4(GR4)                                               11920000
         STH   GR4,4(GR12)                                              11940000
         LA    GR12,6(GR12)                                             11960000
GENRDX   LA    GR4,4(GR4)               COMPLETE B INSTRUCTION PRECED-  11980000
         STH   GR4,2(GR6)                ING ADDRESSES OF SUB-OUT+NES   12000000
         LA    GR5,6(GR5)               PLACE LENGTH TO RESERVE FOR     12020000
         STC   GR5,5(GR6)                                               12040000
         CLI   SEQNUM,0                 TEST FOR NUMERIC RECORD SEQ     12060000
         BE    GENRX                    BRANCH IF NOT                   12080000
         MVC   0(8,GR12),PDRSEQ         OTHERWISE GENERATE CALLING      12100000
         LA    GR12,8(GR12)              SEQUENCE FOR PRESEQ SUBR       12120000
         B     GENRX+10                                                 12140000
GENRX    MVC   0(4,GR12),RDRXIT         GENERATE B 4(GR14) TO EXIT      12160000
         LA    GR12,4(GR12)              FROM RDRIVR                    12180000
         STM   GR1,GR3,MVFPTR           SAVE POINTERS                   12200000
         L     GR3,ARGSAV               RESTORE GR3                     12220000
         L     GR6,ARGSAV+4                                             12240000
         XC    CLS(2),CLS               SET CLS AND MFS TO ZERO         12260000
         BAL   GR14,TXTOUT              BRANCH  TO OUTPUT TEXT          12280000
         MVI   SEQNUM,0                 CLEAR REC SEQ NUMBER            12300000
         BR    GR15                     EXIT GENRDR                     12320000
         EJECT                                                          12340000
*********************************************************************** 12360000
*   START GENERATING OBJECT CODE FOR AN INPUT RECORD GROUP            * 12380000
*********************************************************************** 12400000
         SPACE 2                                                        12420000
         BAL   GR15,GENRDR              BRANCH TO GENERATE REC DRIVER   12440000
*                                        FOR SECOND AND SUBSEQUENT      12460000
*                                        RECORD GROUPS OF A FILE GROUP  12480000
BEGREC   BAL   GR1,DEFUB2                                               12500000
         BAL   GR15,ADD2AC              BRANCH TO UPDATE ADDRESS COUNT  12520000
SAVNS    TM    1(GR3),X'60'             TEST FOR NUMERIC REC SEQ        12540000
         BC    12,SAVERI-10             BRANCH IF NOT                   12560000
         PACK  PACWS(8),2(2,GR3)        CONVERT NUMERIC RECORD SEQUENCE 12580000
         CVB   GR2,PACWS                 NUMBER AND SAVE                12600000
         STC   GR2,SEQNUM                                               12620000
         MVC   CTLBYT(1),1(GR3)         SAVE CONTROL BYTE               12640000
         MVC   ASMBLK(4),BAL4           GENERATE BALR 8,0 AS 1ST INST   12660000
*                                        OF OBJ CODE FOR RECORD GROUP   12680000
         LA    GR12,ASMBLK+4            GR12 = NXT AVA&L LOC &N ASMBLK  12700000
SAVERI   MVC   LA1RI+2(2),0(GR13)       SAVE ADDR OF RESULTING IND      12720000
         LA    GR13,2(GR13)                                             12740000
         TM    0(GR6),X'01'             TEST FILE DEVICE                12760000
         BO    CK4SS                    BRANCH IF CARD READER           12780000
         SPACE 1                                                        12800000
         TM    1(GR3),X'80'             FOR OTHER DEVICE TYPES IGNORE   12820000
         BO    AD14SS                    STACKER SELECT IF SPECIFIED    12840000
         B     GENIDT                                                   12860000
         SPACE 1                                                        12880000
CK4SS    TM    1(GR3),X'80'             TEST FOR STACKER SELECT         12900000
         BO    AROUND             BRANCH IF STKR SEL NOT SPECIFIED 3369 12910015
         LA    GR14,1             TEST IF FILE IS                  3369 12920015
         L     GR1,FILEN            TO BE STACKER SELECTED.        3369 12930015
         SLL   GR14,0(GR1)        IF ANY REC GRP IS SS THEN THE    3369 12940015
         N     GR14,FSSBIT(GR7)     ENTIRE FILE IS STKR SELECTED   3369 12950015
         BZ    GENIDT             IF NOT, LEAVE SS CODE = X'00'    3369 12960015
         MVI   SS+1,X'01'         OTHERWISE SET STACKER CODE TO 01 3369 12970015
         B     GENIDT             BRANCH, DO NOT ADVANCE COMPR     3369 12980015
AROUND   MVN   SS+1(1),0(GR13)    HERE IF STKR SEL SPECIFIED       3369 12990015
         TR    SS+1(1),SSCODE-1          STACKER SELECT CODE            13000000
AD14SS   LA    GR13,1(GR13)             ADVANCE CMPPTR                  13020000
         EJECT                                                          13040000
*********************************************************************** 13060000
*   GENIDT GENERATES OBJ PROG INSTUCTIONS TO TEST RECORD ID CODES FOR * 13080000
*  DETERMINING RECORD TYPE (SEE DESCRIPTION FOLLOWING THE ROUTINE)    * 13100000
*********************************************************************** 13120000
         SPACE 2                                                        13140000
GENIDT   TM    1(GR3),X'03'             TEST FOR ID CODES IN CURRENT    13160000
         BZ    EMNXT1                    SPEC, BRANCH IF PRESENT        13180000
         MVI   IDCSW,X'F0'                                              13200000
         IC    GR2,1(GR3)                                               13220000
         LA    GR1,X'03'                                                13240000
         NR    GR1,GR2                  GR1 = NUMBER OF ID CODEES       13260000
IDLOOP   ZAP   PACWS(8),0(3,GR13)                                       13280000
         CVB   GR2,PACWS                GR2 = POSITION OF ID CODE       13300000
         BCTR  GR2,0                                                    13320000
         A     GR2,B2                    WITHIN THE REOCRD              13340000
         TM    3(GR13),X'40'            TEST FOR CHARACTER COMPARE      13360000
         BZ    ZORD                     BRANCH IF NOT                   13380000
         MVI   0(GR12),X'95'            OTHERWISE GENERATE CLI AND      13400000
         MVC   1(1,GR12),4(GR13)         PLACE IDENTIFYING CHARACTER    13420000
         STH   GR2,2(GR12)               IN THE I2 FIELD                13440000
         LA    GR12,4(GR12)                                             13460000
         B     BEBNE                                                    13480000
         SPACE 1                                                        13500000
*   GENERATE CALLING SEQUENCE FOR SUBR TO TEST ZONE OR DIGIT ID CODES   13520000
         SPACE 1                                                        13540000
ZORD     MVC   ZIDCC+3(1),4(GR13)       PLACE COMPARE CODE IN CALL SEQ  13560000
         STH   GR2,TSTZID+6             PLACE COL (BDDD) IN CALL SEQ    13580000
         OI    PASKEY+4(GR7),X'01'      SET PASKEY IN CIOEX DATA        13600000
         TM    3(GR13),X'20'            TEST FOR ZONE COMPARE           13620000
         BZ    DIGITI                   BRANCH IF NOT                   13640000
         MVC   0(14,GR12),TSTZID        GENERATE CALL FOR COMPARING     13660000
         LA    GR12,14(GR12)             ZONE PORTION                   13680000
         B     BEBNE                                                    13700000
DIGITI   MVC   0(12,GR12),TSTZID        GENERATE CALL FOR COMPARING     13720000
         MVC   12(4,GR12),BALDIT         DIGIT PORTION                  13740000
         LA    GR12,16(GR12)                                            13760000
BEBNE    TM    3(GR13),X'80'            TEST FOR NEGATIVE OR POSITIVE   13780000
         BZ    GENBNE                    TEST, BRANCH IF POSITIVE       13800000
         MVC   0(4,GR12),BE02           FOR NEGATIVE GENERATE BE 2(0)   13820000
         B     *+10                      (BRANCH TO NEXT 'OR' OR REC)   13840000
GENBNE   MVC   0(4,GR12),BNE02          FOR POSITIVE GENERATE BNE 2(0)  13860000
         LA    GR12,4(GR12)                                             13880000
         LA    GR13,5(GR13)             ADVANCE CMPPTR                  13900000
         BCT   GR1,IDLOOP               LOOP TO PROCESS NEXT ID CODE    13920000
         BAL   GR14,TXTOUT              BRANCH TO OUTPUT TEXT           13940000
EMNXT1   BAL   GR15,GNXCMP                                              13960000
         B     RECSPC                   BRANCH IF NEXT SPEC IS REC TYPE 13980000
         B     FLDSPC                   BRANCH IF NEXT SPEC IS FLD TYPE 14000000
         B     ENDP2                    OTHERWISE BRANCH TO COMPLETE    14020000
*                                        PHASE PROCESSING               14040000
         SPACE 1                                                        14060000
*********************************************************************** 14080000
*   GENIDT GENERATES THE FOLLOWING INSTRUCTIONS TO TEST RECORD ID     * 14100000
*  CODES FOR DETERMINING RECORD TYPE                                  * 14120000
*                                                                     * 14140000
*   IF THE ENTIRE CHARACTER IS TO BE COMPARED GENERATE THE FOLLOWING  * 14160000
*                                                                     * 14180000
*        CLI   FFF(GR2),X'CC'           FFF = CHAR POSITION IN RECORD * 14200000
BNE02    BNE   2(0)                     CC = IDENTIFYING CHARACTER      14220000
*                                                                     * 14240000
*   IF ONLY THE ZONE PORTION IS TO BE COMPARED                        * 14260000
*    GENERATE CALLING SEQUENCE FOR TEST ZONE (BCD) SUBR               * 14280000
*                                                                     * 14300000
TSTZID   L     GR7,LVDRTZ(GR3)          GR7 POINTS TO SUBR              14320000
         IC    GR9,0(0,GR2)             INSERT RECORD CODE INTO GR9     14340000
ZIDCC    LA    GR10,0                   LOAD GR10 WITH COMPARE CODE     14360000
         BALR  GR11,GR7                 BRANCH TO SUBR                  14380000
BE02     BE    2(0)                     (BE IS GENERATE FOR NEGATIVE    14400000
*                                        TEST AND BNE FOR POSITIVE)   * 14420000
*                                                                     * 14440000
*   IF ONLY THE DIGIT PORTION IS TO BE COMPARED                       * 14460000
*   GENERATE SAME CALLING SEQUENCE USED FOR ZONE ID EXCEPT CHANGE     * 14480000
*   THE BALR GR11,GR7 TO THE INSTRUCTION BELOW                        * 14500000
*                                                                     * 14520000
BALDIT   BAL   GR11,4(GR7)                                              14540000
*                                                                     * 14560000
*********************************************************************** 14580000
         EJECT                                                          14600000
*********************************************************************** 14620000
*   PASS 2 PROCESSING OF THE INPUT FIELD TYPE SPEC.                   * 14640000
*  COMPLETE OBJECT CODE FOR LAST 'OR' OF THE CURRENT RECORD GROUP AND * 14660000
*  GENERATE OBJECT CODE FOR PROCESSING MATCHING FIELDS                * 14680000
*********************************************************************** 14700000
         SPACE 1                                                        14720000
FLDSPC   BAL   GR15,GENORN              BRANCH TO COMPLETE CODE FOR     14740000
*                                        LAST 'OR'                      14760000
         MVI   FLDSW,X'F0'              SET SWITCH TO INDICATE PRESENCE 14780000
*                                        OF FLD SPECS FOR RECORD GROUP  14800000
NXTFLD   LA    GR13,15(GR13)            ADVANCE CMPPTR TO VARIABLE PART 14820000
         TM    1(GR3),X'80'             TEST FOR CONTROL LEVEL FIELD    14840000
         BZ    *+12                     BRANCH IF NOT                   14860000
         LA    GR13,1(GR13)             OTHERWISE ADVANCE CMPPTR AND    14880000
*                                        OF FIELD SPEC                  14900000
         OI    CLS,X'F0'                                                14920000
         TM    1(GR3),X'40'             TEST FOR MATCHING FIELD         14940000
         BZ    ISCHF                    BRANCH IF NOT                   14960000
         LA    GR13,1(GR13)             OTHERWISE ADVANCE CMPPTR AND    14980000
         OI    MFS,X'F0'                 SET INDICATOR TO INDICATE MF'S 15000000
         B     IFINDS-12                                                15020000
TM4IND   TM    1(GR3),0                                                 15040000
ISCHF    TM    1(GR3),X'01'             TEST FOR CHAINING FIELD         15060000
         BZ    *+8                      BRANCH IF NOT                   15080000
         LA    GR13,1(GR13)             ADVANCE CMPPTR                  15100000
         TM    1(GR3),X'20'             TEST FOR FLD-REC REL IND        15120000
         BZ    IFINDS                   BRANCH IF NONE                  15140000
         LA    GR13,2(GR13)             ADVANCE CMPPTR                  15160000
IFINDS   TM    1(GR3),X'1C'             TEST FOR FIELD INDICATORS       15180000
         BZ    ADVNXI+12                BRANCH IF NONE                  15200000
         TM    11(GR3),X'08'            TEST FOR BLANK AFTER            15220000
         BALR  GR15,0                   SAVE CONDITION CODE             15240000
         L     GR4,BLKPTR               GR4 = NEXT BYTE IN WKBUFF       15260000
         BZ    IF1                      BRANCH IF NO BLANK AFTER        15280000
         LH    GR5,BKACNT               GR5 = BLOCK CONTROL             15300000
         BCT   GR5,STOCNT               BRANCH IF NOT 6 ENTRIES ALREADY 15320000
         LA    GR1,WKBUFF                IN WKBUFF                      15340000
         LR    GR4,GR1                                                  15360000
         LA    GR2,BLKOUT               OTHERWISE WRITE CONTENT OF      15380000
         BAL   GR14,IOEXC                WKBUFF ONTO WORK FILE          15400000
         LA    GR5,6                    RESET BLOCK CONTROL             15420000
STOCNT   STH   GR5,BKACNT               SAVE CONTROL                    15440000
         MVC   0(6,GR4),9(GR3)          MOVE FLO NAME INFO INTO WKBUFF  15460000
         XC    6(6,GR4),6(GR4)          CLEAR AREA FOR INDICATORS       15480000
         LA    GR4,6(GR4)                                               15500000
IF1      LA    GR5,X'10'                                                15520000
         LA    GR1,3                                                    15540000
TEST4I   EX    GR5,TM4IND               TEST FOR PRESENCE OF IND        15560000
         BO    SETPM                    BRANCH IF PRESENT               15580000
         SPM   GR15                                                     15600000
         BZ    ADVNXI                   BRANCH IF NO BLANK AFTER        15620000
         LA    GR4,2(GR4)                                               15640000
         B     ADVNXI                                                   15660000
SETPM    SPM   GR15                                                     15680000
         BZ    ADVNXI-4                 BRANCH IF NO BLANK AFTER        15700000
         MVC   0(2,GR4),0(GR13)         OTHERWISE MOVE IND INTO WKBUFF  15720000
         LA    GR4,2(GR4)               ADVANCE TO AREA FOR NEXT IND    15740000
         LA    GR13,2(GR13)             ADVANCE CMPPTR 2 FOR EACH IND   15760000
ADVNXI   SRL   GR5,1                                                    15780000
         BCT   GR1,TEST4I               LOOP FOR 2ND AND 3RD INDS       15800000
         ST    GR4,BLKPTR                                               15820000
         TM    1(GR3),X'02'             TEST FOR STERLING               15840000
         BZ    *+8                      BRANCH IF NOT                   15860000
         LA    GR13,4(GR13)             ADVANCE CMPPTR                  15880000
         BAL   GR15,GNXCMP              BRANCH TO GET NEXT SPEC         15900000
         B     RECSPC                   BRANCH IF NEXT SPEC IS REC TYPE 15920000
         B     NXTFLD                   BRANCH IF NEXT SPEC IS FLD TYPE 15940000
         SPACE 1                                                        15960000
*   COMPLETE GENERATING OBJ CODE FOR LAST RECORD GROUP                  15980000
*  OF LAST INPUT FILE GROUP                                             16000000
         SPACE 1                                                        16020000
ENDP2    CLI   FLDSW,X'F0'              TEST FOR FIELD SPECS PRESENT    16040000
*                                        IN LAST RECORD GROUP           16060000
         BE    *+8                      BRANCH IF YES                   16080000
         BAL   GR15,GENORN              OTHERWISE COMPLETE OBJ CODE FOR 16100000
*                                        LAST 'OR' IN THE RECORD GROUP  16120000
         BAL   GR15,GENRDR              BRANCH TO GENERATE DRIVER FOR   16140000
*                                        LAST RECORD GROUP              16160000
         BAL   GR15,GEUNID              GENERATE CODE TO HANDLE UN-     16180000
*                                        IDENTIFIED RECORD              16200000
         BAL   GR15,ADD2AC                                              16220000
         BAL   GR14,FINTXT                                              16240000
         BAL   GR14,ALIGN                                               16260000
         SPACE 1                                                        16280000
*   GENERATE ARGTAB AND CHFTAB IN OBJ PROG IF CHAINED FILES             16300000
         SPACE 1                                                        16320000
         L     GR1,CHFPTR                                               16340000
         LA    GR2,CHFTAB               TEST FOR PRESENCE OF CHAINED    16360000
         SR    GR1,GR2                   FILES                          16380000
         BZ    GENGIR                   BRANCH IF NONE                  16400000
         L     GR2,ADDCNT(GR7)          OTHERWISE OUTPUT ARGTAB AND     16420000
         LA    GR2,2(GR2)                CHFTAB INTO OBJ PROG           16440000
         ST    GR2,ARGADR               PLACE ADDR OF TABLES INTO GIRC  16460000
         LA    GR11,28(0,GR1)           COMPUTE LENGTH OF TABLES        16480000
         STC   GR11,ARGTAB-1            PLACE DATA IDENT AND LENGTH     16500000
         MVI   ARGTAB-2,X'B0'            PRECEDING TABLES               16520000
         STC   GR11,TABL+1                                              16540000
         BAL   GR15,ADD2AC+4            ADD TABLE LENGTH TO OBJ ADDR    16560000
         BAL   GR14,DMPTXT              BRANCH TO PUT OUT TABLES        16580000
TABL     DC    AL2(0)                                                   16600000
         DC    AL4(ARGTAB-2)                                            16620000
         SPACE 1                                                        16640000
*   GENERATE GIRC OBJECT PROGRAM SUBROUTINE                             16660000
         SPACE 1                                                        16680000
GENGIR   LA    GR2,BUF3LG               INCREASE LENGTH OF TEXT         16700000
*                                        BUFFER FOR OUTPUT OF GIRC      16720000
         ST    GR2,SOOM                                                 16740000
         LA    GR2,ENDGNP                                               16760000
         ST    GR2,BUFTOP                                               16780000
         SR    GR2,GR2                                                  16800000
         CLI   MULTI,1                  TEST FOR MULTIPLE INPUT FILES   16820000
         BL    PUTMIN                   BRANCH IF ONE PRIMARY AND NO    16840000
         IC    GR2,PSFMFL                SECONDARY                      16860000
         BCTR  GR2,0                                                    16880000
         BH    PUTMAX                   BRANCH IF 2 OR MORE SECONDARY   16900000
         MVC   INITS(GNSRLG),GSREC1     OVERLAY INITS AND GNS WITH SUBR 16920000
         MVC   INITPX(IT1SLG),INIT1S    OVERLAY INITPX IN GIRC          16940000
         LA    GR11,GIRTWO              PREPARE TO PUT OUT GIRC TO PRO- 16960000
         B     INSERT                    CESS PRIMARY AND 1 SECONDARY   16980000
PUTMIN   LH    GR1,BA2GNP               MODIFY GIRCB WITHIN GIRC TO     17000000
         STH   GR1,GIRCB+2               BRANCH TO GNP                  17020000
         MVC   PRIFPB+4(GNPLG),GNP      PLACE GNP ROUTINE IMMEDIATELY   17040000
*                                       FOLLOWING FIXED PART OF GIRC    17060000
         MVC   IFMFS(4),IFMFS+4         MODIFY GNR IN GIRC              17080000
         MVI   IFMFS+1,X'F0'                                            17100000
         LA    GR11,MINGIR              PREPARE TO PUT OUT MINIMUM GIRC 17120000
         STH   GR11,GIRCLG              PLACE LENGTH OF GIRC            17140000
*                                        INTO DMPTXT CALL               17160000
         B     LG2DMP                                                   17180000
PUTMAX   LA    GR11,MAXGIR              PREPARE TO PUT OUT MAXIMUM GIRC 17200000
         L     GR5,PTR2ND               ADD TO LENGTH OF THE GIRC SUBR  17220000
         LA    GR4,IP2NDS                4 BYTES FOR EACH ENTRY IN      17240000
         SR    GR5,GR4                   IP2NDS TABLE                   17260000
         AR    GR11,GR5                                                 17280000
         LA    GR5,4(GR5)               PLACE LENGTH INTO DATA IDENT    17300000
         STC   GR5,NUM2ND-1              PRECEDING IP2NDS FOR DMPTXT    17320000
*                                        USE                            17340000
         IC    GR1,MULTI                PLACE NUMER OF SECONDARY        17360000
         LA    GR1,1(GR1)                INTO NUM2ND WITHIN GIRC        17380000
         STC   GR1,NUM2ND+1                                             17400000
         STC   GR2,NXTS+5                                               17420000
INSERT   STC   GR2,SELNXR+1             INSER LENGTH OF MATCHING FLDS   17440000
         STC   GR2,EQPS+1                INTO CLC AND MVC INSTRUCTIONS  17460000
         STC   GR2,PVSPP+5               IN GIRC                        17480000
         LR    GR4,GR11                                                 17500000
         BCTR  GR4,0                                                    17520000
         BCTR  GR4,0                                                    17540000
         A     GR4,B8                                                   17560000
         STH   GR4,EQPS+2               PLACE ADDR OF HOLD AREA INTO    17580000
         STH   GR4,PVSPP+6               INSTRUCTIONS                   17600000
         STH   GR11,GIRCLG              PLACE LENGTH OF GIRC SUBR INTO  17620000
*                                        DMPTXT CALLING SEQUENCE        17640000
         LA    GR11,1(GR2,GR11)         ADD LENGTH OF M FLDS TO GIRC TO 17660000
*                                        RESERVE A HOLD AREA IMMEDI-    17680000
*                                        ATELY FOLLOWING IP2NDS TABLE   17700000
LG2DMP   MVC   AGIRC(4),ADDCNT(GR7)     PLACE OBJ PROG  ADDR OF GIRC    17720000
*                                        SUBR INTO RLDREC               17740000
         BAL   GR15,ADD2AC+4            ADD LENGTH OF GIRC TO OBJ ADDR  17760000
         SPACE 1                                                        17780000
         BAL   GR14,DMPTXT              BRANCH TO PUT OUT GIRC SUBR     17800000
GIRCLG   DC    AL2(0)                                                   17820000
         DC    AL4(GIRC)                                                17840000
         BAL   GR14,FINTXT              BRANCH TO EMPTY TEXT BUFFER     17860000
         EJECT                                                          17880000
*********************************************************************** 17900000
*   END ASSEMBLE PHASE 2, CALL ASSEMBLE PHASE 3                       * 17920000
*********************************************************************** 17940000
         SPACE 2                                                        17960000
         LA    GR1,WKBUFF               TEST FOR BLANK AFTER ENTRIES IN 17980000
         CL    GR1,BLKPTR                WKBUFF (WORK BUFFER)           18000000
         BE    ENDPHS                   BRANCH IF NONE                  18020000
         LA    GR4,71(0,GR1)                                            18040000
         L     GR2,BLKPTR                                               18060000
         SR    GR4,GR2                                                  18080000
         BM    ENDPHS-8                                                 18100000
         EX    GR4,PADOUT               CLEAR BYTES NOT USED IN WKBUFF  18120000
         LA    GR2,BLKOUT                TO ZERO                        18140000
         BAL   GR14,IOEXC               BRANCH TO OUTPUT LAST BLOCK OF  18160000
*                                        BLANK AFTER ENTRIES            18180000
ENDPHS   LM    GR4,GR12,CIXSAV          RESTORE CIOEX GR4-GR7           18200000
         LA    GR1,RLDREC                                               18220000
         LA    GR2,RLDOUT                                               18240000
         BALR  GR5,GR12                                                 18260000
         LA    GR2,PHSCAL               GR2 = ROUTINE NO.               18280000
         BALR  GR5,GR12                 BRANCH TO CIOEX, CALL NEXT PHS  18300000
PADOUT   XC    0(0,GR2),0(GR2)                                          18320000
         EJECT                                                          18340000
*********************************************************************** 18360000
*   DATA STORAGE AND CONSTANTS USED DURING PASS 2 PROCESSING            18380000
*********************************************************************** 18400000
         DS    0D                                                       18420000
PACWS    DS    D                                                        18440000
B2       DC    X'00002000'                                              18460000
B8       DC    X'00008000'                                              18480000
B9ADDR   DC    A(BASEP2+4096)                                           18500000
PTR2ND   DC    A(IP2NDS)                                                18520000
CHFPTR   DC    A(CHFTAB)                POINTER FOR GENERATING CHFTAB   18540000
*                                        (CHAINED FILE ADDRESS TABLE    18560000
CHFMFP   DC    A(CHFMFL-1)              CHFMFL TABLE POINTER            18580000
MVFPTR   DC    A(ADTMVF)                ADTMVF POINTER                  18600000
CLSPTR   DC    A(CLSTAB)                                                18620000
MFSPTR   DC    A(MFSTAB)                                                18640000
NSTPTR   DC    A(NSTAB)                                                 18660000
BLKPTR   DC    A(WKBUFF)                                                18680000
NSCPTR   DC    A(NSCTAB)                                                18700000
ARGSAV   DS    16F                      SAVE AREA FOR ALL GENERAL REG   18720000
CIXSAV   DS    3F                       SAVE AREA FOR GENERAL REGISTERS 18740000
CXRADDR  DC    A(IES13910)             CIOEX ADDRESS                    18760000
*                                        USED BY CIOEX                  18780000
FILEN    DS    F                                                        18800000
BKACNT   DC    H'06'                                                    18820000
FLDSW    DC    X'00'                                                    18840000
         DC    X'03'                    FOR ZERO STACKER SELECT         18860000
SSCODE   DC    X'0102030303'                                            18880000
         DC    4X'03'                                                   18900000
IDCSW    DC    X'00'                                                    18920000
ARGM     DC    X'00'                                                    18940000
UBA04    DC    X'00'                                                    18960000
NXPHSN   DC    C'RPG10140'                                              18980000
BAL4     BAL   GR4,SET528-MFSUBA(GR14)                                  19000000
SETHLT   LA    GR10,H0(GR3)                                             19020000
CLS      DC    X'00'                    CONTROL LEVELS INDICATOR (INDI- 19040000
*                                        CAT5S IF CONTROL LEVELS ARE    19060000
*                                        PRESE5T)                       19080000
         SPACE 1                                                        19100000
MFS      DC    X'00'                    MATCHING FLDS INDICATOR (INDI-  19120000
*                                        CATES IF M FLDS ARE PRESENT)   19140000
WKBUFF   DS    CL72                     WORK BUFFER                     19160000
         SPACE 1                                                        19180000
RLDREC   EQU   *                        RLD RECORD FOR OUTPUT ON RLD    19200000
         DC    X'E5'                     WORK FILE AT END OF PASS 2     19220000
         DC    AL2(LVCLSR)                                              19240000
ACLSR    DC    AL4(0)                   ABSOLUTE ADDR OF CLSUBR         19260000
         DC    AL2(LVDSPC)                                              19280000
ADSPC    DC    AL4(0)                   ABSOLUTE ADDR OF DSPC SUBR      19300000
         SPACE 1                                                        19320000
         DC    AL2(LVDRTY)                                              19340000
ADRTY    DC    AL4(0)                                                   19360000
         DC    AL2(LVGIRC)                                              19380000
AGIRC    DC    AL4(0)                                                   19400000
         DC    X'FD'                                                    19420000
         EJECT                                                          19440000
*********************************************************************** 19460000
*   THE DATA DEFINED BELOW IS COMMON TO PASS 1 AND PASS 2, IT IS GENE-* 19480000
*  RATED BY PASS 1 AND WRITTEN ONTO A WORK FILE . SUBSEQUENTLY THE    * 19500000
*  DATA IS READ IN TO OVERLAY A SIMIARLY DEFINED AREA IN PASS 2.      * 19520000
*********************************************************************** 19540000
         SPACE 1                                                        19560000
         DS    0F                                                       19580000
ADTMVF   DS    300C                     OBJECT PROGRAM ADDRESSES (ABSO- 19600000
*                                        LUTE) OF THE MVFLDS SUB-       19620000
*                                        ROUTINES GENERATED BY PASS 1   19640000
*                                        (3 BYTE ENTRIES)               19660000
         SPACE 1                                                        19680000
HA       DC    F'0'                     OBJECT PROGRAN ADDR (ABSOLUTE)  19700000
*                                        OF HOLD AREA FOR CONTR LEVELS  19720000
         SPACE 1                                                        19740000
OADSPC   DS    F                        OBJ PROG ADDR OF DSPC SUBR      19760000
         SPACE 1                                                        19780000
RRIOFF   DS    F                       OBJ PROG ADDR OF SUBR TO TURN    19800000
*                                       OFF ALL INPUT RECORD RESULTING  19820000
*                                        INDICATORS                     19840000
         SPACE 1                                                        19860000
CLMFWS   DC    F'0'                     OBJECT PROGRAM ADDR (ABSOLUTE)  19880000
*                                        OF THE WORKING STORAGE FOR     19900000
*                                        MATCHING FLDS AND CONTR LEVELS 19920000
         SPACE 1                                                        19940000
CLWSDP   DC    9H'00'                   TABLE OF DISPLACEMENTS TO THE   19960000
*                                        STARTING BYTE WITHING WORKING  19980000
*                                        STORAGE FOR EACH CONTROL LEVEL 20000000
         SPACE 1                                                        20020000
CLMAX    DC    9X'00'                   LENGTH OF CONTROL LEVELS L1-L9  20040000
         SPACE 1                                                        20060000
CLSIND   DC    X'00'                    INDICATOR TO PUT OUT CLSUBR     20080000
*                                        IN PASS 2                      20100000
         SPACE 1                                                        20120000
FET      DC    25X'0'                                                   20140000
         SPACE 1                                                        20160000
*   THE FILE ENVIRONMENT TABLE (FET) IS GENERATED FROM A SCAN OF THE    20180000
*  FILE DESCRIPTION SPEC. IT CONSISTS OF ONE BYTE ENTRIES CONTAINING    20200000
*  THE FOLLOWING INFORMATION FOR EACH INPUT FILE                        20220000
         SPACE 1                                                        20240000
*        BITS       VALUE                                               20260000
         SPACE 1                                                        20280000
*        0-1        00 = PRIMARY FILE                                   20300000
*                   01 = SECONDARY FILE                                 20320000
*                   11 = CHAINED FILE                                   20340000
*        2          NOT USED                                            20360000
*        3     1 = MATCHING FIELDS                                      20380000
*              0 = NO MATCHING FIELDS                                   20400000
*        4          1 =  E SPECIFIED IN COL 17 OF FILE DESCRIPT SPEC    20420000
*                   0 =  BLANK IN COL 17                                20440000
*        5          1 =  ASCENDING SEQUENCE                             20460000
*                   0 =  DESCENDING SEQUENCE OR BLANK                   20480000
*        6          NOT USED                                            20500000
*        7          1 =  CARD INPUT DEVICE                              20520000
*                   0 =  OTHER DEVICE                                   20540000
         SPACE 2                                                        20560000
PSFMFL   DC         X'00'               LENGTH OF M1-M3 FOR PRIMARY     20580000
*                                        AND SECONDARY FILES            20600000
         SPACE 1                                                        20620000
CHFMFL   DS    CL25                     TABLE OF M1-M3 LENGTHS FOR EACH 20640000
*                                        CHAINED FILE WITH MATCH FLDS   20660000
NSTAB    DS    CL25                     TABLE CONTAINS HIGHEST NUMERIC  20680000
*                                        RECORD SEQUENCE NUMBER FOR     20700000
*                                        EACH FILE                      20720000
         SPACE 1                                                        20740000
NSCTAB   DS    100C                     OBJ PROG ADDR OF NSCB'S         20760000
         SPACE 1                                                        20780000
MULTI    DC    X'00'                    NUMBER OF SECONDARY FILES       20800000
         SPACE 1                                                        20820000
CLSTAB   DS    300C                     OBJECT PROGRAM ADDRESSES (ABSO- 20840000
*                                        LUTE OF THE MCL2WS SUBROUTINES 20860000
*                                        GENERATED BY PASS 1            20880000
*                                        (3 BYTE ENTRIES)               20900000
         SPACE 1                                                        20920000
MFSTAB   DS    300C                     OBJECT PROGRAM ADDRESSES (ABSO- 20940000
*                                        LUTE OF THE MFSUBS SUBROUTINES 20960000
*                                        GENERATED BY PASS 1            20980000
         SPACE 1                                                        21000000
DATEND   EQU   *                                                        21020000
DATALG   EQU   DATEND-ADTMVF                                            21040000
         ORG   *+64                                                     21060000
         EJECT                                                          21080000
*********************************************************************** 21100000
ADD2AC   S     GR11,OBJPBR              REMOVE B FROM BDDD IN GR11      21120000
         A     GR11,ADDCNT(GR7)         ADD DDD IN GR11 TO ADRCNT       21140000
         ST    GR11,ADDCNT(GR7)                                         21160000
         L     GR11,OBJPBR              RESET GR11 TO BDDD              21180000
         BR    GR15                                                     21200000
         DS    0F                                                       21220000
OBJPBR   DC    X'00004000'                                              21240000
*********************************************************************** 21260000
*   GNXCMP EXAMINES THE NEXT AVAILABLE BYTE IN THE COMPRESSION BLOCK  * 21280000
*  TO DETERMINE THE TYPE OF SPEC (INPUT RECORD OR FIELD TYPE). IF THE * 21300000
*  END OF THE COMPRESSION BLOCK IS DETECTED, CIOEX GETCMP IS CALLED   * 21320000
*  TO READ THE NEXT BLOCK                                             * 21340000
*********************************************************************** 21360000
         SPACE 2                                                        21380000
GNXCMP   LR    GR3,GR13                 ADVANCE GR3 TO NXT SPEC         21400000
         CLI   0(GR3),C'I'              TEST FOR RECORD TYPE            21420000
         BE    0(GR15)                   BRANCH IF RECORD TYPE          21440000
         CLI   0(GR3),C'D'              TEST FOR FIELD TYPE             21460000
         BE    4(GR15)                   BRANCH IF FIELD TYPE           21480000
         CLI   0(GR3),X'FF'             TEST FOR END OF COMPRESSION BLK 21500000
         BNE   8(GR15)                   BRANCH IF NOT END              21520000
         LA    GR2,GETCMP               OTHERWISE GET NEXT BLOCK        21540000
         BAL   GR14,IOEXC               BRANCH TO CALL CIOEX TO READ    21560000
*                                        NEXT BLOCK OF COMPRESSION      21580000
         LR    GR13,GR3                 RESET CMPPTR TO 1ST SPEC IN BLK 21600000
         B     GNXCMP+2                                                 21620000
         EJECT                                                          21640000
*********************************************************************** 21660000
*   GETINP CALLS CIOEX TO MAKE AVAILABLE WITHIN THE COMPRESSION BLOCK * 21680000
*  THE FIRST INPUT SPEC (UPON EXIT GR3 CONTAINS FIRST BYTE ADDRESS OF * 21700000
*  INPUT SPEC)                                                        * 21720000
*********************************************************************** 21740000
         SPACE 2                                                        21760000
GETINP   LA    GR2,PNTINP               GR2 = ROUTINE NUMBER            21780000
         BAL   GR14,IOEXC               BRANCH TO CALL CIOEX            21800000
         LA    GR2,GETCMP                                               21820000
         BAL   GR14,IOEXC                                               21840000
         AH    GR3,IDSPLC(GR7)          ADD DISPLACE TO 1ST INPUT SPEC  21860000
         LR    GR13,GR3                 INITIALIZE CMPPTR               21880000
         BR    GR15                     EXIT GETINP                     21900000
         SPACE 2                                                        21920000
*********************************************************************** 21940000
*   IOEXC CALLS CIOEX TO PERFORM INPUT/OUTPUT (GR2 CONTAINS NUMBER OF * 21960000
*  CIOEX ROUTINE)                                                     * 21980000
*********************************************************************** 22000000
         SPACE 1                                                        22020000
IOEXC    STM   GR4,GR2,ARGSAV                                           22040000
         LM    GR4,GR12,CIXSAV          RESTORE CIOEX GR4-GR12 (12 = 7) 22060000
         BALR  GR5,GR12                 BRANCH TO CIOEX                 22080000
         LM    GR4,GR2,ARGSAV                                           22100000
         BR    GR14                     EXIT IOEXC                      22120000
         SPACE 2                                                        22140000
*********************************************************************** 22160000
*   ALIGN FORCES THE OBJECT PROGRAM ADDRESS COUNTER TO FULL WORD      * 22180000
*  ALIGNMENT                                                          * 22200000
*********************************************************************** 22220000
         SPACE 1                                                        22240000
ALIGN    L     GR1,ADDCNT(GR7)                                          22260000
         LA    GR1,3(GR1)                                               22280000
         SRL   GR1,2                                                    22300000
         SLL   GR1,2                                                    22320000
         ST    GR1,ADDCNT(GR7)     RESOTRE TO CIOEX DATA AREA           22340000
         ST    GR1,LODLOC          PLACE IN DMPTXT                      22360000
         BR    GR14                                                     22380000
         SPACE 1                                                        22400000
*********************************************************************** 22420000
*   TXTOUT CHECK FOR TEXT BUFFER OVERFLOW AND CALLS DMPTXT TO OUTPUT  * 22440000
*  GENERATED OBJECT CODE                                              * 22460000
*                                                                     * 22480000
*   IF THE CURRENT REQUEST WOULD CAUSE BUFFER OVERFLOW AN EXTRA BRANCH* 22500000
*  (SHOWN BELOW) IS GENERATED FOR THE UBA(S) CAUSING DMPTXT TO NOT    * 22520000
*  OUTPUT. THIS BRANCH THEN BECOMES A UBA AND THE PREDEDING UBA(S)    * 22540000
*  ARE DEFINED TO BRANCH TO IT                                        * 22560000
         SPACE 1                                                        22580000
BB       B     *+8                      BRANCH AROUND UBA               22600000
         B     0(0)                     NEW UBA                         22620000
*********************************************************************** 22640000
         SPACE 1                                                        22660000
TXTOUT   LR    GR5,GR14                 SAVE RETURN IN GR5              22680000
         LA    GR1,ASMBLK               COMPUTE NUMBER OF TEXT BYTES    22700000
         SR    GR12,GR1                  (GR12)-(START ADDR OF ASMBLK)  22720000
IFSOOM   LR    GR2,GR12                                                 22740000
         AH    GR2,SAFETY               ADD C AND COMPARE  NO. OF BYTES 22760000
         C     GR2,SOOM                  REMAINING IN BUFFER (SOOM)     22780000
         BNH   TX2OUT                   BRANCH IF NO OVERFLOW           22800000
         SR    GR2,GR2                  OTHERWISE FOR OVERFLOW GENERATE 22820000
         IC    GR2,PTRUBA                EXTRA BRANCH                   22840000
         STC   GR2,ABCNO+1                                              22860000
         STC   GR2,BB+7                                                 22880000
         STH   GR11,ABCNO+2                                             22900000
         BAL   GR14,ADRDEF              DEFINE UBA(S) PREVENTING OUT-   22920000
ABCNO    DC    AL2(0)                    PUT                            22940000
         DC    AL2(0)                                                   22960000
         LA    GR11,4(GR11)                                             22980000
         STH   GR11,BB+2                                                23000000
         LA    GR11,4(GR11)                                             23020000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT EXTRA BRANCH   23040000
         DC    AL2(8)                                                   23060000
         DC    AL4(BB)                                                  23080000
         B     IFSOOM                   TEST AGAIN FOR OVERFLOW         23100000
TX2OUT   STH   GR12,*+8                                                 23120000
         BAL   GR14,DMPTXT              BRANCH TO OUTPUT GENERATED TEXT 23140000
         DC    AL2(0)                                                   23160000
         DC    AL4(ASMBLK)                                              23180000
         AR    GR11,GR12                ADVANCE OBJ PROG ADDR           23200000
         LR    GR12,GR1                 GR12 = STARTING LOC OF ASMBLK   23220000
         BR    GR5                      EXIT TXTOUT                     23240000
SAFETY   DC    H'12'                                                    23260000
         EJECT                                                          23280000
*********************************************************************** 23300000
*   DMPTXT ACCEPTS OBJECT CODE AND FORMS A BINARY TEXT CARD FOR       * 23320000
*  OUTPUT ON EITHER SYSPCH OR SYS000 (GO FILE)                        * 23340000
DMPTXT   MVC   LENGTH(6),0(GR14) MOVE THE CALLING SEQUENCE.             23360000
         LA    GR14,6(GR14)   BUMP REGISTER OVER CALLING SEQ.           23380000
         STM   0,15,ARGSAV    SAVE ALL REGISTERS PRIOR TO ENTRY .       23400000
         L     DMPRG1,PTR1    POINTS TO THE FIRST AVAILABLE BYTE IN     23420000
         LH    DMPRG2,LENGTH  THE TEXT BUFFER.HAS THE LENGTH OF THE     23440000
         L     DMPRG3,DMPADD  SEGMENT TO BE ADDED,AND ITS ADDRESS.      23460000
DMP1     BAL   DMPRG0,DMPSUB   GO AND MOVE THE SEGMENT TO THE BUFFER.   23480000
         LA    DMPRG1,1(DMPRG1,DMPRG2) SET THE POINTER TO THE           23500000
         ST    DMPRG1,PTR1    FIRST AVAILABLE BYTE IN THE BUFFER.       23520000
         MVI   DMPFLG,X'FF'   SET HE FLAG TO SEARCH OUT THE UBA'S.      23540000
         B     ADR1                                                     23560000
DMPSUB   LA    DMPRG4,256      MOVE ALL THE MULTIPLES OF 256 BYTES      23580000
DMPSUB1  SR    DMPRG2,DMPRG4  FIRST,THEN THE REMAINDER                  23600000
         BC    12,DMPSUB2                                               23620000
         MVC   0(256,DMPRG1),0(DMPRG3)                                  23640000
         AR    DMPRG3,DMPRG4                                            23660000
         BXH   DMPRG1,DMPRG4,DMPSUB1                                    23680000
DMPSUB2  LA    DMPRG2,255(DMPRG2)                                       23700000
         EX    DMPRG2,DMPSUB3 NOW MOVE THE REMAINDER .                  23720000
         BR    DMPRG0                                                   23740000
DMPSUB3  MVC   0(0,DMPRG1),0(DMPRG3)                                    23760000
ADRDEF   MVC   DMPADD(4),0(GR14) MOVE THE CALLING SEQUENCE AF THIS CALL 23780000
         LA    GR14,4(GR14)   AND SET RETURN REGISTER.                  23800000
         STM   0,15,ARGSAV                                              23820000
         LH    DMPRG3,BDDDDFN HAS ADDRESS DEFIN. FOR THIS UBA.          23840000
         MVI   DMPFLG,X'0'    SET SWITCH THAT WE ARE DEFINING UBA'S.    23860000
ADR1     L     DMPRG1,PTRUBA  POINTS TO THE FIRST UBA FOUND IN LAST     23880000
         SR    DMPRG2,DMPRG2  CALL.                                     23900000
         XC    PTRUBA(12),PTRUBA CLEAR UBA POINTERS,AND SAVE AS FIRST   23920000
         MVC   PTRUBA(4),PTR1 UBA POINTER THE NEXT AVAIL.BYTE IN CASE  123940000
                              NO UBA'S ARE FOUND.                       23960000
         LA    DMPRG1,0(DMPRG1) BLANK OUT A POSSIBLE UBA FLAG.          23980000
ADR2     C     DMPRG1,PTR1    HAVE WE SEARCHED THROUGH THE BUFFER.      24000000
         BNL   ADRA           YES ,PUNCH AS MUCH AS POSSIBLE            24020000
         CLI   0(DMPRG1),X'47' IS THIS OPERATION A' 'BRANCH'            24040000
         BE    ADR4           YES,GO SEE WHETHER IT IS A U.B.A.         24060000
         TM    0(DMPRG1),X'B0' IF NOT,IS THIS A SEGMENT OF DATA         24080000
         BC    12,ADR8        NO.                                       24100000
         IC    DMPRG2,1(DMPRG1) PICK UP THE COUNT.                      24120000
         LTR   DMPRG2,DMPRG2    IS IT ZERO,                             24140000
         BC    7,ADR3         SKIP IF NOT,ELSE UPDATE POINTER OVER 256  24160000
         LA    DMPRG1,256(DMPRG1) BYTES OF DATA.                        24180000
ADR3     AR    DMPRG1,DMPRG2  AND ADD LENGTH OF THE DATA SEGMENT.       24200000
         B     ADR2                                                     24220000
ADR4     TM    2(DMPRG1),X'F0' IS THIS BRANCH A U.B.A.                  24240000
         BC    5,ADR8         SKIP IF NOT.                              24260000
         CLI   DMPFLG,X'FF'   ARE WE DEFINING A UBA.                    24280000
         BE    ADR5           NO.                                       24300000
         CLC   IDNO(1),3(DMPRG1) IF SO DO WE DEFINE THIS UBA.           24320000
         BNE   ADR5           SKIP IF NOT.                              24340000
         STH   DMPRG3,2(DMPRG1) ELSE DEFINE THE UBA AND                 24360000
         B     ADR8           GO TO UPDATE POINTER.                     24380000
ADR5     LA    DMPRG4,PTRUBA                                            24400000
         LA    DMPRG2,3                                                 24420000
ADR6     CLC   0(1,DMPRG4),3(DMPRG1) HAS THIS UBA BEEN POSTED.          24440000
         BE    ADR8           YES,ELSE                                  24460000
         CLI   0(DMPRG4),X'0' IS THIS STILL BLANK,                      24480000
         BNE   ADR7                                                     24500000
         ST    DMPRG1,0(DMPRG4) ELSE SAVE THE POINTER                   24520000
         MVC   0(1,DMPRG4),3(DMPRG1) AND THE FLAG.                      24540000
         B     ADR8                                                     24560000
ADR7     LA    DMPRG4,4(DMPRG4) POINT TO NEXT UBA POINTER               24580000
         BCT   DMPRG2,ADR6    POST ONLY 3 DIFFERENT UBA TYPES.          24600000
ADR8     TM    0(DMPRG1),X'C0' TEST FOR INSTRUCTION LENGTH.             24620000
         LA    DMPRG1,2(DMPRG1) ADD 2 FOR  INSTRUCTION OF LENGTH 2      24640000
         BZ    ADR2           CONTINUE                                  24660000
         LA    DMPRG1,2(DMPRG1) ADD 2 MORE FOR LENGTH 4.                24680000
         BM    ADR2           CONTINUE                                  24700000
         LA    DMPRG1,2(DMPRG1) ADD 2 MORE FOR LENGTH 6                 24720000
         B     ADR2           CONTINUE                                  24740000
ADRA     CLC   BUFFRP56+1(3),PTRUBA+1 DO WE HAVE 56 BYTES IN THE        24760000
         BNH   PUSHUP         BUFFER WITHOUT A UBA,IF NOT RETURN.       24780000
DMPTXTRN MVI   CDLEN+1,56     RESTORE CARD LENGTH OF TEXT OUTPUT.       24800000
         S     DMPRG1,BUFTOP  COMPUTE THE NUMBER OF BYTES REMAINING     24820000
         LCR   DMPRG1,DMPRG1  IN THE TEXT BUFFER.                       24840000
         ST    DMPRG1,SOOM                                              24860000
         LM    0,15,ARGSAV    RESTORE ALL REGISTERS TO RETURN.          24880000
         BR    GR14      AND RETURN TO CALLER.                          24900000
PUSHUP   EQU   *                                                        24920000
         LM    4,7,CIXSAV     RESTORE CIOEX REGISTERS.                  24940000
         MVC   0(72,4),PFX     MOVE THE CARD PREFIX TO CIOEX PUNCH      24960000
         MVI   4(4),C' '      BUFFER AND BLANK THE FIRST BYTE OF THE    24980000
         LA    2,12           LOAD ADDRESS TO CONFORM TO TEXT NORM.     25000000
         BALR  5,7            LINK TO PUNCH ROUTINE IN CIOEX.           25020000
         LA    DMPRG1,DMPTXTBF NOW MOVE THE DUMP TEXT BUFFER UP         25040000
         LCR   DMPRG2,DMPRG1  56 BYTES OVERLAYING THE TEXT JUST PUT     25060000
         A     DMPRG2,PTR1    OUT VIA THE CIOEX CALL.                   25080000
         LA    DMPRG3,56(DMPRG1)                                        25100000
         BAL   DMPRG0,DMPSUB                                            25120000
         LA    DMPRG3,PTRUBA  UPDATE ALL UBA POINTERS AS WELL AS        25140000
         LA    DMPRG2,4       THE POINTER TO THE NEXT AVAILABLE BYTE    25160000
PSH1     L     DMPRG1,0(DMPRG3) IN THE DMPTXT BUFFER TO REFLECT THE     25180000
         SH    DMPRG1,CDLEN   LENGTH OF THE CARD PUNCHED OUT.           25200000
         ST    DMPRG1,0(DMPRG3)                                         25220000
         LA    DMPRG3,4(DMPRG3)                                         25240000
         BCT   DMPRG2,PSH1    SIMILARLY ADJUST THE LOAD LOCATION        25260000
         L     DMPRG2,LODLOC  COUNTER TO REFLECT THE TEXT CARD PUT      25280000
         AH    DMPRG2,CDLEN   OUT.                                      25300000
         ST    DMPRG2,LODLOC  THEN GO TO SEE WHETHER WE CANNOT          25320000
         B     ADRA           PUT OUT ANOTHER CARD.                     25340000
FINTXT   STM   0,15,ARGSAV    SAVE ALL REGISTERS PRIOR TO ENTRY .       25360000
         L     DMPRG3,PTR1    FILL WITH BLANKS THE REMAINDER            25380000
         LA    DMPRG2,DMPTXTBF+54 OF THIS INCOMPLETE TEXT CARD          25400000
         SR    DMPRG2,DMPRG3  TO PREPARE IT FOR PUNCHING.               25420000
         LA    DMPRG1,1(DMPRG3)                                         25440000
         MVI   0(DMPRG3),C' '                                           25460000
         EX    DMPRG2,DMPSUB3                                           25480000
         LA    DMPRG1,DMPTXTBF NOW COMPUTE THE LENGTH OF THIS TEXT CARD 25500000
         SR    DMPRG3,DMPRG1  FOR OUTPUT.                               25520000
         BC    12,DMPTXTRN    RETURN DIRECTLY IF THE LENGTH.LE.ZERO.    25540000
         STC   DMPRG3,CDLEN+1                                           25560000
         B     PUSHUP                                                   25580000
PTRUBA   DC    A(DMPTXTBF,0,0,DMPTXTBF) HOLDS THE POINTERS TO THE FIRST125600000
                              UNIQUE OCCURRENCE OF UBA'S IN THE BUFFER. 25620000
PTR1     EQU   PTRUBA+12      POINTER TO THE NEXT AVAILABLE BYTE IN THE125640000
                              DMPTXT BUFFER.                            25660000
BUFFRP56 DC    A(DMPTXTBF+56)                                           25680000
DMPAREA  DC    2F'0'          SCRATCH AREA FOR DMPTXT.                  25700000
DMPFLG   EQU   DMPAREA+1      CONTAINS ADDRESS DEFINITION SWITCH.       25720000
LENGTH   EQU   DMPAREA+2      LENGTH OF SEGMENT TO ADD.                 25740000
DMPADD   EQU   DMPAREA+4      ADDRESS OF FIRST BYTE TO BE ADDED.        25760000
IDNO     EQU   DMPAREA+5      ID NUMBER OF U.B.A TO BE DEFINED.         25780000
BDDDDFN  EQU   DMPAREA+6      'BDDD' DEFINITION FOR THIS U.B.A..        25800000
DMPRG0   EQU   11                                                       25820000
DMPRG1   EQU   12             GENERAL REGISTERS FOR DUMPTEXT ROUTNE     25840000
DMPRG2   EQU   13                                                       25860000
DMPRG3   EQU   14                                                       25880000
DMPRG4   EQU   15                                                       25900000
BUFTOP   DC    A(EOBUF2)                TOP OF BUFFER (HIGH VALUE ADDRS 25920000
SOOM     DC    A(BUF2LG)                REMAINING BYTES IN TEXT BUFFER  25940000
         DC    0F'0'          FORCE TO FULLWORD ALIGNMENT.              25960000
PFX      DC    X'02'          T                                         25980000
         DC    C'TXT'          E  C                                     26000000
LODLOC   DC    F'0'             X  A  P                                 26020000
         DC    C'  '             T  R  R                                26040000
CDLEN    DC    H'56'                 D  E                               26060000
         DC    C'  '                     F                              26080000
         DC    X'00'                      I                             26100000
         DC    X'01'                       X                            26120000
DMPTXTBF DC    0X'0'          BEGINNING OF DUMPTEXT BUFFER.             26140000
         SPACE 2                                                        26160000
*   DMPTXT BUFFER OVERLAYS THE FOLLOWING CANNED OBJECT SUBR WHICH IS    26180000
*  FIRST TEXT OUTPUT BY ASSEMBLE 2.5                                    26200000
         EJECT                                                          26220000
*********************************************************************** 26240000
*   CANNED OBJECT CODE OUTPUT BY PASS 2                               * 26260000
*********************************************************************** 26280000
         SPACE 3                                                        26300000
*********************************************************************** 26320000
*   DRTY IS THE OBJECT PROGRAM SUBR CALLED BY THE CHAINING SUBR TO    * 26340000
*  DETERMINE RECORD TYPE AND SET ON THE RESULTING INDICATOR           * 26360000
*                                                                     * 26380000
*   GR1 CONTAINS NUMBER OF THE REQUESTING FILE WHEN DRTY IS ENTERED   * 26400000
*                                                                     * 26420000
*   DRTY CALLS THE FDRIVR (FILE DRIVER) CORRESPONDING TO THE          * 26440000
*  REQUESTING FILE NUMBER                                             * 26460000
*********************************************************************** 26480000
         SPACE 1                                                        26500000
         CNOP  0,4                                                      26520000
DRTY     L     GR13,LVWORK(GR3)         GR13 = RPG OBJ COMMON WORK STOR 26540000
         ST    GR14,CHNGRR(GR13)        SAVE (GR14)                     26560000
         ST    GR8,CHNGBR(GR13)         SAVE (GR8)                      26580000
         USING DRTY,GR15                                                26600000
         L     GR10,LVGIRC(GR3)                                         26620000
         L     GR2,LARGT(GR10)          GR2 = ARGUMENT TAB              26640000
         AR    GR2,GR3                                                  26660000
         LA    GR11,26(0,GR2)           GR11 = TABLE OF ADDRESSES FOR   26680000
*                                        CHAINED FILE DRIVERS           26700000
         STC   GR1,FUNCT+3              GR1 CONTAINS FILE NUMBER        26720000
         TR    FUNCT+3(1),0(GR2)        TRANSLATE FILE NO. INTO DISPL   26740000
FUNCT    LA    GR10,0                    FOR OBTAINING ADDR OF THE      26760000
*                                        FILE DRIVER (FDRIVR)           26780000
         L     GR1,0(GR10,GR11)          GR1 = ADDR OF FDRIVR           26800000
         AR    GR1,GR3                                                  26820000
         L     GR9,LVIORB(GR3)                                          26840000
         AH    GR9,IORBDP(GR1)          GR9 = ADDR OF IORB              26860000
         LA    GR15,DRTY2                                               26880000
         BALR  GR14,GR15                BRANCH TO DETERMINE RECORDTYPE  26900000
         USING *,GR14                                                   26920000
         L     GR15,FPBCL(GR1)          GR15 = ADDR OF MCL2WS (IF CON-  26940000
         LTR   GR15,GR15                 TROL FIELDS PRESENT IN RECORD) 26960000
         BZ    DRTXIT                   BRANCH IF NO CONTROL FIELDS     26980000
         AR    GR15,GR3                                                 27000000
         L     GR7,LVCLSR(GR3)          GR7 POINTS TO CLSUBR            27020000
         L     GR10,XCLHA(GR7)          GR10 POINTS TO CONTROL LEVELS   27040000
         AR    GR10,GR3                  HOLD AREA                      27060000
         BALR  GR14,GR15                OTHERWISE BRANCH TO MCL2WS SUBR 27080000
DRTXIT   L     GR10,LVDSPC(GR3)                                         27100000
         ST    GR1,STAFPB(GR10)                                         27120000
         L     GR14,CHNGRR(GR13)                                        27140000
         L     GR8,CHNGBR(GR13)                                         27160000
         BR    GR14                     EXIT DRTY SUBR                  27180000
         EJECT                                                          27200000
*********************************************************************** 27220000
*   DRTY2 IS OBJECT PROGRAM SUBR CALLED FROM DRTY AND GNR TO DETERMINE* 27240000
*  THE RECORD TYPE AND TO PROCESS MATCHING FIELDS                     * 27260000
*                                                                     * 27280000
*   ENTRY CONDITIONS AS FOLLOWS                                       * 27300000
*                                                                     * 27320000
*        GR9 = ADDR OF IORB                                           * 27340000
*        GR1 = ADDR OF FPB                                            * 27360000
*        GR13= ADDR OF RPG OBJ PROG COMMON AREA                       * 27380000
* * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * * **  27400000
         SPACE 1                                                        27420000
DRTY2    EQU   *                                                        27440000
         USING *,GR15                                                   27460000
         ST    GR14,DRTY2X(GR13)                                        27480000
         L     GR2,IPREC(GR9)           GR2 = ADDR OF INPUT RECORD      27500000
         XC    MFSUBA(6),MFSUBA                                         27520000
         XC    FDRCL(4,GR1),FDRCL(GR1)  INITALIZE FPB                   27540000
         STM   GR4,GR12,SAV427(GR13)                                    27560000
         CNOP  2,4                                                      27580000
         BALR  GR14,GR1                 BRANCH TO FDRIVR (FILE DRIVER)  27600000
MFSUBA   DC    X'B006'                  ADDR OF MFSUBR IS RETURNED      27620000
         DS    CL2                       HERE BY RDRIVR                 27640000
SCODE    DS    CL2                                                      27660000
         USING MFSUBA,GR8                                               27680000
         LM    GR4,GR12,SAV427(GR13)                                    27700000
         LR    GR8,GR14                                                 27720000
         LR    GR9,GR0                  RESTORE GR9 (POINT TO IORB)     27740000
         CLI   SCODE,0                  TEST FOR STACKER CODE RETURNED  27760000
         BE    GOON                      BY REC ROUTINE - BRANCH IF NOT 27780000
         MVC   SELECT(1,GR9),SCODE      OTHERWISE PLACE CODE INTO IORB  27800000
         MVI   ACTBYT(GR9),X'04'        SET IORB ACTION BYTE            27820000
         L     GR15,LVIOI(GR3)                                          27840000
         BALR  GR14,GR15                BRANCH TO PERFORM STACKER SEL   27860000
GOON     L     GR9,LOCWS                GR9 = ADDR OF WORKING STORAGE   27880000
         AR    GR9,GR3                   FOR CONTROL LEVELS AND M FLDS  27900000
         B     LOCWS+4                                                  27920000
         SPACE 1                                                        27940000
SET528   LA    GR8,4095                 SET BASE REGS 4-8 BEFORE        27960000
         LA    GR5,1(GR4,GR8)            EXECUTING FILE RECORD GROUP    27980000
         LA    GR6,1(GR5,GR8)            ROUTINES FOR DETERMINING       28000000
         LA    GR12,1(GR6,GR8)           RECORD TYPE                    28020000
         LA    GR8,1(GR12,GR8)                                          28040000
         BR    GR4                                                      28060000
         SPACE 1                                                        28080000
         CNOP  2,4                                                      28100000
         DC    X'B006'                                                  28120000
LOCWS    DC    X'00000004'              ABSOLUTE LOC OF WORKING STOR    28140000
         SPACE 1                                                        28160000
*   THE FOLLOWING IS GENERATE IF MATCHING FIELDS MATCHING FIELDS ARE    28180000
*  SPECIFIED IN THE RPG SOURCE PROGRAM                                  28200000
         SPACE 1                                                        28220000
         L     GR15,MFSUBA              GR15 = ADRR OF MFSUBR           28240000
         LTR   GR15,GR15                                                28260000
         BZ    PROCMF+10                BRANCH IF ZERO (NO M FLDS FOR   28280000
         XC    M1(6),M1                  CURRENT REORD)                 28300000
         AR    GR15,GR3                                                 28320000
         BALR  GR14,GR15                OTHERWISE BRANCH TO MFSUBR      28340000
M1       DC    X'B006'                  FIELD LENGTH FOR M1-M3 RETURNED 28360000
M3       DS    CL1                       HERE BY MFSUBR                 28380000
MFTYB    DS    CL3                      FIELD TYPE BYTE FOR M1-M3       28400000
*                                        RETURNED HERE                  28420000
         SPACE 2                                                        28440000
*********************************************************************** 28460000
*   PROCMF IS OBJECT PROG ROUTINE TO MOVE MATCHING FIELDS TO WORKING  * 28480000
*  STORAGE AND COMPARE WITH MATCHING FIELDS OF PRECEDING RECORD       * 28500000
*  (CONTAINED IN HOLD AREA FOLLOWING FPB) FOR FILE SEQUENCE CHECKING  * 28520000
*   HALT INDICATOR H0 IS TURNED ON FOR OUT OF SEQUENCE CONDITION      * 28540000
*                                                                     * 28560000
*   ENTRY CONDITIONS AS FOLLOWS                                       * 28580000
*                                                                     * 28600000
*                                                                     * 28620000
*        GR9 = ADDR OF COMMON WORKING STORAGE FOR MATCHING FIELDS     * 28640000
*               AND CONTROL LEVELS (RESERVED BY ASSEMBLE PHASE 2)     * 28660000
*        GR10 = ADDR OF M1 FIELD IN INPUT AREA                        * 28680000
*        GR11 = ADDR OF M2 FIELD IN INPUT AREA                        * 28700000
*        GR12 = ADDR OF M3 FIELD IN INPUT AREA                        * 28720000
*********************************************************************** 28740000
         SPACE 1                                                        28760000
PROCMF   EQU   *                                                        28780000
         OC    M1(3),M1                 TEST FOR MATCHING FIELDS        28800000
         BC    4,M2WS                   BRANCH IF PRESENT               28820000
         OI    FPBMFI(GR1),X'0F'        OTHERWISE SET FPB TO INDICATE   28840000
         B     XIT                       NO MATCHING FIELDS             28860000
M2WS     STM   GR4,GR5,SAV427(GR13)     SAVE GR4 AND GR5                28880000
         LA    GR4,3                                                    28900000
         LA    GR5,MFTYB+2                                              28920000
         SR    GR15,GR15                                                28940000
         LR    GR0,GR9                                                  28960000
M312WS   IC    GR15,M1-1(GR4)                                           28980000
         LTR   GR15,GR15                TEST FOR MATCHING FIELD         29000000
         BZ    NXTMF+4                  BRANCH IF NOT                   29020000
         BCTR  GR15,0                                                   29040000
         TM    0(GR5),X'F0'             TEST MATCHING FIELD TYPE        29060000
         BZ    NXTMF-4                  BRANCH IF ALPHA                 29080000
         BO    *+12                     BRANCH IF UNPACKED NUMERIC      29100000
         EX    GR15,MF2WS               MOVE PACKED FIELD TO WORK STOR  29120000
         B     NISIGN                                                   29140000
*                                       UNPACKED FIELD IS PACKED AND    29160000
         LR    GR2,GR15                  SIGN FORCED TO 'C'             29180000
         LA    GR2,1(GR2)                                               29200000
         SRL   GR2,1                    COMPUTE L1 LENGTH FOR PACK      29220000
         SLL   GR2,4                     L1=(L+1/2)                     29240000
         OR    GR15,GR2                 FORM L1-62 IN GR15              29260000
         EX    GR15,PAC2WS              EXECUTE PACK                    29280000
         SRL   GR15,4                                                   29300000
NISIGN   LA    GR9,0(GR15,GR9)          GR9 = ADDR OF SIGN POSITION     29320000
         NI    0(GR9),X'FC'             FORCE SIGN TO 'C'               29340000
         LA    GR9,1(GR9)                                               29360000
         B     NXTMF+4                                                  29380000
         EX    GR15,MF2WS               MOVE ALPHA OR PACKED TO WORKING 29400000
NXTMF    LA    GR9,1(GR15,GR9)           STO - ADVANCE TO NEXT AREA     29420000
         BCTR  GR5,0                     IN WORKING STORAGE             29440000
         LR    GR7,GR11                                                 29460000
         LR    GR11,GR10                                                29480000
         BCT   GR4,M312WS               LOOP TO PROCESS MF 1-3          29500000
         LM    GR4,GR5,SAV427(GR13)     RESTORE GR4 AND GR5             29520000
TOTMFL   SR    GR9,GR0                  COMPUTE TOTAL LENGTH OF M FLDS  29540000
         BCTR  GR9,0                                                    29560000
         LR    GR11,GR0                                                 29580000
ALTGO    B     CK41ST                   BYPASS CALL ON USER SUBR IF     29600000
*                                        ALT COLLATING SEQ NOT USED     29620000
*                                       (THIS INST IS OVERLAY WITH INST 29640000
         LR    GR1,GR11                  AT STOGR1 IF ALTSEQ USED)      29660000
         L     GR15,LVALTS(GR3)         GR1 POINTS TO WORK STORAGE      29680000
         ST    GR13,SAV13    SAVE CALLING RTN'S STORAGE AREA       7983 29700000
         L     GR13,LVWORK(GR3)  RPG WORK AREA ADDRESS TO GR13     7983 29720000
         LA    GR13,100(GR13)     INCREMENT TO UN-USED AREA        7983 29740000
         B     ALTOUT            BRANCH AROUND SAVE AREA FOR GR13  7983 29760000
SAV13    DC    F'0'          GR13 SAVED HERE BEFORE EXIT TO ALTSEQ 7983 29780000
ALTOUT   BALR  GR14,GR15         EXIT TO ALTSEQ                    7983 29800000
         L     GR13,SAV13        RESTORE REGISTER 13               7983 29820000
         L     GR1,SAVGR1(GR13)          COLLATING SEQUENCE             29840000
CK41ST   TM    FPBMFI(GR1),X'F0'        IF NO PREVIOUS MF'S             29860000
         BC    12,OUTSEQ+8               BYPASS COMPARE                 29880000
         TM    FPBSEQ(GR1),X'04'        TEST FOR ASCENDING SEQ          29900000
         BZ    DESEQ                    BRANCH IF DESCENDING            29920000
         EX    GR9,SEQCK                CHECK SEQUENCE (ASCENDING)      29940000
         BNL   OUTSEQ+8                 BRANCH IF IN SEQUENCE           29960000
         B     OUTSEQ                   BRANCH IF OUT OF SEQUENCE       29980000
DESEQ    EX    GR9,SEQCK                CHECK SEQUENCE (DESCENDING)     30000000
         BNH   *+12                     BRANCH IF OKAY                  30020000
OUTSEQ   MVI   H0(GR3),X'F0'            OTHERWISE SET HALT IND H0       30040000
         MVI   H0CODE(GR3),X'04'                                        30060000
         MVI   FPBMFI(GR1),X'F0'        SET FPB TO INDICATE M FLDS      30080000
         EX    GR9,MV2MFH               MOVE MATCHING FLDS TO HOLD AREA 30100000
         SPACE 1                                                        30120000
*   THE FOLLOWING INSTRUCTIONS COMPLETE THE DRTY2 OBJ PROG SUBR         30140000
         SPACE 1                                                        30160000
         LR    GR9,GR0                  RESTORE GR9 (POINTS TO WK STO)  30180000
XIT      L     GR14,DRTY2X(GR13)                                        30200000
         BR    GR14                     EXIT DRTY2                      30220000
MF2WS    MVC   0(0,GR9),0(GR7)                                          30240000
PAC2WS   PACK  0(0,GR9),0(0,GR7)                                        30260000
SEQCK    CLC   0(0,GR11),MFHA(GR1)                                      30280000
MV2MFH   MVC   MFHA(0,GR1),0(GR11)                                      30300000
         SPACE 1                                                        30320000
EDRTY    EQU   *                                                        30340000
DRTYLG   EQU   EDRTY-DRTY                                               30360000
         SPACE 1                                                        30380000
DP2DRT   EQU   DRTY2-DRTY                                               30400000
M2       EQU   M1+1                                                     30420000
         SPACE 1                                                        30440000
WSADR    EQU   LOCWS-DRTY                                               30460000
         EJECT                                                          30480000
*********************************************************************** 30500000
*   PRESEQ IS OBJECT PROGRAM SUBR TO CHECK INPUT RECORDS TO BE IN A   * 30520000
*  PREDETERMINED SEQUENCE. IT IS INCLUDED IN THE OBJECT PROGRAM       * 30540000
*  IMMEDIATELY FOLLOWING THE DRTY - DRTY2 SUBROUTINES IF A PREDETER-  * 30560000
*  MINED SEQUENCE IS SPECIFIED IN THE INPUT RECORD TYPE SPECS. PRESEQ * 30580000
*  IS CALLED FROM THE RECORD DRIVER ROUTINE (RDRIVR).                 * 30600000
*********************************************************************** 30620000
         SPACE 1                                                        30640000
PRESEQ   BALR  GR10,0                                                   30660000
         USING *,GR10                                                   30680000
CKSEQ    CLC   2(1,GR15),NXTSEQ(GR1)    COMPARE SEQ NO. OF CURRENT REC  30700000
*                                        WITH EXPECTED NO.              30720000
         BNE   CKSEQ2                   BRANCH IF NOT EQ                30740000
         BAL   GR7,ADV2NS               BRANCH TO BUMP EXPECTED NO.     30760000
         MVC   NSEQ(1,GR1),2(GR15)      OTHERWISE SAVE SEQ NO. TO       30780000
*                                        INDICATE REC RECEIVED FOR      30800000
         B     6(0,GR14)                 EXPECTED NO. AND EXIT          30820000
CKSEQ2   TM    3(GR15),X'08'            TEST IF ONE ONLY SPECIFIED FOR  30840000
*                                        CURRENT RECORD                 30860000
         BO    IFOPT                    BRANCH IF ONE ONLY              30880000
         CLC   NSEQ(1,GR1),2(GR15)      OTHERWISE CHECK FOR AT LEAST    30900000
*                                        ONE RECEIVED FOR EXPECTED NO.  30920000
         BE    6(0,GR14)                EXIT IF EQUAL                   30940000
IFOPT    L     GR9,LNSCB(GR1)                                           30960000
         LA    GR9,1(GR3,GR9)           GR9 = NSCB                      30980000
         SR    GR8,GR8                                                  31000000
         IC    GR8,NXTSEQ(GR1)          GR9 POINTS TO CONTROL BYTE      31020000
         AR    GR9,GR8                   FOR EXPECTED SEQ               31040000
         TM    0(GR9),X'10'             TEST IF EXPECTED REC OPTIONAL   31060000
         LR    GR9,GR0                  RESTORE GR9 (POINT TO IORB)     31080000
         BZ    SETH0                    BRANCH IF NOT TO SET HALT IND   31100000
         BAL   GR7,ADV2NS               OTHERWISE ADVANCE TO NEXT SEQ   31120000
         B     CKSEQ                     NO. AND CHECK AGAIN            31140000
SETH0    MVI   H0(GR3),X'F0'                                            31160000
         MVI   H0CODE(GR3),X'08'                                        31180000
         B     6(0,GR14)                                                31200000
         SPACE 1                                                        31220000
ADV2NS   IC    GR11,NXTSEQ(GR1)                                         31240000
         LA    GR11,1(GR11)             ADVANCE EXPECTED SEQ NO. BY ONE 31260000
         STC   GR11,NXTSEQ(GR1)                                         31280000
         CLC   NXTSEQ(1,GR1),HISEQ(GR1) COMPARE WITH HIGHEST NO. FOR    31300000
*                                        THE FILE                       31320000
         BCR   13,GR7                   BRANCH IF NOT HIGH              31340000
         MVI   NXTSEQ(GR1),1            OTHERWISE RESET EXPECTED SEQ    31360000
         BR    GR7                       NUMBER TO 01 AND EXIT ADV2NS   31380000
PREEND   EQU   *                                                        31400000
PRESLG   EQU   PREEND-PRESEQ                                            31420000
PRESEK   EQU   EDRTY-MFSUBA             DISPLC FOR ACCESSING PRESEQ     31440000
*                                        SUBR IN OBJECT PROG            31460000
STOGR1   ST    GR1,SAVGR1(GR13)         THIS INST IS PLACED INTO CALL   31480000
*                                        FOR ALTSEQ SUBR AT ALTGO       31500000
         SPACE 1                                                        31520000
         ORG   *+8                      RESERVE EXTRA 8 BYTES AT END OF 31540000
*                                        TEXT BUFFER                    31560000
         EJECT                                                          31580000
*********************************************************************** 31600000
*   FDRIVR (FILE DRIVER) IS GENERATED FOR EACH PRIMARY, SECONDARY, OR * 31620000
*  CHAINED INPUT FILE                                                 * 31640000
*********************************************************************** 31660000
         SPACE 1                                                        31680000
FDRIVR   BAL   GR1,28(GR1)              BRANCH AROUND FPB TO 1ST RECORD 31700000
*                                        GROUP OR IF A CARD INPUT FILE  31720000
*                                        TO THE CODING GENERATED        31740000
*                                        FOLLOWING THE FPB (GR1 = FPB)  31760000
FPB      DC    X'B018'                  DATA IDENTIFER (COMPILER USE)   31780000
*                                        USED AT OBJECT TIME AS         31800000
*                                        MATCHING FIELDS INDICATOR      31820000
         DS    CL2                      DISPLACEMENT TO IORB            31840000
*        DS    CL4                      ADDR OF MVFLDS SUBR             31860000
*        DS    CL4                      ADDR OF RESULTING INDICATOR     31880000
*        DS    CL4                      ADDR OF MCL2WS SUBR             31900000
*        DS    CL4                      ADDR OF NSCB FOR THE FILE       31920000
*        DS    CL2                      FILE CONTROL BYTE (EOF ACTION   31940000
*                                        AND SEQUENCE SPECIFICATION)    31960000
*        DS    CL1                      EXPECTED SEQ NUMBER OF          31980000
*                                        NEXT RECORD (PREDETERMINED )   32000000
*        DS    CL1                      HIGH SEQ NUMBER OF FILE         32020000
         SPACE 1                                                        32040000
*   GENERATE THE FOLLOWING IF MATCHING FIELDS ARE PRESENT               32060000
*        DS    LC                       MATCHING FIELDS HOLD AREA       32080000
*                                        (L = LENGTH OF MATCHING FLDS)  32100000
         SPACE 1                                                        32120000
EOBUF2   EQU   FDRIVR-1                                                 32140000
BUF2LG   EQU   EOBUF2-DMPTXTBF          LENGTH OF TEXT BUFFER           32160000
         EJECT                                                          32180000
*********************************************************************** 32200000
*   RDRIVR (RECORD DRIVER) IS  AN OBJECT PROGRAM SUBR GENERATED FOR   * 32220000
*  EACH RECORD GROUP. IN THE OBJECT PROGRAM IT FOLLOWS THE CODING     * 32240000
*  WHICH TESTS THE RECORD ID CODES FOR THE RECORD GROUP. WHEN THE     * 32260000
*  RECORD IS IDENTIFIED THE RDRIVR SUBR TURNS ON THE PROPER RESULTING * 32280000
*  INDICATOR AND SUPPLIES THE ADDRESSES OF SUBROUTINES FOR PROCESSING * 32300000
*  THE RECORD                                                         * 32320000
         SPACE 1                                                        32340000
RDRIVR   EQU   *                                                        32360000
         USING *,8                                                      32380000
         OI    0(GR10),X'F0'            TURN ON RESULTING INDICATOR     32400000
         ST    GR10,FPBRI(GR1)          STORE ADDR OF IND IN FPB        32420000
*        B     *+N                      N = 16 IF MATCHING FLDS AND     32440000
*        DC    X'BOOX'   (X = N-4)            CONTROL LEVELS ARE USED   32460000
*                                       N = 12 IF EITHER M FLDS OR CL'S 32480000
*                                             ARE USED (NOT BOTH)       32500000
         SPACE 1                                                        32520000
*   THE FOLLOWING IS ALWAYS GENERATED                                   32540000
         SPACE 1                                                        32560000
*        DS    CL4                      ADDR OF MVFLDS SUBR             32580000
         SPACE 1                                                        32600000
*   THE FOLLOWING IS GENERATED MATCHING FLDS AND/OR CONTROL LEVELS      32620000
*  ARE SPECIFIED FOR THE RECORD GROUP                                   32640000
         SPACE 1                                                        32660000
*        DS    CL4                      ADDR OF MCL2WS SUBR             32680000
*        DS    CL4                      ADDR OF MFSUBR                  32700000
         SPACE 1                                                        32720000
*   THE FOLLOWING IS ALWAYS GENERATED TO PLACE ADDR OF MVFLDS INTO FPB  32740000
         SPACE 1                                                        32760000
XMVC     MVC   FPBMVF(4,GR1),0          PLACE ADDR OF MVFLDS SUBR FOR   32780000
*                                        THE RECORD INTO FPB            32800000
         SPACE 1                                                        32820000
*   THE FOLLOWING IS GENERATED IF MATCHING FLDS AND/OR CONTROL LEVELS   32840000
*  ARE SPECIFIED FOR THE RECORD GROUP                                   32860000
         SPACE 1                                                        32880000
XMVC2    MVC   FPBCL(4,GR1),0           PLACE ADDR OF MCL2WS SUBR FOR   32900000
*                                       THE RECORD INTO FPB             32920000
*        MVC   0(4,GR14),0              RETURN ADDR OF MFSUBR TO DRTY2  32940000
RDRXIT   B     6(0,GR14)                EXIT RDRIVR                     32960000
         SPACE 1                                                        32980000
*   THE FOLLOWING CODE IS GENERATED INSTEAD OF RDRXIT IF THE RECORD HAS 33000000
*  A NUMERIC SEQUENCE (RECORD MUST APPEAR IN PREDETERMINED ORDER)       33020000
         SPACE 1                                                        33040000
PDRSEQ   BAL   GR15,PRESEK(GR14)                                        33060000
         DC    X'B004'                  DATA ID (COMPILER USE) AND USED 33080000
*                                        AT OBJ TIME AS ENCOUNTERED IND 33100000
SEQNUM   DC    X'00'                    RECORD SEQUENCE NUMBER          33120000
CTLBYT   DS    CL1                      CONTROL BYTE                    33140000
*********************************************************************** 33160000
         EJECT                                                          33180000
*********************************************************************** 33200000
*   GIRC (OBJ PROG SUBR) RECEIVES CONTROL FROM THE MASTER DRIVER TO   * 33220000
*  GET THE NEXT INPUT RECORD FOR PROCESSING                           * 33240000
*********************************************************************** 33260000
         SPACE 1                                                        33280000
         CNOP  0,4                                                      33300000
GIRC     EQU   *                                                        33320000
         BALR  GR8,0                                                    33340000
         USING *,GR8                                                    33360000
         B     GIRCBG                                                   33380000
         DC    X'B00A'                                                  33400000
ARGADR   DS    CL4                                                      33420000
TOFF     DS    CL4                                                      33440000
GIRCBG   ST    GR13,SAVEA+MBR           SAVE MASTER DRIVER BASE AND     33460000
         ST    GR14,SAVEA+GIRCEX         RETURN REGISTERS               33480000
         LA    GR13,SAVEA               GR13 POINTS TO SAVE AREA        33500000
         XC    L1(9,GR3),L1(GR3)        SET OFF L1-L9 LEVEL INDICATORS  33520000
GIRCB    B     GNXR                                                     33540000
         SPACE 1                                                        33560000
SAVEA    DS    14F                      SAVE AREA FOR REGISTERS         33580000
         SPACE 1                                                        33600000
*   WHEN A RECORD IS SELECTED FOR PROCESSING THE FOLLOWING SEQUENCE     33620000
*   TURNS ON THE RESULTING INDICATOR ASSOCIATED WITH THE RECORD AND     33640000
*  TESTS FOR CONTROL LEVEL BREAKS                                       33660000
         SPACE 1                                                        33680000
REDYNX   L     GR7,LVIORB(GR3)          GR7 = ADDR OF IORB              33700000
         AH    GR7,IORBDP-4(GR1)        GR2 = ADDR OF INPUT RECORD      33720000
         L     GR2,IPREC(GR7)            TO BE PROCESSED                33740000
         L     GR10,FPBRI(GR1)                                          33760000
         OI    0(GR10),X'F0'            TURN ON RESULTING INDICATOR     33780000
         LA    GR15,H0(GR3)             TEST IF RI= H0 FOR UNDEFINE REC 33800000
         CLR   GR10,GR15                                                33820000
         BNE   NOTH0                    BRANCH IF NOT                   33840000
         ST    GR7,UDFR(GR3)            OTHERWISE STORE IORB ADDR       33860000
         MVI   H0CODE(GR3),X'10'         AND SET H0 CODE                33880000
NOTH0    L     GR10,LVDSPC(GR3)                                         33900000
         ST    GR1,STAFPB(GR10)         STORE FPB ADDR FOR DSPC USE     33920000
         L     GR15,FPBCL(GR1)          GR15 = ADDR OF MCL2WS           33940000
         LTR   GR15,GR15                                                33960000
         BZ    GIRXIT                   BZ IF NO CL'S FOR REC TYPE      33980000
         AR    GR15,GR3                                                 34000000
         L     GR7,LVCLSR(GR3)                                          34020000
         L     GR10,XCLHA(GR7)                                          34040000
         AR    GR10,GR3                                                 34060000
         L     GR14,LVDRTY(GR3)                                         34080000
         L     GR9,WSADR(GR14)                                          34100000
         AR    GR9,GR3                  GR9 = ADDR OF WORKING STORAGE   34120000
         BALR  GR14,GR15                OTHERWISE BRANCH TO MCL2WS      34140000
GIRXIT   L     GR14,GIRCEX(GR13)        RESTORE MASTER DRIVER BASE AND  34160000
         L     GR13,MBR(GR13)            RETURN REGISTERS               34180000
         BR    GR14                     EXIT GIRC                       34200000
         SPACE 1                                                        34220000
*********************************************************************** 34240000
*   GNR (OBJ PROG SUBR) IS CALLED FROM EITHER GNP OR GNS TO READ A    * 34260000
*  RECORD AND DETERMINE THE TYPE. THE ADDR OF THE FPB FOR THE RE-     * 34280000
*  QUESTING FILE IS IN GR1. GNR CALLS THE IO ROUTINE TO READ AND      * 34300000
*  CALLS DRTY2 TO DETERMINE RECORD TYPE                               * 34320000
*********************************************************************** 34340000
         SPACE 1                                                        34360000
GNR      EQU   *                                                        34380000
         L     GR0,LVIORB(GR3)                                          34400000
         AH    GR0,IORBDP(GR1)          GR0 = ADDR OF IORB              34420000
         LR    GR9,GR0                                                  34440000
         ST    GR14,GNRXIT(GR13)                                        34460000
         L     GR15,TOFF                                                34480000
         AR    GR15,GR3                 BRANCH TO TURN OFF RECORD       34500000
         BALR  GR14,GR15                 RESULTING INDICATORS           34520000
         MVI   ACTBYT(GR9),0            SET ACTION BYTE OF IORB TO READ 34540000
         L     GR15,LVIOI(GR3)          GR15 = ADDR OF IO ROUTINE       34560000
         BALR  GR14,GR15                BRANCH TO READ                  34580000
         CLI   H0(GR3),X'F0'            H0 ON IF ERROR ON DASD FILE     34600000
         BNE   CK4EOF                   BRANCH IF NO ERROR              34620000
         L     GR10,LVDSPC(GR3)             OTHERWISE SET NO RECORD     34640000
         XC    STAFPB(4,GR10),STAFPB(GR10)  INDICATOR FOR DSPC SUBR     34660000
         B     GIRXIT                                                   34680000
CK4EOF   CLI   EOFSW(GR9),EOFVAL                                        34700000
         BNE   GNR2                     BRANCH IF NOT EOF               34720000
         L     GR14,GNRXIT(GR13)                                        34740000
         LA    GR1,4(GR1)               GR1 POINTS TO FPB               34760000
         MVI   EOFIND(GR1),X'F0'        SET EOF INDICATOR IN FPB        34780000
         TM    FPBEOF(GR1),X'08'        TEST FOR E SPECIFIED            34800000
*                                        IN COL 17 OF FILE SPEC         34820000
         BCR   8,GR14                   BRANCH IF NOT                   34840000
         LH    GR7,ECOUNT               TEST FOR EOF ON ALL FILES       34860000
*                                        WHERE E IS SPECIFIED           34880000
         BCT   GR7,NOTYET               BRANCH IF NOT                   34900000
         CLI   FPBMFI(GR1),X'F0'       TEST FOR MATCHING FIELDS    7358 34904017
         BNE   SETLR                     BRANCH IF NOT             7358 34908017
         MVI   ENDECT,X'FF'            SET EOF ON ALL E FILES SW   7358 34912017
         B     NOTYET                  CONTINUE TO PROC MTCH RCDS  7358 34916017
SETLR    OI    LRIND(GR3),X'F0'         SET LR INDICATOR ON             34920000
         MVC   L1(9,GR3),DC9XFO         SET ON L1 - L9                  34940000
         B     GIRXIT                    JOB TO BE TERMINATED           34960000
NOTYET   STH   GR7,ECOUNT               SAVE E COUNT                    34980000
         BR    GR14                                                     35000000
GNR2     ST    GR8,GIRCBR(GR13)         SAVE GIRC BASE REG              35020000
         L     GR15,LVDRTY(GR3)                                         35040000
         LA    GR15,DP2DRT(GR15)        GR15 = ADDR OF DRTY2 SUBR       35060000
         BALR  GR14,GR15                BRANCH TO DETERMINE RECORD TYPE 35080000
         L     GR8,GIRCBR(GR13)         RESTORE GIRC BASE REG           35100000
         L     GR10,FPBRI(GR1)                                          35120000
         MVI   0(GR10),0                TURN RESUTING INDICATOR OFF     35140000
         L     GR14,GNRXIT(GR13)         UNTIL RECORD IS SELECTED FOR   35160000
IFMFS    CLI   FPBMFI(GR1),X'F0'        TEST FOR MATCHING FLDS PRESENT  35180000
         BNE   REDYNX                   BRANCH TO PROCESS RECORD IF     35200000
*                                        NO MATCHING FIELDS             35220000
         BR    GR14                      PROCESSING AND EXIT GNR        35240000
         SPACE 2                                                        35260000
*   NOTE - THE CLI AT IFMFS ABOVE IS CHANGED TO B  REDYNX   IF SECOND-  35280000
*  ARY FILES ARE NOT SPECIFIED IN THE SOURCE PROGRAM                    35300000
         SPACE 2                                                        35320000
RGSTR    DC    F'0'                                                1579 35330015
INITSW   DC    X'B00C'                                                  35340000
DC9XFO   DC    10X'F0'                                                  35360000
         CNOP  2,4                                                      35380000
         DC    X'B006'                                                  35400000
PRIFPB   DS    CL4                                                      35420000
         EJECT                                                          35440000
*   THE FOLLOWING PART OF GIRC IS VARIABLE DEPENDING ON THE NUMBER      35460000
*  OF INPUT FILES                                                       35480000
         SPACE 2                                                        35500000
*   THE ROUTINES BELOW ARE GENERATED AS PART OF GIRC WHEN MULTIPLE      35520000
*  FILES (A PRIMARY AND TWO OR MORE SECONDARY FILES) ARE PRESENT        35540000
         SPACE 2                                                        35560000
*********************************************************************** 35580000
*   GNXP (GENERATED WHEN MULTI-FILES ARE PRESENT) CALLS GNR TO READ   * 35600000
*  NEXT RECORD FROM PRIMARY FILE                                      * 35620000
*********************************************************************** 35640000
         SPACE 1                                                        35660000
GNXP     EQU   *                                                        35680000
         ST    GR14,GNXPRR(GR13)                                        35700000
         L     GR1,PRIFPB                                               35720000
         AR    GR1,GR3                  GR1 = ADDR OF FPB (FDRIVR)      35740000
         BAL   GR14,GNR                 BRANCH TO READ RECORD           35760000
         L     GR14,GNXPRR(GR13)                                        35780000
         CLI   EOFIND(GR1),X'F0'        TEST FOR EOF                    35800000
         BCR   7,GR14                   EXIT GNXP IF NOT EOF            35820000
         MVI   EOFPRI,X'F0'             OTHERWISE SET INDICATORS        35840000
         CLI   EOF2ND,X'F0'             TEST FOR EOF ON ALL SECONDARY   35860000
         BE    SETLR                     FILES, IF SO, BRANCH TO SET    35880000
*                                        LR INDICATOR                   35900000
GNXPO    LA    GR15,DP2EOS              OTHERWISE SET GNXRDP TO RUN     35920000
         STH   GR15,GNXRDP               OUT ALL SECONDARY FILES AND    35940000
         CLI   INITSW,X'B0'             TEST IF SECONDARY(S) READ YET   35960000
         BCR   8,GR14                    BRANCH IF NOT                  35980000
         L     GR1,NXT2ND                                               36000000
*                                       CONTINUE PROCESSING SECONDARY   36020000
         B     GO2EOS+6                  FILES                          36040000
         CNOP  0,4                                                      36060000
         DC    X'B00E'       OBJECT TIME USE                       4923 36070016
         DC    H'0'                     STORAGE FOR REGISTR        4923 36080016
NXT2ND   DC    F'0'          STORAGE FOR ADR OF NXT 2NDARY FILE    4923 36090016
EOFPRI   DC    X'00'                                                    36100000
EOF2ND   DC    X'00'                                                    36120000
ECOUNT   DC    H'00'                                                    36160000
FOUR     DC    H'04'                                                    36180000
ENDECT   DC    X'00'                                               7358 36190017
         SPACE 1                                                        36200000
*********************************************************************** 36220000
*   GNXR SELECTS THE NEXT INPUT RECORD FOR PROCESSING. THE NEXT RECORD* 36240000
*  IS READ FROM THE FILE LAST PROCESSED. RECORDS FROM THE PRIMARY AND * 36260000
*  SECONDARY (OR GROUP OF SECONDARY FILES) FILES ARE COMPARED TO      * 36280000
*  DETERMINE WHICH RECORD TO PROCESS NEXT.                            * 36300000
*   IF THE FILES ARE IN ASCENDING SEQUENCE THE ORDER OF PROCESSING IS * 36320000
*  AS FOLLOWS                                                         * 36340000
*                                                                     * 36360000
*   P   S  PROCESS PRIMARY                                            * 36380000
*   P   S  PROCESS SECONDARY                                          * 36400000
*   P = S  PROCESS ALL PRIMARY RECORDS OF THE MATCHING GROUP AND THEN * 36420000
*          PROCESS THE MATCHING SECONDARY RECORDS                     * 36440000
*                                                                     * 36460000
*   IF DESCENDING ORDER OF PROCESSING IS AS FOLLOWS                   * 36480000
*                                                                     * 36500000
*   P   S  PROCESS SECONDARY                                          * 36520000
*   P   S  PROCESS PRIMARY                                            * 36540000
*   P = S  SAME AS FOR ASCENDING SEQUENCE                             * 36560000
*********************************************************************** 36580000
         SPACE 1                                                        36600000
GNXR     LA    GR15,INITP               GR15 = BASE                     36620000
         MVI   MR(GR3),0                SET MR OFF                      36640000
         AH    GR15,GNXRDP              ADD DISPLACE TO GNXR SEQUENCE   36660000
         BCR   15,GR15                   TO BE EXECUTED AND BRANCH      36680000
         DC    X'B004'                                                  36700000
GNXRDP   DC    H'0'                                                     36720000
         SPACE 1                                                        36740000
*   READ FIRST RECORD OF PRIMARY FILE                                   36760000
         SPACE 1                                                        36780000
INITP    BAL   GR14,GNXP                BRANCH TO READ PRIMARY          36800000
         LA    GR15,DPINITS                                             36820000
         STH   GR15,GNXRDP              SET GNXRDP TO GO TO INITS       36840000
         MVI   INITSW,0                 SET TO INDICATE                 36860000
*                                        SECONDARY(S) INITIALIZED       36880000
INITPX   SR    GR7,GR7                                                  36900000
         LH    GR11,NUM2ND              GR11 = NUMBER OF SECONDARY      36920000
         BCTR  GR11,0                                                   36940000
         B     INITS+4                  BRANCH TO INITIALIZE SECONDARY  36960000
         NOP   0(0,8)                    FILES                          36980000
         SPACE 1                                                        37000000
GETP     BAL   GR14,GNXP                BRANCH TO GET NEXT PRIMARY REC  37020000
         L     GR10,NXT2ND              GR10 = FPB OF SECONDARY FILE    37040000
         B     SELNXR                                                   37060000
         SPACE 1                                                        37080000
GETS     BAL   GR14,GNS                 BRANCH TO GET NEXT SECONDARY    37100000
*                                        RECORD (GR10 = FPB)            37120000
         LR    GR1,GR10                                            7358 37123017
         EX    0,PVSPP+4               COMPARE WITH PRIMARY RECORD 7358 37126017
         BE    SELNXR-8                                            7358 37129017
CHKEDE   CLI   ENDECT,X'FF'            COMPARE FOR EOF ON ALL E REC7358 37132017
         BE    SETLR                   IF SO GO TO TURN ON LR      7358 37135017
         L     GR1,PRIFPB                                               37140000
         LA    GR1,4(GR3,GR1)           GR1 = FPB OF PRIMARY FILE       37160000
         SPACE 1                                                        37180000
*   THE FOLLOWING SEQUENCE COMPARES RECORDS OF THE PRIMARY AND SECOND-  37200000
*  ARY FILES AND SELECTS THE RECORD TO BE PROCESSED NEXT                37220000
         SPACE 1                                                        37240000
SELNXR   CLC   MFHA(0,GR1),MFHA(GR10)   COMPARE SECONDARY TO PRIMARY    37260000
*                                       (L1 FIELD INSERTED BY COMPILER) 37280000
         BE    EQPS                     BRANCH IF EQUAL                 37300000
         BH    PROCS                    BRANCH IF PRIMARY HIGH          37320000
*                                       (A BL INST IS GENERATED IF      37340000
*                                        FILES ARE DESCENDING SEQUENCE) 37360000
         LA    GR15,DPGETP              PRIMARY LOW, SET MR OFF AND     37380000
*                                        PROCESS PRIMARY RECORD         37400000
         STH   GR15,GNXRDP              SET GNXRDP TO GO TO GETP NEXT   37420000
         B     REDYNX                                                   37440000
PROCS    LR    GR1,GR10                 PRIMARY HIGH, SET MR OFF AND    37460000
         LA    GR15,DPGETS               SET GNXRDP TO GO TO GETS NEXT  37480000
         B     PROCS-8                  BRANCH TO PROCESS SECONDARY REC 37500000
EQPS     MVC   0(0,0),MFHA(GR1)         PRIMARY EQ SECONDARY, SAVE      37520000
         MVI   MR(GR3),X'F0'             MATCHING FLDS OF PRIMARY REC   37540000
         LA    GR15,XPVSPP              SET MR ON, SET GNXRDP TO PVSPP  37560000
         B     PROCS-8                   AND BRANCH TO PROC PRIMARY REC 37580000
         SPACE 1                                                        37600000
*   THE FOLLOWING SEQUENCE CAUSES ALL PRIMARY RECORDS OF A MATCHING     37620000
*  GROUP TO BE PROCESSED BEFORE ANY SECONDARY RECORDS OF THE GROUP      37640000
         SPACE 1                                                        37660000
PVSPP    BAL   GR14,GNXP                BRANCH TO GET NEXT PRIMARY REC  37680000
         CLC   0(0,0),MFHA(GR1)         COMPARE WITH PRECEDING RECORD   37700000
         BE    SETMR                    BRANCH IF EQUAL TO PROCESS      37720000
         L     GR1,NXT2ND               OTHERWISE LOAD GR1 WITH FPB OF  37740000
*                                        SECONDARY FILE                 37760000
         LA    GR15,XSVSPP              SET GNXRDP TO GO TO SVSPP NEXT  37780000
         STH   GR15,GNXRDP                                              37800000
         B     SETMR                    BRANCH TO PROC SECONDARY REC    37820000
         SPACE 1                                                        37840000
*   THE FOLLOWING SEQUENCE CAUSES THE SECONDARY RECORDS OF A MATCHING   37860000
*  GROUP TO BE PROCESSED                                                37880000
         SPACE 1                                                        37900000
SVSPP    BAL   GR14,GNS                 BRANCH TO GET NEXT SECONDARY    37920000
         LR    GR1,GR10                                                 37940000
         EX    0,PVSPP+4                COMPARE WITH PRIMARY            37960000
         BNE   CHKEDE                  BRANCH IF NOT EQUAL         7358 37980017
SETMR    MVI   MR(GR3),X'F0'            OTHERWISE IF EQ SET MR INDIC-   38000000
         B     REDYNX                    ATOR ON AND BRANCH TO PROCESS  38020000
         SPACE 1                                                        38040000
*  THE FOLLOWING SEQUENCE IS EXECUTED AFTER DETECTING EOF ON THE        38060000
* SECONDARY FILE(S), IT CAUSES PROCESSING OF THE PRIMARY FILE TO        38080000
* CONTINUE UNTIL EOF IS DETECTED                                        38100000
         SPACE 1                                                        38120000
GO2EOP   BAL   GR14,GNXP                BRANCH TO GET NEXT PRIMARY REC  38140000
         B     REDYNX                   BRANCH TO PROCESS               38160000
         SPACE 1                                                        38180000
*  THE FOLLOWING SEQUENCE IS EXECUTED AFTER DETECTING EOF ON THE        38200000
* PRIMARY FILE, IT CAUSES PROCESSING OF THE SECONDARY FILE(S) TO        38220000
* CONTINUE UNTIL EOF IS DETECTED                                        38240000
         SPACE 1                                                        38260000
GO2EOS   BAL   GR14,GNS                 BRANCH TO GET NEXT SECONDARY    38280000
         LR    GR1,GR10                  RECORD                         38300000
         EX    0,PVSPP+4                                                38320000
         BE    SETMR                                                    38340000
         CLI   ENDECT,X'FF'          COMPARE FOR EOF ON ALL E FILES7358 38346017
         BE    SETLR                   IF SO GO TO TURN ON LR      7358 38352017
RUN2ND   LR    GR10,GR1                                                 38360000
         LA    GR1,DC9XFO-MFHA                                          38380000
         EX    GR0,EQPS                                                 38400000
         LR    GR1,GR10                                                 38420000
         MVC   RUN2ND(4),*+6                                            38440000
         B     REDYNX                   BRANCH TO PROCESS               38460000
         SPACE 1                                                        38480000
*  THE FOLLOWING SEQUENCE INITIALLY READS THE SECONDARY FILE(S)         38500000
         SPACE 1                                                        38520000
INITS    LM    GR11,GR7,NXT2ND-4        READ 1ST RECORD FROM EACH OF    38540000
         L     GR1,IP2NDS(GR7)           THE SECONDARY FILES            38560000
         AR    GR1,GR3                                                  38580000
         STM   GR11,GR7,NXT2ND-4                                        38600000
         BAL   GR14,GNR                 BRANCH TO READ                  38620000
         LM    GR11,GR7,NXT2ND-4                                        38640000
         LA    GR7,4(GR7)               BUMP TO NEXT SECONDARY          38660000
         BCT   GR11,INITS+4             CONTINUE IF NOT LAST SECONDARY  38680000
         BAL   GR14,GNS2                                                38700000
         CLI   EOFPRI,X'F0'             TEST FOR EOF WHEN PRIMARY       38720000
         BE    GNXPO                     WAS INITIALIZED                38740000
*                                       OTHERWISE BRANCH TO SELECT      38760000
         B     SELNXR-8                  SECONDARY FOR COMPARING WITH   38780000
*                                        THE PRIMARY FILE RECORD        38800000
         SPACE 2                                                        38820000
*********************************************************************** 38840000
*   GNS READS THE SECONDARY FILE LAST PROCESSED AND THEN COMPARES THE * 38860000
*  RECORDS FROM EACH SECONDARY FILE TO SELECT ONE FOR COMPARSION WITH * 38880000
*  THE PRIMARY FILE RECORD. IF THE FILES ARE IN ASCENDING SEQUENCE THE* 38900000
*  RECORD WITH THE MATCHING FIELD OF THE LOWEST VALUE IS SELECTED, IF * 38920000
*  DESCENDING SEQUENCE THE HIGHEST RECORD IS SELECTED.                * 38940000
*********************************************************************** 38960000
         SPACE 1                                                        38980000
GNS      ST    GR14,GNSXIT(GR13)                                        39000000
         L     GR1,NXT2ND               OBTAIN ADDR OF FPB FOR LAST     39020000
         SH    GR1,FOUR                 (GR1 = FPB)                     39040000
         BAL   GR14,GNR                 BRANCH TO READ THIS FILE        39060000
         L     GR14,GNSXIT(GR13)                                        39080000
GNS2     SR    GR7,GR7                                                  39100000
         LH    GR11,NUM2ND                                              39120000
         SR    GR10,GR10                                                39140000
         BAL   GR15,GNXTS               GET ADDR OF FPB FOR 1ST FILE IN 39160000
         LR    GR10,GR1                  IP2NDS (SECONDARY FILE LIST)   39180000
NXTS     BAL   GR15,GNXTS               GET ADDR OF FPB FOR NEXT FILE   39200000
         CLC   MFHA(0,GR10),MFHA(GR1)   COMPARE RECORDS OF THE 2 FILES  39220000
*                                        (THE L FIELD OF THE CLC INST   39240000
*                                        IS INSERTED BY THE COMPILER)   39260000
         BNH   NXTS                     BRANCH TO COMPARE LOWEST RECORD 39280000
*                                        OF THE PAIR WITH 3RD RECORD    39300000
*                                        AND ETC (THIS IS CHANGED TO A  39320000
*                                        BNL FOR DESCENDING SEQUENCE)   39340000
         B     NXTS-2                                                   39360000
         SPACE 1                                                        39380000
GNXTS    BCT   GR11,GNXTS2              TEST FOR END OF IP2NDS (SECOND- 39400000
*                                        FILE LIST)                     39420000
         LTR   GR10,GR10                IF END OF LIST, TEST FOR EOF    39440000
*                                        ON ALL FILES                   39460000
         BC    7,GNXTSX                 BRANCH IF NOT                   39480000
         CLI   EOFPRI,X'F0'             OTHERWISE TEST FOR EOF ON       39500000
         BE    SETLR                     PRIMARY FILE - BRANCH IF SO    39520000
         CLI   ENDECT,X'FF'          COMPARE FOR EOF ON ALL E FILES7358 39526017
         BE    SETLR                   IF SO GO TO TURN ON LR      7358 39532017
         LA    GR15,DP2EOP              OTHERWISE SET GNXRDP TO RUN     39540000
         STH   GR15,GNXRDP               OUT THE PRIMARY FILE AND SET   39560000
         MVI   EOF2ND,X'F0'              EOF2ND TO INDICATE EOF ON ALL  39580000
         L     GR1,PRIFPB                SECONDARY FILES                39600000
         LA    GR1,4(GR3,GR1)                                           39620000
         B     REDYNX                   BRANCH TO PROCESS PRIMARY       39640000
GNXTSX   ST    GR10,NXT2ND              GR10 = FPB OF SELECTED FILE -   39660000
         BR    GR14                      SAVE AND EXIT GNS              39680000
GNXTS2   L     GR1,IP2NDS(GR7)          OBTAIN ADDR OF FPB FOR NEXT     39700000
         LA    GR1,4(GR3,GR1)            FILE ENTRY IN IP2NDS           39720000
         LA    GR7,4(GR7)                                               39740000
         CLI   EOFIND(GR1),X'F0'        TEST FOR EOF                    39760000
         BE    GNXTS                    IF EOF BRANCH TO GET NEXT FILE  39780000
         BR    GR15                     EXIT GNXTS                      39800000
         CNOP  0,4                                                      39820000
         DC    X'B000'                                                  39840000
NUM2ND   DC    H'0'                                                     39860000
IP2NDS   EQU   *                                                        39880000
         SPACE 1                                                        39900000
*   THE FOLLOWING DISPLACEMENTS ARE USED TO BRANCH TO THE PROPER        39920000
*  SEQUENCE WITHIN GNXR TO GET NEXT INPUT RECORD                        39940000
         SPACE 1                                                        39960000
DPINITS  EQU   INITS-INITP                                              39980000
DPGETP   EQU   GETP-INITP                                               40000000
DPGETS   EQU   GETS-INITP                                               40020000
XPVSPP   EQU   PVSPP-INITP                                              40040000
XSVSPP   EQU   SVSPP-INITP                                              40060000
DP2EOP   EQU   GO2EOP-INITP                                             40080000
DP2EOS   EQU   GO2EOS-INITP                                             40100000
         EJECT                                                          40120000
*   THE CODE BELOW OVERLAYS INITS WHERE ONLY ONE SECONDARY FILE IS      40140000
*  PRESENT (THE PRECEDING GNS ROUTINE IS NOT INCLUDED AS PART OF GIRC   40160000
*  IN THE OBJECT PROGRAM)                                               40180000
         SPACE 1                                                        40200000
GSREC1   BAL   GR14,INITS+16            BRANCH TO GET 1ST SECONDARY REC 40220000
*                                       (BRANCH TO GSREC1+16)           40240000
         CLI   EOFPRI,X'F0'             TEST FOR EOF WHEN PRIMARY       40260000
         BE    GNXPO                     WAS INITIALIZED                40280000
         B     SELNXR-8                 BRANCH TO COMPARE WITH PRIMARY  40300000
         ST    GR14,GNSXIT(GR13)                                        40320000
         L     GR1,NXT2ND                                               40340000
         SH    GR1,FOUR                                                 40360000
*                                       GR1 = FDRIVR SECONDARY FILE     40380000
         BAL   GR14,GNR                 BRANCH TO READ SECONDARY FILE   40400000
         L     GR14,GNSXIT(GR13)                                        40420000
         B     GNS+4                                                    40440000
*                                       (BRANCH TO GNSREC+4)            40460000
         NOPR  GR8                                                      40480000
         NOP   0(0,8)                                                   40500000
GNSREC   B     INITS+16                 GET NEXT SECONDARY RECORD       40520000
         CLI   EOFIND(GR1),X'F0'        TEST FOR EOF                    40540000
         BE    GNS+16                   BRANCH IF EOF DETECTED          40560000
*                                       (BRANCH TO *+8)                 40580000
         LR    GR10,GR1                 OTHERWISE EXIT GNSREC WITH ADDR 40600000
         BR    GR14                      OF FPB IN GR10                 40620000
         CLI   EOFPRI,X'F0'             TEST FOR EOF ON PRIMARY         40640000
         BE    SETLR                    BRANCH IF SO                    40660000
         CLI   ENDECT,X'FF'          COMPARE FOR EOF ON ALL E FILES7358 40666017
         BE    SETLR                   IF SO GO TO TURN ON LR      7358 40672017
         LA    GR15,DP2EOP              OTHERWISE SET GNXRDF TO RUN     40680000
         STH   GR15,GNXRDP               OUT THE PRIMARY FILE AND SET   40700000
         MVI   EOF2ND,X'F0'              EOF2ND TO INDICATE EOF ON      40720000
         L     GR1,PRIFPB                SECONDARY                      40740000
         LA    GR1,4(GR3,GR1)                                           40760000
         B     REDYNX                   BRANCH TO PROCESS PRIMARY       40780000
XGNSR    EQU   *                                                        40800000
GNSRLG   EQU   XGNSR-GSREC1                                             40820000
         SPACE 3                                                        40840000
*   THE CODE BELOW OVERLAYS INITPX WHERE ONLY ONE SECONDARY IS PRESENT  40860000
         SPACE 1                                                        40880000
INIT1S   L     GR1,NXT2ND                                               40900000
         LA    GR1,4(GR3,GR1)                                           40920000
         ST    GR1,NXT2ND                                               40940000
         B     INITS                                                    40960000
XNIT1S   EQU   *                                                        40980000
IT1SLG   EQU   XNIT1S-INIT1S                                            41000000
         EJECT                                                          41020000
*   THE CODE BELOW IS GENERATED IMMEDIATELY FOLLOWING THE FIXED PART    41040000
*  OF GIRC WHERE ONLY A PRIMARY FILE IS PRESENT WITHOUT ANY SECONDARY   41060000
         SPACE 1                                                        41080000
GNP      EQU   *                                                        41100000
         L     GR1,PRIFPB               GR1 = ADDR OF FPB (FDRIVR)      41120000
         AR    GR1,GR3                                                  41140000
         BAL   GR14,GNR                 BRANCH TO READ RECORD           41160000
         B     SETLR                    BRANCH TO SET LR INDICATOR      41180000
ENDGNP   EQU   *                                                        41200000
GNPLG    EQU   ENDGNP-GNP                                               41220000
         SPACE 1                                                        41240000
BA2GNP   DC    S(PRIFPB+4)                                              41260000
         SPACE 2                                                        41280000
MAXGIR   EQU   IP2NDS-GIRC              LENGTH OF MAXIMUM GIRC SUBR     41300000
*                                        TO HANDLE PRIMARY AND TWO OR   41320000
*                                        MORE SECONDARY INPUT FILES     41340000
         SPACE 1                                                        41360000
GIRTWO   EQU   INITS-GIRC+GNSRLG        LENGTH OF GIRC SUBR TO HANDLE   41380000
*                                        PRIMARY AND ONE SECONDARY FILE 41400000
         SPACE 1                                                        41420000
MINGIR   EQU   EOF2ND-GIRC+GNPLG        LENGTH OF MINIMUM GIRC SUBR TO  41440000
*                                        HANDLE ONLY PRIMARY FILE       41460000
         SPACE 1                                                        41480000
LARGT    EQU   ARGADR-GIRC                                              41500000
         SPACE 1                                                        41520000
BUF3LG   EQU   ENDGNP-DMPTXTBF          LENGTH OF TEXT BUFFER           41540000
*                                        FOR OUTPUT OF GIRC             41560000
         EJECT                                                          41580000
*********************************************************************** 41600000
*   CLSUBR (OBJ PROG SUBR) COMPARES CONTROL LEVEL FIELDS OF THE       * 41620000
*  CURRENT INPUT RECORD WITH LIKE FIELDS OF PRECEDING RECORDS. WHEN   * 41640000
*  A BREAK OCCURS THE APPORIATE LEVEL INDICATOR(S) ARE SET ON AND THE * 41660000
*  VALUE OF THE FIELD IN THE CURRENT RECORD REPLACES THE PRECEDING    * 41680000
*  VALUE CONTAINED IN A HOLD AREA.                                    * 41700000
*                                                                     * 41720000
*   ENTRY CONDITIONS                                                  * 41740000
*                                                                     * 41760000
*        GR9 - POINTS TO WORKING STORAGE AREA WHERE THE CONTROL LEVEL * 41780000
*              DATA OF THE CURRENT INPUT RECORD IS STORED             * 41800000
*                                                                       41820000
*        GR10 - POINTS TO HOLD AREA CONTAINING THE LATEST CONTROL     * 41840000
*               LEVEL VALUES                                          * 41860000
*                                                                     * 41880000
*   CLSUBR IS ENTERED ONCE FOR EACH LEVEL (L1-L9) PRESENT WITHIN A    * 41900000
*  RECORD GROUP                                                       * 41920000
*********************************************************************** 41940000
         SPACE                                                          41960000
         CNOP  0,4                                                      41980000
CLSUBR   EQU   *                                                        42000000
         SPACE 1                                                        42020000
*   THE FOLLOWING CODING IS REPEATED 9 TIMES IN THE OBJECT PROGRAM      42040000
*  (ONCE FOR EACH CONTROL LEVEL L1-L9). THE OP+RANDS OF THE CLC AND     42060000
*  MVC INSTRUCTIONS ARE MODIFIED EACH TIME THE CODING IS REPEATED.      42080000
         SPACE 1                                                        42100000
         ST    GR11,RGSTR               SAVE RET REG & USE FOR BASE1579 42110015
         BALR  GR11,0                   SET BASE FOR CLSUBR        1579 42120015
CLCMPR   CLC   0(0,0),0(0)              COMP WK STP & HOLD AREA    1579 42130015
         BC    0,26(0,GR11)             EXIT IF NO CONTROL BREAK   1579 42140015
         OI    7(GR11),X'80'            AFTER 1ST TIME, EXIT IF EQ 1579 42150015
MV2HA    MVC   0(0,0),0(0)              FOR A BREAK REPLACE HOLD AREA   42160000
         MVC   L1(0,GR3),DC9XFO          AND SET ON L INDICATORS        42180000
CLRTRN   L     GR11,RGSTR               RESTORE RETURN REGISTER    1579 42190015
         BC    15,0(0,GR11)             EXIT CLSUBR                1579 42200015
         SPACE 1                                                        42220000
CLSUBE   EQU   *                                                        42240000
CLSUBL   EQU   CLSUBE-CLSUBR                                            42260000
         SPACE 1                                                        42280000
*   THE FOLLOWING IS PLACED AT THE END OF THE CLSUBR IN THE OBJ PROG    42300000
         SPACE 1                                                        42320000
         DC    X'B0080000'              DATA IDENTIFER (COMPILER USE)   42340000
CLHA     DS    CL4                      ADDRESS (ABSOLUTE) OF THE       42360000
*                                        CONTROL LEVELS HOLD AREA       42380000
         SPACE 1                                                        42400000
XCLHA    EQU   (CLSUBL*9)+4             DISPLACEMENT IN THE OBJ PROG    42420000
*                                        TO CLHA                        42440000
CLSRLG   EQU   (CLSUBL*9)+8             TOTAL LENGTH OF CLSUBR IN THE   42460000
*                                        OBJ PROG                       42480000
         END   ASM25                                                    42500000
