         TITLE 'IES150  OS/360 RPG ASSEMBLE PHASE 4                 29' 00020000
* STATUS       CHANGE LEVEL 1-7                                    I222 00040018
*FUNCTION/OPERATION: PROCESS COMPRESSED OUTPUT-FORMAT SPECIFICATIONS TO 00060000
*   GENERATE LINE CODING FOR OBJECT PROGRAM.                            00080000
*ENTRY POINTS:                                                          00100000
*        IES15010-ENTER PHASE FROM IES15910. PHSLINK  L     15,PHSADDR  00120000
*                                                     BALR  7,15        00140000
*                                                     *                 00160000
*                                                     *                 00180000
*                                            PHSADDR  DC    V(IES15010) 00200000
*        POINTERS, COUNTERS, AND CONSTANTS PASSED IN CIOEX DATA AREA    00220000
*        POINTED TO BY REGISTERS 6 AND 12 UPON ENTRY.                   00240000
*INPUT: COMPRESSED RPG SPECIFICATIONS ON SYSUT2.                        00260000
*OUTPUT: OBJECT TEXT ON SYSPUNCH OR SYSGO,DIAGNOSTICS ON SYSPRINT,CIOEX 00280000
*   LINKAGE VECTOR ENTRIES ON SYSUT3, AND FILE TABLE ON SYSUT1.         00300000
*EXTERNAL ROUTINES:                                                     00320000
*        IES15910-CIOEX ROUTINES FOR ASSEMBLE PHASE 4.0.                00340000
*        GETCMP - GET NEXT BLOCK OF COMPRESSION                         00360000
*        PHSCAL - LOAD THE NEXT PHASE                                   00380000
*        PNTERR - WRITE ERROR NOTE                                      00400000
*        PUTCOD - PUT OUT TEXT ON SYSGO/SYSPCH                          00420000
*        PNTCMP - REINITIALIZE WORKFILE TO FIRST COMPRESSION BLOCK      00440000
*        RLDOUT - PUT OUT A RECORD ON RLD WORKFILE                      00460000
*        BLKOUT - PUT OUT A RECORD ON BLANK-AFTER WORKFILE              00480000
*        BLKIN  - READ IN A RECORD FROM BLANK-AFTER WORKFILE            00500000
*        PNTBLK - REINITIALIZE WORKFILE TO FIRST BLANK-AFTER BLOCK      00520000
*        PNTOUT - POINT TO BLOCK CONTAINING FIRST OUTPUT SPECIFICATION  00540000
*EXITS-NORMAL: END - PHASE FINISHED. BRANCH TO NEXT PHASE VIA PHSCAL.   00560000
*     -ERROR:  B02 - NO VALID OUTPUT SPECIFICATIONS. PRINT ERROR NOTE   00580000
*   222 AND BRANCH TO DIAGNOSTIC PHASE VIA PHSCAL.                      00600000
*TABLES/WORKAREAS:                                                      00620000
*   FILETB - OUTPUT FILE DESCRIPTION TABLE BUILT IN SECTION 1 OF PHASE. 00640000
*            SEE DESCRIPTION AT START OF SECTION 1.                     00660000
*   BUFFER - USED TO ASSEMBLE OBJECT CODE FOR PUTTING OUT TEXT.         00680000
*            SEE DESCRIPTION ON TITLE PAGE FOLLOWING.                   00700000
*ATTRIBUTES: EDITABLE, DOWNWARD COMPATIBLE.                             00720000
*NOTES: N/A                                                             00740000
*                                                                       00760000
*                                                                       00780000
IES15010 START                                                          00800000
*0058000400,185800,186200,186600-186800                            000B 00810016
* 008100,032060-032300,038620-038740,039500,041480-041720          I222 00812018
* 058250-058550,062430-062850,064500-063700,066407-066582          I222 00814018
* 067410-067540,068900-069100,112824-113000,114080-114320          I222 00816018
* 282860-282920,284030-084150,299460-299520,311100-313100          I222 00818018
ASSEMBL4 EQU   *                                                        00820000
         EXTRN IES15910                                                 00840000
*                                                                       00860000
         EJECT                                                          00880000
*        ************************************************************** 00900000
*        ************************************************************** 00920000
*        *                    RPG ASSEMBLE PHASE 4.0  (PART1)         * 00940000
*        *                     USED WITH ASSEMBLE 4.5 (PART2)         * 00960000
*        * PROCESS COMPRESSED OUTPUT-FORMAT SPECIFICATIONS - 5 PASSES * 00980000
*        *            ******         ******         ******            * 01000000
*        *  SECTION I  BUILDS FILE DESCRIPTION TABLE, ANALYZES ERRORS * 01020000
*        *  SECTION II GENERATES MACHINE-LANGUAGE CODE WHICH WILL.... * 01040000
*        * 1. DETERMINE WHEN LINES ARE TO BE PUT OUT                  * 01060000
*        * 2. PLACE PUNCH AND PRINT CONTROL FUNCTIONS IN IORB         * 01080000
*        * 3. LINK TO INTERCEPT ROUTINE FOR PUTING OUT LINE           * 01100000
*        * 4. CONTROL SETTING OF OVERFLOW SWITCHES.                   * 01120000
*        * 5. PERFORM AUTOMATIC SKIPPING TO CHANNEL 01 WHEN NECESSARY * 01140000
*        *                                                            * 01160000
*        * IT ALSO COUNTS NUMBER OF LINE ENTRIES. MAXIMUM IS 1023.    * 01180000
*        ************************************************************** 01200000
*        ************************************************************** 01220000
         SPACE 5                                                        01240000
*        ************************************************************** 01260000
*        * A BUFFER AREA (LABELLED BUFFER) USED BY DMPTXT TO ASSEMBLE * 01280000
*        * OBJECT CODE FOR PUNCHING IS AT END OF COMPILER CDE AND HAS * 01300000
*        * A LENGTH GIVEN BY INITIAL VALUE OF 'SOOM'. IT IS DESIGNED  * 01320000
*        * TO USE ALL AVAILABLE CORE UP TO HEX 1800. IT AUTOMATICALLY * 01340000
*        * ADJUSTS ITS LENGTH IF THE COMPILER CODE IS ALTERED.        * 01360000
*        ************************************************************** 01380000
*        ************************************************************** 01400000
*                                                                       01420000
         EJECT                                                          01440000
*        ************************************************************** 01460000
*        * GENERAL REGISTER ASSIGNMENT FOR PHASE                      * 01480000
*        ************************************************************** 01500000
*                                                                       01520000
REG1     EQU   1                        INTERFACE PARAMETER REGISTER    01540000
SERVRG   EQU   2                        SERVICE ROUTINE NO. REGISTER    01560000
INCREG   EQU   2                        ADDRESS COUNTER INCREM.REGISTER 01580000
CPREG    EQU   3                        COMPRESSION ADDRESS REGISTER    01600000
DSPLRG   EQU   4                        CODE DISPLACEMENT REGISTER      01620000
BACKRG   EQU   5                        LINKAGE REGISTER                01640000
EXTREG   EQU   7                       *SERVICE ROUTINE DRIVER REGISTER 01660000
USE2     EQU   8                        BASE REGISTER FOR CONTRL SECT.2 01680000
USE1     EQU   9                        BASE REGISTER FOR CONTRL SECT.1 01700000
PRTREG   EQU   10                      *PRINT AREA REGISTER             01720000
TABREG   EQU   11                       FILE TABLE ADDRESS REGISTER     01740000
CNTREG   EQU   12                      *INTERFACE COUNTER REGISTER      01760000
PASSRG   EQU   13                       DATA PASS COUNT REGISTER        01780000
BCTREG   EQU   13                       LOOP AND COUNT REGISTER         01800000
WORKRG   EQU   14                       WORK REGISTER                   01820000
LR       EQU   14                       RETURN REGISTER FOR DUMPTEXT    01840000
ER       EQU   15                       BRANCH REGISTER FOR DUMPTEXT    01860000
*                                                                       01880000
*                                      *REGISTERS FULL ON ENTRY         01900000
*                                       REGISTER 4 MUST BE SAVED        01920000
*                                       REGISTER 6 MUST BE SAVED        01940000
*                                                                       01960000
*                                                                       01980000
*        ************************************************************** 02000000
*        * GENERAL REGISTER ASSIGNMENT FOR DUMP-TEXT ROUTINE.         * 02020000
*        * ALL REGISTERS ARE STORED AT ARGSAV WHILE IN THIS ROUTINE.  * 02040000
*        ************************************************************** 02060000
*                                                                       02080000
W1       EQU   2                                                        02100000
RUSE     EQU   3                                                        02120000
DMPRG0   EQU   11                                                       02140000
DMPRG1   EQU   12                                                       02160000
DMPRG2   EQU   13                                                       02180000
GR14     EQU   14                                                       02200000
DMPRG3   EQU   14                                                       02220000
DMPRG4   EQU   15                                                       02240000
*                                                                       02260000
         EJECT                                                          02280000
*        ************************************************************** 02300000
*        * ENTRY INTO ASSEMBLE PHASE 4                                * 02320000
*        *                                                            * 02340000
*        * PHASE HOUSEKEEPING                                         * 02360000
*        ************************************************************** 02380000
*                                                                       02400000
START    BALR  USE1,0                   LOAD USING REGISTER             02420000
         USING *,USE1                                                   02440000
         L     USE2,ADRCT2              LOAD BASE FOR 2ND CONTROL SECT. 02460000
         USING CNTRL2,USE2                                              02480000
         L     7,CXRADDR                                                02500000
         MVC   PHSNAM(8,CNTREG),NEXTPH  GIVE NAME OF NXT PHASE TO INTER 02520000
         L     INCREG,ADDCNT(CNTREG)    HALF-WORD ALIGN ADDRESS COUNTER 02540000
         AL    INCREG,CH01B             DITTO                           02560000
         SRL   INCREG,1                 DITTO                           02580000
         SLL   INCREG,1                 DITTO                           02600000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           02620000
         ST    INCREG,LODLOC            USER CORE ADDR TO DMPTXT ROUTNE 02640000
         ST    DSPLRG,STOREL            SAVE PUNCH BUFFER POINTER       02660000
         SR    DSPLRG,DSPLRG            CLEAR DISPLACEMENT REGISTER     02680000
*                                                                       02700000
         EJECT                                                          02720000
*                                                                       02740000
*                                                                       02760000
*                                                                       02780000
*        ************************************************************** 02800000
*        *          SECTION I - FIRST DATA PASS. FOUR PARTS.          * 02820000
*        *            ******         ******         ******            * 02840000
*        *     BUILD THE OUTPUT FILE DESCRIPTION TABLE.               * 02860000
*        *     USE TABLE TO DIAGNOSE FOR FILE-TYPE ERRORS.            * 02880000
*        ************************************************************** 02900000
*        ************************************************************** 02920000
         SPACE 5                                                        02940000
*        ************************************************************** 02960000
*        * THE OUTPUT FILE DESCRIPTION TABLE CONTAINS A 24-BYTE ENTRY * 02980018
*        * FOR EACH OUTPUT FILE (TYPE O, U, OR C). THERE MAY BE UP TO * 03000000
*        * TEN ENTRIES, EACH WITH THE FOLLOWING FORMAT.....           * 03020000
*        *                                                            * 03040000
*        *     BYTES          CONTENTS                                * 03060000
*        *                                                            * 03080000
*        *     01-03          UNPACKED FILE SEQUENCE NUMBER (001-010) * 03100000
*        *     04             REFERENCE BYTE                          * 03120000
*        *     05-12          FILE NAME                               * 03140000
*        *      13             FILE TYPE (O,U,C,L,A OR V)             * 03160018
*        *     14             FILE FORMAT (F OR V)                    * 03180000
*        *     15-17          MAXIMUM RECORD LENGTH IN BINARY         * 03200000
*        *     18             OVERFLOW INDICATOR (A-G,V OR 0)         * 03206018
*        *     19             I.S. KEY ACCESS CODE                    * 03212018
*        *                        X'7F'= BLKD I.S./NON-I.S.           * 03218018
*        *                        BINARY KEY LENGTH= UNBLKD I.S.,     * 03224018
*        *                           BIT ZERO ON= KEY AREA ACCESS OK  * 03230018
*        *     20-22          DEVICE TYPE (PRT, R-NN, TPE, D-NN)      * 03240000
*        *     23-24          DISPLACEMENT TO IORB TABLE FOR FILE     * 03260000
*        *                                                            * 03280000
*        * WHEN LESS THAN 10 OUTPUT FILES ARE PRESENT, UNUSED ENTRIES * 03300000
*        * IN THE TABLE WILL BE FILLED WITH HEX '00' CHARACTERS.      * 03320000
*        ************************************************************** 03340000
*        ************************************************************** 03360000
*                                                                       03380000
         EJECT                                                          03400000
*        ************************************************************** 03420000
*        * PART 1 -                                                   * 03440000
*        * SEARCH FILE DESCRIPTION COMPRESSION FOR VALID OUTPUT FILES * 03460000
*        * AND BUILD TABLE ENTRIES FOR THESE.                         * 03480000
*        ************************************************************** 03500000
*                                                                       03520000
         LA    TABREG,FILETB            GET ADDR OF START OF FILE TABLE 03540000
         LA    SERVRG,PNTCMP            REINITIALIZE COMPRESSION WKFILE 03560000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   03580000
A00      LA    SERVRG,GETCMP            GET NEW BLOCK OF COMPRESSION    03600000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   03620000
A01      CLI   0(CPREG),X'FD'           TEST FOR END OF COMPR BLOCK     03640000
         BH    A00                      BRANCH IF YES - FF              03660000
         BE    B02                      ERROR - NO OUTPUT SPECS         03680000
         AP    SEQNO(4),PK1             INCREMENT SEQUENCE NUMBER       03700000
         CLI   0(CPREG),CHF             TEST FOR F-TYPE COMPRESSION     03720000
         BNE   A04                      BRANCH IF NO                    03740000
         CLI   9(CPREG),CHI             TEST IF VALID OUTPUT FILE       03760000
         BE    A03                      BRANCH IF NO                    03780000
SEQUNPK  UNPK  0(3,TABREG),SEQNO+2(2)   PUT UNPACKED SEQ NO IN TA  I222 03800018
         MVZ   2(1,TABREG),1(TABREG)    CLEAR SIGN ZONE                 03820000
         MVI   3(TABREG),CHNULL         INITIALIZE REF AND OUTPUT TYPE  03840000
         MVC   4(9,TABREG),1(CPREG)     FILENAME AND FILE TYPE TO TABLE 03860000
         CLI   24(CPREG),CHA            IS ADD FUNCTION SPECIFIED  I222 03862018
         BE    MISCOD                     YES                      I222 03864018
         CLI   24(CPREG),CHV            IS ADD/UPDATE SPECIFIED    I222 03866018
         BE    MISCOD                     YES                      I222 03868018
         CLI   24(CPREG),C'L'           IS LOAD FUNCTION SPECIFIE  I222 03870018
         BNE   *+10                       NO                       I222 03872018
MISCOD   MVC   12(1,TABREG),24(CPREG)   PUT I.S. FUNCTION CODE IN  I222 03874018
         MVC   13(1,TABREG),13(CPREG)   FILE FORMAT TO TABLE            03880000
         MVC   14(3,TABREG),17(CPREG)   BINARY RECORD LENGTH TO TABLE   03900000
         MVC   17(1,TABREG),22(CPREG)   OVERFLOW INDICATOR TO TAB  I222 03920018
         MVC   19(3,TABREG),30(CPREG)   DEVICE TO TABLE                 03940000
         MVC   18(1,TABREG),33(CPREG)   KEYCODE TO TABLE           I222 03950018
         PACK  STOREB,0(3,TABREG)       IORB-TABLE DISPLACEMNT TO TABLE 03960000
         SP    STOREB,PK1               DITTO                           03980000
         MP    STOREB,PK32              DITTO                           04000000
         CVB   REG1,STOREB              DITTO                           04020000
         STH   REG1,STOREB              DITTO                           04040000
         MVC   22(2,TABREG),STOREB      DITTO                           04060000
         CLI   29(CPREG),CHL            TEST IF LINE COUNTER FOR FILE   04080000
         BNE   A02                      BRANCH IF NO                    04100000
         OI    3(TABREG),X'08'          SET INDICATOR FOR PRINT FILE    04120000
A02      LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER   I222 04140018
         B     A03A                    BRANCH AROUND INPUT TEST    I222 04148018
A03      CLI   24(CPREG),CHA            INPUT I.S. FILE ALLOWED T  I222 04156018
         BE    SEQUNPK                    PERFORM ADD FUNCTION     I222 04164018
A03A     LA    CPREG,55(CPREG)                                     I222 04172018
         B     A01                                                      04180000
*                                                                       04200000
         EJECT                                                          04220000
*        ************************************************************** 04240000
*        * PART 2 -                                                   * 04260000
*        * SEARCH FILE EXTENSION COMPRESSION FOR ANY TABLE REFERENCES * 04280000
*        * TO OUTPUT FILES.                                           * 04300000
*        ************************************************************** 04320000
*                                                                       04340000
A04      TM    PASKEY(CNTREG),X'20'     TEST FOR TABLE FILE COMPRESSION 04360000
         BZ    B01                      BRANCH IF NONE                  04380000
A05      CLI   0(CPREG),X'FD'           TEST FOR END OF COMPR BLOCK     04400000
         BH    A14                      BRANCH IF YES                   04420000
         BE    B02                      ERROR - NO OUTPUT SPECS         04440000
         CLI   0(CPREG),CHE             SKIP E AND R TYPE COMPRESSIONS  04460000
         BE    A10                      DITTO                           04480000
         CLI   0(CPREG),CHR             DITTO                           04500000
         BE    A12                      DITTO                           04520000
         BNH   B01                      EXIT- FILE EXTENSION COMPR DONE 04540000
         LA    TABREG,FILETB-24         GET ADDR OF START OF FILE TABLE 04560000
         LA    BCTREG,10                LOAD CYCLE COUNT REG WITH 10    04580000
A06      LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER        04600000
         CLC   3(2,CPREG),1(TABREG)     COMPARE FILE SEQ # TO TBL ENTRY 04620000
         BE    A07                                                      04640000
         BCT   BCTREG,A06               COUNT TBL ENTRIES-EXIT AFTER 10 04660000
         B     A08                                                      04680000
A07      OI    3(TABREG),X'80'          INDICATE FILE REFERENCED        04700000
A08      CLI   24(CPREG),CHT            INCREM.COMP POINTER TO NXT SPEC 04720000
         BNE   A09                      DITTO                           04740000
         LA    CPREG,12(CPREG)          DITTO                           04760000
A09      LA    CPREG,25(CPREG)          DITTO                           04780000
         B     A05                                                      04800000
A10      CLI   8(CPREG),CHC             INCREM.COMP POINTER TO NXT SPEC 04820000
         BNE   A11                      DITTO                           04840000
         LA    CPREG,9(CPREG)           DITTO                           04860000
A11      LA    CPREG,9(CPREG)           DITTO                           04880000
         B     A05                                                      04900000
A12      CLI   14(CPREG),CHC            INCREM.COMP POINTER TO NXT SPEC 04920000
         BNE   A13                      DITTO                           04940000
         LA    CPREG,9(CPREG)           DITTO                           04960000
A13      LA    CPREG,15(CPREG)          DITTO                           04980000
         B     A05                                                      05000000
A14      LA    SERVRG,GETCMP            GET NEW BLOCK OF COMPRESSION    05020000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   05040000
         B     A05                                                      05060000
*                                                                       05080000
         EJECT                                                          05100000
*        ************************************************************** 05120000
*        * PART 3 -                                                   * 05140000
*        * SCAN OUTPUT COMPRESSION IN ORDER TO COMPLETE FILE TABLE AND* 05160000
*        * TO DETERMINE IF ANY INVALID FILES IN OUTPUT SPECS.         * 05180000
*        ************************************************************** 05200000
*                                                                       05220000
B01      LA    SERVRG,PNTOUT            POINT TO 1ST BLOCK OF OUT COMPR 05240000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   05260000
         LA    SERVRG,GETCMP            GET FIRST BLOCK OF OUTPUT COMPR 05280000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   05300000
         AH    CPREG,ODSPLC(CNTREG)     MOVE POINTER TO 1ST OUTPUT SPEC 05320000
         MVC   SEQNO(4),SEQOUT(CNTREG)  OBTAIN SEQ NO. OF 1ST OUT SPEC  05340000
         CLI   0(CPREG),CHO             TEST FOR PRESENCE OF OUTPT SPEC 05360000
         BE    B05A                   BRANCH IF PRESENT            I222 05380018
*        ************************************************************** 05400000
*        *   GO DIRECTLY TO DIAGNOSTIC PHASES- BYPASS ASSEMBLE 4.5    * 05420000
*        ************************************************************** 05440000
B02      UNPK  96(3,PRTREG),CH222       ERROR NOTE 222             I222 05460018
B02A     MVC   PHSNAM(8,CNTREG),DIAGPH  MAKE DIAGNOSTIC NEXT PHAS  I222 05480018
         BAL   BACKRG,ERROUT            BRANCH TO PRINT OUT ERROR NOTE  05500000
         L     DSPLRG,STOREL            RELOAD PUNCH BUFFER POINTER     05520000
         LA    SERVRG,PHSCAL            CALL NEXT PHASE (DIAGN MESSAGE) 05540000
         BR    EXTREG                   BRANCH TO INTERFACE ROUTINE     05560000
*        ************************************************************** 05580000
B03      LA    SERVRG,GETCMP            GET NEXT BLOCK OF OUTPUT COMPR  05600000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   05620000
B04      CLI   0(CPREG),X'FD'           TEST FOR END OF COMPR BLOCK     05640000
         BH    B03                      YES - ANOTHER BLOCK TO FOLLOW   05660000
         BE    C01                      YES - NO MORE COMPRESSION       05680000
         AP    SEQNO(4),PK1             INCREMENT SEQUENCE NUMBER       05700000
         CLI   0(CPREG),CHO             TEST IF NEW SPEC IS RECORD TYPE 05720000
         BNE   B13A                     BRANCH IF NO -FIELD TYPE   I222 05740018
         TM    1(CPREG),X'08'           TEST IF AND-TYPE SPEC           05760000
         BO    B13                      BRANCH IF YES                   05780000
         TM    1(CPREG),X'04'           TEST IF OR-TYPE SPEC            05800000
         BO    B08                      BRANCH IF YES                   05820000
B05      CLI   DEFSW,X'11'              WAS REQUIRED I.S. KEY DEF  I222 05825018
         BNE   B05A                       NITION MISSING FOR LAST  I222 05830018
ERR208   UNPK  96(3,PRTREG),CH208           FILE (ERROR 208)       I222 05835018
         MVC   5(3,PRTREG),LFSEQ        SET TO PRINT SEQ NUM AND   I222 05840018
         MVC   10(8,PRTREG),LFNAM        FILE NAME OF ERROR FILE   I222 05845018
         B     B02A                     SKIP FURTHER COMPILATION   I222 05850018
B05A     LA    TABREG,FILETB-24        GET ADDR OF START OF FILE   I222 05855018
         LA    BCTREG,10                LOAD CYCLE COUNT REG WITH 10    05860000
B06      LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER        05880000
         CLC   10(8,CPREG),4(TABREG)    COMPARE FILENAME TO TABLE ENTRY 05900000
         BE    B07                                                      05920000
         BCT   BCTREG,B06               COUNT TBL ENTRIES-EXIT AFTER 10 05940000
         UNPK  96(3,PRTREG),CH220       ERROR NOTE 220                  05960000
         MVC   0(8,PRTREG),EDTSEQ       OBTAIN SEQ. NO. EDIT PATTERN    05980000
         ED    0(8,PRTREG),SEQNO        EDIT SPEC. SEQ. NO. INTO NOTE   06000000
         MVC   10(8,PRTREG),10(CPREG)   PLACE FILENAME IN ERROR NOTE    06020000
         BAL   BACKRG,ERROUT            BRANCH TO PRINT OUT ERROR NOTE  06040000
         LA    TABREG,GARBGE            SAFEGUARD LAST TABLE ENTRY      06060000
         B     B13                                                      06080000
*                                                                       06100000
*                                       (CONTINUED NEXT PAGE)           06120000
         EJECT                                                          06140000
B07      CLC   3(7,CPREG),BLANK         TEST OUTPUT-TYPE FOR 'OTHER'    06160000
         BNE   B08                      BRANCH IF NOT                   06180000
B07A     OI    3(TABREG),X'10'          INDICATE 'OTHER' OUTPUT T  I222 06200018
         B     B10                                                      06220000
B08      CLI   3(CPREG),SPACE           TEST OUTPUT-TYPE FOR PUNCH      06240000
         BE    B09                      BRANCH NO STK SEL OR ADD   I222 06243018
         CLI   3(CPREG),CHA             TEST FOR I.S. ADD RECORD   I222 06246018
         BNE   B08A                       NOT PRESENT              I222 06249018
         CLI   12(TABREG),CHA           IS ADD FUNCTION ALLOWED F  I222 06252018
         BE    B07A                       FILE, BRANCH YES         I222 06255018
         CLI   12(TABREG),CHV           ALSO BRANCH IF ADD/UPDATE  I222 06258018
         BE    B07A                       FILE                     I222 06261018
         UNPK  96(3,PRTREG),CH155       ERROR NOTE 155             I222 06264018
         MVC   0(8,PRTREG),EDTSEQ       OBTAIN SEQ NO. EDIT PATTE  I222 06267018
         ED    0(8,PRTREG),SEQNO        EDIT SPEC SEQ NO. INTO NO  I222 06270018
         MVC   10(8,PRTREG),4(TABREG)   FILENAME TO ERROR NOTE     I222 06273018
         BAL   BACKRG,ERROUT            BRANCH TO PRINT OUT ERR N  I222 06276018
         MVI   3(CPREG),SPACE           BLANK ERRONEOUS SPEC ENTR  I222 06279018
         B     B07                                                 I222 06282018
B08A     OI    3(TABREG),X'20'          INDICATE PUNCH             I222 06285018
B09      CLC   4(6,CPREG),BLANK         TEST OUTPUT-TYPE FOR PRINT      06300000
         BE    B10                                                      06320000
         OI    3(TABREG),X'40'          INDICATE PRINT                  06340000
B10      TM    1(CPREG),X'04'           DEFSW ALREADY SET IF THIS  I222 06345018
         BO    B10A                       IS 'OR' TYPE SPEC        I222 06350018
         CLI   18(TABREG),X'7F'         IF UNBLOCKED I.S.          I222 06355018
         BNE   B14                        GO TO SUBROUTINE         I222 06360018
B10B     MVI   DEFSW,X'00'              SET KEY DEF REQ SW OFF     I222 06365018
B10A     TM    1(CPREG),X'03'           TEST IF ANY RI INDICATORS  I222 06370018
         BZ    B13                      BRANCH IF NO                    06380000
         IC    BCTREG,1(CPREG)          LOAD BCTREG WITH NO. OF INDIC.  06400000
         SLL   BCTREG,30                DITTO                           06420000
         SRL   BCTREG,30                DITTO                           06440000
         LR    REG1,CPREG               INITIALIZE REG1 FOR OVFL SEARCH 06460000
         LA    REG1,12(REG1)            INCREMENT FOR 'OR' TYPE         06480000
         TM    1(CPREG),X'04'           TEST IF OR-TYPE SPEC            06500000
         BO    B11                      BRANCH IF YES                   06520000
         LA    REG1,8(REG1)             INCREMENT FOR 'NORMAL' TYPE     06540000
B11      CLI   0(REG1),X'13'            CHECK FOR LINE COND. BY OVERFLW 06560000
         BH    B12                      BRANCH IF NO                    06580000
         OI    3(TABREG),X'04'          SET INDICATOR FOR FILE          06600000
B12      LA    REG1,3(REG1)             INCREMENT TO NEXT RI            06620000
         BCT   BCTREG,B11               LOOP TILL ALL RI'S CHECKED      06640000
         B     B13                                                 I222 06640718
B13A     LR    WORKRG,CPREG            INCREMENT WORKREG TO POINT  I222 06641418
         TM    1(WORKRG),X'20'           FIELD END POSITION - +3   I222 06642118
         BZ    ADD3                        NO FIELD NAME PRESENT,  I222 06642818
         LA    WORKRG,6(WORKRG)              FOR FIELD NAME PRESE  I222 06643518
ADD3     LA    WORKRG,3(WORKRG)                                    I222 06644218
         TM    0(WORKRG),X'40'          IS THIS A KEY FIELD        I222 06644918
         BZ    B13                       BRANCH NO                 I222 06645618
         CLI   DEFSW,X'00'              IS ACCESS ALLOWED          I222 06646318
         BNE   FLDLEN                     BRANCH YES               I222 06647018
         UNPK  96(3,PRTREG),CH206       ERROR NOTE 206             I222 06647718
         MVC   0(8,PRTREG),EDTSEQ       OBTAIN SEQ NO. EDIT PATTE  I222 06648418
         ED    0(8,PRTREG),SEQNO        EDIT SPEC SEQ NO. INTO NO  I222 06649118
         MVC   10(8,PRTREG),4(TABREG)   FILE NAME IN ERROR NOTE    I222 06649818
         B     B02A                       FIELD UNDEFINABLE        I222 06650518
FLDLEN   MVC   WORK,18(TABREG)          REMOVE ACCESS CODE FROM    I222 06651218
         NI    WORK,X'7F'                 TEST BUCKET BYTE         I222 06651918
         CLC   2(1,WORKRG),WORK         KEY MUST BE SAME LENGTH O  I222 06652618
         BNH   SWOFF                      THAN GIVEN IN FD SPECS   I222 06653318
         MVC   2(1,WORKRG),WORK         SET END POS TO FD SPEC LN  I222 06654018
         UNPK  96(3,PRTREG),CH209       ERROR NOTE 209             I222 06654718
         MVC   0(8,PRTREG),EDTSEQ       OBTAIN SEQ NO. EDIT PATTE  I222 06655418
         ED    0(8,PRTREG),SEQNO        EDIT SPEC SEQ NO. INTO NO  I222 06656118
         MVC   10(8,PRTREG),4(TABREG)   FILE NAME IN ERROR NOTE    I222 06656818
         BAL   BACKRG,ERROUT            BRANCH TO PRINT ERROR NOT  I222 06657518
SWOFF    MVI   DEFSW,X'01'              REQUIRED KEY IS DEFINED    I222 06658218
B13      SR    WORKRG,WORKRG            INCREASE COMPR POINTER BY DELTA 06660000
         IC    WORKRG,2(CPREG)          DITTO                           06680000
         AR    CPREG,WORKRG             DITTO                           06700000
         B     B04                                                      06720000
*                                                                       06740000
B14      CLI   12(TABREG),C'U'          BYPASS FOR UNBLKD I.S.     I222 06741018
         BNE   B14A                       UPDATE FILES             I222 06742018
         B     B10B                                                I222 06743018
B14A     MVC   LFSEQ,0(TABREG)          SAVE SEQ NUM AND FILENAME  I222 06744018
         MVC   LFNAM,4(TABREG)            FOR POSSIBLE ERROR PRIN  I222 06745018
         TM    18(TABREG),X'80'         IS KEY ACCESS ALLOWED      I222 06746018
         BZ    B10B                       BRANCH NO                I222 06747018
         CLI   12(TABREG),CHV           ADD/UPDATE FILE            I222 06748018
         BNE   SETDEF                     BRANCH NO                I222 06749018
         CLI   3(CPREG),CHA             KEY ACCESS ONLY FOR ADD R  I222 06750018
         BNE   B10B                       NOT UPDATE RCD           I222 06751018
SETDEF   MVI   DEFSW,X'11'              SET KEY DEF REQ SW ON      I222 06752018
         B     B10A                                                I222 06753018
         EJECT                                                          06760000
*        ************************************************************** 06780000
*        * PART 4 -                                                   * 06800000
*        * DO REVERSE SCAN OF OUTPUT FILE DESCRIPTION TABLE IN ORDER  * 06820000
*        * TO DIAGNOSE FILE-TYPE ERRORS - NOTES 221, 223-226          * 06840000
*        ************************************************************** 06860000
*                                                                       06880000
C01      CLI   DEFSW,X'11'              REQ'D KEY FIELD NOT DEFIN  I222 06890018
         BE    ERR208                   BRANCH ON ERROR            I222 06900018
         LA    TABREG,FILETB-24         GET ADDR OF FILE TAB STAR  I222 06910018
         LA    BCTREG,10                LOAD CYCLE COUNT REG WITH 10    06920000
C02      LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER        06940000
         CLI   0(TABREG),X'00'          TEST FOR ANY MORE FILES         06960000
         BE    FIRST2                   BRANCH IF NONE                  06980000
         TM    3(TABREG),X'F0'          TEST IF OUTPUT FILE REFERENCED  07000000
         BC    5,C03                    BRANCH IF YES                   07020000
         UNPK  96(3,PRTREG),CH221       ERROR NOTE 221                  07040000
         MVC   5(3,PRTREG),0(TABREG)    PLACE FILE DESCR SEQ NO.IN NOTE 07060000
         MVC   10(8,PRTREG),4(TABREG)   PLACE FILENAME IN ERROR NOTE    07080000
         BAL   BACKRG,ERROUT            BRANCH TO PRINT OUT ERROR NOTE  07100000
         B     C10                                                      07120000
C03      CLI   19(TABREG),CHP           CHECK IF DEVICE IS A PRINTER    07140000
         BNE   C07                      BRANCH IF NO                    07160000
C04      TM    3(TABREG),X'20'          TEST IF STACKER SEL ON PRT FILE 07180000
         BZ    C05                      BRANCH IF NO                    07200000
         UNPK  96(3,PRTREG),CH224       ERROR NOTE 224                  07220000
         MVC   5(3,PRTREG),0(TABREG)    PLACE FILE DESCR SEQ NO.IN NOTE 07240000
         MVC   10(8,PRTREG),4(TABREG)   PLACE FILENAME IN ERROR NOTE    07260000
         BAL   BACKRG,ERROUT            BRANCH TO PRINT OUT ERROR NOTE  07280000
         B     C06                                                      07300000
C05      TM    3(TABREG),X'10'          TEST IF LINES WITH NO PRT FUNCT 07320000
         BZ    C10                      LOOP IF ALL LINES HAVE FUNCTION 07340000
         UNPK  96(3,PRTREG),CH223       ERROR NOTE 223                  07360000
         MVC   5(3,PRTREG),0(TABREG)    PLACE FILE DESCR SEQ NO.IN NOTE 07380000
         MVC   10(8,PRTREG),4(TABREG)   PLACE FILENAME IN ERROR NOTE    07400000
         BAL   BACKRG,ERROUT            BRANCH TO PRINT OUT ERROR NOTE  07420000
C06      NI    3(TABREG),X'CF'          SET DEVICE INDICATOR TO 'PRINT' 07440000
         OI    3(TABREG),X'40'          DITTO                           07460000
         B     C10                      LOOP TO TEST NEXT ENTRY         07480000
C07      CLI   19(TABREG),CHR           CHECK IF DEVICE IS A PUNCH      07500000
         BNE   C09                      BRANCH IF NO                    07520000
         TM    3(TABREG),X'40'          TEST IF PRINT FN ON PUNCH FILE  07540000
         BZ    C08                      BRANCH IF NO                    07560000
         UNPK  96(3,PRTREG),CH226       ERROR NOTE 226                  07580000
         MVC   5(3,PRTREG),0(TABREG)    PLACE FILE DESCR SEQ NO.IN NOTE 07600000
         MVC   10(8,PRTREG),4(TABREG)   PLACE FILENAME IN ERROR NOTE    07620000
         BAL   BACKRG,ERROUT            BRANCH TO PRINT OUT ERROR NOTE  07640000
C08      NI    3(TABREG),X'AF'          SET DEVICE INDICATOR TO 'PUNCH' 07660000
         OI    3(TABREG),X'20'          DITTO                           07680000
         B     C10                      LOOP TO TEST NEXT ENTRY         07700000
*                                                                       07720000
*                                       (CONTINUED NEXT PAGE)           07740000
         EJECT                                                          07760000
C09      TM    3(TABREG),X'08'          TEST IF LINE COUNTER FOR FILE   07780000
         BO    C04                      BRANCH IF YES                   07800000
         TM    3(TABREG),X'60'          TEST IF PRT OR PUNCH FN ON FILE 07820000
         BZ    C10                      IF NO - LOOP TO TEST NEXT ENTRY 07840000
         UNPK  96(3,PRTREG),CH225       ERROR NOTE 225                  07860000
         MVC   5(3,PRTREG),0(TABREG)    PLACE FILE DESCR SEQ NO.IN NOTE 07880000
         MVC   10(8,PRTREG),4(TABREG)   PLACE FILENAME IN ERROR NOTE    07900000
         BAL   BACKRG,ERROUT            BRANCH TO PRINT OUT ERROR NOTE  07920000
         NI    3(TABREG),X'9F'          SET DEVICE INDICATOR TO 'OTHER' 07940000
         OI    3(TABREG),X'10'          DITTO                           07960000
C10      BCT   BCTREG,C02               COUNT TBL ENTRIES-EXIT AFTER 10 07980000
         B     FIRST2                                                   08000000
*                                                                       08020000
         EJECT                                                          08040000
         SPACE 2                                                        08060000
*        ************************************************************** 08080000
*        *            SECTION I TABLE AND CONSTANT AREA.              * 08100000
*        ************************************************************** 08120000
*        ************************************************************** 08140000
*        ************************************************************** 08160000
*                                                                       08180000
         SPACE 5                                                        08200000
*        ************************************************************** 08220000
*        * ADDRESS CONSTANTS FOR REFERENCING OTHER CONTROL SECTIONS.  * 08240000
*        ************************************************************** 08260000
*                                                                       08280000
CXRADDR  DC    A(IES15910)              ADDR. OF CIOEX FOR THIS PHASE   08300000
ADRCT2   DC    A(IES15510)              ADDR. OF SECOND CONTROL SECTION 08320000
*                                                                       08340000
         SPACE 3                                                        08360000
*        ************************************************************** 08380000
*        *           OUTPUT FILE DESCRIPTION TABLE AREA.              * 08400000
*        *                                                            * 08420000
*        * THE TABLE IS USED IN SECTION TWO OF THIS PHASE AND IS ALSO * 08440000
*        * PASSED ON TO ASSEMBLE PHASE 4.5 VIA BLANK-AFTER WORKFILE.  * 08460000
*        ************************************************************** 08480000
*                                                                       08500000
         DS    0D                       DOUBLE WORD ALIGN               08520000
FILETB   DC    240X'00'                                            I222 08540018
TABADD   DC    F'0'                     AREA FOR TABLE START ADDR  I222 08560018
*                                                                       08580000
*              THE FOUR-BYTE ADDRESS OF THE BEGINNING OF THE FIELD-CODE 08600000
*              DISPLACEMENT TABLE IS PASSED FROM THIS PHASE TO ASSEMBLE 08620000
*              PHASE 4.5 AS BYTES 241-244 OF THE FILE DESCRIPTION TABLE 08640000
*              ******************************************************** 08660000
         EJECT                                                          08680000
*                                                                       08700000
*                                                                       08720000
*                                                                       08740000
*        ************************************************************** 08760000
*        *              SECTION II - FOUR DATA PASSES.                * 08780000
*        *            ******         ******         ******            * 08800000
*        * SWITCHING AND CONNECTING ROUTINES FOR SEQUENCING THROUGH   * 08820000
*        * PROGRAM PASSES 2 TO 7.                                     * 08840000
*        *            ******         ******         ******            * 08860000
*        * 1. GENERATE OBJECT CODE FOR LINE-TYPE (O) SPECIFICATIONS   * 08880000
*        *    AND CODE FOR LINKING WITH OTHER OBJECT CODE SEGMENTS.   * 08900000
*        * 2. GENERAL SUBROUTINES                                     * 08920000
*        * 3. DMPTXT SUBROUTINE USED FOR BUFFERING AND PUNCHING ALL   * 08940000
*        *    OBJECT CODE ISSUED.                                     * 08960000
*        ************************************************************** 08980000
*        ************************************************************** 09000000
*                                                                       09020000
         EJECT                                                          09040000
*        ************************************************************** 09060000
*        * FIRST ENTRY INTO 'TOTAL LINE' CODE BLOCK.                  * 09080000
*        * 1. WRITE LINKAGE INFORMATION ON RLD WORKFILE               * 09100000
*        * 2. ISSUE CODE TO LOAD + STORE REGISTERS + STORE CONSTANTS. * 09120000
*        ************************************************************** 09140000
*                                                                       09160000
FIRST2   MVC   RLDRCD+1(2),LVTLIN       TOTAL LN VECT.DISP.TO RLD ENTRY 09180000
         BAL   BACKRG,LINKPN            BRANCH TO LINK AND PUNCH SUBRTN 09200000
         B     REINIT                  .BYPASS TEST INITIAL TIME        09220000
         SPACE 3                                                        09240000
*        * ************************************************************ 09260000
*        * OBTAIN LINE COUNT AT END OF PASS 2. THIS IS MAX LINE COUNT * 09280000
*        * ************************************************************ 09300000
*                                                                       09320000
TSTSW2   TM    PAS2SW,X'02'            .FTO SWITCH                      09340000
         BO    REINIT                  .GO REINIT CTR                   09360000
         OI    PAS2SW,X'02'            .TURN ON SWITCH                  09380000
         MVC   LINCT(4),LINCTR         .SAVE HIGHEST COUNT              09400000
*                                                                       09420000
*                                                                       09440000
*        ************************************************************** 09460000
*        * ENTER NEXT DATA PASS.               USED BY PASSES 2 TO 7. * 09480000
*        * REINITIALIZE COMPRESSION FILE FOR NEXT PASS OF OUTPUT SPECS* 09500000
*        ************************************************************** 09520000
*                                                                       09540000
REINIT   LA    SERVRG,PNTOUT            POINT TO 1ST BLOCK OF OUT COMPR 09560000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   09580000
         LA    SERVRG,GETCMP            GET FIRST BLOCK OF OUTPUT COMPR 09600000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   09620000
         AH    CPREG,ODSPLC(CNTREG)     MOVE POINTER TO 1ST OUTPUT SPEC 09640000
         MVC   SEQNO(4),SEQOUT(CNTREG)  OBTAIN SEQ NO. OF 1ST OUT SPEC  09660000
DOAGN    LH    WORKRG,NEG4             .INIT TO -4                      09680000
         ST    WORKRG,LINCTR           .LINE COUNTER                    09700000
         L     PASSRG,STOREC            OBTAIN PASS NUMBER INDICATOR    09720000
         LA    PASSRG,4(PASSRG)         INCREM PASSRG TO INDIC NXT PASS 09740000
         ST    PASSRG,STOREC            STORE PASS NUMBER INDICATOR     09760000
         B     PASSIN                   BRANCH TO NEXT PASS             09780000
*                                                                       09800000
         EJECT                                                          09820000
*                                                                       09840000
*        ************************************************************** 09860000
*        * EXAMINE NEXT COMPRESSED OUTPUT SPEC IF ANY.                * 09880000
*        * 1. TESTS FOR END OF COMPRESSION BLOCK                      * 09900000
*        * 2. TESTS WHETHER RECORD (O) OR FIELD (M) TYPE COMPR SPEC   * 09920000
*        * 3. TESTS RECORD-TYPE SPECS FOR 'AND' AND 'OR'              * 09940000
*        * 4. FOR 'OR' SPECS, ISSUE PUNCH/PRINT CODE IF REQUIRED      * 09960000
*        ************************************************************** 09980000
*                                                                       10000000
D01      LA    SERVRG,GETCMP            GET NEXT BLOCK OF OUTPUT COMPR  10020000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   10040000
PASSIN   CLI   0(CPREG),X'FD'           TEST FOR END OF COMPR BLOCK     10060000
         BH    D01                      END (FF- ANOTHER BLK TO FOLLOW) 10080000
         BE    TSTSW2                   END (FD- NO MORE COMPRESSION)   10100000
         CLI   0(CPREG),CHO             TEST IF NEW SPEC IS RECORD TYPE 10120000
         BNE   FIELD                    BRANCH IF NO - FIELD TYPE (M)   10140000
         TM    1(CPREG),X'08'           TEST IF 'AND' TYPE SPEC         10160000
         BZ    D02                      BRANCH IF NO                    10180000
         TM    ANDSW,X'40'              IS RECORD TO BE OUTPT THIS PASS 10200000
         BO    G03                      BRANCH IF YES                   10220000
         B     D07                      BRANCH TO PICK UP NEXT SPEC     10240000
D02      TM    1(CPREG),X'04'           TEST IF AN 'OR' TYPE SPEC       10260000
         BZ    D03                      BRANCH IF NO                    10280000
         TM    SWTCH1,X'A0'             IS PUNCH/PRINT INFO ALREADY OUT 10300000
         BC    9,D02A                   BRANCH IF YES                   10320000
         BAL   BACKRG,PRNTFN            ISSUE CODE TO FILL PRNT/PNCH FN 10340000
         OI    PNCHSW,X'80'             SET PUNCH/PRINT ISSUED SWITCH   10360000
D02A     CLC   4(6,CPREG),BLANK         SEE IF PRT FNS BLANK ON OR-TYPE 10380000
         BNE   D04                      BRANCH IF NO                    10400000
         B     D05                                                      10420000
*                                                                       10440000
         EJECT                                                          10460000
*        ************************************************************** 10480000
*        * PERFORM FUNCTIONS TO FINISH PREVIOUS LINE AND START NEXT.  * 10500000
*        * 1. FINISH CODE-OUTPUT AND FILL UBA'S FOR LAST LINE, IF ANY.* 10520000
*        * 2. UPDATE ADDRESS COUNTER TO INCLUDE LAST CODE BLOCK.      * 10540000
*        * 3. STORE FILENAME AND PRINT-PUNCH INFORMATION FROM COMPR.  * 10560000
*        ************************************************************** 10580000
*                                                                       10600000
D03      TM    LINESW,X'20'             IS THERE PREVIOUS LINE TO OUTPT 10620000
         BZ    D03O                     BRANCH IF NO                    10640000
         LA    ER,DMPTXT                                                10660000
         TM    PNCHSW,X'80'             IS PUNCH/PRINT INFO ALREADY OUT 10680000
         BO    D03A                     BRANCH IF YES                   10700000
         BAL   BACKRG,PRNTFN            ISSUE CODE TO FILL PRNT/PNCH FN 10720000
D03A     CLI   ABCUSE+2,CHNULL          TEST IF UNDEFINED 'OR' BRANCHES 10740000
         BE    D03H                     BRANCH IF NONE                  10760000
         MVC   J14(2),CH02B             MOVE UBA IDENTIFIER TO LINKAGE  10780000
         BAL   BACKRG,UBADEF                                            10800000
D03H     TM    FLDSW,X'01'              ANY FIELDS IN PREVIOUS LINE     10820000
         BO    D03L                     BRANCH IF YES                   10840000
         NC    COD041+2(2),RESET                                        10860000
         TM    LINCTR,X'FF'                                             10880000
         BO    D03J                                                     10900000
         OC    COD041+2(2),LINCTR+2                                     10920000
         B     D03K                                                     10940000
D03J     OC    COD041+2(2),LINCT+2                                      10960000
D03K     BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      10980000
         DC    AL2(8)                                                   11000000
         DC    AL4(COD041)                                              11020000
         LA    DSPLRG,8(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 11040000
D03L     BAL   BACKRG,SETCOD            LINK TO CODE-SETTING ROUTINE    11060000
         TM    TTOVSW,X'02'             IS OVFL SWITCH TO BE SET        11080000
         BO    D03M                     BRANCH IF NO                    11100000
         BAL   BACKRG,OVFSET            LINK TO PUNCH COD007            11120000
D03M     CLI   ABCUSE+4,CHNULL          CHECK FOR ANY UNDEF.BRANCH ADDR 11140000
         BE    D03N                     BRANCH IF NONE                  11160000
         MVC   J14(2),CH04B             MOVE UBA IDENTIFIER TO LINKAGE  11180000
         BAL   BACKRG,UBADEF                                            11200000
D03N     L     INCREG,ADDCNT(CNTREG)    UPDATE THE ADDRESS COUNTER      11220000
         LA    INCREG,2(DSPLRG,INCREG)  DITTO                           11240000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           11260000
         SR    DSPLRG,DSPLRG            CLEAR DISPLACEMENT REGISTER     11280000
D03O     CLI   3(CPREG),CHA             IS THIS AN ADD I.S. RECOR  I222 11281018
         BE    D03P                       YES, BRANCH              I222 11282018
         LA    BCTREG,10                INITIALIZE FOR SEARCH      I222 11283018
         LA    TABREG,FILETB            GET FILE TABLE ADDR        I222 11284018
FINDFIL  CLC   10(8,CPREG),4(TABREG)    SEARCH FOR FILENAME MATCH  I222 11285018
         BE    COMPADD                  CHECK FOR ADD REQ          I222 11286018
         LA    TABREG,24(TABREG)        NEXT ENTRY                 I222 11287018
         BCT   BCTREG,FINDFIL           TRY, TRY, TRY AGAIN        I222 11288018
         B     D03R                     BRANCH AFTER 10            I222 11289018
COMPADD  CLI   12(TABREG),CHA           DOES FILE REQ ADD RCDS     I222 11290018
         BNE   D03R                       NO                       I222 11291018
         UNPK  96(3,PRTREG),CH156       ERROR NOTE 156             I222 11292018
         MVC   0(8,PRTREG),EDTSEQ       OBTAIN SEQ NO. EDIT PATTE  I222 11293018
         ED    0(8,PRTREG),SEQNO        EDIT SPEC SEQ NO. INTO NO  I222 11294018
         MVC   10(7,PRTREG),4(TABREG)     FILENAME IN ERROR NOTE   I222 11295018
         B     B02A                     RECORD UNDEFINABLE         I222 11296018
D03P     MVI   COD010+5,X'03'           ALTER CODE THAT PUTS ACTI  I222 11297018
         B     *+8                        BYTE INTO IORB  X'03'=A  I222 11298018
D03R     MVI   COD010+5,X'02'               WRITE, X'02'=REG WRIT  I222 11299018
         MVC   STOREB(8),10(CPREG)      STORE FILENAME FOR COMPAR  I222 11300018
         L     WORKRG,LINCTR           .PICK UP LINE COUNT              11320000
         LA    WORKRG,4(WORKRG)         STEP UP 4                       11340000
         ST    WORKRG,LINCTR            STORE UPDATED LINE COUNT        11360000
         NI    SWTCH1,X'4E'             RESET -- BALR,LINE,PUNCH,FLD SW 11380000
D04      MVC   STOREE+1(6),4(CPREG)     STORE NEW PRINT FUNCTIONS       11400000
D05      MVI   STOREE,C' '              TEST FOR ADD               I222 11408018
         CLI   3(CPREG),CHA               RECORD AND DON'T         I222 11416018
         BE    *+10                       MOVE AN 'A'              I222 11424018
         MVC   STOREE(1),3(CPREG)         IF PRESENT               I222 11432018
         L     PASSRG,STOREC            OBTAIN PASS NUMBER INDICATOR    11440000
*                                                                       11460000
         EJECT                                                          11480000
*        ************************************************************** 11500000
*        * DETERMINE WHICH DATA PASS IS BEING PERFORMED AT PRESENT.   * 11520000
*        * GOES TO ROUTINES WHICH DECIDE IF SPEC PROCESSED THIS PASS. * 11540000
*        ************************************************************** 11560000
*                                                                       11580000
NEXT     B     NEXT(PASSRG)                                             11600000
         B     PASS2                                                    11620000
         B     END2                                                     11640000
         B     PASS3                                                    11660000
         B     PASS4                                                    11680000
         B     END5                                                     11700000
         B     PASS6                                                    11720000
         B     END                                                      11740000
*                                                                       11760000
*                                                                       11780000
*                                                                       11800000
*        ************************************************************** 11820000
*        * ROUTINES FOR DECIDING WHICH PASS SPEC IS TO BE PROCESSED.  * 11840000
*        ************************************************************** 11860000
*                                                                       11880000
PASS2    TM    1(CPREG),X'D0'           TEST IF TOTAL LINE NOT OVERFLOW 11900000
         BC    5,D06                    BRANCH IF NO                    11920000
         B     GENER1                                                   11940000
*                                                                       11960000
PASS3    TM    1(CPREG),X'30'           TEST IF TOTAL LINE CONDIT.BY OF 11980000
         BC    12,D06                   BRANCH IF NO                    12000000
         B     GENER1                                                   12020000
*                                                                       12040000
PASS4    TM    1(CPREG),X'90'           TEST IF HEAD. LINE CONDIT.BY OF 12060000
         BC    12,PASS5                 BRANCH IF NO                    12080000
         B     GENER1                                                   12100000
*                                                                       12120000
PASS5    TM    1(CPREG),X'50'           TEST IF DETAIL LNE CONDIT.BY OF 12140000
         BC    12,D06                   BRANCH IF NO                    12160000
         B     GENER1                                                   12180000
*                                                                       12200000
PASS6    TM    1(CPREG),X'70'           TEST IF HEAD. LINE NOT OVERFLOW 12220000
         BC    5,PASS7                  BRANCH IF NO                    12240000
         B     GENER1                                                   12260000
*                                                                       12280000
PASS7    TM    1(CPREG),X'B0'           TEST IF DETAIL LNE NOT OVERFLOW 12300000
         BC    5,D06                    BRANCH IF NO                    12320000
         B     GENER1                                                   12340000
*                                                                       12360000
*                                                                       12380000
*              NOTE.....                                                12400000
*              FOR COMPATIBILITY WITH PREVIOUS VERSIONS OF RPG NO       12420000
*              DISTINCTION IS MADE BETWEEN HEADING AND DETAIL LINES.    12440000
*              TO PROCESS ALL HEADING LINES BEFORE THE DETAIL LINES     12460000
*              SIX DATA PASSES ARE REQUIRED INSTEAD OF FOUR. TO EFFECT  12480000
*              THIS INSERT BRANCHES TO PASS5 AND PASS7 IN PROPER PLACE  12500000
*              IN 'NEXT' ABOVE, AND CHANGE BC IN 'PASS4' AND 'PASS6'    12520000
*              TO BRANCH TO D06 AS IS DONE IN OTHER FOUR CASES.         12540000
*                                                                       12560000
         EJECT                                                          12580000
*                                                                       12600000
*        ************************************************************** 12620000
*        * RESET APPROPRIATE SWITCHES FOR NEXT SPECIFICATION.         * 12640000
*        * INCREASE COMPRESSION POINTER IN ORDER TO PICK UP NEXT SPEC * 12660000
*        ************************************************************** 12680000
*                                                                       12700000
D06      NI    ANDSW,X'BF'              RESET 'AND INCLUDED' SWITCH     12720000
         TM    1(CPREG),X'04'           TEST IF AN 'OR' TYPE SPEC       12740000
         BO    D07                      BRANCH IF YES                   12760000
         NI    PROCSW,X'FB'             RESET 'PROCESS RECORD' SWITCH   12780000
D07      SR    WORKRG,WORKRG            INCREASE COMPR POINTER BY DELTA 12800000
         IC    WORKRG,2(CPREG)          DITTO                           12820000
         AR    CPREG,WORKRG             DITTO                           12840000
         AP    SEQNO(4),PK1             INCREMENT SEQUENCE NUMBER       12860000
         B     PASSIN                                                   12880000
*                                                                       12900000
         EJECT                                                          12920000
*        ************************************************************** 12940000
*        * GENERATE USER OBJECT CODE FOR LINE-TYPE (O) SPECIFICATIONS * 12960000
*        ************************************************************** 12980000
*                                                                       13000000
GENER1   LA    TABREG,FILETB            GET ADDR OF START OF FILE TABLE 13020000
         LA    BCTREG,10                LOAD CYCLE COUNT REG WITH 10    13040000
G02      CLC   STOREB(8),4(TABREG)      COMPARE FILENAME TO TABLE ENTRY 13060000
         BE    G10                                                      13080000
         LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER        13100000
         BCT   BCTREG,G02               COUNT TBL ENTRIES-EXIT AFTER 10 13120000
         B     D06                                                      13140000
         SPACE 3                                                        13160000
********************                                                    13180000
* 'AND' TYPE SPECS *                                                    13200000
G03      LA    ER,DMPTXT                                                13220000
         MVC   COD004+2(2),4(CPREG)     MOVE IN FIRST RI ADDRESS        13240000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             13260000
         CLI   3(CPREG),CHN             CHECK IF A 'NOT' TEST           13280000
         BNE   G05                      BRANCH IF NO                    13300000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            13320000
G05      BAL   BACKRG,J02                                               13340000
         TM    1(CPREG),X'02'           TEST IF ANY MORE R. INDICATORS  13360000
         BZ    D07                      BRANCH IF NO                    13380000
         MVC   COD004+2(2),7(CPREG)     MOVE IN SECOND RI ADDRESS       13400000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             13420000
         CLI   6(CPREG),CHN             CHECK IF A 'NOT' TEST           13440000
         BNE   G07                      BRANCH IF NO                    13460000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            13480000
G07      BAL   BACKRG,J02                                               13500000
         TM    1(CPREG),X'01'           TEST IF ANOTHER R. INDICATOR    13520000
         BZ    D07                      BRANCH IF NO                    13540000
         MVC   COD004+2(2),10(CPREG)    MOVE IN THIRD RI ADDRESS        13560000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             13580000
         CLI   9(CPREG),CHN             CHECK IF A 'NOT' TEST           13600000
         BNE   G08                      BRANCH IF NO                    13620000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            13640000
G08      BAL   BACKRG,J02                                               13660000
         B     D07                                                      13680000
*                                                                       13700000
         EJECT                                                          13720000
G10      OI    PROCSW,X'04'             IND.PRESENT RCD BEING PROCESSED 13740000
         OI    LINESW,X'20'             INDICATE A LINE IS BEING BUILT  13760000
         OI    ANDSW,X'40'              IND. FOLLOWING 'AND'S PROCESSED 13780000
         LA    ER,DMPTXT                                                13800000
         TM    1(CPREG),X'03'           TEST IF ANY RESULTING INDICATOR 13820000
         BZ    G24                      BRANCH IF NO INDICATORS         13840000
         TM    1(CPREG),X'04'           TEST IF AN 'OR' TYPE SPEC       13860000
         BZ    G20                      BRANCH IF NO                    13880000
*                                                                       13900000
*******************                                                     13920000
* 'OR' TYPE SPECS *                                                     13940000
         MVC   COD004+2(2),11(CPREG)    MOVE IN FIRST RI ADDRESS        13960000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             13980000
         CLI   10(CPREG),CHN            CHECK IF A 'NOT' TEST           14000000
         BNE   G11                      BRANCH IF NO                    14020000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            14040000
G11      TM    BALRSW,X'10'             IS THIS THE FIRST CODE FOR LINE 14060000
         BO    G12                      BRANCH IF NO                    14080000
         BAL   BACKRG,J01                                               14100000
         B     G13                                                      14120000
G12      NI    PNCHSW,X'7F'             RESET PNCH/PRNT FN ISSUED SWTCH 14140000
         BALR  LR,ER                    LINKAGE TO DMPTXT               14160000
         DC    AL2(4)                                                   14180000
         DC    AL4(COD005)                                              14200000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 14220000
         IC    WORKRG,ABCUSE+2          INCREMENT UBA COUNTER NUMBER 2  14240000
         LA    WORKRG,1(WORKRG)         DITTO                           14260000
         STC   WORKRG,ABCUSE+2          DITTO                           14280000
         CLI   ABCUSE+4,CHNULL          TEST IF UNDEFINED IND. BRANCHES 14300000
         BE    G12A                     BRANCH IF NONE                  14320000
         MVC   J14(2),CH04B             MOVE UBA IDENTIFIER TO LINKAGE  14340000
         BAL   BACKRG,UBADEF                                            14360000
G12A     BAL   BACKRG,J02                                               14380000
G13      TM    1(CPREG),X'02'           TEST IF ANY MORE R. INDICATORS  14400000
         BZ    D07                      BRANCH IF NO                    14420000
         MVC   COD004+2(2),14(CPREG)    MOVE IN SECOND RI ADDRESS       14440000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             14460000
         CLI   13(CPREG),CHN            CHECK IF A 'NOT' TEST           14480000
         BNE   G14                      BRANCH IF NO                    14500000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            14520000
G14      BAL   BACKRG,J02                                               14540000
         TM    1(CPREG),X'01'           TEST IF ANOTHER R. INDICATOR    14560000
         BZ    D07                      BRANCH IF NO                    14580000
         MVC   COD004+2(2),17(CPREG)    MOVE IN THIRD RI ADDRESS        14600000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             14620000
         CLI   16(CPREG),CHN            CHECK IF A 'NOT' TEST           14640000
         BNE   G15                      BRANCH IF NO                    14660000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            14680000
G15      BAL   BACKRG,J02                                               14700000
         B     D07                                                      14720000
*                                                                       14740000
         EJECT                                                          14760000
********************                                                    14780000
* H/D/T TYPE SPECS *                                                    14800000
G20      MVC   COD004+2(2),19(CPREG)    MOVE IN FIRST RI ADDRESS        14820000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             14840000
         CLI   18(CPREG),CHN            CHECK IF A 'NOT' TEST           14860000
         BNE   G21                      BRANCH IF NO                    14880000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            14900000
G21      BAL   BACKRG,J01                                               14920000
         TM    1(CPREG),X'02'           TEST IF ANY MORE R. INDICATORS  14940000
         BZ    D07                      BRANCH IF NO                    14960000
         MVC   COD004+2(2),22(CPREG)    MOVE IN SECOND RI ADDRESS       14980000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             15000000
         CLI   21(CPREG),CHN            CHECK IF A 'NOT' TEST           15020000
         BNE   G22                      BRANCH IF NO                    15040000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            15060000
G22      BAL   BACKRG,J02                                               15080000
         TM    1(CPREG),X'01'           TEST IF ANOTHER R. INDICATOR    15100000
         BZ    D07                      BRANCH IF NO                    15120000
         MVC   COD004+2(2),25(CPREG)    MOVE IN THIRD RI ADDRESS        15140000
         MVI   COD004+1,X'F0'           'INDICATOR ON' TEST             15160000
         CLI   24(CPREG),CHN            CHECK IF A 'NOT' TEST           15180000
         BNE   G23                      BRANCH IF NO                    15200000
         MVI   COD004+1,X'00'           'INDICATOR OFF' TEST            15220000
G23      BAL   BACKRG,J02                                               15240000
         B     D07                                                      15260000
         SPACE 3                                                        15280000
********************                                                    15300000
* NO RI INDICATORS *   * ONLY H/D/T CAN HAVE NO INDICATORS. *           15320000
G24      OI    BALRSW,X'10'             SET SWITCH ON - BALR ISSUED     15340000
         BALR  LR,ER                    LINK TO DMPTXT ROUTINE          15360000
         DC    AL2(2)                                                   15380000
         DC    AL4(COD003)                                              15400000
         LH    DSPLRG,CH00B             INITIALIZE DISPL. REG FOR LINE  15420000
         B     D07                                                      15440000
*                                                                       15460000
         EJECT                                                          15480000
*        ************************************************************** 15500000
*        * SET UP LINK TO TABLE (GENERATED IN ASMBL45) FOR BRANCH     * 15520000
*        * TO FIELD CODE.(BUILT IN ASMBL45) FOR FIELD-TYPE(M) SPECS.  * 15540000
*        * ************************************************************ 15560000
*        * LOGIC IS THAT LINE CODE (CONDITIONING IF FIELD CODE FOR    * 15580000
*        * THAT LINE IS TO BE EXECUTED) WILL BRANCH ON A TABLE BUILT  * 15600000
*        * BY THE ASMBL45 AND EXPRESSED AS A SERIES OF DISPLACEMENTS. * 15620000
*        * THE TABLE CONTENTS (PLUS BASE) WILL INDICATE THE START OF  * 15640000
*        * FIELD CODING FOR THAT LINE.                                * 15660000
*        ************************************************************** 15680000
*                                                                       15700000
FIELD    TM    PROCSW,X'04'             IS RECORD TO BE OUTPT THIS PASS 15720000
         BZ    D07                      BRANCH IF NO                    15740000
         LA    ER,DMPTXT                                                15760000
         TM    PNCHSW,X'80'             IS PUNCH/PRINT INFO ALREADY OUT 15780000
         BO    F01                      BRANCH IF YES                   15800000
         BAL   BACKRG,PRNTFN            ISSUE CODE TO FILL PRNT/PNCH FN 15820000
         OI    PNCHSW,X'80'             SET PNCH/PRNT ISSUED SWITCH     15840000
F01      CLI   ABCUSE+2,CHNULL          TEST IF UNDEFINED 'OR' BRANCHES 15860000
         BE    F02                      BRANCH IF NONE                  15880000
         MVC   J14(2),CH02B             MOVE UBA IDENTIFIER TO LINKAGE  15900000
         BAL   BACKRG,UBADEF                                            15920000
F02      TM    LINCTR+2,X'F0'          .DOES NO. OF LINES EXCEED 4096   15940000
         BZ    INLIMT                  .NO                              15960000
         UNPK  96(3,PRTREG),CH237      .ERROR NOTE 237 -TERMINATE       15980000
         BAL   BACKRG,ERROUT           .PRINT OUT ERROR NOTE            16000000
         MVC   PHSNAM(8,CNTREG),DIAGPH .MAKE DIAGNOSTIC NEXT PHASE      16020000
         L     DSPLRG,STOREL           .RELOAD PUNCH BUFFER POINTER     16040000
         LA    SERVRG,PHSCAL           .CALL NEXT PHASE(DIAGN MSG)      16060000
         BR    EXTREG                  .BRANCH TO INTERFACE             16080000
INLIMT   TM    FLDSW,X'01'             .IS THIS FIRST FLD OF A GROUP    16100000
         BO    D07                      NO                              16120000
         NC    COD041+2(2),RESET       .BUILD DISPLACEMENT BITS 20-31   16140000
         OC    COD041+2(2),LINCTR+2    .OF USER CODE                    16160000
         BAL   LR,DMPTXT               .LINK TO PUNCH-CODE ROUTINE      16180000
         DC    AL2(8)                  .DITTO                           16200000
         DC    AL4(COD041)             .DITTO                           16220000
         LA    DSPLRG,8(DSPLRG)        .INCREMENT DISPLACEMENT          16240000
         OI    FLDSW,X'01'             .PREVENT MULTIPLE LINKAGES       16260000
         B     D07                     .LOOP BACK                       16280000
         EJECT                                                          16300000
*        ************************************************************** 16320000
*        * SUBROUTINE -                                               * 16340000
*        * ISSUE CODE FOR MOVING PUNCH/PRINT INFORMATION TO THE IORB. * 16360000
*        ************************************************************** 16380000
*                                                                       16400000
PRNTFN   TM    3(TABREG),X'10'          TEST IF PRINT/PUNCH OR OTHER FL 16420000
         BO    0(BACKRG)                EXIT PRNTFN IF 'OTHER'          16440000
         ST    BACKRG,STOREA            STORE RETURN ADDRESS            16460000
         LH    REG1,22(TABREG)          GET IORB DISPLACEMENT FOR FILE  16480000
         LA    REG1,15(REG1)            ADD ON SKIP BEF/STCK SEL DISPL. 16500000
         STH   REG1,STORED                                              16520000
         NC    COD009+2(2),RESET        PUT SK-BF/ST-SEL DISPL. IN CODE 16540000
         OC    COD009+2(2),STORED       DITTO                           16560000
         TM    3(TABREG),X'40'          TEST IF A PRINT FILE            16580000
         BO    H03                      BRANCH IF YES                   16600000
         LA    BCTREG,5                 LOAD CYCLE COUNT REG WITH 5     16620000
         LA    WORKRG,STCKTB-2          ADDR.OF STACKER TRANSLATE TABLE 16640000
H01      LA    WORKRG,2(WORKRG)         INCREMENT TO NEXT TABLE ENTRY   16660000
         CLC   STOREE(1),0(WORKRG)      CMP SPEC STACKER TO TABLE ENTRY 16680000
         BE    H02                      BRANCH IF EQUAL                 16700000
         BCT   BCTREG,H01               COUNT AND EXIT AT END OF TABLE  16720000
H02      MVC   COD009+1(1),1(WORKRG)    PLACE STACKER SELECT IN CODE    16740000
         BAL   BCTREG,J04                                               16760000
         B     H16                                                      16780000
H03      CLC   STOREE+1(6),BLANK        CHECK IF ANY PRINT FNS GIVEN    16800000
         BNE   H04                      BRANCH IF YES                   16820000
         MVI   STOREE+2,CH1             ASSUME SINGLE SPACE AFTER       16840000
H04      CLC   STOREE+3(2),BLANK        IS THERE A SKIP BEFORE ENTRY    16860000
         BE    H07                      BRANCH IF NO                    16880000
         LA    BCTREG,12                LOAD CYCLE COUNT REGISTER       16900000
         LA    WORKRG,SKIPTB-3          ADDR.OF SKIP TRANSLATE TABLE    16920000
H05      LA    WORKRG,3(WORKRG)         INCREMENT TO NEXT TABLE ENTRY   16940000
         CLC   STOREE+3(2),0(WORKRG)    CMP SPEC SKIP BEF.TO TBLE ENTRY 16960000
         BE    H06                      BRANCH IF EQUAL                 16980000
         BCT   BCTREG,H05               COUNT AND EXIT AT END OF TABLE  17000000
H06      MVC   COD009+1(1),2(WORKRG)    PLACE 'SKIP BEFORE' IN CODE     17020000
         BAL   BCTREG,J04                                               17040000
H07      LA    REG1,1(REG1)             ADD DISPL. TO 'SPACE BEFORE'    17060000
         CLI   STOREE+1,SPACE           IS THERE A 'SPACE BEFORE' ENTRY 17080000
         BE    H10                      BRANCH IF NO                    17100000
         CLI   STOREE+1,CH0             IS IT ZERO SPACE BEFORE         17120000
         BE    H10                      BRANCH IF YES                   17140000
         STH   REG1,STORED                                              17160000
         NC    COD009+2(2),RESET        PUT SPACE BEF. DISPL. IN CODE   17180000
         OC    COD009+2(2),STORED       DITTO                           17200000
         LA    BCTREG,4                 LOAD CYCLE COUNT REGISTER       17220000
         LA    WORKRG,SPCETB-2          ADDR.OF SPACE TRANSLATE TABLE   17240000
H08      LA    WORKRG,2(WORKRG)         INCREMENT TO NEXT TABLE ENTRY   17260000
         CLC   STOREE+1(1),0(WORKRG)    CMP SPEC SPACE BEF.TO TBL ENTRY 17280000
         BE    H09                      BRANCH IF EQUAL                 17300000
         BCT   BCTREG,H08               COUNT AND EXIT AT END OF TABLE  17320000
H09      MVC   COD009+1(1),1(WORKRG)    PLACE 'SPACE BEFORE' IN CODE    17340000
         BAL   BCTREG,J04                                               17360000
*                                                                       17380000
*                                       (CONTINUED NEXT PAGE)           17400000
         EJECT                                                          17420000
H10      LA    REG1,1(REG1)             ADD DISPL. TO 'SKIP AFTER'      17440000
         CLC   STOREE+5(2),BLANK        IS THERE A 'SKIP AFTER' ENTRY   17460000
         BE    H13                      BRANCH IF NO                    17480000
         STH   REG1,STORED                                              17500000
         NC    COD009+2(2),RESET        PUT SKIP AFTER DISPL. IN CODE   17520000
         OC    COD009+2(2),STORED       DITTO                           17540000
         LA    BCTREG,12                LOAD CYCLE COUNT REGISTER       17560000
         LA    WORKRG,SKIPTB-3          ADDR. OF SKIP TRANSLATE TABLE   17580000
H11      LA    WORKRG,3(WORKRG)         INCREMENT TO NEXT TABLE ENTRY   17600000
         CLC   STOREE+5(2),0(WORKRG)    CMP SPEC SKIP AFT.TO TBLE ENTRY 17620000
         BE    H12                      BRANCH IF EQUAL                 17640000
         BCT   BCTREG,H11               COUNT AND EXIT AT END OF TABLE  17660000
H12      MVC   COD009+1(1),2(WORKRG)    PLACE 'SKIP AFTER' IN CODE      17680000
         BAL   BCTREG,J04                                               17700000
H13      LA    REG1,1(REG1)             ADD DISPL. TO 'SPACE AFTER'     17720000
         CLI   STOREE+2,SPACE           IS THERE A 'SPACE AFTER' ENTRY  17740000
         BE    H16                      BRANCH IF NO                    17760000
         STH   REG1,STORED                                              17780000
         NC    COD009+2(2),RESET        PUT SPACE AFTER DISPL. IN CODE  17800000
         OC    COD009+2(2),STORED       DITTO                           17820000
         LA    BCTREG,4                 LOAD CYCLE COUNT REGISTER       17840000
         LA    WORKRG,SPCETB-2          ADDR. OF SPACE TRANSLATE TABLE  17860000
H14      LA    WORKRG,2(WORKRG)         INCREMENT TO NEXT TABLE ENTRY   17880000
         CLC   STOREE+2(1),0(WORKRG)    CMP SPEC SPACE AFT.TO TBL ENTRY 17900000
         BE    H15                      BRANCH IF EQUAL                 17920000
         BCT   BCTREG,H14               COUNT AND EXIT AT END OF TABLE  17940000
H15      MVC   COD009+1(1),1(WORKRG)    PLACE 'SPACE AFTER' IN CODE     17960000
         BAL   BCTREG,J04                                               17980000
H16      L     BACKRG,STOREA            RELOAD RETURN ADDRESS           18000000
         BR    BACKRG                   RETURN                          18020000
*                                                                       18040000
         EJECT                                                          18060000
*        ************************************************************** 18080000
*        * LINK AND PUNCH SUBROUTINE.                                 * 18100000
*        * 1.OUTPUTS V-TYPE LINKAGE RECORD ON RLD WKFL.FOR EACH BLOCK.* 18120000
*        * 2.ISSUES FIRST OBJECT CODE OF BLOCK.                       * 18140000
*        ************************************************************** 18160000
*                                                                       18180000
LINKPN   MVC   RLDRCD+3(4),ADDCNT(CNTREG)    MOVE ADDRESS TO RLD ENTRY  18200000
         ST    BACKRG,STOREA            STORE RETURN ADDRESS            18220000
         LA    REG1,RLDRCD              OUTPUT LINKAGE ON RLD WORKFILE  18240000
         LA    SERVRG,RLDOUT            DITTO                           18260000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   18280000
         L     BACKRG,STOREA            RELOAD RETURN ADDRESS           18300000
         BAL   LR,DMPTX1                LINK TO PUNCH-CODE ROUTINE      18320000
         DC    AL2(36)                  DITTO                           18340000
         DC    AL4(COD001)                                              18360000
         L     INCREG,ADDCNT(CNTREG)    INCREMENT THE ADDRESS COUNTER   18380000
         LA    INCREG,36(INCREG)        DITTO                           18400000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           18420000
         BR    BACKRG                   RETURN                          18440000
         SPACE 5                                                        18460000
*        ************************************************************** 18480000
*        * SUBROUTINES -                                              * 18500000
*        * COMMON LINKAGES TO PUNCH-CODE ROUTINE (DMPTXT).            * 18520000
*        ************************************************************** 18540000
J01      BALR  LR,ER                                                    18560000
         DC    AL2(2)                                              000B 18580016
         DC    AL4(COD003)                                              18600000
         LH    DSPLRG,CH00B            LOAD DISPLACEMENT           000B 18620016
         OI    BALRSW,X'10'             SET SWITCH ON - BALR ISSUED     18640000
* FOLLOWING CODE ELININATES THE CLI CODE FOR L0 IN OUTPUT SPECS    000B 18648016
J02      CLI   COD004+1,X'00'          IF CODE IS TO TEST FOR 'NOT'000B 18656016
         BE    J0A                       THEN CONTINUE TO GEN CODE.000B 18664016
         CLC   COD004+2(2),LOADD       CHK FOR L0 ADDRESS (OFFSETN 000B 18672016
         BCR   8,BACKRG                IF L0 INDICATED, RETURN     000B 18680016
J0A      BALR  LR,ER                   OTHERWISE, GENERATE CLI CODE000B 18688016
         DC    AL2(8)                                                   18700000
         DC    AL4(COD004)                                              18720000
         LA    DSPLRG,8(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 18740000
J03      IC    WORKRG,ABCUSE+4          INCREMENT UBA COUNTER NUMBER 4  18760000
         LA    WORKRG,1(WORKRG)         DITTO                           18780000
         STC   WORKRG,ABCUSE+4          DITTO                           18800000
         BR    BACKRG                                                   18820000
*                                                                       18840000
J04      BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      18860000
         DC    AL2(4)                                                   18880000
         DC    AL4(COD009)                                              18900000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 18920000
         BR    BCTREG                                                   18940000
LOADD    DC    X'307A'                 BDDD REP OF L0 ADDRESS      000B 18946016
         DS    0F                                                  000B 18952016
*                                                                       18960000
         EJECT                                                          18980000
*        ************************************************************** 19000000
*        * SUBROUTINE -                                               * 19020000
*        * SET UP AND ISSUE USER CODE FOR LINKING TO INTERCEPT ROUTNE * 19040000
*        ************************************************************** 19060000
*                                                                       19080000
SETCOD   LH    REG1,22(TABREG)          GET IORB DISPLACEMENT FOR FILE  19100000
         STH   REG1,STORED              DITTO                           19120000
         NC    COD010+10(2),RESET       PUT DISPLACEMENT INTO USER-CODE 19140000
         OC    COD010+10(2),STORED      DITTO                           19160000
         LA    REG1,8(REG1)             ADD ON RCD LENGTH ENTRY DISPL.  19180000
         STH   REG1,STORED                                              19200000
         NC    COD010+2(2),RESET        PUT RCD LNGTH DISP.IN USER-CODE 19220000
         OC    COD010+2(2),STORED       DITTO                           19240000
         LA    REG1,6(REG1)             ADD ON ACTION BYTE ENTRY DISPL. 19260000
         STH   REG1,STORED                                              19280000
         NC    COD010+6(2),RESET        PUT ACTION B. DISP.IN USER-CODE 19300000
         OC    COD010+6(2),STORED       DITTO                           19320000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      19340000
         DC    AL2(14)                                                  19360000
         DC    AL4(COD010)                                              19380000
         LA    DSPLRG,14(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 19400000
         BR    BACKRG                   RETURN                          19420000
         SPACE 5                                                        19440000
*        ************************************************************** 19460000
*        * SUBROUTINE - PUT OVERFLOW-SWITCH ON/OFF FROM X-SWITCH.     * 19480000
*        ************************************************************** 19500000
*                                                                       19520000
OVFSET   TM    3(TABREG),X'40'          TEST IF PRINT FILE              19540000
         BZ    0(0,BACKRG)              BRANCH IF NO                    19560000
         CLI   17(TABREG),SPACE         TEST FOR AN OVERFLOW INDICATOR  19580000
         BE    0(0,BACKRG)              BRANCH IF NONE                  19600000
         LH    REG1,22(TABREG)          GET IORB DISPLACEMENT FOR FILE  19620000
         LA    REG1,19(REG1)            ADD ON X-SWITCH DISPLACEMENT    19640000
         STH   REG1,STORED                                              19660000
         NC    COD007+4(2),RESET        PUT X-SW. DISPL. INTO USER-CODE 19680000
         OC    COD007+4(2),STORED       DITTO                           19700000
         MVC   COD007+3(1),17(TABREG)   PUT OVFL-SW.DISP.INTO USE  I222 19720018
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      19740000
         DC    AL2(6)                                                   19760000
         DC    AL4(COD007)                                              19780000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 19800000
         BR    BACKRG                   RETURN                          19820000
*                                                                       19840000
         EJECT                                                          19860000
*        ************************************************************** 19880000
*        * LINKAGE TO UBA DEFINING SUBROUTINE                         * 19900000
*        ************************************************************** 19920000
*                                                                       19940000
UBADEF   STH   DSPLRG,J15               ADDRESS FOR UNDEF BRANCH ADDR   19960000
         OI    J15,X'80'                INSERT BASE REGISTER 8          19980000
         BAL   LR,ADRDEF                LINK TO UBA DEFINING SUBROUTINE 20000000
J14      DS    CL2                                                      20020000
J15      DS    CL2                                                      20040000
         BR    BACKRG                   RETURN                          20060000
         SPACE 5                                                        20080000
*        ************************************************************** 20100000
*        * SUBROUTINE.                                                * 20120000
*        * LINK TO RPG CIOEX TO PRINT OUT ERROR NOTE                  * 20140000
*        ************************************************************** 20160000
*                                                                       20180000
*                                                                       20200000
ERROUT   ST    BACKRG,STOREA            STORE RETURN ADDRESS            20220000
         LA    SERVRG,PNTERR            PRINT OUT ERROR NOTE            20240000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   20260000
         L     BACKRG,STOREA            RELOAD RETURN ADDRESS           20280000
         BR    BACKRG                   RETURN                          20300000
*                                                                       20320000
         EJECT                                                          20340000
*        ************************************************************** 20360000
*        * END OF PASS 2 (TOTAL LINE, NOT CONDITIONED BY OVERFLOW).   * 20380000
*        * ISSUE CODE FOR TESTING OVERFLOW SWITCHES FOR PRINT FILES.  * 20400000
*        ************************************************************** 20420000
*                                                                       20440000
END2     BAL   LR,DMPTX1                LINK TO PUNCH-CODE ROUTINE      20460000
         DC    AL2(6)                                                   20480000
         DC    AL4(COD008)                                              20500000
         L     INCREG,ADDCNT(CNTREG)    INCREMENT THE ADDRESS COUNTER   20520000
         LA    INCREG,6(INCREG)         DITTO                           20540000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           20560000
         MVC   RLDRCD+1(2),LVDOFL       OVFLW LN.VECT.DISP.TO RLD ENTRY 20580000
         BAL   BACKRG,LINKPN            BRANCH TO LINK AND PUNCH SUBRTN 20600000
         BAL   LR,DMPTX1                LINK TO PUNCH-CODE ROUTINE      20620000
         DC    AL2(58)                                                  20640000
         DC    AL4(COD011)                                              20660000
         LA    INCREG,58(INCREG)        INCREMENT THE ADDRESS COUNTER   20680000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           20700000
         B     DOAGN                     GO FOR NEXT PASS               20720000
*                                                                       20740000
         EJECT                                                          20760000
*        ************************************************************** 20780000
*        * END OF PASS 5 (DETAIL LINE, CONDITIONED BY OVERFLOW).      * 20800000
*        * ISSUE CODE FOR PRINT-FILE AUTOMATIC SKIP TO CHANNEL 01.    * 20820000
*        * ISSUE CODE FOR END OF FIRST OBJECT CODE OUTPUT BLOCK.      * 20840000
*        * UPDATE ADDRESS COUNTER TO INCLUDE LAST CODE BLOCK.         * 20860000
*        ************************************************************** 20880000
*                                                                       20900000
END5     MVC   RLDRCD+1(2),AOFB         OVFL-BYP.VECT.DISP.TO RLD ENTRY 20920000
         MVC   RLDRCD+3(4),ADDCNT(CNTREG)    MOVE ADDRESS TO RLD ENTRY  20940000
         LA    REG1,RLDRCD              OUTPUT VECTOR ON RLD WORKFILE   20960000
         LA    SERVRG,RLDOUT            DITTO                           20980000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   21000000
         LA    ER,DMPTX1                                                21020000
         BALR  LR,ER                    LINK TO PUNCH-CODE ROUTINE      21040000
         DC    AL2(2)                                                   21060000
         DC    AL4(COD003)                                              21080000
         LA    TABREG,FILETB            GET ADDR OF START OF FILE TABLE 21100000
         LA    BCTREG,10                LOAD CYCLE COUNT REG WITH 10    21120000
N04      TM    3(TABREG),X'40'          TEST IF PRINT FILE              21140000
         BZ    N05                      BRANCH IF NO                    21160000
         TM    3(TABREG),X'04'          TEST FOR ANY FILE-LINE COND.OVF 21180000
         BO    N05                      BRANCH IF ANY                   21200000
         LH    REG1,22(TABREG)          GET IORB DISPLACEMENT FOR FILE  21220000
         LA    REG1,19(REG1)            ADD ON X-SWITCH DISPLACEMENT    21240000
         STH   REG1,STORED                                              21260000
         NC    COD021+2(2),RESET        PUT DISPLACEMENT INTO USER-CODE 21280000
         OC    COD021+2(2),STORED       DITTO                           21300000
         BALR  LR,ER                    LINK TO PUNCH-CODE ROUTINE      21320000
         DC    AL2(8)                                                   21340000
         DC    AL4(COD021)                                              21360000
         LA    DSPLRG,8(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 21380000
         MVI   ABCUSE+8,X'01'           INCREMENT UBA COUNTER NUMBER 8  21400000
         MVC   STOREE(7),BLANK          PLACE CHANNEL 01 SKIP IN CODE   21420000
         MVC   STOREE+3(2),SKIPTB       DITTO                           21440000
         ST    BCTREG,STOREG            STORE CYCLE COUNT               21460000
         BAL   BACKRG,PRNTFN            ISSUE CODE TO FILL PRNT/PNCH FN 21480000
         BALR  LR,ER                    LINK TO PUNCH-CODE ROUTINE      21500000
         DC    AL2(4)                                                   21520000
         DC    AL4(COD012)                                              21540000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 21560000
         BAL   BACKRG,SETCOD            LINK TO CODE-SETTING ROUTINE    21580000
         MVC   J14(2),CH08B             MOVE UBA IDENTIFIER TO LINKAGE  21600000
         BAL   BACKRG,UBADEF                                            21620000
         L     BCTREG,STOREG            RELOAD CYCLE COUNT              21640000
N05      LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER        21660000
         BCT   BCTREG,N04                                               21680000
         L     INCREG,ADDCNT(CNTREG)    UPDATE THE ADDRESS COUNTER      21700000
         LA    INCREG,2(DSPLRG,INCREG)  DITTO                           21720000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           21740000
         SR    DSPLRG,DSPLRG            CLEAR DISPLACEMENT REGISTER     21760000
         LA    TABREG,FILETB           THE FOLLOWING               5050 21761016
         LA    BCTREG,10               CODE IS PUT                 5050 21762016
GJM1     TM    3(TABREG),X'40'         OUT TO CORRECT THE          5050 21763016
         BZ    GJM2                    OVERFLOW-OF CONDITION       5050 21764016
         LH    REG1,22(TABREG)         WHICH MIGHT OCCUR DURING    5050 21765016
         LA    REG1,19(REG1)           A DETAIL TO TOTAL           5050 21766016
         STH   REG1,STORED             BRANCH AND SUBSEQUENT       5050 21767016
         NC    COD002+2(2),RESET       LOOPING.                    5050 21768016
         OC    COD002+2(2),STORED      IDENTICAL CODE IS PUT OUT   5050 21769016
         BAL   LR,DMPTX1               TO TURN OFF THE OVERFLOW    5050 21770016
         DC    AL2(4)                  INDICATOR DURING A NORMAL   5050 21771016
         DC    AL4(COD002)             OBJECT  TIME FLOW IN        5050 21772016
         LA    INCREG,4(INCREG)        PROGRAM LOGIC.              5050 21773016
         ST    INCREG,ADDCNT(CNTREG)   THIS PREVENTS BEING CAUGHT  5050 21774016
GJM2     LA    TABREG,24(TABREG)       IN A LOOP WITH THE OVERFLOW 5050 21775016
         BCT   BCTREG,GJM1             INDICATOR ON.               5050 21776016
         BALR  LR,ER                    LINK TO PUNCH-CODE ROUTINE      21780000
         DC    AL2(6)                                                   21800000
         DC    AL4(COD008)                                              21820000
         LA    INCREG,6(INCREG)         INCREMENT ADDRESS COUNTER       21840000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           21860000
         OI    TTOVSW,X'02'             INDIC TOTAL+OV LINES FINISHED   21880000
         SPACE 2                                                        21900000
*        ************************************************************** 21920000
*        * ISSUE CODE FOR FIRST ENTRY INTO 'DETAIL LINE' CODE BLOCK.  * 21940000
*        * 1. WRITE LINKAGE INFORMATION ON RLD WORKFILE               * 21960000
*        * 2. ISSUE CODE TO LOAD + STORE REGISTERS + STORE CONSTANTS. * 21980000
*        * 3. ISSUE CODE TO RESET X-SWITCHES FOR ALL PRINTFILES.      * 22000000
*        ************************************************************** 22020000
*                                                                       22040000
         MVC   RLDRCD+1(2),LVDLIN       DET'L LN VECT.DISP.TO RLD ENTRY 22060000
         BAL   BACKRG,LINKPN            BRANCH TO LINK AND PUNCH SUBRTN 22080000
         LA    TABREG,FILETB            GET ADDR OF START OF FILE TABLE 22100000
         LA    BCTREG,10                LOAD CYCLE COUNT REG WITH 10    22120000
K01      TM    3(TABREG),X'40'          TEST IF PRINT FILE              22140000
         BZ    K02                      BRANCH IF NO                    22160000
         LH    REG1,22(TABREG)          GET IORB DISPLACEMENT FOR FILE  22180000
         LA    REG1,19(REG1)            ADD ON X-SWITCH DISPLACEMENT    22200000
         STH   REG1,STORED                                              22220000
         NC    COD002+2(2),RESET        PUT DISPLACEMENT INTO USER-CODE 22240000
         OC    COD002+2(2),STORED       DITTO                           22260000
         BAL   LR,DMPTX1                LINK TO PUNCH-CODE ROUTINE      22280000
         DC    AL2(4)                                                   22300000
         DC    AL4(COD002)                                              22320000
         LA    INCREG,4(INCREG)         INCREMENT THE ADDRESS COUNTER   22340000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           22360000
K02      LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER        22380000
         BCT   BCTREG,K01               COUNT TBL ENTRIES-EXIT AFTER 10 22400000
         B     DOAGN                    GO REINIT CTR                   22420000
*                                                                       22440000
         EJECT                                                          22460000
*        ************************************************************** 22480000
*        * PUNCH OUT FINAL CODE AND LINK TO NEXT PHASE.               * 22500000
*        ************************************************************** 22520000
*                                                                       22540000
END      BAL   LR,DMPTX1                LINK TO PUNCH-CODE ROUTINE      22560000
         DC    AL2(16)                                                  22580000
         DC    AL4(COD045)                                              22600000
         LA    DSPLRG,16(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 22620000
         LA    TABREG,FILETB            GET ADDR OF START OF FILE TABLE 22640000
         LA    BCTREG,10                LOAD CYCLE COUNT REG WITH 10    22660000
N01      BAL   BACKRG,OVFSET            LINK TO PUNCH COD007            22680000
         LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER        22700000
         BCT   BCTREG,N01               COUNT TBL ENTRIES-EXIT AFTER 10 22720000
         BAL   LR,DMPTX1                LINK TO PUNCH-CODE ROUTINE      22740000
         DC    AL2(6)                                                   22760000
         DC    AL4(COD008)                                              22780000
         L     INCREG,ADDCNT(CNTREG)    UPDATE THE ADDRESS COUNTER      22800000
         LA    INCREG,9(DSPLRG,INCREG) .6 FOR COUNT 3 FOR ALIGNMENT     22820000
         SRL   INCREG,2                .FULL WORD ALIGN                 22840000
         SLL   INCREG,2                .DITTO                           22860000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           22880000
*        ************************************************************** 22900000
*        *     CORE IMMEDIATELY AFTER TRUE FILETB(240BYTES) WILL      * 22920000
*        *     CONTAIN THE STARTING ADDR OF THE TABLE FOR FIELD       * 22940000
*        *     BRANCHES- USED FOR COMMUNICATION BETWEEN ASMBL4 AND 45 * 22960000
*        ************************************************************** 22980000
         MVC   TABADD(4),ADDCNT(CNTREG)  .PLACE TABL START ADDR    I222 23000018
         MVC   RLDRCD+3(4),ADDCNT(CNTREG)   .MOVE ADDR PRIOR TO TABL    23020000
         A     INCREG,LINCT            .TO RLD ENTRY AND BUMP REG BY    23040000
         LA    INCREG,4(INCREG)        .TABLE SIZE                      23060000
         ST    INCREG,ADDCNT(CNTREG)   .DITTO                           23080000
         MVC   RLDRCD+1(2),LVLTB       .VECTOR TO RLD ENTRY             23100000
         LA    REG1,RLDRCD             .OUTPUT LINKAGE ON RLD WORKFILE  23120000
         LA    SERVRG,RLDOUT           .DITTO                           23140000
         BALR  BACKRG,EXTREG           .(LINK TO EXTERNAL SUBROUTINE)   23160000
         L     DSPLRG,STOREL            RELOAD PUNCH BUFFER POINTER     23180000
         BAL   LR,FINTXT                                                23200000
*                                                                       23220000
*                                       (CONTINUED NEXT PAGE)           23240000
         EJECT                                                          23260000
*        ************************************************************** 23280000
*        * INITIALIZE BLKAFT FILE. PASS OVER BLKAFTER RECORDS,IF ANY. * 23300000
*        *     PUT OUT FILE DESCRIPTION TABLE TO BLANK-AFTER FOR      * 23320000
*        *     NEXT PHASE USAGE. RECORD STARTS WITH 'F0' OR '00'.     * 23340000
*        ************************************************************** 23360000
*                                                                       23380000
         LA    SERVRG,PNTBLK           .REINIT BLANKAF WKFL             23400000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   23420000
         CLC   NUMBLK(2,CNTREG),CH00B  .ARE THERE ANY BLANK-AFT ENTRIES 23440000
         BE    REWND                    BRANCH IF NONE                  23460000
         LH    WORKRG,NUMBLK(CNTREG)   .LOAD CYCLE CNT WITH NO. OF BLKS 23480000
PASBLK   LA    REG1,BUFFER             .ADDR OF WASTE AREA              23500000
         LA    SERVRG,BLKIN            .GET NEW BLOCK                   23520000
         ST    WORKRG,STOREC           .SAVE BLOCK COUNT                23540000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   23560000
         L     WORKRG,STOREC           .RECALL BLOCK COUNT              23580000
         BCT   WORKRG,PASBLK                                            23600000
REWND    LA    REG1,FILETB             .PUT OUT 4 RECORDS OF 72 BYTES   23620000
         LA    SERVRG,BLKOUT           .DITTO                           23640000
         BALR  BACKRG,EXTREG           .DITTO                           23660000
         LA    REG1,FILETB+72          .SECOND RECORD                   23680000
         LA    SERVRG,BLKOUT           .DITTO                           23700000
         BALR  BACKRG,EXTREG           .DITTO                           23720000
         LA    REG1,FILETB+144         .THIRD RECORD                    23740000
         LA    SERVRG,BLKOUT           .DITTO                           23760000
         BALR  BACKRG,EXTREG           .DITTO                           23780000
         LA    REG1,FILETB+216         .FOURTH RECORD                   23800000
         LA    SERVRG,BLKOUT           .DITTO                           23820000
         BALR  BACKRG,EXTREG           .DITTO                           23840000
         LA    SERVRG,PHSCAL            CALL NEXT PHASE                 23860000
         BR    EXTREG                                                   23880000
*                                                                       23900000
*                        ***************************                    23920000
*                        * END OF MAIN LINE CODE.  *                    23940000
*                        * EXIT TO THE NEXT PHASE. *                    23960000
*                        ***************************                    23980000
         EJECT                                                          24000000
*        ************************************************************** 24020000
*        *               START OF NEW CONTROL SECTION.                * 24040000
*        ************************************************************** 24060000
*        ************************************************************** 24080000
*                                                                       24100000
ENDCS1   DS    0D                                                       24120000
IES15510 CSECT                                                          24140000
CNTRL2   EQU   *                                                        24160000
*        ************************************************************** 24180000
         SPACE 5                                                        24200000
*        ************************************************************** 24220000
*        * CHECK IF ENOUGH ROOM IN CODE BUFFER FOR NEXT BLOCK OF CODE.* 24240000
*        * IF NOT, REMOVE UNDEFINED BR.ADDR.WHICH IS BLOCKING OUTPUT. * 24260000
*        ************************************************************** 24280000
*                                                                       24300000
DMPTXT   STM   12,13,STOREM             SAVE CONTENTS OF REGISTERS      24320000
J10      LH    12,0(LR)                 DETERMINE 'NEW CODE' LENGTH +8  24340000
         AH    12,CH08B                 DITTO                           24360000
         CL    12,SOOM                  COMPARE LNGTH TO ROOM IN BUFFER 24380000
         BNH   J11                      BRANCH TO PUNCH CODE IF ROOM    24400000
         MVC   COD006+6(2),ABCWAY       MOVE UBA IDENTIFIER TO FWD BR   24420000
         MVC   J12(2),ABCWAY            MOVE UBA IDENTIFIER TO LINKAGE  24440000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 24460000
         STH   DSPLRG,J13               ADDRESS FOR UNDEF BRANCH ADDR   24480000
         OI    J13,X'80'                INSERT BASE REGISTER 8          24500000
         LR    12,LR                    SAVE RETURN ADDRESS             24520000
         BAL   LR,ADRDEF                LINK TO UBA DEFINING SUBROUTINE 24540000
J12      DS    CL2                                                      24560000
J13      DS    CL2                                                      24580000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 24600000
         STH   DSPLRG,COD006+2          PUT ADDRESS IN BRANCH           24620000
         OI    COD006+2,X'80'           INSERT BASE REGISTER 8          24640000
         BAL   LR,DMPTX1                LINK TO TEXT-PUNCHING SUBROUTNE 24660000
         DC    AL2(8)                                                   24680000
         DC    AL4(COD006)                                              24700000
         LR    LR,12                    RESTORE RETURN ADDRESS          24720000
         LH    12,COD006+6              INCREMENT PROPER UBA COUNTER    24740000
         LA    13,ABCUSE                DITTO                           24760000
         AR    13,12                    DITTO                           24780000
         MVI   0(13),X'01'              DITTO                           24800000
         B     J10                      RECHECK BUFFER ROOM             24820000
*                                                                       24840000
J11      LM    12,13,STOREM             RESTORE REGISTERS               24860000
*                                                                       24880000
         EJECT                                                          24900000
*        ************************************************************** 24920000
*        * SUBROUTINE FOR PUNCHING TEXT CARDS AND FILLING IN UNDEFINED* 24940000
*        * BRANCH ADDR. STORES CODE IN BUFFER TILL 56 BYTES AVAILABLE.* 24960000
*        ************************************************************** 24980000
*                                                                       25000000
DMPTX1   MVC   LENGTH(6),0(GR14) MOVE THE CALLING SEQUENCE.             25020000
         LA    GR14,6(GR14)   BUMP REGISTER OVER CALLING SEQ.           25040000
         STM   0,15,ARGSAV    SAVE ALL REGISTERS PRIOR TO ENTRY .       25060000
         L     DMPRG1,PTR1    POINTS TO THE FIRST AVAILABLE BYTE IN     25080000
         LH    DMPRG2,LENGTH  THE TEXT BUFFER.HAS THE LENGTH OF THE     25100000
         L     DMPRG3,DMPADD  SEGMENT TO BE ADDED,AND ITS ADDRESS.      25120000
         BAL   DMPRG0,DMPSUB   GO AND MOVE THE SEGMENT TO THE BUFFER.   25140000
         LA    DMPRG1,1(DMPRG1,DMPRG2) SET THE POINTER TO THE           25160000
         ST    DMPRG1,PTR1    FIRST AVAILABLE BYTE IN THE BUFFER.       25180000
         MVI   DMPFLG,X'FF'   SET HE FLAG TO SEARCH OUT THE UBA'S.      25200000
         B     ADR1                                                     25220000
DMPSUB   LA    DMPRG4,256      MOVE ALL THE MULTIPLES OF 256 BYTES      25240000
DMPSUB1  SR    DMPRG2,DMPRG4  FIRST,THEN THE REMAINDER                  25260000
         BC    12,DMPSUB2                                               25280000
         MVC   0(256,DMPRG1),0(DMPRG3)                                  25300000
         AR    DMPRG3,DMPRG4                                            25320000
         BXH   DMPRG1,DMPRG4,DMPSUB1                                    25340000
DMPSUB2  LA    DMPRG2,255(DMPRG2)                                       25360000
         EX    DMPRG2,DMPSUB3 NOW MOVE THE REMAINDER .                  25380000
         BR    DMPRG0                                                   25400000
DMPSUB3  MVC   0(0,DMPRG1),0(DMPRG3)                                    25420000
ADRDEF   MVC   DMPADD(4),0(GR14) MOVE THE CALLING SEQUENCE AF THIS CALL 25440000
         LA    GR14,4(GR14)   AND SET RETURN REGISTER.                  25460000
         STM   0,15,ARGSAV                                              25480000
         LH    DMPRG3,BDDDDFN HAS ADDRESS DEFIN. FOR THIS UBA.          25500000
         MVI   DMPFLG,X'0'    SET SWITCH THAT WE ARE DEFINING UBA'S.    25520000
ADR1     L     DMPRG1,PTRUBA  POINTS TO THE FIRST UBA FOUND IN LAST     25540000
         SR    DMPRG2,DMPRG2  CALL.                                     25560000
         XC    PTRUBA(12),PTRUBA CLEAR UBA POINTERS,AND SAVE AS FIRST   25580000
         MVC   PTRUBA(4),PTR1 UBA POINTER THE NEXT AVAIL.BYTE IN CASE  125600000
                              NO UBA'S ARE FOUND.                       25620000
         LA    DMPRG1,0(DMPRG1) BLANK OUT A POSSIBLE UBA FLAG.          25640000
ADR2     C     DMPRG1,PTR1    HAVE WE SEARCHED THROUGH THE BUFFER.      25660000
         BNL   ADRA           YES ,PUNCH AS MUCH AS POSSIBLE            25680000
         CLI   0(DMPRG1),X'47' IS THIS OPERATION A' 'BRANCH'            25700000
         BE    ADR4           YES,GO SEE WHETHER IT IS A U.B.A.         25720000
         TM    0(DMPRG1),X'B0' IF NOT,IS THIS A SEGMENT OF DATA         25740000
         BC    12,ADR8        NO.                                       25760000
         IC    DMPRG2,1(DMPRG1) PICK UP THE COUNT.                      25780000
         LTR   DMPRG2,DMPRG2    IS IT ZERO,                             25800000
         BC    7,ADR3         SKIP IF NOT,ELSE UPDATE POINTER OVER 256  25820000
         LA    DMPRG1,256(DMPRG1) BYTES OF DATA.                        25840000
ADR3     AR    DMPRG1,DMPRG2  AND ADD LENGTH OF THE DATA SEGMENT.       25860000
         B     ADR2                                                     25880000
*                                                                       25900000
*                                       (CONTINUED NEXT PAGE)           25920000
         EJECT                                                          25940000
ADR4     TM    2(DMPRG1),X'F0' IS THIS BRANCH A U.B.A.                  25960000
         BC    5,ADR8         SKIP IF NOT.                              25980000
         CLI   DMPFLG,X'FF'   ARE WE DEFINING A UBA.                    26000000
         BE    ADR5           NO.                                       26020000
         CLC   IDNO(1),3(DMPRG1) IF SO DO WE DEFINE THIS UBA.           26040000
         BNE   ADR5           SKIP IF NOT.                              26060000
         STH   DMPRG3,2(DMPRG1) ELSE DEFINE THE UBA AND                 26080000
         LA    W1,ABCUSE                RESET UBA COUNTER               26100000
         SR    3,3                      ZERO COMPRESSION REG            26120000
         IC    RUSE,IDNO                DITTO                           26140000
         AR    W1,RUSE                  DITTO                           26160000
         MVI   0(W1),X'00'              DITTO                           26180000
         B     ADR8           GO TO UPDATE POINTER.                     26200000
ADR5     LA    DMPRG4,PTRUBA                                            26220000
         LA    DMPRG2,3                                                 26240000
ADR6     CLC   0(1,DMPRG4),3(DMPRG1) HAS THIS UBA BEEN POSTED.          26260000
         BE    ADR8           YES,ELSE                                  26280000
         CLI   0(DMPRG4),X'0' IS THIS STILL BLANK,                      26300000
         BNE   ADR7                                                     26320000
         ST    DMPRG1,0(DMPRG4) ELSE SAVE THE POINTER                   26340000
         MVC   0(1,DMPRG4),3(DMPRG1) AND THE FLAG.                      26360000
         B     ADR8                                                     26380000
ADR7     LA    DMPRG4,4(DMPRG4) POINT TO NEXT UBA POINTER               26400000
         BCT   DMPRG2,ADR6    POST ONLY 3 DIFFERENT UBA TYPES.          26420000
ADR8     TM    0(DMPRG1),X'C0' TEST FOR INSTRUCTION LENGTH.             26440000
         LA    DMPRG1,2(DMPRG1) ADD 2 FOR  INSTRUCTION OF LENGTH 2      26460000
         BZ    ADR2           CONTINUE                                  26480000
         LA    DMPRG1,2(DMPRG1) ADD 2 MORE FOR LENGTH 4.                26500000
         BM    ADR2           CONTINUE                                  26520000
         LA    DMPRG1,2(DMPRG1) ADD 2 MORE FOR LENGTH 6                 26540000
         B     ADR2           CONTINUE                                  26560000
ADRA     CLC   BUFFRP56+1(3),PTRUBA+1 DO WE HAVE 56 BYTES IN THE        26580000
         BNH   PUSHUP         BUFFER WITHOUT A UBA,IF NOT RETURN.       26600000
DMPTXTRN MVI   CDLEN+1,56     RESTORE CARD LENGTH OF TEXT OUTPUT.       26620000
         S     DMPRG1,BUFTOP  COMPUTE THE NUMBER OF BYTES REMAINING     26640000
         LCR   DMPRG1,DMPRG1  IN THE TEXT BUFFER.                       26660000
         ST    DMPRG1,SOOM                                              26680000
         LM    0,15,ARGSAV    RESTORE ALL REGISTERS TO RETURN.          26700000
         BR    GR14      AND RETURN TO CALLER.                          26720000
*                                                                       26740000
*                                       (CONTINUED NEXT PAGE)           26760000
         EJECT                                                          26780000
PUSHUP   EQU   *                                                        26800000
         L     DSPLRG,STOREL            RELOAD PUNCH BUFFER POINTER     26820000
         MVC   0(72,4),PFX     MOVE THE CARD PREFIX TO CIOEX PUNCH      26840000
         MVI   4(4),C' '      BUFFER AND BLANK THE FIRST BYTE OF THE    26860000
         LA    2,12           LOAD ADDRESS TO CONFORM TO TEXT NORM.     26880000
         BALR  5,7            LINK TO PUNCH ROUTINE IN CIOEX.           26900000
         LA    DMPRG1,BUFFER   NOW MOVE THE DUMP TEXT BUFFER UP         26920000
         LCR   DMPRG2,DMPRG1  56 BYTES OVERLAYING THE TEXT JUST PUT     26940000
         A     DMPRG2,PTR1    OUT VIA THE CIOEX CALL.                   26960000
         LA    DMPRG3,56(DMPRG1)                                        26980000
         BAL   DMPRG0,DMPSUB                                            27000000
         LA    DMPRG3,PTRUBA  UPDATE ALL UBA POINTERS AS WELL AS        27020000
         LA    DMPRG2,4       THE POINTER TO THE NEXT AVAILABLE BYTE    27040000
PSH1     L     DMPRG1,0(DMPRG3) IN THE DMPTXT BUFFER TO REFLECT THE     27060000
         SH    DMPRG1,CDLEN   LENGTH OF THE CARD PUNCHED OUT.           27080000
         ST    DMPRG1,0(DMPRG3)                                         27100000
         LA    DMPRG3,4(DMPRG3)                                         27120000
         BCT   DMPRG2,PSH1    SIMILARLY ADJUST THE LOAD LOCATION        27140000
         L     DMPRG2,LODLOC  COUNTER TO REFLECT THE TEXT CARD PUT      27160000
         AH    DMPRG2,CDLEN   OUT.                                      27180000
         ST    DMPRG2,LODLOC  THEN GO TO SEE WHETHER WE CANNOT          27200000
         B     ADRA           PUT OUT ANOTHER CARD.                     27220000
FINTXT   STM   0,15,ARGSAV    SAVE ALL REGISTERS PRIOR TO ENTRY .       27240000
         L     DMPRG3,PTR1    FILL WITH BLANKS THE REMAINDER            27260000
         LA    DMPRG2,BUFFER+54   OF THIS INCOMPLETE TEXT CARD          27280000
         SR    DMPRG2,DMPRG3  TO PREPARE IT FOR PUNCHING.               27300000
         LA    DMPRG1,1(DMPRG3)                                         27320000
         MVI   0(DMPRG3),C' '                                           27340000
         EX    DMPRG2,DMPSUB3                                           27360000
         LA    DMPRG1,BUFFER   NOW COMPUTE THE LENGTH OF THIS TEXT CARD 27380000
         SR    DMPRG3,DMPRG1  FOR OUTPUT.                               27400000
         BC    12,DMPTXTRN    RETURN DIRECTLY IF THE LENGTH.LE.ZERO.    27420000
         STC   DMPRG3,CDLEN+1                                           27440000
         B     PUSHUP                                                   27460000
*                                                                       27480000
         EJECT                                                          27500000
*        ************************************************************** 27520000
*        * CONSTANTS, STORAGES, INDICATORS, ETC. USED IN DMPTXT.      * 27540000
*        ************************************************************** 27560000
*                                                                       27580000
         CNOP  2,4                      ALIGN TO A HALF WORD            27600000
         DC    X'00'                    WASTE BYTE FOR ALIGNMENT        27620000
ABCWAY   DC    X'00'                    ABC OF BRANCH HOLDING UP PUNCH. 27640000
PTRUBA   DC    A(BUFFER,0,0,BUFFER)     HOLDS THE POINTERS TO THE FIRST127660000
                              UNIQUE OCCURRENCE OF UBA'S IN THE BUFFER. 27680000
PTR1     EQU   PTRUBA+12      POINTER TO THE NEXT AVAILABLE BYTE IN THE127700000
                              DMPTXT BUFFER.                            27720000
BUFFRP56 DC    A(BUFFER+56)                                             27740000
DMPAREA  DC    2F'0'          SCRATCH AREA FOR DMPTXT.                  27760000
DMPFLG   EQU   DMPAREA+1      CONTAINS ADDRESS DEFINITION SWITCH.       27780000
LENGTH   EQU   DMPAREA+2      LENGTH OF SEGMENT TO ADD.                 27800000
DMPADD   EQU   DMPAREA+4      ADDRESS OF FIRST BYTE TO BE ADDED.        27820000
IDNO     EQU   DMPAREA+5      ID NUMBER OF U.B.A TO BE DEFINED.         27840000
BDDDDFN  EQU   DMPAREA+6      'BDDD' DEFINITION FOR THIS U.B.A..        27860000
BUFTOP   DC    A(FIN)                   TOP OF BUFFER (HIGH VALUE ADDR) 27880000
SOOM     DC    A(FIN-BUFFER+1)          REMAINING BYTES IN TEXT BUFFER  27900000
ABCUSE   DC    XL10'0'                  COUNTS OF UBA USAGE             27920000
*                                                                       27940000
         EJECT                                                          27960000
*        ************************************************************** 27980000
*        * SWITCHES AND INDICATORS                                    * 28000000
*        ************************************************************** 28020000
*                                                                       28040000
SWTCH1   DC    X'00'                    GENERAL SWITCH NO. 1            28060000
FLDSW    EQU   SWTCH1                   XXXX  XXX1   SUPPRESS FLD LINK  28080000
TTOVSW   EQU   SWTCH1                   XXXX  XX1X   PASS 5 FINISHED    28100000
PROCSW   EQU   SWTCH1                   XXXX  X1XX   PRSENT LINE STARTD 28120000
BALRSW   EQU   SWTCH1                   XXX1  XXXX   BALR ISSUED        28140000
LINESW   EQU   SWTCH1                   XX1X  XXXX   PRVIOUS LINE BUILT 28160000
ANDSW    EQU   SWTCH1                   X1XX  XXXX   PROCESS 'AND' SPEC 28180000
PNCHSW   EQU   SWTCH1                   1XXX  XXXX   PNCH/PRNT ISSUED   28200000
*                                                                       28220000
*                                                                       28240000
SWTCH2   DC    X'00'                   .GENERAL SWITCH NO. 2            28260000
PAS2SW   EQU   SWTCH2                  .XXXX  XX1X  INDIC PASS 2 COMPLT 28280000
DEFSW    DC    X'00'                   KEY DEFINITION SW - INIT O  I222 28286018
WORK     DC    X'00'                    WORK AREA                  I222 28292018
*                                                                       28300000
         SPACE 5                                                        28320000
*        ************************************************************** 28340000
*        * PACKED NUMBERS FOR ERROR NOTES -                           * 28360000
*        ************************************************************** 28380000
*                                                                       28400000
CH155    DC    X'155F'                                             I222 28403018
CH156    DC    X'156F'                                             I222 28406018
CH206    DC    X'206F'                                             I222 28409018
CH208    DC    X'208F'                                             I222 28412018
CH209    DC    X'209F'                                             I222 28415018
CH220    DC    X'220F'                                                  28420000
CH221    DC    X'221F'                                                  28440000
CH222    DC    X'222F'                                                  28460000
CH223    DC    X'223F'                                                  28480000
CH224    DC    X'224F'                                                  28500000
CH225    DC    X'225F'                                                  28520000
CH226    DC    X'226F'                                                  28540000
CH237    DC    X'237F'                                                  28560000
*                                                                       28580000
         EJECT                                                          28600000
*        ************************************************************** 28620000
*        * CONSTANTS                                                  * 28640000
*        ************************************************************** 28660000
*                                                                       28680000
CH01B    DC    1F'1'                                                    28700000
CH00B    DC    1H'0000'                                                 28720000
CH02B    DC    1H'0002'                                                 28740000
CH04B    DC    1H'0004'                                                 28760000
CH08B    DC    1H'0008'                                                 28780000
NEG4     DC    1H'-4'                   FOR LINCTR INITIALIZATION       28800000
BLANK    DC    C'            '                                          28820000
EDTSEQ   DC    X'4020202021202020'                                      28840000
SEQNO    DC    PL4'+0'                                                  28860000
PK1      DC    PL1'+1'                                                  28880000
PK32     DC    PL2'+32'                                                 28900000
RESET    DC    X'F000'                                                  28920000
NEXTPH   DC    C'RPG10160'              NAME OF NEXT PHASE              28940000
DIAGPH   DC    C'RPG10190'              DIAG PHASE USED IF NO OUT SPECS 28960000
         SPACE 3                                                        28980000
*        ************************************************************** 29000000
*        * LINKAGE VECTOR DISPLACEMENTS.                              * 29020000
*        ************************************************************** 29040000
*                                                                       29060000
LVDLIN   DC    AL2(192)                 DISP.TO DET'L LINE LINKAGE VECT 29080000
LVTLIN   DC    AL2(196)                 DISP.TO TOTAL LINE LINKAGE VECT 29100000
AOFB     DC    AL2(252)                 DISP.TO OVF.BYPASS LINKAGE VECT 29120000
LVLTB    DC    AL2(268)                .DISPL TO TABLE OF FIELD BR ADRS 29140000
LVDOFL   DC    AL2(276)                 DISP.TO OVFLW LINE LINKAGE VECT 29160000
*                                                                       29180000
         EJECT                                                          29200000
*        ************************************************************** 29220000
*        * BUFFER AREA FOR BUILDING RLD WORKFILE ENTRY FOR LINKAGE    * 29240000
*        ************************************************************** 29260000
*                                                                       29280000
RLDRCD   DC    C'V'                                                     29300000
         DS    CL6                                                      29320000
         DC    X'FD'                                                    29340000
*                                                                       29360000
         SPACE 2                                                        29380000
*        ************************************************************** 29400000
*        * PRINT AND PUNCH CONTROL CHARACTER TRANSLATION TABLES.      * 29420000
*        ************************************************************** 29440000
*                                                                       29460000
STCKTB   DC    X'4001F101F202F402F303'  STACKER TRANSLATE TABLE         29480000
*                                                                       29500000
SPCETB   DC    X'F000F101F202F303'      SPACE TRANSLATE TABLE           29520000
*                                                                       29540000
SKIPTB   DC    X'F0F101F0F202'          SKIP TRANSLATE TABLE            29560000
         DC    X'F0F303F0F404F0F505F0F606F0F707'                        29580000
         DC    X'F0F808F0F909F1F00AF1F10BF1F20C'                        29600000
*                                                                       29620000
         SPACE 2                                                        29640000
*        ************************************************************** 29660000
*        * STORAGE AREAS                                              * 29680000
*        ************************************************************** 29700000
*                                                                       29720000
ARGSAV   DS    16F                      SAVE AREA FOR ALL REGISTERS     29740000
LINCTR   DC    F'0'                    .TEMP PASS TO PASS CTR           29760000
LINCT    DC    F'0'                    .LINE COUNT                      29780000
STOREC   DC    F'0'                     PASS NUMBER INDICATOR STORAGE   29800000
STOREA   DS    1F                       STORE RETURN ADDRESS FOR SUBRTN 29820000
STOREB   DS    1D                       PRESENT FILENAME STORAGE        29840000
STOREM   DS    1D                       STORE REG. DURING BUFFER CHECK  29860000
STOREG   DS    1F                       STORE REGISTER DURING SUBROUTNE 29880000
STOREL   DS    1F                       STORE POINTER TO PUNCH BUFFER   29900000
STORED   DS    1H                       FOR TEMPORARY WORK STORAGE      29920000
STOREE   DS    CL7                      PRESENT PUNCH-PRINT FN STORAGE  29940000
LFSEQ    DS    CL3                      LAST FILE SEQ NUMBER       I222 29946018
LFNAM    DS    CL8                      LAST FILE NAME             I222 29952018
*                                                                       29960000
         EJECT                                                          29980000
*        ************************************************************** 30000000
*        * CODED ROUTINES FOR OUTPUT AS MACHINE-LANGUAGE PROGRAM      * 30020000
*        ************************************************************** 30040000
*                                                                       30060000
COD001   L     IORBBS,LVIORB(0,DATBS1)                                  30080000
         L     AREABS,LVWORK(0,DATBS1)  LOAD R10 WITH ADDR.OF WORK AREA 30100000
         STM   LINKBS,RTRNRG,0(AREABS)  STORE REG'S FOR LINKAGE PHASE   30120000
         MVI   13(AREABS),X'1C'         STORE PACKED ONE IN WORK AREA   30140000
         MVI   14(AREABS),C' '          STORE BLANK IN WORK AREA        30160000
         MVI   15(AREABS),C' '          STORE BLANK IN WORK AREA        30180000
         MVI   101(AREABS),C' '         STORE BLANK IN WORK AREA(STERL) 30200000
         L     13,LVIOI(0,DATBS1)       LD R13 WITH ADDR.OF INTRCPT RTN 30220000
         L     12,LVLNTB(3)                                             30240000
COD002   MVI   0(IORBBS),X'00'          SET OFF FILE X-SWITCH           30260000
COD003   BALR  8,0                                                      30280000
COD004   CLI   0(0),X'FF'               TEST RI CONDITIONING RECORD     30300000
         BNE   4(0,0)                                                   30320000
COD005   B     2(0,0)                   BRNCH OVER FOLLWNG OR-LNE TESTS 30340000
COD006   B     0(0,0)                   BUFFER OVERFLOW                 30360000
         B     0(0,0)                                                   30380000
COD007   MVC   0(1,DATBS1),0(IORBBS)    PUT OVFL-SW. ON/OFF FROM X-SW.  30400000
COD008   LM    LINKBS,RTRNRG,0(AREABS)  RESTORE REG'S FOR LINKAGE PHASE 30420000
         BR    RTRNRG                                                   30440000
COD009   MVI   0(IORBBS),X'00'          PUT PUNCH-PRINT INFO INTO IORB  30460000
COD010   STH   0,0(IORBBS)              PUT RECORD LENGTH INTO IORB     30480000
         MVI   0(IORBBS),X'02'          PUT 'WRITE' IN IORB ACTION BYTE 30500000
         LA    0,0(0,IORBBS)            LOAD REG 0 WITH ADDRESS OF IORB 30520000
         BALR  14,13                    LINK TO INTERCERT ROUTINE       30540000
COD011   L     OVFLBS,LVAOFB(0,DATBS1)  OBTAIN ADDRESS OF OVERFL BYPASS 30560000
         MVI   12(AREABS),X'00'         RESET COMMON OVERFLOW SWITCH    30580000
         OC    12(1,AREABS),12(DATBS1)  'OR' OVFL-SWTCH TO COMMON SWTCH 30600000
         OC    12(1,AREABS),13(DATBS1)  DITTO                           30620000
         OC    12(1,AREABS),14(DATBS1)  DITTO                           30640000
         OC    12(1,AREABS),15(DATBS1)  DITTO                           30660000
         OC    12(1,AREABS),16(DATBS1)  DITTO                           30680000
         OC    12(1,AREABS),17(DATBS1)  DITTO                           30700000
         OC    12(1,AREABS),18(DATBS1)  DITTO                           30720000
         OC    12(1,AREABS),19(DATBS1)  DITTO                           30740000
         BCR   8,OVFLBS                 SKIP AROUND LINES COND. BY OVFL 30760000
COD012   LA    0,18(0,0)                LOAD MINIMUM REC.LNGTH FOR IORB 30780000
COD021   CLI   0(IORBBS),X'F0'          TEST X-SWITCH FOR SKIP TO CH.01 30800000
         BNE   8(0,0)                   BRANCH IF NO OVERFLOW           30820000
COD041   L     9,0(0,12)               .LINE CT +DISPL -LINK HAS BASED  30840000
         AR    9,3                     .PLUS DISPLACEMENT               30860000
         BALR  14,9                    .GO FIELD                        30880000
COD045   BALR  8,0                      DON'T SET OVFL SW'S ON 1ST PASS 30900000
         NOP   14(0,8)                                                  30920000
         OI    1(8),X'F0'                                               30940000
         LM    LINKBS,RTRNRG,0(AREABS)                                  30960000
         BR    RTRNRG                                                   30980000
*                                                                       31000000
         EJECT                                                          31020000
*        ************************************************************** 31040000
*        * SYMBOL DEFINITIONS FOR IMMEDIATE INSTRUCTIONS              * 31060000
*        ************************************************************** 31080000
*                                                                       31100000
CHA      EQU   C'A'                                                I222 31110018
CHC      EQU   C'C'                                                     31120000
CHE      EQU   C'E'                                                     31140000
CHF      EQU   C'F'                                                     31160000
CHI      EQU   C'I'                                                     31180000
CHL      EQU   C'L'                                                     31200000
CHN      EQU   C'N'                                                     31220000
CHO      EQU   C'O'                                                     31240000
CHP      EQU   C'P'                                                     31260000
CHR      EQU   C'R'                                                     31280000
CHT      EQU   C'T'                                                     31300000
CHV      EQU   C'V'                                                I222 31310018
CHNULL   EQU   X'00'                                                    31320000
CH0      EQU   C'0'                                                     31340000
CH1      EQU   C'1'                                                     31360000
SPACE    EQU   C' '                                                     31380000
*                                                                       31400000
GARBGE   EQU   ARGSAV                                                   31420000
         SPACE 3                                                        31440000
*        ************************************************************** 31460000
*        * REGISTERS + DISPLACEMENT ASSIGNMENT FOR OBJECT CODE.       * 31480000
*        *     NOTE. RTRNRG (14) IN LINE IS REG 1 IN FIELD            * 31500000
*        ************************************************************** 31520000
*                                                                       31540000
IORBBS   EQU   2                                                        31560000
DATBS1   EQU   3                                                        31580000
AREABS   EQU   10                                                       31600000
OVFLBS   EQU   11                                                       31620000
LINKBS   EQU   13                                                       31640000
RTRNRG   EQU   14                                                       31660000
*                                                                       31680000
LVIOI    EQU   148                      DISPLAC. TO ADDR. OF I/O ROUTNE 31700000
LVIORB   EQU   200                      DISPLAC. TO IORB LINKAGE VECTOR 31720000
LVWORK   EQU   232                      DISPLAC. TO ADDR. OF WORK AREA  31740000
LVAOFB   EQU   252                      DISPLAC. TO ADDR. OF OFL BYPASS 31760000
LVLNTB   EQU   268                     .DISP TO TABLE LINKAGE VECTOR    31780000
*                                                                       31800000
         EJECT                                                          31820000
*        ************************************************************** 31840000
*        * CALLING NUMBERS FOR RPG   CIOEX   SERVICE ROUTINES         * 31860000
*        ************************************************************** 31880000
*                                                                       31900000
GETCMP   EQU   0                        GET NEXT BLOCK OF COMPRESSION   31920000
PHSCAL   EQU   4                        LOAD THE NEXT PHASE             31940000
PNTERR   EQU   6                        WRITE ERROR NOTE                31960000
PNTCMP   EQU   16                       REINITIALIZE TO FIRST COMPR BLK 31980000
RLDOUT   EQU   18                       OUTPUT AN RLD RECORD            32000000
BLKOUT   EQU   24                      .OUTPUT RECORD ON BLANK-AFT.FILE 32020000
BLKIN    EQU   26                      .GET NEW BLOCK BLKAF             32040000
PNTBLK   EQU   28                       REINITIALIZE TO FIRST BLANK-AFT 32060000
PNTOUT   EQU   34                       POINT TO BLCK WITH 1ST OUT.SPEC 32080000
*                                                                       32100000
         SPACE 3                                                        32120000
*        ************************************************************** 32140000
*        * CALLING NUMBERS FOR RPG   CIOEX   TABLES AND COUNTERS      * 32160000
*        ************************************************************** 32180000
*                                                                       32200000
PHSNAM   EQU   X'08'                    NAME OF NEXT PHASE TO BE CALLED 32220000
ADDCNT   EQU   X'34'                    HIGHEST 'USER' CORE POS(BINARY) 32240000
NUMBLK   EQU   X'80'                    NO. OF BLOCKS ON BLKAF FILE     32260000
ODSPLC   EQU   X'8A'                    DISPL.TO 1ST OUTPT SPEC IN BLCK 32280000
SEQOUT   EQU   X'AA'                    SEQ NO. OF FIRST OUTPUT SPEC    32300000
PASKEY   EQU   X'C4'                    TABLE INDICATOR FROM ENTER PH.1 32320000
*                                                                       32340000
         EJECT                                                          32360000
*        ************************************************************** 32380000
*        * TEXT CARD OUTPUT AREA AND CODE BUFFER FOR DMPTXT           * 32400000
*        ************************************************************** 32420000
*                                                                       32440000
         DS    0D                       FORCE TO DOUBLE WORD ALIGNMENT  32460000
PFX      DC    X'02'          T                                         32480000
         DC    C'TXT'          E  C                                     32500000
LODLOC   DC    F'0'             X  A  P                                 32520000
         DC    C'  '             T  R  R                                32540000
CDLEN    DC    H'56'                 D  E                               32560000
         DC    C'  '                     F                              32580000
         DC    X'00'                      I                             32600000
         DC    X'01'                       X                            32620000
BUFFER   DC    0C'0'                    BUFFER AREA FOR DMPTXT          32640000
         ORG   IES15510+6143+START-ENDCS1                               32660000
FIN      DS    0CL1                                                     32680000
*        ************************************************************** 32700000
*        ************************************************************** 32720000
         EJECT                                                          32740000
         END   ASSEMBL4                                                 32760000
