         TITLE 'IES160  OS/360 RPG ASSEMBLE PHASE 4.5               31' 00020000
* STATUS       CHANGE LEVEL 1-9                                  A33556 00040020
*FUNCTION/OPERATION: PROCESS COMPRESSED OUTPUT-FORMAT SPECIFICATIONS TO 00060000
*   GENERATE FIELD CODING FOR OBJECT PROGRAM.                           00080000
*ENTRY POINTS:                                                          00100000
*        IES16010-ENTER PHASE FROM IES16910. PHSLINK  L     15,PHSADDR  00120000
*                                                     BALR  7,15        00140000
*                                                     *                 00160000
*                                                     *                 00180000
*                                            PHSADDR  DC    V(IES16010) 00200000
*        POINTERS, COUNTERS, AND CONSTANTS PASSED IN CIOEX DATA AREA    00220000
*        POINTED TO BY REGISTERS 6 AND 12 UPON ENTRY.                   00240000
*INPUT: COMPRESSED RPG SPECIFICATIONS ON SYSUT2 AND BLANK-AFTER ENTRIES 00260000
*   AND FILE DESCRIPTION TABLE ON SYSUT1.                               00280000
*OUTPUT: OBJECT TEXT ON SYSPUNCH OR SYSGO,DIAGNOSTICS ON SYSPRINT,AND   00300000
*   CIOEX LINKAGE VECTOR ENTRIES ON SYSUT3.                             00320000
*EXTERNAL ROUTINES:                                                     00340000
*        IES16910-CIOEX ROUTINES FOR ASSEMBLE PHASE 4.5.                00360000
*        GETCMP - GET NEXT BLOCK OF COMPRESSION                         00380000
*        PHSCAL - LOAD THE NEXT PHASE                                   00400000
*        PNTERR - WRITE ERROR NOTE                                      00420000
*        PUTCOD - PUT OUT TEXT ON SYSGO/SYSPCH                          00440000
*        RLDOUT - PUT OUT A RECORD ON RLD WORKFILE                      00460000
*        BLKIN  - READ IN A RECORD FROM BLANK-AFTER WORKFILE            00480000
*        PNTBLK - REINITIALIZE WORKFILE TO FIRST BLANK-AFTER BLOCK      00500000
*        PNTOUT - POINT TO BLOCK CONTAINING FIRST OUTPUT SPECIFICATION  00520000
*EXITS-NORMAL: QUIT - PHASE FINISHED. BRANCH TO NEXT PHASE VIA PHSCAL.  00540000
*     -ERROR:  NONE.                                                    00560000
*TABLES/WORKAREAS:                                                      00580000
*   FILETB - OUTPUT FILE DESCRIPTION TABLE READ FROM WORKFILE.          00600000
*            SEE DESCRIPTION AT END OF TABLE.                           00620000
*   BLATAB - TABLE AREA FOR BLOCKED BLANK-AFTER ENTRIES FROM WORKFILE.  00640000
*   RLDRCD - BUFFER AREA FOR BUILDING LINE-FIELD LINKING TABLE ENTRIES. 00660000
*   BUFFER - USED TO ASSEMBLE OBJECT CODE FOR PUTTING OUT TEXT.         00680000
*            SEE DESCRIPTION ON TITLE PAGE FOLLOWING.                   00700000
*ATTRIBUTES: EDITABLE, DOWNWARD COMPATIBLE.                             00720000
*NOTES: N/A                                                             00740000
*                                                                       00760000
*                                                                       00780000
IES16010 START                                                          00800000
* 044460-044700,050850-051100,054100,069020-069140,071700,101900   I222 00803000
* 123700,127900,131900,145300,155820-156160,190010-206974          I222 00806000
* 208810-208900,215030-215300,216260-216500,242510-242570          I222 00809000
* 218000-249680,265200-266800,288220-288360,311900,314300          I222 00812000
* 265100                                                         A20661 00815000
ASMBL45  EQU   *                                                        00820000
         EXTRN IES16910                                                 00840000
*                                                                       00860000
         EJECT                                                          00880000
*        ************************************************************** 00900000
*        ************************************************************** 00920000
*        *             RPG ASSEMBLE 4.5 (PART TWO)                    * 00940000
*        *             PRECEEDED BY ASSEMBLE 4.0(PART ONE)            * 00960000
*        *            ******         ******         ******            * 00980000
*        * GENERATES MACHINE-LANGUAGE CODE FOR.....                   * 01000000
*        * 1. BUILDING ALL LINES FROM FIELDS                          * 01020000
*        * 2. PERFORMING ALL OPERATIONS DEALING WITH FIELDS...        * 01040000
*        *    (A) BLANKING-AFTER ANY FIELDS SO REQUESTING             * 01060000
*        *    (B) INCREMENTING AND RESETING ANY PAGE FIELDS           * 01080000
*        *    (C) EDITING NUMERIC FIELDS SO REQUESTING                * 01100000
*        *    (D) LINKING TO STERLING CONVERSION ROUTINE              * 01120000
*        * 3. OBTAINING OUTPUT RECORD LENGTH FOR VARIABLE LNGTH FILES * 01140000
*        *                                                            * 01160000
*        * IT ALSO COMPLETES TABLE OF DISPLACEMENTS USED FOR BRANCHING* 01180000
*        * TO PROPER LINE-BUILDING CODE FROM LINE-CONTROL CODE PUT OUT* 01200000
*        * PREVIOUSLY BY ASSEMBLE 4.0                                 * 01220000
*        ************************************************************** 01240000
*        ************************************************************** 01260000
         SPACE 2                                                        01280000
*        ************************************************************** 01300000
*        * LOGIC IS THAT LINE CODE (CONDITIONING IF FIELD CODE FOR    * 01320000
*        * THAT LINE IS TO BE EXECUTED) WILL BRANCH ON A TABLE BUILT  * 01340000
*        * BY THE ASMBL45 AND EXPRESSED AS A SERIES OF DISPLACEMENTS. * 01360000
*        * THE TABLE CONTENTS (PLUS BASE) WILL INDICATE THE START OF  * 01380000
*        * FIELD CODING FOR THAT LINE.                                * 01400000
*        ************************************************************** 01420000
         SPACE 3                                                        01440000
*        ************************************************************** 01460000
*        * A BUFFER AREA (LABELLED BUFFER) USED BY DMPTXT TO ASSEMBLE * 01480000
*        * OBJECT CODE FOR PUNCHING IS AT END OF COMPILER CDE AND HAS * 01500000
*        * A LENGTH GIVEN BY INITIAL VALUE OF 'SOOM'. IT IS DESIGNED  * 01520000
*        * TO USE ALL AVAILABLE CORE UP TO HEX 1800. IT AUTOMATICALLY * 01540000
*        * ADJUSTS ITS LENGTH IF THE COMPILER CODE IS ALTERED.        * 01560000
*        ************************************************************** 01580000
*        ************************************************************** 01600000
*                                                                       01620000
         EJECT                                                          01640000
*        ************************************************************** 01660000
*        * GENERAL REGISTER ASSIGNMENT FOR PHASE                      * 01680000
*        ************************************************************** 01700000
*                                                                       01720000
ZERORG   EQU   0                       . FOR ARITH ONLY A WORK REG      01740000
REG1     EQU   1                        INTERFACE PARAMETER REGISTER    01760000
SERVRG   EQU   2                        SERVICE ROUTINE NO. REGISTER    01780000
INCREG   EQU   2                        ADDRESS COUNTER INCREM.REGISTER 01800000
STERRG   EQU   2                        WORK REGISTER DURING STERLING   01820000
CPREG    EQU   3                        COMPRESSION ADDRESS REGISTER    01840000
DSPLRG   EQU   4                        CODE DISPLACEMENT REGISTER      01860000
BACKRG   EQU   5                        LINKAGE REGISTER                01880000
EXTREG   EQU   7                       *SERVICE ROUTINE DRIVER REGISTER 01900000
USE2     EQU   8                        BASE REGISTER FOR CONTRL SECT.2 01920000
USE1     EQU   9                        BASE REGISTER FOR CONTRL SECT.1 01940000
PRTREG   EQU   10                      *PRINT AREA REGISTER             01960000
TABREG   EQU   11                       FILE TABLE ADDRESS REGISTER     01980000
CNTREG   EQU   12                      *INTERFACE COUNTER REGISTER      02000000
BCTREG   EQU   13                       LOOP AND COUNT REGISTER         02020000
WORKRG   EQU   14                       WORK REGISTER                   02040000
LR       EQU   14                       RETURN REGISTER FOR DUMPTEXT    02060000
ER       EQU   15                       BRANCH REGISTER FOR DUMPTEXT    02080000
*                                                                       02100000
*                                      *REGISTERS FULL ON ENTRY         02120000
*                                       REGISTER 4 MUST BE SAVED        02140000
*                                       REGISTER 6 MUST BE SAVED        02160000
*                                                                       02180000
*                                                                       02200000
*        ************************************************************** 02220000
*        * GENERAL REGISTER ASSIGNMENT FOR DUMP-TEXT ROUTINE.         * 02240000
*        * ALL REGISTERS ARE STORED AT ARGSAV WHILE IN THIS ROUTINE.  * 02260000
*        ************************************************************** 02280000
*                                                                       02300000
W1       EQU   2                                                        02320000
RUSE     EQU   3                                                        02340000
DMPRG0   EQU   11                                                       02360000
DMPRG1   EQU   12                                                       02380000
DMPRG2   EQU   13                                                       02400000
GR14     EQU   14                                                       02420000
DMPRG3   EQU   14                                                       02440000
DMPRG4   EQU   15                                                       02460000
*                                                                       02480000
         EJECT                                                          02500000
*        ************************************************************** 02520000
*        * ENTRY INTO ASSEMBLE PHASE 4.5                              * 02540000
*        *                                                            * 02560000
*        * PHASE HOUSEKEEPING                                         * 02580000
*        ************************************************************** 02600000
*                                                                       02620000
START    BALR  USE1,0                   LOAD USING REGISTER             02640000
         USING *,USE1                                                   02660000
         L     USE2,ADRCT2              LOAD BASE FOR 2ND CONTROL SECT  02680000
         USING IES16010+4096,USE2                                       02700000
         L     7,CXRADDR                                                02720000
         OI    NOFTAB,X'40'            .INITIALIZE ON                   02740000
         MVC   PHSNAM(8,CNTREG),NEXTPH  GIVE NAME OF NXT PHASE TO INTER 02760000
         L     INCREG,ADDCNT(CNTREG)   .PICK UP ADDR                    02780000
         ST    INCREG,LODLOC            USER CORE ADDR TO DMPTXT ROUTNE 02800000
         ST    DSPLRG,STOREL            SAVE PUNCH BUFFER POINTER       02820000
         SR    DSPLRG,DSPLRG            CLEAR DISPLACEMENT REGISTER     02840000
*                                                                       02860000
         EJECT                                                          02880000
*        ************************************************************** 02900000
*        * INITIALIZE COMPRESSION AND GET FILE DESCRIPTION TABLE,     * 02920000
*        * LINKAGE TABLE START ADDR FROM BLANK-AFTER WORKFILE         * 02940000
*        ************************************************************** 02960000
*                                                                       02980000
         LA    SERVRG,PNTOUT            POINT TO 1ST BLOCK OF OUT COMPR 03000000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   03020000
         LA    SERVRG,GETCMP            GET FIRST BLOCK OF OUTPUT COMPR 03040000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   03060000
         AH    CPREG,ODSPLC(CNTREG)     MOVE POINTER TO 1ST OUTPUT SPEC 03080000
         LA    SERVRG,PNTBLK           .REINIT BLANKAFT WORKFILE        03100000
         BALR  BACKRG,EXTREG           .(LINK TO EXTERNAL SUBR)         03120000
         LH    WORKRG,NUMBLK(CNTREG)   .PICK UP BLOCK COUNT OF BLNKAF   03140000
         SH    WORKRG,CH03B            .LESS 3 TO GET FIRST FD REC      03160000
GETFD    LA    REG1,FILETB             .ADDR OF AREA                    03180000
         LA    SERVRG,BLKIN            .FROM WHERE                      03200000
         ST    WORKRG,STOREA           .SAVE BLK CNT                    03220000
         BALR  BACKRG,EXTREG           .(LINK TO EXTERNAL SUBR)         03240000
         L     WORKRG,STOREA           .RECALL COUNT                    03260000
         BCT   WORKRG,GETFD                                             03280000
         LA    REG1,FILETB+72          .SECOND RECORD                   03300000
         LA    SERVRG,BLKIN            .DITTO                           03320000
         BALR  BACKRG,EXTREG           .(LINK TO EXTERNAL SUBR)         03340000
         LA    REG1,FILETB+144         .THIRD RECORD                    03360000
         LA    SERVRG,BLKIN            .DITTO                           03380000
         BALR  BACKRG,EXTREG           .(LINK TO EXTERNAL SUBR)         03400000
         LA    REG1,FILETB+216         .FOURTH RECORD                   03420000
         LA    SERVRG,BLKIN            .DITTO                           03440000
         BALR  BACKRG,EXTREG           .(LINK TO EXTERNAL SUBR)         03460000
*                                                                       03480000
         SPACE 5                                                        03500000
*        ************************************************************** 03520000
*        *     CORE IMMEDIATELY AFTER TRUE FILETB(240BYTES) WILL      * 03540000
*        *     CONTAIN THE STARTING ADDR OF THE TABLE FOR FIELD       * 03560000
*        *     BRANCHES- USED FOR COMMUNICATION BETWEEN ASMBL4 AND 45 * 03580000
*        ************************************************************** 03600000
*                                                                       03620000
         MVC   TABLAD(4),TABADD        .OBTAIN TABL START ADDR     000H 03640000
         MVC   LASTFD(4),INITFD        .INITIALIZE TO STARTPOINT        03660000
         MVC   SEQNO(4),SEQOUT(CNTREG)  OBTAIN SEQ NO. OF 1ST OUT SPEC  03680000
         B     ENTRY                   .GO TEST COMPRESSION             03700000
*                                                                       03720000
         EJECT                                                          03740000
*        ************************************************************** 03760000
*        *          TABLE AND CONSTANT AREA FOR FIRST CSECT.          * 03780000
*        ************************************************************** 03800000
*        ************************************************************** 03820000
*        ************************************************************** 03840000
         SPACE 5                                                        03860000
*        ************************************************************** 03880000
*        * ADDRESS CONSTANTS FOR REFERENCING OTHER CONTROL SECTIONS   * 03900000
*        ************************************************************** 03920000
*                                                                       03940000
CXRADDR  DC    A(IES16910)              ADDR. OF CIOEX FOR THIS PHASE   03960000
ADRCT2   DC    A(IES16010+4096)         ADDRESS FOR SECOND BASE R  I222 03980000
*                                                                       04000000
         SPACE 3                                                        04020000
*        ************************************************************** 04040000
*        *        OUTPUT FILE DESCRIPTION TABLE AREA                  * 04060000
*        ************************************************************** 04080000
*                                                                       04100000
         DS    0D                       DOUBLE WORD ALIGN               04120000
FILETB   DS    288C                    .240 USED FOR FILE DESCR TAB000H 04130000
TABADD   EQU   FILETB+240               TABLE START ADDR           000H 04140000
*        ************************************************************** 04160000
         SPACE 2                                                        04180000
*        ************************************************************** 04200000
*        * THE OUTPUT FILE DESCRIPTION TABLE CONTAINS A 24-BYTE ENTRY * 04220000
*        * FOR EACH OUTPUT FILE (TYPE O, U, OR C). THERE MAY BE UP TO * 04240000
*        * TEN ENTRIES, EACH WITH THE FOLLOWING FORMAT.....           * 04260000
*        *                                                            * 04280000
*        *     BYTES          CONTENTS                                * 04300000
*        *                                                            * 04320000
*        *     01-03          UNPACKED FILE SEQUENCE NUMBER (001-010) * 04340000
*        *     04             REFERENCE BYTE                          * 04360000
*        *     05-12          FILE NAME                               * 04380000
*        *      13             FILE TYPE (O,U,C,L,A OR V)             * 04400000
*        *     14             FILE FORMAT (F OR V)                    * 04420000
*        *     15-17          MAXIMUM RECORD LENGTH IN BINARY         * 04440000
*        *     18             OVERFLOW INDICATOR(A-F,V OR 0)          * 04446000
*        *     19             I.S. KEY ACCESS CODE                    * 04452000
*        *                        X'7F'= BLKD I.S./NON-I.S.           * 04458000
*        *                        BINARY KEY LENGTH= UNBLKD I.S.,     * 04464000
*        *                           BIT ZERO ON= KEY AREA ACCESS OK  * 04470000
*        *     20-22          DEVICE TYPE (PRT, R-NN, TPE, D-NN)      * 04480000
*        *     23-24          DISPLACEMENT TO IORB TABLE FOR FILE     * 04500000
*        *                                                            * 04520000
*        * WHEN LESS THAN 10 OUTPUT FILES ARE PRESENT, UNUSED ENTRIES * 04540000
*        * IN THE TABLE WILL BE FILLED WITH HEX '00' CHARACTERS.      * 04560000
*        ************************************************************** 04580000
*        ************************************************************** 04600000
*                                                                       04620000
         EJECT                                                          04640000
*        ************************************************************** 04660000
*        *                     MAIN LINE CODE.                        * 04680000
*        * SECTION I - ROUTINE FOR CONTROLLING THE SEQUENCING THROUGH * 04700000
*        * THE OUTPUT SPECIFICATIONS FROM COMPRESSION AND DETERMINING * 04720000
*        * WHICH ARE FIELD-TYPE. FIELD-TYPE ARE PROCESSED IN SECT. II * 04740000
*        ************************************************************** 04760000
*        ************************************************************** 04780000
         SPACE 2                                                        04800000
*        ************************************************************** 04820000
*        * EXAMINE NEXT COMPRESSED OUTPUT SPEC IF ANY.                * 04840000
*        * 1. TESTS FOR END OF COMPRESSION BLOCK                      * 04860000
*        * 2. TESTS WHETHER RECORD (O) OR FIELD (M) TYPE COMPR SPEC   * 04880000
*        * 3. TESTS RECORD-TYPE SPECS FOR 'AND' AND 'OR'              * 04900000
*        ************************************************************** 04920000
*                                                                       04940000
NXTBLK   LA    SERVRG,GETCMP            GET NEXT BLOCK OF COMPRESSION   04960000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   04980000
ENTRY    CLI   0(CPREG),X'FD'           TEST FOR END OF COMPRESSION BLK 05000000
         BH    NXTBLK                   END (FF- ANOTHER BLK TO FOLLOW) 05020000
         BE    END                      END (FD- NO MORE COMPRESSION)   05040000
         CLI   0(CPREG),CHO             TEST IF NEW SPEC IS RECORD TYPE 05060000
         BNE   TSTNAM                   BRANCH IF NO - FIELD TYPE (M)   05080000
         CLI   3(CPREG),C'A'            IS THIS AN I.S. ADD RECOR  I222 05085000
         MVI   ARSW,X'00'               SWITCH OFF IF NOT ADD RCD  I222 05090000
         BNE   SETFLDSW                 AND GO SET FIELD SWITCH    I222 05095000
         OI    ARSW,X'01'               ELSE,MUST KNOW WHICH FLDS  I222 05100000
*                                       ARE IN AN ADDED RECORD     I222 05105000
SETFLDSW NI    FLD1SW,X'FD'             RESET FIELD SWITCH         I222 05110000
         TM    1(CPREG),X'0C'          .IS IT 'AND' OR 'OR'             05120000
*        *************************************************************  05140000
         BM    INCOMP                  .BRANCH IF EITHER                05160000
*        *************************************************************  05180000
         SPACE 3                                                        05200000
*        ************************************************************** 05220000
*        *  1. REINIT BASE FOR RELOCATION IN LINE CODE IF UNDEFINED   * 05240000
*        *     LABELS WERE PRESENT                                    * 05260000
*        *  2. PUT OUT BR TO RETURN TO LINE CODE- EXCEPT FIRST TIME   * 05280000
*        *     ALSO AT END                                            * 05300000
*        *  3. PUT OUT ADDR TO TABLE, BALR FOR NEXT LINE CODE         * 05320000
*        *  4. SEARCH FILE DESCRIPTION, INDICATE IF NO HITS           * 05340000
*        *  5. GET NEXT SPEC -(INCOMP)                                * 05360000
*        ************************************************************** 05380000
*                                                                       05400000
         MVC   ARSW1(1),ARSW            SAVE ADD SW ACROSS AND/OR  I222 05410000
         TM    FTOSW,X'20'             .IS THIS FIRST TIME              05420000
         BNZ   FIELD2                  .BRANCH IF NO                    05440000
         OI    FTOSW,X'20'             .TURN ON                         05460000
         B     FIELD3                  .DONT PUT OUT BR ADDR            05480000
*                                                                       05500000
         EJECT                                                          05520000
*                                                                       05540000
FIELD2   TM    ULABSW,X'04'            .TEST IF ULABL USED              05560000
         BZ    NOULAB                  . NOT ANY ULABELS USED           05580000
         NI    ULABSW,X'FB'            .TURN OFF ULABSW                 05600000
         CLC   RECEND+1(3),14(TABREG)   COMPARE HIGH FIELD TO REC.LNGTH 05620000
         BH    M05                      BRANCH IF OUTSIDE RECORD        05640000
         CLI   13(TABREG),CHV           IS THIS A VARIABLE LENGTH FILE  05660000
         BE    M06                      BRANCH IF YES                   05680000
M05      MVC   RECEND+2(2),15(TABREG)   REPLACE WITH MAXIMUM REC.LNGTH  05700000
M06      MVC   COD043+6(2),RECEND+2     PLACE RECORD LENGTH IN CODE     05720000
         BAL   LR,DMPTXT               .PUT OUT BRANCH                  05740000
         DC    AL2(10)                 .AND RESET BASE                  05760000
         DC    AL4(COD043)             .FOR PREVIOUS FIELD              05780000
         LA    DSPLRG,10(DSPLRG)       .INCREMENT                       05800000
         B     M07                     .PASS ALTERNATE CODE             05820000
*                                                                       05840000
NOULAB   CLC   RECEND+1(3),14(TABREG)   COMPARE HIGH FIELD TO REC.LNGTH 05860000
         BH    M01                      BRANCH IF OUTSIDE RECORD        05880000
         CLI   13(TABREG),CHV           IS THIS A VARIABLE LENGTH FILE  05900000
         BE    M02                      BRANCH IF YES                   05920000
M01      MVC   RECEND+2(2),15(TABREG)   REPLACE WITH MAXIMUM REC.LNGTH  05940000
M02      MVC   COD043+6(2),RECEND+2     PLACE RECORD LENGTH IN CODE     05960000
         BAL   LR,DMPTXT               .PUT OUT BRANCH                  05980000
         DC    AL2(6)                  .RETURN TO LINE                  06000000
         DC    AL4(COD043+4)                                            06020000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 06040000
M07      MVC   RECEND(4),CH18B          RESTORE RECORD LENGTH COUNTER   06060000
*                                                                       06080000
*                                       (CONTINUED NEXT PAGE)           06100000
         EJECT                                                          06120000
*        ************************************************************** 06140000
*        THIS CODING PLACES ADDR OF NEXT FIELD SPEC IN RLD TABLE        06160000
*        ************************************************************** 06180000
*                                                                       06200000
FIELD3   L     WORKRG,LASTFD           .GET NEXT ADR TO FILL            06220000
         CLI   0(WORKRG),X'FD'         .END REACHED                     06240000
         BNE   NOTFUL                  .NO                              06260000
         LA    REG1,RLDRCD             .OUTPUT LINKAGE ON RLDX WORKFILE 06280000
         LA    SERVRG,RLDOUT           .DITTO                           06300000
         BALR  BACKRG,EXTREG           .(LINK TO EXTERNAL SUBROUTINE)   06320000
         MVC   LASTFD(4),INITFD        .REINITIALIZE TO TABL STARTPOINT 06340000
         B     FIELD3                  .GO BACK AND SET ADDR            06360000
*                                                                       06380000
*                                                                       06400000
NOTFUL   L     ZERORG,ADDCNT(CNTREG)   .GET ADDRESS                     06420000
         AR    ZERORG,DSPLRG           .PLUS COUNT TO FIELD             06440000
         ST    ZERORG,0(WORKRG)        .PLACE STARTING ADDRESS          06460000
*                                      .   NEXT FIELD IN RLDX TABLE     06480000
         LA    WORKRG,4(WORKRG)        . UP FOUR TO NEXT TABL ADDR      06500000
         ST    WORKRG,LASTFD           .SAVE ADDR FOR NEXT TIME         06520000
         ST    ZERORG,ADDCNT(CNTREG)   .SAVE COUNT                      06540000
         BAL   LR,DMPTXT               .OUTPUT                          06560000
         DC    AL2(2)                  .BALR9                           06580000
         DC    AL4(COD044)             .DITTO                           06600000
         L     DSPLRG,ADDCNT(CNTREG)   .BUMP 2                          06620000
         LA    DSPLRG,2(DSPLRG)        .DITTO                           06640000
         ST    DSPLRG,ADDCNT(CNTREG)   .SAVE TOTAL                      06660000
         SR    DSPLRG,DSPLRG           .ZERO DISPLACEMENT               06680000
         MVC   STOREB(8),10(CPREG)     .STORE FILENAME FOR LATER COMPAR 06700000
         NI    PROCSW,X'FE'            .RESET PROC SW                   06720000
         LA    TABREG,FILETB           .GET ADDR START OF FILE TABLE    06740000
         LA    BCTREG,10               .LOAD CYCLE COUNT OF REG WITH 10 06760000
SRCH     CLC   STOREB(8),4(TABREG)     .COMPAR FILENAM TO ENTRY IN TABL 06780000
         BE    FTABHIT                 .EXIT INDICATE HIT               06800000
         LA    TABREG,24(TABREG)        INCREMENT TABLE REGISTER   000H 06820000
         BCT   BCTREG,SRCH             .COUNT TBL ENTRIES EXIT AFTER 10 06840000
         OI    PROCSW,X'01'            .INDIC NOT TO BE PROCESSED       06860000
         B     INCOMP                  . TO NEXT COMPRESSION            06880000
FTABHIT  NI    NOFTAB,X'BF'            .RESET SWITCH HIT ON FD TABLE    06900000
         MVC   KEYSW,18(TABREG)         MOVE I.S. KEY ACCESS CODE  000H 06902000
         CLI   KEYSW,X'7F'              BLKD I.S. OR NON-I.S.      I222 06904000
         BE    SETADSW                  YES,GO SET ADD SW          I222 06906000
         MVC   KEYLNG+1(1),KEYSW        SAVE KEY LENGTH AND        I222 06908000
         NI    KEYLNG+1,X'7F'           SET OFF KEY ACCESS CODE    I222 06910000
         MVC   RECLNG(2),15(TABREG)     SAVE RECORD LENGTH         I222 06912000
SETADSW  MVC   ADDSW(1),3(CPREG)        USED TO CHECK FOR ADD RCD  I222 06914000
*        ************************************************************** 06920000
*        * THIS SWITCH IS TESTED AT END OF THIS PASS.IF STILL ON,ERR  * 06940000
*        ************************************************************** 06960000
         SPACE 2                                                        06980000
*        ********************************                               07000000
*        *INCREASE COMPRESSION AND LOOP *                               07020000
*        ********************************                               07040000
*                                                                       07060000
INCOMP   SR    WORKRG,WORKRG            INCREASE COMPR POINTER BY DELTA 07080000
         IC    WORKRG,2(CPREG)          DITTO                           07100000
         AR    CPREG,WORKRG             DITTO                           07120000
         NI    SWTCH1,X'E7'             RESET STERLING INDICATORS       07140000
         AP    SEQNO(4),PK1             INCREMENT SEQUENCE NUMBER       07160000
         MVC   ARSW(1),ARSW1            RESTORE SAVED CONDITION    I222 07170000
         B     ENTRY                    GO TEST COMPRESSION             07180000
*                                                                       07200000
         EJECT                                                          07220000
*        ************************************************************** 07240000
*        *   DATA ALL PROCESSED- CLOSING ROUTINE                      * 07260000
*        ************************************************************** 07280000
*                                                                       07300000
END      CLC   LASTFD,INITFD           .ARE WE AT START OF NEW RLDX     07320000
         BE    NORLDX                  .YES DO NOT CREATE ANY           07340000
         L     WORKRG,LASTFD           .NO WRITE LAST RLDX              07360000
         MVC   0(2,WORKRG),LADRID      .DROP IN FD TO TRUNCATE          07380000
         LA    REG1,RLDRCD             .OUTPUT FINAL RLDX LINKAGE       07400000
         LA    SERVRG,RLDOUT           .DITTO                           07420000
         BALR  BACKRG,EXTREG           .(LINK TO EXTERNAL SUBROUTINE)   07440000
*        .......... WE HAVE NOW PUT LAST RLDX OUT .......               07460000
*        .......... NOW BUILD LAST BRANCH ADDR, WINDUP,AND CALL NEXTPHS 07480000
NORLDX   CLC   RECEND+1(3),14(TABREG)   COMPARE HIGH FIELD TO REC.LNGTH 07500000
         BH    M03                      BRANCH IF OUTSIDE RECORD        07520000
         CLI   13(TABREG),CHV           IS THIS A VARIABLE LENGTH FILE  07540000
         BE    M04                      BRANCH IF YES                   07560000
M03      MVC   RECEND+2(2),15(TABREG)   REPLACE WITH MAXIMUM REC.LNGTH  07580000
M04      MVC   COD043+6(2),RECEND+2     PLACE RECORD LENGTH IN CODE     07600000
         BAL   LR,DMPTXT               .LINK TO PUNCH CODE ROUTINE      07620000
         DC    AL2(10)                 .PUT OUT LASTBRANCH AND BASE     07640000
         DC    AL4(COD043)             .GEN BR REG 14                   07660000
         L     INCREG,ADDCNT(CNTREG)    UPDATE THE ADDRESS COUNTER      07680000
         LA    INCREG,10(DSPLRG,INCREG)  DITTO                          07700000
         ST    INCREG,ADDCNT(CNTREG)    DITTO                           07720000
         L     DSPLRG,STOREL            RELOAD PUNCH BUFFER POINTER     07740000
         BAL   LR,FINTXT               .GO FOR ANY UNPUNCHED TEXT       07760000
         TM    NOFTAB,X'40'             ARE THERE ANY VALID OUTPT FILES 07780000
         BZ    QUIT                     BRANCH IF YES                   07800000
         UNPK  96(3,PRTREG),CH222      .ERROR NOTE 222                  07820000
         BAL   BACKRG,ERROUT           .DITTO                           07840000
QUIT     LA    SERVRG,PHSCAL           .CALL NEXT PHASE                 07860000
         BR    EXTREG                  .OUT                             07880000
*                                                                       07900000
*                        ***************************                    07920000
*                        * END OF MAIN LINE CODE.  *                    07940000
*                        * EXIT TO THE NEXT PHASE. *                    07960000
*                        ***************************                    07980000
         EJECT                                                          08000000
*        ************************************************************** 08020000
*        * SECTION II -  PUT OUT CODE FOR BUILDING LINES FROM THEIR   * 08040000
*        * FIELDS, EDITING, BLANKING, CONVERTING TO STERLING, ETC.    * 08060000
*        ************************************************************** 08080000
*        ************************************************************** 08100000
         SPACE 3                                                        08120000
*        ************************************************************** 08140000
*        * START OF FIELD CODING-DETERMINE TYPE OF FIELD              * 08160000
*        ************************************************************** 08180000
*                                                                       08200000
TSTNAM   TM    PROCSW,X'01'            .IS RECORD TO BE OPUT THIS PASS  08220000
         BO    INCOMP                  .NO                              08240000
         TM    1(CPREG),X'20'           IS THERE A FIELD NAME           08260000
         BZ    CONST                    BRANCH IF NO (CONSTANT SPEC.)   08280000
         CLI   3(CPREG),X'F0'           TEST IF SPEC IS VALID           08300000
         BE    INCOMP                   BRANCH IF NO-DON'T PROCESS SPEC 08320000
         TM    7(CPREG),X'E0'           TEST IF FIELD IS EXTERNAL       08340000
         BZ    F03                      BRANCH IF NO                    08360000
         NI    7(CPREG),X'0F'           REMOVE EXTERNAL FLAG            08380000
         BAL   BACKRG,DATOV1            LINK TO TEST FOR DATA OVERFLOW  08400000
         OI    ULABSW,X'04'            .TURN ON TO INDIC ULABL USED     08420000
         MVC   COD018+2(2),3(CPREG)     PUT ULABL FIELD ADDR. IN CODE   08440000
         MVC   3(2,CPREG),EXTERN        OVERLAY COMPRESS. FIELD ADDRESS 08460000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      08480000
         DC    AL2(4)                                                   08500000
         DC    AL4(COD018)                                              08520000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 08540000
F03      MVC   STOREH+1(3),9(CPREG)     STORE END POSITION              08560000
         NI    STOREH+1,X'7F'           REMOVE 'PAGE' INDICATOR IF ANY  08580000
         TM    1(CPREG),X'04'           IS THERE AN EDIT WORD           08600000
         BZ    F04                      BRANCH IF NO                    08620000
*                                                                       08640000
         EJECT                                                          08660000
*        *************                                                  08680000
*        * EDIT WORD *                                                  08700000
         LA    BCTREG,12(CPREG)         OBTAIN ADDRESS OF EDIT INFO.    08720000
         SR    REG1,REG1                DITTO                           08740000
         IC    REG1,0(BCTREG)           DITTO                           08760000
         AR    BCTREG,REG1              DITTO                           08780000
         TM    7(CPREG),X'0B'           TEST IF FIELD IS NUMERIC        08800000
         BC    12,E00                   BRANCH IF YES                   08820000
         UNPK  96(3,PRTREG),CH231       ERROR NOTE 231                  08840000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  08860000
         B     F05                                                      08880000
E00      TM    1(CPREG),X'02'           IS THIS A STERLING FIELD        08900000
         BZ    E01                      BRANCH IF NO                    08920000
         TM    3(TABREG),X'40'          IS THIS A PRINT FILE            08940000
         BZ    E11                      BRANCH IF NO                    08960000
         BAL   BACKRG,STERL             LINK TO STERLING ROUTINE        08980000
E01      CLC   6(1,CPREG),5(BCTREG)     IS EDIT PATTERN LONG ENOUGH     09000000
         BNH   E02                      BRANCH IF YES                   09020000
         UNPK  96(3,PRTREG),CH230       ERROR NOTE 230                  09040000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  09060000
E02      SR    REG1,REG1                                                09080000
         IC    REG1,16(CPREG)                                           09100000
         STC   REG1,COD026+1            EDIT PATTERN LNGTH(-1) TO CODE  09120000
         BCTR  REG1,0                                                   09140000
         ST    REG1,STOREF              STORE LNGTH OF EDIT PATTERN(-2) 09160000
         TM    5(BCTREG),X'01'          TEST IF LENGTH IS EVEN OR ODD   09180000
         BZ    E03                      BRANCH IF ODD                   09200000
         BCTR  REG1,0                                                   09220000
         ST    REG1,STOREF              STORE LNGTH OF EDIT PATTERN(-3) 09240000
E03      BAL   BACKRG,DATOV3            LINK TO TEST FOR DATA OVERFLOW  09260000
         SR    REG1,REG1                CALC.LENGTH OF PACKED FIELD(-1) 09280000
         IC    REG1,6(CPREG)            DITTO                           09300000
         LA    REG1,1(REG1)             DITTO                           09320000
         SRL   REG1,1                   DITTO                           09340000
         STC   REG1,STOREK+3            DITTO                           09360000
         BAL   BACKRG,F10                                               09380000
         CLC   6(1,CPREG),5(BCTREG)     IS FIELD LONG ENOUGH FOR PATTRN 09400000
         BNL   E05                      BRANCH IF YES                   09420000
         IC    REG1,5(BCTREG)           CALC.LNG OF PACKD EDIT DIG.(-1) 09440000
         LA    REG1,1(REG1)             DITTO                           09460000
         SRL   REG1,1                   DITTO                           09480000
         SLL   REG1,4                   PUT PCKD LNTHS IN CDE FOR L1/L2 09500000
         O     REG1,STOREK              DITTO                           09520000
         STC   REG1,COD030+1            DITTO                           09540000
         MVC   COD030+4(2),3(CPREG)     PUT FIELD ADDRESS IN CODE       09560000
         MVC   COD026+10(2),COD030+2    PUT ADDR.OF AUGMENTD FLD IN CDE 09580000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      09600000
         DC    AL2(6)                                                   09620000
         DC    AL4(COD030)                                              09640000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 09660000
         B     E06                                                      09680000
*                                                                       09700000
*                                       (CONTINUED NEXT PAGE)           09720000
         EJECT                                                          09740000
*        ************************                                       09760000
*        * EDIT FLOATING DOLLAR *                                       09780000
E04      IC    REG1,6(BCTREG)           DISP.OF ZERO SUPP.CHAR TO CODE  09800000
         LA    REG1,33(REG1)            DITTO                           09820000
         STC   REG1,COD025+3            DITTO                           09840000
         MVC   COD031+4(2),COD026+10    PUT FIELD ADDR.IN CODE          09860000
         MVC   COD031+1(1),2(BCTREG)    EDIT WORD BODY LENGTH TO CODE   09880000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      09900000
         DC    AL2(10)                                                  09920000
         DC    AL4(COD025)                                              09940000
         LA    DSPLRG,10(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 09960000
         BAL   BACKRG,DATOV1            LINK TO TEST FOR DATA OVERFLOW  09980000
         BAL   LR,DMPTXT                                                10000000
         DC    AL2(12)                                                  10020000
         DC    AL4(COD031)                                              10040000
         LA    DSPLRG,12(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 10060000
         B     E08                                                      10080000
*                                                                       10100000
E05      MVC   COD026+10(2),3(CPREG)    PUT FIELD ADDRESS IN CODE       10120000
E06      MVC   COD026+4(2),13(CPREG)    ADDR.OF EDIT PATTERN TO CODE    10140000
         MVC   COD026+13(1),STOREF+3    LNGTH OF EDIT PATTN(-2) TO CODE 10160000
         NC    COD026+14(2),RESET       INSERT ADDR. OF FIELD IN RECORD 10180000
         BAL   BACKRG,KEYSUB            CHECK NATURE OF FIELD      I222 10190000
         OC    COD026+14(2),FDSTRT+2    DITTO                           10200000
         MVI   COD026+17,X'21'          PUT EDIT PATTERN DISP. IN CODE  10220000
         MVI   COD028+3,X'21'           REPEAT                          10240000
         TM    5(BCTREG),X'01'          TEST IF LENGTH IS EVEN OR ODD   10260000
         BZ    E07                      BRANCH IF ODD                   10280000
         MVI   COD026+17,X'22'          PUT EDIT PATTERN DISP. IN CODE  10300000
         MVI   COD028+3,X'22'           REPEAT                          10320000
E07      TM    3(BCTREG),X'04'          TEST FOR FLOATING DOLLAR        10340000
         BO    E04                      BRANCH IF YES                   10360000
         MVC   COD026+7(1),2(BCTREG)    EDIT WORD BODY LENGTH TO CODE   10380000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      10400000
         DC    AL2(6)                                                   10420000
         DC    AL4(COD026)                                              10440000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 10460000
         BAL   BACKRG,DATOV1            LINK TO TEST FOR DATA OVERFLOW  10480000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      10500000
         DC    AL2(6)                                                   10520000
         DC    AL4(COD026+6)                                            10540000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 10560000
         TM    3(BCTREG),X'08'          TEST FOR FIXED DOLLAR           10580000
         BZ    E08                      BRANCH IF NO                    10600000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      10620000
         DC    AL2(4)                                                   10640000
         DC    AL4(COD028)                                              10660000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 10680000
*                                                                       10700000
*                                       (CONTINUED NEXT PAGE)           10720000
         EJECT                                                          10740000
*        ********************                                           10760000
*        * EDIT STATUS SIGN *                                           10780000
E08      TM    3(BCTREG),X'02'          TEST IF (-) STATUS              10800000
         BO    E09                      BRANCH IF YES                   10820000
         TM    3(BCTREG),X'01'          TEST IF CR STATUS               10840000
         BZ    E10                      BRANCH IF NO                    10860000
         MVC   COD032+7(1),4(BCTREG)    DISP. OF SIGN STATUS TO CODE    10880000
         OI    COD032+7,X'20'           DITTO                           10900000
         LA    WORKRG,10(DSPLRG)        PUT BRANCH ADDRESS IN CODE      10920000
         STH   WORKRG,COD032+2          DITTO                           10940000
         OI    COD032+2,X'90'          .INSERT BASE REG 9               10960000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      10980000
         DC    AL2(10)                                                  11000000
         DC    AL4(COD032)                                              11020000
         LA    DSPLRG,10(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 11040000
         B     E10                                                      11060000
E09      MVC   COD029+7(1),4(BCTREG)    DISP. OF SIGN STATUS TO CODE    11080000
         OI    COD029+7,X'20'           DITTO                           11100000
         LA    WORKRG,8(DSPLRG)         PUT BRANCH ADDRESS IN CODE      11120000
         STH   WORKRG,COD029+2          DITTO                           11140000
         OI    COD029+2,X'90'          .INSERT BASE REG 9               11160000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      11180000
         DC    AL2(8)                                                   11200000
         DC    AL4(COD029)                                              11220000
         LA    DSPLRG,8(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 11240000
*                                                                       11260000
E10      BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      11280000
         DC    AL2(6)                                                   11300000
         DC    AL4(COD027)                                              11320000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 11340000
         B     BLNKAF                                                   11360000
*                                                                       11380000
E11      UNPK  96(3,PRTREG),CH236       ERROR NOTE 236                  11400000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  11420000
         B     F05                                                      11440000
*                                                                       11460000
         EJECT                                                          11480000
F04      LA    BCTREG,5(CPREG)          SET POINTER TO RESLT INDICATORS 11500000
F05      MVC   STOREF+3(1),6(CPREG)     STORE LENGTH OF FIELD (-1)      11520000
         BAL   BACKRG,DATOV1            LINK TO TEST FOR DATA OVERFLOW  11540000
         TM    7(CPREG),X'0B'           TEST IF FIELD IS NUMERIC        11560000
         BO    ALPHA                    BRANCH IF NO                    11580000
*                                                                       11600000
*        ***********                                                    11620000
*        * NUMERIC *                                                    11640000
         L     WORKRG,STOREF            CALC.LENGTH OF PACKED FIELD(-1) 11660000
         LA    WORKRG,1(WORKRG)         DITTO                           11680000
         SRL   WORKRG,1                 DITTO                           11700000
         ST    WORKRG,STOREK            SAVE PACKED LENGTH (-1)         11720000
         TM    1(CPREG),X'01'           IS OUTPT TO BE IN PACKED FORMAT 11740000
         BZ    UNPAK                    BRANCH IF NO                    11760000
         ST    WORKRG,STOREF            PUT PACKD LNGTH(-1)IN FLD LNGTH 11780000
         NI    1(CPREG),X'FE'           (TO BYPASS ERROR NOTE 227)      11800000
*                                                                       11820000
*        ***************************                                    11840000
*        * ALPHA OR PACKED NUMERIC *                                    11860000
ALPHA    TM    1(CPREG),X'11'           TEST IF ZERO-SUPPRESS OR PACKNG 11880000
         BZ    F07                      BRANCH IF NO                    11900000
         UNPK  96(3,PRTREG),CH227       ERROR NOTE 227                  11920000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  11940000
F07      TM    1(CPREG),X'02'           TEST IF STERLING                11960000
         BZ    F08                      BRANCH IF NO                    11980000
         UNPK  96(3,PRTREG),CH232       ERROR NOTE 232                  12000000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  12020000
F08      BAL   BACKRG,F10                                               12040000
F08A     MVC   COD016+4(2),3(CPREG)     PUT FIELD ADDRESS IN CODE       12060000
         B     F09                                                      12080000
*                                                                       12100000
*        ************                                                   12120000
*        * CONSTANT *                                                   12140000
CONST    MVC   STOREF+3(1),10(CPREG)    STORE LENGTH OF CONSTANT (-1)   12160000
         MVC   STOREH+1(3),3(CPREG)     STORE END POSITION              12180000
         LA    BCTREG,1(CPREG)          SET POINTER TO RESLT INDICATORS 12200000
         SR    REG1,REG1                DITTO                           12220000
         IC    REG1,5(BCTREG)           DITTO                           12240000
         AR    BCTREG,REG1              DITTO                           12260000
         BAL   BACKRG,DATOV2            LINK TO TEST FOR DATA OVERFLOW  12280000
         BAL   BACKRG,F10                                               12300000
         MVC   COD016+4(2),7(CPREG)     PUT FIELD ADDRESS IN CODE       12320000
F09      MVC   COD016+1(1),STOREF+3     PUT FIELD LENGTH IN USER-CODE   12340000
         NC    COD016+2(2),RESET        PUT IN ADDR. OF FIELD IN RECORD 12360000
         BAL   BACKRG,KEYSUB            CHECK NATURE OF FIELD      I222 12370000
         OC    COD016+2(2),FDSTRT+2     DITTO                           12380000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      12400000
         DC    AL2(6)                                                   12420000
         DC    AL4(COD016)                                              12440000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 12460000
         B     BLNKAF                                                   12480000
*                                                                       12500000
         EJECT                                                          12520000
*        ********************                                           12540000
*        * UNPACKED NUMERIC *                                           12560000
UNPAK    TM    1(CPREG),X'02'           IS THERE A STERLING FIELD       12580000
         BO    S16                      BRANCH IF YES                   12600000
         BAL   BACKRG,F10                                               12620000
         L     WORKRG,STOREK            RELOAD PACKED LENGTH (-1)       12640000
         TM    1(CPREG),X'10'           IS THERE ZERO SUPPRESSION       12660000
         BO    ZERSUP                   BRANCH IF YES                   12680000
         L     REG1,STOREF              PUT UNPCKD/PCKD LENGTHS IN CODE 12700000
         SLL   REG1,4                   DITTO                           12720000
         OR    REG1,WORKRG              DITTO                           12740000
         STC   REG1,COD017+1            DITTO                           12760000
         NC    COD017+2(2),RESET        PUT IN ADDR. OF FIELD IN RECORD 12780000
         BAL   BACKRG,KEYSUB            CHECK NATURE OF FIELD      I222 12790000
         OC    COD017+2(2),FDSTRT+2     DITTO                           12800000
         MVC   COD017+4(2),3(CPREG)     PUT FIELD ADDRESS IN CODE       12820000
         NC    COD017+8(2),RESET   PUT ADDR OF SIGN POS. IN CODE        12840017
         NC    COD017+16(2),RESET  DITTO                                12860017
         LH    WORKRG,STOREF+2     LOAD UNPACKED LEN             A33556 12865020
         AH    WORKRG,FDSTRT+2     ADD PCKD LEN TO STARTING LOC  A33556 12870020
         STH   WORKRG,STOREH+2     STORE FOR CODE                A33556 12875020
         OC    COD017+8(2),STOREH+2 DITTO                               12880017
         OC    COD017+16(2),STOREH+2                                    12900017
         LA    WORKRG,18(DSPLRG)   PUT BRANCH ADDR IN CODE              12920017
         STH   WORKRG,COD017+12    DITTO                                12940017
         OI    COD017+12,X'90'     INSERT BASE REG 9                    12960017
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      12980000
         DC    AL2(18)             NO OF BYTES TO BE PUNCHED            13000017
         DC    AL4(COD017)                                              13020000
         LA    DSPLRG,18(DSPLRG)   INCREMENT DISPLACEMENT REGISTER      13040017
         B     BLNKAF                                                   13060000
         SPACE 3                                                        13080000
*        **********************************                             13100000
*        * ZERO SUPPRESS UNPACKED NUMERIC *                             13120000
ZERSUP   MVC   COD024+10(2),3(CPREG)    PUT FIELD ADDRESS IN CODE       13140000
         MVC   COD024+13(1),STOREF+3    PUT FIELD LENGTH IN CODE (-1)   13160000
         NC    COD024+14(2),RESET       PUT IN ADDR. OF FIELD IN RECORD 13180000
         BAL   BACKRG,KEYSUB            CHECK NATURE OF FIELD      I222 13190000
         OC    COD024+14(2),FDSTRT+2    DITTO                           13200000
         SR    REG1,REG1                OBTAIN ORIGINAL L AND ADD 1     13220000
         IC    REG1,6(CPREG)            DITTO                           13240000
         LA    REG1,1(REG1)             DITTO                           13260000
         MVI   COD024+17,X'11'          PUT EDIT PATTERN DISP. IN CODE  13280000
         TM    6(CPREG),X'01'           TEST IF LENGTH IS EVEN OR ODD   13300000
         BZ    F19                      BRANCH IF ODD                   13320000
         MVI   COD024+17,X'12'          PUT EDIT PATTERN DISP. IN CODE  13340000
         LA    REG1,1(REG1)             INCREASE LENGTH BY 1            13360000
F19      STC   REG1,COD024+1            PUT ORIGINAL FLD LENGTH IN CODE 13380000
         STC   REG1,COD024+7            REPEAT                          13400000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      13420000
         DC    AL2(18)                                                  13440000
         DC    AL4(COD024)                                              13460000
         LA    DSPLRG,18(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 13480000
         B     BLNKAF                                                   13500000
*                                                                       13520000
         EJECT                                                          13540000
*        ******************************                                 13560000
*        * NON-EDITED STERLING FIELDS *                                 13580000
S16      BAL   BACKRG,STERL1            LINK TO STERLING ROUTINE        13600000
         BAL   BACKRG,F10                                               13620000
         TM    3(TABREG),X'40'          IS THIS A PRINT FILE            13640000
         BO    S17                      BRANCH IF YES                   13660000
         TM    1(CPREG),X'10'           IS THERE ZERO SUPPRESSION       13680000
         BZ    F08A                     BRANCH IF NO                    13700000
         MVC   COD038+2(2),3(CPREG)     PUT WORK AREA ADDRESS IN CODE   13720000
         LA    REG1,4(DSPLRG)           PUT BRANCH ADDRESS IN CODE      13740000
         STH   REG1,COD038+22           DITTO                           13760000
         OI    COD038+22,X'90'         .INSERT BASE REG 9               13780000
         LA    REG1,20(REG1)            DITTO                           13800000
         STH   REG1,COD038+10           DITTO                           13820000
         OI    COD038+10,X'90'         .INSERT BASE REG 9               13840000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      13860000
         DC    AL2(24)                                                  13880000
         DC    AL4(COD038)                                              13900000
         LA    DSPLRG,24(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 13920000
         B     F08A                                                     13940000
S17      MVI   S21A+1,X'26'            *ADJUST LENGTH OF CODE           13960000
         MVI   S21A+9,X'26'            *                                13980000
         MVI   COD037+23,X'66'         *PUT DISPLACEMENT IN CODE        14000000
         MVC   COD037+4(2),3(CPREG)     PUT FIELD ADDRESS IN CODE       14020000
         SR    REG1,REG1                GET EDIT PATTERN LENGTH (-1)    14040000
         IC    REG1,6(CPREG)            DITTO                           14060000
         MVC   COD037+19(1),STOREF+3   *CORRECTED FIELD LENGTH TO CODE  14080000
         TM    3(STERRG),X'01'          TEST IF LENGTH IS EVEN OR ODD   14100000
         BZ    S19                      DITTO                           14120000
         TM    7(CPREG),X'01'           DITTO                           14140000
         BO    S20                      BRANCH IF ODD                   14160000
S18      MVI   S21A+1,X'22'            *ADJUST LENGTH OF CODE           14180000
         MVI   S21A+9,X'22'            *                                14200000
         MVI   COD037+23,X'67'         *PUT DISPLACEMENT IN CODE        14220000
         LA    REG1,1(REG1)                                             14240000
         B     S20                                                      14260000
S19      TM    7(CPREG),X'01'                                           14280000
         BO    S18                                                      14300000
S20      STC   REG1,COD036+1                                            14320000
         LA    REG1,1(REG1)                                             14340000
         STC   REG1,COD037+1                                            14360000
         SR    WORKRG,WORKRG            PUT PATTERN ADDRESS IN CODE     14380000
         IC    WORKRG,7(CPREG)          DITTO                           14400000
         LA    WORKRG,287(WORKRG)       DITTO                           14420000
         SR    WORKRG,REG1              DITTO                           14440000
         STH   WORKRG,STORED            DITTO                           14460000
         NC    COD036+4(2),RESET        DITTO                           14480000
         OC    COD036+4(2),STORED       DITTO                           14500000
         NC    COD037+20(2),RESET      *INSERT ADDR. OF FIELD IN RECORD 14520000
         BAL   BACKRG,KEYSUB            CHECK NATURE OF FIELD      I222 14530000
         OC    COD037+20(2),FDSTRT+2   *DITTO                           14540000
*                                                                       14560000
*                                       (CONTINUED NEXT PAGE)           14580000
         EJECT                                                          14600000
         SR    WORKRG,WORKRG          **CLEAR REGISTER                  14620000
         IC    WORKRG,7(CPREG)        **OBTAIN DECIMAL POSITIONS        14640000
         LA    WORKRG,1(WORKRG)       **                                14660000
         STC   WORKRG,COD037+7        **PUT LNGTH OF FIRST MOVE IN CODE 14680000
         LA    WORKRG,2(WORKRG)       **                                14700000
         STC   WORKRG,COD037+13       **PUT LGTH OF SECOND MOVE IN CODE 14720000
         SR    REG1,WORKRG            **DETERMINE MVC ADDRESSES         14740000
         LA    REG1,99(REG1)          **DITTO                           14760000
         STH   REG1,STORED            **DITTO                           14780000
         NC    COD037+14(2),RESET     **DITTO                           14800000
         OC    COD037+14(2),STORED    **DITTO                           14820000
         LA    REG1,1(REG1)           **DITTO                           14840000
         STH   REG1,STORED            **DITTO                           14860000
         NC    COD037+16(2),RESET     **DITTO                           14880000
         OC    COD037+16(2),STORED    **DITTO                           14900000
         LA    REG1,2(REG1)           **DITTO                           14920000
         STH   REG1,STORED            **DITTO                           14940000
         NC    COD037+8(2),RESET      **DITTO                           14960000
         OC    COD037+8(2),STORED     **DITTO                           14980000
         LA    REG1,1(REG1)           **DITTO                           15000000
         STH   REG1,STORED            **DITTO                           15020000
         NC    COD037+10(2),RESET     **DITTO                           15040000
         OC    COD037+10(2),STORED    **DITTO                           15060000
         TM    1(CPREG),X'10'           IS THERE ZERO SUPPRESSION       15080000
         BO    S22                      BRANCH IF YES                   15100000
         MVC   COD037+26(2),COD037+20  *                                15120000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      15140000
S21A     DC    AL2(34)                 *                                15160000
         DC    AL4(COD036)                                              15180000
         LA    DSPLRG,34(DSPLRG)       *INCREMENT DISPLACEMENT REGISTER 15200000
         B     S23                                                      15220000
S22      BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      15240000
         DC    AL2(6)                                                   15260000
         DC    AL4(COD036)                                              15280000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 15300000
         BAL   LR,DMPTXT                                                15320000
         DC    AL2(24)                 *                                15340000
         DC    AL4(COD037)                                              15360000
         LA    DSPLRG,24(DSPLRG)       *INCREMENT DISPLACEMENT REGISTER 15380000
S23      CLI   7(CPREG),X'00'           ARE THERE DECIMAL PENCE         15400000
         BE    S24                      BRANCH IF NO                    15420000
S23A     MVC   STORED(2),STOREH+2                                       15440000
         B     S25                                                      15460000
S24      L     WORKRG,STOREH            DETERMINE POS. OF STANDARD SIGN 15480000
         CH    WORKRG,CH04B            *DITTO                           15500000
         BL    S23A                     DITTO                           15520000
         SH    WORKRG,CH04B            *DITTO                           15540000
         STH   WORKRG,STORED            DITTO                           15560000
S25      NC    COD035+2(2),RESET        PUT STANDARD SIGN POS. IN CODE  15580000
         SR    LR,LR                    CLEAR WORK REG             I222 15582000
         CLI   ADDSW,C'A'               IS THIS AN ADD RECORD      I222 15584000
         BNE   KEYACC1                  NO,CHECK KEY ACCESS        I222 15586000
         LA    LR,16                    ADD SYSTEM SPACE IN WORK   I222 15588000
*                                       AREA TO ADD RCD FIELD DIS  I222 15590000
         CLI   KFND,X'FF'               IS THIS FIELD IN KEY AREA  I222 15592000
         BNE   ADDLNG                   NO, SAVE FIELD DISP        I222 15594000
         AH    LR,RECLNG                ADD RCD LNG TO FIELD DISP  I222 15596000
         B     ADDLNG                   GO, DAVE FIELD DISP        I222 15598000
*                                                                  I222 15600000
KEYACC1  TM    KEYSW,X'80'              IS KEY AREA ACCESS ALLOWE  I222 15602000
         BZ    NOINC1                   NO,DON'T ADD KEY LNG       I222 15604000
         CLI   KFND,X'FF'               IS THIS FIELD IN KEY AREA  I222 15606000
         BE    NOINC1                   YES, DON'T ADD KEY LENGTH  I222 15608000
         AH    LR,KEYLNG                ELSE, INCR DISP BY KEYLNG  I222 15610000
ADDLNG   AH    LR,STORED                GET CORRECT DISP FOR FIEL  I222 15612000
         STH   LR,STORED                                           I222 15614000
NOINC1   OC    COD035+2(2),STORED       PUT STD. SIGN POS. INTO C  I222 15616000
         OI    SIGNSW,X'08'             INDICATE SIGN MUST BE PUT OUT   15620000
         B     BLNKAF                                                   15640000
*                                                                       15660000
         EJECT                                                          15680000
*        ************************************************************** 15700000
*        * PUT OUT CODE FOR BLANK-AFTER OF NUMERIC OR ALPHA FIELD.    * 15720000
*        ************************************************************** 15740000
*                                                                       15760000
BLNKAF   TM    1(CPREG),X'08'           TEST IF BLANK AFTER             15780000
         BO    FLDEND                    BRANCH IF NO                   15800000
         TM    1(CPREG),X'20'           IS THERE A FIELD NAME           15820000
         BO    BL01                     BRANCH IF YES                   15840000
         MVC   STOREF+3(1),10(CPREG)    STORE LENGTH OF LITERAL (-1)    15860000
         MVC   COD019+2(2),7(CPREG)     PUT LITERAL ADDRESS IN USER-CDE 15880000
         MVC   COD019+8(2),7(CPREG)     REPEAT                          15900000
         MVC   STOREI+2(2),7(CPREG)     STORE LITERAL ADDRESS           15920000
         B     BL02                                                     15940000
BL01     TM    7(CPREG),X'0B'           TEST IF FIELD IS NUMERIC        15960000
         BC    12,BL05A                 BRANCH IF YES                   15980000
         MVC   COD039+5(1),6(CPREG)     PUT FIELD LENGTH IN CODE        16000000
         MVC   STOREF+3(1),6(CPREG)     STORE LENGTH OF FIELD (-1)      16020000
         MVC   COD019+2(2),3(CPREG)     PUT FIELD ADDRESS IN USER-CODE  16040000
         MVC   COD019+8(2),3(CPREG)     REPEAT                          16060000
         MVC   STOREI+2(2),3(CPREG)     STORE FIELD ADDRESS             16080000
BL02     MVI   BL04+1,X'04'                                             16100000
         MVI   BL04A+3,X'04'                                            16120000
         L     REG1,STOREF              LOAD THE LENGTH                 16140000
         LTR   REG1,REG1                CHECK FOR LENGTH OF 1           16160000
         BZ    BL03                     BRANCH IF YES                   16180000
         MVI   BL04+1,X'0A'                                             16200000
         MVI   BL04A+3,X'0A'                                            16220000
         BCTR  REG1,0                   DECREASE LENGTH BY 1            16240000
         STC   REG1,COD019+5            PUT DECREASED LENGTH IN CODE    16260000
         L     REG1,STOREI              OBTAIN ADDRESS OF START OF FLD  16280000
         LA    REG1,1(REG1)             INCREASE ADDRESS BY 1           16300000
         STH   REG1,COD019+6            PUT START+1 IN CODE             16320000
BL03     BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      16340000
BL04     DC    AL2(0)                                                   16360000
         DC    AL4(COD019)                                              16380000
BL04A    LA    DSPLRG,0(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 16400000
         B     BL06A                                                    16420000
BL05A    TM    1(CPREG),X'02'           IS THIS A STERLING FIELD        16440000
         BZ    BL05                     BRANCH IF NO                    16460000
         SR    REG1,REG1                                                16480000
         IC    REG1,SAVLNTH                                             16500000
         LA    REG1,1(REG1)                                             16520000
         SRL   REG1,1                                                   16540000
         STC   REG1,STOREK+3                                            16560000
         MVC   3(4,CPREG),STOREN        RESTORE COMPRESSION             16580000
BL05     MVC   COD020+2(2),3(CPREG)     PUT FIELD ADDRESS IN USER CODE  16600000
         MVC   COD020+4(2),3(CPREG)     REPEAT                          16620000
         MVC   COD039+5(1),STOREK+3     PUT PACKED LENGTH IN CODE       16640000
         L     REG1,STOREK              PUT PACKD LNG IN CODE FOR L1/LI 16660000
         SLL   REG1,4                    DITTO                          16680000
         O     REG1,STOREK               DITTO                          16700000
         STC   REG1,COD020+1             DITTO                          16720000
         BAL   LR,DMPTXT                 LINK TO PUNCH-CODE ROUTINE     16740000
         DC    AL2(6)                                                   16760000
         DC    AL4(COD020)                                              16780000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 16800000
*                                                                       16820000
BL06A    TM    1(CPREG),X'20'           IS THERE A FIELD NAME           16840000
         BZ    BL06                     BRANCH IF NO                    16860000
         TM    5(CPREG),X'04'           IS THIS A TABLE FIELD           16880000
         BZ    BL06                     BRANCH IF NO                    16900000
         MVC   COD039+8(2),3(CPREG)     PUT HOLD-AREA ADDRESS IN CODE   16920000
         MVC   STOREI+2(2),3(CPREG)     PUT TABLE FIELD ADDRESS IN CODE 16940000
         L     WORKRG,STOREI            DITTO                           16960000
         SH    WORKRG,CH04B             DITTO                           16980000
         STH   WORKRG,COD039+2          DITTO                           17000000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      17020000
         DC    AL2(10)                                                  17040000
         DC    AL4(COD039)                                              17060000
         LA    DSPLRG,10(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 17080000
BL06     TM    1(CPREG),X'20'           IS THERE A FIELD NAME           17100000
         BZ    FLDEND                   BRANCH IF NO                    17120000
         LA    SERVRG,PNTBLK            REINITIALIZE BLANK-AFT WORKFILE 17140000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   17160000
         LH    WORKRG,NUMBLK(CNTREG)    LOAD CYCLE REG WITH NO.OF BLCKS 17180000
         SH    WORKRG,CH04B            .REDUCE BY 4 FOR FILE DESCR RECS 17200000
         BZ    FLDEND                                                   17220000
BL07     LA    REG1,BLATAB              GET ADDR.OF BLNK-AFTER TBL AREA 17240000
         ST    WORKRG,STOREA            SAVE BLOCK COUNT                17260000
         LA    SERVRG,BLKIN             GET NEW BLOCK OF BLANK-AFTER    17280000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   17300000
         LA    REG1,BLATAB              GET ADDR.OF BLNK-AFTER TBL AREA 17320000
         LA    BCTREG,6                 LOAD BLOCKING FACTOR IN COUNTER 17340000
BL08     CLC   0(6,REG1),3(CPREG)       CHECK TBL FOR CORRECT FIELD     17360000
         BNE   BL09                     BRANCH IF NO                    17380000
         CLI   10(REG1),X'00'           IS THERE A ZERO INDICATOR       17400000
         BE    BL09                     BRANCH IF NO                    17420000
         MVC   COD022+2(2),10(REG1)     PUT RI ADDRESS IN USER-CODE     17440000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      17460000
         DC    AL2(4)                                                   17480000
         DC    AL4(COD022)                                              17500000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 17520000
BL09     LA    REG1,12(REG1)            INCREMENT TABLE ADDRESS         17540000
         BCT   BCTREG,BL08              CYCLE THROUGH BLOCK ENTRIES     17560000
         L     WORKRG,STOREA            RELOAD BLOCK COUNT              17580000
         BCT   WORKRG,BL07              CYCLE THROUGH BLOCKS            17600000
*                                                                       17620000
*                                                                       17640000
*              NOTE.....                                                17660000
*              FOR COMPATIBILITY WITH PREVIOUS VERSIONS OF RPG, WHEN A  17680000
*              FIELD IS BLANKED ANY ZERO INDICATOR IS TURNED ON BUT ANY 17700000
*              PLUS OR MINUS INDICATOR FOR THE FIELD IS NOT TURNED OFF. 17720000
*              HOWEVER, ALL THE INFORMATION NEEDED TO SET THESE OFF IS  17740000
*              CARRIED ON THE BLANK-AFTER WORK-FILE AND CAN BE UTILIZED 17760000
*              BY ADDING TO THE ABOVE ROUTINE.                          17780000
*                                                                       17800000
         EJECT                                                          17820000
*        ************************************************************** 17840000
*        * FINISH CODE FOR THIS FIELD.                                * 17860000
*        * RETURN FOR NEXT SPECIFICATION.                             * 17880000
*        ************************************************************** 17900000
*                                                                       17920000
FLDEND   TM    SIGNSW,X'08'             IS THERE A NON-STND STERL. SIGN 17940000
         BZ    F21                      BRANCH IF NO                    17960000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      17980000
         DC    AL2(6)                                                   18000000
         DC    AL4(COD035)                                              18020000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT COUNTER  18040000
F21      CLI   ABCUSE+6,CHNULL          CHECK FOR ANY UNDEF.BRANCH ADDR 18060000
         BE    INCOMP                   BRANCH IF NONE                  18080000
         MVC   J14(2),CH06B             MOVE UBA IDENTIFIER TO LINKAGE  18100000
         BAL   BACKRG,UBADEF                                            18120000
         CL    DSPLRG,CH40B                                        1578 18122015
         BL    INCOMP                                              1578 18124015
         BAL   LR,DMPTXT                OUTPUT BALR 9,0 SINCE      1578 18126015
         DC    AL2(2)                    DISP HAS EXCEEDED         1578 18128015
         DC    AL4(COD044)                DECIMAL 4032             1578 18130015
         L     WORKRG,ADDCNT(CNTREG)    GET ADDRESS                1578 18132015
         LA    WORKRG,2(DSPLRG,WORKRG)  INCREASE BY DISPL          1578 18134015
         ST    WORKRG,ADDCNT(CNTREG)    STORE IN ADDR COUNTER      1578 18136015
         SR    DSPLRG,DSPLRG            ZERO DISPL REGISTER        1578 18138015
         B     INCOMP                   RETURN NEXT COMPRESSION         18140000
*                                                                       18160000
         EJECT                                                          18180000
*        ************************************************************** 18200000
*        * SUBROUTINE.                                                * 18220000
*        * 1.DIAGNOSTICS ON STERLING FIELDS.                          * 18240000
*        * 2.SET UP  CODE FOR LINK TO STERLING CONVERSION ROUTINE.    * 18260000
*        * 3.DETERMNE CORRECT LNGTHS + ADDRESSES FOR STERLING FIELDS. * 18280000
*        ************************************************************** 18300000
*                                                                       18320000
STERL    OI    EDITSW,X'10'             INDICATE FIELD TO BE EDITED     18340000
STERL1   ST    BACKRG,STOREJ            STORE RETURN ADDRESS            18360000
         MVI   COD034+14,X'FF'          RESET LINKAGE FLAG BIT          18380000
         LR    REG1,BCTREG              SET POINTER TO STERL. SIGN POS. 18400000
         TM    1(CPREG),X'80'           DITTO                           18420000
         BZ    S01                      DITTO                           18440000
         LA    REG1,6(REG1)             DITTO                           18460000
S01      TM    1(CPREG),X'40'           DITTO                           18480000
         BZ    S02                      DITTO                           18500000
         LA    REG1,3(REG1)             DITTO                           18520000
S02      TM    1(CPREG),X'08'           DITTO                           18540000
         BO    S03                      DITTO                           18560000
         LA    REG1,2(REG1)             DITTO                           18580000
S03      CLI   10(REG1),CHS             IS IT STANDARD SIGN POSITION    18600000
         BE    S03B                     BRANCH IF YES                   18620000
         ST    REG1,STOREG                                              18640000
         TM    3(TABREG),X'40'          IS THIS A PRINT FILE            18660000
         BZ    S04                      BRANCH IF NO                    18680000
         UNPK  96(3,PRTREG),CH233       ERROR NOTE 233                  18700000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  18720000
         B     S05                                                      18740000
S03B     TM    3(TABREG),X'40'          IS THIS A PRINT FILE            18760000
         BO    S06                      BRANCH IF YES                   18780000
         CLI   7(CPREG),X'00'           ARE THERE ANY DECIMALS          18800000
         BNE   S06                      BRANCH IF YES                   18820000
         L     WORKRG,STOREH            GET THE END POSITION            18840000
         SH    WORKRG,CH03B             LOCATE UNIT POUNDS POS.FOR SIGN 18860000
         TM    STRLNG(CNTREG),X'08'     IS IT BSI OR IBM TYPE           18880000
         BO    S03C                     BRANCH IF BSI                   18900000
         BCTR  WORKRG,0                                                 18920000
S03C     ST    WORKRG,STOREP            OVERLAY STANDARD SIGN POSITION  18940000
         MVC   7(4,REG1),STOREP         DITTO                           18960000
S03A     OI    SIGNSW,X'08'             INDICATE NON-STANDARD SIGN POS. 18980000
         NC    COD035+2(2),RESET        PUT STERLING SIGN POS. IN CODE  19000000
         SR    LR,LR                    CLEAR WORK REG             I222 19001000
         CLI   ADDSW,C'A'               IS THIS AN ADD RECORD      I222 19002000
         BNE   KEYACC2                  NO, CHECK KEY AREA ACCESS  I222 19003000
         LA    LR,16                    ADD SYSTEM SPACE IN WORK   I222 19004000
*                                        AREA TO ADD RCD FIELD DI  I222 19005000
         CLI   KFND,X'FF'               IS THIS FIELD IN KEY AREA  I222 19006000
         BNE   ADDLNG2                  NO, SAVE FIELD DISP        I222 19007000
         AH    LR,RECLNG                ADD RCD LNG TO FIELD DISP  I222 19008000
         B     ADDLNG2                  GO, DAVE FIELD DISP        I222 19009000
*                                                                  I222 19010000
KEYACC2  TM    KEYSW,X'80'              IS KEY AREA ACCESS ALLOWE  I222 19011000
         BZ    NOINC2                   NO, DON'T ADD KEY LENGTH   I222 19012000
         CLI   KFND,X'FF'               IS THIS FIELD IN KEY AREA  I222 19013000
         BE    NOINC2                   YES, DON'T ADD KEY LENGTH  I222 19014000
         AH    LR,KEYLNG                ELSE, INCR DISP BY KEYLNG  I222 19015000
ADDLNG2  MVC   HWORD(2),9(REG1)         ADD REC LNG TO SIGN        I222 19016000
         AH    LR,HWORD                   POSITION IF NON-KEY-ARE  I222 19017000
         STH   LR,HWORD                   FIELD                    I222 19018000
         MVC   9(2,REG1),HWORD                                     I222 19019000
NOINC2   OC    COD035+2(2),9(REG1)      PUT STRLNG SGN. POS. IN C  I222 19020000
         B     S07                                                      19040000
S04      CLC   8(3,REG1),14(TABREG)     COMP. SIGN POS.TO RECORD LENGTH 19060000
         BL    S03A                     BRANCH IF WITHIN RECORD         19080000
         UNPK  96(3,PRTREG),CH234       ERROR NOTE 234                  19100000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  19120000
S05      L     REG1,STOREG                                              19140000
         MVC   7(4,REG1),STANDR         REPLACE SIGN POS. WITH STANDARD 19160000
S06      NI    COD034+14,X'BF'          INDICATE STANDARD SIGN POSITION 19180000
*                                                                       19200000
*                                       (CONTINUED NEXT PAGE)           19220000
         EJECT                                                          19240000
S07      MVC   COD034+13(1),7(CPREG)    PUT DECIMAL PENCE POSIT.IN CODE 19260000
         MVC   STOREN(4),3(CPREG)       STORE COMPRESS.ENTRY FOR BLNKAF 19280000
         MVC   COD034+8(4),3(CPREG)     PUT FIELD ADDRESS IN CODE       19300000
         SR    REG1,REG1                CLEAR REGISTER                  19320000
         SR    WORKRG,WORKRG            DITTO                           19340000
         TM    7(CPREG),X'0C'           IS DECIMAL LNGTH GREATER THAN 3 19360000
         BZ    S08                      BRANCH IF NO                    19380000
         UNPK  96(3,PRTREG),CH235       ERROR NOTE 235                  19400000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  19420000
         B     INCOMP                                                   19440000
*                                                                       19460000
S08      MVC   COD034+12(1),7(CPREG)    PUT DECIMAL PENCE POSIT.IN CODE 19480000
         IC    REG1,6(CPREG)            OBTAIN FIELD LENGTH             19500000
         IC    WORKRG,7(CPREG)          OBTAIN DECIMAL POSITIONS        19520000
         LA    STERRG,STRLTB-5          ADDR. OF STERLING LENGTH TABLE  19540000
         CLR   REG1,WORKRG              ARE THERE ANY INTEGER PENCE     19560000
         BL    S11                      BRANCH IF NO                    19580000
         SR    REG1,WORKRG              CALCULATE INTEGER PENCE LENGTH  19600000
         STC   REG1,STORED              STORE LENGTH                    19620000
         LA    BACKRG,12                LOAD CYCLE COUNT REGISTER       19640000
S09      LA    STERRG,5(STERRG)         INCREMENT TO NEXT TABLE ENTRY   19660000
         CLC   STORED(1),0(STERRG)      CMP INTEGER LNGTH TO TBLE ENTRY 19680000
         BE    S10                      BRANCH IF EQUAL                 19700000
         BCT   BACKRG,S09               COUNT AND EXIT AT END OF TABLE  19720000
         STM   0,15,ARGSAV              SAVE REGISTERS                  19740000
         UNPK  96(3,PRTREG),CH238       ERROR NOTE 238                  19760000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  19780000
         LM    0,15,ARGSAV              RESTORE REGISTERS               19800000
S10      TM    EDITSW,X'10'             IS THIS AN EDIT WORD FIELD      19820000
         BZ    S12                      BRANCH IF NO                    19840000
         LA    STERRG,4(STERRG)         INCREMENT TABLE POINTER         19860000
         B     S13                                                      19880000
S11      LA    STERRG,21(STERRG)        FOR LATER EVEN/ODD TEST         19900000
         TM    3(TABREG),X'40'          IS THIS A PRINT FILE            19920000
         BO    S14                      BRANCH IF YES                   19940000
         NI    COD034+14,X'7F'          INDICATE NOT A PRINT FILE       19960000
         B     S15                                                      19980000
*                                                                       20000000
*                                       (CONTINUED NEXT PAGE)           20020000
         EJECT                                                          20040000
S12      LA    STERRG,1(STERRG)         INCREMENT TABLE POINTER         20060000
         TM    3(TABREG),X'40'          IS THIS A PRINT FILE            20080000
         BO    S13                      BRANCH IF YES                   20100000
         NI    COD034+14,X'7F'          INDICATE NOT A PRINT FILE       20120000
         LA    STERRG,1(STERRG)         INCREMENT TABLE POINTER         20140000
         TM    STRLNG(CNTREG),X'04'     IS IT BSI OR IBM TYPE           20160000
         BO    S13                      BRANCH IF IBM                   20180000
         LA    STERRG,1(STERRG)         INCREMENT TABLE POINTER         20200000
S13      IC    REG1,0(STERRG)           OBTAIN NEW INTEGER LENGTH       20220000
         AR    REG1,WORKRG              ADD THE DECIMAL LENGTH          20240000
         MVC   SAVLNTH(1),6(CPREG)                                      20260000
         STC   REG1,6(CPREG)            OVERLAY COMPR. WITH NEW LENGTH  20280000
         TM    EDITSW,X'10'             IS THIS AN EDIT WORD FIELD      20300000
         BO    S14                      BRANCH IF YES                   20320000
         STC   REG1,STOREF+3            STORE NEW LENGTH                20340000
         TM    3(TABREG),X'40'          IS THIS A PRINT FILE            20360000
         BZ    S15                      BRANCH IF NO                    20380000
         BCTR  REG1,0                 **                                20400000
         BCTR  REG1,0                 **                                20420000
         STC   REG1,STOREF+3            STORE NEW LENGTH                20440000
         LA    REG1,2(REG1)                                             20460000
         IC    REG1,3(STERRG)                                           20480000
         AR    REG1,WORKRG                                              20500000
S14      LA    REG1,1(REG1)             CALCULATE PACKED LENGTH         20520000
         SRL   REG1,1                   DITTO                           20540000
S15      IC    WORKRG,CH63B             OVERLAY FLD ADDR.WITH CONVERTED 20560000
         SR    WORKRG,REG1              DITTO                           20580000
         STC   WORKRG,4(CPREG)          DITTO                           20600000
         MVI   3(CPREG),X'A0'           DITTO                           20620000
         L     BACKRG,STOREJ            RELOAD RETURN ADDRESS           20640000
         BR    BACKRG                   RETURN                          20660000
*                                                                       20680000
*****************************************************************  I222 20680600
*  SUBROUTINE  KEYSUB                                              I222 20681200
*  1. FOR I. S. ADD RECORDS - ADDS 16 TO ALL FIELD DISPLA          I222 20681800
*     CEMENTS, ADDS RECORD LENGTH TO ALL KEY AREA                  I222 20682400
*     FIELDS (WORK AREA - 16 BYTES, RCD, KEY)                      I222 20683000
*  2. FOR I. S. NON-ADD RECORDS - ADDS KEY LNG TO DATA             I222 20683600
*     FIELD DISP IF KEY AREA ACCESS ALLOWED                        I222 20684200
*  3. FOR I.S. UPDATE RECORDS - NO ACCESS TO KEY AREA FIELDS       I222 20684800
*    KEY AREA FIELDS ALLOWED (DIAGNOSED IN ASSEMBLE 4)             I222 20685400
*****************************************************************  I222 20686000
*                                                                  I222 20686600
KEYSUB   SR    LR,LR                    CLEAR WORK REG             I222 20687200
         CLI   ADDSW,C'A'               IS THIS AN ADD RECORD      I222 20687800
         BNE   KEYACC                   NO, CHECK KEY AREA ACCESS  I222 20688400
         LA    LR,16                    ADD SYSTEM SPAC IN WORK-   I222 20689000
*                                       AREA TO ADD RCD FIELD DIS  I222 20689600
         CLI   KFND,X'FF'               IS THIS FIELD IN KEY AREA  I222 20690200
         BNE   ADDLNG3                  NO, SAVE FIELD DISP        I222 20690800
         AH    LR,RECLNG                ADD RCD LNG TO FIELD DISP  I222 20691400
         B     ADDLNG3                  GO, SAVE FIELD DISP        I222 20692000
*                                                                  I222 20692600
KEYACC   TM    KEYSW,X'80'              IS KEY AREA ACCESS ALLOWE  I222 20693200
         BZ    0(BACKRG)                NO, RETURN                 I222 20693800
KEYFLD   CLI   KFND,X'FF'               IS THIS FIELD IN KEY AREA  I222 20694400
         BE    0(BACKRG)                YES,RETURN                 I222 20695000
         AH    LR,KEYLNG                ELSE, INCR DISP BY KEYLNG  I222 20695600
ADDLNG3  AH    LR,FDSTRT+2              UPDATE FIELD DISPALCEMENT  I222 20696200
         STH   LR,FDSTRT+2              AND SAVE IT                I222 20696800
         BR    BACKRG                   RETURN                     I222 20697400
         EJECT                                                          20700000
*        ************************************************************** 20720000
*        * SUBROUTINE.                                                * 20740000
*        * 1.DIAGNOSTICS ON POSITION OF FIELD WITHIN LINE.            * 20760000
*        * 2.PUT OUT CODE FOR TESTING RI'S CONDITIONING A FIELD.      * 20780000
*        * 3.PUT OUT CODE FOR HANDLING PAGE FIELDS.                   * 20800000
*        * 4.PUT OUT CODE FOR LINK TO STERLING CONVERSION ROUTINE.    * 20820000
*        ************************************************************** 20840000
*                                                                       20860000
F10      ST    BACKRG,STOREJ             STORE RETURN ADDRESS           20880000
         TM    STOREH+1,X'40'           IS THIS A KEY AREA FIELD   000H 20881000
         BZ    KFNDOFF                    NO                       I222 20882000
         MVI   KFND,X'FF'               TURN KEY AREA FLD SW ON    I222 20883000
         NI    STOREH+1,X'40'           REMOVE CODE FROM END POS   000H 20884000
         L     REG1,STOREH              END POSITION OF KEY FIELD  I222 20885000
         BCTR  REG1,0                     REDUCED BY ONE           I222 20886000
         S     REG1,STOREF              START OF KEY FIELD-1       I222 20887000
         ST    REG1,FDSTRT                                         I222 20888000
         B     F12                                                 I222 20889000
KFNDOFF  MVI   KFND,X'00'               TURN KEY AREA FIELD OFF    I222 20890000
         L     REG1,STOREH              OBTAIN END POSITION OF FIELD    20900000
         CL    REG1,RECEND              IS THIS THE HIGHEST END POS.    20920000
         BNH   F10A                     BRANCH IF NO                    20940000
         ST    REG1,RECEND              STORE NEW HIGH END POS.FOR REC. 20960000
F10A     BCTR  REG1,0                   REPLACE END POS. BY END -1      20980000
         ST    REG1,STOREH              DITTO                           21000000
         CLC   STOREF+1(3),STOREH+1     IS END POS.LARGE ENOUGH FOR FLD 21020000
         BNH   F11                      BRANCH IF YES                   21040000
         UNPK  96(3,PRTREG),CH229       ERROR NOTE 229                  21060000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  21080000
         B     INCOMP                   DROP FIELD                      21100000
F11      S     REG1,STOREF              OBTAIN START OF FIELD (-1)      21120000
         ST    REG1,FDSTRT              DITTO                           21140000
         CLC   STOREH+1(3),14(TABREG)   COMP. END POS. TO RECORD LENGTH 21160000
         BL    F12                      BRANCH IF OK                    21180000
         ST    SERVRG,STOREG                                            21200000
         UNPK  96(3,PRTREG),CH228       ERROR NOTE 228                  21220000
         BAL   BACKRG,ERROR             BRANCH TO PRINT OUT ERROR NOTE  21240000
         CLC   FDSTRT+1(3),14(TABREG)   COMP. FIELD START TO RCD LENGTH 21260000
         BNL   INCOMP                   EXIT IF FIELD OUTSIDE RECORD    21280000
         L     SERVRG,STOREG                                            21300000
         MVI   STOREG,CHNULL            CHANGE FLD LENGTH TO WITHIN RCD 21320000
         MVC   STOREG+1(3),14(TABREG)   DITTO                           21340000
         L     REG1,STOREG              DITTO                           21360000
         S     REG1,FDSTRT              DITTO                           21380000
         BCTR  REG1,0                   DITTO                           21400000
         ST    REG1,STOREF              DITTO                           21420000
F12      TM    FLD1SW,X'02'             IS THIS THE FIRST FIELD OF LINE 21440000
         BO    F12A                     BRANCH IF NO                    21460000
         OI    FLD1SW,X'02'             INDICATE FIRST FIELD PROCESSED  21480000
         LH    REG1,22(TABREG)          GET IORB DISPLACEMENT FOR FILE  21500000
         TM    ARSW,X'01'               IS FLD IN I.S. ADDED RCD   I222 21503000
         BO    ADDISP                   YES, GET WRKAR ADDR FROM   I222 21506000
*                                       IORB                       I222 21509000
         MVI   PLEN+1,X'04'             SET UP TO PUT ONLY COD015  I222 21512000
         MVI   INCDISP+3,X'04'            MODIFIES INSTRUCTION     I222 21515000
         B     SAVDISP                                             I222 21518000
ADDISP   LA    REG1,16(REG1)            POINT TO ADDR WORKL IN IO  I222 21521000
         MVI   PLEN+1,X'08'             SET UP PUT FOR COD015+SRL  I222 21524000
         MVI   INCDISP+3,X'08'            MODIFIES INSTRUCTION     I222 21527000
SAVDISP  STH   REG1,STORED              SAVE DISP TO IORB          I222 21530000
         NC    COD015+2(2),RESET        PUT RECORD ADDR INTO USER-CODE  21540000
         OC    COD015+2(2),STORED       DITTO                           21560000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      21580000
PLEN     DC    AL2(0)                   VAR LNGTH OF CODE PUNCHED  I222 21600000
         DC    AL4(COD015)                                              21620000
INCDISP  LA    DSPLRG,0(DSPLRG)         MODIFIED INSTRUCTION       I222 21626000
*  MODIFIED ONLY BY CODE BETWEEN LABEL F12 AND HERE - ZERO WILL BE 000H 21632000
* REPLACED BY 4 IF ONLY COD015 IS USED, WILL BE REPLACED BY 8 IF   000H 21638000
* SRL INSTRUCTION ALSO PUT OUT                                     000H 21644000
*                                                                  000H 21650000
         CLI   12(TABREG),CHC           IS THIS A COMBINED FILE         21660000
         BNE   F12A                     BRANCH IF NO                    21680000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      21700000
         DC    AL2(4)                                                   21720000
         DC    AL4(COD040)                                              21740000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 21760000
*                                                                       21780000
*                                       (CONTINUED NEXT PAGE)           21800000
         EJECT                                                          21820000
F12A     TM    1(CPREG),X'C0'           TEST IF ANY RESULTING INDICATOR 21840000
         BZ    F16                      BRANCH IF NO INDICATORS         21860000
         MVC   COD014+2(2),8(BCTREG)    MOVE IN FIRST RI ADDRESS        21880000
         MVI   COD014+1,X'F0'           'INDICATOR ON' TEST             21900000
         CLI   7(BCTREG),CHN            CHECK IF A 'NOT' TEST           21920000
         BNE   F13                      BRANCH IF NO                    21940000
         MVI   COD014+1,X'00'           'INDICATOR OFF' TEST            21960000
F13      BAL   BACKRG,J05                                               21980000
         TM    1(CPREG),X'80'           TEST IF ANY MORE R. INDICATORS  22000000
         BZ    F16                      BRANCH IF NO                    22020000
         MVC   COD014+2(2),11(BCTREG)   MOVE IN SECOND RI ADDRESS       22040000
         MVI   COD014+1,X'F0'           'INDICATOR ON' TEST             22060000
         CLI   10(BCTREG),CHN           CHECK IF A 'NOT' TEST           22080000
         BNE   F14                      BRANCH IF NO                    22100000
         MVI   COD014+1,X'00'           'INDICATOR OFF' TEST            22120000
F14      BAL   BACKRG,J05                                               22140000
         TM    1(CPREG),X'40'           TEST IF ANOTHER R. INDICATOR    22160000
         BZ    F16                      BRANCH IF NO                    22180000
         MVC   COD014+2(2),14(BCTREG)   MOVE IN THIRD RI ADDRESS        22200000
         MVI   COD014+1,X'F0'           'INDICATOR ON' TEST             22220000
         CLI   13(BCTREG),CHN           CHECK IF A 'NOT' TEST           22240000
         BNE   F15                      BRANCH IF NO                    22260000
         MVI   COD014+1,X'00'           'INDICATOR OFF' TEST            22280000
F15      BAL   BACKRG,J05                                               22300000
*                                                                       22320000
F16      TM    1(CPREG),X'20'           IS THERE A FIELD NAME           22340000
         BZ    F18                      BRANCH IF NO                    22360000
         TM    9(CPREG),X'80'           TEST IF FIELD IS PAGE(N)        22380000
         BZ    F18                      BRANCH IF NO                    22400000
         TM    1(CPREG),X'C0'           TEST IF ANY RESULTING INDICATOR 22420000
         BZ    F17                      BRANCH IF NO                    22440000
         L     WORKRG,STOREK            RELOAD PACKED LENGTH (-1)       22460000
         LR    REG1,WORKRG              PUT PCKD LNGTH IN CDE FOR L1/L2 22480000
         SLL   REG1,4                   DITTO                           22500000
         OR    REG1,WORKRG              DITTO                           22520000
         STC   REG1,COD020+1            DITTO                           22540000
         MVC   COD020+2(2),3(CPREG)     PUT FIELD ADDRESS IN CODE       22560000
         MVC   COD020+4(2),3(CPREG)     REPEAT                          22580000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      22600000
         DC    AL2(6)                                                   22620000
         DC    AL4(COD020)                                              22640000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 22660000
         MVC   J14(2),CH06B             MOVE UBA IDENTIFIER TO LINKAGE  22680000
         BAL   BACKRG,UBADEF                                            22700000
F17      L     REG1,STOREK              PUT PCKD LNGTH IN CDE FOR L1/L2 22720000
         SLL   REG1,4                   DITTO                           22740000
         STC   REG1,COD023+1            DITTO                           22760000
         MVC   COD023+2(2),3(CPREG)     PUT FIELD ADDRESS IN CODE       22780000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      22800000
         DC    AL2(6)                                                   22820000
         DC    AL4(COD023)                                              22840000
         LA    DSPLRG,6(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 22860000
*                                                                       22880000
*                                       (CONTINUED NEXT PAGE)           22900000
         EJECT                                                          22920000
F18      TM    1(CPREG),X'02'           IS THIS A STERLING FIELD        22940000
         BZ    F18A                     RETURN IF NO                    22960000
         BAL   BACKRG,DATOV1            LINK TO TEST FOR DATA OVERFLOW  22980000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      23000000
         DC    AL2(16)                                                  23020000
         DC    AL4(COD034)                                              23040000
         LA    DSPLRG,16(DSPLRG)        INCREMENT DISPLACEMENT REGISTER 23060000
F18A     L     BACKRG,STOREJ            RELOAD RETURN ADDRESS           23080000
         BR    BACKRG                   RETURN                          23100000
*                                                                       23120000
         EJECT                                                          23140000
*        ************************************************************** 23160000
*        * SUBROUTINE.                                                * 23180000
*        * TEST IF PRESENT FIELD ADDRESS OVERFLW KEY HAS CHANGED FROM * 23200000
*        * PREVIOUS KEY. IF CHANGED ISSUE CODE TO LOAD CORRECT VALUE. * 23220000
*        ************************************************************** 23240000
*                                                                       23260000
DATOV1   CLC   8(1,CPREG),RG7OVF        TEST IF FLD ADDR.OVERFL.CHANGED 23280000
         BE    0(0,BACKRG)              BR.IF NO CHANGE FROM PRECED.FLD 23300000
         CLI   8(CPREG),X'00'           TEST IF OVFL. INDICATOR IS ZERO 23320000
         BE    OV01                     BRANCH IF YES                   23340000
         SR    WORKRG,WORKRG            OBTAIN OVFL INDICATOR NO. (1-4) 23360000
         IC    WORKRG,8(CPREG)          DITTO                           23380000
         B     OV03                                                     23400000
DATOV2   CLC   12(1,CPREG),RG7OVF       TEST IF FLD ADDR.OVERFL.CHANGED 23420000
         BE    0(0,BACKRG)              BR.IF NO CHANGE FROM PRECED.FLD 23440000
         CLI   12(CPREG),X'00'          TEST IF OVFL. INDICATOR IS ZERO 23460000
         BE    OV01                     BRANCH IF YES                   23480000
         SR    WORKRG,WORKRG            OBTAIN OVFL INDICATOR NO. (1-4) 23500000
         IC    WORKRG,12(CPREG)         DITTO                           23520000
         B     OV03                                                     23540000
DATOV3   CLC   18(1,CPREG),RG7OVF       TEST IF FLD ADDR.OVERFL.CHANGED 23560000
         BE    0(0,BACKRG)              BR.IF NO CHANGE FROM PRECED.FLD 23580000
         CLI   18(CPREG),X'00'          TEST IF OVFL. INDICATOR IS ZERO 23600000
         BNE   OV02                     BRANCH IF NO                    23620000
OV01     MVI   RG7OVF,X'00'             SAVE INDICATOR                  23640000
         LA    REG1,LVDBS5              OBTAIN ADDR.OF DATA BASE 5 VAL. 23660000
         B     OV05                                                     23680000
OV02     SR    WORKRG,WORKRG            OBTAIN OVFL INDICATOR NO. (1-4) 23700000
         IC    WORKRG,18(CPREG)         DITTO                           23720000
OV03     STC   WORKRG,RG7OVF            SAVE PRESENT INDICATOR          23740000
         LA    REG1,LVOVF1-4            OBTAIN ADDR.OF 1ST OVRFLW VALUE 23760000
OV04     LA    REG1,4(REG1)             STEP TO NEXT OVERFLOW VALUE     23780000
         BCT   WORKRG,OV04              CYCLE TILL CORRECT VALUE REACHD 23800000
OV05     STH   REG1,COD033+2            PUT ADDR.OF VALUE INTO CODE     23820000
         OI    COD033+2,X'30'           INSERT BASE REGISTER 3          23840000
         BAL   LR,DMPTXT                LINK TO PUNCH-CODE ROUTINE      23860000
         DC    AL2(4)                                                   23880000
         DC    AL4(COD033)                                              23900000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 23920000
         BR    BACKRG                                                   23940000
*                                                                       23960000
         EJECT                                                          23980000
*        ***************************************                        24000000
*        * SUBROUTINE.                         *                        24020000
*        *  OUTPUT COMMON RI CONDITIONING CODE *                        24040000
*        ***************************************                        24060000
*                                                                       24080000
* FOLLOWING CODE ELININATES THE CLI CODE FOR L0 IN OUTPUT SPECS    000B 24085016
J05      CLI   COD014+1,X'00'          IF INDICATOR OFF TEST       000B 24090016
         BE    J0A                     GENERATE CODE               000B 24095016
         CLC   COD014+2(2),LOADD       OTHERWISE, CHK FOR L0 ADDR  000B 24100016
         BCR   8,BACKRG                IF YES, BYPASS GEN OF CLI   000B 24105016
J0A      BAL   LR,DMPTXT               LINK TO PUNCH CODE          000B 24110016
         DC    AL2(8)                                                   24120000
         DC    AL4(COD014)                                              24140000
         LA    DSPLRG,8(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 24160000
         IC    WORKRG,ABCUSE+6          INCREMENT UBA COUNTER NUMBER 6  24180000
         LA    WORKRG,1(WORKRG)         DITTO                           24200000
         STC   WORKRG,ABCUSE+6          DITTO                           24220000
         BR    BACKRG                                                   24240000
LOADD    DC    X'307A'                 BDDD REP OF L0 ADDRESS      000B 24250016
*         ************************************************************* 24251000
*         ************************************************************* 24252000
*         ************************************************************* 24253000
         DS    0D                       TO NEXT DOUBLEWORD BOUNDR  I222 24254000
CNTRL2   EQU   *                                                        24255000
*         ************************************************************* 24256000
*         ************************************************************* 24257000
         SPACE 5                                                        24260000
*        *************************************                          24280000
*        * SUBROUTINE.                       *                          24300000
*        *  UNDEFINED BRANCH ADDRESS LINKAGE *                          24320000
*        *************************************                          24340000
*                                                                       24360000
UBADEF   STH   DSPLRG,J15               ADDRESS FOR UNDEF BRANCH ADDR   24380000
         OI    J15,X'90'               .INSERT BASE REG 9               24400000
         BAL   LR,ADRDEF                LINK TO UBA DEFINING SUBROUTINE 24420000
J14      DS    CL2                                                      24440000
J15      DS    CL2                                                      24460000
         BR    BACKRG                   RETURN                          24480000
         SPACE 5                                                        24500000
*        ************************************************************** 24520000
*        * SUBROUTINE.                                                * 24540000
*        * LINK TO RPG CIOEX TO PRINT OUT ERROR NOTE                  * 24560000
*        ************************************************************** 24580000
*                                                                       24600000
ERROR    MVC   0(8,PRTREG),EDTSEQ       OBTAIN SEQ. NO. EDIT PATTERN    24620000
         ED    0(8,PRTREG),SEQNO        EDIT SPEC. SEQ. NO. INTO NOTE   24640000
ERROUT   ST    BACKRG,STOREA            STORE RETURN ADDRESS            24660000
         LA    SERVRG,PNTERR            PRINT OUT ERROR NOTE            24680000
         BALR  BACKRG,EXTREG            (LINK TO EXTERNAL SUBROUTINE)   24700000
         L     BACKRG,STOREA            RELOAD RETURN ADDRESS           24720000
         BR    BACKRG                   RETURN                          24740000
*                                                                       24760000
         EJECT                                                          24780000
         SPACE 5                                                        24980000
*        ************************************************************** 25000000
*        * CHECK IF ENOUGH ROOM IN CODE BUFFER FOR NEXT BLOCK OF CODE.* 25020000
*        * IF NOT, REMOVE UNDEFINED BR.ADDR.WHICH IS BLOCKING OUTPUT. * 25040000
*        ************************************************************** 25060000
*                                                                       25080000
DMPTXT   STM   12,13,STOREM             SAVE CONTENTS OF REGISTERS      25100000
J10      LH    12,0(LR)                 DETERMINE 'NEW CODE' LENGTH +8  25120000
         AH    12,CH08B                 DITTO                           25140000
         CL    12,SOOM                  COMPARE LNGTH TO ROOM IN BUFFER 25160000
         BNH   J11                      BRANCH TO PUNCH CODE IF ROOM    25180000
         MVC   COD006+6(2),ABCWAY       MOVE UBA IDENTIFIER TO FWD BR   25200000
         MVC   J12(2),ABCWAY            MOVE UBA IDENTIFIER TO LINKAGE  25220000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 25240000
         STH   DSPLRG,J13               ADDRESS FOR UNDEF BRANCH ADDR   25260000
         OI    J13,X'90'               .INSERT BASE REG 9               25280000
         LR    12,LR                    SAVE RETURN ADDRESS             25300000
         BAL   LR,ADRDEF                LINK TO UBA DEFINING SUBROUTINE 25320000
J12      DS    CL2                                                      25340000
J13      DS    CL2                                                      25360000
         LA    DSPLRG,4(DSPLRG)         INCREMENT DISPLACEMENT REGISTER 25380000
         STH   DSPLRG,COD006+2          PUT ADDRESS IN BRANCH           25400000
         OI    COD006+2,X'90'          .INSERT BASE REG 9               25420000
         BAL   LR,DMPTX1                LINK TO TEXT-PUNCHING SUBROUTNE 25440000
         DC    AL2(8)                                                   25460000
         DC    AL4(COD006)                                              25480000
         LR    LR,12                    RESTORE RETURN ADDRESS          25500000
         LH    12,COD006+6              INCREMENT PROPER UBA COUNTER    25520000
         LA    13,ABCUSE                DITTO                           25540000
         AR    13,12                    DITTO                           25560000
         MVI   0(13),X'01'              DITTO                           25580000
         B     J10                      RECHECK BUFFER ROOM             25600000
*                                                                       25620000
J11      LM    12,13,STOREM             RESTORE REGISTERS               25640000
*                                                                       25660000
         EJECT                                                          25680000
*        ************************************************************** 25700000
*        * SUBROUTINE FOR PUNCHING TEXT CARDS AND FILLING IN UNDEFINED* 25720000
*        * BRANCH ADDR. STORES CODE IN BUFFER TILL 56 BYTES AVAILABLE.* 25740000
*        ************************************************************** 25760000
*                                                                       25780000
DMPTX1   MVC   LENGTH(6),0(GR14) MOVE THE CALLING SEQUENCE.             25800000
         LA    GR14,6(GR14)   BUMP REGISTER OVER CALLING SEQ.           25820000
         STM   0,15,ARGSAV    SAVE ALL REGISTERS PRIOR TO ENTRY .       25840000
         L     DMPRG1,PTR1    POINTS TO THE FIRST AVAILABLE BYTE IN     25860000
         LH    DMPRG2,LENGTH  THE TEXT BUFFER.HAS THE LENGTH OF THE     25880000
         L     DMPRG3,DMPADD  SEGMENT TO BE ADDED,AND ITS ADDRESS.      25900000
         BAL   DMPRG0,DMPSUB   GO AND MOVE THE SEGMENT TO THE BUFFER.   25920000
         LA    DMPRG1,1(DMPRG1,DMPRG2) SET THE POINTER TO THE           25940000
         ST    DMPRG1,PTR1    FIRST AVAILABLE BYTE IN THE BUFFER.       25960000
         MVI   DMPFLG,X'FF'   SET HE FLAG TO SEARCH OUT THE UBA'S.      25980000
         B     ADR1                                                     26000000
DMPSUB   LA    DMPRG4,256      MOVE ALL THE MULTIPLES OF 256 BYTES      26020000
DMPSUB1  SR    DMPRG2,DMPRG4  FIRST,THEN THE REMAINDER                  26040000
         BC    12,DMPSUB2                                               26060000
         MVC   0(256,DMPRG1),0(DMPRG3)                                  26080000
         AR    DMPRG3,DMPRG4                                            26100000
         BXH   DMPRG1,DMPRG4,DMPSUB1                                    26120000
DMPSUB2  LA    DMPRG2,255(DMPRG2)                                       26140000
         EX    DMPRG2,DMPSUB3 NOW MOVE THE REMAINDER .                  26160000
         BR    DMPRG0                                                   26180000
DMPSUB3  MVC   0(0,DMPRG1),0(DMPRG3)                                    26200000
ADRDEF   MVC   DMPADD(4),0(GR14) MOVE THE CALLING SEQUENCE AF THIS CALL 26220000
         LA    GR14,4(GR14)   AND SET RETURN REGISTER.                  26240000
         STM   0,15,ARGSAV                                              26260000
         LH    DMPRG3,BDDDDFN HAS ADDRESS DEFIN. FOR THIS UBA.          26280000
         MVI   DMPFLG,X'0'    SET SWITCH THAT WE ARE DEFINING UBA'S.    26300000
ADR1     L     DMPRG1,PTRUBA  POINTS TO THE FIRST UBA FOUND IN LAST     26320000
         SR    DMPRG2,DMPRG2  CALL.                                     26340000
         XC    PTRUBA(12),PTRUBA CLEAR UBA POINTERS,AND SAVE AS FIRST   26360000
         MVC   PTRUBA(4),PTR1 UBA POINTER THE NEXT AVAIL.BYTE IN CASE  126380000
                              NO UBA'S ARE FOUND.                       26400000
         LA    DMPRG1,0(DMPRG1) BLANK OUT A POSSIBLE UBA FLAG.          26420000
ADR2     C     DMPRG1,PTR1    HAVE WE SEARCHED THROUGH THE BUFFER.      26440000
         BNL   ADRA           YES ,PUNCH AS MUCH AS POSSIBLE            26460000
         CLI   0(DMPRG1),X'47' IS THIS OPERATION A' 'BRANCH'            26480000
         BE    ADR4           YES,GO SEE WHETHER IT IS A U.B.A.         26500000
         B     ADR8                                              A20661 26510000
*                                       (CONTINUED NEXT PAGE)           26700000
         EJECT                                                          26720000
ADR4     TM    2(DMPRG1),X'F0' IS THIS BRANCH A U.B.A.                  26740000
         BC    5,ADR8         SKIP IF NOT.                              26760000
         CLI   DMPFLG,X'FF'   ARE WE DEFINING A UBA.                    26780000
         BE    ADR5           NO.                                       26800000
         CLC   IDNO(1),3(DMPRG1) IF SO DO WE DEFINE THIS UBA.           26820000
         BNE   ADR5           SKIP IF NOT.                              26840000
         STH   DMPRG3,2(DMPRG1) ELSE DEFINE THE UBA AND                 26860000
         LA    W1,ABCUSE                RESET UBA COUNTER               26880000
         SR    3,3                      ZERO COMPRESSION REG            26900000
         IC    RUSE,IDNO                DITTO                           26920000
         AR    W1,RUSE                  DITTO                           26940000
         MVI   0(W1),X'00'              DITTO                           26960000
         B     ADR8           GO TO UPDATE POINTER.                     26980000
ADR5     LA    DMPRG4,PTRUBA                                            27000000
         LA    DMPRG2,3                                                 27020000
ADR6     CLC   0(1,DMPRG4),3(DMPRG1) HAS THIS UBA BEEN POSTED.          27040000
         BE    ADR8           YES,ELSE                                  27060000
         CLI   0(DMPRG4),X'0' IS THIS STILL BLANK,                      27080000
         BNE   ADR7                                                     27100000
         ST    DMPRG1,0(DMPRG4) ELSE SAVE THE POINTER                   27120000
         MVC   0(1,DMPRG4),3(DMPRG1) AND THE FLAG.                      27140000
         B     ADR8                                                     27160000
ADR7     LA    DMPRG4,4(DMPRG4) POINT TO NEXT UBA POINTER               27180000
         BCT   DMPRG2,ADR6    POST ONLY 3 DIFFERENT UBA TYPES.          27200000
ADR8     TM    0(DMPRG1),X'C0' TEST FOR INSTRUCTION LENGTH.             27220000
         LA    DMPRG1,2(DMPRG1) ADD 2 FOR  INSTRUCTION OF LENGTH 2      27240000
         BZ    ADR2           CONTINUE                                  27260000
         LA    DMPRG1,2(DMPRG1) ADD 2 MORE FOR LENGTH 4.                27280000
         BM    ADR2           CONTINUE                                  27300000
         LA    DMPRG1,2(DMPRG1) ADD 2 MORE FOR LENGTH 6                 27320000
         B     ADR2           CONTINUE                                  27340000
ADRA     CLC   BUFFRP56+1(3),PTRUBA+1 DO WE HAVE 56 BYTES IN THE        27360000
         BNH   PUSHUP         BUFFER WITHOUT A UBA,IF NOT RETURN.       27380000
DMPTXTRN MVI   CDLEN+1,56     RESTORE CARD LENGTH OF TEXT OUTPUT.       27400000
         S     DMPRG1,BUFTOP  COMPUTE THE NUMBER OF BYTES REMAINING     27420000
         LCR   DMPRG1,DMPRG1  IN THE TEXT BUFFER.                       27440000
         ST    DMPRG1,SOOM                                              27460000
         LM    0,15,ARGSAV    RESTORE ALL REGISTERS TO RETURN.          27480000
         BR    GR14      AND RETURN TO CALLER.                          27500000
*                                                                       27520000
*                                       (CONTINUED NEXT PAGE)           27540000
         EJECT                                                          27560000
PUSHUP   EQU   *                                                        27580000
         L     DSPLRG,STOREL            RELOAD PUNCH BUFFER POINTER     27600000
         MVC   0(72,4),PFX     MOVE THE CARD PREFIX TO CIOEX PUNCH      27620000
         MVI   4(4),C' '      BUFFER AND BLANK THE FIRST BYTE OF THE    27640000
         LA    2,12           LOAD ADDRESS TO CONFORM TO TEXT NORM.     27660000
         BALR  5,7            LINK TO PUNCH ROUTINE IN CIOEX.           27680000
         LA    DMPRG1,BUFFER   NOW MOVE THE DUMP TEXT BUFFER UP         27700000
         LCR   DMPRG2,DMPRG1  56 BYTES OVERLAYING THE TEXT JUST PUT     27720000
         A     DMPRG2,PTR1    OUT VIA THE CIOEX CALL.                   27740000
         LA    DMPRG3,56(DMPRG1)                                        27760000
         BAL   DMPRG0,DMPSUB                                            27780000
         LA    DMPRG3,PTRUBA  UPDATE ALL UBA POINTERS AS WELL AS        27800000
         LA    DMPRG2,4       THE POINTER TO THE NEXT AVAILABLE BYTE    27820000
PSH1     L     DMPRG1,0(DMPRG3) IN THE DMPTXT BUFFER TO REFLECT THE     27840000
         SH    DMPRG1,CDLEN   LENGTH OF THE CARD PUNCHED OUT.           27860000
         ST    DMPRG1,0(DMPRG3)                                         27880000
         LA    DMPRG3,4(DMPRG3)                                         27900000
         BCT   DMPRG2,PSH1    SIMILARLY ADJUST THE LOAD LOCATION        27920000
         L     DMPRG2,LODLOC  COUNTER TO REFLECT THE TEXT CARD PUT      27940000
         AH    DMPRG2,CDLEN   OUT.                                      27960000
         ST    DMPRG2,LODLOC  THEN GO TO SEE WHETHER WE CANNOT          27980000
         B     ADRA           PUT OUT ANOTHER CARD.                     28000000
FINTXT   STM   0,15,ARGSAV    SAVE ALL REGISTERS PRIOR TO ENTRY .       28020000
         L     DMPRG3,PTR1    FILL WITH BLANKS THE REMAINDER            28040000
         LA    DMPRG2,BUFFER+54   OF THIS INCOMPLETE TEXT CARD          28060000
         SR    DMPRG2,DMPRG3  TO PREPARE IT FOR PUNCHING.               28080000
         LA    DMPRG1,1(DMPRG3)                                         28100000
         MVI   0(DMPRG3),C' '                                           28120000
         EX    DMPRG2,DMPSUB3                                           28140000
         LA    DMPRG1,BUFFER   NOW COMPUTE THE LENGTH OF THIS TEXT CARD 28160000
         SR    DMPRG3,DMPRG1  FOR OUTPUT.                               28180000
         BC    12,DMPTXTRN    RETURN DIRECTLY IF THE LENGTH.LE.ZERO.    28200000
         STC   DMPRG3,CDLEN+1                                           28220000
         B     PUSHUP                                                   28240000
*                                                                       28260000
         EJECT                                                          28280000
*        ************************************************************** 28300000
*        * CONSTANTS, STORAGES, INDICATORS, ETC. USED IN DMPTXT.      * 28320000
*        ************************************************************** 28340000
*                                                                       28360000
         CNOP  2,4                      ALIGN TO A HALF WORD            28380000
         DC    X'00'                    WASTE BYTE FOR ALIGNMENT        28400000
ABCWAY   DC    X'00'                    ABC OF BRANCH HOLDING UP PUNCH. 28420000
PTRUBA   DC    A(BUFFER,0,0,BUFFER)     HOLDS THE POINTERS TO THE FIRST128440000
                              UNIQUE OCCURRENCE OF UBA'S IN THE BUFFER. 28460000
PTR1     EQU   PTRUBA+12      POINTER TO THE NEXT AVAILABLE BYTE IN THE128480000
                              DMPTXT BUFFER.                            28500000
BUFFRP56 DC    A(BUFFER+56)                                             28520000
DMPAREA  DC    2F'0'          SCRATCH AREA FOR DMPTXT.                  28540000
DMPFLG   EQU   DMPAREA+1      CONTAINS ADDRESS DEFINITION SWITCH.       28560000
LENGTH   EQU   DMPAREA+2      LENGTH OF SEGMENT TO ADD.                 28580000
DMPADD   EQU   DMPAREA+4      ADDRESS OF FIRST BYTE TO BE ADDED.        28600000
IDNO     EQU   DMPAREA+5      ID NUMBER OF U.B.A TO BE DEFINED.         28620000
BDDDDFN  EQU   DMPAREA+6      'BDDD' DEFINITION FOR THIS U.B.A..        28640000
BUFTOP   DC    A(FIN)                   TOP OF BUFFER (HIGH VALUE ADDR) 28660000
SOOM     DC    A(FIN-BUFFER+1)          REMAINING BYTES IN TEXT BUFFER  28680000
ABCUSE   DC    XL10'0'                  COUNTS OF UBA USAGE             28700000
*                                                                       28720000
         EJECT                                                          28740000
*        ************************************************************** 28760000
*        * SWITCHES AND INDICATORS                                    * 28780000
*        ************************************************************** 28800000
*                                                                       28820000
ADDSW    DC    X'00'                    SIGNALS ADD RCD            I222 28822000
KEYSW    DC    X'00'                    HOLDS I.S. KEY ACCESS COD  I222 28824000
KEYLNG   DC    H'0'                     HOLDS I. S. KEY LENGTH     I222 28826000
RECLNG   DC    H'0'                     HOLDS I.S. REC LENGTH      I222 28828000
KFND     DC    X'00'                    I.S. FLD LOCATION SWITCH   I222 28830000
ARSW     DC    X'00'                    X'01' IF FLD IN I.S. ADDE  I222 28832000
*                                             RECORD               I222 28834000
ARSW1    DC    X'00'                    SAVES ADD SWITCH           I222 28836000
SWTCH1   DC    X'00'                    GENERAL SWITCH NO. 1            28840000
PROCSW   EQU   SWTCH1                  .XXXX  XXX1   LINE NOT TO BE PRO 28860000
FLD1SW   EQU   SWTCH1                   XXXX  XX1X   FIRST FLD OF LINE  28880000
ULABSW   EQU   SWTCH1                  .XXXX  X1XX   ULABL WAS USED     28900000
SIGNSW   EQU   SWTCH1                   XXXX  1XXX   NON-STND STER.SIGN 28920000
EDITSW   EQU   SWTCH1                   XXX1  XXXX   EDIT STERLING FLD. 28940000
FTOSW    EQU   SWTCH1                  .XX1X  XXXX   FTO FOR BR ADDR    28960000
NOFTAB   EQU   SWTCH1                  .X1XX  XXXX   NOT IN FD TABLE    28980000
*                                                                       29000000
*                                                                       29020000
RG7OVF   DC    X'00'                    FIELD ADDR. OVERFLOW INDICATOR  29040000
*                                                                       29060000
         SPACE 5                                                        29080000
*        ************************************************************** 29100000
*        * PACKED NUMBERS FOR ERROR NOTES                             * 29120000
*        ************************************************************** 29140000
*                                                                       29160000
CH222    DC    X'222F'                                                  29180000
CH227    DC    X'227F'                                                  29200000
CH228    DC    X'228F'                                                  29220000
CH229    DC    X'229F'                                                  29240000
CH230    DC    X'230F'                                                  29260000
CH231    DC    X'231F'                                                  29280000
CH232    DC    X'232F'                                                  29300000
CH233    DC    X'233F'                                                  29320000
CH234    DC    X'234F'                                                  29340000
CH235    DC    X'235F'                                                  29360000
CH236    DC    X'236F'                                                  29380000
CH238    DC    X'238F'                                                  29400000
*                                                                       29420000
         EJECT                                                          29440000
*        ************************************************************** 29460000
*        * CONSTANTS                                                  * 29480000
*        ************************************************************** 29500000
*                                                                       29520000
CH03B    DC    1H'0003'                                                 29540000
CH04B    DC    1H'0004'                                                 29560000
CH06B    DC    1H'0006'                                                 29580000
CH08B    DC    1H'0008'                                                 29600000
CH18B    DC    1F'18'                                                   29620000
CH40B    DC    1F'4032'                                            1578 29630015
EDTSEQ   DC    X'4020202021202020'                                      29640000
SEQNO    DC    PL4'+0'                                                  29660000
PK1      DC    PL1'+1'                                                  29680000
CH63B    DC    X'63'                    FOR LOCATING CONVERTED STERLING 29700000
RESET    DC    X'F000'                                                  29720000
STANDR   DC    C'   S'                  STANDARD SIGN POS.OVERLAY-STERL 29740000
EXTERN   DC    X'C000'                  ADDR.OVERLAY FOR REFRNCNG EXTRN 29760000
NEXTPH   DC    C'RPG10170'              NAME OF NEXT PHASE              29780000
*                                                                       29800000
         EJECT                                                          29820000
*        ************************************************************** 29840000
*        * TABLE AREA FOR BLOCKED BLANK-AFTER ENTRIES FROM WORKFILE   * 29860000
*        ************************************************************** 29880000
*                                                                       29900000
BLATAB   DS    1CL72                                                    29920000
*                                                                       29940000
         SPACE 3                                                        29960000
*        ************************************************************** 29980000
*        * BUFFER AREA FOR BUILDING RLD WORKFILE ENTRY FOR LINKAGE    * 30000000
*        ************************************************************** 30020000
*                                                                       30040000
         CNOP  2,4                     .ALIGN TO HALF WORD              30060000
         DC    X'00'                   .WASTE 1 BYTE                    30080000
RLDRCD   DC    C'X'                    .IDENTIFIER  X                   30100000
TABLAD   DS    CL4                     .TABLE ADDRESS.. ON HALFWORD BDY 30120000
BRADDR   DC    124X'00'       31  4 BYTE BRANCH ADR BUCKETS        4279 30140015
LADRID   DC    X'FD'                   .LAST ADDRESS IDENT              30160000
*                                                                       30180000
LASTFD   DC    F'0'                    .HOLD NEXT ADR.INITALY A(BRADDR) 30200000
INITFD   DC    A(BRADDR)               .ADDR OF FIRST ENTRY IN RLDX     30220000
*                                                                       30240000
         SPACE 5                                                        30260000
*        ************************************************************** 30280000
*        * STERLING FLD LNGTH CONVERSION TBL FOR PRINT,IBM,BSI,& EDIT * 30300000
*        ************************************************************** 30320000
*                                                                       30340000
STRLTB   DC    X'0006030204'                                            30360000
         DC    X'0106030204'                                            30380000
         DC    X'0206030204'                                            30400000
         DC    X'0307040305'                                            30420000
         DC    X'0408050406'                                            30440000
         DC    X'0509060507'                                            30460000
         DC    X'060A070608'                                            30480000
         DC    X'070B080709'                                            30500000
         DC    X'080C09080A'                                            30520000
         DC    X'090D0A090B'                                            30540000
         DC    X'0A0E0B0A0C'                                            30560000
         DC    X'0B0E0B0A0C'                                            30580000
*                                                                       30600000
*              NOTE.....                                                30620000
*              TO ALTER THE COMPILER SO THAT FIELDS READ IN AS STERLING 30640000
*              ARE PUT OUT WITH SAME LENGTH, THE 4TH-11TH DC'S IN ABOVE 30660000
*              TABLE SHOULD BE CHANGED TO.....                          30680000
*                          X'0306030204', X'0407040305', X'0508050406', 30700000
*                          X'0609060507', X'070A070608', X'080B080709', 30720000
*                          X'090C09080A', X'0A0D0A090B'.                30740000
*                                                                       30760000
         EJECT                                                          30780000
*        ************************************************************** 30800000
*        * STORAGE AREAS                                              * 30820000
*        ************************************************************** 30840000
*                                                                       30860000
ARGSAV   DS    16F                      SAVE AREA FOR ALL REGISTERS     30880000
FDSTRT   DS    1F                       START POSITION OF FIELD (-1)    30900000
STOREA   DS    1F                       STORE RETURN ADDRESS FOR SUBRTN 30920000
STOREB   DS    1D                       PRESENT FILENAME STORAGE        30940000
STOREM   DS    1D                       STORE REG. DURING BUFFER CHECK  30960000
STOREF   DC    F'0'                     FIELD LENGTH STORAGE (-1)       30980000
STOREG   DS    1F                       STORE REGISTER DURING SUBROUTNE 31000000
STOREH   DC    F'0'                     END POSITION OF FIELD (-1)      31020000
RECEND   DC    F'18'                    RECORD LENGTH FOR VARIABLE FILE 31040000
STOREI   DC    F'0'                     WORK STORAGE IN BLANK-AFTER     31060000
STOREJ   DS    1F                       STORE RETURN ADDR DURING FIELDS 31080000
STOREK   DS    1F                       PACKED FIELD LENGTH STORAGE(-1) 31100000
STOREL   DS    1F                       STORE POINTER TO PUNCH BUFFER   31120000
STOREN   DS    1F                       STORE UNCONVERT.STERL.FLD.ADDR. 31140000
STOREP   DS    1F                       TEMPORARY WORK STORAGE          31160000
STORED   DS    1H                       FOR TEMPORARY WORK STORAGE      31180000
HWORD    DC    H'0'                     HALF-WD OF STORAGE         I222 31190000
SAVLNTH  DS    1C                                                       31200000
*                                                                       31220000
         EJECT                                                          31240000
*        ************************************************************** 31260000
*        * CODED ROUTINES FOR OUTPUT AS MACHINE-LANGUAGE PROGRAM      * 31280000
*        ************************************************************** 31300000
*                                                                       31320000
COD006   B     0(0,0)                   BUFFER OVERFLOW                 31340000
         B     0(0,0)                                                   31360000
COD014   CLI   0(0),X'FF'               TEST RI CONDITIONING FIELD      31380000
         BNE   6(0,0)                                                   31400000
COD015   L     OUTPBS,0(0,IORBBS)       LOAD ADDR. OF RCD OUTPUT BUFFER 31420000
         SRL   OUTPBS,8                 ADJUST WORKL ADDR FROM IO  I222 31430000
COD016   MVC   0(0,OUTPBS),0(0)         MOVE FIELD INTO RECORD          31440000
COD017   UNPK  0(0,OUTPBS),0(0,0)       PUT NUMERIC FIELD INTO RECORD   31460000
         TM    0(OUTPBS),X'D0'     TEST IF FIELD NEGATIVE               31480017
         BO    0(0,0)              BRANCH IF YES                        31500017
         OI    0(OUTPBS),X'F0'     REMOVE POSITIVE SIGN ZONE            31520017
COD018   L     ULABRG,0(0,0)            LOAD ADDR. FOR ULABL REFERENCE  31540000
COD019   MVI   0(0),C' '                BLANK AFTER - ALPHA FIELD       31560000
         MVC   0(0,0),0(0)              DITTO                           31580000
COD020   SP    0(0,0),0(0,0)            BLANK AFTER - NUMERIC FIELD     31600000
*                                       ALSO- RESET PAGE NUMBER TO ZERO 31620000
COD022   MVI   0(0),X'F0'               SET ON ZERO/BLNK IND.FOR BL-AFT 31640000
COD023   AP    0(0,0),13(1,AREABS)      INCREASE PAGE NO. BY ONE        31660000
COD024   MVC   16(0,AREABS),256(AREABS) ZERO SUPPRESS NUMERIC FIELD     31680000
         ED    16(0,AREABS),0(0)                                        31700000
         MVC   0(0,OUTPBS),0(AREABS)                                    31720000
COD025   LA    1,0(AREABS)              INIT. FOR FLOATING DOLLAR       31740000
COD026   MVC   32(0,AREABS),0(0)        MOVE FLD. TO WORKAREA FOR EDIT  31760000
         ED    32(0,AREABS),0(0)        EDIT NUMERIC FIELD              31780000
COD027   MVC   0(0,OUTPBS),0(AREABS)    MOVE EDITED FIELD INTO RECORD   31800000
COD028   MVI   0(AREABS),C'$'           PLACE FIXED DOLLAR IN EDITWORD  31820000
COD029   BM    0(0,9)                   FOR BLANKING (-) STATUS         31840000
         MVI   0(AREABS),C' '                                           31860000
COD030   ZAP   60(0,AREABS),0(0,0)      INCREASE FLD LENGTH BEFORE EDIT 31880000
COD031   EDMK  32(0,AREABS),0(0)        EDIT FOR FLOATING DOLLAR        31900000
         BCTR  1,0                                                      31920000
         MVI   0(1),C'$'                PLACE FLOATING DOLLAR IN FIELD  31940000
COD032   BM    0(0,9)                   FOR BLANKING CR STATUS          31960000
         MVC   0(2,AREABS),14(AREABS)                                   31980000
COD033   L     DATBS5,0(0,0)            LOAD DATBS5 REG.WITH OVFL ADDR. 32000000
COD034   L     STRLRG,LVSTRO(0,DATBS1)  OBTAIN ADDR.OF STERLING ROUTINE 32020000
         BALR  RTRNRG,STRLRG            LINK TO STERLING CONVERSION RT. 32040000
         DC    X'B00A'                  CONSTANT IDENTIFIER FOR DMPTXT  32060000
         DS    CL8                      LINK INFORMATION                32080000
COD035   MVZ   0(1,OUTPBS),100(AREABS)  PLACE STERLING SIGN IN RECORD   32100000
COD036   MVC   102(0,AREABS),0(AREABS)  GET PATTERN FOR STERLING PRINT  32120000
         MVI   102(AREABS),X'21'        INSERT IF NO ZERO SUPPRESS      32140000
COD037   ED    101(0,AREABS),0(0)       EDIT STERLING FIELD FOR PRINT   32160000
         MVC   0(0,AREABS),0(AREABS)  **REMOVE SPACING FROM EDITED FLD  32180000
         MVC   0(0,AREABS),0(AREABS)  **DITTO                           32200000
         MVC   0(0,OUTPBS),102(AREABS)  MOVE EDITED FIELD INTO RECORD   32220000
         OI    0(OUTPBS),X'F0'          INSERT IF NO ZERO SUPPRESS      32240000
*                                                                       32260000
*                                       (CONTINUED NEXT PAGE)           32280000
         EJECT                                                          32300000
COD038   LA    ZSUPRG,0(0,0)            ZERO-SUPP. NON-PRNT STERL.FIELD 32320000
         CLI   0(ZSUPRG),C'0'                                           32340000
         BNE   0(0,9)                                                   32360000
         MVI   0(ZSUPRG),C' '                                           32380000
         LA    ZSUPRG,1(ZSUPRG)                                         32400000
         B     0(0,9)                                                   32420000
COD039   L     BLTBRG,0(0,0)            BLANK-AFTER OF TABLE FIELD      32440000
         MVC   0(0,BLTBRG),0(0)         DITTO                           32460000
COD040   LA    OUTPBS,80(OUTPBS)        COMBINED FILE OUTPUT BUFF.ADDR. 32480000
COD043   L     ULABRG,LVLNTB(0,3)      .BASE FOR RELOCATION IN LINECODE 32500000
         LA    0,0(0,0)                 LOAD RECORD LENGTH FOR IORB     32520000
         BR    LINREG                  .RETURN TO NEXT LINE             32540000
COD044   BALR  9,0                                                      32560000
         SPACE 5                                                        32580000
*            **NOTE.....                                                32600000
*              IN ORDER TO CHANGE AUTOMATIC EDITING FEATURE OF STERLING 32620000
*              ROUTINES SO THAT POUNDS, SHILLINGS, AND PENCE FIELDS ARE 32640000
*              SEPARATED BY A BLANK (AS WELL AS HAVING ZERO-SUPPRESSION 32660000
*              ON TENS POSITION) ANY INSTRUCTION ON PAGES 17,18,24 WITH 32680000
*              ** PRECEDING COMMENTS SHOULD BE OMITTED AND THOSE WITH * 32700000
*              PRECEDING COMMENTS SHOULD HAVE LENGTHS OR DISPLACEMENTS  32720000
*              ALTERED. (ALSO IN COD037 ABOVE.)                         32740000
*                                                                       32760000
         EJECT                                                          32780000
*        ************************************************************** 32800000
*        * SYMBOL DEFINITIONS FOR IMMEDIATE INSTRUCTIONS              * 32820000
*        ************************************************************** 32840000
*                                                                       32860000
CHC      EQU   C'C'                                                     32880000
CHN      EQU   C'N'                                                     32900000
CHO      EQU   C'O'                                                     32920000
CHS      EQU   C'S'                                                     32940000
CHV      EQU   C'V'                                                     32960000
CHNULL   EQU   X'00'                                                    32980000
CH0      EQU   C'0'                                                     33000000
*                                                                       33020000
         SPACE 3                                                        33040000
*        ************************************************************** 33060000
*        * REGISTERS + DISPLACEMENT ASSIGNMENT FOR OBJECT CODE.       * 33080000
*        *     NOTE. RTRNRG (14) IN LINE IS REG 1 IN FIELD            * 33100000
*        ************************************************************** 33120000
*                                                                       33140000
RTRNRG   EQU   1                       .LINKAGE RETURN FROM STERLING    33160000
ZSUPRG   EQU   1                        WORK REG.FOR ZERO-SUPP. OF STER 33180000
BLTBRG   EQU   1                        WORK REG.FOR BLANKING TABLE FLD 33200000
IORBBS   EQU   2                                                        33220000
DATBS1   EQU   3                                                        33240000
DATBS5   EQU   7                                                        33260000
AREABS   EQU   10                                                       33280000
OUTPBS   EQU   11                                                       33300000
ULABRG   EQU   12                       REG. FOR ADDRESSING EXTERNALS   33320000
LINREG   EQU   14                      .RETURN REG FROM FIELD           33340000
STRLRG   EQU   15                                                       33360000
*                                                                       33380000
LVSTRO   EQU   168                      DISPLAC. TO ADDR. OF STERL.CONV 33400000
LVDBS5   EQU   228                      DISPLAC. TO DATA BASE 5 VALUE   33420000
LVOVF1   EQU   236                      DISPLAC. TO OVERFLOW 1 VALUE    33440000
LVLNTB   EQU   268                     .DISP TO TABLE LINKAGE VECTOR    33460000
*                                                                       33480000
         EJECT                                                          33500000
*        ************************************************************** 33520000
*        * CALLING NUMBERS FOR RPG   CIOEX   SERVICE ROUTINES         * 33540000
*        ************************************************************** 33560000
*                                                                       33580000
GETCMP   EQU   0                        GET NEXT BLOCK OF COMPRESSION   33600000
PHSCAL   EQU   4                        LOAD THE NEXT PHASE             33620000
PNTERR   EQU   6                        WRITE ERROR NOTE                33640000
RLDOUT   EQU   18                       OUTPUT AN RLD RECORD            33660000
BLKIN    EQU   26                       GET NEW BLOCK OF BLANK-AFTER    33680000
PNTBLK   EQU   28                       REINIT.TO 1ST BLANK-AFTER BLOCK 33700000
PNTOUT   EQU   34                       POINT TO BLCK WITH 1ST OUT.SPEC 33720000
*                                                                       33740000
         SPACE 3                                                        33760000
*        ************************************************************** 33780000
*        * CALLING NUMBERS FOR RPG   CIOEX   TABLES AND COUNTERS      * 33800000
*        ************************************************************** 33820000
*                                                                       33840000
PHSNAM   EQU   X'08'                    NAME OF NEXT PHASE TO BE CALLED 33860000
ADDCNT   EQU   X'34'                    HIGHEST 'USER' CORE POS(BINARY) 33880000
NUMBLK   EQU   X'80'                    NO.OF BLANK-AFTER BLOCKS ON FLE 33900000
ODSPLC   EQU   X'8A'                    DISPL.TO 1ST OUTPT SPEC IN BLCK 33920000
STRLNG   EQU   X'93'                    STERLING IBM/BSI INDICATOR      33940000
SEQOUT   EQU   X'AA'                    SEQ NO. OF FIRST OUTPUT SPEC    33960000
*                                                                       33980000
         EJECT                                                          34000000
*        ************************************************************** 34020000
*        * TEXT CARD OUTPUT AREA AND CODE BUFFER FOR DMPTXT           * 34040000
*        ************************************************************** 34060000
*                                                                       34080000
         DS    0D                       FORCE TO DOUBLE WORD ALIGNMENT  34100000
PFX      DC    X'02'          T                                         34120000
         DC    C'TXT'          E  C                                     34140000
LODLOC   DC    F'0'             X  A  P                                 34160000
         DC    C'  '             T  R  R                                34180000
CDLEN    DC    H'56'                 D  E                               34200000
         DC    C'  '                     F                              34220000
         DC    X'00'                      I                             34240000
         DC    X'01'                       X                            34260000
BUFFER   DC    0C'0'                    BUFFER AREA FOR DMPTXT          34280000
         ORG   CNTRL2+6143+START-CNTRL2                                 34300000
FIN      DS    0CL1                                                     34320000
*        ************************************************************** 34340000
*        ************************************************************** 34360000
         EJECT                                                          34380000
         END   ASMBL45                                                  34400000
