         TITLE 'IES169  OS/360 RPG CIOEX OF ASSEMBLE PHASE 4.5      32' 00020000
* STATUS  CHANGE LEVEL 1-4                                         3142 00040015
*                                                                       00060000
*FUNCTION/OPERATION   THE CIOEX ROUTINES ARE A SET OF EXTERNAL          00080000
*                     SUBROUTINES WHICH PERFORM ALL OF THE INPUT/OUTPUT 00100000
*                     OPERATIONS FOR THE COMPILER PHASES.  THE CIOEX    00120000
*                     ROUTINES OPERATE IN CONJUNCTION WITH THE CIOEX    00140000
*                     DATA AREA (POINTED TO BY REGISTER 6) WHICH        00160000
*                     CONTAINS THE DCB ADDRESSES, THE PRINTER AND       00180000
*                     READER/PUNCH BUFFERS, AND INFORMATION TO BE       00200000
*                     UPDATED WITH EACH INPUT/OUTPUT OPERATION.         00220000
*                     THE INDIVIDUAL CIOEX ROUTINES AND THE FUNCTIONS   00240000
*                     THEY PERFORM ARE DESCRIBED AT THE BEGINNING       00260000
*                     OF EACH ROUTINE.                                  00280000
*                                                                       00300000
*                     THOSE CIOEX ROUTINES REQUIRED BY A PHASE          00320000
*                     ARE ASSEMBLED AS A SEPARATE MODULE AND            00340000
*                     LINK-EDITED WITH THE PARENT PHASE.                00360000
*                     THE CIOEX CSECT ALSO SERVES AS THE ENTRY POINT    00380000
*                     FOR THE PHASE LOAD MODULE.                        00400000
*                                                                       00420000
*ENTRY POINT, INITIAL   IESCEX FROM THE CALLING PHASE VIA THE XCTL MACR 00440000
*                                                                       00460000
*ENTRY POINT, CIOEX ROUTINES   IES16910 FROM IES16010                   00480000
*                              CALLING SEQUENCE   EXTRN IES16910        00500000
*                                                 L     7,CXRADDR       00520000
*                                                 LA    2,CXRCODE       00540000
*                                                 BALR  5,7             00560000
*                                                 *                     00580000
*                                                 *                     00600000
*                                                 *                     00620000
*                                        CXRADDR  DC    A(IES16910)     00640000
*                                        CXRCODE  EQU   0,2,...50 DISPL 00660000
*                                                       TO THE ADDRESS  00680000
*                                                       OF THE CIOEX    00700000
*                                                       ROUTINE WANTED  00720000
*                                                       WITHIN THE      00740000
*                                                       TRANSFER VECTOR 00760000
*                                                                       00780000
*                              ADDRESS OF THE CIOEX DATA AREA PASSED    00800000
*                              IN REGISTER 6                            00820000
*                                                                       00840000
*INPUT   REQUEST CODE FOR THE CIOEX ROUTINE WANTED IN REGISTER 2        00860000
*        CIOEX DATA AREA                                                00880000
*                                                                       00900000
*OUTPUT   COMPLETED I/O OPERATION AS REQUESTED                          00920000
*         UPDATED CIOEX DATA AREA                                       00940000
*                                                                       00960000
*EXTERNAL ROUTINES   NONE                                               00980000
*                                                                       01000000
*EXIT, INITIAL   TO IES16010                                            01020000
*                CALLING SEQUENCE   PHSLINK  L     15,PHSADDR           01040000
*                                            BALR  7,15                 01060000
*                                            *                          01080000
*                                            *                          01100000
*                                            *                          01120000
*                                   PHSADDR  DC    V(IES16010)          01140000
*                                                                       01160000
*EXIT, CIOEX ROUTINES (EXCEPT PHSCAL)   BR    5        CIOEX RETURN REG 01180000
*                                                                       01200000
*EXIT, CIOEX PHSCAL   XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA       01220000
*                                                                       01240000
*EXIT, SYNCHRONOUS I/O ERROR   SET RETURN CODE TO 20                    01260000
*                              CALL TERMINAL PHASE VIA CIOEX PHSCAL     01280000
*                                                                       01300000
*TABLES/WORK AREAS   NONE                                               01320000
*                                                                       01340000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             01360000
*                                                                       01380000
*NOTES   ALL I/O OPERATIONS ARE PERFORMED WITH BSAM                     01400000
*        THE FOLLOWING MACROS ARE USED - READ                           01420000
*                                        WRITE                          01440000
*                                        CHECK                          01460000
*                                        NOTE                           01480000
*                                        POINT                          01500000
*                                                                       01520000
IESCEX   START                                                          01540000
*0059000400                                                        3142 01550015
         ENTRY IES16910                                                 01560000
         USING CXDATA,6                                                 01580000
         USING *,15                                                     01600000
         ST    14,CXHLDREG              SAVE RETURN ADDR                01620000
PHSLINK  L     15,PHSADDR               LOAD PHASE ENTRY POINT ADDR     01640000
         BALR  7,15                     LINK TO USER PHASE              01660000
         USING *,7                                                      01680000
CXBASE   ST    13,CXSAVEAR+8            SAVE USER WORK REG, NON-VOLATLE 01700000
         LA    13,CXSAVEAR              LOAD SAVE AREA ADDR             01720000
         ST    5,CXSAVEAR               SAVE USER RETURN ADDR           01740000
         LA    5,CXRETURN               FORCE RETURN VIA CIOEX          01760000
         LH    2,CXRTAB(2)              DISP TO CIOEX ROUTINE           01780000
         AR    2,7                      ADD BASE REG                    01800000
SPECRTRN BR    2                        BRANCH TO CIOEX ROUTINE WANTED  01820000
***********************************************                         01840000
*RETURN VIA CIOEX TO RESTORE WORK REG 13                                01860000
***********************************************                         01880000
CXRETURN L     13,CXSAVEAR+8            RESTORE USER WORK REG 13        01900000
         L     5,CXSAVEAR               RESTORE USER RETURN ADDRESS     01920000
DUMRTRN  BR    5                        RETURN TO USER                  01940000
***********************************************                         01960000
*TABLE OF DISPLACEMENTS TO CIOEX ROUTINES FROM BASE REG ADDRESS         01980000
***********************************************                         02000000
CXRTAB   DC    AL2(GETCMP-CXBASE)       GET COMPRESSION      ROUTINE 0  02020000
         DC    AL2(PUTCMP-CXBASE)       PUT COMPRESSION      ROUTINE 2  02040000
         DC    AL2(PHSCAL-CXBASE)       PHASE CALL           ROUTINE 4  02060000
         DC    AL2(PNTERR-CXBASE)       PRINT ERROR NOTE     ROUTINE 6  02080000
         DC    AL2(PNTSPC-CXBASE)       PRINT SPEC           ROUTINE 8  02100000
         DC    AL2(RDSPEC-CXBASE)       READ SPEC            ROUTINE 10 02120000
         DC    AL2(PUTCOD-CXBASE)       PUNCH/GO OUTPUT      ROUTINE 12 02140000
         DC    AL2(SWITCH-CXBASE)       SWITCH WKFIL1,WKFIL2 ROUTINE 14 02160000
         DC    AL2(PTCMPR-CXBASE)       POINT COMP FOR READ  ROUTINE 16 02180000
         DC    AL2(RLDOUT-CXBASE)       WRITE RLD            ROUTINE 18 02200000
         DC    AL2(RLDIN-CXBASE)        READ RLD             ROUTINE 20 02220000
         DC    AL2(PTRLDW-CXBASE)       POINT RLD FOR WRITE  ROUTINE 22 02240000
         DC    AL2(BLKOUT-CXBASE)       WRITE BLANK AFTER    ROUTINE 24 02260000
         DC    AL2(BLKIN-CXBASE)        READ BLANK AFTER     ROUTINE 26 02280000
         DC    AL2(PTBLKW-CXBASE)       POINT BLKAFTR, WRITE ROUTINE 28 02300000
         DC    AL2(PNTINP-CXBASE)       POINT FIRST INPUT SP ROUTINE 30 02320000
         DC    AL2(PNTCLC-CXBASE)       POINT FIRST CALC SP  ROUTINE 32 02340000
         DC    AL2(PNTOUT-CXBASE)       POINT FIRST OUTPT SP ROUTINE 34 02360000
         DC    AL2(NOTEIN-CXBASE)       NOTE FIRST INPUT SP  ROUTINE 36 02380000
         DC    AL2(NOTECL-CXBASE)       NOTE FIRST CALC SP   ROUTINE 38 02400000
         DC    AL2(NOTEOT-CXBASE)       NOTE FIRST OUTPUT SP ROUTINE 40 02420000
         DC    AL2(NTASGN-CXBASE)       NOTE ANY SPEC        ROUTINE 42 02440000
         DC    AL2(PTASGN-CXBASE)       POINT TO PREV NOTE   ROUTINE 44 02460000
         DC    AL2(PHDUMP-CXBASE)       DUMP WITHIN LIMITS   ROUTINE 46 02480000
         DC    AL2(PTBLKR-CXBASE)       POINT BLKAFTR, READ  ROUTINE 48 02500000
         DC    AL2(PTRLDR-CXBASE)       POINT RLD FOR READ   ROUTINE 50 02520000
PHSADDR  DC    V(IES16010)              PHASE ENTRY POINT ADDR          02540000
DADEVT   EQU   X'20'                    DEVICE TYPE CODE FOR DIRECT ACC 02560000
IES16910 EQU   CXBASE                                                   02580000
***********************************************                         02600000
*COMMON READ/WRITE/CHECK ROUTINE FOR ALL FILES                          02620000
***********************************************                         02640000
READ     MVI   TYPE,X'80'               SET FOR READ SF                 02660000
         B     *+8                                                      02680000
WRITE    MVI   TYPE,X'20'               SET FOR WRITE SF                02700000
         LA    1,DECB                   LOAD DECB ADDR                  02720000
         STM   14,15,8(1)               STORE DCB ADDR AND AREA ADDR    02740000
         L     15,48(0,14)              LOAD DCB OFFSET                 02760000
         BALR  14,15                    LINK FOR READ/WRITE             02780000
*        CHECK DECB                                                     02800000
         LA    1,DECB                   LOAD DECB ADDR                  02820000
         L     14,8(0,1)                LOAD DCB ADDR                   02840000
         L     15,52(0,14)              LOAD CHECK ROUT ADDR            02860000
         LR    14,2                     SET FOR DIRECT RETURN TO USER   02880000
         BALR  2,15                     LINK TO CHECK                   02900000
         NOP   0                                                        02920000
***********************************************                         02940000
*SYNCHRONOUS ERROR ROUTINE                                              02960000
***********************************************                         02980000
         MVI   CXRETCDE,20              SYNCH ERROR RETURN CODE         03000000
         MVC   CXPHSNAM(8),TERMPHS      SET TO CALL TERMINAL PHASE      03020000
         B     PHSCALC                  CLOSE FILES AND RETURN TO SUPV  03040000
TERMPHS  DC    C'RPG10250'              PHASE NAME FOR TERMINAL PHASE   03060000
***********************************************                         03080000
*COMMON DECB FOR ALL FILES                                              03100000
***********************************************                         03120000
DECB     DC    F'0'                     EVENT CONTROL BLOCK             03140000
OPFLD    DC    X'00'                    OP FIELD                        03160000
TYPE     DC    X'00'                    READ/WRITE SF                   03180000
LENGFLD  DC    AL2(0)                   LENGTH FIELD                    03200000
DCBADDR  DC    A(0)                     DCB ADDRESS                     03220000
AREADDR  DC    A(0)                     AREA ADDRESS                    03240000
         DC    A(0)                     POINTER TO STATUS INDICATORS    03260000
***********************************************                         03280000
*GET COMPRESSION                                                        03300000
***********************************************                         03320000
GETCMP   TM    CXCMPOVF+1,X'F0'         TEST FOR COMPRESSION OVERFLOW   03340000
         BZ    GETCMPA                  COMPRESSION STILL IN CORE       03360000
*        READ  DECB,SF,WKFIL1,(CXCMPADD),(CXCMPEXT)                     03380000
         MVC   LENGFLD(2),CXCMPEXT+2    LENGTH OF COMPR TO DECB         03400000
         L     14,CXDCBWK1              LOAD WORK FILE 1 DCB ADDR AND   03420000
         L     15,CXCMPADD                   COMPR ADDR                 03440000
         BAL   2,READ                   LINK FOR READ                   03460000
         LH    14,CXBLKNUM              LOAD COMPR BLOCK NO. BEING PROC 03480000
         LA    14,1(14)                 INCREMENT                       03500000
         STH   14,CXBLKNUM              STORE UPDATED COMPR BLOCK NO.   03520000
GETCMPA  L     3,CXCMPADD               REINIT COMPR REG TO BEG OF BLK  03540000
         BR    5                        RETURN TO USER                  03560000
***********************************************                         03580000
*PHASE CALL ROUTINE                                                     03600000
***********************************************                         03620000
*XCTL TO NEXT PHASE GIVEN IN CIOEX DATA AREA                            03640000
***********************************************                         03660000
PHSCALC  LR    12,6                     REINIT REG 12 TO CIOEX DATA AR  03680000
PHSCAL   EQU   PHSCALC                                                  03700000
         L     14,CXHLDREG              RESTORE RETURN ADDR             03720000
         LA    9,CXPHSNAM                                               03740000
         XCTL  EPLOC=(9)                CALL NEXT PHASE                 03760000
***********************************************                         03780000
*ERROR NOTE ROUTINE                                                     03800000
***********************************************                         03820000
PNTERR   PACK  CXDUBLWD(8),PNTRAREA+96(3)                               03840000
         CVB   14,CXDUBLWD              CONVERT NOTE NUMBER TO BINARY   03860000
         LA    15,7                     MASK FOR REMAINDER              03880000
         NR    15,14                    PICK OFF REMAINDER              03900000
         SRL   14,3                     DIVIDE NOTE NUMBER BY 8         03920000
         LA    2,256                    INIT BIT TO TURN ON ERROR NOTE  03940000
         LA    15,1(15)                 INCR REMAINDER FOR BCT INSTR    03960000
PNTERRA  SRL   2,1                      ADJUST BIT TO CORRESP TO REMAIN 03980000
         BCT   15,PNTERRA                                               04000000
         IC    15,CXNOTES(14)           PICK UP ERROR NOTE BYTE         04020000
         OR    15,2                     TURN ON BIT CORRESP TO ERR NOTE 04040000
         STC   15,CXNOTES(14)           STORE UPDATED ERROR NOTE BYTE   04060000
         MVC   PNTRAREA+93(3),PNTERRB   MOVE 'IES' TO PRINT BUFF        04080000
         MVI   PNTRAREA+99,C'I'         INSERT INFORMATION IDENT        04100000
         B     PNTSPC                   PRINT ERROR NOTE                04120000
PNTERRB  DC    C'IES'                   OS/RPG PREFIX                   04140000
***********************************************                         04160000
*PRINT SPECIFICATION                                                    04180000
***********************************************                         04200000
PNTSPC   TM    CXCMPOPT,X'04'           IF NOLIST                       04220000
         BCR   1,5                        RETURN TO USER                04240000
*        WRITE DECB,SF,LSTFIL,PNTRARAC                                  04260000
         L     14,CXDCBLST              LOAD LIST FILE DCB ADDR AND     04280000
         LA    15,PNTRARAC                   PRINT BUFFER ADDR W/CTL CH 04300000
         BAL   2,WRITE                  LINK FOR WRITE                  04320000
         MVI   PNTRAREA,C' '            CLEAR                           04340000
         MVC   PNTRAREA+1(119),PNTRAREA   PRINT BUFFER                  04360000
***********************************************                         04380000
*TAKE CARE OF CARRIAGE CONTROL, OVERFLOW AND HEADING                    04400000
***********************************************                         04420000
         CLI   PNTRARAC,C'0'            WAS DOUBLE SPACE SPECIFIED      04440000
         BNE   *+10                     NO                              04460000
         SP    CXLINBCT(2),CXONEPCK     YES, DECR LINE COUNT ONE EXTRA  04480000
         MVC   PNTRARAC(1),PNTSPCA      SET CONTROL CHAR FOR NEXT PRINT 04500000
         MVI   PNTSPCA,C' '             SET FOR SING SP, NEXT PRINT + 1 04520000
         SP    CXLINBCT(2),CXONEPCK     DECREMENT LINE COUNT            04540000
         BCR   2,5                      IF POSITIVE RETURN TO USER      04560000
         MVI   PNTRARAC,C'1'            SET CONTROL CHAR FOR PAGE EJECT 04580000
         MVC   CXLINBCT(2),CXLINCNT     INIT LINE COUNT - 52 LINES      04600000
         AP    CXPAGNUM(4),CXONEPCK     INCR PAGE NUMBER                04620000
         UNPK  PNTRAREA+96(4),CXPAGNUM(4) PLACE PAGE NUM IN PRINT AREA  04640000
         OI    PNTRAREA+99,X'F0'        ERASE PLUS SIGN                 04660000
         MVC   PNTRAREA+91(4),PNTSPCB   MOVE 'PAGE' INTO PRINT BUFF     04680000
         MVC   PNTRAREA+70(8),CXTODAY   MOVE IN DATE                    04700000
         MVC   PNTRAREA+50(8),CXSTEPNA  MOVE IN STEP NAME               04720000
         MVC   PNTRAREA+40(8),CXJOBNAM  MOVE IN JOB NAME                04740000
         MVC   PNTRAREA+5(17),CXHEADIN  MOVE IN RPG/E IDENT             04760000
         MVI   PNTSPCA,C'0'             SET FOR DOUB SP, NEXT PRINT + 1 04780000
         B     PNTSPC                   PRINT HEADING LINE              04800000
PNTSPCA  DC    C' '                     SINGLE SPACE                    04820000
PNTSPCB  DC    C'PAGE'                                                  04840000
***********************************************                         04860000
*PUNCH/GO ROUTINE                                                       04880000
***********************************************                         04900000
PUTCOD   TM    CXCMPOPT,X'03'           IF NOLOAD,NODECK                04920000
         BCR   1,5                        RETURN TO USER                04940000
         MVC   72(4,4),CXPGRNAM         IDENTIFY THE CARD               04960000
         AP    CXPUNCNT(4),CXONEPCK(1)    WITH PROGRAM NAME             04980000
         UNPK  76(4,4),CXPUNCNT(4)        AND SEQUENCE NUMBER           05000000
         OI    79(4),X'F0'              ERASE PLUS SIGN                 05020000
*        WRITE DECB,SF,PNCHGO,RDRPCHAR                                  05040000
         L     14,CXDCBPGO              LOAD PUNCH/GO FILE DCB ADDR AND 05060000
         LA    15,RDRPCHAR                   PUNCH AREA ADDR            05080000
         BAL   2,WRITE                  LINK FOR WRITE                  05100000
         TM    CXCMPOPT,X'02'           TEST FOR LOAD,DECK              05120000
         BZ    PUTCODA                  NO                              05140000
         L     14,CXDCBSRC              YES, PUNCH CARD                 05160000
         LA    15,RDRPCHAR                ONTO SYSPUNCH                 05180000
         BAL   2,WRITE                                                  05200000
PUTCODA  MVI   0(4),C' '                CLEAR                           05220000
         MVC   1(79,4),0(4)               PUNCH BUFFER                  05240000
         BR    5                        RETURN TO USER                  05260000
***********************************************                         05280000
*POINT TO BEGINNING OF A FILE FOR WKFIL1, WKFIL2, WKFIL3                05300000
***********************************************                         05320000
PTCMP    L     1,CXDCBWK1               LOAD DCB ADDR                   05340000
         LA    0,256                    LOAD TTRZ BLOCK ID FOR DA, 0010 05360000
         TM    17(1),DADEVT             IS DEVICE TYPE DA               05380000
         BO    PTCMPA                   YES                             05400000
         LA    0,1                      LOAD ZZCC ID FOR TAPE, 0001     05420000
PTCMPA   ST    0,CXDUBLWD+4             STORE BLOCK ID FOR POINT        05440000
         LA    0,CXDUBLWD+4             LOAD ADDR OF BLOCK ID FOR POINT 05460000
         POINT (1),(0)                  POINT TO BLOCK 1                05480000
         XC    CXBLKNUM(2),CXBLKNUM     ZERO COMPR BLOCK NUM BEING PROC 05500000
         BR    5                        RETURN TO USER                  05520000
PTCMPR   EQU   PTCMP                                                    05540000
PTCMPW   EQU   PTCMP                                                    05560000
***********************************************                         05580000
*WORK FILE SERVICE   (REG 1 CONTAINS ADDR OF I/O AREA)                  05600000
***********************************************                         05620000
*        WRITE DECB,SF,(CXDCBWK3),(1),132                               05640000
RLDOUT   ST    1,RLDOUTE                STORE ADDR OF I/O AREA          05660000
         MVC   LENGFLD(2),RLDOUTF       SUPPLY LENGTH TO DECB           05680000
         L     14,CXDCBWK3              LOAD DCB ADDR AND               05700000
         L     15,RLDOUTE                    ADDR OF I/O AREA           05720000
         BAL   2,WRITE                  LINK FOR WRITE                  05740000
         LH    14,CXNUMRLD              LOAD FILE COUNTER               05760000
         LA    14,1(14)                 INCREMENT                       05780000
         STH   14,CXNUMRLD              STORE UPDATED COUNTER           05800000
         L     1,RLDOUTE                RESTORE REG 1 FOR USER          05820000
         BR    5                        RETURN TO USER                  05840000
RLDOUTE  DS    F                        ADDR OF I/O AREA                05860000
RLDOUTF  DC    H'132'                   LENGTH OF RECORD                05880000
***********************************************                         05900000
*WORK FILE SERVICE   (REG 1 CONTAINS ADDR OF I/O AREA)                  05920000
***********************************************                         05940000
*        WRITE DECB,SF,(CXDCBWK2),(1),72                                05960000
BLKOUT   ST    1,BLKOUTE                STORE ADDR OF I/O AREA          05980000
         MVC   LENGFLD(2),BLKOUTF       SUPPLY LENGTH TO DECB           06000000
         L     14,CXDCBWK2              LOAD DCB ADDR AND               06020000
         L     15,BLKOUTE                    ADDR OF I/O AREA           06040000
         BAL   2,WRITE                  LINK FOR WRITE                  06060000
         LH    14,CXNUMBLK              LOAD FILE COUNTER               06080000
         LA    14,1(14)                 INCREMENT                       06100000
         STH   14,CXNUMBLK              STORE UPDATED COUNTER           06120000
         L     1,BLKOUTE                RESTORE REG 1 FOR USER          06140000
         BR    5                        RETURN TO USER                  06160000
BLKOUTE  DS    F                        ADDR OF I/O AREA                06180000
BLKOUTF  DC    H'72'                    LENGTH OF RECORD                06200000
***********************************************                         06220000
*WORK FILE SERVICE   (REG 1 CONTAINS ADDR OF I/O AREA)                  06240000
***********************************************                         06260000
*        READ  DECB,SF,(CXDCBWK2),(1),72                                06280000
BLKIN    ST    1,BLKINE                 STORE ADDR OF I/O AREA          06300000
         MVC   LENGFLD(2),BLKINF        SUPPLY LENGTH TO DECB           06320000
         L     14,CXDCBWK2              LOAD DCB ADDR AND               06340000
         L     15,BLKINE                     ADDR OF I/O AREA           06360000
         BAL   2,READ                   LINK FOR READ                   06380000
         L     1,BLKINE                 RESTORE REG 1 FOR USER          06400000
         BR    5                        RETURN TO USER                  06420000
BLKINE   DS    F                        ADDR OF I/O AREA                06440000
BLKINF   DC    H'72'                    LENGTH OF RECORD                06460000
***********************************************                         06480000
*POINT TO BEGINNING OF A FILE FOR WKFIL1, WKFIL2, WKFIL3                06500000
***********************************************                         06520000
PTBLK    L     1,CXDCBWK2               LOAD DCB ADDR                   06540000
         LA    0,256                    LOAD TTRZ BLOCK ID FOR DA, 0010 06560000
         TM    17(1),DADEVT             IS DEVICE TYPE DA               06580000
         BO    PTBLKA                   YES                             06600000
         LA    0,1                      LOAD ZZCC ID FOR TAPE, 0001     06620000
PTBLKA   ST    0,CXDUBLWD+4             STORE BLOCK ID FOR POINT        06640000
         LA    0,CXDUBLWD+4             LOAD ADDR OF BLOCK ID FOR POINT 06660000
         POINT (1),(0)                  POINT TO BLOCK 1                06680000
         BR    5                        RETURN TO USER                  06700000
PHDUMP   EQU   DUMRTRN                                                  06720000
PTBLKR   EQU   PTBLK                                                    06740000
PTBLKW   EQU   PTBLK                                                    06760000
***********************************************                         06780000
*POINT CPMPRESSION TO READ THE BLOCK CONTAINING THE FIRST               06800000
*   INPUT,CALC, OR OUTPUT SPECIFICATION                                 06820000
***********************************************                         06840000
PNTOUT   TM    CXCMPOVF+1,X'F0'         DID COMPRESSION OVERFLOW        06860000
         BCR   8,5                      NO, RETURN TO USER              06880000
         LA    0,CXOUTCNT               LOAD BLOCK ID ADDR FROM NOTE    06900000
         L     1,CXDCBWK1               LOAD DCB ADDR FOR COMP          06920000
         POINT (1),(0)                  POINT                           06940000
         BR    5                        RETURN TO USER                  06960000
PUTCMP   EQU   DUMRTRN                                                  06980000
RDSPEC   EQU   DUMRTRN                                                  07000000
SWITCH   EQU   DUMRTRN                                                  07020000
RLDIN    EQU   DUMRTRN                                                  07040000
PTRLDW   EQU   DUMRTRN                                                  07060000
PNTINP   EQU   DUMRTRN                                                  07080000
PNTCLC   EQU   DUMRTRN                                                  07100000
NOTEIN   EQU   DUMRTRN                                                  07120000
NOTECL   EQU   DUMRTRN                                                  07140000
NOTEOT   EQU   DUMRTRN                                                  07160000
NTASGN   EQU   DUMRTRN                                                  07180000
PTASGN   EQU   DUMRTRN                                                  07200000
PTRLDR   EQU   DUMRTRN                                                  07220000
***********************************************                         07240000
*CIOEX DATA AREA                                                        07260000
***********************************************                         07280000
CXDATA   DSECT                                                          07300000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       07320000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 07340000
*                                         (START WITH PREPHASE)         07360000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 07380000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       07400000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   07420000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     07440000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     07460000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     07480000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        07500000
CXFLDADD DS    F                                FIELD NAME TABLE        07520000
CXLITADD DS    F                                LITERAL TABLE           07540000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 07560000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     07580000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      07600000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   07620000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                07640000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      07660000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         07680000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      07700000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    07720000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     07740000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    07760000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            07780000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    07800000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   07820000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           07840000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      07860000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  07880000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   07900000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 07920000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    07940000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         07960000
CXRETCDE DC    X'00'                    RETURN CODE                     07980000
CXIPTEOF BR    2                        LINKAGE TO EOF ROUTINE          08000000
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            08020000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          08040000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    08060000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           08080000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     08100000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    08120000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                08140000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             08160000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            08180000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     08200000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      08220000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    08240000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   08260000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        08280000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               08300000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     08320000
CXSYNERR B     4(2)                     LINKAGE TO SYNCH ERROR ROUTINE  08340000
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    08360000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     08380000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        08400000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          08420000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        08440000
CXTODAY  DC    C'  /  /  '              DATE                            08460000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             08480000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        08500000
RDRPCHAR DS    80C                      READER/PUNCH AREA               08520000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       08540000
PNTRAREA DS    120C                     PRINT AREA                      08560000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 08580000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 08600000
CXINAREA DS    F                        ADDR OF BUFFER FOR SYSIN   3142 08605015
CXDBLKAD DS    F                        ADDR OF DEBLK RTN FOR SYSIN3142 08610015
CXFDSSFT DS    F                        FILE STACKER SELECT BITS   3369 08615015
CXDEND   EQU   *                                                        08620000
         END   IESCEX                                                   08640000
