         TITLE 'IES170  OS/360 RPG I/O PHASE 1                      33' 00020000
* STATUS       CHANGE LEVEL 1-9                                  A33141 00040020
*FUNCTION/OPERATION: I/O PHASE 1 PERFORMS THE FOLLOWING FUNCTIONS-      00060000
*                                                                       00080000
*                  (1) CONSTRUCTS AND OUTPUTS A DCB AND WORK AREA FOR   00100000
*                      EACH FILE.                                       00120000
*                                                                       00140000
*                  (2) CONSTRUCTS AND OUTPUTS AND IORB (INPUT/OUTPUT    00160000
*                      REQUEST BLOCK) FOR EACH FILE.                    00180000
*                                                                       00200000
*                  (3) CONSTRUCTS POINTER TABLES AND PASSES THEM ON     00220000
*                       TO I/O PHASE 2.                                 00240000
*                                                                       00260000
*                  (4) LOCATE AND OUTPUT LINE COUTER TABLES.            00280000
*                                                                       00300000
*ENTRY POINT:  IES17010 FROM IES17910                                   00320000
*              PHSLINK   L    15,PHSADDR                                00340000
*                       BALR 7,15                                       00360000
*                                                                       00380000
*                                                                       00400000
*              PHSADDR   DC   V(IES17010)                               00420000
*                                                                       00440000
*              POINTERS COUNTERS, AND CONSTANTS PASSED IN               00460000
*              CIOEX DATA AREA POINTERED TO BY REGISTERS                00480000
*              6 AND 12 UPON ENTRY.                                     00500000
*INPUT:        COMPRESSION - SYSUT1                                     00520000
*                                                                       00540000
*                                                                       00560000
*OUTPUT:       DCB'S, WORK AREAS, IORB'S AND LINE COUNTER TABLE-        00580000
*              SYSPUNCH/SYSGO.                                          00600000
*                                                                       00620000
*              POINTER TABLES AND DRIVER POINTER - SYSUT3               00640000
*                                                                       00660000
*                                                                       00680000
*EXTERNAL ROUTINES: IES17910 - CIOEX ROUTINES FOR I/O PHASE 1.          00700000
*                                                                       00720000
*              BLKOUT  - OUTPUT TO BLANK AFTER FILE                     00740000
*                                                                       00760000
*              PNTBLK  - REINITIALIZE BLANK AFTER FILE TO BEGINNING     00780000
*                                                                       00800000
*              PNTCMP  - REINITIALIZE WORKFILE CONTAINING COMPRESSION.  00820000
*                                                                       00840000
*              PUTCOD  - PUT ASSEMBLY OUTPUT ON SYSGO/SYSPCH            00860000
*                                                                       00880000
*              PHSCAL  - LOAD NEXT PHASE                                00900000
*EXITS - NORMAL: VIA PHSCAL                                             00920000
*                                                                       00940000
*      - ERROR:   NONE                                                  00960000
*                                                                       00980000
*TABLES/WORK AREAS: NONE                                                01000000
*                                                                       01020000
*                                                                       01040000
*ATTRIBUTES: EDITABLE, DOWNWARD COMPATIBLE                              01060000
*                                                                       01080000
*NOTES:  CAUTION- THE LENGTHS OF THE I/O DRIVERS MUST BE OBTAINED       01100000
*                 FROM I/O 2 AND ENTERED IN I/O 1 AS EQUATES.           01120000
         SPACE 10                                                       01140000
*   *****************************************************************   01160000
*   * THE OPERATION OF THIS ROUTINE (INPUT-OUTPUT PHASE COMPILER)   *   01180000
*   * DEPENDS UPON AN INTERNAL REPRESENTATION OF THE EXTERNAL       *   01200000
*   * CHARACTER SET WHICH IS EQUIVALENT TO THE ONE USED AT ASSEMBLY *   01220000
*   * TIME.  THE CODING HAS BEEN ARRANGED SO THAT REDEFINITION OF   *   01240000
*   * 'CHARACTER' CONSTANTS BY REASSEMBLY WILL RESULT IN CORRECT    *   01260000
*   * CODES FOR THE NEW DEFINITION OF THE INTERNAL CHARACTER SET.   *   01280000
*   *****************************************************************   01300000
         EJECT                                                          01320000
IES17010 START                                                          01340000
*0143000400,013500-013600,082000,121200                            000I 01348017
*0143038400,038800,041400,041800-042000,066200,066600-066800       000Z 01356017
*0143091000-092400,094000,094400,095800,096200,157200-157400       000Z 01364017
*0143157800-158000,166200,166600-166800,171000,178200              000Z 01372017
* 029060-029120,029500,069440-070120,070550-071100,072200-073000   I222 01373000
* 100820-100920,145400,146500,146510-146650,147100,148820-149820   I222 01374000
* 149807-150192,184660-184720,200210-200300,204700                 I222 01375000
* 153660-153720,155060-155120,155460-155520,164871-164873        A21747 01376000
IOPHASE  EQU   *                                                        01380000
*              *****************************************                01400000
*              * REGISTER DEFINITIONS USED IN IO PHASE *                01420000
*              *****************************************                01440000
X0       EQU   0         R    VOLATILE WORK REGISTER                    01460000
LCT      EQU   1         R    LOCATION COUNTER REGISTER                 01480000
SLVRG2   EQU   1         R T   TEXT OUTPUT UTILITY                      01500000
SERVRG   EQU   2         R    SERVICE ROUTINE REGISTER                  01520000
X2       EQU   2    V    R              WORK REGISTER                   01540000
COMPR    EQU   3        *R    COMPRESSION POINTER REGISTER (55 BYTES)   01560000
PUNBUFFR EQU   4        *R    PERMANENT POINTER TO PUNCH BUFFER(CIOEX)  01580000
RETURN   EQU   5         R    RETURN REGISTER FOR BAL AND BALR INSTRUC. 01600000
X5       EQU   5         R    WORK REGISTER                             01620000
DATA     EQU   6        *R    DATA SECTION BASE REGISTER                01640000
IODRIVRG EQU   7        *R    CIOEX IO DRIVER REGISTER                  01660000
RQSTPT   EQU   IODRIVRG       FOR OUTPUT VIA CIOEX                      01680000
IOPHASER EQU   8        *R    IO PHASE BASE REGISTER                    01700000
FILE#    EQU   9         R    FILE NUMBER IN REGISTER                   01720000
IOPRINTR EQU   10       *R    CIOEX IO PRINT REGISTER                   01740000
X10      EQU   10        R    DCB  BASE REGISTER                        01760000
CNTREG   EQU   11        R T  NO.OF BYTES TO BE PUT INTO TEXT           01780000
X11      EQU   11        R         WORK REGISTER                        01800000
LOCREG   EQU   12        R T  LOCATION OF TEXT IN CORE TO BE PUNCHED    01820000
X12      EQU   12        R         WORK REGISTER                        01840000
ADDREG   EQU   13        R T  ADDRESS TO GO ON TXT CARD ORIGIN          01860000
X13      EQU   13   V    R    TO GET A BLOCK OF COMPRESSION + WORK REG. 01880000
*           ON ENTRY TO IOPHSE REG 13 POINTS TO SAVE AREA IN CONTROL PR 01900000
DCBREG   EQU   14   V    R    POINTS TO DCB POINTER TABLE               01920000
SLVRG1   EQU   15   V    R T   TEXT OUTPUT UTILITY                      01940000
X15      EQU   15   V    R        WORK REGISTER                         01960000
DISPLACR EQU   15    V   R    BYTE DISPLACEMENT FOR DCB/WA OUTPUT       01980000
XR1      EQU   1                                                   000Z 01982017
XR2      EQU   2                                                   000Z 01984017
XR5      EQU   5                                                   000Z 01986017
XR7      EQU   7                                                   000Z 01988017
XR8      EQU   8                                                   000Z 01990017
XR10     EQU   10                                                  000Z 01992017
XR14     EQU   14                                                  000Z 01994017
XR15     EQU   15                                                  000Z 01996017
*                                                                       02000000
*            *******************************************************    02020000
*            **DISPLACEMENT OF 'CONSTANTS' FROM DATA REGISTER (=6) *    02040000
*            *******************************************************    02060000
*        *************************************************************  02080000
*        * THE VALUES OF THE FOLLOWING EQU'S ARE OBTAINED FROM I/O   *  02100000
*        * PHASE 2 THUS CARE MUST BE TAKEN TO INSURE THAT ANY CHANGE *  02120000
*        * IN THE VALUES IN I/O 2 ARE REFLECED HERE.                 *  02140000
*        *                                                           *  02160000
*        *************************************************************  02180000
*                                                                       02200000
IORPGSZE EQU   X'2D8'                   LENGTH OF IORPG            I222 02220000
QSWRSIZE EQU   X'E0'                                             A22156 02240000
QSLNSIZE EQU   222      LENGTH OF LINE                                  02260000
BSAMSIZE EQU   X'AC'                   LENGTH OF BSAM            A27112 02280000
QSAMSIZE EQU   X'C8'               LENGTH OF QSAM                A27505 02300020
QSPRSIZE EQU   172       LENGTH OF QSAM PRINT ROUTINE                   02320000
ISAMSIZE EQU   X'4E2'              LENGTH OF OBJ ISAM RTN        A31061 02340020
BDAMSIZE EQU   X'D6'         LENGTH OF OBJ TIME INTERFACE RTN      1115 02360014
*                                                                       02380000
ADDCNT   EQU   X'34'          DISPLACEMENT FROM REGISTER 6 (DATA)       02400000
PHSNAM   EQU   8          DISPLACEMENT OF PHASE NAME IN CIOEX           02420000
EXTCNT   EQU   X'7C'         'EXTERNAL' ESD COUNTER DISPLACEMENT        02440000
FSSBIT   EQU   X'21C'        FILE STACKER SELECT BITS              3369 02450015
*                                                                       02460000
*            *********************************                          02480000
*            * LINKAGES TO RESIDENT ROUTINES *                          02500000
*            *********************************                          02520000
*                                                                       02540000
GETCMP   EQU   0              SERV ID TO READ A COMPR BLOCK AND SET PTR 02560000
RLDOUT   EQU   18                  FOR RLD CARD OUTPUT                  02580000
PHSCAL   EQU   4         CIOEX NEXT PHASE LINK ROUTINE                  02600000
PNTCMP   EQU   16             SERVICE ID TO REWIND THE COMPRESSION FILE 02620000
PUNCOD   EQU   12             CIOEX CODE FOR OUTPUT ON SYSPUNCH OR GO   02640000
PNTBLK   EQU   28        REINITIALIZE BLANK-AFTER FILE                  02660000
BLKOUT   EQU   24        OUTPUT TO BLANK-AFTER FILE                     02680000
         EJECT                                                          02700000
*                   *****************************                       02720000
*                   * COMPRESSION DISPLACEMENTS *                       02740000
*                   *****************************                       02760000
FILENAME EQU   1              FILE NAME  (GOES TO DDNAME IN DCB)        02780000
FILETYPE EQU   9              FILE TYPE (=INPUT,OUTPUT,UPDATE,COMBINED) 02800000
FILEDESG EQU   10             FILE DESIGNATION (=P,S,C,R,T.OR BLANK)    02820000
FILEFORM EQU   13             FILE FORMAT (=FIXED OR VARIABLE)          02840000
BLKLENGT EQU   14             BLOCK LENGTH                              02860000
RECLENGT EQU   17             RECORD LENGTH                             02880000
FILEMODE EQU   20                 MODE OF PROCESSING (FILE DESCRIP)     02900000
KEYLENGT EQU   21                  KEY LENGTH                      I222 02906000
CYLOFL   EQU   23                  CYLINDER OVERFLOW               I222 02912000
RAFTYPE  EQU   23        RECORD ADDRESS TYPE (I, K, OR BLANK)           02920000
FILEORG  EQU   24             FILE ORGANIZATION (=IND SEQ,DIRECT,BLANK) 02940000
KEYLOC   EQU   25                  KEY LOCATION                    I222 02950000
EXTNCODE EQU   29             EXTENSION CODE (=L,E,BLANK)               02960000
DDEVICE  EQU   30                       DISPL TO DEVICE ENTRY IN COMPR  02980000
LABEL    EQU   37             LABEL EXIT ADDRESS (=X'00' IF STANDARD)   03000000
         SPACE 4                                                        03020000
*                   *****************************                       03040000
*                   * PROGRAM EQUIVALENCE CARDS *                       03060000
*                   *****************************                       03080000
*                                                                       03100000
FILES    EQU   10             NO.OF FILES ALLOWED BY RPG                03120000
* *****************************************************************     03140000
* * NOTE-  THE NUMBER OF FILES GIVEN ABOVE MUST ALWAYS EQUAL THE **     03160000
* *        NUMBER OF FILES ALLOWED IN THE RPG SPECIFICATIONS     **     03180000
* *****************************************************************     03200000
PRNPNCLR EQU   B'11111100'        TO CLEAR PRINT/PUNCH BITS FROM FLAGS  03220000
PRNTPNCH EQU   B'00000011'         BITS FOR TEST OF FLAGS               03240000
PRINTFLG EQU   B'00000010'         *    *   *    *  *                   03260000
PUNCHFLG EQU   B'00000001'         *    *   *    *  *                   03280000
OPENIN   EQU   128                      'OPEN' INPUT PARAMETER          03300000
OPENOUT  EQU   143                      'OPEN' OUTPUT PARAMETER         03320000
OPENUP   EQU   132                      'OPEN' UPDAT PARAMETER          03340000
OPENIO   EQU   X'83'                    'OPEN' INOUT PARAMETER          03360000
*              ************************                                 03380000
*              * DCB PARAMETERS BELOW *                                 03400000
*              ************************                                 03420000
*                                                                       03440000
F$RECFM  EQU     B'10000000'       SETS 'F' IN RECFM   (FIXED RECORDS)  03460000
B$RECFM  EQU     B'00010000'       SETS 'B' IN RECFM   (BLOCKED RECRDS) 03480000
V$RECFM  EQU     B'01000000'       SETS 'V' IN RECFM   (VARIABLE RECS.) 03500000
S$RECFM  EQU     B'10001000'       SETS 'S' IN RECFM  (STANDARD BLOCKS) 03520000
A$RECFM  EQU     B'00000100'       SETS 'A' IN RECFM   (ASA CODE-PUNCH) 03540000
M$RECFM  EQU     B'00000010'       SETS 'M' IN RECFM (MACHNE CODE-PRNT) 03560000
SU$RECFM EQU   B'01001000'        SET 'VS' IN RECFM  (VAR SPANNED) 000I 03566017
SB$RECFM EQU   B'01011000'        SET 'VBS' IN RECFM  (VAR BLK SPA)000I 03572017
*                                                                       03580000
G$MACRF  EQU     B'01010010'       SETS MACRF FOR GET(MOVE MODE)& CNTRL 03600000
NC$MACRF EQU   B'01010000'        GET(MOVE) NO CNTRL               3369 03610015
P$MACRF  EQU     B'01010000'       SETS MACRF+1 FOR PUT(MOVE MODE)      03620000
W$MACRF  EQU   B'00100000'         SETS MACRF FOR WRITE                 03640000
RC$MACRF EQU   B'00100010'         SETS MACRF FOR READ AND CNTRL        03660000
*                                                                       03680000
         EJECT                                                          03700000
*       *************************************************************   03720000
*       * SAVE REGISTERS, INITIALIZE COMPRESSION FILE,              *   03740000
*       *   ALIGN THE LOCATION COUNTER & INITIALIZE POINTER VECTORS *   03760000
*       *************************************************************   03780000
*                                                                       03800000
         USING IHADCB,10                USE REG 10 FOR DCB BASE         03820000
IOPHSE   BALR  XR8,0                                               000Z 03840017
         USING *,IOPHASER               BASE REG 8 FOR I/O 1       000Z 03860017
         ST    XR10,SAV10            SAVE REGISTER 10 FOR WHOLE    000Z 03880017
         L     LCT,ADDCNT(DATA)    PICK IP LOCN COUNTER ADDRESS         03900000
         BAL   RETURN,ALIGNLCT     TO ALIGN LCT ON DBL WORD BOUNDARY    03920000
*                                                                       03940000
         LA    X10,DCB$                 POINT R10 TO DCB SETUP AREA     03960000
         LA    FILE#,1             SET FILE NO.= 1                      03980000
         ST    LCT,FWHOLD                                               04000000
         MVC   PVDCB(4),FWHOLD     STORE ADDRESS OF FIRST POINTER       04020000
         LA    LCT,TABLPASS(LCT)   BUMP LOCN CNTR OVER DCB+WA PTRS      04040000
         ST    LCT,FWHOLD                                               04060000
         MVC   PVLCTR(4),FWHOLD    STORE ADDRESS OF QSLN (1ST DRVR PTR) 04080000
         LA    LCT,DRIVPASS(LCT)   BUMP LOCN CNTR OVER DRIVER POINTERS  04100000
         SPACE 2                                                        04120000
         STM   XR14,XR2,SAV2      **************************       000Z 04140017
         LA    SERVRG,PNTCMP      * INITIALIZE CPMPRESSION *            04160000
         BALR  XR5,XR7            **************************       000Z 04180017
         LM    XR14,XR2,SAV2            RESTORE REGISTERS(VOLATILE)000Z 04200017
         LA    DCBREG,DCBPTR       DCB PTR REGISTER POINTS TO DCB PTR   04220000
         SPACE 2                                                        04240000
*                                 ******************************        04260000
IO0      BAL   X13,NEWBLOCK       *READ A BLOCK OF COMPRESSION *        04280000
*                                 ******************************        04300000
IO1A     CLI   0(COMPR),C'F'      *TEST FOR FILE DESCRIPTION COMPR.*    04320000
         BE    IOPH2               OUT TO IOPH2 IF YES                  04340000
*                                                                       04360000
*  * IOPH2 CONTROLS PROCESSING AND PUNCHING OF DCB'S WITH THEIR WORK  * 04380000
*  *   AREAS AND THE STORAGE OF THEIR POINTERS INTO THE POINTER TABLES* 04400000
         SPACE 2                                                        04420000
         CH    FILE#,HALFONE            WERE THERE ANY FILE DESCR SPECS 04440000
         BE    CALLDIAG                 NO, CALL DIAG 1                 04460000
*                                                                       04480000
         CLI   0(COMPR),X'FF'     *TEST FOR END OF BLOCK                04500000
         BE    IO0                 GET NEXT BLOCK IF YES                04520000
*                                                                       04540000
*     ***********************************************************       04560000
*     * DCB'S AND WORK AREAS ARE ALL ON TXT CARDS AT THIS POINT *       04580000
*     ***********************************************************       04600000
*                                                                       04620000
         STH   FILE#,FNFLAG        STORE NO.OF FILES+1                  04640000
         LA    FILE#,1             SET FILE# = 1                        04660000
         CL    FILE#,QSLNPTR       IS LINE CTR USED (I.E. GRTR THAN 1)  04680000
         BH    IO3I                AROUND IF NO LINE CTR SPECS.         04700000
         EJECT                                                          04720000
*              *************************************************        04740000
*              * LOCATE LINE COUNTER TABLES AND OUTPUT AS TEXT *        04760000
*              *************************************************        04780000
*                                                                       04800000
         ST    LCT,PVFLCT          STORE ADDRESS INTO LN CTR TABLE PTR  04820000
*                                                                       04840000
IO3      CLI   0(COMPR),C'L'       IS THIS A LINE COUNTER ENTRY?        04860000
         BE    IO3L                YES                                  04880000
*                                                                       04900000
         CLI   0(COMPR),C'E'    NO - IS IT AN EXTENSION ENTRY?          04920000
         BE    IO3E                YES                                  04940000
*                                                                       04960000
         CLI   0(COMPR),C'R'    NO - IS IT AN RAF ENTRY?                04980000
         BE    IO3R                YES                                  05000000
*                                                                       05020000
         CLI   0(COMPR),C'T'    NO - IS IT A TABLE ENTRY?               05040000
         BE    IO3T                YES                                  05060000
*                                                                       05080000
         CLI   0(COMPR),X'FF'   NO - IS IT THE END OF BLOCK?            05100000
         BNE   IO3Z                DONE IF NO                           05120000
*                                  YES, END OF BLOCK                    05140000
         BAL   X13,NEWBLOCK        GET NEXT BLOCK OF COMPRESSION        05160000
         B     IO3                                                      05180000
*                                                                       05200000
*              UPDATE COMPR TO PASS OVER AN EXTENSION ENTRY             05220000
IO3E     CLI   8(COMPR),C' '       BLANK TEST                           05240000
         BE    IO3E1                                                    05260000
         LA    COMPR,9(COMPR)      NO, SKIP 18 BYTES                    05280000
IO3E1    LA    COMPR,9(COMPR)      YES, SKIP 9 BYTES                    05300000
         B     IO3                                                      05320000
*                                                                       05340000
*              UPDATE COMPR TO PASS OVER AN RAF ENTRY                   05360000
IO3R     CLI   14(COMPR),C' '      BLANK TEST                           05380000
         BE    IO3R1                                                    05400000
         LA    COMPR,9(COMPR)      NO, SKIP 24 BYTES                    05420000
IO3R1    LA    COMPR,15(COMPR)     YES, SKIP 15 BYTES                   05440000
         B     IO3                                                      05460000
*                                                                       05480000
*              UPDATE COMPR TO PASS OVER A TABLE ENTRY                  05500000
IO3T     CLI   24(COMPR),C' '      BLANK TEST                           05520000
         BE    IO3T1                                                    05540000
         LA    COMPR,12(COMPR)     NO, SKIP 37 BYTES                    05560000
IO3T1    LA    COMPR,25(COMPR)     YES,SKIP 25 BYTES                    05580000
         B     IO3                                                      05600000
         EJECT                                                          05620000
*     ********************************************************          05640000
*     * OUTPUT(PUNCH) A LINE COUNTER TABLE(27 BYTES) AS TEXT *          05660000
*     ********************************************************          05680000
*                                                                       05700000
IO3L     LR    LOCREG,COMPR             TEST ADDRESS = COMPR            05720000
         LA    CNTREG,27                BYTE COUNT = 27                 05740000
         LR    ADDREG,LCT               CARD ADDRESS = LCT              05760000
*                                                                       05780000
         BAL   RETURN,TXTCHR       GO TO PUNCH                          05800000
*                                                                       05820000
         LA    LCT,27(LCT)         UPDATE LCT                           05840000
         LA    COMPR,27(COMPR)     UPDATE COMPRESSION                   05860000
         B     IO3                                                      05880000
         SPACE 6                                                        05900000
*   ******************************************************************* 05920000
*   * PUNCH A FULL WORD OF X'FF' TO SIGNIFY END OF LINE COUNTER TABLES* 05940000
*   ******************************************************************* 05960000
*                                                                       05980000
IO3Z     LA    LOCREG,FWFF              TEXT ADDR = LOCN OF ALL FF      06000000
         LA    CNTREG,4                 BYTE COUNT = 4                  06020000
         LR    ADDREG,LCT               CARD ADDRESS = LCT              06040000
*                                                                       06060000
         BAL   RETURN,TXTCHR       GO PUNCH THE CARD                    06080000
*                                                                       06100000
         LA    LCT,4(LCT)          UPDATE LOC CTR                       06120000
*                                                                       06140000
         BAL   RETURN,ALIGNLCT     TO ALIGN LCT ON DBL WORD BOUNDARY    06160000
         EJECT                                                          06180000
*              **********************************************           06200000
*              * START IORB GENERATION PASS AFTER SKIP OVER *           06220000
*              *        AREA FOR IORPG AND DRIVER ROUTINES  *           06240000
*              **********************************************           06260000
*                                                                       06280000
IO3I     ST    LCT,PVIORPG         SET ADDRESS OF IORPG INTO POINTER    06300000
         LA    LCT,IORPGSZE(LCT)   LENGTH OF IORPG ADDED TO LCT         06320000
         LA    X11,DRIVER#         COUNT REGISTER = NO. OF DRIVERS      06340000
         SR    X13,X13             SET R13 = 0                          06360000
         SPACE 2                                                        06380000
IO3A     L     X12,QSLNPTR(X13)  ************************************** 06400000
         LTR   X12,X12           * CHECK DRIVE PTRS FOR USE, IF LNGTH * 06420000
         BZ    IO3B              * IS PRESENT PLACE LCT INTO POINTER  * 06440000
         BAL   RETURN,ALIGNLCT   * TO ALIGN LCT ON DBL WORD BOUNDARY  * 06460000
         SLL   X12,4                   ADJUST LNGTH TO LEFT        0969 06467014
         OR    X12,LCT                 COMBINE LNGTH + ADDRS       0969 06474014
         ST    X12,QSLNPTR(X13)        AND SAVE                    0969 06481014
* AT THIS POINT THE POINTER CONTAINS THE LENGTH IN BITS 0-11       0969 06488014
* AND THE ADDRESS IN BITS 12331.  THIS WILL ALLOW FOR A LENGTH     0969 06495014
* OF 4095 AND AN ADDRESS OF 1,048,575.                             0969 06502014
         SRL   X12,20                  ADJ LNTH TO ADD TO LCT      0969 06509014
         AR    LCT,X12           * AND ADD LENGTH TO LCT              * 06520000
IO3B     LA    X13,4(X13)               UPDATE PTR ADDRESS              06540000
         BCT   X11,IO3A                 OUT WHEN R11 = 0                06560000
         BAL   RETURN,ALIGNLCT     TO ALIGN LCT ON DBL WORD BOUNDARY    06580000
         SPACE 2                                                        06600000
         STM   XR14,XR2,SAV2  **************************           000Z 06620017
         LA    SERVRG,PNTCMP  * INITIALIZE COMPRESSION *                06640000
         BALR  XR5,XR7        **************************           000Z 06660017
         LM    XR14,XR2,SAV2            RESTORE REGISTERS(VOLATILE)000Z 06680017
         SPACE 6                                                        06700000
*                   **********************************                  06720000
*                   * GENERATE AND PUNCH IORB TABLES *                  06740000
*                   **********************************                  06760000
*                                                                       06780000
         LA    DCBREG,DCBPTR      RESET DCBREG TO POINT TO 1ST DCB PTR  06800000
         ST    LCT,PVIORB     ADDR OF 1ST IORB TO POINTER               06820000
IO4      BAL   X13,NEWBLOCK   READ A BLOCK OF COMPRESSION               06840000
IO4A     XC    IORB$(36),IORB$     SET IORB(+ 1 WORD) TO ALL ZEROES     06860000
         CLI   0(COMPR),X'FF'      END OF BLOCK?                        06880000
         BE    IO4            OUT IF YES                                06900000
         MVC   ISLIM$(1),RAFTYPE(COMPR)  RECORD ADDRESS TYPE TO IORB    06920000
         MVC   FILFORM(1),FILEFORM(COMPR)    FILE FORMAT TO IORB        06940000
         CLI   FILEORG(COMPR),C'I'     IS THIS INPUT OR UPDATE     I222 06944000
         BE    ISIORB                  IS  YES,BUILD IORB          I222 06948000
         CLI   FILEORG(COMPR),C'V'     IS THIS ADD/UPDATE IS       I222 06952000
         BE    ISIORB                  YES, GO BUILD IORB          I222 06956000
         CLI   FILEORG(COMPR),C'A'     IS THIS ADD I.S.            I222 06960000
         BE    ISIORB                  YES, GO BUILD IORB          I222 06964000
         CLI   FILEORG(COMPR),C'L'     IS THIS LOAD I. S.          I222 06968000
         BNE   IO5                     YES, GO BUILD IORB          I222 06972000
ISIORB   MVC   ISLIM$(1),FILEMODE(COMPR)  FILE TO IORB             I222 06976000
         MVC   LCTAG$(1),ISFLG(DCBREG)   I.S. IORB FILE FLAG       I222 06980000
         MVC   RECLG$(2),ISRLNG(DCBREG)  BINARY RCD LNG TO IORB    I222 06984000
         MVC   KLNGTH$(1),KEYLNG(DCBREG) BINARY KEYLNGTH TO IORB   I222 06988000
         MVI   LCTVAL$,X'00'            ZERO PREVIOUS BYTE         I222 06992000
         MVC   SPACB$(3),ADDWKAR+1(DCBREG)   POSSIBLE ADD WKAR AD  I222 06996000
         TM    33(COMPR),X'80'          TEST FOR KEY AREA ACCESS   I222 07000000
         BZ    IO5A1                    NOT ALLOWED, BRANCH        I222 07004000
         OI    WORSW,X'01'              SET SW FOR DRIVER          I222 07008000
         B     IO5A1                    CONTINUE I.S. IORB BUILD   I222 07012000
         EJECT                                                          07020000
*                 ***                       ***                         07040000
*                 * START IORB PROCESSING NOW *                         07060000
*                 ***                       ***                         07080000
IO5      CLI   EXTNCODE(COMPR),C'L'     IS LINE COUNTER USED?      I222 07085000
         BNE   IO5A                     AROUND IF NOT              I222 07090000
*                                                                       07095000
         MVI   LCTAG$,11                SET LINE COUNTER TAG = 11  I222 07100000
IO5A     MVC   RECLG$(2),RECLENGT+1(COMPR)  INSERT RECORD LENGTH   I222 07105000
IO5A1    STC   FILE#,FILENO$            INSERT FILE NUMBER         I222 07110000
         OI    FPASS$,11           11 TO FIRST PASS FLAG                07120000
         IC    X13,0(DCBREG)       GET FILE TYPE FROM DCB PTR           07140000
         STC   X13,FTYPE$          FILE TYPE INSERTED                   07160000
         MVI   0(DCBREG),0         CLEAR FILE TYPE BYTE IN DCBPTR       07180000
*                                                                       07200000
*                                                                       07320000
*              SET FILETYPE FLAG = 'OPEN' PARAMETER       -             07340000
         LA    X12,OPENIN               INPUT PARAMETER TO R12          07360000
         CLI   FILETYPE(COMPR),C'I'   TEST FOR INPUT                    07380000
         BE    IO5B                                                     07400000
*                                                                       07420000
         LA    X12,OPENOUT              OUTPUT PARAMETER TO R12         07440000
         CLI   FILETYPE(COMPR),C'O'   TEST FOR OUTPUT                   07460000
         BE    IO5B                                                     07480000
*                                                                       07500000
         LA    X12,OPENUP               UPDATE PARAMETER TO R12         07520000
         CLI   FILETYPE(COMPR),C'U'   TEST FOR UPDATE                   07540000
         BE    IO5B                                                     07560000
*                                                                       07580000
         LA    X12,OPENIO               INOUT PAR TO R12 (COMBINED FL)  07600000
IO5B     STC   X12,TBLFLG$         INSER TABLE FLAG (CODE IS IN R12)    07620000
*                                                                       07640000
         CLI   FILEDESG(COMPR),C'T'   TEST FOR TABLE                    07660000
         BNE   IO5B0                    AROUND IF NOT A TABLE FILE      07680000
         OI    UNIT$,X'10'         SET TABLE FILE FLAG IN UNIT          07700000
*                                                                       07720000
*                        SET RECORD ADDRESS                             07740000
IO5B0    L     X11,REACHWA(DCBREG)      PICK UP WORK AREA ADDRESS       07760000
         BAL   RETURN,TSTPRPN      GO FETCH PRINT/PUNCH BITS            07780000
*                                                                       07800000
         CLI   EXTNCODE(COMPR),C'L'     TEST FOR LINE COUNTER USAGE     07820000
         BE    IO5B1                    AROUND IF = 'L'                 07840000
*                                                                       07860000
*  CAUTION-  TSTPRPN USES REGISTERS 12 AND 13...                        07880000
*                                                                       07900000
         TM    FLAGS,PRNTPNCH     TEST FOR PRINT OR PUNCH               07920000
         BZ    IO5C                     AROUND IF NOT                   07940000
         OI    UNIT$,X'01'              SET UNIT = PUNCH                07960000
*                                                                       07980000
IO5B1    LA    X11,1(X11)          ADD 1 TO WORKAREA ADDRESS FOR CONTRL 08000000
         MVC   SKIPB$(4),FWFF    SET SKIPS AND SPACES TO 'NULL' VALUE   08020000
         TM    FLAGS,PRINTFLG           TEST FOR PRINT                  08040000
         BZ    IO5C                     AROUND IF NOT A PRINTER         08060000
         XI    UNIT$,X'03'              SET UNIT = PRINTER              08080000
         B     IO5D                                                     08100000
*                                                                       08120000
         SPACE 2                                                        08140000
         SPACE 3                                                        08160000
IO5C     CLI   FILEFORM(COMPR),C'V'     TEST FOR VARIABLE RECORD        08180000
         BE    IO5D               IF V, INCREASE COUNT             000I 08186017
         CLI   FILEFORM(COMPR),C'S' CHK FOR SPAN UNBLKED           000I 08192017
         BE    IO5D               IF S, INCREASE COUNT             000I 08198017
         CLI   FILEFORM(COMPR),C'M'  CHK FOR SPAN BLOCKED          000I 08204017
         BNE   IO5E               IF NOT, DO NOT INCREASE COUNT    000I 08210017
*                                                                       08220000
IO5D     LA    X11,4(X11)          ADD 4 TO WORK ADDR FOR VARBL LENGTH  08240000
*                                                                       08260000
IO5E     ST    X11,RECADD$         STORE RECORD ADDRESS                 08280000
         SPACE 6                                                        08300000
*                   **********************************                  08320000
*                   * SEND IORB TO TXT PUNCH ROUTINE *                  08340000
*                   **********************************                  08360000
         LA    LOCREG,IORB$        POINTS TO IORB AREA (TO BE PUNCHED)  08380000
         LR    ADDREG,LCT          LCT = CARD ORIGIN                    08400000
         LA    CNTREG,IORBLN$         BYTES OUT = IORB LENGTH           08420000
*                                                                       08440000
         BAL   RETURN,TXTCHR       OUT TO PUNCH TEXT                    08460000
*                                                                       08480000
         LA    LCT,IORBLN$(LCT)    UPDATE LOCN COUNTER BY IORB LENGTH   08500000
         LA    FILE#,1(FILE#)      BUMP FILE NO. BY 1                   08520000
         LA    DCBREG,4(DCBREG)         UPDATE DCB ADDRESS PTR BY 4     08540000
IO5F     LA    COMPR,55(COMPR)     UPDATE COMPRESSION POINTER           08560000
         CH    FILE#,FNFLAG        HAVE WE FINISHED?                    08580000
         BNE   IO4A            BACK IF NO....                           08600000
         EJECT                                                          08620000
*                 ****************************                          08640000
*                 * TERMINAL PROCESSING AREA *                          08660000
*                 ****************************                          08680000
*                                                                       08700000
         LA    LOCREG,IORB$+IORBLN$ *********************************   08720000
         LR    ADDREG,LCT         * PUNCH 1 WORD OF ZERO TO SIGNIFY *   08740000
         LA    CNTREG,4           *  END OF IORB TABLES             *   08760000
         BAL   RETURN,TXTCHR      ***********************************   08780000
*                                                                       08800000
         LA    LCT,4(LCT)          UPDATE LCT BY 4                      08820000
         ST    LCT,ADDCNT(DATA)      STORE CURRENT LCT FOR CIOEX USAGE  08840000
         L     LCT,PVIORPG         LOCN FOR IORPG TO LOCN COUNTER       08860000
*                                                                       08880000
         LH    X5,EXTCNT(DATA)          UPDATE ESD NO. COUNTER          08900000
         LA    X5,1(X5)                                                 08920000
         STH   X5,EXTCNT(DATA)                                          08940000
*                                                                       08960000
**************   *************  ***********  ****** *****        *****  08980000
*   OUTPUT DRIVER POINTERS TO BLANK AFTER. THE POINTERS WILL BE READ *  09000000
*   FROM THE BLANK AFTER FILE IN I/O 2 AND WILL BE USED TO DETERMINE *  09020000
*   WHICH DRIVER ROUTINES SHOULD BE PUNCHED OUT.                     *  09040000
*                                                                    *  09060000
**************   *************  ***********  ****** *****        *****  09080000
         LA    XR2,PNTBLK REINITIALIZE BLANK AFTER FILE            000Z 09100017
         BALR  RETURN,XR7                                          000Z 09120017
         LA    XR1,DCBPTR LOAD ADDRESS OF POINTERS                 000Z 09140017
         LA    XR2,BLKOUT                                          000Z 09160017
         BALR  RETURN,XR7 OUTPUT REMAINDER OF POINTERS             000Z 09180017
         LA    XR1,72(XR1) PREPARE TO OUTPUT REMAINDER OF POINTERS 000Z 09200017
         LA    XR2,BLKOUT     BLANK-OUT                            000Z 09220017
         BALR  RETURN,XR7                                          000Z 09240017
         SPACE 9                                                        09260000
         SPACE 3                                                        09280000
*                                                                       09300000
*              ***********************************************          09320000
*              * SEND POINTER VECTOR TABLE TO RLDOUT ROUTINE *          09340000
*              ***********************************************          09360000
*                                                                       09380000
         LA    XR1,VRLD            SET POINTER TO VECTOR TABLE     000Z 09400017
         LA    SERVRG,RLDOUT                                            09420000
         BALR  XR5,XR7                                             000Z 09440017
         SPACE 10                                                       09460000
*                 *********************************************         09480000
*                 * THIS IS WHERE IOPHSE CALLS THE NEXT PHASE *         09500000
*                 *********************************************         09520000
*                                                                       09540000
         MVC   PHSNAM(8,DATA),NXTPHASE                                  09560000
IO1DONE  L     XR10,SAV10               RESTORE REGISTER 10        000Z 09580017
         LA    SERVRG,PHSCAL                                            09600000
         BR    XR7                      GO TO NEXT PHASE           000Z 09620017
*                                                                       09640000
CALLDIAG MVC   PHSNAM(8,DATA),DIAG1     SET TO CALL DIAG 1              09660000
         B     IO1DONE                                                  09680000
         EJECT                                                          09700000
*              ***************************************************      09720000
*              * MASTER CONTROL FOR DCB AND WORK AREA GENERATION *      09740000
*              ***************************************************      09760000
*                                                                       09780000
*     ****************************************************************  09800000
*     * IOPH2 INSERTS PARAMETERS INTO DCB SKELETONS, RESERVES MEMORY *  09820000
*     *   FOR THEIR CORRESPONDING WORK AREAS, PLACES THEIR LOC'N COUN*  09840000
*     *  -TER ADDRESSES INTO THEIR POINTERS AND PUNCHES THEIR TEXT   *  09860000
*     *   CARDS.  THE ACCESS METHOD PROCESSORS BSAM, QSAM, BDAM, AND *  09880000
*     *   QISAM ARE CONTROLLED FROM IOPH2.                           *  09900000
*     ****************************************************************  09920000
*                                                                       09940000
IOPH2    ST    LCT,0(DCBREG)           LOC CTR ADDR TO DCBPTR      0969 09960014
*        GO TO INITIALIZE THEN SET THE PRINT AND PUNCH BITS IN 'FLAGS'  09980000
*                                                                       10000000
         BAL   RETURN,TSTPRPN  CAUTION- TSTPRPN USES REGISTERS 12 & 13  10020000
*                                                                       10040000
         CLI   FILEORG(COMPR),C'I'    FILE ORGANIZATION = INDEX.SEQNTL? 10060000
         BE    QISAM         -YES, GO TO QISAM                          10080000
         CLI   FILEORG(COMPR),C'V'     IS THIS ADD/UPDATE IS       I222 10082000
         BE    QISAM                   BRANCH YES                  I222 10084000
         CLI   FILEORG(COMPR),C'A'     IS THIS ADD OR ADD/         I222 10086000
         BE    QISAM                   INPUT IS, BRANCH YES        I222 10088000
         CLI   FILEORG(COMPR),C'L'     IS THIS LOAD IS             I222 10090000
         BE    QISAM                   BRANCH YES                  I222 10092000
*                                                                       10100000
         CLI    FILEORG(COMPR),C'D'     TEST FILE TYPE = D (DIRECT)     10120000
         BE    BDAM          IF YES, GO TO BDAM PROCESSOR               10140000
*                                                                       10160000
         CLI   FILETYPE(COMPR),C'C'     FILE TYPE COMBINED              10180000
         BNE   QSAMP                    NO, GO TO QSAM ROUTINE          10200000
*        IF NONE OF THE ABOVE ACCESS METHODS, GO ON TO BSAM BELOW       10220000
         SPACE 5                                                        10240000
*        ***************************************************            10260000
*        * BASIC SEQUENTIAL ACCESS METHOD PROCESSOR (BSAM) *            10280000
*        *    (FOR PROCESSING COMBINED FILES ONLY)         *            10300000
*        ***************************************************            10320000
*                                                                       10340000
BSAMP    MVC   DCB$(BSAMLN),BSAMDCB     MOVE BSAM DCB SKELETON TO DCB$  10360000
SETDDNAM MVC   DCBDDNAM(8),FILENAME(COMPR) MOVE FILENAME TO DDNAME      10380000
         LA    X12,BSAMSIZE        BSAM OBJ TIME PROCESSOR              10400000
         STH   X12,BSAMPTR                   SIZE TO BSAM POINTER       10420000
         MVI   0(DCBREG),8         BSAM CODE TO DCBPTR                  10440000
         LA    DISPLACR,BSAMLN     BSAM DCB LENGTH TO DISPLACEMENT REG. 10460000
         EJECT                                                          10480000
*       *************************************************************** 10500000
*       * ALL METHODS RETURN HERE ON COMPLETION EXCEPT ISAM,          * 10520000
*       *   - DISPLACR CONTAINS NO. OF BYTES IN DCB (PLUS 8 BYTES FOR * 10540000
*       *     AN EXIT LIST IF A USER 'LABEL' ROUTINE IS INDICATED)    * 10560000
*       *   - DCBPTR(FOR THE FILE NO.) CONTAINS LOCN CNTR ADDR OF ITS * 10580000
*       *      DCB(IN LOW ORDER BYTES) AND FILE TYPE CODE IN HI ORDER.* 10600000
*       *   - DRIVER POINTERS (IF DRIVER NEEDED AT OBJECT TIME) WILL  * 10620000
*       *           CONTAIN THE DRIVER SIZE IN THE LEFTMOST 2 BYTES   * 10640000
*       *************************************************************** 10660000
*                                                                       10680000
IO6E     LR    X12,LCT                                                  10700000
         AR    X12,DISPLACR         LOCN CTR + DCB DISPLACEMENT         10720000
         ST    X12,REACHWA(DCBREG)      TO CORRESPONDING WORK AREA PTR. 10740000
         LA    LOCREG,DCB$         ORG OF DCB TABLE TO LOCREG(FOR TEXT) 10760000
         LR    CNTREG,DISPLACR     NO. OF BYTES TO PUNCH (FOR TEXT)     10780000
         CLI   FILETYPE(COMPR),C'C'     IS FILE TYPE = COMBINED?        10800000
         BE    IO6F                   AROUND IF COMBINED FILE           10820000
         CLI   FILEORG(COMPR),C'D'  IS THIS A DIRECT FILE,              10840000
         BE    IO6E1          YES.                                      10860000
         AH    DISPLACR,DCBLRECL        ADD LOG.RECRD LNGTH TO DISPLACR 10880000
         B     IO6H                                                I222 10930000
IO6E1    AH    DISPLACR,DCBBLKSI    WORKAREA LENGTH IS IN BLKSIZE.      10980000
         B     IO6H           CONTINUE NORMALLY.                        11000000
*                                                                       11020000
*  ******************************************************************** 11040000
*  * TO PROCESS A 'BSAM'  DCB(USES ON-LINE CARD I/O) THE TEXT IS PUN- * 11060000
*  *  CHED FROM DCB$+16 AND THE DCB POINTER IS SET TO DCB$-16.        * 11080000
*  ******************************************************************** 11100000
*                                                                       11120000
IO6F     LA    DISPLACR,160(DISPLACR)            ADD 160 TO DISPLACR    11140000
         L     X13,0(DCBREG)       DCBPTR TO R13                 A33141 11150020
         LA    X13,0(X13)          ZERO 1ST BYTE OF PTR          A33141 11160020
         LA    X0,16                                             A33141 11170020
         SR    X13,X0                                            A33141 11180020
         IC    X0,0(DCBREG)        SAVE FIRST                    A33141 11190020
         ST    X13,0(DCBREG)         BYTE OF                     A33141 11200020
         STC   X0,0(DCBREG)            POINTER                   A33141 11210020
         LA    LOCREG,16(LOCREG)   INCREASE LOC REGISTER BY 16          11240000
*                                                                       11260000
IO6H     LR    ADDREG,LCT          LOCATION FOR TXT CARD                11280000
*                                                                       11300000
         BAL   RETURN,TXTCHR       GO OUT AND PUNCH DCB                 11320000
         SPACE 5                                                        11340000
*              **********************************                       11360000
*              * UPDATE REGISTERS FOR NEXT PASS *                       11380000
*              **********************************                       11400000
*                                                                       11420000
         LA    FILE#,1(FILE#)      ADD 1 TO FILE NUMBER REGISTER        11440000
         AR    LCT,DISPLACR        UPDATE LOCN CNTR BY DCB + WORK AREA  11460000
*                                                                       11480000
         BAL   RETURN,ALIGNLCT     TO ALIGN LCT ON DBL WORD BOUNDARY    11500000
*                                                                       11520000
         LA    DCBREG,4(DCBREG)    UPDATE DCB POINTER TABLE REGISTER    11540000
IO6J     LA    COMPR,55(COMPR)     UPDATE COMPRESSION POINTER REGISTER  11560000
*                                *******************************        11580000
         B     IO1A              * RETURN TO PROCESS NEXT FILE *        11600000
*                                *******************************        11620000
         EJECT                                                          11640000
*  ******************************************************************** 11660000
*  * QSAM PROCESSING STARTS HERE....MORE PARAMETERS SET INTO THE QSAM * 11680000
*  *  DCB, BLOCK AND RECORD LENGTHS USED TO COMPUTE WORK AREA SIZE,   * 11700000
*  *  OBJ. TIME QSAM PROCESSOR LENGTH STORED INTO QSAM DRIVER POINTER * 11720000
*  *  TO INDICATE IT MUST BE PUNCHED INTO THE RPG OBJ. DECK           * 11740000
*  ******************************************************************** 11760000
*                                                                       11780000
QSAMP    MVC   DCB$(QSAMLND),QSAMDCB    MOVE QSAM DCB SKELETON TO DCB$  11800000
         EX    0,SETDDNAM          MOVE FILENAME TO DDNAME IN DCB$      11820000
         MVC   DCBLRECL(2),RECLENGT+1(COMPR)   RECORD LENGTH TO LRECL   11840000
         MVC   BLOCKLN+1(3),BLKLENGT(COMPR)  BLOCK LENGTH TO STORAGE    11860000
         MVI   DCBMACR,X'00'            CLEAR MACR BIT IN QSAM DCB      11880000
         CLI   FILETYPE(COMPR),C'I'     TEST FOR INPUT FILE        8496 11900000
         BNE   PASS                     NO - GO TO PASS            8496 11920000
         CLI   DDEVICE(COMPR),C'R'    TEST FOR READER FILE         3369 11928015
         BNE   PASS                    NO, BRANCH TO PASS          3369 11936015
         LA    X12,1                   LOAD TEST ELEMENT           3369 11944015
         SLL   X12,0(FILE#)  POSITION ELEMENT TO TEST FOR FILE     3369 11952015
         N     X12,FSSBIT(DATA)   TEST FOR STACKER SELECT FILE     3369 11960015
         BZ    PASS               FILE NOT STACKER SELECTED        3369 11968015
         MVI   DCBBUFNO,X'01'           MOVE A X'01' INTO BUFNO    8496 11980000
PASS     LH    X11,DCBLRECL             RECORD LENGTH TO R11       8496 12000000
*                                                                       12020000
         SR    X12,X12             R12 = 0                              12040000
         L     X13,BLOCKLN      BLOCK LENGTH/                           12060000
         DR    X12,X11                     /RECORD LN.= QUOTIENT(IN R13 12080000
         LA    X12,1          1 TO R12                                  12100000
         CLI   FILEFORM(COMPR),C'S'      CHK FOR SPANNED UNBLKED   000I 12104017
         BNE   IO7AX              CONTINUE CHECK                   000I 12108017
         OI    DCBRECFM,SU$RECFM  SET TO 'VS'                      000I 12112017
         B     IO7A               CONTINUE PROCESSING              000I 12116017
IO7AX    CLI   FILEFORM(COMPR),C'M'     "HK FOR SPANNED BLOCKED    000I 12120017
         BNE   IO7AXX             GO CHK FOR FIXED--DO COMPARE     000I 12124017
         OI    DCBRECFM,SB$RECFM  SET TO 'VBS'                     000I 12128017
         B     IO7A               CONTINUE PROCESSING              000I 12132017
IO7AXX   CR    X12,X13            COMPARE FOR FIXED                000I 12136017
         BE    IO7A           AROUND IF     EQUAL                       12140000
*                                                                       12160000
         OI    DCBRECFM,B$RECFM    SET RECFM = B (BLOCKED RECORDS)      12180000
*                                                                       12200000
IO7A     CLI   EXTNCODE(COMPR),C'L'     TEST FOR LINE COUNTER USAGE     12220000
         BE    IO7A1                    GO TO RECL INCREMENT IF LNCNTR  12240000
         TM    FLAGS,PRNTPNCH      IS PRINT OR PUNCH USED?              12260000
         BZ    IO7B           AROUND IF NOT                             12280000
*                                                                       12300000
IO7A1    LA    X11,1(X11)     RECORD LENGTH+1 TO R11                    12320000
         STH   X11,DCBLRECL   UPDATES LRECL BY 1                        12340000
         TM    FLAGS,PRINTFLG      IS PRINTER USED?                     12360000
         BO    IO7C                AROUND IF    PRINTER                 12380000
         SPACE 4                                                        12400000
*    ****************************************************************** 12420000
*    * AT THIS POINT (IO7B)- R11 = LRECL,    R12 = 1                  * 12440000
*    *                       R13 = BLOCKLENGTH/RECORD LENGTH          * 12460000
*    ****************************************************************** 12480000
*                                                                       12500000
IO7B     CLI   FILEFORM(COMPR),C'V'     TEST FOR VARIABLE FORMAT        12520000
         BE    IO7C                AROUND IF VARIABLE                   12540000
         CLI   FILEFORM(COMPR),C'S'  CHECK FOR SPANNED UNBLOCKED   000I 12544017
         BE    IO7C+4             INCREASE COUNT                   000I 12548017
         CLI   FILEFORM(COMPR),C'M'  CHK FOR SPANNED BLOCKED       000I 12552017
         BE    IO7C+4             INCREASE COUNT                   000I 12556017
*                                                                       12560000
         OI    DCBRECFM,F$RECFM    SET RECFM = F(FIXED LENGTH RECORDS)  12580000
         SR    X12,X12             SET R12 = 0                          12600000
         MR    X12,X11             COMPUTE FIXED BLOCK SIZE             12620000
         STH   X13,DCBBLKSI        STORE INTO DCB                       12640000
         B     IO7M                GO TO QSAM CINTINUATION              12660000
         EJECT                                                          12680000
*                                                                       12700000
*          *** QSAM VARIABLE FORMAT PROCESSING ***                      12720000
*                                                                       12740000
IO7C     OI    DCBRECFM,V$RECFM    SET RECFM = V                        12760000
         LA    X11,4(X11)          LRECL + 4 TO LRECL                   12780000
         STH   X11,DCBLRECL        STORE NEW LRECL                      12800000
         CLI   FILEFORM(COMPR),C'M'    CHECK FOR SPAN-BLOCK        000I 12801017
         BE    IO7D               CALCULATE BLOCK SIZE             000I 12802017
         CLI   FILEFORM(COMPR),C'S'    CHECK FOR SPAN-UNBLOCK      000I 12803017
         BNE   LABEL3             MUST BE VARIABLE-UNAPANNED       000I 12804017
         L     X13,BLOCKLN        LOAD BLK LENGTH FROM SPEC        000I 12805017
         LA    X13,8(X13)         INC BY 2 DESCRIPTOR WORDS        000I 12806017
         CLI   EXTNCODE(COMPR),C'L'    CHK FOR LINE COUNTER        000I 12807017
         BE    LABEL1             IF YES, ADD ONE TO COUNT         000I 12808017
         TM    FLAGS,PRNTPNCH     CHECK FOR PRINTER OR PUNCH       000I 12809017
         BZ    LABEL2             IF NOT, STORE COUNT              000I 12810017
LABEL1   LA    X13,1(X13)         INCLUDE CONTROL CHARACTER        000I 12811017
LABEL2   STH   X13,DCBBLKSI       STORE BLKSIZE COUNT              000I 12812017
         B     IO7M               CONTINUE TO PROC FILE            000I 12813017
LABEL3   EQU   *                                                   000I 12814017
         CR    X12,X13       TEST FOR MULTIPLE RECORDS IN BLOCK         12820000
         BNE   IO7D                AROUND IF MULTIPLE                   12840000
*                                                                       12860000
         L     X13,BLOCKLN                                              12880000
         LA    X13,20(X13)         INCREMENT BLOCK LENGTH BY 20         12900000
         STH   X13,DCBBLKSI        STORE BLOCK LENGTH INTO DCB          12920000
         B     IO7M                GO TO QSAM CONTINUATION              12940000
         SPACE 4                                                        12960000
*          *** USE FORMULA TO COMPUTE BLOCK SIZE FOR VARIABLE RECORDS * 12980000
*   ************************************************************        13000000
*   * LET BLOCK LENGTH/RECORD LENGTH = X  AND THEN LET X+3 = C *        13020000
*   * THUS-                                                    *        13040000
*   *      BLKSIZE = BLOCK LENGTH + 4C + 4  OR                 *        13060000
*   *      BLKSIZE = BLOCK LENGTH + 4X + 16 = Y                *        13080000
*   * AND,                                                     *        13100000
*   *    IF PUNCH OR PRINT, THEN  BLKSIZE = Y + (X+3)          *        13120000
*   ************************************************************        13140000
*                                                                       13160000
IO7D     SLL   X12,4               R12 NOW = 16                         13180000
         SLL   X13,2          R13 = 4(BLOCK LENGTH/RECORD LENGTH)       13200000
         AR    X12,X13        R12 =  R13 + 16 = 4X + 16                 13220000
         A     X12,BLOCKLN    R12 =  BLOCK LENGTH + R13 + 16 = Y        13240000
         TM    FLAGS,PRNTPNCH TEST FLAGS FOR PRINT OR PUNCH             13260000
         BZ    IO7E           AROUND IF NO PRINT OR PUNCH               13280000
         SRL   X13,2          4X/4 = X                                  13300000
         AR    X12,X13        Y + X TO Y                                13320000
         LA    X12,3(X12)     Y + X + 3 TO Y                            13340000
IO7E     STH   X12,DCBBLKSI   Y TO BLKSIZE                              13360000
         EJECT                                                          13380000
*             ***********************************                       13400000
*             * COMPLETE THE DCB ENTRY FOR QSAM *                       13420000
*             ***********************************                       13440000
*                                                                       13460000
IO7M     MVI   0(DCBREG),4              QSAM CODE TO DCBPTR             13480000
         LA    X12,QSAMSIZE        QSAM LENGTH                          13500000
         STH   X12,QSAMPTR               TO QSAM PTR (LEFTMOST 2 BYTES) 13520000
*                                                                       13540000
         LA    DISPLACR,QSAMLND    QSAM DCB LENGTH TO DISPLACEMENT REG. 13560000
*                                                                       13580000
         CLI   LABEL(COMPR),X'00'       TEST FOR PRESENCE OF 'LABEL'    13600000
         BNE   IO7S                GO TO LABEL ROUTINE IF PRESENT       13620000
*                                                                       13640000
IO7O     CLI   FILETYPE(COMPR),C'I'     IS FILE TYPE ='I' ? (INPUT?)    13660000
         BNE   IO7U                AROUND IF NOT INPUT             0090 13680014
         BAL   5,BKSYSTST               GO TEST FOR BLOCKED SYSIN  3142 13690015
*                                                                       13700000
         MVI   DCBMACR,G$MACRF          SET MACRF = GMC =GET,MOVE,CNTRL 13720000
         LA    X12,1              CHECK TO                         3369 13723015
         SLL   X12,0(FILE#)         SEE IF THE FILE                3369 13726015
         N     X12,FSSBIT(DATA)       IS STACKER SELECTED          3369 13729015
         BM    IO6E               IF YES, LEAVE CNTRL BIT SET      3369 13732015
         MVI   DCBMACR,NC$MACRF   IF NO, TURN OFF CNTRL BIT        3369 13735015
         B     IO6E           GO BACK TO PHASE PROCESSING               13740000
*                                                                       13760000
IO7U     CLI   FILETYPE(COMPR),C'U' IS FILE TYPE ='U' (UPDATE?)    0090 13762014
         BNE   IO7N                AROUND IF NOT UPDATE            0090 13764014
         MVI   DCBMACR,X'48'       SET FOR GET (LOCATE MODE)       0090 13766014
         MVI   DCBMACR+1,X'48'     SET FOR PUTX (LOCATE MODE)      0090 13768014
         LA    X12,QSWRSIZE        QSAM WRITE ROUTINE LENGTH       0090 13770014
         STH   X12,QSWRPTR   TO QSWR POINTER (LEFTMOST 2 BYTES)    0090 13772014
         B     IO6E                GO BACK TO PHASE PROCESSING     0090 13774014
*                                                                       13776014
IO7N     MVI   DCBMACR+1,P$MACRF        SET MACRF = PM = PUT ;MOVE MODE 13780000
         LA    X12,QSWRSIZE   QS WRITE ROUTINE LENGTH                   13800000
         STH   X12,QSWRPTR         TO QSWR POINTER(LEFTMOST 2 BYTES)    13820000
*                                                                       13840000
         TM    FLAGS,PUNCHFLG      TEST PUNCH BIT                       13860000
         BZ    IO7P                AROUND IF NOT PUNCH                  13880000
         CLC   DDEVICE(3,COMPR),READ40  IS DEVICE A 2540                13900000
         BE    IO7N1                    YES                             13920000
*                                                                       13940000
         OI    DCBRECFM,A$RECFM    SET 'A' IN RECFM                     13960000
         B     IO6E           GO BACK TO PHASE PROCESSING               13980000
*                                                                       14000000
IO7N1    OI    DCBRECFM,M$RECFM         USE MACH CODE FOR 2540 STKR SEL 14020000
         B     IO6E                                                     14040000
*                                                                       14060000
IO7P     TM    FLAGS,PRINTFLG      TEST PRINT BIT                       14080000
         BO    IO7Q                                                     14100000
         CLI   EXTNCODE(COMPR),C'L'     TEST FOR LINE COUNTER SPECS     14120000
         BNE   IO6E        IF NO,GO BACK TO PHASE PROCESSING            14140000
         OI    DCBRECFM,M$RECFM         INSERT MACHINE CODE        8821 14160000
*                                                                       14180000
         LA    X12,QSLNSIZE   OBJ TIME LINE COUNTER ROUTINE SIZE        14200000
         STH   X12,QSLNPTR         TO QSLN POINTER(LEFTMOST 2 BYTES)    14220000
         B     IO6E                                                     14240000
*                                                                       14260000
IO7Q     OI    DCBRECFM,M$RECFM   SET RECFM = M (USE MACHINE CODE FOR   14280000
         LA    X12,QSPRSIZE        QS PRINT ROUTINE SIZE                14300000
         STH   X12,QSPRPTR               TO QSPR POINTER(LEFTMOST BYTES 14320000
         B     IO6E           FINAL EXIT FROM QSAM PROCESSOR            14340000
         EJECT                                                          14360000
*       ***********************************                             14380000
*       * INDEXED SEQUENTIAL ACCESS METHOD*                             14400000
*       * (QISAM & BISAM)                 *                             14420000
*       ***********************************                             14440000
*                                                                       14460000
*                                                                       14480000
QISAM    MVC   DCB$(ISAML2),ISAMDCB     MOVE ISAM DCB SKELETON TO DECB  14500000
         MVC   DCB$+ISAML2(26),DECB                                     14520000
         EX    0,SETDDNAM               MOVE FILENAME TO DDNAME IN DCB  14560000
         LA    X12,ISAMSIZE             ISAM OBJ TIME PROCESSOR         14580000
         STH   X12,QISAMPTR                SIZE TO ISAM POINTER         14600000
         MVI   0(DCBREG),12             QISAM CODE TO DCBPTR            14620000
         LA    DISPLACR,ISAMLN          ISAM DCB LENGTH TO DISPL. REG.  14640000
         XC    DCBOPTCD(12),DCBOPTCD    ZERO OPTION CODE, MAC,     I222 14650000
         XC    DCBLRECL(2),DCBLRECL     SET LRECL TO ZERO          I222 14651000
         LR    X12,LCT                  GET LOCATION COUNTER       I222 14652000
         AR    X12,DISPLACR             LOCN CTR + DCB LENGTH      I222 14653000
         ST    X12,REACHWA(DCBREG)      TO FILE WORKAREA PTR       I222 14654000
         XC    DBLWRK,DBLWRK            CLEAR WORK AREA            I222 14655000
         MVC   DBLWRK+6(2),KEYLENGT(COMPR)  GET PACKED KEY LENGT   I222 14656000
         CVB   X12,DBLWRK               CONVERT IT TO BINARY       I222 14657000
         STC   X12,DCBKEYLE             AND PLACE INTO DCB         I222 14658000
         STC   X12,KEYLNG(DCBREG)        AND SAVE FOR IORB         I222 14659000
         STH   X12,ISKLNG               SAVE BINARY KEY LNG        I222 14660000
         MVC   ISRLNG(2,DCBREG),RECLENGT+1(COMPR)  SAVE REC LENGT  I222 14661000
         XC    DCBRECFM(2),DCBRECFM     ZERO RECORD FORMAT IN DCB  I222 14662000
*   CYLINDER OVERFLOW, RKP AND BLOCKSIZE IN DCB                    I222 14663000
         CLI   FILEORG(COMPR),C'L'      LOAD FILE TEST             I222 14664000
         BE    ISLOAD                   YES, BRANCH                I222 14665000
         CLI   FILEMODE(COMPR),C'R'     IS FILE TO BE PROCESS RANDOMLY  14680000
         BE    ISRANDO                  BRANCH IF YES                   14700000
         MVI   ISFLG(DCBREG),X'40'       SET IORB FLAG FOR RTR FI  I222 14710000
         MVI   DCBMAC,X'00'    MAC OF DCB FOR GET                       14720000
         MVC   DCBMACR(2),GETPUT        DCB FOR GET & PUTX(LOCATE MODE) 14740000
         CLI   FILETYPE(COMPR),C'I'   INPUT FILE                        14760000
         BNE   ISEND                    NO,BRANCH TO ALLOC WKAR    I222 14780000
         MVC   DCBMACR(2),GETLOCIS      CODE TO DCB FOR GET-LOCATE000W  14800000
         B     ISEND                    GO TO ALLOC WORKAREA            14820000
ISRANDO  MVC   DCBMACR(2),READWR        DCB FOR READ & WRITE            14860000
         MVI   DCBMAC,X'0C'        MAC OF DCB FOR READ & WRITE          14880000
         MVI   ISFLG(DCBREG),X'44'       SET IORB FLAG FOR ADD/U   I222 14882000
         CLI   FILEORG(COMPR),C'V'      ADD/UPDATE FILE            I222 14884000
         BE    ISADDUP                  YES, BRANCH                I222 14886000
         CLI   FILEORG(COMPR),C'A'      ADD FILE, NO UPDATE        I222 14888000
         BE    ISADD                    YES, BRANCH                I222 14890000
         MVI   ISFLG(DCBREG),X'40'      INPUT OR UPDATE FILE       I222 14892000
         CLI   FILETYPE(COMPR),C'I'     INPUT FILE                      14900000
         BNE   ISEND                    NO, BRANCH                 I222 14930000
ISINPUT  MVC   DCBMACR(2),READIS       MACR OF DCB FOR READ             14960000
         MVI   DCBMAC,X'00'            MAC OF DCB FOR READ              14980000
         B     ISEND                    SET UP WORKAREA DISP       I222 14980700
*                                                                       14981400
ISADD    CLI   FILETYPE(COMPR),C'I'     INPUT/ADD FILE             I222 14982100
         BNE   ISADDO                   NO, BRANCH                 I222 14982800
         MVI   ISFLG(DCBREG),X'43'       SET IORB FLAG FOR ADD/I   I222 14983500
         NI    DCBMAC,X'F3'             REMOVE UPDATE READ/WR COD  I222 14984200
ISADDUP  OI    DCBMAC,X'02'             SET ADD WRITE CODE         I222 14984900
         OI    DCBMACR+1,X'20'          SET ADD WRITE CODE         I222 14985600
         TM    33(COMPR),X'80'          IS KEY AREA ACCESSS ALLOW  I222 14986300
         BZ    ADD16                    NO,SET UP PTR TO ADD WKAR  I222 14987000
         AH    DISPLACR,ISKLNG         ADD KEY LNG FOR I/U WKAR    I222 14987700
         AH    DISPLACR,ISRLNG(DCBREG)  ADD RCD LNG FOR I/U WKAR   I222 14988400
         B     ADD16               GO ADD SYSTEM SPACE TO WRKAREA  I222 14989100
ISADDO   MVI   ISFLG(DCBREG),X'42'       SET IORB FLAG FOR ADD/O   I222 14989800
         MVI   DCBMAC,X'02'             SET ADD WRITE CODE         I222 14990500
         MVC   DCBMACR(2),ADDWR         SET ADD WRITE CODE         I222 14991200
ADD16    LR    X13,LCT                 IF ADD COMBINED WITH INPUT  I222 14991900
         AR    X13,DISPLACR            UPDATE, WORKAREAS CONTIGUO  I222 14992600
         ST    X13,ADDWKAR(DCBREG)     SAVE PTR TO ADD WORKAREA    I222 14993300
         LA    DISPLACR,16(DISPLACR)    BUMP PAST SL IN WORKAREA   I222 14994000
         B     ISEND1                                              I222 14994700
*                                                                       14995400
ISLOAD   MVI   ISFLG(DCBREG),X'41'       SET IORB FLAG FOR LOAD F  I222 14996100
         MVC   DCBLRECL(2),RECLENGT+1(COMPR) RCD LNG TO DCB        I222 14996800
         XC    DBLWRK,DBLWRK            CLEAR WORK AREA            I222 14997500
         MVC   DBLWRK+7(1),CYLOFL(COMPR) GET PACKED CYL OVERFLOW   I222 14998200
         CVB   X12,DBLWRK               CONVERT TO BINARY          I222 14998900
         STC   X12,DCBCYLOF             AND PLACE INTO DCB         I222 14999600
         MVC   DBLWRK,KEYLOC+2(COMPR)   GET KEY LOCATION           I222 15000300
         LH    X12,DBLWRK               IF KEY LOCATION NOT        I222 15001000
         LTR   X12,X12                  GIVEN OR SET TO ZERO       I222 15001700
         BZ    RKPZERO                  BRANCH, ELSE PLACE         I222 15002400
         BCTR  X12,0                    THE RELATIVE KEY           I222 15003100
         STH   X12,DCBRKP               POSITION INTO THE DCB      I222 15003800
RKPZERO  MVC   DCBBLKSI(2),BLKLENGT+1(COMPR)   BLKSIZE TO DCB      I222 15004500
         MVC   DCBBLKSI(2),BLKLENGT+1(COMPR)   BLKSIZE TO DCB      I222 15005200
         MVI   DCBRECFM,X'81'           FXD UNB RCDS, KEYLN GIVN   I222 15005900
         MVI   DCBMACR,X'00'            SET MACRO FORM FOR         I222 15006600
         MVI   DCBMACR+1,X'50'          PUT IN MOVE MODE           I222 15007300
         CLC   BLKLENGT(3,COMPR),RECLENGT(COMPR)  ARE RCDS UNBLKD  I222 15008000
         BE    ISEND                    YES, BRANCH                I222 15008700
         OI    DCBRECFM,X'10'           =FXD BLK RCDS, KEYLEN GIV  I222 15009400
*                                                                       15010100
ISEND    TM    33(COMPR),X'80'          IS KEY AREA ACCESS ALLOWE  I222 15010800
         BO    ISEND1                   YES, BRANCH                I222 15011500
         TM    DCBMACR,X'20'            TEST FOR INPUT/UPDT FILE   I222 15012200
         BZ    ISEND2                   NOT ONE OF THESE, BRANCH   I222 15012900
         LA    DISPLACR,4(DISPLACR)     NEEDED FOR OPEN RTN ONLY   I222 15013600
         B     SET4PCH                  BRANCH TO PUNCH DCB        I222 15014300
ISEND1   AH    DISPLACR,ISKLNG         ADD KEY LENGTH TO WORKAREA  I222 15015000
ISEND2   AH    DISPLACR,ISRLNG(DCBREG)  ADD RCD LENGTH TO WORKARE  I222 15015700
SET4PCH  LA    CNTREG,ISAMLN           SET DCB LENGTH AND LOCATIO  I222 15016400
         LA    LOCREG,DCB$              FOR PUNCH ROUTINE          I222 15017100
         B     IO6H                                                I222 15017800
*                                                                       15018500
ADDWR    DC    X'0020'                  MACR CODE (ADD WRITE)      I222 15019200
READIS   DC    X'2400'       MACR CODE (READ)                           15020000
GETLOCIS DC    X'4882'                  MACR CODE(GET-LOC.MODE)    I222 15040000
GETPUT   DC    X'48C6'            MACR OF DCB FOR GET & PUT             15060000
READWR   DC    X'2420'        MACR OF DCB FOR READ & WRITE              15080000
         SPACE 2                                                        15100000
*************  *************   *********** ******************           15120000
*        *************************************************************  15140000
*        * A LABEL CHECKER ADDRESS IS PRESENT.  THIS ROUTINE WILL*****  15160000
*        *  SET UP AN EXIT LIST(TO BE OUTPUT WITH THE QSAM DCB) CON- *  15180000
*        *  TAINING THE ADDRESS OF THE LABEL PROCESSOR.  AN RLD AND  *  15200000
*        *  AN ESD CARD WILL BE GENERATED FOR USE BY THE LOADER      *  15220000
*        *************************************************************  15240000
*                                                                       15260000
IO7S     LA    X5,EXLSTOFF(LCT)         EXLST$ OFFSET FROM DCB(+LOC CT) 15280000
         SPACE 1                                                        15300000
*   SET UP EXIT LIST LOCN IN EXLST$ AND SET UP EXLST$ IN RLD            15320000
         SPACE 1                                                        15340000
         STH   X5,RLDCARD+2        SET RLD ENTRY                        15360000
         SRL   X5,16                                             A21747 15366000
         STC   X5,RLDCARD+1                                      A21747 15372000
         LA    X5,QSAMLND(LCT)     R5 = EXIT LIST LOCATION              15380000
         ST    X5,DCBEXLST         SET RELOCATION INCREMENT IN XLST1747 15400000
         SPACE 1                                                        15420000
*   SET RLD ENTRIES FOR LABEL PROCESSOR ADDRESS                         15440000
         SPACE 1                                                        15460000
         LA    X5,1(X5)            UPDATE LOCN COUNTER ADDR             15480000
         STH   X5,RLDLCT1+1        LOCN COUNTER VALUE FOR 1ST ENTRY     15500000
         SRL   X5,16                                             A21747 15506000
         STC   X5,RLDLCT1                                        A21747 15512000
         LA    X5,4(X5)            UPDATE LOCN COUNTER ADDR             15520000
         STH   X5,RLDLCT2+1        LOCN COUNTER VALUE FOR 2ND ENTRY     15540000
         SRL   X5,16                                             A21747 15546000
         STC   X5,RLDLCT2                                        A21747 15552000
         LH    X5,EXTCNT(DATA)     ESD ID NUMBER TO R5                  15560000
         LA    X5,1(X5)                 UPDATE ESD NO. BY 1             15580000
         STH   X5,RLDID1           ESD ID TO RLD ENTRIES                15600000
         STH   X5,RLDID2                                                15620000
         STH   X5,EXTCNT(DATA)     STORE UPDATED ESD ID NO. INTO DATA   15640000
         SPACE 1                                                        15660000
*                        SEND RLD CARD TO RLDOUT ROUTINE                15680000
         SPACE 1                                                        15700000
         STM   XR14,XR2,SAV2            SAVE REGISTERS             000Z 15720017
         LA    XR1,RLDCARD                                         000Z 15740017
         LA    SERVRG,RLDOUT                                            15760000
         BALR  XR5,XR7                                             000Z 15780017
         LM    XR14,XR2,SAV2            RESTORE REGISTERS          000Z 15800017
         SPACE 5                                                        15820000
*              *************************************************        15840000
*              * SET UP AND PUT OUT THE ESD CARD FOR EXIT LIST *        15860000
*              *************************************************        15880000
         SPACE 1                                                        15900000
*                  (PUNCH BUFFER IS ALL BLANKS AT THIS TIME)            15920000
         MVC    0(4,PUNBUFFR),ESDCARD   SET IST 4 COLS OF ESD CARD      15940000
         MVC   ESDC11(2,PUNBUFFR),ESDCOL11  SET COLS 11 AND 12          15960000
         MVC   ESDID(2,PUNBUFFR),RLDID1  SET IDENTIFICATION COLS        15980000
         MVC   ESDSYMBL(6,PUNBUFFR),LABEL(COMPR)  SET EXTERNAL SYMBOL   16000000
         MVC   ESDC25(4,PUNBUFFR),ESDCOL25  SET COLS 25 THRU 28         16020000
*                                                                       16040000
*                   GO TO THE CIOEX PUNCH ROUTINE                       16060000
*                                                                       16080000
         STM   14,2,SAV2                                                16100000
         LA    SERVRG,PUNCOD       LOAD SERVICE REGISTER WITH PUNCH CD. 16120000
         BALR  RETURN,RQSTPT       GO TO PUNCH ESD CARD                 16140000
         LM    14,2,SAV2                                                16160000
         SPACE 1                                                        16180000
         LA    DISPLACR,8(DISPLACR)     UPDATE DISPLACEMENT REGISTER   X16200000
                                   BY LENGTH OF EXIT LIST (8 BYTES)     16220000
         XC    DCB$+QSAMLND(8),DCB$+QSAMLND    INIT EXIT LIST TO ZEROS  16240000
*                        SET UP EXIT LIST PREFIX FORMAT                 16260000
         CLI   FILETYPE(COMPR),C'I'     TEST FOR INPUT FILE             16280000
         BNE   IO7T                  AROUND IF OUTPUT FILE              16300000
*                                                                       16320000
         MVI   DCB$+QSAMLND,X'01'  SET UP INPUT LABEL PREFIXES          16340000
         MVI   DCB$+QSAMLND+4,X'83'                                     16360000
         B     IO7O                RETURN TO CONTINUE PROCESSING        16380000
*                                                                       16400000
IO7T     MVI   DCB$+QSAMLND,X'02'  SET UP OUTPUT LABEL PREFIXES         16420000
         MVI   DCB$+QSAMLND+4,X'84'                                     16440000
         B     IO7N                RETURN TO QSAM PROCESSING            16460000
         SPACE 5                                                        16480000
***************************************************************    3142 16480215
*                                                                  3142 16480415
*   CHECK THE FILE FOR ELIGIBILITY AS BLOCKED SYSIN AT OBJECT      3142 16480615
*   TIME. IF ELIGIBLE, THE DCB WILL BE MODIFIED SO THAT THE OBJECT 3142 16480815
*   TIME OPEN WILL DEFAULT TO THE CORRECT BLOCK SIZE.              3142 16481015
*                                                                  3142 16481215
***************************************************************    3142 16481415
*                                                                  3142 16481615
*   CHECK BLK/SYSIN ELIGIBILITY. AT THIS POINT THE FILE IS KNOWN   3142 16481815
*   TO BE QSAM AND INPUT.                                          3142 16482015
*                                                                  3142 16482215
BKSYSTST ST    5,BKSYSSAV               SAVE WORK REGISTER         3142 16482415
         TM    DCBRECFM,X'80'           IS IT FIXED LENGTH?        3142 16482615
         BZ    BKSYSEXT                   IF NO - EXIT             3142 16482815
         TM    DCBRECFM,X'10'           IS IT BLOCKED?             3142 16483015
         BO    BKSYSEXT                   IF YES - EXIT            3142 16483215
         SR    5,5                                                 3142 16483415
         LA    5,80                                                3142 16483615
         CH    5,DCBLRECL               IS RECORD LGTH = 80?       3142 16483815
         BNE   BKSYSEXT                   IF NO - EXIT             3142 16484015
         CLI   LABEL(COMPR),X'00'       IS USER LABEL SPECIFIED?   3142 16484215
         BNE   BKSYSEXT                   IF YES - EXIT            3142 16484415
*                                                                  3142 16484615
*   THE FILE IS ELIGIBLE FOR BLOCKED SYSIN STATUS AT OBJECT TIME.  3142 16484815
*   THE FOLLOWING ROUTINE MODIFIES THE DCB TO ALLOW FOR THE        3142 16485015
*   FILE BEING BLOCKED AS SYSIN BY THE READER/INTERPRETER WHILE    3142 16485215
*   RUNNING UNDER MVT.                                             3142 16485415
*                                                                  3142 16485615
         OI    DCBRECFM,X'10'           RECFM = FB                 3142 16485815
         LA    5,0                      BLKSIZE = 0. OPEN WILL     3142 16486015
         STH   5,DCBBLKSI                 DEFAULT TO TRUE BLK SIZE 3142 16486215
*                                                                  3142 16486415
*   BUILD AN EXIT LIST IN DCB FOR ELIGIBLE FILES                   3142 16486615
*                                                                  3142 16486815
         LA    5,EXLSTOFF(LCT)         GET DCB OFFSET (+LOC CT)    3142 16487015
         STH   X5,BSEXTRLD+2       SET RLD ENTRY                 A21747 16487100
         SRL   X5,16                                             A21747 16487200
         STC   X5,BSEXTRLD+1                                     A21747 16487300
         LA    5,QSAMLND(LCT)          R5=EXIT LIST LOCN           3142 16487415
         ST    X5,DCBEXLST             STOW IN DCB$              A21747 16487600
         LA    5,1(5)                  UPDATE LOC CT               3142 16487815
         STH   X5,BSEXTRLD+8       STOW LOC CTR VALUE            A21747 16487900
         SRL   X5,16                                             A21747 16488000
         STC   X5,BSEXTRLD+7                                     A21747 16488100
*                                                                  3142 16488215
*   WRITE THE RLD RECORD FOR REQUIRED EXIT LIST                    3142 16488415
*                                                                  3142 16488615
         STM   14,2,SAV2                                           3142 16488815
         LA    1,BSEXTRLD                                          3142 16489015
         LA    SERVRG,RLDOUT                                       3142 16489215
         BALR  5,7                                                 3142 16489415
         LM    14,2,SAV2                                           3142 16489615
*                                                                  3142 16489815
*   BUILD THE ACTUAL EXIT LIST ENTRY, AND MOVE IN EXIT ROUTINE     3142 16490015
*                                                                  3142 16490215
         LA    DISPLACR,20(DISPLACR)   UPDATE DISPLACEMENT REG     3142 16490415
         XC    DCB$+QSAMLND(4),DCB$+QSAMLND  ZERO EXIT LIST        3142 16490615
         LA    5,QSAMLND(LCT)          R5=EXIT LIST LOCN           3142 16491015
         LA    5,4(5)                  R5=EXIT RTN LOCN            3142 16491215
         ST    X5,DCB$+QSAMLND         STORE IN EXIT LIST        A21747 16491300
         MVI   DCB$+QSAMLND,X'85'      SET PREFIF IN ENTRY       A21747 16491400
         LA    5,DCB$+QSAMLND+4        R5=PTR TO RTN BUILD AREA    3142 16491615
         MVC   0(16,5),BSEXTRTN        SET UP EXIT ROUTINE         3142 16491815
*                                                                  3142 16492015
BKSYSEXT L     5,BKSYSSAV               RESTORE WORK REGISTER      3142 16492215
         BR    5                          AND RETURN TO QSAM PROC  3142 16492415
BKSYSSAV DS    F                                                   3142 16492615
*                                                                  3142 16492815
         DS    0F                                                  3142 16493015
BSEXTRLD DC    X'D9'                                               3142 16493215
         DC    FL3'0'                  EXLST$ ENTRY                3142 16493415
         DC    FL2'1'                                              3142 16493615
         DC    X'03'                                               3142 16493815
         DC    FL3'0'                  LOCN CTR VALUE              3142 16494015
         DC    FL2'1'                  ESDID                       3142 16494215
         DC    X'03'                                               3142 16494415
         DC    X'FD'                                               3142 16494615
*                                                                  3142 16494815
*   THE FOLLOWING EXIT ROUTINE IS PUT OUT IMMEDIATELY FOLLOWING    3142 16495015
*   THE PREVIOUSLY GENERATED EXIT LIST                             3142 16495215
*                                                                  3142 16495415
         USING BSEXTRTN,XR15                                       000Z 16495617
         CNOP  0,4                                                 3142 16495815
BSEXTRTN SR    5,5                     OBTAIN ZERO COMPARAND       3142 16496015
         CH    5,62(7)                 IS DCB'S BLKSIZE STILL = 0? 3142 16496215
         BNE   BSEXTRET                 NO - DON'T MEDDLE          3142 16496415
         MVI   63(7),X'50'              YES - MAKE IT 80 BYTES     3142 16496615
BSEXTRET BR    14                      RETURN TO OPEN PROCESSOR    3142 16496815
         DROP  XR15                                                000Z 16497817
*                   ********************                                16500000
*                   * UTILITY ROUTINES *                                16520000
*                   ********************                                16540000
*                                                                       16560000
*      *** GET A BLOCK OF COMPRESSION ***                               16580000
*                                      **LINK = BAL  R13,NEWBLOCK       16600000
NEWBLOCK STM   XR14,XR2,SAV2                                       000Z 16620017
         LA    SERVRG,GETCMP       SET PARAMETER                        16640000
         BALR  XR5,XR7             GO GET COMPRESSION              000Z 16660017
         LM    XR14,XR2,SAV2                                       000Z 16680017
         BR    X13                 RETURN                               16700000
         SPACE 5                                                        16720000
*           **************************************************          16740000
*           * THIS SUBROUTINE ALIGNS THE LOCATION COUNTER ON *          16760000
*           *             A DOUBLE WORD BOUNDARY             *          16780000
*           **************************************************          16800000
*                                                                       16820000
ALIGNLCT LA    LCT,7(LCT)                                               16840000
         N     LCT,DALIGN                                               16860000
         BR    RETURN                                                   16880000
         EJECT                                                          16900000
*        *****************************                                  16920000
*        * OUTPUT USER TEXT ROUTINES *   LOCREG = ADDR OF 1ST BYTE OUT  16940000
*        *****************************   CNTREG = NO. OG BYTES OUT      16960000
*                                        ADDREG = ADDR OF LOCN CNTR=LCT 16980000
*                                       (REG 4 ALWAYS PTS TO OUT BUFF)  17000000
*          ********************************************************     17020000
*          * TXTCHR REGULATES FLOW OF BYTES TO OUTPUT TXT ROUTINE *     17040000
*          ********************************************************     17060000
TXTCHR   ST    RETURN,TXTHLD                                            17080000
         STM   XR14,XR2,TXTSAV                                     000Z 17100017
*                                                                       17120000
TXT01    LA    SLVRG1,56           POSSIBLE NUMBER OF OUTPUT BYTES      17140000
         CLR   CNTREG,SLVRG1       TEST FOR COUNT LESS THAN 56          17160000
         BNL   TXT02               AROUND IF 56 OR MORE                 17180000
*                                                                       17200000
         LR    SLVRG1,CNTREG       NO.OF BYTES TO SLVRG1                17220000
*                                                                       17240000
TXT02    LR    SLVRG2,ADDREG                                            17260000
         SR    CNTREG,SLVRG1       NO.OF REMAINING BYTES TO CNTREG      17280000
         AR    ADDREG,SLVRG1       BUMP ADDRESS REGISTER                17300000
         SPACE 4                                                        17320000
*              ********************************************             17340000
*              * OUTPUT TXT CARDS (OR TEXT) AT THIS POINT *             17360000
*              ********************************************             17380000
*                             SLVRG1 = NUMBER OF BYTES                  17400000
*                             SLVRG2 = LOCATION PUNCHED INTO CARD       17420000
*                             LOCREG = AREA IN CORE TO BE PUNCHED       17440000
*                                                                       17460000
         STH   SLVRG1,TXTLEN       LENGTH OF TXT INFO IN CARD           17480000
         ST    SLVRG2,FULLWD                                            17500000
         MVC   TXTADD(3),FULLWD+1  PUT 24 BIT ADDRESS INTO CARD         17520000
         MVC   0(16,PUNBUFFR),TXTIMG    MOVE 1ST 16 COLS TO BUFFER      17540000
         LR    SLVRG2,LOCREG                                            17560000
         AR    LOCREG,SLVRG1       UPDATE LOCN REG FOR NEXT PASS THRU   17580000
         BCTR  SLVRG1,0            REDUCE COUNT BY 1                    17600000
*                                                                       17620000
         EX    SLVRG1,PUNMVC       MOVE TEXT TO PUNCH BUFFER            17640000
         LA    SERVRG,PUNCOD    ***SET UP FOR OUTPUT***                 17660000
*                                                                       17680000
         BALR  RETURN,RQSTPT       GO TO OUTPUT TEXT CARD               17700000
*                                                                       17720000
         LTR   CNTREG,CNTREG       IS THEIR ANY MORE TO BE PUNCHED      17740000
         BH    TXT01               YES                                  17760000
*                                                                       17780000
         L     RETURN,TXTHLD       NO                                   17800000
         LM    XR14,XR2,TXTSAV     RESTORE REGISTERS               000Z 17820017
*                                                                       17840000
*                        FINAL EXIT FROM TEXT PUNCHING                  17860000
         BR    RETURN              EXIT                                 17880000
*                                                                       17900000
PUNMVC   MVC   16(0,PUNBUFFR),0(SLVRG2)                                 17920000
         EJECT                                                          17940000
*********************************************************************** 17960000
*        SET PRINT/PUNCH BITS FROM DEVICE ENTRY IN COMPRESSION          17980000
*********************************************************************** 18000000
TSTPRPN  NI    FLAGS,PRNPNCLR     CLEAR PRINT/PUNCH BITS FROM FLAGS   * 18020000
         CLI   FILETYPE(COMPR),C'O'     TEST FOR AN OUTPUT FILE         18040000
         BNE   A2                       NOT AN OUTPUT FILE, SKIP ROUTNE 18060000
*                                                                     * 18080000
         CLI   DDEVICE(COMPR),C'P'      TEST FOR PRINTER              * 18100000
         BNE   A1                                                     * 18120000
*                                                                     * 18140000
         OI    FLAGS,B'00000010'        SET PRINT FLAG                * 18160000
         BR    RETURN                                                 * 18180000
*                                                                     * 18200000
A1       CLI   DDEVICE(COMPR),C'R'      TEST FOR PUNCH                * 18220000
         BNE   A2                                                     * 18240000
         OI    FLAGS,B'00000001'        SET PUNCH FLAG                * 18260000
*                                                                     * 18280000
A2       BR    RETURN                                                 * 18300000
*********************************************************************** 18320000
         EJECT                                                          18340000
*       ************************************                            18360000
*       *       SAVE AREA AND CONSTANTS    *                            18380000
*       ************************************                            18400000
*                                                                       18420000
FNFLAG   DC    H'0'                                                     18440000
HALFONE  DC    H'1'                     CONSTANT 1                      18460000
ISKLNG   DC    H'0'                    I.S. KEY LENGTH                  18466000
DBLWRK   DS    1D                       DOUBLE-WORD WORK AREA      I222 18472000
**  CONSTANT SECTION BELOW USED BY OUTPUT USER TEXT ROUTINE    ******   18480000
TXTHLD   DC    F'0'                                                     18500000
FULLWD   DC    F'0'                                                     18520000
TXTIMG   DC    X'02'          ***************************************** 18540000
         DC    CL4'TXT '      *         TXT CARD IMAGE - 1ST 16 COLS  * 18560000
TXTADD   DC    CL5'     '     *   CARD ADDRESS                        * 18580000
TXTLEN   DC    CL4'    '      *   LENGTH OF INFORMATION               * 18600000
         DC    X'0001'        ***************************************** 18620000
**  END OF SECTION USED FOR 'OUTPUT USER TEXT'  ************            18640000
DALIGN   DC    X'FFFFFFF8'    MASK FOR DOUBLE WORD ALIGNMENT            18660000
FWHOLD   DC    F'0'                FULL WORD HOLD AREA                  18680000
SAV2     DC    5F'0'         5 REG UTILITY SAVE AREA                    18700000
SAV10    DC    F'0'                     STORAGE FOR REGISTER 10 SAVE    18720000
TXTSAV   EQU   SAV2                                                     18740000
BLOCKLN  DC    F'0'          BLOCK LENGTH CONVERTED FROM COMPRESSION    18760000
FWFF     DC    4X'FF'         FULL WORD OF BITS                         18780000
READ40   DC    C'R40'                   DEVICE ENTRY FOR 2540           18800000
NXTPHASE DC    C'RPG10180'              PHASE NAME FOR I/O 2            18820000
DIAG1    DC    C'RPG10190'              PHASE NAME FOR DIAG 1           18840000
         SPACE 1                                                        18860000
*              ********************************************             18880000
*              * RLD CARD FORMAT FOR EXIT LIST PROCESSING *             18900000
*              ********************************************             18920000
         SPACE 1                                                        18940000
         DS    0F                                                       18960000
RLDCARD  DC    X'D9'                                                    18980000
         DC    FL3'0'         EXLST$ ENTRY                              19000000
         DC    FL2'1'                                                   19020000
         DC    X'03'                                                    19040000
RLDLCT1  DC    FL3'0'         1ST LABEL ENTRY - (LOCN COUNTER VALUE)    19060000
RLDID1   DC    FL2'0'         EXTERNAL SYMBOL ID                        19080000
         DC    X'03'                                                    19100000
RLDLCT2  DC    FL3'0'         2ND LABEL ENTRY - (LOCN COUNTER VALUE)    19120000
RLDID2   DC    FL2'0'         EXTERNAL SYMBOL ID                        19140000
         DC    X'03'                                                    19160000
         DC    X'FD'                                                    19180000
         EJECT                                                          19200000
*              ******************************************************   19220000
*              * OUTPUT AREA - POINTER TABLES, LINKAGE VECTOR TABLE *   19240000
*              *               DRIVER POINTERS, DCB, AND IORB       *   19260000
*              ******************************************************   19280000
*                                                                       19300000
DCBPTR   DC    (FILES)F'0'         POINTERS TO DCB TABLES               19320000
REACHWA  EQU   *-DCBPTR       DISPLACEMENT OF CORRESP WORK AREA FRM DCB 19340000
*                                                                       19360000
WAPTR    DC    (FILES)F'0'         POINTERS TO WORK AREAS               19380000
TABLPASS EQU   *-DCBPTR            TO PASS OVER DCB AND WORK AREA PTRS  19400000
*                                                                       19420000
QSLNPTR  DC    F'0'      POINTERS TO - LINE COUNTER ROUTINE             19440000
QSAMPTR  DC    F'0'                    QSAM PROCESSOR                   19460000
BSAMPTR  DC    F'0'                    BSAM PROCESSOR                   19480000
QISAMPTR DC    F'0'                    QISAM PROCESSOR                  19500000
BDAMPTR  DC    F'0'                    BDAM PROCESSOR                   19520000
QSWRPTR  DC    F'0'                    QS WRITE ROUTINE                 19540000
QSPRPTR  DC    F'0'                    QS PRINT ROUTINE                 19560000
PTRTBLNG EQU   *-DCBPTR            TOTAL NO. OF BYTES IN POINTER TABLES 19580000
DRIVPASS EQU   *-QSLNPTR           TO PASS OVER DRIVER POINTERS         19600000
DRIVER#  EQU   DRIVPASS/4     NO.OF DRIVERS USED BY RPG (OBJECT TIME)   19620000
         SPACE 2                                                        19640000
*                   ************************                            19660000
*                   * LINKAGE VECTOR TABLE *                            19680000
*                   ************************                            19700000
*                                                                       19720000
FZERO    DC    X'00'     ' CHAR OF ZERO TO FORCE LV TABLE TO ODD BOUNDS 19740000
FLAGS    EQU   FZERO            USE FZERO BYTE FOR FLAG BYTE            19760000
VRLD     DC    X'E5'               V-TYPE IDENTIFIER                    19780000
*                                                                       19800000
         DC    FL2'200'      PVIORB DISPLACEMENT                        19820000
PVIORB   DC    FL4'0'              ADDRESS CONSTANT OF 1ST IORB         19840000
         DC    FL2'204'      PVDCB DISPLACEMENT                         19860000
PVDCB    DC    FL4'0'              ADDRESS CONSTANT OF DCB POINTER      19880000
         DC    FL2'208'      PVIORPG DISPLACEMENT                       19900000
PVIORPG  DC    FL4'0'              ADDRESS CONSTANT OF IO INTERFACE     19920000
         DC    FL2'220'      PVLCTR DISPLACEMENT                        19940000
PVLCTR   DC    FL4'0'              ADDRESS CONSTANT OF LINE COUNTER PTR 19960000
         DC    FL2'224'      PVFLCT DISPLACEMENT                        19980000
PVFLCT   DC    FL4'0'              ADDR CONST OF LINE COUNTER TABLES    20000000
         DC    X'FD'        * END OF LV TABLE *                         20020000
ISAVE    DC    (FILES)F'0'              USED TO SAVE VALUES        I222 20021000
*                                       GENERATED DURING DCB BUIL  I222 20022000
*                                       FOR I.S. FILES             I222 20023000
ISFLG    EQU   ISAVE-DCBPTR             DISP TO FLAG FOR I.S.FILE  I222 20024000
KEYLNG   EQU   ISAVE-DCBPTR+1           DISP TO BIN KEYLNG FOR I.  I222 20025000
ISRLNG   EQU   ISAVE-DCBPTR+2          DISP TO I.S. RCD LENGTH     I222 20026000
*                                                                  I222 20027000
ISAVE1   DC    (FILES)F'0'             USED TO SAVE VALUES         I222 20028000
*                                      GENERATED DURING DCB BUILD  I222 20029000
ADDWKAR  EQU   ISAVE1-DCBPTR           DISP TO ADD WORKAREA ADDR        20030000
         SPACE 2                                                        20040000
*              **************************************************       20060000
*              * ESD CARD FORMAT FOR EXIT LIST EXTERNAL SYMBOLS *       20080000
*              **************************************************       20100000
         SPACE 1                                                        20120000
ESDCARD  DC    X'02'          FOR 12-2-9 PUNCH IN COLUMN 1              20140000
         DC    CL3'ESD'       COLS 2-4                                  20160000
ESDC11   EQU   10                       FOR INSERTION IN COLUMN 11      20180000
ESDCOL11 DC    XL2'0010'      COLS 11-12 (12-0-1-8-9 AND 12-11-1-8-9)   20200000
ESDID    EQU   14             COLS 15-16 (EXTERNAL SYMBOL ID)           20220000
ESDSYMBL EQU   16             COLS 17-22 (EXTERNAL SYMBOL NAME)         20240000
ESDC25   EQU   24                       FOR INSERTION IN COLUMN 25      20260000
ESDCOL25 DC    X'02000000'    COL 25  (AND 26 THRU 28 WHICH ARE ALL 0)  20280000
         EJECT                                                          20300000
*                   ********************************                    20320000
*                   * IORB TABLE - LENGTH 32 BYTES *                    20340000
*                   ********************************                    20360000
IORB$    DS    F'0'     +O    RECORD ADDRESS                            20380000
RECADD$  EQU   IORB$    +O                                              20400000
DAMPAR$  DS    F'0'      +4        DAM/ISFMS POINTR                     20420000
RECLG$   DS    H'0'      +8        RECORD LENGTH                        20440000
LCTVAL$  DS    H'0'      +10       LINE COUNTER VALUE                   20460000
KLNGTH$  EQU   LCTVAL$+1                I.S. BINARY KEYLENGTH      I222 20470000
LCTAG$   DS    X'00'     +12       LINE COUNTER TAG                     20480000
FILENO$  DS    X'00'     +13       FILE NUMBER                          20500000
ACTION$  DS    X'00'     +14       ACTION BYTE                          20520000
SKIPB$   DS    X'00'     +15       SKIP BEFORE PRINT / STACKER SELECT   20540000
SPACB$   DS    X'00'     +16       SPACE BEFORE PRINT                   20560000
SKIPA$   DS    X'00'     +17       SKIP AFTER PRINT                     20580000
SPACA$   DS    X'00'     +18       SPACE AFTER PRINT                    20600000
OV1$     DS    X'00'     +19       OV / EOF SWITCH                      20620000
OV2$     DS    X'00'     +20       SECOND OV SWITCH                     20640000
FILFORM  DS    X'00'         +21       FILE FORMAT V= VARIABLE          20660000
*        *                                         F= FIXED LENGTH      20680000
ISLIM$   DS    X'00'     +22       ISFMS WITH LIMITS ON SWITCH          20700000
FPASS$   DS    X'00'     +23       FIRST PASS SWITCH,  0B = ON          20720000
FTYPE$   DS    X'00'     +24       FILE TYPE                            20740000
TBLFLG$  DS    X'00'     +25       TABLE FLAG                           20760000
UNIT$    DS    X'00'     +26       PUNCH = 01    PRINTER = 02          X20780000
                                   RDR/PCH = 04    CNTRL PENDING = 08   20800000
*                                  TABLE FILE = 16                      20820000
WORSW    DC    X'00'          ISAM- WORSW=X'10' SETL WITH GENERIC KEY   20840000
*                                   HAS TAKEN PLACE.                    20860000
BUFADDR  DC    F'0'           ISAM- BUFFER ADDRESS FROM READ DECB       20880000
*                             IS STORED HERE WHEN WRITE IS ISSUED       20900000
*                             THIS ADDRESS IS MOVED TO WRITE DECB.      20920000
*                                                                       20940000
IORBLN$  EQU   *-IORB$                  IORB TABLE LENGTH               20960000
*                                                                       20980000
*****************************************************************       21000000
*        ACTION BYTE                 *  FILE TYPE               *       21020000
*        # 00  READ                  *  # 04   QSAM             *       21040000
*        # 02  WRITE                 *  # 08   BSAM             *       21060000
*        # 04  STACKER SELECT        *  # 12   QISAM            *       21080000
*                                    *  # 16   BDAM             *       21100000
*****************************************************************       21120000
*        OV / EOF SWITCH             *  TABLE FLAG              *       21140000
*        # 00  NO OV, NO EOF, NO EOX * = X'80' INPUT FILE       *       21160000
*        # F0  PRINTER OVERFLOW      * = X'83' COMBINED FILE            21180000
*        # 22  EOF OR END OF EXTENT  * = X'8F' OUTPUT FILE      *       21200000
*        # 33  END OF ISFMS LIMITS   * = X'84' UPDATE FILE      *       21220000
*****************************************************************       21240000
         EJECT                                                          21260000
*                      *************************                        21280000
*                      * DCB TABLE WITH FORMAT *                        21300000
*                      *************************                        21320000
         ORG   IORB$          RESET ORIGIN FOR OVERLAY                  21340000
*                                                                       21360000
DCB$     DS    75F                      DCB SETUP AREA                  21380000
EXLSTOFF EQU   X'25'               OFFSET OF EXLST FROM DCB ORIGIN      21400000
*                                                                       21420000
*              ***********************************************          21440000
*              * CODES USED FOR              RECFM AND MACRF *          21460000
*********************************************************************** 21480000
*    RECFM -        '10XX1XXX' = S    *   MACRF -                     * 21500000
*  'XXX1XXXX' = B   'XXXXX10X' = A    *  '0101001000000000' = GMC     * 21520000
*  '10XXXXXX' = F   'XXXXX01X' = M    *  '0000000001010010' = PMC     * 21540000
*  '01XXXXXX' = V   'XXXXXXX1' = KEY  *  '0010001000100000' = RC,W    * 21560000
*********************************************************************** 21580000
*                                                                       21600000
BSAMDCB  DCB   DSORG=PS,MACRF=(R,W),DDNAME=FILENAME,DEVD=RD,RECFM=UA,  X21620000
               BLKSIZE=81                                               21640000
*                                                                       21660000
BSAMLN   EQU   *-BSAMDCB                                                21680000
*                                                                       21700000
*                                                                       21720000
QSAMDCB  DCB   DSORG=PS,MACRF=GM,DDNAME=FILENAME,BFTEK=S,BFALN=D   8496 21740000
QSAMLND  EQU   *-QSAMDCB           DCB LENGTH WITH DISK                 21760000
         SPACE 1                                                        21780000
*                                                                       21800000
         SPACE 1                                                        21820000
ISAMDCB  DCB   DSORG=IS,MACRF=(GL,SK,PU),DDNAME=FILENAME                21840000
ISAML2   EQU   *-ISAMDCB                                                21860000
         READ  DECB,K,READIS,'S','S',READIS,MF=L                        21880000
ISAMLN   EQU   *-ISAMDCB          LENGTH OF ISAM DCB                    21900000
         EJECT                                                          21920000
         SPACE 2                                                        21940000
*        **********************************                             21960000
*        * CREATE THE DCB FOR A BDAM FILE *                             21980000
*        **********************************                             22000000
         SPACE 3                                                        22020000
BDAM     MVC   DCB$(BDAMDCBL),BDAMDCB    SKELETON DCB FOR BDAM FILES    22040000
         EX    0,SETDDNAM     MOVE THE FILE NAME TO THE DCB.            22060000
         LA    X12,BDAMSIZE   LENGTH OF THE INTERFACE ROUTINE.          22080000
         STH   X12,BDAMPTR                                              22100000
         MVC   DCBBLKSI(2),RECLENGT+1(COMPR)    RECORD LENGTH.          22120000
         LA    DISPLACR,BDAMDCBL  LENGTH OF THE DCB.                    22140000
         CLI   RAFTYPE(COMPR),C'K' PROCESSING BY KEYS,                  22160000
         BNE   BDAM1          NO.                                       22180000
         MVI   DCBMACR,X'31'    AND SET MACRF TO PROCESS BY KEY WITH    22200000
BDAM1    CLI   FILETYPE(COMPR),C'U' FEEDBACK.IS THIS AN UPDATE FILE,    22220000
         BNE   BDAM2          NO.                                       22240000
         MVI   DCBMACR+1,X'28'    ELSE SET TO UPDATE BY RECORD ID.      22260000
BDAM2    MVI   0(DCBREG),16   SET THIS TO BDAM FILE .                   22280000
         B     IO6E           PROCESS NEXT SPEC.                        22300000
         DC    3F'0'          SCRATCH AREA PRECEDING THE DCB.           22320000
         DC    F'0'           FEEDBACK AREA AND BLKRF AREA.             22340000
BDAMDCB  DCB   DSORG=DA,MACRF=RIC,DDNAME=FILENAME,OPTCD=FE,            122360000
               RECFM=F,LIMCT=16777215,BLKSIZE=80,BUFNO=1                22380000
BDAMDCBL EQU   *-BDAMDCB      LENGTH OF THE DCB + BLKREF + 12 BYTES.    22400000
         SPACE 2                                                        22420000
         DCBD  DSORG=(PS,IS)                                            22440000
         END                                                            22460000
