         TITLE 'IES241  OS/360 RPG STERLING IN OF LINKAGE PHASE     48' 00020000
*   A CSECT OF LINKAGE PHASE.                                           00040000
*   CODE IS PUNCHED OUT AT COMPILE TIME IF CALLED FOR BY RPG            00060000
*        SOURCE PROGRAM.                                                00080000
*   STERLING CONVERSION - INPUT CODE IS EXECUTED AT OBJECT TIME.        00100000
IES24110 START                                                          00120000
STERLIN  EQU   *                                                        00140000
**********************************************************************  00160000
*** STERLING INPUT CONVERSION ROUTINE                              ***  00180000
*********************************************************************** 00200000
RETURN   EQU   1    ADDRESS FOR RETURN                                  00220000
INPUTRCD EQU   2    ADDRESS OF INPUT RECORD                             00240000
CSECT    EQU   3    CONTROL SECTION (REGISTER 3 TO 7)                   00260000
CALC     EQU   8    USED FOR CALCULATION                                00280000
ONE      EQU   9    CONSTANT ONE(1)                                     00300000
BASE     EQU   10   BASE REGISTER                                       00320000
PTR      EQU   11   POINTER                                             00340000
CALC3    EQU   12   USED FOR CALCULATION                                00360000
CALC2    EQU   13   USED FOR CALCULATION                                00380000
WORKAREA EQU   14   ADDRESS OF BEGINNING OF COMMON WORK AREA            00400000
DEC#     EQU   15   NUMBER(#) OF DECIMALS                               00420000
*********************************************************************** 00440000
         ENTRY IESSTRCI                 STERCODI                        00460000
         ENTRY IESLR110                 LR1                             00480000
         ENTRY IESUP110                 UP1                             00500000
*                                                                       00520000
* SAVE REGISTERS,    LOCATE WORKAREA, AND INITIALIZE                    00540000
*********************************************************************** 00560000
LR1      DS    0C                                                       00580000
         USING *,BASE                                                   00600000
SUBR     ST    WORKAREA,REGWKAR       SAVE REGISTER 1                   00620000
         L     WORKAREA,232(0,3)        PICK UP ADDRESS OF WORKAREA     00640000
         MVI   0(WORKAREA),X'00'                                        00660000
         MVC   1(255,WORKAREA),0(WORKAREA)  CLEAR WORKAREA              00680000
         STM   0,15,HOLDAREA            STORE ALL REGISTERS             00700000
         LA    ONE,1               PUT CONSTANT ONE(1) INTO A REGISTER  00720000
*********************************************************************** 00740000
*                                                                       00760000
* SET UP POINTERS TO DATA                                               00780000
*                                                                       00800000
*********************************************************************** 00820000
         SR    DEC#,DEC#   PICK UP...                                   00840000
         IC    DEC#,6(RETURN)     ...NUMBER OF DECIMALS                 00860000
         LA    CALC,2      SET SHILLING LENGTH TO 2 FOR BSI             00880000
         TM    STERCODE,X'40' TEST FORMAT OF SHILLINGS                  00900000
         BZ    STORCODE    IF BSI BRANCH TO STORE INSTRUCTION           00920000
         AR    CALC,ONE                                                 00940000
STORCODE STC   CALC,SHILENTH+1                                          00960000
         AR    CALC,DEC#       COMPUTE...                               00980000
         SR    CALC2,CALC2            ...LENGTH...                      01000000
         IC    CALC2,7(RETURN)                 ...OF POUND...           01020000
         TM    STERCODE,X'40'           IF BSI SHILLINGS, LENGTH MUST   01040000
         BO    SHIFT                     BE DECREASED BY 1              01060000
         SR    CALC2,ONE                                                01080000
SHIFT    CR    CALC2,CALC               IF NO POUNDS, EXIT              01100000
         BL    RTN                                                      01120000
         SR    CALC2,CALC                                 ...FIELD...   01140000
         LTR   PTR,INPUTRCD    SET POINTER TO...                        01160000
         AH    PTR,2(RETURN)                 ...START OF FIELD          01180000
*********************************************************************** 01200000
*                                                                       01220000
* PACK AND MOVE POUNDS TO WORKAREA                                      01240000
*                                                                       01260000
*********************************************************************** 01280000
         LTR   CALC3,CALC2    SET UP...                                 01300000
         AR    CALC2,ONE                            ...POUND FIELD      01320000
         SRL   CALC2,1              ...LENGTH OF NEW...                 01340000
         LTR   CALC,CALC2          ...SAVE IT...                        01360000
         SLL   CALC2,4          AND POSITION IT WITH OLD LENGTH...      01380000
         AR    CALC2,CALC3      ...FOR INSTRUCTION MASK                 01400000
         EX    CALC2,PACKPDS    EXECUTE PACK POUNDS                     01420000
         AR    PTR,CALC3      SET POINTER TO LAST POUND                 01440000
*                                                                       01460000
* ADD PLUS SIGN AND CONVERT POUNDS TO SHILLINGS                         01480000
*                                                                       01500000
         LTR   CALC2,CALC       SAVE LENGTH OF POUND FIELD              01520000
         AR    CALC,WORKAREA  SET UP INSTRUCTION MASK                   01540000
         NI    2(CALC),X'F0'  KNOCK OF ZONE IN LAST POUND DIGIT         01560000
         MVI   3(CALC),X'0C'  PUT ZERO AND PLUS SIGN AT END OF POUNDS   01580000
         LTR   CALC3,CALC2    SET UP...                                 01600000
         AR    CALC3,ONE            ...INSTRUCTION...                   01620000
         SLL   CALC3,4                            ...MASK               01640000
         AR    CALC3,CALC2    ...FOR MOVE WITH OFFSET INSTRUCTION       01660000
         EX    CALC3,MVPDSWOS EXECUTE MOVE POUNDS WITH OFFSET INSTRUCT. 01680000
         AR    CALC3,ONE      CORRECT INSTRUCTION MASK                  01700000
         EX    CALC3,ADPDTOPD EXECUTE ADD PDS TO PDS INSTRUCTION        01720000
         AR    CALC2,ONE      CORRECT SHILLING FIELD LENGTH...          01740000
         LTR   CALC,CALC2     ...SAVE IT...                             01760000
         SLL   CALC2,4        ...AND POSITION AS INSTRUCTION MASK       01780000
*                                                                       01800000
* CONVERT SHILLINGS AND ADD TO POUNDS FIELD                             01820000
*                                                                       01840000
         TM    STERCODE,X'40' TEST SHILLING FORMAT                      01860000
         BZ    BSISHIL        BRANCH TO BSI SHILLING CONVERSION         01880000
         PACK  TEMP(2),1(2,PTR) IBM CONVERSION                          01900000
         OI    TEMP+1,X'0C'        FORCE PLUS SIGN               A33543 01910020
         AR    PTR,ONE        ADD EXTRA ONE TO POINTER AS IBM USES 2    01920000
         B     ENDOFSHL       EXIT                                      01940000
BSISHIL  MVC   TEMP(1),1(PTR)   MOVE SHILLINGS TO TEMPORARY STORAGE     01960000
         NI    TEMP,X'0F'       KNOCK OFF ZONES                         01980000
         TM    1(PTR),X'B0'     TEST SHILLING ZONE                      02000000
         BC    9,SHILMVII       IF ALL ZEROS OR ALL ONES TENS DIGIT BR  02020000
         OI    TEMP,X'10'       STORE TENS DIGIT                        02040000
SHILMVII MVI   TEMP+1,X'0C'     STORE PLUS SIGN                         02060000
         MVO   TEMP(2),TEMP(1)  POSITION DIGITS AND SIGN                02080000
ENDOFSHL AR    PTR,ONE          SET POINTER TO LAST SHILLING DIGIT      02100000
         EX    CALC2,ADSHTOPD   EXECUTE ADD SHILLINGS TO POUNDS INSTRU  02120000
*                                                                       02140000
* CONVERT PENCE TO DECIMAL FORMAT AND ADD TO  CONVER                    02160000
*                                                                       02180000
*   THIS NEXT INSTRUCTION IS NECESSARY BECAUSE OF VAGARIES OF MP INST.  02200000
         MVC   0(2,WORKAREA),TWOZROS   PUT IN MULTIPLY PAD              02220000
         AR    CALC,ONE       CORRECT ...                               02240000
         AR    CALC,ONE            ...FIELD LENGTH...                   02260000
         LTR   CALC2,CALC                         ...SAVE IT            02280000
         SLL   CALC2,4        ...AND POSITION FOR INSTRUCTION MASK      02300000
         LA    CALC2,1(CALC2)           PLACE MULTIPLIER LENGTH-1       02320000
         EX    CALC2,SHTOPENC  MULT SHIL BY 12 TO CONVERT TO PENCE      02340000
         AR    PTR,ONE        SET POINTER TO PENCE DIGIT                02360000
         MVC   TEMP(1),0(PTR)   TRANSFER PENCE DIGIT TO TEMPORARY STORE 02380000
         NI    TEMP,X'0F'       KNOCK OFF PENCE ZONE                    02400000
         TM    0(PTR),X'B0'     TEST PENCE ZONE                         02420000
         BC    9,PENCMVII       IF NOT 5(+) OR 6(-) GO TO MOVE IMM INST 02440000
         LA    CALC3,16         PUT X'10' INTO CALC3 REGISTER           02460000
         TM    0(PTR),X'10'     TEST EPNCE ZONE                         02480000
         BZ    PZNMINUS         IF PENCE ZONE IS MINUS BRANCH           02500000
         TM    STERCODE,X'20'   TEST FOR IBM OR BSI FORMAT              02520000
         BZ    PENCLEVN         IBM FORMAT SO ELEVEN PENCE              02540000
         BO    STORPENC         BSI FORMAT SO STORE  10 PENCE           02560000
PZNMINUS TM    STERCODE,X'20'   TEST FOR IBM OR BSI FORMAT              02580000
         BZ    STORPENC         IBM FORMAT SO STORE  10 PENCE           02600000
PENCLEVN AR    CALC3,ONE        BSI FORMAT SO ELEVEN PENCE              02620000
STORPENC STC   CALC3,TEMP       STORE PENCE                             02640000
PENCMVII MVI   TEMP+1,X'0C'   ADD PLUS SIGN                             02660000
         MVO   TEMP(2),TEMP(1)  POSITIONS PENCE DIGITS AND SIGN         02680000
         EX    CALC2,ADPETOPD                                           02700000
*                                                                       02720000
* PACK AND MOVE DECIMALS TO POUND FIELD                                 02740000
*                                                                       02760000
         LTR   CALC3,WORKAREA      SET POINTER TO LAST DIGIT...         02780000
         AR    CALC3,CALC               ...OF PENCE FIELD.              02800000
         LTR   DEC#,DEC#           SET CONDITION CODE OF NO. OF DEC DGT 02820000
         BZ    STORSIGN                 IF NO DECIMAL DIGITS, EXIT      02840000
         TM    6(RETURN),X'01'     TEST DEC DGTS FOR A UNITS DIGIT(1-3) 02860000
         BZ    TWODEC              IF NO UNITS DIGIT, 2 DECIMAL DIGITS  02880000
* NOTE - THIS INSTRUCTION DEPENDS ON A LEADING ZERO INTRODUCED BY MULT  02900000
         SRL   CALC2,4                  SET UP MASK TO MOVE WITH        02920000
         LR    0,CALC2                       OFFSET THE ACCUMULATED     02940000
         SLL   CALC2,4                       PENCE FIELD SO 1 DECIMAL   02960000
         OR    CALC2,0                       MAY BE INSERTED            02980000
         EX    CALC2,MVPDWOS2      EXECUTE OFFSET INSTRUCTION           03000000
         TM    6(RETURN),X'02'     TEST DEC DGTS FOR A TWOS DIGIT (3)   03020000
         BZ    ONEDEC              IF NO TWOS DGT,THEN 1 DECIMAL DIGIT  03040000
         PACK  0(2,CALC3),1(3,PTR) PACK 3 DEC DIGITS TO PENCE FIELD     03060000
         B     THREEDEC            BRANCH TO CORRECT LPDFLD  INSTRUCT.  03080000
ONEDEC   PACK  0(1,CALC3),1(1,PTR) PACK  ONE DECIMAL DIGIT TO PENCE FLD 03100000
         B     STORSIGN              EXIT TO STORE SIGN                 03120000
TWODEC   UNPK  TEMP(1),0(1,CALC3)  MOVE AND UNPACK LAST PENCE DIGIT     03140000
         MVC   TEMP+1(2),1(PTR)    MOVE 2 DECIMAL DIGITS NEXT TO PE DGT 03160000
         PACK  0(2,CALC3),TEMP(3)  PACK ALL THREE DIGITS TO PENCE FIELD 03180000
THREEDEC AR    CALC,ONE            CORRET LENGTH OF POUND FIELD         03200000
*                                                                       03220000
* SUFFIX SIGN TO ANSWER                                                 03240000
*                                                                       03260000
         AR    CALC3,ONE                ADJUST FOR POSSIBLE MINUS SIGN  03280000
STORSIGN TM    4(RETURN),X'FF'     TEST SIGN DISPLACEMENT FOR STDRD POS 03300000
         BO    STANSIGN            BRANCH IF SIGN IN STANDARD POSITION  03320000
         LH    PTR,4(RETURN)       SET POINTER...                       03340000
         AR    PTR,INPUTRCD                   ...TO SIGN POSITION.      03360000
         SR    PTR,ONE                  ADJUST SIGN POSITION            03380000
         TM    0(PTR),X'D0'             TEST FOR MINUS SIGN             03400000
         B     BRONPLUS            BRANCH TO BRANCH ON PLUS INST        03420000
STANSIGN LTR   DEC#,DEC#           TEST NUMBER OF DECIMALS              03440000
         BNE   STORANS             SIGN ALREADY STORED IF THERE ARE DEC 03460000
         SH    PTR,SHILENTH        SET POINTER TO LAST POUND POSITION.  03480000
         TM    0(PTR),X'D0'        TEST SIGN FOR MINUS                  03500000
BRONPLUS BM    STORANS                  BRANCH IF SIGN NOT MINUS        03520000
         TM    0(PTR),X'F0'             BRANCH IF ZONE IS NUMERIC (F)   03540000
         BO    STORANS                                                  03560000
         NI    0(CALC3),X'F0'           KNOCK OFF SIGN                  03580000
         OI    0(CALC3),X'0D'           PUT IN MINUS SIGN               03600000
*                                                                       03620000
* STORE ANSWER(IN PENCE AND DECIMAL PENCE) IN TARGET FIELD              03640000
*                                                                       03660000
STORANS  MVC   LAINST+2(2),8(RETURN)   PICK UP TARGET FLD BASE AND DISP 03680000
LAINST   LA    DEC#,0(0,0)             CONVERT TO ADDRESS               03700000
         SR    CALC3,CALC3             CLEAR REGISTER                   03720000
         IC    CALC3,10(RETURN)        PICK UP LENGTH TO TARGET FIELD   03740000
         LTR   CALC2,CALC              PICK UP LENGTH OF ANSWER FIELD   03760000
         SR    CALC2,CALC3             COMPARE THE TWO LENGTHS          03780000
         BZ    STORANSI       IF LENGTHS EQUAL BRANCH TO STORE ANS INST 03800000
         BP    LONGANS        BRANCH IF ANSWER FIELD IS LARGER          03820000
*                             TARGET FIELD IS LARGER                    03840000
         LPR   CALC2,CALC2    SET LENGTH DIFFERENCE POSITIVE            03860000
         MVI   0(DEC#),0                                                03880000
         AR    DEC#,ONE                                                 03900000
         EX    CALC2,CLEARTAR   EXECUTE INSTRUCTION TO CLEAR TARGET FLD 03920000
         AR    DEC#,CALC2       CORRECT TARGET FIELD                    03940000
         B     STORANSI       BRANCH TO STORE ANSWER INSTRUCTIONS       03960000
LONGANS  AR    WORKAREA,CALC2   CORRECT POINTER TO PENCE TO PU LAST DGT 03980000
         LTR   CALC,CALC3       GET CORRECT LENGTH INTO CALC REGISTER   04000000
STORANSI EX    CALC,FINALMVI    EXECUTE FINAL MOVE OF ANSWER INST.      04020000
*                                                                       04040000
* RESTORE REGISTERS AND RETURN TO CALLING PROGRAM                       04060000
*                                                                       04080000
RTN      LM    0,15,HOLDAREA            RESTORE ALL REGISTERS           04100000
         L     WORKAREA,REGWKAR RESTORE REGISTER  1                     04120000
         LA    RETURN,12(RETURN)        INCREMENT RETURN REGISTER BY 12 04140000
         BCR   15,RETURN                RE-ENTER ASSEMBLE PHASE         04160000
*********************************************************************** 04180000
*                                                                       04200000
* CONSTANTS AND TEMPORARY STORAGE                                       04220000
*                                                                       04240000
*********************************************************************** 04260000
REGWKAR  DS    A         STORAGE FOR REGISTER LABELLED WORKAREA         04280000
STERCODE DS    C                                                        04300000
SHILENTH DC    H'0'      HOW MANY CHARACTERS IN SHILLING - 1 OR 2       04320000
TWOZROS  DC    X'0000'        ZEROES FOR MULTIPLY PAD                   04340000
TEMP     DS    F         TEMPORARY STORAGE                              04360000
PACKPDS  PACK  2(0,WORKAREA),0(0,PTR) PACK POUNDS FROM  INPUTRCD TO WKA 04380000
ADSHTOPD AP    2(0,WORKAREA),TEMP(2)       ADD SHILLINGSTO POUNDS INST  04400000
MVPDSWOS MVO   2(0,WORKAREA),2(0,WORKAREA) MOVE POUNDS WITH OFFSET      04420000
ADPDTOPD AP    2(0,WORKAREA),2(0,WORKAREA)  ADD POUNDS TO POUNDS TO GET 04440000
SHTOPENC MP    0(0,WORKAREA),TWELVE(0)  MPY SHILLINGS BY 12 TO GET PENC 04460000
TWELVE   DC    X'012C'   CONVERSION FACTOR-SHILLINGS TO PENCE           04480000
ADPETOPD AP    0(0,WORKAREA),TEMP(2)   ADD PENCE TO POUND FIELD         04500000
MVPDWOS2 MVO   0(0,WORKAREA),0(0,WORKAREA)  POSITION PENCE FOR DECIMALS 04520000
CLEARTAR MVC   0(0,ONE),0(DEC#)     CLEAR TARGET FIELD INSTRUCTION      04540000
FINALMVI MVC   0(0,DEC#),0(WORKAREA)    FINAL MOVE INSTRUCTION          04560000
HOLDAREA DS    16F                                                      04580000
STERCODI EQU   STERCODE      STERLING CODE                              04600000
UP1      DC    C'0'                                                     04620000
IESLR110 EQU   LR1                                                      04640000
IESUP110 EQU   UP1                                                      04660000
IESSTRCI EQU   STERCODI                                                 04680000
         END                                                            04700000
