         TITLE 'IES242  OS/360 RPG STERLING OUT OF LINKAGE PHASE    49' 00020000
*   A CSECT OF LINKAGE PHASE.                                           00040000
*   CODE IS PUNCHED OUT AT COMPILE TIME IF CALLED FOR BY RPG            00060000
*        SOURCE PROGRAM.                                                00080000
*   STERLING CONVERSION - OUTPUT CODE IS EXECUTED AT OBJECT TIME.       00100000
IES24210 START                                                          00120000
STERLOUT EQU   *                                                        00140000
*************  ***********  **********************************          00160000
*** STERLING OUTPUT CONVERSION ROUTINE                              *** 00180000
*** THIS ROUTINE WILL CONVERT A PACKED PENCE FIELD WITH A MAXIMUM   *** 00200000
***  OF EIGHT POSITIONS TO A POUNDS-SHILLINGS-PENCE-DECIMAL PENCE   *** 00220000
***  CONFIGURATION                                                  *** 00240000
*** A MAXIMUM OF THREE DECIMAL POSITIONS MAY BE SPECIFIED           *** 00260000
*********************************************************************** 00280000
         ENTRY IESSTRCO                 STERCODO                        00300000
         ENTRY IESLR210                 LR2                             00320000
         ENTRY IESUP210                 UP2                             00340000
*********************************************************************** 00360000
***                      REGISTER ASSIGNMENTS                       *** 00380000
*********************************************************************** 00400000
RETURN   EQU   1                        RETURN REGISTER                 00420000
DATBS1   EQU   3                        CONTROL (REGISTERS 3-7)         00440000
DATA     EQU   8                        WORK REGISTER                   00460000
WORK     EQU   9                        ADDRESS OF WORKAREA+85          00480000
LONG     EQU   10                       WORK REGISTER                   00500000
DEC      EQU   11                       WORK REGISTER                   00520000
HOLD     EQU   12                       WORK REGISTER                   00540000
BASE     EQU   15                       BASE REGISTER                   00560000
*********************************************************************** 00580000
*** SAVE REGISTERS - LOCATE AND CLEAR WORKAREA                      *** 00600000
*********************************************************************** 00620000
LR2      DS    0C                                                       00640000
STEROT   BALR  BASE,0                                                   00660000
         USING *,BASE                                                   00680000
         STM   0,15,HOLDAREA            SAVE REGISTERS 8-12             00700000
         L     WORK,232(0,DATBS1)       LOAD FIRST USABLE POSITION      00720000
         LA    WORK,85(WORK)                       OF WORKAREA          00740000
         USING WORKAREA,WORK              OF WORKAREA                   00760000
         XC    WORKAREA(171),WORKAREA   CLEAR USABLE WORK AREA          00780000
*********************************************************************** 00800000
*** PICKUP ADDRESS AND LENGTH OF PENCE FIELD AS WELL AS NUMBER OF   *** 00820000
***  INPUT DECIMAL PENCE                                            *** 00840000
*********************************************************************** 00860000
         SR    DATA,DATA                CLEAR REGISTER                  00880000
         MVC   LOADINST+2(2),2(RETURN)  MOVE BASE AND DISPLACEMENT TO   00900000
LOADINST LA    DATA,0(DATA,0)           ADDRESS OF PENCE FIELD          00920000
         MVI   OUTFLD+15,X'CC'          PUT PLUS SIGN IN OUTPUT FIELD   00940000
*********************************************************************** 00960000
*** UNPACK PENCE FIELD PLACING DECIMAL POSITIONS                    *** 00980000
*** REPACK ALL NON-DECIMAL PENCE AND EXECUTE DIVISIONS FOR THE      *** 01000000
***   POUNDS, SHILLINGS, AND PENCE FIELDS                           *** 01020000
*** THEN UNPACK THE THREE FIELDS AND REMOVE SIGNS                   *** 01040000
*********************************************************************** 01060000
         MVC   DECPENC(3),F0            PUT PADDING IN DECIMAL POSITION 01080000
         LA    LONG,12                  LOAD 11 FOR MINIMUM PACK-1      01100000
         MVN   WORD+3(1),7(RETURN)      FULL-WORD ALIGN NO. DECIMAL     01120000
         A     LONG,WORD                 POSITIONS FOR ADD - THEN ADD   01140000
         LR    HOLD,LONG                STORE NO. DIGITS PACKED-1       01160000
         SLL   LONG,4                   SHIFT LEFT FOR USE IN UNPACK    01180000
         SR    DEC,DEC                  CLEAR REGISTER                  01200000
         IC    DEC,5(RETURN)            INSERT UNPACKED PENCE FIELD     01220000
         A     DEC,ONE                  ADD ONE SO PACKED LENGTH WILL   01240000
         SRL   DEC,1                     BE CORRECT AFTER SHIFTING-SHFT 01260000
         OR    LONG,DEC                 PLACE PACKED LENGTH FOR UNPACK  01280000
         EX    LONG,UNPACK              UNPACK FIELD PLACING DECIMALS   01300000
         LA    LONG,POUNDS              ADD FIELD LENGTH TO BEG. OF FLD 01320000
         AR    HOLD,LONG                POINT TO POSITION OF SIGN       01340000
         TM    0(HOLD),X'F0'            TEST FOR NUMERIC SIGN ZONE      01360000
         BO    REPACK                   NUMERIC, THEREFORE PLUS ASSUMED 01380000
         TM    0(HOLD),X'D0'            IS SIGN NEGATIVE                01400000
         BM    REPACK                   NO - GO TO REPACK ALL BUT DECS. 01420000
         MVI   OUTFLD+15,X'DD'          YES - PUT NEGATIVE SIGN IN OUTP 01440000
REPACK   MVZ   0(1,HOLD),F0             REMOVE SIGN FROM INPUT FIELD    01460000
         PACK  POUNDS(13),POUNDS(13)                                    01480000
         DP    POUNDS(13),TWOFORTY      DIVIDE PENCE BY 240 FOR POUNDS  01500000
         DP    POUNDS+9(4),TWELVE       DIVIDE REMAINDER BY 12 FOR SHLS 01520000
         UNPK  STORE1(9),POUNDS+4(5)    UNPACK POUND FIELD INTO STG     01540000
         MVC   POUNDS(9),STORE1         MOVE UNPACKED FIELD TO POUNDS   01560000
         UNPK  POUNDS+9(2),POUNDS+9(2)  UNPACK SHILLING FIELD           01580000
         UNPK  POUNDS+11(2),POUNDS+11(2)  UNPACK PENCE FIELD            01600000
         MVZ   POUNDS+1(12),POUNDS      REMOVE SIGN ZONES FROM 3 FIELDS 01620000
*********************************************************************** 01640000
*** CHECK LAST 4 BITS OF BYTE STERCODE (CXSTRLNG IN CIOEX DATA) TO  *** 01660000
***   DETERMINE WHETHER IBM OR BSI IS REQUIRED FOR SHILLING AND     *** 01680000
***   PENCE OUTPUT -- CHANGE FIELDS ACCORDINGLY                     *** 01700000
*** THEN CHECK FOR PRINT OR PUNCH OUTPUT                            *** 01720000
***   IF PRINT, PACK FIELD TO FINAL WORKAREA FIELD AND EXIT         *** 01740000
***   IF PUNCH, CHECK FOR STANDARD SIGN -- IF STANDARD NOT          *** 01760000
***     SPECIFIED, MOVE CHARACTERS TO FINAL FIELD AND EXIT          *** 01780000
***     IF STANDARD, PLACE SIGN IN RIGHTMOST POSITION OD DEC PENCE  *** 01800000
***     FIELD IF THERE ARE ANY, OTHERWISE IN RIGHTMOST POSITION OF  *** 01820000
***     POUND FIELD                                                 *** 01840000
*** IT IS NECESSARY TO DETERMINE THE NUMBER OF OUTPUT DECIMALS      *** 01860000
***  DESIRED SO THAT THE CORRECT NUMBER OF FIELDS ARE MOVED, AND SO *** 01880000
***  THE STANDARD SIGN MAY BE PLACED NEXT TO THE LAST DECIMAL       *** 01900000
*********************************************************************** 01920000
         TM    8(RETURN),X'80'          PRINT REQUESTED                 01940000
         BO    OUTYPE                   YES                             01960000
         MVC   PAD(2),F0                PAD FOR PUNCH/TAPE FIELDS       01980000
         MVZ   POUNDS+8(1),OUTFLD+15    MOVE SIGN TO LOW ORDER POUNDS   02000000
TSTPENCE CLC   PENCE(2),TEN             COMPARE PENCE WITH TEN          02020000
         BL    MOVE                     IF LOW, LEAVE AS IS, MOVE FIELD 02040000
         MVI   STORE1,X'50'             PLACE TWELVEPUNCH FOR PENCE     02060000
         TM    STERCODE,X'01'           IS IBM PENCE REQUESTED          02080000
         BO    IBM                      YES                             02100000
         CLC   PENCE(2),TEN             NO - IS PENCE EQUAL TO 10       02120000
         BE    MOVEP                    YES, SHIFT FIELD                02140000
ELVPNCH  MVI   STORE1,X'60'             NO, PUT ELEVENPUNCH FOR PENCE   02160000
         B     MOVEP                                                    02180000
IBM      CLC   PENCE(2),TEN             IS PENCE EQUAL TO 10            02200000
         BE    ELVPNCH                  YES, PUT ELEVENPUNCH            02220000
MOVEP    MVC   PENCE+1(1),STORE1                                        02240000
MOVE     MVC   OUTFLD+4(11),POUNDS      MOVE POUNDS AND SHILS TMPRARILY 02260000
         MVC   POUNDS+1(11),OUTFLD+4    MOVE BACK, DELETING 1 PENCE FLD 02280000
         MVI   POUNDS,X'F0'             PUT PAD IN FIELD                02300000
         TM    STERCODE,X'04'           IS IBM SHILLING REQUESTED       02320000
         BO    OUTYPE                   YES - NEED NOT CHANGE ANYTHING  02340000
         CLC   SHILS+1(2),TEN           COMPARE SHILLINGS WITH TEN      02360000
         BL    SHIFT                    LOW - LEAVE AS IS, SHIFT FIELD  02380000
         BE    TWLVPNCH                                                 02400000
         MVZ   SHILS+2,PLUS             PLACE ALPHA ZONE FOR 11-19 SHLS 02420000
         B     SHIFT                                                    02440000
TWLVPNCH MVI   SHILS+2,X'50'            PUT TWELVEPUNCH FOR SHILLING    02460000
SHIFT    MVC   OUTFLD+5(9),POUNDS+1     MOVE POUNDS TO TEMP AREA - PUT  02480000
         MVC   POUNDS+2(9),OUTFLD+5     BACK, REMOVING 1 SHILLING FIELD 02500000
         MVI   POUNDS+1,X'F0'           PUT FILLER IN HIGH ORDER POSITN 02520000
OUTYPE   SR    DEC,DEC                  CLEAR REGISTER                  02540000
         IC    DEC,6(RETURN)            PLACE NO. DECS. IN REGISTER     02560000
         LA    DATA,12                  LOAD 12 IN REGISTER             02580000
         AR    DATA,DEC                 ADD NO DEC POS TO GET FLD-1     02600000
         LA    LONG,14                  LOAD 14 (NO -1 TO MOVE)         02620000
         SLL   LONG,4                   SHIFT LEFT 4 FOR PACK INST      02640000
         OR    LONG,DATA                PUT LENGTH-1 OF FLD TO MOVE     02660000
         LA    HOLD,PAD                                                 02680000
         AR    HOLD,DEC                                                 02700000
         TM    8(RETURN),X'40'          NON-STANDARD SIGN REQUESTED     02720000
         BO    MVZONE                   YES                             02740000
         TM    8(RETURN),X'80'          PRINT REQUESTED                 02760000
         BZ    PUNCH                    NO                              02780000
         MVZ   POUNDS+9(2),F0           CLEAR SIGN FROM POUNDS FIELD    02800000
         EX    LONG,PACK                EXECUTE PACK INST FOR PRINT OUT 02820000
         MVN   OUTFLD+14(1),OUTFLD+15   ATTACH SIGN TO LOW ORDER POS.   02840000
EXIT     MVI   PAD,X'40'                MOVE BLANK FOR EDIT PURPOSES    02860000
         NI    OUTFLD+15,X'F0'          CLEAR NUMERIC PORTION OF SIGN   02880000
         LM    0,15,HOLDAREA            RESTORE REGISTERS               02900000
         LA    RETURN,10(RETURN)        INC. RETURN REGISTER BY 10      02920000
         BCR   15,RETURN                                                02940000
PUNCH    LTR   DEC,DEC                                                  02960000
         BE    PUTOUT                   IF ZERO, SIGN IN POUNDS O.K.    02980000
         MVZ   POUNDS+9(2),F0           NOT ZERO - REMOVE SIGN FROM LBS 03000000
         MVC   OUTFLD(15),0(HOLD)       MOVE FIELD TO OUTPUT AREA       03020000
         MVZ   OUTFLD+14(1),OUTFLD+15   PUT SIGN IN DEC POSITION        03040000
         B     EXIT                                                     03060000
MVZONE   MVZ   POUNDS+9(2),F0           CLEAR SIGN FROM PDS. FOR NONSTD 03080000
PUTOUT   MVC   OUTFLD(15),0(HOLD)       MOVE FIELD TO OUTPUT AREA       03100000
         B     EXIT                                                     03120000
PACK     PACK  OUTFLD(0),POUNDS(0)                                      03140000
UNPACK   UNPK  POUNDS(0),0(0,DATA)      EXECUTED WITH LENGTHS ORED IN   03160000
*********************************************************************** 03180000
***                      STORAGE DEFINITIONS                        *** 03200000
*********************************************************************** 03220000
F0       DC    3X'F0'                                                   03240000
TWOFORTY DC    X'0000240C'                                              03260000
TWELVE   DC    X'012C'                                                  03280000
STERCODE DC    C'0'                                                     03300000
TEN      DC    X'F1F0'                                                  03320000
PLUS     DC    X'C0'                                                    03340000
WORD     DC    F'0'                                                     03360000
ONE      DC    F'1'                                                     03380000
HOLDAREA DS    16F                                                      03400000
STERCODO EQU   STERCODE      STERLING CODE                              03420000
UP2      DC    C'0'                                                     03440000
*********************************************************************** 03460000
***                      WORKAREA DEFINITIONS                       *** 03480000
*********************************************************************** 03500000
WORKAREA DSECT                                                          03520000
OUTFLD   DS    16C                                                      03540000
PAD      DS    2C                                                       03560000
POUNDS   DS    9C                                                       03580000
SHILS    DS    2C                                                       03600000
PENCE    DS    2C                                                       03620000
DECPENC  DS    3C                                                       03640000
STORE1   DS    9C                                                       03660000
STORE2   DS    1C                                                       03680000
IESSTRCO EQU   STERCODO                                                 03700000
IESLR210 EQU   LR2                                                      03720000
IESUP210 EQU   UP2                                                      03740000
         END                                                            03760000
