         TITLE 'IES246  OS/360 RPG TABLE LOOK-UP OF LINKAGE PHASE   53' 00020000
*   A CSECT OF LINKAGE PHASE.                                           00040000
*   CODE IS PUNCHED OUT AT COMPILE TIME IF CALLED FOR BY RPG            00060000
*        SOURCE PROGRAM.                                                00080000
*   TABLE LOOK-UP CODE IS EXECUTED AT OBJECT TIME.                      00100000
IES24610 START                                                          00120000
LOKIT    EQU   *                                                        00140000
************************************************************            00160000
************************************************************            00180000
         ENTRY IESLR310                 LR3                             00200000
         ENTRY IESUP310                 UP3                             00220000
LR3      EQU   *                                                        00240000
RELOC    EQU   3                                                        00260000
SAVE1    EQU   6                                                        00280000
POINT2   EQU   6              MUST BE EVEN   NOTE  POINT2+1 USED        00300000
FCTTLF   EQU   8              CANNOT EQU ARGTLF                         00320000
TURNIN   EQU   POINT2                                                   00340000
SEARCH   EQU   9              MUST BE ODD                               00360000
ARGTLF   EQU   SEARCH+1                                                 00380000
TABLE    EQU   SEARCH+2       ARGTLF+1                                  00400000
LENGTH   EQU   SEARCH+3       TABLE +1                                  00420000
END      EQU   SEARCH+4       LENGTH+1                                  00440000
SAVE2    EQU   13                                                       00460000
PARAM    EQU   14                                                       00480000
RETURN   EQU   14                                                       00500000
MYBASE   EQU   15                                                       00520000
*                                                                       00540000
         USING *,MYBASE                                                 00560000
         USING TLF,ARGTLF                                               00580000
         USING PRLIST,PARAM                                             00600000
************************************************************            00620000
*                                                                       00640000
LOKUP    EQU   *                                                        00660000
         STM   SAVE1,SAVE2,GRSAVE       SAVE GENERAL REGISTERS          00680000
         EX    0,TOHILO            TURN OFF HI/LO INDICATOR             00700000
         EX    0,TOEQ              TURN OFF EQ INDICATOR                00720000
         IC    TURNIN,INDON                                             00740000
         LM    SEARCH,ARGTLF,TOF1   GET ADR OF F1-SEARCH VALUE          00760000
*                                    AND ADR OF F2-ARG TABLE HOLD AREA  00780000
         AR    SEARCH,RELOC      DO OWN RELOCATION                      00800000
         AR    ARGTLF,RELOC                                             00820000
         SH    ARGTLF,SUBTLF     DECREMENT BACK TO BEGINNING OF TLF     00840000
         TM    TOF1EX,F1MASK        Q. IS F1 EXTERNAL   (ULABL)         00860000
         BZ    NOTEX        GO IF NOT EXTERNAL                          00880000
         L     SEARCH,0(SEARCH)                                         00900000
*                                       NOW SET FOR  BXLE LOOP          00920000
*                                                                       00940000
NOTEX    EQU   *                                                        00960000
         L     TABLE,TLSTRT   PICK UP STARTING ADDR OF ARG TABLE        00980000
         L     END,TLEND      PICK UP ENDING ADDR OF ARG TABLE          01000000
         BCTR  END,0     USE BXLE BUT NO BRANCH ON EQUAL                01020000
         EJECT                                                          01040000
         SR    LENGTH,LENGTH       SET TO ZERO                          01060000
         IC    LENGTH,TLLEN   PICK UP LENGTH OF TABLE VALUE             01080000
*                                                                       01100000
         TM    TLALPH,ALMASK                                            01120000
         BO    NOADJ1    GO IF ALPHA AND NO LENGTH ADJUST NEEDED        01140000
         LA    LENGTH,1(0,LENGTH)    DO LENGTH+1 FOR ((LENGTH+1)/2)     01160000
         SRL   LENGTH,1(0)      DIVIDE TO GET NUMERIC MOVE LENGTH       01180000
*                                                                       01200000
NOADJ1   EQU   *                                                        01220000
*                                                                       01240000
*              MOVE LENGTHS FOR INSERTION INTO INSTRUCTIONS ARE THUS    01260000
*                        ALPHA--LENGTH       NUMERIC--((LENGTH+1)/2)    01280000
*                                                                       01300000
         STC   LENGTH,COMP+1  INSERT LENGTH FOR CLC OR RIGHT HALF OF CP 01320000
         STC   LENGTH,MOVEIN+1                                          01340000
         LA    LENGTH,1(0,LENGTH)                                       01360000
         MVI   COMP,CLC       ASSUME CLC--CHANGE LATER IF NUMERIC COMPR 01380000
CLC      EQU   X'D5'      OP CODE FOR CLC                               01400000
*                                                                       01420000
         MVZ   BYTE,TOKEY    * SET BYTE FOR SPECIAL                     01440000
         MVN   BYTE,TLALPH             LOW...ASCENDING OR               01460000
         NI    BYTE,X'E3'              HIGH DESCENDING TEST             01480000
LOASCD   EQU   X'41'     BYTE CONTENT IF LOW SEARCH,ASCENDING TABLE     01500000
HIDSCD   EQU   X'82'     BYTE CONTENT IF HI SEARCH,DESCENDING TABLE     01520000
*                                                                       01540000
         TM    TLALPH,ALMASK                                            01560000
         BO    COMP           GO IF ALPHA TABLE                         01580000
* STAY IF NUMERIC TABLE                                                 01600000
         MVO   COMP+1(1),COMP+1(1)  GET LEFT HALF LENGTH FOR CP         01620000
         MVI   COMP,CP   INSERT OP CODE FOR NUMERIC COMPARE             01640000
CP       EQU   X'F9'     COMPARE PACKED OP CODE                         01660000
*                                                                       01680000
COMP     CLC   0(0,SEARCH),0(TABLE)  OP AND LENGTH SET AT OBJECT TIME   01700000
         BE    EQUL      GO IF EQUAL TABLE VALUE AND SEARCH ARG         01720000
         BH    HIGH      GO IF SEARCH ARG HIGHER THAN TABLE VALUE       01740000
*  STAY IF SEARCH ARG LESS THAN TABLE VALUE                             01760000
         TM    TLASCD,ASMASK   Q. ASCENDING TABLE                       01780000
         BO    FOUND      GO IF IN BETWEEN TABLE VALUES                 01800000
NEXT     EQU   *                                                        01820000
         BXLE  TABLE,LENGTH,COMP                                        01840000
         SR    TABLE,LENGTH                                             01860000
         TM    BYTE,LOASCD        END OF ASCENDING TABLE WITH           01880000
         BO    TAKEIT             LOW SEARCH SO USE LAST VALUE          01900000
         TM    BYTE,HIDSCD           END OF DESCENDING TABLE WITH       01920000
         BO    TAKEIT                HIGH SEARCH SO USE LAST VALUE      01940000
         B     SET3     ERROR .....NOT FOUND.....                       01960000
************************************************************            01980000
         EJECT                                                          02000000
FOUND    TM    TOHISH,HIMASK   Q. IS THIS HI SEARCH                     02020000
         BO    TAKEIT      GO USE PRESENT TABLE VALUE IF HI,ASCND       02040000
         TM    TOLOSH,LOMASK    Q. IS THIS LO SEARCH                    02060000
         BO    S           GO USE PRIOR TABLE VALUE IF LO,ASCND         02080000
         B     SET3     ...NOT FOUND...ERROR                            02100000
************************************************************            02120000
S        EQU   *                                                        02140000
*                          STAY HERE IF USE PRIOR VALUE                 02160000
*                          BUT CHECK NOT FIRST TABLE ENTRY              02180000
         SR    TABLE,LENGTH                                             02200000
         CL    TABLE,TLSTRT                                             02220000
         BL    SET3    GO ERROR EXIT IF FIRST TABLE VALUE               02240000
************************************************************            02260000
*                                                                       02280000
TAKEIT   EQU   *                                                        02300000
         EX    TURNIN,TOHILO  SET HI/LO INDICATOR                       02320000
TAKE     ST    TABLE,TLADR     SAVE PRESENT ADDR IN TLF                 02340000
MOVEIN   MVC   TLTAB,0(TABLE)  LENGTH SET AT OBJECT TIME                02360000
************************************************************            02380000
         EJECT                                                          02400000
*                                  CALCULATE NUMBER OF ENTRIES INTO     02420000
*                                  TABLE FOR FUNCTION MOVE              02440000
*                                                                       02460000
         L     FCTTLF,TORF         GET BASE FOR RF -- FUNCTION TLF BASE 02480000
         DROP  ARGTLF                                                   02500000
         USING TLF,FCTTLF          BASE FOR FUNCTION TLF                02520000
         LA    FCTTLF,1(0,FCTTLF)   RESTORE +1 LOST WHEN BCT TEST       02540000
         BCT   FCTTLF,DOFUN         IF ZERO THEN NO RELATED FUNCTION    02560000
SET3     EQU   *                                                        02580000
EXITGO   EQU   *                                                        02600000
         LM    SAVE1,SAVE2,GRSAVE  RESTORE REGISTERS                    02620000
         B     TORET+1        .....EXIT FROM LOKUP ROUTINE.....         02640000
*                                                                       02660000
DOFUN    EQU   *                                                        02680000
         DROP  FCTTLF                                                   02700000
         USING TLF,ARGTLF                                               02720000
         LR    POINT2+1,TABLE                                           02740000
         S     POINT2+1,TLSTRT                                          02760000
         SR    POINT2,POINT2                                            02780000
         DR    POINT2,LENGTH                                            02800000
         DROP  ARGTLF                                                   02820000
         USING TLF,FCTTLF                                               02840000
         AR    FCTTLF,RELOC                                             02860000
         SH    FCTTLF,SUBTLF                                            02880000
         SR    LENGTH,LENGTH                                            02900000
         IC    LENGTH,TLLEN                                             02920000
         TM    TLALPH,ALMASK   Q. IS FUNCTION ALPHA                     02940000
         BO    NOADJ2    GO IF ALPHA AND NO LENGTH ADJUST NEEDED        02960000
         LA    LENGTH,1(0,LENGTH)  CALCULATE MOVE LENGTH FOR            02980000
         SRL   LENGTH,1(0)         NUMERIC AS  ((LENGTH+1)/2)           03000000
NOADJ2   EQU   *                                                        03020000
         STC   LENGTH,MVIN2+1                                           03040000
         LA    LENGTH,1(0,LENGTH)                                       03060000
         MR    POINT2,LENGTH                                            03080000
         A     POINT2+1,TLSTRT                                          03100000
MVIN2    MVC   TLTAB,0(POINT2+1)   LENGTH SET AT OBJECT TIME            03120000
         ST    POINT2+1,TLADR                                           03140000
         B     EXITGO                                                   03160000
************************************************************            03180000
         EJECT                                                          03200000
         DROP  FCTTLF                                                   03220000
         USING TLF,ARGTLF                                               03240000
*********************************************************************** 03260000
*                                                                       03280000
*                                                                       03300000
*                                                                       03320000
EQUL     TM    TOEQSH,EQMASK                                            03340000
         BO    GETEQ         EQUAL SEARCH SO KEEP THIS VALUE            03360000
         CLI   BYTE,LOASCD     Q. TAKE PRIOR VALUE IF                   03380000
         BE    S          LOW SEARCH ON AN ASCENDING TABLE              03400000
         CLI   BYTE,HIDSCD      Q. TAKE PRIOR VALUE IF                  03420000
         BE    S          HIGH SEARCH ON A DESCENDING TABLE             03440000
         B     NEXT                                                     03460000
GETEQ    EQU   *                                                        03480000
         IC    TURNIN,INDON                                             03500000
         EX    TURNIN,TOEQ    TURN EQUAL INDICATOR ON                   03520000
         B     TAKE                                                     03540000
************************************************************            03560000
*                                                                       03580000
HIGH     TM    TLASCD,ASMASK  Q. ASCENDING TABLE  HERE IF SEARCH GTR    03600000
         BO    NEXT                                                     03620000
         TM    TOHISH,HIMASK  Q. HI TYPE SEARCH                         03640000
         BO    S                                                        03660000
         TM    TOLOSH,LOMASK                                            03680000
         BO    TAKEIT                                                   03700000
         B     NEXT                                                     03720000
************************************************************            03740000
         DS    0F                                                       03760000
GRSAVE   DC    8CL4'0'     SAVE AREA FOR GENERAL REGISTERS USED         03780000
         DS    0H                                                       03800000
SUBTLF   DC    AL2(TLTAB-TLALPH)                                        03820000
BYTE     DC    X'00'          FILLED IN AT OBJECT TIME                  03840000
INDON    DC    X'F0'                                                    03860000
************************************************************            03880000
UP3      EQU   *                                                        03900000
************************************************************            03920000
************************************************************            03940000
         EJECT                                                          03960000
*                   CALLING SEQUENCE                                    03980000
*              IF SYMBOL BEGINS WITH  TO  THEN FROM PARAMETER LIST      04000000
*                                                                       04020000
PRLIST   DSECT     **************************************************** 04040000
*              CL0 *CNOP 2,4                                          * 04060000
*              CL4 *L    15,LVLKUP(3)   GET ADDRESS FROM LINKAGE VECTR* 04080000
*              CL2 *BALR 14,15                                        * 04100000
TOF1     DS    CL4 *DS   F              ADDRESS OF FACTOR 1           * 04120000
TOF2     DS    CL4 *DS   F              ADDRESS OF FACTOR 2           * 04140000
TORF     DS    CL4 *DS   F              ADDRESS OF RESULT(ZERO IF NULL* 04160000
TOHILO   DS    CL4 *MVI  HIGHLO,X'00'   NO HIGH/LOW THEN USE OP CLI     04180000
TOEQ     DS    CL4 *MVI  EQUAL,X'00'    NO EQUAL THEN USE OP CLI      * 04200000
TOKEY    DS    CL1 *DS   CL1            TYPE OF SEARCH BYTE   HI-X'80'* 04220000
*                  *          BIT 0=0   NO HIGH INDICATOR               04240000
*                                  =1      HIGH INDICATOR SPECIFIED     04260000
*                  *              1=0   NO LOW  INDICATOR             * 04280000
*                                  =1      LOW INDICATOR SPECIFIED      04300000
*                  *              2=0   NO EQUAL INDICATOR            * 04320000
*                                  =1      EQUAL INDICATOR SPECIFIED    04340000
*                  *              3=0   FACTOR 1 NOT EXTERNAL         * 04360000
*                  *               =1   FACTOR 1 IS EXTERNAL (ULABL)  * 04380000
*                  *            4-7     NOT ASSIGNED                  * 04400000
TORET    DS    CL1 *DS   CL1    NOT NOW USED                            04420000
*                  **************************************************** 04440000
*                                                                       04460000
TOHISH   EQU   TOKEY          TO HIGH SEARCH KEY              HI-X'80'  04480000
HIMASK   EQU   X'80'          SEARCH TYPE *HIGH * MASK                  04500000
TOLOSH   EQU   TOKEY          TO LOW SEARCH KEY               LO-X'40'  04520000
LOMASK   EQU   X'40'          SEARCH TYPE *LOW  * MASK                  04540000
TOEQSH   EQU   TOKEY          TO EQUAL SEARCH KEY             EQ-X'20'  04560000
EQMASK   EQU   X'20'          SEARCH TYPE *EQUAL* MASK                  04580000
TOF1EX   EQU   TOKEY          TO EXTERNAL KEY  FACTOR 1 EXTERNAL-X'10'  04600000
F1MASK   EQU   X'10'           SEARCH TYPE  *ULABL*  MASK               04620000
*********************************************************************** 04640000
         EJECT                                                          04660000
*********************************************************************** 04680000
*                   TABLE LINKAGE FIELD                                 04700000
*              IF SYMBOL BEGINS WITH  TL  THEN FROM TABLE LINKAGE FIELD 04720000
*                                                                       04740000
TLF      DSECT     **************************************************** 04760000
*        DS    CL0   *                                                  04780000
TLALPH   DS    CL1   *   ORGANIZATION CODE BYTE - ASCENDING,DESCEND,ETC 04800000
*                             BIT  0-3    NOT USED                      04820000
*                             BIT    4=0 NUMERIC                        04840000
*                                     =1 ALPHA                          04860000
*                                    5=0 PACKED                         04880000
*                                     =1 UNPACKED                       04900000
*                                  6-7=00 RANDOM                        04920000
*                                     =01 ASCENDING                     04940000
*                                     =10 DESCENDING                    04960000
*                                     =11 NOT ASSIGNED                  04980000
TLLEN    DS    CL1   *   LENGTH OF AN ENTRY                             05000000
TLNUM    DS    CL2   *   NUMBER OF ENTRIES                              05020000
TLSTRT   DS    CL4   *   STARTING ADDRESS                               05040000
TLEND    DS    CL4   *   END ADDRESS                                    05060000
TLADR    DS    CL4   *   ADDRESS OF MOST RECENTLY FOUND VALUE           05080000
TLTAB    DS    CL256 *   TABLE HOLD AREA FOR VALUE FOUND                05100000
*                  **************************************************** 05120000
*                                                                       05140000
ALMASK   EQU   X'08'     ALPHA MASK FOR TLF TLALPH BYTE                 05160000
TLASCD   EQU   TLALPH                                                   05180000
ASMASK   EQU   X'01'     ASCENDING SEQUENCED TABLE                      05200000
*                                                                       05220000
*                                                                       05240000
*              LENGTH IN TLF IS -NO. CHARACTERS MINUS ONE IF ALPHA      05260000
*                               -NO. DIGITS MINUS ONE IF NUMERIC        05280000
*              FOR NUMERIC THEN THE NO. OF BYTES IS                     05300000
*                              ((LENGTH+1)/2)+1                         05320000
*              FOR ALPHA THEN THE NO. OF BYTES IS                       05340000
*                                LENGTH+1                               05360000
*                                                                       05380000
************************************************************            05400000
************************************************************            05420000
IESLR310 EQU   LR3                                                      05440000
IESUP310 EQU   UP3                                                      05460000
         END                                                            05480000
