         TITLE 'IES250  OS/360 RPG TERMINAL PHASE                   56' 00020000
***********************************************                         00040000
*FUNCTIONS OF RPG/E TERMINAL PHASE -                                    00060000
*  - CLOSE FILES                                                        00080000
*  - SET FOR RETURN TO SUPERVISOR OR CALLING PROG                       00100000
***********************************************                         00120000
IES25010 START                                                          00140000
TERMINAL  EQU  *                                                        00160000
         BALR  8,0                      LOAD BASE REG                   00180000
         USING *,8                                                      00200000
         USING CXDATA,6                                                 00220000
         ST    14,CXHLDREG              SAVE RETURN ADDR                00240000
***********************************************                         00260000
*CLOSE FILES                                                            00280000
***********************************************                         00300000
         LM    2,4,CXDCBSRC             PICK UP DCB ADDRS FOR ALL FILES 00320000
         LM    9,11,CXDCBWK1                                            00340000
         CLOSE ((2),DISP)                                               00360000
         CLOSE ((3),DISP,                                              X00380000
               (4),DISP,                                               X00400000
               (9),REREAD,                                             X00420000
               (10),REREAD,                                            X00440000
               (11),REREAD)                                             00460000
***********************************************                         00480000
*RESTORE USER PAGE NUMBER, IF ANY                                       00500000
***********************************************                         00520000
         CLI   CXHDGSW,X'F0'            WAS THERE A PAGE NUMBER PASSED  00540000
         BNE   RESPIE                   NO                              00560000
         L     1,CXSAVEAR+4             CALLING SAVE AREA               00580000
         L     1,24(1)                  POINTER TO PARMETER LIST        00600000
         L     2,8(0,1)                 POINTER TO HEADING STRING       00620000
         AP    CXPAGNUM(4),CXONEPCK     NEXT PAGE NUMBER TO BE USED     00640000
         UNPK  2(4,2),CXPAGNUM(4)       RESTORE USER PAGE NUMBER        00660000
         OI    5(2),X'F0'               REMOVE PLUS SIGN                00680000
***********************************************                         00700000
*REINSTATE PREVIOUS TASK SPIE, IF ANY                                   00720000
***********************************************                         00740000
RESPIE   L     1,CXSPIESV               LOAD ADDR OF PREVIOUS PICA      00760000
         LTR   1,1                      WAS THERE ANY                   00780000
         BZ    RETURN                   NO                              00800000
         SPIE  MF=(E,(1))               YES, REINSTATE IT               00820000
***********************************************                         00840000
*SET FOR RETURN TO SUPERVISOR OR CALLING PROG                           00860000
***********************************************                         00880000
RETURN   L     14,CXHLDREG              RESTORE RETURN ADDR             00900000
         BR    14                       RETURN TO RES PHASE             00920000
***********************************************                         00940000
*CIOEX DATA AREA                                                        00960000
***********************************************                         00980000
CXDATA   DSECT                                                          01000000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       01020000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 01040000
*                                         (START WITH PREPHASE)         01060000
CXDCBSRC DS    F                        ADDR OF DCB FOR SOURCE LANG FIL 01080000
CXDCBLST DS    F                        ADDR OF DCB FOR LIST FILE       01100000
CXDCBPGO DS    F                        ADDR OF DCB FOR PUNCH/GO FILE   01120000
CXDCBWK1 DS    F                        ADDR OF DCB FOR WORK FILE 1     01140000
CXDCBWK2 DS    F                        ADDR OF DCB FOR WORK FILE 2     01160000
CXDCBWK3 DS    F                        ADDR OF DCB FOR WORK FILE 3     01180000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        01200000
CXFLDADD DS    F                                FIELD NAME TABLE        01220000
CXLITADD DS    F                                LITERAL TABLE           01240000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 01260000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     01280000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      01300000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   01320000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                01340000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      01360000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         01380000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      01400000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    01420000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     01440000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    01460000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            01480000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    01500000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   01520000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           01540000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      01560000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  01580000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   01600000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 01620000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    01640000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         01660000
CXRETCDE DC    X'00'                    RETURN CODE                     01680000
CXIPTEOF BR    2                        LINKAGE TO EOF ROUTINE          01700000
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            01720000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          01740000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    01760000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           01780000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     01800000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    01820000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                01840000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             01860000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            01880000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     01900000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      01920000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    01940000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   01960000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        01980000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               02000000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     02020000
CXSYNERR B     4(2)                     LINKAGE TO SYNCH ERROR ROUTINE  02040000
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    02060000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     02080000
CXHEADIN DC    C'OS/RPG(32K)*V1,L0'     HEADER AND VERSION IDENT        02100000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          02120000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        02140000
CXTODAY  DC    C'  /  /  '              DATE                            02160000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             02180000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        02200000
RDRPCHAR DS    80C                      READER/PUNCH AREA               02220000
PNTRARAC DC    X'F1'                    CONTROL CHAR FOR CARRIAGE       02240000
PNTRAREA DS    120C                     PRINT AREA                      02260000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 02280000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 02300000
CXDEND   EQU   *                                                        02320000
         END   TERMINAL                                                 02340000
