         TITLE 'IESRPG  OS/360 RPG RESIDENT PHASE                    1' 00020000
* STATUS       CHANGE LEVEL 1-10                                        00040000
*                                                                       00060000
*FUNCTION/OPERATION   THE RESIDENT PHASE SERVES AS AN INTERFACE BETWEEN 00080000
*                     OS OR THE CALLING PROGRAM AND THE RPG PROCESSOR.  00100000
*                     THE RESIDENT PHASE RECEIVES CONTROL INITIALLY,    00120000
*                     SAVES ALL THE REGISTERS, SETS UP THE PROCESSOR    00140000
*                     SAVE AREA, ISSUES THE SPIE MACRO FOR THE          00160000
*                     PROCESSOR, AND THEN LINKS TO THE PREPHASE.        00180000
*                     AFTER COMPILATION IS FINISHED THE RESIDENT PHASE  00200000
*                     ACCEPTS CONTROL BACK FROM THE TERMINAL PHASE,     00220000
*                     RESTORES ALL THE REGISTERS, SETS THE RETURN CODE, 00240000
*                     AND THEN RETURNS CONTROL TO OS OR THE CALLING     00260000
*                     PROGRAM.  THE RESIDENT PHASE STAYS IN CORE        00280000
*                     THROUGHOUT EXECUTION OF RPG.  IT THEREFORE        00300000
*                     CONTAINS THE DCB'S FOR THE PROCESSOR DATA SETS,   00320000
*                     THE SPIE ROUTINE, AND THE CIOEX DATA AREA.        00340000
*                                                                       00360000
*ENTRY POINT FROM OS OR CALLING PROGRAM   IESRPG                        00380000
*                                                                       00400000
*ENTRY POINT FROM TERMINAL PHASE(IES25010)   RETURN ADDRESS CONTAINED   00420000
*                                            IN REGISTER 14             00440000
*                                                                       00460000
*                     STANDARD LINKAGE CONVENTIONS ARE ASSUMED ON ENTRY 00480000
*                                                                       00500000
*INPUT   ENTRY POINT ADDRESS IN REGISTER 15                             00520000
*        RETURN ADDRESS IN REGISTER 14                                  00540000
*        SAVE AREA ADDRESS IN OS OR CALLING PROGRAM IN REGISTER 13      00560000
*                                                                       00580000
*OUTPUT   ADDRESS OF CIOEX DATA AREA IN REGISTER 6                      00600000
*        ADDRESS OF SAVE AREA IN OS OR CALLING PROGRAM IN CIOEX DATA    00620000
*        ADDRESS OF PICA FROM PREVIOUS SPIE, IF ANY, IN CIOEX DATA      00640000
*                                                                       00660000
*EXTERNAL ROUTINES   NONE                                               00680000
*                                                                       00700000
*EXIT - INITIAL   TO PREPHASE CIOEX (IES00910) VIA THE LINK MACRO       00720000
*                                                                       00740000
*EXIT - TERMINAL   TO OS OR CALLING PROGRAM VIA THE RETURN MACRO        00760000
*                                                                       00780000
*TABLES/WORK AREAS   NONE                                               00800000
*                                                                       00820000
*ATTRIBUTES   EDITABLE, DOWNWARD COMPATIBLE                             00840000
*                                                                       00860000
IESRPG   START                                                          00880000
*1480000400,008860-008920,020600                                   000D 00890017
* 008818-008962                                                    000Z 00890400
         SPACE 1                                                        00890800
****************************************************************** 000Z 00891200
*                                                                  000Z 00891600
*        GENERAL REGISTER EQUATES FOR THIS PHASE                   000Z 00892000
*                                                                  000Z 00892400
****************************************************************** 000Z 00892800
XR0      EQU   0                                                        00893200
XR1      EQU   1                                                   000Z 00893600
XR2      EQU   2                                                   000Z 00894000
XR3      EQU   3                                                   000Z 00894400
XR4      EQU   4                                                   000Z 00894800
XR5      EQU   5                                                   000Z 00895200
XR6      EQU   6                                                   000Z 00895600
XR7      EQU   7                                                   000Z 00896000
XR8      EQU   8                                                   000Z 00896400
XR9      EQU   9                                                   000Z 00896800
XR10     EQU   10                                                  000Z 00897200
XR11     EQU   11                                                  000Z 00897600
XR12     EQU   12                                                  000Z 00898000
XR13     EQU   13                                                  000Z 00898400
XR14     EQU   14                                                  000Z 00898800
XR15     EQU   15                                                  000Z 00899200
         SPACE 1                                                        00899600
RESPHASE EQU   *                                                        00900000
***********************************************                         00920000
*CIOEX DATA AREA                                                        00940000
***********************************************                         00960000
CXDUBLWD DS    D                        DOUBLE WORD FOR WORK AREA       00980000
CXPHSNAM DC    C'RPG10000'              NAME OF NEXT PHASE TO BE LOADED 01000000
*                                         (START WITH PREPHASE)         01020000
CXDCBSRC DC    A(SRCFIL)                ADDR OF DCB FOR SOURCE LANG FIL 01040000
CXDCBLST DC    A(LSTFIL)                ADDR OF DCB FOR LIST FILE       01060000
CXDCBPGO DC    A(PNCHGO)                ADDR OF DCB FOR PUNCH/GO FILE   01080000
CXDCBWK1 DC    A(WKFIL1)                ADDR OF DCB FOR WORK FILE 1     01100000
CXDCBWK2 DC    A(WKFIL2)                ADDR OF DCB FOR WORK FILE 2     01120000
CXDCBWK3 DC    A(WKFIL3)                ADDR OF DCB FOR WORK FILE 3     01140000
CXRIADDR DS    F                        ADDR OF RESULT IND TABLE        01160000
CXFLDADD DS    F                                FIELD NAME TABLE        01180000
CXLITADD DS    F                                LITERAL TABLE           01200000
CXADDCNT DC    A(0)                     COUNTER OF CORE USED FOR OBJECT 01220000
CXCMPADD DS    F                        ADDRESS OF COMPRESSION AREA     01240000
CXCMPEXT DS    F                        LENGTH OF COMPRESSION AREA      01260000
CXHLDREG DS    F                        HOLD AREA FOR RETURN REGISTER   01280000
CXNOTES  DC    8F'0'                    ERROR NOTE ARRAY                01300000
CXFLDLEN DS    F                        LENGTH OF FIELD NAME TABLE      01320000
CXLITLEN DS    F                        LENGTH OF LITERAL TABLE         01340000
CXCALCNT DC    F'0'                     RECORD COUNT FOR NOTE CALC      01360000
CXOUTCNT DC    F'0'                     RECORD COUNT FOR NOTE OUTPUT    01380000
CXINPCNT DC    F'0'                     RECORD COUNT FOR NOTE INPUT     01400000
CXNOTNUM DC    F'0'                     RECORD COUNT FOR NOTE ASSIGN    01420000
CXEXTCNT DC    H'0'                     EXTERNAL ESD COUNTER            01440000
CXNUMCMP DC    H'0'                     NUMBER OF COMPRESSION BLOCKS    01460000
CXNUMBLK DC    H'0'                     NUMBER OF BLANK AFTER ENTRIES   01480000
CXNUMRLD DC    H'0'                     NUMBER OF RLD RECORDS           01500000
CXBLKNUM DC    H'0'                     COMP BLOCK BEING PROCESSED      01520000
CXIDSPLC DC    H'0'                     DISPLACEMENT TO 1ST INPUT SPEC  01540000
CXCDSPLC DC    H'0'                     DISPLACEMENT TO 1ST CALC SPEC   01560000
CXODSPLC DC    H'0'                     DISPLACEMENT TO 1ST OUTPUT SPEC 01580000
CXANSPLC DC    H'0'                     DISPLACEMENT FOR NOTE ASSIGN    01600000
CXHDGSW  DC    X'00'                    USER PAGE NUMBER SWITCH         01620000
CXRETCDE DC    X'00'                    RETURN CODE                     01640000
CXIPTEOF BR    XR2                      LINKAGE TO EOF ROUTINE     000Z 01660000
CXCMPOPT DC    X'00'                    COMPILER OPTION BYTE            01680000
CXSTRLNG DC    X'00'                    STERLING CODE SWITCHES          01700000
CXCOLSEQ DC    X'00'                    ALTERNATE COLLATING SEQUENCE    01720000
CXINVPRT DC    X'00'                    INVERTED PRINT SWITCH           01740000
CXONEPCK DC    P'+1'                    NUMBER '1' IN PACKED FORMAT     01760000
CXTRKBF  DC    X'00'                    TRACK BLOCKING FACTOR FOR DA    01780000
CXLITOVF DC    X'0000000C'              LITERAL OVERFLOW                01800000
CXFLDOVF DC    X'0000000C'              FIELD NAME OVERFLOW             01820000
CXCMPOVF DC    X'0000'                  COMPRESSION OVERFLOW            01840000
CXSEQINP DC    X'0000000C'              SEQ NUM OF FIRST INPUT SPEC     01860000
CXSEQCAL DC    X'0000000C'              SEQ NUM OF FIRST CALC SPEC      01880000
CXSEQOUT DC    X'0000000C'              SEQ NUM OF FIRST OUTPUT SPEC    01900000
CXLINBCT DC    X'000C'                  LINE COUNTER BRANCH AND COUNT   01920000
CXLINCNT DC    X'052C'                  LINE COUNTER TOTAL VALUE        01940000
CXPAGNUM DC    X'0000000C'              PAGE NUMBER COUNT               01960000
CXPUNCNT DC    X'0000000C'              SEQUENCE COUNT FOR PUNCHING     01980000
CXSYNERR B     4(XR2)                LINKAGE TO SYNCH ERROR ROU    000Z 02000000
CXPGRNAM DC    CL6'RPGOBJ'              PROGRAM NAME                    02020000
CXPASKEY DC    8X'00'                   TEMP STORAGE BETWEEN PHASES     02040000
CXHEADIN DC    C'OS/RPG(32K)*V1M10'                                     02060000
CXJOBNAM DS    8C                       JOB NAME FROM JOB CARD          02080000
CXSTEPNA DS    8C                       STEP NAME FROM EXEC CARD        02100000
CXTODAY  DC    C'  /  /  '              DATE                            02120000
CXSYSPDD DC    C'SYSPUNCH'              DDNAME FOR SYSPUNCH             02140000
RDRPCHCD DC    X'F1'                    CONTROL CHAR FOR STACKER        02160000
RDRPCHAR DS    80C                      READER/PUNCH AREA               02180000
PNTRARAC DC    C'+'                    CONTROL CHAR FOR CARRIAGE A22130 02200000
PNTRAREA DS    120C                     PRINT AREA                      02220000
CXSAVEAR DS    18F                      CIOEX SAVE AREA                 02240000
CXSPIESV DS    F                        ADDR OF PICA FROM PREVIOUS SPIE 02260000
CXINAREA DC    F'0'                     ADDR OF BUFFER FOR SYSIN   3142 02265015
CXDBLKAD DC    A(DEBLKIPT)              ADDR OF DEBLK RTN FOR SYSIN3142 02270015
CXFDSSFT DC    F'0'                     FILE STACKER SELECT BITS   3369 02275015
CXSEQCHK DC    X'000000000000'          PAGE/LINE SEQUENCE CHECK   000A 02277016
CXCRDCNT DC    H'1'                     SOURCE STATEMENT COUNT     I168 02278000
CXDEND   EQU   *                                                        02280000
         EJECT                                                          02300000
***********************************************                         02320000
*INTERFACE BETWEEN SYSTEM (OR CALLING PROGRAM) AND RPG PROCESSOR        02340000
***********************************************                         02360000
         ORG   CXDUBLWD                                                 02380000
         USING *,XR15                                              000Z 02400000
         B     INIT                                                     02420000
         ORG                                                            02440000
         DROP  XR15                                                000Z 02460000
         USING CXDUBLWD,XR6                                        000Z 02480000
INIT     SAVE  (14,12)                                                  02500000
         LR    XR6,XR15                 LOAD CIOEX DATA BASE REG   000Z 02520000
         ST    XR13,CXSAVEAR+4       SAVE ADDR OF CALLING SAVE     000Z 02540000
         LA    XR13,CXSAVEAR            ADDR OF RPG SAVE AREA      000Z 02560000
***********************************************                         02580000
*ISSUE SPIE FOR PROCESSOR                                               02600000
***********************************************                         02620000
         SPIE  SPIEROUT,((1,7),9,11,12,15) MASK ALL MASKABLE INTERRUPTS 02640000
         ST    XR1,CXSPIESV             SAVE ADDR OF PREVIOUS PICA 000Z 02660000
***********************************************                         02680000
*LINK TO PREPHASE                                                       02700000
***********************************************                         02720000
         LINK  EPLOC=CXPHSNAM                                           02740000
***********************************************                         02760000
*RETURN POINT FROM TERMINAL PHASE                                       02780000
***********************************************                         02800000
         SR    XR15,XR15                                           000Z 02820000
         IC    XR15,CXRETCDE           LOAD RETURN CODE INTO RE    000Z 02840000
         L     XR13,CXSAVEAR+4      RESTORE ADDR OF CALLING SAV    000Z 02860000
         RETURN (14,12),RC=(15)         EOJ                             02880000
***********************************************                         02900000
*SPIE ROUTINE                                                           02920000
***********************************************                         02940000
         USING SPIEROUT,XR15                                       000Z 02950000
SPIEROUT ABEND 24,DUMP                  BLOW THE TASK                   02961016
**********************************************                     3142 02962016
*                                                                  3142 02963016
*   THIS IS OPEN EXIT TO HANDLE BLOCKED SYSIN                      3142 02964016
*                                                                  3142 02965016
**********************************************                     3142 02966016
         USING OPENEXIT,XR15                                       000Z 02967000
         CNOP  0,4                                                 3142 02968016
OPENEXIT STM   XR0,XR3,EXITSAVE         SAVE WORK REGISTERS        000Z 02969000
         LR    XR3,XR15                 NEW BASE REGISTER          000Z 02970000
         DROP  XR15                                                000Z 02971000
         USING OPENEXIT,XR3                                        000Z 02972000
         LA    XR15,SRCFIL              BASE ON DCB                000Z 02973000
         MVI   INBLKSZ,X'FF'            1ST RECORD SW = ON         3142 02975016
         SR    XR2,XR2                  GET ZERO COMPERAND         000Z 02976000
         CH    XR2,62(XR0,XR15)         IS BLKSIZE=ZERO            000Z 02977000
         BC    7,BLDAREA                NO - GO BUILD A BUFFER     3142 02980016
         LA    XR2,80                   GET DEFAULT VALUE          000Z 02980700
         STH   XR2,62(XR0,XR15)          & SAVE IN BLKSIZE.        000Z 02981400
*                                                                  3142 02982316
*   BUILD A BUFFER TO HANDLE A FULL BLOCK - INDIVIDUAL SOURCE      3142 02982616
*   STATEMENTS WILL BE DEBLOCKED INTO RDRPCHAR AS REQUIRED.        3142 02982916
*                                                                  3142 02983216
BLDAREA  LH    XR2,62(XR0,XR15)         GET BLKSIZE                000Z 02983500
         STH   XR2,INBLKSZ+2             & SAVE IT.                000Z 02983800
         GETMAIN EU,LV=(2),A=CXINAREA                              6910 02984116
*                                                                  3142 02984316
*   CXINAREA NOW POINTS TO THE HEAD OF THE BUFFER WHICH WILL       3142 02984516
*   CONTAIN A BLOCK OF SOURCE RECORDS FROM SYSIN                   3142 02984716
*                                                                  3142 02984916
         LM    XR0,XR3,EXITSAVE     RESTORE WORK REGISTERS         000Z 02985100
         BR    XR14                  & RETURN TO CALLER            000Z 02985300
EXITSAVE DS    4F                                                  6910 02985716
*                                                                  3142 02985916
**********************************************                     3142 02986116
*                                                                  3142 02986316
*   DEBLOCK ROUTINE FOR SYSIN - ENTERED FROM CIOEX ROUTINES        3142 02986516
*                                                                  3142 02986716
**********************************************                     3142 02986916
         CNOP  0,4                                                 3142 02987116
         USING *,XR15                                              000Z 02987300
DEBLKIPT STM   XR3,XR4,DEBLKSAV     SAVE WORK REGISTERS            000Z 02987500
         CLI   INBLKSZ,X'FF'            IS IT 1ST RECORD?          3142 02987716
         BNE   DEBLKONE                 NO - CONTINUE DEBLOCK      3142 02987916
         MVI   INBLKSZ,X'00'            YES - SET SW = OFF         3142 02988116
         B     EOFTOBUF                PREPARE FOR SHORT BLOCK     6910 02988316
DEBLKONE L     XR3,BLKPOS               GET BLOCK POSITION         000Z 02988400
         C     XR3,INBLKSZ              ANY RECORDS LEFT           000Z 02988500
         BL    MOVEONE                  YES - MOVE TO WORK AREA    3142 02988616
         SR    XR3,XR3                  NO - RESTORE POINTER TO    000Z 02988700
         ST    XR3,BLKPOS                HEAD OF BLOCK.            000Z 02988800
EOFTOBUF L     XR4,CXINAREA             GET ADDRESS OF BUFFER      000Z 02988900
         LR    XR3,XR4                                             000Z 02989000
         A     XR4,INBLKSZ              ADD PHYSICAL RECORD LENGTH 000Z 02989100
MOVSA    MVC   0(2,XR3),ENDFILE         PUT /* OVER OLD LOG RCD    000Z 02989200
         LA    XR3,80(XR3)              POINT TO NEXT LOG RECORD   000Z 02989300
         CR    XR3,XR4                  BUFFER FINISHED            000Z 02989400
         BL    MOVSA                   NO, CONTINUE MOVES          6910 02989516
         LM    XR3,XR4,DEBLKSAV     RESTORE REGISTERS              000Z 02989700
         B     4(XR5)               GO READ A BLOCK                000Z 02989900
*                                                                  3142 02990215
MOVEONE  L     XR4,CXINAREA         GET CURRENT RECORD             000Z 02990400
         AR    XR4,XR3               POINTER IN REG 4              000Z 02990600
         MVC   RDRPCHAR(80),0(XR4)  MOVE SOURCE TO WORK AREA       000Z 02990800
         CLC   RDRPCHAR(2),ENDFILE      IS IT EOF ON SYSIN?        3142 02991015
         BNE   BLKSTEP                  NO - CONTINUE              3142 02991215
         LM    XR3,XR4,DEBLKSAV     YES - RESTORE REGISTERS        000Z 02991400
         B     8(XR5)                & TAKE EOF EXIT               000Z 02991600
*                                                                  3142 02991815
BLKSTEP  A     XR3,STEP80           INCREMENT BLOCK POSITION       000Z 02992000
         ST    XR3,BLKPOS            & STORE BACK                  000Z 02992200
         LM    XR3,XR4,DEBLKSAV     RESTORE WORK REGISTERS         000Z 02992400
         B     0(XR5)               RETURN TO CIOEX                000Z 02992600
*                                                                  3142 02992815
ENDFILE  DC    CL2'/*'                  EOF COMPARAND              3142 02993015
         DS    0F                                                  3142 02993215
STEP80   DC    1F'80'                   LOGICAL RECORD LGTH        3142 02993415
INBLKSZ  DC    1F'0'                    PHYSICAL RECORD LGTH       3142 02993615
BLKPOS   DC    1F'0'                    CURRENT BLOCK OFFSET       3142 02993815
DEBLKSAV DS    2F                       REGISTER SAVE AREA         3142 02994015
*                                                                  3142 02994215
***********************************************                         03000000
*DCB FOR SOURCE LANGUAGE FILE                                           03020000
***********************************************                         03040000
SRCFIL   DCB   DSORG=PS,MACRF=(R),DDNAME=SYSIN,DEVD=DA,RECFM=FB,   3142X03045015
               LRECL=80,NCP=1,EODAD=CXIPTEOF,                      3142X03050015
               SYNAD=CXSYNERR,EXLST=EXITLIST                       3142 03055015
*                                                                  3142 03060015
*   EXIT LIST FOR SRCFIL DCB                                       3142 03065015
*                                                                  3142 03070015
         CNOP  0,4                                                 3142 03075015
EXITLIST DC    X'85'                    CODE & POINTER FOR         3142 03080015
         DC    AL3(OPENEXIT)             OPEN EXIT ROUTINE         3142 03085015
*                                                                  3142 03090015
***********************************************                         03100000
*DCB FOR LIST FILE                                                      03120000
***********************************************                         03140000
LSTFIL   DCB   DSORG=PS,MACRF=(W),DDNAME=SYSPRINT,DEVD=DA,RECFM=FA,    X03160000
               LRECL=121,BLKSIZE=121,NCP=1,SYNAD=CXSYNERR               03180000
***********************************************                         03200000
*DCB FOR PUNCH/GO FILE                                                  03220000
***********************************************                         03240000
PNCHGO   DCB   DSORG=PS,MACRF=(W),DDNAME=SYSPUNCH,DEVD=DA,RECFM=F,     X03260000
               LRECL=80,BLKSIZE=80,NCP=1                                03280000
***********************************************                         03300000
*DCB FOR WORK FILE 1                                                    03320000
***********************************************                         03340000
WKFIL1   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=SYSUT1,DEVD=DA,RECFM=U,   X03360000
               BLKSIZE=32760,NCP=1,SYNAD=CXSYNERR                       03380000
***********************************************                         03400000
*DCB FOR WORK FILE 2                                                    03420000
***********************************************                         03440000
WKFIL2   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=SYSUT2,DEVD=DA,RECFM=U,   X03460000
               BLKSIZE=32760,NCP=1,SYNAD=CXSYNERR                       03480000
***********************************************                         03500000
*DCB FOR WORK FILE 3                                                    03520000
***********************************************                         03540000
WKFIL3   DCB   DSORG=PS,MACRF=(RP,WP),DDNAME=SYSUT3,DEVD=DA,RECFM=U,   X03560000
               BLKSIZE=132,NCP=1,SYNAD=CXSYNERR                         03580000
         END   RESPHASE                                                 03600000
