         TITLE '      IER8BO - OS/360 SORT/MERGE - 360S-SM023 12/12/67' 00200017
         SPACE 2                                                        00400017
*MODULE NAME  *** IER8BO ***                                            00600017
         SPACE 2                                                        00800017
*STATUS CHANGES LEVEL 0                                                 01000017
         SPACE 2                                                        01200017
*MODULE FUNCTION/OPERATION PHASE 3 RUNNING MODULE VRE -WITH E35 EXIT.   01400017
*   THE FUNCTION OF THIS MODULE IS TO BLOCK VARIABLE LENGTH SPANNED     01600017
*   RECORDS. TO ACCOMPLISH THIS IT USES A MOVE ROUTINE AND QSAM PUT IN  01800017
*   MOVE MODE                                                           02000017
*   THE USER ROUTINE IS EXECUTED ONCE FOR EVERY RECORD LEAVING THE      02200017
*   MERGE. THE EXIT OCCURS AFTER THE RECORD TO BE PUT LEAVES THE MERGE. 02400017
*   THE USER MAY THEN DO THE FOLLOWING 1. INSERT A RECORD,2. DELETE OR  02600017
*   SUMMARIZE A RECORD,OR 3.DO NOTHING, ALTER, LENGTHEN, OR SHORTEN A   02800017
*   RECORD. THE USER RETURNS TO THE APPROPRIATE ROUTINE IN THIS MODULE. 03000017
*   THE MODULE LINKS TO THE PROPER DEBLOCK OR EOJ MODULE WHEN NEEDED.   03200017
         SPACE 1                                                        03400017
*   LINKAGE FROM MODULE TO USER IS VIA THE CALL MACRO                   03600017
*   LINKAGE FROM USER TO MODULE IS VIA RETURN REGISTER PLUS PROPER      03800017
*   DISPLACEMENT(DEPENDS ON WHAT RTN THE USER WISHES TO RETURN TO)      04000017
         SPACE 1                                                        04200017
*   TWO PARAMETERS ARE PASSED TO THE USER. THE ADDR OF THE RECORD       04400017
*   LEAVING THE MERGE, AND THE STARTING ADDRESS OF THE AREA IN THE      04600017
*   WORKAREA INTO WHICH THE PREVIOUS RECORD HAD BEEN PLACED.            04800017
         SPACE 1                                                        05000017
*   THE USER CAN PASS TWO PARAMETERS TO THE MODULE, THE ADDRESS OF THE  05200017
*   RECORD HE WISHES TO INSERT, DO NOTHING, ALTER, LENGTHEN, SHORTEN    05400017
*   IN RB, AND A 4 IF HE HAS CHANGED THE INTEGRITY OF THE CONTROL FIELD 05600017
*   OF THE RCD COMING FROM THE MERGE OR A ZERO IF HE HAS NOT, IN THE    05800017
*   THIRD PARAMETER OF THE PARAMETER LIST                               06000017
         SPACE 1                                                        06200017
*   THE MODULE PASSES THESE PARAMETERS TO THE MERGE FOR SEQUENCE        06400017
*   CHECKING AGAINST THE NEXT RECORD THE MERGE PASSES TO THE MODULE     06600017
         SPACE 1                                                        06800017
*   AT EOJ,MODULE ZEROS OUT PARAM 1 OF THE PARAM LIST TO USER           07000017
         SPACE 1                                                        07200017
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      07400017
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET                        07600017
         SPACE 2                                                        07800017
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               08000017
         SPACE 1                                                        08200017
*   IER9BO                                                              08400017
         SPACE 2                                                        08600017
*LIST OF MACROS USED BY THE MODULE:                                     08800017
         SPACE 1                                                        09000017
*   SMPPI                                                               09200017
*   PUT                                                                 09400017
         SPACE 2                                                        09600017
*ENTRY POINTS:                                                          09800017
         SPACE 1                                                        10000017
*   FROM MERGE NETWORK             ENTRY FROM MERGE NETWORK:            10200017
*                                    CALLING SEQUENCE-                  10400017
*                                      L    RL,PPIBLK+4                 10600017
*                                      B    0(RL)      LAST RECORD      10800017
*                                      B    4(RL)      NORMAL           11000017
*   FROM  SYSTEM PUT               ENTRY FROM PUT :                     11200017
*                                    CALLING SEQUENCE-                  11400017
*                                      BR   RO                          11600017
*   FROM OPEN OUTPUT/EOJ           ENTRY FROM IERRPG:                   11800017
*                                    CALLING SEQUENCE-                  12000017
*                                      L    RL,PPIBLK+4                 12200017
*                                      B    0(RL)      ZERO INPUT FILE  12400017
*   FROM USER EXIT                 ENTRY FROM EXIT E35                  12600017
*                                    CALLING SEQUENCE-                  12800017
*                                      RETURN  RC=(15) RO = RETURN REG  13000017
         SPACE 2                                                        13200017
*INPUT: PPI FIELDS REFERENCED                                           13400017
         SPACE 1                                                        13600017
*   PPICOUNT    PPIX35                                                  13800017
*   PPIDOOBA                                                            14000017
*   PPIDEB                                                              14200017
*   PPIGETMN                                                            14400017
         SPACE 1                                                        14600017
*   VARIOUS ADDRESSES AND COUNTERS                                      14800017
         SPACE 2                                                        15000017
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             15200017
         SPACE 1                                                        15400017
*   PPICOUNT                                                            15600017
*   PPIDOOBA                                                            15800017
*   PPIDOUO                                                             16000017
         SPACE 1                                                        16200017
*   UPDATE COUNTERS AND OUTPUT BUFFER ADDRESSES                         16400017
         SPACE 2                                                        16600017
*EXTERNAL ROUTINES:                                                     16800017
         SPACE 1                                                        17000017
*   NONE                                                                17200017
         SPACE 2                                                        17400017
*EXTERNAL PARAMETERS:                                                   17600017
         SPACE 1                                                        17800017
*   SEE REGISTERS                                                       18000017
         SPACE 2                                                        18200017
*EXITS: NORMAL                                                          18400017
         SPACE 1                                                        18600017
*   DEBLOCK                        EXIT TO DEBLOCK                      18800017
*                                    CALLING SEQUENCE-                  19000017
*                                      L    RL,PPIDEB+4                 19200017
*                                      B    4(RL)                       19400017
*   PUT MOVE MODE                  EXIT TO OS PUT MOVE MODE             19600017
*                                    CALLING SEQUENCE                   19800017
*                                      L    RF,WDCB    DCB ADDRESS      20000017
*                                      L    RA,WOPBUFAD   WORKAREA ADR  20200017
*                                      PUT  (RF),(RA)                   20400017
*   END OF JOB                    EXIT TO IERRPG                        20600017
*                                    CALLING SEQUENCE-                  20800017
*                                      L    RL     PPIWRT + 4           21000017
*                                      BR   RL                          21200017
*   USER                          EXIT TO EXIT E35                      21400017
*                                      L    RP,PPIX35+4                 21600017
*                                    CALLING SEQUENCE                   21800017
*                                    BALR RO,RP                         22000017
         SPACE 2                                                        22200017
*EXITS: ERROR                                                           22400017
         SPACE 1                                                        22600017
*   NONE                                                                22800017
         SPACE 2                                                        23000017
*TABLES/WORK AREAS:                                                     23200017
         SPACE 1                                                        23400017
*   WRCDLGTH-LENGTH OF RECORD TO MOVE TO OUTPUT BUFFER                  23600017
*   WMRGRCD-ADDR OF WINNER RECORD IN INPUT BUFFER                       23800017
*   WOPBUFAD- ADDR OF WINNER RECORD IN WORKAREA FOR QSAM PUT            24000017
*   WINTEGSW-SEQUENCE CHECK SWITCH SET BY USER                          24200017
*   WDCB-OUTPUT DCB ADDRESS                                             24400017
*   WINSRTSW-INSERT SWITCH IS TURNED ON FOR INSERTING RECORDS           24600017
*   WSYSEOF-SYSTEM END OF FILE SW TURNED ON WHEN INPUT EOF IS REACHED   24800017
*   WUSREOF-USER END OF FILE SWITCH IS TURNED ON AFTER USER REACHES EOF 25000017
         SPACE 2                                                        25200017
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  25400017
         SPACE 2                                                        25600017
*NOTES:                                                                 25800017
         SPACE 1                                                        26000017
*   THE MODULE IS EXECUTED FOR ANY VAR SPANNED OUTPUT SORT WITH USER    26200017
*   EXIT E35.                                                           26400017
         SPACE 2                                                        26600017
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            26800017
         SPACE 1                                                        27000017
RA       EQU   0                   CONTENTS IN- N/A                     27200017
*                                  USE- ADDR. OF WORKAREA FOR QSAM PUT  27400017
*                                  CONTENTS OUT- ADDR. OF WORKAREA FOR  27600017
*                                    QSAM PUT IN MOVE MODE.             27800017
RB       EQU   1                   CONTENTS IN- N/A                     28000017
*                                  USE- E35 TO BLK(ADDR OF NEXT RECORD  28200017
*                                    TO BE PUT)                         28400017
*                                    -PUT TO BLK(ADDR OF WORKAREA )     28600017
*                                     - BLK TO E35(ADDR OF A PARAMETER  28800017
*                                    LIST)                              29000017
*                                  CONTENTS OUT- N/A                    29200017
RC       EQU   2                   CONTENTS IN- N/A                     29400017
*                                  USE- NOT USED                        29600017
*                                  CONTENTS OUT- N/A                    29800017
RD       EQU   3                   CONTENTS IN- NTWK TO BLK(ADDR OF A   30000017
*                                    WINNER IN INPUT BFR W/FILE INCR IN 30200017
*                                    1ST BYTE)                          30400017
*                                  USE- NOT USED                        30600017
*                                  CONTENTS OUT- BLK TO DEBLK(INCR OF   30800017
*                                    WINNER'S FILE)                     31000017
RE       EQU   4                   CONTENTS IN- N/A                     31200017
*                                  USE- WORK REGISTER HAVING ADDR OF    31400017
*                                    WINNER IN INPUT BUFFER             31600017
*                                  CONTENTS OUT- N/A                    31800017
RF       EQU   5                   CONTENTS IN- N/A                     32000017
*                                  USE- WORK REGISTER HAVING ADDR OF    32200017
*                                    WORKAREA FOR PUT IN MOVE MODE      32400017
*                                     - BLK TO PUT(ADDR OF OUTPUT DCB)  32600017
*                                  CONTENTS OUT- N/A                    32800017
RG       EQU   6                   CONTENTS IN- N/A                     33000017
*                                  USE- GENERAL WORK REGISTER           33200017
*                                     - RECORD COUNTER                  33400017
*                                  CONTENTS OUT- N/A                    33600017
RH       EQU   7                   CONTENTS IN- N/A                     33800017
*                                  USE- DELETE SUMMARIZE COUNTER        34000017
*                                     - GENERAL WORK REGISTER           34200017
RI       EQU   8                   CONTENTS IN- N/A                     34400017
*                                  USE- LENGTH OF WINNER RECORD         34600017
*                                     - INSERT COUNTER                  34800017
*                                  CONTENTS OUT - N/A                   35000017
RJ       EQU   9                   CONTENTS IN- N/A                     35200017
*                                  USE- NOT USED                        35400017
*                                  CONTENTS OUT- N/A                    35600017
RK       EQU   10                  CONTENTS IN- N/A                     35800017
*                                  USE- NOT USED                        36000017
*                                  CONTENTS OUT- N/A                    36200017
RL       EQU   11                  CONTENTS IN- THIS MODULE ENTRY PT    36400017
*                                  USE- MODULE BASE REGISTER            36600017
*                                  CONTENTS OUT- DEBLOCK ENTRY PT       36800017
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   37000017
*                                  USE- NOT USED                        37200017
*                                  CONTENTS OUT- EQUALS OR EXTRACT RTN  37400017
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          37600017
*                                  USE- PPI REFERENCE,REGISTER SAVE     37800017
*                                    AREA                               38000017
*                                  CONTENTS OUT- ADDRESS OF PPI         38200017
RO       EQU   14                  CONTENTS IN- N/A                     38400017
*                                  USE- RETURN REG FROM PUT AND USER    38600017
*                                    EXIT E35.                          38800017
*                                  CONTENTS OUT- N/A                    39000017
RP       EQU   15                  CONTENTS IN- N/A                     39200017
*                                  USE- BRANCH REG TO PUT AND EXIT E35  39400017
*                                     - RETURN CODE FROM EXIT E35.      39600017
*                                  CONTENTS OUT- N/A                    39800017
         SPACE 2                                                        40000017
*START OF MODULE CODE PROPER:                                           40200017
         SPACE 2                                                        40400017
IER8BO   CSECT                                                          40600017
*0784                                                              4549 40700018
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    40800017
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  41000017
         USING IHADCB,RF                                                41200017
         SPACE 1                                                        41400017
* ENTER BRANCH TABLE FROM MERGE OR READ PRIME RTN                       41600017
         SPACE 1                                                        41800017
IERDB34  B     RBSETREG            FROM MERGE,LAST RECORD, OR           42000017
*                                  FROM READ PRIME ZERO INPUT FILE      42200017
         LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     42400017
RBSETPAR ST    RD,WMRGRCD          SET PARAMETER 1 OF 2 FOR CALL MACRO  42600017
*                                    ADDR OF NEXT RCD FR MERGE TO PUT   42800017
         SPACE 1                                                        43000017
* CALL MACRO EXPANSION TO USER EXIT E35                                 43200017
         SPACE 1                                                        43400017
RBUSREXT LA    RB,WMRGRCD          PARAM LIST ADDR. WILL BE OVLAYED BY  43600017
*                                    B RBLOADRE ON USER EOF             43800017
         L     RP,PPIX35+4         IF ATTACHED, PPIX35 WILL HAVE ADDR   44000017
*                                    OF ATTACHED EXIT FROM PPI          44200017
         BALR  RO,RP               BR TO USER                           44400017
         SPACE 1                                                        44600017
* USER RETURNS TO MODULE VIA RETURN REG AND PROPER DISPLACEMENTS        44800017
         SPACE 1                                                        45000017
         B     *+4(15)             GO TO ENTRY POINT                    45200018
         B     RBALSHNO            BR TO ALTER,LENGTHN,SHRTN,NOTHG RTN  45400017
         B     RBDELSUM            BR TO DELETE-SUMMARIZE RTNE          45600017
         B     RBUSREOF            BR TO USER END OF FILE ROUTINE       45800017
         SPACE 1                                                        46000017
* INSERT A RECORD                                                       46200017
         SPACE 1                                                        46400017
RBINSRT1 OI    WINSRTSW,X'01'      TURN INSERT SWITCH ON                46600017
         LA    RINSERT,1(0,RINSERT)  INCR INSERT CTR BY ONE             46800017
         LA    RCDCTR,1(0,RCDCTR)  INCR RCD COUNTER BY ONE, ALSO        47000017
RBOVLAY  B     RBLOADRE            BR TO LOAD ADDR OF RCD FOR MOVE RTN  47200017
         SPACE 2                                                        47400017
* ALTER,LENGTHEN,SHORTEN,DO NOTHING TO THE INPUT RECORD FROM THE MERGE. 47450017
         SPACE 1                                                        47500017
RBALSHNO MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  47550017
*                                    FOR MERGE NETWORK SEQU CHECK       47600017
RBLOADRE MVC   WRCDLGTH+2(2),0(RB)  MOVE RCD LENGTH TO A BOUNDARY. RB   47800017
*                                     WILL BE OVLAYD BY RD ON USER EOF. 48000017
RBOVLAY1 LR    RE,RB               STORE ADDR OF RCD FROM THE MERGE IN  48200017
*                                    MOVE RTN REG. THIS INSTR WILL BE   48400017
*                                    OVLAYD BY LR RE,RD ON USER EOF     48600017
RBONOP   BC    15,RBOFIRST         CHANGED TO NOP BY FIRST RCD          48800017
         L     RA,WOPBUFAD         LOAD WORKAREA ADDRESS                49000017
         L     RF,WDCB             DCB ADDRESS                          49200017
         MVC   DCBLRECL(2),WRCDLGTH+2  RCD LENGTH                       49400017
         PUT   (RF),(RA)                                                49600017
         SPACE 1                                                        49800017
RBOMOVE  L     RF,WOPBUFAD                                              50000017
         STM   RG,RI,PPICOUNT      SAVE COUNTERS                        50200017
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           50400017
         SPACE 1                                                        50600017
* GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA     50800017
*   AREA TO ANOTHER, REGISTERS ARE USED AS FOLLOWS-                     51000017
         SPACE 1                                                        51200017
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  51400017
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    51600017
*        RI    DATA RCD LENGTH                                          51800017
         SPACE 1                                                        52000017
* IN ADDITION THE ROUTINE USES REGISTERS RG AND RH                      52200017
         SPACE 1                                                        52400017
         CL    RI,KON256           RCD LENGTH TO 256                    52600017
         BC    12,RBNMV020         LESS THAN OR EQUAL                   52800017
         SPACE 1                                                        53000017
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    53200017
         LNR   RG,RH                 256 BYTES EACH                     53400017
RBKMOVE  MVC   0(256,RF),0(RE)                                          53600017
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     53800017
         AR    RF,RH                 BYTES                              54000017
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    54200017
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 54400017
         SPACE 1                                                        54600017
KON256   DC    F'256'              CONSTANT 256                         54800018
KMOVE1   MVC   0(1,RF),0(RE)                                            55000017
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             55200017
         BCTR  RG,0                DECR RG BY ONE                       55400017
         EX    RG,KMOVE1                                                55600017
         SPACE 1                                                        55800017
* END OF GENERALIZED MOVE ROUTINE.                                      56000017
         SPACE 1                                                        56200017
         LM    RG,RI,PPICOUNT      RESTORE REGISTERS                    56400017
         CLI   WINSRTSW,X'00'      TEST INSERT SWITGH                   56600017
         BC    8,RBDOOBA           OFF,BR TO STORE ADDR OF OUTPUT RCD   56800017
*                                    IN PPI                             57000017
         NI    WINSRTSW,X'00'      TURN INSERT SWITCH OFF               57200017
         B     RBUSREXT            BR TO USER EXIT                      57400017
         SPACE 2                                                        57600017
RBDOOBA  LA    RCDCTR,1(0,RCDCTR)  INCREMENT RECORD CTR BY ONE          57800017
RBDEBLK  STM   RG,RI,PPICOUNT      SAVE COUNTERS                        58000017
         SPACE 1                                                        58200017
* INTERFACE TO DEBLOCK MODULE. RD HAS FILE NO OF WINNER IN 1ST BYTE     58400017
         SPACE 1                                                        58600017
         L     RL,PPIDEB+4         DEBLOCK ADDR                         58800017
         B     4(0,RL)             BR TO DEBLOCK MODULE                 59000017
         SPACE 2                                                        59200017
* LAST RECORD AND ZERO INPUT FILE ROUTINE                               59400017
         SPACE 1                                                        59600017
RBSETREG LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     59800017
         SR    RD,RD               ZERO WINNER REG(PARAM 1 TO USER)     60000017
         OI    WSYSEOF,X'01'       SET SYSTEM END OF FILE SWITCH        60200017
         CLI   WUSREOF,X'00'       TEST IF USER END OF FILE SWITCH ON   60400017
         BC    7,RBEOJ             ON,BR TO END OF JOB MODULE           60600017
         B     RBSETPAR            OFF,BR TO USER ROUTINE               60800017
         SPACE 2                                                        61000017
* USER END OF FILE ROUTINE                                              61200017
         SPACE 1                                                        61400017
RBUSREOF OI    WUSREOF,X'01'       SET USER END OF FILE SWITCH          61600017
         MVC   RBUSREXT,RBOVLAY    OVERLAY USER EXIT(BYPASS EXIT E35)   61800017
         MVI   RBLOADRE+4,X'30'    OVERLAY INSTR(CHANGES RB TO RD)      62000017
         MVI   RBOVLAY1+1,X'43'    OVERLAY INSTR(CHANGES RB TO RD)      62200017
         MVI   PPIDOUO+3,X'00'     RESET SWITCH SO MERGE WILL NOW SEQ   62400017
*                                    CHECK THE REST OF THE RCDS         62600017
         CLI   WSYSEOF,X'00'       TEST IF SYSTEM END OF FILE SWITCH ON 62800017
         BC    7,RBEOJ             ON, BR TO END OF JOB MODULE          63000017
         TM    PPISW1+3,X'04'      ATTACHED SORT                   4549 63060018
         BO    RBEOJ               IF YES BR TO EOJ                4549 63120018
         B     RBLOADRE            BR TO LOAD ADDR OF RCD IN RD         63200017
         SPACE 2                                                        63400017
* LINKAGE TO END OF JOB MODULE                                          63600017
RBEOJ    L     RF,WDCB            LOAD DCB ADDRESS                      63900017
         L     RA,WOPBUFAD         LOAD WORKAREA ADDRESS                64200017
         PUT   (RF),(RA)                                                64400017
         L     RL,PPIWRT+4      END OF JOB ADDRESS                      64500017
         BR    RL                  EOJ EXIT TO MODULE NAMED IERRPG      64600017
         SPACE 2                                                        64800017
* DELETE OR SUMMARIZE A RECORD                                          65000017
         SPACE 1                                                        65200017
RBDELSUM LA    RDELSUMM,1(0,RDELSUMM)  INCR DELETE-SUMMARIZE CTR BY ONE 65400017
         CLC   PPICOUNT,KZERO      CHK IF ANY RCDS HAVE GONE THRU       65600017
         BE    RBAROUND            BR IF DELETING BEGINNING RCDS        65800017
         MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  66000017
*                                    FOR MERGE NETWORK SEQU CHECK       66200017
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         66400017
         SPACE 2                                                        66600017
RBAROUND MVC   PPIDOUO,KFOUR       NO SEQUENCE CHECK                    66800017
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         67000017
         SPACE 1                                                        67200017
RBOFIRST NI    RBONOP+1,X'00'                                           67400017
         BC    15,RBOMOVE                                               69400017
         SPACE 2                                                        69600017
* LIST OF CONSTANTS USED BY THE MODULE                                  69800017
KZERO    DC    F'0'                ZERO                                 70000017
KFOUR    DC    F'4'                FOUR                                 70200017
         SPACE 2                                                        70400017
* LIST OF WORK AREAS                                                    70600017
         SPACE 1                                                        70800017
WRCDLGTH DC    F'0'                RECORD LENGTH                        71000017
WMRGRCD  DC    F'0'                PARAM 1,ADDR OF NEXT RCD TO BE PUT   71200017
WOPBUFAD DC    F'0'                PARAM 2, ADDR TO WORKAREA FOR PUT    71400017
WINTEGSW DC    F'0'                PARAM3,USER INTEGRITY SWITCH(0 =     71600017
*                                    SEQUENCE CHECK,4 = NO SEQU CHECK)  71800017
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR OUTPUT FILE 72000017
*                                    LOADED BY ASSGN RTN                72200017
WINSRTSW DC    X'00'               INSERT SWITCH                        72400017
WSYSEOF  DC    X'00'               SYSTEM END OF FILE SWITCH            72600017
WUSREOF  DC    X'00'               USER END OF FILE SWITCH              72800017
RINSERT  EQU   RI                                                       73000017
RDELSUMM EQU   RH                                                       73200017
RCDCTR   EQU   RG                                                       73400017
         SPACE 2                                                        73600017
         EJECT                                                          73800017
         SMPPI                                                          74000017
         EJECT                                                          74200017
         DCBD  DSORG=PS                                                 74400017
         END                                                            74600017
