         TITLE '      IER8ON - OS/360 SORT/MERGE - 360S-SM023 11/15/66' 00070013
         SPACE 1                                                        00140013
*MODULE NAME *** IER8ON ***                                             00210013
         SPACE 2                                                        00280013
*STATUS: CHANGE LEVEL 0                                                 00350013
         SPACE 2                                                        00420013
*MODULE FUNCTION/OPERATION: THIS IS THE PHASE 1-PHASE 2 DISK ALGORITHM  00490013
*     FOR A 2314 SORT OR FOR A 2311 SORT WITH AT LEAST THREE SEPARATE   00560013
*     DEVICES. ITS FUNCTIONS ARE AS FOLLOWS:                            00630013
*   1. DETERMINE WHEN TO SORT AND WHEN TO MERGE.                        00700013
*   2. KEEP STARTING ADDRESSES OF ALL SEQUENCES.                        00770013
*   3. PASS CHAIN ADDRESS TO WRITE ROUTINE FOR LAST RECORD OF EACH      00840013
*      TRACK, EXCEPT AT EOS.                                            00910013
*   4. INFORM NETWORK INITIALIZATION ROUTINE WHEN WE ARE STARTING THE   00980013
*      MTH SEQUENCE DURING SORT PHASE.                                  01050013
*   5. INFORM NETWORK INITIALIZATION ROUTINE WHEN WE ARE SWITCHING FROM 01120013
*      SORT TO MERGE PHASE AND WHAT THE MERGE ORDER IS.                 01190013
*   6. INFORM NETWORK INITIALIZATION ROUTINE WHEN WE ARE SWITCHING FROM 01260013
*      MERGE TO SORT PHASE.                                             01330013
*   7. KEEP RECORD OF FREE TRACK AREAS ON ALL WORK AREAS.               01400013
*   8. SET UP DISK ADDRESSES FOR READ PRIME.                            01470013
*   9. DETERMINE WHETHER OR NOT ANOTHER READ CAN BE STARTED AFTER AN    01540013
*      EOS INDICATION FROM READ ROUTINE DURING A MERGE PASS.            01610013
*   10.AFTER EOF IT MUST CONTROL THE MERGES UNTIL FINAL MERGE PHASE.    01680013
*   11.IT MUST PASS THE STARTING ADDRESSES FOR ALL SEQUENCES FOR THE    01750013
*      START OF FINAL MERGE PHASE.                                      01820013
         SPACE 2                                                        01890013
*MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:                       01960013
         SPACE 1                                                        02030013
*   IER9ON                                                              02100013
         SPACE 2                                                        02170013
*MACROS USED -                                                          02240013
         SPACE 1                                                        02310013
*   SMPPI                                                               02380013
         SPACE 2                                                        02450013
*ENTRY POINTS:                                                          02520013
         SPACE 1                                                        02590013
*        ENTRY IER8ON              ENTRY FROM IER8PA                    02660013
*                                    CALLING SEQUENCE-                  02730013
*                                      L     RL,PPIALG+4                02800013
*                                      BR    RL   (REAL OR DUMMY EOF)   02870013
         SPACE 1                                                        02940013
*                                      L     RL,PPIALG+4                03010013
*                                      BAL   RO,4(0,RL) (GET CHAIN ADR) 03080013
         SPACE 1                                                        03150013
*                                      L     RL,PPIALG+4                03220013
*                                      B     8(0,RL)    (AT EOS)        03290013
         SPACE 1                                                        03360013
*                                  ENTRY FROM SORT NETWORK INITIAL.     03430013
*                                    CALLING SEQUENCE-                  03500013
*                                      L     RL,PPIALG+4                03570013
*                                      B     12(0,RL)                   03640013
         SPACE 1                                                        03710013
*                                  ENTRY FROM IER8GB                    03780013
*                                    CALLING SEQUENCE-                  03850013
*                                      L     RL,PPIALG+4                03920013
*                                      BAL   RO,16(0,RL)  (REL. A TRK.) 03990013
         SPACE 1                                                        04060013
*                                      L     RL,PPIALG+4                04130013
*                                      B     20(0,RL)     (AT EOS)      04200013
         SPACE 2                                                        04270013
*INPUT: PPI FIELDS REFERENCED -                                         04340013
         SPACE 1                                                        04410013
*   PPISW1      PPIRD       PPIINT                                      04480013
*   PPIDEB      PPIADSSC    PPIWKARE                                    04550013
*   PPICOUNT    PPIDELCT    PPIINSCT                                    04620013
*   PPIUNTCT    PPIMRGMX                                                04690013
         SPACE 2                                                        04760013
*OUTPUT: PPI FIELDS ALTERED -                                           04830013
         SPACE 1                                                        04900013
*   PPISW1      PPIWKARE    PPIDEPHO                                    04970013
*   PPIMRGMX    PPIENDAR                                                05040013
         SPACE 2                                                        05110013
*EXTERNAL ROUTINES:                                                     05180013
         SPACE 1                                                        05250013
*        IERRMA                    MESSAGE MODULE                       05320013
         SPACE 2                                                        05390013
*EXTERNAL PARAMETERS:                                                   05460013
         SPACE 1                                                        05530013
*        PPIWKARE CONTAINS M DISK ADDRESSES AT READ PRIME TIME FOR THE  05600013
*                 READ ROUTINE AND IT CONTAINS THE CHAIN ADDRESS UPON   05670013
*                 RETURN TO THE WRITE ROUTINE                           05740013
*        PPIDEPHO CONTAINS THE DISK ADDRESS FOR THE START OF THE NEXT   05810013
*                 SEQUENCE TO BE WRITTEN                                05880013
         SPACE 2                                                        05950013
*EXITS: NORMAL                                                          06020013
         SPACE 1                                                        06090013
*   IER8PA  -  RETURN WITH CHAIN ADDRESS                                06160013
*   IER8GB  -  BRANCH TO IT AT READ PRIME TIME AND AFTER EOS (READ).    06230013
*              RETURN TO IT AFTER RELEASING TRACK                       06300013
*   DEBLOCK -  BRANCH TO IT AFTER SORT PHASE EOS EXCEPT AFTER M-1 OR    06370013
*              MTH SEQUENCE                                             06440013
*   NETWORK INITIALIZATION - BRANCH TO IT AFTER M-1 SEQUENCES. ALSO,    06510013
*              AFTER M SEQUENCES IF EQUALS ROUTINE IS BEING USED AND    06580013
*              WHEN SWITCHING FROM MERGE TO SORT PHASE                  06650013
         SPACE 2                                                        06720013
*EXITS: ERROR                                                           06790013
         SPACE 1                                                        06860013
*   IERRCV  -  BRANCH AND LINK TO PRINT ERROR MESSAGE. BRANCH TO IT TO  06930013
*              ABORT JOB                                                07000013
         SPACE 2                                                        07070013
*TABLES/WORK AREAS:                                                     07140013
         SPACE 1                                                        07210013
*   WSEQCTR IS A HALF WORD FOR THE NUMBER OF SEQUENCES IN THIS SORT PH. 07280013
*   WSEQTOTL IS A HALF WORD FOR TOTAL NUMBER OF SEQUENCES OUT OF ALL    07350013
*   SORT PHASES SO FAR.                                                 07420013
*   THE TABLE POINTED TO BY KTABLEX IS THE MAIN ALGORITHM TABLE UPON    07490013
*   WHICH THE ALGORITHM BASES NEARLY ALL OF ITS DECISIONS.              07560013
*   THE AREA POINTED TO BY KPOOL IS FOR THE USE OF ANY FREE TRACK LIST  07630013
*   NEEDING ROOM FOR MORE ENTRIES.                                      07700013
         SPACE 2                                                        07770013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  07840013
         SPACE 2                                                        07910013
*NOTES: THIS MODULE IS USED FOR ALL 2314 SORTS AND FOR 2311 SORTS WITH  07980013
*   AT LEAST THREE SEPARATE DEVICES.                                    08050013
         EJECT                                                          08120013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            08190013
         SPACE 1                                                        08260013
RA       EQU   0                   CONTENTS IN - N/A                    08330013
*                                  USED - GENERAL WORK REGISTER.        08400013
*                                  CONTENTS OUT - ADDRESS OF ERROR      08470013
*                                    MESSAGE WHEN BRANCHING TO THE      08540013
*                                    PRINT ROUTINE.                     08610013
RB       EQU   1                   CONTENTS IN - THE REAL AREA INCRE-   08680013
*                                    MENT WHEN ENTERED FROM IER8PA AT   08750013
*                                    EOS OR FOR A CHAIN ADDRESS.        08820013
*                                              - LOGICAL AREA INCREMENT 08890013
*                                    WHEN ENTERED FROM IER8GB AT EOS.   08960013
*                                  USED - GENERAL WORK REGISTER.        09030013
*                                  CONTENTS OUT - WHEN BRANCHING TO     09100013
*                                    READ AFTER A READ EOS IT WILL CON- 09170013
*                                    TAIN A 0 OR 4 TO INDICATE NO OR    09240013
*                                    YES TO ANOTHER READ.               09310013
*                                               - NUMBER OF BYTES TO BE 09380013
*                                    PRINTED WHEN BRANCHING TO THE      09450013
*                                    PRINT ROUTINE.                     09520013
*                                               - ALWAYS CONTAINS A 4   09590013
*                                    WHEN BRANCHING TO IERRCV AT END OF 09660013
*                                    PHASE.                             09730013
RC       EQU   2                   CONTENTS IN - N/A                    09800013
*                                  USED - GENERAL WORK REGISTER.        09870013
*                                  CONTENTS OUT - N/A                   09940013
RD       EQU   3                   CONTENTS IN - N/A                    10010013
*                                  USED - GENERAL WORK REGISTER.        10080013
*                                  CONTENTS OUT - N/A                   10150013
RE       EQU   4                   CONTENTS IN - N/A                    10220013
*                                  USED - GENERAL WORK REGISTER.        10290013
*                                  CONTENTS OUT - N/A                   10360013
RF       EQU   5                   CONTENTS IN - N/A                    10430013
*                                  USED - GENERAL WORK REGISTER.        10500013
*                                  CONTENTS OUT - N/A                   10570013
RG       EQU   6                   CONTENTS IN - N/A                    10640013
*                                  USED - GENERAL WORK REGISTER.        10710013
*                                  CONTENTS OUT - N/A                   10780013
RH       EQU   7                   CONTENTS IN - N/A                    10850013
*                                  USED - GENERAL WORK REGISTER.        10920013
*                                  CONTENTS OUT - N/A                   10990013
RI       EQU   8                   CONTENTS IN - N/A                    11060013
*                                  USED - GENERAL WORK REGISTER.        11130013
*                                  CONTENTS OUT - N/A                   11200013
RJ       EQU   9                   CONTENTS IN - N/A                    11270013
*                                  USED - GENERAL WORK REGISTER.        11340013
*                                  CONTENTS OUT - N/A                   11410013
RK       EQU   10                  CONTENTS IN - N/A                    11480013
*                                  USED - GENERAL WORK REGISTER.        11550013
*                                  CONTENTS OUT - N/A                   11620013
RL       EQU   11                  CONTENTS IN - ADDRESS OF IER8ON.     11690013
*                                  USED - MODULE BASE REGISTER.         11760013
*                                  CONTENTS OUT - ADDRESS OF READ,      11830013
*                                    WRITE,DEBLOCK AND NETWORK INITIAL- 11900013
*                                    IZATION ROUTINES WHEN BRANCHING    11970013
*                                    TO THEM.                           12040013
RM       EQU   12                  CONTENTS IN - N/A                    12110013
*                                  USED - MESSAGE MODULE BASE REGISTER  12180013
*                                    AND GENERAL WORK REGISTER.         12250013
*                                  CONTENTS OUT - N/A                   12320013
RN       EQU   13                  CONTENTS IN - ADDRESS OF PPI.        12390013
*                                  USED - PPI BASE REGISTER.            12460013
*                                  CONTENTS OUT - ADDRESS OF PPI.       12530013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS WHEN    12600013
*                                    PRINT ROUTINE RETURNS.             12670013
*                                  USED - NOT USED.                     12740013
*                                  CONTENTS OUT - RETURN ADDRESS WHEN   12810013
*                                    BRANCHING TO WRITE ROUTINE AND     12880013
*                                    WHEN RETURNING TO READ ROUTINE     12950013
*                                    AFTER RELEASE TRACK ENTRY.         13020013
RP       EQU   15                  CONTENTS IN - N/A                    13090013
*                                  USED - BRANCH REGISTER FOR IERRCV.   13160013
*                                  CONTENTS OUT - ADDRESS OF PPIADSSC   13230013
*                                    WHEN BRANCHING TO IERRCV.          13300013
         SPACE 2                                                        13370013
*START OF MODULE CODE PROPER:                                           13440013
         SPACE 2                                                        13510013
IER8ON   CSECT                                                          13580013
*                                                                A27990 13610000
         USING *,RL                MODULE BASE REGISTER                 13650013
         USING IERRCA,RN           PPI BASE REGISTER                    13720013
         USING DIERRMA,RM          BASE REGISTER FOR MESSAGE MODULE     13790013
         SPACE 2                                                        13860013
*MODULE ENTRY TABLE:                                               3AC3 13930013
         SPACE 1                                                        14000013
         B     ONEOF               FROM WRITE AT EOF (SIM. OR REAL)     14070013
         B     ONCHNADR            FROM WRITE FOR CHAIN ADDRESS         14140013
         B     ONWRTEOS            FROM WRITE AT EOS (PH1 OR PH2)  3BB2 14210013
         B     ONEXRD              FROM NETWORK INITIALIZATION     3BB3 14280013
         B     ONRDTREL            FROM READ TO RELEASE A TRACK         14350013
         B     ONRDEOS             FROM READ AT EOS                     14420013
         SPACE 2                                                        14490013
ONWRTEOS STM   RC,RD,WSAVE1        SAVE RC AND RD                       14560013
         LM    RC,RI,WSAVE         RESTORE REGISTERS                    14630013
         TM    PPISW1+2,X'08'      ARE WE MERGING                  3BC2 14700013
         BO    ONRCDCHK            BRANCH IF YES                        14770013
         BAL   RK,ONREORD          GO REORDER THIS LIST            3BD2 14840013
         SPACE 2                                                        14910013
         LM    RJ,RK,WSEQTOTL                                           14980013
         LA    RJ,1(0,RJ)          ADD 1 TO TOTAL SEQUENCES        3BE2 15050013
         LA    RK,1(0,RK)          ADD 1 TO SEQUENCE CTR. (THIS PHASE)  15120013
         STM   RJ,RK,WSEQTOTL      SAVE TOTALS                          15190013
         CL    RJ,KMSQURD          M SQUARED +1 SEQUENCES YET      3BF2 15260013
         BH    ONMSQPLS            BRANCH IF YES                        15330013
         LA    RD,1(0,RD)          SET I=I+1                       3BG2 15400013
         CL    RD,KMERGORD         IS I NOW LARGER THAN MRG ORD    3BH2 15470013
         BNH   ONGETADR            BRANCH IF NO                         15540013
         SR    RD,RD               SET I=0 IF YES                       15610013
ONGETADR LR    RB,RD               PUT I INCREMENT IN RB                15680013
         BAL   RK,ONGETTRK         BRANCH AND LINK TO GET AN ADR   3BH3 15750013
         SPACE 2                                                        15820013
         BAL   RK,ONCOMPAC         GO PUT DISK ADR IN 4 BYTE FORMAT     15890013
         SPACE 2                                                        15960013
         MVC   PPIDEPHO(8),PPIWKARE      MOVE DISK ADR TO DEPHO    3BJ3 16030013
         LR    RK,RD               LOAD I INTO RH                       16100013
         SLL   RK,2                RK=I X 4                             16170013
         LA    RO,4(0,RK)          GET LOGICAL INCREMENT                16240013
         STC   RO,PPIDEPHO+1       STORE IT                             16310013
         ST    RJ,0(RF,RK)         PUT IN FIRST ROW OF TABLE UNDER I    16380013
         L     RK,WSEQCTR                                               16450013
ONEXIT1  STM   RC,RE,WSAVE         SAVE J, I AND L                      16520013
         LM    RC,RD,WSAVE1                                             16590013
         CL    RK,KMOMONE          DOES SEQ CTR=M-1                3BK4 16660013
         BE    ONMTHSEQ            BRANCH IF YES                        16730013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    16800013
         L     RL,PPIDEB+4                                              16870013
         B     8(0,RL)             BRANCH TO DEBLOCK               3BK5 16940013
         SPACE 2                                                        17010013
ONMTHSEQ L     RL,PPIINT+4                                              17080013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    17150013
         B     8(0,RL)             BRANCH TO NET INIT-MTH SEQ      3BK3 17220013
         SPACE 2                                                        17290013
ONMSQPLS SH    RC,KONE             SET J=J-1                       3BF3 17360013
         BNM   ONGETDA             BRANCH UNLESS IT IS MINUS       3BG3 17430013
         L     RC,KMERGORD         SET J=MERGE ORDER               3BG4 17500013
ONGETDA  LR    RB,RC               SET RB=J                             17570013
         BAL   RK,ONGETTRK         BRANCH AND LINK TO GET AN ADR   3BH4 17640013
         SPACE 2                                                        17710013
         MVC   PPIDEPHO(8),PPIWKARE      MOVE DISK ADR TO DEPHO    3BJ4 17780013
         LR    RM,RC               LOAD J INTO RM                       17850013
         SLL   RM,2                RM=J X 4                             17920013
         LA    RK,4(0,RM)          GET LOGICAL INCREMENT                17990013
         STC   RK,PPIDEPHO+1       STORE IT                             18060013
         BAL   RK,ONCOMPAC         GO PUT DISK ADR IN 4 BYTE FORMAT     18130013
         SPACE 2                                                        18200013
         ST    RJ,0(RF,RM)         PUT IN FIRST ROW OF TABLE UNDER J    18270013
         B     ONEXIT1-4           BRANCH TO EXIT                       18340013
         SPACE 2                                                        18410013
*   THIS SUBROUTINE TAKES THE 8 BYTE DISK ADDRESS FROM PPIWKARE AND     18480013
*   COMPACTS IT INTO 4 BYTES FOR THE ALGORITHM TABLE.                   18550013
         SPACE 1                                                        18620013
ONCOMPAC IC    RJ,PPIWKARE         REAL INCREMENT                       18690013
         SLL   RJ,8                                                     18760013
         IC    RJ,PPIWKARE+4       CYLINDER                             18830013
         SLL   RJ,8                                                     18900013
         IC    RJ,PPIWKARE+6       HEAD                                 18970013
         SLL   RJ,8                ZERO OUT LO ORDER BYTE               19040013
         BR    RK                  RETURN                               19110013
         SPACE 2                                                        19180013
*   THIS SEGMENT OF CODE IS ENTERED AFTER EVERY END OF SEQUENCE WHILE   19250013
*   MERGING                                                             19320013
         SPACE 1                                                        19390013
ONRCDCHK BAL   RK,ONRCDCNT         GO MAKE A CHECK ON RECORD COUNT 3BB1 19460013
         SPACE 1                                                        19530013
         MVI   WSWITCHD,X'00'      CLEAR 'ANOTHER MERGE PASS INDICATOR' 19600013
         TM    PPISW1+3,X'01'      HAVE WE REACHED REAL EOF        3BC1 19670013
         BNO   ONNOEOF             BRANCH IF NOT                        19740013
         TM    PPISW1+7,X'80'      HAVE WE REACHED E15 EOF              19810013
*                                    (WILL BE SET IF E15 NOT ACTIVE)    19880013
         BNO   ONNOEOF             BRANCH IF NO                         19950013
         LTR   RE,RE               DOES L = 0                      3BD1 20020013
         BZ    ONEQZERO            BRANCH IF YES                        20090013
         LR    RM,RE               PUT L IN RM                     3BE1 20160013
         BCT   RM,ONNOEOF          DOES IT = 1  BRANCH IF NO            20230013
         LH    RM,KBPRLS4          BYTES PER ROW OF TABLE-4             20300013
         L     RM,0(RM,RH)         GET INFO FROM L=1 ROW                20370013
         CL    RM,KONEONE          IS INFO=1010                         20440013
         BNE   ONNOEOF             BRANCH IF NO                         20510013
ONEQZERO L     RF,KTABLEX0         SET POINTER TO L=0 ROW          3BF1 20580013
         SR    RC,RC               ZERO FOR MERGE ORDER                 20650013
         SR    RB,RB               DON'T NEED TO SAVE REGS NOW     3BJ1 20720013
         MVC   PPIDSKED(136),PPIENDAR  MOVE FOR END OF PHASE ROUTINE    20790013
         LM    RG,RH,PPIDSKED+48   SAVE THESE 8 BYTES BECAUSE PPIWKARE  20860013
*                                    +128 (PPIDSKED+48) IS USED BY THE  20930013
*                                    SUBROUTINE AT ONEXPAND             21000013
         LA    RE,PPIENDAR         SET POINTER TO PPIENDAR              21070013
ONLOOP1  SR    RJ,RJ                                                    21140013
         A     RJ,0(RB,RF)         GET ENTRY FROM TABLE                 21210013
         BNZ   ONRELONE            BRANCH IF IT'S REAL                  21280013
ONNEXTRY LA    RB,4(0,RB)          UP POINTER TO NEXT ENTRY             21350013
         CH    RB,KBPRLS4          ARE WE THROUGH                       21420013
         BL    ONLOOP1             BRANCH IF NO                         21490013
         STH   RC,PPIMRGMX         STORE MERGE ORDER FOR PHASE 3   3BH1 21560013
         STM   RG,RH,PPIDSKED+48   RESTORE 8 BYTES                      21630013
         CLC   WSEQTOTL(4),KMERGORD  M SEQ. OR MORE                     21700013
         BH    ONDONE              GO EXIT TO RCV IF YES                21770013
         TM    PPISW1+3,X'80'      IS EQUALS BIT ON                     21840013
         BNO   ONDONE              GO EXIT TO RCV IF NO                 21910013
         MVC   ONEXRD(4),KOVERLA2  OVERLAY TO EXIT TO RCV UPON RETURN   21980013
         B     ONOFFA              GO EXIT TO NET. INIT.                22050013
ONDONE   LA    RB,4                INDICATE CALL PHASE 3           3BK1 22120013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    22190013
         L     RP,PPIADSSC                                              22260013
         B     20(0,RP)            GO TO END OF PHASE ENTRY OF RCV 3BK2 22330013
         SPACE 2                                                        22400013
ONRELONE BAL   RK,ONEXPAND         GO EXPAND ADDRESS TO 8 BYTES         22470013
         MVC   0(8,RE),PPIWKARE+128  MOVE ADDRESS INTO PPIENDAR         22540013
         LA    RE,8(0,RE)          UP PPIENDAR POINTER                  22610013
         LA    RC,1(0,RC)          UP MERGE ORDER BY 1                  22680013
         B     ONNEXTRY                                                 22750013
         SPACE 2                                                        22820013
*   THIS SUBROUTINE EXPANDS A 4 BYTE DISK ADDRESS,WHICH IT RECEIVES IN  22890013
*   REGISTER RJ,INTO AN 8 BYTE ADDRESS AT PPIWKARE+128. IT WILL CONTAIN 22960013
*   THE REAL AREA INCREMENT AND A 1 FOR RECORD NO. BUT WILL NOT CONTAIN 23030013
*   THE LOGICAL AREA INCREMENT.                                         23100013
         SPACE 1                                                        23170013
ONEXPAND STH   RJ,PPIWKARE+134     PUT IN TRACK NO.                     23240013
         MVI   PPIWKARE+135,1      PUT IN A 1 FOR RECORD NO.            23310013
         XC    PPIWKARE+128(6),PPIWKARE+128                             23380013
         SRL   RJ,16               POSITION CYLINDER NO.                23450013
         STC   RJ,PPIWKARE+132     PUT IN CYLINDER NO.                  23520013
         SRL   RJ,8                POSITION REAL INCREMENT              23590013
         STC   RJ,PPIWKARE+128     PUT IN REAL INCREMENT                23660013
         BR    RK                  RETURN                               23730013
         SPACE 2                                                        23800013
*   THIS ROUTINE IS ENTERED AFTER EVERY MERGE PASS EXCEPT THE LAST ONE  23870013
*   IN PHASE 2. THE FIRST PORTION WILL BE OVERLAID AT EOF.              23940013
         SPACE 1                                                        24010013
ONNOEOF  NI    PPISW1+7,X'F7'      TURN OFF 'MORE MERGE' BIT       3CB2 24080013
         BAL   RK,ONREORD          GO REORDER ALL FTL              3CC2 24150013
         SPACE 2                                                        24220013
         CLC   WSEQTOTL,KMSQURD    M SQUARED SEQUENCES YET         3CD2 24290013
         BH    ONMTMSQ             BRANCH IF MORE THAN M SQUARED        24360013
         LR    RB,RD               PUT I IN RB                          24430013
         BAL   RK,ONGETTRK         BRANCH AND LINK TO GET AN ADR   3CD1 24500013
         SPACE 1                                                        24570013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE IT TO DEPHO              3CE1 24640013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   24710013
         SPACE 1                                                        24780013
         LR    RM,RD               PUT I IN RM                          24850013
         SLL   RM,2                RM=I X 4                             24920013
         ST    RJ,0(RF,RM)         PUT IN FIRST ROW OF TABLE UNDER I    24990013
         LA    RM,4(0,RM)          GET LOGICAL INCREMENT                25060013
         STC   RM,PPIDEPHO+1       STORE IT                             25130013
ONSETSRT NI    PPISW1+2,X'F7'      SET SW TO SORT-PHASE 2 OFF      3CF1 25200013
         B     ONEXTNET+4          GO EXIT TO NETWORK INITIALIZATION    25270013
         SPACE 2                                                        25340013
ONMTMSQ  LH    RK,KBPRLS3          POINTER TO HI NO.               3CE2 25410013
         AR    RK,RH               PLUS L ROW                           25480013
         CLC   0(1,RK),KMOMONE+3   IS HI NO. = MERGE ORDER-1            25550013
         BE    ONCHKFUR            BRANCH IF YES                        25620013
         SPACE 1                                                        25690013
         LR    RB,RC               SET RB=J                             25760013
ONOLYEOF BC    0,ONAFTEOF          WILL BE UNCOND BRANCH AFTER EOF 3CF2 25830013
         BAL   RK,ONGETTRK         BRANCH AND LINK TO GET AN ADR   3CG2 25900013
         SPACE 1                                                        25970013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE IT TO DEPHO              3CH2 26040013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   26110013
         SPACE 1                                                        26180013
         LR    RM,RC               SET RM=J                             26250013
         SLL   RM,2                RM=J X 4                             26320013
         ST    RJ,0(RF,RM)         PUT IN FIRST ROW OF TABLE UNDER J    26390013
         LA    RM,4(0,RM)          GET LOGICAL INCREMENT                26460013
         STC   RM,PPIDEPHO+1       STORE IT                             26530013
         B     ONSETSRT                                                 26600013
         SPACE 2                                                        26670013
ONCHKFUR LH    RK,KBPRLS4          POINTER TO HI                   3CB3 26740013
         AR    RK,RH               PLUS L ROW                           26810013
         LH    RM,KBPRLS2          POINTER TO LO                        26880013
         AR    RM,RI               PLUS L-1 ROW                         26950013
         CLC   0(1,RM),0(RK)       ARE THEY EQUAL                       27020013
         BE    ONSETMRG            BRANCH IF YES                        27090013
         NI    PPISW1+2,X'F7'      SET SW TO SORT-PHASE 2 OFF      3CB4 27160013
         B     ONUPHI                                                   27230013
         SPACE 2                                                        27300013
ONSETMRG SR    RJ,RJ               CLEAR FOR MERGE ORDER           3CC3 27370013
         LR    RK,RH               ADDRESS OF L ROW                     27440013
         L     RM,KMERGORD         RM = MERGE ORDER                     27510013
         LA    RM,1(0,RM)          PLUS 1                               27580013
ONCHKMT  CLI   0(RK),X'00'         ANYTHING IN THIS ENTRY               27650013
         BNE   ONUPMRG             BRANCH IF YES                        27720013
ONNEXENT LA    RK,4(0,RK)          UP POINTER TO NEXT ENTRY             27790013
         BCT   RM,ONCHKMT          DECREMENT RM-BRANCH IF MORE ENTRIES  27860013
         B     ONCHKUNI            FINISHED WITH THIS ROW               27930013
         SPACE 2                                                        28000013
ONUPMRG  LA    RJ,1(0,RJ)          UP MERGE ORDER BY 1                  28070013
         B     ONNEXENT            GO CONTINUE CHECK                    28140013
         SPACE 2                                                        28210013
ONCHKUNI LR    RK,RD               RK = I                               28280013
         SLL   RK,2                RK = I X 4                           28350013
         AR    RK,RI               RK = ADDRESS OF L-1 ROW + I X 4      28420013
         CLI   0(RK),X'00'         ANYTHING AT THIS ENTRY               28490013
         BE    ONSTORMX            BRANCH IF NO                         28560013
         LA    RJ,1(0,RJ)          UP MERGE ORDER BY 1                  28630013
ONSTORMX STH   RJ,PPIMRGMX         STORE MERGE ORDER                    28700013
         CLI   WSWITCHC,X'00'      IS SWITCH C SET                 3CD3 28770013
         BE    ONSWCNO             BRANCH IF NO                         28840013
         MVI   WSWITCHC,X'00'      CLEAR SWITCH C                  3CE3 28910013
         LTR   RJ,RJ               IS MERGE ORDER = 0              3CF3 28980013
         BZ    ONCLRTBL            BRANCH IF YES                        29050013
         SPACE 1                                                        29120013
         LR    RB,RD               RB = I                          3CG3 29190013
         LA    RB,1(0,RB)          PLUS 1                               29260013
         CL    RB,KMERGORD         IS IT BEYOND TABLE                   29330013
         BNH   ONGOGET             BRANCH IF NO                         29400013
         SR    RB,RB               SET TO 0                             29470013
ONGOGET  BAL   RK,ONGETTRK         GO GET AN ADDRESS                    29540013
         SPACE 2                                                        29610013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE ADDRESS TO DEPHO         3CH3 29680013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   29750013
         SPACE 1                                                        29820013
         LR    RK,RD               RK = I                               29890013
         LA    RK,1(0,RK)          RK = I+1                             29960013
         CL    RK,KMERGORD         ARE WE BEYOND LAST ENTRY             30030013
         BNH   ONNOTGMO            BRANCH IF NOT                        30100013
         SR    RK,RK               SET RK = 0                           30170013
ONNOTGMO SLL   RK,2                TIMES 4                              30240013
         ST    RJ,0(RI,RK)         STORE ADDRESS AT (L-1,I+1)           30310013
         B     ONLDWKAR            GO LOAD PPIWKARE WITH NEXT MRG ADRS  30380013
         SPACE 2                                                        30450013
ONSWCNO  MVI   WSWITCHC,X'FF'      SET SWITCH C                    3CD4 30520013
         LTR   RJ,RJ               IS MERGE ORDER = 0              3CE4 30590013
         BZ    ONCLRTBL            BRANCH IF YES                        30660013
         LR    RB,RD               RB = I                          3CF4 30730013
         SH    RB,KONE             MINUS 1                              30800013
         BNM   ONNOTMIN            BRANCH IF NOT MINUS                  30870013
         L     RB,KMERGORD         SET TO LAST ENTRY                    30940013
ONNOTMIN BAL   RK,ONGETTRK         GO GET AN ADDRESS                    31010013
         SPACE 2                                                        31080013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE ADDRESS TO DEPHO         3CG4 31150013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   31220013
         SPACE 1                                                        31290013
         LR    RK,RD               RK = I                               31360013
         SH    RK,KONE             MINUS 1                              31430013
         BNM   ONNIXMIN            BRANCH IF NOT MINUS                  31500013
         L     RK,KMERGORD         SET TO LAST ENTRY                    31570013
ONNIXMIN SLL   RK,2                I X 4                                31640013
         ST    RJ,0(RI,RK)         STORE ADDRESS AT (L-1,I-1)           31710013
ONLDWKAR LA    RK,4(0,RK)          GET LOGICAL AREA INCREMENT      3CH4 31780013
         STC   RK,PPIDEPHO+1       STORE IT                             31850013
         LA    RM,PPIWKARE         ADDRESS OF WORK AREA            3CH5 31920013
         SR    RO,RO               RO = 0                               31990013
         ST    RO,PPIWKARE+128                                          32060013
         ST    RO,PPIWKARE+132     CLEAR OUT 8 BYTE AREA                32130013
ONLOOP2  SR    RJ,RJ                                                    32200013
         A     RJ,0(RO,RH)         LOAD RJ WITH ENTRY                   32270013
         BNZ   ONGOTONE            BRANCH IF REAL ADDRESS               32340013
ONLOOP3  LA    RO,4(0,RO)          UP POINTER BY 4                      32410013
         CH    RO,KBPRLS4          ARE WE THROUGH WITH THIS LINE        32480013
         BE    ONONELF             BRANCH IF YES                        32550013
         B     ONLOOP2             LOOP IF NO                           32620013
         SPACE 2                                                        32690013
ONGOTONE BAL   RK,ONEXPAND         GO EXPAND ADDRESS                    32760013
         SPACE 1                                                        32830013
         MVC   0(8,RM),PPIWKARE+128  MOVE TO LIST FOR READ ROUTINE      32900013
         LA    RP,4(0,RO)          GET LOGICAL AREA INCREMENT           32970013
         STC   RP,1(0,RM)          STORE IT IN 2ND BYTE OF ADDRESS      33040013
         LA    RM,8(0,RM)          UP LIST POINTER BY 8                 33110013
         B     ONLOOP3             LOOP                                 33180013
         SPACE 2                                                        33250013
ONONELF  LR    RP,RD               RP = I                               33320013
         SLL   RP,2                TIMES 4                              33390013
         SR    RJ,RJ                                                    33460013
         A     RJ,0(RI,RP)         GET ENTRY AT L-1 UNDER I             33530013
         BZ    ONCLRTBL            SKIP IF NUL ENTRY                    33600013
         BAL   RK,ONEXPAND         GO EXPAND ADDRESS                    33670013
         SPACE 1                                                        33740013
         MVC   0(8,RM),PPIWKARE+128  MOVE IT TO LIST FOR READ ROUTINE   33810013
         LA    RP,4(0,RP)          I TIMES 4 PLUS 4                     33880013
         STC   RP,1(0,RM)          INSERT LOGICAL AREA INCREMENT        33950013
ONCLRTBL MVI   0(RH),X'00'         ZERO ONE BYTE                   3CJ4 34020013
         LR    RP,RH               ADDRESS OF TABLE ROW TO CLEAR        34090013
         LH    RJ,KBPRLS6          GET LENGTH FIELD                     34160013
         EX    RJ,ONMOVE           PROPAGATE ZERO THROUGH ROW-4 BYTES   34230013
         LA    RJ,2(0,RJ)          UP IT BY 2                           34300013
         L     RK,KONEONE                                               34370013
         ST    RK,0(RJ,RH)         INSERT 1010 IN LAST 4 BYTES          34440013
         LR    RK,RD               RK = I                               34510013
         SLL   RK,2                TIMES 4                              34580013
         SR    RJ,RJ                                                    34650013
         ST    RJ,0(RK,RI)         ZERO OUT ENTRY AT L-1 UNDER I        34720013
         SPACE 2                                                        34790013
         LH    RJ,KBPRLS4          POINTER TO HI                   3DB2 34860013
         SR    RK,RK                                                    34930013
         IC    RK,1(RJ,RI)         GET HI NO. AT L-1 ROW                35000013
         LA    RK,1(0,RK)          UP IT BY 1                           35070013
         STC   RK,1(RJ,RI)         STORE IT BACK                        35140013
         IC    RM,3(RJ,RI)         GET LO NO. AT L-1                    35210013
         SH    RM,KONE             DECREMENT BY 1                       35280013
         STC   RM,3(RJ,RI)         STORE IT BACK                        35350013
         CL    RK,KMERGORD         HI NO. NOW = MERGE ORDER        3DC2 35420013
         BL    ONDECL              BRANCH IF NO                         35490013
         SPACE 1                                                        35560013
         LH    RK,0(RJ,RI)         GET HI AND HI NO. AT L-1        3DD2 35630013
         STH   RK,2(RJ,RI)         STORE THEM AT LO AND LO NO. AT L-1   35700013
         SRL   RK,8                ZERO OUT HI NO.                      35770013
         LA    RK,1(0,RK)          ADD ONE TO HI                        35840013
         SLL   RK,8                                                     35910013
         STH   RK,0(RJ,RI)         STORE IN HI AND HI NO. AT L-1        35980013
ONDECL   S     RH,KBYPEROW         DECREMENT L ROW POINTER         3DD3 36050013
         S     RI,KBYPEROW         DECREMENT L-1 ROW POINTER            36120013
         BCT   RE,ONNOTZRO         BRANCH IF L NOT EQUAL 0         3DE3 36190013
ONUPL    LA    RE,1(0,RE)          L=L+1                           3DD4 36260013
         A     RH,KBYPEROW         INCREMENT L ROW POINTER              36330013
         A     RI,KBYPEROW         INCREMENT L-1 ROW POINTER            36400013
         LA    RM,10                                                    36470013
         CR    RM,RE               DOES L = 10                     3DE4 36540013
         BE    ONMSG46A            BRANCH TO PRINT MESSAGE              36610013
         LA    RD,1(0,RD)          I = I+1                         3DF4 36680013
         CL    RD,KMERGORD         I = M+1                              36750013
         BNH   ONJTOI              BRANCH IF NO                         36820013
         SR    RD,RD               SET I = 0                            36890013
ONJTOI   LR    RC,RD               SET J = I                       3DG4 36960013
         TM    PPISW1+2,X'08'      SORT OR MERGE                   3DH4 37030013
         BO    ONMGMX              BRANCH IF MERGE                      37100013
ONEXTNET STM   RC,RI,WSAVE         SAVE REGISTERS-OVERLAID AT EOF  3DH5 37170013
         LM    RC,RD,WSAVE1        RESTORE RC AND RD                    37240013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    37310013
         L     RL,PPIINT+4                                              37380013
         B     4(0,RL)             EXIT  TO SORT ENTRY OF INITIAL.      37450013
         SPACE 2                                                        37520013
ONMGMX   CLI   PPIMRGMX+1,X'00'    DOES MERGE ORDER = 0            3DJ3 37590013
         BE    ONMTMSQ             BRANCH IF YES                        37660013
ONRESTO  STM   RC,RI,WSAVE         SAVE REGISTERS                       37730013
         LM    RC,RD,WSAVE1        RESTORE RC AND RD                    37800013
         TM    PPISW1+3,X'80'      IS EQUALS BIT ON                3DJ4 37870013
         BNO   ONEXRD              BRANCH IF NO                         37940013
         CLI   WSWITCHA,X'FF'      IS SWITCH A ON                  3DJ5 38010013
         BE    ONOFFA              BRANCH IF YES                        38080013
ONEXRD   L     RL,PPIRD+4                                          3DK3 38150013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    38220013
         B     4(0,RL)             EXIT TO READ (PRIME)                 38290013
         SPACE 2                                                        38360013
ONOFFA   MVI   WSWITCHA,X'00'      TURN OFF SWITCH A               3DK5 38430013
         L     RL,PPIINT+4                                         3DK4 38500013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    38570013
         BR    RL                  EXIT TO INITIAL. (MERGE ENTRY)       38640013
         SPACE 2                                                        38710013
ONNOTZRO SR    RM,RM                                               3DF3 38780013
         IC    RM,1(RJ,RH)         GET HI NO. AT L                      38850013
         CL    RM,KMOMONE          IS IT = MERGE ORDER - 1              38920013
         BNE   ONUPL               BRANCH IF NOT EQUAL                  38990013
         IC    RM,2(RJ,RI)         GET LO AT L-1                   3DG3 39060013
         SR    RO,RO                                                    39130013
         IC    RO,0(RJ,RH)         GET HI AT L                          39200013
         CR    RM,RO               ARE THEY EQUAL                       39270013
         BNE   ONUPHI              BRANCH IF NO                         39340013
         MVI   WSWITCHD,X'FF'      ANOTHER MERGE PASS TO FOLLOW IMMED.  39410013
         OI    PPISW1+7,X'08'      SET BIT 61 (ANOTHER MERGE PASS) 3DH3 39480013
         B     ONMGMX              BRANCH BACK                          39550013
         SPACE 2                                                        39620013
ONUPHI   LH    RJ,KBPRLS4          POINTER TO HI                        39690013
         LH    RK,0(RJ,RH)         GET HI AND HI NO. AT L               39760013
         STH   RK,2(RJ,RH)         STORE IN LO AND LO NO. AT L          39830013
         SRL   RK,8                ZERO OUT HI NO.                      39900013
         LA    RK,1(0,RK)          ADD ONE TO HI                        39970013
         SLL   RK,8                                                     40040013
         STH   RK,0(RJ,RH)         STORE IN HI AND HI NO. AT L          40110013
         B     ONUPL               GO TO INCRE L                        40180013
         SPACE 2                                                        40250013
ONMSG46A L     RM,PPIRMA+4         SET MSG MOD BASE REG            3DE5 40320013
         LM    RA,RB,MSGP1A02      LOAD PARAMETER REGISTERS             40390013
         L     RP,PPIADSSC                                              40460013
         BAL   RO,12(0,RP)         PRINT MESSAGE -SORT CAP. EXCEEDED    40530013
         SPACE 2                                                        40600013
*APROX RCD CNT IS SUM OF UNIT COUNTS - B, WHERE B IS A MAX. VALUE.  SO  40670013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO B.  THIS NEGATIVE CONDITION    40740013
*   IS MOST LIKELY IF THE BLOCK BEING WRITTEN OUT IS SHORT AND/OR       40810013
*   RECORD FORMAT IS VARIABLE.                                          40880013
         SPACE 1                                                        40950013
         L     RB,PPIUNTCT         ADDR. OF UNIT COUNTERS - TABLE       41020013
         SR    RC,RC                 CONTAINS NO. OF RCDS. PER DEVICE   41090013
         SR    RD,RD                                                    41160013
         IC    RD,PPIBDSVA                                              41230013
RON155   LA    RB,4(0,RB)                                               41300013
         A     RC,0(0,RB)          SUM UNIT COUNTERS                    41370013
         BCT   RD,RON155                                                41440013
         SPACE 2                                                        41510013
         LH    RP,PPISRTBL         B  -F = RCDS./BLOCK                  41580013
         TM    PPISW1,X'80'            V = BYTES/BLOCK                  41650013
         BO    RON157                                                   41720013
         SPACE 1                                                        41790013
         SR    RO,RO               B / MIN.RCD.LENGTH = MAX. NO.        41860013
         LH    RA,PPIRCDL4                                              41930013
         DR    RO,RA                 RCDS. IN BLOCK                     42000013
RON157   CR    RC,RP               CHECK TO MAKE SURE CNT ISN'T         42070013
         BH    RON158                NEGATIVE                           42140013
         SPACE 1                                                        42210013
         LR    RC,RP               SET RCD CNT TO B                     42280013
         B     RON159                                                   42350013
         SPACE 2                                                        42420013
RON158   SR    RC,RP               APROX. RCD CNT = SUM UNIT CNTS - B   42490013
RON159   CVD   RC,WSAVE4           SET UP TO PRINT                      42560013
         BAL   RP,ON0SPRS            COUNT                              42630013
         SPACE 1                                                        42700013
         MVC   MSGP1R06+24(7),WSAVE4+8                                  42770013
         LM    RA,RB,MSGP1A06                                           42840013
         B     ONOUTMSG            BRANCH TO PRINT 'CAPACITY EXCEEDED'  42910013
*                                    MESSAGE AND ABORT                  42980013
         SPACE 2                                                        43050013
*   THIS ROUTINE IS ENTERED AT INPUT EOF AS WELL AS THE SIMULATED EOF   43120013
*   WHICH OCCURS AFTER EACH M SEQUENCES HAVE BEEN SORTED.               43190013
         SPACE 1                                                        43260013
ONEOF    STM   RC,RD,WSAVE1        SAVE RC AND RD FOR CALLING MOD  3EB2 43330013
         LM    RC,RI,WSAVE         RESTORE REGISTERS FOR OWN USE        43400013
         L     RJ,WSEQTOTL                                         3EC2 43470013
         LA    RJ,1(0,RJ)          ADD 1 TO SEQUENCE TOTAL              43540013
         ST    RJ,WSEQTOTL         SAVE IT                              43610013
         BAL   RK,ONREORD          GO REORDER THE FTL (INCRE IN RB)3ED2 43680013
         SPACE 1                                                        43750013
ONSETSWM OI    PPISW1+2,X'08'      SET MERGE SWITCH (PHASE 2)      3EE2 43820013
         OI    WSWITCHA,X'FF'      SET SWITCH A (SWITCHING TO MERGE PH) 43890013
         TM    PPISW1+3,X'01'      IS THIS A REAL EOF              3EF2 43960013
         BZ    ONNOTYET            BRANCH IF NO                         44030013
         TM    PPISW1+7,X'80'      HAVE WE REACHED E15 END OF FILE      44100013
         BO    ONRELEOF            BRANCH IF YES                        44170013
ONNOTYET MVI   WSEQCTR+3,X'00'     SET SEQ CTR = 0                 3EG2 44240013
ONONETIM CLC   WSEQTOTL(4),KMSQURD M SQUARED + 1 SEQUENCES YET     3EB3 44310013
         BNH   ONUPI               BRANCH IF NO                         44380013
         SH    RC,KONE             J=J-1                           3EC3 44450013
         BNM   ONJNOTM             BRANCH UNLESS J NEGATIVE        3ED3 44520013
         L     RC,KMERGORD         SET J=M                         3ED4 44590013
ONJNOTM  LR    RB,RC               RB=INCREMENT (FROM J)           3EE3 44660013
         BAL   RK,ONGETTRK         GO GET AN ADDRESS                    44730013
         SPACE 1                                                        44800013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE IT TO DEPHO              3EF3 44870013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   44940013
         SPACE 1                                                        45010013
         SR    RK,RK               CLEAR RK                             45080013
         LR    RM,RC               RM=J                                 45150013
         SLL   RM,2                TIMES 4                              45220013
         ST    RJ,0(RM,RH)         STORE ADR IN TABLE AT (LJ)           45290013
         LA    RJ,4(0,RM)          GET LOGICAL AREA INCREMENT           45360013
         STC   RJ,PPIDEPHO+1       STORE IT                             45430013
         LH    RJ,KBPRLS4          RJ=POINTER TO HI                     45500013
         IC    RK,1(RJ,RH)         GET HI NO.                           45570013
         LA    RK,1(0,RK)          UP IT BY 1                           45640013
         STC   RK,1(RJ,RH)         STORE IT BACK                        45710013
         CL    RK,KMOMONE          DOES HI NO.=MERGE ORDER-1       3EG3 45780013
         BE    ONISHILO            BRANCH IF YES                        45850013
         SPACE 2                                                        45920013
*   THE FIRST 2 INSTRUCTIONS (10 BYTES) OF THE FOLLOWING CODE WILL BE   45990013
*   OVERLAID BY NOPS AFTER A REAL INPUT END OF FILE.                    46060013
         SPACE 1                                                        46130013
ONONEPAS NI    PPISW1+7,X'F7'      CLEAR BIT 61 (ONLY 1 MRG PASS)  3EH3 46200013
ONSETMO  MVC   PPIMRGMX(2),KMERGORD+2   SET PPIMRGMX=FULL MERGE    3EJ3 46270013
         SR    RB,RB                                               3EJ2 46340013
         L     RO,KTABLEX          SET UP POINTER TO FIRST ROW OF TBL   46410013
         LA    RM,PPIWKARE         SET UP POINTER FOR STORING ADRS      46480013
ONLOOP4  SR    RJ,RJ                                                    46550013
         A     RJ,0(RB,RO)         GET NEXT ENTRY                       46620013
         BNZ   ONACTADR            BRANCH IF IT IS REAL                 46690013
ONLOOP5  LA    RB,4(0,RB)          UP POINTER TO NEXT ENTRY             46760013
         CH    RB,KBPRLS4          ARE WE THROUGH                       46830013
         BL    ONLOOP4             BRANCH IF NO                         46900013
         B     ONCLFSTR            BRANCH WHEN LOOP FINISHED            46970013
         SPACE 2                                                        47040013
ONACTADR BAL   RK,ONEXPAND         GO EXPAND ADDRESS WHICH IS IN RJ     47110013
         SPACE 1                                                        47180013
         MVC   0(8,RM),PPIWKARE+128  MOVE ADDRESS TO PPIWKARE           47250013
         LR    RP,RB               RP=INCREMENT                         47320013
         LA    RP,4(0,RP)          INCREMENT + 4 (START AT 4 NOT 0)     47390013
         STC   RP,1(0,RM)          INSERT LOGICAL INCREMENT             47460013
         LA    RM,8(0,RM)          UP POINTER TO PPIWKARE BY 8          47530013
         B     ONLOOP5             CONTINUE LOOP                        47600013
         SPACE 2                                                        47670013
ONCLFSTR L     RP,KTABLEX          ADDRESS OF FIRST ROW OF TABLE   3EK2 47740013
         MVI   0(RP),X'00'         ZERO FIRST BYTE                      47810013
         LH    RJ,KBPRLS6          NO. OF BYTES TO ZERO                 47880013
         EX    RJ,ONMOVE           PROPAGATE ZEROS THROUGH FIRST ROW-4  47950013
         B     ONRESTO             GO RESTORE REGS AND EXIT             48020013
         SPACE 2                                                        48090013
ONUPI    LA    RD,1(0,RD)          I=I+1                           3EB4 48160013
         CL    RD,KMERGORD         DOES I NOW=MERGE ORDER+1        3EC4 48230013
         BNH   ONSKIP1             BRANCH IF NO                         48300013
         SR    RD,RD               I=0                             3EC5 48370013
ONSKIP1  LR    RB,RD               RB=I                                 48440013
         BAL   RK,ONGETTRK         GO GET AN ADDRESS               3ED5 48510013
         SPACE 1                                                        48580013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE IT TO DEPHO              3EE5 48650013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   48720013
         SPACE 1                                                        48790013
         LR    RM,RD               RM=I                                 48860013
         SLL   RM,2                TIMES 4                              48930013
         ST    RJ,0(RM,RH)         STORE ADDRESS AT (LI)                49000013
         LA    RJ,4(0,RM)          GET LOGICAL AREA INCREMENT           49070013
         STC   RJ,PPIDEPHO+1       STORE IT                             49140013
         LH    RJ,KBPRLS1          POINTER TO LO NO.                    49210013
         SR    RM,RM               CLEAR RM                             49280013
         L     RK,KTABLEX0         POINTER TO L = 0 ROW OF TABLE        49350013
         IC    RM,0(RK,RJ)         GET LO NO.                           49420013
         LA    RM,1(0,RM)          UP BY 1                              49490013
         STC   RM,0(RK,RJ)         STORE IT BACK                        49560013
         CL    RM,KMERGORD                                         3EF5 49630013
         BNE   ONONEPAS            BRANCH IF LO NO. NOT EQ MERGE ORDER  49700013
         LA    RE,1(0,RE)          SET L=L+1                       3EG5 49770013
         A     RH,KBYPEROW         UP POINTER TO NEW L ROW              49840013
         A     RI,KBYPEROW         UP POINTER TO NEW L-1 ROW            49910013
         B     ONONEPAS            BRANCH TO 'ONLY 1 MERGE PASS' RTN    49980013
         SPACE 2                                                        50050013
ONISHILO SR    RO,RO                                               3EE4 50120013
         SR    RP,RP                                                    50190013
         IC    RO,0(RJ,RH)         GET HI AT L                          50260013
         IC    RP,2(RJ,RI)         GET LO AT L-1                        50330013
         CR    RO,RP               ARE THEY EQUAL                       50400013
         BE    ONMTOPAS            GO TO MORE THAN 1 PASS ROUTINE       50470013
         LH    RM,0(RJ,RH)         GET HI AND HI NO. AT L          3EF4 50540013
         STH   RM,2(RJ,RH)         STORE IN LO AND LO NO. AT L          50610013
         SRL   RM,8                HI NO.=0                             50680013
         LA    RM,1(0,RM)          HI=HI+1                              50750013
         SLL   RM,8                POSITION                             50820013
         STH   RM,0(RJ,RH)         STORE AT HI AND HI NO. OF L          50890013
         LA    RE,1(0,RE)          L=L+1                           3EG4 50960013
         A     RH,KBYPEROW         UP L ROW POINTER                     51030013
         A     RI,KBYPEROW         UP L-1 ROW POINTER                   51100013
         LA    RM,10                                                    51170013
         CR    RE,RM               DOES L=10                       3EH4 51240013
         BE    ONMSG46A            GO PRINT MESSAGE AND ABORT           51310013
         SPACE 1                                                        51380013
         LA    RD,1(0,RD)          I=I+1                           3EH5 51450013
         CL    RD,KMERGORD         IS I NOW PAST LAST ENTRY             51520013
         BNH   ONSKIP2             BRANCH IF NO                         51590013
         SR    RD,RD               I=0                                  51660013
ONSKIP2  LR    RC,RD               SET J=I                              51730013
         B     ONONEPAS                                                 51800013
         SPACE 2                                                        51870013
ONMTOPAS OI    PPISW1+7,X'08'      SET MORE THAN 1 PASS BIT        3EJ4 51940013
         MVI   WSWITCHC,X'00'      CLEARED FOR ODD NUMBERED CONSECUTIVE 52010013
*                                    MERGE PASSES                  3EK4 52080013
         MVI   WSWITCHD,X'FF'      ANOTHER MERGE PASS TO FOLLOW IMMED.  52150013
         B     ONSETMO             GO SET UP TO MERGE                   52220013
         SPACE 2                                                        52290013
*   THIS ENTRY IS FROM THE WRITE ROUTINE REQUESTING A CHAIN ADDRESS.    52360013
*   RB CONTAINS THE ACTUAL AREA INCREMENT FOR THE BLOCK BEING WRITTEN.  52430013
         SPACE 1                                                        52500013
ONCHNADR L     RG,KFRTRKLT         LOAD TO ADR OF FTL ROW OF TABLE (-4) 52570013
         LR    RA,RO               SAVE RETURN REG                      52640013
         BAL   RK,ONGETTRK+8       GO GET AN ADDRESS                    52710013
         SPACE 1                                                        52780013
         LR    RO,RA               RESTORE RETURN REG                   52850013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    52920013
         L     RL,PPIWRT+4         LOAD BASE REG FOR WRITE MODULE       52990013
         BR    RO                  RETURN TO WRITE ROUTINE.        3FC2 53060013
*                                    ADDRESS IS IN PPIWKARE.            53130013
         SPACE 1                                                        53200013
*   THIS ENTRY IS FROM THE READ ROUTINE AT EOS. RB WILL CONTAIN THE     53270013
*   LOGICAL AREA INCREMENT. WE MUST DETERMINE IF ANOTHER MERGE PASS IS  53340013
*   TO FOLLOW AND IF SO WHETHER OR NOT ANOTHER READ CAN BE INITIATED    53410013
*   ON THIS AREA NOW. IF IT CAN WE WILL RETURN WITH RB=4 AND THE        53480013
*   ADDRESS TO BE READ IN PPIWKARE. OTHERWISE RB WILL BE ZERO.          53550013
         SPACE 1                                                        53620013
ONRDEOS  CLI   WSWITCHD,X'00'      WILL ANOTHER MERGE PASS FOLLOW  3FB4 53690013
         LM    RC,RI,WSAVE         LOAD MODULE REGISTERS                53760013
         BE    ONNOMO              BRANCH IF NO                         53830013
         CLI   WSWITCHC,X'00'      IS SWITCH C OFF                 3FC4 53900013
         BE    ONSWCOFF            BRANCH IF YES                        53970013
         LR    RM,RD               RM=I                            3FD4 54040013
         SLL   RM,2                TIMES 4                              54110013
         LA    RM,8(0,RM)          PLUS 8                               54180013
         CL    RM,KBYPEROW         IS RM BEYOND LAST ENTRY              54250013
         BNE   ONSKIP3             BRANCH IF NOT                        54320013
         LA    RM,4                SET TO FIRST ENTRY                   54390013
ONSKIP3  CR    RB,RM               DOES RB=AREA I+1                     54460013
         BE    ONNOMO              BRANCH IF YES (THIS IS THE AREA WE   54530013
*                                    ARE WRITING ON)                    54600013
ONDORBEI LR    RM,RD               RM=I                            3FE4 54670013
         SLL   RM,2                TIMES 4                              54740013
         LR    RO,RB               RO=LOGICAL INCREMENT                 54810013
         SH    RO,KFOUR            MINUS 4 (TABLE STARTS AT 0 NOT 4)    54880013
         CR    RM,RO               INCREMENT FOR I AREA                 54950013
         BE    ONRBEI              BRANCH IF YES                        55020013
         SR    RJ,RJ                                               3FF4 55090013
         A     RJ,0(RO,RH)         GET THIS ENTRY                       55160013
         BZ    ONNOMO              BRANCH IF IT IS NOT A REAL ONE       55230013
ONEXPEXT BAL   RK,ONEXPAND         GO EXPAND TO 8 BYTE ADDRESS     3FG4 55300013
         SPACE 1                                                        55370013
         MVC   PPIWKARE(8),PPIWKARE+128    MOVE TO WORK AREA            55440013
         STC   RB,PPIWKARE+1       INSERT LOGICAL AREA INCREMENT        55510013
         LA    RB,4                INDICATE READ POSSIBLE          3FG5 55580013
ONEXITRD L     RL,PPIRD+4                                          3FH5 55650013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    55720013
         BR    RL                  EXIT TO READ ROUTINE                 55790013
         SPACE 2                                                        55860013
ONSWCOFF LR    RM,RD               RM=I                            3FD5 55930013
         SLL   RM,2                TIMES 4                              56000013
         LTR   RM,RM               IS IT ZERO                           56070013
         BNZ   ONSKIP4             BRANCH IF NOT ZERO                   56140013
         LH    RM,KBPRLS4          SET TO LAST ENTRY IN ROW             56210013
ONSKIP4  CR    RM,RB               IS INCREMENT FOR I-1 AREA            56280013
         BE    ONNOMO              BRANCH IF EQUAL (THIS IS THE AREA    56350013
*                                    WE ARE WRITING ON)                 56420013
         B     ONDORBEI            GO SEE IF THIS IS AREA UNDER I       56490013
         SPACE 2                                                        56560013
ONRBEI   SR    RJ,RJ                                               3FE5 56630013
         A     RJ,0(RO,RI)         IS ADDRESS AT L-1 OF THIS INCRE REAL 56700013
         BZ    ONNOMO              BRANCH IF NOT                        56770013
         B     ONEXPEXT            GO EXPAND ADDRESS AND EXIT      3FF5 56840013
         SPACE 2                                                        56910013
ONNOMO   SR    RB,RB               INDICATE NO READ                3FH4 56980013
         B     ONEXITRD            GO EXIT TO READ                      57050013
         SPACE 2                                                        57120013
*   THE FOLLOWING ROUTINE WILL BE ENTERED ONLY ONCE. THAT TIME WILL BE  57190013
*   AFTER THE REAL END OF FILE HAS BEEN REACHED. SOME CODE IS OVERLAID  57260013
*   SO THAT WE DO NOT RETURN TO THE SORT PHASE.                         57330013
         SPACE 1                                                        57400013
ONRELEOF OI    PPISW1+7,X'08'      SET BIT 61 (ONLY MERGE PASSES)  3BB4 57470013
         MVC   ONNOEOF(4),KNOP     OVERLAY 'CLEAR MERGE BIT' INSTRUCT.  57540013
         MVC   ONONEPAS(4),KNOP    OVERLAY 'CLEAR MERGE BIT' INSTRUCT.  57610013
         MVC   ONSETMO(6),KNOP     OVERLAY 'SET MERGE ORDER'       3BC4 57680013
         SR    RO,RO                                                    57750013
         L     RP,WSEQTOTL                                              57820013
         D     RO,KMERGORD         DIVIDE TOTAL SEQS BY MERGE ORDER     57890013
         LTR   RO,RO               IS REMAINDER=0                       57960013
         BNZ   ONSKIP5             BRANCH IF NO                         58030013
         L     RO,KMERGORD         IF YES THIS IS A FULL MERGE          58100013
ONSKIP5  STH   RO,PPIMRGMX         SET MERGE ORDER FOR NEXT MERGE       58170013
         CLC   WSEQTOTL(4),KMERGORD  MORE THAN M SEQUENCES         3BD4 58240013
         BH    ONSETX              BRANCH IF YES                        58310013
         L     RF,KTABLEX          LOAD POINTER TO FIRST ROW       3BE4 58380013
         B     ONEQZERO+4          GO SET UP PPIENDAR AND EXIT          58450013
         SPACE                                                          58520013
ONSETX   L     RM,KMERGORD                                         3BB5 58590013
         SH    RM,PPIMRGMX         RM=NORMAL MERGE ORDER-THIS M.O.      58660013
         CLC   WSEQTOTL(4),KMSQURD   M SQUARED SEQUENCES YET       3BC5 58730013
         BH    ONSKIP6             BRANCH IF YES                        58800013
         AR    RD,RM               I=I+X                           3BD5 58870013
         CL    RD,KMERGORD         IS IT BEYOND END OF TABLE            58940013
         BNH   ONSKIP7             BRANCH IF NO                         59010013
         S     RD,KMERGORD         SUBTRACT MERGE ORDER            3BE5 59080013
         SH    RD,KONE             SUBTRACT ONE MORE                    59150013
         B     ONSKIP7             GO FINISH OVERLAY                    59220013
         SPACE 2                                                        59290013
ONSKIP6  SR    RC,RM               J=J-X                                59360013
         BNM   ONSKIP7             BRANCH IF J NOT NEGATIVE             59430013
         A     RC,KMERGORD         ADD MERGE ORDER                      59500013
         AH    RC,KONE             PLUS 1                               59570013
ONSKIP7  OI    ONOLYEOF+1,X'F0'    CHANGE INSTRUCTION TO BRANCH    3BF5 59640013
         MVC   ONEXTNET(4),ONSETSWM     OVERLAY CODE AT 3DH5       3BG5 59710013
         MVC   ONEXTNET+4(4),KOVERLAY                                   59780013
         B     ONONETIM            SORTING IS DONE-FINISH MERGES        59850013
         SPACE 2                                                        59920013
*   THIS ROUTINE IS ENTERED ONLY AFTER THE REAL INPUT END OF FILE WHEN  59990013
*   A SIMULATED MERGE PASS IS TO BE DONE. (THE TABLE IS UPDATED BUT NO  60060013
*   MERGING IS DONE)                                                    60130013
         SPACE 1                                                        60200013
ONAFTEOF LA    RC,1(0,RC)          J=J+1                           3CJ3 60270013
         CL    RC,KMERGORD         IS J BEYOND END OF TABLE             60340013
         BNH   ONSKIP8             BRANCH IF NO                         60410013
         SR    RC,RC               SET J=0                              60480013
ONSKIP8  LH    RK,KBPRLS4                                          3CK3 60550013
         LH    RM,0(RK,RH)         GET HI NO. AT L                      60620013
         LA    RM,1(0,RM)          ADD 1                                60690013
         STH   RM,0(RK,RH)         STORE IT BACK                        60760013
         MVI   WSWITCHC,X'00'      TURN OFF SWITCH C               3CK2 60830013
         B     ONMTMSQ             MERGE PASS SIMULATED-GO BACK AND     60900013
*                                    SEE IF WE HAVE M-1 SEQUENCES AT    60970013
*                                    THIS LEVEL OF THE TABLE NOW        61040013
         SPACE 2                                                        61110013
*   THIS SUBROUTINE GETS A TRACK FROM THE FREE TRACK LIST INDICATED BY  61180013
*   REGISTER RB. WHEN IT RETURNS THE ADDRESS IS IN THE FIRST 8 BYTES OF 61250013
*   PPIWKARE. IF THE INCREMENT IN RB IS IN THE FORM 0,1,2 ETC THE       61320013
*   SUBROUTINE IS ENTERED FROM THE TOP. IF IT IS IN THE FORM 4,8,12 ETC 61390013
*   THE SUBROUTINE IS ENTERED AT +8 (ONNOTMT). IF NO TRACKS ARE AVAIL-  61460013
*   ABLE FOR THE INDICATED AREA A SEARCH IS MADE FOR THE LARGEST        61530013
*   REMAINING SEGMENT AND A TRACK IS TAKEN FROM THAT AREA LIST.         61600013
         SPACE 1                                                        61670013
ONGETTRK SLL   RB,2                                                3GC2 61740013
         LA    RB,4(0,RB)          CHANGE INCRE FROM 0,1,2 ETC TO 4,8   61810013
ONNOTMT  SR    RJ,RJ                                                    61880013
         ST    RJ,PPIWKARE                                              61950013
         ST    RJ,PPIWKARE+4       ZERO OUT PPIWKARE (FIRST 8 BYTES)    62020013
         IC    RJ,0(RB,RG)         GET NUMBER OF ENTRIES THIS AREA 3GD2 62090013
         L     RM,0(RB,RG)         RM IS POINTER TO FIRST ENTRY         62160013
         LTR   RJ,RJ               ARE THERE ANY ENTRIES           3GE2 62230013
         BZ    ONFNDBIG            BRANCH IF NO                         62300013
         LH    RO,0(0,RM)          GET STARTING ADDRESS            3GF2 62370013
         STC   RO,PPIWKARE+6       STORE TRACK NUMBER                   62440013
         SRL   RO,8                POSITION CYLINDER NUMBER             62510013
         STC   RO,PPIWKARE+4       STORE CYLINDER NUMBER                62580013
         STC   RB,PPIWKARE         STORE REAL INCREMENT                 62650013
         MVI   PPIWKARE+7,X'01'    INSERT 'RECORD 1'                    62720013
         SR    RO,RO                                               3GG2 62790013
         IC    RO,1(0,RM)          GET TRACK NO.                        62860013
         LA    RO,1(0,RO)          UP BY 1                              62930013
         CH    RO,KMXTRK           WAS THAT THE LAST TRACK THIS CYLND   63000013
         BH    ONSKIP9             BRANCH IF YES                        63070013
         STC   RO,1(0,RM)          STORE NEW TRACK ADDRESS              63140013
         LH    RO,0(0,RM)          LOAD STARTING ADDRESS                63210013
         B     ONENTMT             GO CHECK IF THIS ENTRY NOW EMPTY     63280013
         SPACE 2                                                        63350013
ONSKIP9  LH    RO,0(0,RM)          GET CYLINDER AND TRACK               63420013
         SRL   RO,8                SET TRACK TO 0                       63490013
         LA    RO,1(0,RO)          UP CYLINDER BY 1                     63560013
         SLL   RO,8                POSITION                             63630013
         STH   RO,0(0,RM)          STORE IT ON FTL LIST                 63700013
ONENTMT  LH    RP,2(0,RM)          GET ENDING ADDRESS              3GH2 63770013
         N     RO,K00FF            CLEAR TWO HIGH ORDER BYTES           63840013
         N     RP,K00FF            CLEAR TWO HIGH ORDER BYTES           63910013
         CR    RO,RP               IS STARTING ADR LARGER THAN ENDING   63980013
         BNH   ONRETURN+4          BRANCH IF NO                         64050013
         BCT   RJ,ONMVFTL          DECRE CNT-BRANCH IF NOT 0       3GH3 64120013
ONRETURN STC   RJ,0(RB,RG)         STORE COUNT                          64190013
         BR    RK                  RETURN                          3GJ2 64260013
         SPACE 2                                                        64330013
ONMVFTL  LR    RO,RJ               PUT COUNT IN RO                 3GJ3 64400013
ONLOOP6  LA    RP,4(0,RM)          RP IS POINTER TO ENTRY ABOVE RM      64470013
         CLI   0(RP),X'FF'         IS THIS A CHAIN ADDRESS              64540013
         BE    ONTHISCH            BRANCH IF YES                        64610013
ONLOOP7  MVC   0(4,RM),0(RP)       MOVE ENTRY UP 1 PLACE                64680013
         BCT   RO,ONSKIP10         BRANCH IF NOT DONE                   64750013
         B     ONRETURN            GO RETURN                            64820013
         SPACE 2                                                        64890013
ONTHSCHN STM   RC,RE,WSAVE6        KEEP REGISTER CONTENTS        A27990 64898000
         SR    RC,RC               SUBTRACT REGISTERS            A27990 64906000
         SR    RD,RD               FOR DIVIDEND                  A27990 64914000
         LR    RD,RJ               LOAD NO ENTRIES               A27990 64922000
         LA    RE,9                NINE FOR DIVIDEND             A27990 64930000
         DR    RC,RE               CHECK IS SEGMENT              A27990 64938000
         CH    RC,KONE             IN POOL CAN BE RELEASED       A27990 64946000
         BNE   ONSKIP21            NO, BR BACK                   A27990 64954000
         CH    RO,KONE             CHCK IF SEGMENT CAN BE RELEAS A27990 64962000
         BNE   ONSKIP21            NO, BR BACK                   A27990 64970000
         LA    RP,4(0,RP)          RP POINTER TO NEXT LIST ENTRY A27990 64978000
         LR    RC,RM               KEEP ADDR                     A27990 64986000
         L     RE,KFPPTR           LOAD ADDR TO FREPOOL LIST     A27990 64994000
         AH    RE,KFOUR            UPDATE POINTER                A27990 65002000
         ST    RE,KFPPTR           RESTORE UPDATED ADDR          A27990 65010000
         L     RC,0(0,RC)          LOAD ADDR TO NEXT ENTRY       A27990 65018000
         ST    RC,0(0,RE)          MOVE ENTRY UP 1 PLACE         A27990 65026000
         IC    RE,KFPPTR           UPDATE NO ENTRIES             A27990 65034000
         AH    RE,KONE             BY ONE                        A27990 65042000
         STC   RE,KFPPTR           AND STORE IT BACK             A27990 65050000
         LM    RC,RE,WSAVE6        RESTORE WORK REGISTERS        A27990 65058000
         B     ONLOOP7             BRANCH BACK                   A27990 65066000
ONSKIP21 LM    RC,RE,WSAVE6        RESTORE WORK REG              A27990 65074000
         L     RM,0(0,RM)          GET ADDR FROM CHAIN ADDR      A27990 65082000
         B     ONLOOP6             GO UPDATE OTHER POINTER       A27990 65090000
         SPACE 2                                                        65100013
ONTHISCH L     RP,0(0,RP)          GET ADDRESS FROM CHAIN ADDRESS       65170013
         B     ONLOOP7             GO MOVE ENTRY UP 1 PLACE             65240013
         SPACE 2                                                        65310013
ONSKIP10 LA    RM,4(0,RM)          UPDATE POINTER TO NEXT ENTRY         65380013
         CLI   0(RM),X'FF'         IS THIS A CHAIN ADDRESS              65450013
         BE    ONTHSCHN            BRANCH IF YES                        65520013
         B     ONLOOP6             GO UPDATE OTHER POINTER              65590013
         SPACE 2                                                        65660013
ONFNDBIG LA    RB,4                SET RB TO GET FIRST LIST ADR    3GE3 65730013
         SR    RP,RP               CLEAR FOR LARGEST AREA               65800013
ONLOOP8  L     RO,0(RB,RG)         RO=ADDRESS OF LIST                   65870013
         LH    RM,2(0,RO)          ENDING ADDRESS                       65940013
         N     RM,K00FF            CLEAR TWO HIGH ORDER BYTES           66010013
         LH    RJ,0(0,RO)          STARTING ADDRESS                     66080013
         N     RJ,K00FF            CLEAR TWO HIGH ORDER BYTES           66150013
         SR    RM,RJ               END ADDRESS MINUS START ADDRESS      66220013
         BM    ONSKIP11            BRANCH IF EMPTY                      66290013
         OI    WSWITCHB,X'FF'      INDICATE A TRACK AVAILABLE           66360013
         CR    RM,RP               NEWEST AREA THE LARGEST SO FAR       66430013
         BL    ONSKIP11            BRANCH IF NO                         66500013
         LR    RP,RM               SAVE ITS SIZE                        66570013
         STH   RB,WSAVE2           SAVE INCREMENT TO IT                 66640013
ONSKIP11 LA    RB,4(0,RB)          UP POINTER TO NEXT LIST ADDRESS      66710013
         CL    RB,KBYPEROW         ARE WE DONE CHECKING                 66780013
         BNE   ONLOOP8             BRANCH IF NOT                        66850013
         CLI   WSWITCHB,X'00'      ANY TRACKS AVAILABLE                 66920013
         BE    ONMSG46A            BRANCH TO PRINT AND ABORT IF NO      66990013
         MVI   WSWITCHB,X'00'      TURN SWITCH OFF FOR NEXT TIME        67060013
         LH    RB,WSAVE2           GET INCREMENT TO LARGEST AREA        67130013
         B     ONNOTMT             GO GET AN ADDRESS FROM THIS AREA     67200013
         SPACE 2                                                        67270013
*   THE FOLLOWING ROUTINE IS ENTERED ONLY WHEN THE READ ROUTINE HAS     67340013
*   FINISHED READING A TRACK. THE TRACK ADDRESS WILL BE IN PPIWKARE.    67410013
*   THIS ROUTINE WILL RESTORE THAT ADDRESS TO THE FREE TRACK LIST AND   67480013
*   RETURN TO THE READ ROUTINE.                                         67550013
         SPACE 1                                                        67620013
ONRDTREL L     RG,KFRTRKLT         LOAD TO ADR OF LAST ROW-4       3HC2 67690013
         SR    RB,RB                                                    67760013
         SR    RJ,RJ                                                    67830013
         IC    RB,PPIWKARE         GET INCREMENT                        67900013
         IC    RJ,0(RB,RG)         GET NUMBER OF ENTRIES                67970013
         L     RM,0(RB,RG)         GET ADDRESS OF FIRST ENTRY           68040013
         MVC   WSAVE2(1),PPIWKARE+4     GET CYLINDER NUMBER             68110013
         MVC   WSAVE2+1(1),PPIWKARE+6   GET TRACK NUMBER                68180013
         LTR   RJ,RJ               ANY ENTRIES                     3HD2 68250013
         BZ    ONNOENTS            BRANCH IF NO                         68320013
ONLOOP10 CLC   3(1,RM),KMXTRK+1    IS ENDING TRACK LAST IN CYL.    3HE2 68390013
         BE    ONLSTTRK            BRANCH IF YES                        68460013
         LH    RP,2(0,RM)          GET END ADDRESS FOR THIS ENTRY       68530013
ONLOOP9  LH    RK,WSAVE2           LOAD INTO RK                         68600013
         SR    RK,RP               SUBTRACT END ADDRESS FOR THIS ENTRY  68670013
         BCT   RK,ONDECRJ          BRANCH UNLESS DIFFERENCE IS 1        68740013
         LH    RK,WSAVE2           RELOAD RELEASE ADDRESS          3HE3 68810013
         STH   RK,2(0,RM)          STORE AS NEW END ADDRESS             68880013
ONOUTRD  L     RL,PPIRD+4                                          3HE4 68950013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    69020013
         BR    RO                  RETURN TO READ ROUTINE               69090013
         SPACE 2                                                        69160013
ONLSTTRK LH    RP,2(0,RM)          GET END ADDRESS FOR THIS ENTRY       69230013
         AH    RP,KMXTRKCP         ADD COMPLEMENT OF MAXIMUM TRACK      69300013
         B     ONLOOP9             GO SEE IF REL ADR IS ADJACENT        69370013
         SPACE 2                                                        69440013
ONDECRJ  LA    RM,4(0,RM)          UP POINTER TO NEXT ENTRY             69510013
         BCT   RJ,ONSKIP12         DECR RJ - BRANCH IF NOT 0            69580013
         B     ONNEWENT            BRANCH TO NEW ENTRY ROUTINE     3HG2 69650013
         SPACE 2                                                        69720013
ONSKIP12 CLI   0(RM),X'FF'         IS THIS A CHAIN ADDRESS              69790013
         BNE   ONLOOP10            BRANCH IF NO                         69860013
*                                                                  3HF1 69930013
         L     RM,0(0,RM)          USING CHAIN ADR GET ADR OF NEXT ENT  70000013
         B     ONLOOP10            GO CONTINUE SEARCH                   70070013
         SPACE 2                                                        70140013
ONNOENTS MVC   0(1,RM),PPIWKARE+4  MAKE THIS THE STARTING ADDRESS       70210013
         MVC   1(1,RM),PPIWKARE+6    FOR THIS ENTRY                     70280013
         MVC   2(2,RM),0(RM)       ALSO THE ENDING ADDRESS              70350013
         IC    RJ,0(RB,RG)         GET NUMBER OF ENTRIES           3HD4 70420013
         LA    RJ,1(0,RJ)          UP IT BY 1                           70490013
         STC   RJ,0(RB,RG)         STORE IT BACK                        70560013
         B     ONOUTRD             GO EXIT TO READ                      70630013
         SPACE 2                                                        70700013
ONNEWENT SR    RE,RE                                               3HH2 70770013
         SR    RF,RF               CLEAR REGS FOR DIVIDEND              70840013
         IC    RF,0(RB,RG)         INSERT NUMBER OF ENTRIES             70910013
         CH    RF,KONE             IS THERE ONLY ONE ENTRY              70980013
         BE    ONNOENTS            BRANCH IF YES                        71050013
         LA    RH,9                                                     71120013
         DR    RE,RH               DIVIDE BY 9                          71190013
         CH    RE,KONE             IS REMAINDER=1                  3HJ2 71260013
         BNE   ONNOENTS            BRANCH IF NO                         71330013
         SPACE 1                                                        71400013
*   THE FOLLOWING CODE IS ENTERED IF A SEGMENT (40 BYTES) OF FREE       71470013
*   TRACK LIST IS FILLED AND MORE IS NEEDED. IT IS GOTTEN FROM A POOL   71540013
*   AND THE SEGMENTS ARE CHAINED TOGETHER.                              71610013
         SPACE 1                                                        71680013
         SR    RE,RE                                               3HK2 71750013
         AH    RE,KPOOLSZ          ANYTHING LEFT IN POOL                71820013
         BZ    ONSKIP16            BRANCH IF NO                  A27990 71890000
         L     RF,KPOOL            GET ADDRESS OF POOL             3HF4 71960013
         LA    RH,40(0,RF)         UP IT BY 40                          72030013
         ST    RH,KPOOL            STORE NEW ADDRESS BACK               72100013
         SH    RE,KFORTY           SUBTRACT 40 FROM AMOUNT REMAINING    72170013
         STH   RE,KPOOLSZ          STORE IT BACK                        72240013
ONSKIP17 SH    RM,KFOUR            MOVE POINTR BACK TO LST ENT   A27990 72310000
         MVC   0(4,RF),0(RM)       MOVE LAST ENTRY TO NEW SEGMENT  3HG4 72380013
         ST    RF,0(0,RM)          INSERT CHAIN ADDRESS                 72450013
         MVI   0(RM),X'FF'         FLAG IT AS A CHAIN ADDRESS           72520013
         LA    RM,4(0,RF)          SET ENTRY POINTER TO NEW SEG.+4      72590013
         B     ONNOENTS            GO INSERT NEW ENTRY                  72660013
ONSKIP16 SR    RE,RE                                             A27990 72665000
         IC    RE,KFPPTR           ANY ENTRIES IN FREE POOL      A27990 72670000
         CH    RE,KZERO            LIST                          A27990 72675000
         BE    ONMSG46A            NO SORT CAPACITY EXCEEDED     A27990 72680000
         SH    RE,KONE             DECREASE ENTRY BY ONE         A27990 72685000
         L     RF,KFPPTR           ADDR TO FREE POOL LIST        A27990 72690000
         L     RH,KFPPTR           ADDR TO FREE POOL LIST        A27990 72695000
         SH    RH,KFOUR            DECREMENT ADDR BY FOUR        A27990 72700000
         ST    RH,KFPPTR           RESTORE UPDATED ADDR          A27990 72705000
         STC   RE,KFPPTR           RESTORE UPDATED ENTRY         A27990 72710000
         L     RF,0(0,RF)          POINT TO POOL                 A27990 72715000
         B     ONSKIP17            BRANCH BACK                   A27990 72720000
         SPACE 2                                                        72730013
*   THE FOLLOWING SUBROUTINE IS ENTERED EACH TIME THAT A WRITE EOS      72800013
*   CONDITION COMES UP. IT COMBINES ADJACENT SEGMENTS ON A FREE TRACK   72870013
*   LIST. IF WE ARE SORTING ONLY THE LIST FOR THE AREA WE WERE WRITING  72940013
*   ON IS CONSIDERED. IF WE ARE MERGING ALL LISTS ARE CONSIDERED. EACH  73010013
*   TIME WE FINISH A LIST WE BRANCH TO ANOTHER SUBROUTINE WHICH         73080013
*   REORDERS THE LIST BY SIZE OF SEGMENT WITH THE LARGEST SEGMENT       73150013
*   BEING PUT AT THE TOP OF THE LIST.                                   73220013
         SPACE 1                                                        73290013
ONREORD  STM   RC,RF,WSAVE4        SAVE REGISTERS                       73360013
         TM    PPISW1+2,X'08'      ARE WE MERGING                  3JB1 73430013
         BNO   ONSOTING            BRANCH IF SORTING                    73500013
         ST    RK,WSAVE3           SAVE RETURN REGISTER            3JB2 73570013
         LA    RB,4                SET RB TO FIRST AREA                 73640013
ONLOOP11 BAL   RK,ONSOTING         LINK TO DO THIS LIST            3JB3 73710013
         SPACE 2                                                        73780013
         CH    RB,KBPRLS4          HAVE WE FINISHED ALL LISTS      3JC3 73850013
         BE    ONRESTLK            BRANCH IF YES                        73920013
         LA    RB,4(0,RB)          UP POINTER TO NEXT LIST         3JC2 73990013
         B     ONLOOP11            GO DO NEXT LIST                      74060013
         SPACE 2                                                        74130013
ONRESTLK L     RK,WSAVE3           RESTORE RETURN REGISTER         3JC4 74200013
ONGOBACK LM    RC,RF,WSAVE4        RESTORE REGISTERS                    74270013
         BR    RK                  RETURN                               74340013
         SPACE 2                                                        74410013
ONSOTING SR    RC,RC                                               3JC1 74480013
         IC    RC,0(RB,RG)         RC SET TO NO. OF ENTRIES             74550013
         L     RJ,0(RB,RG)         RJ IS POINTER TO FIRST ENTRY         74620013
         LA    RM,4(0,RJ)          RM IS POINTER TO SECOND ENTRY        74690013
         LR    RD,RC                                               3JD1 74760013
         SH    RD,KONE             Y=X-1                                74830013
         CH    RC,KONE             DOES X=0 OR 1                   3JE1 74900013
         BNH   ONGOBACK            GO RETURN IF YES                3JE2 74970013
ONLOOP12 SR    RO,RO                                               3JF1 75040013
         ST    RO,WSAVE5           CLEAR SAVE AREA                      75110013
         MVC   WSAVE5+2(2),2(RM)   GET END ADDRESS AT POINTER 2         75180013
         L     RO,WSAVE5           LOAD IT                              75250013
         CLC   WSAVE5+3(1),KMXTRK+1  IS TRACK ADDRESS LAST IN CYLINDER  75320013
         BNE   ONSKIP13            BRANCH IF NO                         75390013
         AH    RO,KMXTRKCP         ADD COMPLEMENT OF MAXIMUM TRK NO.    75460013
ONSKIP13 MVC   WSAVE5+2(2),0(RJ)   GET START ADDRESS AT POINTER 1       75530013
         L     RP,WSAVE5           LOAD IT                              75600013
         SR    RP,RO               SUBTRACT END FROM START              75670013
         BCT   RP,ONNOTADJ         IF ADJACENT DON'T BRANCH             75740013
         MVC   0(2,RJ),0(RM)       MOVE START ADR FROM PTR 2 TO 1  3JF2 75810013
         B     ONCOMBED            BRANCH OUT-THESE HAVE BEEN COMBINED  75880013
         SPACE 2                                                        75950013
ONNOTADJ MVC   WSAVE5+2(2),2(RJ)   GET END ADDRESS AT POINTER 1         76020013
         L     RO,WSAVE5           LOAD IT                              76090013
         CLC   WSAVE5+3(1),KMXTRK+1  IS TRACK ADR LAST IN CYLINDER      76160013
         BNE   ONSKIP14            BRANCH IF NO                         76230013
         AH    RO,KMXTRKCP         ADD COMPLEMENT OF MAXIMUM TRACK NO.  76300013
ONSKIP14 MVC   WSAVE5+2(2),0(RM)   GET START ADR AT POINTER 2           76370013
         L     RP,WSAVE5           LOAD IT                              76440013
         SR    RP,RO               SUBTRACT END FROM START ADDRESS      76510013
         BCT   RP,ONNOAGIN         BRANCH IF NOT ADJACENT               76580013
         MVC   2(2,RJ),2(RM)       MOVE END ADR FROM PTR 2 TO PTR 1     76650013
         B     ONCOMBED            BRANCH OUT-THESE HAVE BEEN COMBINED  76720013
         SPACE 2                                                        76790013
ONNOAGIN LA    RM,4(0,RM)          UPDATE POINTER 2                3JG1 76860013
         SH    RD,KONE             DECREMENT Y                          76930013
         BZ    ONISXLES            BRANCH IF Y=0                   3JH1 77000013
ONLOOP14 CLI   0(RM),X'FF'         CHK FOR CHAIN ADR AT POINTER 2  3JJ1 77070013
         BNE   ONLOOP12            BRANCH IF NOT                        77140013
         L     RM,0(0,RM)          GET ADDRESS OF NEXT ENTRY       3JK1 77210013
         B     ONLOOP12            GO CHECK ANOTHER PAIR OF ENTRIES     77280013
         SPACE 2                                                        77350013
ONCOMBED SR    RF,RF                                               3JG2 77420013
         IC    RF,0(RB,RG)         GET NUMBER OF ENTRIES                77490013
         SH    RF,KONE             DECREMENT BY 1                       77560013
         STC   RF,0(RB,RG)         STORE IT BACK                        77630013
         BCT   RC,*+4              DECREMENT X                          77700013
         LR    RE,RD               SET Z=Y                         3JH2 77770013
ONLOOP13 SH    RE,KONE             MINUS 1                              77840013
         BZ    ONSKIP18            GO REORDER FTL & POOL         A27990 77910000
         LA    RF,4(0,RM)          SET POINTER 3=POINTER 2+4       3JD4 77980013
         CLI   0(RF),X'FF'         CHK FOR CHAIN ADR AT POINTER 3  3JE4 78050013
         BNE   ONSKIP15            BRANCH IF NOT                        78120013
         L     RF,0(0,RF)          GET ADDRESS OF NEXT ENTRY       3JF4 78190013
ONSKIP15 MVC   0(4,RM),0(RF)       MOVE ENTRY FROM PTR 3 TO PTR 2  3JF5 78260013
         LR    RM,RF               SET POINTE 2=POINTER 3          3JG5 78330013
         B     ONLOOP13            GO CONTINUE MOVING                   78400013
         SPACE 2                                                        78470013
ONISXLES SH    RC,KTWO             X=X-2                           3JD3 78540013
         BC    12,ONCHKENT         BRANCH IF X NOW 0 OR NEGATIVE        78610013
         AH    RC,KONE             X=X+1                           3JE3 78680013
         LA    RJ,4(0,RJ)          UPDATE POINTER 1                3JF3 78750013
         CLI   0(RJ),X'FF'         CHK FOR CHAIN ADR AT POINTER 1  3JG3 78820013
         BNE   ONMOVOVR            BRANCH IF NO                         78890013
         L     RJ,0(0,RJ)          GET ADR OF NEXT ENTRY           3JG4 78960013
ONMOVOVR LR    RM,RJ               SET POINTER 2 = POINTER 1       3JH4 79030013
         LR    RD,RC               SET Y=X                              79100013
         B     ONNOAGIN            GO CONTINUE SEARCH                   79170013
ONSKIP18 STM   RC,RE,WSAVE6        KEEP MAINLINE REG.            A27990 79172000
         SR    RC,RC               CLEAR REG                     A27990 79174000
         SR    RD,RD               FOR DIVIDEND                  A27990 79176000
         IC    RD,0(RB,RG)         GET NO ENTRIES                A27990 79178000
         CH    RD,KONE             ONLY ONE ENTRY                A27990 79180000
         BE    ONSKIP19            YES, BRANCH OUT               A27990 79182000
         LA    RE,9                BY DIVIDING NO ENTRIES BY     A27990 79184000
         DR    RC,RE               NINE NO FREE TRK SEGMENTS     A27990 79186000
         CH    RC,KONE             CAN BE DETERMINED             A27990 79188000
         BNE   ONSKIP19            BRANCH IF MORE THAN ONE SEGM  A27990 79190000
         L     RF,0(RB,RG)         LOAD STARTINGADDR             A27990 79192000
         SR    RC,RC               ZERO REG                      A27990 79194000
         IC    RC,0(RB,RG)         INSERT NO ENTRIES             A27990 79196000
ONLOOPZZ BCT   RC,ONSKIPXX         SCAN FTL                      A27990 79198000
         B     ONSKIP19            BRANCH OUT ENTIRE ENTRY DONE  A27990 79200000
ONSKIPXX LA    RF,4(0,RF)          POINT TO NEXT ENTRY           A27990 79202000
         CLI   0(RF),X'FF'         CHAIN ADDR AT RF              A27990 79204000
         BNE   ONLOOPZZ            NO, LOOP BACK                 A27990 79206000
         CH    RC,KONE             LAST ENTRY                    A27990 79208000
         BNE   ONLOOPZZ            NO, CONTINUE SEARCH           A27990 79210000
         LR    RD,RF               KEEP POINTER REG.             A27990 79212000
         L     RF,0(0,RF)          GET NEW LIST ADDR             A27990 79214000
         ST    RF,KCHAIN           KEEP CHAIN ADDR               A27990 79216000
         L     RE,KFPPTR           LOAD POINTER TO FREE POOL     A27990 79218000
         AH    RE,KFOUR            UP IT BY FOUR                 A27990 79220000
         ST    RE,KFPPTR           RESTORE UPDATED ADDR          A27990 79222000
         MVC   0(4,RE),KCHAIN      MOVE POOL ADDR IN LIST        A27990 79224000
         IC    RE,KFPPTR           UPDATE TOTAL NO OF            A27990 79226000
         AH    RE,KONE             ENTRIES IN LIST               A27990 79228000
         STC   RE,KFPPTR                                         A27990 79230000
         MVC   0(4,RD),0(RF)       MOVE ENTRY                    A27990 79232000
         B     ONLOOPZZ            BRANCH BACK                   A27990 79234000
ONSKIP19 LM    RC,RE,WSAVE6        RESTORE MAINL PGM REGISTER    A27990 79236000
         B     ONMOVOVR            BRANCH OUT                    A27990 79238000
         SPACE 2                                                        79240013
ONCHKENT SR    RP,RP                                                    79310013
         IC    RP,0(RB,RG)         GET NUMBER OF ENTRIES                79380013
         BCT   RP,ONORDLST         BRANCH IF GREATER THAN 0             79450013
         B     ONGOBACK            GO TO RETURN                         79520013
ONORDLST L     RP,0(RB,RG)         POINTER TO INITIAL ENTRY(PTR 1) 3KC2 79590013
         LA    RO,4(0,RP)          POINTER TO NEXT ENTRY(PTR 2)         79660013
         SR    RM,RM                                                    79730013
         ST    RM,WSAVE5           CLEAR SUBROUTINE WORK AREA TO ZERO   79800013
         IC    RM,0(RB,RG)         NO. OF ENTRIES IN THIS LIST.         79870013
         LR    RJ,RM                                                    79940013
         BCTR  RJ,0                ESTABLISH COUNTER(ENTRIES - 1)  3KD2 80010013
         SPACE 1                                                        80080013
ONDTRARA MVC   WSAVE5+2(2),0(RP)   EXPAND START CCTT AT PTR1 TO    3KE2 80150013
*                                  FULLWORD.                            80220013
         L     RF,WSAVE5           GET START CCTT.                      80290013
         MVC   WSAVE5+2(2),2(RP)   EXPAND END CCTT TO FULLWORD.         80360013
         CLC   WSAVE5+2(1),0(RP)   AREA START AND END ON SAME CYLN...   80430013
         BE    ONSUB1              -YES, BYPASS ADDITION OF CONSTANT.   80500013
         SPACE 1                                                        80570013
         AH    RF,KMXTRKCP         -NO, ADD CONSTANT TO START CCTT.     80640013
ONSUB1   L     RE,WSAVE5           GET EXPANDED CCTT AT PTR1.           80710013
         SR    RE,RF               AREA AT PTR1.                        80780013
         EX    RE,ONORDCMP         TEST DIFFERENCE FOR FORM...          80850013
         BC    10,ONSUB1A          -ANS CORRECT(CYL-TRK FORM), TAKE     80920013
*                                   .EQ. OR .GT. BRANCH.                80990013
         AH    RE,KMXTRKCP         -ANS IN TOTAL TRACKS,CHANGE TO       81060013
*                                   CYLN-TRK FORM                       81130013
         SPACE 1                                                        81200013
ONSUB1A  MVC   WSAVE5+2(2),0(RO)   EXPAND START C/T OF NEXT ENTRY(PTR2) 81270013
*                                  (PTR2) TO FULLWORD.                  81340013
         L     RF,WSAVE5           GET START CCTT.                      81410013
         MVC   WSAVE5+2(2),2(RO)   EXPAND PTR2 END CCTT TO FULLWORD.    81480013
         CLC   WSAVE5+2(1),0(RO)   AREA START AND END ON SAME CYLN...   81550013
         BE    ONSUB2              -YES                                 81620013
         SPACE 1                                                        81690013
         AH    RF,KMXTRKCP         -NO                                  81760013
ONSUB2   L     RC,WSAVE5           GET END CCTT AT PTR2.                81830013
         SR    RC,RF               AREA AT PTR2.                        81900013
         EX    RC,ONORDCMP         TEST DIFFERENCE FOR FORM...          81970013
         BC    10,ONSUB2A          -ANS CORRECT(CYL-TRK FORM), TAKE     82040013
*                                   .EQ. OR .GT. BRANCH.                82110013
         AH    RC,KMXTRKCP         -ANS IN TOTAL TRACKS,CHANGE TO       82180013
*                                   CYLN-TRK FORM                       82250013
ONSUB2A  CR    RE,RC               PTR1 AREA .EQ. OR .GT. PTR2 AREA...  82320013
         BC    10,ONSUB3           YES, TRY NEXT ENTRY IN LIST.         82390013
         SPACE 1                                                        82460013
         L     RD,0(0,RP)          NO, SWAP PTR1 AND PTR2 ENTRIES. 3KE3 82530013
         MVC   0(4,RP),0(RO)                                            82600013
         ST    RD,0(0,RO)                                               82670013
ONSUB3   LA    RO,4(0,RO)          INCR PTR2 FOR NEXT ENTRY.       3KF2 82740013
         BCT   RJ,ONSUB4           THIS PASS THRU LIST DONE...     3KG2 82810013
         B     ONSUB5              YES, GO SEE IF ENTIRE LIST DONE      82880013
         SPACE 2                                                        82950013
ONSUB4   TM    0(RO),X'FF'         CHAIN ADDRESS AT PTR2...        3KH2 83020013
         BNO   ONDTRARA            -NO, DETERMINE AREA OF NEXT ENTRY.   83090013
         SPACE 1                                                        83160013
         L     RO,0(0,RO)          -YES, UPDT PTR2 FOR CHAIN LIST. 3KJ2 83230013
         B     ONDTRARA             COMPUTE AREA OF CHAIN LIST ENTRY.   83300013
         SPACE 2                                                        83370013
ONSUB5   ST    RM,WSAVE5                                           3KD4 83440013
         CLI   WSAVE5+3,X'03'      ALL ENTRIES ORDERED...               83510013
         BL    ONRETRN             -YES, GO SET UP FOR MAINPROG RETURN  83580013
         SPACE 2                                                        83650013
         BCTR  RM,0                -NO, DECR LIST ENTRIES BY ONE   3KE4 83720013
         LR    RJ,RM                                                    83790013
         BCTR  RJ,0                DECR PASS-THRU-LIST CTR BY 1.        83860013
         SPACE 1                                                        83930013
         LA    RP,4(0,RP)          UPDATE PTR1 TO NEXT ENTRY.      3KF4 84000013
         TM    0(RP),X'FF'         IS PTR1 ENTRY A CHAIN ADDR...   3KG4 84070013
         BNO   ONSUB6              -NO                                  84140013
         SPACE 1                                                        84210013
         L     RP,0(0,RP)          -YES, UPDT PTR1 TO CHAIN  LIST  3KH4 84280013
*                                   ENTRY                               84350013
ONSUB6   LA    RO,4(0,RP)          SET PTR2 EQUAL TO PTR1+4             84420013
         B     ONSUB4              GO SEE IF PTR2 IS A CHAIN ADDRESS.   84490013
         SPACE 2                                                        84560013
ONRETRN  LM    RC,RF,WSAVE4        RESET MAINPROG REGISTERS        3KD5 84630013
         BR    RK                  RETURN TO MAINPROG.                  84700013
         SPACE 2                                                        84770013
* RECORD COUNT SUBROUTINE                                               84840013
         SPACE 1                                                        84910013
ONRCDCNT L     RJ,PPICOUNT         DETERMINE NO. INPUT RECORDS     3LC2 84980013
         A     RJ,PPIINSCT         -ADD RECORDS INSERTED AND,      3LD2 85050013
         S     RJ,PPIDELCT         -SUBTRACT RECORDS DELETED.           85120013
         SPACE 1                                                        85190013
         L     RP,PPIUNTCT         GET POINTER TO RCD/UNIT COUNT TABLE  85260013
         LA    RP,4(RP)                                                 85330013
         LH    RM,PPINDSKA         GET NUMBER OF DISK AREAS.       3LE2 85400013
         SR    RO,RO                                               3LF2 85470013
ONRCDTOT A     RO,0(RP)            SUM RECORDS FROM WORK AREAS.         85540013
         LA    RP,4(RP)            INCR. FOR NEXT WORK AREA RCD CNT.    85610013
         BCT   RM,ONRCDTOT         FALL THRU WHEN ALL AREAS TOTALED.    85680013
         SPACE 1                                                        85750013
         TM    PPISW1+3,X'01'      HAS QSAM REACHED END OF FILE... 3LG2 85820013
         BZ    ONFLSHRC            -NO, TAKE THE BRANCH                 85890013
         SPACE 1                                                        85960013
         TM    PPISW1+7,X'80'      -YES, HAS USER REACHED EOF...        86030013
         BO    ONRCDCMP             -YES, GO CHECK RECORD COUNTS        86100013
         SPACE 1                                                        86170013
         B     ONSERT               -NO, QSAM HAS BUT USER HASN'T       86240013
         SPACE 2                                                        86310013
         SPACE 1                                                        86380013
ONFLSHRC BCTR  RJ,0                SUBTRACT 1 FOR RECORD HELD BACK 3LH2 86450013
*                                   TO FORCE FLUSHING.                  86520013
         SPACE 1                                                        86590013
         TM    PPISW1+7,X'20'      USER INSERT IN PROGRESS...      3LJ2 86660013
         BZ    ONRCDCMP            -NO, GO COMPARE RECORD COUNTS.       86730013
         SPACE 1                                                        86800013
ONSERT   BCTR  RJ,0                -YES, SUBTRACT 1 FOR RCD HELD        86870013
*                                   BACK TO ALLOW USER INSERT.          86940013
         SPACE 1                                                        87010013
ONRCDCMP CR    RJ,RO               COMPARE RECORDS IN TO RCDS OUT  3LE3 87080013
         BNE   ONCNTABT            RECORD COUNT OFF, GO TO ABORT RTN.   87150013
         SPACE 1                                                        87220013
         BR    RK                  RECORD CNT EQUAL, RETURN TO MAINLINE 87290013
         SPACE 2                                                        87360013
*RECORD COUNT OFF. PRINT COMPUTED TOTALS AND ABORT THE JOB.             87430013
* RO = RECORDS OUT, RJ = RECORDS IN.                                    87500013
         SPACE 1                                                        87570013
ONCNTABT L     RM,PPIRMA+4         SET MESSAGE MODULE ADDRESS.     3LE4 87640013
         LM    RA,RB,MSGP1A03      GET MESSAGE.                         87710013
         CVD   RO,WSAVE4           CONVERT RCDS OUT TO DECIMAL.         87780013
         BAL   RP,ON0SPRS          GO TO ZERO SUPRESS ROUTINE           87850013
         SPACE 1                                                        87920013
         MVC   MSGP1R03+37(7),WSAVE4+8       PUT RCDS OUT INTO MSG.     87990013
         SPACE 1                                                        88060013
         CVD   RJ,WSAVE4           CONVERT RCDS IN TO DECIMAL.          88130013
         BAL   RP,ON0SPRS          GO TO ZERO SUPPRESS ROUTINE.         88200013
         SPACE 1                                                        88270013
         MVC   MSGP1R03+25(7),WSAVE4+8       PUT RCDS IN INTO MSG.      88340013
         SPACE 1                                                        88410013
ONOUTMSG L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    88480013
         L     RP,PPIADSSC         EXIT TO SSC TO PRINT MESSAGE    3LF4 88550013
         BAL   RO,12(0,RP)                                              88620013
         SPACE 1                                                        88690013
         L     RP,PPIADSSC         EXIT TO SSC TO ABORT THE JOB.   3LG4 88760013
         BAL   RO,16(0,RP)                                              88830013
         SPACE 1                                                        88900013
ON0SPRS  UNPK  WSAVE4+7(8),WSAVE4+3(5)  SET TO ZONED DECIMAL FOR PRINT  88970013
         OI    WSAVE4+14,X'F0'          MAKE SIGN POSITIVE.             89040013
         MVI   WSAVE4+15,X'01'          SET STOPPER DIGIT.              89110013
         LA    RO,WSAVE4+7         INITIALIZE LOOP ADDRESS REGISTER.    89180013
ON0SPRS1 CLI   0(RO),X'F0'         TEST FOR ZERO DIGIT.                 89250013
         BNE   0(RP)               NO MORE ZEROS, RETURN.               89320013
         SPACE 1                                                        89390013
         MVI   0(RO),X'40'         INSERT BLANK CHARACTER.              89460013
         LA    RO,1(RO)            INCR ADDRESS REGISTER.               89530013
         B     ON0SPRS1            GO TO TEST NEXT BYTE FOR ZERO.       89600013
         SPACE 2                                                        89670013
ONMOVE   MVC   1(1,RP),0(RP)       USED ONLY BY EXECUTE INSTRUCTIONS    89740013
ONORDCMP CLI   KMXTRK+1,X'00'      USED VIA EXECUTE BY ORDERING LIST    89810013
*                                  SUBROUTINE TO TEST FOR TRUE AREA     89880013
KNOP     NOP   KNOP                                                     89950013
         BR    RA                  USED TO OVERLAY AT INPUT EOF         90020013
KOVERLAY B     ONMTMSQ             USED TO OVERLAY AT INPUT EOF         90090013
KOVERLA2 B     ONDONE              USED TO OVERLAY IF NOT MORE THAN M   90160013
*                                    SEQ. AND EQUALS RTN BEING USED     90230013
WSWITCHA DC    X'00'               SET WHEN SWITCHING FROM SORT TO MRG  90300013
WSWITCHB DC    X'00'               SET TO INDICATE TRACKS ARE AVAILABLE 90370013
WSWITCHC DC    X'00'               SET DURING EACH EVEN NUMBERED        90440013
*                                    CONSECUTIVE MERGE PASS             90510013
WSWITCHD DC    X'00'               USED AT ENTRY FROM READ AT EOS TO    90580013
*                                    SEE IF ANOTHER MERGE PASS FOLLOWS  90650013
WSAVE2   DC    H'0'                WORK AREA FOR SUBROUTINES            90720013
WSEQTOTL DC    F'0'                COUNTER FOR TOTAL SEQUENCES          90790013
WSEQCTR  DC    F'0'                COUNTER FOR SEQUENCES THIS SORT PH.  90860013
WSAVE1   DC    2F'0'               SAVE RC AND RD HERE                  90930013
WSAVE3   DC    F'0'                SAVE AREA                            91000013
         DS    0D                                                       91070013
WSAVE4   DC    4F'0'               SAVE AREA                            91140013
WSAVE5   DC    F'0'               SAVE AND WORK AREA                    91210013
WSAVE    DC    F'1'                SAVE AREA FOR RC (J)                 91280013
         DC    2F'0'               SAVE AREA FOR RD AND RE (I AND L)    91350013
KTABLEX  DC    F'0'                LOADED WITH TABLE ADDRESS BY ASMT.   91420013
KFRTRKLT DC    F'0'                LOADED WITH ADDRESS OF TABLE WHERE   91490013
*                                    FREE TRACK LIST ADDRESSES ARE-4    91560013
*                                    (LOADED BY ASMT. ROUTINE)          91630013
KTABLEL  DC    F'0'                POINTER TO L ROW  (SET ORG BY ASMT)  91700013
KTBLMZON DC    F'0'                POINTER TO L-1 ROW (SET ORG BY ASMT) 91770013
KTABLEX0 DC    F'0'                ADDRESS OF L=0 ROW OF TABLE. (ASMT.) 91840013
KBYPEROW DC    F'0'                BYTES PER ROW OF TABLE       (ASMT.) 91910013
KBPRLS2  DC    H'0'                BYTES PER ROW - 2 (SET BY ASMT.)     91980013
KBPRLS1  DC    H'0'                BYTES PER ROW - 1 (SET BY ASMT.)     92050013
KBPRLS6  DC    H'0'                BYTES PER ROW - 6 (SET BY ASMT.)     92120013
KMXTRK   DC    H'0'                SET BY ASMT.-WILL BE=9 IF 2311-WILL  92190013
*                                    BE=19 IF 2314                      92260013
KMXTRKCP DC    H'0'                SET BY ASMT. HI ORDER BYTE=0 LO      92330013
*                                    ORDER BYTE=COMPLEMENT OF KMXTRK    92400013
KBPRLS3  DC    H'0'                BYTES PER ROW - 3 (SET BY ASMT.)     92470013
KBPRLS4  DC    H'0'                BYTES PER ROW - 4 (SET BY ASMT.)     92540013
KPOOLSZ  DC    H'0'                SET TO SIZE OF POOL BY ASMT.         92610013
KZERO    DC    H'0'                                              A27990 92640000
KONE     DC    H'1'                                                     92680013
KTWO     DC    H'2'                                                     92750013
KFOUR    DC    H'4'                                                     92820013
KFORTY   DC    H'40'                                                    92890013
KMERGORD DC    F'0'                MERGE ORDER (SET BY ASSIGNMENT)      92960013
KMOMONE  DC    F'0'                MERGE ORDER-1 (SET BY ASSIGNMENT)    93030013
KMSQURD  DC    F'0'                SET TO M SQUARED BY ASMT             93100013
KPOOL    DC    F'0'                LOADED TO POOL ADDRESS BY ASMT.      93170013
KFPPTR   DC    F'0'                POINTER TO FREE POOL LIST     A27990 93180000
KCHAIN   DC    F'0'                ADDR TO POOL SEGMENT          A27990 93190000
WSAVE6   DC    3F'0'               SAVE AREA FOR REG 2-4         A27990 93200000
K00FF    DC    XL4'0000FFFF'                                            93240013
KONEONE  DC    X'01000100'         MUST BE ON A FULL WORD BOUNDARY      93310013
DIERRMA  DSECT                                                          93380013
*                                                                       93450013
         COPY  RMAMAIN                                                  93520013
         SMPPI                                                          93590013
         END                                                            93660013
