         TITLE 'IER8PA - OS/360 SORT/MERGE -3605-SM-023  10/14/66'      00100013
*MODULE NAME *** IER8PA ***                                             00200013
         SPACE 2                                                        00300013
*STATUS CHANGE LEVEL 000                                                00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION:  2314 WRITE ROUTINE                         00600013
*   THIS MODULE HANDLES DIRECT ACCESS OUTPUT IN THE SORT/MERGE BY WAY   00700013
*   OF THE EXCP MACRO.  IT ACCEPTS PHYSICAL RECORDS FROM THE BLOCK      00800013
*   ROUTINE AND SCHEDULES THEM TO BE WRITTEN.  THE ROUTINE INTERFACES   00900013
*   WITH IOS, THE ALGORITHM, BLOCK, AND THE SORT NETWORK.  IF EXIT      01000013
*   E19 OR E29 HAS ACTIVATED SYNAD, THE WRITE ROUTINE (ON A WRITE       01100013
*   ERROR) ALLOWS THE USER TO TRY AND CORRECT THE ERROR AFTER IOS HAS   01200013
*   TRIED TO DO SO.  CONTROL IS THEN PASSED TO SORT SYSTEM CONTROL      01300013
*   (IERRCV) TO ABORT THE JOB.  THE MODULE USES THE GETMAIN, EXCP,      01400013
*   WAIT, DCBD, DELETE, AND SMPPI MACROS.                               01500013
*                                                                       01600013
*   IF RECORD FORMAT IS VARIABLE, IER9PA HAS MADE SEVERAL OVERLAYS IN   01700013
*   THIS MODULE'S INSTRUCTIONS TO BYPASS THE BCC (BLOCK CHARACTER       01800013
*   COUNT) TOO.  FOR EXAMPLE, THE INSTRUCTION AT PAEOSEOF HAS ITS FIRST 01900013
*   OPERAND'S DISPLACEMENT ADJUSTED TO 12 -  MVC  12(4,RC),KEOS.        02000013
*                                                                       02100013
*   THIS WRITE MODULE IS ALSO USED WHEN THREE OR MORE 2311 DISK UNITS   02200013
*   ARE DEFINED AS OUR WORK UNITS.  THE ROUTINE DOES NOT KNOW WHETHER   02300013
*   IT IS QUEUING A 2314 OR 2311.  IER9PA DOES THE ADJUSTING BY SETTING 02400013
*   KTRKBAL TO 3625.                                                    02500013
*                                                                       02600013
*   NORMAL INTERFACING OCCURS BETWEEN THE BLOCK AND WRITE ROUTINES.     02700013
*   WHEN DOUBLE BUFFERED, THE WRITE ROUTINE HAS BEEN DESIGNED TO DELAY  02800013
*   WAITING ON A WRITE UNTIL THE NEXT TIME BLOCK ENTERS THE ROUTINE.    02900013
*   FOR SINGLE BUFFERING, A WAIT ALWAYS OCCURS IMMEDIATELY AFTER        03000013
*   QUEUING THE WRITE.  ON EOS OR EOF, THE WRITE DOES NOT RETURN TO     03100013
*   THE BLOCK ROUTINE.  IT INTERFACES WITH THE ALGORITHM THEN, BUT      03200013
*   IT IS STILL RESPONSIBLE FOR PASSING AN EMPTY BUFFER ADDRESS TO THE  03300013
*   BLOCK ROUTINE.   IT DOES THIS BY PLACING THE BUFFER ADDRESS IN THE  03400013
*   BLOCK ROUTINE'S ENTRY TABLE VIA PPIBLK OR PPIBLK2 AT DISPLACEMENT   03500013
*   20 AND 24.                                                          03600013
*                                                                       03700013
*   THERE ARE TWO CONDITIONS WHEN THE WRITE CANNOT DELAY ITS WAIT.  IF  03800013
*   THE 2314 ALGORITHM (IER80N) ENCOUNTERS A 'TWO MERGE PASSES IN A     03900013
*   ROW' CONDITION, IT SETS BIT 61 OF PPISW1 TO TELL THE WRITE ROUTINE  04000013
*   TO WAIT ON THE FORTHCOMING EOS BLOCK.  THIS SEQUENCE IS NEEDED BY   04100013
*   READ BEFORE THE WRITE IS AGAIN EXECUTED.  SO WRITE CHECKS PPISW1,   04200013
*   BIT 61 ON EACH EOS BLOCK AND DOES THE WAIT (DOUBLE BUFFERED COND.)  04300013
*   ONLY IF THE ALGORITHM SPECIFIES SUCH.  THE SECOND CONDITION IS      04400013
*   EOF.  AT THIS POINT ALL FILES MUST BE READY FOR READ TO PRIME, SO   04500013
*   THE WRITE ISSUES A WAIT ON THE LAST BLOCK TO BE WRITTEN BEFORE      04600013
*   PRIMING BEGINS.                                                     04700013
         SPACE 1                                                        04800013
*   THIS MODULE ALSO PERFORMS THE FOLLOWING MISCELLANEOUS FUNCTIONS:    04900013
*        1. DELETES LOAD MODULE (RC9) AFTER ALL ASSIGNMENT ROUTINES     05000013
*           HAVE BEEN EXECUTED                                          05100013
*        2. DETERMINES IF ANOTHER OUTPUT BUFFER IS NEEDED AND ISSUES    05200013
*           A GETMAIN TO OBTAIN IT                                      05300013
         SPACE 2                                                        05400013
*AUTOCHART IDS:  2A THROUGH 2D                                          05500013
         SPACE 2                                                        05600013
*LIST OF MODULES THIS MODULE APPEARS AS A DSECT IN:                     05700013
         SPACE 1                                                        05800013
*        IER9PA                                                         05900013
         SPACE 2                                                        06000013
*MACROS USED:                                                           06100013
         SPACE 1                                                        06200013
*        GETMAIN    FIXED,CONDITIONAL                                   06300013
*        DELETE     IERRC9                                              06400013
*        EXCP       TO WRITE                                            06500013
*        WAIT       TO HAVE I/O POSTED                                  06600013
*        DCBD       DCB DSECT                                           06700013
*        SMPPI      PHASE-PHASE INFO. DSECT                             06800013
*        SVC 17    PURGE MACRO EXPANSION                                06900013
         SPACE 2                                                        07000013
*ENTRY POINTS:                                                          07100013
         SPACE 1                                                        07200013
*        IER8PA  BRANCH TABLE    DISP = 0,12    DUMMY ENTRIES           07300013
*                                     = 4       EOS OR EOS/EOF FROM BLK 07400013
*                                     = 8       NORMAL FROM BLOCK       07500013
         SPACE 2                                                        07600013
*INPUT:  PPI FIELDS REFERENCED                                          07700013
         SPACE 1                                                        07800013
*   PPIALG+4        ALGORITHM BASE                                      07900013
*   PPIBLK+4        BLOCK BASE                                          08000013
*   PPIBLK2+4       BLOCK BASE                                          08100013
*   PPILAB04        SWITCH FOR OBTAINING EXTRA OUT.BUF.                 08200013
*   PPILAB07+2      OUTPUT BUFFER SIZE                                  08300013
*   PPINET+4        SORT NETWORK BASE                                   08400013
*   PPIRCV+4        SSC BASE                                            08500013
*   PPISTDCB        ADDR. OF DCB TABLE                                  08600013
*   PPISW1          BITS 20 AND 61                                      08700013
*   PPIWKARE        CHAIN DISK ADDRESS                                  08800013
         SPACE 2                                                        08900013
*OUTPUT:  PPI FIELDS INITIALIZED OR ALTERED                             09000013
         SPACE 1                                                        09100013
*   PPIDEPHO        OUTPUT DISK ADDRESS                                 09200013
*   PPIGETMN        GETMAIN ADDR.                                       09300013
*   PPIGETSZ          AND SIZE TABLES                                   09400013
*   PPIRCV         I/O UNIT NO.                                         09500013
*   PPILAB05        SECOND OUTPUT BUFFER ADDR.                          09600013
*   PPILAB07        NO. OF OUTPUT BUFFERS                               09700013
*   PPISW1          BIT 42                                              09800013
         SPACE 2                                                        09900013
*EXTERNAL ROUTINES:  N/A                                                10000013
         SPACE 2                                                        10100013
*EXTERNAL PARAMETERS:                                                   10200013
         SPACE 1                                                        10300013
*        CCW'S      CHANNEL COMMAND WORDS                               10400013
*        DCB'S      DATA CONTROL BLOCKS                                 10500013
*        ECB'S      EVENT CONTROL BLOCKS                                10600013
*        IOB'S      INPUT-OUTPUT BLOCKS                                 10700013
*        BUFFERS                                                        10800013
         SPACE 2                                                        10900013
*EXITS-NORMAL:                                                          11000013
         SPACE 1                                                        11100013
*   BLOCK RTNS.  AT DISP =8   FOR NORMAL RETURN WITH EMPTY BUFFER ADDR. 11200013
*   ALGORITHM    AT DISP =0   FOR EOF                                   11300013
*                        =4   FOR OBTAINING CHAIN ADDRESS               11400013
*                        =8   FOR EOS                                   11500013
*   NETWORK      AT DISP =0   FOR STARTING SORT                         11600013
         SPACE 2                                                        11700013
*EXITS-ERROR:                                                           11800013
         SPACE 1                                                        11900013
*   IERRCV       AT DISP =16  FOR ABORTING THE JOB                      12000013
         SPACE 2                                                        12100013
*TABLES/WORK AREAS:  N/A                                                12200013
         SPACE 1                                                        12300013
         SPACE 2                                                        12400013
*ATTRIBUTES:  THIS IS A CLASS A MODULE.                                 12500013
         SPACE 2                                                        12600013
*NOTES:                                                                 12700013
*   THIS MODULE RELIES ON THE SYSTEM MACROS NOT CHANGING IN ANY WAY.    12800013
*   IT IS ONLY USED FOR DIRECT ACCESS WORK UNITS WITH THE 2314 CRISS-   12900013
*   CROSS ALGORITHM.                                                    13000013
         EJECT                                                          13100013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            13200013
         SPACE 1                                                        13300013
RA       EQU   0                   CONTENTS IN- N/A                     13400013
*                                  USE- SYSTEM PARAMETER REGISTER       13500013
*                                  CONTENTS OUT- N/A                    13600013
RB       EQU   1                   CONTENTS IN- N/A                     13700013
*                                  USE- SYSTEM PARAMETER REGISTER       13800013
*                                  CONTENTS OUT- BLOCK COUNT            13900013
RC       EQU   2                   CONTENTS IN- FULL BUFFER ADDRESS     14000013
*                                  USE- WORK REGISTER                   14100013
*                                  CONTENTS OUT- EMPTY BUFFER ADDRESS   14200013
RD       EQU   3                   CONTENTS IN- WINNER RECORD           14300013
*                                  USE- WORK REGISTER                   14400013
*                                  CONTENTS OUT- WINNER RECORD          14500013
RE       EQU   4                   CONTENTS IN- EOF/EOS SWITCH          14600013
*                                  USE- WORK REGISTER                   14700013
*                                  CONTENTS OUT- N/A                    14800013
RF       EQU   5                   CONTENTS IN- N/A                     14900013
*                                  USE- IOB BASE                        15000013
*                                  CONTENTS OUT- N/A                    15100013
RG       EQU   6                   CONTENTS IN- N/A                     15200013
*                                  USE- DCB BASE, WORK REGISTER         15300013
*                                  CONTENTS OUT- N/A                    15400013
RH       EQU   7                   CONTENTS IN- N/A                     15500013
*                                  USE- WORK REGISTER                   15600013
*                                  CONTENTS OUT- N/A                    15700013
RI       EQU   8                   CONTENTS IN- N/A                     15800013
*                                  USE- NOT USED                        15900013
*                                  CONTENTS OUT- N/A                    16000013
RJ       EQU   9                   CONTENTS IN- N/A                     16100013
*                                  USE- NOT USED                        16200013
*                                  CONTENTS OUT- N/A                    16300013
RK       EQU   10                  CONTENTS IN- N/A                     16400013
*                                  USE- NOT USED                        16500013
*                                  CONTENTS OUT- N/A                    16600013
RL       EQU   11                  CONTENTS IN- PROGRAM BASE            16700013
*                                  USE- BASE REGISTER                   16800013
*                                  CONTENTS OUT- NEXT PROGRAM'S BASE    16900013
RM       EQU   12                  CONTENTS IN- EQ/EXTRACT BASE         17000013
*                                  USE- NOT USED                        17100013
*                                  CONTENTS OUT- EQ/EXTRACT BASE        17200013
RN       EQU   13                  CONTENTS IN- PPI BASE                17300013
*                                  USE- SYSTEM REGISTER SAVE AREA-PPI   17400013
*                                  CONTENTS OUT- PPI BASE               17500013
RO       EQU   14                  CONTENTS IN- N/A                     17600013
*                                  USE- SYSTEM RETURN REGISTER          17700013
*                                  CONTENTS OUT- N/A                    17800013
RP       EQU   15                  CONTENTS IN- N/A                     17900013
*                                  USE- SYSTEM LINK REGISTER            18000013
*                                  CONTENTS OUT- N/A                    18100013
         EJECT                                                          18200013
*START OF MODULE CODE PROPER:                                           18300013
         SPACE 2                                                        18400013
IER8PA   CSECT                                                          18500013
*A462500                                                         A35557 18550021
         USING *,RL                PROGRAM BASE                         18600013
         USING IERRCA,RN           PPI BASE                             18700013
         USING IHADCB,RG           DCB BASE                             18800013
         USING IERIOB,RF           IOB BASE                             18900013
         SPACE 1                                                        19000013
PABRTAB  DC    A(0)                DUMMY ENTRY -USED AS CONSTANT        19100013
         B     PAEOSEOF            EOS/EOF ENTRY -RE =0 FOR EOF/EOS     19200013
*                                                    =4 FOR EOS ONLY    19300013
         B     PANORM              NORMAL ENTRY FROM BLOCK              19400013
         DC    A(0)                DUMMY ENTRY -USED AS CONSTANT        19500013
*DELETE IERRC9, TRY FOR EXTRA BUFFER IF NECESSARY, AND LINK TO SORT     19600013
*   NETWORK TO START PROCESSING RECORDS.                         2A     19700013
         DELETE  EP=IERRC9         ALL ASSIGNMENT EXEC, SO DELETE -RC9  19800013
         LTR   RP,RP               CHECK FOR ERROR                      19900013
         BE    PA001                 NO- CONTINUE SORT                  20000013
         SPACE 1                                                        20100013
         L     RP,PPIRCV+4         ERROR OCCURRED- PRINT MESSAGE        20200013
         BAL   RO,28(0,RP)                                              20300013
         SPACE 1                                                        20400013
         L     RP,PPIRCV+4           AND TERMINATE JOB                  20500013
         B     16(0,RP)                                                 20600013
         SPACE 2                                                        20700013
*CHECK TO SEE IF AN ADDITIONAL OUTPUT BUFFER SHOULD BE OBTAINED.        20800013
         SPACE 1                                                        20900013
PA001    TM    PPILAB04,X'80'      IF BIT ON, DON'T GET AN       2AD1   21000013
         BO    PA010                 OUTPUT BUFFER                      21100013
         SPACE 1                                                        21200013
*TRY FOR EXTRA OUTPUT BUFFER                                            21300013
         LH    RC,PPILAB07+2       SET LV                               21400013
         LA    RC,8(0,RC)            PARAMETER                          21500013
         ST    RC,PAGETMN+4                                             21600013
         SPACE 1                                                        21700013
PAGETMN  GETMAIN  EC,LV=80,A=PABRTAB    LV PARAMETER IS DUMMY -SET TO   21800013
*                                        (PPILAB07+2)+8 AT EXEC. TIME   21900013
         LTR   RP,RP               WAS CORE GOTTEN                      22000013
         BNE   PA010                 NO- CORE NOT AVAILABLE             22100013
         SPACE 1                                                        22200013
*CORE OBTAINED FOR SECOND OUTPUT BUFFER                                 22300013
         MVI   PPILAB07,X'02'      SET NO. OF BUFFERS TO 2              22400013
         L     RB,PPIGETSZ                                              22500013
PA002    CLI   0(RB),X'80'         DETERMINE END OF GETMAIN      2AJ1   22600013
         BE    PA003                 TABLES                             22700013
         SPACE 1                                                        22800013
         LA    RB,4(0,RB)          UPDATE TABLE AND                     22900013
         LA    RP,4(0,RP)            DISPLACEMENT COUNT                 23000013
         B     PA002               TEST NEXT ENTRY                      23100013
         SPACE 2                                                        23200013
PA003    MVI   0(RB),X'00'         PLACE SIZE OF GETMAIN         2AB3   23300013
         ST    RC,4(0,RB)                                               23400013
         MVI   4(RB),X'80'           IN TABLE -PPIGETSZ                 23500013
         L     RB,PPIGETMN                                              23600013
         L     RD,PABRTAB          PLACE ADDRESS OF BUFFER              23700013
         ST    RD,4(RP,RB)           IN TABLE -PPIGETMN                 23800013
         LA    RD,8(0,RD)          ADJUST ADDRESS BY 8 BYTES -DIRECT    23900013
         ST    RD,PPILAB05           ACCESS WRITE REQUIRES THIS FOR     24000013
         ST    RD,KBUFF              SEARCH ID - CCHHRKCT -SAVE ACTUAL  24100013
*                                    BUFFER ADDRESS FOR DATA PROCESSING 24200013
PA010    L     RL,PPINET+4         EXIT TO NETWORK TO                   24300013
         BR    RL                    START PROCESSING RECORDS           24400013
         SPACE 2                                                        24500013
*THIS IS THE EOS/EOF ENTRY.  REGISTER RE = 0 FOR EOF                    24600013
*                                        = 4 FOR EOS             2D     24700013
PAEOSEOF MVC   8(4,RC),KEOS        PLACE EOS INDICATOR IN BUFFER 2DB4   24800013
         MVI   PAEOS+1,X'F0'       SET BRANCH TO GO TO ALGORITHM        24900013
         MVI   PAEOS1+1,X'00'      SET BRANCH TO PLACE ADDR. IN BLK.    25000013
         MVI   PA059+1,X'F0'       SET BRANCH TO NOT OBTAIN CHAIN       25100013
         B     PA011(RE)                                                25200013
         SPACE 2                                                        25300013
PA011    MVI   PAEOF+1,X'F0'       ON EOF, SET BRANCH TO WAIT ON FILE   25400013
*                                                                2DD5   25500013
         B     PA020               GO TO NORMAL ENTRY TO QUEUE WRITES   25600013
         SPACE 2                                                        25700013
*THIS IS THE NORMAL ENTRY FROM BLOCK.  REGISTER RB = BUFFER BYTE COUNT  25800013
*                                               RC = FULL BUFFER ADDR.  25900013
*                                               RD = WINNER RCD. 2B     26000013
PANORM   MVC   8(4,RC),KNEOS                                     2BC4   26100013
         MVI   PAEOS+1,X'00'       TURN OFF EOS AND                     26200013
         MVI   PAEOS1+1,X'F0'                                           26300013
         MVI   PAEOF+1,X'00'         EOF SWITCHES -RETURN TO BLOCK NOW  26400013
         MVI   PA059+1,X'00'         AND OBTAIN CHAIN FROM ALG.         26500013
PA020    STM   RB,RE,KSAVE         SAVE REGISTERS                2BD4   26600013
         L     RF,KIOB             SET IOB BASE                         26700013
         CLI   PPILAB07,X'02'      DOUBLE BUFFERED                      26800013
         BE    PAALT030              YES, ISSUE WAIT/QUEUE NEXT WRITE   26900013
         SPACE 2                                                        27000013
*NO. OF OUTPUT BUFFERS IS ONE. ISSUE WRITE, WAIT, AND ERROR CHECK.      27100013
         BAL   RH,PAEXCP           UPDATE IOB, ETC. AND QUEUE WRITE     27200013
PA021    BAL   RH,PAWAIT           WAIT - ERROR CHECK            2BF5   27300013
         SPACE 1                                                        27400013
PAEOS    NOP   PARTALG             EOS SWITCH-IF BRANCH,GO TO ALG.2BG5  27500013
         LM    RC,RD,KSAVE+4       SET PARAMETER REGISTERS              27600013
PARTNV   LA    RC,12(0,RC)         UPDATE BUFFER TO POINT TO DATA AREA  27700013
         TM    PPISW1+2,X'08'      SORT OR MERGE PHASE IN CONTROL       27800013
         BO    PA025                 -MERGE                             27900013
         SPACE 1                                                        28000013
         L     RL,PPIBLK+4         SORT BLOCK BASE                      28100013
         B     8(0,RL)                                                  28200013
         SPACE 2                                                        28300013
PA025    L     RL,PPIBLK2+4        MERGE BLOCK BASE                     28400013
         B     8(0,RL)                                                  28500013
         SPACE 2                                                        28600013
PARTALG  L     RG,KDCB                                          2BH5    28700013
         SR    RB,RB                                                    28800013
         IC    RB,DCBCHECK         FILE'S INCREMENT                     28900013
         CLI   KSAVE+15,X'04'      SET COND. CODE FOR ENTRY TO ALG.     29000013
         L     RL,PPIALG+4         SET ALGORITHM'S BASE FOR             29100013
         BE    8(0,RL)               EOS CONDITION                      29200013
         BR    RL                    EOF CONDITION                      29300013
         SPACE 2                                                        29400013
*NO. OF OUTPUT BUFFERS IS TWO.  ISSUE WAIT, ERROR CHECK, AND QUEUE      29500013
*   WRITE.                                                       2BE3   29600013
PAALT030 NOP   PA035               FIRST TIME THROUGH PASS,BYPASS WAIT  29700013
         MVI   PAALT030+1,X'F0'    SET NOP TO BRANCH, SO ISSUE WAIT     29800013
         MVC   KSAVE+4(4),KBUFF    SET UP TO GIVE ALTERNATE BUFFER      29900013
*                                    TO BLOCK ON RETURN                 30000013
         B     PA040               QUEUE WRITE                          30100013
         SPACE 2                                                        30200013
PA035    BAL   RH,PAWAIT           WAIT - ERROR CHECK            2BE2   30300013
         L     RE,START            SWITCH CCW POINTERS                  30400013
         L     RP,ECBPTR             AT IOB AND ECB+4                   30500013
         MVC   START+1(3),5(RP)                                         30600013
         ST    RE,4(0,RP)                                               30700013
PA040    BAL   RH,PAEXCP           UPDATE IOB AND QUEUE WRITE    2BF1   30800013
         SPACE 2                                                        30900013
PAEOS1   B     PAEOS+4             NOP WHEN EOS                  2BG1   31000013
         SPACE 1                                                        31100013
*ON EOS, WRITE DOES NOT RETURN TO BLOCK.  IT PASSES THE EMPTY BUFFER    31200013
*   ADDRESS TO BLOCK BY STORING THE ADDRESS IN BLOCK'S BRANCH TABLE     31300013
*   AT DISPLACEMENT 20 AND 24.                                          31400013
         L     RO,PPIBLK+4         PLACE BUFFER ADDRESS                 31500013
         L     RP,PPIBLK2+4                                             31600013
         L     RC,KBUFF              IN BLOCK ROUTINES-                 31700013
PAEOSV   LA    RC,12(0,RC)         ADDR. PLUS CHAIN(8) PLUS EOS(4)      31800013
         ST    RC,20(0,RP)           PLUS BCC(4) IF VARIABLE            31900013
         ST    RC,20(0,RO)                                              32000013
         ST    RC,24(0,RP)                                              32100013
         ST    RC,24(0,RO)                                              32200013
PAEOF    NOP   PA050               IF EOF OR 2ND MERGE PASS TO          32300013
         TM    PPISW1+7,X'08'        FOLLOW, ISSUE WAIT ON WRITE        32400013
         BC    8,PARTALG             QUEUED.                     2BH2   32500013
         SPACE 1                                                        32600013
*ON EOF, RESET FIRST TIME THROUGH SWITCH TO BYPASS WAIT FOR DOUBLE BUF. 32700013
*                                                                2BH3   32800013
         SPACE 1                                                        32900013
PA050    MVI   PAALT030+1,X'00'    RESET FIRST TIME THROUGH AND EOF     33000013
         MVI   PAEOF+1,X'00'         SWITCHES                           33100013
         B     PA021               WAIT ON FILE                         33200013
         SPACE 2                                                        33300013
*THIS SUBROUTINE SETS UP THE IOB, CCW, AND BUFFER TO ISSUE AN EXCP.     33400013
*   THE IOB DISK ADDRESS POINTS TO PREVIOUS RECORD WRITTEN, AND AT      33500013
*   BUFFER -8, THE DISK ADDRESS IS FOR RECORD TO BE WRITTEN.  THE       33600013
*   CHAIN DISK ADDRESS IN THE BUFFER IS FOR THE NEXT RECORD TO BE       33700013
*   WRITTEN.. THE CCW LIST USED TO QUEUE A WRITE COMMAND IS-            33800013
*                                                                       33900013
*        SEARCH  ID                                                     34000013
*        TIC                                                            34100013
*        WRITE                                                          34200013
*                                                                       34300013
*   THE ALGORITHM (IER8ON) HAS CONTROL OVER WHERE DATA IS WRITTEN.      34400013
*   IT COMMUNICATES THIS INFORMATION VIA PPI.  PPIDEPHO CONTAINS THE    34500013
*   DISK ADDRESS WHERE PRESENT RECORD IS TO BE WRITTEN, AND PPIWKARE    34600013
*   IS FOR THE CHAIN DISK ADDRESS.                               2C     34700013
*                                                                       34800013
*   UPON ENTERING THIS SUBROUTINE, REGISTERS ARE SET AS FOLLOWS-        34900013
*                                                                       35000013
*        RB -BUFFER BYTE COUNT                                          35100013
*        RC -BUFFER ADDRESS                                             35200013
*        RG -DCB ADDRESS                                                35300013
*        RF -IOB BASE                                                   35400013
*        RH -RETURN ADDRESS                                             35500013
         SPACE 2                                                        35600013
PAEXCP   L     RE,START            LOAD CCW POINTER              2CB1   35700013
         SH    RC,KEIGHT           SET BUFFER ADDR. TO POINT TO         35800013
         ST    RC,PABRTAB+12         CCHHRKCT BEFORE DATA               35900013
         MVC   17(3,RE),PABRTAB+13 SAVE BUFFER ADDR. IN CCW             36000013
         MVC   0(5,RC),PPIDEPHO+3  PLACE CCHHR IN BUFFER                36100013
         STH   RB,6(0,RC)          PLACE BYTE COUNT IN BUFFER AT CT     36200013
         LA    RB,8(0,RB)          ADD 8 (CCHHRKCT) TO BYTE COUNT AND   36300013
         STH   RB,22(0,RE)           SAVE IN CCW                        36400013
         MVI   5(RC),X'00'         SET KEY (K) TO ZERO IN BUFFER        36500013
         SPACE 1                                                        36600013
         IC    RP,PPIDEPHO+7       OBTAIN DISK ADDRESS OF PREVIOUS      36700013
         BCTR  RP,0                                                     36800013
         STC   RP,DISKADR+7          WRITE AND STORE IT IN THE IOB      36900013
         MVC   DISKADR+2(5),PPIDEPHO+2                                  37000013
         SR    RB,RB                                                    37100013
         IC    RB,PPIDEPHO         FILE'S INCREMENT                     37200013
         L     RG,PPISTDCB                                              37300013
         L     RG,0(RB,RG)         OBTAIN FILE'S DCB AND SAVE IN        37400013
         ST    RG,DCBPTR             IOB AND OWN CONSTANT FOR WAIT      37500013
         ST    RG,KDCB                                                  37600013
         MVC   DCBFDAD+2(6),PPIDEPHO+2  SET UP DISK ADDR. IN DCB FOR    37700013
*                                    IOS AND CLOSE                      37800013
PA059    B     PA070V              IF EOS, DON'T GO  FOR CHAIN ADDRESS. 37900013
*                                    INSTEAD HAVE CHAIN POINT TO SELF   38000013
*                                    FOR READ TO RELEASE TRACK LATER.   38100013
PA060    CLI   PPIDEPHO+7,X'00'    MASK IS PPIBPTRK+1 -SET AT           38200013
*                                    ASSIGNMENT TIME             2CD3   38300013
         BE    PA080                 YES -OBTAIN NEW CHAIN FROM ALG.    38400013
         SPACE 1                                                        38500013
         IC    RP,PPIDEPHO+7       SET DISK ADDRESS FOR NEXT            38600013
         LA    RP,1(0,RP)                                               38700013
         STC   RP,PPIDEPHO+7         WRITE                              38800013
PA070V   MVC   8(8,RC),PPIDEPHO    ALSO PLACE AS CHAIN DISK ADDRESS     38900013
         NI    DCBIFLGS,X'3F'      CLEAR ERROR FLAGS IN DCB        2CG3 39000013
         EXCP  (RF)                WRITE                                39100013
         BR    RH                  RETURN TO MAIN LINE                  39200013
         SPACE 2                                                        39300013
*OBTAIN NEW CHAIN ADDRESS FROM THE ALGORITHM.  RB = FILE'S INCREMENT    39400013
         SPACE 1                                                        39500013
PA080    STM   RB,RH,PPIWKARE+8                                         39600013
         L     RL,PPIALG+4         SET ALGORITHM'S BASE                 39700013
         BAL   RO,4(0,RL)                                               39800013
         SPACE 1                                                        39900013
         LM    RB,RH,PPIWKARE+8                                         40000013
         MVC   PPIDEPHO(1),PPIWKARE  SET DEPHO FOR NEXT WRITE WITHOUT   40100013
         MVC   PPIDEPHO+2(6),PPIWKARE+2  DESTROYING LOGICAL INCR -CHAIN 40200013
         B     PA070V                ADDR. PASSED IN PPIWKARE           40300013
         SPACE 2                                                        40400013
*THIS SUBROUTINE ISSUES THE WAIT MACRO, ERROR CHECKS, AND SETS UP THE   40500013
*   PARAMETERS FOR BLOCK.  RF = IOB BASE                         2D     40600013
         SPACE 1                                                        40700013
PAWAIT   MVC   DCBPTR+1(3),KDCB+1  SET DCB ADDRESS IN IOB               40800013
         L     RB,ECBPTR                                                40900013
         WAIT  1,ECB=(1)           WAIT ON FILE                         41000013
         L     RB,ECBPTR                                                41100013
         CLI   0(RB),X'7F'         CHECK FOR ERROR IN                   41200013
         BNE   PAERROR               THE ECB                            41300013
*NO ERROR, SET UP PARAMETERS FOR BLOCK                                  41400013
         L     RB,KSAVE            RESTORE BLOCK COUNT                  41500013
         L     RE,START            OBTAIN BUFFER ADDRESS VIA CCW        41600013
         L     RE,16(0,RE)                                              41700013
         LA    RE,8(0,RE)          BYPASS CCHHRKCT                      41800013
         ST    RE,KSAVE+4          SAVE BUFFER ADDRESS IN REGISTER SAVE 41900013
         ST    RE,KBUFF              AREA AND OWN CONSTANT              42000013
         SPACE 1                                                        42100013
PA090    BR    RH                   IF WE DO NOT HAVE FULL TRACK        42200013
*                                     BLOCKING, THIS RETURN IS NOP'ED   42300013
*                                     AND TRACK BALANCE IS UPDATED      42400013
*UPDATE TRACK BALANCE IN DCB-                                           42500013
         L     RG,KDCB             SET DCB BASE                         42600013
         SH    RE,KEIGHT                                                42700013
PA095    CLI   4(RE),X'00'          CHECK TO SEE IF LAST BLOCK OF TRACK 42800013
         BE    PA100                  YES- RE-INITIALIZE TO FULL        42900013
         SPACE 1                                                        43000013
         LH    RP,DCBTRBAL          DECREMENT TRACK BALANCE BY          43100013
         SR    RP,RB                  AMOUNT OF BYTES WRITTEN           43200013
         STH   RP,DCBTRBAL                                              43300013
         BR    RH                   RETURN TO MAIN LINE                 43400013
         SPACE 2                                                        43500013
PA100    MVC   DCBTRBAL(2),KTRKBAL  RESET TRACK BALANCE TO FULL         43600013
         BR    RH                     TRACK CONSTANT                    43700013
         SPACE 2                                                        43800013
*A WRITE ERROR HAS OCCURRED - CHECK SYNAD, LINK TO IT IF ACTIVATED,     43900013
*   AND THEN TERMINATE THE JOB.                                  2DF2   44000013
         SPACE 1                                                        44100013
PAERROR  CLI   0(RB),X'48'         SEE IF REQUEST WAS PURGED DUE TO     44200013
         BE    PARESTR               AN ERROR ON A READ COMMAND ON UNIT 44300013
         SPACE 1                                                        44400013
         OI    PPISW1+5,X'40'      SET PERM. WRITE ERROR BIT            44500013
         TM    PPISW1+2,X'08'      TEST FOR MERGE                       44600013
         BO    PAERROR2              YES, USE ADCONE29                  44700013
         SPACE 1                                                        44800013
         L     RP,ADCONE19         SORT SYNAD                           44900013
PAERROR1 LTR   RP,RP               CHECK TO SEE IF SYNAD ACTIVATED      45000013
         BE    PANOEXIT              NO, ABORT JOB                      45100013
         SPACE 1                                                        45200013
         L     RB,DCBPTR           SET UP RB -DCB ADDRESS               45300013
         MVI   KIOB,X'10'                 RA -IOB ADDRESS WITH CCW      45400013
         L     RA,KIOB                        DISPL. IN 1ST BYTE        45500013
*CALL USER'S E19/E29 SYNAD ROUTINE                                      45600013
         BALR  RO,RP                                                    45700013
         SPACE 2                                                        45800013
PANOEXIT L     RB,DCBPTR           OBTAIN SPECIFIC UNIT NUMBER          45900013
         L     RB,44(0,RB)                                              46000013
         L     RB,32(0,RB)           FOR IERRCV TO PRINT I/O ERROR      46100013
         MVC   PPIRCV(3),13(RB)                                         46200013
         LR    RG,RF               IOB BASE FOR IERRCV           A35557 46250021
         L     RP,PPIRCV+4           MESSAGE                            46300013
         B     16(0,RP)            ABORT THE JOB                        46400013
         SPACE 2                                                        46500013
PAERROR2 L     RP,ADCONE29         MERGE SYNAD                          46600013
         B     PAERROR1                                                 46700013
         SPACE 2                                                        46800013
*WRITE REQUEST HAS BEEN PURGED DUE TO AN I/O ERROR ON A PREVIOUS        46900013
*   REQUEST FOR THE UNIT                                                47000013
PARESTR  L     RG,KDCB             RESTORE I/O QUEUE LIST               47100013
         NI    DCBIFLGS,X'3F'      RESET ERROR BITS SET BY              47200013
         OI    FLG1,X'40'            IOS                                47300013
         L     RB,44(RG)           DEB ADDRESS                          47400013
         L     RB,16(0,RB)         POINT TO FIRST                       47500021
         LA    RB,0(0,RB)          PURGED IOB                           47550021
         SVC   17                  RESTORE SVC                          47600013
         B     PAWAIT                                                   47700013
         SPACE 2                                                        47800013
         SPACE 2                                                        47900013
         SPACE 2                                                        48000013
*LIST OF ADCONS USED BY MODULE:                                         48100013
         SPACE 1                                                        48200013
ADCONE19 DC    A(0)                                                     48300013
ADCONE29 DC    A(0)                                                     48400013
         SPACE 2                                                        48500013
*LIST OF CONSTANTS USED BY THE MODULE:                                  48600013
         SPACE 1                                                        48700013
KBUFF    DC    A(0)                EMPTY BUFFER ADDRESS                 48800013
KEOS     DC    C'HGHH'             EOS INDICATOR                        48900013
KNEOS    DC    C'HHHH'             NOT EOS INDICATOR                    49000013
KSAVE    DS    4F                  REGISTER SAVE AREA                   49100013
KIOB     DC    A(0)                IOB ADDRESS                          49200013
KDCB     DC    A(0)                DCB ADDRESS                          49300013
KTRKBAL  DC    AL2(7294)           TRACK BALANCE FACTOR  -2314 =7294    49400013
*                                                        -2311 =3625    49500013
KEIGHT   DC    AL2(8)              CONSTANT -8                          49600013
         SPACE 2                                                        49700013
*                                                                       49800013
*LIST OF WORK AREAS/TABLES: N/A                                         49900013
         EJECT                                                          50000013
*LIST OF DSECTS:                                                        50100013
         SPACE 1                                                        50200013
         DS    0F                                                       50300013
IERIOB   DSECT ,                   DUMMY IOB                            50400013
FLG1     DC    X'00'                                                    50500013
FLG2     DC    X'00'                                                    50600013
SENSE    DC    AL2(0)                                                   50700013
ECBPTR   DC    AL4(0)                                                   50800013
CSW      DC    AL4(0)                                                   50900013
         DC    AL4(0)                                                   51000013
START    DC    AL4(0)              CCW POINTER                          51100013
DCBPTR   DC    AL4(0)                                                   51200013
RESTART  DC    AL4(0)                                                   51300013
INCAMT   DC    AL2(0)                                                   51400013
ERRCNTS  DC    AL2(0)                                                   51500013
DISKADR  DC    AL4(0)              MBBCCHHR                             51600013
         DC    AL4(0)                                                   51700013
         EJECT                                                          51800013
         SMPPI                                                          51900013
         EJECT                                                          52000013
         DCBD  DSORG=PS                                                 52100013
         END                                                            52200013
