         TITLE '      IER9BO - OS/360 SORT/MERGE - 360S-SM023 12/12/67' 00200017
         SPACE 2                                                        00400017
*MODULE NAME *** IER9BO ***                                             00600017
         SPACE 2                                                        00800017
*STATUS0  CHANGE LEVEL 0                                                01000017
         SPACE 2                                                        01200017
*MODULE FUNCTION/OPERATION PHASE 3 ASSIGNMENT MODULE VRE RCDS - W. E35  01400017
*   THE FUNCTION OF THIS MODULE IS TO INSERT THE ADDRESS OF THE OUTPUT  01600017
*   DCB IN IER8BN. IT ALSO CHECKS TO SEE IF ATTACHED IN PHASE 3 AND IF  01800017
*   ATTACHED, INSERTS THIS ADDRESS FROM PPIATP3E IN PPIX35. IF NOT      02000017
*   ATTACHED EXIT E35(PPIX35) HAS BEEN ACTIVATED THROUGH CONTROL CARDS. 02200017
         SPACE 2                                                        02400017
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT'               02600017
*                                                                       02800017
*     N/A                                                               03000017
*                                                                       03200017
*MACROS USED'                                                           03400017
         SPACE 1                                                        03600017
*   SMPPI                                                               03800017
         SPACE 2                                                        04000017
*ENTRY POINTS:                                                          04200017
         SPACE 1                                                        04400017
*        ENTRY IER9BO              ENTRY FROM IERRC9                    04600017
*                                    CALLING SEQUENCE-                  04800017
*                                      LOAD  EP=IERABM,DCB=SORTLIB      05000017
*                                      LR    RP,RA                      05200017
*INPUT: PPI FIELDS REFERENCED-                                          05400017
         SPACE 1                                                        05600017
*                                      BALR  RO,RP                      05800017
         SPACE 2                                                        06000017
*   PPISTDCB                                                            06200017
*   PPIATP3E                                                            06400017
         SPACE 1                                                        06600017
*   ADDRESS OF DCBS IN GENERATED CORE AND ADDRESS OF ATTACHED EXIT      06800017
         SPACE 2                                                        07000017
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             07200017
         SPACE 1                                                        07400017
*   PPIX35                                                              07600017
         SPACE 1                                                        07800017
*   IF ATTACHED WILL HAVE ATTACHED ADDRESS                              08000017
         SPACE 2                                                        08200017
*EXTERNAL ROUTINES:                                                     08400017
         SPACE 1                                                        08600017
*   NONE                                                                08800017
         SPACE 2                                                        09000017
*EXTERNAL PARAMETERS:                                                   09200017
         SPACE 1                                                        09400017
*   SEE REGISTERS                                                       09600017
         SPACE 2                                                        09800017
*EXITS: NORMAL                                                          10000017
         SPACE 1                                                        10200017
*   TO IERRC9                      EXIT TO IERRC9                       10400017
*                                    CALLING SEQUENCE-                  10600017
*                                      BR   RO                          10800017
         SPACE 2                                                        11000017
*EXITS: ERROR                                                           11200017
         SPACE 1                                                        11400017
*   NONE                                                                11600017
         SPACE 2                                                        11800017
*TABLES/WORK AREAS:                                                     12000017
         SPACE 1                                                        12200017
*   NONE                                                                12400017
         SPACE 2                                                        12600017
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12800017
         SPACE 2                                                        13000017
*NOTES:                                                                 13200017
         SPACE 1                                                        13400017
*   THE MODULE IS EXECUTED FOR ANY VAR SPANNED OUTPUT SORT WITH E35     13600017
         EJECT                                                          13800017
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            14000017
         SPACE 1                                                        14200017
RA       EQU   0                   CONTENTS IN- N/A                     14400017
*                                  USE- NOT USED                        14600017
*                                  CONTENTS OUT- N/A                    14800017
RB       EQU   1                   CONTENTS IN- N/A                     15000017
*                                  USE- NOT USED                        15200017
*                                  CONTENTS OUT- N/A                    15400017
RC       EQU   2                   CONTENTS IN- N/A                     15600017
*                                  USE- NOT USED                        15800017
*                                  CONTENTS OUT- N/A                    16000017
RD       EQU   3                   CONTENTS IN- N/A                     16200017
*                                  USE- NOT USED                        16400017
*                                  CONTENTS OUT- N/A                    16600017
RE       EQU   4                   CONTENTS IN- N/A                     16800017
*                                  USE- GENERAL WORK REGISTER           17000017
*                                  CONTENTS OUT- N/A                    17200017
RF       EQU   5                   CONTENTS IN- N/A                     17400017
*                                  USE- NOT USED                        17600017
*                                  CONTENTS OUT- N/A                    17800017
RG       EQU   6                   CONTENTS IN- N/A                     18000017
*                                  USE- NOT USED                        18200017
*                                  CONTENTS OUT- N/A                    18400017
RH       EQU   7                   CONTENTS IN- N/A                     18600017
*                                  USE- NOT USED                        18800017
*                                  CONTENTS OUT- N/A                    19000017
RI       EQU   8                   CONTENTS IN- N/A                     19200017
*                                  USE- NOT USED                        19400017
*                                  CONTENTS OUT- N/A                    19600017
RJ       EQU   9                   CONTENTS IN- N/A                     19800017
*                                  USE- NOT USED                        20000017
*                                  CONTENTS OUT- N/A                    20200017
RK       EQU   10                  CONTENTS IN- N/A                     20400017
*                                  USE- BASE REGISTER FOR IERRBO DSECT  20600017
*                                  CONTENTS OUT- N/A                    20800017
RL       EQU   11                  CONTENTS IN- N/A                     21000017
*                                  USE- MODULE BASE REGISTER            21200017
*                                  CONTENTS OUT- N/A                    21400017
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT ADDR  21600017
*                                  USE- NOT USED                        21800017
*                                  CONTENTS OUT- EQUALS OR EXTRACT ADDR 22000017
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          22200017
*                                  USE- PPI REFERENCE,REGISTER SAVE     22400017
*                                    AREA                               22600017
*                                  CONTENTS OUT- ADDRESS OF PPI         22800017
RO       EQU   14                  CONTENTS IN - IERRC9 RETURN REG      23000017
*                                  USE- NOT USED                        23200017
*                                  CONTENTS OUT- IERRC9 RETURN REG      23400017
RP       EQU   15                  CONTENTS IN- THIS MODULE ENTRY PT    23600017
*                                  USE- ESTABLISH THIS MOD BASE REG     23800017
*                                  CONTENTS OUT- N/A                    24000017
         SPACE 2                                                        24200017
*START OF MODULE CODE PROPER:                                           24400017
         SPACE 2                                                        24600017
IER9BO   CSECT                                                          24800017
*0774                                                              4549 24900018
         USING *,RL                                                     25000017
         USING IER8BOD,RK          ADDR OF R.P. DSECT                   25200017
         USING IERRCA,RN                                                25400017
         USING DIERAMC,RJ          MESSAGE MOD BASE REG.                25600017
IERMB34  LR    RL,RP               LOAD MODULE BASE REG                 25800017
         L     RK,PPIBLK+4         ADDR OF IERRBO (R.P) FOR DSECT BASE  26000017
         L     RE,PPIBDSVA+12      STORE ADDRESS OF WORKAREA FOR VRE    26060017
         ST    RE,WOPBUFAD                   IN RUNNING PROGRAM         26120017
         ST    RE,PPIDOOBA                   AND FOR SEQUENCE CHECK     26160017
* CALCULATE ADDR OF OUTPUT DCB AND STORE IN R.P.                        26200017
         SPACE 1                                                        26400017
         L     RE,PPISTDCB         POINTER TO LIST OF DCB ADDRESSES     26600017
         L     RE,0(0,RE)         GET OUTPUT D C B ADDR.                26800017
         ST    RE,WDCB             STORE DCB ADDR IN R.P.               27000017
         L     RJ,PPIAMC+4         SET MESSAGE BASE REG.                27200017
         TM    PPISW1+6,X'01'      TEST DIAGNOSTIC SWITCH               27400017
         BNO   ABONOMES            SWITCH OFF BYPASS MESSAGE            27600017
         ST    RO,ABOSAVO          SAVE RO                              27800017
         L     RA,PPILAB04         LOAD ADDR OF OB1 FOR CONVERSION      28000017
         L     RP,PPICONV+4        LOAD ADDRESS OF CONVERSION ROUTINE   28200017
         BAL   RO,4(RP)            CONVERT                              28400017
         MVC   DMSG942A(8),0(RB)   PUT ADDRESS IN MESSAGE               28600017
         L     RA,PPILAB05         LOAD ADDRESS OF OB2 FOR CONVERSION   28800017
         L     RP,PPICONV+4        LOAD ADDRESS OF CONVERSION ROUTINE   29000017
         BAL   RO,4(RP)            CONVERT                              29200017
         MVC   DMSG942B(8),0(RB)   PUT ADDRESS IN MESSAGE               29400017
         LM    RA,RB,DMSG942X      SET UP FOR PRINTING                  29600017
         L     RP,PPIADSSC         LOAD ADDRESS OF PRINT ROUTINE        29800017
         BAL   RO,12(0,RP)         PRINT                                30000017
         L     RO,ABOSAVO          RESTORE RO                           30200017
ABONOMES CLC   PPIATP3E,KZERO      TEST IF ATTACHED EXIT                30400017
         BC    7,ABATTEXT          YES, BR TO ATTACH EXIT RTN           30600017
         SPACE 1                                                        30800017
* BRANCH TO NEXT ASSIGNMENT RTN                                         31000017
         SPACE 1                                                        31200017
ABENDMOD BR    RO                  RETURN TO IERRC9                     31400017
         SPACE 1                                                        31600017
ABATTEXT MVC   PPIX35+4(4),PPIATP3E SET EXIT E35 TO ATTACHED EXIT       31800017
         B     ABENDMOD            RETURN TO RC9                        32000018
         SPACE 2                                                        32200017
ABOSAVO  DC    F'0'                RETURN ADDR                          32400018
DIERAMC  DSECT                                                          32600017
*                                                                       32800017
       COPY  AMCMAIN                                                    33000017
         EJECT                                                          33200017
*MODULE NAME *** IER8BO *** USER EXIT E35  **** DUMMY MODULE            33400017
         SPACE 2                                                        33600017
*THIS MODULE HANDLES VAR. SPANNED LENGTH RCDS USING PUT IN MOVE MODE.   33800017
*   THE USER ROUTINE IS EXECUTED ONCE FOR EVERY RECORD LEAVING THE      34000017
*   MERGE. THE EXIT OCCURS AFTER THE RECORD TO BE PUT LEAVES THE MERGE. 34200017
*   THE USER MAY THEN DO THE FOLLOWING 1. INSERT A RECORD,2. DELETE OR  34400017
*   SUMMARIZE A RECORD,OR 3.DO NOTHING, ALTER, LENGTHEN, OR SHORTEN A   34600017
*   RECORD. THE USER RETURNS TO THE APPROPRIATE ROUTINE IN THIS MODULE. 34800017
*   THE MODULE LINKS TO THE PROPER DEBLOCK OR EOJ MODULE WHEN NEEDED.   35000017
         SPACE 1                                                        35200017
*   LINKAGE FROM MODULE TO USER IS VIA THE CALL MACRO                   35400017
*   LINKAGE FROM USER TO MODULE IS VIA RETURN REGISTER PLUS PROPER      35600017
*   DISPLACEMENT(DEPENDS ON WHAT RTN THE USER WISHES TO RETURN TO)      35800017
         SPACE 1                                                        36000017
*   TWO PARAMETERS ARE PASSED TO THE USER. THE ADDR OF THE RECORD       36200017
*   LEAVING THE MERGE, AND THE STARTING ADDRESS OF THE AREA IN THE      36400017
*   WORKAREA INTO WHICH THE PREVIOUS RECORD HAD BEEN PLACED.            36600017
         SPACE 1                                                        36800017
*   THE USER CAN PASS TWO PARAMETERS TO THE MODULE, THE ADDRESS OF THE  37000017
*   RECORD HE WISHES TO INSERT, DO NOTHING, ALTER, LENGTHEN, SHORTEN    37200017
*   IN RB, AND A 4 IF HE HAS CHANGED THE INTEGRITY OF THE CONTROL FIELD 37400017
*   OF THE RCD COMING FROM THE MERGE OR A ZERO IF HE HAS NOT, IN THE    37600017
*   THIRD PARAMETER OF THE PARAMETER LIST                               37800017
         SPACE 1                                                        38000017
*   THE MODULE PASSES THESE PARAMETERS TO THE MERGE FOR SEQUENCE        38200017
*   CHECKING AGAINST THE NEXT RECORD THE MERGE PASSES TO THE MODULE     38400017
         SPACE 1                                                        38600017
*   AT EOJ,MODULE ZEROS OUT PARAM 1 OF THE PARAM LIST TO USER           38800017
         SPACE 1                                                        39000017
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      39200017
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET                        39400017
         SPACE 2                                                        39600017
IER8BOD  DSECT                                                          39800017
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    40000017
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  40200017
         USING IHADCB,RF                                                40400017
         SPACE 1                                                        40600017
* ENTER BRANCH TABLE FROM MERGE OR READ PRIME RTN                       40800017
         SPACE 1                                                        41000017
IERDB34  B     RBSETREG            FROM MERGE,LAST RECORD, OR           41200017
*                                  FROM READ PRIME ZERO INPUT FILE      41400017
         LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     41600017
RBSETPAR ST    RD,WMRGRCD          SET PARAMETER 1 OF 2 FOR CALL MACRO  41800017
*                                    ADDR OF NEXT RCD FR MERGE TO PUT   42000017
         SPACE 1                                                        42200017
* CALL MACRO EXPANSION TO USER EXIT E35                                 42400017
         SPACE 1                                                        42600017
RBUSREXT LA    RB,WMRGRCD          PARAM LIST ADDR. WILL BE OVLAYED BY  42800017
*                                    B RBLOADRE ON USER EOF             43000017
         L     RP,PPIX35+4         IF ATTACHED ,PPIX35 WILL HAVE ADD    43200017
*                                    OF ATTACHED EXIT FROM PPI          43400017
         BALR  RO,RP               BR TO USER                           43600017
         SPACE 1                                                        43800017
* USER RETURNS TO MODULE VIA RETURN REG AND PROPER DISPLACEMENTS        44000017
         SPACE 1                                                        44200017
         B     *+4(15)             GO TO ENTRY POINT                    44400018
         B     RBALSHNO            BR TO ALTER,LENGTHN,SHRTN,NOTHG RTN  44600017
         B     RBDELSUM            BR TO DELETE-SUMMARIZE RTNE          44800017
         B     RBUSREOF            BR TO USER END OF FILE ROUTINE       45000017
         SPACE 1                                                        45200017
* INSERT A RECORD                                                       45400017
         SPACE 1                                                        45600017
RBINSRT1 OI    WINSRTSW,X'01'      TURN INSERT SWITCH ON                45800017
         LA    RINSERT,1(0,RINSERT)  INCR INSERT CTR BY ONE             46000017
         LA    RCDCTR,1(0,RCDCTR)  INCR RCD COUNTER BY ONE, ALSO        46200017
RBOVLAY  B     RBLOADRE            BR TO LOAD ADDR OF RCD FOR MOVE RTN  46400017
         SPACE 2                                                        46600017
* ALTER,LENGTHEN,SHORTEN,DO NOTHING TO THE INPUT RECORD FROM THE MERGE. 46800017
         SPACE 1                                                        47000017
RBALSHNO MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  47200017
*                                    FOR MERGE NETWORK SEQU CHECK       47400017
RBLOADRE MVC   WRCDLGTH+2(2),0(RB)  MOVE RCD LENGTH TO A BOUNDARY. RB   47600017
*                                     WILL BE OVLAYD BY RD ON USER EOF. 47800017
RBOVLAY1 LR    RE,RB               STORE ADDR OF RCD FROM THE MERGE IN  48000017
*                                    MOVE RTN REG. THIS INSTR WILL BE   48200017
*                                    OVLAYD BY LR RE,RD ON USER EOF     48400017
RBONOP   BC    15,RBOFIRST         CHANGED TO NOP BY FIRST RCD          48600017
         L     RA,WOPBUFAD         LOAD WORKAREA ADDRESS                48800017
         L     RF,WDCB             DCB ADDRESS                          49000017
         MVC   DCBLRECL(2),WRCDLGTH+2  RCD LENGTH                       49200017
         PUT   (RF),(RA)                                                49400017
         SPACE 1                                                        49600017
RBOMOVE  L     RF,WOPBUFAD                                              49800017
         STM   RG,RI,PPICOUNT      SAVE COUNTERS                        50000017
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           50200017
         SPACE 1                                                        50400017
* GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA     50600017
*   AREA TO ANOTHER, REGISTERS ARE USED AS FOLLOWS-                     50800017
         SPACE 1                                                        51000017
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  51200017
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    51400017
*        RI    DATA RCD LENGTH                                          51600017
         SPACE 1                                                        51800017
* IN ADDITION THE ROUTINE USES REGISTERS RG AND RH                      52000017
         SPACE 1                                                        52200017
         CL    RI,KON256           RCD LENGTH TO 256                    52400017
         BC    12,RBNMV020         LESS THAN OR EQUAL                   52600017
         SPACE 1                                                        52800017
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    53000017
         LNR   RG,RH                 256 BYTES EACH                     53200017
RBKMOVE  MVC   0(256,RF),0(RE)                                          53400017
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     53600017
         AR    RF,RH                 BYTES                              53800017
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    54000017
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 54200017
         SPACE 1                                                        54400017
KON256   DC    F'256'              CONSTANT 256                         54600018
KMOVE1   MVC   0(1,RF),0(RE)                                            54800017
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             55000017
         BCTR  RG,0                DECR RG BY ONE                       55200017
         EX    RG,KMOVE1                                                55400017
         SPACE 1                                                        55600017
* END OF GENERALIZED MOVE ROUTINE.                                      55800017
         SPACE 1                                                        56000017
         LM    RG,RI,PPICOUNT      RESTORE REGISTERS                    56200017
         CLI   WINSRTSW,X'00'      TEST INSERT SWITGH                   56400017
         BC    8,RBDOOBA           OFF,BR TO STORE ADDR OF OUTPUT RCD   56600017
*                                    IN PPI                             56800017
         NI    WINSRTSW,X'00'      TURN INSERT SWITCH OFF               57000017
         B     RBUSREXT            BR TO USER EXIT                      57200017
         SPACE 2                                                        57400017
RBDOOBA  LA    RCDCTR,1(0,RCDCTR)  INCREMENT RECORD CTR BY ONE          57600017
RBDEBLK  STM   RG,RI,PPICOUNT      SAVE COUNTERS                        57800017
         SPACE 1                                                        58000017
* INTERFACE TO DEBLOCK MODULE. PASS FILE NO OF WINNER IN HI BYTE OF RD  58200017
         SPACE 1                                                        58400017
         L     RL,PPIDEB+4         DEBLOCK ADDRESS                      58600017
         B     4(0,RL)             BR TO DEBLOCK MODULE                 58800017
         SPACE 2                                                        59000017
* LAST RECORD AND ZERO INPUT FILE ROUTINE                               59200017
         SPACE 1                                                        59400017
RBSETREG LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     59600017
         SR    RD,RD               ZERO WINNER REG(PARAM 1 TO USER)     59800017
         OI    WSYSEOF,X'01'       SET SYSTEM END OF FILE SWITCH        60000017
         CLI   WUSREOF,X'00'       TEST IF USER END OF FILE SWITCH ON   60200017
         BC    7,RBEOJ             ON,BR TO END OF JOB MODULE           60400017
         B     RBSETPAR            OFF,BR TO USER ROUTINE               60600017
         SPACE 2                                                        60800017
* USER END OF FILE ROUTINE                                              61000017
         SPACE 1                                                        61200017
RBUSREOF OI    WUSREOF,X'01'       SET USER END OF FILE SWITCH          61400017
         MVC   RBUSREXT,RBOVLAY    OVERLAY USER EXIT(BYPASS EXIT E35)   61600017
         MVI   RBLOADRE+4,X'30'    OVERLAY INSTR(CHANGES RB TO RD)      61800017
         MVI   RBOVLAY1+1,X'43'    OVERLAY INSTR(CHANGES RB TO RD)      62000017
         MVI   PPIDOUO+3,X'00'     RESET SWITCH SO MERGE WILL NOW SEQ   62200017
*                                    CHECK THE REST OF THE RCDS         62400017
         CLI   WSYSEOF,X'00'       TEST IF SYSTEM END OF FILE SWITCH ON 62600017
         BC    7,RBEOJ             ON, BR TO END OF JOB MODULE          62800017
         TM    PPISW1+3,X'04'      ATTACHED SORT                   4549 62860018
         BO    RBEOJ               IF YES BR TO EOJ                4549 62920018
         B     RBLOADRE            BR TO LOAD ADDR OF RCD IN RD         63000017
         SPACE 2                                                        63200017
* LINKAGE TO END OF JOB MODULE                                          63400017
RBEOJ    L     RF,WDCB            LOAD DCB ADDRESS                      63700017
         L     RA,WOPBUFAD                                              64000017
         PUT   (RF),(RA)                                                64200017
         L     RL,PPIWRT+4      END OF JOB ADDRESS                      64300017
         BR    RL                  EOJ EXIT TO MODULE NAMED IERRPG      64400017
         SPACE 2                                                        64600017
* DELETE OR SUMMARIZE A RECORD                                          64800017
         SPACE 1                                                        65000017
RBDELSUM LA    RDELSUMM,1(0,RDELSUMM)  INCR DELETE-SUMMARIZE CTR BY ONE 65200017
         CLC   PPICOUNT,KZERO      CHK IF ANY RCDS HAVE GONE THRU       65400017
         BE    RBAROUND            BR IF DELETING BEGINNING RCDS        65600017
         MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  65800017
*                                    FOR MERGE NETWORK SEQU CHECK       66000017
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         66200017
         SPACE 2                                                        66400017
RBAROUND MVC   PPIDOUO,KFOUR       NO SEQUENCE CHECK                    66600017
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         66800017
         SPACE 1                                                        66850017
RBOFIRST NI    RBONOP+1,X'00'                                           66900017
         BC    15,RBOMOVE          START MOVE                           67100018
         SPACE 2                                                        67430017
* LIST OF CONSTANTS TO BE USED OF MODULE                                67480017
KZERO    DC    F'0'                ZERO                                 67540018
KFOUR    DC    F'4'                FOUR                                 67600017
         SPACE 2                                                        67800017
* LIST OF WORK AREAS                                                    68000017
         SPACE 1                                                        70600017
WRCDLGTH DC    F'0'                RECORD LENGTH                        70800017
WMRGRCD  DC    F'0'                PARAM 1,ADDR OF NEXT RCD TO BE PUT   71000017
WOPBUFAD DC    F'0'                PARAM2, ADDR TO WORKAREA             71200018
WINTEGSW DC    F'0'                PARAM3,USER INTEGRITY SWITCH(0 =     71400017
*                                    SEQUENCE CHECK,4 = NO SEQU CHECK)  71600017
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR OUTPUT FILE 71800017
*                                    LOADED BY ASSGN RTN                72000017
WINSRTSW DC    X'00'               INSERT SWITCH                        72200017
WSYSEOF  DC    X'00'               SYSTEM END OF FILE SWITCH            72400017
WUSREOF  DC    X'00'               USER END OF FILE SWITCH              72600017
RINSERT  EQU   RI                                                       72800017
RDELSUMM EQU   RH                                                       73000017
RCDCTR   EQU   RG                                                       73200017
         SPACE 2                                                        73400017
         EJECT                                                          73600017
         SMPPI                                                          73800017
         EJECT                                                          74000017
         DCBD  DSORG=PS                                                 74200017
         END                                                            74400017
