         TITLE 'IER9GN - OS/360 SORT/MERGE - 360-SM-023   10/14/66'     00100013
*MODULE NAME *** IER9GN ***                                             00200013
         SPACE 2                                                        00300013
*STATUS: CHANGE LEVEL 000                                               00400013
         SPACE 2                                                        00500013
*MODULE FUNCTION/OPERATION'                                             00600013
*   THE FUNCTION OF THIS MODULE IS TO GENERATE ALL DCB'S, IOB'S,        00700013
*   ECB'S, AND ALTERNATE CCW POINTER SLOTS ASSOCIATED WITH PHASES       00800013
*   ONE AND TWO OF A CRISS-CROSS DISK SORT. THEY ARE CREATED IN         00900013
*   GENERATED CORE AS FOLLOWS:                                          01000013
*       ONE QSAM DCB FOR INPUT                                          01100013
*       ONE EXCP DCB FOR OUTPUT FOR EACH DISK AREA                      01200013
*       ONE IOB, ECB, AND ALTERNATE CCW POINTER FOR EACH DISK AREA      01300013
*   THE ADDRESS OF EACH DCB GENERATED IS PLACED IN A DCB ADDRESS        01400013
*   TABLE AND DCB OPEN LIST. IF THE ACTIVE BITS FOR ANY OR ALL OF       01500013
*   USER MODIFICATION EXITS E18, E28, E19, AND E29 ARE FOUND ON, THE    01600013
*   PARAMETERS FROM THE USER'S PROGRAM(S) ARE INCORPORATED INTO THE     01700013
*   DCB'S AND THE OPEN LIST.                                            01800013
         SPACE 2                                                        01900013
*USED AS A DSECT IN' N/A                                                02000013
         SPACE 2                                                        02100013
*MACROS USED -                                                          02200013
         SPACE 1                                                        02300013
*   ZMPPI                                                               02400013
*   DCB                                                                 02500013
*   DCBD                                                                02600013
         SPACE 2                                                        02700013
*ENTRY POINTS'                                                          02800013
*                                                                       02900013
*        ENTRY                     ENTRY FROM IERRC9                    03000013
*                                    CALLING SEQUENCE -                 03100013
*                                    LOAD EP=IER9GN,DCB=SORTLIB         03200013
*                                    LR   RP,RA                         03300013
*                                    BALR RO,RP   INITIAL ENTRY         03400013
*                                                                       03500013
*        ENTRY                     ENTRY FROM IERRCV                    03600013
*                                    CALLING SEQUENCE -                 03700013
*                                    BR   RO      AFTER PRINTING MSG.   03800013
         SPACE 2                                                        03900013
*INPUT PPI FIELDS REFERENCED -                                          04000013
         SPACE 1                                                        04100013
*   PPISPGN1   PPINDSKA   PPIDDSRT   PPILAB03   PPILAB06   PPISTAR      04200013
*   PPISW1     PPIMODEX   PPIEOF     PPIOPEN    PPIRCV     PPICONV      04300013
*   PPIAMA     PPIX18     PPIX19     PPIX28     PPIX29                  04400013
         SPACE 2                                                        04500013
*OUTPUT PPI FIELDS INITIALIZED OR ALTERED -                             04600013
         SPACE 1                                                        04700013
*   PPISPGN1   PPISTDCB   PPISTIOB                                      04800013
         SPACE 2                                                        04900013
*EXTERNAL ROUTINES - N/A                                                05000013
         SPACE 2                                                        05100013
*EXTERNAL PARAMETERS - N/A                                              05200013
         SPACE 2                                                        05300013
*EXITS-NORMAL:                                                          05400013
*                                                                       05500013
*   TO IERRC9 - NORMAL RETURN        CALLING SEQUENCE -                 05600013
*                                    BR   RO                            05700013
*                                                                       05800013
*   TO IERRCV TO PRINT MESSAGE       CALLING SEQUENCE -                 05900013
*                                    L    RP,PPIRCV+4                   06000013
*                                    BAL  RO,12(0,RP)                   06100013
         SPACE 2                                                        06200013
*EXITS-ERROR:                                                           06300013
         SPACE 1                                                        06400013
*        NONE                                                           06500013
         SPACE 2                                                        06600013
*TABLES/WORK AREAS:                                                     06700013
         SPACE 1                                                        06800013
*   WDCBADR - UPDATED ADDRESS OF DCB AREA IN CORE                       06900013
*   WECBADR - ADDRESS OF IOB/ECB AREA IN GENERATED CORE                 07000013
*   WFRSTERR - GENERAL USER EXIT SWITCH                                 07100013
*   WREGS - REGISTER SAVE AREA DURING PRINT ROUTINE                     07200013
*   WSAVAREA - GENERAL REGISTER SAVE AREA                               07300013
*   WIOBMDL - MODEL ECB AND IOB USED BY THE PROGRAM                     07400013
*   WEXCPDCB - MODEL OUTPUT EXCP DCB                                    07500013
*   WQSAMDCB - MODEL INPUT QSAM DCB                                     07600013
         SPACE 2                                                        07700013
*ATTRIBUTES: THIS IS A CLASS -A- MODULE                                 07800013
         SPACE 2                                                        07900013
*NOTES - NONE                                                           08000013
         EJECT                                                          08100013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            08200013
         SPACE 2                                                        08300013
RA       EQU   0                   CONTENTS IN- N/A                     08400013
*                                   USE- WORK REGISTER                  08500013
*                                   CONTENTS OUT - UNPREDICTABLE        08600013
         SPACE 1                                                        08700013
RB       EQU   1                   CONTENTS IN- N/A                     08800013
*                                   USE- WORK REGISTER                  08900013
*                                   CONTENTS OUT - UNPREDICTABLE        09000013
         SPACE 1                                                        09100013
RC       EQU   2                   CONTENTS IN- DCB ADDRESS             09200013
*                                   USE- WORK REGISTER                  09300013
*                                  CONTENTS OUT - UNPREDICTABLE         09400013
         SPACE 1                                                        09500013
RD       EQU   3                   CONTENTS IN- N/A                     09600013
*                                   USE- WORK REGISTER                  09700013
*                                  CONTENTS OUT - UNPREDICTABLE         09800013
         SPACE 1                                                        09900013
RE       EQU   4                   CONTENTS IN- N/A                     10000013
*                                   USE- WORK REGISTER                  10100013
*                                  CONTENTS OUT - UNPREDICTABLE         10200013
         SPACE 1                                                        10300013
RF       EQU   5                   CONTENTS IN- N/A                     10400013
*                                   USE- WORK REGISTER                  10500013
*                                  CONTENTS OUT - UNPREDICTABLE         10600013
         SPACE 1                                                        10700013
RG       EQU   6                   CONTENTS IN- N/A                     10800013
*                                   USE- WORK REGISTER                  10900013
*                                  CONTENTS OUT - UNPREDICTABLE         11000013
         SPACE 1                                                        11100013
RH       EQU   7                   CONTENTS IN- N/A                     11200013
*                                   USE- WORK REGISTER                  11300013
*                                  CONTENTS OUT - UNPREDICTABLE         11400013
         SPACE 1                                                        11500013
RI       EQU   8                   CONTENTS IN- N/A                     11600013
*                                   USE- NOT USED                       11700013
*                                  CONTENTS OUT - UNPREDICTABLE         11800013
         SPACE 1                                                        11900013
RJ       EQU   9                   CONTENTS IN- N/A                     12000013
*                                   USE- NOT USED                       12100013
*                                  CONTENTS OUT - UNPREDICTABLE         12200013
         SPACE 1                                                        12300013
RK       EQU   10                  CONTENTS IN- N/A                     12400013
*                                   USE- NOT USED                       12500013
*                                  CONTENTS OUT - UNPREDICTABLE         12600013
         SPACE 1                                                        12700013
RL       EQU   11                  CONTENTS IN- N/A                     12800013
*                                   USE- PROGRAM BASE REGISTER          12900013
*                                  CONTENTS OUT - UNPREDICTABLE         13000013
         SPACE 1                                                        13100013
RM       EQU   12                  CONTENTS IN- N/A                     13200013
*                                   USE- BASE REGISTER FOR DCB DSECT    13300013
*                                  CONTENTS OUT - UNPREDICTABLE         13400013
         SPACE 1                                                        13500013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          13600013
*                                   USE- PPI REFERENCE, REGISTER SAVE   13700013
*                                          AREA                         13800013
*                                   CONTENTS OUT- ADDRESS OF PPI        13900013
         SPACE 1                                                        14000013
RO       EQU   14                   CONTENTS IN- RETURN ADDRESS IN      14100013
*                                                IERRC9                 14200013
*                                   USE- BASE REG FOR PRINT MOD DSECT   14300013
*                                   CONTENTS OUT- RETURN ADDRESS IN     14400013
*                                                 IERRC9                14500013
         SPACE 1                                                        14600013
RP       EQU   15                   CONTENTS IN- ADDRESS OF ENTRY       14700013
*                                   USE- BASE REG FOR OPEN LIST DSECT   14800013
*                                   CONTENTS OUT- UNPREDICTABLE         14900013
         EJECT                                                          15000013
*START OF MODULE CODE PROPER:                                           15100013
         SPACE 2                                                        15200013
IER9GN   CSECT                                                          15300013
IER9GN   CSECT                                                          15400013
         USING *,RL                BASE REGISTER FOR THIS MODULE        15500013
         USING IHADCB,RM           BASE REGISTER FOR DCB DSECT          15600013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      15700013
         USING DIERAMA,RO          BASE REG FOR MESSAGE MODULE DSECT    15800013
         USING OPENLIST,RP         BASE REG FOR OPEN LIST DSECT         15900013
         SPACE 2                                                        16000013
         LR    RL,RP               LOAD BASE REGISTER                   16100013
         STM   RA,RP,WSAVAREA      SAVE REGISTERS                       16200013
         L     RP,PPIOPEN+4        BASE ADDRESS FOR OPEN LIST DSECT     16300013
         SPACE 2                                                        16400013
*        ALLOCATE CORE FOR IOBS, ECBS, DCBS, TABLES. SET UP POINTERS.   16500013
         SPACE 1                                                        16600013
         L     RB,PPISPGN1         STARTING ADDRESS OF GENERATED CORE   16700013
         LH    RE,PPINDSKA         LOAD NUMBER OF OUTPUT DCBS           16800013
         LA    RD,56               LOAD SIZE OF OUTPUT DCBS AND         16900013
         MR    RC,RE                 MULTIPLY                           17000013
         SR    RC,RC               ZERO REG                      A26453 17040019
         STH   RC,WINSIZE          STORE IN WORK AREA            A26453 17080019
         MVC   WINSIZE(2),PPIDCBIN        GET SIZE OF DCB        A26453 17120019
         AH    RD,WINSIZE          ADD SIZE OF INPUT DCB         A26453 17160019
         SR    RB,RD               UPDATE ADDRESS OF GENERATED CORE     17200013
         ST    RB,WDCBADR          SAVE ADDRESS OF DCB AREA             17300013
         NI    WDCBADR+3,X'FC'    ROUND TO FULL WORD BOUNDARY           17400013
         L     RB,WDCBADR                                               17500013
         ST    RB,OPENLIST+4      MOVE AD OF INPUT DCB INTO OPEN LIST   17600013
         SPACE 1                                                        17700013
         LA    RD,48               LOAD SIZE OF ECBS AND IOBS           17800013
         MR    RC,RE               MULTIPLY BY NUMBER OF DISK AREAS     17900013
         SR    RB,RD               UPDATE ADDRESS OF GENERATED CORE     18000013
         ST    RB,WECBADR          SAVE ADDRESS OF IOB AREA             18100013
         SPACE 1                                                        18200013
         LA    RE,1(RE)            ADD ONE FOR QSAM INPUT DCB           18300013
         ST    RE,OPENLIST        STORE NUMBER IN OPEN LIST             18400013
         SLL   RE,2                MULTIPLY BY FOUR                     18500013
         SR    RB,RE               UPDATE ADDRESS OF GENERATED CORE     18600013
         ST    RB,PPISTDCB         SAVE FOR ADDRESS OF DCB TABLE        18700013
         ST    RB,PPISPGN1         SAVE UPDATED GEN CORE ADDRESS        18800013
         MVC   0(4,RB),WDCBADR     MOVE AD OF INPUT DCB INTO DCB AD TBL 18900013
         SPACE 2                                                        19000013
*        IF DIAGNOSTICS, PRINT OUT ADDRESS OF DCB TABLE                 19100013
         SPACE 1                                                        19200013
         TM    PPISW1+6,X'01'      IS DIAGNOSTICS SWITCH ON?            19300013
         BZ    GN01                IF SWITCH OFF, BYPASS MESSAGE        19400013
         LR    RA,RB               LOAD NUMBER TO BE CONVERTED          19500013
         L     RP,PPICONV+4        LOAD ADDRESS OF CONVERSION ROUTINE   19600013
         BAL   RO,4(RP)           BRANCH TO HAVE NUMBER CONVERTED       19700013
         SPACE 1                                                        19800013
         L     RO,PPIAMA+4         ADDRESS OF MESSAGE MODULE            19900013
         MVC   DMSG906A(8),3(RB)   MOVE NUMBER INTO MESSAGE             20000013
         LM    RA,RB,DMSG906X      SET UP PARAMS FOR PRINTING           20100013
         L     RP,PPIRCV+4         ADDRESS OF PRINT ROUTINE             20200013
         BAL   RO,12(RP)           GO TO PRINT RTN                      20300018
         SPACE 2                                                        20400013
*        SET INDICATOR BIT IN FIRST BYTE OF ALL DCB ADR TABLE SLOTS     20500013
         SPACE 1                                                        20600013
GN01     L     RB,PPISTDCB         ADDRESS OF DCB TABLE                 20700013
         LA    RB,4(RB)           UPDATE TO BYPASS INPUT DCB ENTRY      20800013
         LH    RC,PPINDSKA         NUMBER OF DISK AREAS                 20900013
         L     RD,KSIGNBIT         SET SIGN BIT ON                      21000013
         SPACE 1                                                        21100013
GN02     ST    RD,0(RB)            SET SIGN BIT IN DCB TABLE ENTRY      21200013
         BCT   RC,GN03             IF MORE ENTRIES, BRANCH              21300013
         B     GN04                GO TO GEN INPUT DCB                  21400018
         SPACE 1                                                        21500013
GN03     LA    RB,4(RB)            UPDATE POINTER                       21600013
         B     GN02                GO TO SET SIGN BIT IN DCB TAB ENTRY  21700018
         SPACE 2                                                        21800013
*        GENERATE INPUT DCB                                             21900013
         SPACE 1                                                        22000013
GN04     LA    RM,WQSAMDCB         SET UP BASE REG FOR IHADCB           22100013
         MVC   DCBDDNAM(4),PPIDDSRT MOVE IN DD NAME                     22200013
         MVC   DCBBUFNO(1),PPILAB03 MOVE IN NUMBER OF OUTPUT BUFFERS    22300013
         MVC   DCBBUFCB+1(3),PPILAB06+1 MOVE IN ADDRESS OF BUFFER POOL  22400013
         MVC   DCBBUFL(2),PPILAB03+2 MOVE IN SIZE OF INPUT BUFFER       22500013
         MVC   DCBBFTEK+1(3),PPIEOF+5 MOVE IN EOD ADDRESS               22600013
         MVI   DCBEROPT,X'20'     ERROR OPTION = ABORT PROBRAM          22700013
         L     RB,PPIRCV+4                                              22800013
         MVC   DCBSYNAD(4),24(RB)  MOVE IN ADDRESS OF ERROR ROUTINE     22900013
         TM    PPISW1+1,X'08'      IS THERE INPUT DATA CHAINING?        23000013
         BO    GN05                BRANCH IF YES                        23100013
         SPACE 1                                                        23200013
         MVI   DCBBFTEK,X'40'      USE SIMPLE BUFFERING                 23300013
         TM    PPIMODEX+2,X'02'   IS IT VRE INPUT                       23330017
         BO    GNVRE               GO GET MOVE MODE                     23360018
         OI    DCBMACR,X'48'       USE GET LOCATE MODE                  23400013
         B     GN06                GO TEST FOR FULL BUF ALIGNMENT       23460018
GNVRE    OI    DCBMACR,X'50'      GET  MOVE MODE                        23530017
         B     GN06                GO TEST FOR FULL BUF ALIGNMENT       23560018
         SPACE 1                                                        23600013
GN05     MVI   DCBBFTEK,X'10'      USE EXCHANGE BUFFERING               23700013
         OI    DCBMACR,X'44'       USE GET SUBSTITUTE MODE              23800013
         SPACE 1                                                        23900013
GN06     TM    PPISW1+4,X'01'      FULL WORD BUFFER ALIGNMENT           24000013
         BO    GN07                BRANCH IF YES                        24100013
         SPACE 1                                                        24200013
         OI    DCBBFTEK,X'02'      DOUBLE WORD BUFFER ALIGNMENT         24300013
         B     GN08                GO TEST FOR USER MODIFICATION E18    24400018
         SPACE 1                                                        24500013
GN07     OI    DCBBFTEK,X'01'      FULL WORD BUFFER ALIGNMENT           24600013
         SPACE 1                                                        24700013
GN08     TM    PPIMODEX,X'08'      USER MODIFICATION EXIT E18           24800013
         BZ    GN17               BRANCH ON NO                          24900013
         SPACE 2                                                        25000013
*        BRANCH TO USER MODIFICATION EXIT E18                           25100013
         SPACE 1                                                        25200013
         L     RP,PPIX18+4         LOAD ADDRESS OF USER EXIT E18        25300013
         BALR  RO,RP               BRANCH TO USER E18                   25400018
         SPACE 2                                                        25500013
*        RETURN POINT FROM THE USER MODIFICATION PROGRAM                25600013
         SPACE 1                                                        25700013
         LA    RC,TBRANCH          LOAD ADDRESS OF BRANCH TABLE         25800013
         LA    RD,TLDADR           LOAD ADDRESS OF LOAD ADDRESS TABLE   25900013
GN09     SR    RE,RE                                                    26000013
         IC    RE,0(RB)            LOAD OPTION NUMBER                   26100013
         LTR   RE,RE               ARE THERE MORE OPTIONS?              26200013
         BZ    GN17                BRANCH ON NO                         26300013
         CL    RE,KFOUR            CHECK OPTION FOR LEGALITY            26400013
         BNH   GN10                BRANCH IF LEGAL                      26500013
         LA    RH,GN13             LOAD RETURN ADDRESS FROM ERROR RTN   26600013
         B     GN15                BRANCH TO ERROR ROUTINE              26700013
         SPACE 1                                                        26800013
GN10     SLL   RE,2                CONVERT OPTION NUMBER TO INDEX       26900013
         EX    0,0(RE,RD)          EXECUTE PROPER LOAD ADDRESS INSTRUC  27000013
         AR    RE,RC               ADD INDEX TO ADDRESS OF BRANCH TBL   27100013
         BR    RE                  GO TO BRANCH TAB                     27200018
         SPACE 2                                                        27300013
*        BRANCH TABLE USED BY PROGRAM                                   27400013
         SPACE 1                                                        27500013
TBRANCH  DC    F'0'                B   T                                27600018
         B     GN12                 R   A                               27700018
         B     GN12                  A   B                              27800018
         B     GN14                   N   L                             27900018
         B     GN11                    CH  E                            28000018
         SPACE 2                                                        28100013
*        LOAD ADDRESS TABLE USED BY PROGRAM                             28200013
         SPACE 1                                                        28300013
TLDADR   DC    F'0'                LA TABLE                             28400018
         LA    RG,DCBSYNAD+1                                            28500013
         LA    RG,DCBEXLST+1                                            28600013
         LA    RG,DCBEROPT                                              28700013
         L     RG,PPIEOF+4                                              28800013
         SPACE 1                                                        28900013
GN11     LA    RG,9(RG)            UPDATE ADDRESS TO PROPER LOCATION    29000013
GN12     MVC   0(3,RG),1(RB)       MOVE ADDRESS INTO PROPER LOCATION    29100013
GN13     LA    RB,4(RB)            UPDATE POINTER TO USER LIST          29200013
         B     GN09                GO THRU LOOP AGAIN                   29300013
         SPACE 1                                                        29400013
GN14     MVC   0(1,RG),3(RB)       MOVE ERROR OPTION INTO SORT EOD RTN  29500013
         B     GN13                GO TO UPDATE PTR TO USER LST         29600018
         SPACE 2                                                        29700013
*        SET UP ERROR PRINTOUT FOR PRINT MODULE IF FIRST ERROR          29800013
         SPACE 1                                                        29900013
GN15     TM    WFRSTERR,X'01'      FIRST ERROR OPTION?                  30000013
         BO    GN13                BRANCH ON NO                         30100013
         MVI   WFRSTERR,X'01'      ON YES, SET INDICATOR                30200013
         L     RO,PPIAMA+4         LOAD BASE REG FOR MESSAGE MOD DSECT  30300013
         MVC   DCBERREX+16(2),KTAG MOVE '18' INTO ERROR MESSAGE         30400013
GN16     STM   RP,RH,WREGS         SAVE REGISTERS                       30500013
         LM    RA,RB,DCBERAEX      LOAD ADDRESS OF PARAMETERS           30600013
         L     RP,PPIRCV+4         LOAD ADDRESS OF PRINT ROUTINE        30700013
         BAL   RO,12(RP)           GO TO PRINT RTN                      30800018
         SPACE 2                                                        30900013
*        RETURN POINT FROM PRINT MODULE                                 31000013
         SPACE 1                                                        31100013
         LM    RP,RH,WREGS         RESTORE REGISTERS                    31200013
         BR    RH                  RETURN TO WORK ON EXIT E18 PARAMS    31300013
         SPACE 2                                                        31400013
*        MODIFICATION COMPLETE, RETURN TO MAIN PROGRAM                  31500013
         SPACE 1                                                        31600013
GN17     MVI   WFRSTERR,X'00'      RESTORE FIRST OPTION ERROR INDICATOR 31700013
         TM    PPIMODEX+1,X'80'    USER MODIFICATION EXIT 28?           31800013
         BZ    GN22                BRANCH ON NO                         31900013
         SPACE 2                                                        32000013
*        BRANCH TO USER MODIFICATION EXIT E28                           32100013
         SPACE 1                                                        32200013
         L     RP,PPIX28+4         LOAD ADDRESS OF USER EXIT E28        32300013
         BALR  RO,RP               GO TO USER E28                       32400018
         SPACE 2                                                        32500013
*        RETURN POINT FROM USER MODIFICATION EXIT E28                   32600013
         SPACE 1                                                        32700013
GN18     CLI   0(RB),X'00'         ARE THERE MORE OPTIONS?              32800013
         BE    GN22                BRANCH ON NO                         32900013
         L     RP,PPIOPEN+4        LOAD BASE REG FOR OPEN LIST DSECT    33000013
         CLI   0(RB),X'01'         IS THERE A USER SYNAD OPTION?        33100013
         BE    GN20                BRANCH ON YES                        33200013
         CLI   0(RB),X'03'         IS THERE A USER EROPT OPTION?        33300013
         BE    GN21                BRANCH ON YES                        33400013
         BNH   GN19                BRANCH IF VALID OP CODE              33500013
         SPACE 2                                                        33600013
*        IF FIRST ERROR, SET UP ERROR PRINTOUT FOR PRINT MODULE         33700013
         SPACE 1                                                        33800013
         TM    WFRSTERR,X'01'      FIRST OPTION IN ERROR?               33900013
         BO    GN19                BRANCH ON NO                         34000013
         MVI   WFRSTERR,X'01'      ON YES, SET INDICATOR                34100013
         L     RO,PPIAMA+4         LOAD BASE REG FOR MESSAGE MOD DSECT  34200013
         MVC   DCBERREX+16(2),KTAG+2 MOVE '28' INTO ERROR MESSAGE       34300013
         BAL   RH,GN16             BRANCH TO BRANCH TO PRINT ROUTINE    34400013
         SPACE 1                                                        34500013
GN19     LA    RB,4(RB)            UPDATE POINTER TO USER PARAMS        34600013
         B     GN18                GO THRU LOOP AGAIN                   34700013
         SPACE 1                                                        34800013
GN20     MVC   AP1RD2+1(3),1(RB)   MOVE USER SYNAD INTO OPEN LIST       34900013
         B     GN19                DO I GO THRU THE LOOP AGAIN?         35000013
GN21     MVC   AP1RD2(1),3(RB)     MOVE USER EROPT INTO OPEN LIST       35100013
         B     GN19                DO I GO THRU THE LOOP AGAIN?         35200013
         SPACE 2                                                        35300013
*        ENTRIES MADE, RETURN TO MAIN PROGRAM AND MOVE DCB INTO         35400013
*          ALLOCATED CORE                                               35500013
         SPACE 1                                                        35600013
GN22     MVI   WFRSTERR,X'00'      RESTORE FIRST ERROR OPTION INDICATOR 35700013
         L     RD,WDCBADR          ADDRESS OF DCB AREA                  35800013
         MVC   0(96,RD),WQSAMDCB  MOVE DCB INTO ALLOCATED CORE          35900013
         LA    RD,96(RD)           UPDATE ADDRESS OF DCB AREA           36000013
         ST    RD,WDCBADR          SAVE                                 36100013
         SPACE 2                                                        36200013
*        GENERATE OUTPUT EXCP DCBS                                      36300013
         SPACE 1                                                        36400013
GN23     LA    RM,WEXCPDCB         BASE ADDRESS FOR IHADCB DSECT        36500013
         MVC   DCBDDNAM(4),PPIDDSRT                                     36600013
         TM    PPISW1+1,X'04'      IS THERE OUTPUT DATA CHAINING?       36700013
         BO    GN24                BRANCH ON YES                        36800013
         SPACE 1                                                        36900013
         MVI   DCBBFTEK,X'40'      USE SIMPLE BUFFERING                 37000013
         B     GN25                GO TEST FOR FULL WORD BUF ALIGNMENT  37100018
         SPACE 1                                                        37200013
GN24     MVI   DCBBFTEK,X'10'      USE EXCHANGE BUFFERING               37300013
GN25     TM    PPISW1+4,X'01'      FULL WORD BUFFER ALIGNMENT?          37400013
         BO    GN26                BRANCH ON YES                        37500013
         SPACE 1                                                        37600013
         OI    DCBBFTEK,X'02'      USE DOUBLE WORD BUFFER ALIGNMENT     37700013
         B     GN27                GO TEST FOR 2311                     37800018
         SPACE 1                                                        37900013
GN26     OI    DCBBFTEK,X'01'      USE FULL WORD BUFFER ALIGNMENT       38000013
GN27     TM    PPISW1+7,X'04'      IS THIS SORT USING 2311'S            38100013
         BO    GN28                BRANCH ON YES                        38200013
         SPACE 1                                                        38300013
         L     RB,K7294            INITIALIZE TRACK BALANCE FOR 2314    38400013
         STH   RB,DCBTRBAL         NUMBER OF BYTES PER TRACK = 7294     38500013
         B     GN29                GO TEST IF USER E19 IS ACTIVATED     38600018
         SPACE 1                                                        38700013
GN28     LA    RB,3625             INITIALIZE TRACK BALANCE FOR 2311    38800013
         STH   RB,DCBTRBAL         NUMBER OF BYTES PER TRACK = 3625     38900013
GN29     TM    PPIMODEX+1,X'02'    IS USER EXIT E19 ACTIVATED           39000013
         BZ    GN34                BRANCH ON NO                         39100013
         SPACE 2                                                        39200013
*        BRANCH TO USER MODIFICATION EXIT E19                           39300013
         SPACE 1                                                        39400013
         L     RP,PPIX19+4         LOAD ADDRESS OF USER EXIT E19        39500013
         BALR  RO,RP               BRANCH TO E19                        39600018
         SPACE 1                                                        39700013
GN30     CLI   0(RB),X'00'         ARE THERE MORE OPTIONS?              39800013
         BE    GN34                BRANCH ON NO                         39900013
         CLI   0(RB),X'01'         IS THERE A USER SYNAD OPTION?        40000013
         BE    GN32                BRANCH ON YES                        40100013
         CLI   0(RB),X'02'         IS THERE A USER EXLST OPTION?        40200013
         BE    GN33                BRANCH ON YES                        40300013
         SPACE 2                                                        40400013
*        IF FIRST ERROR, SET UP ERROR PRINTOUT FOR PRINT MODULE         40500013
         SPACE 1                                                        40600013
         TM    WFRSTERR,X'01'      FIRST ERROR OPTION                   40700013
         BO    GN31                BRANCH ON NO                         40800013
         OI    WFRSTERR,X'01'      ON YES, SET INDICATOR                40900013
         L     RO,PPIAMA+4         LOAD BASE RES FOR MESSAGE MOD DSECT  41000013
         MVC   DCBERREX+16(2),KTAG+4 MOVE '19' INTO ERROR MESSAGE       41100013
         BAL   RH,GN16             BRANCH TO BRANCH TO PRINT ROUTINE    41200013
         SPACE 2                                                        41300013
*        ARE THERE MORE OPTIONS?                                        41400013
         SPACE 1                                                        41500013
GN31     TM    WFRSTERR,X'10'      IS THIS THE SECOND TIME THRU LOOP?   41600013
         BO    GN34                BRANCH ON YES                        41700013
         OI    WFRSTERR,X'10'      SET ONCE THRU LOOP INDICATOR         41800013
         LA    RB,4(RB)            UPDATE POINTER TO USER PARAMS        41900013
         B     GN30                GO THRU LOOP AGAIN                   42000013
         SPACE 1                                                        42100013
GN32     L     RP,PPIOPEN+4        LOAD BASE REG FOR OPEN LIST DSECT    42200013
         MVC   AP1WRT1+1(3),1(RB)  MOVE USER SYNAD INTO OPEN LIST       42300013
         B     GN31                DO I GO THRU LOOP AGAIN?             42400013
         SPACE 1                                                        42500013
GN33     MVI   WFRSTERR+1,X'FF'    SET USER EXIT E19 EXLST SWITCH       42600013
         MVC   DCBEXLST+1(3),1(RB) STORE EXLST AD IN MODEL DCB          42700013
         B     GN31                DO I GO THRU LOOP AGAIN?             42800013
         SPACE 2                                                        42900013
*        ENTRIES MADE, RETURN TO MAIN PROGRAM                           43000013
         SPACE 1                                                        43100013
GN34     MVI   WFRSTERR,X'00'      RESTORE FIRST ERROR OPTION INDICATOR 43200013
         TM    PPIMODEX+1,X'01'    USER EXIT E29 ACTIVATED?             43300013
         BZ    GN39                BRANCH ON NO                         43400013
         SPACE 2                                                        43500013
*        BRANCH TO USER MODIFICATION EXIT E29                           43600013
         SPACE 1                                                        43700013
         L     RP,PPIX29+4         LOAD ADDRESS OF USER EXIT E29        43800013
         BALR  RO,RP               BRANCH TO E29                        43900018
         SPACE 1                                                        44000013
         L     RP,PPIOPEN+4        ADDRESS OF OPEN LIST                 44100013
GN35     CLI   0(RB),X'00'         ARE THERE MORE OPTIONS?              44200013
         BE    GN39                BRANCH ON NO                         44300013
         CLI   0(RB),X'01'         IS THERE A USER SYNAD OPTION?        44400013
         BE    GN37                BRANCH ON YES                        44500013
         CLI   0(RB),X'02'         IS THERE A USER EXLST OPTION?        44600013
         BE    GN38                BRANCH ON YES                        44700013
         SPACE 2                                                        44800013
*        IF FIRST ERROR, SET UP ERROR PRINTOUT FOR PRINT MODULE         44900013
         SPACE 1                                                        45000013
         TM    WFRSTERR,X'01'      FIRST ERROR OPTION?                  45100013
         BO    GN36                BRANCH ON NO                         45200013
         OI    WFRSTERR,X'01'      ON YES, SET INDICATOR                45300013
         L     RO,PPIAMA+4         LOAD BASE REG OF MESSAGE MOD DSECT   45400013
         MVC   DCBERREX+16(2),KTAG+6 MOVE '29' INTO ERROR MESSAGE       45500013
         BAL   RH,GN16             BRANCH TO BRANCH TO PRINT ROUTINE    45600013
         SPACE 2                                                        45700013
*        ARE THERE MORE OPTIONS?                                        45800013
         SPACE 1                                                        45900013
GN36     TM    WFRSTERR,X'10'      IS THIS THE SECOND TIME THRU LOOP?   46000013
         BO    GN39                BRANCH ON YES                        46100013
         OI    WFRSTERR,X'10'      SET ONCE THRU LOOP INDICATOR         46200013
         LA    RB,4(RB)            UPDATE POINTER TO USER PARAMS        46300013
         B     GN35                GO THRU LOOP AGAIN                   46400013
         SPACE 1                                                        46500013
GN37     MVC   AP1WRT2+1(3),1(RB) MOVE USER SYNAD INKO OPEN LIST        46600013
         B     GN36                DO I GO THRU LOOP AGAIN?             46700013
         SPACE 1                                                        46800013
GN38     TM    WFRSTERR+1,X'FF'    WAS USER EXIT E19 EXLST SWITCH SET?  46900013
         BO    GN36                IF ON, IGNORE. GO THRU LOOP AGAIN    47000013
         MVC   DCBEXLST+1(3),1(RB) OTHERWISE, STORE EXLST AD IN DCB     47100013
         B     GN36                DO I GO THRU LOOP AGAIN?             47200013
         SPACE 2                                                        47300013
*        ENTRIES MADE, RETURN TO MAIN AND SET UP PARAMS FOR LOOP        47400013
         SPACE 1                                                        47500013
GN39     LH    RA,PPINDSKA         LOAD NUMBER OF OUTPUT DCBS TO GEN    47600013
         SR    RB,RB                                                    47700013
         L     RC,WECBADR          LOAD ADDRESS OF ECB/IOB AREA IN CORE 47800013
         L     RD,WDCBADR          LOAD ADDRESS OF DCB AREA IN CORE     47900013
         LR    RF,RC                                                    48000013
         LA    RF,8(RF)            LOAD ADDRESS OF FIRST IOB            48100013
         L     RG,PPISTDCB         LOAD ADDRESS OF DCB ADDRESS TABLE    48200013
         LA    RH,PPISTAR          LOAD ADDRESS OF DISK ADDRESS TABLE   48300013
         L     RP,PPIOPEN+4                                             48400013
         SPACE 2                                                        48500013
*        LOOP TO FINISH GENERATING WORK DCBS AND IOBS AND MOVE THEM     48600013
*        INTO GENERATED CORE                                            48700013
         SPACE 1                                                        48800013
GN40     ST    RC,WECBPTR          STORE ECB ADDRESS IN MODEL IOB       48900013
         ST    RD,WDCBPTR          STORE DCB ADDRESS IN MODEL IOB       49000013
         MVC   0(48,RC),WIOBMDL   MOVE MODEL ECV/IOB INTO CORE          49100013
         ST    RF,DCBIOBAD         STORE IOB ADDRESS IN MODEL EXCP DCB  49200013
         IC    RB,0(RH)            INSERT INCREMENT FOR THIS WORK UNIT  49300013
         STC   RB,DCBCHECK        STORE INCREMENT IN DCB                49400013
         MVC   DCBFDAD+1(7),1(RH)  MOVE DISK ADDRESS INTO DCB           49500013
         ST    RD,0(RB,RG)         STORE DCB ADDRESS IN DCB ADDRESS TBL 49600013
         ST    RD,OPENLIST+4(RB)  STORE DCB ADDRESS IN OPEN LIST        49700013
         SRL   RB,1                DIVIDE INCRE BY 2 TO ACCESS ID TABLE 49800013
         LH    RE,KTABLE(RB)       LOAD SORT WORK NUMBER FOR THIS DCB   49900013
         STH   RE,DCBDDNAM+6       STORE SORTWK IDENTITY NUMBER         50000013
         MVC   0(56,RD),0(RM)      MOVE MODEL DCB INTO ALLOCATED CORE   50100013
         BCT   RA,GN41            DO I GO THRU LOOP AGAIN?              50200013
         SPACE 2                                                        50300013
*        RETURN TO CALLING ROUTINE                                      50400013
         SPACE 1                                                        50500013
         ST    RF,PPISTIOB         SAVE ADDRESS OF FIRST OUTPUT IOB     50600013
         LM    RA,RP,WSAVAREA      RESTORE REGISTERS                    50700013
         BR    RO                  RETURN TO LOAD ROUTINE               50800013
         SPACE 2                                                        50900013
*        UPDATE POINTERS TO GO THRU LOOP AGAIN                          51000013
         SPACE 1                                                        51100013
GN41     LA    RC,48(RC)          UPDATE ECB/IOB AREA PTR               51200013
         LA    RD,56(RD)           UPDATE DCB AREA PTR                  51300013
         LA    RF,48(RF)          UPDATE IOB PTR                        51400013
         LA    RH,8(RH)            UPDATE PTR TO DISK ADDRESS TABLE     51500013
         B     GN40                GO THRU LOOP AGAIN                   51600013
         SPACE 2                                                        51700013
*        LIST OF CONSTANTS USED BY THIS PROGRAM                         51800013
         SPACE 1                                                        51900013
KFOUR    DC    F'4'                USED TO TEST VALID USER OPTION CODE  52000013
K7294    DC    F'7294'             NUMBER OF BYTES PER 2314 TRACK       52100013
KSIGNBIT DC    X'80000000'         SIGN BIT                             52200018
KTABLE   DC    C'000102030405060708' NUMBERS FOR SORTWK DCB'S           52300013
         DC    C'091011121314151617'   DDNAME FIELD                     52400013
KTAG     DC    C'18281929'         USER EXIT NUMBER PUT IN ERROR MSG    52500013
         SPACE 2                                                        52600013
*        LIST OF WORK AREAS USED BY THIS MODULE                         52700013
         SPACE 1                                                        52800013
WDCBADR  DC    F'0'                UPDATED ADDRESS OF DCB AREA IN CORE  52900013
WECBADR  DC    F'0'                ADDRESS OF IOB/ECB AREA IN GEN CORE  53000013
WFRSTERR DC    F'0'                GENERAL USER EXIT SWITCH             53100013
WINSIZE  DC    H'0'                SIZE OF DCB (QSAM)            A26453 53150019
WREGS    DC    9F'0'               REG SAVE AREA DURING PRINT ROUTINE   53200013
WSAVAREA DC    16F'0'              GENERAL REGISTER SAVE AREA           53300013
         SPACE 2                                                        53400013
*        IOB MODEL USED BY PROGRAM                                      53500013
         SPACE 1                                                        53600013
WIOBMDL  DC    2F'0'               THE IOB IS PRECEDED BY A FULL WORD   53700013
         DC    X'40000000'           EVENT CONTROL BLOCK AND A FULL     53800013
WECBPTR  DC    4F'0'                 WORD FOR THE ALTERNATE CCW PTR     53900013
WDCBPTR  DC    2F'0'               D                                    54000018
         DC    X'80010000'          C                                   54100018
         DC    2F'0'                 B POINTER                          54200018
         SPACE 2                                                        54300013
*        OPEN LIST DSECT USED BY MODULE                                 54400013
         SPACE 1                                                        54500013
OPENLIST DSECT                                                          54600013
         DC    19F'0'              USED FOR STORAGE                     54700018
AP1RD2   DC    X'20000000'         USER SYNAD AND EROPT, READ - PH2     54800013
AP1WRT1  DC    F'0'                USER SYNAD, WRITE - PH1              54900013
AP1WRT2  DC    F'0'                USER SYNAD, WRITE - PH2              55000013
         SPACE 2                                                        55100013
*        MESSAGE MODULE DSECT. CONTAINS ALL MESSAGES REQUIRED BY PHASE  55200013
*        ONE ASSIGNMENT MODULES.                                        55300013
         SPACE 2                                                        55400013
*MODULE NAME *** IERAMA ***                                             55500013
*                                                                       55600013
DIERAMA  DSECT                                                          55700013
       COPY  AMAMAIN                                                    55800013
         SPACE 2                                                        55900013
*        MODEL DATA CONTROL BLOCKS USED BY PROGRAM                      56000013
         SPACE 1                                                        56100013
IER9GN   CSECT                                                          56200013
WEXCPDCB DCB   MACRF=(E),DSORG=PS,DDNAME=SORTWK                         56300013
         SPACE 1                                                        56400013
WQSAMDCB DCB   MACRF=(GL),DSORG=PS,DDNAME=SORTIN                        56500018
         SPACE 2                                                        56600013
*        DATA CONTROL BLOCK DSECT USED BY MODULE                        56700013
         SPACE 1                                                        56800013
         DCBD  DSORG=PS                                                 56900013
         SPACE 2                                                        57000013
         SMPPI                                                          57100013
         END                                                            57200013
