         TITLE '    IER9ON - OS/360 SORT/MERGE - 360S-SM023 11/21/66'   00060013
*MODULE NAME:*** IER9ON ***                                             00120013
         SPACE 2                                                        00180013
*STATUS: CHANGE LEVEL 000                                               00240013
         SPACE 2                                                        00300013
*MODULE FUNCTION/OPERATION:   THIS IS THE ASSIGNMENT MODULE FOR IER8ON. 00360013
*   IT DETERMINES THE AMOUNT OF CORE NEEDED FOR THE TABLE,  THE FREE    00420013
*   TRACK LIST(FTL),  AND THE POOL(USED FOR WORK AREAS CONTAINING MORE  00480013
*   THAN 9 SEGMENTS),  AND INITIALIZES THE TABLE PROPER AND THE FREE    00540013
*   TRACK LIST.  CONSTANTS USED BY THE RUNNING PROGRAM ARE DETERMINED   00600013
*   AND PASSED TO THE RUNNING PROGRAM.                                  00660013
         SPACE 2                                                        00720013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT - N/A          00780013
         SPACE 2                                                        00840013
*MACRO'S USED:                                                          00900013
         SPACE 1                                                        00960013
*   SMPPI                                                               01020013
         SPACE 2                                                        01080013
*ENTRY POINTS:                                                          01140013
         SPACE 1                                                        01200013
*        ENTRY                     ENTRY FROM:  IERRC9                  01260013
*                                    CALLING SEQUENCE-                  01320013
*                                       LOAD EP=IER9ON,DCB=SORTLIB      01380013
*                                       LR   RP,RA                      01440013
*                                       BALR RO,RP                      01500013
         SPACE 2                                                        01560013
*INPUT: PPI FIELDS REFERENCED-                                          01620013
         SPACE 1                                                        01680013
*   PPISTAR    PPISPGN1  PPINDSKA                                       01740013
*   PPIENDAR   PPIDEPHO  PPIALG                                         01800013
         SPACE 2                                                        01860013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             01920013
         SPACE 1                                                        01980013
*   PPIDEPHO - FIRST CYLINDER/TRACK ADDRESS FOR WRITE ROUTINE           02040013
*   PPISPGN1 - NEXT AVAILABLE ADDRESS IN GENERATED CORE.                02100013
         SPACE 2                                                        02160013
*EXTERNAL ROUTINES:      N/A                                            02220013
         SPACE 2                                                        02280013
*EXTERNAL PARAMETERS:                                                   02340013
         SPACE 1                                                        02400013
*   REGISTER RO - RETURN ADDRESS OF IERRC9.                             02460013
*   REGISTER RN - ADDRESS OF PPI.                                       02520013
         SPACE 2                                                        02580013
*EXITS: NORMAL - MODULE HAS COMPLETED ASSIGNMENT FUNCTION.              02640013
         SPACE 1                                                        02700013
*   TO IERRC9            RETURN PROCEDURE -                             02760013
*                        -BR   RO                                       02820013
         SPACE 2                                                        02880013
*EXITS: ERROR -          N/A                                            02940013
         SPACE 2                                                        03000013
*TABLES/WORK AREAS:                                                     03060013
         SPACE 1                                                        03120013
*   KRWLNM4    EXPANSION OF HALFWORDS TO FULLWORDS SUITABLE FOR         03180013
*              REGISTER LOADING.                                        03240013
*                                                                       03300013
*   CONSTANTS (SEE 'LIST OF CONSTANTS' AT END OF PROGRAM.)              03360013
         SPACE 2                                                        03420013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  03480013
         SPACE 2                                                        03540013
*NOTES: A DSECT OF IER8ON IS USED IN THIS PROGRAM.                      03600013
         EJECT                                                          03660013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            03720013
         SPACE 1                                                        03780013
RA       EQU   0                   CONTENTS IN- N/A                     03840013
*                                                                       03900013
*                                  USE- NOT USED                        03960013
*                                                                       04020013
*                                  CONTENTS OUT- N/A                    04080013
*                                                                       04140013
RB       EQU   1                   CONTENTS IN- N/A                     04200013
*                                                                       04260013
*                                  USE- SIZE OF POOL/FTL                04320013
*                                                                       04380013
*                                  CONTENTS OUT- N/A                    04440013
*                                                                       04500013
RC       EQU   2                   CONTENTS IN- N/A                     04560013
*                                                                       04620013
*                                  USE- NUMBER OF BYTES PER ROW.        04680013
*                                                                       04740013
*                                  CONTENTS OUT- N/A                    04800013
*                                                                       04860013
RD       EQU   3                   CONTENTS IN- N/A                     04920013
*                                                                       04980013
*                                  USE- ADDRESS OF POOL AREA.           05040013
*                                                                       05100013
*                                  CONTENTS OUT- N/A                    05160013
*                                                                       05220013
RE       EQU   4                   CONTENTS IN- N/A                     05280013
*                                                                       05340013
*                                  USE- ADDRESS OF FREE TRACK LIST(FTL) 05400013
*                                                                       05460013
*                                  CONTENTS OUT- N/A                    05520013
*                                                                       05580013
RF       EQU   5                   CONTENTS IN- N/A                     05640013
*                                                                       05700013
*                                  USE- ADDRESS OF PPISTAR              05760013
*                                                                       05820013
*                                  CONTENTS OUT- N/A                    05880013
*                                                                       05940013
RG       EQU   6                   CONTENTS IN- N/A                     06000013
*                                                                       06060013
*                                  USE- ADDRESS OF FTL ROW IN TABLE.    06120013
*                                                                       06180013
*                                  CONTENTS OUT- N/A                    06240013
*                                                                       06300013
RH       EQU   7                   CONTENTS IN- N/A                     06360013
*                                                                       06420013
*                                  USE- ADDRESS OF PPIENDAR.            06480013
*                                                                       06540013
*                                  CONTENTS OUT- N/A                    06600013
*                                                                       06660013
RI       EQU   8                   CONTENTS IN- N/A                     06720013
*                                                                       06780013
*                                  USE- ADDRESS OF TABLE                06840013
*                                                                       06900013
*                                  CONTENTS OUT- N/A                    06960013
*                                                                       07020013
RJ       EQU   9                   CONTENTS IN- N/A                     07080013
*                                                                       07140013
*                                  USE- SIZE OF FTL AREA + POOL.        07200013
*                                                                       07260013
*                                  CONTENTS OUT- N/A                    07320013
*                                                                       07380013
RK       EQU   10                  CONTENTS IN- N/A                     07440013
*                                                                       07500013
*                                  USE- SIZE OF TABLE PROPER.           07560013
*                                                                       07620013
*                                  CONTENTS OUT- N/A                    07680013
*                                                                       07740013
RL       EQU   11                  CONTENTS IN- N/A                     07800013
*                                                                       07860013
*                                  USE- MODULE BASE REGISTER            07920013
*                                                                       07980013
*                                  CONTENTS OUT- N/A                    08040013
*                                                                       08100013
RM       EQU   12                  CONTENTS IN- N/A                     08160013
*                                                                       08220013
*                                  USE- BASE REGISTER FOR DSECT OF      08280013
*                                       IER8ON                          08340013
*                                  CONTENTS OUT- N/A                    08400013
*                                                                       08460013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          08520013
*                                                                       08580013
*                                  USE- PPI REFERENCE,REGISTER SAVE     08640013
*                                    AREA                               08700013
*                                  CONTENTS OUT- ADDRESS OF PPI         08760013
*                                                                       08820013
RO       EQU   14                  CONTENTS IN - ADDRESS OF IERRC9.     08880013
*                                                                       08940013
*                                  USE- TO RETURN TO IERRC9.            09000013
*                                                                       09060013
*                                  CONTENTS OUT- N/A                    09120013
*                                                                       09180013
RP       EQU   15                  CONTENTS IN- CORE ADDRESS OF IER9ON  09240013
*                                                                       09300013
*                                  USE- NUMBER OF DISK WORK AREAS.      09360013
*                                                                       09420013
*                                  CONTENTS OUT- N/A.                   09480013
*                                                                       09540013
         EJECT                                                          09600013
*START OF MODULE CODE PROPER:                                           09660013
         SPACE 2                                                        09720013
IER9ON   CSECT                                                          09780013
*                                                                A27990 09810000
         USING *,RL                                                     09840013
         LR    RL,RP               MODULE BASE REGISTER.           31F2 09900013
         USING DIER8ON,RM          IER8ON BASE                          09960013
         USING IERRCA,RN           PPI BASE                             10020013
         SPACE 2                                                        10080013
* ASTERISK PRECEDING COMMENT INDICATES PARAMETER PASSED TO R.P.         10140013
* TABLE WIDTH(BYTES PER ROW) = 4(M+1)+4.  (M = MERGE ORDER)             10200013
* TABLE SIZE = 12(4(M+1)+4)                                             10260013
* POOL AREA + FREE TRACK LIST = 2((M+1)(40))                            10320013
* AREA TAKEN FROM GENERATED CORE = TABLE + POOL + FREE TRACK LISTS.     10380013
         SPACE 2                                                        10440013
         SPACE 1                                                        10500013
NO9SIZE1 LH    RP,PPINDSKA         GET M+1.                             10560013
         STC   RP,PPIBDSVA         STORE NUMBER OF DISK AREAS           10620013
         LH    RC,PPIMRGMX         GET MERGE ORDER                      10680013
         STH   RC,PPIMRGOP         STORE IT IN MERGE OP                 10740013
         LR    RC,RP                                                    10800013
         SLL   RC,2                MULT BY 4.                           10860013
         LA    RC,4(0,RC)          DETERMINE BYTES PER ROW              10920013
         L     RM,PPIALG+4         GET BASE FOR RUNNING PROGRAM.        10980013
         ST    RC,KBYPEROW        *PASS TABLE WIDTH TO RUNNING PROG     11040013
         LR    RD,RC               SAVE BYTES/ROW.                      11100013
         BCTR  RD,0                                                     11160013
         SPACE 1                                                        11220013
         STH   RD,KBPRLS1         *PASS BYTES/ROW -1.                   11280013
         BCTR  RD,0                                                     11340013
         STH   RD,KBPRLS2         *PASS BYTES/ROW -2.                   11400013
         BCTR  RD,0                                                     11460013
         STH   RD,KBPRLS3         *PASS BYTES/ROW -3.                   11520013
         BCTR  RD,0                                                     11580013
         STH   RD,KBPRLS4         *PASS BYTES/ROW -4.                   11640013
         SPACE 1                                                        11700013
         SH    RD,K9MTWO                                                11760013
         STH   RD,KBPRLS6         *PASS BYTES/ROW -6.                   11820013
         SPACE 1                                                        11880013
         LA    RB,12                                               31G2 11940013
         MR    RA,RC               SIZE OF TABLE.                       12000013
         LR    RK,RB               SAVE TABLE SIZE.                     12060013
         SPACE 1                                                        12120013
NO9SIZE2 LA    RB,80                                                    12180013
         MR    RA,RP               SIZE OF POOL + FREE TRACK LIST       12240013
         LR    RJ,RB               SAVE SIZE OF POOL + FTL.             12300013
         SRL   RB,1                SIZE OF POOL(ALSO SIZE OF FTL)       12360013
         STH   RB,KPOOLSZ         *PASS POOL SIZE TO 8ON.               12420013
         SPACE 1                                                        12480013
* TOTAL AREA TO BE TAKEN FROM GENERATED CORE(TABEL + POOL + FTL)        12540013
         SPACE 1                                                        12600013
NO9GCSUB L     RI,PPISPGN1         NEXT AVAILABLE ADDR IN GEN CORE 31H2 12660013
         N     RI,KRNDOFF          PUT ON FULLWORD BOUNDARY.            12720013
         LR    RH,RK               GET TABLE SIZE.                      12780013
         AR    RH,RJ               TOTAL CORE                           12840013
         SR    RI,RH               NEW GEN CORE STARTING ADDRESS.       12900013
         ST    RI,PPISPGN1         UPDATE PPI.                          12960013
         ST    RI,KTABLEX         *ALSO PASS START OF TABLE TO 8ON 31J2 13020013
         ST    RI,KTBLMZON        *ADDR OF ROW PRECEDING L = 0 ROW.     13080013
*  ADDITIONAL CORE TAKEN FROM GENERATED CORE FOR FREE POOL       A27990 13085000
*  LIST AREA =(4*(M+1))                                          A27990 13090000
         SR    RE,RE                                             A27990 13095000
         L     RE,PPISPGN1         NEXT AVAILABLE ADDR IN GEN CO A27990 13100000
         N     RE,KRNDOFF          ALIGNE TO FULLWORD BNDRY      A27990 13105000
         LR    RF,RP               LOAD M+1 VALUE                A27990 13110000
         MH    RF,K9MFOUR          FREE POOL LIST LNG            A27990 13115000
         SR    RE,RF               NEW GEN CORE START ADDR       A27990 13120000
         ST    RE,PPISPGN1         UPDATE PPI                    A27990 13125000
         SH    RE,K9MFOUR          POINT TO LIST -4              A27990 13130000
         ST    RE,KFPPTR           KEEP ADDR TO FREE POOL LST    A27990 13135000
         SPACE 1                                                        13140013
* CLEAR TABLE PROPER TO ZERO.                                           13200013
         SPACE 1                                                        13260013
         LR    RF,RP               GET M + 1.                           13320013
         LA    RF,1(0,RF)          SET CNTR FOR MOVE RTN AT M + 2.      13380013
         LR    RE,RI               GET ADDRESS OF TABLE.                13440013
NO9CLEAR MVI   0(RE),X'00'         SET FIRST BYTE FOR PROPAGATION       13500013
         MVC   1(48,RE),0(RE)      SET ONE 48 BYTE BLOCK TO ZERO.       13560013
         LA    RE,48(0,RE)         UP ADDRESS TO NEXT BLOCK.            13620013
         BCT   RF,NO9CLEAR         FALL OUT WHEN 48(M+2) BYTES SET.     13680013
         SPACE 1                                                        13740013
NO9FTLAD LR    RD,RB               GET SIZE OF FTL AREA.           31G4 13800013
         AR    RD,RK               FTL + TABLE.                         13860013
         AR    RD,RI               ADDR OF TBL +(TBL+FTL)= ADDR OF POOL 13920013
         ST    RD,KPOOL           *PASS ADDR OF POOL.                   13980013
         LR    RE,RC               GET BYTES PER ROW.                   14040013
         AR    RE,RI               END ADDRESS OF 1ST ROW.              14100013
         SH    RE,K9MFOUR                                               14160013
         ST    RE,KRWLNM4          END ADDR OF 1ST ROW -4.              14220013
         L     RE,KBYPEROW         GET BYTES PER ROW                    14280013
         A     RE,KTABLEX          DETERMINE L = 0 ROW ADDRESS.         14340013
         ST    RE,KTABLEX0        *PASS L = 0 ROW TO 8ON.               14400013
         ST    RE,KTABLEL         *PASS AGAIN.                          14460013
         SPACE 1                                                        14520013
NO9MFIG  BCTR  RP,0                M = WORK AREAS - 1                   14580013
         LR    RH,RP                                                    14640013
         MR    RG,RP               M SQUARED.                      31G3 14700013
         ST    RH,KMSQURD         *PASS M SQUARED TO R.P.               14760013
         ST    RP,KMERGORD        *PASS M TO R.P.                  31F3 14820013
         BCTR  RP,0                                                     14880013
         ST    RP,KMOMONE         *PASS M - 1 TO R.P.                   14940013
         SPACE 1                                                        15000013
* DETERMINE TYPE OF DEVICE                                              15060013
         SPACE 1                                                        15120013
NO9DVTYP TM    PPISW1+7,X'04'      2314 OR 2311...                      15180013
         BO    NO9D2311            -ON, IT'S A 2311 USING 2314 B&G.     15240013
         SPACE 1                                                        15300013
         LH    RH,K2314TRK         -OFF, IT'S A 2314.                   15360013
         STH   RH,KMXTRK          *PASS TRKS PER CYLN TO 8ON.           15420013
         LH    RH,K2314CMP         GET THE COMPLEMENT -1(X'EC')         15480013
         STH   RH,KMXTRKCP        *PASS COMPLEMENT -1 TO R.P.           15540013
         B     NO9FTLRW                                                 15600013
         SPACE 2                                                        15660013
NO9D2311 LH    RH,K2311TRK                                              15720013
         STH   RH,KMXTRK          *PASS TRKS PER CYLN TO 8ON            15780013
         LH    RH,K2311CMP         GET COMPLEMENT -1(X'F6')             15840013
         STH   RH,KMXTRKCP        *PASS TO R.P.                         15900013
         SPACE 1                                                        15960013
* DETERMINE ADDRESS OF LAST ROW IN TABLE(CONTAINS POINTERS TO FTL'S)    16020013
         SPACE 1                                                        16080013
NO9FTLRW LR    RG,RK               GET TABLE SIZE.                      16140013
         AR    RG,RI               ADDR OF 1 ROW BEYOND FTL ROW.        16200013
         SR    RG,RC               ADDR OF FTL ROW.                     16260013
         SH    RG,K9MFOUR          ADDRESS OF FTL ROW -4.               16320013
         ST    RG,KFRTRKLT        *PASS THIS TO R.P.                    16380013
         SPACE 1                                                        16440013
* INITIALIZE HIGH NO. AND LOW NO. COLUMNS OF TABLE.                     16500013
         SPACE 1                                                        16560013
         L     RG,KRWLNM4          GET ROW LENGTH -4.              31H3 16620013
         AR    RG,RC               ADDR OF L = 0 ROW -4.                16680013
         MVC   0(4,RG),KTBLSET0    INITIALIZE HI-LO PORTION OF L = 0.   16740013
         LA    RH,9                SET COUNTER.                         16800013
NO9STBL  AR    RG,RC               UP POINTER TO NEXT ROW END -4.       16860013
         MVC   0(4,RG),KTBLSET9    INITIALIZE NEXT ROW.                 16920013
         BCT   RH,NO9STBL          FALL OUT WHEN ALL ROWS DONE.         16980013
         SPACE 1                                                        17040013
         LA    RG,4(0,RG)          UP POINTER TO FTL ROW.               17100013
         LH    RP,PPINDSKA         RESET TO NO. OF DISK AREAS.          17160013
         LR    RE,RG                                                    17220013
         AR    RE,RC               POINTER TO FIRST FREE TRK LIST  31J3 17280013
         SPACE 1                                                        17340013
* INITIALIZE FREE TRACK LIST ROW AND FREE TRACK LISTS.             31F4 17400013
         SPACE 1                                                        17460013
         ST    RE,0(0,RG)          SET POINTER IN FTL ROW.              17520013
         MVI   0(RG),X'01'         SET AREA AVAIL BYTE TO 1.            17580013
         SPACE 1                                                        17640013
         LA    RF,PPISTAR          PPISTAR = MBBCCHHR.                  17700013
         LA    RH,PPIENDAR                                              17760013
         SPACE 1                                                        17820013
         MVC   PPIDEPHO(8),0(RF)  *PASS FIRST AREA TO WRITE RTN.   31H4 17880013
         MVI   PPIDEPHO,X'04'      SET REAL INCR FOR FIRST AREA.        17940013
         MVI   PPIDEPHO+1,X'04'    SET LOGICAL INCR.                    18000013
         MVI   PPIDEPHO+7,X'01'    SET RECORD NO.                       18060013
         MVC   1(1,RI),4(RF)       SET 'C'(OF MCHD) IN TABLE.      31J4 18120013
         MVC   2(1,RI),6(RF)       SET 'H'(OF MCHD) IN TABLE.           18180013
         MVI   0(RI),X'04'         SET 'M'(OF MCHD) IN TABLE.           18240013
         MVI   3(RI),X'00'         SET 'D'(OF MCHD) IN TABLE.           18300013
         SPACE 1                                                        18360013
* SET FIRST ENTRY IN FIRST FREE TRACK LIST TO REFLECT REQUIREMENTS FOR  18420013
* WRITE RTN AND END-OF-AREA MARKER                                      18480013
         SPACE 1                                                        18540013
* INCREASE FIRST START TRACK BY 1.                                 31K4 18600013
         SPACE 1                                                        18660013
NO9UPDT  SR    RJ,RJ                                                    18720013
         ST    RJ,KRWLNM4          CLEAR WORK AREA                      18780013
         MVC   KRWLNM4+2(2),1(RI)  EXPAND START 'CH' TO FULLWORD.       18840013
         L     RJ,KRWLNM4                                               18900013
         CLC   KRWLNM4+3(1),KMXTRK+1    START TRK LAST ONE ON CYLN...   18960013
         BNE   NO9UPDT1                 -NO, JUST ADD ONE TO STARTING   19020013
*                                        TRACK                          19080013
         SPACE 1                                                        19140013
         AH    RJ,KMXTRKCP              -YES, BRING TRK ADR TO 'FF'.    19200013
NO9UPDT1 AH    RJ,K9ONE                 UP TRACK ADDR BY 1.             19260013
         STH   RJ,0(RE)            SET START 'CH' AT TOP OF FTL.        19320013
         SPACE 1                                                        19380013
* SUBTRACT ONE TRACK FROM END OF FIRST AREA FOR END-OF-AREA MARKER.     19440013
         SPACE 1                                                        19500013
NO9UPDT2 MVC   KRWLNM4+2(1),4(RH)  GET END CYLN FROM PPIENDAR           19560013
         MVC   KRWLNM4+3(1),6(RH)  GET END TRK FROM PPIENDAR.           19620013
         L     RJ,KRWLNM4                                               19680013
         CLI   KRWLNM4+3,X'00'     ENDING TRK FIRST ONE ON CYLN...      19740013
         BNE   NO9UPDT3            -NO, JUST SUBTRACT ONE.              19800013
         SPACE 1                                                        19860013
         SH    RJ,KMXTRKCP         -YES, DECR BY 'EC'(OR 'F6').         19920013
NO9UPDT3 BCTR  RJ,0                SUBTRACT 1 FOR END-OF-AREA MARKER.   19980013
         STH   RJ,2(RE)            PLACE AREA ENDING CYLN/TRK IN FTL.   20040013
         BCTR  RP,0                DECR NO. OF LISTS REMAINING.         20100013
         SPACE 1                                                        20160013
* INITIALIZE REMAINING LISTS IN FREE TRACK LIST.                        20220013
         SPACE 1                                                        20280013
NO9UPDT4 LA    RG,4(0,RG)          ADDR OF NEXT PTR IN FTL.             20340013
         LA    RE,40(0,RE)         ADDR OF NEXT LIST.                   20400013
         LA    RF,8(0,RF)          NEXT STARTING AREA(IN PPISTAR).      20460013
         LA    RH,8(0,RH)          NEXT ENDING CYL/TRK(IN PPIENDAR).    20520013
         SPACE 1                                                        20580013
         ST    RE,0(0,RG)          PLACE PTR TO FTL IN FTL ROW.         20640013
         MVI   0(RG),X'01'         SET NO. OF AVAIL AREAS IN FTL PTR.   20700013
         MVC   0(1,RE),4(RF)       START CYLN OF NEXT AREA IN FTL.      20760013
         MVC   1(1,RE),6(RF)       START TRACK OF AREA INTO FTL.        20820013
         SPACE 1                                                        20880013
* SUBTRACT ONE TRACK FROM END OF EACH AREA FOR END OF AREA MARKER.      20940013
         SPACE 1                                                        21000013
         MVC   KRWLNM4+2(1),4(RH)  EXPAND END CYLN/TRK TO FULLWORD.     21060013
         MVC   KRWLNM4+3(1),6(RH)                                       21120013
         L     RJ,KRWLNM4                                               21180013
         CLI   KRWLNM4+3,X'00'     ENDING TRK FIRST ONE ON CYLN...      21240013
         BNE   NO9UPDT5            -NO, JUST SUBTRACT 1.                21300013
         SPACE 1                                                        21360013
         SH    RJ,KMXTRKCP         -YES, DECR BY 'EC'(OR 'F6').         21420013
NO9UPDT5 BCTR  RJ,0                SET TO NEW ENDING TRK.               21480013
         STH   RJ,2(RE)            PLACE ENDING CYLN-TRK IN FTL.        21540013
         BCT   RP,NO9UPDT4         DO NEXT AREA.                        21600013
         SPACE 1                                                        21660013
NO9CMPLT BR    RO                  RETURN TO IERRC9.               31K5 21720013
         SPACE 1                                                        21780013
* LIST OF CONSTANTS                                                     21840013
         SPACE 1                                                        21900013
         DS    0F                  ALIGN                                21960013
KRNDOFF  DC    X'7FFFFFFC'         ALIGN TO FULLWORD MASK               22020013
KRWLNM4  DC    F'0'                WORK AREA                            22080013
KTBLSET0 DC    X'02000100'         HI-LO CONSTANT, L = 0 ROW            22140013
KTBLSET9 DC    X'01000100'         HI-LO CONSTANT, L = 1-9 ROW.         22200013
K2311TRK DC    X'0009'             2311 TRACKS PER CYLINDER.            22260013
K2314TRK DC    X'0013'             2314 TRACKS PER CYLINDER.            22320013
K2311CMP DC    X'00F6'        TRKS/CYLN PLUS THIS = FF.(2311)           22380013
K2314CMP DC    X'00EC'        TRKS/CYLN PLUS THIS = FF (2314)           22440013
K9MFOUR  DC    X'0004'                                                  22500013
K9ONE    DC    X'0001'                                                  22560013
K9MTWO   DC    X'0002'                                                  22620013
         EJECT                                                          22680013
DIER8ON  DSECT                                                          22740013
         USING *,RL                MODULE BASE REGISTER                 22800013
         USING IERRCA,RN           PPI BASE REGISTER                    22860013
         USING DIERRMA,RM          BASE REGISTER FOR MESSAGE MODULE     22920013
         SPACE 2                                                        22980013
*MODULE ENTRY TABLE:                                               3AC3 23040013
         SPACE 1                                                        23100013
         B     ONEOF               FROM WRITE AT EOF (SIM. OR REAL)     23160013
         B     ONCHNADR            FROM WRITE FOR CHAIN ADDRESS         23220013
         B     ONWRTEOS            FROM WRITE AT EOS (PH1 OR PH2)  3BB2 23280013
         B     ONEXRD              FROM NETWORK INITIALIZATION     3BB3 23340013
         B     ONRDTREL            FROM READ TO RELEASE A TRACK         23400013
         B     ONRDEOS             FROM READ AT EOS                     23460013
         SPACE 2                                                        23520013
ONWRTEOS STM   RC,RD,WSAVE1        SAVE RC AND RD                       23580013
         LM    RC,RI,WSAVE         RESTORE REGISTERS                    23640013
         TM    PPISW1+2,X'08'      ARE WE MERGING                  3BC2 23700013
         BO    ONRCDCHK            BRANCH IF YES                        23760013
         BAL   RK,ONREORD          GO REORDER THIS LIST            3BD2 23820013
         SPACE 2                                                        23880013
         LM    RJ,RK,WSEQTOTL                                           23940013
         LA    RJ,1(0,RJ)          ADD 1 TO TOTAL SEQUENCES        3BE2 24000013
         LA    RK,1(0,RK)          ADD 1 TO SEQUENCE CTR. (THIS PHASE)  24060013
         STM   RJ,RK,WSEQTOTL      SAVE TOTALS                          24120013
         CL    RJ,KMSQURD          M SQUARED +1 SEQUENCES YET      3BF2 24180013
         BH    ONMSQPLS            BRANCH IF YES                        24240013
         LA    RD,1(0,RD)          SET I=I+1                       3BG2 24300013
         CL    RD,KMERGORD         IS I NOW LARGER THAN MRG ORD    3BH2 24360013
         BNH   ONGETADR            BRANCH IF NO                         24420013
         SR    RD,RD               SET I=0 IF YES                       24480013
ONGETADR LR    RB,RD               PUT I INCREMENT IN RB                24540013
         BAL   RK,ONGETTRK         BRANCH AND LINK TO GET AN ADR   3BH3 24600013
         SPACE 2                                                        24660013
         BAL   RK,ONCOMPAC         GO PUT DISK ADR IN 4 BYTE FORMAT     24720013
         SPACE 2                                                        24780013
         MVC   PPIDEPHO(8),PPIWKARE      MOVE DISK ADR TO DEPHO    3BJ3 24840013
         LR    RK,RD               LOAD I INTO RH                       24900013
         SLL   RK,2                RK=I X 4                             24960013
         LA    RO,4(0,RK)          GET LOGICAL INCREMENT                25020013
         STC   RO,PPIDEPHO+1       STORE IT                             25080013
         ST    RJ,0(RF,RK)         PUT IN FIRST ROW OF TABLE UNDER I    25140013
         L     RK,WSEQCTR                                               25200013
ONEXIT1  STM   RC,RE,WSAVE         SAVE J, I AND L                      25260013
         LM    RC,RD,WSAVE1                                             25320013
         CL    RK,KMOMONE          DOES SEQ CTR=M-1                3BK4 25380013
         BE    ONMTHSEQ            BRANCH IF YES                        25440013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    25500013
         L     RL,PPIDEB+4                                              25560013
         B     8(0,RL)             BRANCH TO DEBLOCK               3BK5 25620013
         SPACE 2                                                        25680013
ONMTHSEQ L     RL,PPIINT+4                                              25740013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    25800013
         B     8(0,RL)             BRANCH TO NET INIT-MTH SEQ      3BK3 25860013
         SPACE 2                                                        25920013
ONMSQPLS SH    RC,KONE             SET J=J-1                       3BF3 25980013
         BNM   ONGETDA             BRANCH UNLESS IT IS MINUS       3BG3 26040013
         L     RC,KMERGORD         SET J=MERGE ORDER               3BG4 26100013
ONGETDA  LR    RB,RC               SET RB=J                             26160013
         BAL   RK,ONGETTRK         BRANCH AND LINK TO GET AN ADR   3BH4 26220013
         SPACE 2                                                        26280013
         MVC   PPIDEPHO(8),PPIWKARE      MOVE DISK ADR TO DEPHO    3BJ4 26340013
         LR    RM,RC               LOAD J INTO RM                       26400013
         SLL   RM,2                RM=J X 4                             26460013
         LA    RK,4(0,RM)          GET LOGICAL INCREMENT                26520013
         STC   RK,PPIDEPHO+1       STORE IT                             26580013
         BAL   RK,ONCOMPAC         GO PUT DISK ADR IN 4 BYTE FORMAT     26640013
         SPACE 2                                                        26700013
         ST    RJ,0(RF,RM)         PUT IN FIRST ROW OF TABLE UNDER J    26760013
         B     ONEXIT1-4           BRANCH TO EXIT                       26820013
         SPACE 2                                                        26880013
*   THIS SUBROUTINE TAKES THE 8 BYTE DISK ADDRESS FROM PPIWKARE AND     26940013
*   COMPACTS IT INTO 4 BYTES FOR THE ALGORITHM TABLE.                   27000013
         SPACE 1                                                        27060013
ONCOMPAC IC    RJ,PPIWKARE         REAL INCREMENT                       27120013
         SLL   RJ,8                                                     27180013
         IC    RJ,PPIWKARE+4       CYLINDER                             27240013
         SLL   RJ,8                                                     27300013
         IC    RJ,PPIWKARE+6       HEAD                                 27360013
         SLL   RJ,8                ZERO OUT LO ORDER BYTE               27420013
         BR    RK                  RETURN                               27480013
         SPACE 2                                                        27540013
*   THIS SEGMENT OF CODE IS ENTERED AFTER EVERY END OF SEQUENCE WHILE   27600013
*   MERGING                                                             27660013
         SPACE 1                                                        27720013
ONRCDCHK BAL   RK,ONRCDCNT         GO MAKE A CHECK ON RECORD COUNT 3BB1 27780013
         SPACE 1                                                        27840013
         MVI   WSWITCHD,X'00'      CLEAR 'ANOTHER MERGE PASS INDICATOR' 27900013
         TM    PPISW1+3,X'01'      HAVE WE REACHED REAL EOF        3BC1 27960013
         BNO   ONNOEOF             BRANCH IF NOT                        28020013
         TM    PPISW1+7,X'80'      HAVE WE REACHED E15 EOF              28080013
*                                    (WILL BE SET IF E15 NOT ACTIVE)    28140013
         BNO   ONNOEOF             BRANCH IF NO                         28200013
         LTR   RE,RE               DOES L = 0                      3BD1 28260013
         BZ    ONEQZERO            BRANCH IF YES                        28320013
         LR    RM,RE               PUT L IN RM                     3BE1 28380013
         BCT   RM,ONNOEOF          DOES IT = 1  BRANCH IF NO            28440013
         LH    RM,KBPRLS4          BYTES PER ROW OF TABLE-4             28500013
         L     RM,0(RM,RH)         GET INFO FROM L=1 ROW                28560013
         CL    RM,KONEONE          IS INFO=1010                         28620013
         BNE   ONNOEOF             BRANCH IF NO                         28680013
ONEQZERO L     RF,KTABLEX0         SET POINTER TO L=0 ROW          3BF1 28740013
         SR    RC,RC               ZERO FOR MERGE ORDER                 28800013
         SR    RB,RB               DON'T NEED TO SAVE REGS NOW     3BJ1 28860013
         MVC   PPIDSKED(136),PPIENDAR  MOVE FOR END OF PHASE ROUTINE    28920013
         LM    RG,RH,PPIDSKED+48   SAVE THESE 8 BYTES BECAUSE PPIWKARE  28980013
*                                    +128 (PPIDSKED+48) IS USED BY THE  29040013
*                                    SUBROUTINE AT ONEXPAND             29100013
         LA    RE,PPIENDAR         SET POINTER TO PPIENDAR              29160013
ONLOOP1  SR    RJ,RJ                                                    29220013
         A     RJ,0(RB,RF)         GET ENTRY FROM TABLE                 29280013
         BNZ   ONRELONE            BRANCH IF IT'S REAL                  29340013
ONNEXTRY LA    RB,4(0,RB)          UP POINTER TO NEXT ENTRY             29400013
         CH    RB,KBPRLS4          ARE WE THROUGH                       29460013
         BL    ONLOOP1             BRANCH IF NO                         29520013
         STH   RC,PPIMRGMX         STORE MERGE ORDER FOR PHASE 3   3BH1 29580013
         STM   RG,RH,PPIDSKED+48   RESTORE 8 BYTES                      29640013
         CLC   WSEQTOTL(4),KMERGORD  M SEQ. OR MORE                     29700013
         BH    ONDONE              GO EXIT TO RCV IF YES                29760013
         TM    PPISW1+3,X'80'      IS EQUALS BIT ON                     29820013
         BNO   ONDONE              GO EXIT TO RCV IF NO                 29880013
         MVC   ONEXRD(4),KOVERLA2  OVERLAY TO EXIT TO RCV UPON RETURN   29940013
         B     ONOFFA              GO EXIT TO NET. INIT.                30000013
ONDONE   LA    RB,4                INDICATE CALL PHASE 3           3BK1 30060013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    30120013
         L     RP,PPIADSSC                                              30180013
         B     20(0,RP)            GO TO END OF PHASE ENTRY OF RCV 3BK2 30240013
         SPACE 2                                                        30300013
ONRELONE BAL   RK,ONEXPAND         GO EXPAND ADDRESS TO 8 BYTES         30360013
         MVC   0(8,RE),PPIWKARE+128  MOVE ADDRESS INTO PPIENDAR         30420013
         LA    RE,8(0,RE)          UP PPIENDAR POINTER                  30480013
         LA    RC,1(0,RC)          UP MERGE ORDER BY 1                  30540013
         B     ONNEXTRY                                                 30600013
         SPACE 2                                                        30660013
*   THIS SUBROUTINE EXPANDS A 4 BYTE DISK ADDRESS,WHICH IT RECEIVES IN  30720013
*   REGISTER RJ,INTO AN 8 BYTE ADDRESS AT PPIWKARE+128. IT WILL CONTAIN 30780013
*   THE REAL AREA INCREMENT AND A 1 FOR RECORD NO. BUT WILL NOT CONTAIN 30840013
*   THE LOGICAL AREA INCREMENT.                                         30900013
         SPACE 1                                                        30960013
ONEXPAND STH   RJ,PPIWKARE+134     PUT IN TRACK NO.                     31020013
         MVI   PPIWKARE+135,1      PUT IN A 1 FOR RECORD NO.            31080013
         XC    PPIWKARE+128(6),PPIWKARE+128                             31140013
         SRL   RJ,16               POSITION CYLINDER NO.                31200013
         STC   RJ,PPIWKARE+132     PUT IN CYLINDER NO.                  31260013
         SRL   RJ,8                POSITION REAL INCREMENT              31320013
         STC   RJ,PPIWKARE+128     PUT IN REAL INCREMENT                31380013
         BR    RK                  RETURN                               31440013
         SPACE 2                                                        31500013
*   THIS ROUTINE IS ENTERED AFTER EVERY MERGE PASS EXCEPT THE LAST ONE  31560013
*   IN PHASE 2. THE FIRST PORTION WILL BE OVERLAID AT EOF.              31620013
         SPACE 1                                                        31680013
ONNOEOF  NI    PPISW1+7,X'F7'      TURN OFF 'MORE MERGE' BIT       3CB2 31740013
         BAL   RK,ONREORD          GO REORDER ALL FTL              3CC2 31800013
         SPACE 2                                                        31860013
         CLC   WSEQTOTL,KMSQURD    M SQUARED SEQUENCES YET         3CD2 31920013
         BH    ONMTMSQ             BRANCH IF MORE THAN M SQUARED        31980013
         LR    RB,RD               PUT I IN RB                          32040013
         BAL   RK,ONGETTRK         BRANCH AND LINK TO GET AN ADR   3CD1 32100013
         SPACE 1                                                        32160013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE IT TO DEPHO              3CE1 32220013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   32280013
         SPACE 1                                                        32340013
         LR    RM,RD               PUT I IN RM                          32400013
         SLL   RM,2                RM=I X 4                             32460013
         ST    RJ,0(RF,RM)         PUT IN FIRST ROW OF TABLE UNDER I    32520013
         LA    RM,4(0,RM)          GET LOGICAL INCREMENT                32580013
         STC   RM,PPIDEPHO+1       STORE IT                             32640013
ONSETSRT NI    PPISW1+2,X'F7'      SET SW TO SORT-PHASE 2 OFF      3CF1 32700013
         B     ONEXTNET+4          GO EXIT TO NETWORK INITIALIZATION    32760013
         SPACE 2                                                        32820013
ONMTMSQ  LH    RK,KBPRLS3          POINTER TO HI NO.               3CE2 32880013
         AR    RK,RH               PLUS L ROW                           32940013
         CLC   0(1,RK),KMOMONE+3   IS HI NO. = MERGE ORDER-1            33000013
         BE    ONCHKFUR            BRANCH IF YES                        33060013
         SPACE 1                                                        33120013
         LR    RB,RC               SET RB=J                             33180013
ONOLYEOF BC    0,ONAFTEOF          WILL BE UNCOND BRANCH AFTER EOF 3CF2 33240013
         BAL   RK,ONGETTRK         BRANCH AND LINK TO GET AN ADR   3CG2 33300013
         SPACE 1                                                        33360013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE IT TO DEPHO              3CH2 33420013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   33480013
         SPACE 1                                                        33540013
         LR    RM,RC               SET RM=J                             33600013
         SLL   RM,2                RM=J X 4                             33660013
         ST    RJ,0(RF,RM)         PUT IN FIRST ROW OF TABLE UNDER J    33720013
         LA    RM,4(0,RM)          GET LOGICAL INCREMENT                33780013
         STC   RM,PPIDEPHO+1       STORE IT                             33840013
         B     ONSETSRT                                                 33900013
         SPACE 2                                                        33960013
ONCHKFUR LH    RK,KBPRLS4          POINTER TO HI                   3CB3 34020013
         AR    RK,RH               PLUS L ROW                           34080013
         LH    RM,KBPRLS2          POINTER TO LO                        34140013
         AR    RM,RI               PLUS L-1 ROW                         34200013
         CLC   0(1,RM),0(RK)       ARE THEY EQUAL                       34260013
         BE    ONSETMRG            BRANCH IF YES                        34320013
         NI    PPISW1+2,X'F7'      SET SW TO SORT-PHASE 2 OFF      3CB4 34380013
         B     ONUPHI                                                   34440013
         SPACE 2                                                        34500013
ONSETMRG SR    RJ,RJ               CLEAR FOR MERGE ORDER           3CC3 34560013
         LR    RK,RH               ADDRESS OF L ROW                     34620013
         L     RM,KMERGORD         RM = MERGE ORDER                     34680013
         LA    RM,1(0,RM)          PLUS 1                               34740013
ONCHKMT  CLI   0(RK),X'00'         ANYTHING IN THIS ENTRY               34800013
         BNE   ONUPMRG             BRANCH IF YES                        34860013
ONNEXENT LA    RK,4(0,RK)          UP POINTER TO NEXT ENTRY             34920013
         BCT   RM,ONCHKMT          DECREMENT RM-BRANCH IF MORE ENTRIES  34980013
         B     ONCHKUNI            FINISHED WITH THIS ROW               35040013
         SPACE 2                                                        35100013
ONUPMRG  LA    RJ,1(0,RJ)          UP MERGE ORDER BY 1                  35160013
         B     ONNEXENT            GO CONTINUE CHECK                    35220013
         SPACE 2                                                        35280013
ONCHKUNI LR    RK,RD               RK = I                               35340013
         SLL   RK,2                RK = I X 4                           35400013
         AR    RK,RI               RK = ADDRESS OF L-1 ROW + I X 4      35460013
         CLI   0(RK),X'00'         ANYTHING AT THIS ENTRY               35520013
         BE    ONSTORMX            BRANCH IF NO                         35580013
         LA    RJ,1(0,RJ)          UP MERGE ORDER BY 1                  35640013
ONSTORMX STH   RJ,PPIMRGMX         STORE MERGE ORDER                    35700013
         CLI   WSWITCHC,X'00'      IS SWITCH C SET                 3CD3 35760013
         BE    ONSWCNO             BRANCH IF NO                         35820013
         MVI   WSWITCHC,X'00'      CLEAR SWITCH C                  3CE3 35880013
         LTR   RJ,RJ               IS MERGE ORDER = 0              3CF3 35940013
         BZ    ONCLRTBL            BRANCH IF YES                        36000013
         SPACE 1                                                        36060013
         LR    RB,RD               RB = I                          3CG3 36120013
         LA    RB,1(0,RB)          PLUS 1                               36180013
         CL    RB,KMERGORD         IS IT BEYOND TABLE                   36240013
         BNH   ONGOGET             BRANCH IF NO                         36300013
         SR    RB,RB               SET TO 0                             36360013
ONGOGET  BAL   RK,ONGETTRK         GO GET AN ADDRESS                    36420013
         SPACE 2                                                        36480013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE ADDRESS TO DEPHO         3CH3 36540013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   36600013
         SPACE 1                                                        36660013
         LR    RK,RD               RK = I                               36720013
         LA    RK,1(0,RK)          RK = I+1                             36780013
         CL    RK,KMERGORD         ARE WE BEYOND LAST ENTRY             36840013
         BNH   ONNOTGMO            BRANCH IF NOT                        36900013
         SR    RK,RK               SET RK = 0                           36960013
ONNOTGMO SLL   RK,2                TIMES 4                              37020013
         ST    RJ,0(RI,RK)         STORE ADDRESS AT (L-1,I+1)           37080013
         B     ONLDWKAR            GO LOAD PPIWKARE WITH NEXT MRG ADRS  37140013
         SPACE 2                                                        37200013
ONSWCNO  MVI   WSWITCHC,X'FF'      SET SWITCH C                    3CD4 37260013
         LTR   RJ,RJ               IS MERGE ORDER = 0              3CE4 37320013
         BZ    ONCLRTBL            BRANCH IF YES                        37380013
         LR    RB,RD               RB = I                          3CF4 37440013
         SH    RB,KONE             MINUS 1                              37500013
         BNM   ONNOTMIN            BRANCH IF NOT MINUS                  37560013
         L     RB,KMERGORD         SET TO LAST ENTRY                    37620013
ONNOTMIN BAL   RK,ONGETTRK         GO GET AN ADDRESS                    37680013
         SPACE 2                                                        37740013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE ADDRESS TO DEPHO         3CG4 37800013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   37860013
         SPACE 1                                                        37920013
         LR    RK,RD               RK = I                               37980013
         SH    RK,KONE             MINUS 1                              38040013
         BNM   ONNIXMIN            BRANCH IF NOT MINUS                  38100013
         L     RK,KMERGORD         SET TO LAST ENTRY                    38160013
ONNIXMIN SLL   RK,2                I X 4                                38220013
         ST    RJ,0(RI,RK)         STORE ADDRESS AT (L-1,I-1)           38280013
ONLDWKAR LA    RK,4(0,RK)          GET LOGICAL AREA INCREMENT      3CH4 38340013
         STC   RK,PPIDEPHO+1       STORE IT                             38400013
         LA    RM,PPIWKARE         ADDRESS OF WORK AREA            3CH5 38460013
         SR    RO,RO               RO = 0                               38520013
         ST    RO,PPIWKARE+128                                          38580013
         ST    RO,PPIWKARE+132     CLEAR OUT 8 BYTE AREA                38640013
ONLOOP2  SR    RJ,RJ                                                    38700013
         A     RJ,0(RO,RH)         LOAD RJ WITH ENTRY                   38760013
         BNZ   ONGOTONE            BRANCH IF REAL ADDRESS               38820013
ONLOOP3  LA    RO,4(0,RO)          UP POINTER BY 4                      38880013
         CH    RO,KBPRLS4          ARE WE THROUGH WITH THIS LINE        38940013
         BE    ONONELF             BRANCH IF YES                        39000013
         B     ONLOOP2             LOOP IF NO                           39060013
         SPACE 2                                                        39120013
ONGOTONE BAL   RK,ONEXPAND         GO EXPAND ADDRESS                    39180013
         SPACE 1                                                        39240013
         MVC   0(8,RM),PPIWKARE+128  MOVE TO LIST FOR READ ROUTINE      39300013
         LA    RP,4(0,RO)          GET LOGICAL AREA INCREMENT           39360013
         STC   RP,1(0,RM)          STORE IT IN 2ND BYTE OF ADDRESS      39420013
         LA    RM,8(0,RM)          UP LIST POINTER BY 8                 39480013
         B     ONLOOP3             LOOP                                 39540013
         SPACE 2                                                        39600013
ONONELF  LR    RP,RD               RP = I                               39660013
         SLL   RP,2                TIMES 4                              39720013
         SR    RJ,RJ                                                    39780013
         A     RJ,0(RI,RP)         GET ENTRY AT L-1 UNDER I             39840013
         BZ    ONCLRTBL            SKIP IF NUL ENTRY                    39900013
         BAL   RK,ONEXPAND         GO EXPAND ADDRESS                    39960013
         SPACE 1                                                        40020013
         MVC   0(8,RM),PPIWKARE+128  MOVE IT TO LIST FOR READ ROUTINE   40080013
         LA    RP,4(0,RP)          I TIMES 4 PLUS 4                     40140013
         STC   RP,1(0,RM)          INSERT LOGICAL AREA INCREMENT        40200013
ONCLRTBL MVI   0(RH),X'00'         ZERO ONE BYTE                   3CJ4 40260013
         LR    RP,RH               ADDRESS OF TABLE ROW TO CLEAR        40320013
         LH    RJ,KBPRLS6          GET LENGTH FIELD                     40380013
         EX    RJ,ONMOVE           PROPAGATE ZERO THROUGH ROW-4 BYTES   40440013
         LA    RJ,2(0,RJ)          UP IT BY 2                           40500013
         L     RK,KONEONE                                               40560013
         ST    RK,0(RJ,RH)         INSERT 1010 IN LAST 4 BYTES          40620013
         LR    RK,RD               RK = I                               40680013
         SLL   RK,2                TIMES 4                              40740013
         SR    RJ,RJ                                                    40800013
         ST    RJ,0(RK,RI)         ZERO OUT ENTRY AT L-1 UNDER I        40860013
         SPACE 2                                                        40920013
         LH    RJ,KBPRLS4          POINTER TO HI                   3DB2 40980013
         SR    RK,RK                                                    41040013
         IC    RK,1(RJ,RI)         GET HI NO. AT L-1 ROW                41100013
         LA    RK,1(0,RK)          UP IT BY 1                           41160013
         STC   RK,1(RJ,RI)         STORE IT BACK                        41220013
         IC    RM,3(RJ,RI)         GET LO NO. AT L-1                    41280013
         SH    RM,KONE             DECREMENT BY 1                       41340013
         STC   RM,3(RJ,RI)         STORE IT BACK                        41400013
         CL    RK,KMERGORD         HI NO. NOW = MERGE ORDER        3DC2 41460013
         BL    ONDECL              BRANCH IF NO                         41520013
         SPACE 1                                                        41580013
         LH    RK,0(RJ,RI)         GET HI AND HI NO. AT L-1        3DD2 41640013
         STH   RK,2(RJ,RI)         STORE THEM AT LO AND LO NO. AT L-1   41700013
         SRL   RK,8                ZERO OUT HI NO.                      41760013
         LA    RK,1(0,RK)          ADD ONE TO HI                        41820013
         SLL   RK,8                                                     41880013
         STH   RK,0(RJ,RI)         STORE IN HI AND HI NO. AT L-1        41940013
ONDECL   S     RH,KBYPEROW         DECREMENT L ROW POINTER         3DD3 42000013
         S     RI,KBYPEROW         DECREMENT L-1 ROW POINTER            42060013
         BCT   RE,ONNOTZRO         BRANCH IF L NOT EQUAL 0         3DE3 42120013
ONUPL    LA    RE,1(0,RE)          L=L+1                           3DD4 42180013
         A     RH,KBYPEROW         INCREMENT L ROW POINTER              42240013
         A     RI,KBYPEROW         INCREMENT L-1 ROW POINTER            42300013
         LA    RM,10                                                    42360013
         CR    RM,RE               DOES L = 10                     3DE4 42420013
         BE    ONMSG46A            BRANCH TO PRINT MESSAGE              42480013
         LA    RD,1(0,RD)          I = I+1                         3DF4 42540013
         CL    RD,KMERGORD         I = M+1                              42600013
         BNH   ONJTOI              BRANCH IF NO                         42660013
         SR    RD,RD               SET I = 0                            42720013
ONJTOI   LR    RC,RD               SET J = I                       3DG4 42780013
         TM    PPISW1+2,X'08'      SORT OR MERGE                   3DH4 42840013
         BO    ONMGMX              BRANCH IF MERGE                      42900013
ONEXTNET STM   RC,RI,WSAVE         SAVE REGISTERS-OVERLAID AT EOF  3DH5 42960013
         LM    RC,RD,WSAVE1        RESTORE RC AND RD                    43020013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    43080013
         L     RL,PPIINT+4                                              43140013
         B     4(0,RL)             EXIT  TO SORT ENTRY OF INITIAL.      43200013
         SPACE 2                                                        43260013
ONMGMX   CLI   PPIMRGMX+1,X'00'    DOES MERGE ORDER = 0            3DJ3 43320013
         BE    ONMTMSQ             BRANCH IF YES                        43380013
ONRESTO  STM   RC,RI,WSAVE         SAVE REGISTERS                       43440013
         LM    RC,RD,WSAVE1        RESTORE RC AND RD                    43500013
         TM    PPISW1+3,X'80'      IS EQUALS BIT ON                3DJ4 43560013
         BNO   ONEXRD              BRANCH IF NO                         43620013
         CLI   WSWITCHA,X'FF'      IS SWITCH A ON                  3DJ5 43680013
         BE    ONOFFA              BRANCH IF YES                        43740013
ONEXRD   L     RL,PPIRD+4                                          3DK3 43800013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    43860013
         B     4(0,RL)             EXIT TO READ (PRIME)                 43920013
         SPACE 2                                                        43980013
ONOFFA   MVI   WSWITCHA,X'00'      TURN OFF SWITCH A               3DK5 44040013
         L     RL,PPIINT+4                                         3DK4 44100013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    44160013
         BR    RL                  EXIT TO INITIAL. (MERGE ENTRY)       44220013
         SPACE 2                                                        44280013
ONNOTZRO SR    RM,RM                                               3DF3 44340013
         IC    RM,1(RJ,RH)         GET HI NO. AT L                      44400013
         CL    RM,KMOMONE          IS IT = MERGE ORDER - 1              44460013
         BNE   ONUPL               BRANCH IF NOT EQUAL                  44520013
         IC    RM,2(RJ,RI)         GET LO AT L-1                   3DG3 44580013
         SR    RO,RO                                                    44640013
         IC    RO,0(RJ,RH)         GET HI AT L                          44700013
         CR    RM,RO               ARE THEY EQUAL                       44760013
         BNE   ONUPHI              BRANCH IF NO                         44820013
         MVI   WSWITCHD,X'FF'      ANOTHER MERGE PASS TO FOLLOW IMMED.  44880013
         OI    PPISW1+7,X'08'      SET BIT 61 (ANOTHER MERGE PASS) 3DH3 44940013
         B     ONMGMX              BRANCH BACK                          45000013
         SPACE 2                                                        45060013
ONUPHI   LH    RJ,KBPRLS4          POINTER TO HI                        45120013
         LH    RK,0(RJ,RH)         GET HI AND HI NO. AT L               45180013
         STH   RK,2(RJ,RH)         STORE IN LO AND LO NO. AT L          45240013
         SRL   RK,8                ZERO OUT HI NO.                      45300013
         LA    RK,1(0,RK)          ADD ONE TO HI                        45360013
         SLL   RK,8                                                     45420013
         STH   RK,0(RJ,RH)         STORE IN HI AND HI NO. AT L          45480013
         B     ONUPL               GO TO INCRE L                        45540013
         SPACE 2                                                        45600013
ONMSG46A L     RM,PPIRMA+4         SET MSG MOD BASE REG            3DE5 45660013
         LM    RA,RB,MSGP1A02      LOAD PARAMETER REGISTERS             45720013
         L     RP,PPIADSSC                                              45780013
         BAL   RO,12(0,RP)         PRINT MESSAGE -SORT CAP. EXCEEDED    45840013
         SPACE 2                                                        45900013
*APROX RCD CNT IS SUM OF UNIT COUNTS - B, WHERE B IS A MAX. VALUE.  SO  45960013
*   IF CNT TURNS NEGATIVE, CNT IS SET TO B.  THIS NEGATIVE CONDITION    46020013
*   IS MOST LIKELY IF THE BLOCK BEING WRITTEN OUT IS SHORT AND/OR       46080013
*   RECORD FORMAT IS VARIABLE.                                          46140013
         SPACE 1                                                        46200013
         L     RB,PPIUNTCT         ADDR. OF UNIT COUNTERS - TABLE       46260013
         SR    RC,RC                 CONTAINS NO. OF RCDS. PER DEVICE   46320013
         SR    RD,RD                                                    46380013
         IC    RD,PPIBDSVA                                              46440013
RON155   LA    RB,4(0,RB)                                               46500013
         A     RC,0(0,RB)          SUM UNIT COUNTERS                    46560013
         BCT   RD,RON155                                                46620013
         SPACE 2                                                        46680013
         LH    RP,PPISRTBL         B  -F = RCDS./BLOCK                  46740013
         TM    PPISW1,X'80'            V = BYTES/BLOCK                  46800013
         BO    RON157                                                   46860013
         SPACE 1                                                        46920013
         SR    RO,RO               B / MIN.RCD.LENGTH = MAX. NO.        46980013
         LH    RA,PPIRCDL4                                              47040013
         DR    RO,RA                 RCDS. IN BLOCK                     47100013
RON157   CR    RC,RP               CHECK TO MAKE SURE CNT ISN'T         47160013
         BH    RON158                NEGATIVE                           47220013
         SPACE 1                                                        47280013
         LR    RC,RP               SET RCD CNT TO B                     47340013
         B     RON159                                                   47400013
         SPACE 2                                                        47460013
RON158   SR    RC,RP               APROX. RCD CNT = SUM UNIT CNTS - B   47520013
RON159   CVD   RC,WSAVE4           SET UP TO PRINT                      47580013
         BAL   RP,ON0SPRS            COUNT                              47640013
         SPACE 1                                                        47700013
         MVC   MSGP1R06+24(7),WSAVE4+8                                  47760013
         LM    RA,RB,MSGP1A06                                           47820013
         B     ONOUTMSG            BRANCH TO PRINT 'CAPACITY EXCEEDED'  47880013
*                                    MESSAGE AND ABORT                  47940013
         SPACE 2                                                        48000013
*   THIS ROUTINE IS ENTERED AT INPUT EOF AS WELL AS THE SIMULATED EOF   48060013
*   WHICH OCCURS AFTER EACH M SEQUENCES HAVE BEEN SORTED.               48120013
         SPACE 1                                                        48180013
ONEOF    STM   RC,RD,WSAVE1        SAVE RC AND RD FOR CALLING MOD  3EB2 48240013
         LM    RC,RI,WSAVE         RESTORE REGISTERS FOR OWN USE        48300013
         L     RJ,WSEQTOTL                                         3EC2 48360013
         LA    RJ,1(0,RJ)          ADD 1 TO SEQUENCE TOTAL              48420013
         ST    RJ,WSEQTOTL         SAVE IT                              48480013
         BAL   RK,ONREORD          GO REORDER THE FTL (INCRE IN RB)3ED2 48540013
         SPACE 1                                                        48600013
ONSETSWM OI    PPISW1+2,X'08'      SET MERGE SWITCH (PHASE 2)      3EE2 48660013
         OI    WSWITCHA,X'FF'      SET SWITCH A (SWITCHING TO MERGE PH) 48720013
         TM    PPISW1+3,X'01'      IS THIS A REAL EOF              3EF2 48780013
         BZ    ONNOTYET            BRANCH IF NO                         48840013
         TM    PPISW1+7,X'80'      HAVE WE REACHED E15 END OF FILE      48900013
         BO    ONRELEOF            BRANCH IF YES                        48960013
ONNOTYET MVI   WSEQCTR+3,X'00'     SET SEQ CTR = 0                 3EG2 49020013
ONONETIM CLC   WSEQTOTL(4),KMSQURD M SQUARED + 1 SEQUENCES YET     3EB3 49080013
         BNH   ONUPI               BRANCH IF NO                         49140013
         SH    RC,KONE             J=J-1                           3EC3 49200013
         BNM   ONJNOTM             BRANCH UNLESS J NEGATIVE        3ED3 49260013
         L     RC,KMERGORD         SET J=M                         3ED4 49320013
ONJNOTM  LR    RB,RC               RB=INCREMENT (FROM J)           3EE3 49380013
         BAL   RK,ONGETTRK         GO GET AN ADDRESS                    49440013
         SPACE 1                                                        49500013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE IT TO DEPHO              3EF3 49560013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   49620013
         SPACE 1                                                        49680013
         SR    RK,RK               CLEAR RK                             49740013
         LR    RM,RC               RM=J                                 49800013
         SLL   RM,2                TIMES 4                              49860013
         ST    RJ,0(RM,RH)         STORE ADR IN TABLE AT (LJ)           49920013
         LA    RJ,4(0,RM)          GET LOGICAL AREA INCREMENT           49980013
         STC   RJ,PPIDEPHO+1       STORE IT                             50040013
         LH    RJ,KBPRLS4          RJ=POINTER TO HI                     50100013
         IC    RK,1(RJ,RH)         GET HI NO.                           50160013
         LA    RK,1(0,RK)          UP IT BY 1                           50220013
         STC   RK,1(RJ,RH)         STORE IT BACK                        50280013
         CL    RK,KMOMONE          DOES HI NO.=MERGE ORDER-1       3EG3 50340013
         BE    ONISHILO            BRANCH IF YES                        50400013
         SPACE 2                                                        50460013
*   THE FIRST 2 INSTRUCTIONS (10 BYTES) OF THE FOLLOWING CODE WILL BE   50520013
*   OVERLAID BY NOPS AFTER A REAL INPUT END OF FILE.                    50580013
         SPACE 1                                                        50640013
ONONEPAS NI    PPISW1+7,X'F7'      CLEAR BIT 61 (ONLY 1 MRG PASS)  3EH3 50700013
ONSETMO  MVC   PPIMRGMX(2),KMERGORD+2   SET PPIMRGMX=FULL MERGE    3EJ3 50760013
         SR    RB,RB                                               3EJ2 50820013
         L     RO,KTABLEX          SET UP POINTER TO FIRST ROW OF TBL   50880013
         LA    RM,PPIWKARE         SET UP POINTER FOR STORING ADRS      50940013
ONLOOP4  SR    RJ,RJ                                                    51000013
         A     RJ,0(RB,RO)         GET NEXT ENTRY                       51060013
         BNZ   ONACTADR            BRANCH IF IT IS REAL                 51120013
ONLOOP5  LA    RB,4(0,RB)          UP POINTER TO NEXT ENTRY             51180013
         CH    RB,KBPRLS4          ARE WE THROUGH                       51240013
         BL    ONLOOP4             BRANCH IF NO                         51300013
         B     ONCLFSTR            BRANCH WHEN LOOP FINISHED            51360013
         SPACE 2                                                        51420013
ONACTADR BAL   RK,ONEXPAND         GO EXPAND ADDRESS WHICH IS IN RJ     51480013
         SPACE 1                                                        51540013
         MVC   0(8,RM),PPIWKARE+128  MOVE ADDRESS TO PPIWKARE           51600013
         LR    RP,RB               RP=INCREMENT                         51660013
         LA    RP,4(0,RP)          INCREMENT + 4 (START AT 4 NOT 0)     51720013
         STC   RP,1(0,RM)          INSERT LOGICAL INCREMENT             51780013
         LA    RM,8(0,RM)          UP POINTER TO PPIWKARE BY 8          51840013
         B     ONLOOP5             CONTINUE LOOP                        51900013
         SPACE 2                                                        51960013
ONCLFSTR L     RP,KTABLEX          ADDRESS OF FIRST ROW OF TABLE   3EK2 52020013
         MVI   0(RP),X'00'         ZERO FIRST BYTE                      52080013
         LH    RJ,KBPRLS6          NO. OF BYTES TO ZERO                 52140013
         EX    RJ,ONMOVE           PROPAGATE ZEROS THROUGH FIRST ROW-4  52200013
         B     ONRESTO             GO RESTORE REGS AND EXIT             52260013
         SPACE 2                                                        52320013
ONUPI    LA    RD,1(0,RD)          I=I+1                           3EB4 52380013
         CL    RD,KMERGORD         DOES I NOW=MERGE ORDER+1        3EC4 52440013
         BNH   ONSKIP1             BRANCH IF NO                         52500013
         SR    RD,RD               I=0                             3EC5 52560013
ONSKIP1  LR    RB,RD               RB=I                                 52620013
         BAL   RK,ONGETTRK         GO GET AN ADDRESS               3ED5 52680013
         SPACE 1                                                        52740013
         MVC   PPIDEPHO(8),PPIWKARE  MOVE IT TO DEPHO              3EE5 52800013
         BAL   RK,ONCOMPAC         GO COMPACT ADDRESS                   52860013
         SPACE 1                                                        52920013
         LR    RM,RD               RM=I                                 52980013
         SLL   RM,2                TIMES 4                              53040013
         ST    RJ,0(RM,RH)         STORE ADDRESS AT (LI)                53100013
         LA    RJ,4(0,RM)          GET LOGICAL AREA INCREMENT           53160013
         STC   RJ,PPIDEPHO+1       STORE IT                             53220013
         LH    RJ,KBPRLS1          POINTER TO LO NO.                    53280013
         SR    RM,RM               CLEAR RM                             53340013
         L     RK,KTABLEX0         POINTER TO L = 0 ROW OF TABLE        53400013
         IC    RM,0(RK,RJ)         GET LO NO.                           53460013
         LA    RM,1(0,RM)          UP BY 1                              53520013
         STC   RM,0(RK,RJ)         STORE IT BACK                        53580013
         CL    RM,KMERGORD                                         3EF5 53640013
         BNE   ONONEPAS            BRANCH IF LO NO. NOT EQ MERGE ORDER  53700013
         LA    RE,1(0,RE)          SET L=L+1                       3EG5 53760013
         A     RH,KBYPEROW         UP POINTER TO NEW L ROW              53820013
         A     RI,KBYPEROW         UP POINTER TO NEW L-1 ROW            53880013
         B     ONONEPAS            BRANCH TO 'ONLY 1 MERGE PASS' RTN    53940013
         SPACE 2                                                        54000013
ONISHILO SR    RO,RO                                               3EE4 54060013
         SR    RP,RP                                                    54120013
         IC    RO,0(RJ,RH)         GET HI AT L                          54180013
         IC    RP,2(RJ,RI)         GET LO AT L-1                        54240013
         CR    RO,RP               ARE THEY EQUAL                       54300013
         BE    ONMTOPAS            GO TO MORE THAN 1 PASS ROUTINE       54360013
         LH    RM,0(RJ,RH)         GET HI AND HI NO. AT L          3EF4 54420013
         STH   RM,2(RJ,RH)         STORE IN LO AND LO NO. AT L          54480013
         SRL   RM,8                HI NO.=0                             54540013
         LA    RM,1(0,RM)          HI=HI+1                              54600013
         SLL   RM,8                POSITION                             54660013
         STH   RM,0(RJ,RH)         STORE AT HI AND HI NO. OF L          54720013
         LA    RE,1(0,RE)          L=L+1                           3EG4 54780013
         A     RH,KBYPEROW         UP L ROW POINTER                     54840013
         A     RI,KBYPEROW         UP L-1 ROW POINTER                   54900013
         LA    RM,10                                                    54960013
         CR    RE,RM               DOES L=10                       3EH4 55020013
         BE    ONMSG46A            GO PRINT MESSAGE AND ABORT           55080013
         SPACE 1                                                        55140013
         LA    RD,1(0,RD)          I=I+1                           3EH5 55200013
         CL    RD,KMERGORD         IS I NOW PAST LAST ENTRY             55260013
         BNH   ONSKIP2             BRANCH IF NO                         55320013
         SR    RD,RD               I=0                                  55380013
ONSKIP2  LR    RC,RD               SET J=I                              55440013
         B     ONONEPAS                                                 55500013
         SPACE 2                                                        55560013
ONMTOPAS OI    PPISW1+7,X'08'      SET MORE THAN 1 PASS BIT        3EJ4 55620013
         MVI   WSWITCHC,X'00'      CLEARED FOR ODD NUMBERED CONSECUTIVE 55680013
*                                    MERGE PASSES                  3EK4 55740013
         MVI   WSWITCHD,X'FF'      ANOTHER MERGE PASS TO FOLLOW IMMED.  55800013
         B     ONSETMO             GO SET UP TO MERGE                   55860013
         SPACE 2                                                        55920013
*   THIS ENTRY IS FROM THE WRITE ROUTINE REQUESTING A CHAIN ADDRESS.    55980013
*   RB CONTAINS THE ACTUAL AREA INCREMENT FOR THE BLOCK BEING WRITTEN.  56040013
         SPACE 1                                                        56100013
ONCHNADR L     RG,KFRTRKLT         LOAD TO ADR OF FTL ROW OF TABLE (-4) 56160013
         LR    RA,RO               SAVE RETURN REG                      56220013
         BAL   RK,ONGETTRK+8       GO GET AN ADDRESS                    56280013
         SPACE 1                                                        56340013
         LR    RO,RA               RESTORE RETURN REG                   56400013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    56460013
         L     RL,PPIWRT+4         LOAD BASE REG FOR WRITE MODULE       56520013
         BR    RO                  RETURN TO WRITE ROUTINE.        3FC2 56580013
*                                    ADDRESS IS IN PPIWKARE.            56640013
         SPACE 1                                                        56700013
*   THIS ENTRY IS FROM THE READ ROUTINE AT EOS. RB WILL CONTAIN THE     56760013
*   LOGICAL AREA INCREMENT. WE MUST DETERMINE IF ANOTHER MERGE PASS IS  56820013
*   TO FOLLOW AND IF SO WHETHER OR NOT ANOTHER READ CAN BE INITIATED    56880013
*   ON THIS AREA NOW. IF IT CAN WE WILL RETURN WITH RB=4 AND THE        56940013
*   ADDRESS TO BE READ IN PPIWKARE. OTHERWISE RB WILL BE ZERO.          57000013
         SPACE 1                                                        57060013
ONRDEOS  CLI   WSWITCHD,X'00'      WILL ANOTHER MERGE PASS FOLLOW  3FB4 57120013
         LM    RC,RI,WSAVE         LOAD MODULE REGISTERS                57180013
         BE    ONNOMO              BRANCH IF NO                         57240013
         CLI   WSWITCHC,X'00'      IS SWITCH C OFF                 3FC4 57300013
         BE    ONSWCOFF            BRANCH IF YES                        57360013
         LR    RM,RD               RM=I                            3FD4 57420013
         SLL   RM,2                TIMES 4                              57480013
         LA    RM,8(0,RM)          PLUS 8                               57540013
         CL    RM,KBYPEROW         IS RM BEYOND LAST ENTRY              57600013
         BNE   ONSKIP3             BRANCH IF NOT                        57660013
         LA    RM,4                SET TO FIRST ENTRY                   57720013
ONSKIP3  CR    RB,RM               DOES RB=AREA I+1                     57780013
         BE    ONNOMO              BRANCH IF YES (THIS IS THE AREA WE   57840013
*                                    ARE WRITING ON)                    57900013
ONDORBEI LR    RM,RD               RM=I                            3FE4 57960013
         SLL   RM,2                TIMES 4                              58020013
         LR    RO,RB               RO=LOGICAL INCREMENT                 58080013
         SH    RO,KFOUR            MINUS 4 (TABLE STARTS AT 0 NOT 4)    58140013
         CR    RM,RO               INCREMENT FOR I AREA                 58200013
         BE    ONRBEI              BRANCH IF YES                        58260013
         SR    RJ,RJ                                               3FF4 58320013
         A     RJ,0(RO,RH)         GET THIS ENTRY                       58380013
         BZ    ONNOMO              BRANCH IF IT IS NOT A REAL ONE       58440013
ONEXPEXT BAL   RK,ONEXPAND         GO EXPAND TO 8 BYTE ADDRESS     3FG4 58500013
         SPACE 1                                                        58560013
         MVC   PPIWKARE(8),PPIWKARE+128    MOVE TO WORK AREA            58620013
         STC   RB,PPIWKARE+1       INSERT LOGICAL AREA INCREMENT        58680013
         LA    RB,4                INDICATE READ POSSIBLE          3FG5 58740013
ONEXITRD L     RL,PPIRD+4                                          3FH5 58800013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    58860013
         BR    RL                  EXIT TO READ ROUTINE                 58920013
         SPACE 2                                                        58980013
ONSWCOFF LR    RM,RD               RM=I                            3FD5 59040013
         SLL   RM,2                TIMES 4                              59100013
         LTR   RM,RM               IS IT ZERO                           59160013
         BNZ   ONSKIP4             BRANCH IF NOT ZERO                   59220013
         LH    RM,KBPRLS4          SET TO LAST ENTRY IN ROW             59280013
ONSKIP4  CR    RM,RB               IS INCREMENT FOR I-1 AREA            59340013
         BE    ONNOMO              BRANCH IF EQUAL (THIS IS THE AREA    59400013
*                                    WE ARE WRITING ON)                 59460013
         B     ONDORBEI            GO SEE IF THIS IS AREA UNDER I       59520013
         SPACE 2                                                        59580013
ONRBEI   SR    RJ,RJ                                               3FE5 59640013
         A     RJ,0(RO,RI)         IS ADDRESS AT L-1 OF THIS INCRE REAL 59700013
         BZ    ONNOMO              BRANCH IF NOT                        59760013
         B     ONEXPEXT            GO EXPAND ADDRESS AND EXIT      3FF5 59820013
         SPACE 2                                                        59880013
ONNOMO   SR    RB,RB               INDICATE NO READ                3FH4 59940013
         B     ONEXITRD            GO EXIT TO READ                      60000013
         SPACE 2                                                        60060013
*   THE FOLLOWING ROUTINE WILL BE ENTERED ONLY ONCE. THAT TIME WILL BE  60120013
*   AFTER THE REAL END OF FILE HAS BEEN REACHED. SOME CODE IS OVERLAID  60180013
*   SO THAT WE DO NOT RETURN TO THE SORT PHASE.                         60240013
         SPACE 1                                                        60300013
ONRELEOF OI    PPISW1+7,X'08'      SET BIT 61 (ONLY MERGE PASSES)  3BB4 60360013
         MVC   ONNOEOF(4),KNOP     OVERLAY 'CLEAR MERGE BIT' INSTRUCT.  60420013
         MVC   ONONEPAS(4),KNOP    OVERLAY 'CLEAR MERGE BIT' INSTRUCT.  60480013
         MVC   ONSETMO(6),KNOP     OVERLAY 'SET MERGE ORDER'       3BC4 60540013
         SR    RO,RO                                                    60600013
         L     RP,WSEQTOTL                                              60660013
         D     RO,KMERGORD         DIVIDE TOTAL SEQS BY MERGE ORDER     60720013
         LTR   RO,RO               IS REMAINDER=0                       60780013
         BNZ   ONSKIP5             BRANCH IF NO                         60840013
         L     RO,KMERGORD         IF YES THIS IS A FULL MERGE          60900013
ONSKIP5  STH   RO,PPIMRGMX         SET MERGE ORDER FOR NEXT MERGE       60960013
         CLC   WSEQTOTL(4),KMERGORD  MORE THAN M SEQUENCES         3BD4 61020013
         BH    ONSETX              BRANCH IF YES                        61080013
         L     RF,KTABLEX          LOAD POINTER TO FIRST ROW       3BE4 61140013
         B     ONEQZERO+4          GO SET UP PPIENDAR AND EXIT          61200013
         SPACE                                                          61260013
ONSETX   L     RM,KMERGORD                                         3BB5 61320013
         SH    RM,PPIMRGMX         RM=NORMAL MERGE ORDER-THIS M.O.      61380013
         CLC   WSEQTOTL(4),KMSQURD   M SQUARED SEQUENCES YET       3BC5 61440013
         BH    ONSKIP6             BRANCH IF YES                        61500013
         AR    RD,RM               I=I+X                           3BD5 61560013
         CL    RD,KMERGORD         IS IT BEYOND END OF TABLE            61620013
         BNH   ONSKIP7             BRANCH IF NO                         61680013
         S     RD,KMERGORD         SUBTRACT MERGE ORDER            3BE5 61740013
         SH    RD,KONE             SUBTRACT ONE MORE                    61800013
         B     ONSKIP7             GO FINISH OVERLAY                    61860013
         SPACE 2                                                        61920013
ONSKIP6  SR    RC,RM               J=J-X                                61980013
         BNM   ONSKIP7             BRANCH IF J NOT NEGATIVE             62040013
         A     RC,KMERGORD         ADD MERGE ORDER                      62100013
         AH    RC,KONE             PLUS 1                               62160013
ONSKIP7  OI    ONOLYEOF+1,X'F0'    CHANGE INSTRUCTION TO BRANCH    3BF5 62220013
         MVC   ONEXTNET(4),ONSETSWM     OVERLAY CODE AT 3DH5       3BG5 62280013
         MVC   ONEXTNET+4(4),KOVERLAY                                   62340013
         B     ONONETIM            SORTING IS DONE-FINISH MERGES        62400013
         SPACE 2                                                        62460013
*   THIS ROUTINE IS ENTERED ONLY AFTER THE REAL INPUT END OF FILE WHEN  62520013
*   A SIMULATED MERGE PASS IS TO BE DONE. (THE TABLE IS UPDATED BUT NO  62580013
*   MERGING IS DONE)                                                    62640013
         SPACE 1                                                        62700013
ONAFTEOF LA    RC,1(0,RC)          J=J+1                           3CJ3 62760013
         CL    RC,KMERGORD         IS J BEYOND END OF TABLE             62820013
         BNH   ONSKIP8             BRANCH IF NO                         62880013
         SR    RC,RC               SET J=0                              62940013
ONSKIP8  LH    RK,KBPRLS4                                          3CK3 63000013
         LH    RM,0(RK,RH)         GET HI NO. AT L                      63060013
         LA    RM,1(0,RM)          ADD 1                                63120013
         STH   RM,0(RK,RH)         STORE IT BACK                        63180013
         MVI   WSWITCHC,X'00'      TURN OFF SWITCH C               3CK2 63240013
         B     ONMTMSQ             MERGE PASS SIMULATED-GO BACK AND     63300013
*                                    SEE IF WE HAVE M-1 SEQUENCES AT    63360013
*                                    THIS LEVEL OF THE TABLE NOW        63420013
         SPACE 2                                                        63480013
*   THIS SUBROUTINE GETS A TRACK FROM THE FREE TRACK LIST INDICATED BY  63540013
*   REGISTER RB. WHEN IT RETURNS THE ADDRESS IS IN THE FIRST 8 BYTES OF 63600013
*   PPIWKARE. IF THE INCREMENT IN RB IS IN THE FORM 0,1,2 ETC THE       63660013
*   SUBROUTINE IS ENTERED FROM THE TOP. IF IT IS IN THE FORM 4,8,12 ETC 63720013
*   THE SUBROUTINE IS ENTERED AT +8 (ONNOTMT). IF NO TRACKS ARE AVAIL-  63780013
*   ABLE FOR THE INDICATED AREA A SEARCH IS MADE FOR THE LARGEST        63840013
*   REMAINING SEGMENT AND A TRACK IS TAKEN FROM THAT AREA LIST.         63900013
         SPACE 1                                                        63960013
ONGETTRK SLL   RB,2                                                3GC2 64020013
         LA    RB,4(0,RB)          CHANGE INCRE FROM 0,1,2 ETC TO 4,8   64080013
ONNOTMT  SR    RJ,RJ                                                    64140013
         ST    RJ,PPIWKARE                                              64200013
         ST    RJ,PPIWKARE+4       ZERO OUT PPIWKARE (FIRST 8 BYTES)    64260013
         IC    RJ,0(RB,RG)         GET NUMBER OF ENTRIES THIS AREA 3GD2 64320013
         L     RM,0(RB,RG)         RM IS POINTER TO FIRST ENTRY         64380013
         LTR   RJ,RJ               ARE THERE ANY ENTRIES           3GE2 64440013
         BZ    ONFNDBIG            BRANCH IF NO                         64500013
         LH    RO,0(0,RM)          GET STARTING ADDRESS            3GF2 64560013
         STC   RO,PPIWKARE+6       STORE TRACK NUMBER                   64620013
         SRL   RO,8                POSITION CYLINDER NUMBER             64680013
         STC   RO,PPIWKARE+4       STORE CYLINDER NUMBER                64740013
         STC   RB,PPIWKARE         STORE REAL INCREMENT                 64800013
         MVI   PPIWKARE+7,X'01'    INSERT 'RECORD 1'                    64860013
         SR    RO,RO                                               3GG2 64920013
         IC    RO,1(0,RM)          GET TRACK NO.                        64980013
         LA    RO,1(0,RO)          UP BY 1                              65040013
         CH    RO,KMXTRK           WAS THAT THE LAST TRACK THIS CYLND   65100013
         BH    ONSKIP9             BRANCH IF YES                        65160013
         STC   RO,1(0,RM)          STORE NEW TRACK ADDRESS              65220013
         LH    RO,0(0,RM)          LOAD STARTING ADDRESS                65280013
         B     ONENTMT             GO CHECK IF THIS ENTRY NOW EMPTY     65340013
         SPACE 2                                                        65400013
ONSKIP9  LH    RO,0(0,RM)          GET CYLINDER AND TRACK               65460013
         SRL   RO,8                SET TRACK TO 0                       65520013
         LA    RO,1(0,RO)          UP CYLINDER BY 1                     65580013
         SLL   RO,8                POSITION                             65640013
         STH   RO,0(0,RM)          STORE IT ON FTL LIST                 65700013
ONENTMT  LH    RP,2(0,RM)          GET ENDING ADDRESS              3GH2 65760013
         N     RO,K00FF            CLEAR TWO HIGH ORDER BYTES           65820013
         N     RP,K00FF            CLEAR TWO HIGH ORDER BYTES           65880013
         CR    RO,RP               IS STARTING ADR LARGER THAN ENDING   65940013
         BNH   ONRETURN+4          BRANCH IF NO                         66000013
         BCT   RJ,ONMVFTL          DECRE CNT-BRANCH IF NOT 0       3GH3 66060013
ONRETURN STC   RJ,0(RB,RG)         STORE COUNT                          66120013
         BR    RK                  RETURN                          3GJ2 66180013
         SPACE 2                                                        66240013
ONMVFTL  LR    RO,RJ               PUT COUNT IN RO                 3GJ3 66300013
ONLOOP6  LA    RP,4(0,RM)          RP IS POINTER TO ENTRY ABOVE RM      66360013
         CLI   0(RP),X'FF'         IS THIS A CHAIN ADDRESS              66420013
         BE    ONTHISCH            BRANCH IF YES                        66480013
ONLOOP7  MVC   0(4,RM),0(RP)       MOVE ENTRY UP 1 PLACE                66540013
         BCT   RO,ONSKIP10         BRANCH IF NOT DONE                   66600013
         B     ONRETURN            GO RETURN                            66660013
         SPACE 2                                                        66720013
ONTHSCHN STM   RC,RE,WSAVE6        KEEP REGISTER CONTENTS        A27990 66726000
         SR    RC,RC               SUBTRACT REGISTERS            A27990 66732000
         SR    RD,RD               FOR DIVIDEND                  A27990 66738000
         LR    RD,RJ               LOAD NO ENTRIES               A27990 66744000
         LA    RE,9                NINE FOR DIVIDEND             A27990 66750000
         DR    RC,RE               CHECK IS SEGMENT              A27990 66756000
         CH    RC,KONE             IN POOL CAN BE RELEASED       A27990 66762000
         BNE   ONSKIP21            NO, BR BACK                   A27990 66768000
         CH    RO,KONE             CHCK IF SEGMENT CAN BE RELEAS A27990 66774000
         BNE   ONSKIP21            NO, BR BACK                   A27990 66780000
         LA    RP,4(0,RP)          RP POINTER TO NEXT LIST ENTRY A27990 66786000
         LR    RC,RM               KEEP ADDR                     A27990 66792000
         L     RE,KFPPTR           LOAD ADDR TO FREPOOL LIST     A27990 66798000
         AH    RE,KFOUR            UPDATE POINTER                A27990 66804000
         ST    RE,KFPPTR           RESTORE UPDATED ADDR          A27990 66810000
         L     RC,0(0,RC)          LOAD ADDR TO NEXT ENTRY       A27990 66816000
         ST    RC,0(0,RE)          MOVE ENTRY UP 1 PLACE         A27990 66822000
         IC    RE,KFPPTR           UPDATE NO ENTRIES             A27990 66828000
         AH    RE,KONE             BY ONE                        A27990 66834000
         STC   RE,KFPPTR           AND STORE IT BACK             A27990 66840000
         LM    RC,RE,WSAVE6        RESTORE WORK REGISTERS        A27990 66846000
         B     ONLOOP7             BRANCH BACK                   A27990 66852000
ONSKIP21 LM    RC,RE,WSAVE6        RESTORE WORK REG              A27990 66858000
         L     RM,0(0,RM)          GET ADDR FROM CHAIN ADDR      A27990 66864000
         B     ONLOOP6             GO UPDATE OTHER POINTER       A27990 66870000
         SPACE 2                                                        66900013
ONTHISCH L     RP,0(0,RP)          GET ADDRESS FROM CHAIN ADDRESS       66960013
         B     ONLOOP7             GO MOVE ENTRY UP 1 PLACE             67020013
         SPACE 2                                                        67080013
ONSKIP10 LA    RM,4(0,RM)          UPDATE POINTER TO NEXT ENTRY         67140013
         CLI   0(RM),X'FF'         IS THIS A CHAIN ADDRESS              67200013
         BE    ONTHSCHN            BRANCH IF YES                        67260013
         B     ONLOOP6             GO UPDATE OTHER POINTER              67320013
         SPACE 2                                                        67380013
ONFNDBIG LA    RB,4                SET RB TO GET FIRST LIST ADR    3GE3 67440013
         SR    RP,RP               CLEAR FOR LARGEST AREA               67500013
ONLOOP8  L     RO,0(RB,RG)         RO=ADDRESS OF LIST                   67560013
         LH    RM,2(0,RO)          ENDING ADDRESS                       67620013
         N     RM,K00FF            CLEAR TWO HIGH ORDER BYTES           67680013
         LH    RJ,0(0,RO)          STARTING ADDRESS                     67740013
         N     RJ,K00FF            CLEAR TWO HIGH ORDER BYTES           67800013
         SR    RM,RJ               END ADDRESS MINUS START ADDRESS      67860013
         BM    ONSKIP11            BRANCH IF EMPTY                      67920013
         OI    WSWITCHB,X'FF'      INDICATE A TRACK AVAILABLE           67980013
         CR    RM,RP               NEWEST AREA THE LARGEST SO FAR       68040013
         BL    ONSKIP11            BRANCH IF NO                         68100013
         LR    RP,RM               SAVE ITS SIZE                        68160013
         STH   RB,WSAVE2           SAVE INCREMENT TO IT                 68220013
ONSKIP11 LA    RB,4(0,RB)          UP POINTER TO NEXT LIST ADDRESS      68280013
         CL    RB,KBYPEROW         ARE WE DONE CHECKING                 68340013
         BNE   ONLOOP8             BRANCH IF NOT                        68400013
         CLI   WSWITCHB,X'00'      ANY TRACKS AVAILABLE                 68460013
         BE    ONMSG46A            BRANCH TO PRINT AND ABORT IF NO      68520013
         MVI   WSWITCHB,X'00'      TURN SWITCH OFF FOR NEXT TIME        68580013
         LH    RB,WSAVE2           GET INCREMENT TO LARGEST AREA        68640013
         B     ONNOTMT             GO GET AN ADDRESS FROM THIS AREA     68700013
         SPACE 2                                                        68760013
*   THE FOLLOWING ROUTINE IS ENTERED ONLY WHEN THE READ ROUTINE HAS     68820013
*   FINISHED READING A TRACK. THE TRACK ADDRESS WILL BE IN PPIWKARE.    68880013
*   THIS ROUTINE WILL RESTORE THAT ADDRESS TO THE FREE TRACK LIST AND   68940013
*   RETURN TO THE READ ROUTINE.                                         69000013
         SPACE 1                                                        69060013
ONRDTREL L     RG,KFRTRKLT         LOAD TO ADR OF LAST ROW-4       3HC2 69120013
         SR    RB,RB                                                    69180013
         SR    RJ,RJ                                                    69240013
         IC    RB,PPIWKARE         GET INCREMENT                        69300013
         IC    RJ,0(RB,RG)         GET NUMBER OF ENTRIES                69360013
         L     RM,0(RB,RG)         GET ADDRESS OF FIRST ENTRY           69420013
         MVC   WSAVE2(1),PPIWKARE+4     GET CYLINDER NUMBER             69480013
         MVC   WSAVE2+1(1),PPIWKARE+6   GET TRACK NUMBER                69540013
         LTR   RJ,RJ               ANY ENTRIES                     3HD2 69600013
         BZ    ONNOENTS            BRANCH IF NO                         69660013
ONLOOP10 CLC   3(1,RM),KMXTRK+1    IS ENDING TRACK LAST IN CYL.    3HE2 69720013
         BE    ONLSTTRK            BRANCH IF YES                        69780013
         LH    RP,2(0,RM)          GET END ADDRESS FOR THIS ENTRY       69840013
ONLOOP9  LH    RK,WSAVE2           LOAD INTO RK                         69900013
         SR    RK,RP               SUBTRACT END ADDRESS FOR THIS ENTRY  69960013
         BCT   RK,ONDECRJ          BRANCH UNLESS DIFFERENCE IS 1        70020013
         LH    RK,WSAVE2           RELOAD RELEASE ADDRESS          3HE3 70080013
         STH   RK,2(0,RM)          STORE AS NEW END ADDRESS             70140013
ONOUTRD  L     RL,PPIRD+4                                          3HE4 70200013
         L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    70260013
         BR    RO                  RETURN TO READ ROUTINE               70320013
         SPACE 2                                                        70380013
ONLSTTRK LH    RP,2(0,RM)          GET END ADDRESS FOR THIS ENTRY       70440013
         AH    RP,KMXTRKCP         ADD COMPLEMENT OF MAXIMUM TRACK      70500013
         B     ONLOOP9             GO SEE IF REL ADR IS ADJACENT        70560013
         SPACE 2                                                        70620013
ONDECRJ  LA    RM,4(0,RM)          UP POINTER TO NEXT ENTRY             70680013
         BCT   RJ,ONSKIP12         DECR RJ - BRANCH IF NOT 0            70740013
         B     ONNEWENT            BRANCH TO NEW ENTRY ROUTINE     3HG2 70800013
         SPACE 2                                                        70860013
ONSKIP12 CLI   0(RM),X'FF'         IS THIS A CHAIN ADDRESS              70920013
         BNE   ONLOOP10            BRANCH IF NO                         70980013
*                                                                  3HF1 71040013
         L     RM,0(0,RM)          USING CHAIN ADR GET ADR OF NEXT ENT  71100013
         B     ONLOOP10            GO CONTINUE SEARCH                   71160013
         SPACE 2                                                        71220013
ONNOENTS MVC   0(1,RM),PPIWKARE+4  MAKE THIS THE STARTING ADDRESS       71280013
         MVC   1(1,RM),PPIWKARE+6    FOR THIS ENTRY                     71340013
         MVC   2(2,RM),0(RM)       ALSO THE ENDING ADDRESS              71400013
         IC    RJ,0(RB,RG)         GET NUMBER OF ENTRIES           3HD4 71460013
         LA    RJ,1(0,RJ)          UP IT BY 1                           71520013
         STC   RJ,0(RB,RG)         STORE IT BACK                        71580013
         B     ONOUTRD             GO EXIT TO READ                      71640013
         SPACE 2                                                        71700013
ONNEWENT SR    RE,RE                                               3HH2 71760013
         SR    RF,RF               CLEAR REGS FOR DIVIDEND              71820013
         IC    RF,0(RB,RG)         INSERT NUMBER OF ENTRIES             71880013
         CH    RF,KONE             IS THERE ONLY ONE ENTRY              71940013
         BE    ONNOENTS            BRANCH IF YES                        72000013
         LA    RH,9                                                     72060013
         DR    RE,RH               DIVIDE BY 9                          72120013
         CH    RE,KONE             IS REMAINDER=1                  3HJ2 72180013
         BNE   ONNOENTS            BRANCH IF NO                         72240013
         SPACE 1                                                        72300013
*   THE FOLLOWING CODE IS ENTERED IF A SEGMENT (40 BYTES) OF FREE       72360013
*   TRACK LIST IS FILLED AND MORE IS NEEDED. IT IS GOTTEN FROM A POOL   72420013
*   AND THE SEGMENTS ARE CHAINED TOGETHER.                              72480013
         SPACE 1                                                        72540013
         SR    RE,RE                                               3HK2 72600013
         AH    RE,KPOOLSZ          ANYTHING LEFT IN POOL                72660013
         BZ    ONSKIP16            BRANCH IF NO                  A27990 72720000
         L     RF,KPOOL            GET ADDRESS OF POOL             3HF4 72780013
         LA    RH,40(0,RF)         UP IT BY 40                          72840013
         ST    RH,KPOOL            STORE NEW ADDRESS BACK               72900013
         SH    RE,KFORTY           SUBTRACT 40 FROM AMOUNT REMAINING    72960013
         STH   RE,KPOOLSZ          STORE IT BACK                        73020013
ONSKIP17 SH    RM,KFOUR            MOVE POINTR BACK TO LST ENT   A27990 73080000
         MVC   0(4,RF),0(RM)       MOVE LAST ENTRY TO NEW SEGMENT  3HG4 73140013
         ST    RF,0(0,RM)          INSERT CHAIN ADDRESS                 73200013
         MVI   0(RM),X'FF'         FLAG IT AS A CHAIN ADDRESS           73260013
         LA    RM,4(0,RF)          SET ENTRY POINTER TO NEW SEG.+4      73320013
         B     ONNOENTS            GO INSERT NEW ENTRY                  73380013
ONSKIP16 SR    RE,RE                                             A27990 73384000
         IC    RE,KFPPTR           ANY ENTRIES IN FREE POOL      A27990 73388000
         CH    RE,KZERO            LIST                          A27990 73392000
         BE    ONMSG46A            NO SORT CAPACITY EXCEEDED     A27990 73396000
         SH    RE,KONE             DECREASE ENTRY BY ONE         A27990 73400000
         L     RF,KFPPTR           ADDR TO FREE POOL LIST        A27990 73404000
         L     RH,KFPPTR           ADDR TO FREE POOL LIST        A27990 73408000
         SH    RH,KFOUR            DECREMENT ADDR BY FOUR        A27990 73412000
         ST    RH,KFPPTR           RESTORE UPDATED ADDR          A27990 73416000
         STC   RE,KFPPTR           RESTORE UPDATED ENTRY         A27990 73420000
         L     RF,0(0,RF)          POINT TO POOL                 A27990 73424000
         B     ONSKIP17            BRANCH BACK                   A27990 73428000
         SPACE 2                                                        73440013
*   THE FOLLOWING SUBROUTINE IS ENTERED EACH TIME THAT A WRITE EOS      73500013
*   CONDITION COMES UP. IT COMBINES ADJACENT SEGMENTS ON A FREE TRACK   73560013
*   LIST. IF WE ARE SORTING ONLY THE LIST FOR THE AREA WE WERE WRITING  73620013
*   ON IS CONSIDERED. IF WE ARE MERGING ALL LISTS ARE CONSIDERED. EACH  73680013
*   TIME WE FINISH A LIST WE BRANCH TO ANOTHER SUBROUTINE WHICH         73740013
*   REORDERS THE LIST BY SIZE OF SEGMENT WITH THE LARGEST SEGMENT       73800013
*   BEING PUT AT THE TOP OF THE LIST.                                   73860013
         SPACE 1                                                        73920013
ONREORD  STM   RC,RF,WSAVE4        SAVE REGISTERS                       73980013
         TM    PPISW1+2,X'08'      ARE WE MERGING                  3JB1 74040013
         BNO   ONSOTING            BRANCH IF SORTING                    74100013
         ST    RK,WSAVE3           SAVE RETURN REGISTER            3JB2 74160013
         LA    RB,4                SET RB TO FIRST AREA                 74220013
ONLOOP11 BAL   RK,ONSOTING         LINK TO DO THIS LIST            3JB3 74280013
         SPACE 2                                                        74340013
         CH    RB,KBPRLS4          HAVE WE FINISHED ALL LISTS      3JC3 74400013
         BE    ONRESTLK            BRANCH IF YES                        74460013
         LA    RB,4(0,RB)          UP POINTER TO NEXT LIST         3JC2 74520013
         B     ONLOOP11            GO DO NEXT LIST                      74580013
         SPACE 2                                                        74640013
ONRESTLK L     RK,WSAVE3           RESTORE RETURN REGISTER         3JC4 74700013
ONGOBACK LM    RC,RF,WSAVE4        RESTORE REGISTERS                    74760013
         BR    RK                  RETURN                               74820013
         SPACE 2                                                        74880013
ONSOTING SR    RC,RC                                               3JC1 74940013
         IC    RC,0(RB,RG)         RC SET TO NO. OF ENTRIES             75000013
         L     RJ,0(RB,RG)         RJ IS POINTER TO FIRST ENTRY         75060013
         LA    RM,4(0,RJ)          RM IS POINTER TO SECOND ENTRY        75120013
         LR    RD,RC                                               3JD1 75180013
         SH    RD,KONE             Y=X-1                                75240013
         CH    RC,KONE             DOES X=0 OR 1                   3JE1 75300013
         BNH   ONGOBACK            GO RETURN IF YES                3JE2 75360013
ONLOOP12 SR    RO,RO                                               3JF1 75420013
         ST    RO,WSAVE5           CLEAR SAVE AREA                      75480013
         MVC   WSAVE5+2(2),2(RM)   GET END ADDRESS AT POINTER 2         75540013
         L     RO,WSAVE5           LOAD IT                              75600013
         CLC   WSAVE5+3(1),KMXTRK+1  IS TRACK ADDRESS LAST IN CYLINDER  75660013
         BNE   ONSKIP13            BRANCH IF NO                         75720013
         AH    RO,KMXTRKCP         ADD COMPLEMENT OF MAXIMUM TRK NO.    75780013
ONSKIP13 MVC   WSAVE5+2(2),0(RJ)   GET START ADDRESS AT POINTER 1       75840013
         L     RP,WSAVE5           LOAD IT                              75900013
         SR    RP,RO               SUBTRACT END FROM START              75960013
         BCT   RP,ONNOTADJ         IF ADJACENT DON'T BRANCH             76020013
         MVC   0(2,RJ),0(RM)       MOVE START ADR FROM PTR 2 TO 1  3JF2 76080013
         B     ONCOMBED            BRANCH OUT-THESE HAVE BEEN COMBINED  76140013
         SPACE 2                                                        76200013
ONNOTADJ MVC   WSAVE5+2(2),2(RJ)   GET END ADDRESS AT POINTER 1         76260013
         L     RO,WSAVE5           LOAD IT                              76320013
         CLC   WSAVE5+3(1),KMXTRK+1  IS TRACK ADR LAST IN CYLINDER      76380013
         BNE   ONSKIP14            BRANCH IF NO                         76440013
         AH    RO,KMXTRKCP         ADD COMPLEMENT OF MAXIMUM TRACK NO.  76500013
ONSKIP14 MVC   WSAVE5+2(2),0(RM)   GET START ADR AT POINTER 2           76560013
         L     RP,WSAVE5           LOAD IT                              76620013
         SR    RP,RO               SUBTRACT END FROM START ADDRESS      76680013
         BCT   RP,ONNOAGIN         BRANCH IF NOT ADJACENT               76740013
         MVC   2(2,RJ),2(RM)       MOVE END ADR FROM PTR 2 TO PTR 1     76800013
         B     ONCOMBED            BRANCH OUT-THESE HAVE BEEN COMBINED  76860013
         SPACE 2                                                        76920013
ONNOAGIN LA    RM,4(0,RM)          UPDATE POINTER 2                3JG1 76980013
         SH    RD,KONE             DECREMENT Y                          77040013
         BZ    ONISXLES            BRANCH IF Y=0                   3JH1 77100013
ONLOOP14 CLI   0(RM),X'FF'         CHK FOR CHAIN ADR AT POINTER 2  3JJ1 77160013
         BNE   ONLOOP12            BRANCH IF NOT                        77220013
         L     RM,0(0,RM)          GET ADDRESS OF NEXT ENTRY       3JK1 77280013
         B     ONLOOP12            GO CHECK ANOTHER PAIR OF ENTRIES     77340013
         SPACE 2                                                        77400013
ONCOMBED SR    RF,RF                                               3JG2 77460013
         IC    RF,0(RB,RG)         GET NUMBER OF ENTRIES                77520013
         SH    RF,KONE             DECREMENT BY 1                       77580013
         STC   RF,0(RB,RG)         STORE IT BACK                        77640013
         BCT   RC,*+4              DECREMENT X                          77700013
         LR    RE,RD               SET Z=Y                         3JH2 77760013
ONLOOP13 SH    RE,KONE             MINUS 1                              77820013
         BZ    ONSKIP18            GO REORDER FTL & POOL         A27990 77880000
         LA    RF,4(0,RM)          SET POINTER 3=POINTER 2+4       3JD4 77940013
         CLI   0(RF),X'FF'         CHK FOR CHAIN ADR AT POINTER 3  3JE4 78000013
         BNE   ONSKIP15            BRANCH IF NOT                        78060013
         L     RF,0(0,RF)          GET ADDRESS OF NEXT ENTRY       3JF4 78120013
ONSKIP15 MVC   0(4,RM),0(RF)       MOVE ENTRY FROM PTR 3 TO PTR 2  3JF5 78180013
         LR    RM,RF               SET POINTE 2=POINTER 3          3JG5 78240013
         B     ONLOOP13            GO CONTINUE MOVING                   78300013
         SPACE 2                                                        78360013
ONISXLES SH    RC,KTWO             X=X-2                           3JD3 78420013
         BC    12,ONCHKENT         BRANCH IF X NOW 0 OR NEGATIVE        78480013
         AH    RC,KONE             X=X+1                           3JE3 78540013
         LA    RJ,4(0,RJ)          UPDATE POINTER 1                3JF3 78600013
         CLI   0(RJ),X'FF'         CHK FOR CHAIN ADR AT POINTER 1  3JG3 78660013
         BNE   ONMOVOVR            BRANCH IF NO                         78720013
         L     RJ,0(0,RJ)          GET ADR OF NEXT ENTRY           3JG4 78780013
ONMOVOVR LR    RM,RJ               SET POINTER 2 = POINTER 1       3JH4 78840013
         LR    RD,RC               SET Y=X                              78900013
         B     ONNOAGIN            GO CONTINUE SEARCH                   78960013
ONSKIP18 STM   RC,RE,WSAVE6        KEEP MAINLINE REG.            A27990 78961000
         SR    RC,RC               CLEAR REG                     A27990 78962000
         SR    RD,RD               FOR DIVIDEND                  A27990 78963000
         IC    RD,0(RB,RG)         GET NO ENTRIES                A27990 78964000
         CH    RD,KONE             ONLY ONE ENTRY                A27990 78965000
         BE    ONSKIP19            YES, BRANCH OUT               A27990 78966000
         LA    RE,9                BY DIVIDING NO ENTRIES BY     A27990 78967000
         DR    RC,RE               NINE NO FREE TRK SEGMENTS     A27990 78968000
         CH    RC,KONE             CAN BE DETERMINED             A27990 78969000
         BNE   ONSKIP19            BRANCH IF MORE THAN ONE SEGM  A27990 78970000
         L     RF,0(RB,RG)         LOAD STARTINGADDR             A27990 78971000
         SR    RC,RC               ZERO REG                      A27990 78972000
         IC    RC,0(RB,RG)         INSERT NO ENTRIES             A27990 78973000
ONLOOPZZ BCT   RC,ONSKIPXX         SCAN FTL                      A27990 78974000
         B     ONSKIP19            BRANCH OUT ENTIRE ENTRY DONE  A27990 78975000
ONSKIPXX LA    RF,4(0,RF)          POINT TO NEXT ENTRY           A27990 78976000
         CLI   0(RF),X'FF'         CHAIN ADDR AT RF              A27990 78977000
         BNE   ONLOOPZZ            NO, LOOP BACK                 A27990 78978000
         CH    RC,KONE             LAST ENTRY                    A27990 78979000
         BNE   ONLOOPZZ            NO, CONTINUE SEARCH           A27990 78980000
         LR    RD,RF               KEEP POINTER REG.             A27990 78981000
         L     RF,0(0,RF)          GET NEW LIST ADDR             A27990 78982000
         ST    RF,KCHAIN           KEEP CHAIN ADDR               A27990 78983000
         L     RE,KFPPTR           LOAD POINTER TO FREE POOL     A27990 78984000
         AH    RE,KFOUR            UP IT BY FOUR                 A27990 78985000
         ST    RE,KFPPTR           RESTORE UPDATED ADDR          A27990 78986000
         MVC   0(4,RE),KCHAIN      MOVE POOL ADDR IN LIST        A27990 78987000
         IC    RE,KFPPTR           UPDATE TOTAL NO OF            A27990 78988000
         AH    RE,KONE             ENTRIES IN LIST               A27990 78989000
         STC   RE,KFPPTR                                         A27990 78990000
         MVC   0(4,RD),0(RF)       MOVE ENTRY                    A27990 78991000
         B     ONLOOPZZ            BRANCH BACK                   A27990 78992000
ONSKIP19 LM    RC,RE,WSAVE6        RESTORE MAINL PGM REGISTER    A27990 78993000
         B     ONMOVOVR            BRANCH OUT                    A27990 78994000
         SPACE 2                                                        79020013
ONCHKENT SR    RP,RP                                                    79080013
         IC    RP,0(RB,RG)         GET NUMBER OF ENTRIES                79140013
         BCT   RP,ONORDLST         BRANCH IF GREATER THAN 0             79200013
         B     ONGOBACK            GO TO RETURN                         79260013
ONORDLST L     RP,0(RB,RG)         POINTER TO INITIAL ENTRY(PTR 1) 3KC2 79320013
         LA    RO,4(0,RP)          POINTER TO NEXT ENTRY(PTR 2)         79380013
         SR    RM,RM                                                    79440013
         ST    RM,WSAVE5           CLEAR SUBROUTINE WORK AREA TO ZERO   79500013
         IC    RM,0(RB,RG)         NO. OF ENTRIES IN THIS LIST.         79560013
         LR    RJ,RM                                                    79620013
         BCTR  RJ,0                ESTABLISH COUNTER(ENTRIES - 1)  3KD2 79680013
         SPACE 1                                                        79740013
ONDTRARA MVC   WSAVE5+2(2),0(RP)   EXPAND START CCTT AT PTR1 TO    3KE2 79800013
*                                  FULLWORD.                            79860013
         L     RF,WSAVE5           GET START CCTT.                      79920013
         MVC   WSAVE5+2(2),2(RP)   EXPAND END CCTT TO FULLWORD.         79980013
         CLC   WSAVE5+2(1),0(RP)   AREA START AND END ON SAME CYLN...   80040013
         BE    ONSUB1              -YES, BYPASS ADDITION OF CONSTANT.   80100013
         SPACE 1                                                        80160013
         AH    RF,KMXTRKCP         -NO, ADD CONSTANT TO START CCTT.     80220013
ONSUB1   L     RE,WSAVE5           GET EXPANDED CCTT AT PTR1.           80280013
         SR    RE,RF               AREA AT PTR1.                        80340013
         EX    RE,ONORDCMP         TEST DIFFERENCE FOR FORM...          80400013
         BC    10,ONSUB1A          -ANS CORRECT(CYL-TRK FORM), TAKE     80460013
*                                   .EQ. OR .GT. BRANCH.                80520013
         AH    RE,KMXTRKCP         -ANS IN TOTAL TRACKS,CHANGE TO       80580013
*                                   CYLN-TRK FORM                       80640013
         SPACE 1                                                        80700013
ONSUB1A  MVC   WSAVE5+2(2),0(RO)   EXPAND START C/T OF NEXT ENTRY(PTR2) 80760013
*                                  (PTR2) TO FULLWORD.                  80820013
         L     RF,WSAVE5           GET START CCTT.                      80880013
         MVC   WSAVE5+2(2),2(RO)   EXPAND PTR2 END CCTT TO FULLWORD.    80940013
         CLC   WSAVE5+2(1),0(RO)   AREA START AND END ON SAME CYLN...   81000013
         BE    ONSUB2              -YES                                 81060013
         SPACE 1                                                        81120013
         AH    RF,KMXTRKCP         -NO                                  81180013
ONSUB2   L     RC,WSAVE5           GET END CCTT AT PTR2.                81240013
         SR    RC,RF               AREA AT PTR2.                        81300013
         EX    RC,ONORDCMP         TEST DIFFERENCE FOR FORM...          81360013
         BC    10,ONSUB2A          -ANS CORRECT(CYL-TRK FORM), TAKE     81420013
*                                   .EQ. OR .GT. BRANCH.                81480013
         AH    RC,KMXTRKCP         -ANS IN TOTAL TRACKS,CHANGE TO       81540013
*                                   CYLN-TRK FORM                       81600013
ONSUB2A  CR    RE,RC               PTR1 AREA .EQ. OR .GT. PTR2 AREA...  81660013
         BC    10,ONSUB3           YES, TRY NEXT ENTRY IN LIST.         81720013
         SPACE 1                                                        81780013
         L     RD,0(0,RP)          NO, SWAP PTR1 AND PTR2 ENTRIES. 3KE3 81840013
         MVC   0(4,RP),0(RO)                                            81900013
         ST    RD,0(0,RO)                                               81960013
ONSUB3   LA    RO,4(0,RO)          INCR PTR2 FOR NEXT ENTRY.       3KF2 82020013
         BCT   RJ,ONSUB4           THIS PASS THRU LIST DONE...     3KG2 82080013
         B     ONSUB5              YES, GO SEE IF ENTIRE LIST DONE      82140013
         SPACE 2                                                        82200013
ONSUB4   TM    0(RO),X'FF'         CHAIN ADDRESS AT PTR2...        3KH2 82260013
         BNO   ONDTRARA            -NO, DETERMINE AREA OF NEXT ENTRY.   82320013
         SPACE 1                                                        82380013
         L     RO,0(0,RO)          -YES, UPDT PTR2 FOR CHAIN LIST. 3KJ2 82440013
         B     ONDTRARA             COMPUTE AREA OF CHAIN LIST ENTRY.   82500013
         SPACE 2                                                        82560013
ONSUB5   ST    RM,WSAVE5                                           3KD4 82620013
         CLI   WSAVE5+3,X'03'      ALL ENTRIES ORDERED...               82680013
         BL    ONRETRN             -YES, GO SET UP FOR MAINPROG RETURN  82740013
         SPACE 2                                                        82800013
         BCTR  RM,0                -NO, DECR LIST ENTRIES BY ONE   3KE4 82860013
         LR    RJ,RM                                                    82920013
         BCTR  RJ,0                DECR PASS-THRU-LIST CTR BY 1.        82980013
         SPACE 1                                                        83040013
         LA    RP,4(0,RP)          UPDATE PTR1 TO NEXT ENTRY.      3KF4 83100013
         TM    0(RP),X'FF'         IS PTR1 ENTRY A CHAIN ADDR...   3KG4 83160013
         BNO   ONSUB6              -NO                                  83220013
         SPACE 1                                                        83280013
         L     RP,0(0,RP)          -YES, UPDT PTR1 TO CHAIN  LIST  3KH4 83340013
*                                   ENTRY                               83400013
ONSUB6   LA    RO,4(0,RP)          SET PTR2 EQUAL TO PTR1+4             83460013
         B     ONSUB4              GO SEE IF PTR2 IS A CHAIN ADDRESS.   83520013
         SPACE 2                                                        83580013
ONRETRN  LM    RC,RF,WSAVE4        RESET MAINPROG REGISTERS        3KD5 83640013
         BR    RK                  RETURN TO MAINPROG.                  83700013
         SPACE 2                                                        83760013
* RECORD COUNT SUBROUTINE                                               83820013
         SPACE 1                                                        83880013
ONRCDCNT L     RJ,PPICOUNT         DETERMINE NO. INPUT RECORDS     3LC2 83940013
         A     RJ,PPIINSCT         -ADD RECORDS INSERTED AND,      3LD2 84000013
         S     RJ,PPIDELCT         -SUBTRACT RECORDS DELETED.           84060013
         SPACE 1                                                        84120013
         L     RP,PPIUNTCT         GET POINTER TO RCD/UNIT COUNT TABLE  84180013
         LA    RP,4(RP)                                                 84240013
         LH    RM,PPINDSKA         GET NUMBER OF DISK AREAS.       3LE2 84300013
         SR    RO,RO                                               3LF2 84360013
ONRCDTOT A     RO,0(RP)            SUM RECORDS FROM WORK AREAS.         84420013
         LA    RP,4(RP)            INCR. FOR NEXT WORK AREA RCD CNT.    84480013
         BCT   RM,ONRCDTOT         FALL THRU WHEN ALL AREAS TOTALED.    84540013
         SPACE 1                                                        84600013
         TM    PPISW1+3,X'01'      HAS QSAM REACHED END OF FILE... 3LG2 84660013
         BZ    ONFLSHRC            -NO, TAKE THE BRANCH                 84720013
         SPACE 1                                                        84780013
         TM    PPISW1+7,X'80'      -YES, HAS USER REACHED EOF...        84840013
         BO    ONRCDCMP             -YES, GO CHECK RECORD COUNTS        84900013
         SPACE 1                                                        84960013
         B     ONSERT               -NO, QSAM HAS BUT USER HASN'T       85020013
         SPACE 2                                                        85080013
         SPACE 1                                                        85140013
ONFLSHRC BCTR  RJ,0                SUBTRACT 1 FOR RECORD HELD BACK 3LH2 85200013
*                                   TO FORCE FLUSHING.                  85260013
         SPACE 1                                                        85320013
         TM    PPISW1+7,X'20'      USER INSERT IN PROGRESS...      3LJ2 85380013
         BZ    ONRCDCMP            -NO, GO COMPARE RECORD COUNTS.       85440013
         SPACE 1                                                        85500013
ONSERT   BCTR  RJ,0                -YES, SUBTRACT 1 FOR RCD HELD        85560013
*                                   BACK TO ALLOW USER INSERT.          85620013
         SPACE 1                                                        85680013
ONRCDCMP CR    RJ,RO               COMPARE RECORDS IN TO RCDS OUT  3LE3 85740013
         BNE   ONCNTABT            RECORD COUNT OFF, GO TO ABORT RTN.   85800013
         SPACE 1                                                        85860013
         BR    RK                  RECORD CNT EQUAL, RETURN TO MAINLINE 85920013
         SPACE 2                                                        85980013
*RECORD COUNT OFF. PRINT COMPUTED TOTALS AND ABORT THE JOB.             86040013
* RO = RECORDS OUT, RJ = RECORDS IN.                                    86100013
         SPACE 1                                                        86160013
ONCNTABT L     RM,PPIRMA+4         SET MESSAGE MODULE ADDRESS.     3LE4 86220013
         LM    RA,RB,MSGP1A03      GET MESSAGE.                         86280013
         CVD   RO,WSAVE4           CONVERT RCDS OUT TO DECIMAL.         86340013
         BAL   RP,ON0SPRS          GO TO ZERO SUPRESS ROUTINE           86400013
         SPACE 1                                                        86460013
         MVC   MSGP1R03+37(7),WSAVE4+8       PUT RCDS OUT INTO MSG.     86520013
         SPACE 1                                                        86580013
         CVD   RJ,WSAVE4           CONVERT RCDS IN TO DECIMAL.          86640013
         BAL   RP,ON0SPRS          GO TO ZERO SUPPRESS ROUTINE.         86700013
         SPACE 1                                                        86760013
         MVC   MSGP1R03+25(7),WSAVE4+8       PUT RCDS IN INTO MSG.      86820013
         SPACE 1                                                        86880013
ONOUTMSG L     RM,PPIAXERT         RELOAD BASE REG FOR EQ OR EXT RTN    86940013
         L     RP,PPIADSSC         EXIT TO SSC TO PRINT MESSAGE    3LF4 87000013
         BAL   RO,12(0,RP)                                              87060013
         SPACE 1                                                        87120013
         L     RP,PPIADSSC         EXIT TO SSC TO ABORT THE JOB.   3LG4 87180013
         BAL   RO,16(0,RP)                                              87240013
         SPACE 1                                                        87300013
ON0SPRS  UNPK  WSAVE4+7(8),WSAVE4+3(5)  SET TO ZONED DECIMAL FOR PRINT  87360013
         OI    WSAVE4+14,X'F0'          MAKE SIGN POSITIVE.             87420013
         MVI   WSAVE4+15,X'01'          SET STOPPER DIGIT.              87480013
         LA    RO,WSAVE4+7         INITIALIZE LOOP ADDRESS REGISTER.    87540013
ON0SPRS1 CLI   0(RO),X'F0'         TEST FOR ZERO DIGIT.                 87600013
         BNE   0(RP)               NO MORE ZEROS, RETURN.               87660013
         SPACE 1                                                        87720013
         MVI   0(RO),X'40'         INSERT BLANK CHARACTER.              87780013
         LA    RO,1(RO)            INCR ADDRESS REGISTER.               87840013
         B     ON0SPRS1            GO TO TEST NEXT BYTE FOR ZERO.       87900013
         SPACE 2                                                        87960013
ONMOVE   MVC   1(1,RP),0(RP)       USED ONLY BY EXECUTE INSTRUCTIONS    88020013
ONORDCMP CLI   KMXTRK+1,X'00'      USED VIA EXECUTE BY ORDERING LIST    88080013
*                                  SUBROUTINE TO TEST FOR TRUE AREA     88140013
KNOP     NOP   KNOP                                                     88200013
         BR    RA                  USED TO OVERLAY AT INPUT EOF         88260013
KOVERLAY B     ONMTMSQ             USED TO OVERLAY AT INPUT EOF         88320013
KOVERLA2 B     ONDONE              USED TO OVERLAY IF NOT MORE THAN M   88380013
*                                    SEQ. AND EQUALS RTN BEING USED     88440013
WSWITCHA DC    X'00'               SET WHEN SWITCHING FROM SORT TO MRG  88500013
WSWITCHB DC    X'00'               SET TO INDICATE TRACKS ARE AVAILABLE 88560013
WSWITCHC DC    X'00'               SET DURING EACH EVEN NUMBERED        88620013
*                                    CONSECUTIVE MERGE PASS             88680013
WSWITCHD DC    X'00'               USED AT ENTRY FROM READ AT EOS TO    88740013
*                                    SEE IF ANOTHER MERGE PASS FOLLOWS  88800013
WSAVE2   DC    H'0'                WORK AREA FOR SUBROUTINES            88860013
WSEQTOTL DC    F'0'                COUNTER FOR TOTAL SEQUENCES          88920013
WSEQCTR  DC    F'0'                COUNTER FOR SEQUENCES THIS SORT PH.  88980013
WSAVE1   DC    2F'0'               SAVE RC AND RD HERE                  89040013
WSAVE3   DC    F'0'                SAVE AREA                            89100013
         DS    0D                                                       89160013
WSAVE4   DC    4F'0'               SAVE AREA                            89220013
WSAVE5   DC    F'0'               SAVE AND WORK AREA                    89280013
WSAVE    DC    F'1'                SAVE AREA FOR RC (J)                 89340013
         DC    2F'0'               SAVE AREA FOR RD AND RE (I AND L)    89400013
KTABLEX  DC    F'0'                LOADED WITH TABLE ADDRESS BY ASMT.   89460013
KFRTRKLT DC    F'0'                LOADED WITH ADDRESS OF TABLE WHERE   89520013
*                                    FREE TRACK LIST ADDRESSES ARE-4    89580013
*                                    (LOADED BY ASMT. ROUTINE)          89640013
KTABLEL  DC    F'0'                POINTER TO L ROW  (SET ORG BY ASMT)  89700013
KTBLMZON DC    F'0'                POINTER TO L-1 ROW (SET ORG BY ASMT) 89760013
KTABLEX0 DC    F'0'                ADDRESS OF L=0 ROW OF TABLE. (ASMT.) 89820013
KBYPEROW DC    F'0'                BYTES PER ROW OF TABLE       (ASMT.) 89880013
KBPRLS2  DC    H'0'                BYTES PER ROW - 2 (SET BY ASMT.)     89940013
KBPRLS1  DC    H'0'                BYTES PER ROW - 1 (SET BY ASMT.)     90000013
KBPRLS6  DC    H'0'                BYTES PER ROW - 6 (SET BY ASMT.)     90060013
KMXTRK   DC    H'0'                SET BY ASMT.-WILL BE=9 IF 2311-WILL  90120013
*                                    BE=19 IF 2314                      90180013
KMXTRKCP DC    H'0'                SET BY ASMT. HI ORDER BYTE=0 LO      90240013
*                                    ORDER BYTE=COMPLEMENT OF KMXTRK    90300013
KBPRLS3  DC    H'0'                BYTES PER ROW - 3 (SET BY ASMT.)     90360013
KBPRLS4  DC    H'0'                BYTES PER ROW - 4 (SET BY ASMT.)     90420013
KPOOLSZ  DC    H'0'                SET TO SIZE OF POOL BY ASMT.         90480013
KZERO    DC    H'0'                                              A27990 90510000
KONE     DC    H'1'                                                     90540013
KTWO     DC    H'2'                                                     90600013
KFOUR    DC    H'4'                                                     90660013
KFORTY   DC    H'40'                                                    90720013
KMERGORD DC    F'0'                MERGE ORDER (SET BY ASSIGNMENT)      90780013
KMOMONE  DC    F'0'                MERGE ORDER-1 (SET BY ASSIGNMENT)    90840013
KMSQURD  DC    F'0'                SET TO M SQUARED BY ASMT             90900013
KPOOL    DC    F'0'                LOADED TO POOL ADDRESS BY ASMT.      90960013
KFPPTR   DC    F'0'                POINTER TO FREE POOL LIST     A27990 90970000
KCHAIN   DC    F'0'                ADDR TO POOL SEGMENT          A27990 90980000
WSAVE6   DC    3F'0'               SAVE AREA FOR REG 2-4         A27990 90990000
K00FF    DC    XL4'0000FFFF'                                            91020013
KONEONE  DC    X'01000100'         MUST BE ON A FULL WORD BOUNDARY      91080013
DIERRMA  DSECT                                                          91140013
*                                                                       91200013
         COPY  RMAMAIN                                                  91260013
         SMPPI                                                          91320013
         END                                                            91380013
