         TITLE 'IERABA - OS/360 SORT/MERGE - 360-SM023 05/11/66'        00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERABA ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION:  OSCILLATING/2314 BLOCK ASSIGNMENT                    02100013
*   THIS MODULE IS AN ASSIGNMENT ROUTINE FOR MODULE IERRBA. IT IS USED  02400013
*   FOR VARIABLE LENGTH RCDS. IN THE SORT PHASE OF AN OSCILLATING/2314  02700013
*   SORT. IT INITIALIZES THE RUNNING PROGRAM AND SETS UP POINTERS TO    03000013
*   THE OUTPUT BUFFER.                                                  03300013
         SPACE 2                                                        03600013
*USED AS A DSECT IN - N/A                                               03900013
*                                                                       04200013
*                                                                       04500013
*LIST OF MACROS USED BY MODULE -                                        04800013
*                                                                       05100013
*   SMPPI                                                               05400013
*                                                                       05700013
*                                                                       06000013
*ENTRY POINTS:                                                          06300013
         SPACE 1                                                        06600013
*   CSECT NAME ONLY -IERABA        ENTRY FROM IERRC9-                   06900013
*                                     LOAD EP=IERABE,DCB=SORTLIB        07200013
*                                     LR   RP,RA                        07500013
*                                     BALR RO,RP                        07800013
         SPACE 2                                                        08100013
*INPUT: - PPI FIELDS REFERENCED -                                       08400013
         SPACE 1                                                        08700013
*   PPILAB04                                                            09000013
*   PPILAB07                                                            09300013
*   PPIBLK                                                              09600013
         SPACE 1                                                        09900013
*   VALUES USED TO COMPUTE THE SIZE OF THE OUTPUT BLOCK.                10200013
         SPACE 2                                                        10500013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED -                          10800013
         SPACE 1                                                        11100013
*   NONE                                                                11400013
         SPACE 2                                                        11700013
*EXTERNAL ROUTINES:                                                     12000013
         SPACE 1                                                        12300013
*        N/A                                                            12600013
         SPACE 2                                                        12900013
*EXTERNAL PARAMETERS:                                                   13200013
         SPACE 1                                                        13500013
*   NONE                                                                13800013
         SPACE 2                                                        14100013
*EXITS-NORMAL                                                           14400013
         SPACE 1                                                        14700013
*   IERRC9 -                       RETURN VIA RO                        15000013
         SPACE 2                                                        15300013
*EXITS-ERROR:                                                           15600013
         SPACE 1                                                        15900013
*   NONE                                                                16200013
         SPACE 2                                                        16500013
*TABLES/WORK AREAS:                                                     16800013
         SPACE 1                                                        17100013
*   NONE                                                                17400013
         SPACE 2                                                        17700013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  18000013
         SPACE 2                                                        18300013
*NOTES:  THIS MODULE WILL BE EXECUTED ONLY FOR A VARIABLE LENGTH SORT.  18600013
         EJECT                                                          18900013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            19200013
         SPACE 1                                                        19500013
RA       EQU   0                   CONTENTS IN - N/A                    19800013
*                                  USED - NOT USED                      20100013
*                                  CONTENT OUT - N/A                    20400013
RB       EQU   1                   CONTENTS IN- N/A                     20700013
*                                  USE- NOT USED                        21000013
*                                  CONTENTS OUT- N/A                    21300013
RC       EQU   2                   CONTENTS IN- N/A                     21600013
*                                  USE- NOT USED                        21900013
*                                  CONTENTS OUT- N/A                    22200013
RD       EQU   3                   CONTENTS IN- N/A                     22500013
*                                  USE- NOT USED                        22800013
*                                  CONTENTS OUT- N/A                    23100013
RE       EQU   4                   CONTENTS IN- N/A                     23400013
*                                  USE- NOT USED                        23700013
*                                  CONTENTS OUT- N/A                    24000013
RF       EQU   5                   CONTENTS IN - N/A                    24300013
*                                  USED - GENERAL WORK REGISTER         24600013
*                                  CONTENTS OUT - N/A                   24900013
RG       EQU   6                   CONTENTS IN - N/A                    25200013
*                                  USED - NOT USED                      25500013
*                                  CONTENTS OUT - N/A                   25800013
RH       EQU   7                   CONTENTS IN- N/A                     26100013
*                                  USE- NOT USED                        26400013
*                                  CONTENTS OUT- N/A                    26700013
RI       EQU   8                   CONTENTS IN- N/A                     27000013
*                                  USE- NOT USED                        27300013
*                                  CONTENTS OUT- N/A                    27600013
RJ       EQU   9                   CONTENTS IN- N/A                     27900013
*                                  USE- NOT USED                        28200013
*                                  CONTENTS OUT- N/A                    28500013
RK       EQU   10                  CONTENTS IN - N/A                    28800013
*                                  USED - BASE REG FOR IERRBE DSECT     29100013
*                                  CONTENTS OUT - N/A                   29400013
RL       EQU   11                  CONTENTS IN - N/A                    29700013
*                                  USED - MODULE BASE REGISTER          30000013
*                                  CONTENTS OUT - N/A                   30300013
RM       EQU   12                  CONTENTS IN - EQUALS OR EXTRACT ADDR 30600013
*                                  USED - NOT USED                      30900013
*                                  CONTENTS OUT - EQULS OR EXTRACT ADDR 31200013
RN       EQU   13                  CONTENTS IN - ADDRESS OF PPI         31500013
*                                  USED - PPI REFERENCES                31800013
*                                  CONTENTS OUT - ADDRESS OF PPI        32100013
RO       EQU   14                  CONTENTS IN - RETURN REG             32400013
*                                  USED - NOT USED                      32700013
*                                  CONTENTS OUT - RETURN REG            33000013
RP       EQU   15                  CONTENTS IN - THIS MODULE ENTRY ADDR 33300013
*                                  USED - ESTABLISH THIS MOD BASE REG   33600013
*                                  CONTENTS OUT - N/A                   33900013
         SPACE 2                                                        34200013
*START OF MODULE CODE PROPER:                                           34500013
         SPACE 2                                                        34800013
IERABA   CSECT                                                          35100013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    35400013
         USING IERRCA,RN           ADDR OF PPI                          35700013
         USING IERRBAD,RK          ADDR OF RUNNING PROGRAM DUMMY MOD    36000013
IERMBA   LR    RL,RP               LOAD MODULE BASE REG                 36300013
         L     RK,PPIBLK+4         ADDR OF IERRBA FOR DSECT BASE        36600013
         MVC   WBLKCCNT,KEIGHT     SET R.P. BLOCK CHAR CTR TO 8         36900013
         L     RF,PPILAB04         LOAD ADDR OF OUTPUT BUFFER #1        37200013
         TM    PPISW1+6,X'02'                                           37500013
         BC    8,ABA1010                                                37800013
         SPACE 1                                                        38100013
*OVERLAY INSTRUCTIONS IN RUNNING PROGRAM SO THAT RECORD IS MOVED TO THE 38400013
*   OUTPUT AREA BEFORE BLOCK POINTER IS INCREMENTED AND SO THAT INITIAL 38700013
*   POINTER RATHER THAN BLOCK POINTER IS PASSED TO WRITE ROUTINE AS     39000013
*   THE BUFFER ADDRESS                                                  39300013
         LA    RF,16(0,RF)         START OF BUF + EOS + BCC + CHAIN     39600013
         MVI   KEIGHT+3,X'10'      SET CONSTANT TO 16                   39900013
         MVC   RBTAPE(2),KNOP      NOP, SO MVC BEFORE UPDATE BUF.PTR.   40200013
         MVC   RBINCR(4),KON       INCR. FOR OUTPUT FILE                40500013
         MVI   WBLKCCNT+3,X'10'    BLOCK COUNT= BCC + EOS + CHAIN.      40800013
         MVC   RBTAPE1(4),KON1     OBTAIN INITIAL                       41100013
         MVC   RBOVLAY2(4),KON2      POINTER TO BUFFER                  41400013
         MVC   RBLDLPTR(4),KON1                                         41700013
         B     ABA1020                                                  42000013
         SPACE 2                                                        42300013
ABA1010  AH    RF,PPILAB07+2       ADD ROUNDED LENGTH OF OUTPUT BLOCK   42600013
         MVC   RBDISK(2),KNOP      NOP, FOR UPDATE BUF.PTR. BEFORE MVC  42900013
         SPACE 1                                                        43200013
ABA1020  ST    RF,WLSTPTR          OUTPUT BUFFER POINTER                43500013
         ST    RF,WLSTPTRD         CURRENT OUTPUT BLK ENDG ADDR+1       43800013
         BR    RO                  RETURN TO LOAD ROUTINE               44100013
         SPACE 2                                                        44400013
*LIST OF CONSTANTS USED BY THE MODULE:                                  44700013
         SPACE 1                                                        45000013
KNOP     DC    X'4700'             NOP                                  45300013
         DROP  RL                                                       45600013
         DROP  RK                                                       45900013
         USING IERRBAD,RL                                               46200013
KON      IC    RJ,PPIDEPHO+1       INCR. FOR OUTPUT FILE                46500013
KON1     L     RH,WLSTPTRD         INITIAL BUFFER                       46800013
KON2     L     RC,WLSTPTRD           POINTER                            47100013
         EJECT                                                          47400013
*** IERRBA ***                                                          47700013
         SPACE 2                                                        48000013
IERRBAD  DSECT ,                   DUMMY MOD OF RUNNING PROGRAM         48300013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    48600013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      48900013
         SPACE 1                                                        49200013
*   ENTRY TABLE                                                         49500013
         SPACE 1                                                        49800013
IERDB1   B     RBLSTRCD            LAST RCD ENTRY FROM REPLACEMENT      50100013
         B     RBEOS               EOS ENTRY FROM REPLACEMENT           50400013
         B     RBWRT               WRITE ENTRY.                         50700013
*   NORMAL REPLACEMENT ENTRY-INCR BLOCK CHAR CTR,CHECK IF RCD WILL FIT  51000013
*     IN OUTPUT BLOCK. IF NOT, WRITE THE BUFFER BEFORE MOVING THE RCD.  51300013
         SPACE 1                                                        51600013
RBLDCCNT L     RG,WBLKCCNT         OUTPUT BLOCK CHARACTER CTR INITIALLY 51900013
*                                    PRESET TO 8 BY A.P.                52200013
         B     RBBRANCH                                                 52500013
         SPACE 1                                                        52800013
WLSTPTR  DC    F'0'                INITIALLY LOADED BY A.P. TO OUTPUT   53100013
*                                    BLOCK ENDING ADDRESS + 1.          53400013
WLSTPTRD DC    F'0'                OUTPUT BLOCK ENDING ADDRESS + 1.     53700013
         SPACE 1                                                        54000013
RBBRANCH AH    RG,0(RD)            ADD LENGTH OF RECORD TO BE MOVED     54300013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 54600013
         BC    2,RBWRTBLK          YES,BR TO WRITE THE BLOCK FIRST      54900013
RBSAVERD ST    RD,WINNER           SAVE ADDR OF RCD IN RSA TO BE BLOCKD 55200013
         L     RE,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD-    55500013
RBTAPE   SH    RE,0(0,RD)          DECR ADDR BY RCD LNGTH-FOR TAPE SORT 55800013
*                                    RCDS FILL OUTPUT BLOCK STARTING    56100013
*                                    FROM HIGH CORE TO LOW CORE. THIS   56400013
         SPACE 1                                                        56700013
*   CALCULATE BEGINNING ADDR OF THIS BIN + STORE AS NEW AVAILABLE BIN   57000013
         SPACE 1                                                        57300013
         S     RD,KFOUR            SUBTR 4 BYTES FOR TREE ADDR IN RSA   57600013
         SH    RD,PPILEXFF         SUBTR LENGTH OF CONTROL FIELD        57900013
         ST    RD,WKEEPAVA         SAVE STRTG ADDR OF BIN IN WORK AREA  58200013
         SPACE 1                                                        58500013
*   LOAD PARAMETERS AND BRANCH TO MOVE MODULE TO MOVE RCD FROM RSA TO   58800013
*     THE OUTPUT BLOCK. TEST IF LAST RCD SWITCH SET.                    59100013
         SPACE 1                                                        59400013
         L     RF,WINNER           LOAD ADDR OF RCD IN RSA              59700013
         L     RB,KFOUR            A 4 DENOTES A BLOCK RTN TO MOVE MOD  60000013
         L     RP,PPIBDSVA+12      LOAD ADDR OF MOVE RTN                60300013
*                                                                       60600013
         LR    RI,RE               ELLIOTT I PUT THIS IN.  DLB          60900013
*                                                                       61200013
         BALR  RO,RP               BR TO MOVE RTN(WILL SAVE ALL REGS +  61500013
*                                    PASS = BINS VACATED IN RB,AND LINK 61800013
*                                    ADDR OF LAST BIN OF RCD IN RF)     62100013
*                                                                       62400013
         LR    RE,RI               ELLIOTT I PUT THIS IN.  DLB          62700013
         SR    RJ,RJ                                                    63000013
RBINCR   IC    RJ,PPIDEPHO+3       INCR. FOR OUTPUT FILE                63300013
         L     RH,PPIUNTCT          LOAD ADDRESS OF UNIT COUNTERS       63600013
         L     RI,0(RJ,RH)          LOAD COUNT FOR THIS UNIT            63900013
         LA    RI,1(RI)           INCREMENT BY ONE                      64200013
         ST    RI,0(RJ,RH)          RESTORE                             64500013
*                                                                       64800013
         CLI   WLASTRCD,X'00'      LAST RCD SWITCH ON                   65100013
         BC    7,RBSEQSW           YES,BR TO SET FINAL EOS SW FOR WRITE 65400013
         L     RI,WINNER           DISK SORT ONLY - ADD RCD.LENGTH      65700013
RBDISK   AH    RE,0(0,RI)            TO BLOCK PTR. -NOP AH FOR TAPE     66000013
         ST    RE,WLSTPTR          SAVE UPDATED OUTPUT BLK ADDR PTR     66300013
         SPACE 1                                                        66600013
*   UPDATE BIN COUNT AND PTR TO NEXT AVAILABLE AREA IN RSA.UPDATE CHAIN 66900013
*     ADDRESS OF LAST BIN VACATED IN RSA IF BIN COUNT IS NOT ZERO       67200013
         SPACE 1                                                        67500013
         L     RI,PPIBDSVA+8       LOAD BIN COUNT                       67800013
         AR    RI,RB               INCR BY = OF BINS JUST VACATED       68100013
         ST    RI,PPIBDSVA+8       STORE UPDATED BIN COUNT FOR DEBLOCK  68400013
         CR    RI,RB               WAS BIN COUNT ZERO BEFORE INCR(IF SO 68700013
*                                    RI WILL NOW EQUAL RB)              69000013
         BC    8,RBSTOKEP          YES,BR TO UPDATE NEXT AVAILABLE BIN  69300013
*                                    PTR ONLY,BECAUSE ALL BINS ARE      69600013
*                                    LINKED TOGETHER ALREADY            69900013
         MVC   0(4,RF),PPIBDSVA+4  STORE ADDR OF NEXT AVAIL BIN IN LINK 70200013
*                                    ADDR OF LAST BIN VACATED           70500013
RBSTOKEP MVC   PPIBDSVA+4(4),WKEEPAVA  ADDR OF AVAIL BIN                70800013
         ST    RG,WBLKCCNT         SAVE CHARACTER COUNTER               71100013
         SPACE 1                                                        71400013
*   INTERFACE TO DEBLOCK MODULE                                         71700013
         SPACE 1                                                        72000013
RBOVLAY1 L     RL,PPIDEB+4         ADDR OF DEBLOCK MOD. THIS INSTR WILL 72300013
*                                    BE OVLAYED BY B RBLDLPTR ON NORMAL 72600013
*                                    EOS, THEN RESTORED FOR NEXT SEQ.   72900013
         B     8(RL)               BR TO DEBLOCK MOD                    73200013
         SPACE 2                                                        73500013
*   FINAL SEQUENCE ROUTINE FOR LAST RECORD                              73800013
         SPACE 1                                                        74100013
RBSEQSW  ST    RE,WLSTPTR          SAVE STRTG ADDR OF LAST RCD IN OUT-  74400013
*                                   PUT BLOCK.                          74700013
         SR    RE,RE               SET LAST SEQ SWITCH FOR WRITE MODULE 75000013
RBTAPE1  L     RH,WLSTPTR                                               75300013
         B     RBDCRLST            BR TO DECR OUTPUT BLOCK PTR          75600013
         SPACE 2                                                        75900013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK.                  76200013
         SPACE 1                                                        76500013
RBWRTBLK SH    RG,0(0,RD)          SUBTRACT LENGTH OF RCD THAT CANT FIT 76800013
*                                    FROM OUTPUT BLOCK COUNT            77100013
RBOVLAY2 L     RC,WLSTPTR          LOAD OUTPUT BLK PTR.FOR DISK,WLSTPTR 77400013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   77700013
         STH   RG,WHOLD            SET ON HALF WORD BOUNDARY            78000013
         MVC   0(2,RC),WHOLD       BCC IN 1ST 2 BYTES OF OUTPUT BLK     78300013
         LR    RB,RG                 ALSO,IN RB FOR WRITE PARAM         78600013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 78900013
         B     8(RL)               BR TO WRITE MODULE                   79200013
         SPACE 2                                                        79500013
*   WRITE MODULE REENTER VIA BRANCH TABLE. RC,FOR TAPE,HAS ADDR OF AN   79800013
*   OUTPUT BLOCK ENDING ADDRESS+1.                                      80100013
         SPACE 1                                                        80400013
RBWRT    ST    RC,WLSTPTRD         SAVE AS INITIAL OUTPUT BLK POINTER   80700013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLOCK WORK PTR       81000013
         L     RG,KEIGHT           REINITIALIZE BCC TO 8 OR 16          81300013
         AH    RG,0(0,RD)          ADD RCD LENGTH OF RCD TO BE MOVED    81600013
*                                    TO OUTPUT BLOCK                    81900013
         B     RBSAVERD                                                 82200013
         SPACE 2                                                        82500013
*   FROM REPLACEMENT. LAST RECORD                                       82800013
         SPACE 1                                                        83100013
RBLSTRCD OI    WLASTRCD,X'01'      TURN ON LAST RCD SWITCH              83400013
         B     RBLDCCNT                                                 83700013
         SPACE 2                                                        84000013
*   FROM REPLACEMENT. NORMAL EOS                                        84300013
         SPACE 1                                                        84600013
RBEOS    MVC   RBOVLAY1,KLDLPTR    OVLAY EXIT TO DEBLOCK FOR NORMAL EOS 84900013
         B     RBLDCCNT            BR TO MOVE LAST RCD OF THIS SEQUENCE 85200013
         SPACE 2                                                        85500013
*   RETURN FROM RBOVLAY1 WHICH WAS OVERLAYED ON THIS NORMAL EOS.        85800013
         SPACE 1                                                        86100013
RBLDLPTR L     RH,WLSTPTR                                               86400013
         LA    RE,4                SET SWITCH TO NORMAL EOS FOR WRITE   86700013
RBDCRLST MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           87000013
         MVC   RBOVLAY1,KIERDD1    RESET RBOVLAY1 TO ORIGINAL INSTR     87300013
         SPACE 1                                                        87600013
*   CONTINUATION POINT FOR LAST RCD. RH POINTS TO BYTE AFTER EOS ENTRY  87900013
         SPACE 1                                                        88200013
         S     RH,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   88500013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      88800013
         MVC   WBLKCCNT,KEIGHT    REINITIALIZE BLOCK CHAR CTR TO 8      89100013
         STH   RG,WHOLD            SET ON HALF WORD BOUNDARY            89400013
         MVI   WLASTRCD,X'00'     RESET LAST RECORD SWITCH TO ZERO      89700013
         MVC   0(2,RH),WHOLD       BCC IN 1ST 2 BYTES OF OUTPUT BLK     90000013
         LR    RB,RG               LOAD BLOCK CHAR CNT FOR WRITE        90300013
         LR    RC,RH               LOAD OUTPUT BLOCK PTR FOR WRITE MOD  90600013
         SPACE 1                                                        90900013
*   INTERFACE TO WRITE MODULE FOR EOS                                   91200013
         SPACE 1                                                        91500013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 91800013
         B     4(RL)               BR TO WRITE MODULE                   92100013
         SPACE 2                                                        92400013
*   LIST OF CONSTANTS USED BY THE MODULE                                92700013
         SPACE 1                                                        93000013
KFOUR    DC    F'4'                                                     93300013
KEIGHT   DC    F'8'                CONSTANT =8 FOR OSCL., =16 FOR 2314  93600013
KIERDD1  L     RL,PPIDEB+4         RESTORE RBOVLAY1 AFTER NORMAL EOS.   93900013
KLDLPTR  B     RBLDLPTR            OVLAY RBOVLAY1 EVERY NORMAL EOS      94200013
         SPACE 1                                                        94500013
*   LIST OF WORK AREAS USED BY THE MODULE                               94800013
         SPACE 1                                                        95100013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHARACTER CTR INITIALLY 95400013
*                                    PRESET TO 8 BY A.P.(2-BCC,2-SYSTEM 95700013
*                                      CHECK,4-EOS)                     96000013
*                                  IF 2314, INITIALLY SET TO 16 TO      96300013
*                                    INCLUDE CHAIN DISK ADDRESS TOO     96600013
WINNER   DC    F'0'                ADDR OF RCD IN RSA TO BE BLOCKED     96900013
*                                    POINTS TO 2 BYTE LENGTH FIELD      97200013
WKEEPAVA DC    F'0'                STARTG ADDR OF BIN                   97500013
WHOLD    DC    H'0'               HALF-WORD BOUNDARY WORK AREA          97800013
WLASTRCD DC    X'00'               LAST RCD SWITCH                      98100013
         EJECT                                                          98400013
         SMPPI                                                          98700013
         END                                                            99000013
