         TITLE '      IERABE - OS/360 SORT/MERGE - 360S-SM023 04/22/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERABE ***                                             00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 000                                                01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMENT MODULE. ANY V.L. SORT.   01400013
*   THE FUNCTION OF THIS MODULE IS TO OVERLAY IERRBE IN APPROPRIATE     01600013
*   PLACES DEPENDING UPON THE TYPE OF SORT.(I.E. TAPE, DISK, DRUM ETC.) 01800013
*   IT ALSO INITIALIZES POINTERS IN IERRBE.                             02000013
         SPACE 2                                                        02200013
*THIS MODULE IS USED AS A DSECT IN'                                     02400013
*                                                                       02600013
*   N/A                                                                 02800013
*                                                                       03000013
*                                                                       03200013
*MACROS USED                                                            03400013
*                                                                       03600013
*   SMPPI                                                               03800013
*                                                                       04000013
*                                                                       04200013
*ENTRY POINTS'                                                          04400013
*                                                                       04600013
*     ENTRY IERABE        ENTRY FROM IERRC9                             04800013
*                         CALLING SEQUENCE-                             05000013
*                           LOAD EP#IERABE,DCB#SORTLIB                  05200013
*                           LR    RP,RA                                 05400013
*                           BALR  RO,RP                                 05600013
*                                                                       05800013
         SPACE 2                                                        06000013
*INPUT: - PPI FIELDS REFERENCED -                                       06200013
         SPACE 1                                                        06400013
*   PPILAB04                                                            06600013
*   PPILAB07                                                            06800013
*   PPIBLK                                                              07000013
         SPACE 1                                                        07200013
*   VALUES USED TO COMPUTE THE SIZE OF THE OUTPUT BLOCK.                07400013
         SPACE 2                                                        07600013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED -                          07800013
         SPACE 1                                                        08000013
*   NONE                                                                08200013
         SPACE 2                                                        08400013
*EXTERNAL ROUTINES:                                                     08600013
         SPACE 1                                                        08800013
*    IERRBE                    BLOCK RUNNING PROGRAM                    09000013
         SPACE 2                                                        09200013
*EXTERNAL PARAMETERS:                                                   09400013
         SPACE 1                                                        09600013
*   NONE                                                                09800013
         SPACE 2                                                        10000013
*EXITS-NORMAL                                                           10200013
         SPACE 1                                                        10400013
*   IERRC9 -                       RETURN VIA RO                        10600013
         SPACE 2                                                        10800013
*EXITS-ERROR:                                                           11000013
         SPACE 1                                                        11200013
*   NONE                                                                11400013
         SPACE 2                                                        11600013
*TABLES/WORK AREAS:                                                     11800013
         SPACE 1                                                        12000013
*   NONE                                                                12200013
         SPACE 2                                                        12400013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12600013
         SPACE 2                                                        12800013
*NOTES:  THIS MODULE WILL BE EXECUTED ONLY FOR A VARIABLE LENGTH SORT.  13000013
         EJECT                                                          13200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            13400013
         SPACE 1                                                        13600013
RA       EQU   0                   CONTENTS IN - N/A                    13800013
*                                  USED - NOT USED                      14000013
*                                  CONTENT OUT - N/A                    14200013
RB       EQU   1                   CONTENTS IN- N/A                     14400013
*                                  USE- NOT USED                        14600013
*                                  CONTENTS OUT- N/A                    14800013
RC       EQU   2                   CONTENTS IN- N/A                     15000013
*                                  USE- NOT USED                        15200013
*                                  CONTENTS OUT- N/A                    15400013
RD       EQU   3                   CONTENTS IN- N/A                     15600013
*                                  USE- NOT USED                        15800013
*                                  CONTENTS OUT- N/A                    16000013
RE       EQU   4                   CONTENTS IN- N/A                     16200013
*                                  USE- NOT USED                        16400013
*                                  CONTENTS OUT- N/A                    16600013
RF       EQU   5                   CONTENTS IN - N/A                    16800013
*                                  USED - GENERAL WORK REGISTER         17000013
*                                  CONTENTS OUT - N/A                   17200013
RG       EQU   6                   CONTENTS IN - N/A                    17400013
*                                  USED - NOT USED                      17600013
*                                  CONTENTS OUT - N/A                   17800013
RH       EQU   7                   CONTENTS IN- N/A                     18000013
*                                  USE- NOT USED                        18200013
*                                  CONTENTS OUT- N/A                    18400013
RI       EQU   8                   CONTENTS IN- N/A                     18600013
*                                  USE- NOT USED                        18800013
*                                  CONTENTS OUT- N/A                    19000013
RJ       EQU   9                   CONTENTS IN- N/A                     19200013
*                                  USE- NOT USED                        19400013
*                                  CONTENTS OUT- N/A                    19600013
RK       EQU   10                  CONTENTS IN - N/A                    19800013
*                                  USED - BASE REG FOR IERRBE DSECT     20000013
*                                  CONTENTS OUT - N/A                   20200013
RL       EQU   11                  CONTENTS IN - N/A                    20400013
*                                  USED - MODULE BASE REGISTER          20600013
*                                  CONTENTS OUT - N/A                   20800013
RM       EQU   12                  CONTENTS IN - EQUALS OR EXTRACT ADDR 21000013
*                                  USED - NOT USED                      21200013
*                                  CONTENTS OUT - EQULS OR EXTRACT ADDR 21400013
RN       EQU   13                  CONTENTS IN - ADDRESS OF PPI         21600013
*                                  USED - PPI REFERENCES                21800013
*                                  CONTENTS OUT - ADDRESS OF PPI        22000013
RO       EQU   14                  CONTENTS IN - RETURN REG             22200013
*                                  USED - NOT USED                      22400013
*                                  CONTENTS OUT - RETURN REG            22600013
RP       EQU   15                  CONTENTS IN - THIS MODULE ENTRY ADDR 22800013
*                                  USED - ESTABLISH THIS MOD BASE REG   23000013
*                                  CONTENTS OUT - N/A                   23200013
         SPACE 2                                                        23400013
*START OF MODULE CODE PROPER:                                           23600013
         SPACE 2                                                        23800013
IERABE   CSECT                                                          24000013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    24200013
         USING IERRCA,RN           ADDR OF PPI                          24400013
         USING IERRBED,RK          ADDR OF RUNNING PROGRAM DUMMY MOD    24600013
IERMBA   LR    RL,RP               LOAD MODULE BASE REG                 24800013
         L     RK,PPIBLK+4         ADDR OF IERRBE(R.P) FOR DSECT BASE   25000013
         MVC   WBLKCCNT,KEIGHT     SET R.P. BLOCK CHAR CTR TO 8         25200013
         L     RF,PPILAB04         LOAD ADDR OF OUTPUT BUFFER #1        25400013
         LA    RF,0(0,RF)          DELETE HIGH ORDER BYTE.              25600013
         TM    PPISW1+1,X'40'      TEST IF TAPE SORT                    25800013
         BC    8,ABDISK            NO, BR TO OVERLAY R.P. FOR DISK      26000013
         SPACE 1                                                        26200013
*TAPE SORT ROUTINE. CALCULATE ENDING ADDR+1 OF THE OUTPUT BUFFER        26400013
         SPACE 1                                                        26600013
         AH    RF,PPILAB07+2       ADD ROUNDED LENGTH OF OUTPUT BLOCK   26800013
         ST    RF,WLSTPTR          HAS OUTPUT BLOCK PTR ENDING ADDR+1   27000013
         ST    RF,WLSTPTRD         CURRENT OUTPUT BLK ENDG ADDR+1       27200013
         MVC   RBDISK(2),KNOP      OVERLAY R.P. INSTR WITH A NOP        27400013
         MVC   RBLDLPTR(4),KON2    OVERLAY R.P. INSTR                   27600013
         MVC   RBTAPE1(4),KON2     OVERLAY R.P. INSTR                   27800013
         SPACE 1                                                        28000013
*INTERFACE TO NEXT MODULE                                               28200013
         SPACE 1                                                        28400013
ABNEXTAP BR    RO                  RETURN                               28600013
         SPACE 2                                                        28800013
*   DISK SORT ROUTINE                                                   29000013
         SPACE 1                                                        29200013
ABDISK   LA    RF,8(0,RF)          EQUALS OUTPUT BLOCK STARTING ADDR+8  29400013
         ST    RF,WLSTPTR          STORE IN R.P. OUTPUT BLK LIST PTR    29600013
         ST    RF,WLSTPTRD         STORE IN R.P. AS CURRENT OUTPUT      29800013
*                                    BLOCK ADDR+8                       30000013
         MVC   RBTAPE(2),KNOP      OVERLAY R.P. INSTR WITH A NOP        30200013
         MVC   RBOVLAY2(4),KON1    OVERLAY R.P. INSTR WITH KON1         30400013
         B     ABNEXTAP            BR TO INTERFACE FOR NEXT A.P.        30600013
         SPACE 2                                                        30800013
         SPACE 2                                                        31000013
*   LIST OF CONSTANTS USED BY MODULE                                    31200013
         SPACE 1                                                        31400013
KNOP     DC    X'4700'                                                  31600013
         DROP  RK                                                       31800013
         USING IERRBED,RL                                               32000013
KON1     L     RC,WLSTPTRD                                              32200013
KON2     L     RH,WLSTPTR                                               32400013
         USING IERABE,RL                                                32600013
         USING IERRBED,RK                                               32800013
         EJECT                                                          33000013
*   MODULE NAME *** IERRBE ***                                          33200013
         SPACE 2                                                        33400013
*   MODULE DEFINITION- BLOCK,SORTPHASE. THE MODULE HANDLES THE VARIABLE 33600013
*     LENGTH RECORDS BY WAY OF THE IOCS EXCP WRITE MACRO. THERE IS NO   33800013
*     DATA CHAINING AND THE MODULE MAINTAINS THE BUFFER SCHEME. THE     34000013
*     MODULE LINKS TO THE VARIABLE MOVE ROUTINE,IERRBF, WHICH MOVES THE 34200013
*     VARIABLE LENGTH RECORD FROM RSA(BINS) TO AN OUTPUT BUFFER. UPON   34400013
*     RETURN FROM THE MOVE ROUTINE, THE MODULE LINKS TO THE APPROPRIATE 34600013
*     DEBLOCK MODULE. THIS MODULE UPDATES THE NEXT AVAILABLE RSA BIN    34800013
*     POINTER AND BIN COUNTER LOCATED IN PPI.                           35000013
         SPACE 1                                                        35200013
*     INFORMATION COMMUNICATED BETWEEN MODULES---                       35400013
         SPACE 1                                                        35600013
*      REPLACEMENT TO BLOCK-- RD HAS ADDRESS OF RECORD IN RSA. 1ST 2    35800013
*        BYTES OF RECORD CONTAIN THE LENGTH.                            36000013
*      BLOCK TO MOVE-- RF HAS ADDRESS OF RCD IN RSA, RE HAS ADDRESS IN  36200013
*        OUTPUT BUFFER TO MOVE RECORD, RB HAS A 4 FOR BLOCK RTN.        36400013
*      MOVE TO BLOCK-- RB HAS NUMBER OF BINS FREED, RF POINTS TO LINK   36600013
*        ADDRESS OF LAST BIN MOVED.                                     36800013
*      BLOCK TO WRITE-- RB HAS OUTPUT BLOCK COUNT, RC HAS ADDRESS OF    37000013
*        OUTPUT BUFFER, RE HAS 4 FOR NORMAL EOS OTHERWISE HAS A ZERO    37200013
*      WRITE TO BLOCK-- RC HAS STARTING ADDRESS OF OUTPUT BLOCK+8 FOR   37400013
*        DISK OR ENDING ADDRESS OF OUTPUT BLOCK+1 FOR TAPE              37600013
         SPACE 2                                                        37800013
IERRBED  DSECT , DUMMY MODULE OF RUNNING PROGRAM CSECT **************** 38000013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    38200013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      38400013
         SPACE 1                                                        38600013
*   ENTRY TABLE                                                         38800013
         SPACE 1                                                        39000013
IERDB1   B     RBLSTRCD            LAST RCD ENTRY FROM REPLACEMENT      39200013
         B     RBEOS               EOS ENTRY FROM REPLACEMENT           39400013
         B     RBWRT               WRITE ENTRY.                         39600013
         B     RBLDCCNT            NORMAL ENTRY FROM REPLACEMENT        39800013
         B     *                   DUMMY ENTRY-NOT USED                 40000013
WLSTPTR  DC    F'0'                INITIALLY LOADED BY A.P. TO OUTPUT   40200013
*                                    BLOCK ENDING ADDR+1 FOR TAPE, OR   40400013
*                                    OUTPUT BLOCK STARTG ADDR+8 FOR A   40600013
*                                    DISK SORT                          40800013
WLSTPTRD DC    F'0'                CURRENT OUTPUT BLK STRTG ADDR+8-DISK 41000013
*                                    OR OUTPUT BLK ENDG ADDR+1-TAPE     41200013
*                                  BOTH POINTERS ARE RESET BY WRITE     41400013
*                                    RTN ON EOS                         41600013
*   NORMAL REPLACEMENT ENTRY-INCR BLOCK CHAR CTR,CHECK IF RCD WILL FIT  41800013
*     IN OUTPUT BLOCK. IF NOT, WRITE THE BUFFER BEFORE MOVING THE RCD.  42000013
         SPACE 1                                                        42200013
RBLDCCNT L     RG,WBLKCCNT         OUTPUT BLOCK CHARACTER CTR INITIALLY 42400013
*                                    PRESET TO 8 BY A.P.                42600013
         AH    RG,0(0,RD)          ADD LENGTH OF RCD TO BE MOVED        42800013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 43000013
         BC    2,RBWRTBLK          YES,BR TO WRITE THE BLOCK FIRST      43200013
RBSAVERD ST    RD,WINNER           SAVE ADDR OF RCD IN RSA TO BE BLOCKD 43400013
         L     RE,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD-    43600013
RBTAPE   SH    RE,0(0,RD)          DECR ADDR BY RCD LNGTH-FOR TAPE SORT 43800013
*                                    RCDS FILL OUTPUT BLOCK STARTING    44000013
*                                    FROM HIGH CORE TO LOW CORE. THIS   44200013
*                                    INSTR WILL BE NOP BY A.P. IF DISK  44400013
         SPACE 1                                                        44600013
*   CALCULATE BEGINNING ADDR OF THIS BIN + STORE AS NEW AVAILABLE BIN   44800013
         SPACE 1                                                        45000013
         S     RD,KFOUR            SUBTR 4 BYTES FOR TREE ADDR IN RSA   45200013
         SH    RD,PPILEXFF         SUBTR LENGTH OF CONTROL FIELD        45400013
         ST    RD,WKEEPAVA         SAVE STRTG ADDR OF BIN IN WORK AREA  45600013
         SPACE 1                                                        45800013
*   LOAD PARAMETERS AND BRANCH TO MOVE MODULE TO MOVE RCD FROM RSA TO   46000013
*     THE OUTPUT BLOCK. TEST IF LAST RCD SWITCH SET.                    46200013
         SPACE 1                                                        46400013
         L     RF,WINNER           LOAD ADDR OF RCD IN RSA              46600013
         L     RB,KFOUR            A 4 DENOTES A BLOCK RTN TO MOVE MOD  46800013
         L     RP,PPIBDSVA+12      LOAD ADDR OF MOVE RTN                47000013
*                                                                       47200013
         LR    RI,RE               ELLIOTT I PUT THIS IN.  DLB          47400013
*                                                                       47600013
         BALR  RO,RP               BR TO MOVE RTN(WILL SAVE ALL REGS +  47800013
*                                    PASS = BINS VACATED IN RB,AND LINK 48000013
*                                    ADDR OF LAST BIN OF RCD IN RF)     48200013
*                                                                       48400013
         LR    RE,RI               ELLIOTT I PUT THIS IN.  DLB          48600013
*                                                                       48800013
         CLI   WLASTRCD,X'00'      LAST RCD SWITCH ON                   49000013
         BC    7,RBSEQSW           YES,BR TO SET FINAL EOS SW FOR WRITE 49200013
         L     RI,WINNER           LOAD ADDR OF RCD IN RSA              49400013
RBDISK   AH    RE,0(0,RI)          DISK SORT ONLY-INCR ADDR IN OUTPUT   49600013
*                                    BLOCK BY RCD LENGTH. THIS INSTR    49800013
*                                    WILL BE A NOP IF TAPE SORT.        50000013
         ST    RE,WLSTPTR          SAVE UPDATED OUTPUT BLK ADDR PTR     50200013
         SPACE 1                                                        50400013
*   UPDATE BIN COUNT AND PTR TO NEXT AVAILABLE AREA IN RSA.UPDATE CHAIN 50600013
*     ADDRESS OF LAST BIN VACATED IN RSA IF BIN COUNT IS NOT ZERO       50800013
         SPACE 1                                                        51000013
         L     RI,PPIBDSVA+8       LOAD BIN COUNT                       51200013
         AR    RI,RB               INCR BY = OF BINS JUST VACATED       51400013
         ST    RI,PPIBDSVA+8       STORE UPDATED BIN COUNT FOR DEBLOCK  51600013
         CR    RI,RB               WAS BIN COUNT ZERO BEFORE INCR(IF SO 51800013
*                                    RI WILL NOW EQUAL RB)              52000013
         BC    8,RBSTOKEP          YES,BR TO UPDATE NEXT AVAILABLE BIN  52200013
*                                    PTR ONLY,BECAUSE ALL BINS ARE      52400013
*                                    LINKED TOGETHER ALREADY            52600013
         MVC   0(4,RF),PPIBDSVA+4  STORE ADDR OF NEXT AVAIL BIN IN LINK 52800013
*                                    ADDR OF LAST BIN VACATED           53000013
RBSTOKEP MVC   PPIBDSVA+4(4),WKEEPAVA  ADDR OF AVAIL BIN                53200013
         ST    RG,WBLKCCNT         SAVE CHARACTER COUNTER               53400013
         SPACE 1                                                        53600013
*   INTERFACE TO DEBLOCK MODULE                                         53800013
         SPACE 1                                                        54000013
RBOVLAY1 L     RL,PPIDEB+4         ADDR OF DEBLOCK MOD. THIS INSTR WILL 54200013
*                                    BE OVLAYED BY B RBLDLPTR ON NORMAL 54400013
*                                    EOS, THEN RESTORED FOR NEXT SEQ.   54600013
         B     8(RL)               BR TO DEBLOCK MOD                    54800013
         SPACE 2                                                        55000013
*   FINAL SEQUENCE ROUTINE FOR LAST RECORD                              55200013
         SPACE 1                                                        55400013
RBSEQSW  ST    RE,WLSTPTR          SAVE STRTG ADDR OF LAST RCD IN OUT-  55600013
*                                    PUT BLK FOR TAPE. IGNORE FOR DISK. 55800013
         SR    RE,RE               SET LAST SEQ SWITCH FOR WRITE MODULE 56000013
RBTAPE1  L     RH,WLSTPTRD         FOR DISK,LOAD OUTPUT BLK PTR. FOR    56200013
*                                    TAPE,A.P. WILL SET TO L RH,WLSTPTR 56400013
         B     RBDCRLST            BR TO DECR OUTPUT BLOCK PTR          56600013
         SPACE 2                                                        56800013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK.                  57000013
         SPACE 1                                                        57200013
RBWRTBLK SH    RG,0(0,RD)          SUBTRACT LENGTH OF RCD THAT CANT FIT 57400013
*                                    FROM OUTPUT BLOCK COUNT            57600013
RBOVLAY2 L     RC,WLSTPTR          LOAD OUTPUT BLK PTR.FOR DISK,WLSTPTR 57800013
*                                    WILL BE OVLAYED BY WLSTPTRD BY A.P 58000013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   58200013
         STH   RG,WHOLD            SET ON HALF WORD BOUNDARY            58400013
         MVC   0(2,RC),WHOLD       BCC IN 1ST 2 BYTES OF OUTPUT BLK     58600013
         LR    RB,RG                 ALSO,IN RB FOR WRITE PARAM         58800013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 59000013
         B     8(RL)               BR TO WRITE MODULE                   59200013
         SPACE 2                                                        59400013
*   WRITE MODULE REENTER VIA BRANCH TABLE. RC,FOR TAPE,HAS ADDR OF AN   59600013
*     OUTPUT BLK ENDING ADDR+1.RC,FOR DISK,HAS OUTPUT BLK STRTG ADDR+8  59800013
         SPACE 1                                                        60000013
RBWRT    ST    RC,WLSTPTRD         SAVE AS INITIAL OUTPUT BLK POINTER   60200013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLOCK WORK PTR       60400013
         LA    RG,8                REINITIALIZE BLOCK CHAR CTR TO 8     60600013
         AH    RG,0(0,RD)          ADD RCD LENGTH OF RCD TO BE MOVED    60800013
*                                    TO OUTPUT BLOCK                    61000013
         B     RBSAVERD                                                 61200013
         SPACE 2                                                        61400013
*   FROM REPLACEMENT. LAST RECORD                                       61600013
         SPACE 1                                                        61800013
RBLSTRCD OI    WLASTRCD,X'01'      TURN ON LAST RCD SWITCH              62000013
         B     RBLDCCNT                                                 62200013
         SPACE 2                                                        62400013
*   FROM REPLACEMENT. NORMAL EOS                                        62600013
         SPACE 1                                                        62800013
RBEOS    MVC   RBOVLAY1,KLDLPTR    OVLAY EXIT TO DEBLOCK FOR NORMAL EOS 63000013
         B     RBLDCCNT            BR TO MOVE LAST RCD OF THIS SEQUENCE 63200013
         SPACE 2                                                        63400013
*   RETURN FROM RBOVLAY1 WHICH WAS OVERLAYED ON THIS NORMAL EOS.        63600013
         SPACE 1                                                        63800013
RBLDLPTR L     RH,WLSTPTRD         LOAD OUTPUT BLOCK PTR(DISK SORT).A.P 64000013
*                                    WILL MAKE L RH,WLSTPTR (TAPE SORT) 64200013
         LA    RE,4                SET SWITCH TO NORMAL EOS FOR WRITE   64400013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           64600013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     64800013
         MVC   RBOVLAY1,KIERDD1    RESET RBOVLAY1 TO ORIGINAL INSTR     65000013
         SPACE 1                                                        65200013
*   CONTINUATION POINT FOR LAST RCD. RH POINTS TO BYTE AFTER EOS ENTRY  65400013
         SPACE 1                                                        65600013
RBDCRLST S     RH,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   65800013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      66000013
         STH   RG,WHOLD            SET ON HALF WORD BOUNDARY            66200013
         MVC   0(2,RH),WHOLD       BCC IN 1ST 2 BYTES OF OUTPUT BLK     66400013
         LR    RB,RG               LOAD BLOCK CHAR CNT FOR WRITE        66600013
         LR    RC,RH               LOAD OUTPUT BLOCK PTR FOR WRITE MOD  66800013
         SPACE 1                                                        67000013
*   INTERFACE TO WRITE MODULE FOR EOS                                   67200013
         SPACE 1                                                        67400013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 67600013
         B     4(RL)               BR TO WRITE MODULE                   67800013
         SPACE 2                                                        68000013
*   LIST OF CONSTANTS USED BY THE MODULE                                68200013
         SPACE 1                                                        68400013
KFOUR    DC    F'4'                                                     68600013
KEIGHT   DC    F'8'                                                     68800013
KIERDD1  L     RL,PPIDEB+4         RESTORE RBOVLAY1 AFTER NORMAL EOS    69000013
KLDLPTR  B     RBLDLPTR            OVLAY RBOVLAY1 EVERY NORMAL EOS      69200013
         SPACE 1                                                        69400013
*   LIST OF WORK AREAS USED BY THE MODULE                               69600013
         SPACE 1                                                        69800013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHARACTER CTR INITIALLY 70000013
*                                    PRESET TO 8 BY A.P.(2-BCC,2-SYSTEM 70200013
*                                      CHECK,4-EOS)                     70400013
WINNER   DC    F'0'                ADDR OF RCD IN RSA TO BE BLOCKED     70600013
*                                    POINTS TO 2 BYTE LENGTH FIELD      70800013
WKEEPAVA DC    F'0'                STARTG ADDR OF BIN                   71000013
WHOLD    DC    H'0'               HALF-WORD BOUNDARY WORK AREA          71200013
WLASTRCD DC    X'00'               LAST RCD SWITCH                      71400013
         EJECT                                                          71600013
         SMPPI                                                          71800013
         END                                                            72000013
