         TITLE ' IERABI - OS/360 SORT/MERGE - 360S-SM-023 05/06/65 '    00200013
*MODULE NAME  *** IERABI ***                                            00400013
         SPACE 2                                                        00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 000                                               01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION--ASSIGNMENT FOR THE RUNNING PROGRAM IERRBI,  01400013
*     BLOCK,PHASE 2. THIS MODULE TESTS WHETHER IT IS A DISK SORT OR     01600013
*     TAPE SORT AND OVERLAYS THE RUNNING PROGRAM WHEREVER NECESSARY.    01800013
*     IT ALSO SETS WORK AREAS AND CONSTANTS TO SPECIFIC VALUES IN THE   02000013
*     RUNNING PROGRAM.THE ASSIGNMENT PROGRAM UTILIZES THE DISK SORT     02200013
*     ROUTINE FOR THE FORWARD BLOCK TAPE SORT.                          02400013
         SPACE 1                                                        02600013
*     THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    02800013
*     INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            03000013
         SPACE 2                                                        03200013
         SPACE 2                                                        03400013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT'               03600013
*                                                                       03800013
*    N/A                                                                04000013
*                                                                       04200013
*MACROS USED'                                                           04400013
         SPACE 1                                                        04600013
*   SMPPI                                                               04800013
         SPACE 2                                                        05000013
*ENTRY POINTS:                                                          05200013
         SPACE 1                                                        05400013
*        ENTRY IERMBG              ENTRY FROM: LOAD MODULE, IERRC9      05600013
*                                    CALLING SEQUENCE-                  05800013
*                                       LOAD   EP=IERABI,DCB=           06000013
*                                       LR     RP,RA                    06200013
*                                       BALR   RO,RP                    06400013
         SPACE 2                                                        06600013
*INPUT: PPI FIELDS REFERENCED-                                          06800013
         SPACE 1                                                        07000013
*   PPILAB04    PPILAB07                                                07200013
*   PPISW1                                                              07400013
         SPACE 2                                                        07600013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             07800013
         SPACE 1                                                        08000013
*    CONSTANTS AND CODE IN THE RUNNING PROGRAM ARE INITIALIZED          08200013
         SPACE 2                                                        08400013
*EXTERNAL ROUTINES:                                                     08600013
         SPACE 1                                                        08800013
*        NONE                                                           09000013
         SPACE 2                                                        09200013
*EXTERNAL PARAMETERS:                                                   09400013
         SPACE 1                                                        09600013
*        NONE                                                           09800013
         SPACE 2                                                        10000013
*EXITS: NORMAL                                                          10200013
         SPACE 1                                                        10400013
*        BR    RO - RETURN TO LOAD MODULE, IERRC9                       10600013
         SPACE 2                                                        10800013
*EXITS: ERROR                                                           11000013
         SPACE 1                                                        11200013
*        NONE                                                           11400013
         SPACE 2                                                        11600013
*TABLES/WORK AREAS:                                                     11800013
         SPACE 1                                                        12000013
*        NONE                                                           12200013
         SPACE 2                                                        12400013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12600013
         SPACE 2                                                        12800013
*NOTES:                                                                 13000013
         SPACE 1                                                        13200013
*    THIS MODULE IS USED FOR VARIABLE LENGTH RECORDS WITHOUT USER EXITS 13400013
*   IN THE MERGE PHASE.                                                 13600013
         SPACE 2                                                        13800013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            14000013
         SPACE 1                                                        14200013
RA       EQU   0                   USE-NOT USED                         14400013
RB       EQU   1                   USE-NOT USED                         14600013
RC       EQU   2                   USE-NOT USED                         14800013
RD       EQU   3                   USE-NOT USED                         15000013
RE       EQU   4                   USE-NOT USED                         15200013
RF       EQU   5                   CONTENTS IN- N/A                     15400013
*                                  USE- WORK REGISTER                   15600013
*                                  CONTENTS OUT- N/A                    15800013
RG       EQU   6                   USE-NOT USED                         16000013
RH       EQU   7                   USE-NOT USED                         16200013
RI       EQU   8                   USE-NOT USED                         16400013
RJ       EQU   9                   USE-NOT USED                         16600013
RK       EQU   10                  CONTENTS IN- N/A                     16800013
*                                  USE- BASE REGISTER FOR DSECT OF      17000013
*                                       RUNNING PROGRAM                 17200013
*                                  CONTENTS OUT- N/A                    17400013
RL       EQU   11                  CONTENTS IN- N/A                     17600013
*                                  USE- BASE REGISTER FOR THIS MODULE   17800013
*                                  CONTENTS OUT- N/A                    18000013
RM       EQU   12                  USE-NOT USED                         18200013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          18400013
*                                  USE- PPI REFERENCE,REGISTER SAVE     18600013
*                                    AREA                               18800013
*                                  CONTENTS OUT- ADDRESS OF PPI         19000013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      19200013
*                                                IERRC9                 19400013
*                                  USE- NOT USED                        19600013
*                                  CONTENTS OUT- RETURN ADDRESS IN      19800013
*                                                IERRC9                 20000013
RP       EQU   15                  CONTENTS IN- BASE ADDRESS OF THIS    20200013
*                                               MODULE                  20400013
*                                  USE- NOT USED                        20600013
*                                  CONTENTS OUT- N/A                    20800013
         SPACE 2                                                        21000013
*START OF MODULE CODE PROPER:                                           21200013
         SPACE 2                                                        21400013
IERABI   CSECT                                                          21600013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    21800013
         USING IERRBID,RK          ADDR OF RUNNING PROGRAM DUMMY MOD    22000013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      22200013
IERMBG   LR    RL,RP               LOAD MODULE BASE REG                 22400013
         L     RK,PPIBLK2+4        LOAD ADDRESS OF RUNNING PROGRAM      22600013
         MVC   WBLKCCNT,KEIGHT     SET BLOCK CHARACTER CTR TO 8         22800013
         L     RF,PPILAB04         LOAD ADDR OF OUTPUT BUFFER 1         23000013
         LA    RF,0(0,RF)          DELETE HIGH ORDER BYTE.              23200013
         TM    PPISW1+1,X'40'      TAPE OR DIRECT ACCESS                23400013
         BZ    ABDISK              DIRECT ACCESS                        23600013
         SPACE 1                                                        23800013
         SPACE 1                                                        24000013
*   TEST FOR FORWARD BLOCK TAPE SORT                                    24200013
         SPACE 1                                                        24400013
         TM    PPISW1+6,X'10'      TEST PPI FOR FORWARD BLOCK BIT       24600013
         BC    1,ABDISK            IF BIT IS ON,BRANCH TO DISK ROUTINE  24800013
         SPACE 2                                                        25000013
*   TAPE SORT ROUTINE                                                   25200013
         SPACE 1                                                        25400013
         AH    RF,PPILAB07+2       ADD ROUNDED LENGTH OF OUTPUT BLOCK   25600013
         ST    RF,WLSTPTR          OUTPUT BLOCK ENDING ADDR+1           25800013
         ST    RF,WLSTPTRD         CURRENT OUTPUT BLK ENDING ADDR+1     26000013
         BR    RO                  RETURN TO LOAD MODULE                26200013
         SPACE 2                                                        26400013
*   DISK SORT ROUTINE                                                   26600013
         SPACE 1                                                        26800013
ABDISK   LA    RF,8(0,RF)          EQUALS OUTPUT BLOCK STRTG ADDR+8     27000013
         ST    RF,WLSTPTR          STORE IN R.P. AS OUTPUT BLK LIST PTR 27200013
         ST    RF,WLSTPTRD         CURRENT OUTPUT BLOCK STRTG ADDR+8    27400013
         MVC   RBSUBRLT(2),KNOP    NOP R.P. TAPE INSTR                  27600013
         MVC   RBSUBRLD(2),KNOP    NOP R.P. TAPE INSTR                  27800013
         MVC   RBLSTPTR(4),KON1    OVERLAY R.P. INSTR WITH KON1         28000013
         MVC   RBEOS(4),KON2       OVERLAY R.P. INSTR WITH KON2         28200013
         BR    RO                  RETURN TO LOAD MODULE                28400013
         SPACE 2                                                        28600013
*   LIST OF CONSTANTS USED BY THE MODULE                                28800013
         SPACE 1                                                        29000013
KNOP     DC    X'4700'             NOP                                  29200013
         DROP  RK                                                       29400013
         USING IERRBID,RL                                               29600013
KON1     L     RC,WLSTPTRD                                              29800013
KON2     L     RE,WLSTPTRD                                              30000013
         USING IERABI,RL                                                30200013
         USING IERRBID,RK                                               30400013
         EJECT                                                          30600013
         TITLE ' IERRBI - OS/360 SORT/MERGE - 360S-SM-023 05/06/65 '    30800013
*   MODULE NAME *** IERRBI ***                                          31000013
         SPACE 2                                                        31200013
*   MODULE DEFINITION ** THIS MODULE HANDLES THE DEBLOCKING AND         31400013
*     BLOCKING OF VARIABLE LENGTH RECORDS. THE BUFFERS ARE FILLED       31600013
*     BY THE READ MODULE AND EMPTIED BY THE WRITE MODULE USING EXCP     31800013
*     MACROS. THIS MODULE MOVES THE VARIABLE LENGTH RECORD FROM THE     32000013
*     INPUT BLOCK DIRECTLY TO THE OUTPUT BLOCK.                         32200013
         SPACE 1                                                        32400013
*     THE MERGE NETWORK INITIALLY PASSES A WINNER TO THE BLOCK SIDE OF  32600013
*     THIS MODULE. BLOCK SEES IF IT CAN FIT IN THE OUTPUT BLOCK AND IF  32800013
*     IT CAN'T, WRITES THE BLOCK THEN MOVES THE RECORD. IT THEN         33000013
*     BRANCHES TO THE DEBLOCK SIDE. DEBLOCK DEBLOCKS ANOTHER RECORD     33200013
*     FROM THE SAME FILE AS THE WINNER, TESTING FIRST IF THAT BLOCK     33400013
*     IS EMPTY. IF IT IS, DEBLOCK READS ANOTHER BLOCK FROM THE SAME     33600013
*     FILE. DEBLOCK THEN PASSES THE ADDRESS OF THE NEW RECORD TO THE    33800013
*     MERGE NETWORK. THE NETWORK FINDS ANOTHER WINNER AND THE PROCESS   34000013
*     IS REPEATED.                                                      34200013
         SPACE 2                                                        34400013
*   FLOWCHARTS --- B5,B7                                                34600013
         SPACE 2                                                        34800013
*   START OF MODULE CODE PROPER                                         35000013
         SPACE 1                                                        35200013
IERRBID  DSECT ,                   DUMMY MODULE OF REAL R.P. IERRBI *** 35400013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    35600013
         USING IERRCA,RN           ADDR OF PPI LOADED EXTERNALLY        35800013
         SPACE 1                                                        36000013
*   ENTRY TABLE                                                         36200013
         SPACE 1                                                        36400013
IERDB2   B     RBEOS               FROM MERGE ON NORMAL EOS             36600013
         B     RBRDRTRN            FROM READ MODULE                     36800013
         B     RBWRT               FROM WRITE MODULE                    37000013
         BC    0,RBSAVE            PRIMING ENTRY-ONLY FOR USER MODS MOD 37200013
         SPACE 1                                                        37400013
*   NORMAL MERGE ENTRY. INCR BLOCK CHAR CTR. CHECK IF RCD WILL FIT IN   37600013
*     OUTPUT BLOCK. IF NOT, WRITE THE BLOCK BEFORE MOVING THE RCD.      37800013
         SPACE 1                                                        38000013
         L     RG,WBLKCCNT         OUTPUT BLOCK CHAR CTR INITIALLY      38200013
*                                    PRESET TO 8 BY A.P.                38400013
         MVC   WRCDLGTH+2(2),0(RD)  MOVE RCD LENGTH TO PROPER BOUNDARY  38600013
         A     RG,WRCDLGTH         ADD RCD LENGTH TO OUTPUT BLOCK CHAR  38800013
*                                    CTR                                39000013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 39200013
         BC    2,RBWRTBLK          GRTR,BR TO WRITE THE BLOCK FIRST     39400013
RBSAVE   ST    RG,WBLKCCNT         SAVE UPDATED BLOCK CHAR CTR          39600013
         ST    RD,WINNER           SAVE ADDR OF RCD IN INPUT BLOCK      39800013
         L     RF,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD     40000013
RBSUBRLT S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR TAPE SORT 40200013
*                                    RCDS FILL OUTPUT BLOCK STARTG FROM 40400013
*                                    HI CORE TO LOW. A.P. WILL NOP THIS 40600013
*                                    INSTR IF DISK                      40800013
         L     RG,PPICOUNT         RECORD COUNTER                       41000013
         LA    RG,1(0,RG)          INCR BY 1 FOR THIS RCD               41200013
         ST    RG,PPICOUNT         STORE UPDATED RECORD COUNTER         41400013
         LR    RE,RD               ADDR OF RCD IN INPUT AREA FOR MOVE   41600013
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           41800013
         SPACE 1                                                        42000013
*   GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA   42200013
*     AREA TO ANOTHER. REGISTERS ARE USED AS FOLLOWS-                   42400013
         SPACE 1                                                        42600013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  42800013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    43000013
*        RI    DATA RCD LENGTH                                          43200013
         SPACE 1                                                        43400013
*   IN ADDITION THE ROUTINE USES REGISTERS RG AND RH.                   43600013
         SPACE 1                                                        43800013
         CL    RI,KON256           RCD LENGTH TO 256                    44000013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   44200013
         SPACE 1                                                        44400013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    44600013
         LNR   RG,RH                 256 BYTES EACH                     44800013
RBKMOVE  MVC   0(256,RF),0(RE)                                          45000013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     45200013
         AR    RF,RH                 BYTES                              45400013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    45600013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 45800013
         SPACE 2                                                        46000013
KON256   DC    F'256'                                                   46200013
KMOVE1   MVC   0(1,RF),0(RE)                                            46400013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             46600013
         BCTR  RG,0                DECR RG BY ONE                       46800013
         EX    RG,KMOVE1                                                47000013
         SPACE 1                                                        47200013
*   END OF GENERALIZED MOVE ROUTINE.                                    47400013
         SPACE 1                                                        47600013
         AR    RF,RI               UPDATE OUTPUT BLOCK RCD PTR BY       47800013
*                                    REMAINING RCD LENGTH               48000013
RBSUBRLD S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR DISK SORT 48200013
*                                    A.P. WILL NOP THIS INSTR.          48400013
         ST    RF,WLSTPTR          SAVE UPDATED OUTPUT BLOCK RCD PTR    48600013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            48800013
         SPACE 2                                                        49000013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK                   49200013
         SPACE 1                                                        49400013
RBWRTBLK S     RG,WRCDLGTH         SUBTR LENGTH OF RCD THAT CAN'T FIT   49600013
*                                    FROM OUTPUT BLOCK CHAR COUNT       49800013
RBLSTPTR L     RC,WLSTPTR          LOAD OUTPUT BLOCK RCD PTR. FOR DISK, 50000013
*                                    A.P.WILL OVERLAY WLSTPTR WITH      50200013
*                                    WLSTPTRD                           50400013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   50600013
         ST    RG,WBLKCCNT         STORE BLK CHAR CTR IN 1ST 2 BYTES    50800013
         MVC   0(2,RC),WBLKCCNT+2                                       51000013
         LR    RB,RG                 ALSO, IN RB FOR WRITE MODULE PARAM 51200013
         SPACE 1                                                        51400013
*   INTERFACE TO WRITE MODULE                                           51600013
         SPACE 1                                                        51800013
         L     RL,PPIWRT+4         LOAD ADDRESS OF WRITE ROUTINE        52000013
         B     8(RL)               BR TO WRITE MODULE                   52200013
         SPACE 1                                                        52400013
*   WRITE MODULE REENTERS VIA BRANCH TABLE. RC FOR TAPE,HAS AN OUTPUT   52600013
*     BLOCK ENDING ADDR+1. FOR DISK, RC HAS OUTPUT BLK STARTING ADDR+8  52800013
         SPACE 1                                                        53000013
RBWRT    ST    RC,WLSTPTRD         SAVE AS CURRENT OUTPUT BLK POINTER   53200013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLK WORK POINTER     53400013
         LA    RG,8                REINITIALIZE BLOCK CHAR CTR TO 8     53600013
         A     RG,WRCDLGTH         ADD LENGTH OF RCD TO BE MOVED TO     53800013
*                                    OUTPUT BLOCK                       54000013
         B     RBSAVE              BR TO MOVE RCD TO OUTPUT BLOCK       54200013
         SPACE 2                                                        54400013
*   FROM MERGE.NORMAL EOS.PREVIOUS RCD WAS EOS RCD AND IS IN OUTPUT BLK 54600013
*     NO NEW RECORDS PASSED TO BLOCK RTN AT THIS TIME.                  54800013
         SPACE 1                                                        55000013
RBEOS    L     RE,WLSTPTR          FOR TAPE USE WLSTPTR.FOR DISK,A.P.   55200013
*                                    WILL OVLAY WLSTPTR WITH WLSTPTRD   55400013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           55600013
         S     RE,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   55800013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      56000013
         MVC   0(2,RE),WBLKCCNT+2  STORE BLK CHAR CNT IN OUTPUT BLK     56200013
         L     RB,WBLKCCNT         LOAD BLOCK CHAR CNT FOR WRITE MOD    56400013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     56600013
         LA    RD,4                SET SWITCH TO NORMAL EOS FOR WRITE   56800013
         LR    RC,RE               LOAD OUTPUT BLOCK PTR FOR WRITE      57000013
         SPACE 1                                                        57200013
*   INTERFACE TO WRITE MODULE FOR NORMAL EOS                            57400013
         SPACE 1                                                        57600013
         L     RL,PPIWRT+4         LOAD ADDRESS OF WRITE ROUTINE        57800013
         B     4(RL)               BR TO WRITE MODULE                   58000013
         SPACE 2                                                        58200013
*   DEBLOCK SIDE OF PROGRAM                                             58400013
         SPACE 1                                                        58600013
RBDEBLCK SRL   RD,24               SHIFT TO GET AT INCR OF WINNER RCD   58800013
         L     RG,PPISBLCT         LOAD ADDR OF INPT BLK CHAR CNT TABLE 59000013
         L     RH,0(RD,RG)         LOAD BLK CHAR CNT OF WINNER'S BLOCK  59200013
         S     RH,WRCDLGTH         SUBTRACT RCD LENGTH OF WINNER        59400013
         C     RH,KZERO            TEST IF BLOCK CHAR CNT IS ZERO       59600013
         BC    8,RBREAD            YES,BR TO READ ANOTHER BLK INTO      59800013
*                                    INPUT BLK JUST VACATED             60000013
         ST    RH,0(RD,RG)         NO,STORE UPDATED BLOCK CHAR CNT      60200013
         L     RD,WINNER           RESTORE WINNER                       60400013
         A     RD,WRCDLGTH         ADDR OF NEXT RCD FROM WINNER FILE    60600013
         SPACE 1                                                        60800013
*   INTERFACE TO MERGE NETWORK                                          61000013
         SPACE 1                                                        61200013
RBMERGE  L     RL,PPINETM+4        LOAD ADDRESS OF MERGE NETWORK        61400013
         B     8(RL)               BR TO MERGE MODULE                   61600013
         SPACE 2                                                        61800013
*   FILL EMPTY INPUT BLOCK OF WINNER. RD HAS INCR IN LOW ORDER BYTE     62000013
         SPACE 1                                                        62200013
RBREAD   L     RG,PPIBDSVA         ADDR OF INPUT BLK ADDR TABLE         62400013
         L     RC,0(RD,RG)         ADDR OF THE WINNER'S INPUT BLOCK     62600013
         SPACE 1                                                        62800013
*   INTERFACE TO READ MODULE                                            63000013
         SPACE 1                                                        63200013
         L     RL,PPIRD+4          LOAD ADDRESS OF READ MODULE          63400013
         B     8(RL)               BR TO READ MODULE                    63600013
         SPACE 2                                                        63800013
*   READ MODULE RETURNS VIA THIS MODULE BRANCH TABLE. THE REGS CONTAIN  64000013
*     THE FOLLOWING.RB - BLOCK CNT,RC - ADDR OF 1ST RCD IN INPUT BLOCK. 64200013
*     RD - INCR,RE - ENDING ADDR OF BLOCK FOR TAPE OR STARTING ADDR     64400013
*     OF BLOCK FOR DISK.                                                64600013
         SPACE 1                                                        64800013
RBRDRTRN L     RG,PPISBLCT         LOAD ADDR OF BLOCK CNT TABLE         65000013
         S     RB,KFOUR            EQUALS TOTAL BYTES(OF RCDS)IN BLOCK  65200013
         ST    RB,0(RD,RG)         STORE NEW BLOCK CHAR CNT IN TABLE    65400013
         L     RG,PPIBDSVA         ADDR OF TABLE OF INPUT BLK STRTG     65600013
*                                    ADDRESSES                          65800013
         ST    RE,0(RD,RG)         STORE IN INDEXED POSITION IN TABLE   66000013
         SLL   RD,24               POSITION INCR IN HI BYTE             66200013
         AR    RD,RC               INSERT STRTG ADDR OF 1ST RCD OF BLK  66400013
         B     RBMERGE             BR TO MERGE                          66600013
         SPACE 2                                                        66800013
*   LIST OF CONSTANTS USED BY THE MODULE                                67000013
         SPACE 1                                                        67200013
KZERO    DC    F'0'                ZERO                                 67400013
KFOUR    DC    F'4'                FOUR                                 67600013
KEIGHT   DC    F'8'                EIGHT                                67800013
         SPACE 2                                                        68000013
*   LIST OF WORK AREAS                                                  68200013
         SPACE 1                                                        68400013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHAR CTR INITIALLY      68600013
*                                    PRESET TO 8 BY A.P.                68800013
WRCDLGTH DC    F'0'                LENGTH OF INPUT RECORD TO BE BLOCKED 69000013
WINNER   DC    F'0'                ADDR OF WINNER RCD IN INPUT BLOCK    69200013
WLSTPTR  DC    F'0'                ADDR IN OUTPUT BLOCK TO MOVE WINNER  69400013
*                                    A.P. INITIALLY SETS TO OUTPUT ENDG 69600013
*                                    ADDR+1 FOR TAPE,OR OUTPUT BLK      69800013
*                                    STARTG ADDR+8 FOR DISK SORT        70000013
WLSTPTRD DC    F'0'                CURRENT OUTPUT BLK STRTG ADDR+8-DISK 70200013
*                                    OR OUTPUT BLK ENDG ADDR+1-TAPE     70400013
         EJECT                                                          70600013
         SMPPI                                                          70800013
         END                                                            71000013
