         TITLE ' IERABK - OS/360 SORT/MERGE - 360S-SM-023 05/14/65 '    00200013
*   MODULE NAME *** IERABK ***                                          00400013
         SPACE 2                                                        00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 000                                               01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION- ASSIGNMENT FOR THE RUNNING PROG IERRBK,     01400013
*     BLOCK,PHASE 2. THIS MODULE TESTS WHETHER IT IS A DISK SORT OR     01600013
*     TAPE SORT AND OVERLAYS THE RUNNING PROGRAM WHEREVER NECESSARY.    01800013
*     IT ALSO SETS WORK AREAS AND CONSTANTS TO SPECIFIC VALUES IN THE   02000013
*     RUNNING PROGRAM. THE ASSIGNMENT PROGRAM UTILIZES THE DISK SORT    02200013
*     ROUTINE FOR THE FORWARD BLOCK TAPE SORT.                          02400013
         SPACE 1                                                        02600013
*     THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR    02800013
*     INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.            03000013
         SPACE 2                                                        03200013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT'               03400013
*                                                                       03600013
*      N/A                                                              03800013
*                                                                       04000013
*MACROS USED'                                                           04200013
         SPACE 1                                                        04400013
*   SMPPI                                                               04600013
         SPACE 2                                                        04800013
*ENTRY POINTS:                                                          05000013
         SPACE 1                                                        05200013
*        ENTRY IERMGB              ENTRY FROM: LOAD MODULE, IERRC9      05400013
*                                    CALLING SEQUENCE-                  05600013
*                                       LOAD   EP=IERABK,DCB=           05800013
*                                       LR     RP,RA                    06000013
*                                       BALR   RO,RP                    06200013
         SPACE 2                                                        06400013
*INPUT: PPI FIELDS REFERENCED-                                          06600013
         SPACE 1                                                        06800013
*   PPILAB04    PPILAB07                                                07000013
*   PPISW1                                                              07200013
         SPACE 2                                                        07400013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             07600013
         SPACE 1                                                        07800013
*   CONSTANTS AND CODE IN THE RUNNING PROGRAM ARE INITIALIZED           08000013
         SPACE 2                                                        08200013
*EXTERNAL ROUTINES:                                                     08400013
         SPACE 1                                                        08600013
*        NONE                                                           08800013
         SPACE 2                                                        09000013
*EXTERNAL PARAMETERS:                                                   09200013
         SPACE 1                                                        09400013
*        NONE                                                           09600013
         SPACE 2                                                        09800013
*EXITS: NORMAL                                                          10000013
         SPACE 1                                                        10200013
*        BR    RO - RETURN TO LOAD MODULE, IERRC9                       10400013
         SPACE 2                                                        10600013
*EXITS: ERROR                                                           10800013
         SPACE 1                                                        11000013
*        NONE                                                           11200013
         SPACE 2                                                        11400013
*TABLES/WORK AREAS:                                                     11600013
         SPACE 1                                                        11800013
*        NONE                                                           12000013
         SPACE 2                                                        12200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12400013
         SPACE 2                                                        12600013
*NOTES:                                                                 12800013
         SPACE 1                                                        13000013
*   THIS MODULE IS USED FOR VARIABLE LENGTH RECORDS WITH USER EXIT E25  13200013
*   IN THE MERGE PHASE.                                                 13400013
         SPACE 2                                                        13600013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            13800013
         SPACE 1                                                        14000013
RA       EQU   0                   USE-NOT USED                         14200013
RB       EQU   1                   USE-NOT USED                         14400013
RC       EQU   2                   USE-NOT USED                         14600013
RD       EQU   3                   USE-NOT USED                         14800013
RE       EQU   4                   USE-NOT USED                         15000013
RF       EQU   5                   CONTENTS IN- N/A                     15200013
*                                  USE- WORK REGISTER                   15400013
*                                  CONTENTS OUT- N/A                    15600013
RG       EQU   6                   USE-NOT USED                         15800013
RH       EQU   7                   USE-NOT USED                         16000013
RI       EQU   8                   USE-NOT USED                         16200013
RJ       EQU   9                   USE-NOT USED                         16400013
RK       EQU   10                  CONTENTS IN- N/A                     16600013
*                                  USE- BASE REGISTER FOR DSECT OF      16800013
*                                       RUNNIN PROGRAM                  17000013
*                                  CONTENTS OUT- N/A                    17200013
RL       EQU   11                  CONTENTS IN- N/A                     17400013
*                                  USE- BASE REGISTER FOR THIS MODULE   17600013
*                                  CONTENTS OUT- N/A                    17800013
RM       EQU   12                  USE-NOT USED                         18000013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          18200013
*                                  USE- PPI REFERENCE,REGISTER SAVE     18400013
*                                    AREA                               18600013
*                                  CONTENTS OUT- ADDRESS OF PPI         18800013
RO       EQU   14                  CONTENTS IN- RETURN ADDRESS IN       19000013
*                                               IERRC9                  19200013
*                                  USE- NOT USED                        19400013
*                                  CONTENTS OUT- RETURN ADDRESS IN      19600013
*                                                IERRC9                 19800013
RP       EQU   15                  CONTENTS IN- BASE ADDRESS OF THIS    20000013
*                                               MODULE                  20200013
*                                  USE- NOT USED                        20400013
*                                  CONTENTS OUT- N/A                    20600013
         SPACE 2                                                        20800013
*START OF MODULE CODE PROPER:                                           21000013
         SPACE 2                                                        21200013
IERABK   CSECT                                                          21400013
*1601376000,430000,464000                                          4553 21500018
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    21600013
         USING IERRBKD,RK          ADDR OF RUNNING PROGRAM DUMMY MOD    21800013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      22000013
IERMBG   LR    RL,RP               LOAD MODULE BASE REG                 22200013
         L     RK,PPIBLK2+4        LOAD ADDRESS OF RUNNING PROGRAM      22400013
         MVC   WBLKCCNT,KEIGHT     SET BLOCK CHARACTER CTR TO 8         22600013
         L     RF,PPILAB04         LOAD ADDR OF OUTPUT BUFFER 1         22800013
         LA    RF,0(0,RF)          DELETE HIGH ORDER BYTE.              23000013
         TM    PPISW1+1,X'40'      TAPE OR DIRECT ACCESS                23200013
         BZ    ABDISK              DIRECT ACCESS                        23400013
         SPACE 1                                                        23600013
         SPACE 1                                                        23800013
*   TEST FORWARD BLOCK BIT IN PPI                                       24000013
         SPACE 1                                                        24200013
         TM    PPISW1+6,X'10'      TEST FORWARD BLOCK BIT IN PPI        24400013
         BC    1,ABDISK            IF ON BRANCH TO DISK SORT ROUTINE    24600013
         SPACE 2                                                        24800013
*   TAPE SORT ROUTINE                                                   25000013
         SPACE 1                                                        25200013
         AH    RF,PPILAB07+2       ADD ROUNDED LENGTH OF OUTPUT BLOCK   25400013
         ST    RF,WLSTPTR          OUTPUT BLOCK ENDING ADDR+1           25600013
         ST    RF,WLSTPTRD         CURRENT OUTPUT BLK ENDING ADDR+1     25800013
         BR    RO                  RETURN TO LOAD MODULE                26000013
         SPACE 2                                                        26200013
*   DISK SORT ROUTINE                                                   26400013
         SPACE 1                                                        26600013
ABDISK   LA    RF,8(0,RF)          EQUALS OUTPUT BLOCK STRTG ADDR+8     26800013
         ST    RF,WLSTPTR          STORE IN R.P. AS OUTPUT BLK LIST PTR 27000013
         ST    RF,WLSTPTRD         CURRENT OUTPUT BLOCK ADDR+8          27200013
         MVC   RBSUBRLT(2),KNOP    NOP R.P. TAPE INSTR                  27400013
         MVC   RBSUBRLD(2),KNOP    NOP R.P. TAPE INSTR                  27600013
         MVC   RBLSTPTR(4),KON1    OVERLAY R.P. INSTR WITH KON1         27800013
         MVC   RBEOS(4),KON2       OVERLAY R.P. INSTR WITH KON2         28000013
         BR    RO                  RETURN TO LOAD MODULE                28200013
         SPACE 2                                                        28400013
*   LIST OF CONSTANTS USED BY THE MODULE                                28600013
         SPACE 1                                                        28800013
KNOP     DC    X'4700'             NOP                                  29000013
         DROP  RK                                                       29200013
         USING IERRBKD,RL                                               29400013
KON1     L     RC,WLSTPTRD                                              29600013
KON2     L     RE,WLSTPTRD                                              29800013
         USING IERABK,RL                                                30000013
         USING IERRBKD,RK                                               30200013
         EJECT                                                          30400013
*   MODULE NAME *** IERRBK *** USER EXIT E25                            30600013
         SPACE 2                                                        30800013
*   MODULE DEFINITION ** THIS MODULE HANDLES THE DEBLOCKING AND         31000013
*     BLOCKING OF VARIABLE LENGTH RECORDS. THE BUFFERS ARE FILLED       31200013
*     BY THE READ MODULE AND EMPTIED BY THE WRITE MODULE USING EXCP     31400013
*     MACROS. THIS MODULE MOVES THE VARIABLE LENGTH RECORD FROM THE     31600013
*     INPUT BLOCK DIRECTLY TO THE OUTPUT BLOCK.                         31800013
         SPACE 1                                                        32000013
*     THE USER EXIT,E25,IS ON THE BLOCK SIDE AND IS EXECUTED ONCE FOR   32200013
*     EVERY RECORD,EXCEPT THE FIRST RECORD OF EACH OUTPUT SEQUENCE.     32400013
*     THE EXIT OCCURS AFTER THE RECORD LEAVES THE MERGE AND WHILE THE   32600013
*     PREVIOUS RECORD IS AVAILABLE IN THE OUTPUT AREA. THE EXIT IS FOR  32800013
*     SUMMARIZATION AND DELETION OF RECORDS(EXCEPT ON THE FIRST RECORD  33000013
*     OF EACH OUTPUT SEQUENCE)                                          33200013
         SPACE 1                                                        33400013
*     THE MERGE NETWORK INITIALLY PASSES A WINNER TO THE BLOCK SIDE OF  33600013
*     THIS MODULE. BLOCK SEES IF IT CAN FIT IN THE OUTPUT BLOCK AND IF  33800013
*     IT CAN'T, WRITES THE BLOCK THEN MOVES THE RECORD. IT THEN         34000013
*     BRANCHES TO THE DEBLOCK SIDE. DEBLOCK DEBLOCKS ANOTHER RECORD     34200013
*     FROM THE SAME FILE AS THE WINNER, TESTING FIRST IF THAT BLOCK     34400013
*     IS EMPTY. IF IT IS, DEBLOCK READS ANOTHER BLOCK FROM THE SAME     34600013
*     FILE. DEBLOCK THEN PASSES THE ADDRESS OF THE NEW RECORD TO THE    34800013
*     MERGE NETWORK. THE NETWORK FINDS ANOTHER WINNER AND THE PROCESS   35000013
*     IS REPEATED.                                                      35200013
         SPACE 2                                                        35400013
*   START OF MODULE CODE PROPER                                         35600013
         SPACE 1                                                        35800013
IERRBKD  DSECT ,                   DUMMY MODULE OF REAL R.P. IERRBK *** 36000013
         USING IERRCA,RN           ADDR OF PPI LOADED EXTERNALLY        36200013
         SPACE 1                                                        36400013
*   ENTRY TABLE                                                         36600013
         SPACE 1                                                        36800013
IERDB2   B     RBEOS               FROM MERGE ON NORMAL EOS             37000013
         B     RBRDRTRN            FROM READ MODULE                     37200013
         B     RBWRT               FROM WRITE MODULE                    37400013
         B     RBBPSUS1            PRIME ENTRY,BYPASS EXIT RTN     4553 37600018
         SPACE 1                                                        37800013
*   NORMAL MERGE ENTRY. INCR BLOCK CHAR CTR. CHECK IF RCD WILL FIT IN   38000013
*     OUTPUT BLOCK. IF NOT, WRITE THE BLOCK BEFORE MOVING THE RCD.      38200013
         SPACE 1                                                        38400013
         ST    RD,WMRGRCD          PARAM 1 TO USER.ADDR OF RCD IN INPUT 38600013
*                                    BLOCK                              38800013
         SPACE 1                                                        39000013
*   CALL MACRO EXPANSION INSTRUCTIONS TO USER EXIT E25                  39200013
         SPACE 1                                                        39400013
         L     RP,PPIX25+4                                              39600013
         LA    RB,WMRGRCD                                               39800013
         BALR  RO,RP                                                    40000013
         SPACE 1                                                        40200013
*   RETURN FROM USER                                                    40400013
         SPACE 1                                                        40600013
         B     *+4(RP)                                                  40800013
         B     RBBPSUSR            DO NOTHING                           41000013
         L     RG,PPIDELCT         DELETE COUNTER                       41200013
         LA    RG,1(0,RG)          INCR DELETE CTR BY 1                 41400013
         ST    RG,PPIDELCT         SAVE UPDATED DELETE CTR              41600013
         ST    RD,WINNER           SAVE WINNER ADDR (DEBLK WILL DELETE) 41800013
         MVC   WRCDLGTH+2(2),0(RD)  MOVE RCD LENGTH TO PROPER BOUNDARY  42000013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            42200013
RBBPSUS1 LR    RB,RD                                               4553 42300018
         SPACE 1                                                        42400013
RBBPSUSR L     RG,WBLKCCNT         OUTPUT BLOCK CHAR CTR INITIALLY      42600013
*                                    PRESET TO 8 BY A.P.                42800013
         MVC   WRCDLGTH+2(2),0(RB) MOVE RCD LENGTH TO PROPER BNDRY 4553 43000018
         A     RG,WRCDLGTH         ADD RCD LENGTH TO OUTPUT BLOCK CHAR  43200013
*                                    CTR                                43400013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 43600013
         BC    2,RBWRTBLK          GRTR,BR TO WRITE THE BLOCK FIRST     43800013
RBSAVE   ST    RG,WBLKCCNT         SAVE UPDATED BLOCK CHAR CTR          44000013
         ST    RD,WINNER           SAVE ADDR OF RCD IN INPUT BLOCK      44200013
         L     RF,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD     44400013
RBSUBRLT S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR TAPE SORT 44600013
*                                    RCDS FILL OUTPUT BLOCK STARTG FROM 44800013
*                                    HI CORE TO LOW. A.P. WILL NOP THIS 45000013
*                                    INSTR IF DISK                      45200013
         ST    RF,WOUTRCD          PARAM 2 TO USER.ADDR OF RCD IN       45400013
*                                    OUTPUT BLOCK                       45600013
         L     RG,PPICOUNT         RECORD COUNTER                       45800013
         LA    RG,1(0,RG)          INCR BY 1 FOR THIS RCD               46000013
         ST    RG,PPICOUNT         STORE UPDATED RECORD COUNTER         46200013
         LR    RE,RB               ADDR OF RCD IN INPUT AREA       4553 46400018
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           46600013
         SPACE 1                                                        46800013
*   GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA   47000013
*     AREA TO ANOTHER. REGISTERS ARE USED AS FOLLOWS-                   47200013
         SPACE 1                                                        47400013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  47600013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    47800013
*        RI    DATA RCD LENGTH                                          48000013
         SPACE 1                                                        48200013
*   IN ADDITION THE ROUTINE USES REGISTERS RG AND RH.                   48400013
         SPACE 1                                                        48600013
         CL    RI,KON256           RCD LENGTH TO 256                    48800013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   49000013
         SPACE 1                                                        49200013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    49400013
         LNR   RG,RH                 256 BYTES EACH                     49600013
RBKMOVE  MVC   0(256,RF),0(RE)                                          49800013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     50000013
         AR    RF,RH                 BYTES                              50200013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    50400013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 50600013
         SPACE 2                                                        50800013
KON256   DC    F'256'                                                   51000013
KMOVE1   MVC   0(1,RF),0(RE)                                            51200013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             51400013
         BCTR  RG,0                DECR RG BY ONE                       51600013
         EX    RG,KMOVE1                                                51800013
         SPACE 1                                                        52000013
*   END OF GENERALIZED MOVE ROUTINE.                                    52200013
         SPACE 1                                                        52400013
         AR    RF,RI               UPDATE OUTPUT BLOCK RCD PTR BY       52600013
*                                    REMAINING RCD LENGTH               52800013
RBSUBRLD S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR DISK SORT 53000013
*                                    A.P. WILL NOP THIS INSTR.          53200013
         ST    RF,WLSTPTR          SAVE UPDATED OUTPUT BLOCK RCD PTR    53400013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            53600013
         SPACE 2                                                        53800013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK                   54000013
         SPACE 1                                                        54200013
RBWRTBLK S     RG,WRCDLGTH         SUBTR LENGTH OF RCD THAT CAN'T FIT   54400013
*                                    FROM OUTPUT BLOCK CHAR COUNT       54600013
         ST    RB,WRBSAVE          STORE MOD RCD ADDR              4553 54700018
RBLSTPTR L     RC,WLSTPTR          LOAD OUTPUT BLOCK RCD PTR. FOR DISK, 54800013
*                                    A.P.WILL OVERLAY WLSTPTR WITH      55000013
*                                    WLSTPTRD                           55200013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   55400013
         ST    RG,WBLKCCNT         ALIGN TO WD BOUNDARY                 55600013
         MVC   0(2,RC),WBLKCCNT+2  STORE BLOK CHAR CTR IN 1ST 2 BYTES   55800013
         LR    RB,RG                 ALSO, IN RB FOR WRITE MODULE PARAM 56000013
         SPACE 1                                                        56200013
*   INTERFACE TO WRITE MODULE                                           56400013
         SPACE 1                                                        56600013
         L     RL,PPIWRT+4         LOAD ADDRESS OF WRITE ROUTINE        56800013
         B     8(RL)               BR TO WRITE MODULE                   57000013
         SPACE 1                                                        57200013
*   WRITE MODULE REENTERS VIA BRANCH TABLE. RC FOR TAPE,HAS AN OUTPUT   57400013
*     BLOCK ENDING ADDR+1. FOR DISK, RC HAS OUTPUT BLK STARTING ADDR+8  57600013
         SPACE 1                                                        57800013
RBWRT    ST    RC,WLSTPTRD         SAVE AS CURRENT OUTPUT BLK POINTER   58000013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLK WORK POINTER     58200013
         LA    RG,8                REINITIALIZE BLOCK CHAR CTR TO 8     58400013
         A     RG,WRCDLGTH         ADD LENGTH OF RCD TO BE MOVED TO     58600013
*                                    OUTPUT BLOCK                       58800013
         L     RB,WRBSAVE          RELOAD MOD RCD ADDR             4553 58900018
         B     RBSAVE              BR TO MOVE RCD TO OUTPUT BLOCK       59000013
         SPACE 2                                                        59200013
*   FROM MERGE.NORMAL EOS.PREVIOUS RCD WAS EOS RCD AND IS IN OUTPUT BLK 59400013
*     NO NEW RECORDS PASSED TO BLOCK RTN AT THIS TIME.                  59600013
         SPACE 1                                                        59800013
RBEOS    L     RE,WLSTPTR          FOR TAPE USE WLSTPTR.FOR DISK,A.P.   60000013
*                                    WILL OVLAY WLSTPTR WITH WLSTPTRD   60200013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           60400013
         S     RE,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   60600013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      60800013
         MVC   0(2,RE),WBLKCCNT+2  STORE BLK CHAR CNT IN OUTPUT BLK     61000013
         L     RB,WBLKCCNT         LOAD BLOCK CHAR CNT FOR WRITE MOD    61200013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     61400013
         LA    RD,4                SET SWITCH TO NORMAL EOS FOR WRITE   61600013
         LR    RC,RE               LOAD OUTPUT BLOCK PTR FOR WRITE      61800013
         SPACE 1                                                        62000013
*   INTERFACE TO WRITE MODULE FOR NORMAL EOS                            62200013
         SPACE 1                                                        62400013
         L     RL,PPIWRT+4         LOAD ADDRESS OF WRITE ROUTINE        62600013
         B     4(RL)               BR TO WRITE MODULE                   62800013
         EJECT                                                          63000013
*   DEBLOCK SIDE OF PROGRAM                                             63200013
         SPACE 1                                                        63400013
RBDEBLCK SRL   RD,24               SHIFT TO GET AT INCR OF WINNER RCD   63600013
         L     RG,PPISBLCT         LOAD ADDR OF INPT BLK CHAR CNT TABLE 63800013
         L     RH,0(RD,RG)         LOAD BLK CHAR CNT OF WINNER'S BLOCK  64000013
         S     RH,WRCDLGTH         SUBTRACT RCD LENGTH OF WINNER        64200013
         C     RH,KZERO            TEST IF BLOCK CHAR CNT IS ZERO       64400013
         BC    8,RBREAD            YES,BR TO READ ANOTHER BLK INTO      64600013
*                                    INPUT BLK JUST VACATED             64800013
         ST    RH,0(RD,RG)         NO,STORE UPDATED BLOCK CHAR CNT      65000013
         L     RD,WINNER           RESTORE WINNER                       65200013
         A     RD,WRCDLGTH         ADDR OF NEXT RCD FROM WINNER FILE    65400013
         SPACE 1                                                        65600013
*   INTERFACE TO MERGE NETWORK                                          65800013
         SPACE 1                                                        66000013
RBMERGE  L     RL,PPINETM+4        LOAD ADDRESS OF MERGE NETWORK        66200013
         B     8(RL)               BR TO MERGE MODULE                   66400013
         SPACE 2                                                        66600013
*   FILL EMPTY INPUT BLOCK OF WINNER. RD HAS INCR IN LOW ORDER BYTE     66800013
         SPACE 1                                                        67000013
RBREAD   L     RG,PPIBDSVA         ADDR OF INPUT BLK ADDR TABLE         67200013
         L     RC,0(RD,RG)         ADDR OF THE WINNER'S INPUT BLOCK     67400013
         SPACE 1                                                        67600013
*   INTERFACE TO READ MODULE                                            67800013
         SPACE 1                                                        68000013
         L     RL,PPIRD+4          LOAD ADDRESS OF READ MODULE          68200013
         B     8(RL)               BR TO READ MODULE                    68400013
         SPACE 2                                                        68600013
*   READ MODULE RETURNS VIA THIS MODULE BRANCH TABLE. THE REGS CONTAIN  68800013
*     THE FOLLOWING.RB - BLOCK CNT,RC - ADDR OF 1ST RCD IN INPUT BLOCK. 69000013
*     RD - INCR,RE - ENDING ADDR OF BLOCK FOR TAPE OR STARTING ADDR     69200013
*     OF BLOCK FOR DISK.                                                69400013
         SPACE 1                                                        69600013
RBRDRTRN L     RG,PPISBLCT         LOAD ADDR OF BLOCK CNT TABLE         69800013
         S     RB,KFOUR            EQUALS TOTAL BYTES(OF RCDS)IN BLK    70000013
         ST    RB,0(RD,RG)         STORE NEW BLOCK CHAR CNT IN TABLE    70200013
         L     RG,PPIBDSVA         ADDR OF TABLE OF INPUT BLK STRTG     70400013
*                                    ADDRESSES                          70600013
         ST    RE,0(RD,RG)         STORE IN INDEXED POSITION IN TABLE   70800013
         SLL   RD,24               POSITION INCR IN HI BYTE             71000013
         AR    RD,RC               INSERT STRTG ADDR OF 1ST RCD OF BLK  71200013
         B     RBMERGE             BR TO MERGE NETWORK                  71400013
         SPACE 2                                                        71600013
*   LIST OF CONSTANTS USED BY THE MODULE                                71800013
         SPACE 1                                                        72000013
KZERO    DC    F'0'                ZERO                                 72200013
KFOUR    DC    F'4'                FOUR                                 72400013
KEIGHT   DC    F'8'                EIGHT                                72600013
         SPACE 2                                                        72800013
*   LIST OF WORK AREAS                                                  73000013
         SPACE 1                                                        73200013
WMRGRCD  DC    F'0'                ADDR OF RCD IN INPUT BLK-USER PARAM1 73400013
WOUTRCD  DC    F'0'                ADDR OF RCD IN OUTPUT BLK-USR PARAM2 73600013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHAR CTR INITIALLY      73800013
*                                    PRESET TO 8 BY A.P.                74000013
WRCDLGTH DC    F'0'                LENGTH OF INPUT RECORD TO BE BLOCKED 74200013
WINNER   DC    F'0'                ADDR OF WINNER RCD IN INPUT BLOCK    74400013
WLSTPTR  DC    F'0'                ADDR IN OUTPUT BLOCK TO MOVE WINNER  74600013
*                                    A.P. INITIALLY SETS TO OUTPUT ENDG 74800013
*                                    ADDR+1 FOR TAPE,OR OUTPUT BLK      75000013
*                                    STARTG ADDR+8 FOR DISK SORT        75200013
WLSTPTRD DC    F'0'                CURRENT OUTPUT BLK STRTG ADDR+8-DISK 75400013
*                                    OR OUTPUT BLK ENDG ADDR+1-TAPE     75600013
WRBSAVE  DC    F'0'                CURRENT MODIFIED RCD ADDR       4553 75700018
         EJECT                                                          75800013
         SMPPI                                                          76000013
         END                                                            76200013
