         TITLE '      IERABM - OS/360 SORT/MERGE - 360S-SM023 04/21/66' 00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERABM ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION/OPERATION: PHASE 3 ASSIGNMENT MODULE. F.L. WITH E35.   02100013
*   THE FUNCTION OF THIS MODULE IS TO INSERT THE ADDRESS OF THE OUTPUT  02400013
*   DCB IN IERRBM. IT ALSO CHECKS TO SEE IF ATTACHED IN PHASE 3 AND IF  02700013
*   ATTACHED, INSERTS THIS ADDRESS FROM PPIATP3E IN PPIX35. IF NOT      03000013
*   ATTACHED EXIT E35 HAS BEEN ACTIVATED THROUGH THE CTL CARDS          03300013
         SPACE 2                                                        03600013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT'               03900013
*                                                                       04200013
*     N/A                                                               04500013
*                                                                       04800013
*LIST OF MACROS USED BY THE MODULE:                                     05100013
         SPACE 1                                                        05400013
*   SMPPI                                                               05700013
         SPACE 2                                                        06000013
*ENTRY POINTS:                                                          06300013
         SPACE 1                                                        06600013
*        ENTRY IERABM              ENTRY FROM IERRC9                    06900013
*                                    CALLING SEQUENCE-                  07200013
*                                      LOAD  EP=IERABM,DCB=SORTLIB      07500013
*                                      LR    RP,RA                      07800013
*                                      BALR  RO,RP                      08100013
         SPACE 2                                                        08400013
*INPUT: - PPI FIELDS REFERENCED                                         08700013
         SPACE 1                                                        09000013
*   PPISTDCB                                                            09300013
*   PPIATP3E                                                            09600013
         SPACE 1                                                        09900013
*   STARTING ADDR OF THE DCBS AND USER ATTACHED EXIT ADDRESS            10200013
         SPACE 2                                                        10500013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED                              10800013
         SPACE 1                                                        11100013
*   NONE                                                                11400013
         SPACE 2                                                        11700013
*EXTERNAL ROUTINES:                                                     12000013
         SPACE 1                                                        12300013
*   NONE                                                                12600013
         SPACE 2                                                        12900013
*EXTERNAL PARAMETERS:                                                   13200013
         SPACE 1                                                        13500013
*   SEE REGISTERS                                                       13800013
         SPACE 2                                                        14100013
*EXITS-NORMAL:                                                          14400013
         SPACE 1                                                        14700013
*   TO IERRC9                      EXIT TO IERRC9.                      15000013
*                                    CALLING SEQUENCE-                  15300013
*                                      BR  RO                           15600013
         SPACE 2                                                        15900013
*EXITS-ERROR                                                            16200013
         SPACE 1                                                        16500013
*   NONE                                                                16800013
         SPACE 2                                                        17100013
*TABLES/WORK AREAS:                                                     17400013
         SPACE 1                                                        17700013
*   NONE                                                                18000013
         SPACE 2                                                        18300013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  18600013
         SPACE 2                                                        18900013
*NOTES: THIS MODULE IS USED FOR ANY FIXED LENGTH SORT WITH EXIT E35     19200013
*       ACTIVE IN IERRBM.                                               19500013
         EJECT                                                          19800013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            20100013
         SPACE 1                                                        20400013
RA       EQU   0                   CONTENTS IN - N/A                    20700013
*                                  USED - NOT USED                      21000013
*                                  CONTENTS OUT- N/A                    21300013
RB       EQU   1                   CONTENTS IN- N/A                     21600013
*                                  USE- NOT USED                        21900013
*                                  CONTENTS OUT- N/A                    22200013
RC       EQU   2                   CONTENTS IN- N/A                     22500013
*                                  USE- NOT USED                        22800013
*                                  CONTENTS OUT- N/A                    23100013
RD       EQU   3                   CONTENTS IN- N/A                     23400013
*                                  USE- NOT USED                        23700013
*                                  CONTENTS OUT- N/A                    24000013
RE       EQU   4                   CONTENTS IN - N/A                    24300013
*                                  USED - GENERAL WORK REGISTER         24600013
*                                  CONTENTS OUT - N/A                   24900013
RF       EQU   5                   CONTENTS IN - N/A                    25200013
*                                  USED - NOT USED                      25500013
*                                  CONTENTS OUT - N/A                   25800013
RG       EQU   6                   CONTENTS IN- N/A                     26100013
*                                  USE- NOT USED                        26400013
*                                  CONTENTS OUT- N/A                    26700013
RH       EQU   7                   CONTENTS IN- N/A                     27000013
*                                  USE- NOT USED                        27300013
*                                  CONTENTS OUT- N/A                    27600013
RI       EQU   8                   CONTENTS IN- N/A                     27900013
*                                  USE- NOT USED                        28200013
*                                  CONTENTS OUT- N/A                    28500013
RJ       EQU   9                   CONTENTS IN- N/A                     28800013
*                                  USE- NOT USED                        29100013
*                                  CONTENTS OUT- N/A                    29400013
RK       EQU   10                  CONTENTS IN - N/A                    29700013
*                                  USED - BASE REG FOR IERRBM DSECT     30000013
*                                  CONTENTS OUT - N/A                   30300013
RL       EQU   11                  CONTENTS IN - N/A                    30600013
*                                  USED - MODULE BASE REGISTER          30900013
*                                  CONTENTS OUT - N/A                   31200013
RM       EQU   12                  CONTENTS IN - EQUALS OR EXTRACT ADDR 31500013
*                                  USED - NOT USED                      31800013
*                                  CONTENTS OUT - EQULS OR EXTRACT ADDR 32100013
RN       EQU   13                  CONTENTS IN - ADDR OF PPI            32400013
*                                  USED - PPI REFERENCES                32700013
*                                  CONTENTS OUT - ADDR OF PPI           33000013
RO       EQU   14                  CONTENTS IN - IERRC9 RETURN REG      33300013
*                                  USED - NOT USED                      33600013
*                                  CONTENTS OUT - IERRC9 RETURN REG     33900013
RP       EQU   15                  CONTENTS IN - THIS MODULE ENTRY PT   34200013
*                                  USED - ESTABLISH THIS MOD BASE REG   34500013
*                                  CONTENTS OUT - N/A                   34800013
         SPACE 2                                                        35100013
*START OF MODULE CODE PROPER:                                           35400013
         SPACE 2                                                        35700013
IERABM   CSECT                                                          36000013
*1601                                                              4549 36100018
         USING *,RL                                                     36300013
         USING IERRBMD,RK          ADDR OF R.P. DSECT                   36600013
         USING IERRCA,RN                                                36900013
         USING DIERAMC,RJ          MESSAGE MODULE BASE REG.             37200013
IERMB34  LR    RL,RP               LOAD MODULE BASE REGISTER            37500013
         L     RK,PPIBLK+4         ADDR OF IERRBM(R.P) FOR DSECT BASE   37800013
* CALCULATE ADDR OF OUTPUT DCB AND STORE IN R.P.                        38100013
         SPACE 1                                                        38400013
         L     RE,PPISTDCB         POINTER TO LIST OF DCB ADDRESSES     38700013
         MVC   WDCB,0(RE)          STORE DCB ADDR IN R.P.               39000013
         TM    PPISW1+6,X'01'      TEST DIAGNOSTIC SWITCH               39300013
         BNO   ABMNOMES            SWITCH OFF BYPASS MESSAGE            39600013
         ST    RO,ABMSAVO          SAVE RO                              39900013
         L     RJ,PPIAMC+4         SET MESSAGE BASE REG.                40200013
         L     RA,PPILAB04         LOAD ADDR OF OB1 FOR CONVERSION      40500013
         L     RP,PPICONV+4        LOAD ADDRESS OF CONVERSION ROUTINE   40800013
         BAL   RO,4(RP)            CONVERT                              41100013
         MVC   DMSG942A(8),0(RB)   PUT ADDRESS IN MESSAGE               41400013
         L     RA,PPILAB05         LOAD ADDRESS OF OB2 FOR CONVERSION   41700013
         L     RP,PPICONV+4        LOAD ADDRESS OF CONVERSION ROUTINE   42000013
         BAL   RO,4(RP)            CONVERT                              42300013
         MVC   DMSG942B(8),0(RB)   PUT ADDRESS IN MESSAGE               42600013
         LM    RA,RB,DMSG942X      SET UP FOR PRINTING                  42900013
         L     RP,PPIADSSC         LOAD ADDRESS OF PRINT ROUTINE        43200013
         BAL   RO,12(0,RP)         PRINT                                43500013
         L     RO,ABMSAVO          RESTORE RO                           43800013
ABMNOMES CLC   PPIATP3E,KZERO      TEST IF ATTACHED EXIT                44100013
         BC    7,ABATTEXT          YES, BR TO ATTACH EXIT RTN           44400013
         SPACE 1                                                        44700013
* BRANCH TO NEXT ASSIGNMENT RTN                                         45000013
         SPACE 1                                                        45300013
ABENDMOD BR    RO                  RETURN TO IERRC9                     45600013
         SPACE 1                                                        45900013
ABATTEXT MVC   PPIX35+4(4),PPIATP3E SET EXIT E35 TO ATTACHED EXIT       46200013
         B     ABENDMOD            BR TO NEXT ASSIGNMENT RTN            46500013
ABMSAVO  DC    F'0'                                                     46800013
DIERAMC  DSECT                                                          47100013
*                                                                       47400013
       COPY  AMCMAIN                                                    47700013
         EJECT                                                          48000013
* MODULE NAME *** IERRBM *** USER EXIT E35  **** DUMMY MODULE ****      48300013
         SPACE 2                                                        48600013
* THIS MODULE HANDLES FIXED LENGTH RECORDS USING THE IOCS PUT MACRO.    48900013
*   THE USER ROUTINE IS EXECUTED ONCE FOR EVERY RECORD LEAVING THE      49200013
*   MERGE. THE EXIT OCCURS AFTER THE RECORD TO BE PUT LEAVES THE MERGE. 49500013
*   THE USER MAY THEN DO THE FOLLOWING 1. INSERT A RECORD,2. DELETE OR  49800013
*   SUMMARIZE A RECORD,OR 3.DO NOTHING, ALTER, LENGTHEN, OR SHORTEN A   50100013
*   RECORD. THE USER RETURNS TO THE APPROPRIATE ROUTINE IN THIS MODULE. 50400013
*   THE MODULE LINKS TO THE PROPER DEBLOCK OR EOJ MODULE WHEN NEEDED.   50700013
         SPACE 1                                                        51000013
*   LINKAGE FROM MODULE TO USER IS VIA THE CALL MACRO                   51300013
*   LINKAGE FROM USER TO MODULE IS VIA RETURN REGISTER PLUS PROPER      51600013
*   DISPLACEMENT(DEPENDS ON WHAT RTN THE USER WISHES TO RETURN TO)      51900013
         SPACE 1                                                        52200013
*   TWO PARAMETERS ARE PASSED TO THE USER. THE ADDR OF THE RECORD       52500013
*   LEAVING THE MERGE, AND THE STARTING ADDRESS OF THE AREA IN THE      52800013
*   OUTPUT BUFFER INTO WHICH THE PREVIOUS RECORD HAD BEEN PLACED.       53100013
         SPACE 1                                                        53400013
*   THE USER CAN PASS TWO PARAMETERS TO THE MODULE, THE ADDRESS OF THE  53700013
*   RECORD HE WISHES TO INSERT, DO NOTHING, ALTER, LENGTHEN, SHORTEN    54000013
*   IN RB, AND A 4 IF HE HAS CHANGED THE INTEGRITY OF THE CONTROL FIELD 54300013
*   OF THE RCD COMING FROM THE MERGE OR A ZERO IF HE HAS NOT, IN THE    54600013
*   THIRD PARAMETER OF THE PARAMETER LIST                               54900013
         SPACE 1                                                        55200013
*   THE MODULE PASSES THESE PARAMETERS TO THE MERGE FOR SEQUENCE        55500013
*   CHECKING AGAINST THE NEXT RECORD THE MERGE PASSES TO THE MODULE     55800013
         SPACE 1                                                        56100013
*   AT EOJ,MODULE ZEROS OUT PARAM 1 OF THE PARAM LIST TO USER           56400013
         SPACE 1                                                        56700013
IERRBMD  DSECT                                                          57000013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    57300013
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  57600013
         SPACE 1                                                        57900013
* ENTER BRANCH TABLE FROM MERGE OR READ PRIME RTN                       58200013
         SPACE 1                                                        58500013
IERDB34  B     RBSETREG            FROM MERGE,LAST RECORD, OR           58800013
*                                  FROM READ PRIME ZERO INPUT FILE      59100013
         LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     59400013
RBSETPAR ST    RD,WMRGRCD          SET PARAMETER 1 OF 2 FOR CALL MACRO  59700013
*                                    ADDR OF NEXT RCD FR MERGE TO PUT   60000013
         SPACE 1                                                        60300013
* CALL MACRO EXPANSION TO USER EXIT E35                                 60600013
         SPACE 1                                                        60900013
RBUSREXT LA    RB,WMRGRCD          PARAM LIST ADDR. WILL BE OVLAYED BY  61200013
*                                    B RBLOADRE ON USER EOF             61500013
         L     RP,PPIX35           IF ATTACH,PPIX35 WILL HAVE ADDR      61800013
*                                    OF ATTACHED EXIT FROM PPI          62100013
         BALR  RO,RP               BR TO USER                           62400013
         SPACE 1                                                        62700013
* USER RETURNS TO MODULE VIA RETURN REG AND PROPER DISPLACEMENTS        63000013
         SPACE 1                                                        63300013
         B     *+4(15)                                                  63600013
         B     RBALSHNO            BR TO ALTER,LENGTHN,SHRTN,NOTHG RTN  63900013
         B     RBDELSUM            BR TO DELETE-SUMMARIZE RTNE          64200013
         B     RBUSREOF            BR TO USER END OF FILE ROUTINE       64500013
         SPACE 1                                                        64800013
* INSERT A RECORD                                                       65100013
         SPACE 1                                                        65400013
RBINSRT1 OI    WINSRTSW,X'01'      TURN INSERT SWITCH ON                65700013
         LA    RINSERT,1(0,RINSERT)  INCR INSERT CTR BY ONE             66000013
         LA    RCDCTR,1(0,RCDCTR)  INCR RCD COUNTER BY ONE, ALSO        66300013
RBOVLAY  B     RBLOADRE            BR TO LOAD ADDR OF RCD FOR MOVE RTN  66600013
         SPACE 2                                                        66900013
* ALTER,LENGTHEN,SHORTEN,DO NOTHING TO THE INPUT RECORD FROM THE MERGE. 67200013
         SPACE 1                                                        67500013
RBALSHNO MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  67800013
*                                    FOR MERGE NETWORK SEQU CHECK       68100013
RBLOADRE LR    RE,RB               STORE ADDR OF RCD FROM THE MERGE IN  68400013
*                                    MOVE RTN REG. THIS INSTR WILL BE   68700013
*                                    OVLAYD BY LR RE,RD ON USER EOF     69000013
         L     RF,WDCB             DCB ADDRESS                          69300013
         PUT   (RF)                UPDATE ADDR IN OUTPUT AREA(REG RB)   69600013
         SPACE 1                                                        69900013
         ST    RB,WOPBUFAD         SAVE ADDR OF RCD IN OUTPUT BFR TO    70200013
*                                    MOVE RCD(2 OF 2 PARAM TO USER)     70500013
         LR    RF,RB               LOAD ADDR OF OUT AREA FOR MOVE RTN   70800013
         L     RP,PPIBDSVA+8       LOAD MOVE RTN BASE REG W/ADDR OF     71100013
*                                    MOVE RCD RTN                       71400013
         BALR  RO,RP               BR TO MOVE RTN-MOVE RCD TO OUT AREA  71700013
         CLI   WINSRTSW,X'00'      TEST INSERT SWITGH                   72000013
         BC    8,RBDOOBA           OFF,BR TO STORE ADDR OF OUTPUT RCD   72300013
*                                    IN PPI                             72600013
         NI    WINSRTSW,X'00'      TURN INSERT SWITCH OFF               72900013
         B     RBUSREXT            BR TO USER EXIT                      73200013
         SPACE 2                                                        73500013
RBDOOBA  ST    RB,PPIDOOBA         ADDR OF RCD IN OUTPUT BUFFER         73800013
         LA    RCDCTR,1(0,RCDCTR)  INCREMENT RECORD CTR BY ONE          74100013
RBDEBLK  STM   RG,RI,PPICOUNT      SAVE COUNTERS                        74400013
         SPACE 1                                                        74700013
* INTERFACE TO DEBLOCK MODULE. PASS FILE NO OF WINNER IN HI BYTE OF RD  75000013
         SPACE 1                                                        75300013
         L     RL,PPIDEB+4         LOAD DEBLOCK ADDR                    75600013
         B     4(0,RL)             BR TO DEBLOCK MODULE                 75900013
         SPACE 2                                                        76200013
* LAST RECORD AND ZERO INPUT FILE ROUTINE                               76500013
         SPACE 1                                                        76800013
RBSETREG LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     77100013
         SR    RD,RD               ZERO WINNER REG(PARAM 1 TO USER)     77400013
         OI    WSYSEOF,X'01'       SET SYSTEM END OF FILE SWITCH        77700013
         CLI   WUSREOF,X'00'       TEST IF USER END OF FILE SWITCH ON   78000013
         BC    7,RBEOJ             ON,BR TO END OF JOB MODULE           78300013
         B     RBSETPAR            OFF,BR TO USER ROUTINE               78600013
         SPACE 2                                                        78900013
* USER END OF FILE ROUTINE                                              79200013
         SPACE 1                                                        79500013
RBUSREOF OI    WUSREOF,X'01'       SET USER END OF FILE SWITCH          79800013
         MVC   RBUSREXT,RBOVLAY    OVERLAY USER EXIT(BYPASS EXIT E35)   80100013
         MVI   RBLOADRE+1,X'43'    OVERLAY INSTR(CHANGES RB TO RD)      80400013
         MVI   PPIDOUO+3,X'00'     RESET SWITCH SO MERGE WILL NOW SEQ   80700013
*                                    CHECK THE REST OF THE RCDS         81000013
         CLI   WSYSEOF,X'00'       TEST IF SYSTEM END OF FILE SWITCH ON 81300013
         BC    7,RBEOJ             ON, BR TO END OF JOB MODULE          81600013
         TM    PPISW1+3,X'04'      ATTACHED SORT                   4549 81700018
         BO    RBEOJ               IF YES BR TO EOJ                4549 81800018
         B     RBLOADRE            BR TO LOAD ADDR OF RCD IN RD         81900013
         SPACE 2                                                        82200013
* LINKAGE TO END OF JOB MODULE                                          82500013
RBEOJ    STM   RG,RI,PPICOUNT      SAVE COUNTERS                        82800013
         L     RL,PPIWRT+4         LOAD BASE REG WITH EOJ MODULE ADDR   83100013
         BR    RL                  EOJ EXIT TO MODULE NAMED IERRPG      83400013
         SPACE 2                                                        83700013
* DELETE OR SUMMARIZE A RECORD                                          84000013
         SPACE 1                                                        84300013
RBDELSUM LA    RDELSUMM,1(0,RDELSUMM)  INCR DELETE-SUMMARIZE CTR BY ONE 84600013
         MVC   PPIDOOBA(4),WOPBUFAD  ADDR OF RCD IN OUTPUT BFR(THE RCD  84900013
*                                      BEFORE THE DELETD OR SUMRZD RCD) 85200013
         CLC   PPICOUNT,KZERO      CHK IF ANY RCDS HAVE GONE THRU       85500013
         BE    RBAROUND            BR IF DELETING BEGINNING RCDS        85800013
         MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  86100013
*                                    FOR MERGE NETWORK SEQU CHECK       86400013
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         86700013
         SPACE 2                                                        87000013
RBAROUND MVC   PPIDOUO,KFOUR       NO SEQUENCE CHECK                    87300013
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         87600013
         EJECT                                                          87900013
* LIST OF CONSTANTS USED BY THE MODULE                                  88200013
KZERO    DC    F'0'                ZERO                                 88500013
KFOUR    DC    F'4'                FOUR                                 88800013
         SPACE 2                                                        89100013
* LIST OF WORK AREAS                                                    89400013
         SPACE 1                                                        89700013
WMRGRCD  DC    F'0'                PARAM 1,ADDR OF NEXT RCD TO BE PUT   90000013
WOPBUFAD DC    F'0'                PARAM 2,ADDR OF LAST RCD PUT(OUTBUF) 90300013
WINTEGSW DC    F'0'                PARAM3,USER INTEGRITY SWITCH(0 =     90600013
*                                    SEQUENCE CHECK,4 = NO SEQU CHECK)  90900013
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR OUTPUT FILE 91200013
*                                    LOADED BY ASSGN RTN                91500013
WINSRTSW DC    X'00'               INSERT SWITCH                        91800013
WSYSEOF  DC    X'00'               SYSTEM END OF FILE SWITCH            92100013
WUSREOF  DC    X'00'               USER END OF FILE SWITCH              92400013
RINSERT  EQU   RI                                                       92700013
RDELSUMM EQU   RH                                                       93000013
RCDCTR   EQU   RG                                                       93300013
         EJECT                                                          93600013
         SMPPI                                                          93900013
         END                                                            94200013
