         TITLE '      IERABO - OS/360 SORT/MERGE - 360S-SM023 04/22/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME:*** IERABO ***                                             00600013
         SPACE 2                                                        00800013
*STATUS: CHANGE LEVEL 000                                               01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 3 ASSIGNMENT MODULE. V.L WITH E35.    01400013
*   THE FUNCTION OF THIS MODULE IS TO INSERT THE ADDRESS OF THE OUTPUT  01600013
*   DCB IN IERRBN. IT ALSO CHECKS TO SEE IF ATTACHED IN PHASE 3 AND IF  01800013
*   ATTACHED, INSERTS THIS ADDRESS FROM PPIATP3E IN PPIX35. IF NOT      02000013
*   ATTACHED EXIT E35(PPIX35) HAS BEEN ACTIVATED THROUGH CONTROL CARDS. 02200013
         SPACE 2                                                        02400013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT'               02600013
*                                                                       02800013
*     N/A                                                               03000013
*                                                                       03200013
*MACROS USED'                                                           03400013
         SPACE 1                                                        03600013
*   SMPPI                                                               03800013
         SPACE 2                                                        04000013
*ENTRY POINTS:                                                          04200013
         SPACE 1                                                        04400013
*        ENTRY IERABO              ENTRY FROM: IERRC9                   04600013
*                                    CALLING SEQUENCE-                  04800013
*                                      LOAD  EP=IERABM,DCB=SORTLIB      05000013
*                                      LR    RP,RA                      05200013
*                                      BALR  RO,RP                      05400013
         SPACE 2                                                        05600013
*INPUT: PPI FIELDS REFERENCED-                                          05800013
         SPACE 1                                                        06000013
*   PPISTDCB                                                            06200013
*   PPIATP3E                                                            06400013
         SPACE 1                                                        06600013
*   ADDRESS OF DCBS IN GENERATED CORE AND ADDRESS OF ATTACHED EXIT      06800013
         SPACE 2                                                        07000013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             07200013
         SPACE 1                                                        07400013
*   PPIX35                                                              07600013
         SPACE 1                                                        07800013
*   IF ATTACHED WILL HAVE ATTACHED ADDRESS                              08000013
         SPACE 2                                                        08200013
*EXTERNAL ROUTINES:                                                     08400013
         SPACE 1                                                        08600013
*   NONE                                                                08800013
         SPACE 2                                                        09000013
*EXTERNAL PARAMETERS:                                                   09200013
         SPACE 1                                                        09400013
*   SEE REGISTERS                                                       09600013
         SPACE 2                                                        09800013
*EXITS: NORMAL                                                          10000013
         SPACE 1                                                        10200013
*   TO IERRC9                      EXIT TO IERRC9                       10400013
*                                    CALLING SEQUENCE-                  10600013
*                                      BR   RO                          10800013
         SPACE 2                                                        11000013
*EXITS: ERROR                                                           11200013
         SPACE 1                                                        11400013
*   NONE                                                                11600013
         SPACE 2                                                        11800013
*TABLES/WORK AREAS:                                                     12000013
         SPACE 1                                                        12200013
*   NONE                                                                12400013
         SPACE 2                                                        12600013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12800013
         SPACE 2                                                        13000013
*NOTES:                                                                 13200013
         SPACE 1                                                        13400013
*   THIS MODULE IS USED FOR ANY VARIABLE LENGTH SORT WITH EXIT E35      13600013
         EJECT                                                          13800013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            14000013
         SPACE 1                                                        14200013
RA       EQU   0                   CONTENTS IN- N/A                     14400013
*                                  USE- NOT USED                        14600013
*                                  CONTENTS OUT- N/A                    14800013
RB       EQU   1                   CONTENTS IN- N/A                     15000013
*                                  USE- NOT USED                        15200013
*                                  CONTENTS OUT- N/A                    15400013
RC       EQU   2                   CONTENTS IN- N/A                     15600013
*                                  USE- NOT USED                        15800013
*                                  CONTENTS OUT- N/A                    16000013
RD       EQU   3                   CONTENTS IN- N/A                     16200013
*                                  USE- NOT USED                        16400013
*                                  CONTENTS OUT- N/A                    16600013
RE       EQU   4                   CONTENTS IN- N/A                     16800013
*                                  USE- GENERAL WORK REGISTER           17000013
*                                  CONTENTS OUT- N/A                    17200013
RF       EQU   5                   CONTENTS IN- N/A                     17400013
*                                  USE- NOT USED                        17600013
*                                  CONTENTS OUT- N/A                    17800013
RG       EQU   6                   CONTENTS IN- N/A                     18000013
*                                  USE- NOT USED                        18200013
*                                  CONTENTS OUT- N/A                    18400013
RH       EQU   7                   CONTENTS IN- N/A                     18600013
*                                  USE- NOT USED                        18800013
*                                  CONTENTS OUT- N/A                    19000013
RI       EQU   8                   CONTENTS IN- N/A                     19200013
*                                  USE- NOT USED                        19400013
*                                  CONTENTS OUT- N/A                    19600013
RJ       EQU   9                   CONTENTS IN- N/A                     19800013
*                                  USE- NOT USED                        20000013
*                                  CONTENTS OUT- N/A                    20200013
RK       EQU   10                  CONTENTS IN- N/A                     20400013
*                                  USE- BASE REGISTER FOR IERRBO DSECT  20600013
*                                  CONTENTS OUT- N/A                    20800013
RL       EQU   11                  CONTENTS IN- N/A                     21000013
*                                  USE- MODULE BASE REGISTER            21200013
*                                  CONTENTS OUT- N/A                    21400013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT ADDR  21600013
*                                  USE- NOT USED                        21800013
*                                  CONTENTS OUT- EQUALS OR EXTRACT ADDR 22000013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          22200013
*                                  USE- PPI REFERENCE,REGISTER SAVE     22400013
*                                    AREA                               22600013
*                                  CONTENTS OUT- ADDRESS OF PPI         22800013
RO       EQU   14                  CONTENTS IN - IERRC9 RETURN REG      23000013
*                                  USE- NOT USED                        23200013
*                                  CONTENTS OUT- IERRC9 RETURN REG      23400013
RP       EQU   15                  CONTENTS IN- THIS MODULE ENTRY PT    23600013
*                                  USE- ESTABLISH THIS MOD BASE REG     23800013
*                                  CONTENTS OUT- N/A                    24000013
         SPACE 2                                                        24200013
*START OF MODULE CODE PROPER:                                           24400013
         SPACE 2                                                        24600013
IERABO   CSECT                                                          24800013
*1601                                                              4549 24900018
         USING *,RL                                                     25000013
         USING IERRBOD,RK          ADDR OF R.P. DSECT                   25200013
         USING IERRCA,RN                                                25400013
         USING DIERAMC,RJ          MESSAGE MOD BASE REG.                25600013
IERMB34  LR    RL,RP               LOAD MODULE BASE REG                 25800013
         L     RK,PPIBLK+4         ADDR OF IERRBO (R.P) FOR DSECT BASE  26000013
* CALCULATE ADDR OF OUTPUT DCB AND STORE IN R.P.                        26200013
         SPACE 1                                                        26400013
         L     RE,PPISTDCB         POINTER TO LIST OF DCB ADDRESSES     26600013
         L     RE,0(0,RE)         GET OUTPUT D C B ADDR.                26800013
         ST    RE,WDCB             STORE DCB ADDR IN R.P.               27000013
         L     RJ,PPIAMC+4         SET MESSAGE BASE REG.                27200013
         TM    PPISW1+6,X'01'      TEST DIAGNOSTIC SWITCH               27400013
         BNO   ABONOMES            SWITCH OFF BYPASS MESSAGE            27600013
         ST    RO,ABOSAVO          SAVE RO                              27800013
         L     RA,PPILAB04         LOAD ADDR OF OB1 FOR CONVERSION      28000013
         L     RP,PPICONV+4        LOAD ADDRESS OF CONVERSION ROUTINE   28200013
         BAL   RO,4(RP)            CONVERT                              28400013
         MVC   DMSG942A(8),0(RB)   PUT ADDRESS IN MESSAGE               28600013
         L     RA,PPILAB05         LOAD ADDRESS OF OB2 FOR CONVERSION   28800013
         L     RP,PPICONV+4        LOAD ADDRESS OF CONVERSION ROUTINE   29000013
         BAL   RO,4(RP)            CONVERT                              29200013
         MVC   DMSG942B(8),0(RB)   PUT ADDRESS IN MESSAGE               29400013
         LM    RA,RB,DMSG942X      SET UP FOR PRINTING                  29600013
         L     RP,PPIADSSC         LOAD ADDRESS OF PRINT ROUTINE        29800013
         BAL   RO,12(0,RP)         PRINT                                30000013
         L     RO,ABOSAVO          RESTORE RO                           30200013
ABONOMES CLC   PPIATP3E,KZERO      TEST IF ATTACHED EXIT                30400013
         BC    7,ABATTEXT          YES, BR TO ATTACH EXIT RTN           30600013
         SPACE 1                                                        30800013
* BRANCH TO NEXT ASSIGNMENT RTN                                         31000013
         SPACE 1                                                        31200013
ABENDMOD BR    RO                  RETURN TO IERRC9                     31400013
         SPACE 1                                                        31600013
ABATTEXT MVC   PPIX35+4(4),PPIATP3E SET EXIT E35 TO ATTACHED EXIT       31800013
         B     ABENDMOD                                                 32000013
         SPACE 2                                                        32200013
ABOSAVO  DC    F'0'                                                     32400013
DIERAMC  DSECT                                                          32600013
*                                                                       32800013
       COPY  AMCMAIN                                                    33000013
         EJECT                                                          33200013
* MODULE NAME *** IERRBO *** USER EXIT E35 **** DUMMY MODULE ****       33400013
         SPACE 2                                                        33600013
* THIS MODULE HANDLES VARIABLE LENGTH RECORDS USING THE IOCS PUT MACRO. 33800013
*   THE USER ROUTINE IS EXECUTED ONCE FOR EVERY RECORD LEAVING THE      34000013
*   MERGE. THE EXIT OCCURS AFTER THE RECORD TO BE PUT LEAVES THE MERGE. 34200013
*   THE USER MAY THEN DO THE FOLLOWING 1. INSERT A RECORD,2. DELETE OR  34400013
*   SUMMARIZE A RECORD,OR 3.DO NOTHING, ALTER, LENGTHEN, OR SHORTEN A   34600013
*   RECORD. THE USER RETURNS TO THE APPROPRIATE ROUTINE IN THIS MODULE. 34800013
*   THE MODULE LINKS TO THE PROPER DEBLOCK OR EOJ MODULE WHEN NEEDED.   35000013
         SPACE 1                                                        35200013
*   LINKAGE FROM MODULE TO USER IS VIA THE CALL MACRO                   35400013
*   LINKAGE FROM USER TO MODULE IS VIA RETURN REGISTER PLUS PROPER      35600013
*   DISPLACEMENT(DEPENDS ON WHAT RTN THE USER WISHES TO RETURN TO)      35800013
         SPACE 1                                                        36000013
*   TWO PARAMETERS ARE PASSED TO THE USER. THE ADDR OF THE RECORD       36200013
*   LEAVING THE MERGE, AND THE STARTING ADDRESS OF THE AREA IN THE      36400013
*   OUTPUT BUFFER INTO WHICH THE PREVIOUS RECORD HAD BEEN PLACED.       36600013
         SPACE 1                                                        36800013
*   THE USER CAN PASS TWO PARAMETERS TO THE MODULE, THE ADDRESS OF THE  37000013
*   RECORD HE WISHES TO INSERT, DO NOTHING, ALTER, LENGTHEN, SHORTEN    37200013
*   IN RB, AND A 4 IF HE HAS CHANGED THE INTEGRITY OF THE CONTROL FIELD 37400013
*   OF THE RCD COMING FROM THE MERGE OR A ZERO IF HE HAS NOT, IN THE    37600013
*   THIRD PARAMETER OF THE PARAMETER LIST                               37800013
         SPACE 1                                                        38000013
*   THE MODULE PASSES THESE PARAMETERS TO THE MERGE FOR SEQUENCE        38200013
*   CHECKING AGAINST THE NEXT RECORD THE MERGE PASSES TO THE MODULE     38400013
         SPACE 1                                                        38600013
*   AT EOJ,MODULE ZEROS OUT PARAM 1 OF THE PARAM LIST TO USER           38800013
         SPACE 1                                                        39000013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      39200013
*   REPRESENTATION OF THE EXTERNAL CHARACTER SET                        39400013
         SPACE 2                                                        39600013
IERRBOD  DSECT                                                          39800013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    40000013
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  40200013
         USING IHADCB,RF                                                40400013
         SPACE 1                                                        40600013
* ENTER BRANCH TABLE FROM MERGE OR READ PRIME RTN                       40800013
         SPACE 1                                                        41000013
IERDB34  B     RBSETREG            FROM MERGE,LAST RECORD, OR           41200013
*                                  FROM READ PRIME ZERO INPUT FILE      41400013
         LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     41600013
RBSETPAR ST    RD,WMRGRCD          SET PARAMETER 1 OF 2 FOR CALL MACRO  41800013
*                                    ADDR OF NEXT RCD FR MERGE TO PUT   42000013
         SPACE 1                                                        42200013
* CALL MACRO EXPANSION TO USER EXIT E35                                 42400013
         SPACE 1                                                        42600013
RBUSREXT LA    RB,WMRGRCD          PARAM LIST ADDR. WILL BE OVLAYED BY  42800013
*                                    B RBLOADRE ON USER EOF             43000013
         L     RP,PPIX35+4         IF ATTACHED ,PPIX35 WILL HAVE ADD    43200013
*                                    OF ATTACHED EXIT FROM PPI          43400013
         BALR  RO,RP               BR TO USER                           43600013
         SPACE 1                                                        43800013
* USER RETURNS TO MODULE VIA RETURN REG AND PROPER DISPLACEMENTS        44000013
         SPACE 1                                                        44200013
         B     *+4(15)                                                  44400013
         B     RBALSHNO            BR TO ALTER,LENGTHN,SHRTN,NOTHG RTN  44600013
         B     RBDELSUM            BR TO DELETE-SUMMARIZE RTNE          44800013
         B     RBUSREOF            BR TO USER END OF FILE ROUTINE       45000013
         SPACE 1                                                        45200013
* INSERT A RECORD                                                       45400013
         SPACE 1                                                        45600013
RBINSRT1 OI    WINSRTSW,X'01'      TURN INSERT SWITCH ON                45800013
         LA    RINSERT,1(0,RINSERT)  INCR INSERT CTR BY ONE             46000013
         LA    RCDCTR,1(0,RCDCTR)  INCR RCD COUNTER BY ONE, ALSO        46200013
RBOVLAY  B     RBLOADRE            BR TO LOAD ADDR OF RCD FOR MOVE RTN  46400013
         SPACE 2                                                        46600013
* ALTER,LENGTHEN,SHORTEN,DO NOTHING TO THE INPUT RECORD FROM THE MERGE. 46800013
         SPACE 1                                                        47000013
RBALSHNO MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  47200013
*                                    FOR MERGE NETWORK SEQU CHECK       47400013
RBLOADRE MVC   WRCDLGTH+2(2),0(RB)  MOVE RCD LENGTH TO A BOUNDARY. RB   47600013
*                                     WILL BE OVLAYD BY RD ON USER EOF. 47800013
RBOVLAY1 LR    RE,RB               STORE ADDR OF RCD FROM THE MERGE IN  48000013
*                                    MOVE RTN REG. THIS INSTR WILL BE   48200013
*                                    OVLAYD BY LR RE,RD ON USER EOF     48400013
         L     RF,WDCB             DCB ADDRESS                          48600013
         MVC   DCBLRECL(2),WRCDLGTH+2  RCD LENGTH                       48800013
         PUT   (RF)                UPDATE ADDR IN OUTPUT AREA(REG RB)   49000013
         SPACE 2                                                        49200013
         ST    RB,WOPBUFAD         SAVE ADDR OF RCD IN OUTPUT BFR TO    49400013
*                                    MOVE RCD(2 OF 2 PARAM TO USER)     49600013
         LR    RF,RB               LOAD ADDR OF OUT AREA FOR MOVE RTN   49800013
         STM   RG,RI,PPICOUNT      SAVE COUNTERS                        50000013
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           50200013
         SPACE 1                                                        50400013
* GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA     50600013
*   AREA TO ANOTHER, REGISTERS ARE USED AS FOLLOWS-                     50800013
         SPACE 1                                                        51000013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  51200013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    51400013
*        RI    DATA RCD LENGTH                                          51600013
         SPACE 1                                                        51800013
* IN ADDITION THE ROUTINE USES REGISTERS RG AND RH                      52000013
         SPACE 1                                                        52200013
         CL    RI,KON256           RCD LENGTH TO 256                    52400013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   52600013
         SPACE 1                                                        52800013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    53000013
         LNR   RG,RH                 256 BYTES EACH                     53200013
RBKMOVE  MVC   0(256,RF),0(RE)                                          53400013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     53600013
         AR    RF,RH                 BYTES                              53800013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    54000013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 54200013
         SPACE 1                                                        54400013
KON256   DC    F'256'                                                   54600013
KMOVE1   MVC   0(1,RF),0(RE)                                            54800013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             55000013
         BCTR  RG,0                DECR RG BY ONE                       55200013
         EX    RG,KMOVE1                                                55400013
         SPACE 1                                                        55600013
* END OF GENERALIZED MOVE ROUTINE.                                      55800013
         SPACE 1                                                        56000013
         LM    RG,RI,PPICOUNT      RESTORE REGISTERS                    56200013
         CLI   WINSRTSW,X'00'      TEST INSERT SWITGH                   56400013
         BC    8,RBDOOBA           OFF,BR TO STORE ADDR OF OUTPUT RCD   56600013
*                                    IN PPI                             56800013
         NI    WINSRTSW,X'00'      TURN INSERT SWITCH OFF               57000013
         B     RBUSREXT            BR TO USER EXIT                      57200013
         SPACE 2                                                        57400013
RBDOOBA  ST    RB,PPIDOOBA         ADDR OF RCD IN OUTPUT BUFFER         57600013
         LA    RCDCTR,1(0,RCDCTR)  INCREMENT RECORD CTR BY ONE          57800013
RBDEBLK  STM   RG,RI,PPICOUNT      SAVE COUNTERS                        58000013
         SPACE 1                                                        58200013
* INTERFACE TO DEBLOCK MODULE. PASS FILE NO OF WINNER IN HI BYTE OF RD  58400013
         SPACE 1                                                        58600013
         L     RL,PPIDEB+4         DEBLOCK ADDRESS                      58800013
         B     4(0,RL)             BR TO DEBLOCK MODULE                 59000013
         SPACE 2                                                        59200013
* LAST RECORD AND ZERO INPUT FILE ROUTINE                               59400013
         SPACE 1                                                        59600013
RBSETREG LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     59800013
         SR    RD,RD               ZERO WINNER REG(PARAM 1 TO USER)     60000013
         OI    WSYSEOF,X'01'       SET SYSTEM END OF FILE SWITCH        60200013
         CLI   WUSREOF,X'00'       TEST IF USER END OF FILE SWITCH ON   60400013
         BC    7,RBEOJ             ON,BR TO END OF JOB MODULE           60600013
         B     RBSETPAR            OFF,BR TO USER ROUTINE               60800013
         SPACE 2                                                        61000013
* USER END OF FILE ROUTINE                                              61200013
         SPACE 1                                                        61400013
RBUSREOF OI    WUSREOF,X'01'       SET USER END OF FILE SWITCH          61600013
         MVC   RBUSREXT,RBOVLAY    OVERLAY USER EXIT(BYPASS EXIT E35)   61800013
         MVI   RBLOADRE+4,X'30'    OVERLAY INSTR(CHANGES RB TO RD)      62000013
         MVI   RBOVLAY1+1,X'43'    OVERLAY INSTR(CHANGES RB TO RD)      62200013
         MVI   PPIDOUO+3,X'00'     RESET SWITCH SO MERGE WILL NOW SEQ   62400013
*                                    CHECK THE REST OF THE RCDS         62600013
         CLI   WSYSEOF,X'00'       TEST IF SYSTEM END OF FILE SWITCH ON 62800013
         BC    7,RBEOJ             ON, BR TO END OF JOB MODULE          63000013
         TM    PPISW1+3,X'04'      ATTACHED SORT                   4549 63060018
         BO    RBEOJ               IF YES BR TO EOJ                4549 63120018
         B     RBLOADRE            BR TO LOAD ADDR OF RCD IN RD         63200013
         SPACE 2                                                        63400013
* LINKAGE TO END OF JOB MODULE                                          63600013
RBEOJ    L     RL,PPIWRT+4         END OF JOB ADDRESS                   63800013
         BR    RL                  EOJ EXIT TO MODULE NAMED IERRPG      64000013
         SPACE 2                                                        64200013
* DELETE OR SUMMARIZE A RECORD                                          64400013
         SPACE 1                                                        64600013
RBDELSUM LA    RDELSUMM,1(0,RDELSUMM)  INCR DELETE-SUMMARIZE CTR BY ONE 64800013
         MVC   PPIDOOBA(4),WOPBUFAD  ADDR OF RCD IN OUTPUT BFR(THE RCD  65000013
*                                      BEFORE THE DELETD OR SUMRZD RCD) 65200013
         CLC   PPICOUNT,KZERO      CHK IF ANY RCDS HAVE GONE THRU       65400013
         BE    RBAROUND            BR IF DELETING BEGINNING RCDS        65600013
         MVC   PPIDOUO(4),WINTEGSW  STORE USER INTEGRITY SWITCH IN PPI  65800013
*                                    FOR MERGE NETWORK SEQU CHECK       66000013
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         66200013
         SPACE 2                                                        66400013
RBAROUND MVC   PPIDOUO,KFOUR       NO SEQUENCE CHECK                    66600013
         B     RBDEBLK             BR TO DEBLOCK MODULE LINKAGE         66800013
         SPACE 2                                                        67000013
* LIST OF CONSTANTS USED BY THE MODULE                                  67200013
KZERO    DC    F'0'                ZERO                                 67400013
KFOUR    DC    F'4'                FOUR                                 67600013
         SPACE 2                                                        67800013
* LIST OF WORK AREAS                                                    68000013
         SPACE 1                                                        68200013
WRCDLGTH DC    F'0'                RECORD LENGTH                        68400013
WMRGRCD  DC    F'0'                PARAM 1,ADDR OF NEXT RCD TO BE PUT   68600013
WOPBUFAD DC    F'0'                PARAM 2,ADDR OF LAST RCD PUT(OUTBUF) 68800013
WINTEGSW DC    F'0'                PARAM3,USER INTEGRITY SWITCH(0 =     69000013
*                                    SEQUENCE CHECK,4 = NO SEQU CHECK)  69200013
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR OUTPUT FILE 69400013
*                                    LOADED BY ASSGN RTN                69600013
WINSRTSW DC    X'00'               INSERT SWITCH                        69800013
WSYSEOF  DC    X'00'               SYSTEM END OF FILE SWITCH            70000013
WUSREOF  DC    X'00'               USER END OF FILE SWITCH              70200013
RINSERT  EQU   RI                                                       70400013
RDELSUMM EQU   RH                                                       70600013
RCDCTR   EQU   RG                                                       70800013
         SPACE 2                                                        71000013
         EJECT                                                          71200013
         SMPPI                                                          71400013
         EJECT                                                          71600013
         DCBD  DSORG=PS                                                 71800013
         END                                                            72000013
