         TITLE 'IERABV - OS/360 SORT/MERGE - 360-SM023 05/11/66'        00200013
*MODULE NAME:*** IERABV ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION:                                             01200013
*   THIS MODULE IS AN ASSIGNMENT ROUTINE FOR THE RUNNING PROGRAM        01400013
*   IERRBV, A BLOCK/DEBLOCK ROUTINE FOR VARIABLE LENGTH RECORDS WITHOUT 01600013
*   USER EXITS IN THE MERGE PHASE OF AN OSCL/2314 SORT.  IT SETS        01800013
*   WORK AREAS AND CONSTANTS TO SPECIFIC VALUES IN THE RUNNING PROGRAM. 02000013
*   IT ALSO ALLOCATES AREA IN GENERATED CORE FOR THE TAPE UNIT COUNTERS 02200013
*   WHICH KEEP TRACK OF THE NUMBER OF RECORDS ON EACH UNIT.             02400013
         SPACE 2                                                        02600013
*MACRO'S USED:                                                          02800013
         SPACE 1                                                        03000013
*   SMPPI                                                               03200013
         SPACE 2                                                        03400013
*ENTRY POINTS:                                                          03600013
         SPACE 1                                                        03800013
*        ENTRY IERMBG              ENTRY FROM: LOAD MODULE, IERRC9      04000013
*                                    CALLING SEQUENCE-                  04200013
*                                       LOAD   EP=IERABV,DCB=           04400013
*                                       LR     RP,RA                    04600013
*                                       BALR   RO,RP                    04800013
         SPACE 2                                                        05000013
*INPUT: PPI FIELDS REFERENCED-                                          05200013
         SPACE 1                                                        05400013
*   PPILAB04    PPILAB07                                                05600013
*   PPIBDSVA    PPIUNTCT                                                05800013
*   PPISPGN1                                                            06000013
         SPACE 2                                                        06200013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             06400013
         SPACE 1                                                        06600013
*   PPIUNTCT                                                            06800013
*   PPISPGN1                                                            07000013
*   CONSTANTS AND CODE IN THE RUNNING PROGRAM ARE INITIALIZD            07200013
*   ALLOCATES AREA FOR TAPE UNIT COUNTERS IN GENERATED CORE             07400013
         SPACE 2                                                        07600013
*EXTERNAL ROUTINES:                                                     07800013
         SPACE 1                                                        08000013
*        NONE                                                           08200013
         SPACE 2                                                        08400013
*EXTERNAL PARAMETERS:                                                   08600013
         SPACE 1                                                        08800013
*        NONE                                                           09000013
         SPACE 2                                                        09200013
*EXITS: NORMAL                                                          09400013
         SPACE 1                                                        09600013
*        BR    RO - RETURN TO LOAD MODULE, IERRC9                       09800013
         SPACE 2                                                        10000013
*EXITS: ERROR                                                           10200013
         SPACE 1                                                        10400013
*        NONE                                                           10600013
         SPACE 2                                                        10800013
*TABLES/WORK AREAS:                                                     11000013
         SPACE 1                                                        11200013
*        NONE                                                           11400013
         SPACE 2                                                        11600013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  11800013
         SPACE 2                                                        12000013
*NOTES:                                                                 12200013
         SPACE 1                                                        12400013
*   THIS MODULE IS USED FOR VARIABLE LENGTH RECORDS WITOUT USER EXITS   12600013
*   IN THE MERGE PHASE.                                                 12800013
         SPACE 2                                                        13000013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            13200013
         SPACE 1                                                        13400013
RA       EQU   0                   USE-NOT USED                         13600013
RB       EQU   1                   USE-NOT USED                         13800013
RC       EQU   2                   USE-NOT USED                         14000013
RD       EQU   3                   CONTENTS IN- N/A                     14200013
*                                  USE- WORK REGISTER                   14400013
*                                  CONTENTS OUT- N/A                    14600013
RE       EQU   4                   CONTENTS IN- N/A                     14800013
*                                  USE- WORK REGISTER                   15000013
*                                  CONTENTS OUT- N/A                    15200013
RF       EQU   5                   CONTENTS IN- N/A                     15400013
*                                  USE- WORK REGISTER                   15600013
*                                  CONTENTS OUT- N/A                    15800013
RG       EQU   6                   USE-NOT USED                         16000013
RH       EQU   7                   USE-NOT USED                         16200013
RI       EQU   8                   USE-NOT USED                         16400013
RJ       EQU   9                   USE-NOT USED                         16600013
RK       EQU   10                  CONTENTS IN- N/A                     16800013
*                                  USE- BASE REGISTER FOR DSECT OF      17000013
*                                       RUNNING PROGRAM                 17200013
*                                  CONTENTS OUT- N/A                    17400013
RL       EQU   11                  CONTENTS IN- N/A                     17600013
*                                  USE- BASE REGISTER FOR THIS MODULE   17800013
*                                  CONTENTS OUT- N/A                    18000013
RM       EQU   12                  USE-NOT USED                         18200013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          18400013
*                                  USE- PPI REFERENCE,REGISTER SAVE     18600013
*                                    AREA                               18800013
*                                  CONTENTS OUT- ADDRESS OF PPI         19000013
RO       EQU   14                  CONTENTS IN - RETURN ADDRESS IN      19200013
*                                                IERRC9                 19400013
*                                  USE- NOT USED                        19600013
*                                  CONTENTS OUT- RETURN ADDRESS IN      19800013
*                                                IERRC9                 20000013
RP       EQU   15                  CONTENTS IN- BASE ADDRESS OF THIS    20200013
*                                               MODULE                  20400013
*                                  USE- NOT USED                        20600013
*                                  CONTENTS OUT- N/A                    20800013
         SPACE 2                                                        21000013
*START OF MODULE CODE PROPER:                                           21200013
         SPACE 2                                                        21400013
IERABV   CSECT                                                          21600013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    21800013
         USING IERRBVD,RK          ADDR OF RUNNING PROGRAM DUMMY MOD    22000013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      22200013
IERMBG   LR    RL,RP               LOAD MODULE BASE REG                 22400013
         L     RK,PPIBLK2+4        LOAD ADDRESS OF RUNNING PROGRAM      22600013
         MVC   WBLKCCNT,KEIGHT     SET BLOCK CHARACTER CTR TO 8         22800013
         L     RF,PPILAB04         LOAD ADDR OF OUTPUT BUFFER 1         23000013
         TM    PPISW1+6,X'02'      CHECK FOR 2314                       23200013
         BO    ABV2314               YES, SET UP TO BLOCK FORWARD       23400013
         SPACE 1                                                        23600013
         AH    RF,PPILAB07+2       ADD ROUNDED LENGTH OF OUTBLOCK BLOCK 23800013
ABV1000  ST    RF,WLSTPTR          OUTPUT BLOCK ADDRESS                 24000013
         ST    RF,WLSTPTRD         CURRENT OUTPUT BLK ENDING ADDR+1     24200013
         SPACE 2                                                        24400013
*        SET UP TAPE UNIT COUNTERS IN GENERATED CORE                    24600013
         SPACE 1                                                        24800013
         SR    RD,RD                                                    25000013
         IC    RD,PPIBDSVA          LOAD NUMBER OF TAPE UNITS           25200013
         LA    RD,1(RD)                                                 25400013
         LA    RF,4                                                     25600013
         MR    RE,RD                MULTIPLY BY FOUR                    25800013
         L     RD,PPISPGN1          LOAD ADDRESS OF GENERATED CORE      26000013
         SR    RD,RF                SUBTRACT REQUIRED AMT OF CORE       26200013
         N     RD,KROUND          PUT ON FULL WORD BOUNDARY             26400013
         MVI   0(RD),X'00'          ZERO OUT THE AREA                   26600013
         S     RF,KTWO                                                  26800013
         EX    RF,BTZERO                                                27000013
         ST    RD,PPISPGN1          STORE NEW ADDRESS OF GEN. CORE      27200013
         ST    RD,PPIUNTCT          STORE ADDRESS OF UNIT COUNTERS      27400013
         BR    RO                  RETURN TO LOAD MODULE                27600013
         SPACE 2                                                        27800013
ABV2314  LA    RF,16(0,RF)         ADJUST FOR EOS,BCC AND CHAIN BYTES   28000013
         MVI   KEIGHT+3,X'10'                                           28200013
         MVI   KFOUR+3,X'0C'       ADJUST BCC BY CHAIN TOO              28400013
         MVI   WBLKCCNT+3,X'10'                                         28600013
         MVC   RBSUBRLT(2),KNOP    OVERLAY TO MOVE RCD., THEN UPDATE    28800013
         MVC   RBSUBRLD(2),KNOP    BLOCK POINTER                        29000013
         MVC   RBLSTPTR(4),KABVKON1 INITIAL BLOCK                       29200013
         MVC   RBEOS(4),KABVKON2     POINTER                            29400013
         MVC   RBINCR(4),KABVKON                                        29600013
         B     ABV1000                                                  29800013
         SPACE 2                                                        30000013
*        EXECUTED MOVE INSTRUCTION TO ZERO OUT UNIT COUNTER AREA        30200013
         SPACE 1                                                        30400013
BTZERO   MVC   1(1,RD),0(RD)                                            30600013
         SPACE 2                                                        30800013
*        CONSTANTS USED BY THE PROGRAM                                  31000013
         SPACE 1                                                        31200013
KTWO     DC    F'2'                                                     31400013
KROUND   DC    X'FFFFFFFC'                                              31600013
KNOP     DC    X'4700'                                                  31800013
         DROP  RL                                                       32000013
         DROP  RK                                                       32200013
         USING IERRBVD,RL                                               32400013
KABVKON1 L     RC,WLSTPTRD         INITIAL                              32600013
KABVKON  IC    RG,PPIDEPHO+1                                            32800013
KABVKON2 L     RE,WLSTPTRD                                              33000013
         EJECT                                                          33200013
*        DSECT OF RUNNING PROGRAM *** IERABV ***                        33400013
         SPACE 3                                                        33600013
IERRBVD  DSECT                                                          33800013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    34000013
         USING IERRCA,RN           ADDR OF PPI LOADED EXTERNALLY        34200013
         SPACE 1                                                        34400013
*   ENTRY TABLE                                                         34600013
         SPACE 1                                                        34800013
IERDB2   B     RBEOS               FROM MERGE ON NORMAL EOS             35000013
         B     RBRDRTRN            FROM READ MODULE                     35200013
         B     RBWRT               FROM WRITE MODULE                    35400013
         BC    0,RBSAVE            PRIMING ENTRY-ONLY FOR USER MODS MOD 35600013
         B     RBBRANCH                                                 35800013
         SPACE 1                                                        36000013
WLSTPTR  DC    F'0'                INITIALLY LOADED BY A.P. TO OUTPUT   36200013
*                                    BLOCK ENDING ADDRESS + 1.          36400013
WLSTPTRD DC    F'0'                OUTPUT BLOCK ENDING ADDRESS + 1.     36600013
         SPACE 1                                                        36800013
         SPACE 1                                                        37000013
*   NORMAL MERGE ENTRY. INCR BLOCK CHAR CTR. CHECK IF RCD WILL FIT IN   37200013
*     OUTPUT BLOCK. IF NOT, WRITE THE BLOCK BEFORE MOVING THE RCD.      37400013
         SPACE 1                                                        37600013
RBBRANCH L     RG,WBLKCCNT         OUTPUT BLOCK CHAR CTR INITIALLY      37800013
*                                    PRESET TO 8 BY A.P.                38000013
         MVC   WRCDLGTH+2(2),0(RD)  MOVE RCD LENGTH TO PROPER BOUNDARY  38200013
         A     RG,WRCDLGTH         ADD RCD LENGTH TO OUTPUT BLOCK CHAR  38400013
*                                    CTR                                38600013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 38800013
         BC    2,RBWRTBLK          GRTR,BR TO WRITE THE BLOCK FIRST     39000013
RBSAVE   ST    RG,WBLKCCNT         SAVE UPDATED BLOCK CHAR CTR          39200013
         ST    RD,WINNER           SAVE ADDR OF RCD IN INPUT BLOCK      39400013
         L     RF,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD     39600013
RBSUBRLT S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR TAPE SORT 39800013
*                                    RCDS FILL OUTPUT BLOCK STARTG FROM 40000013
*                                    HI CORE TO LOW.                    40200013
         SR    RG,RG                                                    40400013
RBINCR   IC    RG,PPIDEPHO+3                                            40600013
         L     RH,PPIUNTCT          LOAD ADDRESS OF UNIT COUNTERS       40800013
         L     RI,0(RG,RH)          LOAD COUNT FOR THIS UNIT            41000013
         LA    RI,1(RI)           INCREMENT BY ONE                      41200013
         ST    RI,0(RG,RH)          RESTORE                             41400013
         LR    RE,RD               ADDR OF RCD IN INPUT AREA FOR MOVE   41600013
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           41800013
         SPACE 1                                                        42000013
*   GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA   42200013
*     AREA TO ANOTHER. REGISTERS ARE USED AS FOLLOWS-                   42400013
         SPACE 1                                                        42600013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  42800013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    43000013
*        RI    DATA RCD LENGTH                                          43200013
         SPACE 1                                                        43400013
*   IN ADDITION THE ROUTINE USES REGISTERS RG AND RH.                   43600013
         SPACE 1                                                        43800013
         CL    RI,KON256           RCD LENGTH TO 256                    44000013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   44200013
         SPACE 1                                                        44400013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    44600013
         LNR   RG,RH                 256 BYTES EACH                     44800013
RBKMOVE  MVC   0(256,RF),0(RE)                                          45000013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     45200013
         AR    RF,RH                 BYTES                              45400013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    45600013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 45800013
         SPACE 2                                                        46000013
KON256   DC    F'256'                                                   46200013
KMOVE1   MVC   0(1,RF),0(RE)                                            46400013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             46600013
         BCTR  RG,0                DECR RG BY ONE                       46800013
         EX    RG,KMOVE1                                                47000013
         SPACE 1                                                        47200013
*   END OF GENERALIZED MOVE ROUTINE.                                    47400013
         SPACE 1                                                        47600013
         AR    RF,RI               UPDATE OUTPUT BLOCK RCD PTR BY       47800013
*                                    REMAINING RCD LENGTH               48000013
RBSUBRLD S     RF,WRCDLGTH         DECR ADDRESS BY RECORD LENGTH        48200013
         ST    RF,WLSTPTR          SAVE UPDATED OUTPUT BLOCK RCD PTR    48400013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            48600013
         SPACE 2                                                        48800013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK                   49000013
         SPACE 1                                                        49200013
RBWRTBLK S     RG,WRCDLGTH         SUBTR LENGTH OF RCD THAT CAN'T FIT   49400013
*                                    FROM OUTPUT BLOCK CHAR COUNT       49600013
RBLSTPTR L     RC,WLSTPTR          LOAD OUTPUT BLOCK RECORD POINTER     49800013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   50000013
         ST    RG,WBLKCCNT         STORE BLK CHAR CTR IN 1ST 2 BYTES    50200013
         MVC   0(2,RC),WBLKCCNT+2                                       50400013
         LR    RB,RG                 ALSO, IN RB FOR WRITE MODULE PARAM 50600013
         SPACE 1                                                        50800013
*   INTERFACE TO WRITE MODULE                                           51000013
         SPACE 1                                                        51200013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 51400013
         B     8(RL)               BR TO WRITE MODULE                   51600013
         SPACE 1                                                        51800013
*   WRITE MODULE REENTERS VIA BRANCH TABLE. RC FOR TAPE,HAS AN OUTPUT   52000013
*   BLOCK ENDING ADDRESS+1.                                             52200013
         SPACE 1                                                        52400013
RBWRT    ST    RC,WLSTPTRD         SAVE AS CURRENT OUTPUT BLK POINTER   52600013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLK WORK POINTER     52800013
         L     RG,KEIGHT           REINITIALIZE BCC TO 8 OR 16          53000013
         A     RG,WRCDLGTH         ADD LENGTH OF RCD TO BE MOVED TO     53200013
*                                    OUTPUT BLOCK                       53400013
         B     RBSAVE              BR TO MOVE RCD TO OUTPUT BLOCK       53600013
         SPACE 2                                                        53800013
*   FROM MERGE.NORMAL EOS.PREVIOUS RCD WAS EOS RCD AND IS IN OUTPUT BLK 54000013
*     NO NEW RECORDS PASSED TO BLOCK RTN AT THIS TIME.                  54200013
         SPACE 1                                                        54400013
RBEOS    L     RE,WLSTPTR                                               54600013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           54800013
         S     RE,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   55000013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      55200013
         MVC   0(2,RE),WBLKCCNT+2  STORE BLK CHAR CNT IN OUTPUT BLK     55400013
         L     RB,WBLKCCNT         LOAD BLOCK CHAR CNT FOR WRITE MOD    55600013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     55800013
         LR    RC,RE               LOAD OUTPUT BLOCK PTR FOR WRITE      56000013
         LA    RE,4                 SET INDICATION FOR NON-FINAL EOS    56200013
         SPACE 1                                                        56400013
*   INTERFACE TO WRITE MODULE FOR NORMAL EOS                            56600013
         SPACE 1                                                        56800013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 57000013
         B     4(RL)               BR TO WRITE MODULE                   57200013
         SPACE 2                                                        57400013
*   DEBLOCK SIDE OF PROGRAM                                             57600013
         SPACE 1                                                        57800013
RBDEBLCK SRL   RD,24               SHIFT TO GET AT INCR OF WINNER RCD   58000013
         L     RH,PPIUNTCT        LOAD ADDRESS OF UNIT COUNTERS         58200013
         L     RF,0(RD,RH)        LOAD COUNT FOR THIS UNIT              58400013
         BCTR  RF,0               DECREMENT BY ONE                      58600013
         ST    RF,0(RD,RH)        STORE                                 58800013
         L     RG,PPISBLCT         LOAD ADDR OF INPT BLK CHAR CNT TABLE 59000013
         L     RH,0(RD,RG)         LOAD BLK CHAR CNT OF WINNER'S BLOCK  59200013
         S     RH,WRCDLGTH         SUBTRACT RCD LENGTH OF WINNER        59400013
         C     RH,KZERO            TEST IF BLOCK CHAR CNT IS ZERO       59600013
         BC    8,RBREAD            YES,BR TO READ ANOTHER BLK INTO      59800013
*                                    INPUT BLK JUST VACATED             60000013
         ST    RH,0(RD,RG)         NO,STORE UPDATED BLOCK CHAR CNT      60200013
         L     RD,WINNER           RESTORE WINNER                       60400013
         A     RD,WRCDLGTH         ADDR OF NEXT RCD FROM WINNER FILE    60600013
         SPACE 1                                                        60800013
*   INTERFACE TO MERGE NETWORK                                          61000013
         SPACE 1                                                        61200013
RBMERGE  L     RL,PPINETM+4        ADDR OF MERGE MODULE                 61400013
         B     8(RL)               BR TO MERGE MODULE                   61600013
         SPACE 2                                                        61800013
*   FILL EMPTY INPUT BLOCK OF WINNER. RD HAS INCR IN LOW ORDER BYTE     62000013
         SPACE 1                                                        62200013
RBREAD   L     RG,PPIBDSVA         ADDR OF INPUT BLK ADDR TABLE         62400013
         L     RC,0(RD,RG)         ADDR OF THE WINNER'S INPUT BLOCK     62600013
         SPACE 1                                                        62800013
*   INTERFACE TO READ MODULE                                            63000013
         SPACE 1                                                        63200013
         L     RL,PPIRD+4          ADDR OF READ MODULE                  63400013
         B     8(RL)               BR TO READ MODULE                    63600013
         SPACE 2                                                        63800013
*   READ MODULE RETURNS VIA THIS MODULE BRANCH TABLE. THE REGS CONTAIN  64000013
*     THE FOLLOWING.RB - BLOCK CNT,RC - ADDR OF 1ST RCD IN INPUT BLOCK. 64200013
*      RD - INCREMENT, RE - ENDING ADDRESS OF BLOCK                     64400013
         SPACE 1                                                        64600013
RBRDRTRN L     RG,PPISBLCT         LOAD ADDR OF BLOCK CNT TABLE         64800013
         S     RB,KFOUR            EQUALS TOTAL BYTES(OF RCDS)IN BLOCK  65000013
         ST    RB,0(RD,RG)         STORE NEW BLOCK CHAR CNT IN TABLE    65200013
         L     RG,PPIBDSVA         ADDR OF TABLE OF INPUT BLK STRTG     65400013
*                                    ADDRESSES                          65600013
         ST    RE,0(RD,RG)         STORE IN INDEXED POSITION IN TABLE   65800013
         SLL   RD,24               POSITION INCR IN HI BYTE             66000013
         AR    RD,RC               INSERT STRTG ADDR OF 1ST RCD OF BLK  66200013
         B     RBMERGE             BR TO MERGE                          66400013
         SPACE 2                                                        66600013
*   LIST OF CONSTANTS USED BY THE MODULE                                66800013
         SPACE 1                                                        67000013
KZERO    DC    F'0'                ZERO                                 67200013
KFOUR    DC    F'4'                FOUR                                 67400013
KEIGHT   DC    F'8'                CONSTANT =8 FOR OSCL., =16 FOR 2314  67600013
         SPACE 2                                                        67800013
*   LIST OF WORK AREAS                                                  68000013
         SPACE 1                                                        68200013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHAR CTR INITIALLY      68400013
*                                    PRESET TO 8 BY A.P.                68600013
WRCDLGTH DC    F'0'                LENGTH OF INPUT RECORD TO BE BLOCKED 68800013
WINNER   DC    F'0'                ADDR OF WINNER RCD IN INPUT BLOCK    69000013
         EJECT                                                          69200013
         SMPPI                                                          69400013
         END                                                            69600013
