         TITLE 'IERABX - OS/360 SORT/MERGE - 360-SM023 05/11/66'        00200013
*MODULE NAME:*** IERABX ***                                             00400013
         SPACE 2                                                        00600013
*STATUS: CHANGE LEVEL 000                                               00800013
         SPACE 2                                                        01000013
*MODULE FUNCTION/OPERATION:                                             01200013
*   THIS MODULE IS AN ASSIGNMENT ROUTINE FOR IERRBW, A BLOCK/DEBLOCK    01400013
*   ROUTINE FOR VARIABLE LENGTH RECORDS WITH USER MODIFICATION EXIT     01600013
*   E25 FOR THE MERGE PHASE OF AN OSCL/2314 SORT.  IT SETS WORK AREAS   01800013
*   AND CONSTANTS TO SPECIFIC VALUES IN THE RUNNING PROGRAM. IT ALSO    02000013
*   ALLOCATES AREA IN GENERATED CORE FOR THE TAPE UNIT COUNTERS WHICH   02200013
*   KEEP TRACK OF THE NUMBER OF RECORDS ON EACH UNIT.                   02400013
         SPACE 2                                                        02600013
*USED AS A DSECT IN - N/A                                               02800013
*                                                                       03000013
*                                                                       03200013
*MACROS USED -                                                          03400013
         SPACE 1                                                        03600013
*   SMPPI                                                               03800013
         SPACE 2                                                        04000013
*ENTRY POINTS:                                                          04200013
         SPACE 1                                                        04400013
*        ENTRY IERMGB              ENTRY FROM: LOAD MODULE, IERRC9      04600013
*                                    CALLING SEQUENCE-                  04800013
*                                       LOAD   EP=IERABX,DCB=           05000013
*                                       LR     RP,RA                    05200013
*                                       BALR   RO,RP                    05400013
         SPACE 2                                                        05600013
*INPUT: PPI FIELDS REFERENCED-                                          05800013
         SPACE 1                                                        06000013
*   PPILAB04    PPILAB07                                                06200013
*   PPIBDSVA    PPIUNTCT                                                06400013
*   PPISPGN1                                                            06600013
         SPACE 2                                                        06800013
*OUTPUT: PPI FIELDS INITIALIZED OR ALTERED-                             07000013
         SPACE 1                                                        07200013
*   PPIUNTCT                                                            07400013
*   PPISPGN1                                                            07600013
*   CONSTANTS AND CODE IN THE RUNNING PROGRAM ARE INITIALIZED           07800013
*   ALLOCATES AREA FOR TAPE UNIT COUNTERS IN GENERATED CORE             08000013
         SPACE 2                                                        08200013
*EXTERNAL ROUTINES:                                                     08400013
         SPACE 1                                                        08600013
*        NONE                                                           08800013
         SPACE 2                                                        09000013
*EXTERNAL PARAMETERS:                                                   09200013
         SPACE 1                                                        09400013
*        NONE                                                           09600013
         SPACE 2                                                        09800013
*EXITS: NORMAL                                                          10000013
         SPACE 1                                                        10200013
*        BR    RO - RETURN TO LOAD MODULE, IERRC9                       10400013
         SPACE 2                                                        10600013
*EXITS: ERROR                                                           10800013
         SPACE 1                                                        11000013
*        NONE                                                           11200013
         SPACE 2                                                        11400013
*TABLES/WORK AREAS:                                                     11600013
         SPACE 1                                                        11800013
*        NONE                                                           12000013
         SPACE 2                                                        12200013
*ATTRIBUTES: THIS IS A CLASS A MODULE.                                  12400013
         SPACE 2                                                        12600013
*NOTES:                                                                 12800013
         SPACE 1                                                        13000013
*   THIS MODULE IS USED FOR VARIABLE LENGTH RECORDS WITH USER EXIT E25  13200013
*   IN THE MERGE PHASE.                                                 13400013
         SPACE 2                                                        13600013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            13800013
         SPACE 1                                                        14000013
RA       EQU   0                   USE-NOT USED                         14200013
RB       EQU   1                   USE-NOT USED                         14400013
RC       EQU   2                   USE-NOT USED                         14600013
RD       EQU   3                   CONTENTS IN- N/A                     14800013
*                                  USE- WORK REGISTER                   15000013
*                                  CONTENTS OUT- N/A                    15200013
RE       EQU   4                   CONTENTS IN- N/A                     15400013
*                                  USE- WORK REGISTER                   15600013
*                                  CONTENTS OUT- N/A                    15800013
RF       EQU   5                   CONTENTS IN- N/A                     16000013
*                                  USE- WORK REGISTER                   16200013
*                                  CONTENTS OUT- N/A                    16400013
RG       EQU   6                   USE-NOT USED                         16600013
RH       EQU   7                   USE-NOT USED                         16800013
RI       EQU   8                   USE-NOT USED                         17000013
RJ       EQU   9                   USE-NOT USED                         17200013
RK       EQU   10                  CONTENTS IN- N/A                     17400013
*                                  USE- BASE REGISTER FOR DSECT OF      17600013
*                                       RUNNIN PROGRAM                  17800013
*                                  CONTENTS OUT- N/A                    18000013
RL       EQU   11                  CONTENTS IN- N/A                     18200013
*                                  USE- BASE REGISTER FOR THIS MODULE   18400013
*                                  CONTENTS OUT- N/A                    18600013
RM       EQU   12                  USE-NOT USED                         18800013
RN       EQU   13                  CONTENTS IN- ADDRESS OF PPI          19000013
*                                  USE- PPI REFERENCE,REGISTER SAVE     19200013
*                                    AREA                               19400013
*                                  CONTENTS OUT- ADDRESS OF PPI         19600013
RO       EQU   14                  CONTENTS IN- RETURN ADDRESS IN       19800013
*                                               IERRC9                  20000013
*                                  USE- NOT USED                        20200013
*                                  CONTENTS OUT- RETURN ADDRESS IN      20400013
*                                                IERRC9                 20600013
RP       EQU   15                  CONTENTS IN- BASE ADDRESS OF THIS    20800013
*                                               MODULE                  21000013
*                                  USE- NOT USED                        21200013
*                                  CONTENTS OUT- N/A                    21400013
         SPACE 2                                                        21600013
*START OF MODULE CODE PROPER:                                           21800013
         SPACE 2                                                        22000013
IERABX   CSECT                                                          22200013
*1615362000,428000,466000                                          4553 22300018
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    22400013
         USING IERRBXD,RK          ADDR OF RUNNING PROGRAM DUMMY MOD    22600013
         USING IERRCA,RN           PPI COMMON MODULE BASE REGISTER      22800013
IERMBG   LR    RL,RP               LOAD MODULE BASE REG                 23000013
         L     RK,PPIBLK2+4        LOAD ADDRESS OF RUNNING PROGRAM      23200013
         MVC   WBLKCCNT,KEIGHT     SET BLOCK CHARACTER CTR TO 8         23400013
         L     RF,PPILAB04         LOAD ADDR OF OUTPUT BUFFER 1         23600013
         TM    PPISW1+6,X'02'      CHECK FOR 2314                       23800013
         BO    ABX1020               YES, SET UP TO BLOCK FORWARD       24000013
         SPACE 1                                                        24200013
         AH    RF,PPILAB07+2         ADD ROUNDED LENGTH OF OUTPUT BLOCK 24400013
ABX1010  ST    RF,WLSTPTR          OUTPUT BLOCK ADDRESS                 24600013
         ST    RF,WLSTPTRD         CURRENT OUTPUT BLK ENDING ADDR+1     24800013
         SPACE 2                                                        25000013
*        SET UP TAPE UNIT COUNTERS IN GENERATED CORE                    25200013
         SPACE 1                                                        25400013
         SR    RD,RD                                                    25600013
         IC    RD,PPIBDSVA          LOAD NUMBER OF TAPE UNITS           25800013
         LA    RD,1(RD)                                                 26000013
         LA    RF,4                                                     26200013
         MR    RE,RD                MULTIPLY BY FOUR                    26400013
         L     RD,PPISPGN1          LOAD ADDRESS OF GENERATED CORE      26600013
         SR    RD,RF                SUBTRACT REQUIRED AMT OF CORE       26800013
         N     RD,KROUND          PUT ON FULL WORD BOUNDARY             27000013
         MVI   0(RD),X'00'          ZERO OUT THE AREA                   27200013
         S     RF,KTWO                                                  27400013
         EX    RF,BTZERO                                                27600013
         ST    RD,PPISPGN1          STORE NEW ADDRESS OF GEN. CORE      27800013
         ST    RD,PPIUNTCT          STORE ADDRESS OF UNIT COUNTERS      28000013
         BR    RO                  RETURN TO LOAD MODULE                28200013
         SPACE 2                                                        28400013
ABX1020  LA    RF,16(0,RF)         ADJUST FOR EOS,BCC, AND CHAIN BYTES  28600013
         MVI   KEIGHT+3,X'10'                                           28800013
         MVI   KFOUR+3,X'0C'       ADJUST BCC BY CHAIN TOO              29000013
         MVI   WBLKCCNT+3,X'10'                                         29200013
         MVC   RBSUBRLT(2),KNOP    OVERLAY TO MOVE RCD, THEN UPDATE     29400013
         MVC   RBSUBRLD(2),KNOP      BLOCK POINTER                      29600013
         MVC   RBLSTPTR(4),KABXKON1 INITIAL BLOCK                       29800013
         MVC   RBEOS(4),KABXKON2     POINTER                            30000013
         MVC   RBINCR(4),KABXKON   INCR. FOR OUTPUT FILE                30200013
         B     ABX1010                                                  30400013
         SPACE 2                                                        30600013
*        EXECUTED MOVE INSTRUCTION TO ZERO OUT UNIT COUNTER AREA        30800013
         SPACE 1                                                        31000013
BTZERO   MVC   1(1,RD),0(RD)                                            31200013
         SPACE 2                                                        31400013
*        CONSTANTS USED BY THE PROGRAM                                  31600013
         SPACE 1                                                        31800013
KTWO     DC    F'2'                                                     32000013
KROUND   DC    X'FFFFFFFC'                                              32200013
KNOP     DC    X'4700'                                                  32400013
         DROP  RL                                                       32600013
         DROP  RK                                                       32800013
         USING IERRBXD,RL                                               33000013
KABXKON  IC    RG,PPIDEPHO+1       INCR. FOR OUTPUT UNIT                33200013
KABXKON1 L     RC,WLSTPTRD                                              33400013
KABXKON2 L     RE,WLSTPTRD                                              33600013
         EJECT                                                          33800013
*MODULE NAME *** IERRBX *** USER EXIT E25                               34000013
         SPACE 3                                                        34200013
IERRBXD  DSECT ,                   DUMMY MODULE OF REAL R.P. IERRBX     34400013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    34600013
         USING IERRCA,RN           ADDR OF PPI LOADED EXTERNALLY        34800013
         SPACE 1                                                        35000013
*   ENTRY TABLE                                                         35200013
         SPACE 1                                                        35400013
IERDB2   B     RBEOS               FROM MERGE ON NORMAL EOS             35600013
         B     RBRDRTRN            FROM READ MODULE                     35800013
         B     RBWRT               FROM WRITE MODULE                    36000013
         B     RBBPSUS1            PRIME ENTRY,BYPASS EXIT RTN     4553 36200018
         B     RBBRANCH                                                 36400013
         SPACE 1                                                        36600013
WLSTPTR  DC    F'0'                INITIALLY LOADED BY A.P. TO OUTPUT   36800013
*                                    BLOCK ENDING ADDRESS + 1.          37000013
WLSTPTRD DC    F'0'                OUTPUT BLOCK ENDING ADDRESS + 1.     37200013
         SPACE 1                                                        37400013
         SPACE 1                                                        37600013
*   NORMAL MERGE ENTRY. INCR BLOCK CHAR CTR. CHECK IF RCD WILL FIT IN   37800013
*     OUTPUT BLOCK. IF NOT, WRITE THE BLOCK BEFORE MOVING THE RCD.      38000013
         SPACE 1                                                        38200013
RBBRANCH ST    RD,WMRGRCD          PARAM 1 TO USER. AD OF RCD IN INPUT  38400013
*                                    BLOCK                              38600013
         SPACE 1                                                        38800013
*   CALL MACRO EXPANSION INSTRUCTIONS TO USER EXIT E25                  39000013
         SPACE 1                                                        39200013
         L     RP,PPIX25+4         ADDR OF USER EXIT E25                39400013
         LA    RB,WMRGRCD                                               39600013
         BALR  RO,RP                                                    39800013
         SPACE 1                                                        40000013
*   RETURN FROM USER                                                    40200013
         SPACE 1                                                        40400013
         B     *+4(RP)                                                  40600013
         B     RBBPSUSR            DO NOTHING                           40800013
         L     RG,PPIDELCT         DELETE COUNTER                       41000013
         LA    RG,1(0,RG)          INCR DELETE CTR BY 1                 41200013
         ST    RG,PPIDELCT         SAVE UPDATED DELETE CTR              41400013
         ST    RD,WINNER           SAVE WINNER ADDR (DEBLK WILL DELETE) 41600013
         MVC   WRCDLGTH+2(2),0(RD)  MOVE RCD LENGTH TO PROPER BOUNDARY  41800013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            42000013
RBBPSUS1 LR    RB,RD                                               4553 42100018
         SPACE 1                                                        42200013
RBBPSUSR L     RG,WBLKCCNT         OUTPUT BLOCK CHAR CTR INITIALLY      42400013
*                                    PRESET TO 8 BY A.P.                42600013
         MVC   WRCDLGTH+2(2),0(RB) MOVE RCD LENGTH TO PROPER BNDRY 4553 42800018
         A     RG,WRCDLGTH         ADD RCD LENGTH TO OUTPUT BLOCK CHAR  43000013
*                                    CTR                                43200013
         CH    RG,PPILAB07+2       GREATER THAN ROUNDED OUTPUT BLOCKING 43400013
         BC    2,RBWRTBLK          GRTR,BR TO WRITE THE BLOCK FIRST     43600013
RBSAVE   ST    RG,WBLKCCNT         SAVE UPDATED BLOCK CHAR CTR          43800013
         ST    RD,WINNER           SAVE ADDR OF RCD IN INPUT BLOCK      44000013
         L     RF,WLSTPTR          ADDR IN OUTPUT BLOCK TO MOVE RCD     44200013
RBSUBRLT S     RF,WRCDLGTH         DECR ADDR BY RCD LGTH. FOR TAPE SORT 44400013
*                                    RCDS FILL OUTPUT BLOCK STARTG FROM 44600013
*                                    HI CORE TO LOW.                    44800013
         ST    RF,WOUTRCD          PARAM 2 TO USER.ADDR OF RCD IN       45000013
*                                    OUTPUT BLOCK                       45200013
         SR    RG,RG                                                    45400013
RBINCR   IC    RG,PPIDEPHO+3       INCR. FOR OUTPUT FILE COUNT          45600013
         L     RH,PPIUNTCT          LOAD ADDRESS OF UNIT COUNTERS       45800013
         L     RI,0(RG,RH)          LOAD COUNT FOR THIS UNIT            46000013
         LA    RI,1(RI)           INCREMENT BY ONE                      46200013
         ST    RI,0(RG,RH)          RESTORE                             46400013
         LR    RE,RB               ADDR OF RCD IN INPUT AREA       4553 46600018
         L     RI,WRCDLGTH         LENGTH OF RCD FOR MOVE RTN           46800013
         SPACE 1                                                        47000013
*   GENERALIZED MOVE RTN USED TO MOVE ANY SIZE DATA RCD FROM ONE DATA   47200013
*     AREA TO ANOTHER. REGISTERS ARE USED AS FOLLOWS-                   47400013
         SPACE 1                                                        47600013
*        RE    ADDR FROM WHICH THE DATA IS TO BE MOVED                  47800013
*        RF    ADDR TO WHICH THE DATA IS TO BE MOVED                    48000013
*        RI    DATA RCD LENGTH                                          48200013
         SPACE 1                                                        48400013
*   IN ADDITION THE ROUTINE USES REGISTERS RG AND RH.                   48600013
         SPACE 1                                                        48800013
         CL    RI,KON256           RCD LENGTH TO 256                    49000013
         BC    12,RBNMV020         LESS THAN OR EQUAL                   49200013
         SPACE 1                                                        49400013
         LA    RH,256              SET UP TO MOVE RCD IN SECTIONS OF    49600013
         LNR   RG,RH                 256 BYTES EACH                     49800013
RBKMOVE  MVC   0(256,RF),0(RE)                                          50000013
         AR    RE,RH               UPDATE DATA AREA POINTERS BY 256     50200013
         AR    RF,RH                 BYTES                              50400013
         BXLE  RI,RG,RBNMV020      TEST FOR REMAINING LENGTH--LE 256    50600013
         BC    15,RBKMOVE          ANOTHER FULL MOVE OF 256 BYTES NEEDD 50800013
         SPACE 2                                                        51000013
KON256   DC    F'256'                                                   51200013
KMOVE1   MVC   0(1,RF),0(RE)                                            51400013
RBNMV020 LR    RG,RI               MOVE LENGTH LE 256 BYTES             51600013
         BCTR  RG,0                DECR RG BY ONE                       51800013
         EX    RG,KMOVE1                                                52000013
         SPACE 1                                                        52200013
*   END OF GENERALIZED MOVE ROUTINE.                                    52400013
         SPACE 1                                                        52600013
         AR    RF,RI               UPDATE OUTPUT BLOCK RCD PTR BY       52800013
*                                    REMAINING RCD LENGTH               53000013
RBSUBRLD S     RF,WRCDLGTH          DECREMENT ADDRESS BY RECORD LENGTH  53200013
         ST    RF,WLSTPTR          SAVE UPDATED OUTPUT BLOCK RCD PTR    53400013
         B     RBDEBLCK            BR TO DEBLOCK ANOTHER RCD            53600013
         SPACE 2                                                        53800013
*   WRITE A BLOCK. THIS RCD CAN'T FIT INTO THIS BLOCK                   54000013
         SPACE 1                                                        54200013
RBWRTBLK S     RG,WRCDLGTH         SUBTR LENGTH OF RCD THAT CAN'T FIT   54400013
*                                    FROM OUTPUT BLOCK CHAR COUNT       54600013
         ST    RB,WRBSAVE          STORE MOD RCD ADDR              4553 54700018
RBLSTPTR L     RC,WLSTPTR           LOAD OUTPUT BLOCK RECORD POINTER    54800013
         S     RC,KEIGHT           EQUALS ADDR OF OUTPUT BLK TO WRITE   55000013
         ST    RG,WBLKCCNT         ALIGN TO WD BOUNDARY                 55200013
         MVC   0(2,RC),WBLKCCNT+2  STORE BLOK CHAR CTR IN 1ST 2 BYTES   55400013
         LR    RB,RG                 ALSO, IN RB FOR WRITE MODULE PARAM 55600013
         SPACE 1                                                        55800013
*   INTERFACE TO WRITE MODULE                                           56000013
         SPACE 1                                                        56200013
         L     RL,PPIWRT+4         ADDR OF WRITE MODULE                 56400013
         B     8(RL)               BR TO WRITE MODULE                   56600013
         SPACE 1                                                        56800013
*   WRITE MODULE REENTERS VIA BRANCH TABLE. RC FOR TAPE,HAS AN OUTPUT   57000013
*   BLOCK ENDING ADDRESS+1.                                             57200013
         SPACE 1                                                        57400013
RBWRT    ST    RC,WLSTPTRD         SAVE AS CURRENT OUTPUT BLK POINTER   57600013
         ST    RC,WLSTPTR          STORE AS OUTPUT BLK WORK POINTER     57800013
         L     RG,KEIGHT           REINITIALIZE BCC TO 8 OR 16          58000013
         A     RG,WRCDLGTH         ADD LENGTH OF RCD TO BE MOVED TO     58200013
*                                    OUTPUT BLOCK                       58400013
         L     RB,WRBSAVE          RELOAD MOD RCD ADDR             4553 58500018
         B     RBSAVE              BR TO MOVE RCD TO OUTPUT BLOCK       58600013
         SPACE 2                                                        58800013
*   FROM MERGE.NORMAL EOS.PREVIOUS RCD WAS EOS RCD AND IS IN OUTPUT BLK 59000013
*     NO NEW RECORDS PASSED TO BLOCK RTN AT THIS TIME.                  59200013
         SPACE 1                                                        59400013
RBEOS    L     RE,WLSTPTR                                               59600013
         MVC   WLSTPTR,WLSTPTRD    RESET OUTPUT BLOCK POINTER           59800013
         S     RE,KEIGHT           DECR OUTPUT BLK PTR BY 8 TO INSERT   60000013
*                                    BLOCK CHAR CNT IN 1ST 2 BYTES      60200013
         MVC   0(2,RE),WBLKCCNT+2  STORE BLK CHAR CNT IN OUTPUT BLK     60400013
         L     RB,WBLKCCNT         LOAD BLOCK CHAR CNT FOR WRITE MOD    60600013
         MVC   WBLKCCNT,KEIGHT     REINITIALIZE BLOCK CHAR CTR TO 8     60800013
         LR    RC,RE               LOAD OUTPUT BLOCK PTR FOR WRITE      61000013
         LA    RE,4                 SET INDICATION FOR NON-FINAL EOS    61200013
         SPACE 1                                                        61400013
*   INTERFACE TO WRITE MODULE FOR NORMAL EOS                            61600013
         SPACE 1                                                        61800013
         L     RL,PPIWRT+4                                              62000013
         B     4(RL)               BR TO WRITE MODULE                   62200013
         EJECT                                                          62400013
*   DEBLOCK SIDE OF PROGRAM                                             62600013
         SPACE 1                                                        62800013
RBDEBLCK SRL   RD,24               SHIFT TO GET AT INCR OF WINNER RCD   63000013
         L     RH,PPIUNTCT        LOAD ADDRESS OF UNIT COUNTERS         63200013
         L     RF,0(RD,RH)        LOAD COUNT FOR THIS UNIT              63400013
         BCTR  RF,0               DECREMENT BY ONE                      63600013
         ST    RF,0(RD,RH)        STORE                                 63800013
         L     RG,PPISBLCT         LOAD ADDR OF INPT BLK CHAR CNT TABLE 64000013
         L     RH,0(RD,RG)         LOAD BLK CHAR CNT OF WINNER'S BLOCK  64200013
         S     RH,WRCDLGTH         SUBTRACT RCD LENGTH OF WINNER        64400013
         C     RH,KZERO            TEST IF BLOCK CHAR CNT IS ZERO       64600013
         BC    8,RBREAD            YES,BR TO READ ANOTHER BLK INTO      64800013
*                                    INPUT BLK JUST VACATED             65000013
         ST    RH,0(RD,RG)         NO,STORE UPDATED BLOCK CHAR CNT      65200013
         L     RD,WINNER           RESTORE WINNER                       65400013
         A     RD,WRCDLGTH         ADDR OF NEXT RCD FROM WINNER FILE    65600013
         SPACE 1                                                        65800013
*   INTERFACE TO MERGE NETWORK                                          66000013
         SPACE 1                                                        66200013
RBMERGE  L     RL,PPINETM+4        ADDR OF MERGE MODULE                 66400013
         B     8(RL)               BR TO MERGE MODULE                   66600013
         SPACE 2                                                        66800013
*   FILL EMPTY INPUT BLOCK OF WINNER. RD HAS INCR IN LOW ORDER BYTE     67000013
         SPACE 1                                                        67200013
RBREAD   L     RG,PPIBDSVA         ADDR OF INPUT BLK ADDR TABLE         67400013
         L     RC,0(RD,RG)         ADDR OF THE WINNER'S INPUT BLOCK     67600013
         SPACE 1                                                        67800013
*   INTERFACE TO READ MODULE                                            68000013
         SPACE 1                                                        68200013
         L     RL,PPIRD+4          ADDR OF READ MODULE                  68400013
         B     8(RL)               BR TO READ MODULE                    68600013
         SPACE 2                                                        68800013
*   READ MODULE RETURNS VIA THIS MODULE BRANCH TABLE. THE REGS CONTAIN  69000013
*     THE FOLLOWING.RB - BLOCK CNT,RC - ADDR OF 1ST RCD IN INPUT BLOCK. 69200013
*     RD - INCREMENT, RE - ENDING ADDRESS OF BLOCK.                     69400013
         SPACE 1                                                        69600013
RBRDRTRN L     RG,PPISBLCT         LOAD ADDR OF BLOCK CNT TABLE         69800013
         S     RB,KFOUR            EQUALS TOTAL BYTES(OF RCDS)IN BLK    70000013
         ST    RB,0(RD,RG)         STORE NEW BLOCK CHAR CNT IN TABLE    70200013
         L     RG,PPIBDSVA         ADDR OF TABLE OF INPUT BLK STRTG     70400013
*                                    ADDRESSES                          70600013
         ST    RE,0(RD,RG)         STORE IN INDEXED POSITION IN TABLE   70800013
         SLL   RD,24               POSITION INCR IN HI BYTE             71000013
         AR    RD,RC               INSERT STRTG ADDR OF 1ST RCD OF BLK  71200013
         B     RBMERGE             BR TO MERGE NETWORK                  71400013
         SPACE 2                                                        71600013
*   LIST OF CONSTANTS USED BY THE MODULE                                71800013
         SPACE 1                                                        72000013
KZERO    DC    F'0'                ZERO                                 72200013
KFOUR    DC    F'4'                FOUR                                 72400013
KEIGHT   DC    F'8'                CONSTANT =8 FOR OSCL., =16 FOR 2314  72600013
         SPACE 2                                                        72800013
*   LIST OF WORK AREAS                                                  73000013
         SPACE 1                                                        73200013
WMRGRCD  DC    F'0'                ADDR OF RCD IN INPUT BLK-USER PARAM1 73400013
WOUTRCD  DC    F'0'                ADDR OF RCD IN OUTPUT BLK-USR PARAM2 73600013
WBLKCCNT DC    F'0'                OUTPUT BLOCK CHAR CTR INITIALLY      73800013
*                                    PRESET TO 8 BY A.P.                74000013
WRCDLGTH DC    F'0'                LENGTH OF INPUT RECORD TO BE BLOCKED 74200013
WINNER   DC    F'0'                ADDR OF WINNER RCD IN INPUT BLOCK    74400013
WRBSAVE  DC    F'0'                CURRENT MODIFIED RCD ADDR       4553 74500018
         EJECT                                                          74600013
         SMPPI                                                          74800013
         END                                                            75000013
