         TITLE '      IERADB - OS/360 SORT/MERGE - 360S-SM023 05/06/66' 00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERADB ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMNT MODULE. F.L. SORT W/O E15 02100013
*   THE FUNCTION OF THIS MODULE IS TO BUILD A TABLE OF RSA ADDRESSES    02400013
*   WITH THEIR RESPECTIVE AREA BYTE COUNTS IN IERRDB. THE TABLE IS      02700013
*   NEEDED BECAUSE RECORD STORAGE AREA MAY NOT BE CONTIGUOUS. THIS      03000013
*   MODULE ALSO BUILDS THE INPUT BUFFERS USING THE BUILD MACRO. IT      03300013
*   ALSO OBTAINS THE ADDRESS OF THE INPUT DCB AND PUTS IT IN THE        03600013
*   RUNNING PROGRAM,IERRDB.                                             03900013
*   IERADB INSERTS THE RECORD LENGTH OF THE FIXED LENGTH RECORD WHICH   04200013
*   MUST BE LESS THAN OR EQUAL TO 256 BYTES IN IERRDB MOVE INSTRUCTION. 04500013
         SPACE 2                                                        04800013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               05100013
         SPACE 1                                                        05400013
*   NONE                                                                05700013
         SPACE 2                                                        06000013
*LIST OF MACROS USED BY MODULE:                                         06300013
         SPACE 1                                                        06600013
*   SMPPI                                                               06900013
*   BUILD                                                               07200013
         SPACE 2                                                        07500013
*ENTRY POINTS:                                                          07800013
         SPACE 1                                                        08100013
*   FROM IERRC9                    ENTRY FROM:IERRC9                    08400013
*                                    CALLING SEQUENCE-                  08700013
*                                      LOAD EP=IERADB,DCB=SORTLIB       09000013
*                                      LR   RP,RA                       09300013
*                                      BALR RO,RP                       09600013
         SPACE 2                                                        09900013
*INPUT: - PPI FIELDS REFERENCED                                         10200013
         SPACE 1                                                        10500013
*   PPIDEB     PPISTDCB   PPILAB08                                      10800013
*   PPIRCDL1   PPILAB03                                                 11100013
*   PPILEXFF   PPILAB06                                                 11400013
         SPACE 1                                                        11700013
*   INFO IS NEEDED TO BUILD THE RSA TABLE IN IERRDB AND TO BUILD THE    12000013
*   INPUT BUFFERS.                                                      12300013
         SPACE 2                                                        12600013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            12900013
         SPACE 1                                                        13200013
*   NONE                                                                13500013
         SPACE 2                                                        13800013
*EXTERNAL ROUTINES:                                                     14100013
         SPACE 1                                                        14400013
*   NONE                                                                14700013
         SPACE 2                                                        15000013
*EXTERNAL PARAMETERS:                                                   15300013
         SPACE 1                                                        15600013
*   SEE REGISTERS                                                       15900013
         SPACE 2                                                        16200013
*EXITS-NORMAL:                                                          16500013
         SPACE 1                                                        16800013
*   TO IERRC9                      EXIT TO:IERRC9                       17100013
*                                    CALLING SEQUENCE-                  17400013
*                                      BR   RO         RETURN           17700013
         SPACE 2                                                        18000013
*EXITS-ERROR:                                                           18300013
         SPACE 1                                                        18600013
*   NONE                                                                18900013
         SPACE 2                                                        19200013
*TABLES/WORK AREAS:                                                     19500013
         SPACE 1                                                        19800013
*   WAREA-WORK AREA                                                     20100013
         SPACE 2                                                        20400013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   20700013
         SPACE 2                                                        21000013
*NOTES: THIS MODULE WILL EXECUTE FOR ANY FIXED LENGTH SORT WITHOUT EXIT 21300013
*   E15 AND E16. THE FIXED LENGTH INPUT RCD MUST BE EQUL/L.T. 256 BYTES 21600013
         EJECT                                                          21900013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            22200013
         SPACE 1                                                        22500013
RA       EQU   0                   CONTENTS IN- N/A                     22800013
*                                  USE- HAS NO. OF BUFFERS AND BUFFER   23100013
*                                    SIZE FOR BUILD MACRO               23400013
*                                  CONTENTS OUT- N/A                    23700013
RB       EQU   1                   CONTENTS IN- N/A                     24000013
*                                  USE- ADDR OF INPUT BUFFER POOL FOR   24300013
*                                    BUILD MACRO                        24600013
*                                  CONTENTS OUT- N/A                    24900013
RC       EQU   2                   CONTENTS IN- N/A                     25200013
*                                  USE- ADDR OF RSA TABLE IN IERRDB     25500013
*                                  CONTENTS OUT- N/A                    25800013
RD       EQU   3                   CONTENTS IN- N/A                     26100013
*                                  USE- COUNTER FOR NO. OF RSA AREAS    26400013
*                                  CONTENTS OUT- N/A                    26700013
RE       EQU   4                   CONTENTS IN- N/A                     27000013
*                                  USE- WORK REGISTER                   27300013
*                                  CONTENTS OUT- N/A                    27600013
RF       EQU   5                   CONTENTS IN- N/A                     27900013
*                                  USE- PTR TO THE TABLE OF RSA ADDRS   28200013
*                                    IN PPI                             28500013
*                                  CONTENTS OUT- N/A                    28800013
RG       EQU   6                   CONTENTS IN- N/A                     29100013
*                                  USE- INDEX REGISTER                  29400013
*                                     - WORK REGISTER                   29700013
*                                  CONTENTS OUT- N/A                    30000013
RH       EQU   7                   CONTENTS IN- N/A                     30300013
*                                  USE- WORK REGISTER                   30600013
*                                  CONTENTS OUT- N/A                    30900013
RI       EQU   8                   CONTENTS IN- N/A                     31200013
*                                  USE- WORK REGISTER                   31500013
*                                  CONTENTS OUT- N/A                    31800013
RJ       EQU   9                   CONTENTS IN- N/A                     32100013
*                                  USE- NOT USED                        32400013
*                                  CONTENTS OUT- N/A                    32700013
RK       EQU   10                  CONTENTS IN- N/A                     33000013
*                                  USE- IERRDB DSECT BASE REGISTER      33300013
*                                  CONTENTS OUT- N/A                    33600013
RL       EQU   11                  CONTENTS IN- N/A                     33900013
*                                  USE-MODULE BASE REGISTER             34200013
*                                  CONTENTS OUT- N/A                    34500013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   34800013
*                                  USE- NOT USED                        35100013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   35400013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              35700013
*                                  USE-PPI REFERENCES,REG SAVE AREA     36000013
*                                  CONTENTS OUT-ADDR OF PPI             36300013
RO       EQU   14                  CONTENTS IN- IERRC9 RETURN ADDR      36600013
*                                  USE- NOT USED                        36900013
*                                  CONTENTS OUT- IERRC9 RETURN ADDR     37200013
RP       EQU   15                  CONTENTS IN- IERADB ENTRY PT         37500013
*                                  USE- ESTABLISH IERADB BASE REGISTER  37800013
*                                  CONTENTS OUT- N/A                    38100013
         SPACE 2                                                        38400013
*START OF MODULE CODE PROPER:                                           38700013
         SPACE 2                                                        39000013
IERADB   CSECT                                                          39300013
         USING *,RL                THIS MODULE BASE REG                 39600013
         USING IERRDB,RK                                                39900013
         USING IERRCA,RN                                                40200013
IERMDA   LR    RL,RP               SET THIS MODULE BASE REGISTER        40500013
         L     RK,PPIDEB+4         SET IERRDB DSECT BASE REGISTER       40800013
         SPACE 2                                                        41100013
*ESTABLISH ALL RECORD STORAGE AREA ADDRESSES AND THEIR RESPECTIVE BYTE  41400013
*   COUNTS AND BUILD RSA TABLE IN IERRDB                                41700013
         SPACE 1                                                        42000013
         LA    RC,TABLRSA          ADDR OF RSA TABLE IN IERRDB          42300013
         SR    RD,RD                                                    42600013
         SR    RG,RG                                                    42900013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     43200013
         LA    RH,4                4 BYTES FOR TREE ADDR                43500013
         AH    RH,PPILEXFF         PLUS SIZE OF ROUNDED EXTRACTED       43800013
*                                    CONTROL FIELDS                     44100013
         L     RF,PPILAB08         PTR TO TABLE OF RSA ADDRS WITH THEIR 44400013
*                                    RESPECTIVE BYTE COUNTS             44700013
ADBRSALP L     RE,0(RG,RF)         STRTG ADDR OF AN RSA AREA            45000013
         AR    RE,RH               ADDR OF 1ST RCD IN THIS RSA AREA     45300013
         ST    RE,0(RG,RC)         STORE IN IERRDB RSA ADDR TABLE       45600013
         L     RE,4(RG,RF)         BYTE COUNT OF THIS RSA AREA          45900013
         ST    RE,4(RG,RC)         STORE IN IERRDB RSA ADDR TABLE       46200013
         LA    RG,8(0,RG)          UPDATE INDEX PTR                     46500013
         BCT   RD,ADBRSALP         DECR RSA CTR. LOOP IF MORE RSA AREAS 46800013
         SPACE 1                                                        47100013
*INSERT INPUT DCB ADDR AND RECORD LENGTH IN IERRDB. BUILD INPUT BUFFERS 47400013
         SPACE 1                                                        47700013
         L     RG,PPISTDCB         SET INPUT DCB ADDRS IN RUNNING PROG. 48000013
         L     RE,0(RG)                                                 48300013
         ST    RE,KADCB                                                 48600013
         LH    RI,PPIRCDL1         SET RCD LENGTH - 1 IN IN-LINE        48900013
         BCTR  RI,0                  MOVE INSTR IN RUNNING PROG         49200013
         STC   RI,RDB1030+1                                             49500013
         SPACE 1                                                        49800013
         L     RB,PPILAB02         ADDR OF INPUT BUFFER POOL ADDR TABLE 50100013
         MVC   WAREA+2(2),PPILAB03+2                                    50400013
         MVC   WAREA+1(1),PPILAB03                                      50700013
         L     0,WAREA             SET NO. OF BUFFERS AND BUFFER SIZE   51000013
*                                  IN REG 0                             51300013
         SPACE 2                                                        51600013
         BUILDS (1),(0)            BUILD INPUT BUFFERS                  51900013
         SPACE 2                                                        52200013
         SPACE 2                                                        52500013
*INTERFACE TO IERRC9                                                    52800013
         SPACE 1                                                        53100013
         BR    RO                  RETURN                               53400013
         SPACE 2                                                        53700013
*LIST OF WORK AREAS:                                                    54000013
         SPACE 1                                                        54300013
WAREA    DC    F'0'                                                     54600013
         EJECT                                                          54900013
IERRDB   DSECT ,                   DUMMY RUNNING PROGRAM                55200013
IERDD1   B     RDB1050             ENTRY FROM SORT NETWORK.G RCDS IN    55500013
*                                    TREE.(ONCE ONLY)                   55800013
         B     RDB1060             ENTRY FROM EOF ROUTINE               56100013
RDB1010  L     RH,ADCONPTR         NORMAL NETWORK,BLOCK ENTRY. LOAD RSA 56400013
*                                    TABLE PTR. WILL BE B RDB1020 AFTER 56700013
*                                    RSA  IS FILLED WITH G+1 RCDS AND   57000013
*                                    BY A BR TO THE NTWK AFTER EOF.     57300013
         LM    RD,RE,0(RH)         RD-START OF RSA RCD. RE- THIS RSA    57600013
*                                    REMAINING BYTE COUNT.              57900013
RDB1020  L     RG,KADCB            ADDR OF THE INPUT DCB                58200013
         GET   (RG)                                                     58500013
         SPACE 1                                                        58800013
*GET RETURNS ADDR OF RCD IN INPUT BUFFER IN RB.                         59100013
         SPACE 1                                                        59400013
RDBRTRN  S     RE,PPIBINSZ         SUBTRACT BINSIZE FROM RSA BYTE COUNT 59700013
*                                    WILL BE B RDLOADRC AFTER G+1 RCDS. 60000013
         BM    RDNEWRSA            BR IF MINUS(RCD CAN'T FIT IN THIS    60300013
*                                    RSA)                               60600013
RDBOVLAY BC    0,RDBLAST           WILL BE A BR AFTER TREE HAS G RCDS.  60900013
         SPACE 2                                                        61200013
*MOVE RECORD FROM INPUT BUFFER TO RSA.                                  61500013
         SPACE 1                                                        61800013
RDLOADRC LR    RC,RB               INPUT RCD ADDR FOR EXTRACT RTN       62100013
RDB1030  MVC   0(1,RD),0(RC)       MOVE RCD FROM INPUT BFR TO RSA.      62400013
*                                    LENGTH SET BY A.P.                 62700013
         SPACE 1                                                        63000013
*UPDATE RECORD  COUNTER                                                 63300013
         SPACE 1                                                        63600013
         L     RG,PPICOUNT                                              63900013
         LA    RG,1(RG)            INCR RCD COUNT BY 1                  64200013
         ST    RG,PPICOUNT                                              64500013
         SPACE 1                                                        64800013
*UPDATE RSA TABLE PARAMETERS                                            65100013
         SPACE 1                                                        65400013
RDB1040  LR    RF,RD               WILL BE OVLAYED BY BR TO NETWORK     65700013
*                                    AFTER G+1 RCDS                     66000013
         A     RF,PPIBINSZ         UPDATE RSA ADDR TO NEXT BIN          66300013
         ST    RF,0(0,RH)          STORE IN RSA TABLE                   66600013
         ST    RE,4(0,RH)          STORE THIS RSA REMAINING BYTE COUNT  66900013
         SPACE 1                                                        67200013
*INTERFACE WITH SORT NETWORK DURING FILL OF TREE.                       67500013
         SPACE 1                                                        67800013
         L     RL,PPINET+4         ADDR OF NETWORK                      68100013
         B     4(RL)                 BR TO FILL TREE                    68400013
         SPACE 2                                                        68700013
*UPDATE POINTER TO NEXT RSA TABLE ENTRY(NEXT RSA AREA)                  69000013
         SPACE 1                                                        69300013
RDNEWRSA LA    RH,8(0,RH)          UPDATE PTR                           69600013
         ST    RH,ADCONPTR         SAVE UPDATED PTR TO THE TABLE        69900013
         LM    RD,RE,0(RH)         NEW RSA PARAMETERS                   70200013
         B     RDBRTRN             BR TO PROCESS THIS INPUT RCD         70500013
         SPACE 2                                                        70800013
         SPACE 2                                                        71100013
*SORT TREE HAS BEEN FILLED.  THE NEXT DEBLOCKED RECORD IS MOVED TO THE  71400013
*NEXT SPACE IN RSA.  IN ALL SUBSEQUENT ENTRIES TO THIS MODULE, RD WILL  71700013
*POINT TO THE WINNER RECORD IN RSA.  THE DEBLOCKED RECORD MUST BE MOVED 72000013
*TO THE LOCATION INDICATED BY RD. ALSO, THIS MODULE MUST NOW ENTER THE  72300013
*SORT NETWORK AT ITS NORMAL ENTRY POINT.  THE FOLLOWING CODE MODIFIES   72600013
*THIS MODULE TO EFFECT THESE NEW REQUIREMENTS.                          72900013
         SPACE 1                                                        73200013
RDB1050  MVI   RDBOVLAY+1,X'F0'    MAKE THE INSTR A DIRECT BRANCH       73500013
         B     RDB1010                                                  73800013
         SPACE 2                                                        74100013
RDBLAST  MVC   RDB1010(4),KMOD1                                         74400013
         MVC   RDBRTRN(4),KMOD2                                         74700013
         MVC   RDB1040(8),KMOD3                                         75000013
         B     RDLOADRC            MOVE THIS INPUT RCD TO RSA(G+1 RCD)  75300013
         SPACE 2                                                        75600013
*WHEN EOF HAS BEEN REACHED, THERE ARE NO MORE RECORDS TO BE DEBLOCKED   75900013
*BUT THE SORT NETWORK MUST EMPTY ITS TREE.  FUTURE ENTRIES TO THIS      76200013
*MODULE DO NO PROCESSING, BUT MERELY EXIT TO THE SORT NETWORK AT ITS    76500013
*EMPTYING ENTRY.  THE FOLLOWING CODING MODIFIES THE PRESENT ENTRY POINT 76800013
*TO EFFECT THIS CHANGE AND THEN EXITS TO THE SORT NETWORK AT ITS EOF    77100013
*ENTRY.                                                                 77400013
         SPACE 1                                                        77700013
RDB1060  MVC   RDB1010(8),KMOD4    BR DIRECTLY TO SORT NETWORK          78000013
         SPACE 1                                                        78300013
*INTERFACE TO SORT NETWORK ON EOF.                                      78600013
         SPACE 1                                                        78900013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 79200013
         B     8(RL)                                                    79500013
         SPACE 2                                                        79800013
*ADCONS USED BY THE MODULE:                                             80100013
         SPACE 1                                                        80400013
ADCONPTR DC    A(TABLRSA)                                               80700013
         SPACE 2                                                        81000013
*CONSTANTS USED BY THE MODULE:                                          81300013
         SPACE 1                                                        81600013
KMOD1    B     RDB1020             OVERLAY RDB1010 AFTER G+1 RCDS       81900013
KMOD2    B     RDLOADRC            OVERLAY RDBRTRN AFTER G+1 RCDS       82200013
KMOD3    L     RL,PPINET+4         OVERLAY RDB1040 AFTER G+1 RCDS       82500013
         B     12(RL)                NORMAL BRANCH TO NETWORK           82800013
KMOD4    L     RL,PPINET+4         OVERLAY RDB1010 AFTER EOF            83100013
         B     16(RL)                FLUSH BRANCH TO NTWK               83400013
KADCB    DC    F'0'                INPUT DCB ADDR LOADED BY A.P.        83700013
         SPACE 2                                                        84000013
*LIST OF WORK AREAS/TABLES:                                             84300013
         SPACE 1                                                        84600013
TABLRSA  DC    10F'0'              SPACE AVAILABLE FOR 5 NON-CONTIGUOUS 84900013
*                                    RSA ENTRIES.EACH ENTRY 8 BYTES.    85200013
*                                    4 BYTES-ADDR IN BIN TO MOVE RCD    85500013
*                                    4 BYTES-REMAINING BYTE COUNT OF    85800013
*                                      THIS RSA.                        86100013
*                                    INITIALIZED BY A.P.                86400013
         SPACE 2                                                        86700013
         EJECT                                                          87000013
         SMPPI                                                          87300013
         END                                                            87600013
