         TITLE '      IERADC - OS/360 SORT/MERGE - 360S-SM023 05/06/66' 00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERADC ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMENT MODULE. F.L SORT W/O E15 02100013
*   THE FUNCTION OF THIS MODULE IS TO BUILD A TABLE OF RSA ADDRESSES    02400013
*   WITH THEIR RESPECTIVE AREA BYTE COUNTS IN IERRDC. THE TABLE IS      02700013
*   NEEDED BECAUSE RECORD STORAGE AREA MAY NOT BE CONTIGUOUS. THIS      03000013
*   MODULE ALSO BUILDS THE INPUT BUFFERS USING THE BUILD MACRO. IT      03300013
*   ALSO OBTAINS THE ADDRESS OF THE INPUT DCB AND PUTS IT IN THE        03600013
*   RUNNING PROGRAM IERRDC.                                             03900013
         SPACE 2                                                        04200013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               04500013
         SPACE 1                                                        04800013
*   NONE                                                                05100013
         SPACE 2                                                        05400013
*LIST OF MACROS USED BY MODULE:                                         05700013
         SPACE 1                                                        06000013
*   SMPPI                                                               06300013
*   BUILD                                                               06600013
         SPACE 2                                                        06900013
*ENTRY POINTS:                                                          07200013
         SPACE 1                                                        07500013
*   FROM  IERRC9                   ENTRY FROM:IERRC9                    07800013
*                                    CALLING SEQUENCE-                  08100013
*                                      LOAD EP=IERADC,DCB=SORTLIB       08400013
*                                      LR   RP,RA                       08700013
*                                      BALR RO,RP                       09000013
         SPACE 2                                                        09300013
*INPUT: - PPI FIELDS REFERENCED                                         09600013
         SPACE 1                                                        09900013
*   PPIDEB     PPILAB08                                                 10200013
*   PPILAB03   PPILEXFF                                                 10500013
*   PPILAB06   PPISTDCB                                                 10800013
         SPACE 1                                                        11100013
*   INFO IS NEEDED TO BUILD THE RSA TABLE IN IERRDC AND TO BUILD THE    11400013
*   INPUT BUFFERS.                                                      11700013
         SPACE 2                                                        12000013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            12300013
         SPACE 1                                                        12600013
*   NONE                                                                12900013
         SPACE 2                                                        13200013
*EXTERNAL ROUTINES:                                                     13500013
         SPACE 1                                                        13800013
*   NONE                                                                14100013
         SPACE 2                                                        14400013
*EXTERNAL PARAMETERS:                                                   14700013
         SPACE 1                                                        15000013
*   SEE REGISTERS                                                       15300013
         SPACE 2                                                        15600013
*EXITS-NORMAL:                                                          15900013
         SPACE 1                                                        16200013
*   TO IERRC9                      EXIT TO: IERRC9                      16500013
*                                    CALLING SEQUENCE-                  16800013
*                                      BR   RO         RETURN           17100013
         SPACE 2                                                        17400013
*EXITS-ERROR:                                                           17700013
         SPACE 1                                                        18000013
*   NONE                                                                18300013
         SPACE 2                                                        18600013
*TABLES/WORK AREAS:                                                     18900013
         SPACE 1                                                        19200013
*   WAREA-WORK AREA                                                     19500013
         SPACE 2                                                        19800013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   20100013
         SPACE 2                                                        20400013
*NOTES- THIS MODULE WILL EXECUTE FOR ANY FIXED LENGTH SORT WITHOUT      20700013
*   EXITS E15 AND E16. THE INPUT RCD MUST BE GREATER THAN 256 BYTES.    21000013
         EJECT                                                          21300013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            21600013
         SPACE 1                                                        21900013
RA       EQU   0                   CONTENTS IN- N/A                     22200013
*                                  USE- LOAD TO NO.OF BUFFERS AND       22500013
*                                    BUFFER SIZE FOR BUILD MACRO        22800013
*                                  CONTENTS OUT- N/A                    23100013
RB       EQU   1                   CONTENTS IN- N/A                     23400013
*                                  USE- ADDR OF INPUT BUFFER POOL FOR   23700013
*                                    BUILD MACRO                        24000013
*                                  CONTENTS OUT- N/A                    24300013
RC       EQU   2                   CONTENTS IN- N/A                     24600013
*                                  USE- ADDR OF RSA TABLE IN IERRDC     24900013
*                                  CONTENTS OUT- N/A                    25200013
RD       EQU   3                   CONTENTS IN- N/A                     25500013
*                                  USE- COUNTER FOR NO. OF RSA AREAS    25800013
*                                  CONTENTS OUT- N/A                    26100013
RE       EQU   4                   CONTENTS IN- N/A                     26400013
*                                  USE- WORK REGISTER                   26700013
*                                  CONTENTS OUT- N/A                    27000013
RF       EQU   5                   CONTENTS IN- N/A                     27300013
*                                  USE- PTR TO THE TABLE OF RSA ADDRS   27600013
*                                    IN PPI                             27900013
*                                  CONTENTS OUT- N/A                    28200013
RG       EQU   6                   CONTENTS IN- N/A                     28500013
*                                  USE- INDEX REGISTER                  28800013
*                                     - WORK REGISTER                   29100013
*                                  CONTENTS OUT- N/A                    29400013
RH       EQU   7                   CONTENTS IN- N/A                     29700013
*                                  USE- WORK REGISTER                   30000013
*                                  CONTENTS OUT- N/A                    30300013
RI       EQU   8                   CONTENTS IN- N/A                     30600013
*                                  USE- WORK REGISTER                   30900013
*                                  CONTENTS OUT- N/A                    31200013
RJ       EQU   9                   CONTENTS IN- N/A                     31500013
*                                  USE- NOT USED                        31800013
*                                  CONTENTS OUT- N/A                    32100013
RK       EQU   10                  CONTENTS IN- N/A                     32400013
*                                  USE- IERRDC DSECT BASE REGISTER      32700013
*                                  CONTENTS OUT- N/A                    33000013
RL       EQU   11                  CONTENTS IN- N/A                     33300013
*                                  USE-MODULE BASE REGISTER             33600013
*                                  CONTENTS OUT- N/A                    33900013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   34200013
*                                  USE- NOT USED                        34500013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   34800013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              35100013
*                                  USE-PPI REFERENCES,REG SAVE AREA     35400013
*                                  CONTENTS OUT-ADDR OF PPI             35700013
RO       EQU   14                  CONTENTS IN- IERRC9 RETURN ADDR      36000013
*                                  USE- NOT USED                        36300013
*                                  CONTENTS OUT- IERRC9 RETURN ADDR     36600013
RP       EQU   15                  CONTENTS IN- IERADC ENTRY PT         36900013
*                                  USE- ESTABLISH IERADC BASE REGISTER  37200013
*                                  CONTENTS OUT- N/A                    37500013
         SPACE 2                                                        37800013
*START OF MODULE CODE PROPER:                                           38100013
         SPACE 2                                                        38400013
IERADC   CSECT                                                          38700013
* 582000                                                         A24562 38800019
         USING *,RL                THIS MODULE BASE REGISTER            39000013
         USING IERRDC,RK           BASE REG FOR R.P. DSECT              39300013
         USING IERRCA,RN           PPI BASE REG                         39600013
IERMDA   LR    RL,RP               SET THIS MODULE BASE REGISTER        39900013
         L     RK,PPIDEB+4         SET IERRDC DSECT BASE REGISTER       40200013
         SPACE 2                                                        40500013
*ESTABLISH ALL RECORD STORAGE AREA ADDRESSES AND THEIR RESPECTIVE BYTE  40800013
*   COUNTS AND BUILD RSA TABLE IN IERRDB.                               41100013
         SPACE 1                                                        41400013
         LA    RC,TABLRSA          ADDR OF RSA TABLE IN IERRDC          41700013
         SR    RD,RD                                                    42000013
         SR    RG,RG                                                    42300013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     42600013
         LA    RH,4                4 BYTES FOR TREE ADDRESS             42900013
         AH    RH,PPILEXFF         PLUS SIZE OF ROUNDED EXTRACTED       43200013
*                                    CONTROL FIELDS                     43500013
         L     RF,PPILAB08         PTR TO TABLE OF RSA ADDRS WITH THEIR 43800013
*                                    RESPECTIVE BYTE COUNTS             44100013
ADCRSALP L     RE,0(RG,RF)         STARTING ADDR OF AN RSA AREA         44400013
         AR    RE,RH               EQLS ADDR OF 1ST RCD IN THE RSA AREA 44700013
         ST    RE,0(RG,RC)         STORE IN IERRDC RSA ADDR TABLE       45000013
         L     RE,4(RG,RF)         BYTE COUNT OF THIS RSA AREA          45300013
         ST    RE,4(RG,RC)         STORE IN IERRDC RSA ADDR TABLE       45600013
         LA    RG,8(0,RG)          UPDATE INDEX REG                     45900013
         BCT   RD,ADCRSALP         DECR RSA CTR, LOOP IF MORE RSA AREAS 46200013
         SPACE 1                                                        46500013
*INSERT INPUT DCB ADDR IN IERRDC. BUILD INPUT BUFFERS.                  46800013
         SPACE 1                                                        47100013
         L     RG,PPISTDCB         SET INPUT DCB ADDRS IN RUN PROG      47400013
         L     RE,0(RG)                                                 47700013
         ST    RE,KADCB                                                 48000013
         SPACE 1                                                        48300013
         L     RB,PPILAB02         ADDR OF INPUT BUFFER POOL ADDR TABLE 48600013
         MVC   WAREA+2(2),PPILAB03+2                                    48900013
         MVC   WAREA+1(1),PPILAB03                                      49200013
         L     0,WAREA             SET NO. OF BUFFERS AND BUFFER SIZE   49500013
*                                  IN REG 0                             49800013
         SPACE 2                                                        50100013
         BUILDS (1),(0)            BUILD INPUT BUFFERS                  50400013
         SPACE 1                                                        50700013
         SPACE 1                                                        51000013
*INTERFACE TO IERRC9                                                    51300013
         SPACE 1                                                        51600013
         BR    RO                  RETURN                               51900013
         SPACE 2                                                        52200013
*LIST OF WORK AREAS:                                                    52500013
         SPACE 1                                                        52800013
WAREA    DC    F'0'                                                     53100013
         EJECT                                                          53400013
IERRDC   DSECT ,                   DUMMY RUNNING PROGRAM                53700013
         USING *,RL                THIS MODULE BASE REGISTER            54000013
         USING IERRCA,RN                                                54300013
IERDD1   B     RDC1050             ENTRY FROM SORT NETWORK. G RECORDS   54600013
*                                    ARE IN THE TREE(ONCE ONLY)         54900013
         B     RDC1060             ENTRY FROM EOF ROUTINE               55200013
         SPACE 2                                                        55500013
*NORMAL ENTRY FROM NETWORK WHILE FILLING TREE, ENTRY FROM ALGORITHM ON  55800013
*   OUTPUT EOS, NORMAL ENTRY FROM BLOCK WHILE RUNNING.                  56100013
         SPACE 1                                                        56400013
RDC1010  L     RH,ADCONPTR         LOAD RSA TABLE POINTER. THIS INSTR   56700013
*                                    WILL BE OVLAYED BY B RDB1020 AFTER 57000013
*                                    RSA IS FILLED WITH G+1 RCDS AND    57300013
*                                    BY A BR TO THE NTWK AFTER EOF.     57600013
         L     RD,0(RH)            ADDR OF AREA IN RSA FOR INPUT RCD    57900013
         L     RI,4(RH)            REMAINING BYTE COUNT OF RSA   A24562 58200019
RDC1020  L     RG,KADCB            ADDR OF THE INPUT DCB                58500013
         GET   (RG)                                                     58800013
         SPACE 1                                                        59100013
*GET RETURNS ADDR OF RCD IN INPUT BUFFER IN RB.                         59400013
         SPACE 1                                                        59700013
RDCRTRN  S     RI,PPIBINSZ         SUBTRACT BINSIZE FROM RSA BYTE COUNT 60000013
*                                    THIS WILL BE OVLAYED BY B RDLOADRC 60300013
*                                    AFTER G+1 RCDS                     60600013
         BM    RDNEWRSA            BR IF MINUS-RCD CANT FIT IN THIS RSA 60900013
RDCOVLAY BC    0,RDCLAST           WILL BE A BR AFTER TREE HAS G RCDS.  61200013
         SPACE 2                                                        61500013
*LINK TO MOVE LIST WHICH MOVES THE RECORD FROM THE INPUT BUFFER TO RSA. 61800013
*INPUT BUFFER RCD ADDR IN RE. RSA RCD ADDR IN RF                        62100013
         SPACE 1                                                        62400013
RDLOADRF LR    RF,RD               ADDR IN RSA TO MOVE INPUT RCD        62700013
         LR    RE,RB               INPUT RCD ADDR                       63000013
         L     RP,PPIBDSVA+4       ADDR OF MOVE LIST                    63300013
         BALR  RO,RP                                                    63600013
         SPACE 2                                                        63900013
*UPDATE RECORD COUNTER. LOAD RC IN CASE WE HAVE EXTRACT ROUTINE         64200013
         SPACE 1                                                        64500013
         LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          64800013
         L     RG,PPICOUNT                                              65100013
         LA    RG,1(RG)            INCR RCD COUNT BY 1                  65400013
         ST    RG,PPICOUNT                                              65700013
         SPACE 2                                                        66000013
*UPDATE RSA TABLE PARAMETERS                                            66300013
         SPACE 1                                                        66600013
RDC1040  LR    RF,RD               ADDR OF RCD IN RSA. WILL BE OVLAYED  66900013
*                                    BY BR TO NETWORK AFTER G+1 RCDS.   67200013
         A     RF,PPIBINSZ         UPDATE RSA ADDR TO NEXT BIN          67500013
         ST    RF,0(0,RH)          STORE IN RSA TABLE                   67800013
         ST    RI,4(0,RH)          STORE THIS RSA REMAINING BYTE COUNT  68100013
         SPACE 1                                                        68400013
*INTERFACE WITH SORT NETWORK DURING FILL OF TREE.                       68700013
         SPACE 1                                                        69000013
         L     RL,PPINET+4         ADDR OF NETWORK                      69300013
         B     4(RL)               BR TO FILL TREE                      69600013
         SPACE 2                                                        69900013
*UPDATE POINTER TO NEXT ENTRY IN RSA TABLE(EQUALS NEXT RSA AREA)        70200013
         SPACE 1                                                        70500013
RDNEWRSA LA    RH,8(0,RH)          UPDATE PTR                           70800013
         ST    RH,ADCONPTR         SAVE UPDATED PTR                     71100013
         L     RD,0(RH)            NEW RSA RCD ADDR                     71400013
         L     RI,4(RH)            COUNT OF THIS NEW RSA                71700013
         B     RDCRTRN             BR TO PROCESS THE INPUT RCD          72000013
         SPACE 2                                                        72300013
         SPACE 2                                                        72600013
*SORT TREE HAS BEEN FILLED.  IN FUTURE ENTRIES TO THIS MODULE, RD WILL  72900013
*POINT TO THE WINNER RECORD IN RSA.  THE NEW RECORD WHICH HAS BEEN      73200013
*DEBLOCKED MUST BE MOVED TO THE LOCATION IN RSA INDICATED BY RD.  ALSO, 73500013
*THIS MODULE MUST NOW ENTER THE SORT NETWORK AT 12(RL).       THE       73800013
*FOLLOWING CODE MODIFIES THIS MODULE TO EFFECT THESE NEW REQUIREMENTS.  74100013
         SPACE 1                                                        74400013
RDC1050  MVI   RDCOVLAY+1,X'F0'    MAKE THE INSTR A DIRECT BRANCH       74700013
         B     RDC1010             BR TO PROCESS THE G+1 RCD            75000013
         SPACE 2                                                        75300013
RDCLAST  MVC   RDC1010(4),KMOD1                                         75600013
         MVC   RDCRTRN(4),KMOD2                                         75900013
         MVC   RDC1040(8),KMOD3                                         76200013
         B     RDLOADRF            BR TO MOVE G+1 RCD TO RSA            76500013
         SPACE 2                                                        76800013
*WHEN EOF HAS BEEN REACHED, THERE ARE NO MORE RECORDS TO BE DEBLOCKED   77100013
*BUT THE SORT NETWORK MUST EMPTY ITS TREE.  FUTURE ENTRIES TO THIS      77400013
*MODULE DO NO PROCESSING, BUT MERELY EXIT TO THE SORT NETWORK AT        77700013
*16(RL).  THE FOLLOWING CODING MODIFIES THE PRESENT ENTRY POINT TO      78000013
*EFFECT THIS CHANGE AND THEN EXITS TO THE SORT NETWORK AT 8(RL), THE    78300013
*EOF ENTRY.                                                             78600013
         SPACE 1                                                        78900013
RDC1060  MVC   RDC1010(8),KMOD4    BR DIRECTLY TO SORT NETWORK          79200013
         SPACE 2                                                        79500013
*INTERFACE TO SORT NETWORK ON EOF.                                      79800013
         SPACE 1                                                        80100013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 80400013
         B     8(RL)                                                    80700013
         SPACE 2                                                        81000013
*ADCONS USED BY THE MODULE:                                             81300013
         SPACE 1                                                        81600013
ADCONPTR DC    A(TABLRSA)                                               81900013
         SPACE 2                                                        82200013
*CONSTANTS USED BY THE MODULE:                                          82500013
         SPACE 1                                                        82800013
KMOD1    B     RDC1020             OVERLAY RDC1010 AFTER G+1 RCDS       83100013
KMOD2    B     RDLOADRF            OVERLAY RDCRTRN AFTER G+1 RCDS       83400013
KMOD3    L     RL,PPINET+4         OVERLAY RDC1040 AFTER G+1 RCDS       83700013
         B     12(RL)                NORMAL BR TO THE NETWORK           84000013
KMOD4    L     RL,PPINET+4         OVERLAY RDC1010 AFTER INPUT EOF.     84300013
         B     16(RL)                FLUSH BRANCH TO NETWORK            84600013
KADCB    DC    F'0'                INPUT DCB ADDR LOADED BY A.P.        84900013
         SPACE 2                                                        85200013
*LIST OF WORK AREAS/TABLES:                                             85500013
         SPACE 1                                                        85800013
TABLRSA  DC    10F'0'              SPACE AVAILABLE FOR 5 NON-CONTIGUOUS 86100013
*                                    RSA ENTRIES.EACH ENTRY 8 BYTES.    86400013
*                                    4 BYTES-ADDR IN BIN TO MOVE RCD    86700013
*                                    4 BYTES-REMAINING BYTE COUNT OF    87000013
*                                      THIS RSA.                        87300013
*                                    THIS TABLE INITIALIZED BY IERADD   87600013
         EJECT                                                          87900013
         SMPPI                                                          88200013
         END                                                            88500013
