         TITLE '      IERADD - OS/360 SORT/MERGE - 360S-SM023 05/08/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERADD ***                                             00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 000                                                01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSGNMT MOD. F.L. W/E15 AND/OR E16  01400013
*   THE FUNCTION OF THIS MODULE IS TO INITIALIZE A RECORD STORAGE AREA  01600013
*   TABLE IN IERRDD. THIS TABLE WOULD CONSIST OF UP TO 5 ENTRIES FOR    01800013
*   5 NON-CONTIGUOUS RSA'S. THIS MODULE BUILDS THE INPUT BUFFER(S)      02000013
*   IT ALSO CHECKS TO SEE WHETHER WE ARE ATTACHED,WHETHER E15 AND E16   02200013
*   ARE ACTIVATED AND OVERLAYS IERRDD IN APPROPRIATE PLACES. IT ALSO    02400013
*   PASSES IERRDD THE STARTING ADDRESS OF THE INPUT DCB.                02600013
         SPACE 2                                                        02800013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               03000013
         SPACE 1                                                        03200013
*   NONE                                                                03400013
         SPACE 2                                                        03600013
*LIST OF MACROS USED BY MODULE:                                         03800013
         SPACE 1                                                        04000013
*   SMPPI                                                               04200013
*   BUILD                                                               04400013
         SPACE 2                                                        04600013
*ENTRY POINTS:                                                          04800013
         SPACE 1                                                        05000013
*   FROM  IERRC9                   ENTRY FROM:IERRC9                    05200013
*                                    CALLING SEQUENCE-                  05400013
*                                      LOAD EP=IERADD,DCB=SORTLIB       05600013
*                                      LR   RP,RA                       05800013
*                                      BALR RO,RP                       06000013
         SPACE 2                                                        06200013
*INPUT: - PPI FIELDS REFERENCED                                         06400013
         SPACE 1                                                        06600013
*   PPIDEB     PPILAB08   PPINMAX                                       06800013
*   PPILAB03   PPILEXFF   PPIATP1E                                      07000013
*   PPILAB06   PPIMODEX   PPISTDCB                                      07200013
         SPACE 1                                                        07400013
*   INFO IS NEEDED TO BUILD RSA TABLE IN IERRDD,TO BUILD THE INPUT      07600013
*   BUFFER(S),TO SEE WHAT USER EXITS ARE ACTIVATED                      07800013
         SPACE 2                                                        08000013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            08200013
         SPACE 1                                                        08400013
*   NONE                                                                08600013
         SPACE 2                                                        08800013
*EXTERNAL ROUTINES:                                                     09000013
         SPACE 1                                                        09200013
*   NONE                                                                09400013
         SPACE 2                                                        09600013
*EXTERNAL PARAMETERS:                                                   09800013
         SPACE 1                                                        10000013
*   SEE REGISTERS                                                       10200013
         SPACE 2                                                        10400013
*EXITS-NORMAL:                                                          10600013
         SPACE 1                                                        10800013
*   TO  IERRC9                     EXIT TO:IERRC9                       11000013
*                                    CALLING SEQUENCE-                  11200013
*                                      BR   RO         RETURN           11400013
         SPACE 2                                                        11600013
*EXITS-ERROR:                                                           11800013
         SPACE 1                                                        12000013
*   NONE                                                                12200013
         SPACE 2                                                        12400013
*TABLES/WORK AREAS:                                                     12600013
         SPACE 1                                                        12800013
*   WAREA-WORK AREA                                                     13000013
         SPACE 2                                                        13200013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   13400013
         SPACE 2                                                        13600013
*NOTES:THIS MODULE WILL EXECUTE FOR ANY FIXED LENGTH SORT HAVING        13800013
*   USER EXITS E15 AND/OR E16, OR ATTACHED                              14000013
         EJECT                                                          14200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            14400013
         SPACE 1                                                        14600013
RA       EQU   0                   CONTENTS IN- N/A                     14800013
*                                  USE- NO. OF BUFFERS AND BUFFER SIZE  15000013
*                                    FOR BUILD MACRO                    15200013
*                                  CONTENTS OUT- N/A                    15400013
RB       EQU   1                   CONTENTS IN- N/A                     15600013
*                                  USE- ADDR OF INPUT BUFFER POOL FOR   15800013
*                                    BUILD MACRO                        16000013
*                                  CONTENTS OUT- N/A                    16200013
RC       EQU   2                   CONTENTS IN- N/A                     16400013
*                                  USE- ADDR OF RSA TABLE IN IERRDC     16600013
*                                  CONTENTS OUT- N/A                    16800013
RD       EQU   3                   CONTENTS IN- N/A                     17000013
*                                  USE- COUNTER FOR NO. OF RSA AREAS    17200013
*                                  CONTENTS OUT- N/A                    17400013
RE       EQU   4                   CONTENTS IN- N/A                     17600013
*                                  USE- WORK REGISTER                   17800013
*                                  CONTENTS OUT- N/A                    18000013
RF       EQU   5                   CONTENTS IN- N/A                     18200013
*                                  USE- ADDR OF RSA TABLE IN PPI        18400013
*                                  CONTENTS OUT- N/A                    18600013
RG       EQU   6                   CONTENTS IN- N/A                     18800013
*                                  USE- INDEX REGISTER                  19000013
*                                  CONTENTS OUT- N/A                    19200013
RH       EQU   7                   CONTENTS IN- N/A                     19400013
*                                  USE- WORK REGISTER                   19600013
*                                  CONTENTS OUT- N/A                    19800013
RI       EQU   8                   CONTENTS IN- N/A                     20000013
*                                  USE- NOT USED                        20200013
*                                  CONTENTS OUT- N/A                    20400013
RJ       EQU   9                   CONTENTS IN- N/A                     20600013
*                                  USE- NOT USED                        20800013
*                                  CONTENTS OUT- N/A                    21000013
RK       EQU   10                  CONTENTS IN-N/A                      21200013
*                                  USE- IERRDD DSECT BASE REGISTER      21400013
*                                  CONTENTS OUT- N/A                    21600013
RL       EQU   11                  CONTENTS IN- N/A                     21800013
*                                  USE-MODULE BASE REGISTER             22000013
*                                  CONTENTS OUT- N/A                    22200013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   22400013
*                                  USE- NOT USED                        22600013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   22800013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              23000013
*                                  USE-PPI REFERENCES,REG SAVE AREA     23200013
*                                  CONTENTS OUT-ADDR OF PPI             23400013
RO       EQU   14                  CONTENTS IN- IERRC9 RETURN ADDR      23600013
*                                  USE- NOT USED                        23800013
*                                  CONTENTS OUT- IERRC9 RETURN ADDR     24000013
RP       EQU   15                  CONTENTS IN- IERADD ENTRY PT         24200013
*                                  USE- ESTABLISH IERADD BASE REGISTER  24400013
*                                  CONTENTS OUT- N/A                    24600013
         SPACE 2                                                        24800013
*START OF MODULE CODE PROPER:                                           25000013
         SPACE 2                                                        25200013
IERADD   CSECT                                                          25400013
         USING *,RL                THIS MODULE BASE REGISTER            25600013
         USING IERRDD,RK           BASE REG FOR R.P. DSECT              25800013
         USING IERRCA,RN           PPI BASE REG                         26000013
IERMDA   LR    RL,RP                                                    26200013
         L     RK,PPIDEB+4                                              26400013
         SPACE 2                                                        26600013
*ESTABLISH ALL RECORD STORAGE AREA ADDRESSES AND THEIR RESPECTIVE BYTE  26800013
*   COUNTS AND BUILD RSA TABLE IN IERRDD.                               27000013
         SPACE 1                                                        27200013
         LA    RC,TABLRSA          ADDR OF RSA TABLE IN IERRDD.         27400013
         SR    RD,RD                                                    27600013
         SR    RG,RG                                                    27800013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     28000013
         LA    RH,4                4 BYTES FOR TREE ADDRESS             28200013
         AH    RH,PPILEXFF         PLUS SIZE OF ROUNDED EXTRACTED       28400013
*                                    CONTROL FIELDS                     28600013
         L     RF,PPILAB08         PTR TO TABLE OF RSA ADDRS WITH THEIR 28800013
*                                    RESPECTIVE BYTE COUNTS             29000013
ADDRSALP L     RE,0(RG,RF)         STARTING ADDR OF AN RSA AREA         29200013
         AR    RE,RH               EQLS ADDR OF 1ST RCD IN THE RSA AREA 29400013
         ST    RE,0(RG,RC)         STORE IN IERRDD RSA ADDR TABLE       29600013
         L     RE,4(RG,RF)         BYTE COUNT OF THIS RSA AREA          29800013
         ST    RE,4(RG,RC)         STORE IN IERRDD RSA ADDR TABLE       30000013
         LA    RG,8(0,RG)          UPDATE INDEX REG                     30200013
         BCT   RD,ADDRSALP         DECR RSA CTR, LOOP IF MORE RSA AREAS 30400013
         SPACE 1                                                        30600013
         CLC   PPIATP1E,KZERO      TEST IF ATTACHED EXIT                30800013
         BC    7,ADBYPSB           YES, BYPASS BUILD MACRO              31000013
         SPACE 1                                                        31200013
* SET UP AND BUILD THE INPUT BUFFER(S)                                  31400013
         SPACE 1                                                        31600013
         L     RB,PPILAB02         ADDR OF INPUT BUFFER POOL ADDR TABLE 31800013
         MVC   WAREA+2(2),PPILAB03+2  SIZE OF INPUT BFR(S)              32000013
         MVC   WAREA+1(1),PPILAB03   NO. OF INPUT BFR(S)                32200013
         L     0,WAREA             NO. AND SIZE OF BFR(S) IN BYTES      32400013
         SPACE 1                                                        32600013
         BUILDS (1),(0)            BUILD INPUT BUFFER(S)                32800013
         SPACE 1                                                        33000013
* CALCULATE ADDR OF DCB AND STORE IN R.P.                               33200013
         SPACE 1                                                        33400013
ADBYPSB  L     RE,PPISTDCB         POINTER TO LIST OF DCB ADDRESSES     33600013
         MVC   WDCB,0(RE)          STORE DCB ADDR IN R.P.               33800013
         SPACE 1                                                        34000013
         TM    PPIMODEX,X'20'      TEST IF NMAX EXIT ACTIVATED          34200013
         BC    1,ADSTONMX          YES,BR TO STORE NMAX IN R.P.         34400013
         MVC   RDTSTNMX(4),K3      OVERLAY NMAX TEST,INSERT RTN OF R.P. 34600013
         MVC   RDOVLAY4(4),K4      OVERLAY NMAX TEST,DO NOTHG,ETC R.P.  34800013
ADTSTATT CLC   PPIATP1E,KZERO      TEST IF ATTACHED EXIT                35000013
         BC    7,ADATTEXT          YES, BR TO ATTACH EXIT RTN           35200013
         TM    PPIMODEX,X'40'      TEST IF ANY USER RCD MODIFICATIONS   35400013
         BC    1,ADENDMOD          YES, BR TO LINK TO NEXT RTN          35600013
         MVC   RDUSREXT,RDOVLAY4   OVERLAY USER EXIT E15 WITH A BRANCH  35800013
*                                    TO DO NOTHING RTN IN R.P.          36000013
         MVI   WUSREOF,X'01'       SET USER EXIT E15 EOF SWITCH         36200013
         SPACE 1                                                        36400013
*INTERFACE TO IERRC9                                                    36600013
         SPACE 1                                                        36800013
ADENDMOD BR    RO                  RETURN                               37000013
         SPACE 2                                                        37200013
ADATTEXT MVC   PPIX15+4(4),PPIATP1E R.P. EXIT E15 NOW LINKS TO ATTACH   37400013
*                                    RTN                                37600013
         MVI   WSYSEOF,X'01'       TURN ON SYSTEM EOF SWITCH            37800013
         MVC   RDTSTISW(4),K5      OVLAY INSERT SWITCH TEST IN R.P.     38000013
         B     ADENDMOD            BR TO LINK TO NEXT RTN               38200013
         SPACE 2                                                        38400013
ADSTONMX L     RE,PPINMAX          LOAD NMAX                            38600013
         LA    RE,1(0,RE)          EQUALS NMAX + 1 (TO ALLOW BCT INSTR  38800013
*                                    IN R.P. TO DECR NMAX CTR)          39000013
         ST    RE,PPINMAX                                               39200013
         B     ADTSTATT            BR TO TEST IF ATTACHED               39400013
         SPACE 1                                                        39600013
         SPACE 2                                                        39800013
* LIST OF CONSTANTS USED BY THE MODULE                                  40000013
KZERO    DC    F'0'                                                     40200013
         SPACE 1                                                        40400013
         SPACE 2                                                        40600013
* LIST OF WORK AREAS                                                    40800013
WAREA    DC    F'0'                                                     41000013
         EJECT                                                          41200013
IERRDD   DSECT ,                   DSECT OF IERRDD                      41400013
         USING *,RL                MODULE BASE REG LOADED EXTERNALLY    41600013
         USING IERRCA,RN           PUT RN IN USING TABLE WITH PPI ADDR  41800013
         USING IERRMA,RO           MESSAGE MODULE ADDR                  42000013
         SPACE 1                                                        42200013
* ENTER BRANCH TABLE FROM REPLACEMENT SORT,0(RL).FROM READ MOD, 4(RL).  42400013
*   OR FROM REPLACEMENT SORT(INITIALLY TO FILL TREE), ALGORITHM(AT THE  42600013
*   END OF A SEQUENCE), BLOCK MODULE(AFTER FILLING TREE), 8(RL).        42800013
IERDD1   B     RDOVLAYF            FROM REPL SORT,FINISHD FILLING TREE  43000013
         B     RDSETSW             FROM READ MOD(GET,ON EOF)            43200013
* FROM REPLACEMT SORT BLOCK MOD,OR ALGORITHM                            43400013
         SPACE 1                                                        43600013
RDNORMAL ST    RD,WINNER           ADDR OF A FREE AREA IN RSA-LAST WNR  43800013
RDLDCTRS STM   RJ,RK,WRJ           SAVE TRANSPARENT REGS                44000013
         LM    RG,RI,PPICOUNT      RESTORE COUNTERS                     44200013
         L     RK,WDCB             RESTORE DCB ADDRESS                  44400013
         L     RJ,PPINMAX          RESTORE NMAX                         44600013
         LTR   RJ,RJ               CHECK FOR 0 OR NMAX                  44800013
         BC    2,RDTSTISW          IF NMAX PLUS CONTINUE                45000013
         LA    RJ,1                NMAX MUST BE 1                       45200013
RDTSTISW TM    WINSRTSW,X'01'      TST INSERT SW. WILL BE OVLAYED BY    45400013
*                                    A.P. IF ATTACHED,OR BY R.P. ON     45600013
*                                    SYSTEM EOF,WITH B RDUSREXT         45800013
         BC    1,RDUSREXT          ON, BR TO USER EXIT                  46000013
RDGET    GET   (RK)                UPDATE ADDR IN INPUT AREA(REG RB)    46200013
*                                    REG RK HAS DCB ADDR                46400013
         LA    RG,1(0,RG)          INCR RCD CTR BY ONE                  46600013
         ST    RB,WINPTRCD         SAVE ADDR OF RCD THATS IN INPUT BLK  46800013
         SPACE 1                                                        47000013
* USER MOD EXIT E15 USING CALL MACRO EXPANSION INSTRUCTIONS.            47200013
*   PASS ADDR OF PARAMETER LIST(ADDR OF INPUT RCD) IN REGISTER RB       47400013
         SPACE 1                                                        47600013
RDUSREXT LA    RB,WINPTRCD         ADDR OF PARAMETER LIST. IF E15 NOT   47800013
*                                    ACTIVATED, OR IF ACTIVATED AND HIT 48000013
*                                    USER EOF,THIS INSTR WILL BE OVLAYD 48200013
*                                    BY B RDALSHNO                      48400013
         L     RP,PPIX15+4         ADDR OF USER EXIT E15. IF ATTACHED   48600013
*                                    A.P. WILL LOAD PPIX15 WITH ADDR IN 48800013
*                                    PPIATP1E                           49000013
         BALR  RO,RP               BR TO USER                           49200013
         SPACE 1                                                        49400013
* USER RETURNS TO MODULE VIA RETURNREG AND PROPER DISPLACEMENTS. USER   49600013
*   PASSES ADDR OF RECORD TO BE INSERTED OR ADDR OF WORK AREA IF HE     49800013
*   ALTERS,LENGTHENS,OR SHORTENS A RCD IN REG RB.                       50000013
         SPACE 1                                                        50200013
         B     *+4(15)                                                  50400013
RDOVLAY4 B     RDALSHNO            ALTER,LENGTHN,SHORTN,DO NOTHING      50600013
*                                    WILL BE OVERLAYED BY K4 IF,WHEN    50800013
*                                    REACH NMAX IT IS IGNORED, OR BY    51000013
*                                    A.P. WITH K4 IF EXIT NOT ACTIVE    51200013
         B     RDDELETE            DELETE A RCD                         51400013
         B     RDUSREOF            USER END OF FILE                     51600013
         SPACE 1                                                        51800013
* INSERT A RECORD                                                       52000013
         SPACE 1                                                        52200013
RDTSTNMX BCT   RJ,RDISWON          DECR NMAX CTR BY ONE AND TEST TO     52400013
*                                    SEE IF REACHED NMAX                52600013
*                                    WILL BE OVERLAYED BY K3 IF, WHEN   52800013
*                                    REACH NMAX IT IS IGNORED, OR BY    53000013
*                                    A.P. WITH K3 IF EXIT NOT ACTIVE    53200013
         B     RDWSW1ON            YES,BR TO NMAX USER EXIT E16,SW ON   53400013
         SPACE 2                                                        53600013
* SYSTEM END OF FILE ROUTINE                                            53800013
         SPACE 1                                                        54000013
RDSETSW  OI    WSYSEOF,X'01'       SET SYSTEM EOF SWITCH                54200013
         SR    RB,RB               CLEAR INPUT RCD PARAM REG            54400013
         MVC   RDTSTISW,K5         TO BYPASS GOING TO GET AFTER SYS EOF 54600013
         TM    WUSREOF,X'01'       TEST IF USER EOF SWITCH ON           54800013
         BC    1,RDCNTSRT          YES,BR TO EOF FLUSH RTN              55000013
         B     RDUSREXT-4          NO, BR TO USER                       55200013
         SPACE 2                                                        55400013
* USER END OF FILE ROUTINE                                              55600013
         SPACE 1                                                        55800013
RDUSREOF OI    WUSREOF,X'01'       SET USER EOF SWITCH                  56000013
         MVC   RDUSREXT,RDOVLAY4   OVLAY USER EXIT-BYPASS EXIT E15      56200013
         TM    WSYSEOF,X'01'       TEST IF SYSTEM EOF SWITCH ON         56400013
         BC    1,RDCNTSRT          YES,BR TO EOF FLUSH RTN              56600013
         L     RB,WINPTRCD         RESTORE ADDR OF RCD IN INPUT BLK     56800013
         B     RDALSHNO            BR TO SORT THIS RCD                  57000013
         SPACE 2                                                        57200013
RDISWON  OI    WINSRTSW,X'01'      TURN INSERT SWITCH ON                57400013
         LA    RI,1(0,RI)          INCR INSERT CTR BY ONE               57600013
RDSTM    STM   RG,RI,PPICOUNT      SAVE COUNTERS                        57800013
         ST    RJ,PPINMAX          SAVE NMAX CTR                        58000013
         SPACE 1                                                        58200013
* INITALIZE AND BR TO MOVE RTN TO MOVE NEXT INPUT RCD TO RSA            58400013
         SPACE 1                                                        58600013
RDOVLAY5 B     RDDLDRSA            BR TO GET ADDR IN RSA TO MOVE RCD    58800013
*                                    WILL BE OVLAYED BY L RF,WINNER     59000013
*                                    AFTER G+1 RCDS                     59200013
RDDLDRE  LR    RE,RB               ADDR OF RCD IN INPUT BUFFER OR FROM  59400013
*                                    USER'S WORK AREA                   59600013
         L     RP,PPIBDSVA+4       ADDR OF MOVE RTN IN GENERATED CORE   59800013
         BALR  RO,RP               BR TO MOVE RTN.MOVE RCD TO RSA       60000013
RDOVLAY6 B     RDFILLTR            BR TO SORT NETWORK FILLING TREE RTN  60200013
*                                    WILL BE OVLAYED BY NOP AFTER       60400013
*                                    TREE IS INITIALLY FILLED           60600013
         SPACE 2                                                        60800013
* NORMAL EXIT TO SORT NETWORK AFTER PREVIOUS INSTR IS OVERLAYED BY NOP  61000013
         SPACE 1                                                        61200013
         LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          61400013
         L     RD,WINNER                                                61600013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 61800013
         B     12(RL)              BR TO SORT NETWORK NORMAL RTN        62000013
         SPACE 2                                                        62200013
* EXIT TO SORT NETWORK WHILE FILLING TREE                               62400013
         SPACE 1                                                        62600013
RDFILLTR LR    RC,RB               ADDR OF RCD IN INPUT BUFFER          62800013
         A     RD,PPIBINSZ         UPDATE TO NEXT BIN IN THIS RSA       63000013
         ST    RD,0(0,RK)          SAVE IN RSA TABLE                    63200013
         S     RD,PPIBINSZ         RESTORE FOR NETWORK. ADDR OF THIS    63400013
*                                    RCD IN RSA                         63600013
         L     RL,PPINET+4         ADDR OF NETWORK                      63800013
         B     4(RL)               BR TO SORT NETWORK FILL TREE RTN     64000013
         SPACE 2                                                        64200013
         SPACE 2                                                        64400013
* FINISHED FILLING TREE RTN -ONE TIME RTN                               64600013
         SPACE 1                                                        64800013
RDOVLAYF NI    RDOVLAY6+1,X'00'    NOP THE BR INSTR TO THE FILLING EXIT 65000013
         MVI   RDDOVLAY+1,X'F0'    OVLAY INSTR IN RSA TABLE ROUTINE     65200013
         B     RDLDCTRS            BR TO GET G+1 RECORD.                65400013
         SPACE 2                                                        65600013
*RSA TABLE ROUTINE USED DURING FILLING OF TREE. ENTER HERE ONLY THROUGH 65800013
*   G+1 RECORDS.                                                        66000013
         SPACE 1                                                        66200013
RDDLDRSA L     RK,ADCONPTR         RSA TABLE PTR                        66400013
RDDRTRN  LM    RD,RE,0(RK)         RD=ADDR IN THIS RSA,RE=REMAINING     66600013
*                                    BYTE COUNT OF THIS RSA.            66800013
         S     RE,PPIBINSZ         SUBTR SIZE OF THIS RCD               67000013
         BM    RDNEWRSA            BR IF MINUS-RCD CANT FIT IN THIS     67200013
RDDOVLAY BC    0,RDDLAST           WILL BE A BR AFTER RSA HAS G RCDS    67400013
         SPACE 2                                                        67600013
         ST    RE,4(0,RK)          SAVE REMAING BYTE COUNT OF THIS RSA  67800013
         LR    RF,RD               ADDR IN RSA TO MOVE THE RCD          68000013
         B     RDDLDRE             BR TO MOVE RCD TO RSA                68200013
         SPACE 2                                                        68400013
RDNEWRSA LA    RK,8(0,RK)          UPDATE RSA TABLE PTR TO NEXT RSA     68600013
*                                    ENTRY(NEXT NON-CONTIGUOUS RSA)     68800013
         ST    RK,ADCONPTR         SAVE UPDATED PTR                     69000013
         B     RDDRTRN             BR TO USE THIS RSA                   69200013
         SPACE 2                                                        69400013
*WE ARE GOING TO PROCESS THE G+1 RECORD.                                69600013
         SPACE 1                                                        69800013
RDDLAST  ST    RD,WINNER           ADDR IN RSA TO MOVE RCD              70000013
         MVC   RDOVLAY5(4),K1      OVLAY BRANCH INSTR TO RSA TABLE RTN  70200013
         B     RDOVLAY5            BR TO MOVE G+1 RCD TO RSA.           70400013
         SPACE 2                                                        70600013
* FROM USER,ON NMAX RETURN,TO SORT CURRENT NO OF RCDS ONLY              70800013
         SPACE 1                                                        71000013
RDSETPPI OI    PPISW1+3,X'02'      TURN ESTIMATED FILE SWITCH ON IN PPI 71200013
         TM    WSYSEOF,X'01'       WAS SYSTEM EOF REACHED               71400013
         BC    1,RDCNTSRT          YES,BR AROUND NEXT INSTRS-FLUSH TREE 71600013
         BCTR  RG,0                DECR PPICOUNT BY ONE                 71800013
         SPACE 1                                                        72000013
* FROM GET ON END OF FILE                                               72200013
RDCNTSRT MVC   RDNORMAL,K2         OVERLAY DEBLOCK MODULE               72400013
         STM   RG,RI,PPICOUNT      SAVE COUNTERS                        72600013
         L     RL,PPINET+4         ADDR OF NTWK                         72800013
         B     8(RL)               BR TO NTWK TO EMPTY TREE             73000013
         SPACE 2                                                        73200013
RDEMPTYT L     RL,PPINET+4         ADDR OF NTWK                         73400013
         B     16(RL)              BR TO SORT TO CONTINUE EMPTYING TREE 73600013
         SPACE 2                                                        73800013
* WRITE MESSAGE NMAX EXCEEDED                                           74000013
         SPACE 1                                                        74200013
RDWSW1ON OI    WSW1,X'01'          TURN SWITCH 1 ON                     74400013
RDMSGS   L     RD,PPIRMA+4         ADDR OF MESSAGE MODULE               74600013
         LR    RE,RB               SAVE ADDR OF NMAX+1 RCD              74800013
         LM    RA,RB,MSGP1A04      NAME AND LENGTH OF MESSAGE           75000013
         L     RP,PPIADSSC         LOAD PRINT RTN ADDR                  75200013
         BAL   RO,12(0,RP)         BR TO PRINT RTN                      75400013
         SPACE 1                                                        75600013
* USER EXIT E16 -SORT CAPACITY, NMAX, HAS BEEN REACHED                  75800013
*   CALL MACRO INSTRUCTION EXPANSION                                    76000013
         SPACE 1                                                        76200013
         LR    RB,RE               RESTORE ADDR OF NMAX+1 RCD           76400013
         L     RP,PPIX16+4         ADDR OF NMAX EXIT                    76600013
         BALR  RO,RP               BR TO USER                           76800013
         SPACE 2                                                        77000013
* USER RETURNS TO MODULE VIA RETURNREG AND PROPER DISPLACEMENTS.        77200013
         SPACE 1                                                        77400013
         B     *+4(15)                                                  77600013
         B     RDSETPPI            SORT CURRENT NO OF RCDS ONLY         77800013
         B     RDIGNORE            IGNORE NMAX AND CONTINUE TO SORT     78000013
         SPACE 1                                                        78200013
* ABORT THE JOB. SET UP ABNORMAL END INDICATION FOR SORT SYSTEM CONTROL 78400013
         SPACE 1                                                        78600013
         L     RP,PPIADSSC                                              78800013
         BAL   RO,16(0,RP)         BR TO SORT SYSTEM CONTROL            79000013
         SPACE 1                                                        79200013
* IGNORE NMAX. OVERLAY NMAX TEST WITH A BYPASS BRANCH INSTR.            79400013
         SPACE 1                                                        79600013
RDIGNORE MVC   RDTSTNMX(4),K3      OVERLAY NMAX TEST,INSERT RTN         79800013
         CLC   RDUSREXT,RDOVLAY4   HAS USER EXIT CODE BEEN OVERLAID?    80000013
         BNE   *+10                IF NOT, BRANCH AROUND NEXT INSTRUC   80200013
         MVC   RDUSREXT,K4         CHANGE OVERLAID INSTRUCTION          80400013
         MVC   RDOVLAY4(4),K4      OVERLAY NMAX TEST,DO NOTHG,ALTER RTN 80600013
         TM    WSW1,X'01'          TEST SWITCH 1                        80800013
         BC    1,RDISWON           ON,BR TO TURN INSERT SWITCH ON       81000013
         B     RDISWOFF            BR TO TURN INSERT SWITCH OFF         81200013
         SPACE 2                                                        81400013
* DO NOTHING, ALTER, LENGTHEN, SHORTEN A RCD. ADDR OF INPUT RCD IN RB.  81600013
         SPACE 1                                                        81800013
RDALSHNO BCT   RJ,RDISWOFF         DECR NMAX CTR BY ONE AND TST TO SEE  82000013
*                                    IF REACHED NMAX                    82200013
         B     RDMSGS              YES, BR TO NMAX USER EXIT E16        82400013
         SPACE 2                                                        82600013
RDISWOFF NI    WINSRTSW,X'00'      TURN OFF INSERT SWITCH               82800013
         B     RDSTM               BR TO LOAD ADDR OF FREE AREA IN RSA  83000013
         SPACE 2                                                        83200013
* DELETE A RECORD                                                       83400013
         SPACE 1                                                        83600013
RDDELETE NI    WINSRTSW,X'00'      TURN OFF INSERT SWITCH               83800013
         LA    RH,1(0,RH)          INCR DELETE CTR BY ONE               84000013
         B     RDGET               BR TO GET ANOTHER RECORD             84200013
         SPACE 1                                                        84400013
* END OF CODING --- ADCONS NEXT PAGE                                    84600013
         EJECT                                                          84800013
* LIST OF ADCONS USED BY THE MODULE                                     85000013
         SPACE 1                                                        85200013
ADCONPTR DC    A(TABLRSA)          ADDR OF RSA TABLE                    85400013
* LIST OF CONSTANTS USED BY THE MODULE                                  85600013
         SPACE 1                                                        85800013
K1       L     RF,WINNER           OVERLAY WHEN FINISHED FILLING TREE   86000013
K2       B     RDEMPTYT            OVERLAY TO EMPTYTREE ON GET EOF      86200013
K3       B     RDISWON             BYPASS NMAX TEST IN INSERT RTN       86400013
K4       B     RDISWOFF            BYPASS NMAX TEST IN DO NOTHG,ETC RTN 86600013
K5       B     RDUSREXT            OVERLAY INSERT SW TEST BY A.P. IF    86800013
*                                    ATTACHED                           87000013
         SPACE 2                                                        87200013
* LIST OF WORK AREAS                                                    87400013
         SPACE 1                                                        87600013
WSW1     DC    X'00'               SWITCH 1 IN INSERT RTN               87800013
WINSRTSW DC    X'00'               INSERT SWITCH                        88000013
WUSREOF  DC    X'00'               USER END OF FILE SW. SET BY A.P. IF  88200013
*                                    EXIT E15 IS INACTIVE.              88400013
WSYSEOF  DC    X'00'               SYSTEM END OF FILE SWITCH            88600013
WINNER   DC    F'0'                SORT WINNER RCD ADDR                 88800013
WDCB     DC    F'0'                CONTAINS ADDR OF DCB FOR INPUT FILE  89000013
*                                    LOADED BY ASSIGNMENT ROUTINE       89200013
WRJ      DC    2F'0'               SAVE TRANPARENT REGS                 89400013
WINPTRCD DC    F'0'                ADDR OF RCD IN INPUT AREA            89600013
TABLRSA  DC    10F'0'              SPACE AVAILABLE FOR 5 NON-CONTIGUOUS 89800013
*                                    RSA ENTRIES.EACH ENTRY 8 BYTES.    90000013
*                                    4 BYTES- ADDR IN BIN TO MOVE RCD   90200013
*                                    4 BYTES- REMAINING BYTE COUNT OF   90400013
*                                      THIS RSA.                        90600013
*                                    THIS TABLE INITIALIZED BY IERADD   90800013
         EJECT                                                          91000013
* MODULE NAME ***IERRMA***                                              91200013
*                                                                       91400013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        91600013
* PHASE 1 RUNNING PROGRAM.                                              91800013
         SPACE 1                                                        92000013
IERRMA   DSECT                                                          92200013
       COPY  RMAMAIN                                                    92400013
         EJECT                                                          92600013
         SMPPI                                                          92800013
         END   IERADD                                                   93000013
