         TITLE '      IERADE - OS/360 SORT/MERGE - 360S-SM023 05/08/66' 00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERADE ***                                             00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 000                                                01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMT MODULE. V.L W/E15 &/OR E16 01400013
*   THE FUNCTION OF THIS MODULE IS TO CALCULATE THE NUMBER OF BINS IN   01600013
*   UP TO 5 NON-CONTIGUOUS RECORD STORAGE AREAS AND CHAIN ALL THESE     01800013
*   BINS TOGETHER. IT PUTS THE ADDRESS OF THE FIRST BIN IN THE FIRST    02000013
*   RSA IN AVAIL(PPIBDSVA+4). INPUT BUFFERS ARE SET UP VIA THE BUILD    02200013
*   MACRO. EXTRACT SIZE + 4 IS CALCULATED AND STORED IN THE RUNNING     02400013
*   PROGRAM. EXITS E15 AND E16 ARE TESTED AND A TEST IS MADE TO SEE IF  02600013
*   SORT HAS BEEN ATTACHED. AS A RESULT OF THESE TESTS PROPER OVERLAYS  02800013
*   WILL BE MADE AND NMAX+1 MAY BE STORED IN RUNNING PROGRAM,IERRDE.    03000013
         SPACE 1                                                        03200013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      03400013
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.              03600013
         SPACE 2                                                        03800013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               04000013
         SPACE 1                                                        04200013
*   NONE                                                                04400013
         SPACE 2                                                        04600013
*LIST OF MACROS USED BY MODULE:                                         04800013
         SPACE 1                                                        05000013
*   SMPPI                                                               05200013
*   BUILD                                                               05400013
         SPACE 2                                                        05600013
*ENTRY POINTS:                                                          05800013
         SPACE 1                                                        06000013
*   FROM IERRC9                    ENTRY FROM:IERRC9                    06200013
*                                    CALLING SEQUENCE-                  06400013
*                                      LOAD EP=IERADD,DCB=SORTLIB       06600013
*                                      LR   RP,RA                       06800013
*                                      BALR RO,RP                       07000013
         SPACE 2                                                        07200013
*INPUT: - PPI FIELDS REFERENCED                                         07400013
         SPACE 1                                                        07600013
*   PPINMAX    PPILAB03   PPIMODEX                                      07800013
*   PPIBINSZ   PPILAB06   PPILEXFF                                      08000013
*   PPIATPIE   PPILAB08                                                 08200013
         SPACE 1                                                        08400013
*   ADDRESSES FOR BUFFERS AND TABLES,INFO FOR USER EXITS AND FOR THE    08600013
*   RSA CHAINING ROUTINE AND FOR THE BUILD MACRO                        08800013
         SPACE 2                                                        09000013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            09200013
         SPACE 1                                                        09400013
*   PPIBDSVA                                                            09600013
         SPACE 1                                                        09800013
*   INITIALIZE START OF RSA(AVAIL) AND TOTAL NUMBER OF BINS IN ALL THE  10000013
*   RSA'S.                                                              10200013
         SPACE 2                                                        10400013
*EXTERNAL ROUTINES:                                                     10600013
         SPACE 1                                                        10800013
*   NONE                                                                11000013
         SPACE 2                                                        11200013
*EXTERNAL PARAMETERS:                                                   11400013
         SPACE 1                                                        11600013
*   SEE REGISTERS                                                       11800013
         SPACE 2                                                        12000013
*EXITS-NORMAL:                                                          12200013
         SPACE 1                                                        12400013
*   TO IERRC9                      EXIT TO:IERRC9                       12600013
*                                    CALLING SEQUENCE-                  12800013
*                                      BR   RO         RETURN           13000013
         SPACE 2                                                        13200013
*EXITS-ERROR:                                                           13400013
         SPACE 1                                                        13600013
*   NONE                                                                13800013
         SPACE 2                                                        14000013
*TABLES/WORK AREAS:                                                     14200013
         SPACE 1                                                        14400013
*   WCOMBINE-WORK AREA                                                  14600013
         SPACE 2                                                        14800013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   15000013
         SPACE 2                                                        15200013
*NOTES: THIS MODULE WILL EXECUTE FOR ANY VARIABLE LENGTH SORT HAVING    15400013
*   USER EXITS E15 AND/OR E16, OR ATTACHED                              15600013
         EJECT                                                          15800013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            16000013
         SPACE 1                                                        16200013
RA       EQU   0                   CONTENTS IN-N/A                      16400013
*                                  USE-NO. OF BUFFERS AND BUFFER SIZE   16600013
*                                    FOR BUILD MACRO                    16800013
*                                  CONTENTS OUT-N/A                     17000013
RB       EQU   1                   CONTENTS IN-N/A                      17200013
*                                  USE-ADDR OF INPUT BUFFER POOL FOR    17400013
*                                    BUILD MACRO.                       17600013
*                                  CONTENTS OUT-N/A                     17800013
RC       EQU   2                   CONTENTS IN-N/A                      18000013
*                                  USE-NOT USED                         18200013
*                                  CONTENTS OUT-N/A                     18400013
RD       EQU   3                   CONTENTS IN-N/A                      18600013
*                                  USE-NO. OF RSA AREAS -RSA TABLE CALC 18800013
*                                  CONTENTS OUT-N/A                     19000013
RE       EQU   4                   CONTENTS IN-N/A                      19200013
*                                  USE-WORK REGISTER                    19400013
*                                  CONTENTS OUT-N/A                     19600013
RF       EQU   5                   CONTENTS IN-N/A                      19800013
*                                  USE-NO. OF BYTES COUNTER IN 1 RSA    20000013
*                                  CONTENTS OUT-N/A                     20200013
RG       EQU   6                   CONTENTS IN-N/A                      20400013
*                                  USE-CURRENT BIN ADDR IN AN RSA-USED  20600013
*                                    IN RSA TABLE CALC.                 20800013
*                                  CONTENTS OUT- N/A                    21000013
RH       EQU   7                   CONTENTS IN-N/A                      21200013
*                                  USE-PTR TO RSA TABLE IN PPI-UPDATE   21400013
*                                    FOR EACH RSA.                      21600013
*                                  CONTENTS OUT- N/A                    21800013
RI       EQU   8                   CONTENTS IN- N/A                     22000013
*                                  USE- GENERAL WORK REGISTER           22200013
*                                  CONTENTS OUT-N/A                     22400013
RJ       EQU   9                   CONTENTS IN- N/A                     22600013
*                                  USE-NOT USED                         22800013
*                                  CONTENTS OUT-N/A                     23000013
RK       EQU   10                  CONTENTS IN- N/A                     23200013
*                                  USE-IERRDE DSECT BASE REGISTER       23400013
*                                  CONTENTS OUT-N/A                     23600013
RL       EQU   11                  CONTENTS IN-N/A                      23800013
*                                  USE-MODULE BASE REGISTER             24000013
*                                  CONTENTS OUT-N/A                     24200013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   24400013
*                                  USE-NOT USED                         24600013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   24800013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              25000013
*                                  USE-PPI REFERENCES,REG SAVE AREA     25200013
*                                  CONTENTS OUT-ADDR OF PPI             25400013
RO       EQU   14                  CONTENTS IN-IERRC9 RETURN ADDR       25600013
*                                  USE-NOT USED                         25800013
*                                  CONTENTS OUT-IERRC9 RETURN ADDR      26000013
RP       EQU   15                  CONTENTS IN-IERADE ENTRY PT          26200013
*                                  USE-ESTABLISH IERADE BASE REG        26400013
*                                  CONTENTS OUT-N/A                     26600013
         SPACE 2                                                        26800013
*START OF MODULE CODE PROPER:                                           27000013
         SPACE 2                                                        27200013
IERADE   CSECT                                                          27400013
*                                                                A35520 27500021
         USING *,RL                THIS MODULE BASE REGISTER            27600013
         USING IERRDE,RK           IERRDE DSECT BASE REGISTER           27800013
         USING IERRCA,RN           PPI ADDR                             28000013
IERMDA   LR    RL,RP               ESTABLISH THIS MODULE BASE REGISTER  28200013
         L     RK,PPIDEB+4         ADDR OF IERRDE CSECT                 28400013
         SPACE 2                                                        28600013
*CHAIN ALL BINS TOGETHER BY PUTTING IN EACH BIN THE ADDR OF THE NEXT    28800013
*   AVAILABLE BIN. SAVE THE ADDRESS OF THE 1ST AVAILABLE BIN IN         29000013
*   PPIBDSVA+4,AND THE TOTAL NO. OF AVAILABLE BINS IN PPIBDSVA+8.       29200013
         SPACE 1                                                        29400013
         SR    RD,RD                                                    29600013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     29800013
         L     RH,PPILAB08         PTR TO RSA TABLE IN PPI              30000013
         L     RG,0(0,RH)          ADDR OF THIS RSA AREA BIN            30200013
         ST    RG,PPIBDSVA+4       SAVE THIS ADDR IN AVAIL(FOR IERRDE)  30400013
ADELOOPO L     RF,4(0,RH)          NO. OF BYTES IN THIS RSA AREA        30600013
         C     RF,PPIBINSZ         IS RSA < BINSIZE ?            A35520 30660021
         BL    ADELOOPJ            IF YES BRANCH                 A35520 30720021
         LA    RI,ADELOOPI         LOAD RETURN REG FOR THIS LOOP CALC   30800013
         SR    RE,RE                                                    31000013
         D     RE,PPIBINSZ         RE=NO.OF BINS IN THIS RSA AREA       31200013
         L     RE,PPIBDSVA+8       TOTAL NO.OF BINS IN ALL RSA'S SO FAR 31400013
         AR    RE,RF               UPDATE BIN COUNT                     31600013
         ST    RE,PPIBDSVA+8       SAVE UPDATED BIN COUNT               31800013
ADELOOPI BCT   RF,ADECHAIN         DECR NO. OF BINS CTR FOR THIS RSA.   32000013
*                                    BR IF MORE BINS IN THIS RSA.       32200013
ADELOOPJ BCT   RD,ADNXTRSA         DECR NO. OF RSA'S CTR. BR IF  A35520 32400021
*                                    RSA'S. THE LAST BIN IN LAST RSA    32600013
*                                    HAS NO CHAIN ADDR                  32800013
         A     RF,PPIATP1E         ARE WE ATTACHED                      33000013
         BC    7,ADENOBLD          YES-DON'T BUILD BUFFERS              33200013
         MVC   WCOMBINE+1(1),PPILAB03                                   33400013
         MVC   WCOMBINE+2(2),PPILAB03+2                                 33600013
         L     RA,WCOMBINE         POSITION NO. AND SIZE OF BUFFERS     33800013
         L     RB,PPILAB02         ADDR OF INPUT BUFFER POOL ADDR TABLE 34000013
         BUILDS (1),(0)                                                 34200013
         SPACE 2                                                        34400013
ADENOBLD LH    RE,PPILEXFF         GET EXTRACT SIZE                     34600013
         A     RE,KFOUR                                                 34800013
         STH   RE,EXPLFOUR         STORE EXTRACT SIZE + 4               35000013
         TM    PPIMODEX,X'20'      TEST IF NMAX EXIT ACTIVATED          35200013
         BC    1,ADESTNM           GO STORE NMAX IN R.P.-IT'S ACTIVE    35400013
         MVC   RDEMAXCK(4),K2      OVERLAY NMAX TEST IN INSERT LEG      35600013
         MVC   RDEDONO(4),K3       OVERLAY NMAX TEST IN ALTER LEG       35800013
ADETATT  CLC   PPIATP1E,KZERO      TEST IF ATTACHED                     36000013
         BC    7,ADEATACH          IT IS ATTACHED                       36200013
         TM    PPIMODEX,X'40'      TEST FOR USER RCD MOD EXIT           36400013
         BC    1,ADEEXIT           BRANCH TO EXIT                       36600013
         MVC   RDEUEXIT(4),K4      OVERLAY USER EXIT 15 WITH A BRANCH   36800013
         MVC   RDEMSG(4),K6                                             37000013
         MVI   WUSREOF,X'00'       TURN ON USER EOF SWITCH              37200013
         MVI   RDEISWON,X'58'      CHANGE INSTRUCTION TO L RB,ADRHOLD   37400013
ADEEXIT  L     RE,PPISTDCB         ADDR DCB TABLE                A26453 37440019
         L     RE,0(RE)                                          A26453 37480019
         ST    RE,KAWORK+4         INIT. DCB IN R.P.             A26453 37520019
         TM    PPIMODEX+2,X'02'    VRE IN?                       A26453 37560019
         BZ    ADERETUR            NO...                         A26453 37600019
         L     RE,PPIGETMN         YES...                        A26453 37640019
         L     RE,12(RE)           GET ADDRESS OF VRE WORK       A26453 37680019
         ST    RE,KAWORK           FROM GETMN AND INIT. R.P.     A26453 37720019
ADERETUR BR    RO                  RETURN TO IERRC9              A26453 37760019
         SPACE 2                                                        37800013
ADESTNM  L     RE,PPINMAX          LOAD NMAX                            38000013
         LA    RE,1(0,RE)          PLUS 1 (FOR USING BCT INSTRUCTION)   38200013
         ST    RE,PPINMAX                                               38400013
         B     ADETATT             GO TEST FOR ATTACHED                 38600013
         SPACE 2                                                        38800013
ADEATACH MVC   PPIX15+4(4),PPIATP1E E15 NOW IS ATTACHED                 39000013
         MVI   WINPEOF,X'00'       TURN ON SYSTEM EOF SWITCH            39200013
         MVC   RDENORM(4),K5       OVERLAY INSRT SW TEST-BR ARND GET    39400013
         B     ADEEXIT             BRANCH TO EXIT                       39600013
         SPACE 2                                                        39800013
ADNXTRSA LA    RI,ADEREAL          RESET RETURN REG FOR THIS LOOP       40000013
         SPACE 2                                                        40200013
*INSERT CHAIN ADDR IN EACH BIN OF EACH RSA EXCEPT THE LAST BIN OF THE   40400013
*   LAST RSA.                                                           40600013
         SPACE 1                                                        40800013
ADECHAIN A     RG,PPIBINSZ         ADDR OF THIS BIN + BIN SIZE          41000013
         LR    RE,RG               SAVE ADDR OF THE NEXT BIN            41200013
         S     RE,KFOUR            PTS TO AREA IN PREVIOUS BIN TO PUT   41400013
*                                    THE CHAIN ADDR OF NEXT BIN(IN RG)  41600013
         ST    RG,0(0,RE)          PREVIOUS BIN NOW CHAINED TO NEXT BIN 41800013
         BR    RI                  BR TO ADELOOPI ON ALL BINS EXCEPT    42000013
*                                    THE LAST BIN IN EACH RSA OTHERWISE 42200013
*                                    BR TO ADEREAL ON THIS LAST BIN     42400013
         SPACE 2                                                        42600013
*OVERLAY LAST BIN CHAIN ADDR OF THIS RSA WITH PROPER ADDRESS.(1ST BIN   42800013
*   ADDR OF NEXT RSA)                                                   43000013
         SPACE 1                                                        43200013
ADEREAL  LA    RH,8(0,RH)          UPDATE PPI RSA TABLE PTR TO NEXT     43400013
*                                    RSA ENTRY                          43600013
         L     RG,0(0,RH)          ADDR OF 1ST BIN IN NEXT RSA          43800013
         ST    RG,0(0,RE)          STORE AS CHAIN ADDR IN LAST BIN OF   44000013
*                                    PREVIOUS RSA.                      44200013
         B     ADELOOPO            BR TO CHAIN BINS OF THIS RSA         44400013
         SPACE 2                                                        44600013
*LIST OF CONSTANTS:                                                     44800013
         SPACE 1                                                        45000013
KFOUR    DC    F'4'                CONSTANT 4                           45200013
KZERO    DC    F'0'                CONSTANT 0                           45400013
         SPACE 2                                                        45600013
*LIST OF WORK AREAS/TABLES:                                             45800013
         SPACE 1                                                        46000013
WCOMBINE DC    F'0'                WORK AREA                            46200013
         EJECT                                                          46400013
IERRDE   DSECT                                                          46600013
         USING *,RL                THIS MODULE BASE REG                 46800013
         USING IERRCA,RN           ADDR OF PPI                          47000013
         USING IERRMA,RO           MESSAGE MODULE ADR                   47200013
IERDD1   B     RDEOLAY             GO TO OVERLAY EXITS                  47400013
         B     RDEEOF              GO TO EOF ROUTINE                    47600013
RDENTER  CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  47800013
         BL    RDENORM             NO FIT SWITCH OFF                    48000013
         BH    RDESPEC             NO. OF BINS WAS=0                    48200013
         SR    RE,RE                                                    48400013
         A     RE,PPIBDSVA+8                                            48600013
         BZ    RDEBINZ             BIN COUNT STILL=0                    48800013
         L     RA,WSAVE                                                 49000013
         L     RE,WSAVE+4          RELOAD REGS TO CONTINUE MOVE         49200013
         L     RC,WSAVE+8          LOC FOR CHAIN ADR-USED AFTER PARTIAL 49400013
         L     RD,PPIBDSVA+4       ADR OF NEXT AVAIL BIN                49600013
         ST    RD,0(0,RC)          INSERT CHAIN ADDRESS                 49800013
         LA    RB,8(0)             INDICATE DEBLOCK WITH NOFIT PREVIOUS 50000013
         L     RF,PPIBDSVA+4       LOAD ADR OF NEXT BIN IN RSA          50200013
RDEMOVE  L     RP,PPIBDSVA+12      LOAD ADR OF MOVE ROUTINE             50400013
         BALR  RO,RP               BRANCH TO MOVE ROUTINE               50600013
         B     RDENOTF             RECORD DIDN'T FIT                    50800013
         SPACE                                                          51000013
*  RECORD FIT ROUTINE                                                   51200013
         SPACE                                                          51400013
         CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  51600013
         BC    7,RDEUSUAL          LAST MOVE WAS NOT A NO FIT           51800013
         L     RD,WSAVAIL          GET RSA STARTING ADR OF RECORD       52000013
         SR    RC,RC                                                    52200013
         ST    RC,WSAVAIL          ZERO OUT WSAVAIL                     52400013
         B     RDEUSUAL+4          RD ALREADY LOADED                    52600013
RDEUSUAL L     RD,PPIBDSVA+4       BEGIN ADR OF RCD JUST MOVED          52800013
         AH    RD,EXPLFOUR         ADD EXT SIZE & 4                     53000013
         L     RC,ADRHOLDB         LOAD BUFFER ADDRESS                  53200013
         L     RE,PPIBDSVA+8                                            53400013
         SR    RE,RB                                                    53600013
         ST    RE,PPIBDSVA+8       UPDATE BIN COUNT                     53800013
         L     RE,0(0,RF)                                               54000013
         ST    RE,PPIBDSVA+4       UPDATE AVAIL                         54200013
         NI    NOFITSW,X'00'       TURN OFF NO FIT SWITCH               54400013
         L     RL,PPINET+4                                              54600013
RDEFIT   B     4(0,RL)             EXIT TO SORT ON RECORD FIT CONDITION 54800013
         SPACE                                                          55000013
*  RECORD NO FIT ROUTINE                                                55200013
         SPACE                                                          55400013
RDENOTF  ST    RA,WSAVE                                                 55600013
         STM   RE,RF,WSAVE+4       SAVE INFO FOR NEXT MOVE              55800013
         SR    RD,RD                                                    56000013
         ST    RD,PPIBDSVA+8       BINS AVAIL=0                         56200013
         OI    NOFITSW,X'01'       SET NOFITSW=01                       56400013
         A     RD,WSAVAIL                                               56600013
         BC    7,RDEBINZ           MORE THAN ONE NO FIT ON SAME RECORD  56800013
         L     RD,PPIBDSVA+4                                            57000013
         ST    RD,WSAVAIL          SAVE RSA ADR OF START OF RECORD      57200013
RDEBINZ  L     RL,PPINET+4                                              57400013
         B     24(0,RL)            EXIT TO SORT ON RECORD NO FIT        57600013
RDESPEC  SR    RE,RE                                                    57800013
         A     RE,PPIBDSVA+8       CHECK BIN COUNT                      58000013
         BZ    RDEBINZ             BIN COUNT STILL ZERO                 58200013
         NI    NOFITSW,X'00'       ZERO NOFITSW-BIN COUNT NO LONGER 0   58400013
         L     RE,ADRHOLDA         RELOAD BUFFER ADDRESS                58600013
RDEPTB   L     RF,PPIBDSVA+4                                            58800013
         AH    RF,EXPLFOUR         ADD EXT SIZE & 4 TO AVAIL ADR        59000013
         ST    RE,ADRHOLDB         SAVE BUFFER ADDRESS                  59200013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE ROUTINE     59400013
         B     RDEMOVE             CONTINUE PREP FOR MOVE               59600013
RDENORM  CLI   INSERTSW,X'00'                                           59800013
         BH    RDEISWON                                                 60000013
RDEGET   LM    RA,RB,KAWORK        DCB ADDR AND/OR VRE WORK ADDR A26453 60200019
         GET   (1),(0)             GET RECORD GL OR GM           A26453 60500019
         L     RJ,PPICOUNT                                              60800013
         LA    RJ,1(0,RJ)                                               61000013
         ST    RJ,PPICOUNT         ADD 1 TO RECORD COUNT                61200013
         ST    RB,ADRHOLD                                               61400013
RDEISWON LA    RB,ADRHOLD          SET UP PARAMETER FOR USER MOD        61600013
*                                    WILL BE L RB,ADRHOLD ON USER EOF   61800013
         L     RJ,PPINMAX          RESTORE NMAX REG                     62000013
         LTR   RJ,RJ               TEST FOR 0 OR NMAX                   62200013
         BC    2,RDEUEXIT          IF NMAX PLUS EXIT                    62400013
         LA    RJ,1                NMAX MUST BE AT LEAST 1              62600013
         SPACE                                                          62800013
*  USER MOD EXIT E15 USING CALL MACRO EXPANSION INSTRUCTIONS.           63000013
*    ADDRESS OF INPUT RECORD PASSED IN RB                               63200013
         SPACE                                                          63400013
RDEUEXIT L     RP,PPIX15+4         OVERLAYED IF THIS EXIT NOT ACTIVATED 63600013
*                                  OR IF USER EOF REACHED.              63800013
         BALR  RO,RP               BRANCH TO USER                       64000013
         SPACE                                                          64200013
*  USER RETURNS VIA RO WITH PROPER DISPLACEMENT IN RP. HE ALSO PASSES,  64400013
*    IN REG RB, THE ADR OF THE RECORD TO BE INSERTED OR THE ADR OF THE  64600013
*    WORK AREA IF THE USER HAS ALTERED THE RECORD.                      64800013
         SPACE                                                          65000013
         B     *+4(15)                                                  65200013
         B     RDEDONO             ALTER OR DO NOTHING                  65400013
         B     RDELETE             DELETE A RECORD                      65600013
         B     RDEUEOF             USER END OF FILE                     65800013
         SPACE                                                          66000013
*  INSERT A RECORD                                                      66200013
         SPACE                                                          66400013
RDEMAXCK BCT   RJ,RDEINSRT         CHECK FOR NMAX AND DECREMENT         66600013
         B     RDEMSG              NMAX RCHD-GO TO OUTPUT MESS AND E16  66800013
RDEINSRT OI    INSERTSW,X'01'      SET INSERT SWITCH                    67000013
         L     RF,PPIINSCT                                              67200013
         LA    RF,1(0,RF)                                               67400013
         ST    RF,PPIINSCT         ADD 1 TO INSERT COUNT                67600013
RDETSTBC LR    RE,RB               SET UP BUFF ADR FOR MOVE             67800013
         ST    RJ,PPINMAX          SAVE NMAX REG                        68000013
         SR    RF,RF                                                    68200013
         A     RF,PPIBDSVA+8       TEST BIN COUNT                       68400013
         BC    7,RDEPTB            BRANCH ON BIN COUNT NOT EQUAL 0      68600013
         ST    RE,ADRHOLDA         SAVE RCD ADR UNTIL BIN IS AVAILABLE  68800013
         OI    NOFITSW,X'03'       SET NO FIT SWITCH = 11               69000013
         B     RDEBINZ             GO TO NO FIT EXIT                    69200013
RDEDONO  BCT   RJ,RDENOTM          CHECK FOR NMAX AND DECREMENT         69400013
         B     RDEMSG              NMAX RCHD-GO TO OUTPUT MESS AND E16  69600013
RDENOTM  NI    INSERTSW,X'00'      ZERO INSERT SWITCH                   69800013
         B     RDETSTBC            GO CHECK BIN COUNT                   70000013
RDELETE  NI    INSERTSW,X'00'      ZERO INSERT SWITCH                   70200013
         L     RF,PPIDELCT                                              70400013
         LA    RF,1(0,RF)                                               70600013
         ST    RF,PPIDELCT         ADD 1 TO DELETE COUNT                70800013
         B     RDEGET              GO GET ANOTHER RECORD                71000013
RDEMSG   STH   RP,WINSALT          SAVE INSERT-ALTER CONDITION          71200013
         L     RO,PPIRMA           MESSAGE MODULE ADDR                  71400013
         LR    RE,RB               SAVE BUFF ADR                        71600013
         LM    RA,RB,MSGP1A04                                           71800013
         L     RP,PPIADSSC         LOAD PRINT RTN ADR                   72000013
         BAL   RO,12(0,RP)         BR TO PRINT RTN                      72200013
         SPACE                                                          72400013
*  USER EXIT E16-SORT CAPACITY, NMAX, HAS BEEN REACHED                  72600013
*    CALL MACRO INSTRUCTION EXPANSION                                   72800013
         SPACE                                                          73000013
         LR    RB,RE               RESTORE BUFF ADR                     73200013
         L     RP,PPIX16+4         NMAX EXIT ADDR                       73400013
         BALR  RO,RP               BRANCH TO USER                       73600013
         SPACE                                                          73800013
*  USER RETURNS TO MODULE VIA RO WITH PROPER DISPLACEMENT IN RP         74000013
         SPACE                                                          74200013
         B     *+4(15)                                                  74400013
         B     RDSETPPI            SORT CURRENT NO OF RCDS ONLY         74600013
         B     RDEIGNOR            IGNORE NMAX-CONTINUE SORT            74800013
         SPACE                                                          75000013
*  ABORT THE JOB                                                        75200013
         SPACE                                                          75400013
         L     RP,PPIADSSC                                              75600013
         BAL   RO,16(0,RP)         EXIT TO SORT SYSTEM CONTROL          75800013
RDESRTCR MVC   RDENTER(4),K1       OVERLAY ENTRANCE                     76000013
         SPACE 2                                                        76200013
*INTERFACE TO NETWORK                                                   76400013
         SPACE 1                                                        76600013
         L     RL,PPINET+4         ADDR OF NETWORK                      76800013
         B     8(0,RL)             BR TO SORT NTWK TO STRT EMPTY TREE   77000013
         SPACE 2                                                        77200013
RDEMPTYT L     RL,PPINET+4         ADDR OF NETWORK                      77400013
         B     16(0,RL)            BRANCH TO SORT TO CONT. EMPTY TREE   77600013
         SPACE                                                          77800013
* FROM USER,ON NMAX RETURN,TO SORT CURRENT NO OF RCDS ONLY              78000013
         SPACE 1                                                        78200013
RDSETPPI OI    PPISW1+3,X'02'      TURN ESTIMATED FILE SWITCH ON IN PPI 78400013
         CLI   WINPEOF,X'00'       WAS SYSTEM INPUT EOF REACHED         78600013
         BC    8,RDESRTCR          YES,DO NOT DECR PPICOUNT-FLUSH TREE  78800013
         L     RE,PPICOUNT         RCD IN INPUT BFR WILL NOT BE SORTED  79000013
         BCTR  RE,0                DECR PPICOUNT BY ONE                 79200013
         ST    RE,PPICOUNT         RESTORE PPICOUNT                     79400013
         B     RDESRTCR            BR TO FLUSH TREE                     79600013
         SPACE 1                                                        79800013
*  IGNORE NMAX-OVERLAY NMAX TEST WITH A BRANCH                          80000013
         SPACE                                                          80200013
RDEIGNOR MVC   RDEMAXCK(4),K2      OVERLAY NMAX CK IN INSERT LEG        80400013
         MVC   RDEDONO(4),K3       OVERLAY NMAX CK IN ALTER LEG         80600013
         SR    RF,RF                                                    80800013
         AH    RF,WINSALT                                               81000013
         BZ    RDENOTM             RESUME WITH INPUT RECORD             81200013
         B     RDEINSRT            RESUME WITH INSERT RECORD            81400013
RDEOLAY  LA    RE,12(0)                                                 81600013
         STC   RE,RDEFIT+3         OVERLAY FILLING-FIT EXIT             81800013
         LA    RE,28(0)                                                 82000013
         STC   RE,RDESPEC-1        OVERLAY FILLING-NO FIT EXIT          82200013
         B     RDENTER             BRANCH TO NORMAL ENTRANCE            82400013
RDEUEOF  CLI   WINPEOF,X'00'       HAVE WE REACHED INPUT EOF            82600013
         BE    RDESRTCR            YES-GO EMPTY TREE                    82800013
         SR    RF,RF                                                    83000013
         STC   RF,WUSREOF          INDICATE USER EOF                    83200013
         MVC   RDEUEXIT(4),K4      OVERLAY AFTER USER EOF               83400013
         MVC   RDEMSG,K6                                                83600013
         L     RB,ADRHOLD          RESTORE ADDR OF RCD IN INPUT BLK     83800013
         MVI   RDEISWON,X'58'      CHANGE LA INSTRUCTION TO L           84000013
         B     RDENOTM             BRANCH TO MOVE INPUT RECORD          84200013
RDEEOF   CLI   WUSREOF,X'00'       HAS USER REACHED EOF                 84400013
         BE    RDESRTCR            GO OVERLAY ENTRANCE                  84600013
         SR    RF,RF                                                    84800013
         STC   RF,WINPEOF          INDICATE INPUT EOF                   85000013
         MVC   RDEGET(4),K5        OVERLAY AFTER INPUT EOF              85200013
         SR    RB,RB                                                    85400013
         ST    RB,ADRHOLD          INPUT EOF INDICATION TO USER         85600013
         B     RDEISWON            GO TO SET UP FOR BRANCH TO USER      85800013
         SPACE 2                                                        86000013
*LIST OF WORK AREAS/TABLES:                                             86200013
         SPACE 1                                                        86400013
NOFITSW  DC    X'00'                                                    86600013
INSERTSW DC    X'00'                                                    86800013
EXPLFOUR DC    H'0'                                                     87000013
WSAVE    DC    3F'0'               FOR MOVE RTN                         87200013
ADRHOLD  DC    F'0'                FOR BUFFER ADR                       87400013
ADRHOLDA DC    F'0'                RECORD ADR WHEN BIN COUNT=0          87600013
ADRHOLDB DC    F'0'                RECORD ADR FOR MOVE RTN AND SORT RTN 87800013
WUSREOF  DC    X'01'               USER EOF SWITCH                      88000013
WINPEOF  DC    X'01'               INPUT EOF SWITCH                     88200013
WINSALT  DC    H'0'                INSERT-ALTER SWITCH                  88400013
WSAVAIL  DC    F'0'                SAVE AREA FOR RSA RECORD ADDRESS     88600013
         SPACE 2                                                        88800013
*LIST OF CONSTANTS:                                                     89000013
K1       B     RDEMPTYT            OVERLAY TO EMPTY TREE                89200013
K2       B     RDEINSRT            OVERLAY IN INSERT LEG                89400013
K3       B     RDENOTM             OVERLAY IN ALTER LEG                 89600013
K4       B     RDEDONO             OVERLAY AFTER USER EOF               89800013
K5       B     RDEISWON           OVLY AFTER INPUT E O F                90000013
K6       BC    0,0                                                      90200013
KAWORK   DC    2F'0'               FOR DCB AND VRE WORK ADDRS    A26453 90300019
         EJECT                                                          90400013
* MODULE NAME ***IERRMA***                                              90600013
*                                                                       90800013
* THIS MODULE CONTAINS ALL OF THE MESSAGES THAT ARE REQUIRED FOR        91000013
* PHASE 1 RUNNING PROGRAM.                                              91200013
         SPACE 1                                                        91400013
IERRMA   DSECT                                                          91600013
*                                                                       91800013
       COPY  RMAMAIN                                                    92000013
         EJECT                                                          92200013
         SMPPI                                                          92400013
         END                                                            92600013
