         TITLE '      IERADG - OS/360 SORT/MERGE - 360S-SM023 05/08/66' 00300013
         SPACE 2                                                        00600013
*MODULE NAME *** IERADG ***                                             00900013
         SPACE 2                                                        01200013
*STATUS:CHANGE LEVEL 000                                                01500013
         SPACE 2                                                        01800013
*MODULE FUNCTION/OPERATION: PHASE 1 ASSIGNMENT MODULE. V.L.NO PH1 EXITS 02100013
*   THE FUNCTION OF THIS MODULE IS TO CALCULATE THE NUMBER OF BINS IN   02400013
*   UP TO 5 NON-CONTIGUOUS RECORD STORAGE AREAS AND CHAIN ALL THESE     02700013
*   BINS TOGETHER. IT PUTS THE ADDRESS OF THE FIRST BIN IN THE FIRST    03000013
*   RSA IN AVAIL(PPIBDSVA+4). INPUT BUFFERS ARE SET UP VIA THE BUILD    03300013
*   MACRO. EXTRACT SIZE+4 IS CALCULATED AND STORED IN THE RUNNING       03600013
*   PROGRAM,IERRDG.                                                     03900013
         SPACE 1                                                        04200013
*   THE OPERATION OF THIS MODULE DOES NOT DEPEND UPON A PARTICULAR      04500013
*   INTERNAL REPRESENTATION OF THE EXTERNAL CHARACTER SET.              04800013
         SPACE 2                                                        05100013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               05400013
         SPACE 1                                                        05700013
*   NONE                                                                06000013
         SPACE 2                                                        06300013
*LIST OF MACROS USED BY MODULE:                                         06600013
         SPACE 1                                                        06900013
*   SMPPI                                                               07200013
*   BUILD                                                               07500013
         SPACE 2                                                        07800013
*ENTRY POINTS:                                                          08100013
         SPACE 1                                                        08400013
*   FROM IERRC9                    ENTRY FROM:IERRC9                    08700013
*                                    CALLING SEQUENCE-                  09000013
*                                      LOAD EP=IERADG,DCB=SORTLIB       09300013
*                                      LR   RP,RA                       09600013
*                                      BALR RO,RP                       09900013
         SPACE 2                                                        10200013
*INPUT: - PPI FIELDS REFERENCED                                         10500013
         SPACE 1                                                        10800013
*   PPIBINSZ   PPILAB08                                                 11100013
*   PPILAB03   PPILEXFF                                                 11400013
*   PPILAB06                                                            11700013
         SPACE 1                                                        12000013
*   ADDRESSES FOR BUFFERS AND TABLES,FOR THE RSA CHAINING ROUTINE, AND  12300013
*   FOR THE BUILD MACRO                                                 12600013
         SPACE 2                                                        12900013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            13200013
         SPACE 1                                                        13500013
*   PPIBDSVA                                                            13800013
         SPACE 1                                                        14100013
*   INITIALIZE START OF RSA(AVAIL) AND TOTAL NUMBER OF BINS IN ALL THE  14400013
*   RSA'S                                                               14700013
         SPACE 2                                                        15000013
*EXTERNAL ROUTINES:                                                     15300013
         SPACE 1                                                        15600013
*   NONE                                                                15900013
         SPACE 2                                                        16200013
*EXTERNAL PARAMETERS:                                                   16500013
         SPACE 1                                                        16800013
*   SEE REGISTERS                                                       17100013
         SPACE 2                                                        17400013
*EXITS-NORMAL:                                                          17700013
         SPACE 1                                                        18000013
*   TO IERRC9                      EXIT TO:IERRC9                       18300013
*                                    CALLING SEQUENCE-                  18600013
*                                      BR   RO         RETURN           18900013
         SPACE 2                                                        19200013
*EXITS-ERROR:                                                           19500013
         SPACE 1                                                        19800013
*   NONE                                                                20100013
         SPACE 2                                                        20400013
*TABLES/WORK AREAS:                                                     20700013
         SPACE 1                                                        21000013
*   WCOMBINE-WORK AREA                                                  21300013
         SPACE 2                                                        21600013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   21900013
         SPACE 2                                                        22200013
*NOTES: THIS MODULE WILL EXECUTE FOR ANY VARIABLE LENGTH SORT HAVING    22500013
*   NO PHASE 1 USER EXITS                                               22800013
         EJECT                                                          23100013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            23400013
         SPACE 1                                                        23700013
RA       EQU   0                   CONTENTS IN-N/A                      24000013
*                                  USE-NO. OF BUFFERS AND BUFFER SIZE   24300013
*                                    FOR BUILD MACRO                    24600013
*                                  CONTENTS OUT-N/A                     24900013
RB       EQU   1                   CONTENTS IN-N/A                      25200013
*                                  USE-ADDR OF INPUT BUFFER POOL FOR    25500013
*                                    BUILD MACRO.                       25800013
*                                  CONTENTS OUT-N/A                     26100013
RC       EQU   2                   CONTENTS IN-N/A                      26400013
*                                  USE-NOT USED                         26700013
*                                  CONTENTS OUT-N/A                     27000013
RD       EQU   3                   CONTENTS IN-N/A                      27300013
*                                  USE-NO. OF RSA AREAS-RSA TABLE CALC  27600013
*                                  CONTENTS OUT-N/A                     27900013
RE       EQU   4                   CONTENTS IN-N/A                      28200013
*                                  USE-WORK REGISTER                    28500013
*                                  CONTENTS OUT-N/A                     28800013
RF       EQU   5                   CONTENTS IN-N/A                      29100013
*                                  USE-NO. OF BYTES COUNTER IN 1 RSA    29400013
*                                  CONTENTS OUT-N/A                     29700013
RG       EQU   6                   CONTENTS IN-N/A                      30000013
*                                  USE-CURRENT BIN ADDRESS IN A RSA-    30300013
*                                    USED IN RSA TABLE CALC.            30600013
*                                  CONTENTS OUT-N/A                     30900013
RH       EQU   7                   CONTENTS IN- N/A                     31200013
*                                  USE- GENERAL WORK REGISTER           31500013
*                                  CONTENTS OUT-N/A                     31800013
RI       EQU   8                   CONTENTS IN- N/A                     32100013
*                                  USE- NOT USED                        32400013
*                                  CONTENTS OUT- N/A                    32700013
RJ       EQU   9                   CONTENTS IN- N/A                     33000013
*                                  USE- NOT USED                        33300013
*                                  CONTENTS OUT- N/A                    33600013
RK       EQU   10                  CONTENTS IN- N/A                     33900013
*                                  USE-IERRDG BASE REGISTER             34200013
*                                  CONTENTS OUT-N/A                     34500013
RL       EQU   11                  CONTENTS IN-N/A                      34800013
*                                  USE-MODULE BASE REGISTER             35100013
*                                  CONTENTS OUT-N/A                     35400013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   35700013
*                                  USE-NOT USED                         36000013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   36300013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              36600013
*                                  USE-PPI REFERENCES,REG SAVE AREA     36900013
*                                  CONTENTS OUT-ADDR OF PPI             37200013
RO       EQU   14                  CONTENTS IN-IERRC9 RETURN ADDR       37500013
*                                  USE-NOT USED                         37800013
*                                  CONTENTS OUT-IERRC9 RETURN ADDR      38100013
RP       EQU   15                  CONTENTS IN-IERADG ENTRY PT          38400013
*                                  USE-ESTABLISH THIS MOD BASE REGISTER 38700013
*                                  CONTENTS OUT-N/A                     39000013
         SPACE 2                                                        39300013
*START OF MODULE CODE PROPER:                                           39600013
         SPACE 2                                                        39900013
IERADG   CSECT                                                          40200013
         USING *,RL                THIS MODULE BASE REGISTER            40500013
         USING IERRDG,RK           IERRDG DSECT BASE REGISTER           40800013
         USING IERRCA,RN           PPI ADDR                             41100013
IERMDA   LR    RL,RP               ESTABLISH THIS MODULE BASE REGISTER  41400013
         L     RK,PPIDEB+4         ADDR OF IERRDG CSECT                 41700013
         SPACE 2                                                        42000013
*CHAIN ALL BINS TOGETHER BY PUTTING IN EACH BIN THE ADDR OF THE NEXT    42300013
*   AVAILABLE BIN. SAVE THE ADDRESS OF THE 1ST AVAILABLE BIN IN         42600013
*   PPIBDSVA+4,AND THE TOTAL NO. OF AVAILABLE BINS IN PPIBDSVA+8.       42900013
         SPACE 1                                                        43200013
         SR    RD,RD                                                    43500013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     43800013
         L     RH,PPILAB08         PTR TO RSA TABLE IN PPI              44100013
         L     RG,0(0,RH)          ADDR OF THIS RSA AREA BIN            44400013
         ST    RG,PPIBDSVA+4       SAVE THIS ADDR IN AVAIL(FOR IERRDG)  44700013
ADELOOPO L     RF,4(0,RH)          NO. OF BYTES IN THIS RSA AREA        45000013
         LA    RI,ADELOOPI         LOAD RETURN REG FOR THIS LOOP CALC   45300013
         SR    RE,RE                                                    45600013
         D     RE,PPIBINSZ         RF=NO. OF BINS IN THIS RSA AREA      45900013
         L     RE,PPIBDSVA+8       TOTAL NO.OF BINS IN ALL RSA'S SO FAR 46200013
         AR    RE,RF               UPDATE BIN COUNT                     46500013
         ST    RE,PPIBDSVA+8       SAVE UPDATED BIN COUNT               46800013
ADELOOPI BCT   RF,ADECHAIN         DECR NO. OF BINS CTR FOR THIS RSA.   47100013
*                                    BR IF MORE BINS IN THIS RSA.       47400013
         BCT   RD,ADNXTRSA         DECR NO. OF RSA'S CTR. BR IF MORE    47700013
*                                    RSA,S.THE LAST BIN IN THE LAST RSA 48000013
*                                    HAS NO CHAIN ADDR                  48300013
         MVC   WCOMBINE+1(1),PPILAB03                                   48600013
         MVC   WCOMBINE+2(2),PPILAB03+2                                 48900013
         L     RA,WCOMBINE         POSITION NO. AND SIZE OF BUFFERS     49200013
         L     RB,PPILAB02         ADDR OF INPUT BUFFER POOL ADDR TABLE 49500013
         BUILDS (1),(0)            BUILD THE INPUT BUFFER(S)            49800013
         SPACE 2                                                        50100013
         LH    RE,PPILEXFF         GET EXTRACT SIZE                     50400013
         A     RE,KFOUR                                                 50700013
         STH   RE,EXPLFOUR         STORE EXTRACT SIZE + 4               51000013
         L     RE,PPISTDCB         DCB ADDRESS                   A26453 51030019
         L     RE,0(RE)                                          A26453 51060019
         ST    RE,KAWORK+4         STORE IN R.P.WORK AREA        A26453 51090019
         TM    PPIMODEX+2,X'02'    VRE IN?                       A26453 51120019
         BZ    ADGRETUR            NO...                         A26453 51150019
         L     RE,PPIGETMN         ADDR OF GETMAIN TABLE OF ADDR A26453 51180019
         L     RE,12(RE)           FETCH ADDR OF VRE WORK AREA   A26453 51210019
         ST    RE,KAWORK           STORE IN R.P. WORK AREA       A26453 51240019
ADGRETUR BR    RO                  RETURN TO IERRC9              A26453 51270019
         BR    RO                  RETURN TO IERRC9                     51300013
         SPACE 2                                                        51600013
ADNXTRSA LA    RI,ADEREAL          RESET RETURN REG FOR THIS LOOP       51900013
         SPACE 2                                                        52200013
*INSERT CHAIN ADDR IN EACH BIN OF EACH RSA EXCEPT THE LAST BIN OF THE   52500013
*   LAST RSA.                                                           52800013
         SPACE 1                                                        53100013
ADECHAIN A     RG,PPIBINSZ         ADDR OF THIS BIN + BIN SIZE          53400013
         LR    RE,RG               SAVE ADDR OF THE NEXT BIN            53700013
         S     RE,KFOUR            PTS TO AREA IN PREVIOUS BIN TO PUT   54000013
*                                    THE CHAIN ADDR OF NEXT BIN(IN RG)  54300013
         ST    RG,0(0,RE)          PREVIOUS BIN NOW CHAINED TO NEXT BIN 54600013
         BR    RI                  BR TO ADELOOPI ON ALL BINS EXCEPT    54900013
*                                    THE LAST BIN IN EACH RSA OTHERWISE 55200013
*                                    BR TO ADEREAL ON THIS LAST BIN     55500013
         SPACE 2                                                        55800013
*OVERLAY LAST BIN CHAIN ADDR OF THIS RSA WITH PROPER ADDRESS.(1ST BIN   56100013
*   ADDR OF NEXT RSA)                                                   56400013
         SPACE 1                                                        56700013
ADEREAL  LA    RH,8(0,RH)          UPDATE PPI RSA TABLE PTR TO NEXT     57000013
*                                    RSA ENTRY                          57300013
         L     RG,0(0,RH)          ADDR OF 1ST BIN IN NEXT RSA          57600013
         ST    RG,0(0,RE)          STORE AS CHAIN ADDR IN LAST BIN OF   57900013
*                                    PREVIOUS RSA.                      58200013
         B     ADELOOPO            BR TO CHAIN BINS OF THIS RSA         58500013
         SPACE 2                                                        58800013
*LIST OF CONSTANTS:                                                     59100013
         SPACE 1                                                        59400013
KFOUR    DC    F'4'                CONSTANT 4                           59700013
         SPACE 2                                                        60000013
*LIST OF WORK AREAS/TABLES:                                             60300013
         SPACE 1                                                        60600013
WCOMBINE DC    F'0'                WORK AREA                            60900013
         EJECT                                                          61200013
IERRDG   DSECT                                                          61500013
         USING *,RL                THIS MODULE BASE REG                 61800013
         USING IERRCA,RN           ADDR OF PPI                          62100013
IERDD1   B     RDGOLAY             GO TO OVERLAY EXITS                  62400013
         B     RDGEOF              GO TO EOF ROUTINE                    62700013
RDGBEGIN CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  63000013
         BL    RDGNORM             NO FIT SWITCH OFF                    63300013
         BH    RDGSPEC             NO. OF BINS=0 DURING FILL            63600013
         SR    RE,RE                                                    63900013
         A     RE,PPIBDSVA+8                                            64200013
         BZ    RDGNOFIT                                                 64500013
         L     RA,WSAVE                                                 64800013
         L     RE,WSAVE+4                                               65100013
         L     RC,WSAVE+8          LOC FOR CHAIN ADR-USED AFTER PARTIAL 65400013
         L     RD,PPIBDSVA+4       ADR OF NEXT AVAIL BIN                65700013
         ST    RD,0(RC)            INSERT CHAIN ADDRESS                 66000013
         L     RB,KEIGHT           INDICATE DEBLOCK WITH NOFIT PREV     66300013
RDGBINS  L     RF,PPIBDSVA+4       LOAD ADR OF NEXT BIN IN RSA          66600013
         L     RP,PPIBDSVA+12      LOAD ADR OF MOVE ROUTINE             66900013
         BALR  RO,RP               BRANCH TO MOVE ROUTINE               67200013
         B     RDGNOTF             RECORD DIDN'T FIT                    67500013
         SPACE                                                          67800013
*  RECORD FIT ROUTINE                                                   68100013
         SPACE                                                          68400013
         CLI   NOFITSW,X'01'       CHECK NO FIT SWITCH                  68700013
         BC    7,RDGUSUAL          LAST MOVE WAS NOT A NO FIT           69000013
         L     RD,WSAVAIL          GET RSA STARTING ADR OF RECORD       69300013
         SR    RC,RC                                                    69600013
         ST    RC,WSAVAIL          ZERO OUT WSAVAIL                     69900013
         B     RDGUSUAL+4          RD ALREADY LOADED                    70200013
RDGUSUAL L     RD,PPIBDSVA+4       BEGIN ADR OF RECORD JUST MOVED       70500013
         AH    RD,EXPLFOUR         ADD EXT SIZE + 4                     70800013
         L     RC,ADRHOLD          LOAD BUFFER ADDRESS                  71100013
         L     RE,PPIBDSVA+8                                            71400013
         SR    RE,RB                                                    71700013
         ST    RE,PPIBDSVA+8       UPDATE BIN COUNT                     72000013
         L     RE,0(RF)                                                 72300013
         ST    RE,PPIBDSVA+4       UPDATE AVAIL                         72600013
         NI    NOFITSW,X'00'       TURN OFF NO FIT SWITCH               72900013
         L     RL,PPINET+4                                              73200013
RDGFIT   B     4(RL)               EXIT TO SORT ON RECORD FIT CONDITION 73500013
         SPACE                                                          73800013
*  RECORD NOFIT ROUTINE                                                 74100013
         SPACE                                                          74400013
RDGNOTF  ST    RA,WSAVE                                                 74700013
         STM   RE,RF,WSAVE+4       SAVE INFO FOR NEXT MOVE              75000013
         SR    RD,RD                                                    75300013
         ST    RD,PPIBDSVA+8       BINS AVAIL=0                         75600013
         OI    NOFITSW,X'01'                                            75900013
         A     RD,WSAVAIL                                               76200013
         BC    7,RDGNOFIT         SECOND NOFIT ON SAME RECORD           76500013
         L     RD,PPIBDSVA+4                                            76800013
         ST    RD,WSAVAIL          SAVE RSA ADR OF START OF RECORD      77100013
RDGNOFIT L     RL,PPINET+4                                              77400013
         B     24(RL)              EXIT TO SORT ON RECORD NO FIT        77700013
RDGNORM  LM    RA,RB,KAWORK        DCB ADDRESS AND/OR VRE WORK   A26453 78100019
         GET   (1),(0)                                           A26453 78500019
RDGGOT   ST    RB,ADRHOLD          SAVE ADDRESS OF RECORD               78900013
         L     RE,PPICOUNT                                              79200013
         LA    RE,1(RE)                                                 79500013
         ST    RE,PPICOUNT         ADD ONE TO RECORD COUNT              79800013
         LR    RE,RB               SET UP BUFFER ADDRESS FOR MOVE RTN   80100013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE ROUTINE     80400013
         SR    RD,RD                                                    80700013
         A     RD,PPIBDSVA+8                                            81000013
         BC    7,RDGMOVE           BRANCH UNLESS BIN COUNT=0            81300013
         OI    NOFITSW,X'03'                                            81600013
         B     RDGNOFIT            SPECIAL NO FIT CONDITION             81900013
         SPACE                                                          82200013
*  OVERLAY EXITS TO REPLACEMENT - CHANGE FROM FILLING TO NORMAL         82500013
         SPACE                                                          82800013
RDGOLAY  LA    RE,12(0)                                                 83100013
         STC   RE,RDGFIT+3         OVERLAY EXIT TO SORT-RECORD FIT      83400013
         LA    RE,28(0)                                                 83700013
         STC   RE,RDGNORM-1        OVERLAY EXIT TO SORT-RECORD NO FIT   84000013
         B     RDGBEGIN            BRANCH TO NORMAL ENTRY               84300013
         SPACE                                                          84600013
*  EOF - SET UP UNCONDITIONAL RETURN TO REPLACEMENT FOR FUTURE USE      84900013
         SPACE                                                          85200013
RDGEOF   MVC   RDGBEGIN(4),RDGFIT-4                                     85500013
         MVC   RDGBEGIN+4(4),KBRANCH    OVERLAY ENTRY WITH UNCOND EXIT  85800013
         L     RL,PPINET+4                                              86100013
         B     8(RL)               ONE TIME EXIT AT EOF                 86400013
RDGSPEC  SR    RE,RE                                                    86700013
         A     RE,PPIBDSVA+8                                            87000013
         BZ    RDGNOFIT                                                 87300013
         NI    NOFITSW,X'00'       ZERO NOFITSW - SPEC CONDITION        87600013
         SR    RB,RB               INDICATE DEBLOCK TO MOVE             87900013
         L     RE,ADRHOLD          LOAD BUFFER ADR                      88200013
RDGMOVE  L     RF,PPIBDSVA+4                                            88500013
         AH    RF,EXPLFOUR         ADD EXT SIZE + 4 TO AVAIL ADR        88800013
         B     RDGBINS+4           CONTINUE PREP FOR MOVE               89100013
         SPACE 2                                                        89400013
*LIST OF CONSTANTS:                                                     89700013
         SPACE 1                                                        90000013
KBRANCH  B     16(RL)                                                   90300013
NOFITSW  DC    X'00'                                                    90600013
ADRHOLD  DC    F'0'                                                     90900013
KEIGHT   DC    F'8'                                                     91200013
WSAVE    DC    3F'0'                                                    91500013
WSAVAIL  DC    F'0'                SAVE AREA FOR RSA RECORD ADR         91800013
EXPLFOUR DC    H'0'                EXTRACT SIZE + 4                     92100013
KAWORK   DC    2F'0'               FOR DCB AND/OR VRE WORK ADDR  A26453 92200019
         SMPPI                                                          92400013
         END                                                            92700013
