         TITLE 'IERADP  -  OS/360 SORT/MERGE - 360-SM023 5/11/66'       00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERADP ***                                             00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 000                                                01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION                                                        01400013
*   OSCL./2314 SORT PHASE ASSIGNMENT -FIXED LENGTH W/O USER EXIT E15.   01600013
*   THE FUNCTION OF THIS MODULE IS TO BUILD A TABLE OF RSA ADDRESSES    01800013
*   WITH THEIR RESPECTIVE AREA BYTE COUNTS IN IERRDB. THE TABLE IS      02000013
*   NEEDED BECAUSE RECORD STORAGE AREA MAY NOT BE CONTIGUOUS. THIS      02200013
*   MODULE ALSO BUILDS THE INPUT BUFFERS USING THE BUILD MACRO. IT      02400013
*   ALSO OBTAINS THE ADDRESS OF THE INPUT DCB AND PUTS IT IN THE        02600013
*   RUNNING PROGRAM,IERRDB.                                             02800013
*   IERADB INSERTS THE RECORD LENGTH OF THE FIXED LENGTH RECORD WHICH   03000013
*   MUST BE LESS THAN OR EQUAL TO 256 BYTES IN IERRDB MOVE INSTRUCTION. 03200013
*   IF 2314 SORTING TECH. IS BEING USED, THE RMAX CHECK IN R.P. IS      03400013
*   OVERLAYED -I.E. RDP1035 BECOMES UNCOND. BRANCH TO RDP1030 -2.       03600013
         SPACE 2                                                        03800013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               04000013
         SPACE 1                                                        04200013
*   NONE                                                                04400013
         SPACE 2                                                        04600013
*LIST OF MACROS USED BY MODULE:                                         04800013
         SPACE 1                                                        05000013
*   SMPPI                                                               05200013
*   BUILDS                                                              05400013
         SPACE 2                                                        05600013
*ENTRY POINTS:                                                          05800013
         SPACE 1                                                        06000013
*   FROM IERRC9                    ENTRY FROM:IERRC9                    06200013
*                                    CALLING SEQUENCE-                  06400013
*                                      LOAD EP=IERADB,DCB=SORTLIB       06600013
*                                      LR   RP,RA                       06800013
*                                      BALR RO,RP                       07000013
         SPACE 2                                                        07200013
*INPUT: - PPI FIELDS REFERENCED                                         07400013
         SPACE 1                                                        07600013
*   PPIDEB     PPISTDCB   PPILAB08                                      07800013
*   PPIRCDL1   PPILAB03                                                 08000013
*   PPILEXFF   PPILAB02                                                 08200013
         SPACE 1                                                        08400013
*   INFO IS NEEDED TO BUILD THE RSA TABLE IN IERRDB AND TO BUILD THE    08600013
*   INPUT BUFFERS.                                                      08800013
         SPACE 2                                                        09000013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            09200013
         SPACE 1                                                        09400013
*   PPISW1                                                              09600013
         SPACE 2                                                        09800013
*EXTERNAL ROUTINES:                                                     10000013
         SPACE 1                                                        10200013
*   NONE                                                                10400013
         SPACE 2                                                        10600013
*EXTERNAL PARAMETERS:                                                   10800013
         SPACE 1                                                        11000013
*   SEE REGISTERS                                                       11200013
         SPACE 2                                                        11400013
*EXITS-NORMAL:                                                          11600013
         SPACE 1                                                        11800013
*   TO IERRC9                      EXIT TO:IERRC9                       12000013
*                                    CALLING SEQUENCE-                  12200013
*                                      BR   RO         RETURN           12400013
         SPACE 2                                                        12600013
*EXITS-ERROR:                                                           12800013
         SPACE 1                                                        13000013
*   NONE                                                                13200013
         SPACE 2                                                        13400013
*TABLES/WORK AREAS:                                                     13600013
         SPACE 1                                                        13800013
*   WAREA-WORK AREA                                                     14000013
         SPACE 2                                                        14200013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   14400013
         SPACE 2                                                        14600013
*NOTES: THIS MODULE WILL EXECUTE FOR ANY FIXED LENGTH SORT WITHOUT EXIT 14800013
*   E15 AND E16. THE FIXED LENGTH INPUT RCD MUST BE EQUL/L.T. 256 BYTES 15000013
         EJECT                                                          15200013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            15400013
         SPACE 1                                                        15600013
RA       EQU   0                   CONTENTS IN- N/A                     15800013
*                                  USE- HAS NO. OF BUFFERS AND BUFFER   16000013
*                                    SIZE FOR BUILD MACRO               16200013
*                                  CONTENTS OUT- N/A                    16400013
RB       EQU   1                   CONTENTS IN- N/A                     16600013
*                                  USE- ADDR OF INPUT BUFFER POOL FOR   16800013
*                                    BUILD MACRO                        17000013
*                                  CONTENTS OUT- N/A                    17200013
RC       EQU   2                   CONTENTS IN- N/A                     17400013
*                                  USE- ADDR OF RSA TABLE IN IERRDB     17600013
*                                  CONTENTS OUT- N/A                    17800013
RD       EQU   3                   CONTENTS IN- N/A                     18000013
*                                  USE- COUNTER FOR NO. OF RSA AREAS    18200013
*                                  CONTENTS OUT- N/A                    18400013
RE       EQU   4                   CONTENTS IN- N/A                     18600013
*                                  USE- WORK REGISTER                   18800013
*                                  CONTENTS OUT- N/A                    19000013
RF       EQU   5                   CONTENTS IN- N/A                     19200013
*                                  USE- PTR TO THE TABLE OF RSA ADDRS   19400013
*                                    IN PPI                             19600013
*                                  CONTENTS OUT- N/A                    19800013
RG       EQU   6                   CONTENTS IN- N/A                     20000013
*                                  USE- INDEX REGISTER                  20200013
*                                     - WORK REGISTER                   20400013
*                                  CONTENTS OUT- N/A                    20600013
RH       EQU   7                   CONTENTS IN- N/A                     20800013
*                                  USE- WORK REGISTER                   21000013
*                                  CONTENTS OUT- N/A                    21200013
RI       EQU   8                   CONTENTS IN- N/A                     21400013
*                                  USE- WORK REGISTER                   21600013
*                                  CONTENTS OUT- N/A                    21800013
RJ       EQU   9                   CONTENTS IN- N/A                     22000013
*                                  USE- NOT USED                        22200013
*                                  CONTENTS OUT- N/A                    22400013
RK       EQU   10                  CONTENTS IN- N/A                     22600013
*                                  USE- IERRDB DSECT BASE REGISTER      22800013
*                                  CONTENTS OUT- N/A                    23000013
RL       EQU   11                  CONTENTS IN- N/A                     23200013
*                                  USE-MODULE BASE REGISTER             23400013
*                                  CONTENTS OUT- N/A                    23600013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   23800013
*                                  USE- NOT USED                        24000013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   24200013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              24400013
*                                  USE-PPI REFERENCES,REG SAVE AREA     24600013
*                                  CONTENTS OUT-ADDR OF PPI             24800013
RO       EQU   14                  CONTENTS IN- IERRC9 RETURN ADDR      25000013
*                                  USE- NOT USED                        25200013
*                                  CONTENTS OUT- IERRC9 RETURN ADDR     25400013
RP       EQU   15                  CONTENTS IN- IERADB ENTRY PT         25600013
*                                  USE- ESTABLISH IERADB BASE REGISTER  25800013
*                                  CONTENTS OUT- N/A                    26000013
         SPACE 2                                                        26200013
*START OF MODULE CODE PROPER:                                           26400013
         SPACE 2                                                        26600013
IERADP   CSECT                                                          26800013
         USING *,RL                THIS MODULE BASE REG                 27000013
         USING IERRDP,RK                                                27200013
         USING IERRCA,RN                                                27400013
IERMDA   LR    RL,RP               SET THIS MODULE BASE REGISTER        27600013
         L     RK,PPIDEB+4         SET IERRDB DSECT BASE REGISTER       27800013
         SPACE 2                                                        28000013
*ESTABLISH ALL RECORD STORAGE AREA ADDRESSES AND THEIR RESPECTIVE BYTE  28200013
*   COUNTS AND BUILD RSA TABLE IN IERRDB                                28400013
         SPACE 1                                                        28600013
         L     RC,PPILAB08         PTR TO TABLE OF RSA ADDRS WITH       28800013
         ST    RC,ADCONPTR           THEIR RESPECTIVE BYTE COUNTS       29000013
         SR    RD,RD                                                    29200013
         SR    RG,RG                                                    29400013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     29600013
         LA    RH,4                4 BYTES FOR TREE ADDR                29800013
         AH    RH,PPILEXFF         PLUS SIZE OF ROUNDED EXTRACTED       30000013
*                                    CONTROL FIELDS                     30200013
         L     RF,PPILAB08         PTR TO TABLE OF RSA ADDRS WITH THEIR 30400013
*                                    RESPECTIVE BYTE COUNTS             30600013
ADPRSALP L     RE,0(RG,RF)         STARTING ADDRESS OF AN RSA AREA      30800013
         AR    RE,RH               ADDR OF 1ST RCD IN THIS RSA AREA     31000013
         ST    RE,0(RG,RC)         STORE IN IERRDB RSA ADDR TABLE       31200013
         L     RE,4(RG,RF)         BYTE COUNT OF THIS RSA AREA          31400013
         S     RE,PPIBINSZ         SUBTRACT LENGTH OF FIRST RECORD      31600013
         ST    RE,4(RG,RC)         STORE IN IERRDB RSA ADDR TABLE       31800013
         LA    RG,8(0,RG)          UPDATE INDEX PTR                     32000013
         BCT   RD,ADPRSALP         DECR RSA CTR. LOOP IF MORE RSA AREAS 32200013
         MVC   WADDRSA(8),0(RC)    MOVE PARAMS INTO RUNNIGN PROGRAM     32400013
         SPACE 1                                                        32600013
*INSERT INPUT DCB ADDR AND RECORD LENGTH IN IERRDB. BUILD INPUT BUFFERS 32800013
         SPACE 1                                                        33000013
         L     RG,PPISTDCB         SET INPUT DCB ADDRS IN RUNNING PROG. 33200013
         L     RE,0(RG)                                                 33400013
         ST    RE,KADCB                                                 33600013
         LH    RI,PPIRCDL1         SET RCD LENGTH - 1 IN IN-LINE        33800013
         BCTR  RI,0                  MOVE INSTR IN RUNNING PROG         34000013
         STC   RI,RDP1030+1                                             34200013
         SPACE 1                                                        34400013
         L     RB,PPILAB02        SET REG 1 = ADDRESS OF BUFFER LIST    34600013
         MVC   WAREA+2(2),PPILAB03+2                                    34800013
         MVC   WAREA+1(1),PPILAB03                                      35000013
         L     0,WAREA             SET NO. OF BUFFERS AND BUFFER SIZE   35200013
*                                  IN REG 0                             35400013
         SPACE 2                                                        35600013
         BUILDS (1),(0)                                                 35800013
         SPACE 2                                                        36000013
*   SET USER EOF SWITCH IN PPI, SINCE THERE IS NO USER EXIT             36200013
         SPACE 1                                                        36400013
         OI    PPISW1+7,X'80'                                           36600013
         SPACE 2                                                        36800013
         SPACE 2                                                        37000013
*IF 2314, OVERLAY RMAX CHECK IN R.P.  RETURN TO IERRC9.                 37200013
         SPACE 1                                                        37400013
         TM    PPISW1+6,X'02'      2314 SORT                            37600013
         BCR   8,RO                NO, RETURN TO -RC9                   37800013
         SPACE 1                                                        38000013
         MVC   RDP1035(4),KADPKON  OVERLAY RMAX CHECK                   38200013
         SPACE 1                                                        38400013
         BR    RO                  RETURN                               38600013
         SPACE 2                                                        38800013
*LIST OF WORK AREAS:                                                    39000013
         SPACE 1                                                        39200013
WAREA    DC    F'0'                                                     39400013
         SPACE 2                                                        39600013
*LIST OF CONSTANTS:                                                     39800013
         SPACE 1                                                        40000013
         DROP  RL                                                       40200013
         DROP  RK                                                       40400013
         USING IERRDP,RL                                                40600013
KADPKON  B     RDP1030-2           OVERLAY RMAX CHECK                   40800013
         EJECT                                                          41000013
IERRDP   DSECT                     DUMMY RUNNING PROGRAM                41200013
         USING *,RL                THIS MODULE BASE REG                 41400013
         USING IERRCA,RN           PPI ADDR                             41600013
IERDD1   B     RDP1050             ENTRY FROM SORT NETWORK. G RECORDS   41800013
*                                    ARE IN THE TREE(ONCE ONLY)         42000013
         B     RDP1060             ENTRY FROM EOF ROUTINE               42200013
         B     RDP1010             NORMAL ENTRY WHILE FILLING TREE      42400013
*                                   WILL BE OVERLAID BY:                42600013
*                                   B  RDP1020 WHEN RSA HAS BEEN FILLD  42800013
*                                   B  RDP1065 AFTER INPUT EOF          43000013
         SPACE 2                                                        43200013
*        ENTRY TO REINITIALIZE IN ORDER TO BEGIN FILLING TREE           43400013
         SPACE 1                                                        43600013
         MVC   RDP1040(8),KMOD5    REOVERLAY OVERLAID INSTRUCTIONS      43800013
         MVC   IERDD1+8(4),KMOD2                                        44000013
         L     RH,PPILAB08         LOAD ADDRESS OF RSA PARAM TABLE      44200013
         ST    RH,ADCONPTR         STORE                                44400013
         MVC   WADDRSA(8),0(RH)    MOVE NEW PARAMS INTO WORK AREA       44600013
*                                   FIRST WORD = ADDRESS NEXT RSA BIN   44800013
*                                   SECOND WORD = BIN BYTE COUNT MINUS  45000013
*                                   ONE RECORD LENGTH                   45200013
         L     RB,WADDRESS         LOAD REGISTER FOR MOVE INSTRUCTION   45400013
         L     RD,WADDRSA            TO MOVE SAVED RECORD INTO RSA      45600013
         B     RDP1035             BRANCH TO MOVE RECORD                45800013
         SPACE 2                                                        46000013
*NORMAL ENTRY FROM NETWORK WHILE FILLING TREE, ENTRY FROM ALGORITHM ON  46200013
*   OUTPUT EOS, NORMAL ENTRY FROM BLOCK WHILE RUNNING                   46400013
         SPACE 1                                                        46600013
RDP1010  L     RD,WADDRSA          LOAD UPDATED ADDRESS OF RSA          46800013
RDP1020  L     RG,KADCB            ADDR OF THE INPUT DCB                47000013
         GET   (RG)                                                     47200013
         SPACE 1                                                        47400013
*GET RETURNS ADDR OF RCD IN INPUT BUFFER IN RB.                         47600013
         SPACE 1                                                        47800013
         ST    RB,WADDRESS         SAVE ADDRESS OF RECORD IN BUFFER     48000013
         SPACE 1                                                        48200013
*UPDATE RECORD  COUNTER                                                 48400013
         SPACE 1                                                        48600013
         L     RG,PPICOUNT                                              48800013
         LA    RG,1(RG)            INCR RCD COUNT BY 1                  49000013
         ST    RG,PPICOUNT                                              49200013
RDP1035  L     RG,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   49400013
         LA    RG,1(RG)              MAX NO OF RECORDS ON 1 REEL TAPE   49600013
         ST    RG,WRMAX           SAVE                                  49800013
         C     RG,PPIRMAX          HAVE RMAX RECORDS BEEN EXCEEDED?     50000013
         BH    RDP1055             BRANCH ON YES                        50200013
         SPACE 2                                                        50400013
*        MOVE RECORD FROM INPUT BUFFER TO RSA                           50600013
         SPACE 1                                                        50800013
         LR    RC,RB               LOAD PARAM REG FOR SORT NETWORK      51000013
RDP1030  MVC   0(1,RD),0(RC)       MOVE RCD FROM INPUT BUFFER TO RSA -  51200013
*                                    LENGTH SET BY ASSIGNMENT ROUTINE   51400013
         SPACE 2                                                        51600013
*UPDATE RSA TABLE PARAMETERS                                            51800013
         SPACE 1                                                        52000013
RDP1040  LR    RF,RD               WILL BE OVLAYED BY BR TO NETWORK     52200013
*                                    AFTER G+1 RCDS                     52400013
         A     RF,PPIBINSZ         UPDATE RSA ADDR TO NEXT BIN          52600013
         ST    RF,WADDRSA          STORE                                52800013
         L     RE,WBYTECNT         LOAD REMAINING BYTES IN RSA CHUNK    53000013
         S     RE,PPIBINSZ         SUBTRACT LENGTH OF NEXT RECORD       53200013
         BM    RDP1045             BRANCH ON MINUS RESULT TO UPDATE PTR 53400013
         ST    RE,WBYTECNT         OTHERWISE STORE                      53600013
         SPACE 1                                                        53800013
*INTERFACE WITH SORT NETWORK DURING FILL OF TREE.                       54000013
         SPACE 1                                                        54200013
         L     RL,PPINET+4         ADDR OF NETWORK                      54400013
         B     4(RL)                 BR TO FILL TREE.                   54600013
         SPACE 2                                                        54800013
*UPDATE POINTER TO NEXT RSA TABLE ENTRY(NEXT RSA AREA)                  55000013
         SPACE 1                                                        55200013
RDP1045  L     RH,ADCONPTR         LOAD ADDRESS IN RSA PARAM TABLE      55400013
         LA    RH,8(RH)                UPDATE TO NEXT TABLE ENTRY       55600013
         ST    RH,ADCONPTR             SAVE UPDATED POINTER TO TABLE    55800013
         MVC   WADDRSA(8),0(RH)    MOVE NEW PARAMS INTO WORK AREA       56000013
*                                   FIRST WORD = ADDRESS NEXT RSA BIN   56200013
*                                   SECOND WORD = BIN BYTE COUNT MINUS  56400013
*                                   ONE RECORD LENGTH                   56600013
         L     RL,PPINET+4         ADDRESS OF SORT NETWORK              56800013
         B     4(RL)               BRANCH TO FILL TREE                  57000013
         SPACE 2                                                        57200013
         SPACE 2                                                        57400013
*SORT TREE HAS BEEN FILLED.  THE NEXT DEBLOCKED RECORD IS MOVED TO THE  57600013
*NEXT SPACE IN RSA.  IN ALL SUBSEQUENT ENTRIES TO THIS MODULE, RD WILL  57800013
*POINT TO THE WINNER RECORD IN RSA.  THE DEBLOCKED RECORD MUST BE MOVED 58000013
*TO THE LOCATION INDICATED BY RD. ALSO, THIS MODULE MUST NOW ENTER THE  58200013
*SORT NETWORK AT ITS NORMAL ENTRY POINT.  THE FOLLOWING CODE MODIFIES   58400013
*THIS MODULE TO EFFECT THESE NEW REQUIREMENTS.                          58600013
         SPACE 1                                                        58800013
RDP1050  MVC   IERDD1+8(4),KMOD1   MOCIFY ENTRY BRANCH ADDRESS          59000013
         MVC   RDP1040(8),KMOD3    MODIFY EXIT ADDRESS                  59200013
         B     RDP1010             RETURN TO GET NEXT RECORD            59400013
         SPACE 1                                                        59600013
RDP1055  SR    RE,RE               RMAX COUNT HAS BEEN EXCEEDED         59800013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   60000013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  60200013
         SPACE 2                                                        60400013
*WHEN EOF HAS BEEN REACHED, THERE ARE NO MORE RECORDS TO BE DEBLOCKED   60600013
*BUT THE SORT NETWORK MUST EMPTY ITS TREE.  FUTURE ENTRIES TO THIS      60800013
*MODULE DO NO PROCESSING, BUT MERELY EXIT TO THE SORT NETWORK AT ITS    61000013
*EMPTYING ENTRY.  THE FOLLOWING CODING MODIFIES THE PRESENT ENTRY POINT 61200013
*TO EFFECT THIS CHANGE AND THEN EXITS TO THE SORT NETWORK AT ITS EOF    61400013
*ENTRY.                                                                 61600013
         SPACE 1                                                        61800013
RDP1060  MVC   IERDD1+8(4),KMOD4   BR DIRECTLY TO SORT NETWORK          62000013
         SPACE 2                                                        62200013
*INTERFACE TO SORT NETWORK ON EOF.                                      62400013
         SPACE 1                                                        62600013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 62800013
         B     8(RL)                                                    63000013
         SPACE 2                                                        63200013
*        INTERFACE TO SORT NETWORK TO FLUSH TREE                        63400013
         SPACE 1                                                        63600013
RDP1065  L     RL,PPINET+4         BRANCH IMMEDIATELY BACK TO NETWORK   63800013
         B     16(RL)                AFTER INPUT EOF                    64000013
         SPACE 2                                                        64200013
*CONSTANTS USED BY THE MODULE:                                          64400013
         SPACE 1                                                        64600013
KMOD1    B     RDP1020             OVERLAY RDP1010 AFTER G+1 RCDS       64800013
KMOD2    B     RDP1010             TO RESTORE NETWORK ENTRY FOR FILLING 65000013
KMOD3    L     RL,PPINET+4         OVERLAY RDP1040 AFTER G+1 RCDS       65200013
         B     12(RL)                NORMAL BRANCH TO NETWORK           65400013
KMOD4    B     RDP1065             RETURN TO NETWORK AFTER INPUT EOF    65600013
KMOD5    LR    RF,RD               TO RESTORE INSTRUCTIONS OVERLAID     65800013
         A     RF,PPIBINSZ           BY BRANCH TO NETWORK AFTER TREE    66000013
         ST    RF,WADDRSA            IS FILLED                          66200013
KADCB    DC    F'0'                INPUT DCB ADDR LOADED BY A.P.        66400013
         SPACE 2                                                        66600013
*LIST OF WORK AREAS/TABLES:                                             66800013
         SPACE 1                                                        67000013
WADDRESS DS    F                   ADDRESS OF RECORD FROM LAST 'GET'    67200013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     67400013
WADDRSA  DS    F                   UPDATED ADDRESS OF RSA               67600013
WBYTECNT DS    F                   REMAINING BYTE COUNT IN RSA CHUNK    67800013
ADCONPTR  DS   F                                                        68000013
         SPACE 2                                                        68200013
         EJECT                                                          68400013
         SMPPI                                                          68600013
         END                                                            68800013
