         TITLE 'IERADQ - OS/360 SORT/MERGE - 360-SM023 05/11/66'        00200013
         SPACE 2                                                        00400013
*MODULE NAME *** IERADQ ***                                             00600013
         SPACE 2                                                        00800013
*STATUS:CHANGE LEVEL 000                                                01000013
         SPACE 2                                                        01200013
*MODULE FUNCTION                                                        01400013
*   OSCL/2314 SORT PHASE ASSIGNMENT - FIXED LENGTH W/O USER EXIT E15.   01600013
*   THE FUNCTION OF THIS MODULE IS TO BUILD A TABLE OF RSA ADDRESSES    01800013
*   WITH THEIR RESPECTIVE AREA BYTE COUNTS IN IERRDC. THE TABLE IS      02000013
*   NEEDED BECAUSE RECORD STORAGE AREA MAY NOT BE CONTIGUOUS. THIS      02200013
*   MODULE ALSO BUILDS THE INPUT BUFFERS USING THE BUILD MACRO. IT      02400013
*   ALSO OBTAINS THE ADDRESS OF THE INPUT DCB AND PUTS IT IN THE        02600013
*   RUNNING PROGRAM IERRDC.                                             02800013
         SPACE 2                                                        03000013
*LIST OF MODULES IN WHICH THIS MODULE APPEARS AS A DSECT:               03200013
         SPACE 1                                                        03400013
*   NONE                                                                03600013
         SPACE 2                                                        03800013
*LIST OF MACROS USED BY MODULE:                                         04000013
         SPACE 1                                                        04200013
*   SMPPI                                                               04400013
*   BUILDS                                                              04600013
         SPACE 2                                                        04800013
*ENTRY POINTS:                                                          05000013
         SPACE 1                                                        05200013
*   FROM  IERRC9                   ENTRY FROM:IERRC9                    05400013
*                                    CALLING SEQUENCE-                  05600013
*                                      LOAD EP=IERADC,DCB=SORTLIB       05800013
*                                      LR   RP,RA                       06000013
*                                      BALR RO,RP                       06200013
         SPACE 2                                                        06400013
*INPUT: - PPI FIELDS REFERENCED                                         06600013
         SPACE 1                                                        06800013
*   PPIDEB     PPILAB08                                                 07000013
*   PPILAB03   PPILEXFF                                                 07200013
*   PPILAB02   PPISTDCB                                                 07400013
         SPACE 1                                                        07600013
*   INFO IS NEEDED TO BUILD THE RSA TABLE IN IERRDC AND TO BUILD THE    07800013
*   INPUT BUFFERS.                                                      08000013
         SPACE 2                                                        08200013
*OUTPUT: - PPI FIELDS INITIALIZED OR ALTERED                            08400013
         SPACE 1                                                        08600013
*   PPISW1                                                              08800013
         SPACE 2                                                        09000013
*EXTERNAL ROUTINES:                                                     09200013
         SPACE 1                                                        09400013
*   NONE                                                                09600013
         SPACE 2                                                        09800013
*EXTERNAL PARAMETERS:                                                   10000013
         SPACE 1                                                        10200013
*   SEE REGISTERS                                                       10400013
         SPACE 2                                                        10600013
*EXITS-NORMAL:                                                          10800013
         SPACE 1                                                        11000013
*   TO IERRC9                      EXIT TO: IERRC9                      11200013
*                                    CALLING SEQUENCE-                  11400013
*                                      BR   RO         RETURN           11600013
         SPACE 2                                                        11800013
*EXITS-ERROR:                                                           12000013
         SPACE 1                                                        12200013
*   NONE                                                                12400013
         SPACE 2                                                        12600013
*TABLES/WORK AREAS:                                                     12800013
         SPACE 1                                                        13000013
*   WAREA-WORK AREA                                                     13200013
         SPACE 2                                                        13400013
*ATTRIBUTES: THIS IS A CLASS A MODULE                                   13600013
         SPACE 2                                                        13800013
*NOTES:THIS MODULE WILL EXECUTE FOR ANY FIXED LENGTH SORT WITHOUT EXITS 14000013
*   E15 AND E16. THE INPUT RCD MUST BE GREATER THAN 256 BYTES.          14200013
         EJECT                                                          14400013
*LIST OF GENERAL REGISTER EQUATE STATEMENTS:                            14600013
         SPACE 1                                                        14800013
RA       EQU   0                   CONTENTS IN- N/A                     15000013
*                                  USE- LOAD TO NO.OF BUFFERS AND       15200013
*                                    BUFFER SIZE FOR BUILD MACRO        15400013
*                                  CONTENTS OUT- N/A                    15600013
RB       EQU   1                   CONTENTS IN- N/A                     15800013
*                                  USE- ADDR OF INPUT BUFFER POOL FOR   16000013
*                                    BUILD MACRO                        16200013
*                                  CONTENTS OUT- N/A                    16400013
RC       EQU   2                   CONTENTS IN- N/A                     16600013
*                                  USE- ADDR OF RSA TABLE IN IERRDC     16800013
*                                  CONTENTS OUT- N/A                    17000013
RD       EQU   3                   CONTENTS IN- N/A                     17200013
*                                  USE- COUNTER FOR NO. OF RSA AREAS    17400013
*                                  CONTENTS OUT- N/A                    17600013
RE       EQU   4                   CONTENTS IN- N/A                     17800013
*                                  USE- WORK REGISTER                   18000013
*                                  CONTENTS OUT- N/A                    18200013
RF       EQU   5                   CONTENTS IN- N/A                     18400013
*                                  USE- PTR TO THE TABLE OF RSA ADDRS   18600013
*                                    IN PPI                             18800013
*                                  CONTENTS OUT- N/A                    19000013
RG       EQU   6                   CONTENTS IN- N/A                     19200013
*                                  USE- INDEX REGISTER                  19400013
*                                     - WORK REGISTER                   19600013
*                                  CONTENTS OUT- N/A                    19800013
RH       EQU   7                   CONTENTS IN- N/A                     20000013
*                                  USE- WORK REGISTER                   20200013
*                                  CONTENTS OUT- N/A                    20400013
RI       EQU   8                   CONTENTS IN- N/A                     20600013
*                                  USE- WORK REGISTER                   20800013
*                                  CONTENTS OUT- N/A                    21000013
RJ       EQU   9                   CONTENTS IN- N/A                     21200013
*                                  USE- NOT USED                        21400013
*                                  CONTENTS OUT- N/A                    21600013
RK       EQU   10                  CONTENTS IN- N/A                     21800013
*                                  USE- IERRDC DSECT BASE REGISTER      22000013
*                                  CONTENTS OUT- N/A                    22200013
RL       EQU   11                  CONTENTS IN- N/A                     22400013
*                                  USE-MODULE BASE REGISTER             22600013
*                                  CONTENTS OUT- N/A                    22800013
RM       EQU   12                  CONTENTS IN- EQUALS OR EXTRACT RTN   23000013
*                                  USE- NOT USED                        23200013
*                                  CONTENTS OUT-EQUALS OR EXTRACT RTN   23400013
RN       EQU   13                  CONTENTS IN-ADDR OF PPI              23600013
*                                  USE-PPI REFERENCES,REG SAVE AREA     23800013
*                                  CONTENTS OUT-ADDR OF PPI             24000013
RO       EQU   14                  CONTENTS IN- IERRC9 RETURN ADDR      24200013
*                                  USE- NOT USED                        24400013
*                                  CONTENTS OUT- IERRC9 RETURN ADDR     24600013
RP       EQU   15                  CONTENTS IN- IERADC ENTRY PT         24800013
*                                  USE- ESTABLISH IERADC BASE REGISTER  25000013
*                                  CONTENTS OUT- N/A                    25200013
         SPACE 2                                                        25400013
*START OF MODULE CODE PROPER:                                           25600013
         SPACE 2                                                        25800013
IERADQ   CSECT                                                          26000013
         USING *,RL                THIS MODULE BASE REGISTER            26200013
         USING IERRDQ,RK           BASE REG FOR R.P. DSECT              26400013
         USING IERRCA,RN           PPI BASE REG                         26600013
IERMDA   LR    RL,RP               SET THIS MODULE BASE REGISTER        26800013
         L     RK,PPIDEB+4         SET IERRDC DSECT BASE REGISTER       27000013
         SPACE 2                                                        27200013
*ESTABLISH ALL RECORD STORAGE AREA ADDRESSES AND THEIR RESPECTIVE BYTE  27400013
*   COUNTS AND BUILD RSA TABLE IN IERRDB.                               27600013
         SPACE 1                                                        27800013
         L     RC,PPILAB08         PTR TO TABLE OF RSA ADDRS WITH       28000013
         ST    RC,ADCONPTR           THEIR RESPECTIVE BYTE COUNTS       28200013
         SR    RD,RD                                                    28400013
         SR    RG,RG                                                    28600013
         IC    RD,PPILAB08         NO. OF RSA AREAS                     28800013
         LA    RH,4                4 BYTES FOR TREE ADDRESS             29000013
         AH    RH,PPILEXFF         PLUS SIZE OF ROUNDED EXTRACTED       29200013
*                                    CONTROL FIELDS                     29400013
         L     RF,PPILAB08         PTR TO TABLE OF RSA ADDRS WITH THEIR 29600013
*                                    RESPECTIVE BYTE COUNTS             29800013
ADQRSALP L     RE,0(RG,RF)         STARTING ADDRESS OF AN RSA AREA      30000013
         AR    RE,RH               EQLS ADDR OF 1ST RCD IN THE RSA AREA 30200013
         ST    RE,0(RG,RC)         STORE IN IERRDC RSA ADDR TABLE       30400013
         L     RE,4(RG,RF)         BYTE COUNT OF THIS RSA AREA          30600013
         S     RE,PPIBINSZ         SUBTRACT LENGTH OF FIRST RECORD      30800013
         ST    RE,4(RG,RC)         STORE IN IERRDC RSA ADDR TABLE       31000013
         LA    RG,8(0,RG)          UPDATE INDEX REG                     31200013
         BCT   RD,ADQRSALP         DECR RSA CTR, LOOP IF MORE RSA AREAS 31400013
         MVC   WADDRSA(8),0(RC)    MOVE PARAMS INTO RUNNIGN PROGRAM     31600013
         SPACE 1                                                        31800013
*INSERT INPUT DCB ADDR IN IERRDC. BUILD INPUT BUFFERS.                  32000013
         SPACE 1                                                        32200013
         L     RG,PPISTDCB         SET INPUT DCB ADDRS IN RUN PROG      32400013
         L     RE,0(RG)                                                 32600013
         ST    RE,KADCB                                                 32800013
         SPACE 1                                                        33000013
         L     RB,PPILAB02        SET REG 1 = ADDRESS OF BUFFER LIST    33200013
         MVC   WAREA+2(2),PPILAB03+2                                    33400013
         MVC   WAREA+1(1),PPILAB03                                      33600013
         L     0,WAREA             SET NO. OF BUFFERS AND BUFFER SIZE   33800013
*                                  IN REG 0                             34000013
         SPACE 2                                                        34200013
         BUILDS (1),(0)                                                 34400013
         SPACE 2                                                        34600013
*   SET USER EOF SWITCH IN PPI, SINCE THERE IS NO USER EXIT             34800013
         SPACE 1                                                        35000013
         OI    PPISW1+7,X'80'                                           35200013
         SPACE 1                                                        35400013
         SPACE 1                                                        35600013
*IF 2314, OVERLAY RMAX CHECK IN R.P. RETURN TO IERRC9.                  35800013
         SPACE 1                                                        36000013
         TM    PPISW1+6,X'02'      2314 SORT                            36200013
         BCR   8,RO                NO, RETURN TO -RC9                   36400013
         SPACE 1                                                        36600013
         MVC   RDQ1035(4),KADQKON  OVERLAY RMAX CHECK                   36800013
         SPACE 1                                                        37000013
         BR    RO                  RETURN                               37200013
         SPACE 2                                                        37400013
*LIST OF WORK AREAS:                                                    37600013
         SPACE 1                                                        37800013
WAREA    DC    F'0'                                                     38000013
         SPACE 2                                                        38200013
*LIST OF CONSTANTS:                                                     38400013
         SPACE 1                                                        38600013
         DROP  RK                                                       38800013
         DROP  RL                                                       39000013
         USING IERRDQ,RL                                                39200013
KADQKON  B     RDQ1038             OVERLAY RMAX CHECK                   39400013
         EJECT                                                          39600013
IERRDQ   DSECT                     DUMMY RUNNING PROGRAM                39800013
         USING *,RL                THIS MODULE BASE REGISTER            40000013
         USING IERRCA,RN                                                40200013
IERDD1   B     RDQ1050             ENTRY FROM SORT NETWORK. G RECORDS   40400013
*                                    ARE IN THE TREE(ONCE ONLY)         40600013
         B     RDQ1060             ENTRY FROM EOF ROUTINE               40800013
         B     RDQ1010             NORMAL ENTRY WHILE FILLING TREE      41000013
*                                   WILL BE OVERLAID BY:                41200013
*                                   B  RDQ1020 WHEN RSA HAS BEEN FILLD  41400013
*                                   B  RDQ1065 AFTER INPUT EOF          41600013
         SPACE 2                                                        41800013
*        ENTRY TO REINITIALIZE IN ORDER TO BEGIN FILLING TREE           42000013
         SPACE 1                                                        42200013
         MVC   RDQ1040(8),KMOD5    REOVERLAY OVERLAID INSTRUCTIONS      42400013
         MVC   IERDD1+8(4),KMOD2                                        42600013
         L     RH,PPILAB08         LOAD ADDRESS OF RSA PARAM TABLE      42800013
         ST    RH,ADCONPTR         STORE                                43000013
         MVC   WADDRSA(8),0(RH)    MOVE NEW PARAMS INTO WORK AREA       43200013
*                                   FIRST WORD = ADDRESS NEXT RSA BIN   43400013
*                                   SECOND WORD = BIN BYTE COUNT MINUS  43600013
*                                   ONE RECORD LENGTH                   43800013
         L     RB,WADDRESS         LOAD REGISTER FOR MOVE INSTRUCTION   44000013
         LR    RC,RB               INITIALIZE RC IN CASE OF EXTRACT     44200013
         L     RD,WADDRSA            TO MOVE SAVED RECORD INTO RSA      44400013
         B     RDQ1035             BRANCH TO MOVE RECORD                44600013
         SPACE 2                                                        44800013
*NORMAL ENTRY FROM NETWORK WHILE FILLING TREE, ENTRY FROM ALGORITHM ON  45000013
*   OUTPUT EOS, NORMAL ENTRY FROM BLOCK WHILE RUNNING.                  45200013
         SPACE 1                                                        45400013
RDQ1010  L     RD,WADDRSA          LOAD UPDATED ADDRESS OF RSA          45600013
RDQ1020  L     RG,KADCB            ADDR OF THE INPUT DCB                45800013
         GET   (RG)                                                     46000013
         SPACE 1                                                        46200013
*GET RETURNS ADDR OF RCD IN INPUT BUFFER IN RB.                         46400013
         SPACE 1                                                        46600013
         ST    RB,WADDRESS         SAVE ADDRESS OF RECORD IN BUFFER     46800013
         LR    RC,RB              INITIALIZE RC IN CASE OF EXTRACT      47000013
         SPACE 2                                                        47200013
*        UPDATE RECORD COUNTER                                          47400013
         SPACE 1                                                        47600013
         L     RG,PPICOUNT                                              47800013
         LA    RG,1(RG)            INCR RCD COUNT BY 1                  48000013
         ST    RG,PPICOUNT                                              48200013
RDQ1035  L     RG,WRMAX            INCREMENT COUNTER FOR RMAX. RMAX =   48400013
         LA    RG,1(RG)              MAX NO OF RECORDS ON 1 REEL TAPE   48600013
         C     RG,PPIRMAX          HAVE RMAX RECORDS BEEN EXCEEDED?     48800013
         BH    RDQ1055             BRANCH ON YES                        49000013
         ST    RG,WRMAX            SAVE                                 49200013
         SPACE 2                                                        49400013
*LINK TO MOVE LIST WHICH MOVES THE RECORD FROM THE INPUT BUFFER TO RSA. 49600013
*INPUT BUFFER RCD ADDRESS IN RE. RSA RCD ADDRESS IN RF.                 49800013
         SPACE 1                                                        50000013
RDQ1038  LR    RF,RD               ADDRESS IN RSA TO MOVE INPUT RCD     50200013
         LR    RE,RB               INPUT RECORD ADDRESS                 50400013
         L     RP,PPIBDSVA+4       ADDRESS OF MOVE LIST                 50600013
         BALR  RO,RP                                                    50800013
         SPACE 2                                                        51000013
*UPDATE RSA TABLE PARAMETERS                                            51200013
         SPACE 1                                                        51400013
RDQ1040  LR    RF,RD               ADDR OF RCD IN RSA. WILL BE OVLAYED  51600013
*                                    BY BR TO NETWORK AFTER G+1 RCDS.   51800013
         A     RF,PPIBINSZ         UPDATE RSA ADDR TO NEXT BIN          52000013
         ST    RF,WADDRSA          STORE                                52200013
         L     RE,WBYTECNT         LOAD REMAINING BYTES IN RSA CHUNK    52400013
         S     RE,PPIBINSZ         SUBTRACT LENGTH OF NEXT RECORD       52600013
         BM    RDQ1045             BRANCH ON MINUS RESULT TO UPDATE PTR 52800013
         ST    RE,WBYTECNT         OTHERWISE STORE                      53000013
         SPACE 1                                                        53200013
*INTERFACE WITH SORT NETWORK DURING FILL OF TREE.                       53400013
         SPACE 1                                                        53600013
         L     RL,PPINET+4         ADDR OF NETWORK                      53800013
         B     4(RL)               BR TO FILL TREE                      54000013
         SPACE 2                                                        54200013
*UPDATE POINTER TO NEXT ENTRY IN RSA TABLE(EQUALS NEXT RSA AREA)        54400013
         SPACE 1                                                        54600013
RDQ1045  L     RH,ADCONPTR         LOAD ADDRESS IN RSA PARAM TABLE      54800013
         LA    RH,8(RH)                UPDATE TO NEXT TABLE ENTRY       55000013
         ST    RH,ADCONPTR             SAVE UPDATED POINTER TO TABLE    55200013
         MVC   WADDRSA(8),0(RH)    MOVE NEW PARAMS INTO WORK AREA       55400013
*                                   FIRST WORD = ADDRESS NEXT RSA BIN   55600013
*                                   SECOND WORD = BIN BYTE COUNT MINUS  55800013
*                                   ONE RECORD LENGTH                   56000013
         L     RL,PPINET+4         ADDRESS OF SORT NETWORK              56200013
         B     4(RL)               BRANCH TO FILL TREE                  56400013
         SPACE 2                                                        56600013
*SORT TREE HAS BEEN FILLED.  IN FUTURE ENTRIES TO THIS MODULE, RD WILL  56800013
*POINT TO THE WINNER RECORD IN RSA.  THE NEW RECORD WHICH HAS BEEN      57000013
*DEBLOCKED MUST BE MOVED TO THE LOCATION IN RSA INDICATED BY RD.  ALSO, 57200013
*THIS MODULE MUST NOW ENTER THE SORT NETWORK AT 12(RL).       THE       57400013
*FOLLOWING CODE MODIFIES THIS MODULE TO EFFECT THESE NEW REQUIREMENTS.  57600013
         SPACE 1                                                        57800013
RDQ1050  MVC   IERDD1+8(4),KMOD1   MOCIFY ENTRY BRANCH ADDRESS          58000013
         MVC   RDQ1040(8),KMOD3    MODIFY EXIT ADDRESS                  58200013
         B     RDQ1010             RETURN TO GET NEXT RECORD            58400013
         SPACE 1                                                        58600013
RDQ1055  SR    RE,RE               RMAX COUNT HAS BEEN EXCEEDED         58800013
         ST    RE,WRMAX            ZERO OUT COUNT FOR RMAX IN PROGRAM   59000013
         OI    PPISW1+7,X'40'      SET RMAX BIT IN PPI                  59200013
         SPACE 2                                                        59400013
*WHEN EOF HAS BEEN REACHED, THERE ARE NO MORE RECORDS TO BE DEBLOCKED   59600013
*BUT THE SORT NETWORK MUST EMPTY ITS TREE.  FUTURE ENTRIES TO THIS      59800013
*MODULE DO NO PROCESSING, BUT MERELY EXIT TO THE SORT NETWORK AT        60000013
*16(RL).  THE FOLLOWING CODING MODIFIES THE PRESENT ENTRY POINT TO      60200013
*EFFECT THIS CHANGE AND THEN EXITS TO THE SORT NETWORK AT 8(RL), THE    60400013
*EOF ENTRY.                                                             60600013
         SPACE 1                                                        60800013
RDQ1060  MVC   IERDD1+8(4),KMOD4   BR DIRECTLY TO SORT NETWORK          61000013
         SPACE 2                                                        61200013
*INTERFACE TO SORT NETWORK ON EOF.                                      61400013
         SPACE 1                                                        61600013
         L     RL,PPINET+4         ADDR OF SORT NETWORK                 61800013
         B     8(RL)                                                    62000013
         SPACE 2                                                        62200013
*        INTERFACE TO SORT NETWORK TO FLUSH TREE                        62400013
         SPACE 1                                                        62600013
RDQ1065  L     RL,PPINET+4         BRANCH IMMEDIATELY BACK TO NETWORK   62800013
         B     16(RL)                AFTER INPUT EOF                    63000013
         SPACE 2                                                        63200013
*CONSTANTS USED BY THE MODULE:                                          63400013
         SPACE 1                                                        63600013
KMOD1    B     RDQ1020             OVERLAY RDQ1010 AFTER G+1 RCDS       63800013
KMOD2    B     RDQ1010             TO RESTORE NETWORK ENTRY FOR FILLING 64000013
KMOD3    L     RL,PPINET+4         OVERLAY RDQ1040 AFTER G+1 RCDS       64200013
         B     12(RL)                NORMAL BR TO THE NETWORK           64400013
KMOD4    B     RDQ1065                                                  64600013
KMOD5    LR    RF,RD               TO RESTORE INSTRUCTIONS OVERLAID     64800013
         A     RF,PPIBINSZ           BY BRANCH TO NETWORK AFTER TREE    65000013
         ST    RF,WADDRSA            IS FILLED                          65200013
KADCB    DC    F'0'                INPUT DCB ADDR LOADED BY A.P.        65400013
         SPACE 2                                                        65600013
*LIST OF WORK AREAS/TABLES:                                             65800013
         SPACE 1                                                        66000013
WADDRESS DS    F                   ADDRESS OF RECORD FROM LAST 'GET'    66200013
WRMAX    DC    F'0'                COUNT TO COMPARE AGAINST PPIRMAX     66400013
WADDRSA  DS    F                   UPDATED ADDRESS OF RSA               66600013
WBYTECNT DS    F                   REMAINING BYTE COUNT IN RSA CHUNK    66800013
ADCONPTR  DS   F                                                        67000013
         EJECT                                                          67200013
         SMPPI                                                          67400013
         END                                                            67600013
